data/qcsrc/server/cl_physics.qc

   1 float sv_accelerate;
   2 float sv_friction;
   3 float sv_maxspeed;
   4 float sv_airaccelerate;
   5 float sv_maxairspeed;
   6 float sv_stopspeed;
   7 float sv_gravity;
   8 float sv_airaccel_sideways_friction;
   9 float sv_airaccel_qw;
  10 .float ladder_time;
  11 .entity ladder_entity;
  12 .float gravity;
  13 .float swamp_slowdown;
  14 .float lastflags;
  15 .float lastground;
  16 .float wasFlying;
  17 .float spectatorspeed;
  18
  19 #define SHTEST_DELTA 10
  20 #define SHTEST_THRESHOLD 1.1
  21 .float shtest_next;
  22 .float shtest_accumulator;
  23
  24 /*
  25 =============
  26 PlayerJump
  27
  28 When you press the jump key
  29 =============
  30 */
  31 void PlayerJump (void)
  32 {
  33         float mjumpheight;
  34
  35         mjumpheight = cvar("sv_jumpvelocity");
  36         if (self.waterlevel >= WATERLEVEL_SWIMMING)
  37         {
  38                 if (self.watertype == CONTENT_WATER)
  39                         self.velocity_z = 200;
  40                 else if (self.watertype == CONTENT_SLIME)
  41                         self.velocity_z = 80;
  42                 else
  43                         self.velocity_z = 50;
  44
  45                 return;
  46         }
  47
  48
  49         if (!(self.flags & FL_ONGROUND))
  50                 return;
  51
  52         if(!sv_pogostick)
  53                 if (!(self.flags & FL_JUMPRELEASED))
  54                         return;
  55
  56         if(self.health <= g_bloodloss)
  57                 return;
  58
  59         if(g_runematch)
  60         {
  61                 if(self.runes & RUNE_SPEED)
  62                 {
  63                         if(self.runes & CURSE_SLOW)
  64                                 mjumpheight = mjumpheight * cvar("g_balance_rune_speed_combo_jumpheight");
  65                         else
  66                                 mjumpheight = mjumpheight * cvar("g_balance_rune_speed_jumpheight");
  67                 }
  68                 else if(self.runes & CURSE_SLOW)
  69                 {
  70                         mjumpheight = mjumpheight * cvar("g_balance_curse_slow_jumpheight");
  71                 }
  72         }
  73
  74         if(g_minstagib && (self.items & IT_INVINCIBLE))
  75         {
  76                 mjumpheight = mjumpheight * cvar("g_minstagib_speed_jumpheight");
  77         }
  78
  79         self.velocity_z = self.velocity_z + mjumpheight;
  80         self.oldvelocity_z = self.velocity_z;
  81
  82         self.flags &~= FL_ONGROUND;
  83         self.flags &~= FL_JUMPRELEASED;
  84
  85         if (self.crouch)
  86                 setanim(self, self.anim_duckjump, FALSE, TRUE, TRUE);
  87         else
  88                 setanim(self, self.anim_jump, FALSE, TRUE, TRUE);
  89
  90         if(g_jump_grunt)
  91                 PlayerSound(playersound_jump, CHAN_PLAYER, VOICETYPE_PLAYERSOUND);
  92 }
  93
  94 void CheckWaterJump()
  95 {
  96         local vector start, end;
  97
  98 // check for a jump-out-of-water
  99         makevectors (self.angles);
 100         start = self.origin;
 101         start_z = start_z + 8;
 102         v_forward_z = 0;
 103         normalize(v_forward);
 104         end = start + v_forward*24;
 105         traceline (start, end, TRUE, self);
 106         if (trace_fraction < 1)
 107         {       // solid at waist
 108                 start_z = start_z + self.maxs_z - 8;
 109                 end = start + v_forward*24;
 110                 self.movedir = trace_plane_normal * -50;
 111                 traceline (start, end, TRUE, self);
 112                 if (trace_fraction == 1)
 113                 {       // open at eye level
 114                         self.flags |= FL_WATERJUMP;
 115                         self.velocity_z = 225;
 116                         self.flags &~= FL_JUMPRELEASED;
 117                         self.teleport_time = time + 2;  // safety net
 118                         return;
 119                 }
 120         }
 121 };
 122
 123 float racecar_angle(float forward, float down)
 124 {
 125         float ret, angle_mult;
 126
 127         if(forward < 0)
 128         {
 129                 forward = -forward;
 130                 down = -down;
 131         }
 132
 133         ret = vectoyaw('0 1 0' * down + '1 0 0' * forward);
 134
 135         angle_mult = forward / (800 + forward);
 136
 137         if(ret > 180)
 138                 return ret * angle_mult + 360 * (1 - angle_mult);
 139         else
 140                 return ret * angle_mult;
 141 }
 142
 143 void RaceCarPhysics()
 144 {
 145         // using this move type for "big rigs"
 146         // the engine does not push the entity!
 147
 148         float accel, steer, f;
 149         vector angles_save, rigvel;
 150
 151         angles_save = self.angles;
 152         accel = bound(-1, self.movement_x / sv_maxspeed, 1);
 153         steer = bound(-1, self.movement_y / sv_maxspeed, 1);
 154
 155         if(g_bugrigs_reverse_speeding)
 156         {
 157                 if(accel < 0)
 158                 {
 159                         // back accel is DIGITAL
 160                         // to prevent speedhack
 161                         if(accel < -0.5)
 162                                 accel = -1;
 163                         else
 164                                 accel = 0;
 165                 }
 166         }
 167
 168         self.angles_x = 0;
 169         self.angles_z = 0;
 170         makevectors(self.angles); // new forward direction!
 171
 172         if(self.flags & FL_ONGROUND || g_bugrigs_air_steering)
 173         {
 174                 float myspeed, upspeed, steerfactor, accelfactor;
 175
 176                 myspeed = self.velocity * v_forward;
 177                 upspeed = self.velocity * v_up;
 178
 179                 // responsiveness factor for steering and acceleration
 180                 f = 1 / (1 + pow(max(-myspeed, myspeed) / g_bugrigs_speed_ref, g_bugrigs_speed_pow));
 181                 //MAXIMA: f(v) := 1 / (1 + (v / g_bugrigs_speed_ref) ^ g_bugrigs_speed_pow);
 182
 183                 if(myspeed < 0 && g_bugrigs_reverse_spinning)
 184                         steerfactor = -myspeed * g_bugrigs_steer;
 185                 else
 186                         steerfactor = -myspeed * f * g_bugrigs_steer;
 187
 188                 if(myspeed < 0 && g_bugrigs_reverse_speeding)
 189                         accelfactor = g_bugrigs_accel;
 190                 else
 191                         accelfactor = f * g_bugrigs_accel;
 192                 //MAXIMA: accel(v) := f(v) * g_bugrigs_accel;
 193
 194                 if(accel < 0)
 195                 {
 196                         if(myspeed > 0)
 197                         {
 198                                 myspeed = max(0, myspeed - frametime * (g_bugrigs_friction_floor - g_bugrigs_friction_brake * accel));
 199                         }
 200                         else
 201                         {
 202                                 if(!g_bugrigs_reverse_speeding)
 203                                         myspeed = min(0, myspeed + frametime * g_bugrigs_friction_floor);
 204                         }
 205                 }
 206                 else
 207                 {
 208                         if(myspeed >= 0)
 209                         {
 210                                 myspeed = max(0, myspeed - frametime * g_bugrigs_friction_floor);
 211                         }
 212                         else
 213                         {
 214                                 if(g_bugrigs_reverse_stopping)
 215                                         myspeed = 0;
 216                                 else
 217                                         myspeed = min(0, myspeed + frametime * (g_bugrigs_friction_floor + g_bugrigs_friction_brake * accel));
 218                         }
 219                 }
 220                 // terminal velocity = velocity at which 50 == accelfactor, that is, 1549 units/sec
 221                 //MAXIMA: friction(v) := g_bugrigs_friction_floor;
 222
 223                 self.angles_y += steer * frametime * steerfactor; // apply steering
 224                 makevectors(self.angles); // new forward direction!
 225
 226                 myspeed += accel * accelfactor * frametime;
 227
 228                 rigvel = myspeed * v_forward + '0 0 1' * upspeed;
 229         }
 230         else
 231         {
 232                 myspeed = vlen(self.velocity);
 233
 234                 // responsiveness factor for steering and acceleration
 235                 f = 1 / (1 + pow(max(0, myspeed / g_bugrigs_speed_ref), g_bugrigs_speed_pow));
 236                 steerfactor = -myspeed * f;
 237                 self.angles_y += steer * frametime * steerfactor; // apply steering
 238
 239                 rigvel = self.velocity;
 240                 makevectors(self.angles); // new forward direction!
 241         }
 242
 243         rigvel = rigvel * max(0, 1 - vlen(rigvel) * g_bugrigs_friction_air * frametime);
 244         //MAXIMA: airfriction(v) := v * v * g_bugrigs_friction_air;
 245         //MAXIMA: total_acceleration(v) := accel(v) - friction(v) - airfriction(v);
 246         //MAXIMA: solve(total_acceleration(v) = 0, v);
 247
 248         if(g_bugrigs_planar_movement)
 249         {
 250                 vector rigvel_xy, neworigin, up;
 251                 float mt;
 252
 253                 rigvel_z -= frametime * sv_gravity; // 4x gravity plays better
 254                 rigvel_xy = rigvel;
 255                 rigvel_xy_z = 0;
 256
 257                 if(g_bugrigs_planar_movement_car_jumping && !g_touchexplode) // touchexplode is a better way to handle collisions
 258                         mt = MOVE_NORMAL;
 259                 else
 260                         mt = MOVE_NOMONSTERS;
 261
 262                 tracebox(self.origin, self.mins, self.maxs, self.origin + '0 0 1024', mt, self);
 263                 up = trace_endpos - self.origin;
 264
 265                 // BUG RIGS: align the move to the surface instead of doing collision testing
 266                 // can we move?
 267                 tracebox(trace_endpos, self.mins, self.maxs, trace_endpos + rigvel_xy * frametime, mt, self);
 268
 269                 // align to surface
 270                 tracebox(trace_endpos, self.mins, self.maxs, trace_endpos - up + '0 0 1' * rigvel_z * frametime, mt, self);
 271
 272                 if(trace_fraction < 0.5)
 273                 {
 274                         trace_fraction = 1;
 275                         neworigin = self.origin;
 276                 }
 277                 else
 278                         neworigin = trace_endpos;
 279
 280                 if(trace_fraction < 1)
 281                 {
 282                         // now set angles_x so that the car points parallel to the surface
 283                         self.angles = vectoangles(
 284                                         '1 0 0' * v_forward_x * trace_plane_normal_z
 285                                         +
 286                                         '0 1 0' * v_forward_y * trace_plane_normal_z
 287                                         +
 288                                         '0 0 1' * -(v_forward_x * trace_plane_normal_x + v_forward_y * trace_plane_normal_y)
 289                                         );
 290                         self.flags |= FL_ONGROUND;
 291                 }
 292                 else
 293                 {
 294                         // now set angles_x so that the car points forward, but is tilted in velocity direction
 295                         self.flags &~= FL_ONGROUND;
 296                 }
 297
 298                 self.velocity = (neworigin - self.origin) * (1.0 / frametime);
 299                 self.movetype = MOVETYPE_NOCLIP;
 300         }
 301         else
 302         {
 303                 rigvel_z -= frametime * sv_gravity; // 4x gravity plays better
 304                 self.velocity = rigvel;
 305                 self.movetype = MOVETYPE_FLY;
 306         }
 307
 308         trace_fraction = 1;
 309         tracebox(self.origin, self.mins, self.maxs, self.origin - '0 0 4', MOVE_NORMAL, self);
 310         if(trace_fraction != 1)
 311         {
 312                 self.angles = vectoangles2(
 313                                 '1 0 0' * v_forward_x * trace_plane_normal_z
 314                                 +
 315                                 '0 1 0' * v_forward_y * trace_plane_normal_z
 316                                 +
 317                                 '0 0 1' * -(v_forward_x * trace_plane_normal_x + v_forward_y * trace_plane_normal_y),
 318                                 trace_plane_normal
 319                                 );
 320         }
 321         else
 322         {
 323                 vector vel_local;
 324
 325                 vel_local_x = v_forward * self.velocity;
 326                 vel_local_y = v_right * self.velocity;
 327                 vel_local_z = v_up * self.velocity;
 328
 329                 self.angles_x = racecar_angle(vel_local_x, vel_local_z);
 330                 self.angles_z = racecar_angle(-vel_local_y, vel_local_z);
 331         }
 332
 333         // smooth the angles
 334         vector vf1, vu1, smoothangles;
 335         makevectors(self.angles);
 336         f = bound(0, frametime * g_bugrigs_angle_smoothing, 1);
 337         if(f == 0)
 338                 f = 1;
 339         vf1 = v_forward * f;
 340         vu1 = v_up * f;
 341         makevectors(angles_save);
 342         vf1 = vf1 + v_forward * (1 - f);
 343         vu1 = vu1 + v_up * (1 - f);
 344         smoothangles = vectoangles2(vf1, vu1);
 345         self.angles_x = -smoothangles_x;
 346         self.angles_z =  smoothangles_z;
 347 }
 348
 349 .vector movement_old;
 350 .float buttons_old;
 351 .vector v_angle_old;
 352
 353 void Nixnex_GiveCurrentWeapon();
 354 void SV_PlayerPhysics()
 355 {
 356         local vector wishvel, wishdir, v;
 357         local float wishspeed, f, maxspd_mod, spd, maxairspd, airaccel, swampspd_mod, shtest_score, buttons;
 358         string temps;
 359
 360         buttons = self.BUTTON_ATCK + 2 * self.BUTTON_JUMP + 4 * self.BUTTON_ATCK2 + 8 * self.BUTTON_ZOOM + 16 * self.BUTTON_CROUCH + 32 * self.BUTTON_HOOK + 64 * self.BUTTON_USE;
 361         if(!sv_maxidle_spectatorsareidle || self.movetype == MOVETYPE_WALK)
 362         {
 363                 if(buttons != self.buttons_old || self.movement != self.movement_old || self.v_angle != self.v_angle_old)
 364                         self.parm_idlesince = time;
 365         }
 366         self.buttons_old = buttons;
 367         self.movement_old = self.movement;
 368         self.v_angle_old = self.v_angle;
 369
 370         if(time > self.shtest_next)
 371         {
 372                 if(self.shtest_next > 0)
 373                 {
 374                         // self.shtest_accumulator:
 375                         //   started at time - SHTEST_DELTA
 376                         //   should be at SHTEST_DELTA
 377                         shtest_score = self.shtest_accumulator / (SHTEST_DELTA + time - self.shtest_next);
 378                         if(shtest_score > SHTEST_THRESHOLD)
 379                                 print("TIME PARADOX: shtest for ", self.netname, " said ", ftos(shtest_score), "\n");
 380                         else if(cvar("developer_shtest"))
 381                                 dprint("okay: shtest for ", self.netname, " said ", ftos(shtest_score), "\n");
 382                 }
 383                 self.shtest_next = time + SHTEST_DELTA;
 384                 self.shtest_accumulator = 0;
 385         }
 386         self.shtest_accumulator += frametime;
 387
 388         if (clienttype(self) == CLIENTTYPE_BOT)
 389                 bot_think();
 390
 391         self.modelflags &~= MF_ROCKET;
 392
 393         if (self.movetype == MOVETYPE_NONE && self.disableclientprediction != 2)
 394                 return;
 395
 396         if (self.punchangle != '0 0 0')
 397         {
 398                 f = vlen(self.punchangle) - 10 * frametime;
 399                 if (f > 0)
 400                         self.punchangle = normalize(self.punchangle) * f;
 401                 else
 402                         self.punchangle = '0 0 0';
 403         }
 404
 405         if (self.punchvector != '0 0 0')
 406         {
 407                 f = vlen(self.punchvector) - 30 * frametime;
 408                 if (f > 0)
 409                         self.punchvector = normalize(self.punchvector) * f;
 410                 else
 411                         self.punchvector = '0 0 0';
 412         }
 413
 414         maxspd_mod = 1;
 415
 416         if(g_runematch)
 417         {
 418                 if(self.runes & RUNE_SPEED)
 419                 {
 420                         if(self.runes & CURSE_SLOW)
 421                                 maxspd_mod = maxspd_mod * cvar("g_balance_rune_speed_combo_moverate");
 422                         else
 423                                 maxspd_mod = maxspd_mod * cvar("g_balance_rune_speed_moverate");
 424                 }
 425                 else if(self.runes & CURSE_SLOW)
 426                 {
 427                         maxspd_mod = maxspd_mod * cvar("g_balance_curse_slow_moverate");
 428                 }
 429         }
 430
 431         if(g_minstagib && (self.items & IT_INVINCIBLE))
 432         {
 433                 maxspd_mod = cvar("g_minstagib_speed_moverate");
 434         }
 435
 436         swampspd_mod = 1;
 437         if(self.in_swamp) {
 438                 swampspd_mod = self.swamp_slowdown; //cvar("g_balance_swamp_moverate");
 439         }
 440
 441         if(self.flags & FL_NOTARGET)
 442         {
 443                 maxspd_mod = cvar("sv_spectator_speed_multiplier");
 444                 if(!self.spectatorspeed)
 445                         self.spectatorspeed = maxspd_mod;
 446                 if(self.impulse && self.impulse <= 19)
 447                 {
 448                         if(self.lastflags & FL_NOTARGET)
 449                         {
 450                                 if(self.impulse == 10 || self.impulse == 15 || self.impulse == 18)
 451                                         self.spectatorspeed = bound(1, self.spectatorspeed + 0.5, 5);
 452                                 else if(self.impulse == 11)
 453                                         self.spectatorspeed = maxspd_mod;
 454                                 else if(self.impulse == 12 || self.impulse == 16  || self.impulse == 19)
 455                                         self.spectatorspeed = bound(1, self.spectatorspeed - 0.5, 5);
 456                                 else if(self.impulse >= 1 && self.impulse <= 9)
 457                                         self.spectatorspeed = 1 + 0.5 * (self.impulse - 1);
 458                         } // otherwise just clear
 459                         self.impulse = 0;
 460                 }
 461                 maxspd_mod = self.spectatorspeed;
 462         }
 463
 464         spd = sv_maxspeed * maxspd_mod * swampspd_mod;
 465
 466         if(self.speed != spd)
 467         {
 468                 self.speed = spd;
 469                 temps = ftos(spd);
 470                 stuffcmd(self, strcat("cl_forwardspeed ", temps, "\n"));
 471                 stuffcmd(self, strcat("cl_backspeed ", temps, "\n"));
 472                 stuffcmd(self, strcat("cl_sidespeed ", temps, "\n"));
 473                 stuffcmd(self, strcat("cl_upspeed ", temps, "\n"));
 474
 475                 temps = ftos(sv_accelerate * maxspd_mod);
 476                 stuffcmd(self, strcat("cl_movement_accelerate ", temps, "\n"));
 477         }
 478
 479         // if dead, behave differently
 480         if (self.deadflag)
 481                 return;
 482
 483         if (!self.fixangle && !g_bugrigs)
 484         {
 485                 self.angles_x = 0;
 486                 self.angles_y = self.v_angle_y;
 487                 self.angles_z = 0;
 488         }
 489
 490         if(self.flags & FL_ONGROUND)
 491         if(self.wasFlying)
 492         {
 493                 self.wasFlying = 0;
 494
 495                 if(self.waterlevel < WATERLEVEL_SWIMMING)
 496                 if(time >= self.ladder_time)
 497                 if not(self.hook)
 498                 {
 499                         self.nextstep = time + 0.3 + random() * 0.1;
 500                         trace_dphitq3surfaceflags = 0;
 501                         tracebox(self.origin, self.mins, self.maxs, self.origin - '0 0 1', MOVE_NOMONSTERS, self);
 502                         if not(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOSTEPS)
 503                         {
 504                                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_METALSTEPS)
 505                                         GlobalSound(globalsound_metalfall, CHAN_PLAYER, VOICETYPE_PLAYERSOUND);
 506                                 else
 507                                         GlobalSound(globalsound_fall, CHAN_PLAYER, VOICETYPE_PLAYERSOUND);
 508                         }
 509                 }
 510         }
 511
 512         if(IsFlying(self))
 513                 self.wasFlying = 1;
 514
 515         if(self.classname == "player")
 516         {
 517                 if(sv_doublejump)
 518                 {
 519                         self.flags &~= FL_ONGROUND;
 520                         tracebox(self.origin + '0 0 1', self.mins, self.maxs, self.origin - '0 0 2', MOVE_NORMAL, self);
 521                         if(trace_fraction < 1 && trace_plane_normal_z > 0.7)
 522                                 self.flags |= FL_ONGROUND;
 523                 }
 524
 525                 if (self.BUTTON_JUMP)
 526                         PlayerJump ();
 527                 else
 528                         self.flags |= FL_JUMPRELEASED;
 529
 530                 if (self.waterlevel == WATERLEVEL_SWIMMING)
 531                         CheckWaterJump ();
 532         }
 533
 534         if (self.flags & FL_WATERJUMP )
 535         {
 536                 self.velocity_x = self.movedir_x;
 537                 self.velocity_y = self.movedir_y;
 538                 if (time > self.teleport_time || self.waterlevel == WATERLEVEL_NONE)
 539                 {
 540                         self.flags &~= FL_WATERJUMP;
 541                         self.teleport_time = 0;
 542                 }
 543         }
 544         else if (g_bugrigs && self.classname == "player")
 545         {
 546                 RaceCarPhysics();
 547         }
 548         else if (self.movetype == MOVETYPE_NOCLIP || self.movetype == MOVETYPE_FLY)
 549         {
 550                 // noclipping or flying
 551                 self.flags &~= FL_ONGROUND;
 552
 553                 self.velocity = self.velocity * (1 - frametime * sv_friction);
 554                 makevectors(self.v_angle);
 555                 //wishvel = v_forward * self.movement_x + v_right * self.movement_y + v_up * self.movement_z;
 556                 wishvel = v_forward * self.movement_x + v_right * self.movement_y + '0 0 1' * self.movement_z;
 557                 // acceleration
 558                 wishdir = normalize(wishvel);
 559                 wishspeed = vlen(wishvel);
 560                 if (wishspeed > sv_maxspeed*maxspd_mod)
 561                         wishspeed = sv_maxspeed*maxspd_mod;
 562                 if (time >= self.teleport_time)
 563                 {
 564                         f = wishspeed - (self.velocity * wishdir);
 565                         if (f > 0)
 566                                 self.velocity = self.velocity + wishdir * min(f, sv_accelerate*maxspd_mod * frametime * wishspeed);
 567                 }
 568         }
 569         else if (self.waterlevel >= WATERLEVEL_SWIMMING)
 570         {
 571                 // swimming
 572                 self.flags &~= FL_ONGROUND;
 573
 574                 makevectors(self.v_angle);
 575                 //wishvel = v_forward * self.movement_x + v_right * self.movement_y + v_up * self.movement_z;
 576                 wishvel = v_forward * self.movement_x + v_right * self.movement_y + '0 0 1' * self.movement_z;
 577                 if (wishvel == '0 0 0')
 578                         wishvel = '0 0 -60'; // drift towards bottom
 579
 580                 wishdir = normalize(wishvel);
 581                 wishspeed = vlen(wishvel);
 582                 if (wishspeed > sv_maxspeed*maxspd_mod)
 583                         wishspeed = sv_maxspeed*maxspd_mod;
 584                 wishspeed = wishspeed * 0.7;
 585
 586                 // water friction
 587                 self.velocity = self.velocity * (1 - frametime * sv_friction);
 588
 589                 // water acceleration
 590                 f = wishspeed - (self.velocity * wishdir);
 591                 if (f > 0)
 592                         self.velocity = self.velocity + wishdir * min(f, sv_accelerate*maxspd_mod * frametime * wishspeed);
 593         }
 594         else if (time < self.ladder_time)
 595         {
 596                 // on a spawnfunc_func_ladder or swimming in spawnfunc_func_water
 597                 self.flags &~= FL_ONGROUND;
 598
 599                 self.velocity = self.velocity * (1 - frametime * sv_friction);
 600                 makevectors(self.v_angle);
 601                 //wishvel = v_forward * self.movement_x + v_right * self.movement_y + v_up * self.movement_z;
 602                 wishvel = v_forward * self.movement_x + v_right * self.movement_y + '0 0 1' * self.movement_z;
 603                 if (self.gravity)
 604                         self.velocity_z = self.velocity_z + self.gravity * sv_gravity * frametime;
 605                 else
 606                         self.velocity_z = self.velocity_z + sv_gravity * frametime;
 607                 if (self.ladder_entity.classname == "func_water")
 608                 {
 609                         f = vlen(wishvel);
 610                         if (f > self.ladder_entity.speed)
 611                                 wishvel = wishvel * (self.ladder_entity.speed / f);
 612
 613                         self.watertype = self.ladder_entity.skin;
 614                         f = self.ladder_entity.origin_z + self.ladder_entity.maxs_z;
 615                         if ((self.origin_z + self.view_ofs_z) < f)
 616                                 self.waterlevel = WATERLEVEL_SUBMERGED;
 617                         else if ((self.origin_z + (self.mins_z + self.maxs_z) * 0.5) < f)
 618                                 self.waterlevel = WATERLEVEL_SWIMMING;
 619                         else if ((self.origin_z + self.mins_z + 1) < f)
 620                                 self.waterlevel = WATERLEVEL_WETFEET;
 621                         else
 622                         {
 623                                 self.waterlevel = WATERLEVEL_NONE;
 624                                 self.watertype = CONTENT_EMPTY;
 625                         }
 626                 }
 627                 // acceleration
 628                 wishdir = normalize(wishvel);
 629                 wishspeed = vlen(wishvel);
 630                 if (wishspeed > sv_maxspeed)
 631                         wishspeed = sv_maxspeed;
 632                 if (time >= self.teleport_time)
 633                 {
 634                         f = wishspeed - (self.velocity * wishdir);
 635                         if (f > 0)
 636                                 self.velocity = self.velocity + wishdir * min(f, sv_accelerate*maxspd_mod * frametime * wishspeed);
 637                 }
 638         }
 639         else if (g_jetpack && self.BUTTON_HOOK && (!cvar("g_jetpack_ammo") || self.ammo_cells >= 0.01))
 640         {
 641                 //makevectors(self.v_angle_y * '0 1 0');
 642                 makevectors(self.v_angle);
 643                 wishvel = v_forward * self.movement_x + v_right * self.movement_y;
 644                 // add remaining speed as Z component
 645                 maxairspd = sv_maxairspeed*max(1, maxspd_mod);
 646                 // fix speedhacks :P
 647                 wishvel = normalize(wishvel) * min(vlen(wishvel) / maxairspd, 1);
 648                 // add the unused velocity as up component
 649                 wishvel_z += sqrt(max(0, 1 - wishvel * wishvel));
 650                 // it is now normalized, so...
 651                 wishvel_x *= cvar("g_jetpack_acceleration_side");
 652                 wishvel_y *= cvar("g_jetpack_acceleration_side");
 653                 wishvel_z *= cvar("g_jetpack_acceleration_up");
 654                 wishvel_z += cvar("g_jetpack_antigravity") * sv_gravity;
 655
 656                 float fxy, fz;
 657                 fxy = bound(0, 1 - (self.velocity * normalize(wishvel_x * '1 0 0' + wishvel_y * '0 1 0')) / cvar("g_jetpack_maxspeed_side"), 1);
 658                 if(wishvel_z - sv_gravity > 0)
 659                         fz = bound(0, 1 - self.velocity_z / cvar("g_jetpack_maxspeed_up"), 1);
 660                 else
 661                         fz = bound(0, 1 + self.velocity_z / cvar("g_jetpack_maxspeed_up"), 1);
 662
 663                 float fvel;
 664                 fvel = vlen(wishvel);
 665                 wishvel_x *= fxy;
 666                 wishvel_y *= fxy;
 667                 wishvel_z = (wishvel_z - sv_gravity) * fz + sv_gravity;
 668                 fvel = min(1, vlen(wishvel) / fvel);
 669
 670                 if(cvar("g_jetpack_ammo"))
 671                 {
 672                         if(self.ammo_cells < 0.01)
 673                                 f = 0;
 674                         else
 675                                 f = min(1, self.ammo_cells / (cvar("g_jetpack_ammo") * frametime * fvel));
 676                 }
 677                 else
 678                         f = 1;
 679
 680                 if (f > 0 && wishvel != '0 0 0')
 681                 {
 682                         self.velocity = self.velocity + wishvel * f * frametime;
 683                         float c;
 684                         c = self.ammo_cells;
 685                         self.ammo_cells -= cvar("g_jetpack_ammo") * frametime * fvel * f;
 686                         if(floor(c / 5) != floor(self.ammo_cells / 5))
 687                                 sprint(self, strcat("jetpack: less than ", ftos(floor(c)), " cells left\n"));
 688                         else if(self.ammo_cells < 0.01 && cvar("g_jetpack_ammo"))
 689                                 sprint(self, "jetpack: out of fuel\n");
 690                         self.flags &~= FL_ONGROUND;
 691                         self.modelflags |= MF_ROCKET;
 692                 }
 693         }
 694         else if (self.flags & FL_ONGROUND)
 695         {
 696                 // walking
 697                 makevectors(self.v_angle_y * '0 1 0');
 698                 wishvel = v_forward * self.movement_x + v_right * self.movement_y;
 699
 700                 if(!(self.lastflags & FL_ONGROUND))
 701                 {
 702                         if(cvar("speedmeter"))
 703                                 dprint(strcat("landing velocity: ", vtos(self.velocity), " (abs: ", ftos(vlen(self.velocity)), ")\n"));
 704                         if(self.lastground < time - 0.3)
 705                                 self.velocity = self.velocity * (1 - cvar("sv_friction_on_land"));
 706                         if(self.jumppadcount > 1)
 707                                 dprint(strcat(ftos(self.jumppadcount), "x jumppad combo\n"));
 708                         self.jumppadcount = 0;
 709                 }
 710
 711                 if (self.velocity_x || self.velocity_y)
 712                 if (!(self.flags & FL_JUMPRELEASED) || !self.BUTTON_JUMP)
 713                 {
 714                         v = self.velocity;
 715                         v_z = 0;
 716                         f = vlen(v);
 717                         if (f < sv_stopspeed)
 718                                 f = 1 - frametime * (sv_stopspeed / f) * sv_friction;
 719                         else
 720                                 f = 1 - frametime * sv_friction;
 721                         if (f > 0)
 722                                 self.velocity = self.velocity * f;
 723                         else
 724                                 self.velocity = '0 0 0';
 725                 }
 726                 // acceleration
 727                 wishdir = normalize(wishvel);
 728                 wishspeed = vlen(wishvel);
 729                 if (wishspeed > sv_maxspeed*maxspd_mod)
 730                         wishspeed = sv_maxspeed*maxspd_mod;
 731                 if (self.crouch)
 732                         wishspeed = wishspeed * 0.5;
 733                 if (time >= self.teleport_time)
 734                 {
 735                         f = wishspeed - (self.velocity * wishdir);
 736                         if (f > 0)
 737                                 self.velocity = self.velocity + wishdir * min(f, sv_accelerate*maxspd_mod * frametime * wishspeed);
 738                 }
 739         }
 740         else
 741         {
 742                 if(maxspd_mod < 1)
 743                 {
 744                         maxairspd = sv_maxairspeed*maxspd_mod;
 745                         airaccel = sv_airaccelerate*maxspd_mod;
 746                 }
 747                 else
 748                 {
 749                         maxairspd = sv_maxairspeed;
 750                         airaccel = sv_airaccelerate;
 751                 }
 752                 // airborn
 753                 makevectors(self.v_angle_y * '0 1 0');
 754                 wishvel = v_forward * self.movement_x + v_right * self.movement_y;
 755                 // acceleration
 756                 wishdir = normalize(wishvel);
 757                 wishspeed = vlen(wishvel);
 758                 if (wishspeed > maxairspd)
 759                         wishspeed = maxairspd;
 760                 if (self.crouch)
 761                         wishspeed = wishspeed * 0.5;
 762                 if (time >= self.teleport_time)
 763                 {
 764                         // NOTE: this does the same as the commented out old code if:
 765                         //   sv_airaccel_qw 0
 766                         //   sv_airaccel_sideways_friction 0
 767
 768                         float vel_straight;
 769                         float vel_z;
 770                         vector vel_perpend;
 771                         vel_straight = self.velocity * wishdir;
 772                         vel_z = self.velocity_z;
 773                         vel_perpend = self.velocity - vel_straight * wishdir - vel_z * '0 0 1';
 774
 775                         f = wishspeed - vel_straight;
 776                         if(f > 0)
 777                                 vel_straight = vel_straight + min(f, airaccel * frametime * wishspeed) * sv_airaccel_qw;
 778                         if(wishspeed > 0)
 779                                 vel_straight = vel_straight + min(wishspeed, airaccel * frametime * wishspeed) * (1 - sv_airaccel_qw);
 780
 781                         // anti-sideways friction to fix QW-style bunnyhopping
 782                         vel_perpend = vel_perpend * (1 - frametime * (wishspeed / maxairspd) * sv_airaccel_sideways_friction);
 783
 784                         self.velocity = vel_straight * wishdir + vel_z * '0 0 1' + vel_perpend;
 785
 786                         /*
 787                         f = wishspeed;// - (self.velocity * wishdir);
 788                         if (f > 0)
 789                                 self.velocity = self.velocity + wishdir * min(f, airaccel * frametime * wishspeed);
 790                         */
 791                 }
 792         }
 793
 794         if(self.flags & FL_ONGROUND)
 795                 self.lastground = time;
 796
 797         self.lastflags = self.flags;
 798 };