data/qcsrc/server/cl_player.qc

   1
   2 // changes by LordHavoc on 03/29/04 and 03/30/04 at Vermeulen's request
   3 // merged player_run and player_stand to player_anim
   4 // added death animations to player_anim
   5 // can now spawn thrown weapons from anywhere, not just from players
   6 // thrown weapons now fade out after 20 seconds
   7 // created PlayerGib function
   8 // PlayerDie no longer uses hitloc or damage
   9 // PlayerDie now supports dying animations as well as gibbing
  10 // cleaned up PlayerDie a lot
  11 // added CopyBody
  12
  13 .entity pusher;
  14 .float pushltime;
  15
  16 void CopyBody(float keepvelocity)
  17 {
  18         local entity oldself;
  19         if (self.effects & EF_NODRAW)
  20                 return;
  21         oldself = self;
  22         self = spawn();
  23         self.enemy = oldself;
  24         self.lip = oldself.lip;
  25         self.colormap = oldself.colormap;
  26         self.iscreature = oldself.iscreature;
  27         self.angles = oldself.angles;
  28         self.avelocity = oldself.avelocity;
  29         self.classname = "body";
  30         self.damageforcescale = oldself.damageforcescale;
  31         self.effects = oldself.effects;
  32         self.event_damage = oldself.event_damage;
  33         self.animstate_startframe = oldself.animstate_startframe;
  34         self.animstate_numframes = oldself.animstate_numframes;
  35         self.animstate_framerate = oldself.animstate_framerate;
  36         self.animstate_starttime = oldself.animstate_starttime;
  37         self.animstate_endtime = oldself.animstate_endtime;
  38         self.animstate_override = oldself.animstate_override;
  39         self.animstate_looping = oldself.animstate_looping;
  40         self.frame = oldself.frame;
  41         self.dead_frame = oldself.dead_frame;
  42         self.pain_finished = oldself.pain_finished;
  43         self.health = oldself.health;
  44         self.armorvalue = oldself.armorvalue;
  45         self.armortype = oldself.armortype;
  46         self.model = oldself.model;
  47         self.modelindex = oldself.modelindex;
  48         self.movetype = oldself.movetype;
  49         self.nextthink = oldself.nextthink;
  50         self.skin = oldself.skin;
  51         self.solid = oldself.solid;
  52         self.takedamage = oldself.takedamage;
  53         self.think = oldself.think;
  54         self.gibrandom = oldself.gibrandom;
  55         self.customizeentityforclient = oldself.customizeentityforclient;
  56         if (keepvelocity == 1)
  57                 self.velocity = oldself.velocity;
  58         self.oldvelocity = self.velocity;
  59         self.fade_time = oldself.fade_time;
  60         self.fade_rate = oldself.fade_rate;
  61         //self.weapon = oldself.weapon;
  62         setorigin(self, oldself.origin);
  63         setsize(self, oldself.mins, oldself.maxs);
  64         self.oldorigin = oldself.origin;
  65         self = oldself;
  66 }
  67
  68 float animparseerror;
  69 vector animparseline(float animfile)
  70 {
  71         local string line;
  72         local float c;
  73         local vector anim;
  74         if (animfile < 0)
  75                 return '0 1 2';
  76         line = fgets(animfile);
  77         c = tokenize(line);
  78         if (c != 3)
  79         {
  80                 animparseerror = TRUE;
  81                 return '0 1 2';
  82         }
  83         anim_x = stof(argv(0));
  84         anim_y = stof(argv(1));
  85         anim_z = stof(argv(2));
  86         // don't allow completely bogus values
  87         if (anim_x < 0 || anim_y < 1 || anim_z < 0.001)
  88                 anim = '0 1 2';
  89         return anim;
  90 };
  91
  92 void player_setupanimsformodel()
  93 {
  94         local string animfilename;
  95         local float animfile;
  96         // defaults for legacy .zym models without animinfo files
  97         self.anim_die1 = '0 1 0.5'; // 2 seconds
  98         self.anim_die2 = '1 1 0.5'; // 2 seconds
  99         self.anim_draw = '2 1 3'; // TODO: analyze models and set framerate
 100         self.anim_duck = '3 1 100'; // this anim seems bogus in most models, so make it play VERY briefly!
 101         self.anim_duckwalk = '4 1 1';
 102         self.anim_duckjump = '5 1 100'; // zym anims keep playing until changed, so this only has to start the anim, landing will end it
 103         self.anim_duckidle = '6 1 1';
 104         self.anim_idle = '7 1 1';
 105         self.anim_jump = '8 1 100'; // zym anims keep playing until changed, so this only has to start the anim, landing will end it
 106         self.anim_pain1 = '9 1 2'; // 0.5 seconds
 107         self.anim_pain2 = '10 1 2'; // 0.5 seconds
 108         self.anim_shoot = '11 1 5'; // TODO: analyze models and set framerate
 109         self.anim_taunt = '12 1 1'; // FIXME?  there is no code using this anim
 110         self.anim_run = '13 1 1';
 111         self.anim_runbackwards = '14 1 1';
 112         self.anim_strafeleft = '15 1 1';
 113         self.anim_straferight = '16 1 1';
 114         self.anim_dead1 = '17 1 1';
 115         self.anim_dead2 = '18 1 1';
 116         self.anim_forwardright = '19 1 1';
 117         self.anim_forwardleft = '20 1 1';
 118         self.anim_backright = '21 1 1';
 119         self.anim_backleft  = '22 1 1';
 120         animparseerror = FALSE;
 121         animfilename = strcat(self.model, ".animinfo");
 122         animfile = fopen(animfilename, FILE_READ);
 123         if (animfile >= 0)
 124         {
 125                 self.anim_die1         = animparseline(animfile);
 126                 self.anim_die2         = animparseline(animfile);
 127                 self.anim_draw         = animparseline(animfile);
 128                 self.anim_duck         = animparseline(animfile);
 129                 self.anim_duckwalk     = animparseline(animfile);
 130                 self.anim_duckjump     = animparseline(animfile);
 131                 self.anim_duckidle     = animparseline(animfile);
 132                 self.anim_idle         = animparseline(animfile);
 133                 self.anim_jump         = animparseline(animfile);
 134                 self.anim_pain1        = animparseline(animfile);
 135                 self.anim_pain2        = animparseline(animfile);
 136                 self.anim_shoot        = animparseline(animfile);
 137                 self.anim_taunt        = animparseline(animfile);
 138                 self.anim_run          = animparseline(animfile);
 139                 self.anim_runbackwards = animparseline(animfile);
 140                 self.anim_strafeleft   = animparseline(animfile);
 141                 self.anim_straferight  = animparseline(animfile);
 142                 self.anim_forwardright = animparseline(animfile);
 143                 self.anim_forwardleft  = animparseline(animfile);
 144                 self.anim_backright    = animparseline(animfile);
 145                 self.anim_backleft     = animparseline(animfile);
 146                 fclose(animfile);
 147
 148                 // derived anims
 149                 self.anim_dead1 = '0 1 1' + '1 0 0' * (self.anim_die1_x + self.anim_die1_y - 1);
 150                 self.anim_dead2 = '0 1 1' + '1 0 0' * (self.anim_die2_x + self.anim_die2_y - 1);
 151
 152                 if (animparseerror)
 153                         print("Parse error in ", animfilename, ", some player animations are broken\n");
 154         }
 155         else
 156                 dprint("File ", animfilename, " not found, assuming legacy .zym model animation timings\n");
 157         // reset animstate now
 158         player_setanim(self.anim_idle, TRUE, FALSE, TRUE);
 159 };
 160
 161 void player_setanim(vector anim, float looping, float override, float restart)
 162 {
 163         if (!restart)
 164         if (anim_x == self.animstate_startframe)
 165         if (anim_y == self.animstate_numframes)
 166         if (anim_z == self.animstate_framerate)
 167                 return;
 168         self.animstate_startframe = anim_x;
 169         self.animstate_numframes = anim_y;
 170         self.animstate_framerate = anim_z;
 171         self.animstate_starttime = time;
 172         self.animstate_endtime = time + self.animstate_numframes / self.animstate_framerate;
 173         self.animstate_looping = looping;
 174         self.animstate_override = override;
 175         self.frame = self.animstate_startframe;
 176 };
 177
 178 void player_updateframe()
 179 {
 180         if (time >= self.animstate_endtime)
 181         {
 182                 if (self.animstate_looping)
 183                 {
 184                         self.animstate_starttime = self.animstate_endtime;
 185                         self.animstate_endtime = self.animstate_endtime + self.animstate_numframes / self.animstate_framerate;
 186                 }
 187                 self.animstate_override = FALSE;
 188         }
 189         self.frame = self.animstate_startframe + bound(0, (time - self.animstate_starttime) * self.animstate_framerate, self.animstate_numframes - 1);
 190 };
 191
 192 void player_anim (void)
 193 {
 194         player_updateframe();
 195
 196         if (self.deadflag != DEAD_NO)
 197         {
 198                 if (time > self.animstate_endtime)
 199                 {
 200                         if (self.maxs_z > 5)
 201                         {
 202                                 self.maxs_z = 5;
 203                                 setsize(self, self.mins, self.maxs);
 204                         }
 205                         self.frame = self.dead_frame;
 206                 }
 207                 return;
 208         }
 209
 210         if (!self.animstate_override)
 211         {
 212                 if (!(self.flags & FL_ONGROUND))
 213                 {
 214                         if (self.crouch)
 215                                 player_setanim(self.anim_duckjump, FALSE, TRUE, FALSE);
 216                         else
 217                                 player_setanim(self.anim_jump, FALSE, TRUE, FALSE);
 218                 }
 219                 else if (self.crouch)
 220                 {
 221                         if (self.movement_x * self.movement_x + self.movement_y * self.movement_y > 20)
 222                                 player_setanim(self.anim_duckwalk, TRUE, FALSE, FALSE);
 223                         else
 224                                 player_setanim(self.anim_duckidle, TRUE, FALSE, FALSE);
 225                 }
 226                 else if ((self.movement_x * self.movement_x + self.movement_y * self.movement_y) > 20)
 227                 {
 228                         if (self.movement_x > 0 && self.movement_y == 0)
 229                                 player_setanim(self.anim_run, TRUE, FALSE, FALSE);
 230                         else if (self.movement_x < 0 && self.movement_y == 0)
 231                                 player_setanim(self.anim_runbackwards, TRUE, FALSE, FALSE);
 232                         else if (self.movement_x == 0 && self.movement_y > 0)
 233                                 player_setanim(self.anim_straferight, TRUE, FALSE, FALSE);
 234                         else if (self.movement_x == 0 && self.movement_y < 0)
 235                                 player_setanim(self.anim_strafeleft, TRUE, FALSE, FALSE);
 236                         else if (self.movement_x > 0 && self.movement_y > 0)
 237                                 player_setanim(self.anim_forwardright, TRUE, FALSE, FALSE);
 238                         else if (self.movement_x > 0 && self.movement_y < 0)
 239                                 player_setanim(self.anim_forwardleft, TRUE, FALSE, FALSE);
 240                         else if (self.movement_x < 0 && self.movement_y > 0)
 241                                 player_setanim(self.anim_backright, TRUE, FALSE, FALSE);
 242                         else if (self.movement_x < 0 && self.movement_y < 0)
 243                                 player_setanim(self.anim_backleft, TRUE, FALSE, FALSE);
 244                         else
 245                                 player_setanim(self.anim_run, TRUE, FALSE, FALSE);
 246                 }
 247                 else
 248                         player_setanim(self.anim_idle, TRUE, FALSE, FALSE);
 249         }
 250 }
 251 //End change by Supajoe on 11:44 PM EST 11/16/03 (Subject: Player animations)
 252
 253 void SpawnThrownWeapon (vector org, float w)
 254 {
 255         W_ThrowWeapon(randomvec() * 100 + '0 0 200', org - self.origin, FALSE);
 256 }
 257
 258 void PlayerCorpseDamage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 259 {
 260         local float take, save;
 261         if(sv_gentle < 1)
 262                 pointparticles(particleeffectnum("blood"), hitloc, force, bound(0, damage, 200));
 263         // damage resistance (ignore most of the damage from a bullet or similar)
 264         damage = max(damage - 5, 1);
 265
 266         save = bound(0, damage * cvar("g_balance_armor_blockpercent"), self.armorvalue);
 267         take = bound(0, damage - save, damage);
 268
 269         if (save > 10)
 270                 sound (self, CHAN_PROJECTILE, "misc/armorimpact.wav", VOL_BASE, ATTN_NORM);
 271         else if (take > 30)
 272                 sound (self, CHAN_PROJECTILE, "misc/bodyimpact2.wav", VOL_BASE, ATTN_NORM);
 273         else if (take > 10)
 274                 sound (self, CHAN_PROJECTILE, "misc/bodyimpact1.wav", VOL_BASE, ATTN_NORM);
 275
 276         if(sv_gentle < 1) {
 277                 if (take > 50)
 278                         TossGib (world, "models/gibs/chunk.mdl", hitloc, force * -0.1,1);
 279                 if (take > 100)
 280                         TossGib (world, "models/gibs/chunk.mdl", hitloc, force * -0.2,1);
 281         }
 282
 283         if (!(self.flags & FL_GODMODE))
 284         {
 285                 self.armorvalue = self.armorvalue - save;
 286                 self.health = self.health - take;
 287                 // pause regeneration for 5 seconds
 288                 self.pauseregen_finished = max(self.pauseregen_finished, time + cvar("g_balance_pause_health_regen"));
 289         }
 290         self.dmg_save = self.dmg_save + save;//max(save - 10, 0);
 291         self.dmg_take = self.dmg_take + take;//max(take - 10, 0);
 292         self.dmg_inflictor = inflictor;
 293
 294         if (self.health <= -50)
 295         {
 296                 // don't use any animations as a gib
 297                 self.frame = 0;
 298                 self.dead_frame = 0;
 299                 // view just above the floor
 300                 self.view_ofs = '0 0 4';
 301
 302                 // make a juicy mess
 303                 local float multiplier;
 304                 multiplier = 1;
 305                 if (cvar("ekg"))
 306                         multiplier = 5;
 307
 308
 309                 // make a meaty mess
 310                 TossGib (self, "models/gibs/eye.md3", self.origin + self.view_ofs, self.velocity + randomvec() * 150,0);
 311
 312                 if(sv_gentle < 1) {
 313                         te_bloodshower (self.origin + self.mins, self.origin + self.maxs, 1200 * multiplier, 1000);
 314                         TossGib (world, "models/gibs/bloodyskull.md3", self.origin + self.view_ofs, self.velocity,0);
 315
 316                         local float c;
 317                         c = 0;
 318
 319                         while (c < multiplier)
 320                         {
 321                                 c = c + 1;
 322                                 //TossGib (world, "models/gibs/gib1.md3", self.origin, self.velocity + randomvec() * 450,0);
 323                                 //TossGib (world, "models/gibs/gib2.md3", self.origin, self.velocity + randomvec() * 450,0);
 324                                 //TossGib (world, "models/gibs/gib3.md3", self.origin, self.velocity + randomvec() * 450,0);
 325                                 //TossGib (world, "models/gibs/gib4.md3", self.origin, self.velocity + randomvec() * 450,0);
 326                                 //TossGib (world, "models/gibs/gib5.md3", self.origin, self.velocity + randomvec() * 450,0);
 327                                 //TossGib (world, "models/gibs/gib6.md3", self.origin, self.velocity + randomvec() * 450,0);
 328
 329                                 TossGib (world, "models/gibs/arm.md3", self.origin + self.view_ofs, self.velocity + randomvec() * (random() * 120 + 90),0);
 330                                 TossGib (world, "models/gibs/arm.md3", self.origin + self.view_ofs, self.velocity + randomvec() * (random() * 120 + 90),0);
 331                                 //TossGib (world, "models/gibs/arm.md3", self.origin + self.view_ofs, self.velocity + randomvec() * 150,0);
 332                                 //TossGib (world, "models/gibs/arm.md3", self.origin + self.view_ofs, self.velocity + randomvec() * 150,0);
 333                                 TossGib (world, "models/gibs/chest.md3", self.origin + self.view_ofs * 0.5, self.velocity + randomvec() * (random() * 120 + 80),0);
 334                                 //TossGib (world, "models/gibs/smallchest.md3", self.origin + self.view_ofs, self.velocity + randomvec() * 150,0);
 335                                 TossGib (world, "models/gibs/smallchest.md3", self.origin + self.view_ofs, self.velocity + randomvec() * (random() * 120 + 80),0);
 336                                 TossGib (world, "models/gibs/leg1.md3", self.origin + self.view_ofs * -0.2, self.velocity + randomvec() * (random() * 120 + 85),0);
 337                                 TossGib (world, "models/gibs/leg2.md3", self.origin + self.view_ofs * -0.4, self.velocity + randomvec() * (random() * 120 + 85),0);
 338                                 //TossGib (world, "models/gibs/leg1.md3", self.origin + self.view_ofs * -0.2, self.velocity + randomvec() * 150,0);
 339                                 //TossGib (world, "models/gibs/leg2.md3", self.origin + self.view_ofs * -0.4, self.velocity + randomvec() * 150,0);
 340
 341                                 // these splat on impact
 342                                 TossGib (world, "models/gibs/chunk.mdl", self.origin, self.velocity + randomvec() * 450,1);
 343                                 TossGib (world, "models/gibs/chunk.mdl", self.origin, self.velocity + randomvec() * 450,1);
 344                                 TossGib (world, "models/gibs/chunk.mdl", self.origin, self.velocity + randomvec() * 450,1);
 345                                 TossGib (world, "models/gibs/chunk.mdl", self.origin, self.velocity + randomvec() * 450,1);
 346                         }
 347                         sound (self, CHAN_PLAYER, "misc/gib.wav", VOL_BASE, ATTN_NORM);
 348                 }
 349         }
 350 }
 351
 352 void ClientKill_Now_TeamChange();
 353
 354 void PlayerDamage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 355 {
 356         local float take, save, waves, sdelay;
 357
 358         if(self.hook)
 359                 if(self.hook.aiment)
 360                         if(self.hook.aiment == attacker)
 361                                 RemoveGrapplingHook(self); // STOP THAT, you parasite!
 362
 363         damage = damage * bound(1.0, self.cvar_cl_handicap, 100.0);
 364         if(sv_gentle > 0) {
 365                 pointparticles(particleeffectnum("damage_hit"), hitloc, force, bound(0, damage, 200));
 366         } else {
 367                 pointparticles(particleeffectnum("blood"), hitloc, force, bound(0, damage, 200));
 368         }
 369
 370         if(g_arena)
 371         if(numspawned < 2)
 372                 return;
 373
 374         if (!g_minstagib)
 375         {
 376                 save = bound(0, damage * cvar("g_balance_armor_blockpercent"), self.armorvalue);
 377                 take = bound(0, damage - save, damage);
 378         }
 379         else
 380         {
 381                 save = 0;
 382                 take = damage;
 383         }
 384
 385         if (save > 10)
 386                 sound (self, CHAN_PROJECTILE, "misc/armorimpact.wav", VOL_BASE, ATTN_NORM);
 387         else if (take > 30)
 388                 sound (self, CHAN_PROJECTILE, "misc/bodyimpact2.wav", VOL_BASE, ATTN_NORM);
 389         else if (take > 10)
 390                 sound (self, CHAN_PROJECTILE, "misc/bodyimpact1.wav", VOL_BASE, ATTN_NORM); // FIXME possibly remove them?
 391
 392         if (take > 50)
 393                 TossGib (world, "models/gibs/chunk.mdl", hitloc, force * -0.1,1);
 394         if (take > 100)
 395                 TossGib (world, "models/gibs/chunk.mdl", hitloc, force * -0.2,1);
 396
 397         if (time > self.spawnshieldtime)
 398         {
 399                 if (!(self.flags & FL_GODMODE))
 400                 {
 401                         self.armorvalue = self.armorvalue - save;
 402                         self.health = self.health - take;
 403                         // pause regeneration for 5 seconds
 404                         self.pauseregen_finished = max(self.pauseregen_finished, time + cvar("g_balance_pause_health_regen"));
 405
 406                         if (time > self.pain_finished)          //Don't switch pain sequences like crazy
 407                         {
 408                                 self.pain_finished = time + 0.5;        //Supajoe
 409
 410                                 if(sv_gentle < 1) {
 411                                         if (random() > 0.5)
 412                                                 player_setanim(self.anim_pain1, FALSE, TRUE, TRUE);
 413                                         else
 414                                                 player_setanim(self.anim_pain2, FALSE, TRUE, TRUE);
 415
 416                                         if(deathtype != WEP_LASER || attacker != self || self.health < 2 * cvar("g_balance_laser_primary_damage") * cvar("g_balance_selfdamagepercent") + 1)
 417                                         // exclude pain sounds for laserjumps as long as you aren't REALLY low on health and would die of the next two
 418                                         {
 419                                                 if(self.health > 75) // TODO make a "gentle" version?
 420                                                         PlayerSound(playersound_pain100, CHAN_PAIN, 0);
 421                                                 else if(self.health > 50)
 422                                                         PlayerSound(playersound_pain75, CHAN_PAIN, 0);
 423                                                 else if(self.health > 25)
 424                                                         PlayerSound(playersound_pain50, CHAN_PAIN, 0);
 425                                                 else if(self.health > 1)
 426                                                         PlayerSound(playersound_pain25, CHAN_PAIN, 0);
 427                                         }
 428                                 }
 429
 430                                 // throw off bot aim temporarily
 431                                 local float shake;
 432                                 shake = damage * 5 / (bound(0,skill,100) + 1);
 433                                 self.v_angle_x = self.v_angle_x + (random() * 2 - 1) * shake;
 434                                 self.v_angle_y = self.v_angle_y + (random() * 2 - 1) * shake;
 435                         }
 436                 }
 437                 else
 438                         self.max_armorvalue += (save + take);
 439         }
 440         self.dmg_save = self.dmg_save + save;//max(save - 10, 0);
 441         self.dmg_take = self.dmg_take + take;//max(take - 10, 0);
 442         self.dmg_inflictor = inflictor;
 443
 444         if(attacker == self)
 445         {
 446                 // don't reset pushltime for self damage as it may be an attempt to
 447                 // escape a lava pit or similar
 448                 //self.pushltime = 0;
 449         }
 450         else if(attacker.classname == "player" || attacker.classname == "gib")
 451         {
 452                 self.pusher = attacker;
 453                 self.pushltime = time + cvar("g_maxpushtime");
 454         }
 455         else if(time < self.pushltime)
 456         {
 457                 attacker = self.pusher;
 458                 self.pushltime = max(self.pushltime, time + 0.6);
 459         }
 460         else
 461                 self.pushltime = 0;
 462
 463         if (self.health < 1)
 464         {
 465                 float defer_ClientKill_Now_TeamChange;
 466                 defer_ClientKill_Now_TeamChange = FALSE;
 467
 468                 if(sv_gentle < 1) // TODO make a "gentle" version?
 469                 {
 470                         if(deathtype == DEATH_DROWN)
 471                                 PlayerSound(playersound_drown, CHAN_PAIN, 0);
 472                         else
 473                                 PlayerSound(playersound_death, CHAN_PAIN, 0);
 474                 }
 475
 476                 // get rid of kill indicator
 477                 if(self.killindicator)
 478                 {
 479                         remove(self.killindicator);
 480                         self.killindicator = world;
 481                         if(self.killindicator_teamchange)
 482                                 defer_ClientKill_Now_TeamChange = TRUE;
 483
 484                         if(self.classname == "body")
 485                         if(deathtype == DEATH_KILL)
 486                         {
 487                                 // for the lemmings fans, a small harmless explosion
 488                                 pointparticles(particleeffectnum("rocket_explode"), self.origin, '0 0 0', 1);
 489                         }
 490                 }
 491
 492                 // become fully visible
 493                 self.alpha = 1;
 494                 // clear selected player display
 495                 ClearSelectedPlayer();
 496                 // throw a weapon
 497                 SpawnThrownWeapon (self.origin + (self.mins + self.maxs) * 0.5, self.switchweapon);
 498                 // print an obituary message
 499                 Obituary (attacker, self, deathtype);
 500                 DropAllRunes(self);
 501                 if(self == attacker)
 502                         kh_Key_DropAll(self, TRUE);
 503                 else if(attacker.classname == "player" || attacker.classname == "gib")
 504                         kh_Key_DropAll(self, FALSE);
 505                 else
 506                         kh_Key_DropAll(self, TRUE);
 507                 if(self.flagcarried)
 508                 {
 509                         if(attacker.classname != "player" || attacker.team == self.team)
 510                                 DropFlag(self.flagcarried, 1); // penalty for flag loss by suicide
 511                         else
 512                                 DropFlag(self.flagcarried, 0);
 513                 }
 514                 Portal_ClearAllLater(self);
 515                 // clear waypoints
 516                 WaypointSprite_PlayerDead();
 517                 // make the corpse upright (not tilted)
 518                 self.angles_x = 0;
 519                 self.angles_z = 0;
 520                 // don't spin
 521                 self.avelocity = '0 0 0';
 522                 // view from the floor
 523                 self.view_ofs = '0 0 -8';
 524                 // toss the corpse
 525                 self.movetype = MOVETYPE_TOSS;
 526                 // shootable corpse
 527                 self.solid = SOLID_CORPSE;
 528                 // don't stick to the floor
 529                 self.flags = self.flags - (self.flags & FL_ONGROUND);
 530                 // dying animation
 531                 self.deadflag = DEAD_DYING;
 532                 // when to allow respawn
 533                 sdelay = 0;
 534                 waves = 0;
 535                 if(cvar("g_respawn_mapsettings"))
 536                 {
 537                         sdelay = cvar("g_respawn_mapsettings_delay");
 538                         waves = cvar("g_respawn_mapsettings_waves");
 539                 }
 540                 if(!sdelay)
 541                         sdelay = cvar(strcat("g_", GetGametype(), "_respawn_delay"));
 542                 if(!sdelay)
 543                         sdelay = cvar("g_respawn_delay");
 544                 if(!waves)
 545                         waves = cvar(strcat("g_", GetGametype(), "_respawn_waves"));
 546                 if(!waves)
 547                         waves = cvar("g_respawn_waves");
 548                 if(waves)
 549                         self.death_time = ceil((time + sdelay) / waves) * waves;
 550                 else
 551                         self.death_time = time + sdelay;
 552                 if((sdelay + waves >= 5.0) && (self.death_time - time > 1.75))
 553                         self.respawn_countdown = 10; // first number to count down from is 10
 554                 else
 555                         self.respawn_countdown = -1; // do not count down
 556                 if (random() < 0.5)
 557                 {
 558                         player_setanim(self.anim_die1, FALSE, TRUE, TRUE);
 559                         self.dead_frame = self.anim_dead1_x;
 560                 }
 561                 else
 562                 {
 563                         player_setanim(self.anim_die2, FALSE, TRUE, TRUE);
 564                         self.dead_frame = self.anim_dead2_x;
 565                 }
 566                 // set damage function to corpse damage
 567                 self.event_damage = PlayerCorpseDamage;
 568                 // call the corpse damage function just in case it wants to gib
 569                 self.event_damage(inflictor, attacker, 0, deathtype, hitloc, force);
 570                 // set up to fade out later
 571                 SUB_SetFade (self, time + 12 + random () * 4, 1);
 572
 573                 // remove laserdot
 574                 if(self.weaponentity)
 575                         if(self.weaponentity.lasertarget)
 576                                 remove(self.weaponentity.lasertarget);
 577
 578                 if(clienttype(self) == CLIENTTYPE_REAL)
 579                 {
 580                         self.fixangle = TRUE;
 581                         //msg_entity = self;
 582                         //WriteByte (MSG_ONE, SVC_SETANGLE);
 583                         //WriteAngle (MSG_ONE, self.v_angle_x);
 584                         //WriteAngle (MSG_ONE, self.v_angle_y);
 585                         //WriteAngle (MSG_ONE, 80);
 586                 }
 587
 588                 if(g_arena)
 589                         Spawnqueue_Unmark(self);
 590
 591                 if(defer_ClientKill_Now_TeamChange)
 592                         ClientKill_Now_TeamChange();
 593
 594                 if(sv_gentle > 0) {
 595                         // remove corpse
 596                         PlayerCorpseDamage (inflictor, attacker, 100.0, deathtype, hitloc, force);
 597                         pointparticles(particleeffectnum("damage_dissolve"), self.origin, force, 1);
 598                 }
 599         }
 600 }
 601
 602 float UpdateSelectedPlayer_countvalue(float v)
 603 {
 604         return max(0, (v - 1.0) / 0.5);
 605 }
 606
 607 // returns: -2 if no hit, otherwise cos of the angle
 608 // uses the global v_angle
 609 float UpdateSelectedPlayer_canSee(entity p, float mincosangle, float maxdist)
 610 {
 611         vector so, d;
 612         float c;
 613
 614         if(p == self)
 615                 return -2;
 616
 617         if(p.deadflag)
 618                 return -2;
 619
 620         so = self.origin + self.view_ofs;
 621         d = p.origin - so;
 622
 623         // misaimed?
 624         if(dist_point_line(d, '0 0 0', v_forward) > maxdist)
 625                 return -2;
 626
 627         // now find the cos of the angle...
 628         c = normalize(d) * v_forward;
 629
 630         if(c <= mincosangle)
 631                 return -2;
 632
 633         traceline(so, p.origin, MOVE_NOMONSTERS, self);
 634         if(trace_fraction < 1)
 635                 return -2;
 636
 637         return c;
 638 }
 639
 640 void ClearSelectedPlayer()
 641 {
 642         if(self.selected_player)
 643         {
 644                 centerprint_expire(self, CENTERPRIO_POINT);
 645                 self.selected_player = world;
 646                 self.selected_player_display_needs_update = FALSE;
 647         }
 648 }
 649
 650 void UpdateSelectedPlayer()
 651 {
 652         entity selected;
 653         float selected_score;
 654         selected = world;
 655         selected_score = 0.95; // 18 degrees
 656
 657         if(!cvar("sv_allow_shownames"))
 658                 return;
 659
 660         if(clienttype(self) != CLIENTTYPE_REAL)
 661                 return;
 662
 663         if(self.cvar_cl_shownames == 0)
 664                 return;
 665
 666         if(self.cvar_cl_shownames == 1 && !teams_matter)
 667                 return;
 668
 669         makevectors(self.v_angle); // sets v_forward
 670
 671         // 1. cursor trace is always right
 672         if(self.cursor_trace_ent && self.cursor_trace_ent.classname == "player" && !self.cursor_trace_ent.deadflag)
 673         {
 674                 selected = self.cursor_trace_ent;
 675         }
 676         else
 677         {
 678                 // 2. if we don't have a cursor trace, find the player which is least
 679                 //    mis-aimed at
 680                 entity p;
 681                 FOR_EACH_PLAYER(p)
 682                 {
 683                         float c;
 684                         c = UpdateSelectedPlayer_canSee(p, selected_score, 100); // 100 = 2.5 meters
 685                         if(c >= -1)
 686                         {
 687                                 selected = p;
 688                                 selected_score = c;
 689                         }
 690                 }
 691         }
 692
 693         if(selected)
 694         {
 695                 self.selected_player_display_timeout = time + self.cvar_scr_centertime;
 696         }
 697         else
 698         {
 699                 if(time < self.selected_player_display_timeout)
 700                         if(UpdateSelectedPlayer_canSee(self.selected_player, 0.7, 200) >= -1) // 5 meters, 45 degrees
 701                                 selected = self.selected_player;
 702         }
 703
 704         if(selected)
 705         {
 706                 if(selected == self.selected_player)
 707                 {
 708                         float save;
 709                         save = UpdateSelectedPlayer_countvalue(self.selected_player_count);
 710                         self.selected_player_count = self.selected_player_count + frametime;
 711                         if(save != UpdateSelectedPlayer_countvalue(self.selected_player_count))
 712                         {
 713                                 string namestr, healthstr;
 714                                 namestr = playername(selected);
 715                                 if(teams_matter)
 716                                 {
 717                                         healthstr = ftos(floor(selected.health));
 718                                         if(self.team == selected.team)
 719                                         {
 720                                                 namestr = strcat(namestr, " (", healthstr, "%)");
 721                                                 self.selected_player_display_needs_update = TRUE;
 722                                         }
 723                                 }
 724                                 centerprint_atprio(self, CENTERPRIO_POINT, namestr);
 725                         }
 726                 }
 727                 else
 728                 {
 729                         ClearSelectedPlayer();
 730                         self.selected_player = selected;
 731                         self.selected_player_time = time;
 732                         self.selected_player_count = 0;
 733                         self.selected_player_display_needs_update = FALSE;
 734                 }
 735         }
 736         else
 737         {
 738                 ClearSelectedPlayer();
 739         }
 740
 741         if(self.selected_player)
 742                 self.last_selected_player = self.selected_player;
 743 }
 744
 745 float GetVoiceMessageTeamsayType(string type)
 746 {
 747         if(type == "taunt")
 748                 return 0;
 749         if(type == "teamshoot")
 750                 return 2;
 751         return 1;
 752 }
 753
 754 string allvoicesamples = "attack attackinfive coverme defend freelance incoming meet needhelp seenflag taunt teamshoot";
 755 float GetPlayerSoundSampleField_notFound;
 756 float GetPlayerSoundSampleField_fixed;
 757 .string GetVoiceMessageSampleField(string type)
 758 {
 759         GetPlayerSoundSampleField_notFound = 0;
 760         GetPlayerSoundSampleField_fixed = 0;
 761         switch(type)
 762         {
 763                 case "attack":       return playersound_attack;
 764                 case "attackinfive": return playersound_attackinfive;
 765                 case "coverme":      return playersound_coverme;
 766                 case "defend":       return playersound_defend;
 767                 case "freelance":    return playersound_freelance;
 768                 case "incoming":     return playersound_incoming;
 769                 case "meet":         return playersound_meet;
 770                 case "needhelp":     return playersound_needhelp;
 771                 case "seenflag":     return playersound_seenflag;
 772                 case "taunt":        return playersound_taunt;
 773                 case "teamshoot":    return playersound_teamshoot;
 774         }
 775         GetPlayerSoundSampleField_notFound = 1;
 776         return playersound_taunt;
 777 }
 778
 779 .string GetPlayerSoundSampleField(string type)
 780 {
 781         GetPlayerSoundSampleField_notFound = 0;
 782         GetPlayerSoundSampleField_fixed = 0;
 783         switch(type)
 784         {
 785                 case "death":        return playersound_death;
 786                 case "drown":        return playersound_drown;
 787                 case "falling":      return playersound_falling;
 788                 case "gasp":         return playersound_gasp;
 789                 case "jump":         return playersound_jump;
 790                 case "pain25":       return playersound_pain25;
 791                 case "pain50":       return playersound_pain50;
 792                 case "pain75":       return playersound_pain75;
 793                 case "pain100":      return playersound_pain100;
 794         }
 795         GetPlayerSoundSampleField_notFound = 1;
 796         return playersound_taunt;
 797 }
 798
 799 void PrecacheGlobalSound(string samplestring)
 800 {
 801         float n, i;
 802         tokenize(samplestring);
 803         n = stof(argv(1));
 804         if(n > 0)
 805         {
 806                 for(i = 1; i <= n; ++i)
 807                         precache_sound(strcat(argv(0), ftos(i), ".wav"));
 808         }
 809         else
 810         {
 811                 precache_sound(strcat(argv(0), ".wav"));
 812         }
 813 }
 814
 815 void PrecachePlayerSounds(string f)
 816 {
 817         float fh;
 818         string s;
 819         fh = fopen(f, FILE_READ);
 820         if(fh < 0)
 821                 return;
 822         while((s = fgets(fh)))
 823         {
 824                 if(tokenize(s) != 3)
 825                 {
 826                         dprint("Invalid sound info line: ", s, "\n");
 827                         continue;
 828                 }
 829                 PrecacheGlobalSound(strcat(argv(1), " ", argv(2)));
 830         }
 831         fclose(fh);
 832 }
 833
 834 void ClearPlayerSounds()
 835 {
 836         if(self.playersound_attack      ) { strunzone(self.playersound_attack      ); self.playersound_attack = string_null; }
 837         if(self.playersound_attackinfive) { strunzone(self.playersound_attackinfive); self.playersound_attackinfive = string_null; }
 838         if(self.playersound_coverme     ) { strunzone(self.playersound_coverme     ); self.playersound_coverme = string_null; }
 839         if(self.playersound_defend      ) { strunzone(self.playersound_defend      ); self.playersound_defend = string_null; }
 840         if(self.playersound_freelance   ) { strunzone(self.playersound_freelance   ); self.playersound_freelance = string_null; }
 841         if(self.playersound_incoming    ) { strunzone(self.playersound_incoming    ); self.playersound_incoming = string_null; }
 842         if(self.playersound_meet        ) { strunzone(self.playersound_meet        ); self.playersound_meet = string_null; }
 843         if(self.playersound_needhelp    ) { strunzone(self.playersound_needhelp    ); self.playersound_needhelp = string_null; }
 844         if(self.playersound_seenflag    ) { strunzone(self.playersound_seenflag    ); self.playersound_seenflag = string_null; }
 845         if(self.playersound_taunt       ) { strunzone(self.playersound_taunt       ); self.playersound_taunt = string_null; }
 846         if(self.playersound_teamshoot   ) { strunzone(self.playersound_teamshoot   ); self.playersound_teamshoot = string_null; }
 847         if(self.playersound_death       ) { strunzone(self.playersound_death       ); self.playersound_death = string_null; }
 848         if(self.playersound_drown       ) { strunzone(self.playersound_drown       ); self.playersound_drown = string_null; }
 849         if(self.playersound_falling     ) { strunzone(self.playersound_falling     ); self.playersound_falling = string_null; }
 850         if(self.playersound_gasp        ) { strunzone(self.playersound_gasp        ); self.playersound_gasp = string_null; }
 851         if(self.playersound_jump        ) { strunzone(self.playersound_jump        ); self.playersound_jump = string_null; }
 852         if(self.playersound_pain25      ) { strunzone(self.playersound_pain25      ); self.playersound_pain25 = string_null; }
 853         if(self.playersound_pain50      ) { strunzone(self.playersound_pain50      ); self.playersound_pain50 = string_null; }
 854         if(self.playersound_pain75      ) { strunzone(self.playersound_pain75      ); self.playersound_pain75 = string_null; }
 855         if(self.playersound_pain100     ) { strunzone(self.playersound_pain100     ); self.playersound_pain100 = string_null; }
 856 }
 857
 858 void LoadPlayerSounds(string f, float first)
 859 {
 860         float fh;
 861         string s;
 862         var .string field;
 863         fh = fopen(f, FILE_READ);
 864         if(fh < 0)
 865                 return;
 866         while((s = fgets(fh)))
 867         {
 868                 if(tokenize(s) != 3)
 869                         continue;
 870                 field = GetPlayerSoundSampleField(argv(0));
 871                 if(GetPlayerSoundSampleField_notFound)
 872                         field = GetVoiceMessageSampleField(argv(0));
 873                 if(GetPlayerSoundSampleField_notFound)
 874                         continue;
 875                 if(GetPlayerSoundSampleField_fixed)
 876                         if not(first)
 877                                 continue;
 878                 if(self.field)
 879                         strunzone(self.field);
 880                 self.field = strzone(strcat(argv(1), " ", argv(2)));
 881         }
 882         fclose(fh);
 883 }
 884
 885 .float modelindex_for_playersound;
 886 void UpdatePlayerSounds()
 887 {
 888         if(self.modelindex == self.modelindex_for_playersound)
 889                 return;
 890         self.modelindex_for_playersound = self.modelindex;
 891         ClearPlayerSounds();
 892         LoadPlayerSounds("sound/player/default.sounds", 1);
 893         LoadPlayerSounds(strcat(self.model, ".sounds"), 0);
 894 }
 895
 896 void GlobalSound(string sample, float chan, float teamsay)
 897 {
 898         float n;
 899
 900         if(sample == "")
 901                 return;
 902
 903         tokenize(sample);
 904         n = stof(argv(1));
 905         if(n > 0)
 906                 sample = strcat(argv(0), ftos(ceil(random() * n)), ".wav"); // randomization
 907         else
 908                 sample = strcat(argv(0), ".wav"); // randomization
 909
 910         if(teamsay == 2) // only to last attacker
 911         {
 912                 if(teams_matter)
 913                         if(self.pusher)
 914                                 if(self.pusher.team == self.team)
 915                                 {
 916                                         msg_entity = self.pusher;
 917                                         soundto(MSG_ONE, self, chan, sample, VOL_BASE, ATTN_NONE);
 918                                         msg_entity = self;
 919                                         soundto(MSG_ONE, self, chan, sample, VOL_BASE, ATTN_NONE);
 920                                 }
 921         }
 922         else if(teamsay == 0) // to everyone
 923         {
 924                 // broadcast the sound, but it's directional
 925                 sound(self, chan, sample, VOL_BASE, ATTN_NORM);
 926         }
 927         else if(teamsay == 1) // to the same team
 928         {
 929                 if(teams_matter)
 930                 {
 931                         entity e;
 932                         FOR_EACH_REALCLIENT(e)
 933                                 if(!teams_matter || e.team == self.team)
 934                                 {
 935                                         msg_entity = e;
 936                                         soundto(MSG_ONE, self, chan, sample, VOL_BASE, ATTN_NONE);
 937                                 }
 938                 }
 939                 else
 940                 {
 941                         sound(self, chan, sample, VOL_BASE, ATTN_NONE);
 942                 }
 943         }
 944 }
 945
 946 void PlayerSound(.string samplefield, float chan, float teamsay)
 947 {
 948         string sample;
 949         sample = self.samplefield;
 950         GlobalSound(sample, chan, teamsay);
 951 }
 952
 953 void VoiceMessage(string type)
 954 {
 955         var .string sample;
 956         var float teamsay;
 957         sample = GetVoiceMessageSampleField(type);
 958
 959         if(GetPlayerSoundSampleField_notFound)
 960         {
 961                 sprint(self, strcat("Invalid voice. Use one of: ", allvoicesamples, "\n"));
 962                 return;
 963         }
 964
 965         teamsay = GetVoiceMessageTeamsayType(type);
 966
 967         PlayerSound(sample, CHAN_VOICE, teamsay);
 968 }