data/qcsrc/server/cl_physics.qc

   1 float sv_accelerate;
   2 float sv_friction;
   3 float sv_maxspeed;
   4 float sv_airaccelerate;
   5 float sv_maxairspeed;
   6 float sv_stopspeed;
   7 float sv_gravity;
   8 float sv_airaccel_sideways_friction;
   9 float sv_airaccel_qw;
  10 .float ladder_time;
  11 .entity ladder_entity;
  12 .float gravity;
  13 .float swamp_slowdown;
  14 .float lastflags;
  15 .float lastground;
  16
  17 #define SHTEST_DELTA 15
  18 .float shtest_next;
  19 .float shtest_accumulator;
  20
  21 /*
  22 =============
  23 PlayerJump
  24
  25 When you press the jump key
  26 =============
  27 */
  28 void PlayerJump (void)
  29 {
  30         float mjumpheight;
  31
  32         mjumpheight = cvar("sv_jumpvelocity");
  33         if (self.waterlevel >= 2)
  34         {
  35                 if (self.watertype == CONTENT_WATER)
  36                         self.velocity_z = 200;
  37                 else if (self.watertype == CONTENT_SLIME)
  38                         self.velocity_z = 80;
  39                 else
  40                         self.velocity_z = 50;
  41
  42                 return;
  43         }
  44
  45
  46         if (!(self.flags & FL_ONGROUND))
  47                 return;
  48
  49         if (!(self.flags & FL_JUMPRELEASED))
  50                 return;
  51
  52         if(g_runematch)
  53         {
  54                 if(self.runes & RUNE_SPEED)
  55                 {
  56                         if(self.runes & CURSE_SLOW)
  57                                 mjumpheight = mjumpheight * cvar("g_balance_rune_speed_combo_jumpheight");
  58                         else
  59                                 mjumpheight = mjumpheight * cvar("g_balance_rune_speed_jumpheight");
  60                 }
  61                 else if(self.runes & CURSE_SLOW)
  62                 {
  63                         mjumpheight = mjumpheight * cvar("g_balance_curse_slow_jumpheight");
  64                 }
  65         }
  66
  67         if(g_minstagib && (self.items & IT_INVINCIBLE))
  68         {
  69                 mjumpheight = mjumpheight * cvar("g_minstagib_speed_jumpheight");
  70         }
  71
  72         self.velocity_z = self.velocity_z + mjumpheight;
  73         self.oldvelocity_z = self.velocity_z;
  74
  75         self.flags = self.flags - FL_ONGROUND;
  76         self.flags = self.flags - FL_JUMPRELEASED;
  77
  78         if (self.crouch)
  79                 player_setanim(self.anim_duckjump, FALSE, TRUE, TRUE);
  80         else
  81                 player_setanim(self.anim_jump, FALSE, TRUE, TRUE);
  82 }
  83
  84 void() CheckWaterJump =
  85 {
  86         local vector start, end;
  87
  88 // check for a jump-out-of-water
  89         makevectors (self.angles);
  90         start = self.origin;
  91         start_z = start_z + 8;
  92         v_forward_z = 0;
  93         normalize(v_forward);
  94         end = start + v_forward*24;
  95         traceline (start, end, TRUE, self);
  96         if (trace_fraction < 1)
  97         {       // solid at waist
  98                 start_z = start_z + self.maxs_z - 8;
  99                 end = start + v_forward*24;
 100                 self.movedir = trace_plane_normal * -50;
 101                 traceline (start, end, TRUE, self);
 102                 if (trace_fraction == 1)
 103                 {       // open at eye level
 104                         self.flags = self.flags | FL_WATERJUMP;
 105                         self.velocity_z = 225;
 106                         self.flags = self.flags - (self.flags & FL_JUMPRELEASED);
 107                         self.teleport_time = time + 2;  // safety net
 108                         return;
 109                 }
 110         }
 111 };
 112
 113 .vector movement_old;
 114 .float buttons_old;
 115
 116 void Nixnex_GiveCurrentWeapon();
 117 void SV_PlayerPhysics()
 118 {
 119         local vector wishvel, wishdir, v;
 120         local float wishspeed, f, maxspd_mod, spd, maxairspd, airaccel, swampspd_mod, shtest_score, buttons;
 121         string temps;
 122
 123         buttons = self.BUTTON_ATCK + 2 * self.BUTTON_JUMP + 4 * self.BUTTON_ATCK2 + 8 * self.BUTTON_ZOOM + 16 * self.BUTTON_CROUCH + 32 * self.BUTTON_HOOK + 64 * self.BUTTON_USE;
 124         if(buttons != self.buttons_old)
 125                 self.parm_idlesince = time;
 126         self.buttons_old = buttons;
 127
 128         if(self.movement != self.movement_old)
 129                 self.parm_idlesince = time;
 130         self.movement_old = self.movement;
 131
 132         if(time > self.shtest_next)
 133         {
 134                 if(self.shtest_next > 0)
 135                 {
 136                         // self.shtest_accumulator:
 137                         //   started at time - SHTEST_DELTA
 138                         //   should be at SHTEST_DELTA
 139                         shtest_score = self.shtest_accumulator / SHTEST_DELTA;
 140                         if(shtest_score > 1.2)
 141                                 dprint("TIME PARADOX: shtest for ", self.netname, " said ", ftos(shtest_score), "\n");
 142                         else if(cvar("developer_shtest"))
 143                                 dprint("okay: shtest for ", self.netname, " said ", ftos(shtest_score), "\n");
 144                 }
 145                 self.shtest_next = time + SHTEST_DELTA;
 146                 self.shtest_accumulator = 0;
 147         }
 148         self.shtest_accumulator += frametime;
 149
 150         if (clienttype(self) == CLIENTTYPE_BOT)
 151                 bot_think();
 152
 153         if (self.movetype == MOVETYPE_NONE)
 154                 return;
 155
 156         if (self.punchangle != '0 0 0')
 157         {
 158                 f = vlen(self.punchangle) - 10 * frametime;
 159                 if (f > 0)
 160                         self.punchangle = normalize(self.punchangle) * f;
 161                 else
 162                         self.punchangle = '0 0 0';
 163         }
 164
 165         if (self.punchvector != '0 0 0')
 166         {
 167                 f = vlen(self.punchvector) - 30 * frametime;
 168                 if (f > 0)
 169                         self.punchvector = normalize(self.punchvector) * f;
 170                 else
 171                         self.punchvector = '0 0 0';
 172         }
 173
 174         maxspd_mod = 1;
 175
 176         if(g_runematch)
 177         {
 178                 if(self.runes & RUNE_SPEED)
 179                 {
 180                         if(self.runes & CURSE_SLOW)
 181                                 maxspd_mod = maxspd_mod * cvar("g_balance_rune_speed_combo_moverate");
 182                         else
 183                                 maxspd_mod = maxspd_mod * cvar("g_balance_rune_speed_moverate");
 184                 }
 185                 else if(self.runes & CURSE_SLOW)
 186                 {
 187                         maxspd_mod = maxspd_mod * cvar("g_balance_curse_slow_moverate");
 188                 }
 189         }
 190
 191         if(g_minstagib && (self.items & IT_INVINCIBLE))
 192         {
 193                 maxspd_mod = cvar("g_minstagib_speed_moverate");
 194         }
 195
 196         swampspd_mod = 1;
 197         if(self.in_swamp) {
 198                 swampspd_mod = self.swamp_slowdown; //cvar("g_balance_swamp_moverate");
 199         }
 200
 201         if(self.flags & FL_NOTARGET)
 202                 maxspd_mod = cvar("sv_spectator_speed_multiplier");
 203
 204         spd = sv_maxspeed * maxspd_mod * swampspd_mod;
 205
 206         if(self.speed != spd)
 207         {
 208                 self.speed = spd;
 209                 temps = ftos(spd);
 210                 stuffcmd(self, strcat("cl_forwardspeed ", temps, "\n"));
 211                 stuffcmd(self, strcat("cl_backspeed ", temps, "\n"));
 212                 stuffcmd(self, strcat("cl_sidespeed ", temps, "\n"));
 213                 stuffcmd(self, strcat("cl_upspeed ", temps, "\n"));
 214
 215                 temps = ftos(sv_accelerate * maxspd_mod);
 216                 stuffcmd(self, strcat("cl_movement_accelerate ", temps, "\n"));
 217         }
 218
 219         // if dead, behave differently
 220         if (self.deadflag)
 221                 return;
 222
 223         if (!self.fixangle)
 224         {
 225                 self.angles_x = 0;
 226                 self.angles_y = self.v_angle_y;
 227                 self.angles_z = 0;
 228         }
 229
 230         if(self.classname == "player")
 231         {
 232                 if (self.button2)
 233                         PlayerJump ();
 234                 else
 235                         self.flags = self.flags | FL_JUMPRELEASED;
 236
 237                 if (self.waterlevel == 2)
 238                         CheckWaterJump ();
 239         }
 240
 241         if (self.flags & FL_WATERJUMP )
 242         {
 243                 self.velocity_x = self.movedir_x;
 244                 self.velocity_y = self.movedir_y;
 245                 if (time > self.teleport_time || self.waterlevel == 0)
 246                 {
 247                         self.flags = self.flags - (self.flags & FL_WATERJUMP);
 248                         self.teleport_time = 0;
 249                 }
 250         }
 251         else if (self.movetype == MOVETYPE_NOCLIP || self.movetype == MOVETYPE_FLY)
 252         {
 253                 // noclipping or flying
 254                 self.flags = self.flags - (self.flags & FL_ONGROUND);
 255
 256                 self.velocity = self.velocity * (1 - frametime * sv_friction);
 257                 makevectors(self.v_angle);
 258                 //wishvel = v_forward * self.movement_x + v_right * self.movement_y + v_up * self.movement_z;
 259                 wishvel = v_forward * self.movement_x + v_right * self.movement_y + '0 0 1' * self.movement_z;
 260                 // acceleration
 261                 wishdir = normalize(wishvel);
 262                 wishspeed = vlen(wishvel);
 263                 if (wishspeed > sv_maxspeed*maxspd_mod)
 264                         wishspeed = sv_maxspeed*maxspd_mod;
 265                 if (time >= self.teleport_time)
 266                 {
 267                         f = wishspeed - (self.velocity * wishdir);
 268                         if (f > 0)
 269                                 self.velocity = self.velocity + wishdir * min(f, sv_accelerate*maxspd_mod * frametime * wishspeed);
 270                 }
 271         }
 272         else if (self.waterlevel >= 2)
 273         {
 274                 // swimming
 275                 self.flags = self.flags - (self.flags & FL_ONGROUND);
 276
 277                 makevectors(self.v_angle);
 278                 //wishvel = v_forward * self.movement_x + v_right * self.movement_y + v_up * self.movement_z;
 279                 wishvel = v_forward * self.movement_x + v_right * self.movement_y + '0 0 1' * self.movement_z;
 280                 if (wishvel == '0 0 0')
 281                         wishvel = '0 0 -60'; // drift towards bottom
 282
 283                 wishdir = normalize(wishvel);
 284                 wishspeed = vlen(wishvel);
 285                 if (wishspeed > sv_maxspeed*maxspd_mod)
 286                         wishspeed = sv_maxspeed*maxspd_mod;
 287                 wishspeed = wishspeed * 0.7;
 288
 289                 // water friction
 290                 self.velocity = self.velocity * (1 - frametime * sv_friction);
 291
 292                 // water acceleration
 293                 f = wishspeed - (self.velocity * wishdir);
 294                 if (f > 0)
 295                         self.velocity = self.velocity + wishdir * min(f, sv_accelerate*maxspd_mod * frametime * wishspeed);
 296         }
 297         else if (time < self.ladder_time)
 298         {
 299                 // on a spawnfunc_func_ladder or swimming in spawnfunc_func_water
 300                 self.flags = self.flags - (self.flags & FL_ONGROUND);
 301
 302                 self.velocity = self.velocity * (1 - frametime * sv_friction);
 303                 makevectors(self.v_angle);
 304                 //wishvel = v_forward * self.movement_x + v_right * self.movement_y + v_up * self.movement_z;
 305                 wishvel = v_forward * self.movement_x + v_right * self.movement_y + '0 0 1' * self.movement_z;
 306                 if (self.gravity)
 307                         self.velocity_z = self.velocity_z + self.gravity * sv_gravity * frametime;
 308                 else
 309                         self.velocity_z = self.velocity_z + sv_gravity * frametime;
 310                 if (self.ladder_entity.classname == "func_water")
 311                 {
 312                         f = vlen(wishvel);
 313                         if (f > self.ladder_entity.speed)
 314                                 wishvel = wishvel * (self.ladder_entity.speed / f);
 315
 316                         self.watertype = self.ladder_entity.skin;
 317                         f = self.ladder_entity.origin_z + self.ladder_entity.maxs_z;
 318                         if ((self.origin_z + self.view_ofs_z) < f)
 319                                 self.waterlevel = 3;
 320                         else if ((self.origin_z + (self.mins_z + self.maxs_z) * 0.5) < f)
 321                                 self.waterlevel = 2;
 322                         else if ((self.origin_z + self.mins_z + 1) < f)
 323                                 self.waterlevel = 1;
 324                         else
 325                         {
 326                                 self.waterlevel = 0;
 327                                 self.watertype = CONTENT_EMPTY;
 328                         }
 329                 }
 330                 // acceleration
 331                 wishdir = normalize(wishvel);
 332                 wishspeed = vlen(wishvel);
 333                 if (wishspeed > sv_maxspeed)
 334                         wishspeed = sv_maxspeed;
 335                 if (time >= self.teleport_time)
 336                 {
 337                         f = wishspeed - (self.velocity * wishdir);
 338                         if (f > 0)
 339                                 self.velocity = self.velocity + wishdir * min(f, sv_accelerate*maxspd_mod * frametime * wishspeed);
 340                 }
 341         }
 342         else if (self.flags & FL_ONGROUND)
 343         {
 344                 // walking
 345                 makevectors(self.v_angle_y * '0 1 0');
 346                 wishvel = v_forward * self.movement_x + v_right * self.movement_y;
 347
 348                 if(!(self.lastflags & FL_ONGROUND))
 349                 {
 350                         if(cvar("speedmeter"))
 351                                 dprint(strcat("landing velocity: ", vtos(self.velocity), " (abs: ", ftos(vlen(self.velocity)), ")\n"));
 352                         if(self.lastground < time - 0.3)
 353                                 self.velocity = self.velocity * (1 - cvar("sv_friction_on_land"));
 354                         if(self.jumppadcount > 1)
 355                                 dprint(strcat(ftos(self.jumppadcount), "x jumppad combo\n"));
 356                         self.jumppadcount = 0;
 357                 }
 358
 359                 if (self.velocity_x || self.velocity_y)
 360                 if (!(self.flags & FL_JUMPRELEASED) || !self.button2)
 361                 {
 362                         v = self.velocity;
 363                         v_z = 0;
 364                         f = vlen(v);
 365                         if (f < sv_stopspeed)
 366                                 f = 1 - frametime * (sv_stopspeed / f) * sv_friction;
 367                         else
 368                                 f = 1 - frametime * sv_friction;
 369                         if (f > 0)
 370                                 self.velocity = self.velocity * f;
 371                         else
 372                                 self.velocity = '0 0 0';
 373                 }
 374                 // acceleration
 375                 wishdir = normalize(wishvel);
 376                 wishspeed = vlen(wishvel);
 377                 if (wishspeed > sv_maxspeed*maxspd_mod)
 378                         wishspeed = sv_maxspeed*maxspd_mod;
 379                 if (self.crouch)
 380                         wishspeed = wishspeed * 0.5;
 381                 if (time >= self.teleport_time)
 382                 {
 383                         f = wishspeed - (self.velocity * wishdir);
 384                         if (f > 0)
 385                                 self.velocity = self.velocity + wishdir * min(f, sv_accelerate*maxspd_mod * frametime * wishspeed);
 386                 }
 387         }
 388         else
 389         {
 390                 if(maxspd_mod < 1)
 391                 {
 392                         maxairspd = sv_maxairspeed*maxspd_mod;
 393                         airaccel = sv_airaccelerate*maxspd_mod;
 394                 }
 395                 else
 396                 {
 397                         maxairspd = sv_maxairspeed;
 398                         airaccel = sv_airaccelerate;
 399                 }
 400                 // airborn
 401                 makevectors(self.v_angle_y * '0 1 0');
 402                 wishvel = v_forward * self.movement_x + v_right * self.movement_y;
 403                 // acceleration
 404                 wishdir = normalize(wishvel);
 405                 wishspeed = vlen(wishvel);
 406                 if (wishspeed > maxairspd)
 407                         wishspeed = maxairspd;
 408                 if (self.crouch)
 409                         wishspeed = wishspeed * 0.5;
 410                 if (time >= self.teleport_time)
 411                 {
 412                         // NOTE: this does the same as the commented out old code if:
 413                         //   sv_airaccel_qw 0
 414                         //   sv_airaccel_sideways_friction 0
 415
 416                         float vel_straight;
 417                         float vel_z;
 418                         vector vel_perpend;
 419                         vel_straight = self.velocity * wishdir;
 420                         vel_z = self.velocity_z;
 421                         vel_perpend = self.velocity - vel_straight * wishdir - vel_z * '0 0 1';
 422
 423                         f = wishspeed - vel_straight;
 424                         if(f > 0)
 425                                 vel_straight = vel_straight + min(f, airaccel * frametime * wishspeed) * sv_airaccel_qw;
 426                         if(wishspeed > 0)
 427                                 vel_straight = vel_straight + min(wishspeed, airaccel * frametime * wishspeed) * (1 - sv_airaccel_qw);
 428
 429                         // anti-sideways friction to fix QW-style bunnyhopping
 430                         vel_perpend = vel_perpend * (1 - frametime * (wishspeed / maxairspd) * sv_airaccel_sideways_friction);
 431
 432                         self.velocity = vel_straight * wishdir + vel_z * '0 0 1' + vel_perpend;
 433
 434                         /*
 435                         f = wishspeed;// - (self.velocity * wishdir);
 436                         if (f > 0)
 437                                 self.velocity = self.velocity + wishdir * min(f, airaccel * frametime * wishspeed);
 438                         */
 439                 }
 440         }
 441
 442         if(self.flags & FL_ONGROUND)
 443                 self.lastground = time;
 444
 445         self.lastflags = self.flags;
 446 };