data/qcsrc/server/cl_physics.qc

   1 float sv_accelerate;
   2 float sv_friction;
   3 float sv_maxspeed;
   4 float sv_airaccelerate;
   5 float sv_maxairspeed;
   6 float sv_stopspeed;
   7 float sv_gravity;
   8 float sv_airaccel_sideways_friction;
   9 float sv_airaccel_qw;
  10 .float ladder_time;
  11 .entity ladder_entity;
  12 .float gravity;
  13 .float swamp_slowdown;
  14 .float lastflags;
  15 .float lastground;
  16 .float wasFlying;
  17 .float spectatorspeed;
  18
  19 #define SHTEST_DELTA 10
  20 #define SHTEST_THRESHOLD 1.1
  21 .float shtest_next;
  22 .float shtest_accumulator;
  23
  24 /*
  25 =============
  26 PlayerJump
  27
  28 When you press the jump key
  29 =============
  30 */
  31 void PlayerJump (void)
  32 {
  33         float mjumpheight;
  34
  35         mjumpheight = cvar("sv_jumpvelocity");
  36         if (self.waterlevel >= 2)
  37         {
  38                 if (self.watertype == CONTENT_WATER)
  39                         self.velocity_z = 200;
  40                 else if (self.watertype == CONTENT_SLIME)
  41                         self.velocity_z = 80;
  42                 else
  43                         self.velocity_z = 50;
  44
  45                 return;
  46         }
  47
  48
  49         if (!(self.flags & FL_ONGROUND))
  50                 return;
  51
  52         if(!sv_pogostick)
  53                 if (!(self.flags & FL_JUMPRELEASED))
  54                         return;
  55
  56         if(g_runematch)
  57         {
  58                 if(self.runes & RUNE_SPEED)
  59                 {
  60                         if(self.runes & CURSE_SLOW)
  61                                 mjumpheight = mjumpheight * cvar("g_balance_rune_speed_combo_jumpheight");
  62                         else
  63                                 mjumpheight = mjumpheight * cvar("g_balance_rune_speed_jumpheight");
  64                 }
  65                 else if(self.runes & CURSE_SLOW)
  66                 {
  67                         mjumpheight = mjumpheight * cvar("g_balance_curse_slow_jumpheight");
  68                 }
  69         }
  70
  71         if(g_minstagib && (self.items & IT_INVINCIBLE))
  72         {
  73                 mjumpheight = mjumpheight * cvar("g_minstagib_speed_jumpheight");
  74         }
  75
  76         self.velocity_z = self.velocity_z + mjumpheight;
  77         self.oldvelocity_z = self.velocity_z;
  78
  79         self.flags = self.flags - FL_ONGROUND;
  80         self.flags = self.flags - FL_JUMPRELEASED;
  81
  82         if (self.crouch)
  83                 player_setanim(self.anim_duckjump, FALSE, TRUE, TRUE);
  84         else
  85                 player_setanim(self.anim_jump, FALSE, TRUE, TRUE);
  86
  87         if(g_jump_grunt)
  88                 PlayerSound(playersound_jump, CHAN_PLAYER, 0);
  89 }
  90
  91 void CheckWaterJump()
  92 {
  93         local vector start, end;
  94
  95 // check for a jump-out-of-water
  96         makevectors (self.angles);
  97         start = self.origin;
  98         start_z = start_z + 8;
  99         v_forward_z = 0;
 100         normalize(v_forward);
 101         end = start + v_forward*24;
 102         traceline (start, end, TRUE, self);
 103         if (trace_fraction < 1)
 104         {       // solid at waist
 105                 start_z = start_z + self.maxs_z - 8;
 106                 end = start + v_forward*24;
 107                 self.movedir = trace_plane_normal * -50;
 108                 traceline (start, end, TRUE, self);
 109                 if (trace_fraction == 1)
 110                 {       // open at eye level
 111                         self.flags = self.flags | FL_WATERJUMP;
 112                         self.velocity_z = 225;
 113                         self.flags = self.flags - (self.flags & FL_JUMPRELEASED);
 114                         self.teleport_time = time + 2;  // safety net
 115                         return;
 116                 }
 117         }
 118 };
 119
 120 float racecar_angle(float forward, float down)
 121 {
 122         float ret, angle_mult;
 123
 124         if(forward < 0)
 125         {
 126                 forward = -forward;
 127                 down = -down;
 128         }
 129
 130         ret = vectoyaw('0 1 0' * down + '1 0 0' * forward);
 131
 132         angle_mult = forward / (800 + forward);
 133
 134         if(ret > 180)
 135                 return ret * angle_mult + 360 * (1 - angle_mult);
 136         else
 137                 return ret * angle_mult;
 138 }
 139
 140 .vector movement_old;
 141 .float buttons_old;
 142 .vector v_angle_old;
 143
 144 void Nixnex_GiveCurrentWeapon();
 145 void SV_PlayerPhysics()
 146 {
 147         local vector wishvel, wishdir, v;
 148         local float wishspeed, f, maxspd_mod, spd, maxairspd, airaccel, swampspd_mod, shtest_score, buttons;
 149         string temps;
 150
 151         buttons = self.BUTTON_ATCK + 2 * self.BUTTON_JUMP + 4 * self.BUTTON_ATCK2 + 8 * self.BUTTON_ZOOM + 16 * self.BUTTON_CROUCH + 32 * self.BUTTON_HOOK + 64 * self.BUTTON_USE;
 152         if(!sv_maxidle_spectatorsareidle || self.movetype == MOVETYPE_WALK)
 153         {
 154                 if(buttons != self.buttons_old || self.movement != self.movement_old || self.v_angle != self.v_angle_old)
 155                         self.parm_idlesince = time;
 156         }
 157         self.buttons_old = buttons;
 158         self.movement_old = self.movement;
 159         self.v_angle_old = self.v_angle;
 160
 161         if(time > self.shtest_next)
 162         {
 163                 if(self.shtest_next > 0)
 164                 {
 165                         // self.shtest_accumulator:
 166                         //   started at time - SHTEST_DELTA
 167                         //   should be at SHTEST_DELTA
 168                         shtest_score = self.shtest_accumulator / (SHTEST_DELTA + time - self.shtest_next);
 169                         if(shtest_score > SHTEST_THRESHOLD)
 170                                 print("TIME PARADOX: shtest for ", self.netname, " said ", ftos(shtest_score), "\n");
 171                         else if(cvar("developer_shtest"))
 172                                 dprint("okay: shtest for ", self.netname, " said ", ftos(shtest_score), "\n");
 173                 }
 174                 self.shtest_next = time + SHTEST_DELTA;
 175                 self.shtest_accumulator = 0;
 176         }
 177         self.shtest_accumulator += frametime;
 178
 179         if (clienttype(self) == CLIENTTYPE_BOT)
 180                 bot_think();
 181
 182         if (self.movetype == MOVETYPE_NONE && self.disableclientprediction != 2)
 183                 return;
 184
 185         if(g_bugrigs && self.movetype == MOVETYPE_WALK)
 186         {
 187                 self.disableclientprediction = 1;
 188                 self.movetype = MOVETYPE_NOCLIP;
 189         }
 190
 191         if (self.punchangle != '0 0 0')
 192         {
 193                 f = vlen(self.punchangle) - 10 * frametime;
 194                 if (f > 0)
 195                         self.punchangle = normalize(self.punchangle) * f;
 196                 else
 197                         self.punchangle = '0 0 0';
 198         }
 199
 200         if (self.punchvector != '0 0 0')
 201         {
 202                 f = vlen(self.punchvector) - 30 * frametime;
 203                 if (f > 0)
 204                         self.punchvector = normalize(self.punchvector) * f;
 205                 else
 206                         self.punchvector = '0 0 0';
 207         }
 208
 209         maxspd_mod = 1;
 210
 211         if(g_runematch)
 212         {
 213                 if(self.runes & RUNE_SPEED)
 214                 {
 215                         if(self.runes & CURSE_SLOW)
 216                                 maxspd_mod = maxspd_mod * cvar("g_balance_rune_speed_combo_moverate");
 217                         else
 218                                 maxspd_mod = maxspd_mod * cvar("g_balance_rune_speed_moverate");
 219                 }
 220                 else if(self.runes & CURSE_SLOW)
 221                 {
 222                         maxspd_mod = maxspd_mod * cvar("g_balance_curse_slow_moverate");
 223                 }
 224         }
 225
 226         if(g_minstagib && (self.items & IT_INVINCIBLE))
 227         {
 228                 maxspd_mod = cvar("g_minstagib_speed_moverate");
 229         }
 230
 231         swampspd_mod = 1;
 232         if(self.in_swamp) {
 233                 swampspd_mod = self.swamp_slowdown; //cvar("g_balance_swamp_moverate");
 234         }
 235
 236         if(self.flags & FL_NOTARGET)
 237         {
 238                 maxspd_mod = cvar("sv_spectator_speed_multiplier");
 239                 if(!self.spectatorspeed)
 240                         self.spectatorspeed = maxspd_mod;
 241                 if(self.impulse && self.impulse <= 19)
 242                 {
 243                         if(self.lastflags & FL_NOTARGET)
 244                         {
 245                                 if(self.impulse == 10 || self.impulse == 15 || self.impulse == 18)
 246                                         self.spectatorspeed = bound(1, self.spectatorspeed + 0.5, 5);
 247                                 else if(self.impulse == 11)
 248                                         self.spectatorspeed = maxspd_mod;
 249                                 else if(self.impulse == 12 || self.impulse == 16  || self.impulse == 19)
 250                                         self.spectatorspeed = bound(1, self.spectatorspeed - 0.5, 5);
 251                                 else if(self.impulse >= 1 && self.impulse <= 9)
 252                                         self.spectatorspeed = 1 + 0.5 * (self.impulse - 1);
 253                         } // otherwise just clear
 254                         self.impulse = 0;
 255                 }
 256                 maxspd_mod = self.spectatorspeed;
 257         }
 258
 259         spd = sv_maxspeed * maxspd_mod * swampspd_mod;
 260
 261         if(self.speed != spd)
 262         {
 263                 self.speed = spd;
 264                 temps = ftos(spd);
 265                 stuffcmd(self, strcat("cl_forwardspeed ", temps, "\n"));
 266                 stuffcmd(self, strcat("cl_backspeed ", temps, "\n"));
 267                 stuffcmd(self, strcat("cl_sidespeed ", temps, "\n"));
 268                 stuffcmd(self, strcat("cl_upspeed ", temps, "\n"));
 269
 270                 temps = ftos(sv_accelerate * maxspd_mod);
 271                 stuffcmd(self, strcat("cl_movement_accelerate ", temps, "\n"));
 272         }
 273
 274         // if dead, behave differently
 275         if (self.deadflag)
 276                 return;
 277
 278         if (!self.fixangle && !g_bugrigs)
 279         {
 280                 self.angles_x = 0;
 281                 self.angles_y = self.v_angle_y;
 282                 self.angles_z = 0;
 283         }
 284
 285         if(self.flags & FL_ONGROUND)
 286         if(self.wasFlying)
 287         {
 288                 self.wasFlying = 0;
 289
 290                 if(self.waterlevel < 2)
 291                 if(time >= self.ladder_time)
 292                 if not(self.hook)
 293                 {
 294                         self.nextstep = time + 0.3 + random() * 0.1;
 295                         trace_dphitq3surfaceflags = 0;
 296                         tracebox(self.origin, self.mins, self.maxs, self.origin - '0 0 1', MOVE_NOMONSTERS, self);
 297                         if not(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOSTEPS)
 298                         {
 299                                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_METALSTEPS)
 300                                         GlobalSound(globalsound_metalfall, CHAN_PLAYER, 0);
 301                                 else
 302                                         GlobalSound(globalsound_fall, CHAN_PLAYER, 0);
 303                         }
 304                 }
 305         }
 306
 307         if(IsFlying(self))
 308                 self.wasFlying = 1;
 309
 310         if(self.classname == "player")
 311         {
 312                 if(sv_doublejump)
 313                 {
 314                         self.flags = self.flags - (self.flags & FL_ONGROUND);
 315                         tracebox(self.origin + '0 0 1', self.mins, self.maxs, self.origin - '0 0 2', MOVE_NORMAL, self);
 316                         if(trace_fraction < 1 && trace_plane_normal_z > 0.7)
 317                                 self.flags = self.flags | FL_ONGROUND;
 318                 }
 319
 320                 if (self.BUTTON_JUMP)
 321                         PlayerJump ();
 322                 else
 323                         self.flags = self.flags | FL_JUMPRELEASED;
 324
 325                 if (self.waterlevel == 2)
 326                         CheckWaterJump ();
 327         }
 328
 329         if (self.flags & FL_WATERJUMP )
 330         {
 331                 self.velocity_x = self.movedir_x;
 332                 self.velocity_y = self.movedir_y;
 333                 if (time > self.teleport_time || self.waterlevel == 0)
 334                 {
 335                         self.flags = self.flags - (self.flags & FL_WATERJUMP);
 336                         self.teleport_time = 0;
 337                 }
 338         }
 339         else if (g_bugrigs && self.classname == "player")
 340         {
 341                 // using this move type for "big rigs"
 342                 // the engine does not push the entity!
 343
 344                 float accel, steer, myspeed, steerfactor, accelfactor, upspeed, friction;
 345                 vector neworigin, up, angles_save, rigvel, rigvel_xy;
 346
 347                 angles_save = self.angles;
 348                 accel = self.movement_x / sv_maxspeed;
 349                 steer = self.movement_y / sv_maxspeed;
 350
 351                 self.angles_x = 0;
 352                 self.angles_z = 0;
 353                 makevectors(self.angles); // new forward direction!
 354
 355                 if(self.flags & FL_ONGROUND || g_bugrigs == 1)
 356                 // BUG RIGS: responsive to movement while in air (matches big rigs better where the car is NEVER in air)
 357                 // g_bugrigs 2 turns off that bug
 358                 {
 359                         myspeed = self.velocity * v_forward;
 360                         upspeed = self.velocity * v_up;
 361
 362                         // responsiveness factor for steering and acceleration
 363                         f = 1 / (1 + pow(max(0, myspeed / 400), 2));
 364
 365                         steerfactor = -myspeed * f;
 366                         accelfactor = f * 800;
 367
 368                         // BUG RIGS: make friction FAIL if reversing
 369                         if(accel < 0)
 370                         {
 371                                 if(myspeed <= 0)
 372                                         friction = 0;
 373                                 else
 374                                         myspeed = max(0, myspeed - frametime * 1000);
 375                         }
 376                         else
 377                                 myspeed = max(0, myspeed - frametime * 50);
 378                                 // terminal velocity = velocity at which 50 == accelfactor, that is, 1549 units/sec
 379
 380                         // BUG RIGS: stop when reversing and releasing the button
 381                         if(myspeed < 0 && accel == 0)
 382                                 myspeed = 0;
 383
 384                         self.angles_y += steer * frametime * steerfactor; // apply steering
 385                         makevectors(self.angles); // new forward direction!
 386
 387                         myspeed += accel * accelfactor * frametime;
 388
 389                         rigvel = myspeed * v_forward + '0 0 1' * upspeed;
 390                 }
 391                 else
 392                 {
 393                         myspeed = vlen(self.velocity);
 394
 395                         // responsiveness factor for steering and acceleration
 396                         f = 1 / (1 + pow(max(0, myspeed / 400), 2));
 397                         steerfactor = -myspeed * f;
 398                         self.angles_y += steer * frametime * steerfactor; // apply steering
 399
 400                         rigvel = self.velocity;
 401                         makevectors(self.angles); // new forward direction!
 402                 }
 403
 404                 rigvel_z -= frametime * sv_gravity; // 4x gravity plays better
 405                 rigvel_xy = rigvel;
 406                 rigvel_xy_z = 0;
 407
 408                 tracebox(self.origin, self.mins, self.maxs, self.origin + '0 0 1024', MOVE_NORMAL, self);
 409                 up = trace_endpos - self.origin;
 410
 411                 // BUG RIGS: align the move to the surface instead of doing collision testing
 412                 // can we move?
 413                 tracebox(trace_endpos, self.mins, self.maxs, trace_endpos + rigvel_xy * frametime, MOVE_NORMAL, self);
 414
 415                 // align to surface
 416                 tracebox(trace_endpos, self.mins, self.maxs, trace_endpos - up + '0 0 1' * rigvel_z * frametime, MOVE_NORMAL, self);
 417
 418                 if(trace_fraction < 0.5)
 419                 {
 420                         trace_fraction = 1;
 421                         neworigin = self.origin;
 422                 }
 423                 else
 424                         neworigin = trace_endpos;
 425
 426                 self.velocity = (neworigin - self.origin) * (1.0 / frametime);
 427
 428                 if(trace_fraction < 1)
 429                 {
 430                         // now set angles_x so that the car points parallel to the surface
 431                         self.angles = vectoangles(
 432                                 '1 0 0' * v_forward_x * trace_plane_normal_z
 433                                 +
 434                                 '0 1 0' * v_forward_y * trace_plane_normal_z
 435                                 +
 436                                 '0 0 1' * -(v_forward_x * trace_plane_normal_x + v_forward_y * trace_plane_normal_y)
 437                         );
 438                         self.flags |= FL_ONGROUND;
 439                 }
 440                 else
 441                 {
 442                         // now set angles_x so that the car points forward, but is tilted in velocity direction
 443                         vector vel_local;
 444
 445                         vel_local_x = v_forward * self.velocity;
 446                         vel_local_y = v_right * self.velocity;
 447                         vel_local_z = v_up * self.velocity;
 448
 449                         self.angles_x = racecar_angle(vel_local_x, vel_local_z);
 450                         self.angles_z = racecar_angle(-vel_local_y, vel_local_z);
 451
 452                         self.flags (-) FL_ONGROUND;
 453                 }
 454
 455                 // smooth the angles
 456                 vector vf1, vu1, smoothangles;
 457                 makevectors(self.angles);
 458                 vf1 = v_forward * frametime * 5;
 459                 vu1 = v_up;
 460                 makevectors(angles_save);
 461                 vf1 = vf1 + v_forward * (1 - frametime * 5);
 462                 vu1 = vu1 + v_up * (1 - frametime * 5);
 463                 smoothangles = vectoangles2(vf1, vu1);
 464                 self.angles_x = -smoothangles_x;
 465                 self.angles_z =  smoothangles_z;
 466         }
 467         else if (self.movetype == MOVETYPE_NOCLIP || self.movetype == MOVETYPE_FLY)
 468         {
 469                 // noclipping or flying
 470                 self.flags = self.flags - (self.flags & FL_ONGROUND);
 471
 472                 self.velocity = self.velocity * (1 - frametime * sv_friction);
 473                 makevectors(self.v_angle);
 474                 //wishvel = v_forward * self.movement_x + v_right * self.movement_y + v_up * self.movement_z;
 475                 wishvel = v_forward * self.movement_x + v_right * self.movement_y + '0 0 1' * self.movement_z;
 476                 // acceleration
 477                 wishdir = normalize(wishvel);
 478                 wishspeed = vlen(wishvel);
 479                 if (wishspeed > sv_maxspeed*maxspd_mod)
 480                         wishspeed = sv_maxspeed*maxspd_mod;
 481                 if (time >= self.teleport_time)
 482                 {
 483                         f = wishspeed - (self.velocity * wishdir);
 484                         if (f > 0)
 485                                 self.velocity = self.velocity + wishdir * min(f, sv_accelerate*maxspd_mod * frametime * wishspeed);
 486                 }
 487         }
 488         else if (self.waterlevel >= 2)
 489         {
 490                 // swimming
 491                 self.flags = self.flags - (self.flags & FL_ONGROUND);
 492
 493                 makevectors(self.v_angle);
 494                 //wishvel = v_forward * self.movement_x + v_right * self.movement_y + v_up * self.movement_z;
 495                 wishvel = v_forward * self.movement_x + v_right * self.movement_y + '0 0 1' * self.movement_z;
 496                 if (wishvel == '0 0 0')
 497                         wishvel = '0 0 -60'; // drift towards bottom
 498
 499                 wishdir = normalize(wishvel);
 500                 wishspeed = vlen(wishvel);
 501                 if (wishspeed > sv_maxspeed*maxspd_mod)
 502                         wishspeed = sv_maxspeed*maxspd_mod;
 503                 wishspeed = wishspeed * 0.7;
 504
 505                 // water friction
 506                 self.velocity = self.velocity * (1 - frametime * sv_friction);
 507
 508                 // water acceleration
 509                 f = wishspeed - (self.velocity * wishdir);
 510                 if (f > 0)
 511                         self.velocity = self.velocity + wishdir * min(f, sv_accelerate*maxspd_mod * frametime * wishspeed);
 512         }
 513         else if (time < self.ladder_time)
 514         {
 515                 // on a spawnfunc_func_ladder or swimming in spawnfunc_func_water
 516                 self.flags = self.flags - (self.flags & FL_ONGROUND);
 517
 518                 self.velocity = self.velocity * (1 - frametime * sv_friction);
 519                 makevectors(self.v_angle);
 520                 //wishvel = v_forward * self.movement_x + v_right * self.movement_y + v_up * self.movement_z;
 521                 wishvel = v_forward * self.movement_x + v_right * self.movement_y + '0 0 1' * self.movement_z;
 522                 if (self.gravity)
 523                         self.velocity_z = self.velocity_z + self.gravity * sv_gravity * frametime;
 524                 else
 525                         self.velocity_z = self.velocity_z + sv_gravity * frametime;
 526                 if (self.ladder_entity.classname == "func_water")
 527                 {
 528                         f = vlen(wishvel);
 529                         if (f > self.ladder_entity.speed)
 530                                 wishvel = wishvel * (self.ladder_entity.speed / f);
 531
 532                         self.watertype = self.ladder_entity.skin;
 533                         f = self.ladder_entity.origin_z + self.ladder_entity.maxs_z;
 534                         if ((self.origin_z + self.view_ofs_z) < f)
 535                                 self.waterlevel = 3;
 536                         else if ((self.origin_z + (self.mins_z + self.maxs_z) * 0.5) < f)
 537                                 self.waterlevel = 2;
 538                         else if ((self.origin_z + self.mins_z + 1) < f)
 539                                 self.waterlevel = 1;
 540                         else
 541                         {
 542                                 self.waterlevel = 0;
 543                                 self.watertype = CONTENT_EMPTY;
 544                         }
 545                 }
 546                 // acceleration
 547                 wishdir = normalize(wishvel);
 548                 wishspeed = vlen(wishvel);
 549                 if (wishspeed > sv_maxspeed)
 550                         wishspeed = sv_maxspeed;
 551                 if (time >= self.teleport_time)
 552                 {
 553                         f = wishspeed - (self.velocity * wishdir);
 554                         if (f > 0)
 555                                 self.velocity = self.velocity + wishdir * min(f, sv_accelerate*maxspd_mod * frametime * wishspeed);
 556                 }
 557         }
 558         else if (self.flags & FL_ONGROUND)
 559         {
 560                 // walking
 561                 makevectors(self.v_angle_y * '0 1 0');
 562                 wishvel = v_forward * self.movement_x + v_right * self.movement_y;
 563
 564                 if(!(self.lastflags & FL_ONGROUND))
 565                 {
 566                         if(cvar("speedmeter"))
 567                                 dprint(strcat("landing velocity: ", vtos(self.velocity), " (abs: ", ftos(vlen(self.velocity)), ")\n"));
 568                         if(self.lastground < time - 0.3)
 569                                 self.velocity = self.velocity * (1 - cvar("sv_friction_on_land"));
 570                         if(self.jumppadcount > 1)
 571                                 dprint(strcat(ftos(self.jumppadcount), "x jumppad combo\n"));
 572                         self.jumppadcount = 0;
 573                 }
 574
 575                 if (self.velocity_x || self.velocity_y)
 576                 if (!(self.flags & FL_JUMPRELEASED) || !self.BUTTON_JUMP)
 577                 {
 578                         v = self.velocity;
 579                         v_z = 0;
 580                         f = vlen(v);
 581                         if (f < sv_stopspeed)
 582                                 f = 1 - frametime * (sv_stopspeed / f) * sv_friction;
 583                         else
 584                                 f = 1 - frametime * sv_friction;
 585                         if (f > 0)
 586                                 self.velocity = self.velocity * f;
 587                         else
 588                                 self.velocity = '0 0 0';
 589                 }
 590                 // acceleration
 591                 wishdir = normalize(wishvel);
 592                 wishspeed = vlen(wishvel);
 593                 if (wishspeed > sv_maxspeed*maxspd_mod)
 594                         wishspeed = sv_maxspeed*maxspd_mod;
 595                 if (self.crouch)
 596                         wishspeed = wishspeed * 0.5;
 597                 if (time >= self.teleport_time)
 598                 {
 599                         f = wishspeed - (self.velocity * wishdir);
 600                         if (f > 0)
 601                                 self.velocity = self.velocity + wishdir * min(f, sv_accelerate*maxspd_mod * frametime * wishspeed);
 602                 }
 603         }
 604         else
 605         {
 606                 if(maxspd_mod < 1)
 607                 {
 608                         maxairspd = sv_maxairspeed*maxspd_mod;
 609                         airaccel = sv_airaccelerate*maxspd_mod;
 610                 }
 611                 else
 612                 {
 613                         maxairspd = sv_maxairspeed;
 614                         airaccel = sv_airaccelerate;
 615                 }
 616                 // airborn
 617                 makevectors(self.v_angle_y * '0 1 0');
 618                 wishvel = v_forward * self.movement_x + v_right * self.movement_y;
 619                 // acceleration
 620                 wishdir = normalize(wishvel);
 621                 wishspeed = vlen(wishvel);
 622                 if (wishspeed > maxairspd)
 623                         wishspeed = maxairspd;
 624                 if (self.crouch)
 625                         wishspeed = wishspeed * 0.5;
 626                 if (time >= self.teleport_time)
 627                 {
 628                         // NOTE: this does the same as the commented out old code if:
 629                         //   sv_airaccel_qw 0
 630                         //   sv_airaccel_sideways_friction 0
 631
 632                         float vel_straight;
 633                         float vel_z;
 634                         vector vel_perpend;
 635                         vel_straight = self.velocity * wishdir;
 636                         vel_z = self.velocity_z;
 637                         vel_perpend = self.velocity - vel_straight * wishdir - vel_z * '0 0 1';
 638
 639                         f = wishspeed - vel_straight;
 640                         if(f > 0)
 641                                 vel_straight = vel_straight + min(f, airaccel * frametime * wishspeed) * sv_airaccel_qw;
 642                         if(wishspeed > 0)
 643                                 vel_straight = vel_straight + min(wishspeed, airaccel * frametime * wishspeed) * (1 - sv_airaccel_qw);
 644
 645                         // anti-sideways friction to fix QW-style bunnyhopping
 646                         vel_perpend = vel_perpend * (1 - frametime * (wishspeed / maxairspd) * sv_airaccel_sideways_friction);
 647
 648                         self.velocity = vel_straight * wishdir + vel_z * '0 0 1' + vel_perpend;
 649
 650                         /*
 651                         f = wishspeed;// - (self.velocity * wishdir);
 652                         if (f > 0)
 653                                 self.velocity = self.velocity + wishdir * min(f, airaccel * frametime * wishspeed);
 654                         */
 655                 }
 656         }
 657
 658         if(self.flags & FL_ONGROUND)
 659                 self.lastground = time;
 660
 661         self.lastflags = self.flags;
 662 };