data/qcsrc/server/cl_player.qc

   1
   2 // changes by LordHavoc on 03/29/04 and 03/30/04 at Vermeulen's request
   3 // merged player_run and player_stand to player_anim
   4 // added death animations to player_anim
   5 // can now spawn thrown weapons from anywhere, not just from players
   6 // thrown weapons now fade out after 20 seconds
   7 // created PlayerGib function
   8 // PlayerDie no longer uses hitloc or damage
   9 // PlayerDie now supports dying animations as well as gibbing
  10 // cleaned up PlayerDie a lot
  11 // added CopyBody
  12
  13 .entity pusher;
  14 .float pushltime;
  15
  16 void CopyBody(float keepvelocity)
  17 {
  18         local entity oldself;
  19         if (self.effects & EF_NODRAW)
  20                 return;
  21         oldself = self;
  22         self = spawn();
  23         self.colormap = oldself.colormap;
  24         self.iscreature = oldself.iscreature;
  25         self.angles = oldself.angles;
  26         self.avelocity = oldself.avelocity;
  27         self.classname = "body";
  28         self.damageforcescale = oldself.damageforcescale;
  29         self.effects = oldself.effects;
  30         self.event_damage = oldself.event_damage;
  31         self.animstate_startframe = oldself.animstate_startframe;
  32         self.animstate_numframes = oldself.animstate_numframes;
  33         self.animstate_framerate = oldself.animstate_framerate;
  34         self.animstate_starttime = oldself.animstate_starttime;
  35         self.animstate_endtime = oldself.animstate_endtime;
  36         self.animstate_override = oldself.animstate_override;
  37         self.animstate_looping = oldself.animstate_looping;
  38         self.frame = oldself.frame;
  39         self.dead_frame = oldself.dead_frame;
  40         self.pain_finished = oldself.pain_finished;
  41         self.health = oldself.health;
  42         self.armorvalue = oldself.armorvalue;
  43         self.armortype = oldself.armortype;
  44         self.model = oldself.model;
  45         self.modelindex = oldself.modelindex;
  46         self.movetype = oldself.movetype;
  47         self.nextthink = oldself.nextthink;
  48         self.skin = oldself.skin;
  49         self.solid = oldself.solid;
  50         self.takedamage = oldself.takedamage;
  51         self.think = oldself.think;
  52         self.gibrandom = oldself.gibrandom;
  53         self.customizeentityforclient = oldself.customizeentityforclient;
  54         if (keepvelocity == 1)
  55                 self.velocity = oldself.velocity;
  56         self.oldvelocity = self.velocity;
  57         self.fade_time = oldself.fade_time;
  58         self.fade_rate = oldself.fade_rate;
  59         //self.weapon = oldself.weapon;
  60         setorigin(self, oldself.origin);
  61         setsize(self, oldself.mins, oldself.maxs);
  62         self.oldorigin = oldself.origin;
  63         self = oldself;
  64 }
  65
  66 float animparseerror;
  67 vector(float animfile) animparseline =
  68 {
  69         local string line;
  70         local float c;
  71         local vector anim;
  72         if (animfile < 0)
  73                 return '0 1 2';
  74         line = fgets(animfile);
  75         c = tokenize(line);
  76         if (c != 3)
  77         {
  78                 animparseerror = TRUE;
  79                 return '0 1 2';
  80         }
  81         anim_x = stof(argv(0));
  82         anim_y = stof(argv(1));
  83         anim_z = stof(argv(2));
  84         // don't allow completely bogus values
  85         if (anim_x < 0 || anim_y < 1 || anim_z < 0.001)
  86                 anim = '0 1 2';
  87         return anim;
  88 };
  89
  90 void() player_setupanimsformodel =
  91 {
  92         local string animfilename;
  93         local float animfile;
  94         // defaults for legacy .zym models without animinfo files
  95         self.anim_die1 = '0 1 0.5'; // 2 seconds
  96         self.anim_die2 = '1 1 0.5'; // 2 seconds
  97         self.anim_draw = '2 1 3'; // TODO: analyze models and set framerate
  98         self.anim_duck = '3 1 100'; // this anim seems bogus in most models, so make it play VERY briefly!
  99         self.anim_duckwalk = '4 1 1';
 100         self.anim_duckjump = '5 1 100'; // zym anims keep playing until changed, so this only has to start the anim, landing will end it
 101         self.anim_duckidle = '6 1 1';
 102         self.anim_idle = '7 1 1';
 103         self.anim_jump = '8 1 100'; // zym anims keep playing until changed, so this only has to start the anim, landing will end it
 104         self.anim_pain1 = '9 1 2'; // 0.5 seconds
 105         self.anim_pain2 = '10 1 2'; // 0.5 seconds
 106         self.anim_shoot = '11 1 5'; // TODO: analyze models and set framerate
 107         self.anim_taunt = '12 1 1'; // FIXME?  there is no code using this anim
 108         self.anim_run = '13 1 1';
 109         self.anim_runbackwards = '14 1 1';
 110         self.anim_strafeleft = '15 1 1';
 111         self.anim_straferight = '16 1 1';
 112         self.anim_dead1 = '17 1 1';
 113         self.anim_dead2 = '18 1 1';
 114         self.anim_forwardright = '19 1 1';
 115         self.anim_forwardleft = '20 1 1';
 116         self.anim_backright = '21 1 1';
 117         self.anim_backleft  = '22 1 1';
 118         animparseerror = FALSE;
 119         animfilename = strcat(self.model, ".animinfo");
 120         animfile = fopen(animfilename, FILE_READ);
 121         if (animfile >= 0)
 122         {
 123                 self.anim_die1         = animparseline(animfile);
 124                 self.anim_die2         = animparseline(animfile);
 125                 self.anim_draw         = animparseline(animfile);
 126                 self.anim_duck         = animparseline(animfile);
 127                 self.anim_duckwalk     = animparseline(animfile);
 128                 self.anim_duckjump     = animparseline(animfile);
 129                 self.anim_duckidle     = animparseline(animfile);
 130                 self.anim_idle         = animparseline(animfile);
 131                 self.anim_jump         = animparseline(animfile);
 132                 self.anim_pain1        = animparseline(animfile);
 133                 self.anim_pain2        = animparseline(animfile);
 134                 self.anim_shoot        = animparseline(animfile);
 135                 self.anim_taunt        = animparseline(animfile);
 136                 self.anim_run          = animparseline(animfile);
 137                 self.anim_runbackwards = animparseline(animfile);
 138                 self.anim_strafeleft   = animparseline(animfile);
 139                 self.anim_straferight  = animparseline(animfile);
 140                 self.anim_forwardright = animparseline(animfile);
 141                 self.anim_forwardleft  = animparseline(animfile);
 142                 self.anim_backright    = animparseline(animfile);
 143                 self.anim_backleft     = animparseline(animfile);
 144                 fclose(animfile);
 145
 146                 // derived anims
 147                 self.anim_dead1 = '0 1 1' + '1 0 0' * (self.anim_die1_x + self.anim_die1_y - 1);
 148                 self.anim_dead2 = '0 1 1' + '1 0 0' * (self.anim_die2_x + self.anim_die2_y - 1);
 149
 150                 if (animparseerror)
 151                         print("Parse error in ", animfilename, ", some player animations are broken\n");
 152         }
 153         else
 154                 dprint("File ", animfilename, " not found, assuming legacy .zym model animation timings\n");
 155         // reset animstate now
 156         player_setanim(self.anim_idle, TRUE, FALSE, TRUE);
 157 };
 158
 159 void(vector anim, float looping, float override, float restart) player_setanim =
 160 {
 161         if (!restart)
 162         if (anim_x == self.animstate_startframe)
 163         if (anim_y == self.animstate_numframes)
 164         if (anim_z == self.animstate_framerate)
 165                 return;
 166         self.animstate_startframe = anim_x;
 167         self.animstate_numframes = anim_y;
 168         self.animstate_framerate = anim_z;
 169         self.animstate_starttime = time;
 170         self.animstate_endtime = time + self.animstate_numframes / self.animstate_framerate;
 171         self.animstate_looping = looping;
 172         self.animstate_override = override;
 173         self.frame = self.animstate_startframe;
 174 };
 175
 176 void() player_updateframe =
 177 {
 178         if (time >= self.animstate_endtime)
 179         {
 180                 if (self.animstate_looping)
 181                 {
 182                         self.animstate_starttime = self.animstate_endtime;
 183                         self.animstate_endtime = self.animstate_endtime + self.animstate_numframes / self.animstate_framerate;
 184                 }
 185                 self.animstate_override = FALSE;
 186         }
 187         self.frame = self.animstate_startframe + bound(0, (time - self.animstate_starttime) * self.animstate_framerate, self.animstate_numframes - 1);
 188 };
 189
 190 void player_anim (void)
 191 {
 192         player_updateframe();
 193
 194         if (self.deadflag != DEAD_NO)
 195         {
 196                 if (time > self.animstate_endtime)
 197                 {
 198                         if (self.maxs_z > 5)
 199                         {
 200                                 self.maxs_z = 5;
 201                                 setsize(self, self.mins, self.maxs);
 202                         }
 203                         self.frame = self.dead_frame;
 204                 }
 205                 return;
 206         }
 207
 208         if (!self.animstate_override)
 209         {
 210                 if (!(self.flags & FL_ONGROUND))
 211                 {
 212                         if (self.crouch)
 213                                 player_setanim(self.anim_duckjump, FALSE, TRUE, FALSE);
 214                         else
 215                                 player_setanim(self.anim_jump, FALSE, TRUE, FALSE);
 216                 }
 217                 else if (self.crouch)
 218                 {
 219                         if (self.movement_x * self.movement_x + self.movement_y * self.movement_y > 20)
 220                                 player_setanim(self.anim_duckwalk, TRUE, FALSE, FALSE);
 221                         else
 222                                 player_setanim(self.anim_duckidle, TRUE, FALSE, FALSE);
 223                 }
 224                 else if ((self.movement_x * self.movement_x + self.movement_y * self.movement_y) > 20)
 225                 {
 226                         if (self.movement_x > 0 && self.movement_y == 0)
 227                                 player_setanim(self.anim_run, TRUE, FALSE, FALSE);
 228                         else if (self.movement_x < 0 && self.movement_y == 0)
 229                                 player_setanim(self.anim_runbackwards, TRUE, FALSE, FALSE);
 230                         else if (self.movement_x == 0 && self.movement_y > 0)
 231                                 player_setanim(self.anim_straferight, TRUE, FALSE, FALSE);
 232                         else if (self.movement_x == 0 && self.movement_y < 0)
 233                                 player_setanim(self.anim_strafeleft, TRUE, FALSE, FALSE);
 234                         else if (self.movement_x > 0 && self.movement_y > 0)
 235                                 player_setanim(self.anim_forwardright, TRUE, FALSE, FALSE);
 236                         else if (self.movement_x > 0 && self.movement_y < 0)
 237                                 player_setanim(self.anim_forwardleft, TRUE, FALSE, FALSE);
 238                         else if (self.movement_x < 0 && self.movement_y > 0)
 239                                 player_setanim(self.anim_backright, TRUE, FALSE, FALSE);
 240                         else if (self.movement_x < 0 && self.movement_y < 0)
 241                                 player_setanim(self.anim_backleft, TRUE, FALSE, FALSE);
 242                         else
 243                                 player_setanim(self.anim_run, TRUE, FALSE, FALSE);
 244                 }
 245                 else
 246                         player_setanim(self.anim_idle, TRUE, FALSE, FALSE);
 247         }
 248 }
 249 //End change by Supajoe on 11:44 PM EST 11/16/03 (Subject: Player animations)
 250
 251 void SpawnThrownWeapon (vector org, float w)
 252 {
 253         if (!cvar("g_pickup_items"))
 254         if (!g_minstagib)
 255                 return;
 256         if (!w)
 257                 return;
 258         if (w == IT_LASER)
 259                 return;
 260
 261         W_ThrowWeapon(randomvec() * 100 + '0 0 200', org - self.origin, FALSE);
 262 }
 263
 264 void PlayerCorpseDamage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 265 {
 266         local float take, save;
 267         pointparticles(particleeffectnum("blood"), hitloc, force, bound(0, damage, 200));
 268         // damage resistance (ignore most of the damage from a bullet or similar)
 269         damage = max(damage - 5, 1);
 270
 271         save = bound(0, damage * cvar("g_balance_armor_blockpercent"), self.armorvalue);
 272         take = bound(0, damage - save, damage);
 273
 274         if (save > 10)
 275                 sound (self, CHAN_IMPACT, "misc/armorimpact.wav", 1, ATTN_NORM);
 276         else if (take > 30)
 277                 sound (self, CHAN_IMPACT, "misc/bodyimpact2.wav", 1, ATTN_NORM);
 278         else if (take > 10)
 279                 sound (self, CHAN_IMPACT, "misc/bodyimpact1.wav", 1, ATTN_NORM);
 280
 281         if (take > 50)
 282                 TossGib (world, "models/gibs/chunk.mdl", hitloc, force * -0.1,1);
 283         if (take > 100)
 284                 TossGib (world, "models/gibs/chunk.mdl", hitloc, force * -0.2,1);
 285
 286         if (!(self.flags & FL_GODMODE))
 287         {
 288                 self.armorvalue = self.armorvalue - save;
 289                 self.health = self.health - take;
 290                 // pause regeneration for 5 seconds
 291                 self.pauseregen_finished = max(self.pauseregen_finished, time + cvar("g_balance_pause_health_regen"));
 292         }
 293         self.dmg_save = self.dmg_save + save;//max(save - 10, 0);
 294         self.dmg_take = self.dmg_take + take;//max(take - 10, 0);
 295         self.dmg_inflictor = inflictor;
 296
 297         if (self.health <= -50)
 298         {
 299                 // don't use any animations as a gib
 300                 self.frame = 0;
 301                 self.dead_frame = 0;
 302                 // view just above the floor
 303                 self.view_ofs = '0 0 4';
 304
 305                 // make a juicy mess
 306                 local float multiplier;
 307                 multiplier = 1;
 308                 if (cvar("ekg"))
 309                         multiplier = 5;
 310                 te_bloodshower (self.origin + self.mins, self.origin + self.maxs, 1200 * multiplier, 1000);
 311
 312                 // make a meaty mess
 313                 TossGib (self, "models/gibs/eye.md3", self.origin, self.velocity,0);
 314                 TossGib (world, "models/gibs/bloodyskull.md3", self.origin, '0 0 600',0);
 315
 316                 local float c;
 317                 c = 0;
 318                 while (c < multiplier)
 319                 {
 320                         c = c + 1;
 321                         TossGib (world, "models/gibs/gib1.md3", self.origin, self.velocity,0);
 322                         //TossGib (world, "models/gibs/gib2.md3", self.origin, self.velocity,0);
 323                         TossGib (world, "models/gibs/gib1.mdl", self.origin, self.velocity,0);
 324                         //TossGib (world, "models/gibs/gib3.md3", self.origin, self.velocity,0);
 325                         TossGib (world, "models/gibs/gib2.mdl", self.origin, self.velocity,0);
 326                         //TossGib (world, "models/gibs/gib4.md3", self.origin, self.velocity,0);
 327                         TossGib (world, "models/gibs/gib3.mdl", self.origin, self.velocity,0);
 328
 329                         // these destory on impact
 330                         TossGib (world, "models/gibs/gib5.md3", self.origin, '-500 0 450',1);
 331                         //TossGib (world, "models/gibs/gib6.md3", self.origin, '0 500 450',1);
 332                         TossGib (world, "models/gibs/chunk.mdl", self.origin, '0 -500 450',1);
 333                         TossGib (world, "models/gibs/chunk.mdl", self.origin, '500 0 450',1);
 334                         TossGib (world, "models/gibs/chunk.mdl", self.origin, self.velocity,1);
 335                         TossGib (world, "models/gibs/chunk.mdl", self.origin, '0 0 450',1);
 336                 }
 337
 338                 sound (self, CHAN_VOICE, "misc/gib.wav", 1, ATTN_NORM);
 339         }
 340 }
 341
 342 void PlayerDamage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 343 {
 344         local float take, save, waves, sdelay;
 345
 346         damage = damage * bound(1.0, self.cvar_cl_handicap, 100.0);
 347
 348         pointparticles(particleeffectnum("blood"), hitloc, force, bound(0, damage, 200));
 349         if (self.pain_finished < time)          //Don't switch pain sequences like crazy
 350         {
 351                 if (random() > 0.5)
 352                         player_setanim(self.anim_pain1, FALSE, TRUE, TRUE);
 353                 else
 354                         player_setanim(self.anim_pain2, FALSE, TRUE, TRUE);
 355                 self.pain_finished = time + 0.5;        //Supajoe
 356
 357                 // throw off bot aim temporarily
 358                 local float shake;
 359                 shake = damage * 5 / (bound(0,skill,100) + 1);
 360                 self.v_angle_x = self.v_angle_x + (random() * 2 - 1) * shake;
 361                 self.v_angle_y = self.v_angle_y + (random() * 2 - 1) * shake;
 362         }
 363
 364         if(g_arena)
 365         if(numspawned < 2)
 366                 return;
 367
 368         if (!g_minstagib)
 369         {
 370                 save = bound(0, damage * cvar("g_balance_armor_blockpercent"), self.armorvalue);
 371                 take = bound(0, damage - save, damage);
 372         }
 373         else
 374         {
 375                 save = 0;
 376                 take = damage;
 377         }
 378
 379         if (save > 10)
 380                 sound (self, CHAN_IMPACT, "misc/armorimpact.wav", 1, ATTN_NORM);
 381         else if (take > 30)
 382                 sound (self, CHAN_IMPACT, "misc/bodyimpact2.wav", 1, ATTN_NORM);
 383         else if (take > 10)
 384                 sound (self, CHAN_IMPACT, "misc/bodyimpact1.wav", 1, ATTN_NORM);
 385
 386         if (take > 50)
 387                 TossGib (world, "models/gibs/chunk.mdl", hitloc, force * -0.1,1);
 388         if (take > 100)
 389                 TossGib (world, "models/gibs/chunk.mdl", hitloc, force * -0.2,1);
 390
 391         if (time > self.spawnshieldtime)
 392         {
 393                 if (!(self.flags & FL_GODMODE))
 394                 {
 395                         self.armorvalue = self.armorvalue - save;
 396                         self.health = self.health - take;
 397                         // pause regeneration for 5 seconds
 398                         self.pauseregen_finished = max(self.pauseregen_finished, time + cvar("g_balance_pause_health_regen"));
 399                 }
 400                 else
 401                         self.max_armorvalue += (save + take);
 402         }
 403         self.dmg_save = self.dmg_save + save;//max(save - 10, 0);
 404         self.dmg_take = self.dmg_take + take;//max(take - 10, 0);
 405         self.dmg_inflictor = inflictor;
 406
 407         if(attacker == self)
 408         {
 409                 // don't reset pushltime for self damage as it may be an attempt to
 410                 // escape a lava pit or similar
 411                 //self.pushltime = 0;
 412         }
 413         else if(attacker.classname == "player" || attacker.classname == "gib")
 414         {
 415                 self.pusher = attacker;
 416                 self.pushltime = time + cvar("g_maxpushtime");
 417         }
 418         else if(time < self.pushltime)
 419         {
 420                 attacker = self.pusher;
 421                 self.pushltime = max(self.pushltime, time + 0.6);
 422         }
 423         else
 424                 self.pushltime = 0;
 425
 426         if (self.health < 1)
 427         {
 428                 self.deaths += 1;
 429
 430                 // become fully visible
 431                 self.alpha = 1;
 432                 // clear selected player display
 433                 ClearSelectedPlayer();
 434                 // throw a weapon
 435                 SpawnThrownWeapon (self.origin + (self.mins + self.maxs) * 0.5, self.switchweapon);
 436                 // print an obituary message
 437                 Obituary (attacker, self, deathtype);
 438                 DropAllRunes(self);
 439                 if(self == attacker)
 440                         kh_Key_DropAll(self, TRUE);
 441                 else if(attacker.classname == "player" || attacker.classname == "gib")
 442                         kh_Key_DropAll(self, FALSE);
 443                 else
 444                         kh_Key_DropAll(self, TRUE);
 445                 if(self.flagcarried)
 446                         DropFlag(self.flagcarried);
 447                 // clear waypoints
 448                 WaypointSprite_PlayerDead();
 449                 // make the corpse upright (not tilted)
 450                 self.angles_x = 0;
 451                 self.angles_z = 0;
 452                 // don't spin
 453                 self.avelocity = '0 0 0';
 454                 // view from the floor
 455                 self.view_ofs = '0 0 -8';
 456                 // toss the corpse
 457                 self.movetype = MOVETYPE_TOSS;
 458                 // shootable corpse
 459                 self.solid = SOLID_CORPSE;
 460                 // don't stick to the floor
 461                 self.flags = self.flags - (self.flags & FL_ONGROUND);
 462                 // dying animation
 463                 self.deadflag = DEAD_DYING;
 464                 // when to allow respawn
 465                 sdelay = 0;
 466                 waves = 0;
 467                 if(cvar("g_respawn_mapsettings"))
 468                 {
 469                         sdelay = cvar("g_respawn_mapsettings_delay");
 470                         waves = cvar("g_respawn_mapsettings_waves");
 471                 }
 472                 if(!sdelay)
 473                         sdelay = cvar(strcat("g_", GetGametype(), "_respawn_delay"));
 474                 if(!sdelay)
 475                         sdelay = cvar("g_respawn_delay");
 476                 if(!waves)
 477                         waves = cvar(strcat("g_", GetGametype(), "_respawn_waves"));
 478                 if(!waves)
 479                         waves = cvar("g_respawn_waves");
 480                 if(waves)
 481                         self.death_time = ceil((time + sdelay) / waves) * waves;
 482                 else
 483                         self.death_time = time + sdelay;
 484                 if((sdelay + waves >= 5.0) && (self.death_time - time > 1.75))
 485                         self.respawn_countdown = 10; // first number to count down from is 10
 486                 else
 487                         self.respawn_countdown = -1; // do not count down
 488                 if (random() < 0.5)
 489                 {
 490                         player_setanim(self.anim_die1, FALSE, TRUE, TRUE);
 491                         self.dead_frame = self.anim_dead1_x;
 492                 }
 493                 else
 494                 {
 495                         player_setanim(self.anim_die2, FALSE, TRUE, TRUE);
 496                         self.dead_frame = self.anim_dead2_x;
 497                 }
 498                 // set damage function to corpse damage
 499                 self.event_damage = PlayerCorpseDamage;
 500                 // call the corpse damage function just in case it wants to gib
 501                 self.event_damage(inflictor, attacker, 0, deathtype, hitloc, force);
 502                 // set up to fade out later
 503                 SUB_SetFade (self, time + 12 + random () * 4, 1);
 504
 505                 // remove laserdot
 506                 if(self.weaponentity)
 507                         if(self.weaponentity.lasertarget)
 508                                 remove(self.weaponentity.lasertarget);
 509
 510                 if(clienttype(self) == CLIENTTYPE_REAL)
 511                 {
 512                         self.fixangle = TRUE;
 513                         //msg_entity = self;
 514                         //WriteByte (MSG_ONE, SVC_SETANGLE);
 515                         //WriteAngle (MSG_ONE, self.v_angle_x);
 516                         //WriteAngle (MSG_ONE, self.v_angle_y);
 517                         //WriteAngle (MSG_ONE, 80);
 518                 }
 519
 520                 if(g_arena)
 521                         Spawnqueue_Unmark(self);
 522         }
 523 }
 524
 525 float UpdateSelectedPlayer_countvalue(float v)
 526 {
 527         return max(0, (v - 1.0) / 0.5);
 528 }
 529
 530 // returns: -2 if no hit, otherwise cos of the angle
 531 // uses the global v_angle
 532 float UpdateSelectedPlayer_canSee(entity p, float mincosangle, float maxdist)
 533 {
 534         vector so, d;
 535         float c;
 536
 537         if(p == self)
 538                 return -2;
 539
 540         if(p.deadflag)
 541                 return -2;
 542
 543         so = self.origin + self.view_ofs;
 544         d = p.origin - so;
 545
 546         // misaimed?
 547         if(dist_point_line(d, '0 0 0', v_forward) > maxdist)
 548                 return -2;
 549
 550         // now find the cos of the angle...
 551         c = normalize(d) * v_forward;
 552
 553         if(c <= mincosangle)
 554                 return -2;
 555
 556         traceline(so, p.origin, MOVE_NOMONSTERS, self);
 557         if(trace_fraction < 1)
 558                 return -2;
 559
 560         return c;
 561 }
 562
 563 void ClearSelectedPlayer()
 564 {
 565         if(self.selected_player)
 566         {
 567                 centerprint_expire(self, CENTERPRIO_POINT);
 568                 self.selected_player = world;
 569                 self.selected_player_display_needs_update = FALSE;
 570         }
 571 }
 572
 573 void UpdateSelectedPlayer()
 574 {
 575         entity selected;
 576         float selected_score;
 577         selected = world;
 578         selected_score = 0.95; // 18 degrees
 579
 580         if(!cvar("sv_allow_shownames"))
 581                 return;
 582
 583         if(clienttype(self) != CLIENTTYPE_REAL)
 584                 return;
 585
 586         if(self.cvar_cl_shownames == 0)
 587                 return;
 588
 589         if(self.cvar_cl_shownames == 1 && !teams_matter)
 590                 return;
 591
 592         makevectors(self.v_angle); // sets v_forward
 593
 594         // 1. cursor trace is always right
 595         if(self.cursor_trace_ent && self.cursor_trace_ent.classname == "player" && !self.cursor_trace_ent.deadflag)
 596         {
 597                 selected = self.cursor_trace_ent;
 598         }
 599         else
 600         {
 601                 // 2. if we don't have a cursor trace, find the player which is least
 602                 //    mis-aimed at
 603                 entity p;
 604                 FOR_EACH_PLAYER(p)
 605                 {
 606                         float c;
 607                         c = UpdateSelectedPlayer_canSee(p, selected_score, 100); // 100 = 2.5 meters
 608                         if(c >= -1)
 609                         {
 610                                 selected = p;
 611                                 selected_score = c;
 612                         }
 613                 }
 614         }
 615
 616         if(selected)
 617         {
 618                 self.selected_player_display_timeout = time + self.cvar_scr_centertime;
 619         }
 620         else
 621         {
 622                 if(time < self.selected_player_display_timeout)
 623                         if(UpdateSelectedPlayer_canSee(self.selected_player, 0.7, 200) >= -1) // 5 meters, 45 degrees
 624                                 selected = self.selected_player;
 625         }
 626
 627         if(selected)
 628         {
 629                 if(selected == self.selected_player)
 630                 {
 631                         float save;
 632                         save = UpdateSelectedPlayer_countvalue(self.selected_player_count);
 633                         self.selected_player_count = self.selected_player_count + frametime;
 634                         if(save != UpdateSelectedPlayer_countvalue(self.selected_player_count))
 635                         {
 636                                 string namestr, healthstr;
 637                                 namestr = playername(selected);
 638                                 if(teams_matter)
 639                                 {
 640                                         healthstr = ftos(floor(selected.health));
 641                                         if(self.team == selected.team)
 642                                         {
 643                                                 namestr = strcat(namestr, " (", healthstr, "%)");
 644                                                 self.selected_player_display_needs_update = TRUE;
 645                                         }
 646                                 }
 647                                 centerprint_atprio(self, CENTERPRIO_POINT, namestr);
 648                         }
 649                 }
 650                 else
 651                 {
 652                         ClearSelectedPlayer();
 653                         self.selected_player = selected;
 654                         self.selected_player_time = time;
 655                         self.selected_player_count = 0;
 656                         self.selected_player_display_needs_update = FALSE;
 657                 }
 658         }
 659         else
 660         {
 661                 ClearSelectedPlayer();
 662         }
 663
 664         if(self.selected_player)
 665                 self.last_selected_player = self.selected_player;
 666 }
 667
 668 .string playersound_attack;
 669 .string playersound_attackinfive;
 670 .string playersound_coverme;
 671 .string playersound_defend;
 672 .string playersound_freelance;
 673 .string playersound_incoming;
 674 .string playersound_meet;
 675 .string playersound_needhelp;
 676 .string playersound_seenflag;
 677 .string playersound_taunt;
 678 .string playersound_teamshoot;
 679 .float modelindex_for_playersound;
 680
 681 float GetVoiceMessageTeamsayType(string type)
 682 {
 683         if(type == "taunt")
 684                 return 0;
 685         if(type == "teamshoot")
 686                 return 2;
 687         return 1;
 688 }
 689
 690 string allvoicesamples = "attack attackinfive coverme defend freelance incoming meet needhelp seenflag taunt teamshoot";
 691 float GetPlayerSoundSampleField_notFound;
 692 .string GetVoiceMessageSampleField(string type)
 693 {
 694         GetPlayerSoundSampleField_notFound = 0;
 695         switch(type)
 696         {
 697                 case "attack":       return playersound_attack;
 698                 case "attackinfive": return playersound_attackinfive;
 699                 case "coverme":      return playersound_coverme;
 700                 case "defend":       return playersound_defend;
 701                 case "freelance":    return playersound_freelance;
 702                 case "incoming":     return playersound_incoming;
 703                 case "meet":         return playersound_meet;
 704                 case "needhelp":     return playersound_needhelp;
 705                 case "seenflag":     return playersound_seenflag;
 706                 case "taunt":        return playersound_taunt;
 707                 case "teamshoot":    return playersound_teamshoot;
 708         }
 709         GetPlayerSoundSampleField_notFound = 1;
 710         return playersound_taunt;
 711 }
 712
 713 .string GetPlayerSoundSampleField(string type)
 714 {
 715         GetPlayerSoundSampleField_notFound = 0;
 716         switch(type)
 717         {
 718                 case "attack":       return playersound_attack;
 719                 default:             return GetVoiceMessageSampleField(type);
 720         }
 721 }
 722
 723 void PrecachePlayerSounds(string f)
 724 {
 725         float fh;
 726         float i, n;
 727         string s;
 728         fh = fopen(f, FILE_READ);
 729         if(fh < 0)
 730                 return;
 731         while((s = fgets(fh)))
 732         {
 733                 if(tokenize(s) != 3)
 734                 {
 735                         dprint("Invalid sound info line: ", s, "\n");
 736                         continue;
 737                 }
 738                 n = stof(argv(2));
 739                 for(i = 1; i <= n; ++i)
 740                         precache_sound(strcat(argv(1), ftos(i), ".wav"));
 741         }
 742         fclose(fh);
 743 }
 744
 745 void LoadPlayerSounds(string f)
 746 {
 747         float fh;
 748         string s;
 749         var .string field;
 750         fh = fopen(f, FILE_READ);
 751         if(fh < 0)
 752                 return;
 753         while((s = fgets(fh)))
 754         {
 755                 if(tokenize(s) != 3)
 756                         continue;
 757                 field = GetPlayerSoundSampleField(argv(0));
 758                 if(GetPlayerSoundSampleField_notFound)
 759                         continue;
 760                 if(self.field)
 761                         strunzone(self.field);
 762                 self.field = strzone(strcat(argv(1), " ", argv(2)));
 763         }
 764         fclose(fh);
 765 }
 766
 767 void UpdatePlayerSounds()
 768 {
 769         if(self.modelindex == self.modelindex_for_playersound)
 770                 return;
 771         self.modelindex_for_playersound = self.modelindex;
 772         LoadPlayerSounds("sound/player/default.sounds");
 773         LoadPlayerSounds(strcat(self.model, ".sounds"));
 774 }
 775
 776 float precache_sound_index (string s) = #19;
 777 void soundto(entity e, entity sounddest, float chan, string samp, float vol, float atten)
 778 {
 779         vector o;
 780         if(clienttype(sounddest) != CLIENTTYPE_REAL)
 781                 return;
 782         o = e.origin + 0.5 * (e.mins + e.maxs);
 783         msg_entity = sounddest;
 784         WriteByte(MSG_ONE, 6);
 785         WriteByte(MSG_ONE, 27); // all bits except SND_LOOPING
 786         WriteByte(MSG_ONE, vol * 255);
 787         WriteByte(MSG_ONE, atten * 64);
 788         WriteEntity(MSG_ONE, e);
 789         WriteByte(MSG_ONE, chan);
 790         WriteShort(MSG_ONE, precache_sound_index(samp));
 791         WriteCoord(MSG_ONE, o_x);
 792         WriteCoord(MSG_ONE, o_y);
 793         WriteCoord(MSG_ONE, o_z);
 794 }
 795
 796 void VoiceMessage(string type)
 797 {
 798         // TODO precache voice messages?
 799         var string sample;
 800         var float teamsay;
 801         sample = self.(GetPlayerSoundSampleField(type));
 802
 803         if(GetPlayerSoundSampleField_notFound)
 804         {
 805                 sprint(self, strcat("Invalid voice. Use one of: ", allvoicesamples, "\n"));
 806                 return;
 807         }
 808
 809         if(!sample)
 810                 return;
 811
 812         teamsay = GetVoiceMessageTeamsayType(type);
 813
 814         tokenize(sample);
 815         sample = strcat(argv(0), ftos(ceil(random() * stof(argv(1)))), ".wav"); // randomization
 816
 817         if(teamsay == 2)
 818         {
 819                 if(teams_matter)
 820                         if(self.pusher)
 821                                 if(self.pusher.team == self.team)
 822                                 {
 823                                         soundto(self, self.pusher, CHAN_VOICE, sample, 1, ATTN_NONE);
 824                                         soundto(self, self, CHAN_VOICE, sample, 1, ATTN_NONE);
 825                                 }
 826         }
 827         else if(teamsay == 0 || !teams_matter)
 828         {
 829                 // broadcast the sound, but it's directional
 830                 sound(self, CHAN_VOICE, sample, 1, ATTN_NORM);
 831         }
 832         else if(teamsay == 1)
 833         {
 834                 entity e;
 835                 FOR_EACH_REALCLIENT(e)
 836                         if(e.team == self.team)
 837                                 soundto(self, e, CHAN_VOICE, sample, 1, ATTN_NONE);
 838         }
 839 }