data/qcsrc/server/cl_player.qc

   1
   2 // changes by LordHavoc on 03/29/04 and 03/30/04 at Vermeulen's request
   3 // merged player_run and player_stand to player_anim
   4 // added death animations to player_anim
   5 // can now spawn thrown weapons from anywhere, not just from players
   6 // thrown weapons now fade out after 20 seconds
   7 // created PlayerGib function
   8 // PlayerDie no longer uses hitloc or damage
   9 // PlayerDie now supports dying animations as well as gibbing
  10 // cleaned up PlayerDie a lot
  11 // added CopyBody
  12
  13 .entity pusher;
  14 .float pushltime;
  15
  16 void CopyBody(float keepvelocity)
  17 {
  18         local entity oldself;
  19         if (self.effects & EF_NODRAW)
  20                 return;
  21         oldself = self;
  22         self = spawn();
  23         self.colormap = oldself.colormap;
  24         self.iscreature = oldself.iscreature;
  25         self.angles = oldself.angles;
  26         self.avelocity = oldself.avelocity;
  27         self.classname = "body";
  28         self.damageforcescale = oldself.damageforcescale;
  29         self.effects = oldself.effects;
  30         self.event_damage = oldself.event_damage;
  31         self.animstate_startframe = oldself.animstate_startframe;
  32         self.animstate_numframes = oldself.animstate_numframes;
  33         self.animstate_framerate = oldself.animstate_framerate;
  34         self.animstate_starttime = oldself.animstate_starttime;
  35         self.animstate_endtime = oldself.animstate_endtime;
  36         self.animstate_override = oldself.animstate_override;
  37         self.animstate_looping = oldself.animstate_looping;
  38         self.frame = oldself.frame;
  39         self.dead_frame = oldself.dead_frame;
  40         self.pain_finished = oldself.pain_finished;
  41         self.health = oldself.health;
  42         self.armorvalue = oldself.armorvalue;
  43         self.armortype = oldself.armortype;
  44         self.model = oldself.model;
  45         self.modelindex = oldself.modelindex;
  46         self.movetype = oldself.movetype;
  47         self.nextthink = oldself.nextthink;
  48         self.skin = oldself.skin;
  49         self.solid = oldself.solid;
  50         self.takedamage = oldself.takedamage;
  51         self.think = oldself.think;
  52         self.gibrandom = oldself.gibrandom;
  53         self.customizeentityforclient = oldself.customizeentityforclient;
  54         if (keepvelocity == 1)
  55                 self.velocity = oldself.velocity;
  56         self.oldvelocity = self.velocity;
  57         self.fade_time = oldself.fade_time;
  58         self.fade_rate = oldself.fade_rate;
  59         //self.weapon = oldself.weapon;
  60         setorigin(self, oldself.origin);
  61         setsize(self, oldself.mins, oldself.maxs);
  62         self.oldorigin = oldself.origin;
  63         self = oldself;
  64 }
  65
  66 float animparseerror;
  67 vector(float animfile) animparseline =
  68 {
  69         local string line;
  70         local float c;
  71         local vector anim;
  72         if (animfile < 0)
  73                 return '0 1 2';
  74         line = fgets(animfile);
  75         c = tokenize(line);
  76         if (c != 3)
  77         {
  78                 animparseerror = TRUE;
  79                 return '0 1 2';
  80         }
  81         anim_x = stof(argv(0));
  82         anim_y = stof(argv(1));
  83         anim_z = stof(argv(2));
  84         // don't allow completely bogus values
  85         if (anim_x < 0 || anim_y < 1 || anim_z < 0.001)
  86                 anim = '0 1 2';
  87         return anim;
  88 };
  89
  90 void() player_setupanimsformodel =
  91 {
  92         local string animfilename;
  93         local float animfile;
  94         // defaults for legacy .zym models without animinfo files
  95         self.anim_die1 = '0 1 0.5'; // 2 seconds
  96         self.anim_die2 = '1 1 0.5'; // 2 seconds
  97         self.anim_draw = '2 1 3'; // TODO: analyze models and set framerate
  98         self.anim_duck = '3 1 100'; // this anim seems bogus in most models, so make it play VERY briefly!
  99         self.anim_duckwalk = '4 1 1';
 100         self.anim_duckjump = '5 1 100'; // zym anims keep playing until changed, so this only has to start the anim, landing will end it
 101         self.anim_duckidle = '6 1 1';
 102         self.anim_idle = '7 1 1';
 103         self.anim_jump = '8 1 100'; // zym anims keep playing until changed, so this only has to start the anim, landing will end it
 104         self.anim_pain1 = '9 1 2'; // 0.5 seconds
 105         self.anim_pain2 = '10 1 2'; // 0.5 seconds
 106         self.anim_shoot = '11 1 5'; // TODO: analyze models and set framerate
 107         self.anim_taunt = '12 1 1'; // FIXME?  there is no code using this anim
 108         self.anim_run = '13 1 1';
 109         self.anim_runbackwards = '14 1 1';
 110         self.anim_strafeleft = '15 1 1';
 111         self.anim_straferight = '16 1 1';
 112         self.anim_dead1 = '17 1 1';
 113         self.anim_dead2 = '18 1 1';
 114         self.anim_forwardright = '19 1 1';
 115         self.anim_forwardleft = '20 1 1';
 116         self.anim_backright = '21 1 1';
 117         self.anim_backleft  = '22 1 1';
 118         animparseerror = FALSE;
 119         animfilename = strcat(self.model, ".animinfo");
 120         animfile = fopen(animfilename, FILE_READ);
 121         if (animfile >= 0)
 122         {
 123                 self.anim_die1         = animparseline(animfile);
 124                 self.anim_die2         = animparseline(animfile);
 125                 self.anim_draw         = animparseline(animfile);
 126                 self.anim_duck         = animparseline(animfile);
 127                 self.anim_duckwalk     = animparseline(animfile);
 128                 self.anim_duckjump     = animparseline(animfile);
 129                 self.anim_duckidle     = animparseline(animfile);
 130                 self.anim_idle         = animparseline(animfile);
 131                 self.anim_jump         = animparseline(animfile);
 132                 self.anim_pain1        = animparseline(animfile);
 133                 self.anim_pain2        = animparseline(animfile);
 134                 self.anim_shoot        = animparseline(animfile);
 135                 self.anim_taunt        = animparseline(animfile);
 136                 self.anim_run          = animparseline(animfile);
 137                 self.anim_runbackwards = animparseline(animfile);
 138                 self.anim_strafeleft   = animparseline(animfile);
 139                 self.anim_straferight  = animparseline(animfile);
 140                 self.anim_forwardright = animparseline(animfile);
 141                 self.anim_forwardleft  = animparseline(animfile);
 142                 self.anim_backright    = animparseline(animfile);
 143                 self.anim_backleft     = animparseline(animfile);
 144                 fclose(animfile);
 145
 146                 // derived anims
 147                 self.anim_dead1 = '0 1 1' + '1 0 0' * (self.anim_die1_x + self.anim_die1_y - 1);
 148                 self.anim_dead2 = '0 1 1' + '1 0 0' * (self.anim_die2_x + self.anim_die2_y - 1);
 149
 150                 if (animparseerror)
 151                         print("Parse error in ", animfilename, ", some player animations are broken\n");
 152         }
 153         else
 154                 dprint("File ", animfilename, " not found, assuming legacy .zym model animation timings\n");
 155         // reset animstate now
 156         player_setanim(self.anim_idle, TRUE, FALSE, TRUE);
 157 };
 158
 159 void(vector anim, float looping, float override, float restart) player_setanim =
 160 {
 161         if (!restart)
 162         if (anim_x == self.animstate_startframe)
 163         if (anim_y == self.animstate_numframes)
 164         if (anim_z == self.animstate_framerate)
 165                 return;
 166         self.animstate_startframe = anim_x;
 167         self.animstate_numframes = anim_y;
 168         self.animstate_framerate = anim_z;
 169         self.animstate_starttime = time;
 170         self.animstate_endtime = time + self.animstate_numframes / self.animstate_framerate;
 171         self.animstate_looping = looping;
 172         self.animstate_override = override;
 173         self.frame = self.animstate_startframe;
 174 };
 175
 176 void() player_updateframe =
 177 {
 178         if (time >= self.animstate_endtime)
 179         {
 180                 if (self.animstate_looping)
 181                 {
 182                         self.animstate_starttime = self.animstate_endtime;
 183                         self.animstate_endtime = self.animstate_endtime + self.animstate_numframes / self.animstate_framerate;
 184                 }
 185                 self.animstate_override = FALSE;
 186         }
 187         self.frame = self.animstate_startframe + bound(0, (time - self.animstate_starttime) * self.animstate_framerate, self.animstate_numframes - 1);
 188 };
 189
 190 void player_anim (void)
 191 {
 192         player_updateframe();
 193
 194         if (self.deadflag != DEAD_NO)
 195         {
 196                 if (time > self.animstate_endtime)
 197                 {
 198                         if (self.maxs_z > 5)
 199                         {
 200                                 self.maxs_z = 5;
 201                                 setsize(self, self.mins, self.maxs);
 202                         }
 203                         self.frame = self.dead_frame;
 204                 }
 205                 return;
 206         }
 207
 208         if (!self.animstate_override)
 209         {
 210                 if (!(self.flags & FL_ONGROUND))
 211                 {
 212                         if (self.crouch)
 213                                 player_setanim(self.anim_duckjump, FALSE, TRUE, FALSE);
 214                         else
 215                                 player_setanim(self.anim_jump, FALSE, TRUE, FALSE);
 216                 }
 217                 else if (self.crouch)
 218                 {
 219                         if (self.movement_x * self.movement_x + self.movement_y * self.movement_y > 20)
 220                                 player_setanim(self.anim_duckwalk, TRUE, FALSE, FALSE);
 221                         else
 222                                 player_setanim(self.anim_duckidle, TRUE, FALSE, FALSE);
 223                 }
 224                 else if ((self.movement_x * self.movement_x + self.movement_y * self.movement_y) > 20)
 225                 {
 226                         if (self.movement_x > 0 && self.movement_y == 0)
 227                                 player_setanim(self.anim_run, TRUE, FALSE, FALSE);
 228                         else if (self.movement_x < 0 && self.movement_y == 0)
 229                                 player_setanim(self.anim_runbackwards, TRUE, FALSE, FALSE);
 230                         else if (self.movement_x == 0 && self.movement_y > 0)
 231                                 player_setanim(self.anim_straferight, TRUE, FALSE, FALSE);
 232                         else if (self.movement_x == 0 && self.movement_y < 0)
 233                                 player_setanim(self.anim_strafeleft, TRUE, FALSE, FALSE);
 234                         else if (self.movement_x > 0 && self.movement_y > 0)
 235                                 player_setanim(self.anim_forwardright, TRUE, FALSE, FALSE);
 236                         else if (self.movement_x > 0 && self.movement_y < 0)
 237                                 player_setanim(self.anim_forwardleft, TRUE, FALSE, FALSE);
 238                         else if (self.movement_x < 0 && self.movement_y > 0)
 239                                 player_setanim(self.anim_backright, TRUE, FALSE, FALSE);
 240                         else if (self.movement_x < 0 && self.movement_y < 0)
 241                                 player_setanim(self.anim_backleft, TRUE, FALSE, FALSE);
 242                         else
 243                                 player_setanim(self.anim_run, TRUE, FALSE, FALSE);
 244                 }
 245                 else
 246                         player_setanim(self.anim_idle, TRUE, FALSE, FALSE);
 247         }
 248 }
 249 //End change by Supajoe on 11:44 PM EST 11/16/03 (Subject: Player animations)
 250
 251 void SpawnThrownWeapon (vector org, float w)
 252 {
 253         if (!cvar("g_pickup_items"))
 254         if (!g_minstagib)
 255                 return;
 256         if (!w)
 257                 return;
 258         if (w == IT_LASER)
 259                 return;
 260
 261         W_ThrowWeapon(randomvec() * 100 + '0 0 200', org - self.origin, FALSE);
 262 }
 263
 264 void PlayerCorpseDamage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 265 {
 266         local float take, save;
 267         pointparticles(particleeffectnum("blood"), hitloc, force, bound(0, damage, 200));
 268         // damage resistance (ignore most of the damage from a bullet or similar)
 269         damage = max(damage - 5, 1);
 270
 271         save = bound(0, damage * cvar("g_balance_armor_blockpercent"), self.armorvalue);
 272         take = bound(0, damage - save, damage);
 273
 274         if (save > 10)
 275                 sound (self, CHAN_IMPACT, "misc/armorimpact.wav", 1, ATTN_NORM);
 276         else if (take > 30)
 277                 sound (self, CHAN_IMPACT, "misc/bodyimpact2.wav", 1, ATTN_NORM);
 278         else if (take > 10)
 279                 sound (self, CHAN_IMPACT, "misc/bodyimpact1.wav", 1, ATTN_NORM);
 280
 281         if (take > 50)
 282                 TossGib (world, "models/gibs/chunk.mdl", hitloc, force * -0.1,1);
 283         if (take > 100)
 284                 TossGib (world, "models/gibs/chunk.mdl", hitloc, force * -0.2,1);
 285
 286         if (!(self.flags & FL_GODMODE))
 287         {
 288                 self.armorvalue = self.armorvalue - save;
 289                 self.health = self.health - take;
 290                 // pause regeneration for 5 seconds
 291                 self.pauseregen_finished = max(self.pauseregen_finished, time + cvar("g_balance_pause_health_regen"));
 292         }
 293         self.dmg_save = self.dmg_save + save;//max(save - 10, 0);
 294         self.dmg_take = self.dmg_take + take;//max(take - 10, 0);
 295         self.dmg_inflictor = inflictor;
 296
 297         if (self.health <= -50)
 298         {
 299                 // don't use any animations as a gib
 300                 self.frame = 0;
 301                 self.dead_frame = 0;
 302                 // view just above the floor
 303                 self.view_ofs = '0 0 4';
 304
 305                 // make a juicy mess
 306                 local float multiplier;
 307                 multiplier = 1;
 308                 if (cvar("ekg"))
 309                         multiplier = 5;
 310                 te_bloodshower (self.origin + self.mins, self.origin + self.maxs, 1200 * multiplier, 1000);
 311
 312                 // make a meaty mess
 313                 TossGib (self, "models/gibs/eye.md3", self.origin + self.view_ofs, self.velocity + randomvec() * 150,0);
 314                 TossGib (world, "models/gibs/bloodyskull.md3", self.origin + self.view_ofs, self.velocity,0);
 315
 316                 local float c;
 317                 c = 0;
 318                 while (c < multiplier)
 319                 {
 320                         c = c + 1;
 321                         //TossGib (world, "models/gibs/gib1.md3", self.origin, self.velocity + randomvec() * 450,0);
 322                         //TossGib (world, "models/gibs/gib2.md3", self.origin, self.velocity + randomvec() * 450,0);
 323                         //TossGib (world, "models/gibs/gib3.md3", self.origin, self.velocity + randomvec() * 450,0);
 324                         //TossGib (world, "models/gibs/gib4.md3", self.origin, self.velocity + randomvec() * 450,0);
 325                         //TossGib (world, "models/gibs/gib5.md3", self.origin, self.velocity + randomvec() * 450,0);
 326                         //TossGib (world, "models/gibs/gib6.md3", self.origin, self.velocity + randomvec() * 450,0);
 327
 328                         TossGib (world, "models/gibs/arm.md3", self.origin + self.view_ofs, self.velocity + randomvec() * (random() * 120 + 90),0);
 329                         TossGib (world, "models/gibs/arm.md3", self.origin + self.view_ofs, self.velocity + randomvec() * (random() * 120 + 90),0);
 330                         //TossGib (world, "models/gibs/arm.md3", self.origin + self.view_ofs, self.velocity + randomvec() * 150,0);
 331                         //TossGib (world, "models/gibs/arm.md3", self.origin + self.view_ofs, self.velocity + randomvec() * 150,0);
 332                         TossGib (world, "models/gibs/chest.md3", self.origin + self.view_ofs * 0.5, self.velocity + randomvec() * (random() * 120 + 80),0);
 333                         //TossGib (world, "models/gibs/smallchest.md3", self.origin + self.view_ofs, self.velocity + randomvec() * 150,0);
 334                         TossGib (world, "models/gibs/smallchest.md3", self.origin + self.view_ofs, self.velocity + randomvec() * (random() * 120 + 80),0);
 335                         TossGib (world, "models/gibs/leg1.md3", self.origin + self.view_ofs * -0.2, self.velocity + randomvec() * (random() * 120 + 85),0);
 336                         TossGib (world, "models/gibs/leg2.md3", self.origin + self.view_ofs * -0.4, self.velocity + randomvec() * (random() * 120 + 85),0);
 337                         //TossGib (world, "models/gibs/leg1.md3", self.origin + self.view_ofs * -0.2, self.velocity + randomvec() * 150,0);
 338                         //TossGib (world, "models/gibs/leg2.md3", self.origin + self.view_ofs * -0.4, self.velocity + randomvec() * 150,0);
 339
 340                         // these splat on impact
 341                         TossGib (world, "models/gibs/chunk.mdl", self.origin, self.velocity + randomvec() * 450,1);
 342                         TossGib (world, "models/gibs/chunk.mdl", self.origin, self.velocity + randomvec() * 450,1);
 343                         TossGib (world, "models/gibs/chunk.mdl", self.origin, self.velocity + randomvec() * 450,1);
 344                         TossGib (world, "models/gibs/chunk.mdl", self.origin, self.velocity + randomvec() * 450,1);
 345                 }
 346
 347                 sound (self, CHAN_VOICE, "misc/gib.wav", 1, ATTN_NORM);
 348         }
 349 }
 350
 351 void ClientKill_Now_TeamChange();
 352
 353 void PlayerDamage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 354 {
 355         local float take, save, waves, sdelay;
 356
 357         damage = damage * bound(1.0, self.cvar_cl_handicap, 100.0);
 358
 359         pointparticles(particleeffectnum("blood"), hitloc, force, bound(0, damage, 200));
 360         if (self.pain_finished < time)          //Don't switch pain sequences like crazy
 361         {
 362                 if (random() > 0.5)
 363                         player_setanim(self.anim_pain1, FALSE, TRUE, TRUE);
 364                 else
 365                         player_setanim(self.anim_pain2, FALSE, TRUE, TRUE);
 366                 self.pain_finished = time + 0.5;        //Supajoe
 367
 368                 // throw off bot aim temporarily
 369                 local float shake;
 370                 shake = damage * 5 / (bound(0,skill,100) + 1);
 371                 self.v_angle_x = self.v_angle_x + (random() * 2 - 1) * shake;
 372                 self.v_angle_y = self.v_angle_y + (random() * 2 - 1) * shake;
 373         }
 374
 375         if(g_arena)
 376         if(numspawned < 2)
 377                 return;
 378
 379         if (!g_minstagib)
 380         {
 381                 save = bound(0, damage * cvar("g_balance_armor_blockpercent"), self.armorvalue);
 382                 take = bound(0, damage - save, damage);
 383         }
 384         else
 385         {
 386                 save = 0;
 387                 take = damage;
 388         }
 389
 390         if (save > 10)
 391                 sound (self, CHAN_IMPACT, "misc/armorimpact.wav", 1, ATTN_NORM);
 392         else if (take > 30)
 393                 sound (self, CHAN_IMPACT, "misc/bodyimpact2.wav", 1, ATTN_NORM);
 394         else if (take > 10)
 395                 sound (self, CHAN_IMPACT, "misc/bodyimpact1.wav", 1, ATTN_NORM);
 396
 397         if (take > 50)
 398                 TossGib (world, "models/gibs/chunk.mdl", hitloc, force * -0.1,1);
 399         if (take > 100)
 400                 TossGib (world, "models/gibs/chunk.mdl", hitloc, force * -0.2,1);
 401
 402         if (time > self.spawnshieldtime)
 403         {
 404                 if (!(self.flags & FL_GODMODE))
 405                 {
 406                         self.armorvalue = self.armorvalue - save;
 407                         self.health = self.health - take;
 408                         // pause regeneration for 5 seconds
 409                         self.pauseregen_finished = max(self.pauseregen_finished, time + cvar("g_balance_pause_health_regen"));
 410                 }
 411                 else
 412                         self.max_armorvalue += (save + take);
 413         }
 414         self.dmg_save = self.dmg_save + save;//max(save - 10, 0);
 415         self.dmg_take = self.dmg_take + take;//max(take - 10, 0);
 416         self.dmg_inflictor = inflictor;
 417
 418         if(attacker == self)
 419         {
 420                 // don't reset pushltime for self damage as it may be an attempt to
 421                 // escape a lava pit or similar
 422                 //self.pushltime = 0;
 423         }
 424         else if(attacker.classname == "player" || attacker.classname == "gib")
 425         {
 426                 self.pusher = attacker;
 427                 self.pushltime = time + cvar("g_maxpushtime");
 428         }
 429         else if(time < self.pushltime)
 430         {
 431                 attacker = self.pusher;
 432                 self.pushltime = max(self.pushltime, time + 0.6);
 433         }
 434         else
 435                 self.pushltime = 0;
 436
 437         if (self.health < 1)
 438         {
 439                 float defer_ClientKill_Now_TeamChange;
 440                 defer_ClientKill_Now_TeamChange = FALSE;
 441
 442                 self.deaths += 1;
 443
 444                 // get rid of kill indicator
 445                 if(self.killindicator)
 446                 {
 447                         remove(self.killindicator);
 448                         self.killindicator = world;
 449                         if(self.killindicator_teamchange)
 450                                 defer_ClientKill_Now_TeamChange = TRUE;
 451                 }
 452
 453                 // become fully visible
 454                 self.alpha = 1;
 455                 // clear selected player display
 456                 ClearSelectedPlayer();
 457                 // throw a weapon
 458                 SpawnThrownWeapon (self.origin + (self.mins + self.maxs) * 0.5, self.switchweapon);
 459                 // print an obituary message
 460                 Obituary (attacker, self, deathtype);
 461                 DropAllRunes(self);
 462                 if(self == attacker)
 463                         kh_Key_DropAll(self, TRUE);
 464                 else if(attacker.classname == "player" || attacker.classname == "gib")
 465                         kh_Key_DropAll(self, FALSE);
 466                 else
 467                         kh_Key_DropAll(self, TRUE);
 468                 if(self.flagcarried)
 469                         DropFlag(self.flagcarried);
 470                 // clear waypoints
 471                 WaypointSprite_PlayerDead();
 472                 // make the corpse upright (not tilted)
 473                 self.angles_x = 0;
 474                 self.angles_z = 0;
 475                 // don't spin
 476                 self.avelocity = '0 0 0';
 477                 // view from the floor
 478                 self.view_ofs = '0 0 -8';
 479                 // toss the corpse
 480                 self.movetype = MOVETYPE_TOSS;
 481                 // shootable corpse
 482                 self.solid = SOLID_CORPSE;
 483                 // don't stick to the floor
 484                 self.flags = self.flags - (self.flags & FL_ONGROUND);
 485                 // dying animation
 486                 self.deadflag = DEAD_DYING;
 487                 // when to allow respawn
 488                 sdelay = 0;
 489                 waves = 0;
 490                 if(cvar("g_respawn_mapsettings"))
 491                 {
 492                         sdelay = cvar("g_respawn_mapsettings_delay");
 493                         waves = cvar("g_respawn_mapsettings_waves");
 494                 }
 495                 if(!sdelay)
 496                         sdelay = cvar(strcat("g_", GetGametype(), "_respawn_delay"));
 497                 if(!sdelay)
 498                         sdelay = cvar("g_respawn_delay");
 499                 if(!waves)
 500                         waves = cvar(strcat("g_", GetGametype(), "_respawn_waves"));
 501                 if(!waves)
 502                         waves = cvar("g_respawn_waves");
 503                 if(waves)
 504                         self.death_time = ceil((time + sdelay) / waves) * waves;
 505                 else
 506                         self.death_time = time + sdelay;
 507                 if((sdelay + waves >= 5.0) && (self.death_time - time > 1.75))
 508                         self.respawn_countdown = 10; // first number to count down from is 10
 509                 else
 510                         self.respawn_countdown = -1; // do not count down
 511                 if (random() < 0.5)
 512                 {
 513                         player_setanim(self.anim_die1, FALSE, TRUE, TRUE);
 514                         self.dead_frame = self.anim_dead1_x;
 515                 }
 516                 else
 517                 {
 518                         player_setanim(self.anim_die2, FALSE, TRUE, TRUE);
 519                         self.dead_frame = self.anim_dead2_x;
 520                 }
 521                 // set damage function to corpse damage
 522                 self.event_damage = PlayerCorpseDamage;
 523                 // call the corpse damage function just in case it wants to gib
 524                 self.event_damage(inflictor, attacker, 0, deathtype, hitloc, force);
 525                 // set up to fade out later
 526                 SUB_SetFade (self, time + 12 + random () * 4, 1);
 527
 528                 // remove laserdot
 529                 if(self.weaponentity)
 530                         if(self.weaponentity.lasertarget)
 531                                 remove(self.weaponentity.lasertarget);
 532
 533                 if(clienttype(self) == CLIENTTYPE_REAL)
 534                 {
 535                         self.fixangle = TRUE;
 536                         //msg_entity = self;
 537                         //WriteByte (MSG_ONE, SVC_SETANGLE);
 538                         //WriteAngle (MSG_ONE, self.v_angle_x);
 539                         //WriteAngle (MSG_ONE, self.v_angle_y);
 540                         //WriteAngle (MSG_ONE, 80);
 541                 }
 542
 543                 if(g_arena)
 544                         Spawnqueue_Unmark(self);
 545
 546                 if(defer_ClientKill_Now_TeamChange)
 547                         ClientKill_Now_TeamChange();
 548         }
 549 }
 550
 551 float UpdateSelectedPlayer_countvalue(float v)
 552 {
 553         return max(0, (v - 1.0) / 0.5);
 554 }
 555
 556 // returns: -2 if no hit, otherwise cos of the angle
 557 // uses the global v_angle
 558 float UpdateSelectedPlayer_canSee(entity p, float mincosangle, float maxdist)
 559 {
 560         vector so, d;
 561         float c;
 562
 563         if(p == self)
 564                 return -2;
 565
 566         if(p.deadflag)
 567                 return -2;
 568
 569         so = self.origin + self.view_ofs;
 570         d = p.origin - so;
 571
 572         // misaimed?
 573         if(dist_point_line(d, '0 0 0', v_forward) > maxdist)
 574                 return -2;
 575
 576         // now find the cos of the angle...
 577         c = normalize(d) * v_forward;
 578
 579         if(c <= mincosangle)
 580                 return -2;
 581
 582         traceline(so, p.origin, MOVE_NOMONSTERS, self);
 583         if(trace_fraction < 1)
 584                 return -2;
 585
 586         return c;
 587 }
 588
 589 void ClearSelectedPlayer()
 590 {
 591         if(self.selected_player)
 592         {
 593                 centerprint_expire(self, CENTERPRIO_POINT);
 594                 self.selected_player = world;
 595                 self.selected_player_display_needs_update = FALSE;
 596         }
 597 }
 598
 599 void UpdateSelectedPlayer()
 600 {
 601         entity selected;
 602         float selected_score;
 603         selected = world;
 604         selected_score = 0.95; // 18 degrees
 605
 606         if(!cvar("sv_allow_shownames"))
 607                 return;
 608
 609         if(clienttype(self) != CLIENTTYPE_REAL)
 610                 return;
 611
 612         if(self.cvar_cl_shownames == 0)
 613                 return;
 614
 615         if(self.cvar_cl_shownames == 1 && !teams_matter)
 616                 return;
 617
 618         makevectors(self.v_angle); // sets v_forward
 619
 620         // 1. cursor trace is always right
 621         if(self.cursor_trace_ent && self.cursor_trace_ent.classname == "player" && !self.cursor_trace_ent.deadflag)
 622         {
 623                 selected = self.cursor_trace_ent;
 624         }
 625         else
 626         {
 627                 // 2. if we don't have a cursor trace, find the player which is least
 628                 //    mis-aimed at
 629                 entity p;
 630                 FOR_EACH_PLAYER(p)
 631                 {
 632                         float c;
 633                         c = UpdateSelectedPlayer_canSee(p, selected_score, 100); // 100 = 2.5 meters
 634                         if(c >= -1)
 635                         {
 636                                 selected = p;
 637                                 selected_score = c;
 638                         }
 639                 }
 640         }
 641
 642         if(selected)
 643         {
 644                 self.selected_player_display_timeout = time + self.cvar_scr_centertime;
 645         }
 646         else
 647         {
 648                 if(time < self.selected_player_display_timeout)
 649                         if(UpdateSelectedPlayer_canSee(self.selected_player, 0.7, 200) >= -1) // 5 meters, 45 degrees
 650                                 selected = self.selected_player;
 651         }
 652
 653         if(selected)
 654         {
 655                 if(selected == self.selected_player)
 656                 {
 657                         float save;
 658                         save = UpdateSelectedPlayer_countvalue(self.selected_player_count);
 659                         self.selected_player_count = self.selected_player_count + frametime;
 660                         if(save != UpdateSelectedPlayer_countvalue(self.selected_player_count))
 661                         {
 662                                 string namestr, healthstr;
 663                                 namestr = playername(selected);
 664                                 if(teams_matter)
 665                                 {
 666                                         healthstr = ftos(floor(selected.health));
 667                                         if(self.team == selected.team)
 668                                         {
 669                                                 namestr = strcat(namestr, " (", healthstr, "%)");
 670                                                 self.selected_player_display_needs_update = TRUE;
 671                                         }
 672                                 }
 673                                 centerprint_atprio(self, CENTERPRIO_POINT, namestr);
 674                         }
 675                 }
 676                 else
 677                 {
 678                         ClearSelectedPlayer();
 679                         self.selected_player = selected;
 680                         self.selected_player_time = time;
 681                         self.selected_player_count = 0;
 682                         self.selected_player_display_needs_update = FALSE;
 683                 }
 684         }
 685         else
 686         {
 687                 ClearSelectedPlayer();
 688         }
 689
 690         if(self.selected_player)
 691                 self.last_selected_player = self.selected_player;
 692 }
 693
 694 float precache_sound_index (string s) = #19;
 695 void soundto(entity e, entity sounddest, float chan, string samp, float vol, float atten)
 696 {
 697         vector o;
 698         if(clienttype(sounddest) != CLIENTTYPE_REAL)
 699                 return;
 700         o = e.origin + 0.5 * (e.mins + e.maxs);
 701         msg_entity = sounddest;
 702         WriteByte(MSG_ONE, 6);
 703         WriteByte(MSG_ONE, 27); // all bits except SND_LOOPING
 704         WriteByte(MSG_ONE, vol * 255);
 705         WriteByte(MSG_ONE, atten * 64);
 706         WriteEntity(MSG_ONE, e);
 707         WriteByte(MSG_ONE, chan);
 708         WriteShort(MSG_ONE, precache_sound_index(samp));
 709         WriteCoord(MSG_ONE, o_x);
 710         WriteCoord(MSG_ONE, o_y);
 711         WriteCoord(MSG_ONE, o_z);
 712 }
 713
 714 #if 0
 715 .string playersound_attack;
 716 .string playersound_attackinfive;
 717 .string playersound_coverme;
 718 .string playersound_defend;
 719 .string playersound_freelance;
 720 .string playersound_incoming;
 721 .string playersound_meet;
 722 .string playersound_needhelp;
 723 .string playersound_seenflag;
 724 .string playersound_taunt;
 725 .string playersound_teamshoot;
 726 .float modelindex_for_playersound;
 727
 728 float GetVoiceMessageTeamsayType(string type)
 729 {
 730         if(type == "taunt")
 731                 return 0;
 732         if(type == "teamshoot")
 733                 return 2;
 734         return 1;
 735 }
 736
 737 string allvoicesamples = "attack attackinfive coverme defend freelance incoming meet needhelp seenflag taunt teamshoot";
 738 float GetPlayerSoundSampleField_notFound;
 739 .string GetVoiceMessageSampleField(string type)
 740 {
 741         GetPlayerSoundSampleField_notFound = 0;
 742         switch(type)
 743         {
 744                 case "attack":       return playersound_attack;
 745                 case "attackinfive": return playersound_attackinfive;
 746                 case "coverme":      return playersound_coverme;
 747                 case "defend":       return playersound_defend;
 748                 case "freelance":    return playersound_freelance;
 749                 case "incoming":     return playersound_incoming;
 750                 case "meet":         return playersound_meet;
 751                 case "needhelp":     return playersound_needhelp;
 752                 case "seenflag":     return playersound_seenflag;
 753                 case "taunt":        return playersound_taunt;
 754                 case "teamshoot":    return playersound_teamshoot;
 755         }
 756         GetPlayerSoundSampleField_notFound = 1;
 757         return playersound_taunt;
 758 }
 759
 760 .string GetPlayerSoundSampleField(string type)
 761 {
 762         GetPlayerSoundSampleField_notFound = 0;
 763         switch(type)
 764         {
 765                 case "attack":       return playersound_attack;
 766                 default:             return GetVoiceMessageSampleField(type);
 767         }
 768 }
 769
 770 void PrecachePlayerSounds(string f)
 771 {
 772         float fh;
 773         float i, n;
 774         string s;
 775         fh = fopen(f, FILE_READ);
 776         if(fh < 0)
 777                 return;
 778         while((s = fgets(fh)))
 779         {
 780                 if(tokenize(s) != 3)
 781                 {
 782                         dprint("Invalid sound info line: ", s, "\n");
 783                         continue;
 784                 }
 785                 n = stof(argv(2));
 786                 for(i = 1; i <= n; ++i)
 787                         precache_sound(strcat(argv(1), ftos(i), ".wav"));
 788         }
 789         fclose(fh);
 790 }
 791
 792 void LoadPlayerSounds(string f)
 793 {
 794         float fh;
 795         string s;
 796         var .string field;
 797         fh = fopen(f, FILE_READ);
 798         if(fh < 0)
 799                 return;
 800         while((s = fgets(fh)))
 801         {
 802                 if(tokenize(s) != 3)
 803                         continue;
 804                 field = GetPlayerSoundSampleField(argv(0));
 805                 if(GetPlayerSoundSampleField_notFound)
 806                         continue;
 807                 if(self.field)
 808                         strunzone(self.field);
 809                 self.field = strzone(strcat(argv(1), " ", argv(2)));
 810         }
 811         fclose(fh);
 812 }
 813
 814 void UpdatePlayerSounds()
 815 {
 816         if(self.modelindex == self.modelindex_for_playersound)
 817                 return;
 818         self.modelindex_for_playersound = self.modelindex;
 819         LoadPlayerSounds("sound/player/default.sounds");
 820         LoadPlayerSounds(strcat(self.model, ".sounds"));
 821 }
 822
 823 void VoiceMessage(string type)
 824 {
 825         // TODO precache voice messages?
 826         var string sample;
 827         var float teamsay;
 828         sample = self.(GetPlayerSoundSampleField(type));
 829
 830         if(GetPlayerSoundSampleField_notFound)
 831         {
 832                 sprint(self, strcat("Invalid voice. Use one of: ", allvoicesamples, "\n"));
 833                 return;
 834         }
 835
 836         if(!sample)
 837                 return;
 838
 839         teamsay = GetVoiceMessageTeamsayType(type);
 840
 841         tokenize(sample);
 842         sample = strcat(argv(0), ftos(ceil(random() * stof(argv(1)))), ".wav"); // randomization
 843
 844         if(teamsay == 2)
 845         {
 846                 if(teams_matter)
 847                         if(self.pusher)
 848                                 if(self.pusher.team == self.team)
 849                                 {
 850                                         soundto(self, self.pusher, CHAN_VOICE, sample, 1, ATTN_NONE);
 851                                         soundto(self, self, CHAN_VOICE, sample, 1, ATTN_NONE);
 852                                 }
 853         }
 854         else if(teamsay == 0 || !teams_matter)
 855         {
 856                 // broadcast the sound, but it's directional
 857                 sound(self, CHAN_VOICE, sample, 1, ATTN_NORM);
 858         }
 859         else if(teamsay == 1)
 860         {
 861                 entity e;
 862                 FOR_EACH_REALCLIENT(e)
 863                         if(e.team == self.team)
 864                                 soundto(self, e, CHAN_VOICE, sample, 1, ATTN_NONE);
 865         }
 866 }
 867 #else
 868 void PrecachePlayerSounds(string f) { }
 869 void UpdatePlayerSounds() { }
 870 void VoiceMessage(string type) { sprint(self, "Sorry, voice command support is not done yet. Maybe later.\n"); }
 871 #endif