data/qcsrc/server/cl_physics.qc

   1 float sv_accelerate;
   2 float sv_friction;
   3 float sv_maxspeed;
   4 float sv_airaccelerate;
   5 float sv_maxairspeed;
   6 float sv_stopspeed;
   7 float sv_gravity;
   8 float sv_airaccel_sideways_friction;
   9 float sv_airaccel_qw;
  10 .float ladder_time;
  11 .entity ladder_entity;
  12 .float gravity;
  13 .float swamp_slowdown;
  14 .float lastflags;
  15 .float lastground;
  16 .float wasFlying;
  17 .float spectatorspeed;
  18
  19 #define SHTEST_DELTA 10
  20 #define SHTEST_THRESHOLD 1.1
  21 .float shtest_next;
  22 .float shtest_accumulator;
  23
  24 /*
  25 =============
  26 PlayerJump
  27
  28 When you press the jump key
  29 =============
  30 */
  31 void PlayerJump (void)
  32 {
  33         float mjumpheight;
  34
  35         mjumpheight = cvar("sv_jumpvelocity");
  36         if (self.waterlevel >= WATERLEVEL_SWIMMING)
  37         {
  38                 if (self.watertype == CONTENT_WATER)
  39                         self.velocity_z = 200;
  40                 else if (self.watertype == CONTENT_SLIME)
  41                         self.velocity_z = 80;
  42                 else
  43                         self.velocity_z = 50;
  44
  45                 return;
  46         }
  47
  48
  49         if (!(self.flags & FL_ONGROUND))
  50                 return;
  51
  52         if(!sv_pogostick)
  53                 if (!(self.flags & FL_JUMPRELEASED))
  54                         return;
  55
  56         if(self.health <= g_bloodloss)
  57                 return;
  58
  59         if(g_runematch)
  60         {
  61                 if(self.runes & RUNE_SPEED)
  62                 {
  63                         if(self.runes & CURSE_SLOW)
  64                                 mjumpheight = mjumpheight * cvar("g_balance_rune_speed_combo_jumpheight");
  65                         else
  66                                 mjumpheight = mjumpheight * cvar("g_balance_rune_speed_jumpheight");
  67                 }
  68                 else if(self.runes & CURSE_SLOW)
  69                 {
  70                         mjumpheight = mjumpheight * cvar("g_balance_curse_slow_jumpheight");
  71                 }
  72         }
  73
  74         if(g_minstagib && (self.items & IT_INVINCIBLE))
  75         {
  76                 mjumpheight = mjumpheight * cvar("g_minstagib_speed_jumpheight");
  77         }
  78
  79         self.velocity_z = self.velocity_z + mjumpheight;
  80         self.oldvelocity_z = self.velocity_z;
  81
  82         self.flags &~= FL_ONGROUND;
  83         self.flags &~= FL_JUMPRELEASED;
  84
  85         if (self.crouch)
  86                 setanim(self, self.anim_duckjump, FALSE, TRUE, TRUE);
  87         else
  88                 setanim(self, self.anim_jump, FALSE, TRUE, TRUE);
  89
  90         if(g_jump_grunt)
  91                 PlayerSound(playersound_jump, CHAN_PLAYER, VOICETYPE_PLAYERSOUND);
  92 }
  93
  94 void CheckWaterJump()
  95 {
  96         local vector start, end;
  97
  98 // check for a jump-out-of-water
  99         makevectors (self.angles);
 100         start = self.origin;
 101         start_z = start_z + 8;
 102         v_forward_z = 0;
 103         normalize(v_forward);
 104         end = start + v_forward*24;
 105         traceline (start, end, TRUE, self);
 106         if (trace_fraction < 1)
 107         {       // solid at waist
 108                 start_z = start_z + self.maxs_z - 8;
 109                 end = start + v_forward*24;
 110                 self.movedir = trace_plane_normal * -50;
 111                 traceline (start, end, TRUE, self);
 112                 if (trace_fraction == 1)
 113                 {       // open at eye level
 114                         self.flags |= FL_WATERJUMP;
 115                         self.velocity_z = 225;
 116                         self.flags &~= FL_JUMPRELEASED;
 117                         self.teleport_time = time + 2;  // safety net
 118                         return;
 119                 }
 120         }
 121 };
 122
 123 float racecar_angle(float forward, float down)
 124 {
 125         float ret, angle_mult;
 126
 127         if(forward < 0)
 128         {
 129                 forward = -forward;
 130                 down = -down;
 131         }
 132
 133         ret = vectoyaw('0 1 0' * down + '1 0 0' * forward);
 134
 135         angle_mult = forward / (800 + forward);
 136
 137         if(ret > 180)
 138                 return ret * angle_mult + 360 * (1 - angle_mult);
 139         else
 140                 return ret * angle_mult;
 141 }
 142
 143 void RaceCarPhysics()
 144 {
 145         // using this move type for "big rigs"
 146         // the engine does not push the entity!
 147
 148         float accel, steer, f;
 149         vector angles_save, rigvel;
 150
 151         angles_save = self.angles;
 152         accel = bound(-1, self.movement_x / sv_maxspeed, 1);
 153         steer = bound(-1, self.movement_y / sv_maxspeed, 1);
 154
 155         if(g_bugrigs_reverse_speeding)
 156         {
 157                 if(accel < 0)
 158                 {
 159                         // back accel is DIGITAL
 160                         // to prevent speedhack
 161                         if(accel < -0.5)
 162                                 accel = -1;
 163                         else
 164                                 accel = 0;
 165                 }
 166         }
 167
 168         self.angles_x = 0;
 169         self.angles_z = 0;
 170         makevectors(self.angles); // new forward direction!
 171
 172         if(self.flags & FL_ONGROUND || g_bugrigs_air_steering)
 173         {
 174                 float myspeed, upspeed, steerfactor, accelfactor;
 175
 176                 myspeed = self.velocity * v_forward;
 177                 upspeed = self.velocity * v_up;
 178
 179                 // responsiveness factor for steering and acceleration
 180                 f = 1 / (1 + pow(max(-myspeed, myspeed) / g_bugrigs_speed_ref, g_bugrigs_speed_pow));
 181                 //MAXIMA: f(v) := 1 / (1 + (v / g_bugrigs_speed_ref) ^ g_bugrigs_speed_pow);
 182
 183                 if(myspeed < 0 && g_bugrigs_reverse_spinning)
 184                         steerfactor = -myspeed * g_bugrigs_steer;
 185                 else
 186                         steerfactor = -myspeed * f * g_bugrigs_steer;
 187
 188                 if(myspeed < 0 && g_bugrigs_reverse_speeding)
 189                         accelfactor = g_bugrigs_accel;
 190                 else
 191                         accelfactor = f * g_bugrigs_accel;
 192                 //MAXIMA: accel(v) := f(v) * g_bugrigs_accel;
 193
 194                 if(accel < 0)
 195                 {
 196                         if(myspeed > 0)
 197                         {
 198                                 myspeed = max(0, myspeed - frametime * (g_bugrigs_friction_floor - g_bugrigs_friction_brake * accel));
 199                         }
 200                         else
 201                         {
 202                                 if(!g_bugrigs_reverse_speeding)
 203                                         myspeed = min(0, myspeed + frametime * g_bugrigs_friction_floor);
 204                         }
 205                 }
 206                 else
 207                 {
 208                         if(myspeed >= 0)
 209                         {
 210                                 myspeed = max(0, myspeed - frametime * g_bugrigs_friction_floor);
 211                         }
 212                         else
 213                         {
 214                                 if(g_bugrigs_reverse_stopping)
 215                                         myspeed = 0;
 216                                 else
 217                                         myspeed = min(0, myspeed + frametime * (g_bugrigs_friction_floor + g_bugrigs_friction_brake * accel));
 218                         }
 219                 }
 220                 // terminal velocity = velocity at which 50 == accelfactor, that is, 1549 units/sec
 221                 //MAXIMA: friction(v) := g_bugrigs_friction_floor;
 222
 223                 self.angles_y += steer * frametime * steerfactor; // apply steering
 224                 makevectors(self.angles); // new forward direction!
 225
 226                 myspeed += accel * accelfactor * frametime;
 227
 228                 rigvel = myspeed * v_forward + '0 0 1' * upspeed;
 229         }
 230         else
 231         {
 232                 myspeed = vlen(self.velocity);
 233
 234                 // responsiveness factor for steering and acceleration
 235                 f = 1 / (1 + pow(max(0, myspeed / g_bugrigs_speed_ref), g_bugrigs_speed_pow));
 236                 steerfactor = -myspeed * f;
 237                 self.angles_y += steer * frametime * steerfactor; // apply steering
 238
 239                 rigvel = self.velocity;
 240                 makevectors(self.angles); // new forward direction!
 241         }
 242
 243         rigvel = rigvel * max(0, 1 - vlen(rigvel) * g_bugrigs_friction_air * frametime);
 244         //MAXIMA: airfriction(v) := v * v * g_bugrigs_friction_air;
 245         //MAXIMA: total_acceleration(v) := accel(v) - friction(v) - airfriction(v);
 246         //MAXIMA: solve(total_acceleration(v) = 0, v);
 247
 248         if(g_bugrigs_planar_movement)
 249         {
 250                 vector rigvel_xy, neworigin, up;
 251                 float mt;
 252
 253                 rigvel_z -= frametime * sv_gravity; // 4x gravity plays better
 254                 rigvel_xy = rigvel;
 255                 rigvel_xy_z = 0;
 256
 257                 if(g_bugrigs_planar_movement_car_jumping && !g_touchexplode) // touchexplode is a better way to handle collisions
 258                         mt = MOVE_NORMAL;
 259                 else
 260                         mt = MOVE_NOMONSTERS;
 261
 262                 tracebox(self.origin, self.mins, self.maxs, self.origin + '0 0 1024', mt, self);
 263                 up = trace_endpos - self.origin;
 264
 265                 // BUG RIGS: align the move to the surface instead of doing collision testing
 266                 // can we move?
 267                 tracebox(trace_endpos, self.mins, self.maxs, trace_endpos + rigvel_xy * frametime, mt, self);
 268
 269                 // align to surface
 270                 tracebox(trace_endpos, self.mins, self.maxs, trace_endpos - up + '0 0 1' * rigvel_z * frametime, mt, self);
 271
 272                 if(trace_fraction < 0.5)
 273                 {
 274                         trace_fraction = 1;
 275                         neworigin = self.origin;
 276                 }
 277                 else
 278                         neworigin = trace_endpos;
 279
 280                 if(trace_fraction < 1)
 281                 {
 282                         // now set angles_x so that the car points parallel to the surface
 283                         self.angles = vectoangles(
 284                                         '1 0 0' * v_forward_x * trace_plane_normal_z
 285                                         +
 286                                         '0 1 0' * v_forward_y * trace_plane_normal_z
 287                                         +
 288                                         '0 0 1' * -(v_forward_x * trace_plane_normal_x + v_forward_y * trace_plane_normal_y)
 289                                         );
 290                         self.flags |= FL_ONGROUND;
 291                 }
 292                 else
 293                 {
 294                         // now set angles_x so that the car points forward, but is tilted in velocity direction
 295                         self.flags &~= FL_ONGROUND;
 296                 }
 297
 298                 self.velocity = (neworigin - self.origin) * (1.0 / frametime);
 299                 self.movetype = MOVETYPE_NOCLIP;
 300         }
 301         else
 302         {
 303                 rigvel_z -= frametime * sv_gravity; // 4x gravity plays better
 304                 self.velocity = rigvel;
 305                 self.movetype = MOVETYPE_FLY;
 306         }
 307
 308         trace_fraction = 1;
 309         tracebox(self.origin, self.mins, self.maxs, self.origin - '0 0 4', MOVE_NORMAL, self);
 310         if(trace_fraction != 1)
 311         {
 312                 self.angles = vectoangles2(
 313                                 '1 0 0' * v_forward_x * trace_plane_normal_z
 314                                 +
 315                                 '0 1 0' * v_forward_y * trace_plane_normal_z
 316                                 +
 317                                 '0 0 1' * -(v_forward_x * trace_plane_normal_x + v_forward_y * trace_plane_normal_y),
 318                                 trace_plane_normal
 319                                 );
 320         }
 321         else
 322         {
 323                 vector vel_local;
 324
 325                 vel_local_x = v_forward * self.velocity;
 326                 vel_local_y = v_right * self.velocity;
 327                 vel_local_z = v_up * self.velocity;
 328
 329                 self.angles_x = racecar_angle(vel_local_x, vel_local_z);
 330                 self.angles_z = racecar_angle(-vel_local_y, vel_local_z);
 331         }
 332
 333         // smooth the angles
 334         vector vf1, vu1, smoothangles;
 335         makevectors(self.angles);
 336         f = bound(0, frametime * g_bugrigs_angle_smoothing, 1);
 337         if(f == 0)
 338                 f = 1;
 339         vf1 = v_forward * f;
 340         vu1 = v_up * f;
 341         makevectors(angles_save);
 342         vf1 = vf1 + v_forward * (1 - f);
 343         vu1 = vu1 + v_up * (1 - f);
 344         smoothangles = vectoangles2(vf1, vu1);
 345         self.angles_x = -smoothangles_x;
 346         self.angles_z =  smoothangles_z;
 347 }
 348
 349 .vector movement_old;
 350 .float buttons_old;
 351 .vector v_angle_old;
 352
 353 void Nixnex_GiveCurrentWeapon();
 354 void SV_PlayerPhysics()
 355 {
 356         local vector wishvel, wishdir, v;
 357         local float wishspeed, f, maxspd_mod, spd, maxairspd, airaccel, swampspd_mod, shtest_score, buttons;
 358         string temps;
 359         float buttons_prev;
 360
 361         buttons = self.BUTTON_ATCK + 2 * self.BUTTON_JUMP + 4 * self.BUTTON_ATCK2 + 8 * self.BUTTON_ZOOM + 16 * self.BUTTON_CROUCH + 32 * self.BUTTON_HOOK + 64 * self.BUTTON_USE;
 362         if(!sv_maxidle_spectatorsareidle || self.movetype == MOVETYPE_WALK)
 363         {
 364                 if(buttons != self.buttons_old || self.movement != self.movement_old || self.v_angle != self.v_angle_old)
 365                         self.parm_idlesince = time;
 366         }
 367         buttons_prev = self.buttons_old;
 368         self.buttons_old = buttons;
 369         self.movement_old = self.movement;
 370         self.v_angle_old = self.v_angle;
 371
 372         if(time > self.shtest_next)
 373         {
 374                 if(self.shtest_next > 0)
 375                 {
 376                         // self.shtest_accumulator:
 377                         //   started at time - SHTEST_DELTA
 378                         //   should be at SHTEST_DELTA
 379                         shtest_score = self.shtest_accumulator / (SHTEST_DELTA + time - self.shtest_next);
 380                         if(shtest_score > SHTEST_THRESHOLD)
 381                                 print("TIME PARADOX: shtest for ", self.netname, " said ", ftos(shtest_score), "\n");
 382                         else if(cvar("developer_shtest"))
 383                                 dprint("okay: shtest for ", self.netname, " said ", ftos(shtest_score), "\n");
 384                 }
 385                 self.shtest_next = time + SHTEST_DELTA;
 386                 self.shtest_accumulator = 0;
 387         }
 388         self.shtest_accumulator += frametime;
 389
 390         if (clienttype(self) == CLIENTTYPE_BOT)
 391                 bot_think();
 392
 393         self.items &~= IT_USING_JETPACK;
 394
 395         if (self.movetype == MOVETYPE_NONE && self.disableclientprediction != 2)
 396                 return;
 397
 398         if (self.punchangle != '0 0 0')
 399         {
 400                 f = vlen(self.punchangle) - 10 * frametime;
 401                 if (f > 0)
 402                         self.punchangle = normalize(self.punchangle) * f;
 403                 else
 404                         self.punchangle = '0 0 0';
 405         }
 406
 407         if (self.punchvector != '0 0 0')
 408         {
 409                 f = vlen(self.punchvector) - 30 * frametime;
 410                 if (f > 0)
 411                         self.punchvector = normalize(self.punchvector) * f;
 412                 else
 413                         self.punchvector = '0 0 0';
 414         }
 415
 416         maxspd_mod = 1;
 417
 418         if(g_runematch)
 419         {
 420                 if(self.runes & RUNE_SPEED)
 421                 {
 422                         if(self.runes & CURSE_SLOW)
 423                                 maxspd_mod = maxspd_mod * cvar("g_balance_rune_speed_combo_moverate");
 424                         else
 425                                 maxspd_mod = maxspd_mod * cvar("g_balance_rune_speed_moverate");
 426                 }
 427                 else if(self.runes & CURSE_SLOW)
 428                 {
 429                         maxspd_mod = maxspd_mod * cvar("g_balance_curse_slow_moverate");
 430                 }
 431         }
 432
 433         if(g_minstagib && (self.items & IT_INVINCIBLE))
 434         {
 435                 maxspd_mod = cvar("g_minstagib_speed_moverate");
 436         }
 437
 438         swampspd_mod = 1;
 439         if(self.in_swamp) {
 440                 swampspd_mod = self.swamp_slowdown; //cvar("g_balance_swamp_moverate");
 441         }
 442
 443         if(self.classname != "player")
 444         {
 445                 maxspd_mod = cvar("sv_spectator_speed_multiplier");
 446                 if(!self.spectatorspeed)
 447                         self.spectatorspeed = maxspd_mod;
 448                 if(self.impulse && self.impulse <= 19)
 449                 {
 450                         // if(self.lastflags & FL_NOTARGET)
 451                         {
 452                                 if(self.impulse == 10 || self.impulse == 15 || self.impulse == 18)
 453                                         self.spectatorspeed = bound(1, self.spectatorspeed + 0.5, 5);
 454                                 else if(self.impulse == 11)
 455                                         self.spectatorspeed = maxspd_mod;
 456                                 else if(self.impulse == 12 || self.impulse == 16  || self.impulse == 19)
 457                                         self.spectatorspeed = bound(1, self.spectatorspeed - 0.5, 5);
 458                                 else if(self.impulse >= 1 && self.impulse <= 9)
 459                                         self.spectatorspeed = 1 + 0.5 * (self.impulse - 1);
 460                         } // otherwise just clear
 461                         self.impulse = 0;
 462                 }
 463                 maxspd_mod = self.spectatorspeed;
 464         }
 465
 466         spd = sv_maxspeed * maxspd_mod * swampspd_mod;
 467
 468         if(self.speed != spd)
 469         {
 470                 self.speed = spd;
 471                 temps = ftos(spd);
 472                 stuffcmd(self, strcat("cl_forwardspeed ", temps, "\n"));
 473                 stuffcmd(self, strcat("cl_backspeed ", temps, "\n"));
 474                 stuffcmd(self, strcat("cl_sidespeed ", temps, "\n"));
 475                 stuffcmd(self, strcat("cl_upspeed ", temps, "\n"));
 476
 477                 temps = ftos(sv_accelerate * maxspd_mod);
 478                 stuffcmd(self, strcat("cl_movement_accelerate ", temps, "\n"));
 479         }
 480
 481         // if dead, behave differently
 482         if (self.deadflag)
 483                 goto end;
 484
 485         if (!self.fixangle && !g_bugrigs)
 486         {
 487                 self.angles_x = 0;
 488                 self.angles_y = self.v_angle_y;
 489                 self.angles_z = 0;
 490         }
 491
 492         if(self.flags & FL_ONGROUND)
 493         if(self.wasFlying)
 494         {
 495                 self.wasFlying = 0;
 496
 497                 if(self.waterlevel < WATERLEVEL_SWIMMING)
 498                 if(time >= self.ladder_time)
 499                 if not(self.hook)
 500                 {
 501                         self.nextstep = time + 0.3 + random() * 0.1;
 502                         trace_dphitq3surfaceflags = 0;
 503                         tracebox(self.origin, self.mins, self.maxs, self.origin - '0 0 1', MOVE_NOMONSTERS, self);
 504                         if not(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOSTEPS)
 505                         {
 506                                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_METALSTEPS)
 507                                         GlobalSound(globalsound_metalfall, CHAN_PLAYER, VOICETYPE_PLAYERSOUND);
 508                                 else
 509                                         GlobalSound(globalsound_fall, CHAN_PLAYER, VOICETYPE_PLAYERSOUND);
 510                         }
 511                 }
 512         }
 513
 514         if(IsFlying(self))
 515                 self.wasFlying = 1;
 516
 517         if(self.classname == "player")
 518         {
 519                 if(sv_doublejump)
 520                 {
 521                         self.flags &~= FL_ONGROUND;
 522                         tracebox(self.origin + '0 0 1', self.mins, self.maxs, self.origin - '0 0 2', MOVE_NORMAL, self);
 523                         if(trace_fraction < 1 && trace_plane_normal_z > 0.7)
 524                                 self.flags |= FL_ONGROUND;
 525                 }
 526
 527                 if (self.BUTTON_JUMP)
 528                         PlayerJump ();
 529                 else
 530                         self.flags |= FL_JUMPRELEASED;
 531
 532                 if (self.waterlevel == WATERLEVEL_SWIMMING)
 533                         CheckWaterJump ();
 534         }
 535
 536         if (self.flags & FL_WATERJUMP )
 537         {
 538                 self.velocity_x = self.movedir_x;
 539                 self.velocity_y = self.movedir_y;
 540                 if (time > self.teleport_time || self.waterlevel == WATERLEVEL_NONE)
 541                 {
 542                         self.flags &~= FL_WATERJUMP;
 543                         self.teleport_time = 0;
 544                 }
 545         }
 546         else if (g_bugrigs && self.classname == "player")
 547         {
 548                 RaceCarPhysics();
 549         }
 550         else if (self.movetype == MOVETYPE_NOCLIP || self.movetype == MOVETYPE_FLY)
 551         {
 552                 // noclipping or flying
 553                 self.flags &~= FL_ONGROUND;
 554
 555                 self.velocity = self.velocity * (1 - frametime * sv_friction);
 556                 makevectors(self.v_angle);
 557                 //wishvel = v_forward * self.movement_x + v_right * self.movement_y + v_up * self.movement_z;
 558                 wishvel = v_forward * self.movement_x + v_right * self.movement_y + '0 0 1' * self.movement_z;
 559                 // acceleration
 560                 wishdir = normalize(wishvel);
 561                 wishspeed = vlen(wishvel);
 562                 if (wishspeed > sv_maxspeed*maxspd_mod)
 563                         wishspeed = sv_maxspeed*maxspd_mod;
 564                 if (time >= self.teleport_time)
 565                 {
 566                         f = wishspeed - (self.velocity * wishdir);
 567                         if (f > 0)
 568                                 self.velocity = self.velocity + wishdir * min(f, sv_accelerate*maxspd_mod * frametime * wishspeed);
 569                 }
 570         }
 571         else if (self.waterlevel >= WATERLEVEL_SWIMMING)
 572         {
 573                 // swimming
 574                 self.flags &~= FL_ONGROUND;
 575
 576                 makevectors(self.v_angle);
 577                 //wishvel = v_forward * self.movement_x + v_right * self.movement_y + v_up * self.movement_z;
 578                 wishvel = v_forward * self.movement_x + v_right * self.movement_y + '0 0 1' * self.movement_z;
 579                 if (wishvel == '0 0 0')
 580                         wishvel = '0 0 -60'; // drift towards bottom
 581
 582                 wishdir = normalize(wishvel);
 583                 wishspeed = vlen(wishvel);
 584                 if (wishspeed > sv_maxspeed*maxspd_mod)
 585                         wishspeed = sv_maxspeed*maxspd_mod;
 586                 wishspeed = wishspeed * 0.7;
 587
 588                 // water friction
 589                 self.velocity = self.velocity * (1 - frametime * sv_friction);
 590
 591                 // water acceleration
 592                 f = wishspeed - (self.velocity * wishdir);
 593                 if (f > 0)
 594                         self.velocity = self.velocity + wishdir * min(f, sv_accelerate*maxspd_mod * frametime * wishspeed);
 595         }
 596         else if (time < self.ladder_time)
 597         {
 598                 // on a spawnfunc_func_ladder or swimming in spawnfunc_func_water
 599                 self.flags &~= FL_ONGROUND;
 600
 601                 self.velocity = self.velocity * (1 - frametime * sv_friction);
 602                 makevectors(self.v_angle);
 603                 //wishvel = v_forward * self.movement_x + v_right * self.movement_y + v_up * self.movement_z;
 604                 wishvel = v_forward * self.movement_x + v_right * self.movement_y + '0 0 1' * self.movement_z;
 605                 if (self.gravity)
 606                         self.velocity_z = self.velocity_z + self.gravity * sv_gravity * frametime;
 607                 else
 608                         self.velocity_z = self.velocity_z + sv_gravity * frametime;
 609                 if (self.ladder_entity.classname == "func_water")
 610                 {
 611                         f = vlen(wishvel);
 612                         if (f > self.ladder_entity.speed)
 613                                 wishvel = wishvel * (self.ladder_entity.speed / f);
 614
 615                         self.watertype = self.ladder_entity.skin;
 616                         f = self.ladder_entity.origin_z + self.ladder_entity.maxs_z;
 617                         if ((self.origin_z + self.view_ofs_z) < f)
 618                                 self.waterlevel = WATERLEVEL_SUBMERGED;
 619                         else if ((self.origin_z + (self.mins_z + self.maxs_z) * 0.5) < f)
 620                                 self.waterlevel = WATERLEVEL_SWIMMING;
 621                         else if ((self.origin_z + self.mins_z + 1) < f)
 622                                 self.waterlevel = WATERLEVEL_WETFEET;
 623                         else
 624                         {
 625                                 self.waterlevel = WATERLEVEL_NONE;
 626                                 self.watertype = CONTENT_EMPTY;
 627                         }
 628                 }
 629                 // acceleration
 630                 wishdir = normalize(wishvel);
 631                 wishspeed = vlen(wishvel);
 632                 if (wishspeed > sv_maxspeed)
 633                         wishspeed = sv_maxspeed;
 634                 if (time >= self.teleport_time)
 635                 {
 636                         f = wishspeed - (self.velocity * wishdir);
 637                         if (f > 0)
 638                                 self.velocity = self.velocity + wishdir * min(f, sv_accelerate*maxspd_mod * frametime * wishspeed);
 639                 }
 640         }
 641         else if ((self.items & IT_JETPACK) && self.BUTTON_HOOK && (!cvar("g_jetpack_fuel") || self.ammo_fuel >= 0.01 || self.items & IT_UNLIMITED_WEAPON_AMMO))
 642         {
 643                 //makevectors(self.v_angle_y * '0 1 0');
 644                 makevectors(self.v_angle);
 645                 wishvel = v_forward * self.movement_x + v_right * self.movement_y;
 646                 // add remaining speed as Z component
 647                 maxairspd = sv_maxairspeed*max(1, maxspd_mod);
 648                 // fix speedhacks :P
 649                 wishvel = normalize(wishvel) * min(vlen(wishvel) / maxairspd, 1);
 650                 // add the unused velocity as up component
 651                 wishvel_z = 0;
 652
 653                 // if(self.BUTTON_JUMP)
 654                         wishvel_z = sqrt(max(0, 1 - wishvel * wishvel));
 655
 656                 // it is now normalized, so...
 657                 float a_side, a_up, a_add, a_diff;
 658                 a_side = cvar("g_jetpack_acceleration_side");
 659                 a_up = cvar("g_jetpack_acceleration_up");
 660                 a_add = cvar("g_jetpack_antigravity") * sv_gravity;
 661
 662                 wishvel_x *= a_side;
 663                 wishvel_y *= a_side;
 664                 wishvel_z *= a_up;
 665                 wishvel_z += a_add;
 666
 667                 float best;
 668                 best = 0;
 669                 //////////////////////////////////////////////////////////////////////////////////////
 670                 // finding the maximum over all vectors of above form
 671                 // with wishvel having an absolute value of 1
 672                 //////////////////////////////////////////////////////////////////////////////////////
 673                 // we're finding the maximum over
 674                 //   f(a_side, a_up, a_add, z) := a_side * (1 - z^2) + (a_add + a_up * z)^2;
 675                 // for z in the range from -1 to 1
 676                 //////////////////////////////////////////////////////////////////////////////////////
 677                 // maximum is EITHER attained at the single extreme point:
 678                 a_diff = a_side * a_side - a_up * a_up;
 679                 if(a_diff != 0)
 680                 {
 681                         f = a_add * a_up / a_diff; // this is the zero of diff(f(a_side, a_up, a_add, z), z)
 682                         if(f > -1 && f < 1) // can it be attained?
 683                         {
 684                                 best = (a_diff + a_add * a_add) * (a_diff + a_up * a_up) / a_diff;
 685                                 //print("middle\n");
 686                         }
 687                 }
 688                 // OR attained at z = 1:
 689                 f = (a_up + a_add) * (a_up + a_add);
 690                 if(f > best)
 691                 {
 692                         best = f;
 693                         //print("top\n");
 694                 }
 695                 // OR attained at z = -1:
 696                 f = (a_up - a_add) * (a_up - a_add);
 697                 if(f > best)
 698                 {
 699                         best = f;
 700                         //print("bottom\n");
 701                 }
 702                 best = sqrt(best);
 703                 //////////////////////////////////////////////////////////////////////////////////////
 704
 705                 //print("best possible acceleration: ", ftos(best), "\n");
 706
 707                 float fxy, fz;
 708                 fxy = bound(0, 1 - (self.velocity * normalize(wishvel_x * '1 0 0' + wishvel_y * '0 1 0')) / cvar("g_jetpack_maxspeed_side"), 1);
 709                 if(wishvel_z - sv_gravity > 0)
 710                         fz = bound(0, 1 - self.velocity_z / cvar("g_jetpack_maxspeed_up"), 1);
 711                 else
 712                         fz = bound(0, 1 + self.velocity_z / cvar("g_jetpack_maxspeed_up"), 1);
 713
 714                 float fvel;
 715                 fvel = vlen(wishvel);
 716                 wishvel_x *= fxy;
 717                 wishvel_y *= fxy;
 718                 wishvel_z = (wishvel_z - sv_gravity) * fz + sv_gravity;
 719
 720                 fvel = min(1, vlen(wishvel) / best);
 721                 if(cvar("g_jetpack_fuel") && !(self.items & IT_UNLIMITED_WEAPON_AMMO))
 722                         f = min(1, self.ammo_fuel / (cvar("g_jetpack_fuel") * frametime * fvel));
 723                 else
 724                         f = 1;
 725
 726                 //print("this acceleration: ", ftos(vlen(wishvel) * f), "\n");
 727
 728                 if (f > 0 && wishvel != '0 0 0')
 729                 {
 730                         self.velocity = self.velocity + wishvel * f * frametime;
 731                         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
 732                                 self.ammo_fuel -= cvar("g_jetpack_fuel") * frametime * fvel * f;
 733                         self.flags &~= FL_ONGROUND;
 734                         self.items |= IT_USING_JETPACK;
 735
 736                         // jetpack also inhibits health regeneration, but only for 1 second
 737                         self.pauseregen_finished = max(self.pauseregen_finished, time + cvar("g_balance_pause_fuel_regen"));
 738                 }
 739         }
 740         else if (self.flags & FL_ONGROUND)
 741         {
 742                 // we get here if we ran out of ammo
 743                 if((self.items & IT_JETPACK) && self.BUTTON_HOOK && !(buttons_prev & 32))
 744                         sprint(self, "You don't have any fuel for the ^2Jetpack\n");
 745
 746                 // walking
 747                 makevectors(self.v_angle_y * '0 1 0');
 748                 wishvel = v_forward * self.movement_x + v_right * self.movement_y;
 749
 750                 if(!(self.lastflags & FL_ONGROUND))
 751                 {
 752                         if(cvar("speedmeter"))
 753                                 dprint(strcat("landing velocity: ", vtos(self.velocity), " (abs: ", ftos(vlen(self.velocity)), ")\n"));
 754                         if(self.lastground < time - 0.3)
 755                                 self.velocity = self.velocity * (1 - cvar("sv_friction_on_land"));
 756                         if(self.jumppadcount > 1)
 757                                 dprint(strcat(ftos(self.jumppadcount), "x jumppad combo\n"));
 758                         self.jumppadcount = 0;
 759                 }
 760
 761                 if (self.velocity_x || self.velocity_y)
 762                 if (!(self.flags & FL_JUMPRELEASED) || !self.BUTTON_JUMP)
 763                 {
 764                         v = self.velocity;
 765                         v_z = 0;
 766                         f = vlen(v);
 767                         if (f < sv_stopspeed)
 768                                 f = 1 - frametime * (sv_stopspeed / f) * sv_friction;
 769                         else
 770                                 f = 1 - frametime * sv_friction;
 771                         if (f > 0)
 772                                 self.velocity = self.velocity * f;
 773                         else
 774                                 self.velocity = '0 0 0';
 775                 }
 776                 // acceleration
 777                 wishdir = normalize(wishvel);
 778                 wishspeed = vlen(wishvel);
 779                 if (wishspeed > sv_maxspeed*maxspd_mod)
 780                         wishspeed = sv_maxspeed*maxspd_mod;
 781                 if (self.crouch)
 782                         wishspeed = wishspeed * 0.5;
 783                 if (time >= self.teleport_time)
 784                 {
 785                         f = wishspeed - (self.velocity * wishdir);
 786                         if (f > 0)
 787                                 self.velocity = self.velocity + wishdir * min(f, sv_accelerate*maxspd_mod * frametime * wishspeed);
 788                 }
 789         }
 790         else
 791         {
 792                 // we get here if we ran out of ammo
 793                 if((self.items & IT_JETPACK) && self.BUTTON_HOOK && !(buttons_prev & 32))
 794                         sprint(self, "You don't have any fuel for the ^2Jetpack\n");
 795
 796                 if(maxspd_mod < 1)
 797                 {
 798                         maxairspd = sv_maxairspeed*maxspd_mod;
 799                         airaccel = sv_airaccelerate*maxspd_mod;
 800                 }
 801                 else
 802                 {
 803                         maxairspd = sv_maxairspeed;
 804                         airaccel = sv_airaccelerate;
 805                 }
 806                 // airborn
 807                 makevectors(self.v_angle_y * '0 1 0');
 808                 wishvel = v_forward * self.movement_x + v_right * self.movement_y;
 809                 // acceleration
 810                 wishdir = normalize(wishvel);
 811                 wishspeed = vlen(wishvel);
 812                 if (wishspeed > maxairspd)
 813                         wishspeed = maxairspd;
 814                 if (self.crouch)
 815                         wishspeed = wishspeed * 0.5;
 816                 if (time >= self.teleport_time)
 817                 {
 818                         // NOTE: this does the same as the commented out old code if:
 819                         //   sv_airaccel_qw 0
 820                         //   sv_airaccel_sideways_friction 0
 821
 822                         float vel_straight;
 823                         float vel_z;
 824                         vector vel_perpend;
 825                         vel_straight = self.velocity * wishdir;
 826                         vel_z = self.velocity_z;
 827                         vel_perpend = self.velocity - vel_straight * wishdir - vel_z * '0 0 1';
 828
 829                         f = wishspeed - vel_straight;
 830                         if(f > 0)
 831                                 vel_straight = vel_straight + min(f, airaccel * frametime * wishspeed) * sv_airaccel_qw;
 832                         if(wishspeed > 0)
 833                                 vel_straight = vel_straight + min(wishspeed, airaccel * frametime * wishspeed) * (1 - sv_airaccel_qw);
 834
 835                         // anti-sideways friction to fix QW-style bunnyhopping
 836                         vel_perpend = vel_perpend * (1 - frametime * (wishspeed / maxairspd) * sv_airaccel_sideways_friction);
 837
 838                         self.velocity = vel_straight * wishdir + vel_z * '0 0 1' + vel_perpend;
 839
 840                         /*
 841                         f = wishspeed;// - (self.velocity * wishdir);
 842                         if (f > 0)
 843                                 self.velocity = self.velocity + wishdir * min(f, airaccel * frametime * wishspeed);
 844                         */
 845                 }
 846         }
 847
 848 :end
 849         if(self.flags & FL_ONGROUND)
 850                 self.lastground = time;
 851
 852         self.lastflags = self.flags;
 853 };