data/qcsrc/server/cl_player.qc

   1
   2 // changes by LordHavoc on 03/29/04 and 03/30/04 at Vermeulen's request
   3 // merged player_run and player_stand to player_anim
   4 // added death animations to player_anim
   5 // can now spawn thrown weapons from anywhere, not just from players
   6 // thrown weapons now fade out after 20 seconds
   7 // created PlayerGib function
   8 // PlayerDie no longer uses hitloc or damage
   9 // PlayerDie now supports dying animations as well as gibbing
  10 // cleaned up PlayerDie a lot
  11 // added CopyBody
  12
  13 .entity pusher;
  14 .float pushltime;
  15
  16 void CopyBody(float keepvelocity)
  17 {
  18         local entity oldself;
  19         if (self.effects & EF_NODRAW)
  20                 return;
  21         oldself = self;
  22         self = spawn();
  23         self.enemy = oldself;
  24         self.lip = oldself.lip;
  25         self.colormap = oldself.colormap;
  26         self.iscreature = oldself.iscreature;
  27         self.angles = oldself.angles;
  28         self.avelocity = oldself.avelocity;
  29         self.classname = "body";
  30         self.damageforcescale = oldself.damageforcescale;
  31         self.effects = oldself.effects;
  32         self.event_damage = oldself.event_damage;
  33         self.animstate_startframe = oldself.animstate_startframe;
  34         self.animstate_numframes = oldself.animstate_numframes;
  35         self.animstate_framerate = oldself.animstate_framerate;
  36         self.animstate_starttime = oldself.animstate_starttime;
  37         self.animstate_endtime = oldself.animstate_endtime;
  38         self.animstate_override = oldself.animstate_override;
  39         self.animstate_looping = oldself.animstate_looping;
  40         self.frame = oldself.frame;
  41         self.dead_frame = oldself.dead_frame;
  42         self.pain_finished = oldself.pain_finished;
  43         self.health = oldself.health;
  44         self.armorvalue = oldself.armorvalue;
  45         self.armortype = oldself.armortype;
  46         self.model = oldself.model;
  47         self.modelindex = oldself.modelindex;
  48         self.movetype = oldself.movetype;
  49         self.nextthink = oldself.nextthink;
  50         self.skin = oldself.skin;
  51         self.solid = oldself.solid;
  52         self.takedamage = oldself.takedamage;
  53         self.think = oldself.think;
  54         self.gibrandom = oldself.gibrandom;
  55         self.customizeentityforclient = oldself.customizeentityforclient;
  56         if (keepvelocity == 1)
  57                 self.velocity = oldself.velocity;
  58         self.oldvelocity = self.velocity;
  59         self.fade_time = oldself.fade_time;
  60         self.fade_rate = oldself.fade_rate;
  61         //self.weapon = oldself.weapon;
  62         setorigin(self, oldself.origin);
  63         setsize(self, oldself.mins, oldself.maxs);
  64         self.oldorigin = oldself.origin;
  65         self = oldself;
  66 }
  67
  68 float animparseerror;
  69 vector animparseline(float animfile)
  70 {
  71         local string line;
  72         local float c;
  73         local vector anim;
  74         if (animfile < 0)
  75                 return '0 1 2';
  76         line = fgets(animfile);
  77         c = tokenize_sane(line);
  78         if (c != 3)
  79         {
  80                 animparseerror = TRUE;
  81                 return '0 1 2';
  82         }
  83         anim_x = stof(argv(0));
  84         anim_y = stof(argv(1));
  85         anim_z = stof(argv(2));
  86         // don't allow completely bogus values
  87         if (anim_x < 0 || anim_y < 1 || anim_z < 0.001)
  88                 anim = '0 1 2';
  89         return anim;
  90 };
  91
  92 void player_setupanimsformodel()
  93 {
  94         local string animfilename;
  95         local float animfile;
  96         // defaults for legacy .zym models without animinfo files
  97         self.anim_die1 = '0 1 0.5'; // 2 seconds
  98         self.anim_die2 = '1 1 0.5'; // 2 seconds
  99         self.anim_draw = '2 1 3'; // TODO: analyze models and set framerate
 100         self.anim_duck = '3 1 100'; // this anim seems bogus in most models, so make it play VERY briefly!
 101         self.anim_duckwalk = '4 1 1';
 102         self.anim_duckjump = '5 1 100'; // zym anims keep playing until changed, so this only has to start the anim, landing will end it
 103         self.anim_duckidle = '6 1 1';
 104         self.anim_idle = '7 1 1';
 105         self.anim_jump = '8 1 100'; // zym anims keep playing until changed, so this only has to start the anim, landing will end it
 106         self.anim_pain1 = '9 1 2'; // 0.5 seconds
 107         self.anim_pain2 = '10 1 2'; // 0.5 seconds
 108         self.anim_shoot = '11 1 5'; // TODO: analyze models and set framerate
 109         self.anim_taunt = '12 1 1'; // FIXME?  there is no code using this anim
 110         self.anim_run = '13 1 1';
 111         self.anim_runbackwards = '14 1 1';
 112         self.anim_strafeleft = '15 1 1';
 113         self.anim_straferight = '16 1 1';
 114         self.anim_dead1 = '17 1 1';
 115         self.anim_dead2 = '18 1 1';
 116         self.anim_forwardright = '19 1 1';
 117         self.anim_forwardleft = '20 1 1';
 118         self.anim_backright = '21 1 1';
 119         self.anim_backleft  = '22 1 1';
 120         animparseerror = FALSE;
 121         animfilename = strcat(self.model, ".animinfo");
 122         animfile = fopen(animfilename, FILE_READ);
 123         if (animfile >= 0)
 124         {
 125                 self.anim_die1         = animparseline(animfile);
 126                 self.anim_die2         = animparseline(animfile);
 127                 self.anim_draw         = animparseline(animfile);
 128                 self.anim_duck         = animparseline(animfile);
 129                 self.anim_duckwalk     = animparseline(animfile);
 130                 self.anim_duckjump     = animparseline(animfile);
 131                 self.anim_duckidle     = animparseline(animfile);
 132                 self.anim_idle         = animparseline(animfile);
 133                 self.anim_jump         = animparseline(animfile);
 134                 self.anim_pain1        = animparseline(animfile);
 135                 self.anim_pain2        = animparseline(animfile);
 136                 self.anim_shoot        = animparseline(animfile);
 137                 self.anim_taunt        = animparseline(animfile);
 138                 self.anim_run          = animparseline(animfile);
 139                 self.anim_runbackwards = animparseline(animfile);
 140                 self.anim_strafeleft   = animparseline(animfile);
 141                 self.anim_straferight  = animparseline(animfile);
 142                 self.anim_forwardright = animparseline(animfile);
 143                 self.anim_forwardleft  = animparseline(animfile);
 144                 self.anim_backright    = animparseline(animfile);
 145                 self.anim_backleft     = animparseline(animfile);
 146                 fclose(animfile);
 147
 148                 // derived anims
 149                 self.anim_dead1 = '0 1 1' + '1 0 0' * (self.anim_die1_x + self.anim_die1_y - 1);
 150                 self.anim_dead2 = '0 1 1' + '1 0 0' * (self.anim_die2_x + self.anim_die2_y - 1);
 151
 152                 if (animparseerror)
 153                         print("Parse error in ", animfilename, ", some player animations are broken\n");
 154         }
 155         else
 156                 dprint("File ", animfilename, " not found, assuming legacy .zym model animation timings\n");
 157         // reset animstate now
 158         player_setanim(self.anim_idle, TRUE, FALSE, TRUE);
 159 };
 160
 161 void player_setanim(vector anim, float looping, float override, float restart)
 162 {
 163         if (!restart)
 164         if (anim_x == self.animstate_startframe)
 165         if (anim_y == self.animstate_numframes)
 166         if (anim_z == self.animstate_framerate)
 167                 return;
 168         self.animstate_startframe = anim_x;
 169         self.animstate_numframes = anim_y;
 170         self.animstate_framerate = anim_z;
 171         self.animstate_starttime = time;
 172         self.animstate_endtime = time + self.animstate_numframes / self.animstate_framerate;
 173         self.animstate_looping = looping;
 174         self.animstate_override = override;
 175         self.frame = self.animstate_startframe;
 176 };
 177
 178 void player_updateframe()
 179 {
 180         if (time >= self.animstate_endtime)
 181         {
 182                 if (self.animstate_looping)
 183                 {
 184                         self.animstate_starttime = self.animstate_endtime;
 185                         self.animstate_endtime = self.animstate_endtime + self.animstate_numframes / self.animstate_framerate;
 186                 }
 187                 self.animstate_override = FALSE;
 188         }
 189         self.frame = self.animstate_startframe + bound(0, (time - self.animstate_starttime) * self.animstate_framerate, self.animstate_numframes - 1);
 190 };
 191
 192 void player_anim (void)
 193 {
 194         player_updateframe();
 195
 196         if (self.deadflag != DEAD_NO)
 197         {
 198                 if (time > self.animstate_endtime)
 199                 {
 200                         if (self.maxs_z > 5)
 201                         {
 202                                 self.maxs_z = 5;
 203                                 setsize(self, self.mins, self.maxs);
 204                         }
 205                         self.frame = self.dead_frame;
 206                 }
 207                 return;
 208         }
 209
 210         if (!self.animstate_override)
 211         {
 212                 if (!(self.flags & FL_ONGROUND))
 213                 {
 214                         if (self.crouch)
 215                                 player_setanim(self.anim_duckjump, FALSE, TRUE, FALSE);
 216                         else
 217                                 player_setanim(self.anim_jump, FALSE, TRUE, FALSE);
 218                 }
 219                 else if (self.crouch)
 220                 {
 221                         if (self.movement_x * self.movement_x + self.movement_y * self.movement_y > 20)
 222                                 player_setanim(self.anim_duckwalk, TRUE, FALSE, FALSE);
 223                         else
 224                                 player_setanim(self.anim_duckidle, TRUE, FALSE, FALSE);
 225                 }
 226                 else if ((self.movement_x * self.movement_x + self.movement_y * self.movement_y) > 20)
 227                 {
 228                         if (self.movement_x > 0 && self.movement_y == 0)
 229                                 player_setanim(self.anim_run, TRUE, FALSE, FALSE);
 230                         else if (self.movement_x < 0 && self.movement_y == 0)
 231                                 player_setanim(self.anim_runbackwards, TRUE, FALSE, FALSE);
 232                         else if (self.movement_x == 0 && self.movement_y > 0)
 233                                 player_setanim(self.anim_straferight, TRUE, FALSE, FALSE);
 234                         else if (self.movement_x == 0 && self.movement_y < 0)
 235                                 player_setanim(self.anim_strafeleft, TRUE, FALSE, FALSE);
 236                         else if (self.movement_x > 0 && self.movement_y > 0)
 237                                 player_setanim(self.anim_forwardright, TRUE, FALSE, FALSE);
 238                         else if (self.movement_x > 0 && self.movement_y < 0)
 239                                 player_setanim(self.anim_forwardleft, TRUE, FALSE, FALSE);
 240                         else if (self.movement_x < 0 && self.movement_y > 0)
 241                                 player_setanim(self.anim_backright, TRUE, FALSE, FALSE);
 242                         else if (self.movement_x < 0 && self.movement_y < 0)
 243                                 player_setanim(self.anim_backleft, TRUE, FALSE, FALSE);
 244                         else
 245                                 player_setanim(self.anim_run, TRUE, FALSE, FALSE);
 246                 }
 247                 else
 248                         player_setanim(self.anim_idle, TRUE, FALSE, FALSE);
 249         }
 250 }
 251 //End change by Supajoe on 11:44 PM EST 11/16/03 (Subject: Player animations)
 252
 253 void SpawnThrownWeapon (vector org, float w)
 254 {
 255         W_ThrowWeapon(randomvec() * 100 + '0 0 200', org - self.origin, FALSE);
 256 }
 257
 258 void PlayerCorpseDamage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 259 {
 260         local float take, save;
 261         if(sv_gentle < 1)
 262                 pointparticles(particleeffectnum("blood"), hitloc, force, bound(0, damage, 200));
 263         // damage resistance (ignore most of the damage from a bullet or similar)
 264         damage = max(damage - 5, 1);
 265
 266         save = bound(0, damage * cvar("g_balance_armor_blockpercent"), self.armorvalue);
 267         take = bound(0, damage - save, damage);
 268
 269         if (save > 10)
 270                 sound (self, CHAN_PROJECTILE, "misc/armorimpact.wav", VOL_BASE, ATTN_NORM);
 271         else if (take > 30)
 272                 sound (self, CHAN_PROJECTILE, "misc/bodyimpact2.wav", VOL_BASE, ATTN_NORM);
 273         else if (take > 10)
 274                 sound (self, CHAN_PROJECTILE, "misc/bodyimpact1.wav", VOL_BASE, ATTN_NORM);
 275
 276         if(independent_players)
 277         if(sv_gentle < 1) {
 278                 if (take > 50)
 279                         TossGib (world, "models/gibs/chunk.mdl", hitloc, force * -0.1,1);
 280                 if (take > 100)
 281                         TossGib (world, "models/gibs/chunk.mdl", hitloc, force * -0.2,1);
 282         }
 283
 284         if (!(self.flags & FL_GODMODE))
 285         {
 286                 self.armorvalue = self.armorvalue - save;
 287                 self.health = self.health - take;
 288                 // pause regeneration for 5 seconds
 289                 self.pauseregen_finished = max(self.pauseregen_finished, time + cvar("g_balance_pause_health_regen"));
 290         }
 291         self.dmg_save = self.dmg_save + save;//max(save - 10, 0);
 292         self.dmg_take = self.dmg_take + take;//max(take - 10, 0);
 293         self.dmg_inflictor = inflictor;
 294
 295         if (self.health <= -50)
 296         {
 297                 // don't use any animations as a gib
 298                 self.frame = 0;
 299                 self.dead_frame = 0;
 300                 // view just above the floor
 301                 self.view_ofs = '0 0 4';
 302
 303                 // make a juicy mess
 304                 local float multiplier;
 305                 multiplier = 1;
 306                 if (cvar("ekg"))
 307                         multiplier = 5;
 308
 309
 310                 // make a meaty mess
 311                 if(independent_players)
 312                 {
 313                         TossGib (self, "models/gibs/eye.md3", self.origin + self.view_ofs, self.velocity + randomvec() * 150,0);
 314                         self.solid = SOLID_TRIGGER; // undo SOLID_CORPSE
 315                         self.takedamage = DAMAGE_NO; // can't damage this gib, to prevent better jumps from it
 316                 }
 317                 else
 318                         TossGib (self, "models/gibs/eye.md3", self.origin + self.view_ofs, self.velocity + randomvec() * 150,0);
 319
 320                 if not(independent_players)
 321                 if(sv_gentle < 1) {
 322                         te_bloodshower (self.origin + self.mins, self.origin + self.maxs, 1200 * multiplier, 1000);
 323                         TossGib (world, "models/gibs/bloodyskull.md3", self.origin + self.view_ofs, self.velocity,0);
 324
 325                         local float c;
 326                         c = 0;
 327
 328                         while (c < multiplier)
 329                         {
 330                                 c = c + 1;
 331                                 //TossGib (world, "models/gibs/gib1.md3", self.origin, self.velocity + randomvec() * 450,0);
 332                                 //TossGib (world, "models/gibs/gib2.md3", self.origin, self.velocity + randomvec() * 450,0);
 333                                 //TossGib (world, "models/gibs/gib3.md3", self.origin, self.velocity + randomvec() * 450,0);
 334                                 //TossGib (world, "models/gibs/gib4.md3", self.origin, self.velocity + randomvec() * 450,0);
 335                                 //TossGib (world, "models/gibs/gib5.md3", self.origin, self.velocity + randomvec() * 450,0);
 336                                 //TossGib (world, "models/gibs/gib6.md3", self.origin, self.velocity + randomvec() * 450,0);
 337
 338                                 TossGib (world, "models/gibs/arm.md3", self.origin + self.view_ofs, self.velocity + randomvec() * (random() * 120 + 90),0);
 339                                 TossGib (world, "models/gibs/arm.md3", self.origin + self.view_ofs, self.velocity + randomvec() * (random() * 120 + 90),0);
 340                                 //TossGib (world, "models/gibs/arm.md3", self.origin + self.view_ofs, self.velocity + randomvec() * 150,0);
 341                                 //TossGib (world, "models/gibs/arm.md3", self.origin + self.view_ofs, self.velocity + randomvec() * 150,0);
 342                                 TossGib (world, "models/gibs/chest.md3", self.origin + self.view_ofs * 0.5, self.velocity + randomvec() * (random() * 120 + 80),0);
 343                                 //TossGib (world, "models/gibs/smallchest.md3", self.origin + self.view_ofs, self.velocity + randomvec() * 150,0);
 344                                 TossGib (world, "models/gibs/smallchest.md3", self.origin + self.view_ofs, self.velocity + randomvec() * (random() * 120 + 80),0);
 345                                 TossGib (world, "models/gibs/leg1.md3", self.origin + self.view_ofs * -0.2, self.velocity + randomvec() * (random() * 120 + 85),0);
 346                                 TossGib (world, "models/gibs/leg2.md3", self.origin + self.view_ofs * -0.4, self.velocity + randomvec() * (random() * 120 + 85),0);
 347                                 //TossGib (world, "models/gibs/leg1.md3", self.origin + self.view_ofs * -0.2, self.velocity + randomvec() * 150,0);
 348                                 //TossGib (world, "models/gibs/leg2.md3", self.origin + self.view_ofs * -0.4, self.velocity + randomvec() * 150,0);
 349
 350                                 // these splat on impact
 351                                 TossGib (world, "models/gibs/chunk.mdl", self.origin, self.velocity + randomvec() * 450,1);
 352                                 TossGib (world, "models/gibs/chunk.mdl", self.origin, self.velocity + randomvec() * 450,1);
 353                                 TossGib (world, "models/gibs/chunk.mdl", self.origin, self.velocity + randomvec() * 450,1);
 354                                 TossGib (world, "models/gibs/chunk.mdl", self.origin, self.velocity + randomvec() * 450,1);
 355                         }
 356                         sound (self, CHAN_PLAYER, "misc/gib.wav", VOL_BASE, ATTN_NORM);
 357                 }
 358         }
 359 }
 360
 361 void ClientKill_Now_TeamChange();
 362
 363 void PlayerDamage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 364 {
 365         local float take, save, waves, sdelay;
 366
 367         if(!DEATH_ISSPECIAL(deathtype))
 368         {
 369                 damage *= sqrt(bound(1.0, self.cvar_cl_handicap, 100.0));
 370                 if(self != attacker)
 371                         damage /= sqrt(bound(1.0, attacker.cvar_cl_handicap, 100.0));
 372         }
 373
 374         if(sv_gentle > 0) {
 375                 pointparticles(particleeffectnum("damage_hit"), hitloc, force, bound(0, damage, 200));
 376         } else {
 377                 pointparticles(particleeffectnum("blood"), hitloc, force, bound(0, damage, 200));
 378         }
 379
 380         if(g_arena)
 381         if(numspawned < 2)
 382                 return;
 383
 384         if (!g_minstagib)
 385         {
 386                 save = bound(0, damage * cvar("g_balance_armor_blockpercent"), self.armorvalue);
 387                 take = bound(0, damage - save, damage);
 388         }
 389         else
 390         {
 391                 save = 0;
 392                 take = damage;
 393         }
 394
 395         if (save > 10)
 396                 sound (self, CHAN_PROJECTILE, "misc/armorimpact.wav", VOL_BASE, ATTN_NORM);
 397         else if (take > 30)
 398                 sound (self, CHAN_PROJECTILE, "misc/bodyimpact2.wav", VOL_BASE, ATTN_NORM);
 399         else if (take > 10)
 400                 sound (self, CHAN_PROJECTILE, "misc/bodyimpact1.wav", VOL_BASE, ATTN_NORM); // FIXME possibly remove them?
 401
 402         if(sv_gentle < 1)
 403         if not(independent_players)
 404         {
 405                 if (take > 50)
 406                         TossGib (world, "models/gibs/chunk.mdl", hitloc, force * -0.1,1);
 407                 if (take > 100)
 408                         TossGib (world, "models/gibs/chunk.mdl", hitloc, force * -0.2,1);
 409         }
 410
 411         if (time > self.spawnshieldtime)
 412         {
 413                 if (!(self.flags & FL_GODMODE))
 414                 {
 415                         self.armorvalue = self.armorvalue - save;
 416                         self.health = self.health - take;
 417                         // pause regeneration for 5 seconds
 418                         self.pauseregen_finished = max(self.pauseregen_finished, time + cvar("g_balance_pause_health_regen"));
 419
 420                         if (time > self.pain_finished)          //Don't switch pain sequences like crazy
 421                         {
 422                                 self.pain_finished = time + 0.5;        //Supajoe
 423
 424                                 if(sv_gentle < 1) {
 425                                         if (random() > 0.5)
 426                                                 player_setanim(self.anim_pain1, FALSE, TRUE, TRUE);
 427                                         else
 428                                                 player_setanim(self.anim_pain2, FALSE, TRUE, TRUE);
 429
 430                                         if(!DEATH_ISWEAPON(deathtype, WEP_LASER) || attacker != self || self.health < 2 * cvar("g_balance_laser_primary_damage") * cvar("g_balance_selfdamagepercent") + 1)
 431                                         // exclude pain sounds for laserjumps as long as you aren't REALLY low on health and would die of the next two
 432                                         {
 433                                                 if(self.health > 75) // TODO make a "gentle" version?
 434                                                         PlayerSound(playersound_pain100, CHAN_PAIN, 0);
 435                                                 else if(self.health > 50)
 436                                                         PlayerSound(playersound_pain75, CHAN_PAIN, 0);
 437                                                 else if(self.health > 25)
 438                                                         PlayerSound(playersound_pain50, CHAN_PAIN, 0);
 439                                                 else if(self.health > 1)
 440                                                         PlayerSound(playersound_pain25, CHAN_PAIN, 0);
 441                                         }
 442                                 }
 443
 444                                 // throw off bot aim temporarily
 445                                 local float shake;
 446                                 shake = damage * 5 / (bound(0,skill,100) + 1);
 447                                 self.v_angle_x = self.v_angle_x + (random() * 2 - 1) * shake;
 448                                 self.v_angle_y = self.v_angle_y + (random() * 2 - 1) * shake;
 449                         }
 450                 }
 451                 else
 452                         self.max_armorvalue += (save + take);
 453         }
 454         self.dmg_save = self.dmg_save + save;//max(save - 10, 0);
 455         self.dmg_take = self.dmg_take + take;//max(take - 10, 0);
 456         self.dmg_inflictor = inflictor;
 457
 458         if(attacker == self)
 459         {
 460                 // don't reset pushltime for self damage as it may be an attempt to
 461                 // escape a lava pit or similar
 462                 //self.pushltime = 0;
 463         }
 464         else if(attacker.classname == "player" || attacker.classname == "gib")
 465         {
 466                 self.pusher = attacker;
 467                 self.pushltime = time + cvar("g_maxpushtime");
 468         }
 469         else if(time < self.pushltime)
 470         {
 471                 attacker = self.pusher;
 472                 self.pushltime = max(self.pushltime, time + 0.6);
 473         }
 474         else
 475                 self.pushltime = 0;
 476
 477         if (self.health < 1)
 478         {
 479                 float defer_ClientKill_Now_TeamChange;
 480                 defer_ClientKill_Now_TeamChange = FALSE;
 481
 482                 if(sv_gentle < 1) // TODO make a "gentle" version?
 483                 {
 484                         if(deathtype == DEATH_DROWN)
 485                                 PlayerSound(playersound_drown, CHAN_PAIN, 0);
 486                         else
 487                                 PlayerSound(playersound_death, CHAN_PAIN, 0);
 488                 }
 489
 490                 // get rid of kill indicator
 491                 if(self.killindicator)
 492                 {
 493                         remove(self.killindicator);
 494                         self.killindicator = world;
 495                         if(self.killindicator_teamchange)
 496                                 defer_ClientKill_Now_TeamChange = TRUE;
 497
 498                         if(self.classname == "body")
 499                         if(deathtype == DEATH_KILL)
 500                         {
 501                                 // for the lemmings fans, a small harmless explosion
 502                                 pointparticles(particleeffectnum("rocket_explode"), self.origin, '0 0 0', 1);
 503                         }
 504                 }
 505
 506                 // become fully visible
 507                 self.alpha = 1;
 508                 // clear selected player display
 509                 ClearSelectedPlayer();
 510                 // throw a weapon
 511                 SpawnThrownWeapon (self.origin + (self.mins + self.maxs) * 0.5, self.switchweapon);
 512                 // print an obituary message
 513                 Obituary (attacker, inflictor, self, deathtype);
 514                 race_PreDie();
 515                 DropAllRunes(self);
 516                 if(self == attacker)
 517                         kh_Key_DropAll(self, TRUE);
 518                 else if(attacker.classname == "player" || attacker.classname == "gib")
 519                         kh_Key_DropAll(self, FALSE);
 520                 else
 521                         kh_Key_DropAll(self, TRUE);
 522                 if(self.flagcarried)
 523                 {
 524                         if(attacker.classname != "player" && attacker.classname != "gib")
 525                                 DropFlag(self.flagcarried, self, attacker); // penalty for flag loss by suicide
 526                         else if(attacker.team == self.team)
 527                                 DropFlag(self.flagcarried, attacker, attacker); // penalty for flag loss by suicide/teamkill
 528                         else
 529                                 DropFlag(self.flagcarried, world, attacker);
 530                 }
 531                 Portal_ClearAllLater(self);
 532                 // clear waypoints
 533                 WaypointSprite_PlayerDead();
 534                 // make the corpse upright (not tilted)
 535                 self.angles_x = 0;
 536                 self.angles_z = 0;
 537                 // don't spin
 538                 self.avelocity = '0 0 0';
 539                 // view from the floor
 540                 self.view_ofs = '0 0 -8';
 541                 // toss the corpse
 542                 self.movetype = MOVETYPE_TOSS;
 543                 // shootable corpse
 544                 self.solid = SOLID_CORPSE;
 545                 // don't stick to the floor
 546                 self.flags = self.flags - (self.flags & FL_ONGROUND);
 547                 // dying animation
 548                 self.deadflag = DEAD_DYING;
 549                 // when to allow respawn
 550                 sdelay = 0;
 551                 waves = 0;
 552                 if(cvar("g_respawn_mapsettings"))
 553                 {
 554                         sdelay = cvar("g_respawn_mapsettings_delay");
 555                         waves = cvar("g_respawn_mapsettings_waves");
 556                 }
 557                 if(!sdelay)
 558                         sdelay = cvar(strcat("g_", GetGametype(), "_respawn_delay"));
 559                 if(!sdelay)
 560                         sdelay = cvar("g_respawn_delay");
 561                 if(!waves)
 562                         waves = cvar(strcat("g_", GetGametype(), "_respawn_waves"));
 563                 if(!waves)
 564                         waves = cvar("g_respawn_waves");
 565                 if(waves)
 566                         self.death_time = ceil((time + sdelay) / waves) * waves;
 567                 else
 568                         self.death_time = time + sdelay;
 569                 if((sdelay + waves >= 5.0) && (self.death_time - time > 1.75))
 570                         self.respawn_countdown = 10; // first number to count down from is 10
 571                 else
 572                         self.respawn_countdown = -1; // do not count down
 573                 if (random() < 0.5)
 574                 {
 575                         player_setanim(self.anim_die1, FALSE, TRUE, TRUE);
 576                         self.dead_frame = self.anim_dead1_x;
 577                 }
 578                 else
 579                 {
 580                         player_setanim(self.anim_die2, FALSE, TRUE, TRUE);
 581                         self.dead_frame = self.anim_dead2_x;
 582                 }
 583                 // set damage function to corpse damage
 584                 self.event_damage = PlayerCorpseDamage;
 585                 // call the corpse damage function just in case it wants to gib
 586                 self.event_damage(inflictor, attacker, 0, deathtype, hitloc, force);
 587                 // set up to fade out later
 588                 SUB_SetFade (self, time + 12 + random () * 4, 1);
 589
 590                 // remove laserdot
 591                 if(self.weaponentity)
 592                         if(self.weaponentity.lasertarget)
 593                                 remove(self.weaponentity.lasertarget);
 594
 595                 if(clienttype(self) == CLIENTTYPE_REAL)
 596                 {
 597                         self.fixangle = TRUE;
 598                         //msg_entity = self;
 599                         //WriteByte (MSG_ONE, SVC_SETANGLE);
 600                         //WriteAngle (MSG_ONE, self.v_angle_x);
 601                         //WriteAngle (MSG_ONE, self.v_angle_y);
 602                         //WriteAngle (MSG_ONE, 80);
 603                 }
 604
 605                 if(g_arena)
 606                         Spawnqueue_Unmark(self);
 607
 608                 if(defer_ClientKill_Now_TeamChange)
 609                         ClientKill_Now_TeamChange();
 610
 611                 if(sv_gentle > 0) {
 612                         // remove corpse
 613                         PlayerCorpseDamage (inflictor, attacker, 100.0, deathtype, hitloc, force);
 614                         pointparticles(particleeffectnum("damage_dissolve"), self.origin, force, 1);
 615                 }
 616         }
 617 }
 618
 619 float UpdateSelectedPlayer_countvalue(float v)
 620 {
 621         return max(0, (v - 1.0) / 0.5);
 622 }
 623
 624 // returns: -2 if no hit, otherwise cos of the angle
 625 // uses the global v_angle
 626 float UpdateSelectedPlayer_canSee(entity p, float mincosangle, float maxdist)
 627 {
 628         vector so, d;
 629         float c;
 630
 631         if(p == self)
 632                 return -2;
 633
 634         if(p.deadflag)
 635                 return -2;
 636
 637         so = self.origin + self.view_ofs;
 638         d = p.origin - so;
 639
 640         // misaimed?
 641         if(dist_point_line(d, '0 0 0', v_forward) > maxdist)
 642                 return -2;
 643
 644         // now find the cos of the angle...
 645         c = normalize(d) * v_forward;
 646
 647         if(c <= mincosangle)
 648                 return -2;
 649
 650         traceline(so, p.origin, MOVE_NOMONSTERS, self);
 651         if(trace_fraction < 1)
 652                 return -2;
 653
 654         return c;
 655 }
 656
 657 void ClearSelectedPlayer()
 658 {
 659         if(self.selected_player)
 660         {
 661                 centerprint_expire(self, CENTERPRIO_POINT);
 662                 self.selected_player = world;
 663                 self.selected_player_display_needs_update = FALSE;
 664         }
 665 }
 666
 667 void UpdateSelectedPlayer()
 668 {
 669         entity selected;
 670         float selected_score;
 671         selected = world;
 672         selected_score = 0.95; // 18 degrees
 673
 674         if(!cvar("sv_allow_shownames"))
 675                 return;
 676
 677         if(clienttype(self) != CLIENTTYPE_REAL)
 678                 return;
 679
 680         if(self.cvar_cl_shownames == 0)
 681                 return;
 682
 683         if(self.cvar_cl_shownames == 1 && !teams_matter)
 684                 return;
 685
 686         makevectors(self.v_angle); // sets v_forward
 687
 688         // 1. cursor trace is always right
 689         if(self.cursor_trace_ent && self.cursor_trace_ent.classname == "player" && !self.cursor_trace_ent.deadflag)
 690         {
 691                 selected = self.cursor_trace_ent;
 692         }
 693         else
 694         {
 695                 // 2. if we don't have a cursor trace, find the player which is least
 696                 //    mis-aimed at
 697                 entity p;
 698                 FOR_EACH_PLAYER(p)
 699                 {
 700                         float c;
 701                         c = UpdateSelectedPlayer_canSee(p, selected_score, 100); // 100 = 2.5 meters
 702                         if(c >= -1)
 703                         {
 704                                 selected = p;
 705                                 selected_score = c;
 706                         }
 707                 }
 708         }
 709
 710         if(selected)
 711         {
 712                 self.selected_player_display_timeout = time + self.cvar_scr_centertime;
 713         }
 714         else
 715         {
 716                 if(time < self.selected_player_display_timeout)
 717                         if(UpdateSelectedPlayer_canSee(self.selected_player, 0.7, 200) >= -1) // 5 meters, 45 degrees
 718                                 selected = self.selected_player;
 719         }
 720
 721         if(selected)
 722         {
 723                 if(selected == self.selected_player)
 724                 {
 725                         float save;
 726                         save = UpdateSelectedPlayer_countvalue(self.selected_player_count);
 727                         self.selected_player_count = self.selected_player_count + frametime;
 728                         if(save != UpdateSelectedPlayer_countvalue(self.selected_player_count))
 729                         {
 730                                 string namestr, healthstr;
 731                                 namestr = playername(selected);
 732                                 if(teams_matter)
 733                                 {
 734                                         healthstr = ftos(floor(selected.health));
 735                                         if(self.team == selected.team)
 736                                         {
 737                                                 namestr = strcat(namestr, " (", healthstr, "%)");
 738                                                 self.selected_player_display_needs_update = TRUE;
 739                                         }
 740                                 }
 741                                 centerprint_atprio(self, CENTERPRIO_POINT, namestr);
 742                         }
 743                 }
 744                 else
 745                 {
 746                         ClearSelectedPlayer();
 747                         self.selected_player = selected;
 748                         self.selected_player_time = time;
 749                         self.selected_player_count = 0;
 750                         self.selected_player_display_needs_update = FALSE;
 751                 }
 752         }
 753         else
 754         {
 755                 ClearSelectedPlayer();
 756         }
 757
 758         if(self.selected_player)
 759                 self.last_selected_player = self.selected_player;
 760 }
 761
 762 float GetVoiceMessageTeamsayType(string type)
 763 {
 764         if(type == "taunt")
 765                 return 0;
 766         if(type == "teamshoot")
 767                 return 2;
 768         if(type == "teamshoot_auto")
 769                 return 3;
 770         return 1;
 771 }
 772
 773 string allvoicesamples;
 774 float GetPlayerSoundSampleField_notFound;
 775 float GetPlayerSoundSampleField_fixed;
 776 .string GetVoiceMessageSampleField(string type)
 777 {
 778         GetPlayerSoundSampleField_notFound = 0;
 779         GetPlayerSoundSampleField_fixed = 0;
 780         switch(type)
 781         {
 782 #define _VOICEMSG(m) case #m: return playersound_##m;
 783                 ALLVOICEMSGS
 784 #undef _VOICEMSG
 785                 // exception:
 786                 case "teamshoot_auto": return playersound_teamshoot;
 787         }
 788         GetPlayerSoundSampleField_notFound = 1;
 789         return playersound_taunt;
 790 }
 791
 792 .string GetPlayerSoundSampleField(string type)
 793 {
 794         GetPlayerSoundSampleField_notFound = 0;
 795         GetPlayerSoundSampleField_fixed = 0;
 796         switch(type)
 797         {
 798 #define _VOICEMSG(m) case #m: return playersound_##m;
 799                 ALLPLAYERSOUNDS
 800 #undef _VOICEMSG
 801         }
 802         GetPlayerSoundSampleField_notFound = 1;
 803         return playersound_taunt;
 804 }
 805
 806 void PrecacheGlobalSound(string samplestring)
 807 {
 808         float n, i;
 809         tokenize_sane(samplestring);
 810         n = stof(argv(1));
 811         if(n > 0)
 812         {
 813                 for(i = 1; i <= n; ++i)
 814                         precache_sound(strcat(argv(0), ftos(i), ".wav"));
 815         }
 816         else
 817         {
 818                 precache_sound(strcat(argv(0), ".wav"));
 819         }
 820 }
 821
 822 void PrecachePlayerSounds(string f)
 823 {
 824         float fh;
 825         string s;
 826         fh = fopen(f, FILE_READ);
 827         if(fh < 0)
 828                 return;
 829         while((s = fgets(fh)))
 830         {
 831                 if(tokenize_sane(s) != 3)
 832                 {
 833                         dprint("Invalid sound info line: ", s, "\n");
 834                         continue;
 835                 }
 836                 PrecacheGlobalSound(strcat(argv(1), " ", argv(2)));
 837         }
 838         fclose(fh);
 839
 840         if not(allvoicesamples)
 841         {
 842 #define _VOICEMSG(m) allvoicesamples = strcat(allvoicesamples, " ", #m);
 843                 ALLVOICEMSGS
 844 #undef _VOICEMSG
 845                 allvoicesamples = strzone(substring(allvoicesamples, 1, strlen(allvoicesamples) - 1));
 846         }
 847 }
 848
 849 void ClearPlayerSounds()
 850 {
 851 #define _VOICEMSG(m) if(self.playersound_##m) { strunzone(self.playersound_##m); self.playersound_##m = string_null; }
 852         ALLPLAYERSOUNDS
 853         ALLVOICEMSGS
 854 #undef _VOICEMSG
 855 }
 856
 857 void LoadPlayerSounds(string f, float first)
 858 {
 859         float fh;
 860         string s;
 861         var .string field;
 862         fh = fopen(f, FILE_READ);
 863         if(fh < 0)
 864                 return;
 865         while((s = fgets(fh)))
 866         {
 867                 if(tokenize_sane(s) != 3)
 868                         continue;
 869                 field = GetPlayerSoundSampleField(argv(0));
 870                 if(GetPlayerSoundSampleField_notFound)
 871                         field = GetVoiceMessageSampleField(argv(0));
 872                 if(GetPlayerSoundSampleField_notFound)
 873                         continue;
 874                 if(GetPlayerSoundSampleField_fixed)
 875                         if not(first)
 876                                 continue;
 877                 if(self.field)
 878                         strunzone(self.field);
 879                 self.field = strzone(strcat(argv(1), " ", argv(2)));
 880         }
 881         fclose(fh);
 882 }
 883
 884 .float modelindex_for_playersound;
 885 void UpdatePlayerSounds()
 886 {
 887         if(self.modelindex == self.modelindex_for_playersound)
 888                 return;
 889         self.modelindex_for_playersound = self.modelindex;
 890         ClearPlayerSounds();
 891         LoadPlayerSounds("sound/player/default.sounds", 1);
 892         LoadPlayerSounds(strcat(self.model, ".sounds"), 0);
 893 }
 894
 895 void GlobalSound(string sample, float chan, float teamsay)
 896 {
 897         float n;
 898
 899         if(sample == "")
 900                 return;
 901
 902         tokenize_sane(sample);
 903         n = stof(argv(1));
 904         if(n > 0)
 905                 sample = strcat(argv(0), ftos(floor(random() * n + 1)), ".wav"); // randomization
 906         else
 907                 sample = strcat(argv(0), ".wav"); // randomization
 908
 909         if(teamsay == 3) // only to last attacker
 910         {
 911                 if(self.pusher)
 912                         if(self.pusher.team == self.team)
 913                         {
 914                                 msg_entity = self.pusher;
 915                                 if(clienttype(msg_entity) == CLIENTTYPE_REAL)
 916                                         soundto(MSG_ONE, self, chan, sample, VOL_BASE, ATTN_NONE);
 917                         }
 918         }
 919         else if(teamsay == 2) // only to last attacker and self
 920         {
 921                 if(self.pusher)
 922                         if(self.pusher.team == self.team)
 923                         {
 924                                 msg_entity = self.pusher;
 925                                 if(clienttype(msg_entity) == CLIENTTYPE_REAL)
 926                                         soundto(MSG_ONE, self, chan, sample, VOL_BASE, ATTN_NONE);
 927                                 msg_entity = self;
 928                                 if(clienttype(msg_entity) == CLIENTTYPE_REAL)
 929                                         soundto(MSG_ONE, self, chan, sample, VOL_BASE, ATTN_NONE);
 930                         }
 931         }
 932         else if(teamsay == 0) // to everyone
 933         {
 934                 // broadcast the sound, but it's directional
 935                 sound(self, chan, sample, VOL_BASE, ATTN_MIN);
 936         }
 937         else if(teamsay == 1) // to the same team
 938         {
 939                 if(teams_matter)
 940                 {
 941                         entity e;
 942                         FOR_EACH_REALCLIENT(e)
 943                                 if(!teams_matter || e.team == self.team)
 944                                 {
 945                                         msg_entity = e;
 946                                         soundto(MSG_ONE, self, chan, sample, VOL_BASE, ATTN_NONE);
 947                                 }
 948                 }
 949                 else
 950                 {
 951                         sound(self, chan, sample, VOL_BASE, ATTN_NONE);
 952                 }
 953         }
 954         else if(teamsay == 4) // auto taunt
 955         {
 956                 float tauntrand;
 957                 tauntrand = random();
 958                 FOR_EACH_REALCLIENT(e)
 959                 if (tauntrand < e.cvar_cl_autotaunt)
 960                 {
 961                         msg_entity = e;
 962                         soundto(MSG_ONE, self, chan, sample, VOL_BASE, ATTN_MIN);
 963                 }
 964         }
 965 }
 966
 967 void PlayerSound(.string samplefield, float chan, float teamsay)
 968 {
 969         string sample;
 970         sample = self.samplefield;
 971         GlobalSound(sample, chan, teamsay);
 972 }
 973
 974 void VoiceMessage(string type)
 975 {
 976         var .string sample;
 977         var float teamsay;
 978         sample = GetVoiceMessageSampleField(type);
 979
 980         if(GetPlayerSoundSampleField_notFound)
 981         {
 982                 sprint(self, strcat("Invalid voice. Use one of: ", allvoicesamples, "\n"));
 983                 return;
 984         }
 985
 986         teamsay = GetVoiceMessageTeamsayType(type);
 987
 988         PlayerSound(sample, CHAN_VOICE, teamsay);
 989 }