data/qcsrc/server/cl_player.qc

   1 $frame die1 die2 draw duck duckwalk duckjump duckidle idle
   2 $frame jump pain1 pain2 shoot taunt run runbackwards
   3 $frame strafeleft straferight dead1 dead2 forwardright
   4 $frame forwardleft backright backleft
   5
   6 // changes by LordHavoc on 03/29/04 and 03/30/04 at Vermeulen's request
   7 // merged player_run and player_stand to player_anim
   8 // added death animations to player_anim
   9 // can now spawn thrown weapons from anywhere, not just from players
  10 // thrown weapons now fade out after 20 seconds
  11 // created PlayerGib function
  12 // PlayerDie no longer uses hitloc or damage
  13 // PlayerDie now supports dying animations as well as gibbing
  14 // cleaned up PlayerDie a lot
  15 // added CopyBody
  16
  17 .entity pusher;
  18 .float pushltime;
  19
  20 void CopyBody(float keepvelocity)
  21 {
  22         local entity oldself;
  23         if (self.effects & EF_NODRAW)
  24                 return;
  25         oldself = self;
  26         self = spawn();
  27         self.colormap = oldself.colormap;
  28         self.iscreature = oldself.iscreature;
  29         self.angles = oldself.angles;
  30         self.avelocity = oldself.avelocity;
  31         self.classname = "body";
  32         self.damageforcescale = oldself.damageforcescale;
  33         self.effects = oldself.effects;
  34         self.event_damage = oldself.event_damage;
  35         self.frame = oldself.frame;
  36         self.health = oldself.health;
  37         self.armorvalue = oldself.armorvalue;
  38         self.armortype = oldself.armortype;
  39         self.model = oldself.model;
  40         self.modelindex = oldself.modelindex;
  41         self.movetype = oldself.movetype;
  42         self.nextthink = oldself.nextthink;
  43         self.skin = oldself.skin;
  44         self.solid = oldself.solid;
  45         self.takedamage = oldself.takedamage;
  46         self.think = oldself.think;
  47         if (keepvelocity == 1)
  48                 self.velocity = oldself.velocity;
  49         self.oldvelocity = self.velocity;
  50         self.fade_time = oldself.fade_time;
  51         self.fade_rate = oldself.fade_rate;
  52         //self.weapon = oldself.weapon;
  53         setorigin(self, oldself.origin);
  54         setsize(self, oldself.mins, oldself.maxs);
  55         self.oldorigin = oldself.origin;
  56         self = oldself;
  57 }
  58
  59 void player_anim (void)
  60 {
  61         if (self.deadflag != DEAD_NO)
  62         {
  63                 if (time > self.dead_time)
  64                 {
  65                         if (self.maxs_z > 5)
  66                         {
  67                                 self.maxs_z = 5;
  68                                 setsize(self, self.mins, self.maxs);
  69                         }
  70                         self.frame = self.dead_frame;
  71                 }
  72                 else
  73                         self.frame = self.die_frame;
  74                 return;
  75         }
  76
  77
  78         if (self.crouch)
  79         {
  80                 if (self.movement_x * self.movement_x + self.movement_y * self.movement_y > 20)
  81                         self.frame = $duckwalk;
  82                 else
  83                         self.frame = $duckidle;
  84         }
  85         else if ((self.movement_x * self.movement_x + self.movement_y * self.movement_y) > 20)
  86         {
  87                 if (self.movement_x > 0 && self.movement_y == 0)
  88                         self.frame = $run;
  89                 else if (self.movement_x < 0 && self.movement_y == 0)
  90                         self.frame = $runbackwards;
  91                 else if (self.movement_x == 0 && self.movement_y > 0)
  92                         self.frame = $straferight;
  93                 else if (self.movement_x == 0 && self.movement_y < 0)
  94                         self.frame = $strafeleft;
  95                 else if (self.movement_x > 0 && self.movement_y > 0)
  96                         self.frame = $forwardright;
  97                 else if (self.movement_x > 0 && self.movement_y < 0)
  98                         self.frame = $forwardleft;
  99                 else if (self.movement_x < 0 && self.movement_y > 0)
 100                         self.frame = $backright;
 101                 else if (self.movement_x < 0 && self.movement_y < 0)
 102                         self.frame = $backleft;
 103                 else
 104                         self.frame = $run;
 105         }
 106         else if (self.pain_finished > time)
 107                 self.frame = self.pain_frame;
 108         else if (self.attack_finished > time)
 109                 self.frame = $shoot;
 110         else
 111                 self.frame = $idle;
 112
 113         if (!(self.flags & FL_ONGROUND))
 114         {
 115                 if (self.crouch)
 116                         self.frame = $duckidle;         // if player is crouching while in air, show crouch frame
 117                 else
 118                         self.frame = $jump;
 119         }
 120 }
 121 //End change by Supajoe on 11:44 PM EST 11/16/03 (Subject: Player animations)
 122
 123 void SpawnThrownWeapon (vector org, float w)
 124 {
 125         if (!cvar("g_pickup_items"))
 126         if (!cvar("g_minstagib"))
 127                 return;
 128         if (!w)
 129                 return;
 130         if (w == IT_LASER)
 131                 return;
 132
 133         W_ThrowWeapon(randomvec() * 100 + '0 0 200', org - self.origin, FALSE);
 134 }
 135
 136 void PlayerCorpseDamage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 137 {
 138         local float take, save;
 139         te_blood (hitloc, force, damage);
 140         // damage resistance (ignore most of the damage from a bullet or similar)
 141         damage = max(damage - 5, 1);
 142
 143         save = bound(0, damage * cvar("g_balance_armor_blockpercent"), self.armorvalue);
 144         take = bound(0, damage - save, damage);
 145
 146         if (save > 10)
 147                 sound (self, CHAN_IMPACT, "misc/armorimpact.wav", 1, ATTN_NORM);
 148         else if (take > 30)
 149                 sound (self, CHAN_IMPACT, "misc/bodyimpact2.wav", 1, ATTN_NORM);
 150         else if (take > 10)
 151                 sound (self, CHAN_IMPACT, "misc/bodyimpact1.wav", 1, ATTN_NORM);
 152
 153         if (take > 50)
 154                 TossGib (world, "models/gibs/chunk.mdl", hitloc, force * -0.1,1);
 155         if (take > 100)
 156                 TossGib (world, "models/gibs/chunk.mdl", hitloc, force * -0.2,1);
 157
 158         if (!(self.flags & FL_GODMODE))
 159         {
 160                 self.armorvalue = self.armorvalue - save;
 161                 self.health = self.health - take;
 162                 // pause regeneration for 5 seconds
 163                 self.pauseregen_finished = max(self.pauseregen_finished, time + cvar("g_balance_pause_health_regen"));
 164         }
 165         self.dmg_save = self.dmg_save + save;//max(save - 10, 0);
 166         self.dmg_take = self.dmg_take + take;//max(take - 10, 0);
 167         self.dmg_inflictor = inflictor;
 168
 169         if (self.health <= -50)
 170         {
 171                 // don't use any animations as a gib
 172                 self.frame = 0;
 173                 self.dead_frame = 0;
 174                 self.die_frame = 0;
 175                 // view just above the floor
 176                 self.view_ofs = '0 0 4';
 177
 178                 // make a juicy mess
 179                 te_bloodshower (self.origin + self.mins, self.origin + self.maxs, 800, 1000);
 180                 te_bloodshower (self.origin + self.mins, self.origin + self.maxs, 400, 1000);
 181
 182                 // make a meaty mess
 183                 TossGib (self, "models/gibs/eye.md3", self.origin, self.velocity,0);
 184                 TossGib (world, "models/gibs/bloodyskull.md3", self.origin, '0 0 600',0);
 185
 186                 TossGib (world, "models/gibs/gib1.md3", self.origin, self.velocity,0);
 187                 //TossGib (world, "models/gibs/gib2.md3", self.origin, self.velocity,0);
 188                 TossGib (world, "models/gibs/gib1.mdl", self.origin, self.velocity,0);
 189                 //TossGib (world, "models/gibs/gib3.md3", self.origin, self.velocity,0);
 190                 TossGib (world, "models/gibs/gib2.mdl", self.origin, self.velocity,0);
 191                 //TossGib (world, "models/gibs/gib4.md3", self.origin, self.velocity,0);
 192                 TossGib (world, "models/gibs/gib3.mdl", self.origin, self.velocity,0);
 193
 194                 // these destory on impact
 195                 TossGib (world, "models/gibs/gib5.md3", self.origin, '-500 0 450',1);
 196                 //TossGib (world, "models/gibs/gib6.md3", self.origin, '0 500 450',1);
 197                 TossGib (world, "models/gibs/chunk.mdl", self.origin, '0 -500 450',1);
 198                 TossGib (world, "models/gibs/chunk.mdl", self.origin, '500 0 450',1);
 199                 TossGib (world, "models/gibs/chunk.mdl", self.origin, self.velocity,1);
 200                 TossGib (world, "models/gibs/chunk.mdl", self.origin, '0 0 450',1);
 201
 202                 sound (self, CHAN_VOICE, "misc/gib.wav", 1, ATTN_NORM);
 203         }
 204 }
 205
 206 void DropAllRunes(entity pl);
 207
 208
 209 void PlayerDamage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 210 {
 211         local float take, save;
 212
 213         te_blood (hitloc, force, damage);
 214         if (self.pain_finished < time)          //Don't switch pain sequences like crazy
 215         {
 216                 if (random() > 0.5)
 217                         self.pain_frame = $pain1;
 218                 else
 219                         self.pain_frame = $pain2;
 220                 self.pain_finished = time + 0.5;        //Supajoe
 221
 222                 // throw off bot aim temporarily
 223                 local float shake;
 224                 shake = damage * 5 / (bound(0,skill,100) + 1);
 225                 self.v_angle_x = self.v_angle_x + (random() * 2 - 1) * shake;
 226                 self.v_angle_y = self.v_angle_y + (random() * 2 - 1) * shake;
 227         }
 228
 229         if(cvar("g_arena"))
 230         if(numspawned < 2)
 231                 return;
 232
 233         if (!cvar("g_minstagib"))
 234         {
 235                 save = bound(0, damage * cvar("g_balance_armor_blockpercent"), self.armorvalue);
 236                 take = bound(0, damage - save, damage);
 237         }
 238         else
 239         {
 240                 save = 0;
 241                 take = damage;
 242         }
 243
 244         if (save > 10)
 245                 sound (self, CHAN_IMPACT, "misc/armorimpact.wav", 1, ATTN_NORM);
 246         else if (take > 30)
 247                 sound (self, CHAN_IMPACT, "misc/bodyimpact2.wav", 1, ATTN_NORM);
 248         else if (take > 10)
 249                 sound (self, CHAN_IMPACT, "misc/bodyimpact1.wav", 1, ATTN_NORM);
 250
 251         if (take > 50)
 252                 TossGib (world, "models/gibs/chunk.mdl", hitloc, force * -0.1,1);
 253         if (take > 100)
 254                 TossGib (world, "models/gibs/chunk.mdl", hitloc, force * -0.2,1);
 255
 256         if (!(self.flags & FL_GODMODE))
 257         if (time > self.spawnshieldtime)
 258         {
 259                 self.armorvalue = self.armorvalue - save;
 260                 self.health = self.health - take;
 261                 // pause regeneration for 5 seconds
 262                 self.pauseregen_finished = max(self.pauseregen_finished, time + cvar("g_balance_pause_health_regen"));
 263         }
 264         self.dmg_save = self.dmg_save + save;//max(save - 10, 0);
 265         self.dmg_take = self.dmg_take + take;//max(take - 10, 0);
 266         self.dmg_inflictor = inflictor;
 267
 268         if(attacker == self)
 269         {
 270                 // don't reset pushltime for self damage as it may be an attempt to
 271                 // escape a lava pit or similar
 272                 //self.pushltime = 0;
 273         }
 274         else if(attacker.classname == "player" || attacker.classname == "gib")
 275         {
 276                 self.pusher = attacker;
 277                 self.pushltime = time + cvar("g_maxpushtime");
 278         }
 279         else if(time < self.pushltime)
 280         {
 281                 attacker = self.pusher;
 282                 self.pushltime = max(self.pushltime, time + 0.6);
 283         }
 284         else
 285                 self.pushltime = 0;
 286
 287         if (self.health < 1)
 288         {
 289                 self.deaths += 1;
 290
 291                 // become fully visible
 292                 self.alpha = 1;
 293                 // clear selected player display
 294                 ClearSelectedPlayer();
 295                 // throw a weapon
 296                 SpawnThrownWeapon (self.origin + (self.mins + self.maxs) * 0.5, self.switchweapon);
 297                 // print an obituary message
 298                 Obituary (attacker, self, deathtype);
 299                 DropAllRunes(self);
 300                 // make the corpse upright (not tilted)
 301                 self.angles_x = 0;
 302                 self.angles_z = 0;
 303                 // don't spin
 304                 self.avelocity = '0 0 0';
 305                 // view from the floor
 306                 self.view_ofs = '0 0 -8';
 307                 // toss the corpse
 308                 self.movetype = MOVETYPE_TOSS;
 309                 // shootable corpse
 310                 self.solid = SOLID_CORPSE;
 311                 // don't stick to the floor
 312                 self.flags = self.flags - (self.flags & FL_ONGROUND);
 313                 // dying animation
 314                 self.deadflag = DEAD_DYING;
 315                 // when to allow respawn
 316                 self.death_time = time + 0.5;
 317                 // when to switch to the dead_frame
 318                 self.dead_time = time + 2;
 319                 if (random() < 0.5)
 320                 {
 321                         self.die_frame = $die1;
 322                         self.dead_frame = $dead1;
 323                 }
 324                 else
 325                 {
 326                         self.die_frame = $die2;
 327                         self.dead_frame = $dead2;
 328                 }
 329                 // start the animation
 330                 player_anim();
 331                 // set damage function to corpse damage
 332                 self.event_damage = PlayerCorpseDamage;
 333                 // call the corpse damage function just in case it wants to gib
 334                 self.event_damage(inflictor, attacker, 0, deathtype, hitloc, force);
 335                 // set up to fade out later
 336                 SUB_SetFade (self, time + 12 + random () * 4, 1);
 337
 338                 // remove laserdot
 339                 if(self.weaponentity)
 340                         if(self.weaponentity.lasertarget)
 341                                 remove(self.weaponentity.lasertarget);
 342
 343                 if(clienttype(self) == CLIENTTYPE_REAL)
 344                 {
 345                         self.fixangle = TRUE;
 346                         //msg_entity = self;
 347                         //WriteByte (MSG_ONE, SVC_SETANGLE);
 348                         //WriteAngle (MSG_ONE, self.v_angle_x);
 349                         //WriteAngle (MSG_ONE, self.v_angle_y);
 350                         //WriteAngle (MSG_ONE, 80);
 351                 }
 352
 353                 if(cvar("g_arena"))
 354                         Spawnqueue_Unmark(self);
 355         }
 356 }
 357
 358 float UpdateSelectedPlayer_countvalue(float v)
 359 {
 360         return max(0, (v - 1.0) / 0.5);
 361 }
 362
 363 // returns: -2 if no hit, otherwise cos of the angle
 364 // uses the global v_angle
 365 float UpdateSelectedPlayer_canSee(entity p, float mincosangle, float maxdist)
 366 {
 367         vector so, d;
 368         float c;
 369
 370         if(p == self)
 371                 return -2;
 372
 373         if(p.deadflag)
 374                 return -2;
 375
 376         so = self.origin + self.view_ofs;
 377         d = p.origin - so;
 378
 379         // misaimed?
 380         if(dist_point_line(d, '0 0 0', v_forward) > maxdist)
 381                 return -2;
 382
 383         // now find the cos of the angle...
 384         c = normalize(d) * v_forward;
 385
 386         if(c <= mincosangle)
 387                 return -2;
 388
 389         traceline(so, p.origin, MOVE_NOMONSTERS, self);
 390         if(trace_fraction < 1)
 391                 return -2;
 392
 393         return c;
 394 }
 395
 396 void ClearSelectedPlayer()
 397 {
 398         if(self.selected_player)
 399         {
 400                 centermsg_set(CENTERMSG_POINT, "");
 401                 self.selected_player = world;
 402                 self.selected_player_display_needs_update = FALSE;
 403         }
 404 }
 405
 406 void UpdateSelectedPlayer()
 407 {
 408         entity selected;
 409         float selected_score;
 410         selected = world;
 411         selected_score = 0.95; // 18 degrees
 412
 413         if(!cvar("sv_allow_shownames"))
 414                 return;
 415
 416         if(clienttype(self) != CLIENTTYPE_REAL)
 417                 return;
 418
 419         if(self.cvar_cl_shownames == 0)
 420                 return;
 421
 422         if(self.cvar_cl_shownames == 1 && !teams_matter)
 423                 return;
 424
 425         makevectors(self.v_angle); // sets v_forward
 426
 427         // 1. cursor trace is always right
 428         if(self.cursor_trace_ent && self.cursor_trace_ent.classname == "player" && !self.cursor_trace_ent.deadflag)
 429         {
 430                 selected = self.cursor_trace_ent;
 431         }
 432         else
 433         {
 434                 // 2. if we don't have a cursor trace, find the player which is least
 435                 //    mis-aimed at
 436                 entity p;
 437                 for(p = find(world, classname, "player"); p; p = find(p, classname, "player"))
 438                 {
 439                         float c;
 440                         c = UpdateSelectedPlayer_canSee(p, selected_score, 100); // 100 = 2.5 meters
 441                         if(c >= -1)
 442                         {
 443                                 selected = p;
 444                                 selected_score = c;
 445                         }
 446                 }
 447         }
 448
 449         if(selected)
 450         {
 451                 self.selected_player_display_timeout = time + self.cvar_scr_centertime;
 452         }
 453         else
 454         {
 455                 if(time < self.selected_player_display_timeout)
 456                         if(UpdateSelectedPlayer_canSee(self.selected_player, 0.7, 200) >= -1) // 5 meters, 45 degrees
 457                                 selected = self.selected_player;
 458         }
 459
 460         if(selected)
 461         {
 462                 if(selected == self.selected_player)
 463                 {
 464                         float save;
 465                         save = UpdateSelectedPlayer_countvalue(self.selected_player_count);
 466                         self.selected_player_count = self.selected_player_count + frametime;
 467                         if(save != UpdateSelectedPlayer_countvalue(self.selected_player_count))
 468                         {
 469                                 string namestr, healthstr;
 470                                 if(teams_matter)
 471                                 {
 472                                         namestr = decolorize(selected.netname);
 473                                         healthstr = ftos(floor(selected.health));
 474                                         if(self.team == selected.team)
 475                                         {
 476                                                 namestr = strcat(Team_ColorCode(selected.team), namestr, " (", healthstr, "%)");
 477                                                 self.selected_player_display_needs_update = TRUE;
 478                                         }
 479                                         else
 480                                                 namestr = strcat(Team_ColorCode(selected.team), namestr);
 481                                 }
 482                                 else
 483                                 {
 484                                         namestr = selected.netname;
 485                                 }
 486                                 centermsg_set(CENTERMSG_POINT, namestr);
 487                         }
 488                 }
 489                 else
 490                 {
 491                         ClearSelectedPlayer();
 492                         self.selected_player = selected;
 493                         self.selected_player_time = time;
 494                         self.selected_player_count = 0;
 495                         self.selected_player_display_needs_update = FALSE;
 496                         // dprint("Selected: ", selected.netname, "\n");
 497                 }
 498         }
 499         else
 500         {
 501                 ClearSelectedPlayer();
 502         }
 503
 504         if(self.selected_player)
 505                 self.last_selected_player = self.selected_player;
 506 }