data/qcsrc/server/cl_physics.qc

   1 .float race_penalty;
   2 .float restart_jump;
   3
   4 float sv_accelerate;
   5 float sv_friction;
   6 float sv_maxspeed;
   7 float sv_airaccelerate;
   8 float sv_maxairspeed;
   9 float sv_stopspeed;
  10 float sv_gravity;
  11 float sv_airaccel_sideways_friction;
  12 float sv_airaccel_qw;
  13 float sv_airstopaccelerate;
  14 float sv_airstrafeaccelerate;
  15 float sv_maxairstrafespeed;
  16 float sv_aircontrol;
  17 float sv_warsowbunny_airforwardaccel;
  18 float sv_warsowbunny_accel;
  19 float sv_warsowbunny_topspeed;
  20 float sv_warsowbunny_turnaccel;
  21 float sv_warsowbunny_backtosideratio;
  22
  23 .float ladder_time;
  24 .entity ladder_entity;
  25 .float gravity;
  26 .float swamp_slowdown;
  27 .float lastflags;
  28 .float lastground;
  29 .float wasFlying;
  30 .float spectatorspeed;
  31
  32 #define SHTEST_DELTA 10
  33 #define SHTEST_THRESHOLD 1.1
  34 .float shtest_next;
  35 .float shtest_accumulator;
  36 .float doublejump_nextjumptime;
  37
  38 /*
  39 =============
  40 PlayerJump
  41
  42 When you press the jump key
  43 =============
  44 */
  45 void PlayerJump (void)
  46 {
  47         float mjumpheight;
  48
  49         mjumpheight = cvar("sv_jumpvelocity");
  50         if (self.waterlevel >= WATERLEVEL_SWIMMING)
  51         {
  52                 if (self.watertype == CONTENT_WATER)
  53                         self.velocity_z = 200;
  54                 else if (self.watertype == CONTENT_SLIME)
  55                         self.velocity_z = 80;
  56                 else
  57                         self.velocity_z = 50;
  58
  59                 return;
  60         }
  61
  62         if (!(self.flags & FL_ONGROUND))
  63                 return;
  64
  65         if(!sv_pogostick)
  66                 if (!(self.flags & FL_JUMPRELEASED))
  67                         return;
  68
  69         if(self.health <= g_bloodloss)
  70                 return;
  71
  72         if(sv_doublejump)
  73                 if(time < self.doublejump_nextjumptime)
  74                         return;
  75
  76         if(g_runematch)
  77         {
  78                 if(self.runes & RUNE_SPEED)
  79                 {
  80                         if(self.runes & CURSE_SLOW)
  81                                 mjumpheight = mjumpheight * cvar("g_balance_rune_speed_combo_jumpheight");
  82                         else
  83                                 mjumpheight = mjumpheight * cvar("g_balance_rune_speed_jumpheight");
  84                 }
  85                 else if(self.runes & CURSE_SLOW)
  86                 {
  87                         mjumpheight = mjumpheight * cvar("g_balance_curse_slow_jumpheight");
  88                 }
  89         }
  90
  91         if(g_minstagib && (self.items & IT_INVINCIBLE))
  92         {
  93                 mjumpheight = mjumpheight * cvar("g_minstagib_speed_jumpheight");
  94         }
  95
  96         if(!(self.lastflags & FL_ONGROUND))
  97         {
  98                 if(cvar("speedmeter"))
  99                         dprint(strcat("landing velocity: ", vtos(self.velocity), " (abs: ", ftos(vlen(self.velocity)), ")\n"));
 100                 if(self.lastground < time - 0.3)
 101                         self.velocity = self.velocity * (1 - cvar("sv_friction_on_land"));
 102                 if(self.jumppadcount > 1)
 103                         dprint(strcat(ftos(self.jumppadcount), "x jumppad combo\n"));
 104                 self.jumppadcount = 0;
 105         }
 106
 107         self.velocity_z = self.velocity_z + mjumpheight;
 108         self.oldvelocity_z = self.velocity_z;
 109
 110         self.flags &~= FL_ONGROUND;
 111         self.flags &~= FL_JUMPRELEASED;
 112
 113         if (self.crouch)
 114                 setanim(self, self.anim_duckjump, FALSE, TRUE, TRUE);
 115         else
 116                 setanim(self, self.anim_jump, FALSE, TRUE, TRUE);
 117
 118         if(g_jump_grunt)
 119                 PlayerSound(playersound_jump, CHAN_PLAYER, VOICETYPE_PLAYERSOUND);
 120
 121         if(sv_doublejump)
 122         {
 123                 // we're moving upwards at self.velocity_z
 124                 // only allow jumping after we got 3 units upwards
 125                 // so we for sure leave the FL_ONGROUND check
 126                 //
 127                 // but as this sucks because of factoring in gravity, we'll just do it
 128                 // for 4 units, and constant velocity
 129                 self.doublejump_nextjumptime = time + 4 / max(40, self.velocity_z); // max 0.1s blocking of jumps
 130         }
 131
 132         self.restart_jump = -1; // restart jump anim next time
 133         // value -1 is used to not use the teleport bit (workaround for tiny hitch when re-jumping)
 134 }
 135
 136 void CheckWaterJump()
 137 {
 138         local vector start, end;
 139
 140 // check for a jump-out-of-water
 141         makevectors (self.angles);
 142         start = self.origin;
 143         start_z = start_z + 8;
 144         v_forward_z = 0;
 145         normalize(v_forward);
 146         end = start + v_forward*24;
 147         traceline (start, end, TRUE, self);
 148         if (trace_fraction < 1)
 149         {       // solid at waist
 150                 start_z = start_z + self.maxs_z - 8;
 151                 end = start + v_forward*24;
 152                 self.movedir = trace_plane_normal * -50;
 153                 traceline (start, end, TRUE, self);
 154                 if (trace_fraction == 1)
 155                 {       // open at eye level
 156                         self.flags |= FL_WATERJUMP;
 157                         self.velocity_z = 225;
 158                         self.flags &~= FL_JUMPRELEASED;
 159                         self.teleport_time = time + 2;  // safety net
 160                         return;
 161                 }
 162         }
 163 };
 164
 165 float racecar_angle(float forward, float down)
 166 {
 167         float ret, angle_mult;
 168
 169         if(forward < 0)
 170         {
 171                 forward = -forward;
 172                 down = -down;
 173         }
 174
 175         ret = vectoyaw('0 1 0' * down + '1 0 0' * forward);
 176
 177         angle_mult = forward / (800 + forward);
 178
 179         if(ret > 180)
 180                 return ret * angle_mult + 360 * (1 - angle_mult);
 181         else
 182                 return ret * angle_mult;
 183 }
 184
 185 void RaceCarPhysics()
 186 {
 187         // using this move type for "big rigs"
 188         // the engine does not push the entity!
 189
 190         float accel, steer, f;
 191         vector angles_save, rigvel;
 192
 193         angles_save = self.angles;
 194         accel = bound(-1, self.movement_x / sv_maxspeed, 1);
 195         steer = bound(-1, self.movement_y / sv_maxspeed, 1);
 196
 197         if(g_bugrigs_reverse_speeding)
 198         {
 199                 if(accel < 0)
 200                 {
 201                         // back accel is DIGITAL
 202                         // to prevent speedhack
 203                         if(accel < -0.5)
 204                                 accel = -1;
 205                         else
 206                                 accel = 0;
 207                 }
 208         }
 209
 210         self.angles_x = 0;
 211         self.angles_z = 0;
 212         makevectors(self.angles); // new forward direction!
 213
 214         if(self.flags & FL_ONGROUND || g_bugrigs_air_steering)
 215         {
 216                 float myspeed, upspeed, steerfactor, accelfactor;
 217
 218                 myspeed = self.velocity * v_forward;
 219                 upspeed = self.velocity * v_up;
 220
 221                 // responsiveness factor for steering and acceleration
 222                 f = 1 / (1 + pow(max(-myspeed, myspeed) / g_bugrigs_speed_ref, g_bugrigs_speed_pow));
 223                 //MAXIMA: f(v) := 1 / (1 + (v / g_bugrigs_speed_ref) ^ g_bugrigs_speed_pow);
 224
 225                 if(myspeed < 0 && g_bugrigs_reverse_spinning)
 226                         steerfactor = -myspeed * g_bugrigs_steer;
 227                 else
 228                         steerfactor = -myspeed * f * g_bugrigs_steer;
 229
 230                 if(myspeed < 0 && g_bugrigs_reverse_speeding)
 231                         accelfactor = g_bugrigs_accel;
 232                 else
 233                         accelfactor = f * g_bugrigs_accel;
 234                 //MAXIMA: accel(v) := f(v) * g_bugrigs_accel;
 235
 236                 if(accel < 0)
 237                 {
 238                         if(myspeed > 0)
 239                         {
 240                                 myspeed = max(0, myspeed - frametime * (g_bugrigs_friction_floor - g_bugrigs_friction_brake * accel));
 241                         }
 242                         else
 243                         {
 244                                 if(!g_bugrigs_reverse_speeding)
 245                                         myspeed = min(0, myspeed + frametime * g_bugrigs_friction_floor);
 246                         }
 247                 }
 248                 else
 249                 {
 250                         if(myspeed >= 0)
 251                         {
 252                                 myspeed = max(0, myspeed - frametime * g_bugrigs_friction_floor);
 253                         }
 254                         else
 255                         {
 256                                 if(g_bugrigs_reverse_stopping)
 257                                         myspeed = 0;
 258                                 else
 259                                         myspeed = min(0, myspeed + frametime * (g_bugrigs_friction_floor + g_bugrigs_friction_brake * accel));
 260                         }
 261                 }
 262                 // terminal velocity = velocity at which 50 == accelfactor, that is, 1549 units/sec
 263                 //MAXIMA: friction(v) := g_bugrigs_friction_floor;
 264
 265                 self.angles_y += steer * frametime * steerfactor; // apply steering
 266                 makevectors(self.angles); // new forward direction!
 267
 268                 myspeed += accel * accelfactor * frametime;
 269
 270                 rigvel = myspeed * v_forward + '0 0 1' * upspeed;
 271         }
 272         else
 273         {
 274                 myspeed = vlen(self.velocity);
 275
 276                 // responsiveness factor for steering and acceleration
 277                 f = 1 / (1 + pow(max(0, myspeed / g_bugrigs_speed_ref), g_bugrigs_speed_pow));
 278                 steerfactor = -myspeed * f;
 279                 self.angles_y += steer * frametime * steerfactor; // apply steering
 280
 281                 rigvel = self.velocity;
 282                 makevectors(self.angles); // new forward direction!
 283         }
 284
 285         rigvel = rigvel * max(0, 1 - vlen(rigvel) * g_bugrigs_friction_air * frametime);
 286         //MAXIMA: airfriction(v) := v * v * g_bugrigs_friction_air;
 287         //MAXIMA: total_acceleration(v) := accel(v) - friction(v) - airfriction(v);
 288         //MAXIMA: solve(total_acceleration(v) = 0, v);
 289
 290         if(g_bugrigs_planar_movement)
 291         {
 292                 vector rigvel_xy, neworigin, up;
 293                 float mt;
 294
 295                 rigvel_z -= frametime * sv_gravity; // 4x gravity plays better
 296                 rigvel_xy = rigvel;
 297                 rigvel_xy_z = 0;
 298
 299                 if(g_bugrigs_planar_movement_car_jumping && !g_touchexplode) // touchexplode is a better way to handle collisions
 300                         mt = MOVE_NORMAL;
 301                 else
 302                         mt = MOVE_NOMONSTERS;
 303
 304                 tracebox(self.origin, self.mins, self.maxs, self.origin + '0 0 1024', mt, self);
 305                 up = trace_endpos - self.origin;
 306
 307                 // BUG RIGS: align the move to the surface instead of doing collision testing
 308                 // can we move?
 309                 tracebox(trace_endpos, self.mins, self.maxs, trace_endpos + rigvel_xy * frametime, mt, self);
 310
 311                 // align to surface
 312                 tracebox(trace_endpos, self.mins, self.maxs, trace_endpos - up + '0 0 1' * rigvel_z * frametime, mt, self);
 313
 314                 if(trace_fraction < 0.5)
 315                 {
 316                         trace_fraction = 1;
 317                         neworigin = self.origin;
 318                 }
 319                 else
 320                         neworigin = trace_endpos;
 321
 322                 if(trace_fraction < 1)
 323                 {
 324                         // now set angles_x so that the car points parallel to the surface
 325                         self.angles = vectoangles(
 326                                         '1 0 0' * v_forward_x * trace_plane_normal_z
 327                                         +
 328                                         '0 1 0' * v_forward_y * trace_plane_normal_z
 329                                         +
 330                                         '0 0 1' * -(v_forward_x * trace_plane_normal_x + v_forward_y * trace_plane_normal_y)
 331                                         );
 332                         self.flags |= FL_ONGROUND;
 333                 }
 334                 else
 335                 {
 336                         // now set angles_x so that the car points forward, but is tilted in velocity direction
 337                         self.flags &~= FL_ONGROUND;
 338                 }
 339
 340                 self.velocity = (neworigin - self.origin) * (1.0 / frametime);
 341                 self.movetype = MOVETYPE_NOCLIP;
 342         }
 343         else
 344         {
 345                 rigvel_z -= frametime * sv_gravity; // 4x gravity plays better
 346                 self.velocity = rigvel;
 347                 self.movetype = MOVETYPE_FLY;
 348         }
 349
 350         trace_fraction = 1;
 351         tracebox(self.origin, self.mins, self.maxs, self.origin - '0 0 4', MOVE_NORMAL, self);
 352         if(trace_fraction != 1)
 353         {
 354                 self.angles = vectoangles2(
 355                                 '1 0 0' * v_forward_x * trace_plane_normal_z
 356                                 +
 357                                 '0 1 0' * v_forward_y * trace_plane_normal_z
 358                                 +
 359                                 '0 0 1' * -(v_forward_x * trace_plane_normal_x + v_forward_y * trace_plane_normal_y),
 360                                 trace_plane_normal
 361                                 );
 362         }
 363         else
 364         {
 365                 vector vel_local;
 366
 367                 vel_local_x = v_forward * self.velocity;
 368                 vel_local_y = v_right * self.velocity;
 369                 vel_local_z = v_up * self.velocity;
 370
 371                 self.angles_x = racecar_angle(vel_local_x, vel_local_z);
 372                 self.angles_z = racecar_angle(-vel_local_y, vel_local_z);
 373         }
 374
 375         // smooth the angles
 376         vector vf1, vu1, smoothangles;
 377         makevectors(self.angles);
 378         f = bound(0, frametime * g_bugrigs_angle_smoothing, 1);
 379         if(f == 0)
 380                 f = 1;
 381         vf1 = v_forward * f;
 382         vu1 = v_up * f;
 383         makevectors(angles_save);
 384         vf1 = vf1 + v_forward * (1 - f);
 385         vu1 = vu1 + v_up * (1 - f);
 386         smoothangles = vectoangles2(vf1, vu1);
 387         self.angles_x = -smoothangles_x;
 388         self.angles_z =  smoothangles_z;
 389 }
 390
 391 void CPM_PM_Aircontrol(vector wishdir, float wishspeed)
 392 {
 393         float zspeed, xyspeed, dot, k;
 394
 395         if(self.movement_x == 0 || self.movement_y != 0)
 396                 return; // can't control movement if not moving forward or backward
 397
 398         zspeed = self.velocity_z;
 399         self.velocity_z = 0;
 400         xyspeed = vlen(self.velocity);
 401         self.velocity = normalize(self.velocity);
 402
 403         dot = self.velocity * wishdir;
 404         k = 32;
 405         k *= sv_aircontrol*dot*dot*frametime;
 406
 407         if(dot > 0) // we can't change direction while slowing down
 408                 self.velocity = normalize(self.velocity * xyspeed + wishdir * k);
 409
 410         self.velocity = self.velocity * xyspeed;
 411         self.velocity_z = zspeed;
 412 }
 413
 414 void PM_Accelerate(vector wishdir, float wishspeed, float wishspeed0, float accel, float accelqw, float sidefric)
 415 {
 416         float vel_straight;
 417         float vel_z;
 418         vector vel_perpend;
 419         float addspeed;
 420         float savespeed;
 421
 422         if(cvar("sv_gameplayfix_q2airaccelerate"))
 423                 wishspeed0 = wishspeed;
 424
 425         savespeed = self.velocity * self.velocity;
 426
 427         vel_straight = self.velocity * wishdir;
 428         vel_z = self.velocity_z;
 429         vel_perpend = self.velocity - vel_straight * wishdir - vel_z * '0 0 1';
 430
 431         addspeed = wishspeed - vel_straight;
 432         if(addspeed > 0)
 433                 vel_straight = vel_straight + min(addspeed, accel * frametime * wishspeed0) * accelqw;
 434         if(wishspeed > 0)
 435                 vel_straight = vel_straight + min(wishspeed, accel * frametime * wishspeed0) * (1 - accelqw);
 436
 437         if(sidefric < 0 && (vel_perpend*vel_perpend))
 438         {
 439                 float f, fmin;
 440                 f = (1 + frametime * wishspeed * sidefric);
 441                 fmin = (savespeed - vel_straight*vel_straight) / (vel_perpend*vel_perpend);
 442                 if(fmin <= 0)
 443                         vel_perpend = vel_perpend * f;
 444                 else
 445                         vel_perpend = vel_perpend * min(1, max(fmin, f));
 446         }
 447         else
 448                 vel_perpend = vel_perpend * (1 - frametime * wishspeed * sidefric);
 449
 450         self.velocity = vel_straight * wishdir + vel_z * '0 0 1' + vel_perpend;
 451 }
 452
 453 void PM_AirAccelerate(vector wishdir, float wishspeed)
 454 {
 455         vector curvel, wishvel, acceldir, curdir;
 456         float addspeed, accelspeed, curspeed, f;
 457         float dot;
 458
 459         if(wishspeed == 0)
 460                 return;
 461
 462         curvel = self.velocity;
 463         curvel_z = 0;
 464         curspeed = vlen(curvel);
 465
 466         if(wishspeed > curspeed * 1.01)
 467         {
 468                 wishspeed = min(wishspeed, curspeed + sv_warsowbunny_airforwardaccel * sv_maxspeed * frametime);
 469         }
 470         else
 471         {
 472                 f = max(0, (sv_warsowbunny_topspeed - curspeed) / (sv_warsowbunny_topspeed - sv_maxspeed));
 473                 wishspeed = max(curspeed, sv_maxspeed) + sv_warsowbunny_accel * f * sv_maxspeed * frametime;
 474         }
 475         wishvel = wishdir * wishspeed;
 476         acceldir = wishvel - curvel;
 477         addspeed = vlen(acceldir);
 478         acceldir = normalize(acceldir);
 479
 480         accelspeed = min(addspeed, sv_warsowbunny_turnaccel * sv_maxspeed * frametime);
 481
 482         if(sv_warsowbunny_backtosideratio < 1)
 483         {
 484                 curdir = normalize(curvel);
 485                 dot = acceldir * curdir;
 486                 if(dot < 0)
 487                         acceldir = acceldir - (1 - sv_warsowbunny_backtosideratio) * dot * curdir;
 488         }
 489
 490         self.velocity += accelspeed * acceldir;
 491 }
 492
 493 .vector movement_old;
 494 .float buttons_old;
 495 .vector v_angle_old;
 496 .string lastclassname;
 497
 498 void Nixnex_GiveCurrentWeapon();
 499 .float() PlayerPhysplug;
 500
 501 string specialcommand = "xwxwxsxsxaxdxaxdx1x ";
 502 .float specialcommand_pos;
 503 void SpecialCommand()
 504 {
 505 #ifdef TETRIS
 506         TetrisImpulse();
 507 #else
 508         if(sv_cheats || self.maycheat)
 509                 self.impulse = 99;
 510         else
 511                 print("A hollow voice says \"Plugh\".\n");
 512 #endif
 513 }
 514
 515 float speedaward_speed;
 516 string speedaward_holder;
 517 void race_send_speedaward(float msg)
 518 {
 519         // send the best speed of the round
 520         WriteByte(msg, SVC_TEMPENTITY);
 521         WriteByte(msg, TE_CSQC_RACE);
 522         WriteByte(msg, RACE_NET_SPEED_AWARD);
 523         WriteShort(msg, floor(speedaward_speed+0.5));
 524         WriteString(msg, speedaward_holder);
 525 }
 526
 527 float speedaward_alltimebest;
 528 string speedaward_alltimebest_holder;
 529 void race_send_speedaward_alltimebest(float msg)
 530 {
 531         // send the best speed
 532         WriteByte(msg, SVC_TEMPENTITY);
 533         WriteByte(msg, TE_CSQC_RACE);
 534         WriteByte(msg, RACE_NET_SPEED_AWARD_BEST);
 535         WriteShort(msg, floor(speedaward_alltimebest+0.5));
 536         WriteString(msg, speedaward_alltimebest_holder);
 537 }
 538
 539 string GetMapname(void);
 540 float speedaward_lastupdate;
 541 float speedaward_lastsent;
 542 void SV_PlayerPhysics()
 543 {
 544         local vector wishvel, wishdir, v;
 545         local float wishspeed, f, maxspd_mod, spd, maxairspd, airaccel, swampspd_mod, shtest_score, buttons;
 546         string temps;
 547         float buttons_prev;
 548         float not_allowed_to_move;
 549         string c;
 550
 551     if(self.PlayerPhysplug)
 552         if(self.PlayerPhysplug())
 553             return;
 554
 555         if(g_race || g_cts)
 556         {
 557                 // if record times matter
 558                 // ensure nothing EVIL is being done (i.e. strafebot)
 559                 // this hinders joystick users though
 560                 // but it still gives SOME analog control
 561                 // TODO implement this for engine cl_movement code too (basically, clipping to the four axes)
 562                 wishvel_x = fabs(self.movement_x);
 563                 wishvel_y = fabs(self.movement_y);
 564                 if(wishvel_x != 0 && wishvel_y != 0 && wishvel_x != wishvel_y)
 565                 {
 566                         wishvel_z = 0;
 567                         wishspeed = vlen(wishvel);
 568                         if(wishvel_x >= 2 * wishvel_y)
 569                         {
 570                                 // pure X motion
 571                                 if(self.movement_x > 0)
 572                                         self.movement_x = wishspeed;
 573                                 else
 574                                         self.movement_x = -wishspeed;
 575                                 self.movement_y = 0;
 576                         }
 577                         else if(wishvel_y >= 2 * wishvel_x)
 578                         {
 579                                 // pure Y motion
 580                                 self.movement_x = 0;
 581                                 if(self.movement_y > 0)
 582                                         self.movement_y = wishspeed;
 583                                 else
 584                                         self.movement_y = -wishspeed;
 585                         }
 586                         else
 587                         {
 588                                 // diagonal
 589                                 if(self.movement_x > 0)
 590                                         self.movement_x = 0.70710678118654752440 * wishspeed;
 591                                 else
 592                                         self.movement_x = -0.70710678118654752440 * wishspeed;
 593                                 if(self.movement_y > 0)
 594                                         self.movement_y = 0.70710678118654752440 * wishspeed;
 595                                 else
 596                                         self.movement_y = -0.70710678118654752440 * wishspeed;
 597                         }
 598                 }
 599         }
 600
 601         self.race_movetime_frac += frametime;
 602         f = floor(self.race_movetime_frac);
 603         self.race_movetime_frac -= f;
 604         self.race_movetime_count += f;
 605         self.race_movetime = self.race_movetime_frac + self.race_movetime_count;
 606
 607         buttons = self.BUTTON_ATCK + 2 * self.BUTTON_JUMP + 4 * self.BUTTON_ATCK2 + 8 * self.BUTTON_ZOOM + 16 * self.BUTTON_CROUCH + 32 * self.BUTTON_HOOK + 64 * self.BUTTON_USE + 128 * (self.movement_x < 0) + 256 * (self.movement_x > 0) + 512 * (self.movement_y < 0) + 1024 * (self.movement_y > 0);
 608
 609         if(!buttons)
 610                 c = "x";
 611         else if(buttons == 1)
 612                 c = "1";
 613         else if(buttons == 2)
 614                 c = " ";
 615         else if(buttons == 128)
 616                 c = "s";
 617         else if(buttons == 256)
 618                 c = "w";
 619         else if(buttons == 512)
 620                 c = "a";
 621         else if(buttons == 1024)
 622                 c = "d";
 623         else
 624                 c = "?";
 625
 626         if(c == substring(specialcommand, self.specialcommand_pos, 1))
 627         {
 628                 self.specialcommand_pos += 1;
 629                 if(self.specialcommand_pos >= strlen(specialcommand))
 630                 {
 631                         self.specialcommand_pos = 0;
 632                         SpecialCommand();
 633                         return;
 634                 }
 635         }
 636         else if(self.specialcommand_pos && (c != substring(specialcommand, self.specialcommand_pos - 1, 1)))
 637                 self.specialcommand_pos = 0;
 638
 639         if(!sv_maxidle_spectatorsareidle || self.movetype == MOVETYPE_WALK)
 640         {
 641                 if(buttons != self.buttons_old || self.movement != self.movement_old || self.v_angle != self.v_angle_old)
 642                         self.parm_idlesince = time;
 643         }
 644         buttons_prev = self.buttons_old;
 645         self.buttons_old = buttons;
 646         self.movement_old = self.movement;
 647         self.v_angle_old = self.v_angle;
 648
 649         if(time < self.nickspamtime)
 650         if(self.nickspamcount >= cvar("g_nick_flood_penalty_yellow"))
 651         {
 652                 // slight annoyance for nick change scripts
 653                 self.movement = -1 * self.movement;
 654                 self.BUTTON_ATCK = self.BUTTON_JUMP = self.BUTTON_ATCK2 = self.BUTTON_ZOOM = self.BUTTON_CROUCH = self.BUTTON_HOOK = self.BUTTON_USE = 0;
 655
 656                 if(self.nickspamcount >= cvar("g_nick_flood_penalty_red")) // if you are persistent and the slight annoyance above does not stop you, I'll show you!
 657                 {
 658                         self.angles_x = random() * 360;
 659                         self.angles_y = random() * 360;
 660                         // at least I'm not forcing retardedview by also assigning to angles_z
 661                         self.fixangle = 1;
 662                 }
 663         }
 664
 665         if(time > self.shtest_next)
 666         {
 667                 if(self.shtest_next > 0)
 668                 {
 669                         // self.shtest_accumulator:
 670                         //   started at time - SHTEST_DELTA
 671                         //   should be at SHTEST_DELTA
 672                         shtest_score = self.shtest_accumulator / (SHTEST_DELTA + time - self.shtest_next);
 673                         if(shtest_score > SHTEST_THRESHOLD)
 674                                 print("TIME PARADOX: shtest for ", self.netname, " said ", ftos(shtest_score), "\n");
 675                         else if(cvar("developer_shtest"))
 676                                 dprint("okay: shtest for ", self.netname, " said ", ftos(shtest_score), "\n");
 677                 }
 678                 self.shtest_next = time + SHTEST_DELTA;
 679                 self.shtest_accumulator = 0;
 680         }
 681         self.shtest_accumulator += frametime;
 682
 683         if (clienttype(self) == CLIENTTYPE_BOT)
 684                 bot_think();
 685
 686         self.items &~= IT_USING_JETPACK;
 687
 688         if(self.classname == "player")
 689         {
 690                 if(self.race_penalty)
 691                         if(time > self.race_penalty)
 692                                 self.race_penalty = 0;
 693
 694                 not_allowed_to_move = 0;
 695                 if(self.race_penalty)
 696                         not_allowed_to_move = 1;
 697                 if(!cvar("sv_ready_restart_after_countdown"))
 698                 if(time < game_starttime)
 699                         not_allowed_to_move = 1;
 700
 701                 if(not_allowed_to_move)
 702                 {
 703                         self.velocity = '0 0 0';
 704                         self.movetype = MOVETYPE_NONE;
 705                         self.disableclientprediction = 2;
 706                 }
 707                 else if(self.disableclientprediction == 2)
 708                 {
 709                         if(self.movetype == MOVETYPE_NONE)
 710                                 self.movetype = MOVETYPE_WALK;
 711                         self.disableclientprediction = 0;
 712                 }
 713         }
 714
 715         if (self.movetype == MOVETYPE_NONE)
 716                 return;
 717
 718         if (self.punchangle != '0 0 0')
 719         {
 720                 f = vlen(self.punchangle) - 10 * frametime;
 721                 if (f > 0)
 722                         self.punchangle = normalize(self.punchangle) * f;
 723                 else
 724                         self.punchangle = '0 0 0';
 725         }
 726
 727         if (self.punchvector != '0 0 0')
 728         {
 729                 f = vlen(self.punchvector) - 30 * frametime;
 730                 if (f > 0)
 731                         self.punchvector = normalize(self.punchvector) * f;
 732                 else
 733                         self.punchvector = '0 0 0';
 734         }
 735
 736         maxspd_mod = 1;
 737
 738         if(g_runematch)
 739         {
 740                 if(self.runes & RUNE_SPEED)
 741                 {
 742                         if(self.runes & CURSE_SLOW)
 743                                 maxspd_mod = maxspd_mod * cvar("g_balance_rune_speed_combo_moverate");
 744                         else
 745                                 maxspd_mod = maxspd_mod * cvar("g_balance_rune_speed_moverate");
 746                 }
 747                 else if(self.runes & CURSE_SLOW)
 748                 {
 749                         maxspd_mod = maxspd_mod * cvar("g_balance_curse_slow_moverate");
 750                 }
 751         }
 752
 753         if(g_minstagib && (self.items & IT_INVINCIBLE))
 754         {
 755                 maxspd_mod = cvar("g_minstagib_speed_moverate");
 756         }
 757
 758         if(g_nexball && self.ballcarried)
 759         {
 760                 maxspd_mod = cvar("g_nexball_basketball_carrier_speed");
 761         }
 762
 763         swampspd_mod = 1;
 764         if(self.in_swamp) {
 765                 swampspd_mod = self.swamp_slowdown; //cvar("g_balance_swamp_moverate");
 766         }
 767
 768         if(self.classname != "player")
 769         {
 770                 maxspd_mod = cvar("sv_spectator_speed_multiplier");
 771                 if(!self.spectatorspeed)
 772                         self.spectatorspeed = maxspd_mod;
 773                 if(self.impulse && self.impulse <= 19)
 774                 {
 775                         if(self.lastclassname != "player")
 776                         {
 777                                 if(self.impulse == 10 || self.impulse == 15 || self.impulse == 18)
 778                                         self.spectatorspeed = bound(1, self.spectatorspeed + 0.5, 5);
 779                                 else if(self.impulse == 11)
 780                                         self.spectatorspeed = maxspd_mod;
 781                                 else if(self.impulse == 12 || self.impulse == 16  || self.impulse == 19)
 782                                         self.spectatorspeed = bound(1, self.spectatorspeed - 0.5, 5);
 783                                 else if(self.impulse >= 1 && self.impulse <= 9)
 784                                         self.spectatorspeed = 1 + 0.5 * (self.impulse - 1);
 785                         } // otherwise just clear
 786                         self.impulse = 0;
 787                 }
 788                 maxspd_mod = self.spectatorspeed;
 789         }
 790
 791         spd = max(sv_maxspeed, sv_maxairspeed) * maxspd_mod * swampspd_mod;
 792         if(self.speed != spd)
 793         {
 794                 self.speed = spd;
 795                 temps = ftos(spd);
 796                 stuffcmd(self, strcat("cl_forwardspeed ", temps, "\n"));
 797                 stuffcmd(self, strcat("cl_backspeed ", temps, "\n"));
 798                 stuffcmd(self, strcat("cl_sidespeed ", temps, "\n"));
 799                 stuffcmd(self, strcat("cl_upspeed ", temps, "\n"));
 800         }
 801
 802         maxspd_mod *= swampspd_mod; // only one common speed modder please!
 803         swampspd_mod = 1;
 804
 805         // if dead, behave differently
 806         if (self.deadflag)
 807                 goto end;
 808
 809         if (!self.fixangle && !g_bugrigs)
 810         {
 811                 self.angles_x = 0;
 812                 self.angles_y = self.v_angle_y;
 813                 self.angles_z = 0;
 814         }
 815
 816         if(self.flags & FL_ONGROUND)
 817         if(self.wasFlying)
 818         {
 819                 self.wasFlying = 0;
 820
 821                 if(self.waterlevel < WATERLEVEL_SWIMMING)
 822                 if(time >= self.ladder_time)
 823                 if not(self.hook)
 824                 {
 825                         self.nextstep = time + 0.3 + random() * 0.1;
 826                         trace_dphitq3surfaceflags = 0;
 827                         tracebox(self.origin, self.mins, self.maxs, self.origin - '0 0 1', MOVE_NOMONSTERS, self);
 828                         if not(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOSTEPS)
 829                         {
 830                                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_METALSTEPS)
 831                                         GlobalSound(globalsound_metalfall, CHAN_PLAYER, VOICETYPE_PLAYERSOUND);
 832                                 else
 833                                         GlobalSound(globalsound_fall, CHAN_PLAYER, VOICETYPE_PLAYERSOUND);
 834                         }
 835                 }
 836         }
 837
 838         if(IsFlying(self))
 839                 self.wasFlying = 1;
 840
 841         if(self.classname == "player")
 842         {
 843                 if(sv_doublejump)
 844                 {
 845                         self.flags &~= FL_ONGROUND;
 846                         tracebox(self.origin + '0 0 1', self.mins, self.maxs, self.origin - '0 0 1', MOVE_NORMAL, self);
 847                         if(trace_fraction < 1 && trace_plane_normal_z > 0.7)
 848                                 self.flags |= FL_ONGROUND;
 849                 }
 850
 851                 if (self.BUTTON_JUMP)
 852                         PlayerJump ();
 853                 else
 854                         self.flags |= FL_JUMPRELEASED;
 855
 856                 if (self.waterlevel == WATERLEVEL_SWIMMING)
 857                         CheckWaterJump ();
 858         }
 859
 860         if (self.flags & FL_WATERJUMP )
 861         {
 862                 self.velocity_x = self.movedir_x;
 863                 self.velocity_y = self.movedir_y;
 864                 if (time > self.teleport_time || self.waterlevel == WATERLEVEL_NONE)
 865                 {
 866                         self.flags &~= FL_WATERJUMP;
 867                         self.teleport_time = 0;
 868                 }
 869         }
 870         else if (g_bugrigs && self.classname == "player")
 871         {
 872                 RaceCarPhysics();
 873         }
 874         else if (self.movetype == MOVETYPE_NOCLIP || self.movetype == MOVETYPE_FLY)
 875         {
 876                 // noclipping or flying
 877                 self.flags &~= FL_ONGROUND;
 878
 879                 self.velocity = self.velocity * (1 - frametime * sv_friction);
 880                 makevectors(self.v_angle);
 881                 //wishvel = v_forward * self.movement_x + v_right * self.movement_y + v_up * self.movement_z;
 882                 wishvel = v_forward * self.movement_x + v_right * self.movement_y + '0 0 1' * self.movement_z;
 883                 // acceleration
 884                 wishdir = normalize(wishvel);
 885                 wishspeed = vlen(wishvel);
 886                 if (wishspeed > sv_maxspeed*maxspd_mod)
 887                         wishspeed = sv_maxspeed*maxspd_mod;
 888                 if (time >= self.teleport_time)
 889                         PM_Accelerate(wishdir, wishspeed, wishspeed, sv_accelerate*maxspd_mod, 1, 0);
 890         }
 891         else if (self.waterlevel >= WATERLEVEL_SWIMMING)
 892         {
 893                 // swimming
 894                 self.flags &~= FL_ONGROUND;
 895
 896                 makevectors(self.v_angle);
 897                 //wishvel = v_forward * self.movement_x + v_right * self.movement_y + v_up * self.movement_z;
 898                 wishvel = v_forward * self.movement_x + v_right * self.movement_y + '0 0 1' * self.movement_z;
 899                 if (wishvel == '0 0 0')
 900                         wishvel = '0 0 -60'; // drift towards bottom
 901
 902                 wishdir = normalize(wishvel);
 903                 wishspeed = vlen(wishvel);
 904                 if (wishspeed > sv_maxspeed*maxspd_mod)
 905                         wishspeed = sv_maxspeed*maxspd_mod;
 906                 wishspeed = wishspeed * 0.7;
 907
 908                 // water friction
 909                 self.velocity = self.velocity * (1 - frametime * sv_friction);
 910
 911                 // water acceleration
 912                 PM_Accelerate(wishdir, wishspeed, wishspeed, sv_accelerate*maxspd_mod, 1, 0);
 913         }
 914         else if (time < self.ladder_time)
 915         {
 916                 // on a spawnfunc_func_ladder or swimming in spawnfunc_func_water
 917                 self.flags &~= FL_ONGROUND;
 918
 919                 self.velocity = self.velocity * (1 - frametime * sv_friction);
 920                 makevectors(self.v_angle);
 921                 //wishvel = v_forward * self.movement_x + v_right * self.movement_y + v_up * self.movement_z;
 922                 wishvel = v_forward * self.movement_x + v_right * self.movement_y + '0 0 1' * self.movement_z;
 923                 if (self.gravity)
 924                         self.velocity_z = self.velocity_z + self.gravity * sv_gravity * frametime;
 925                 else
 926                         self.velocity_z = self.velocity_z + sv_gravity * frametime;
 927                 if (self.ladder_entity.classname == "func_water")
 928                 {
 929                         f = vlen(wishvel);
 930                         if (f > self.ladder_entity.speed)
 931                                 wishvel = wishvel * (self.ladder_entity.speed / f);
 932
 933                         self.watertype = self.ladder_entity.skin;
 934                         f = self.ladder_entity.origin_z + self.ladder_entity.maxs_z;
 935                         if ((self.origin_z + self.view_ofs_z) < f)
 936                                 self.waterlevel = WATERLEVEL_SUBMERGED;
 937                         else if ((self.origin_z + (self.mins_z + self.maxs_z) * 0.5) < f)
 938                                 self.waterlevel = WATERLEVEL_SWIMMING;
 939                         else if ((self.origin_z + self.mins_z + 1) < f)
 940                                 self.waterlevel = WATERLEVEL_WETFEET;
 941                         else
 942                         {
 943                                 self.waterlevel = WATERLEVEL_NONE;
 944                                 self.watertype = CONTENT_EMPTY;
 945                         }
 946                 }
 947                 // acceleration
 948                 wishdir = normalize(wishvel);
 949                 wishspeed = vlen(wishvel);
 950                 if (wishspeed > sv_maxspeed*maxspd_mod)
 951                         wishspeed = sv_maxspeed*maxspd_mod;
 952                 if (time >= self.teleport_time)
 953                 {
 954                         // water acceleration
 955                         PM_Accelerate(wishdir, wishspeed, wishspeed, sv_accelerate*maxspd_mod, 1, 0);
 956                 }
 957         }
 958         else if ((self.items & IT_JETPACK) && self.BUTTON_HOOK && (!cvar("g_jetpack_fuel") || self.ammo_fuel >= 0.01 || self.items & IT_UNLIMITED_WEAPON_AMMO))
 959         {
 960                 //makevectors(self.v_angle_y * '0 1 0');
 961                 makevectors(self.v_angle);
 962                 wishvel = v_forward * self.movement_x + v_right * self.movement_y;
 963                 // add remaining speed as Z component
 964                 maxairspd = sv_maxairspeed*max(1, maxspd_mod);
 965                 // fix speedhacks :P
 966                 wishvel = normalize(wishvel) * min(vlen(wishvel) / maxairspd, 1);
 967                 // add the unused velocity as up component
 968                 wishvel_z = 0;
 969
 970                 // if(self.BUTTON_JUMP)
 971                         wishvel_z = sqrt(max(0, 1 - wishvel * wishvel));
 972
 973                 // it is now normalized, so...
 974                 float a_side, a_up, a_add, a_diff;
 975                 a_side = cvar("g_jetpack_acceleration_side");
 976                 a_up = cvar("g_jetpack_acceleration_up");
 977                 a_add = cvar("g_jetpack_antigravity") * sv_gravity;
 978
 979                 wishvel_x *= a_side;
 980                 wishvel_y *= a_side;
 981                 wishvel_z *= a_up;
 982                 wishvel_z += a_add;
 983
 984                 float best;
 985                 best = 0;
 986                 //////////////////////////////////////////////////////////////////////////////////////
 987                 // finding the maximum over all vectors of above form
 988                 // with wishvel having an absolute value of 1
 989                 //////////////////////////////////////////////////////////////////////////////////////
 990                 // we're finding the maximum over
 991                 //   f(a_side, a_up, a_add, z) := a_side * (1 - z^2) + (a_add + a_up * z)^2;
 992                 // for z in the range from -1 to 1
 993                 //////////////////////////////////////////////////////////////////////////////////////
 994                 // maximum is EITHER attained at the single extreme point:
 995                 a_diff = a_side * a_side - a_up * a_up;
 996                 if(a_diff != 0)
 997                 {
 998                         f = a_add * a_up / a_diff; // this is the zero of diff(f(a_side, a_up, a_add, z), z)
 999                         if(f > -1 && f < 1) // can it be attained?
1000                         {
1001                                 best = (a_diff + a_add * a_add) * (a_diff + a_up * a_up) / a_diff;
1002                                 //print("middle\n");
1003                         }
1004                 }
1005                 // OR attained at z = 1:
1006                 f = (a_up + a_add) * (a_up + a_add);
1007                 if(f > best)
1008                 {
1009                         best = f;
1010                         //print("top\n");
1011                 }
1012                 // OR attained at z = -1:
1013                 f = (a_up - a_add) * (a_up - a_add);
1014                 if(f > best)
1015                 {
1016                         best = f;
1017                         //print("bottom\n");
1018                 }
1019                 best = sqrt(best);
1020                 //////////////////////////////////////////////////////////////////////////////////////
1021
1022                 //print("best possible acceleration: ", ftos(best), "\n");
1023
1024                 float fxy, fz;
1025                 fxy = bound(0, 1 - (self.velocity * normalize(wishvel_x * '1 0 0' + wishvel_y * '0 1 0')) / cvar("g_jetpack_maxspeed_side"), 1);
1026                 if(wishvel_z - sv_gravity > 0)
1027                         fz = bound(0, 1 - self.velocity_z / cvar("g_jetpack_maxspeed_up"), 1);
1028                 else
1029                         fz = bound(0, 1 + self.velocity_z / cvar("g_jetpack_maxspeed_up"), 1);
1030
1031                 float fvel;
1032                 fvel = vlen(wishvel);
1033                 wishvel_x *= fxy;
1034                 wishvel_y *= fxy;
1035                 wishvel_z = (wishvel_z - sv_gravity) * fz + sv_gravity;
1036
1037                 fvel = min(1, vlen(wishvel) / best);
1038                 if(cvar("g_jetpack_fuel") && !(self.items & IT_UNLIMITED_WEAPON_AMMO))
1039                         f = min(1, self.ammo_fuel / (cvar("g_jetpack_fuel") * frametime * fvel));
1040                 else
1041                         f = 1;
1042
1043                 //print("this acceleration: ", ftos(vlen(wishvel) * f), "\n");
1044
1045                 if (f > 0 && wishvel != '0 0 0')
1046                 {
1047                         self.velocity = self.velocity + wishvel * f * frametime;
1048                         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
1049                                 self.ammo_fuel -= cvar("g_jetpack_fuel") * frametime * fvel * f;
1050                         self.flags &~= FL_ONGROUND;
1051                         self.items |= IT_USING_JETPACK;
1052
1053                         // jetpack also inhibits health regeneration, but only for 1 second
1054                         self.pauseregen_finished = max(self.pauseregen_finished, time + cvar("g_balance_pause_fuel_regen"));
1055                 }
1056         }
1057         else if (self.flags & FL_ONGROUND)
1058         {
1059                 // we get here if we ran out of ammo
1060                 if((self.items & IT_JETPACK) && self.BUTTON_HOOK && !(buttons_prev & 32))
1061                         sprint(self, "You don't have any fuel for the ^2Jetpack\n");
1062
1063                 // walking
1064                 makevectors(self.v_angle_y * '0 1 0');
1065                 wishvel = v_forward * self.movement_x + v_right * self.movement_y;
1066
1067                 if(!(self.lastflags & FL_ONGROUND))
1068                 {
1069                         if(cvar("speedmeter"))
1070                                 dprint(strcat("landing velocity: ", vtos(self.velocity), " (abs: ", ftos(vlen(self.velocity)), ")\n"));
1071                         if(self.lastground < time - 0.3)
1072                                 self.velocity = self.velocity * (1 - cvar("sv_friction_on_land"));
1073                         if(self.jumppadcount > 1)
1074                                 dprint(strcat(ftos(self.jumppadcount), "x jumppad combo\n"));
1075                         self.jumppadcount = 0;
1076                 }
1077
1078 #ifdef LETS_TEST_FTEQCC
1079                 if(self.velocity_x || self.velocity_y)
1080                 {
1081                         // good
1082                 }
1083                 else
1084                 {
1085                         if(self.velocity_x)
1086                                 checkclient();
1087                         if(self.velocity_y)
1088                                 checkclient();
1089                 }
1090 #endif
1091
1092                 v = self.velocity;
1093                 v_z = 0;
1094                 f = vlen(v);
1095                 if(f > 0)
1096                 {
1097                         if (f < sv_stopspeed)
1098                                 f = 1 - frametime * (sv_stopspeed / f) * sv_friction;
1099                         else
1100                                 f = 1 - frametime * sv_friction;
1101                         if (f > 0)
1102                                 self.velocity = self.velocity * f;
1103                         else
1104                                 self.velocity = '0 0 0';
1105                 }
1106
1107                 // acceleration
1108                 wishdir = normalize(wishvel);
1109                 wishspeed = vlen(wishvel);
1110                 if (wishspeed > sv_maxspeed*maxspd_mod)
1111                         wishspeed = sv_maxspeed*maxspd_mod;
1112                 if (self.crouch)
1113                         wishspeed = wishspeed * 0.5;
1114                 if (time >= self.teleport_time)
1115                         PM_Accelerate(wishdir, wishspeed, wishspeed, sv_accelerate*maxspd_mod, 1, 0);
1116         }
1117         else
1118         {
1119                 float wishspeed0;
1120                 // we get here if we ran out of ammo
1121                 if((self.items & IT_JETPACK) && self.BUTTON_HOOK && !(buttons_prev & 32))
1122                         sprint(self, "You don't have any fuel for the ^2Jetpack\n");
1123
1124                 if(maxspd_mod < 1)
1125                 {
1126                         maxairspd = sv_maxairspeed*maxspd_mod;
1127                         airaccel = sv_airaccelerate*maxspd_mod;
1128                 }
1129                 else
1130                 {
1131                         maxairspd = sv_maxairspeed;
1132                         airaccel = sv_airaccelerate;
1133                 }
1134                 // airborn
1135                 makevectors(self.v_angle_y * '0 1 0');
1136                 wishvel = v_forward * self.movement_x + v_right * self.movement_y;
1137                 // acceleration
1138                 wishdir = normalize(wishvel);
1139                 wishspeed = wishspeed0 = vlen(wishvel);
1140                 if (wishspeed0 > sv_maxspeed*maxspd_mod)
1141                         wishspeed0 = sv_maxspeed*maxspd_mod;
1142                 if (wishspeed > maxairspd)
1143                         wishspeed = maxairspd;
1144                 if (self.crouch)
1145                         wishspeed = wishspeed * 0.5;
1146                 if (time >= self.teleport_time)
1147                 {
1148                         float accelerating;
1149                         float wishspeed2;
1150                         float airaccelqw;
1151
1152                         airaccelqw = sv_airaccel_qw;
1153                         accelerating = (self.velocity * wishdir > 0);
1154                         wishspeed2 = wishspeed;
1155
1156                         // CPM
1157                         if(sv_airstopaccelerate)
1158                                 if(self.velocity * wishdir < 0)
1159                                         airaccel = sv_airstopaccelerate*maxspd_mod;
1160                         if(self.movement_x == 0 && self.movement_y != 0)
1161                         {
1162                                 if(sv_maxairstrafespeed)
1163                                 {
1164                                         wishspeed = min(wishspeed, sv_maxairstrafespeed*maxspd_mod);
1165                                         if(sv_maxairstrafespeed < sv_maxairspeed)
1166                                                 airaccelqw = 1;
1167                                 }
1168                                 if(sv_airstrafeaccelerate)
1169                                 {
1170                                         airaccel = sv_airstrafeaccelerate*maxspd_mod;
1171                                         if(sv_airstrafeaccelerate > sv_airaccelerate)
1172                                                 airaccelqw = 1;
1173                                 }
1174                         }
1175                         // !CPM
1176
1177                         if(sv_warsowbunny_turnaccel && accelerating && self.movement_y == 0 && self.movement_x != 0)
1178                                 PM_AirAccelerate(wishdir, wishspeed);
1179                         else
1180                                 PM_Accelerate(wishdir, wishspeed, wishspeed0, airaccel, airaccelqw, sv_airaccel_sideways_friction / maxairspd);
1181
1182                         if(sv_aircontrol)
1183                                 CPM_PM_Aircontrol(wishdir, wishspeed2);
1184                 }
1185         }
1186
1187         if((g_cts || g_race) && self.classname != "observer") {
1188                 if(vlen(self.velocity - self.velocity_z * '0 0 1') > speedaward_speed) {
1189                         speedaward_speed = vlen(self.velocity - self.velocity_z * '0 0 1');
1190                         speedaward_holder = self.netname;
1191                         speedaward_lastupdate = time;
1192                 }
1193                 if(speedaward_speed > speedaward_lastsent && time - speedaward_lastupdate > 1) {
1194                         string rr;
1195                         if(g_cts)
1196                                 rr = CTS_RECORD;
1197                         else
1198                                 rr = RACE_RECORD;
1199                         race_send_speedaward(MSG_ALL);
1200                         speedaward_lastsent = speedaward_speed;
1201                         if (speedaward_speed > speedaward_alltimebest) {
1202                                 speedaward_alltimebest = speedaward_speed;
1203                                 speedaward_alltimebest_holder = speedaward_holder;
1204                                 db_put(ServerProgsDB, strcat(GetMapname(), rr, "speed/speed"), ftos(speedaward_alltimebest));
1205                                 db_put(ServerProgsDB, strcat(GetMapname(), rr, "speed/netname"), speedaward_alltimebest_holder);
1206                                 race_send_speedaward_alltimebest(MSG_ALL);
1207                         }
1208                 }
1209         }
1210 :end
1211         if(self.flags & FL_ONGROUND)
1212                 self.lastground = time;
1213
1214         self.lastflags = self.flags;
1215         self.lastclassname = self.classname;
1216 };