data/qcsrc/server/cl_physics.qc

   1 float sv_accelerate;
   2 float sv_friction;
   3 float sv_maxspeed;
   4 float sv_airaccelerate;
   5 float sv_maxairspeed;
   6 float sv_stopspeed;
   7 float sv_gravity;
   8 float sv_airaccel_sideways_friction;
   9 float sv_airaccel_qw;
  10 .float ladder_time;
  11 .entity ladder_entity;
  12 .float gravity;
  13 .float swamp_slowdown;
  14 .float lastflags;
  15 .float lastground;
  16
  17 #define SHTEST_DELTA 15
  18 .float shtest_next;
  19 .float shtest_accumulator;
  20
  21 /*
  22 =============
  23 PlayerJump
  24
  25 When you press the jump key
  26 =============
  27 */
  28 void PlayerJump (void)
  29 {
  30         float mjumpheight;
  31
  32         mjumpheight = cvar("sv_jumpvelocity");
  33         if (self.waterlevel >= 2)
  34         {
  35                 if (self.watertype == CONTENT_WATER)
  36                         self.velocity_z = 200;
  37                 else if (self.watertype == CONTENT_SLIME)
  38                         self.velocity_z = 80;
  39                 else
  40                         self.velocity_z = 50;
  41
  42                 return;
  43         }
  44
  45
  46         if (!(self.flags & FL_ONGROUND))
  47                 return;
  48
  49         if(!sv_pogostick)
  50                 if (!(self.flags & FL_JUMPRELEASED))
  51                         return;
  52
  53         if(g_runematch)
  54         {
  55                 if(self.runes & RUNE_SPEED)
  56                 {
  57                         if(self.runes & CURSE_SLOW)
  58                                 mjumpheight = mjumpheight * cvar("g_balance_rune_speed_combo_jumpheight");
  59                         else
  60                                 mjumpheight = mjumpheight * cvar("g_balance_rune_speed_jumpheight");
  61                 }
  62                 else if(self.runes & CURSE_SLOW)
  63                 {
  64                         mjumpheight = mjumpheight * cvar("g_balance_curse_slow_jumpheight");
  65                 }
  66         }
  67
  68         if(g_minstagib && (self.items & IT_INVINCIBLE))
  69         {
  70                 mjumpheight = mjumpheight * cvar("g_minstagib_speed_jumpheight");
  71         }
  72
  73         self.velocity_z = self.velocity_z + mjumpheight;
  74         self.oldvelocity_z = self.velocity_z;
  75
  76         self.flags = self.flags - FL_ONGROUND;
  77         self.flags = self.flags - FL_JUMPRELEASED;
  78
  79         if (self.crouch)
  80                 player_setanim(self.anim_duckjump, FALSE, TRUE, TRUE);
  81         else
  82                 player_setanim(self.anim_jump, FALSE, TRUE, TRUE);
  83 }
  84
  85 void CheckWaterJump()
  86 {
  87         local vector start, end;
  88
  89 // check for a jump-out-of-water
  90         makevectors (self.angles);
  91         start = self.origin;
  92         start_z = start_z + 8;
  93         v_forward_z = 0;
  94         normalize(v_forward);
  95         end = start + v_forward*24;
  96         traceline (start, end, TRUE, self);
  97         if (trace_fraction < 1)
  98         {       // solid at waist
  99                 start_z = start_z + self.maxs_z - 8;
 100                 end = start + v_forward*24;
 101                 self.movedir = trace_plane_normal * -50;
 102                 traceline (start, end, TRUE, self);
 103                 if (trace_fraction == 1)
 104                 {       // open at eye level
 105                         self.flags = self.flags | FL_WATERJUMP;
 106                         self.velocity_z = 225;
 107                         self.flags = self.flags - (self.flags & FL_JUMPRELEASED);
 108                         self.teleport_time = time + 2;  // safety net
 109                         return;
 110                 }
 111         }
 112 };
 113
 114 .vector movement_old;
 115 .float buttons_old;
 116 .vector v_angle_old;
 117
 118 void Nixnex_GiveCurrentWeapon();
 119 void SV_PlayerPhysics()
 120 {
 121         local vector wishvel, wishdir, v;
 122         local float wishspeed, f, maxspd_mod, spd, maxairspd, airaccel, swampspd_mod, shtest_score, buttons;
 123         string temps;
 124
 125         buttons = self.BUTTON_ATCK + 2 * self.BUTTON_JUMP + 4 * self.BUTTON_ATCK2 + 8 * self.BUTTON_ZOOM + 16 * self.BUTTON_CROUCH + 32 * self.BUTTON_HOOK + 64 * self.BUTTON_USE;
 126         if(!sv_maxidle_spectatorsareidle || self.movetype == MOVETYPE_WALK)
 127         {
 128                 if(buttons != self.buttons_old || self.movement != self.movement_old || self.v_angle != self.v_angle_old)
 129                         self.parm_idlesince = time;
 130         }
 131         self.buttons_old = buttons;
 132         self.movement_old = self.movement;
 133         self.v_angle_old = self.v_angle;
 134
 135         if(time > self.shtest_next)
 136         {
 137                 if(self.shtest_next > 0)
 138                 {
 139                         // self.shtest_accumulator:
 140                         //   started at time - SHTEST_DELTA
 141                         //   should be at SHTEST_DELTA
 142                         shtest_score = self.shtest_accumulator / SHTEST_DELTA;
 143                         if(shtest_score > 1.2)
 144                                 dprint("TIME PARADOX: shtest for ", self.netname, " said ", ftos(shtest_score), "\n");
 145                         else if(cvar("developer_shtest"))
 146                                 dprint("okay: shtest for ", self.netname, " said ", ftos(shtest_score), "\n");
 147                 }
 148                 self.shtest_next = time + SHTEST_DELTA;
 149                 self.shtest_accumulator = 0;
 150         }
 151         self.shtest_accumulator += frametime;
 152
 153         if (clienttype(self) == CLIENTTYPE_BOT)
 154                 bot_think();
 155
 156         if (self.movetype == MOVETYPE_NONE)
 157                 return;
 158
 159         if (self.punchangle != '0 0 0')
 160         {
 161                 f = vlen(self.punchangle) - 10 * frametime;
 162                 if (f > 0)
 163                         self.punchangle = normalize(self.punchangle) * f;
 164                 else
 165                         self.punchangle = '0 0 0';
 166         }
 167
 168         if (self.punchvector != '0 0 0')
 169         {
 170                 f = vlen(self.punchvector) - 30 * frametime;
 171                 if (f > 0)
 172                         self.punchvector = normalize(self.punchvector) * f;
 173                 else
 174                         self.punchvector = '0 0 0';
 175         }
 176
 177         maxspd_mod = 1;
 178
 179         if(g_runematch)
 180         {
 181                 if(self.runes & RUNE_SPEED)
 182                 {
 183                         if(self.runes & CURSE_SLOW)
 184                                 maxspd_mod = maxspd_mod * cvar("g_balance_rune_speed_combo_moverate");
 185                         else
 186                                 maxspd_mod = maxspd_mod * cvar("g_balance_rune_speed_moverate");
 187                 }
 188                 else if(self.runes & CURSE_SLOW)
 189                 {
 190                         maxspd_mod = maxspd_mod * cvar("g_balance_curse_slow_moverate");
 191                 }
 192         }
 193
 194         if(g_minstagib && (self.items & IT_INVINCIBLE))
 195         {
 196                 maxspd_mod = cvar("g_minstagib_speed_moverate");
 197         }
 198
 199         swampspd_mod = 1;
 200         if(self.in_swamp) {
 201                 swampspd_mod = self.swamp_slowdown; //cvar("g_balance_swamp_moverate");
 202         }
 203
 204         if(self.flags & FL_NOTARGET)
 205                 maxspd_mod = cvar("sv_spectator_speed_multiplier");
 206
 207         spd = sv_maxspeed * maxspd_mod * swampspd_mod;
 208
 209         if(self.speed != spd)
 210         {
 211                 self.speed = spd;
 212                 temps = ftos(spd);
 213                 stuffcmd(self, strcat("cl_forwardspeed ", temps, "\n"));
 214                 stuffcmd(self, strcat("cl_backspeed ", temps, "\n"));
 215                 stuffcmd(self, strcat("cl_sidespeed ", temps, "\n"));
 216                 stuffcmd(self, strcat("cl_upspeed ", temps, "\n"));
 217
 218                 temps = ftos(sv_accelerate * maxspd_mod);
 219                 stuffcmd(self, strcat("cl_movement_accelerate ", temps, "\n"));
 220         }
 221
 222         // if dead, behave differently
 223         if (self.deadflag)
 224                 return;
 225
 226         if (!self.fixangle)
 227         {
 228                 self.angles_x = 0;
 229                 self.angles_y = self.v_angle_y;
 230                 self.angles_z = 0;
 231         }
 232
 233         if(self.classname == "player")
 234         {
 235                 if(sv_doublejump)
 236                 {
 237                         self.flags = self.flags - (self.flags & FL_ONGROUND);
 238                         tracebox(self.origin + '0 0 1', self.mins, self.maxs, self.origin - '0 0 2', MOVE_NORMAL, self);
 239                         if(trace_fraction < 1 && trace_plane_normal_z > 0.7)
 240                                 self.flags = self.flags | FL_ONGROUND;
 241                 }
 242
 243                 if (self.BUTTON_JUMP)
 244                         PlayerJump ();
 245                 else
 246                         self.flags = self.flags | FL_JUMPRELEASED;
 247
 248                 if (self.waterlevel == 2)
 249                         CheckWaterJump ();
 250         }
 251
 252         if (self.flags & FL_WATERJUMP )
 253         {
 254                 self.velocity_x = self.movedir_x;
 255                 self.velocity_y = self.movedir_y;
 256                 if (time > self.teleport_time || self.waterlevel == 0)
 257                 {
 258                         self.flags = self.flags - (self.flags & FL_WATERJUMP);
 259                         self.teleport_time = 0;
 260                 }
 261         }
 262         else if (self.movetype == MOVETYPE_NOCLIP || self.movetype == MOVETYPE_FLY)
 263         {
 264                 // noclipping or flying
 265                 self.flags = self.flags - (self.flags & FL_ONGROUND);
 266
 267                 self.velocity = self.velocity * (1 - frametime * sv_friction);
 268                 makevectors(self.v_angle);
 269                 //wishvel = v_forward * self.movement_x + v_right * self.movement_y + v_up * self.movement_z;
 270                 wishvel = v_forward * self.movement_x + v_right * self.movement_y + '0 0 1' * self.movement_z;
 271                 // acceleration
 272                 wishdir = normalize(wishvel);
 273                 wishspeed = vlen(wishvel);
 274                 if (wishspeed > sv_maxspeed*maxspd_mod)
 275                         wishspeed = sv_maxspeed*maxspd_mod;
 276                 if (time >= self.teleport_time)
 277                 {
 278                         f = wishspeed - (self.velocity * wishdir);
 279                         if (f > 0)
 280                                 self.velocity = self.velocity + wishdir * min(f, sv_accelerate*maxspd_mod * frametime * wishspeed);
 281                 }
 282         }
 283         else if (self.waterlevel >= 2)
 284         {
 285                 // swimming
 286                 self.flags = self.flags - (self.flags & FL_ONGROUND);
 287
 288                 makevectors(self.v_angle);
 289                 //wishvel = v_forward * self.movement_x + v_right * self.movement_y + v_up * self.movement_z;
 290                 wishvel = v_forward * self.movement_x + v_right * self.movement_y + '0 0 1' * self.movement_z;
 291                 if (wishvel == '0 0 0')
 292                         wishvel = '0 0 -60'; // drift towards bottom
 293
 294                 wishdir = normalize(wishvel);
 295                 wishspeed = vlen(wishvel);
 296                 if (wishspeed > sv_maxspeed*maxspd_mod)
 297                         wishspeed = sv_maxspeed*maxspd_mod;
 298                 wishspeed = wishspeed * 0.7;
 299
 300                 // water friction
 301                 self.velocity = self.velocity * (1 - frametime * sv_friction);
 302
 303                 // water acceleration
 304                 f = wishspeed - (self.velocity * wishdir);
 305                 if (f > 0)
 306                         self.velocity = self.velocity + wishdir * min(f, sv_accelerate*maxspd_mod * frametime * wishspeed);
 307         }
 308         else if (time < self.ladder_time)
 309         {
 310                 // on a spawnfunc_func_ladder or swimming in spawnfunc_func_water
 311                 self.flags = self.flags - (self.flags & FL_ONGROUND);
 312
 313                 self.velocity = self.velocity * (1 - frametime * sv_friction);
 314                 makevectors(self.v_angle);
 315                 //wishvel = v_forward * self.movement_x + v_right * self.movement_y + v_up * self.movement_z;
 316                 wishvel = v_forward * self.movement_x + v_right * self.movement_y + '0 0 1' * self.movement_z;
 317                 if (self.gravity)
 318                         self.velocity_z = self.velocity_z + self.gravity * sv_gravity * frametime;
 319                 else
 320                         self.velocity_z = self.velocity_z + sv_gravity * frametime;
 321                 if (self.ladder_entity.classname == "func_water")
 322                 {
 323                         f = vlen(wishvel);
 324                         if (f > self.ladder_entity.speed)
 325                                 wishvel = wishvel * (self.ladder_entity.speed / f);
 326
 327                         self.watertype = self.ladder_entity.skin;
 328                         f = self.ladder_entity.origin_z + self.ladder_entity.maxs_z;
 329                         if ((self.origin_z + self.view_ofs_z) < f)
 330                                 self.waterlevel = 3;
 331                         else if ((self.origin_z + (self.mins_z + self.maxs_z) * 0.5) < f)
 332                                 self.waterlevel = 2;
 333                         else if ((self.origin_z + self.mins_z + 1) < f)
 334                                 self.waterlevel = 1;
 335                         else
 336                         {
 337                                 self.waterlevel = 0;
 338                                 self.watertype = CONTENT_EMPTY;
 339                         }
 340                 }
 341                 // acceleration
 342                 wishdir = normalize(wishvel);
 343                 wishspeed = vlen(wishvel);
 344                 if (wishspeed > sv_maxspeed)
 345                         wishspeed = sv_maxspeed;
 346                 if (time >= self.teleport_time)
 347                 {
 348                         f = wishspeed - (self.velocity * wishdir);
 349                         if (f > 0)
 350                                 self.velocity = self.velocity + wishdir * min(f, sv_accelerate*maxspd_mod * frametime * wishspeed);
 351                 }
 352         }
 353         else if (self.flags & FL_ONGROUND)
 354         {
 355                 // walking
 356                 makevectors(self.v_angle_y * '0 1 0');
 357                 wishvel = v_forward * self.movement_x + v_right * self.movement_y;
 358
 359                 if(!(self.lastflags & FL_ONGROUND))
 360                 {
 361                         if(cvar("speedmeter"))
 362                                 dprint(strcat("landing velocity: ", vtos(self.velocity), " (abs: ", ftos(vlen(self.velocity)), ")\n"));
 363                         if(self.lastground < time - 0.3)
 364                                 self.velocity = self.velocity * (1 - cvar("sv_friction_on_land"));
 365                         if(self.jumppadcount > 1)
 366                                 dprint(strcat(ftos(self.jumppadcount), "x jumppad combo\n"));
 367                         self.jumppadcount = 0;
 368                 }
 369
 370                 if (self.velocity_x || self.velocity_y)
 371                 if (!(self.flags & FL_JUMPRELEASED) || !self.BUTTON_JUMP)
 372                 {
 373                         v = self.velocity;
 374                         v_z = 0;
 375                         f = vlen(v);
 376                         if (f < sv_stopspeed)
 377                                 f = 1 - frametime * (sv_stopspeed / f) * sv_friction;
 378                         else
 379                                 f = 1 - frametime * sv_friction;
 380                         if (f > 0)
 381                                 self.velocity = self.velocity * f;
 382                         else
 383                                 self.velocity = '0 0 0';
 384                 }
 385                 // acceleration
 386                 wishdir = normalize(wishvel);
 387                 wishspeed = vlen(wishvel);
 388                 if (wishspeed > sv_maxspeed*maxspd_mod)
 389                         wishspeed = sv_maxspeed*maxspd_mod;
 390                 if (self.crouch)
 391                         wishspeed = wishspeed * 0.5;
 392                 if (time >= self.teleport_time)
 393                 {
 394                         f = wishspeed - (self.velocity * wishdir);
 395                         if (f > 0)
 396                                 self.velocity = self.velocity + wishdir * min(f, sv_accelerate*maxspd_mod * frametime * wishspeed);
 397                 }
 398         }
 399         else
 400         {
 401                 if(maxspd_mod < 1)
 402                 {
 403                         maxairspd = sv_maxairspeed*maxspd_mod;
 404                         airaccel = sv_airaccelerate*maxspd_mod;
 405                 }
 406                 else
 407                 {
 408                         maxairspd = sv_maxairspeed;
 409                         airaccel = sv_airaccelerate;
 410                 }
 411                 // airborn
 412                 makevectors(self.v_angle_y * '0 1 0');
 413                 wishvel = v_forward * self.movement_x + v_right * self.movement_y;
 414                 // acceleration
 415                 wishdir = normalize(wishvel);
 416                 wishspeed = vlen(wishvel);
 417                 if (wishspeed > maxairspd)
 418                         wishspeed = maxairspd;
 419                 if (self.crouch)
 420                         wishspeed = wishspeed * 0.5;
 421                 if (time >= self.teleport_time)
 422                 {
 423                         // NOTE: this does the same as the commented out old code if:
 424                         //   sv_airaccel_qw 0
 425                         //   sv_airaccel_sideways_friction 0
 426
 427                         float vel_straight;
 428                         float vel_z;
 429                         vector vel_perpend;
 430                         vel_straight = self.velocity * wishdir;
 431                         vel_z = self.velocity_z;
 432                         vel_perpend = self.velocity - vel_straight * wishdir - vel_z * '0 0 1';
 433
 434                         f = wishspeed - vel_straight;
 435                         if(f > 0)
 436                                 vel_straight = vel_straight + min(f, airaccel * frametime * wishspeed) * sv_airaccel_qw;
 437                         if(wishspeed > 0)
 438                                 vel_straight = vel_straight + min(wishspeed, airaccel * frametime * wishspeed) * (1 - sv_airaccel_qw);
 439
 440                         // anti-sideways friction to fix QW-style bunnyhopping
 441                         vel_perpend = vel_perpend * (1 - frametime * (wishspeed / maxairspd) * sv_airaccel_sideways_friction);
 442
 443                         self.velocity = vel_straight * wishdir + vel_z * '0 0 1' + vel_perpend;
 444
 445                         /*
 446                         f = wishspeed;// - (self.velocity * wishdir);
 447                         if (f > 0)
 448                                 self.velocity = self.velocity + wishdir * min(f, airaccel * frametime * wishspeed);
 449                         */
 450                 }
 451         }
 452
 453         if(self.flags & FL_ONGROUND)
 454                 self.lastground = time;
 455
 456         self.lastflags = self.flags;
 457 };