data/qcsrc/server/cl_player.qc

   1
   2 // changes by LordHavoc on 03/29/04 and 03/30/04 at Vermeulen's request
   3 // merged player_run and player_stand to player_anim
   4 // added death animations to player_anim
   5 // can now spawn thrown weapons from anywhere, not just from players
   6 // thrown weapons now fade out after 20 seconds
   7 // created PlayerGib function
   8 // PlayerDie no longer uses hitloc or damage
   9 // PlayerDie now supports dying animations as well as gibbing
  10 // cleaned up PlayerDie a lot
  11 // added CopyBody
  12
  13 .entity pusher;
  14 .float pushltime;
  15
  16 void CopyBody(float keepvelocity)
  17 {
  18         local entity oldself;
  19         if (self.effects & EF_NODRAW)
  20                 return;
  21         oldself = self;
  22         self = spawn();
  23         self.colormap = oldself.colormap;
  24         self.iscreature = oldself.iscreature;
  25         self.angles = oldself.angles;
  26         self.avelocity = oldself.avelocity;
  27         self.classname = "body";
  28         self.damageforcescale = oldself.damageforcescale;
  29         self.effects = oldself.effects;
  30         self.event_damage = oldself.event_damage;
  31         self.animstate_startframe = oldself.animstate_startframe;
  32         self.animstate_numframes = oldself.animstate_numframes;
  33         self.animstate_framerate = oldself.animstate_framerate;
  34         self.animstate_starttime = oldself.animstate_starttime;
  35         self.animstate_endtime = oldself.animstate_endtime;
  36         self.animstate_override = oldself.animstate_override;
  37         self.animstate_looping = oldself.animstate_looping;
  38         self.frame = oldself.frame;
  39         self.dead_frame = oldself.dead_frame;
  40         self.pain_finished = oldself.pain_finished;
  41         self.health = oldself.health;
  42         self.armorvalue = oldself.armorvalue;
  43         self.armortype = oldself.armortype;
  44         self.model = oldself.model;
  45         self.modelindex = oldself.modelindex;
  46         self.movetype = oldself.movetype;
  47         self.nextthink = oldself.nextthink;
  48         self.skin = oldself.skin;
  49         self.solid = oldself.solid;
  50         self.takedamage = oldself.takedamage;
  51         self.think = oldself.think;
  52         self.gibrandom = oldself.gibrandom;
  53         self.customizeentityforclient = oldself.customizeentityforclient;
  54         if (keepvelocity == 1)
  55                 self.velocity = oldself.velocity;
  56         self.oldvelocity = self.velocity;
  57         self.fade_time = oldself.fade_time;
  58         self.fade_rate = oldself.fade_rate;
  59         //self.weapon = oldself.weapon;
  60         setorigin(self, oldself.origin);
  61         setsize(self, oldself.mins, oldself.maxs);
  62         self.oldorigin = oldself.origin;
  63         self = oldself;
  64 }
  65
  66 float animparseerror;
  67 vector(float animfile) animparseline =
  68 {
  69         local string line;
  70         local float c;
  71         local vector anim;
  72         if (animfile < 0)
  73                 return '0 1 2';
  74         line = fgets(animfile);
  75         c = tokenize(line);
  76         if (c != 3)
  77         {
  78                 animparseerror = TRUE;
  79                 return '0 1 2';
  80         }
  81         anim_x = stof(argv(0));
  82         anim_y = stof(argv(1));
  83         anim_z = stof(argv(2));
  84         // don't allow completely bogus values
  85         if (anim_x < 0 || anim_y < 1 || anim_z < 0.001)
  86                 anim = '0 1 2';
  87         return anim;
  88 };
  89
  90 void() player_setupanimsformodel =
  91 {
  92         local string animfilename;
  93         local float animfile;
  94         // defaults for legacy .zym models without animinfo files
  95         self.anim_die1 = '0 1 0.5'; // 2 seconds
  96         self.anim_die2 = '1 1 0.5'; // 2 seconds
  97         self.anim_draw = '2 1 3'; // TODO: analyze models and set framerate
  98         self.anim_duck = '3 1 100'; // this anim seems bogus in most models, so make it play VERY briefly!
  99         self.anim_duckwalk = '4 1 1';
 100         self.anim_duckjump = '5 1 100'; // zym anims keep playing until changed, so this only has to start the anim, landing will end it
 101         self.anim_duckidle = '6 1 1';
 102         self.anim_idle = '7 1 1';
 103         self.anim_jump = '8 1 100'; // zym anims keep playing until changed, so this only has to start the anim, landing will end it
 104         self.anim_pain1 = '9 1 2'; // 0.5 seconds
 105         self.anim_pain2 = '10 1 2'; // 0.5 seconds
 106         self.anim_shoot = '11 1 5'; // TODO: analyze models and set framerate
 107         self.anim_taunt = '12 1 1'; // FIXME?  there is no code using this anim
 108         self.anim_run = '13 1 1';
 109         self.anim_runbackwards = '14 1 1';
 110         self.anim_strafeleft = '15 1 1';
 111         self.anim_straferight = '16 1 1';
 112         self.anim_dead1 = '17 1 1';
 113         self.anim_dead2 = '18 1 1';
 114         self.anim_forwardright = '19 1 1';
 115         self.anim_forwardleft = '20 1 1';
 116         self.anim_backright = '21 1 1';
 117         self.anim_backleft  = '22 1 1';
 118         animparseerror = FALSE;
 119         animfilename = strcat(self.model, ".animinfo");
 120         animfile = fopen(animfilename, FILE_READ);
 121         if (animfile >= 0)
 122         {
 123                 self.anim_die1         = animparseline(animfile);
 124                 self.anim_die2         = animparseline(animfile);
 125                 self.anim_draw         = animparseline(animfile);
 126                 self.anim_duck         = animparseline(animfile);
 127                 self.anim_duckwalk     = animparseline(animfile);
 128                 self.anim_duckjump     = animparseline(animfile);
 129                 self.anim_duckidle     = animparseline(animfile);
 130                 self.anim_idle         = animparseline(animfile);
 131                 self.anim_jump         = animparseline(animfile);
 132                 self.anim_pain1        = animparseline(animfile);
 133                 self.anim_pain2        = animparseline(animfile);
 134                 self.anim_shoot        = animparseline(animfile);
 135                 self.anim_taunt        = animparseline(animfile);
 136                 self.anim_run          = animparseline(animfile);
 137                 self.anim_runbackwards = animparseline(animfile);
 138                 self.anim_strafeleft   = animparseline(animfile);
 139                 self.anim_straferight  = animparseline(animfile);
 140                 self.anim_forwardright = animparseline(animfile);
 141                 self.anim_forwardleft  = animparseline(animfile);
 142                 self.anim_backright    = animparseline(animfile);
 143                 self.anim_backleft     = animparseline(animfile);
 144                 fclose(animfile);
 145
 146                 // derived anims
 147                 self.anim_dead1 = '0 1 1' + '1 0 0' * (self.anim_die1_x + self.anim_die1_y - 1);
 148                 self.anim_dead2 = '0 1 1' + '1 0 0' * (self.anim_die2_x + self.anim_die2_y - 1);
 149
 150                 if (animparseerror)
 151                         print("Parse error in ", animfilename, ", some player animations are broken\n");
 152         }
 153         else
 154                 dprint("File ", animfilename, " not found, assuming legacy .zym model animation timings\n");
 155         // reset animstate now
 156         player_setanim(self.anim_idle, TRUE, FALSE, TRUE);
 157 };
 158
 159 void(vector anim, float looping, float override, float restart) player_setanim =
 160 {
 161         if (!restart)
 162         if (anim_x == self.animstate_startframe)
 163         if (anim_y == self.animstate_numframes)
 164         if (anim_z == self.animstate_framerate)
 165                 return;
 166         self.animstate_startframe = anim_x;
 167         self.animstate_numframes = anim_y;
 168         self.animstate_framerate = anim_z;
 169         self.animstate_starttime = time;
 170         self.animstate_endtime = time + self.animstate_numframes / self.animstate_framerate;
 171         self.animstate_looping = looping;
 172         self.animstate_override = override;
 173         self.frame = self.animstate_startframe;
 174 };
 175
 176 void() player_updateframe =
 177 {
 178         if (time >= self.animstate_endtime)
 179         {
 180                 if (self.animstate_looping)
 181                 {
 182                         self.animstate_starttime = self.animstate_endtime;
 183                         self.animstate_endtime = self.animstate_endtime + self.animstate_numframes / self.animstate_framerate;
 184                 }
 185                 self.animstate_override = FALSE;
 186         }
 187         self.frame = self.animstate_startframe + bound(0, (time - self.animstate_starttime) * self.animstate_framerate, self.animstate_numframes - 1);
 188 };
 189
 190 void player_anim (void)
 191 {
 192         player_updateframe();
 193
 194         if (self.deadflag != DEAD_NO)
 195         {
 196                 if (time > self.animstate_endtime)
 197                 {
 198                         if (self.maxs_z > 5)
 199                         {
 200                                 self.maxs_z = 5;
 201                                 setsize(self, self.mins, self.maxs);
 202                         }
 203                         self.frame = self.dead_frame;
 204                 }
 205                 return;
 206         }
 207
 208         if (!self.animstate_override)
 209         {
 210                 if (!(self.flags & FL_ONGROUND))
 211                 {
 212                         if (self.crouch)
 213                                 player_setanim(self.anim_duckjump, FALSE, TRUE, FALSE);
 214                         else
 215                                 player_setanim(self.anim_jump, FALSE, TRUE, FALSE);
 216                 }
 217                 else if (self.crouch)
 218                 {
 219                         if (self.movement_x * self.movement_x + self.movement_y * self.movement_y > 20)
 220                                 player_setanim(self.anim_duckwalk, TRUE, FALSE, FALSE);
 221                         else
 222                                 player_setanim(self.anim_duckidle, TRUE, FALSE, FALSE);
 223                 }
 224                 else if ((self.movement_x * self.movement_x + self.movement_y * self.movement_y) > 20)
 225                 {
 226                         if (self.movement_x > 0 && self.movement_y == 0)
 227                                 player_setanim(self.anim_run, TRUE, FALSE, FALSE);
 228                         else if (self.movement_x < 0 && self.movement_y == 0)
 229                                 player_setanim(self.anim_runbackwards, TRUE, FALSE, FALSE);
 230                         else if (self.movement_x == 0 && self.movement_y > 0)
 231                                 player_setanim(self.anim_straferight, TRUE, FALSE, FALSE);
 232                         else if (self.movement_x == 0 && self.movement_y < 0)
 233                                 player_setanim(self.anim_strafeleft, TRUE, FALSE, FALSE);
 234                         else if (self.movement_x > 0 && self.movement_y > 0)
 235                                 player_setanim(self.anim_forwardright, TRUE, FALSE, FALSE);
 236                         else if (self.movement_x > 0 && self.movement_y < 0)
 237                                 player_setanim(self.anim_forwardleft, TRUE, FALSE, FALSE);
 238                         else if (self.movement_x < 0 && self.movement_y > 0)
 239                                 player_setanim(self.anim_backright, TRUE, FALSE, FALSE);
 240                         else if (self.movement_x < 0 && self.movement_y < 0)
 241                                 player_setanim(self.anim_backleft, TRUE, FALSE, FALSE);
 242                         else
 243                                 player_setanim(self.anim_run, TRUE, FALSE, FALSE);
 244                 }
 245                 else
 246                         player_setanim(self.anim_idle, TRUE, FALSE, FALSE);
 247         }
 248 }
 249 //End change by Supajoe on 11:44 PM EST 11/16/03 (Subject: Player animations)
 250
 251 void SpawnThrownWeapon (vector org, float w)
 252 {
 253         if (!cvar("g_pickup_items"))
 254         if (!g_minstagib)
 255                 return;
 256         if (!w)
 257                 return;
 258         if (w == IT_LASER)
 259                 return;
 260
 261         W_ThrowWeapon(randomvec() * 100 + '0 0 200', org - self.origin, FALSE);
 262 }
 263
 264 void PlayerCorpseDamage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 265 {
 266         local float take, save;
 267         pointparticles(particleeffectnum("blood"), hitloc, force, bound(0, damage, 200));
 268         // damage resistance (ignore most of the damage from a bullet or similar)
 269         damage = max(damage - 5, 1);
 270
 271         save = bound(0, damage * cvar("g_balance_armor_blockpercent"), self.armorvalue);
 272         take = bound(0, damage - save, damage);
 273
 274         if (save > 10)
 275                 sound (self, CHAN_IMPACT, "misc/armorimpact.wav", 1, ATTN_NORM);
 276         else if (take > 30)
 277                 sound (self, CHAN_IMPACT, "misc/bodyimpact2.wav", 1, ATTN_NORM);
 278         else if (take > 10)
 279                 sound (self, CHAN_IMPACT, "misc/bodyimpact1.wav", 1, ATTN_NORM);
 280
 281         if (take > 50)
 282                 TossGib (world, "models/gibs/chunk.mdl", hitloc, force * -0.1,1);
 283         if (take > 100)
 284                 TossGib (world, "models/gibs/chunk.mdl", hitloc, force * -0.2,1);
 285
 286         if (!(self.flags & FL_GODMODE))
 287         {
 288                 self.armorvalue = self.armorvalue - save;
 289                 self.health = self.health - take;
 290                 // pause regeneration for 5 seconds
 291                 self.pauseregen_finished = max(self.pauseregen_finished, time + cvar("g_balance_pause_health_regen"));
 292         }
 293         self.dmg_save = self.dmg_save + save;//max(save - 10, 0);
 294         self.dmg_take = self.dmg_take + take;//max(take - 10, 0);
 295         self.dmg_inflictor = inflictor;
 296
 297         if (self.health <= -50)
 298         {
 299                 // don't use any animations as a gib
 300                 self.frame = 0;
 301                 self.dead_frame = 0;
 302                 // view just above the floor
 303                 self.view_ofs = '0 0 4';
 304
 305                 // make a juicy mess
 306                 local float multiplier;
 307                 multiplier = 1;
 308                 if (cvar("ekg"))
 309                         multiplier = 5;
 310                 te_bloodshower (self.origin + self.mins, self.origin + self.maxs, 1200 * multiplier, 1000);
 311
 312                 // make a meaty mess
 313                 TossGib (self, "models/gibs/eye.md3", self.origin, self.velocity,0);
 314                 TossGib (world, "models/gibs/bloodyskull.md3", self.origin, '0 0 600',0);
 315
 316                 local float c;
 317                 c = 0;
 318                 while (c < multiplier)
 319                 {
 320                         c = c + 1;
 321                         TossGib (world, "models/gibs/gib1.md3", self.origin, self.velocity,0);
 322                         //TossGib (world, "models/gibs/gib2.md3", self.origin, self.velocity,0);
 323                         TossGib (world, "models/gibs/gib1.mdl", self.origin, self.velocity,0);
 324                         //TossGib (world, "models/gibs/gib3.md3", self.origin, self.velocity,0);
 325                         TossGib (world, "models/gibs/gib2.mdl", self.origin, self.velocity,0);
 326                         //TossGib (world, "models/gibs/gib4.md3", self.origin, self.velocity,0);
 327                         TossGib (world, "models/gibs/gib3.mdl", self.origin, self.velocity,0);
 328
 329                         // these destory on impact
 330                         TossGib (world, "models/gibs/gib5.md3", self.origin, '-500 0 450',1);
 331                         //TossGib (world, "models/gibs/gib6.md3", self.origin, '0 500 450',1);
 332                         TossGib (world, "models/gibs/chunk.mdl", self.origin, '0 -500 450',1);
 333                         TossGib (world, "models/gibs/chunk.mdl", self.origin, '500 0 450',1);
 334                         TossGib (world, "models/gibs/chunk.mdl", self.origin, self.velocity,1);
 335                         TossGib (world, "models/gibs/chunk.mdl", self.origin, '0 0 450',1);
 336                 }
 337
 338                 sound (self, CHAN_VOICE, "misc/gib.wav", 1, ATTN_NORM);
 339         }
 340 }
 341
 342 void ClientKill_Now_TeamChange();
 343
 344 void PlayerDamage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 345 {
 346         local float take, save, waves, sdelay;
 347
 348         damage = damage * bound(1.0, self.cvar_cl_handicap, 100.0);
 349
 350         pointparticles(particleeffectnum("blood"), hitloc, force, bound(0, damage, 200));
 351         if (self.pain_finished < time)          //Don't switch pain sequences like crazy
 352         {
 353                 if (random() > 0.5)
 354                         player_setanim(self.anim_pain1, FALSE, TRUE, TRUE);
 355                 else
 356                         player_setanim(self.anim_pain2, FALSE, TRUE, TRUE);
 357                 self.pain_finished = time + 0.5;        //Supajoe
 358
 359                 // throw off bot aim temporarily
 360                 local float shake;
 361                 shake = damage * 5 / (bound(0,skill,100) + 1);
 362                 self.v_angle_x = self.v_angle_x + (random() * 2 - 1) * shake;
 363                 self.v_angle_y = self.v_angle_y + (random() * 2 - 1) * shake;
 364         }
 365
 366         if(g_arena)
 367         if(numspawned < 2)
 368                 return;
 369
 370         if (!g_minstagib)
 371         {
 372                 save = bound(0, damage * cvar("g_balance_armor_blockpercent"), self.armorvalue);
 373                 take = bound(0, damage - save, damage);
 374         }
 375         else
 376         {
 377                 save = 0;
 378                 take = damage;
 379         }
 380
 381         if (save > 10)
 382                 sound (self, CHAN_IMPACT, "misc/armorimpact.wav", 1, ATTN_NORM);
 383         else if (take > 30)
 384                 sound (self, CHAN_IMPACT, "misc/bodyimpact2.wav", 1, ATTN_NORM);
 385         else if (take > 10)
 386                 sound (self, CHAN_IMPACT, "misc/bodyimpact1.wav", 1, ATTN_NORM);
 387
 388         if (take > 50)
 389                 TossGib (world, "models/gibs/chunk.mdl", hitloc, force * -0.1,1);
 390         if (take > 100)
 391                 TossGib (world, "models/gibs/chunk.mdl", hitloc, force * -0.2,1);
 392
 393         if (time > self.spawnshieldtime)
 394         {
 395                 if (!(self.flags & FL_GODMODE))
 396                 {
 397                         self.armorvalue = self.armorvalue - save;
 398                         self.health = self.health - take;
 399                         // pause regeneration for 5 seconds
 400                         self.pauseregen_finished = max(self.pauseregen_finished, time + cvar("g_balance_pause_health_regen"));
 401                 }
 402                 else
 403                         self.max_armorvalue += (save + take);
 404         }
 405         self.dmg_save = self.dmg_save + save;//max(save - 10, 0);
 406         self.dmg_take = self.dmg_take + take;//max(take - 10, 0);
 407         self.dmg_inflictor = inflictor;
 408
 409         if(attacker == self)
 410         {
 411                 // don't reset pushltime for self damage as it may be an attempt to
 412                 // escape a lava pit or similar
 413                 //self.pushltime = 0;
 414         }
 415         else if(attacker.classname == "player" || attacker.classname == "gib")
 416         {
 417                 self.pusher = attacker;
 418                 self.pushltime = time + cvar("g_maxpushtime");
 419         }
 420         else if(time < self.pushltime)
 421         {
 422                 attacker = self.pusher;
 423                 self.pushltime = max(self.pushltime, time + 0.6);
 424         }
 425         else
 426                 self.pushltime = 0;
 427
 428         if (self.health < 1)
 429         {
 430                 self.deaths += 1;
 431
 432                 // get rid of kill indicator
 433                 if(self.killindicator)
 434                 {
 435                         remove(self.killindicator);
 436                         self.killindicator = world;
 437                         if(self.killindicator_teamchange)
 438                                 ClientKill_Now_TeamChange();
 439                 }
 440
 441                 // become fully visible
 442                 self.alpha = 1;
 443                 // clear selected player display
 444                 ClearSelectedPlayer();
 445                 // throw a weapon
 446                 SpawnThrownWeapon (self.origin + (self.mins + self.maxs) * 0.5, self.switchweapon);
 447                 // print an obituary message
 448                 Obituary (attacker, self, deathtype);
 449                 DropAllRunes(self);
 450                 if(self == attacker)
 451                         kh_Key_DropAll(self, TRUE);
 452                 else if(attacker.classname == "player" || attacker.classname == "gib")
 453                         kh_Key_DropAll(self, FALSE);
 454                 else
 455                         kh_Key_DropAll(self, TRUE);
 456                 if(self.flagcarried)
 457                         DropFlag(self.flagcarried);
 458                 // clear waypoints
 459                 WaypointSprite_PlayerDead();
 460                 // make the corpse upright (not tilted)
 461                 self.angles_x = 0;
 462                 self.angles_z = 0;
 463                 // don't spin
 464                 self.avelocity = '0 0 0';
 465                 // view from the floor
 466                 self.view_ofs = '0 0 -8';
 467                 // toss the corpse
 468                 self.movetype = MOVETYPE_TOSS;
 469                 // shootable corpse
 470                 self.solid = SOLID_CORPSE;
 471                 // don't stick to the floor
 472                 self.flags = self.flags - (self.flags & FL_ONGROUND);
 473                 // dying animation
 474                 self.deadflag = DEAD_DYING;
 475                 // when to allow respawn
 476                 sdelay = 0;
 477                 waves = 0;
 478                 if(cvar("g_respawn_mapsettings"))
 479                 {
 480                         sdelay = cvar("g_respawn_mapsettings_delay");
 481                         waves = cvar("g_respawn_mapsettings_waves");
 482                 }
 483                 if(!sdelay)
 484                         sdelay = cvar(strcat("g_", GetGametype(), "_respawn_delay"));
 485                 if(!sdelay)
 486                         sdelay = cvar("g_respawn_delay");
 487                 if(!waves)
 488                         waves = cvar(strcat("g_", GetGametype(), "_respawn_waves"));
 489                 if(!waves)
 490                         waves = cvar("g_respawn_waves");
 491                 if(waves)
 492                         self.death_time = ceil((time + sdelay) / waves) * waves;
 493                 else
 494                         self.death_time = time + sdelay;
 495                 if((sdelay + waves >= 5.0) && (self.death_time - time > 1.75))
 496                         self.respawn_countdown = 10; // first number to count down from is 10
 497                 else
 498                         self.respawn_countdown = -1; // do not count down
 499                 if (random() < 0.5)
 500                 {
 501                         player_setanim(self.anim_die1, FALSE, TRUE, TRUE);
 502                         self.dead_frame = self.anim_dead1_x;
 503                 }
 504                 else
 505                 {
 506                         player_setanim(self.anim_die2, FALSE, TRUE, TRUE);
 507                         self.dead_frame = self.anim_dead2_x;
 508                 }
 509                 // set damage function to corpse damage
 510                 self.event_damage = PlayerCorpseDamage;
 511                 // call the corpse damage function just in case it wants to gib
 512                 self.event_damage(inflictor, attacker, 0, deathtype, hitloc, force);
 513                 // set up to fade out later
 514                 SUB_SetFade (self, time + 12 + random () * 4, 1);
 515
 516                 // remove laserdot
 517                 if(self.weaponentity)
 518                         if(self.weaponentity.lasertarget)
 519                                 remove(self.weaponentity.lasertarget);
 520
 521                 if(clienttype(self) == CLIENTTYPE_REAL)
 522                 {
 523                         self.fixangle = TRUE;
 524                         //msg_entity = self;
 525                         //WriteByte (MSG_ONE, SVC_SETANGLE);
 526                         //WriteAngle (MSG_ONE, self.v_angle_x);
 527                         //WriteAngle (MSG_ONE, self.v_angle_y);
 528                         //WriteAngle (MSG_ONE, 80);
 529                 }
 530
 531                 if(g_arena)
 532                         Spawnqueue_Unmark(self);
 533         }
 534 }
 535
 536 float UpdateSelectedPlayer_countvalue(float v)
 537 {
 538         return max(0, (v - 1.0) / 0.5);
 539 }
 540
 541 // returns: -2 if no hit, otherwise cos of the angle
 542 // uses the global v_angle
 543 float UpdateSelectedPlayer_canSee(entity p, float mincosangle, float maxdist)
 544 {
 545         vector so, d;
 546         float c;
 547
 548         if(p == self)
 549                 return -2;
 550
 551         if(p.deadflag)
 552                 return -2;
 553
 554         so = self.origin + self.view_ofs;
 555         d = p.origin - so;
 556
 557         // misaimed?
 558         if(dist_point_line(d, '0 0 0', v_forward) > maxdist)
 559                 return -2;
 560
 561         // now find the cos of the angle...
 562         c = normalize(d) * v_forward;
 563
 564         if(c <= mincosangle)
 565                 return -2;
 566
 567         traceline(so, p.origin, MOVE_NOMONSTERS, self);
 568         if(trace_fraction < 1)
 569                 return -2;
 570
 571         return c;
 572 }
 573
 574 void ClearSelectedPlayer()
 575 {
 576         if(self.selected_player)
 577         {
 578                 centerprint_expire(self, CENTERPRIO_POINT);
 579                 self.selected_player = world;
 580                 self.selected_player_display_needs_update = FALSE;
 581         }
 582 }
 583
 584 void UpdateSelectedPlayer()
 585 {
 586         entity selected;
 587         float selected_score;
 588         selected = world;
 589         selected_score = 0.95; // 18 degrees
 590
 591         if(!cvar("sv_allow_shownames"))
 592                 return;
 593
 594         if(clienttype(self) != CLIENTTYPE_REAL)
 595                 return;
 596
 597         if(self.cvar_cl_shownames == 0)
 598                 return;
 599
 600         if(self.cvar_cl_shownames == 1 && !teams_matter)
 601                 return;
 602
 603         makevectors(self.v_angle); // sets v_forward
 604
 605         // 1. cursor trace is always right
 606         if(self.cursor_trace_ent && self.cursor_trace_ent.classname == "player" && !self.cursor_trace_ent.deadflag)
 607         {
 608                 selected = self.cursor_trace_ent;
 609         }
 610         else
 611         {
 612                 // 2. if we don't have a cursor trace, find the player which is least
 613                 //    mis-aimed at
 614                 entity p;
 615                 FOR_EACH_PLAYER(p)
 616                 {
 617                         float c;
 618                         c = UpdateSelectedPlayer_canSee(p, selected_score, 100); // 100 = 2.5 meters
 619                         if(c >= -1)
 620                         {
 621                                 selected = p;
 622                                 selected_score = c;
 623                         }
 624                 }
 625         }
 626
 627         if(selected)
 628         {
 629                 self.selected_player_display_timeout = time + self.cvar_scr_centertime;
 630         }
 631         else
 632         {
 633                 if(time < self.selected_player_display_timeout)
 634                         if(UpdateSelectedPlayer_canSee(self.selected_player, 0.7, 200) >= -1) // 5 meters, 45 degrees
 635                                 selected = self.selected_player;
 636         }
 637
 638         if(selected)
 639         {
 640                 if(selected == self.selected_player)
 641                 {
 642                         float save;
 643                         save = UpdateSelectedPlayer_countvalue(self.selected_player_count);
 644                         self.selected_player_count = self.selected_player_count + frametime;
 645                         if(save != UpdateSelectedPlayer_countvalue(self.selected_player_count))
 646                         {
 647                                 string namestr, healthstr;
 648                                 namestr = playername(selected);
 649                                 if(teams_matter)
 650                                 {
 651                                         healthstr = ftos(floor(selected.health));
 652                                         if(self.team == selected.team)
 653                                         {
 654                                                 namestr = strcat(namestr, " (", healthstr, "%)");
 655                                                 self.selected_player_display_needs_update = TRUE;
 656                                         }
 657                                 }
 658                                 centerprint_atprio(self, CENTERPRIO_POINT, namestr);
 659                         }
 660                 }
 661                 else
 662                 {
 663                         ClearSelectedPlayer();
 664                         self.selected_player = selected;
 665                         self.selected_player_time = time;
 666                         self.selected_player_count = 0;
 667                         self.selected_player_display_needs_update = FALSE;
 668                 }
 669         }
 670         else
 671         {
 672                 ClearSelectedPlayer();
 673         }
 674
 675         if(self.selected_player)
 676                 self.last_selected_player = self.selected_player;
 677 }
 678
 679 .string playersound_attack;
 680 .string playersound_attackinfive;
 681 .string playersound_coverme;
 682 .string playersound_defend;
 683 .string playersound_freelance;
 684 .string playersound_incoming;
 685 .string playersound_meet;
 686 .string playersound_needhelp;
 687 .string playersound_seenflag;
 688 .string playersound_taunt;
 689 .string playersound_teamshoot;
 690 .float modelindex_for_playersound;
 691
 692 float GetVoiceMessageTeamsayType(string type)
 693 {
 694         if(type == "taunt")
 695                 return 0;
 696         if(type == "teamshoot")
 697                 return 2;
 698         return 1;
 699 }
 700
 701 string allvoicesamples = "attack attackinfive coverme defend freelance incoming meet needhelp seenflag taunt teamshoot";
 702 float GetPlayerSoundSampleField_notFound;
 703 .string GetVoiceMessageSampleField(string type)
 704 {
 705         GetPlayerSoundSampleField_notFound = 0;
 706         switch(type)
 707         {
 708                 case "attack":       return playersound_attack;
 709                 case "attackinfive": return playersound_attackinfive;
 710                 case "coverme":      return playersound_coverme;
 711                 case "defend":       return playersound_defend;
 712                 case "freelance":    return playersound_freelance;
 713                 case "incoming":     return playersound_incoming;
 714                 case "meet":         return playersound_meet;
 715                 case "needhelp":     return playersound_needhelp;
 716                 case "seenflag":     return playersound_seenflag;
 717                 case "taunt":        return playersound_taunt;
 718                 case "teamshoot":    return playersound_teamshoot;
 719         }
 720         GetPlayerSoundSampleField_notFound = 1;
 721         return playersound_taunt;
 722 }
 723
 724 .string GetPlayerSoundSampleField(string type)
 725 {
 726         GetPlayerSoundSampleField_notFound = 0;
 727         switch(type)
 728         {
 729                 case "attack":       return playersound_attack;
 730                 default:             return GetVoiceMessageSampleField(type);
 731         }
 732 }
 733
 734 void PrecachePlayerSounds(string f)
 735 {
 736         float fh;
 737         float i, n;
 738         string s;
 739         fh = fopen(f, FILE_READ);
 740         if(fh < 0)
 741                 return;
 742         while((s = fgets(fh)))
 743         {
 744                 if(tokenize(s) != 3)
 745                 {
 746                         dprint("Invalid sound info line: ", s, "\n");
 747                         continue;
 748                 }
 749                 n = stof(argv(2));
 750                 for(i = 1; i <= n; ++i)
 751                         precache_sound(strcat(argv(1), ftos(i), ".wav"));
 752         }
 753         fclose(fh);
 754 }
 755
 756 void LoadPlayerSounds(string f)
 757 {
 758         float fh;
 759         string s;
 760         var .string field;
 761         fh = fopen(f, FILE_READ);
 762         if(fh < 0)
 763                 return;
 764         while((s = fgets(fh)))
 765         {
 766                 if(tokenize(s) != 3)
 767                         continue;
 768                 field = GetPlayerSoundSampleField(argv(0));
 769                 if(GetPlayerSoundSampleField_notFound)
 770                         continue;
 771                 if(self.field)
 772                         strunzone(self.field);
 773                 self.field = strzone(strcat(argv(1), " ", argv(2)));
 774         }
 775         fclose(fh);
 776 }
 777
 778 void UpdatePlayerSounds()
 779 {
 780         if(self.modelindex == self.modelindex_for_playersound)
 781                 return;
 782         self.modelindex_for_playersound = self.modelindex;
 783         LoadPlayerSounds("sound/player/default.sounds");
 784         LoadPlayerSounds(strcat(self.model, ".sounds"));
 785 }
 786
 787 float precache_sound_index (string s) = #19;
 788 void soundto(entity e, entity sounddest, float chan, string samp, float vol, float atten)
 789 {
 790         vector o;
 791         if(clienttype(sounddest) != CLIENTTYPE_REAL)
 792                 return;
 793         o = e.origin + 0.5 * (e.mins + e.maxs);
 794         msg_entity = sounddest;
 795         WriteByte(MSG_ONE, 6);
 796         WriteByte(MSG_ONE, 27); // all bits except SND_LOOPING
 797         WriteByte(MSG_ONE, vol * 255);
 798         WriteByte(MSG_ONE, atten * 64);
 799         WriteEntity(MSG_ONE, e);
 800         WriteByte(MSG_ONE, chan);
 801         WriteShort(MSG_ONE, precache_sound_index(samp));
 802         WriteCoord(MSG_ONE, o_x);
 803         WriteCoord(MSG_ONE, o_y);
 804         WriteCoord(MSG_ONE, o_z);
 805 }
 806
 807 void VoiceMessage(string type)
 808 {
 809         // TODO precache voice messages?
 810         var string sample;
 811         var float teamsay;
 812         sample = self.(GetPlayerSoundSampleField(type));
 813
 814         if(GetPlayerSoundSampleField_notFound)
 815         {
 816                 sprint(self, strcat("Invalid voice. Use one of: ", allvoicesamples, "\n"));
 817                 return;
 818         }
 819
 820         if(!sample)
 821                 return;
 822
 823         teamsay = GetVoiceMessageTeamsayType(type);
 824
 825         tokenize(sample);
 826         sample = strcat(argv(0), ftos(ceil(random() * stof(argv(1)))), ".wav"); // randomization
 827
 828         if(teamsay == 2)
 829         {
 830                 if(teams_matter)
 831                         if(self.pusher)
 832                                 if(self.pusher.team == self.team)
 833                                 {
 834                                         soundto(self, self.pusher, CHAN_VOICE, sample, 1, ATTN_NONE);
 835                                         soundto(self, self, CHAN_VOICE, sample, 1, ATTN_NONE);
 836                                 }
 837         }
 838         else if(teamsay == 0 || !teams_matter)
 839         {
 840                 // broadcast the sound, but it's directional
 841                 sound(self, CHAN_VOICE, sample, 1, ATTN_NORM);
 842         }
 843         else if(teamsay == 1)
 844         {
 845                 entity e;
 846                 FOR_EACH_REALCLIENT(e)
 847                         if(e.team == self.team)
 848                                 soundto(self, e, CHAN_VOICE, sample, 1, ATTN_NONE);
 849         }
 850 }