data/qcsrc/server/cl_physics.qc

   1 float sv_accelerate;
   2 float sv_friction;
   3 float sv_maxspeed;
   4 float sv_airaccelerate;
   5 float sv_maxairspeed;
   6 float sv_stopspeed;
   7 float sv_gravity;
   8 float sv_airaccel_sideways_friction;
   9 float sv_airaccel_qw;
  10 .float ladder_time;
  11 .entity ladder_entity;
  12 .float gravity;
  13 .float swamp_slowdown;
  14 .float lastflags;
  15 .float lastground;
  16 .float wasFlying;
  17 .float spectatorspeed;
  18
  19 #define SHTEST_DELTA 10
  20 #define SHTEST_THRESHOLD 1.1
  21 .float shtest_next;
  22 .float shtest_accumulator;
  23
  24 /*
  25 =============
  26 PlayerJump
  27
  28 When you press the jump key
  29 =============
  30 */
  31 void PlayerJump (void)
  32 {
  33         float mjumpheight;
  34
  35         mjumpheight = cvar("sv_jumpvelocity");
  36         if (self.waterlevel >= 2)
  37         {
  38                 if (self.watertype == CONTENT_WATER)
  39                         self.velocity_z = 200;
  40                 else if (self.watertype == CONTENT_SLIME)
  41                         self.velocity_z = 80;
  42                 else
  43                         self.velocity_z = 50;
  44
  45                 return;
  46         }
  47
  48
  49         if (!(self.flags & FL_ONGROUND))
  50                 return;
  51
  52         if(!sv_pogostick)
  53                 if (!(self.flags & FL_JUMPRELEASED))
  54                         return;
  55
  56         if(g_runematch)
  57         {
  58                 if(self.runes & RUNE_SPEED)
  59                 {
  60                         if(self.runes & CURSE_SLOW)
  61                                 mjumpheight = mjumpheight * cvar("g_balance_rune_speed_combo_jumpheight");
  62                         else
  63                                 mjumpheight = mjumpheight * cvar("g_balance_rune_speed_jumpheight");
  64                 }
  65                 else if(self.runes & CURSE_SLOW)
  66                 {
  67                         mjumpheight = mjumpheight * cvar("g_balance_curse_slow_jumpheight");
  68                 }
  69         }
  70
  71         if(g_minstagib && (self.items & IT_INVINCIBLE))
  72         {
  73                 mjumpheight = mjumpheight * cvar("g_minstagib_speed_jumpheight");
  74         }
  75
  76         self.velocity_z = self.velocity_z + mjumpheight;
  77         self.oldvelocity_z = self.velocity_z;
  78
  79         self.flags = self.flags - FL_ONGROUND;
  80         self.flags = self.flags - FL_JUMPRELEASED;
  81
  82         if (self.crouch)
  83                 player_setanim(self.anim_duckjump, FALSE, TRUE, TRUE);
  84         else
  85                 player_setanim(self.anim_jump, FALSE, TRUE, TRUE);
  86
  87         if(g_jump_grunt)
  88                 PlayerSound(playersound_jump, CHAN_PLAYER, 0);
  89 }
  90
  91 void CheckWaterJump()
  92 {
  93         local vector start, end;
  94
  95 // check for a jump-out-of-water
  96         makevectors (self.angles);
  97         start = self.origin;
  98         start_z = start_z + 8;
  99         v_forward_z = 0;
 100         normalize(v_forward);
 101         end = start + v_forward*24;
 102         traceline (start, end, TRUE, self);
 103         if (trace_fraction < 1)
 104         {       // solid at waist
 105                 start_z = start_z + self.maxs_z - 8;
 106                 end = start + v_forward*24;
 107                 self.movedir = trace_plane_normal * -50;
 108                 traceline (start, end, TRUE, self);
 109                 if (trace_fraction == 1)
 110                 {       // open at eye level
 111                         self.flags = self.flags | FL_WATERJUMP;
 112                         self.velocity_z = 225;
 113                         self.flags = self.flags - (self.flags & FL_JUMPRELEASED);
 114                         self.teleport_time = time + 2;  // safety net
 115                         return;
 116                 }
 117         }
 118 };
 119
 120 .vector movement_old;
 121 .float buttons_old;
 122 .vector v_angle_old;
 123
 124 void Nixnex_GiveCurrentWeapon();
 125 void SV_PlayerPhysics()
 126 {
 127         local vector wishvel, wishdir, v;
 128         local float wishspeed, f, maxspd_mod, spd, maxairspd, airaccel, swampspd_mod, shtest_score, buttons;
 129         string temps;
 130
 131         buttons = self.BUTTON_ATCK + 2 * self.BUTTON_JUMP + 4 * self.BUTTON_ATCK2 + 8 * self.BUTTON_ZOOM + 16 * self.BUTTON_CROUCH + 32 * self.BUTTON_HOOK + 64 * self.BUTTON_USE;
 132         if(!sv_maxidle_spectatorsareidle || self.movetype == MOVETYPE_WALK)
 133         {
 134                 if(buttons != self.buttons_old || self.movement != self.movement_old || self.v_angle != self.v_angle_old)
 135                         self.parm_idlesince = time;
 136         }
 137         self.buttons_old = buttons;
 138         self.movement_old = self.movement;
 139         self.v_angle_old = self.v_angle;
 140
 141         if(time > self.shtest_next)
 142         {
 143                 if(self.shtest_next > 0)
 144                 {
 145                         // self.shtest_accumulator:
 146                         //   started at time - SHTEST_DELTA
 147                         //   should be at SHTEST_DELTA
 148                         shtest_score = self.shtest_accumulator / (SHTEST_DELTA + time - self.shtest_next);
 149                         if(shtest_score > SHTEST_THRESHOLD)
 150                                 print("TIME PARADOX: shtest for ", self.netname, " said ", ftos(shtest_score), "\n");
 151                         else if(cvar("developer_shtest"))
 152                                 dprint("okay: shtest for ", self.netname, " said ", ftos(shtest_score), "\n");
 153                 }
 154                 self.shtest_next = time + SHTEST_DELTA;
 155                 self.shtest_accumulator = 0;
 156         }
 157         self.shtest_accumulator += frametime;
 158
 159         if (clienttype(self) == CLIENTTYPE_BOT)
 160                 bot_think();
 161
 162         if (self.movetype == MOVETYPE_NONE)
 163                 return;
 164
 165         if (self.punchangle != '0 0 0')
 166         {
 167                 f = vlen(self.punchangle) - 10 * frametime;
 168                 if (f > 0)
 169                         self.punchangle = normalize(self.punchangle) * f;
 170                 else
 171                         self.punchangle = '0 0 0';
 172         }
 173
 174         if (self.punchvector != '0 0 0')
 175         {
 176                 f = vlen(self.punchvector) - 30 * frametime;
 177                 if (f > 0)
 178                         self.punchvector = normalize(self.punchvector) * f;
 179                 else
 180                         self.punchvector = '0 0 0';
 181         }
 182
 183         maxspd_mod = 1;
 184
 185         if(g_runematch)
 186         {
 187                 if(self.runes & RUNE_SPEED)
 188                 {
 189                         if(self.runes & CURSE_SLOW)
 190                                 maxspd_mod = maxspd_mod * cvar("g_balance_rune_speed_combo_moverate");
 191                         else
 192                                 maxspd_mod = maxspd_mod * cvar("g_balance_rune_speed_moverate");
 193                 }
 194                 else if(self.runes & CURSE_SLOW)
 195                 {
 196                         maxspd_mod = maxspd_mod * cvar("g_balance_curse_slow_moverate");
 197                 }
 198         }
 199
 200         if(g_minstagib && (self.items & IT_INVINCIBLE))
 201         {
 202                 maxspd_mod = cvar("g_minstagib_speed_moverate");
 203         }
 204
 205         swampspd_mod = 1;
 206         if(self.in_swamp) {
 207                 swampspd_mod = self.swamp_slowdown; //cvar("g_balance_swamp_moverate");
 208         }
 209
 210         if(self.flags & FL_NOTARGET)
 211         {
 212                 maxspd_mod = cvar("sv_spectator_speed_multiplier");
 213                 if(!self.spectatorspeed)
 214                         self.spectatorspeed = maxspd_mod;
 215                 if(self.impulse && self.impulse <= 12)
 216                 {
 217                         if(self.lastflags & FL_NOTARGET)
 218                         {
 219                                 if(self.impulse == 10)
 220                                         self.spectatorspeed = bound(1, self.spectatorspeed + 0.5, 5);
 221                                 else if(self.impulse == 11)
 222                                         self.spectatorspeed = maxspd_mod;
 223                                 else if(self.impulse == 12)
 224                                         self.spectatorspeed = bound(1, self.spectatorspeed - 0.5, 5);
 225                                 else if(self.impulse >= 1 && self.impulse <= 9)
 226                                         self.spectatorspeed = 1 + 0.5 * (self.impulse - 1);
 227                         } // otherwise just clear
 228                         self.impulse = 0;
 229                         print("impulse\n");
 230                 }
 231                 maxspd_mod = self.spectatorspeed;
 232         }
 233
 234         spd = sv_maxspeed * maxspd_mod * swampspd_mod;
 235
 236         if(self.speed != spd)
 237         {
 238                 self.speed = spd;
 239                 temps = ftos(spd);
 240                 stuffcmd(self, strcat("cl_forwardspeed ", temps, "\n"));
 241                 stuffcmd(self, strcat("cl_backspeed ", temps, "\n"));
 242                 stuffcmd(self, strcat("cl_sidespeed ", temps, "\n"));
 243                 stuffcmd(self, strcat("cl_upspeed ", temps, "\n"));
 244
 245                 temps = ftos(sv_accelerate * maxspd_mod);
 246                 stuffcmd(self, strcat("cl_movement_accelerate ", temps, "\n"));
 247         }
 248
 249         // if dead, behave differently
 250         if (self.deadflag)
 251                 return;
 252
 253         if (!self.fixangle)
 254         {
 255                 self.angles_x = 0;
 256                 self.angles_y = self.v_angle_y;
 257                 self.angles_z = 0;
 258         }
 259
 260         if(self.flags & FL_ONGROUND)
 261         if(self.wasFlying)
 262         {
 263                 self.wasFlying = 0;
 264
 265                 if(self.waterlevel < 2)
 266                 if(time >= self.ladder_time)
 267                 if not(self.hook)
 268                 {
 269                         self.nextstep = time + 0.3 + random() * 0.1;
 270                         trace_dphitq3surfaceflags = 0;
 271                         tracebox(self.origin, self.mins, self.maxs, self.origin - '0 0 1', MOVE_NOMONSTERS, self);
 272                         if not(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOSTEPS)
 273                         {
 274                                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_METALSTEPS)
 275                                         GlobalSound(globalsound_metalfall, CHAN_PLAYER, 0);
 276                                 else
 277                                         GlobalSound(globalsound_fall, CHAN_PLAYER, 0);
 278                         }
 279                 }
 280         }
 281
 282         if(IsFlying(self))
 283                 self.wasFlying = 1;
 284
 285         if(self.classname == "player")
 286         {
 287                 if(sv_doublejump)
 288                 {
 289                         self.flags = self.flags - (self.flags & FL_ONGROUND);
 290                         tracebox(self.origin + '0 0 1', self.mins, self.maxs, self.origin - '0 0 2', MOVE_NORMAL, self);
 291                         if(trace_fraction < 1 && trace_plane_normal_z > 0.7)
 292                                 self.flags = self.flags | FL_ONGROUND;
 293                 }
 294
 295                 if (self.BUTTON_JUMP)
 296                         PlayerJump ();
 297                 else
 298                         self.flags = self.flags | FL_JUMPRELEASED;
 299
 300                 if (self.waterlevel == 2)
 301                         CheckWaterJump ();
 302         }
 303
 304         if (self.flags & FL_WATERJUMP )
 305         {
 306                 self.velocity_x = self.movedir_x;
 307                 self.velocity_y = self.movedir_y;
 308                 if (time > self.teleport_time || self.waterlevel == 0)
 309                 {
 310                         self.flags = self.flags - (self.flags & FL_WATERJUMP);
 311                         self.teleport_time = 0;
 312                 }
 313         }
 314         else if (self.movetype == MOVETYPE_NOCLIP || self.movetype == MOVETYPE_FLY)
 315         {
 316                 // noclipping or flying
 317                 self.flags = self.flags - (self.flags & FL_ONGROUND);
 318
 319                 self.velocity = self.velocity * (1 - frametime * sv_friction);
 320                 makevectors(self.v_angle);
 321                 //wishvel = v_forward * self.movement_x + v_right * self.movement_y + v_up * self.movement_z;
 322                 wishvel = v_forward * self.movement_x + v_right * self.movement_y + '0 0 1' * self.movement_z;
 323                 // acceleration
 324                 wishdir = normalize(wishvel);
 325                 wishspeed = vlen(wishvel);
 326                 if (wishspeed > sv_maxspeed*maxspd_mod)
 327                         wishspeed = sv_maxspeed*maxspd_mod;
 328                 if (time >= self.teleport_time)
 329                 {
 330                         f = wishspeed - (self.velocity * wishdir);
 331                         if (f > 0)
 332                                 self.velocity = self.velocity + wishdir * min(f, sv_accelerate*maxspd_mod * frametime * wishspeed);
 333                 }
 334         }
 335         else if (self.waterlevel >= 2)
 336         {
 337                 // swimming
 338                 self.flags = self.flags - (self.flags & FL_ONGROUND);
 339
 340                 makevectors(self.v_angle);
 341                 //wishvel = v_forward * self.movement_x + v_right * self.movement_y + v_up * self.movement_z;
 342                 wishvel = v_forward * self.movement_x + v_right * self.movement_y + '0 0 1' * self.movement_z;
 343                 if (wishvel == '0 0 0')
 344                         wishvel = '0 0 -60'; // drift towards bottom
 345
 346                 wishdir = normalize(wishvel);
 347                 wishspeed = vlen(wishvel);
 348                 if (wishspeed > sv_maxspeed*maxspd_mod)
 349                         wishspeed = sv_maxspeed*maxspd_mod;
 350                 wishspeed = wishspeed * 0.7;
 351
 352                 // water friction
 353                 self.velocity = self.velocity * (1 - frametime * sv_friction);
 354
 355                 // water acceleration
 356                 f = wishspeed - (self.velocity * wishdir);
 357                 if (f > 0)
 358                         self.velocity = self.velocity + wishdir * min(f, sv_accelerate*maxspd_mod * frametime * wishspeed);
 359         }
 360         else if (time < self.ladder_time)
 361         {
 362                 // on a spawnfunc_func_ladder or swimming in spawnfunc_func_water
 363                 self.flags = self.flags - (self.flags & FL_ONGROUND);
 364
 365                 self.velocity = self.velocity * (1 - frametime * sv_friction);
 366                 makevectors(self.v_angle);
 367                 //wishvel = v_forward * self.movement_x + v_right * self.movement_y + v_up * self.movement_z;
 368                 wishvel = v_forward * self.movement_x + v_right * self.movement_y + '0 0 1' * self.movement_z;
 369                 if (self.gravity)
 370                         self.velocity_z = self.velocity_z + self.gravity * sv_gravity * frametime;
 371                 else
 372                         self.velocity_z = self.velocity_z + sv_gravity * frametime;
 373                 if (self.ladder_entity.classname == "func_water")
 374                 {
 375                         f = vlen(wishvel);
 376                         if (f > self.ladder_entity.speed)
 377                                 wishvel = wishvel * (self.ladder_entity.speed / f);
 378
 379                         self.watertype = self.ladder_entity.skin;
 380                         f = self.ladder_entity.origin_z + self.ladder_entity.maxs_z;
 381                         if ((self.origin_z + self.view_ofs_z) < f)
 382                                 self.waterlevel = 3;
 383                         else if ((self.origin_z + (self.mins_z + self.maxs_z) * 0.5) < f)
 384                                 self.waterlevel = 2;
 385                         else if ((self.origin_z + self.mins_z + 1) < f)
 386                                 self.waterlevel = 1;
 387                         else
 388                         {
 389                                 self.waterlevel = 0;
 390                                 self.watertype = CONTENT_EMPTY;
 391                         }
 392                 }
 393                 // acceleration
 394                 wishdir = normalize(wishvel);
 395                 wishspeed = vlen(wishvel);
 396                 if (wishspeed > sv_maxspeed)
 397                         wishspeed = sv_maxspeed;
 398                 if (time >= self.teleport_time)
 399                 {
 400                         f = wishspeed - (self.velocity * wishdir);
 401                         if (f > 0)
 402                                 self.velocity = self.velocity + wishdir * min(f, sv_accelerate*maxspd_mod * frametime * wishspeed);
 403                 }
 404         }
 405         else if (self.flags & FL_ONGROUND)
 406         {
 407                 // walking
 408                 makevectors(self.v_angle_y * '0 1 0');
 409                 wishvel = v_forward * self.movement_x + v_right * self.movement_y;
 410
 411                 if(!(self.lastflags & FL_ONGROUND))
 412                 {
 413                         if(cvar("speedmeter"))
 414                                 dprint(strcat("landing velocity: ", vtos(self.velocity), " (abs: ", ftos(vlen(self.velocity)), ")\n"));
 415                         if(self.lastground < time - 0.3)
 416                                 self.velocity = self.velocity * (1 - cvar("sv_friction_on_land"));
 417                         if(self.jumppadcount > 1)
 418                                 dprint(strcat(ftos(self.jumppadcount), "x jumppad combo\n"));
 419                         self.jumppadcount = 0;
 420                 }
 421
 422                 if (self.velocity_x || self.velocity_y)
 423                 if (!(self.flags & FL_JUMPRELEASED) || !self.BUTTON_JUMP)
 424                 {
 425                         v = self.velocity;
 426                         v_z = 0;
 427                         f = vlen(v);
 428                         if (f < sv_stopspeed)
 429                                 f = 1 - frametime * (sv_stopspeed / f) * sv_friction;
 430                         else
 431                                 f = 1 - frametime * sv_friction;
 432                         if (f > 0)
 433                                 self.velocity = self.velocity * f;
 434                         else
 435                                 self.velocity = '0 0 0';
 436                 }
 437                 // acceleration
 438                 wishdir = normalize(wishvel);
 439                 wishspeed = vlen(wishvel);
 440                 if (wishspeed > sv_maxspeed*maxspd_mod)
 441                         wishspeed = sv_maxspeed*maxspd_mod;
 442                 if (self.crouch)
 443                         wishspeed = wishspeed * 0.5;
 444                 if (time >= self.teleport_time)
 445                 {
 446                         f = wishspeed - (self.velocity * wishdir);
 447                         if (f > 0)
 448                                 self.velocity = self.velocity + wishdir * min(f, sv_accelerate*maxspd_mod * frametime * wishspeed);
 449                 }
 450         }
 451         else
 452         {
 453                 if(maxspd_mod < 1)
 454                 {
 455                         maxairspd = sv_maxairspeed*maxspd_mod;
 456                         airaccel = sv_airaccelerate*maxspd_mod;
 457                 }
 458                 else
 459                 {
 460                         maxairspd = sv_maxairspeed;
 461                         airaccel = sv_airaccelerate;
 462                 }
 463                 // airborn
 464                 makevectors(self.v_angle_y * '0 1 0');
 465                 wishvel = v_forward * self.movement_x + v_right * self.movement_y;
 466                 // acceleration
 467                 wishdir = normalize(wishvel);
 468                 wishspeed = vlen(wishvel);
 469                 if (wishspeed > maxairspd)
 470                         wishspeed = maxairspd;
 471                 if (self.crouch)
 472                         wishspeed = wishspeed * 0.5;
 473                 if (time >= self.teleport_time)
 474                 {
 475                         // NOTE: this does the same as the commented out old code if:
 476                         //   sv_airaccel_qw 0
 477                         //   sv_airaccel_sideways_friction 0
 478
 479                         float vel_straight;
 480                         float vel_z;
 481                         vector vel_perpend;
 482                         vel_straight = self.velocity * wishdir;
 483                         vel_z = self.velocity_z;
 484                         vel_perpend = self.velocity - vel_straight * wishdir - vel_z * '0 0 1';
 485
 486                         f = wishspeed - vel_straight;
 487                         if(f > 0)
 488                                 vel_straight = vel_straight + min(f, airaccel * frametime * wishspeed) * sv_airaccel_qw;
 489                         if(wishspeed > 0)
 490                                 vel_straight = vel_straight + min(wishspeed, airaccel * frametime * wishspeed) * (1 - sv_airaccel_qw);
 491
 492                         // anti-sideways friction to fix QW-style bunnyhopping
 493                         vel_perpend = vel_perpend * (1 - frametime * (wishspeed / maxairspd) * sv_airaccel_sideways_friction);
 494
 495                         self.velocity = vel_straight * wishdir + vel_z * '0 0 1' + vel_perpend;
 496
 497                         /*
 498                         f = wishspeed;// - (self.velocity * wishdir);
 499                         if (f > 0)
 500                                 self.velocity = self.velocity + wishdir * min(f, airaccel * frametime * wishspeed);
 501                         */
 502                 }
 503         }
 504
 505         if(self.flags & FL_ONGROUND)
 506                 self.lastground = time;
 507
 508         self.lastflags = self.flags;
 509 };