data/qcsrc/server/cl_physics.qc

   1 float sv_accelerate;
   2 float sv_friction;
   3 float sv_maxspeed;
   4 float sv_airaccelerate;
   5 float sv_maxairspeed;
   6 float sv_stopspeed;
   7 float sv_gravity;
   8 float sv_airaccel_sideways_friction;
   9 float sv_airaccel_qw;
  10 .float ladder_time;
  11 .entity ladder_entity;
  12 .float gravity;
  13 .float swamp_slowdown;
  14 .float lastflags;
  15 .float lastground;
  16
  17 #define SHTEST_DELTA 15
  18 .float shtest_next;
  19 .float shtest_accumulator;
  20
  21 /*
  22 =============
  23 PlayerJump
  24
  25 When you press the jump key
  26 =============
  27 */
  28 void PlayerJump (void)
  29 {
  30         float mjumpheight;
  31
  32         mjumpheight = cvar("sv_jumpvelocity");
  33         if (self.waterlevel >= 2)
  34         {
  35                 if (self.watertype == CONTENT_WATER)
  36                         self.velocity_z = 200;
  37                 else if (self.watertype == CONTENT_SLIME)
  38                         self.velocity_z = 80;
  39                 else
  40                         self.velocity_z = 50;
  41
  42                 return;
  43         }
  44
  45
  46         if (!(self.flags & FL_ONGROUND))
  47                 return;
  48
  49         if(!sv_pogostick)
  50                 if (!(self.flags & FL_JUMPRELEASED))
  51                         return;
  52
  53         if(g_runematch)
  54         {
  55                 if(self.runes & RUNE_SPEED)
  56                 {
  57                         if(self.runes & CURSE_SLOW)
  58                                 mjumpheight = mjumpheight * cvar("g_balance_rune_speed_combo_jumpheight");
  59                         else
  60                                 mjumpheight = mjumpheight * cvar("g_balance_rune_speed_jumpheight");
  61                 }
  62                 else if(self.runes & CURSE_SLOW)
  63                 {
  64                         mjumpheight = mjumpheight * cvar("g_balance_curse_slow_jumpheight");
  65                 }
  66         }
  67
  68         if(g_minstagib && (self.items & IT_INVINCIBLE))
  69         {
  70                 mjumpheight = mjumpheight * cvar("g_minstagib_speed_jumpheight");
  71         }
  72
  73         self.velocity_z = self.velocity_z + mjumpheight;
  74         self.oldvelocity_z = self.velocity_z;
  75
  76         self.flags = self.flags - FL_ONGROUND;
  77         self.flags = self.flags - FL_JUMPRELEASED;
  78
  79         if (self.crouch)
  80                 player_setanim(self.anim_duckjump, FALSE, TRUE, TRUE);
  81         else
  82                 player_setanim(self.anim_jump, FALSE, TRUE, TRUE);
  83
  84         if(g_jump_grunt)
  85                 PlayerSound(playersound_jump, CHAN_AUTO, 0);
  86 }
  87
  88 void CheckWaterJump()
  89 {
  90         local vector start, end;
  91
  92 // check for a jump-out-of-water
  93         makevectors (self.angles);
  94         start = self.origin;
  95         start_z = start_z + 8;
  96         v_forward_z = 0;
  97         normalize(v_forward);
  98         end = start + v_forward*24;
  99         traceline (start, end, TRUE, self);
 100         if (trace_fraction < 1)
 101         {       // solid at waist
 102                 start_z = start_z + self.maxs_z - 8;
 103                 end = start + v_forward*24;
 104                 self.movedir = trace_plane_normal * -50;
 105                 traceline (start, end, TRUE, self);
 106                 if (trace_fraction == 1)
 107                 {       // open at eye level
 108                         self.flags = self.flags | FL_WATERJUMP;
 109                         self.velocity_z = 225;
 110                         self.flags = self.flags - (self.flags & FL_JUMPRELEASED);
 111                         self.teleport_time = time + 2;  // safety net
 112                         return;
 113                 }
 114         }
 115 };
 116
 117 .vector movement_old;
 118 .float buttons_old;
 119 .vector v_angle_old;
 120
 121 void Nixnex_GiveCurrentWeapon();
 122 void SV_PlayerPhysics()
 123 {
 124         local vector wishvel, wishdir, v;
 125         local float wishspeed, f, maxspd_mod, spd, maxairspd, airaccel, swampspd_mod, shtest_score, buttons;
 126         string temps;
 127
 128         buttons = self.BUTTON_ATCK + 2 * self.BUTTON_JUMP + 4 * self.BUTTON_ATCK2 + 8 * self.BUTTON_ZOOM + 16 * self.BUTTON_CROUCH + 32 * self.BUTTON_HOOK + 64 * self.BUTTON_USE;
 129         if(!sv_maxidle_spectatorsareidle || self.movetype == MOVETYPE_WALK)
 130         {
 131                 if(buttons != self.buttons_old || self.movement != self.movement_old || self.v_angle != self.v_angle_old)
 132                         self.parm_idlesince = time;
 133         }
 134         self.buttons_old = buttons;
 135         self.movement_old = self.movement;
 136         self.v_angle_old = self.v_angle;
 137
 138         if(time > self.shtest_next)
 139         {
 140                 if(self.shtest_next > 0)
 141                 {
 142                         // self.shtest_accumulator:
 143                         //   started at time - SHTEST_DELTA
 144                         //   should be at SHTEST_DELTA
 145                         shtest_score = self.shtest_accumulator / SHTEST_DELTA;
 146                         if(shtest_score > 1.2)
 147                                 dprint("TIME PARADOX: shtest for ", self.netname, " said ", ftos(shtest_score), "\n");
 148                         else if(cvar("developer_shtest"))
 149                                 dprint("okay: shtest for ", self.netname, " said ", ftos(shtest_score), "\n");
 150                 }
 151                 self.shtest_next = time + SHTEST_DELTA;
 152                 self.shtest_accumulator = 0;
 153         }
 154         self.shtest_accumulator += frametime;
 155
 156         if (clienttype(self) == CLIENTTYPE_BOT)
 157                 bot_think();
 158
 159         if (self.movetype == MOVETYPE_NONE)
 160                 return;
 161
 162         if (self.punchangle != '0 0 0')
 163         {
 164                 f = vlen(self.punchangle) - 10 * frametime;
 165                 if (f > 0)
 166                         self.punchangle = normalize(self.punchangle) * f;
 167                 else
 168                         self.punchangle = '0 0 0';
 169         }
 170
 171         if (self.punchvector != '0 0 0')
 172         {
 173                 f = vlen(self.punchvector) - 30 * frametime;
 174                 if (f > 0)
 175                         self.punchvector = normalize(self.punchvector) * f;
 176                 else
 177                         self.punchvector = '0 0 0';
 178         }
 179
 180         maxspd_mod = 1;
 181
 182         if(g_runematch)
 183         {
 184                 if(self.runes & RUNE_SPEED)
 185                 {
 186                         if(self.runes & CURSE_SLOW)
 187                                 maxspd_mod = maxspd_mod * cvar("g_balance_rune_speed_combo_moverate");
 188                         else
 189                                 maxspd_mod = maxspd_mod * cvar("g_balance_rune_speed_moverate");
 190                 }
 191                 else if(self.runes & CURSE_SLOW)
 192                 {
 193                         maxspd_mod = maxspd_mod * cvar("g_balance_curse_slow_moverate");
 194                 }
 195         }
 196
 197         if(g_minstagib && (self.items & IT_INVINCIBLE))
 198         {
 199                 maxspd_mod = cvar("g_minstagib_speed_moverate");
 200         }
 201
 202         swampspd_mod = 1;
 203         if(self.in_swamp) {
 204                 swampspd_mod = self.swamp_slowdown; //cvar("g_balance_swamp_moverate");
 205         }
 206
 207         if(self.flags & FL_NOTARGET)
 208                 maxspd_mod = cvar("sv_spectator_speed_multiplier");
 209
 210         spd = sv_maxspeed * maxspd_mod * swampspd_mod;
 211
 212         if(self.speed != spd)
 213         {
 214                 self.speed = spd;
 215                 temps = ftos(spd);
 216                 stuffcmd(self, strcat("cl_forwardspeed ", temps, "\n"));
 217                 stuffcmd(self, strcat("cl_backspeed ", temps, "\n"));
 218                 stuffcmd(self, strcat("cl_sidespeed ", temps, "\n"));
 219                 stuffcmd(self, strcat("cl_upspeed ", temps, "\n"));
 220
 221                 temps = ftos(sv_accelerate * maxspd_mod);
 222                 stuffcmd(self, strcat("cl_movement_accelerate ", temps, "\n"));
 223         }
 224
 225         // if dead, behave differently
 226         if (self.deadflag)
 227                 return;
 228
 229         if (!self.fixangle)
 230         {
 231                 self.angles_x = 0;
 232                 self.angles_y = self.v_angle_y;
 233                 self.angles_z = 0;
 234         }
 235
 236         if(self.classname == "player")
 237         {
 238                 if(sv_doublejump)
 239                 {
 240                         self.flags = self.flags - (self.flags & FL_ONGROUND);
 241                         tracebox(self.origin + '0 0 1', self.mins, self.maxs, self.origin - '0 0 2', MOVE_NORMAL, self);
 242                         if(trace_fraction < 1 && trace_plane_normal_z > 0.7)
 243                                 self.flags = self.flags | FL_ONGROUND;
 244                 }
 245
 246                 if (self.BUTTON_JUMP)
 247                         PlayerJump ();
 248                 else
 249                         self.flags = self.flags | FL_JUMPRELEASED;
 250
 251                 if (self.waterlevel == 2)
 252                         CheckWaterJump ();
 253         }
 254
 255         if (self.flags & FL_WATERJUMP )
 256         {
 257                 self.velocity_x = self.movedir_x;
 258                 self.velocity_y = self.movedir_y;
 259                 if (time > self.teleport_time || self.waterlevel == 0)
 260                 {
 261                         self.flags = self.flags - (self.flags & FL_WATERJUMP);
 262                         self.teleport_time = 0;
 263                 }
 264         }
 265         else if (self.movetype == MOVETYPE_NOCLIP || self.movetype == MOVETYPE_FLY)
 266         {
 267                 // noclipping or flying
 268                 self.flags = self.flags - (self.flags & FL_ONGROUND);
 269
 270                 self.velocity = self.velocity * (1 - frametime * sv_friction);
 271                 makevectors(self.v_angle);
 272                 //wishvel = v_forward * self.movement_x + v_right * self.movement_y + v_up * self.movement_z;
 273                 wishvel = v_forward * self.movement_x + v_right * self.movement_y + '0 0 1' * self.movement_z;
 274                 // acceleration
 275                 wishdir = normalize(wishvel);
 276                 wishspeed = vlen(wishvel);
 277                 if (wishspeed > sv_maxspeed*maxspd_mod)
 278                         wishspeed = sv_maxspeed*maxspd_mod;
 279                 if (time >= self.teleport_time)
 280                 {
 281                         f = wishspeed - (self.velocity * wishdir);
 282                         if (f > 0)
 283                                 self.velocity = self.velocity + wishdir * min(f, sv_accelerate*maxspd_mod * frametime * wishspeed);
 284                 }
 285         }
 286         else if (self.waterlevel >= 2)
 287         {
 288                 // swimming
 289                 self.flags = self.flags - (self.flags & FL_ONGROUND);
 290
 291                 makevectors(self.v_angle);
 292                 //wishvel = v_forward * self.movement_x + v_right * self.movement_y + v_up * self.movement_z;
 293                 wishvel = v_forward * self.movement_x + v_right * self.movement_y + '0 0 1' * self.movement_z;
 294                 if (wishvel == '0 0 0')
 295                         wishvel = '0 0 -60'; // drift towards bottom
 296
 297                 wishdir = normalize(wishvel);
 298                 wishspeed = vlen(wishvel);
 299                 if (wishspeed > sv_maxspeed*maxspd_mod)
 300                         wishspeed = sv_maxspeed*maxspd_mod;
 301                 wishspeed = wishspeed * 0.7;
 302
 303                 // water friction
 304                 self.velocity = self.velocity * (1 - frametime * sv_friction);
 305
 306                 // water acceleration
 307                 f = wishspeed - (self.velocity * wishdir);
 308                 if (f > 0)
 309                         self.velocity = self.velocity + wishdir * min(f, sv_accelerate*maxspd_mod * frametime * wishspeed);
 310         }
 311         else if (time < self.ladder_time)
 312         {
 313                 // on a spawnfunc_func_ladder or swimming in spawnfunc_func_water
 314                 self.flags = self.flags - (self.flags & FL_ONGROUND);
 315
 316                 self.velocity = self.velocity * (1 - frametime * sv_friction);
 317                 makevectors(self.v_angle);
 318                 //wishvel = v_forward * self.movement_x + v_right * self.movement_y + v_up * self.movement_z;
 319                 wishvel = v_forward * self.movement_x + v_right * self.movement_y + '0 0 1' * self.movement_z;
 320                 if (self.gravity)
 321                         self.velocity_z = self.velocity_z + self.gravity * sv_gravity * frametime;
 322                 else
 323                         self.velocity_z = self.velocity_z + sv_gravity * frametime;
 324                 if (self.ladder_entity.classname == "func_water")
 325                 {
 326                         f = vlen(wishvel);
 327                         if (f > self.ladder_entity.speed)
 328                                 wishvel = wishvel * (self.ladder_entity.speed / f);
 329
 330                         self.watertype = self.ladder_entity.skin;
 331                         f = self.ladder_entity.origin_z + self.ladder_entity.maxs_z;
 332                         if ((self.origin_z + self.view_ofs_z) < f)
 333                                 self.waterlevel = 3;
 334                         else if ((self.origin_z + (self.mins_z + self.maxs_z) * 0.5) < f)
 335                                 self.waterlevel = 2;
 336                         else if ((self.origin_z + self.mins_z + 1) < f)
 337                                 self.waterlevel = 1;
 338                         else
 339                         {
 340                                 self.waterlevel = 0;
 341                                 self.watertype = CONTENT_EMPTY;
 342                         }
 343                 }
 344                 // acceleration
 345                 wishdir = normalize(wishvel);
 346                 wishspeed = vlen(wishvel);
 347                 if (wishspeed > sv_maxspeed)
 348                         wishspeed = sv_maxspeed;
 349                 if (time >= self.teleport_time)
 350                 {
 351                         f = wishspeed - (self.velocity * wishdir);
 352                         if (f > 0)
 353                                 self.velocity = self.velocity + wishdir * min(f, sv_accelerate*maxspd_mod * frametime * wishspeed);
 354                 }
 355         }
 356         else if (self.flags & FL_ONGROUND)
 357         {
 358                 // walking
 359                 makevectors(self.v_angle_y * '0 1 0');
 360                 wishvel = v_forward * self.movement_x + v_right * self.movement_y;
 361
 362                 if(!(self.lastflags & FL_ONGROUND))
 363                 {
 364                         if(cvar("speedmeter"))
 365                                 dprint(strcat("landing velocity: ", vtos(self.velocity), " (abs: ", ftos(vlen(self.velocity)), ")\n"));
 366                         if(self.lastground < time - 0.3)
 367                                 self.velocity = self.velocity * (1 - cvar("sv_friction_on_land"));
 368                         if(self.jumppadcount > 1)
 369                                 dprint(strcat(ftos(self.jumppadcount), "x jumppad combo\n"));
 370                         self.jumppadcount = 0;
 371                 }
 372
 373                 if (self.velocity_x || self.velocity_y)
 374                 if (!(self.flags & FL_JUMPRELEASED) || !self.BUTTON_JUMP)
 375                 {
 376                         v = self.velocity;
 377                         v_z = 0;
 378                         f = vlen(v);
 379                         if (f < sv_stopspeed)
 380                                 f = 1 - frametime * (sv_stopspeed / f) * sv_friction;
 381                         else
 382                                 f = 1 - frametime * sv_friction;
 383                         if (f > 0)
 384                                 self.velocity = self.velocity * f;
 385                         else
 386                                 self.velocity = '0 0 0';
 387                 }
 388                 // acceleration
 389                 wishdir = normalize(wishvel);
 390                 wishspeed = vlen(wishvel);
 391                 if (wishspeed > sv_maxspeed*maxspd_mod)
 392                         wishspeed = sv_maxspeed*maxspd_mod;
 393                 if (self.crouch)
 394                         wishspeed = wishspeed * 0.5;
 395                 if (time >= self.teleport_time)
 396                 {
 397                         f = wishspeed - (self.velocity * wishdir);
 398                         if (f > 0)
 399                                 self.velocity = self.velocity + wishdir * min(f, sv_accelerate*maxspd_mod * frametime * wishspeed);
 400                 }
 401         }
 402         else
 403         {
 404                 if(maxspd_mod < 1)
 405                 {
 406                         maxairspd = sv_maxairspeed*maxspd_mod;
 407                         airaccel = sv_airaccelerate*maxspd_mod;
 408                 }
 409                 else
 410                 {
 411                         maxairspd = sv_maxairspeed;
 412                         airaccel = sv_airaccelerate;
 413                 }
 414                 // airborn
 415                 makevectors(self.v_angle_y * '0 1 0');
 416                 wishvel = v_forward * self.movement_x + v_right * self.movement_y;
 417                 // acceleration
 418                 wishdir = normalize(wishvel);
 419                 wishspeed = vlen(wishvel);
 420                 if (wishspeed > maxairspd)
 421                         wishspeed = maxairspd;
 422                 if (self.crouch)
 423                         wishspeed = wishspeed * 0.5;
 424                 if (time >= self.teleport_time)
 425                 {
 426                         // NOTE: this does the same as the commented out old code if:
 427                         //   sv_airaccel_qw 0
 428                         //   sv_airaccel_sideways_friction 0
 429
 430                         float vel_straight;
 431                         float vel_z;
 432                         vector vel_perpend;
 433                         vel_straight = self.velocity * wishdir;
 434                         vel_z = self.velocity_z;
 435                         vel_perpend = self.velocity - vel_straight * wishdir - vel_z * '0 0 1';
 436
 437                         f = wishspeed - vel_straight;
 438                         if(f > 0)
 439                                 vel_straight = vel_straight + min(f, airaccel * frametime * wishspeed) * sv_airaccel_qw;
 440                         if(wishspeed > 0)
 441                                 vel_straight = vel_straight + min(wishspeed, airaccel * frametime * wishspeed) * (1 - sv_airaccel_qw);
 442
 443                         // anti-sideways friction to fix QW-style bunnyhopping
 444                         vel_perpend = vel_perpend * (1 - frametime * (wishspeed / maxairspd) * sv_airaccel_sideways_friction);
 445
 446                         self.velocity = vel_straight * wishdir + vel_z * '0 0 1' + vel_perpend;
 447
 448                         /*
 449                         f = wishspeed;// - (self.velocity * wishdir);
 450                         if (f > 0)
 451                                 self.velocity = self.velocity + wishdir * min(f, airaccel * frametime * wishspeed);
 452                         */
 453                 }
 454         }
 455
 456         if(self.flags & FL_ONGROUND)
 457                 self.lastground = time;
 458
 459         if(self.flags & FL_ONGROUND)
 460                 if not(self.lastflags & FL_ONGROUND)
 461                         PlayerSound(playersound_fall, CHAN_AUTO, 0);
 462
 463         self.lastflags = self.flags;
 464 };