data/qcsrc/server/cl_player.qc

   1
   2 // changes by LordHavoc on 03/29/04 and 03/30/04 at Vermeulen's request
   3 // merged player_run and player_stand to player_anim
   4 // added death animations to player_anim
   5 // can now spawn thrown weapons from anywhere, not just from players
   6 // thrown weapons now fade out after 20 seconds
   7 // created PlayerGib function
   8 // PlayerDie no longer uses hitloc or damage
   9 // PlayerDie now supports dying animations as well as gibbing
  10 // cleaned up PlayerDie a lot
  11 // added CopyBody
  12
  13 .entity pusher;
  14 .float pushltime;
  15
  16 void CopyBody(float keepvelocity)
  17 {
  18         local entity oldself;
  19         if (self.effects & EF_NODRAW)
  20                 return;
  21         oldself = self;
  22         self = spawn();
  23         self.enemy = oldself;
  24         self.lip = oldself.lip;
  25         self.colormap = oldself.colormap;
  26         self.iscreature = oldself.iscreature;
  27         self.angles = oldself.angles;
  28         self.avelocity = oldself.avelocity;
  29         self.classname = "body";
  30         self.damageforcescale = oldself.damageforcescale;
  31         self.effects = oldself.effects;
  32         self.event_damage = oldself.event_damage;
  33         self.animstate_startframe = oldself.animstate_startframe;
  34         self.animstate_numframes = oldself.animstate_numframes;
  35         self.animstate_framerate = oldself.animstate_framerate;
  36         self.animstate_starttime = oldself.animstate_starttime;
  37         self.animstate_endtime = oldself.animstate_endtime;
  38         self.animstate_override = oldself.animstate_override;
  39         self.animstate_looping = oldself.animstate_looping;
  40         self.frame = oldself.frame;
  41         self.dead_frame = oldself.dead_frame;
  42         self.pain_finished = oldself.pain_finished;
  43         self.health = oldself.health;
  44         self.armorvalue = oldself.armorvalue;
  45         self.armortype = oldself.armortype;
  46         self.model = oldself.model;
  47         self.modelindex = oldself.modelindex;
  48         self.movetype = oldself.movetype;
  49         self.nextthink = oldself.nextthink;
  50         self.skin = oldself.skin;
  51         self.solid = oldself.solid;
  52         self.takedamage = oldself.takedamage;
  53         self.think = oldself.think;
  54         self.gibrandom = oldself.gibrandom;
  55         self.customizeentityforclient = oldself.customizeentityforclient;
  56         if (keepvelocity == 1)
  57                 self.velocity = oldself.velocity;
  58         self.oldvelocity = self.velocity;
  59         self.fade_time = oldself.fade_time;
  60         self.fade_rate = oldself.fade_rate;
  61         //self.weapon = oldself.weapon;
  62         setorigin(self, oldself.origin);
  63         setsize(self, oldself.mins, oldself.maxs);
  64         self.oldorigin = oldself.origin;
  65         self = oldself;
  66 }
  67
  68 float animparseerror;
  69 vector animparseline(float animfile)
  70 {
  71         local string line;
  72         local float c;
  73         local vector anim;
  74         if (animfile < 0)
  75                 return '0 1 2';
  76         line = fgets(animfile);
  77         c = tokenize(line);
  78         if (c != 3)
  79         {
  80                 animparseerror = TRUE;
  81                 return '0 1 2';
  82         }
  83         anim_x = stof(argv(0));
  84         anim_y = stof(argv(1));
  85         anim_z = stof(argv(2));
  86         // don't allow completely bogus values
  87         if (anim_x < 0 || anim_y < 1 || anim_z < 0.001)
  88                 anim = '0 1 2';
  89         return anim;
  90 };
  91
  92 void player_setupanimsformodel()
  93 {
  94         local string animfilename;
  95         local float animfile;
  96         // defaults for legacy .zym models without animinfo files
  97         self.anim_die1 = '0 1 0.5'; // 2 seconds
  98         self.anim_die2 = '1 1 0.5'; // 2 seconds
  99         self.anim_draw = '2 1 3'; // TODO: analyze models and set framerate
 100         self.anim_duck = '3 1 100'; // this anim seems bogus in most models, so make it play VERY briefly!
 101         self.anim_duckwalk = '4 1 1';
 102         self.anim_duckjump = '5 1 100'; // zym anims keep playing until changed, so this only has to start the anim, landing will end it
 103         self.anim_duckidle = '6 1 1';
 104         self.anim_idle = '7 1 1';
 105         self.anim_jump = '8 1 100'; // zym anims keep playing until changed, so this only has to start the anim, landing will end it
 106         self.anim_pain1 = '9 1 2'; // 0.5 seconds
 107         self.anim_pain2 = '10 1 2'; // 0.5 seconds
 108         self.anim_shoot = '11 1 5'; // TODO: analyze models and set framerate
 109         self.anim_taunt = '12 1 1'; // FIXME?  there is no code using this anim
 110         self.anim_run = '13 1 1';
 111         self.anim_runbackwards = '14 1 1';
 112         self.anim_strafeleft = '15 1 1';
 113         self.anim_straferight = '16 1 1';
 114         self.anim_dead1 = '17 1 1';
 115         self.anim_dead2 = '18 1 1';
 116         self.anim_forwardright = '19 1 1';
 117         self.anim_forwardleft = '20 1 1';
 118         self.anim_backright = '21 1 1';
 119         self.anim_backleft  = '22 1 1';
 120         animparseerror = FALSE;
 121         animfilename = strcat(self.model, ".animinfo");
 122         animfile = fopen(animfilename, FILE_READ);
 123         if (animfile >= 0)
 124         {
 125                 self.anim_die1         = animparseline(animfile);
 126                 self.anim_die2         = animparseline(animfile);
 127                 self.anim_draw         = animparseline(animfile);
 128                 self.anim_duck         = animparseline(animfile);
 129                 self.anim_duckwalk     = animparseline(animfile);
 130                 self.anim_duckjump     = animparseline(animfile);
 131                 self.anim_duckidle     = animparseline(animfile);
 132                 self.anim_idle         = animparseline(animfile);
 133                 self.anim_jump         = animparseline(animfile);
 134                 self.anim_pain1        = animparseline(animfile);
 135                 self.anim_pain2        = animparseline(animfile);
 136                 self.anim_shoot        = animparseline(animfile);
 137                 self.anim_taunt        = animparseline(animfile);
 138                 self.anim_run          = animparseline(animfile);
 139                 self.anim_runbackwards = animparseline(animfile);
 140                 self.anim_strafeleft   = animparseline(animfile);
 141                 self.anim_straferight  = animparseline(animfile);
 142                 self.anim_forwardright = animparseline(animfile);
 143                 self.anim_forwardleft  = animparseline(animfile);
 144                 self.anim_backright    = animparseline(animfile);
 145                 self.anim_backleft     = animparseline(animfile);
 146                 fclose(animfile);
 147
 148                 // derived anims
 149                 self.anim_dead1 = '0 1 1' + '1 0 0' * (self.anim_die1_x + self.anim_die1_y - 1);
 150                 self.anim_dead2 = '0 1 1' + '1 0 0' * (self.anim_die2_x + self.anim_die2_y - 1);
 151
 152                 if (animparseerror)
 153                         print("Parse error in ", animfilename, ", some player animations are broken\n");
 154         }
 155         else
 156                 dprint("File ", animfilename, " not found, assuming legacy .zym model animation timings\n");
 157         // reset animstate now
 158         player_setanim(self.anim_idle, TRUE, FALSE, TRUE);
 159 };
 160
 161 void player_setanim(vector anim, float looping, float override, float restart)
 162 {
 163         if (!restart)
 164         if (anim_x == self.animstate_startframe)
 165         if (anim_y == self.animstate_numframes)
 166         if (anim_z == self.animstate_framerate)
 167                 return;
 168         self.animstate_startframe = anim_x;
 169         self.animstate_numframes = anim_y;
 170         self.animstate_framerate = anim_z;
 171         self.animstate_starttime = time;
 172         self.animstate_endtime = time + self.animstate_numframes / self.animstate_framerate;
 173         self.animstate_looping = looping;
 174         self.animstate_override = override;
 175         self.frame = self.animstate_startframe;
 176 };
 177
 178 void player_updateframe()
 179 {
 180         if (time >= self.animstate_endtime)
 181         {
 182                 if (self.animstate_looping)
 183                 {
 184                         self.animstate_starttime = self.animstate_endtime;
 185                         self.animstate_endtime = self.animstate_endtime + self.animstate_numframes / self.animstate_framerate;
 186                 }
 187                 self.animstate_override = FALSE;
 188         }
 189         self.frame = self.animstate_startframe + bound(0, (time - self.animstate_starttime) * self.animstate_framerate, self.animstate_numframes - 1);
 190 };
 191
 192 void player_anim (void)
 193 {
 194         player_updateframe();
 195
 196         if (self.deadflag != DEAD_NO)
 197         {
 198                 if (time > self.animstate_endtime)
 199                 {
 200                         if (self.maxs_z > 5)
 201                         {
 202                                 self.maxs_z = 5;
 203                                 setsize(self, self.mins, self.maxs);
 204                         }
 205                         self.frame = self.dead_frame;
 206                 }
 207                 return;
 208         }
 209
 210         if (!self.animstate_override)
 211         {
 212                 if (!(self.flags & FL_ONGROUND))
 213                 {
 214                         if (self.crouch)
 215                                 player_setanim(self.anim_duckjump, FALSE, TRUE, FALSE);
 216                         else
 217                                 player_setanim(self.anim_jump, FALSE, TRUE, FALSE);
 218                 }
 219                 else if (self.crouch)
 220                 {
 221                         if (self.movement_x * self.movement_x + self.movement_y * self.movement_y > 20)
 222                                 player_setanim(self.anim_duckwalk, TRUE, FALSE, FALSE);
 223                         else
 224                                 player_setanim(self.anim_duckidle, TRUE, FALSE, FALSE);
 225                 }
 226                 else if ((self.movement_x * self.movement_x + self.movement_y * self.movement_y) > 20)
 227                 {
 228                         if (self.movement_x > 0 && self.movement_y == 0)
 229                                 player_setanim(self.anim_run, TRUE, FALSE, FALSE);
 230                         else if (self.movement_x < 0 && self.movement_y == 0)
 231                                 player_setanim(self.anim_runbackwards, TRUE, FALSE, FALSE);
 232                         else if (self.movement_x == 0 && self.movement_y > 0)
 233                                 player_setanim(self.anim_straferight, TRUE, FALSE, FALSE);
 234                         else if (self.movement_x == 0 && self.movement_y < 0)
 235                                 player_setanim(self.anim_strafeleft, TRUE, FALSE, FALSE);
 236                         else if (self.movement_x > 0 && self.movement_y > 0)
 237                                 player_setanim(self.anim_forwardright, TRUE, FALSE, FALSE);
 238                         else if (self.movement_x > 0 && self.movement_y < 0)
 239                                 player_setanim(self.anim_forwardleft, TRUE, FALSE, FALSE);
 240                         else if (self.movement_x < 0 && self.movement_y > 0)
 241                                 player_setanim(self.anim_backright, TRUE, FALSE, FALSE);
 242                         else if (self.movement_x < 0 && self.movement_y < 0)
 243                                 player_setanim(self.anim_backleft, TRUE, FALSE, FALSE);
 244                         else
 245                                 player_setanim(self.anim_run, TRUE, FALSE, FALSE);
 246                 }
 247                 else
 248                         player_setanim(self.anim_idle, TRUE, FALSE, FALSE);
 249         }
 250 }
 251 //End change by Supajoe on 11:44 PM EST 11/16/03 (Subject: Player animations)
 252
 253 void SpawnThrownWeapon (vector org, float w)
 254 {
 255         W_ThrowWeapon(randomvec() * 100 + '0 0 200', org - self.origin, FALSE);
 256 }
 257
 258 void PlayerCorpseDamage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 259 {
 260         local float take, save;
 261         if(sv_gentle < 1)
 262                 pointparticles(particleeffectnum("blood"), hitloc, force, bound(0, damage, 200));
 263         // damage resistance (ignore most of the damage from a bullet or similar)
 264         damage = max(damage - 5, 1);
 265
 266         save = bound(0, damage * cvar("g_balance_armor_blockpercent"), self.armorvalue);
 267         take = bound(0, damage - save, damage);
 268
 269         if (save > 10)
 270                 sound (self, CHAN_IMPACT, "misc/armorimpact.wav", VOL_BASE, ATTN_NORM);
 271         else if (take > 30)
 272                 sound (self, CHAN_IMPACT, "misc/bodyimpact2.wav", VOL_BASE, ATTN_NORM);
 273         else if (take > 10)
 274                 sound (self, CHAN_IMPACT, "misc/bodyimpact1.wav", VOL_BASE, ATTN_NORM);
 275
 276         if(sv_gentle < 1) {
 277                 if (take > 50)
 278                         TossGib (world, "models/gibs/chunk.mdl", hitloc, force * -0.1,1);
 279                 if (take > 100)
 280                         TossGib (world, "models/gibs/chunk.mdl", hitloc, force * -0.2,1);
 281         }
 282
 283         if (!(self.flags & FL_GODMODE))
 284         {
 285                 self.armorvalue = self.armorvalue - save;
 286                 self.health = self.health - take;
 287                 // pause regeneration for 5 seconds
 288                 self.pauseregen_finished = max(self.pauseregen_finished, time + cvar("g_balance_pause_health_regen"));
 289         }
 290         self.dmg_save = self.dmg_save + save;//max(save - 10, 0);
 291         self.dmg_take = self.dmg_take + take;//max(take - 10, 0);
 292         self.dmg_inflictor = inflictor;
 293
 294         if (self.health <= -50)
 295         {
 296                 // don't use any animations as a gib
 297                 self.frame = 0;
 298                 self.dead_frame = 0;
 299                 // view just above the floor
 300                 self.view_ofs = '0 0 4';
 301
 302                 // make a juicy mess
 303                 local float multiplier;
 304                 multiplier = 1;
 305                 if (cvar("ekg"))
 306                         multiplier = 5;
 307
 308
 309                 // make a meaty mess
 310                 TossGib (self, "models/gibs/eye.md3", self.origin + self.view_ofs, self.velocity + randomvec() * 150,0);
 311
 312                 if(sv_gentle < 1) {
 313                         te_bloodshower (self.origin + self.mins, self.origin + self.maxs, 1200 * multiplier, 1000);
 314                         TossGib (world, "models/gibs/bloodyskull.md3", self.origin + self.view_ofs, self.velocity,0);
 315
 316                         local float c;
 317                         c = 0;
 318
 319                         while (c < multiplier)
 320                         {
 321                                 c = c + 1;
 322                                 //TossGib (world, "models/gibs/gib1.md3", self.origin, self.velocity + randomvec() * 450,0);
 323                                 //TossGib (world, "models/gibs/gib2.md3", self.origin, self.velocity + randomvec() * 450,0);
 324                                 //TossGib (world, "models/gibs/gib3.md3", self.origin, self.velocity + randomvec() * 450,0);
 325                                 //TossGib (world, "models/gibs/gib4.md3", self.origin, self.velocity + randomvec() * 450,0);
 326                                 //TossGib (world, "models/gibs/gib5.md3", self.origin, self.velocity + randomvec() * 450,0);
 327                                 //TossGib (world, "models/gibs/gib6.md3", self.origin, self.velocity + randomvec() * 450,0);
 328
 329                                 TossGib (world, "models/gibs/arm.md3", self.origin + self.view_ofs, self.velocity + randomvec() * (random() * 120 + 90),0);
 330                                 TossGib (world, "models/gibs/arm.md3", self.origin + self.view_ofs, self.velocity + randomvec() * (random() * 120 + 90),0);
 331                                 //TossGib (world, "models/gibs/arm.md3", self.origin + self.view_ofs, self.velocity + randomvec() * 150,0);
 332                                 //TossGib (world, "models/gibs/arm.md3", self.origin + self.view_ofs, self.velocity + randomvec() * 150,0);
 333                                 TossGib (world, "models/gibs/chest.md3", self.origin + self.view_ofs * 0.5, self.velocity + randomvec() * (random() * 120 + 80),0);
 334                                 //TossGib (world, "models/gibs/smallchest.md3", self.origin + self.view_ofs, self.velocity + randomvec() * 150,0);
 335                                 TossGib (world, "models/gibs/smallchest.md3", self.origin + self.view_ofs, self.velocity + randomvec() * (random() * 120 + 80),0);
 336                                 TossGib (world, "models/gibs/leg1.md3", self.origin + self.view_ofs * -0.2, self.velocity + randomvec() * (random() * 120 + 85),0);
 337                                 TossGib (world, "models/gibs/leg2.md3", self.origin + self.view_ofs * -0.4, self.velocity + randomvec() * (random() * 120 + 85),0);
 338                                 //TossGib (world, "models/gibs/leg1.md3", self.origin + self.view_ofs * -0.2, self.velocity + randomvec() * 150,0);
 339                                 //TossGib (world, "models/gibs/leg2.md3", self.origin + self.view_ofs * -0.4, self.velocity + randomvec() * 150,0);
 340
 341                                 // these splat on impact
 342                                 TossGib (world, "models/gibs/chunk.mdl", self.origin, self.velocity + randomvec() * 450,1);
 343                                 TossGib (world, "models/gibs/chunk.mdl", self.origin, self.velocity + randomvec() * 450,1);
 344                                 TossGib (world, "models/gibs/chunk.mdl", self.origin, self.velocity + randomvec() * 450,1);
 345                                 TossGib (world, "models/gibs/chunk.mdl", self.origin, self.velocity + randomvec() * 450,1);
 346                         }
 347                         sound (self, CHAN_VOICE, "misc/gib.wav", VOL_BASE, ATTN_NORM);
 348                 }
 349         }
 350 }
 351
 352 void ClientKill_Now_TeamChange();
 353
 354 void PlayerDamage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 355 {
 356         local float take, save, waves, sdelay;
 357         float painsequence;
 358
 359         damage = damage * bound(1.0, self.cvar_cl_handicap, 100.0);
 360         if(sv_gentle > 0) {
 361                 pointparticles(particleeffectnum("damage_hit"), hitloc, force, bound(0, damage, 200));
 362         } else {
 363                 pointparticles(particleeffectnum("blood"), hitloc, force, bound(0, damage, 200));
 364         }
 365
 366         if(g_arena)
 367         if(numspawned < 2)
 368                 return;
 369
 370         if (!g_minstagib)
 371         {
 372                 save = bound(0, damage * cvar("g_balance_armor_blockpercent"), self.armorvalue);
 373                 take = bound(0, damage - save, damage);
 374         }
 375         else
 376         {
 377                 save = 0;
 378                 take = damage;
 379         }
 380
 381         if (save > 10)
 382                 sound (self, CHAN_IMPACT, "misc/armorimpact.wav", VOL_BASE, ATTN_NORM);
 383         else if (take > 30)
 384                 sound (self, CHAN_IMPACT, "misc/bodyimpact2.wav", VOL_BASE, ATTN_NORM);
 385         else if (take > 10)
 386                 sound (self, CHAN_IMPACT, "misc/bodyimpact1.wav", VOL_BASE, ATTN_NORM); // FIXME possibly remove them?
 387
 388         if (take > 50)
 389                 TossGib (world, "models/gibs/chunk.mdl", hitloc, force * -0.1,1);
 390         if (take > 100)
 391                 TossGib (world, "models/gibs/chunk.mdl", hitloc, force * -0.2,1);
 392
 393         if (time > self.spawnshieldtime)
 394         {
 395                 if (!(self.flags & FL_GODMODE))
 396                 {
 397                         self.armorvalue = self.armorvalue - save;
 398                         self.health = self.health - take;
 399                         // pause regeneration for 5 seconds
 400                         self.pauseregen_finished = max(self.pauseregen_finished, time + cvar("g_balance_pause_health_regen"));
 401
 402                         if (time > self.pain_finished)          //Don't switch pain sequences like crazy
 403                         {
 404                                 self.pain_finished = time + 0.5;        //Supajoe
 405
 406                                 if(sv_gentle < 1) {
 407                                         if (random() > 0.5)
 408                                                 player_setanim(self.anim_pain1, FALSE, TRUE, TRUE);
 409                                         else
 410                                                 player_setanim(self.anim_pain2, FALSE, TRUE, TRUE);
 411
 412                                         if(deathtype != IT_LASER || attacker != self || self.health < 2 * cvar("g_balance_laser_primary_damage") * cvar("g_balance_selfdamagepercent") + 1)
 413                                         // exclude pain sounds for laserjumps as long as you aren't REALLY low on health and would die of the next two
 414                                         {
 415                                                 if(self.health > 75) // TODO make a "gentle" version?
 416                                                         PlayerSound(playersound_pain100, CHAN_AUTO, 0);
 417                                                 else if(self.health > 50)
 418                                                         PlayerSound(playersound_pain75, CHAN_AUTO, 0);
 419                                                 else if(self.health > 25)
 420                                                         PlayerSound(playersound_pain50, CHAN_AUTO, 0);
 421                                                 else if(self.health > 1)
 422                                                         PlayerSound(playersound_pain25, CHAN_AUTO, 0);
 423                                         }
 424                                 }
 425
 426                                 // throw off bot aim temporarily
 427                                 local float shake;
 428                                 shake = damage * 5 / (bound(0,skill,100) + 1);
 429                                 self.v_angle_x = self.v_angle_x + (random() * 2 - 1) * shake;
 430                                 self.v_angle_y = self.v_angle_y + (random() * 2 - 1) * shake;
 431                         }
 432                 }
 433                 else
 434                         self.max_armorvalue += (save + take);
 435         }
 436         self.dmg_save = self.dmg_save + save;//max(save - 10, 0);
 437         self.dmg_take = self.dmg_take + take;//max(take - 10, 0);
 438         self.dmg_inflictor = inflictor;
 439
 440         if(attacker == self)
 441         {
 442                 // don't reset pushltime for self damage as it may be an attempt to
 443                 // escape a lava pit or similar
 444                 //self.pushltime = 0;
 445         }
 446         else if(attacker.classname == "player" || attacker.classname == "gib")
 447         {
 448                 self.pusher = attacker;
 449                 self.pushltime = time + cvar("g_maxpushtime");
 450         }
 451         else if(time < self.pushltime)
 452         {
 453                 attacker = self.pusher;
 454                 self.pushltime = max(self.pushltime, time + 0.6);
 455         }
 456         else
 457                 self.pushltime = 0;
 458
 459         if (self.health < 1)
 460         {
 461                 float defer_ClientKill_Now_TeamChange;
 462                 defer_ClientKill_Now_TeamChange = FALSE;
 463
 464                 if(sv_gentle < 1) // TODO make a "gentle" version?
 465                 {
 466                         if(deathtype == DEATH_DROWN)
 467                                 PlayerSound(playersound_drown, CHAN_AUTO, 0);
 468                         else
 469                                 PlayerSound(playersound_death, CHAN_AUTO, 0);
 470                 }
 471
 472                 // get rid of kill indicator
 473                 if(self.killindicator)
 474                 {
 475                         remove(self.killindicator);
 476                         self.killindicator = world;
 477                         if(self.killindicator_teamchange)
 478                                 defer_ClientKill_Now_TeamChange = TRUE;
 479
 480                         if(self.classname == "body")
 481                         if(deathtype == DEATH_KILL)
 482                         {
 483                                 // for the lemmings fans, a small harmless explosion
 484                                 pointparticles(particleeffectnum("rocket_explode"), self.origin, '0 0 0', 1);
 485                         }
 486                 }
 487
 488                 // become fully visible
 489                 self.alpha = 1;
 490                 // clear selected player display
 491                 ClearSelectedPlayer();
 492                 // throw a weapon
 493                 SpawnThrownWeapon (self.origin + (self.mins + self.maxs) * 0.5, self.switchweapon);
 494                 // print an obituary message
 495                 Obituary (attacker, self, deathtype);
 496                 DropAllRunes(self);
 497                 if(self == attacker)
 498                         kh_Key_DropAll(self, TRUE);
 499                 else if(attacker.classname == "player" || attacker.classname == "gib")
 500                         kh_Key_DropAll(self, FALSE);
 501                 else
 502                         kh_Key_DropAll(self, TRUE);
 503                 if(self.flagcarried)
 504                         DropFlag(self.flagcarried);
 505                 // clear waypoints
 506                 WaypointSprite_PlayerDead();
 507                 // make the corpse upright (not tilted)
 508                 self.angles_x = 0;
 509                 self.angles_z = 0;
 510                 // don't spin
 511                 self.avelocity = '0 0 0';
 512                 // view from the floor
 513                 self.view_ofs = '0 0 -8';
 514                 // toss the corpse
 515                 self.movetype = MOVETYPE_TOSS;
 516                 // shootable corpse
 517                 self.solid = SOLID_CORPSE;
 518                 // don't stick to the floor
 519                 self.flags = self.flags - (self.flags & FL_ONGROUND);
 520                 // dying animation
 521                 self.deadflag = DEAD_DYING;
 522                 // when to allow respawn
 523                 sdelay = 0;
 524                 waves = 0;
 525                 if(cvar("g_respawn_mapsettings"))
 526                 {
 527                         sdelay = cvar("g_respawn_mapsettings_delay");
 528                         waves = cvar("g_respawn_mapsettings_waves");
 529                 }
 530                 if(!sdelay)
 531                         sdelay = cvar(strcat("g_", GetGametype(), "_respawn_delay"));
 532                 if(!sdelay)
 533                         sdelay = cvar("g_respawn_delay");
 534                 if(!waves)
 535                         waves = cvar(strcat("g_", GetGametype(), "_respawn_waves"));
 536                 if(!waves)
 537                         waves = cvar("g_respawn_waves");
 538                 if(waves)
 539                         self.death_time = ceil((time + sdelay) / waves) * waves;
 540                 else
 541                         self.death_time = time + sdelay;
 542                 if((sdelay + waves >= 5.0) && (self.death_time - time > 1.75))
 543                         self.respawn_countdown = 10; // first number to count down from is 10
 544                 else
 545                         self.respawn_countdown = -1; // do not count down
 546                 if (random() < 0.5)
 547                 {
 548                         player_setanim(self.anim_die1, FALSE, TRUE, TRUE);
 549                         self.dead_frame = self.anim_dead1_x;
 550                 }
 551                 else
 552                 {
 553                         player_setanim(self.anim_die2, FALSE, TRUE, TRUE);
 554                         self.dead_frame = self.anim_dead2_x;
 555                 }
 556                 // set damage function to corpse damage
 557                 self.event_damage = PlayerCorpseDamage;
 558                 // call the corpse damage function just in case it wants to gib
 559                 self.event_damage(inflictor, attacker, 0, deathtype, hitloc, force);
 560                 // set up to fade out later
 561                 SUB_SetFade (self, time + 12 + random () * 4, 1);
 562
 563                 // remove laserdot
 564                 if(self.weaponentity)
 565                         if(self.weaponentity.lasertarget)
 566                                 remove(self.weaponentity.lasertarget);
 567
 568                 if(clienttype(self) == CLIENTTYPE_REAL)
 569                 {
 570                         self.fixangle = TRUE;
 571                         //msg_entity = self;
 572                         //WriteByte (MSG_ONE, SVC_SETANGLE);
 573                         //WriteAngle (MSG_ONE, self.v_angle_x);
 574                         //WriteAngle (MSG_ONE, self.v_angle_y);
 575                         //WriteAngle (MSG_ONE, 80);
 576                 }
 577
 578                 if(g_arena)
 579                         Spawnqueue_Unmark(self);
 580
 581                 if(defer_ClientKill_Now_TeamChange)
 582                         ClientKill_Now_TeamChange();
 583
 584                 if(sv_gentle > 0) {
 585                         // remove corpse
 586                         PlayerCorpseDamage (inflictor, attacker, 100.0, deathtype, hitloc, force);
 587                         pointparticles(particleeffectnum("damage_dissolve"), self.origin, force, 1);
 588                 }
 589         }
 590 }
 591
 592 float UpdateSelectedPlayer_countvalue(float v)
 593 {
 594         return max(0, (v - 1.0) / 0.5);
 595 }
 596
 597 // returns: -2 if no hit, otherwise cos of the angle
 598 // uses the global v_angle
 599 float UpdateSelectedPlayer_canSee(entity p, float mincosangle, float maxdist)
 600 {
 601         vector so, d;
 602         float c;
 603
 604         if(p == self)
 605                 return -2;
 606
 607         if(p.deadflag)
 608                 return -2;
 609
 610         so = self.origin + self.view_ofs;
 611         d = p.origin - so;
 612
 613         // misaimed?
 614         if(dist_point_line(d, '0 0 0', v_forward) > maxdist)
 615                 return -2;
 616
 617         // now find the cos of the angle...
 618         c = normalize(d) * v_forward;
 619
 620         if(c <= mincosangle)
 621                 return -2;
 622
 623         traceline(so, p.origin, MOVE_NOMONSTERS, self);
 624         if(trace_fraction < 1)
 625                 return -2;
 626
 627         return c;
 628 }
 629
 630 void ClearSelectedPlayer()
 631 {
 632         if(self.selected_player)
 633         {
 634                 centerprint_expire(self, CENTERPRIO_POINT);
 635                 self.selected_player = world;
 636                 self.selected_player_display_needs_update = FALSE;
 637         }
 638 }
 639
 640 void UpdateSelectedPlayer()
 641 {
 642         entity selected;
 643         float selected_score;
 644         selected = world;
 645         selected_score = 0.95; // 18 degrees
 646
 647         if(!cvar("sv_allow_shownames"))
 648                 return;
 649
 650         if(clienttype(self) != CLIENTTYPE_REAL)
 651                 return;
 652
 653         if(self.cvar_cl_shownames == 0)
 654                 return;
 655
 656         if(self.cvar_cl_shownames == 1 && !teams_matter)
 657                 return;
 658
 659         makevectors(self.v_angle); // sets v_forward
 660
 661         // 1. cursor trace is always right
 662         if(self.cursor_trace_ent && self.cursor_trace_ent.classname == "player" && !self.cursor_trace_ent.deadflag)
 663         {
 664                 selected = self.cursor_trace_ent;
 665         }
 666         else
 667         {
 668                 // 2. if we don't have a cursor trace, find the player which is least
 669                 //    mis-aimed at
 670                 entity p;
 671                 FOR_EACH_PLAYER(p)
 672                 {
 673                         float c;
 674                         c = UpdateSelectedPlayer_canSee(p, selected_score, 100); // 100 = 2.5 meters
 675                         if(c >= -1)
 676                         {
 677                                 selected = p;
 678                                 selected_score = c;
 679                         }
 680                 }
 681         }
 682
 683         if(selected)
 684         {
 685                 self.selected_player_display_timeout = time + self.cvar_scr_centertime;
 686         }
 687         else
 688         {
 689                 if(time < self.selected_player_display_timeout)
 690                         if(UpdateSelectedPlayer_canSee(self.selected_player, 0.7, 200) >= -1) // 5 meters, 45 degrees
 691                                 selected = self.selected_player;
 692         }
 693
 694         if(selected)
 695         {
 696                 if(selected == self.selected_player)
 697                 {
 698                         float save;
 699                         save = UpdateSelectedPlayer_countvalue(self.selected_player_count);
 700                         self.selected_player_count = self.selected_player_count + frametime;
 701                         if(save != UpdateSelectedPlayer_countvalue(self.selected_player_count))
 702                         {
 703                                 string namestr, healthstr;
 704                                 namestr = playername(selected);
 705                                 if(teams_matter)
 706                                 {
 707                                         healthstr = ftos(floor(selected.health));
 708                                         if(self.team == selected.team)
 709                                         {
 710                                                 namestr = strcat(namestr, " (", healthstr, "%)");
 711                                                 self.selected_player_display_needs_update = TRUE;
 712                                         }
 713                                 }
 714                                 centerprint_atprio(self, CENTERPRIO_POINT, namestr);
 715                         }
 716                 }
 717                 else
 718                 {
 719                         ClearSelectedPlayer();
 720                         self.selected_player = selected;
 721                         self.selected_player_time = time;
 722                         self.selected_player_count = 0;
 723                         self.selected_player_display_needs_update = FALSE;
 724                 }
 725         }
 726         else
 727         {
 728                 ClearSelectedPlayer();
 729         }
 730
 731         if(self.selected_player)
 732                 self.last_selected_player = self.selected_player;
 733 }
 734
 735 float GetVoiceMessageTeamsayType(string type)
 736 {
 737         if(type == "taunt")
 738                 return 0;
 739         if(type == "teamshoot")
 740                 return 2;
 741         return 1;
 742 }
 743
 744 string allvoicesamples = "attack attackinfive coverme defend freelance incoming meet needhelp seenflag taunt teamshoot";
 745 float GetPlayerSoundSampleField_notFound;
 746 float GetPlayerSoundSampleField_fixed;
 747 .string GetVoiceMessageSampleField(string type)
 748 {
 749         GetPlayerSoundSampleField_notFound = 0;
 750         GetPlayerSoundSampleField_fixed = 0;
 751         switch(type)
 752         {
 753                 case "attack":       return playersound_attack;
 754                 case "attackinfive": return playersound_attackinfive;
 755                 case "coverme":      return playersound_coverme;
 756                 case "defend":       return playersound_defend;
 757                 case "freelance":    return playersound_freelance;
 758                 case "incoming":     return playersound_incoming;
 759                 case "meet":         return playersound_meet;
 760                 case "needhelp":     return playersound_needhelp;
 761                 case "seenflag":     return playersound_seenflag;
 762                 case "taunt":        return playersound_taunt;
 763                 case "teamshoot":    return playersound_teamshoot;
 764         }
 765         GetPlayerSoundSampleField_notFound = 1;
 766         return playersound_taunt;
 767 }
 768
 769 .string GetPlayerSoundSampleField(string type)
 770 {
 771         GetPlayerSoundSampleField_notFound = 0;
 772         GetPlayerSoundSampleField_fixed = 0;
 773         switch(type)
 774         {
 775                 case "death":        return playersound_death;
 776                 case "drown":        return playersound_drown;
 777                 case "falling":      return playersound_falling;
 778                 case "gasp":         return playersound_gasp;
 779                 case "jump":         return playersound_jump;
 780                 case "pain25":       return playersound_pain25;
 781                 case "pain50":       return playersound_pain50;
 782                 case "pain75":       return playersound_pain75;
 783                 case "pain100":      return playersound_pain100;
 784         }
 785         GetPlayerSoundSampleField_notFound = 1;
 786         return playersound_taunt;
 787 }
 788
 789 void PrecacheGlobalSound(string samplestring)
 790 {
 791         float n, i;
 792         tokenize(samplestring);
 793         n = stof(argv(1));
 794         if(n > 0)
 795         {
 796                 for(i = 1; i <= n; ++i)
 797                         precache_sound(strcat(argv(0), ftos(i), ".wav"));
 798         }
 799         else
 800         {
 801                 precache_sound(strcat(argv(0), ".wav"));
 802         }
 803 }
 804
 805 void PrecachePlayerSounds(string f)
 806 {
 807         float fh;
 808         string s;
 809         fh = fopen(f, FILE_READ);
 810         if(fh < 0)
 811                 return;
 812         while((s = fgets(fh)))
 813         {
 814                 if(tokenize(s) != 3)
 815                 {
 816                         dprint("Invalid sound info line: ", s, "\n");
 817                         continue;
 818                 }
 819                 PrecacheGlobalSound(strcat(argv(1), " ", argv(2)));
 820         }
 821         fclose(fh);
 822 }
 823
 824 void ClearPlayerSounds()
 825 {
 826         if(self.playersound_attack      ) { strunzone(self.playersound_attack      ); self.playersound_attack = string_null; }
 827         if(self.playersound_attackinfive) { strunzone(self.playersound_attackinfive); self.playersound_attackinfive = string_null; }
 828         if(self.playersound_coverme     ) { strunzone(self.playersound_coverme     ); self.playersound_coverme = string_null; }
 829         if(self.playersound_defend      ) { strunzone(self.playersound_defend      ); self.playersound_defend = string_null; }
 830         if(self.playersound_freelance   ) { strunzone(self.playersound_freelance   ); self.playersound_freelance = string_null; }
 831         if(self.playersound_incoming    ) { strunzone(self.playersound_incoming    ); self.playersound_incoming = string_null; }
 832         if(self.playersound_meet        ) { strunzone(self.playersound_meet        ); self.playersound_meet = string_null; }
 833         if(self.playersound_needhelp    ) { strunzone(self.playersound_needhelp    ); self.playersound_needhelp = string_null; }
 834         if(self.playersound_seenflag    ) { strunzone(self.playersound_seenflag    ); self.playersound_seenflag = string_null; }
 835         if(self.playersound_taunt       ) { strunzone(self.playersound_taunt       ); self.playersound_taunt = string_null; }
 836         if(self.playersound_teamshoot   ) { strunzone(self.playersound_teamshoot   ); self.playersound_teamshoot = string_null; }
 837         if(self.playersound_death       ) { strunzone(self.playersound_death       ); self.playersound_death = string_null; }
 838         if(self.playersound_drown       ) { strunzone(self.playersound_drown       ); self.playersound_drown = string_null; }
 839         if(self.playersound_falling     ) { strunzone(self.playersound_falling     ); self.playersound_falling = string_null; }
 840         if(self.playersound_gasp        ) { strunzone(self.playersound_gasp        ); self.playersound_gasp = string_null; }
 841         if(self.playersound_jump        ) { strunzone(self.playersound_jump        ); self.playersound_jump = string_null; }
 842         if(self.playersound_pain25      ) { strunzone(self.playersound_pain25      ); self.playersound_pain25 = string_null; }
 843         if(self.playersound_pain50      ) { strunzone(self.playersound_pain50      ); self.playersound_pain50 = string_null; }
 844         if(self.playersound_pain75      ) { strunzone(self.playersound_pain75      ); self.playersound_pain75 = string_null; }
 845         if(self.playersound_pain100     ) { strunzone(self.playersound_pain100     ); self.playersound_pain100 = string_null; }
 846 }
 847
 848 void LoadPlayerSounds(string f, float first)
 849 {
 850         float fh;
 851         string s;
 852         var .string field;
 853         fh = fopen(f, FILE_READ);
 854         if(fh < 0)
 855                 return;
 856         while((s = fgets(fh)))
 857         {
 858                 if(tokenize(s) != 3)
 859                         continue;
 860                 field = GetPlayerSoundSampleField(argv(0));
 861                 if(GetPlayerSoundSampleField_notFound)
 862                         field = GetVoiceMessageSampleField(argv(0));
 863                 if(GetPlayerSoundSampleField_notFound)
 864                         continue;
 865                 if not(GetPlayerSoundSampleField_fixed)
 866                         if not(first)
 867                                 continue;
 868                 if(self.field)
 869                         strunzone(self.field);
 870                 self.field = strzone(strcat(argv(1), " ", argv(2)));
 871         }
 872         fclose(fh);
 873 }
 874
 875 .float modelindex_for_playersound;
 876 void UpdatePlayerSounds()
 877 {
 878         if(self.modelindex == self.modelindex_for_playersound)
 879                 return;
 880         self.modelindex_for_playersound = self.modelindex;
 881         ClearPlayerSounds();
 882         LoadPlayerSounds("sound/player/default.sounds", 1);
 883         LoadPlayerSounds(strcat(self.model, ".sounds"), 0);
 884 }
 885
 886 void GlobalSound(string sample, float chan, float teamsay)
 887 {
 888         float n;
 889
 890         if(sample == "")
 891                 return;
 892
 893         tokenize(sample);
 894         n = stof(argv(1));
 895         if(n > 0)
 896                 sample = strcat(argv(0), ftos(ceil(random() * n)), ".wav"); // randomization
 897         else
 898                 sample = strcat(argv(0), ".wav"); // randomization
 899
 900         if(teamsay == 2) // only to last attacker
 901         {
 902                 if(teams_matter)
 903                         if(self.pusher)
 904                                 if(self.pusher.team == self.team)
 905                                 {
 906                                         msg_entity = self.pusher;
 907                                         soundto(MSG_ONE, self, chan, sample, VOL_BASE, ATTN_NONE);
 908                                         msg_entity = self;
 909                                         soundto(MSG_ONE, self, chan, sample, VOL_BASE, ATTN_NONE);
 910                                 }
 911         }
 912         else if(teamsay == 0) // to everyone
 913         {
 914                 // broadcast the sound, but it's directional
 915                 sound(self, chan, sample, VOL_BASE, ATTN_NORM);
 916         }
 917         else if(teamsay == 1) // to the same team
 918         {
 919                 if(teams_matter)
 920                 {
 921                         entity e;
 922                         FOR_EACH_REALCLIENT(e)
 923                                 if(!teams_matter || e.team == self.team)
 924                                 {
 925                                         msg_entity = e;
 926                                         soundto(MSG_ONE, self, chan, sample, VOL_BASE, ATTN_NONE);
 927                                 }
 928                 }
 929                 else
 930                 {
 931                         sound(self, chan, sample, VOL_BASE, ATTN_NONE);
 932                 }
 933         }
 934 }
 935
 936 void PlayerSound(.string samplefield, float chan, float teamsay)
 937 {
 938         string sample;
 939         sample = self.samplefield;
 940         GlobalSound(sample, chan, teamsay);
 941 }
 942
 943 void VoiceMessage(string type)
 944 {
 945         var .string sample;
 946         var float teamsay;
 947         sample = GetVoiceMessageSampleField(type);
 948
 949         if(GetPlayerSoundSampleField_notFound)
 950         {
 951                 sprint(self, strcat("Invalid voice. Use one of: ", allvoicesamples, "\n"));
 952                 return;
 953         }
 954
 955         teamsay = GetVoiceMessageTeamsayType(type);
 956
 957         PlayerSound(sample, CHAN_VOICE, teamsay);
 958 }