data/qcsrc/server/cl_physics.qc

   1 .float race_penalty;
   2 .float restart_jump;
   3
   4 float sv_accelerate;
   5 float sv_friction;
   6 float sv_maxspeed;
   7 float sv_airaccelerate;
   8 float sv_maxairspeed;
   9 float sv_stopspeed;
  10 float sv_gravity;
  11 float sv_airaccel_sideways_friction;
  12 float sv_airaccel_qw;
  13 float sv_airstopaccelerate;
  14 float sv_airstrafeaccelerate;
  15 float sv_maxairstrafespeed;
  16 float sv_aircontrol;
  17 float sv_warsowbunny_airforwardaccel;
  18 float sv_warsowbunny_accel;
  19 float sv_warsowbunny_topspeed;
  20 float sv_warsowbunny_turnaccel;
  21 float sv_warsowbunny_backtosideratio;
  22
  23 .float ladder_time;
  24 .entity ladder_entity;
  25 .float gravity;
  26 .float swamp_slowdown;
  27 .float lastflags;
  28 .float lastground;
  29 .float wasFlying;
  30 .float spectatorspeed;
  31
  32 .float doublejump_nextjumptime;
  33
  34 /*
  35 =============
  36 PlayerJump
  37
  38 When you press the jump key
  39 =============
  40 */
  41 void PlayerJump (void)
  42 {
  43         float mjumpheight;
  44
  45         mjumpheight = cvar("sv_jumpvelocity");
  46         if (self.waterlevel >= WATERLEVEL_SWIMMING)
  47         {
  48                 if (self.watertype == CONTENT_WATER)
  49                         self.velocity_z = 200;
  50                 else if (self.watertype == CONTENT_SLIME)
  51                         self.velocity_z = 80;
  52                 else
  53                         self.velocity_z = 50;
  54
  55                 return;
  56         }
  57
  58         if (!(self.flags & FL_ONGROUND))
  59                 return;
  60
  61         if(!sv_pogostick)
  62                 if (!(self.flags & FL_JUMPRELEASED))
  63                         return;
  64
  65         if(self.health <= g_bloodloss)
  66                 return;
  67
  68         if(sv_doublejump)
  69                 if(time < self.doublejump_nextjumptime)
  70                         return;
  71
  72         if(g_runematch)
  73         {
  74                 if(self.runes & RUNE_SPEED)
  75                 {
  76                         if(self.runes & CURSE_SLOW)
  77                                 mjumpheight = mjumpheight * cvar("g_balance_rune_speed_combo_jumpheight");
  78                         else
  79                                 mjumpheight = mjumpheight * cvar("g_balance_rune_speed_jumpheight");
  80                 }
  81                 else if(self.runes & CURSE_SLOW)
  82                 {
  83                         mjumpheight = mjumpheight * cvar("g_balance_curse_slow_jumpheight");
  84                 }
  85         }
  86
  87         if(g_minstagib && (self.items & IT_INVINCIBLE))
  88         {
  89                 mjumpheight = mjumpheight * cvar("g_minstagib_speed_jumpheight");
  90         }
  91
  92         if(!(self.lastflags & FL_ONGROUND))
  93         {
  94                 if(cvar("speedmeter"))
  95                         dprint(strcat("landing velocity: ", vtos(self.velocity), " (abs: ", ftos(vlen(self.velocity)), ")\n"));
  96                 if(self.lastground < time - 0.3)
  97                         self.velocity = self.velocity * (1 - cvar("sv_friction_on_land"));
  98                 if(self.jumppadcount > 1)
  99                         dprint(strcat(ftos(self.jumppadcount), "x jumppad combo\n"));
 100                 self.jumppadcount = 0;
 101         }
 102
 103         self.velocity_z = self.velocity_z + mjumpheight;
 104         self.oldvelocity_z = self.velocity_z;
 105
 106         self.flags &~= FL_ONGROUND;
 107         self.flags &~= FL_JUMPRELEASED;
 108
 109         if (self.crouch)
 110                 setanim(self, self.anim_duckjump, FALSE, TRUE, TRUE);
 111         else
 112                 setanim(self, self.anim_jump, FALSE, TRUE, TRUE);
 113
 114         if(g_jump_grunt)
 115                 PlayerSound(playersound_jump, CHAN_PLAYER, VOICETYPE_PLAYERSOUND);
 116
 117         if(sv_doublejump)
 118         {
 119                 // we're moving upwards at self.velocity_z
 120                 // only allow jumping after we got 3 units upwards
 121                 // so we for sure leave the FL_ONGROUND check
 122                 //
 123                 // but as this sucks because of factoring in gravity, we'll just do it
 124                 // for 4 units, and constant velocity
 125                 self.doublejump_nextjumptime = time + 4 / max(40, self.velocity_z); // max 0.1s blocking of jumps
 126         }
 127
 128         self.restart_jump = -1; // restart jump anim next time
 129         // value -1 is used to not use the teleport bit (workaround for tiny hitch when re-jumping)
 130 }
 131
 132 void CheckWaterJump()
 133 {
 134         local vector start, end;
 135
 136 // check for a jump-out-of-water
 137         makevectors (self.angles);
 138         start = self.origin;
 139         start_z = start_z + 8;
 140         v_forward_z = 0;
 141         normalize(v_forward);
 142         end = start + v_forward*24;
 143         traceline (start, end, TRUE, self);
 144         if (trace_fraction < 1)
 145         {       // solid at waist
 146                 start_z = start_z + self.maxs_z - 8;
 147                 end = start + v_forward*24;
 148                 self.movedir = trace_plane_normal * -50;
 149                 traceline (start, end, TRUE, self);
 150                 if (trace_fraction == 1)
 151                 {       // open at eye level
 152                         self.flags |= FL_WATERJUMP;
 153                         self.velocity_z = 225;
 154                         self.flags &~= FL_JUMPRELEASED;
 155                         self.teleport_time = time + 2;  // safety net
 156                         return;
 157                 }
 158         }
 159 };
 160
 161 float racecar_angle(float forward, float down)
 162 {
 163         float ret, angle_mult;
 164
 165         if(forward < 0)
 166         {
 167                 forward = -forward;
 168                 down = -down;
 169         }
 170
 171         ret = vectoyaw('0 1 0' * down + '1 0 0' * forward);
 172
 173         angle_mult = forward / (800 + forward);
 174
 175         if(ret > 180)
 176                 return ret * angle_mult + 360 * (1 - angle_mult);
 177         else
 178                 return ret * angle_mult;
 179 }
 180
 181 void RaceCarPhysics()
 182 {
 183         // using this move type for "big rigs"
 184         // the engine does not push the entity!
 185
 186         float accel, steer, f;
 187         vector angles_save, rigvel;
 188
 189         angles_save = self.angles;
 190         accel = bound(-1, self.movement_x / sv_maxspeed, 1);
 191         steer = bound(-1, self.movement_y / sv_maxspeed, 1);
 192
 193         if(g_bugrigs_reverse_speeding)
 194         {
 195                 if(accel < 0)
 196                 {
 197                         // back accel is DIGITAL
 198                         // to prevent speedhack
 199                         if(accel < -0.5)
 200                                 accel = -1;
 201                         else
 202                                 accel = 0;
 203                 }
 204         }
 205
 206         self.angles_x = 0;
 207         self.angles_z = 0;
 208         makevectors(self.angles); // new forward direction!
 209
 210         if(self.flags & FL_ONGROUND || g_bugrigs_air_steering)
 211         {
 212                 float myspeed, upspeed, steerfactor, accelfactor;
 213
 214                 myspeed = self.velocity * v_forward;
 215                 upspeed = self.velocity * v_up;
 216
 217                 // responsiveness factor for steering and acceleration
 218                 f = 1 / (1 + pow(max(-myspeed, myspeed) / g_bugrigs_speed_ref, g_bugrigs_speed_pow));
 219                 //MAXIMA: f(v) := 1 / (1 + (v / g_bugrigs_speed_ref) ^ g_bugrigs_speed_pow);
 220
 221                 if(myspeed < 0 && g_bugrigs_reverse_spinning)
 222                         steerfactor = -myspeed * g_bugrigs_steer;
 223                 else
 224                         steerfactor = -myspeed * f * g_bugrigs_steer;
 225
 226                 if(myspeed < 0 && g_bugrigs_reverse_speeding)
 227                         accelfactor = g_bugrigs_accel;
 228                 else
 229                         accelfactor = f * g_bugrigs_accel;
 230                 //MAXIMA: accel(v) := f(v) * g_bugrigs_accel;
 231
 232                 if(accel < 0)
 233                 {
 234                         if(myspeed > 0)
 235                         {
 236                                 myspeed = max(0, myspeed - frametime * (g_bugrigs_friction_floor - g_bugrigs_friction_brake * accel));
 237                         }
 238                         else
 239                         {
 240                                 if(!g_bugrigs_reverse_speeding)
 241                                         myspeed = min(0, myspeed + frametime * g_bugrigs_friction_floor);
 242                         }
 243                 }
 244                 else
 245                 {
 246                         if(myspeed >= 0)
 247                         {
 248                                 myspeed = max(0, myspeed - frametime * g_bugrigs_friction_floor);
 249                         }
 250                         else
 251                         {
 252                                 if(g_bugrigs_reverse_stopping)
 253                                         myspeed = 0;
 254                                 else
 255                                         myspeed = min(0, myspeed + frametime * (g_bugrigs_friction_floor + g_bugrigs_friction_brake * accel));
 256                         }
 257                 }
 258                 // terminal velocity = velocity at which 50 == accelfactor, that is, 1549 units/sec
 259                 //MAXIMA: friction(v) := g_bugrigs_friction_floor;
 260
 261                 self.angles_y += steer * frametime * steerfactor; // apply steering
 262                 makevectors(self.angles); // new forward direction!
 263
 264                 myspeed += accel * accelfactor * frametime;
 265
 266                 rigvel = myspeed * v_forward + '0 0 1' * upspeed;
 267         }
 268         else
 269         {
 270                 myspeed = vlen(self.velocity);
 271
 272                 // responsiveness factor for steering and acceleration
 273                 f = 1 / (1 + pow(max(0, myspeed / g_bugrigs_speed_ref), g_bugrigs_speed_pow));
 274                 steerfactor = -myspeed * f;
 275                 self.angles_y += steer * frametime * steerfactor; // apply steering
 276
 277                 rigvel = self.velocity;
 278                 makevectors(self.angles); // new forward direction!
 279         }
 280
 281         rigvel = rigvel * max(0, 1 - vlen(rigvel) * g_bugrigs_friction_air * frametime);
 282         //MAXIMA: airfriction(v) := v * v * g_bugrigs_friction_air;
 283         //MAXIMA: total_acceleration(v) := accel(v) - friction(v) - airfriction(v);
 284         //MAXIMA: solve(total_acceleration(v) = 0, v);
 285
 286         if(g_bugrigs_planar_movement)
 287         {
 288                 vector rigvel_xy, neworigin, up;
 289                 float mt;
 290
 291                 rigvel_z -= frametime * sv_gravity; // 4x gravity plays better
 292                 rigvel_xy = rigvel;
 293                 rigvel_xy_z = 0;
 294
 295                 if(g_bugrigs_planar_movement_car_jumping && !g_touchexplode) // touchexplode is a better way to handle collisions
 296                         mt = MOVE_NORMAL;
 297                 else
 298                         mt = MOVE_NOMONSTERS;
 299
 300                 tracebox(self.origin, self.mins, self.maxs, self.origin + '0 0 1024', mt, self);
 301                 up = trace_endpos - self.origin;
 302
 303                 // BUG RIGS: align the move to the surface instead of doing collision testing
 304                 // can we move?
 305                 tracebox(trace_endpos, self.mins, self.maxs, trace_endpos + rigvel_xy * frametime, mt, self);
 306
 307                 // align to surface
 308                 tracebox(trace_endpos, self.mins, self.maxs, trace_endpos - up + '0 0 1' * rigvel_z * frametime, mt, self);
 309
 310                 if(trace_fraction < 0.5)
 311                 {
 312                         trace_fraction = 1;
 313                         neworigin = self.origin;
 314                 }
 315                 else
 316                         neworigin = trace_endpos;
 317
 318                 if(trace_fraction < 1)
 319                 {
 320                         // now set angles_x so that the car points parallel to the surface
 321                         self.angles = vectoangles(
 322                                         '1 0 0' * v_forward_x * trace_plane_normal_z
 323                                         +
 324                                         '0 1 0' * v_forward_y * trace_plane_normal_z
 325                                         +
 326                                         '0 0 1' * -(v_forward_x * trace_plane_normal_x + v_forward_y * trace_plane_normal_y)
 327                                         );
 328                         self.flags |= FL_ONGROUND;
 329                 }
 330                 else
 331                 {
 332                         // now set angles_x so that the car points forward, but is tilted in velocity direction
 333                         self.flags &~= FL_ONGROUND;
 334                 }
 335
 336                 self.velocity = (neworigin - self.origin) * (1.0 / frametime);
 337                 self.movetype = MOVETYPE_NOCLIP;
 338         }
 339         else
 340         {
 341                 rigvel_z -= frametime * sv_gravity; // 4x gravity plays better
 342                 self.velocity = rigvel;
 343                 self.movetype = MOVETYPE_FLY;
 344         }
 345
 346         trace_fraction = 1;
 347         tracebox(self.origin, self.mins, self.maxs, self.origin - '0 0 4', MOVE_NORMAL, self);
 348         if(trace_fraction != 1)
 349         {
 350                 self.angles = vectoangles2(
 351                                 '1 0 0' * v_forward_x * trace_plane_normal_z
 352                                 +
 353                                 '0 1 0' * v_forward_y * trace_plane_normal_z
 354                                 +
 355                                 '0 0 1' * -(v_forward_x * trace_plane_normal_x + v_forward_y * trace_plane_normal_y),
 356                                 trace_plane_normal
 357                                 );
 358         }
 359         else
 360         {
 361                 vector vel_local;
 362
 363                 vel_local_x = v_forward * self.velocity;
 364                 vel_local_y = v_right * self.velocity;
 365                 vel_local_z = v_up * self.velocity;
 366
 367                 self.angles_x = racecar_angle(vel_local_x, vel_local_z);
 368                 self.angles_z = racecar_angle(-vel_local_y, vel_local_z);
 369         }
 370
 371         // smooth the angles
 372         vector vf1, vu1, smoothangles;
 373         makevectors(self.angles);
 374         f = bound(0, frametime * g_bugrigs_angle_smoothing, 1);
 375         if(f == 0)
 376                 f = 1;
 377         vf1 = v_forward * f;
 378         vu1 = v_up * f;
 379         makevectors(angles_save);
 380         vf1 = vf1 + v_forward * (1 - f);
 381         vu1 = vu1 + v_up * (1 - f);
 382         smoothangles = vectoangles2(vf1, vu1);
 383         self.angles_x = -smoothangles_x;
 384         self.angles_z =  smoothangles_z;
 385 }
 386
 387 void CPM_PM_Aircontrol(vector wishdir, float wishspeed)
 388 {
 389         float zspeed, xyspeed, dot, k;
 390
 391         if(self.movement_x == 0 || self.movement_y != 0)
 392                 return; // can't control movement if not moving forward or backward
 393
 394         zspeed = self.velocity_z;
 395         self.velocity_z = 0;
 396         xyspeed = vlen(self.velocity);
 397         self.velocity = normalize(self.velocity);
 398
 399         dot = self.velocity * wishdir;
 400         k = 32;
 401         k *= sv_aircontrol*dot*dot*frametime;
 402
 403         if(dot > 0) // we can't change direction while slowing down
 404                 self.velocity = normalize(self.velocity * xyspeed + wishdir * k);
 405
 406         self.velocity = self.velocity * xyspeed;
 407         self.velocity_z = zspeed;
 408 }
 409
 410 void PM_Accelerate(vector wishdir, float wishspeed, float wishspeed0, float accel, float accelqw, float sidefric)
 411 {
 412         float vel_straight;
 413         float vel_z;
 414         vector vel_perpend;
 415         float addspeed;
 416         float savespeed;
 417
 418         if(cvar("sv_gameplayfix_q2airaccelerate"))
 419                 wishspeed0 = wishspeed;
 420
 421         savespeed = self.velocity * self.velocity;
 422
 423         vel_straight = self.velocity * wishdir;
 424         vel_z = self.velocity_z;
 425         vel_perpend = self.velocity - vel_straight * wishdir - vel_z * '0 0 1';
 426
 427         addspeed = wishspeed - vel_straight;
 428         if(addspeed > 0)
 429                 vel_straight = vel_straight + min(addspeed, accel * frametime * wishspeed0) * accelqw;
 430         if(wishspeed > 0)
 431                 vel_straight = vel_straight + min(wishspeed, accel * frametime * wishspeed0) * (1 - accelqw);
 432
 433         if(sidefric < 0 && (vel_perpend*vel_perpend))
 434         {
 435                 float f, fminimum;
 436                 f = (1 - frametime * wishspeed * sidefric);
 437                 fminimum = (savespeed - vel_straight*vel_straight) / (vel_perpend*vel_perpend);
 438                 if(fminimum <= 0)
 439                         vel_perpend = vel_perpend * f;
 440                 else
 441                         vel_perpend = vel_perpend * min(1, max(fminimum, f));
 442         }
 443         else
 444                 vel_perpend = vel_perpend * (1 - frametime * wishspeed * sidefric);
 445
 446         self.velocity = vel_straight * wishdir + vel_z * '0 0 1' + vel_perpend;
 447 }
 448
 449 void PM_AirAccelerate(vector wishdir, float wishspeed)
 450 {
 451         vector curvel, wishvel, acceldir, curdir;
 452         float addspeed, accelspeed, curspeed, f;
 453         float dot;
 454
 455         if(wishspeed == 0)
 456                 return;
 457
 458         curvel = self.velocity;
 459         curvel_z = 0;
 460         curspeed = vlen(curvel);
 461
 462         if(wishspeed > curspeed * 1.01)
 463         {
 464                 wishspeed = min(wishspeed, curspeed + sv_warsowbunny_airforwardaccel * sv_maxspeed * frametime);
 465         }
 466         else
 467         {
 468                 f = max(0, (sv_warsowbunny_topspeed - curspeed) / (sv_warsowbunny_topspeed - sv_maxspeed));
 469                 wishspeed = max(curspeed, sv_maxspeed) + sv_warsowbunny_accel * f * sv_maxspeed * frametime;
 470         }
 471         wishvel = wishdir * wishspeed;
 472         acceldir = wishvel - curvel;
 473         addspeed = vlen(acceldir);
 474         acceldir = normalize(acceldir);
 475
 476         accelspeed = min(addspeed, sv_warsowbunny_turnaccel * sv_maxspeed * frametime);
 477
 478         if(sv_warsowbunny_backtosideratio < 1)
 479         {
 480                 curdir = normalize(curvel);
 481                 dot = acceldir * curdir;
 482                 if(dot < 0)
 483                         acceldir = acceldir - (1 - sv_warsowbunny_backtosideratio) * dot * curdir;
 484         }
 485
 486         self.velocity += accelspeed * acceldir;
 487 }
 488
 489 .vector movement_old;
 490 .float buttons_old;
 491 .vector v_angle_old;
 492 .string lastclassname;
 493
 494 void Nixnex_GiveCurrentWeapon();
 495 .float() PlayerPhysplug;
 496
 497 string specialcommand = "xwxwxsxsxaxdxaxdx1x ";
 498 .float specialcommand_pos;
 499 void SpecialCommand()
 500 {
 501 #ifdef TETRIS
 502         TetrisImpulse();
 503 #else
 504         if(!CheatImpulse(99))
 505                 print("A hollow voice says \"Plugh\".\n");
 506 #endif
 507 }
 508
 509 float speedaward_speed;
 510 string speedaward_holder;
 511 void race_send_speedaward(float msg)
 512 {
 513         // send the best speed of the round
 514         WriteByte(msg, SVC_TEMPENTITY);
 515         WriteByte(msg, TE_CSQC_RACE);
 516         WriteByte(msg, RACE_NET_SPEED_AWARD);
 517         WriteShort(msg, floor(speedaward_speed+0.5));
 518         WriteString(msg, speedaward_holder);
 519 }
 520
 521 float speedaward_alltimebest;
 522 string speedaward_alltimebest_holder;
 523 void race_send_speedaward_alltimebest(float msg)
 524 {
 525         // send the best speed
 526         WriteByte(msg, SVC_TEMPENTITY);
 527         WriteByte(msg, TE_CSQC_RACE);
 528         WriteByte(msg, RACE_NET_SPEED_AWARD_BEST);
 529         WriteShort(msg, floor(speedaward_alltimebest+0.5));
 530         WriteString(msg, speedaward_alltimebest_holder);
 531 }
 532
 533 string GetMapname(void);
 534 float speedaward_lastupdate;
 535 float speedaward_lastsent;
 536 void SV_PlayerPhysics()
 537 {
 538         local vector wishvel, wishdir, v;
 539         local float wishspeed, f, maxspd_mod, spd, maxairspd, airaccel, swampspd_mod, buttons;
 540         string temps;
 541         float buttons_prev;
 542         float not_allowed_to_move;
 543         string c;
 544
 545     if(self.PlayerPhysplug)
 546         if(self.PlayerPhysplug())
 547             return;
 548
 549         self.race_movetime_frac += frametime;
 550         f = floor(self.race_movetime_frac);
 551         self.race_movetime_frac -= f;
 552         self.race_movetime_count += f;
 553         self.race_movetime = self.race_movetime_frac + self.race_movetime_count;
 554
 555         anticheat_physics();
 556
 557         buttons = self.BUTTON_ATCK + 2 * self.BUTTON_JUMP + 4 * self.BUTTON_ATCK2 + 8 * self.BUTTON_ZOOM + 16 * self.BUTTON_CROUCH + 32 * self.BUTTON_HOOK + 64 * self.BUTTON_USE + 128 * (self.movement_x < 0) + 256 * (self.movement_x > 0) + 512 * (self.movement_y < 0) + 1024 * (self.movement_y > 0);
 558
 559         if(!buttons)
 560                 c = "x";
 561         else if(buttons == 1)
 562                 c = "1";
 563         else if(buttons == 2)
 564                 c = " ";
 565         else if(buttons == 128)
 566                 c = "s";
 567         else if(buttons == 256)
 568                 c = "w";
 569         else if(buttons == 512)
 570                 c = "a";
 571         else if(buttons == 1024)
 572                 c = "d";
 573         else
 574                 c = "?";
 575
 576         if(c == substring(specialcommand, self.specialcommand_pos, 1))
 577         {
 578                 self.specialcommand_pos += 1;
 579                 if(self.specialcommand_pos >= strlen(specialcommand))
 580                 {
 581                         self.specialcommand_pos = 0;
 582                         SpecialCommand();
 583                         return;
 584                 }
 585         }
 586         else if(self.specialcommand_pos && (c != substring(specialcommand, self.specialcommand_pos - 1, 1)))
 587                 self.specialcommand_pos = 0;
 588
 589         if(!sv_maxidle_spectatorsareidle || self.movetype == MOVETYPE_WALK)
 590         {
 591                 if(buttons != self.buttons_old || self.movement != self.movement_old || self.v_angle != self.v_angle_old)
 592                         self.parm_idlesince = time;
 593         }
 594         buttons_prev = self.buttons_old;
 595         self.buttons_old = buttons;
 596         self.movement_old = self.movement;
 597         self.v_angle_old = self.v_angle;
 598
 599         if(time < self.nickspamtime)
 600         if(self.nickspamcount >= cvar("g_nick_flood_penalty_yellow"))
 601         {
 602                 // slight annoyance for nick change scripts
 603                 self.movement = -1 * self.movement;
 604                 self.BUTTON_ATCK = self.BUTTON_JUMP = self.BUTTON_ATCK2 = self.BUTTON_ZOOM = self.BUTTON_CROUCH = self.BUTTON_HOOK = self.BUTTON_USE = 0;
 605
 606                 if(self.nickspamcount >= cvar("g_nick_flood_penalty_red")) // if you are persistent and the slight annoyance above does not stop you, I'll show you!
 607                 {
 608                         self.angles_x = random() * 360;
 609                         self.angles_y = random() * 360;
 610                         // at least I'm not forcing retardedview by also assigning to angles_z
 611                         self.fixangle = 1;
 612                 }
 613         }
 614
 615         if (self.punchangle != '0 0 0')
 616         {
 617                 f = vlen(self.punchangle) - 10 * frametime;
 618                 if (f > 0)
 619                         self.punchangle = normalize(self.punchangle) * f;
 620                 else
 621                         self.punchangle = '0 0 0';
 622         }
 623
 624         if (self.punchvector != '0 0 0')
 625         {
 626                 f = vlen(self.punchvector) - 30 * frametime;
 627                 if (f > 0)
 628                         self.punchvector = normalize(self.punchvector) * f;
 629                 else
 630                         self.punchvector = '0 0 0';
 631         }
 632
 633         if (clienttype(self) == CLIENTTYPE_BOT)
 634         {
 635                 if(playerdemo_read())
 636                         return;
 637                 bot_think();
 638         }
 639
 640         self.items &~= IT_USING_JETPACK;
 641
 642         if(self.classname == "player")
 643         {
 644                 if(self.race_penalty)
 645                         if(time > self.race_penalty)
 646                                 self.race_penalty = 0;
 647
 648                 not_allowed_to_move = 0;
 649                 if(self.race_penalty)
 650                         not_allowed_to_move = 1;
 651                 if(!cvar("sv_ready_restart_after_countdown"))
 652                 if(time < game_starttime)
 653                         not_allowed_to_move = 1;
 654
 655                 if(not_allowed_to_move)
 656                 {
 657                         self.velocity = '0 0 0';
 658                         self.movetype = MOVETYPE_NONE;
 659                         self.disableclientprediction = 2;
 660                 }
 661                 else if(self.disableclientprediction == 2)
 662                 {
 663                         if(self.movetype == MOVETYPE_NONE)
 664                                 self.movetype = MOVETYPE_WALK;
 665                         self.disableclientprediction = 0;
 666                 }
 667         }
 668
 669         if (self.movetype == MOVETYPE_NONE)
 670                 return;
 671
 672         maxspd_mod = 1;
 673
 674         if(g_runematch)
 675         {
 676                 if(self.runes & RUNE_SPEED)
 677                 {
 678                         if(self.runes & CURSE_SLOW)
 679                                 maxspd_mod = maxspd_mod * cvar("g_balance_rune_speed_combo_moverate");
 680                         else
 681                                 maxspd_mod = maxspd_mod * cvar("g_balance_rune_speed_moverate");
 682                 }
 683                 else if(self.runes & CURSE_SLOW)
 684                 {
 685                         maxspd_mod = maxspd_mod * cvar("g_balance_curse_slow_moverate");
 686                 }
 687         }
 688
 689         if(g_minstagib && (self.items & IT_INVINCIBLE))
 690         {
 691                 maxspd_mod = cvar("g_minstagib_speed_moverate");
 692         }
 693
 694         if(g_nexball && self.ballcarried)
 695         {
 696                 maxspd_mod = cvar("g_nexball_basketball_carrier_speed");
 697         }
 698
 699         swampspd_mod = 1;
 700         if(self.in_swamp) {
 701                 swampspd_mod = self.swamp_slowdown; //cvar("g_balance_swamp_moverate");
 702         }
 703
 704         if(self.classname != "player")
 705         {
 706                 maxspd_mod = cvar("sv_spectator_speed_multiplier");
 707                 if(!self.spectatorspeed)
 708                         self.spectatorspeed = maxspd_mod;
 709                 if(self.impulse && self.impulse <= 19)
 710                 {
 711                         if(self.lastclassname != "player")
 712                         {
 713                                 if(self.impulse == 10 || self.impulse == 15 || self.impulse == 18)
 714                                         self.spectatorspeed = bound(1, self.spectatorspeed + 0.5, 5);
 715                                 else if(self.impulse == 11)
 716                                         self.spectatorspeed = maxspd_mod;
 717                                 else if(self.impulse == 12 || self.impulse == 16  || self.impulse == 19)
 718                                         self.spectatorspeed = bound(1, self.spectatorspeed - 0.5, 5);
 719                                 else if(self.impulse >= 1 && self.impulse <= 9)
 720                                         self.spectatorspeed = 1 + 0.5 * (self.impulse - 1);
 721                         } // otherwise just clear
 722                         self.impulse = 0;
 723                 }
 724                 maxspd_mod = self.spectatorspeed;
 725         }
 726
 727         spd = max(sv_maxspeed, sv_maxairspeed) * maxspd_mod * swampspd_mod;
 728         if(self.speed != spd)
 729         {
 730                 self.speed = spd;
 731                 temps = ftos(spd);
 732                 stuffcmd(self, strcat("cl_forwardspeed ", temps, "\n"));
 733                 stuffcmd(self, strcat("cl_backspeed ", temps, "\n"));
 734                 stuffcmd(self, strcat("cl_sidespeed ", temps, "\n"));
 735                 stuffcmd(self, strcat("cl_upspeed ", temps, "\n"));
 736         }
 737
 738         maxspd_mod *= swampspd_mod; // only one common speed modder please!
 739         swampspd_mod = 1;
 740
 741         // if dead, behave differently
 742         if (self.deadflag)
 743                 goto end;
 744
 745         if (!self.fixangle && !g_bugrigs)
 746         {
 747                 self.angles_x = 0;
 748                 self.angles_y = self.v_angle_y;
 749                 self.angles_z = 0;
 750         }
 751
 752         if(self.flags & FL_ONGROUND)
 753         if(self.wasFlying)
 754         {
 755                 self.wasFlying = 0;
 756
 757                 if(self.waterlevel < WATERLEVEL_SWIMMING)
 758                 if(time >= self.ladder_time)
 759                 if not(self.hook)
 760                 {
 761                         self.nextstep = time + 0.3 + random() * 0.1;
 762                         trace_dphitq3surfaceflags = 0;
 763                         tracebox(self.origin, self.mins, self.maxs, self.origin - '0 0 1', MOVE_NOMONSTERS, self);
 764                         if not(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOSTEPS)
 765                         {
 766                                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_METALSTEPS)
 767                                         GlobalSound(globalsound_metalfall, CHAN_PLAYER, VOICETYPE_PLAYERSOUND);
 768                                 else
 769                                         GlobalSound(globalsound_fall, CHAN_PLAYER, VOICETYPE_PLAYERSOUND);
 770                         }
 771                 }
 772         }
 773
 774         if(IsFlying(self))
 775                 self.wasFlying = 1;
 776
 777         if(self.classname == "player")
 778         {
 779                 if(sv_doublejump)
 780                 {
 781                         self.flags &~= FL_ONGROUND;
 782                         tracebox(self.origin + '0 0 1', self.mins, self.maxs, self.origin - '0 0 1', MOVE_NORMAL, self);
 783                         if(trace_fraction < 1 && trace_plane_normal_z > 0.7)
 784                                 self.flags |= FL_ONGROUND;
 785                 }
 786
 787                 if (self.BUTTON_JUMP)
 788                         PlayerJump ();
 789                 else
 790                         self.flags |= FL_JUMPRELEASED;
 791
 792                 if (self.waterlevel == WATERLEVEL_SWIMMING)
 793                         CheckWaterJump ();
 794         }
 795
 796         if (self.flags & FL_WATERJUMP )
 797         {
 798                 self.velocity_x = self.movedir_x;
 799                 self.velocity_y = self.movedir_y;
 800                 if (time > self.teleport_time || self.waterlevel == WATERLEVEL_NONE)
 801                 {
 802                         self.flags &~= FL_WATERJUMP;
 803                         self.teleport_time = 0;
 804                 }
 805         }
 806         else if (g_bugrigs && self.classname == "player")
 807         {
 808                 RaceCarPhysics();
 809         }
 810         else if (self.movetype == MOVETYPE_NOCLIP || self.movetype == MOVETYPE_FLY)
 811         {
 812                 // noclipping or flying
 813                 self.flags &~= FL_ONGROUND;
 814
 815                 self.velocity = self.velocity * (1 - frametime * sv_friction);
 816                 makevectors(self.v_angle);
 817                 //wishvel = v_forward * self.movement_x + v_right * self.movement_y + v_up * self.movement_z;
 818                 wishvel = v_forward * self.movement_x + v_right * self.movement_y + '0 0 1' * self.movement_z;
 819                 // acceleration
 820                 wishdir = normalize(wishvel);
 821                 wishspeed = vlen(wishvel);
 822                 if (wishspeed > sv_maxspeed*maxspd_mod)
 823                         wishspeed = sv_maxspeed*maxspd_mod;
 824                 if (time >= self.teleport_time)
 825                         PM_Accelerate(wishdir, wishspeed, wishspeed, sv_accelerate*maxspd_mod, 1, 0);
 826         }
 827         else if (self.waterlevel >= WATERLEVEL_SWIMMING)
 828         {
 829                 // swimming
 830                 self.flags &~= FL_ONGROUND;
 831
 832                 makevectors(self.v_angle);
 833                 //wishvel = v_forward * self.movement_x + v_right * self.movement_y + v_up * self.movement_z;
 834                 wishvel = v_forward * self.movement_x + v_right * self.movement_y + '0 0 1' * self.movement_z;
 835                 if (wishvel == '0 0 0')
 836                         wishvel = '0 0 -60'; // drift towards bottom
 837
 838                 wishdir = normalize(wishvel);
 839                 wishspeed = vlen(wishvel);
 840                 if (wishspeed > sv_maxspeed*maxspd_mod)
 841                         wishspeed = sv_maxspeed*maxspd_mod;
 842                 wishspeed = wishspeed * 0.7;
 843
 844                 // water friction
 845                 self.velocity = self.velocity * (1 - frametime * sv_friction);
 846
 847                 // water acceleration
 848                 PM_Accelerate(wishdir, wishspeed, wishspeed, sv_accelerate*maxspd_mod, 1, 0);
 849         }
 850         else if (time < self.ladder_time)
 851         {
 852                 // on a spawnfunc_func_ladder or swimming in spawnfunc_func_water
 853                 self.flags &~= FL_ONGROUND;
 854
 855                 self.velocity = self.velocity * (1 - frametime * sv_friction);
 856                 makevectors(self.v_angle);
 857                 //wishvel = v_forward * self.movement_x + v_right * self.movement_y + v_up * self.movement_z;
 858                 wishvel = v_forward * self.movement_x + v_right * self.movement_y + '0 0 1' * self.movement_z;
 859                 if (self.gravity)
 860                         self.velocity_z = self.velocity_z + self.gravity * sv_gravity * frametime;
 861                 else
 862                         self.velocity_z = self.velocity_z + sv_gravity * frametime;
 863                 if (self.ladder_entity.classname == "func_water")
 864                 {
 865                         f = vlen(wishvel);
 866                         if (f > self.ladder_entity.speed)
 867                                 wishvel = wishvel * (self.ladder_entity.speed / f);
 868
 869                         self.watertype = self.ladder_entity.skin;
 870                         f = self.ladder_entity.origin_z + self.ladder_entity.maxs_z;
 871                         if ((self.origin_z + self.view_ofs_z) < f)
 872                                 self.waterlevel = WATERLEVEL_SUBMERGED;
 873                         else if ((self.origin_z + (self.mins_z + self.maxs_z) * 0.5) < f)
 874                                 self.waterlevel = WATERLEVEL_SWIMMING;
 875                         else if ((self.origin_z + self.mins_z + 1) < f)
 876                                 self.waterlevel = WATERLEVEL_WETFEET;
 877                         else
 878                         {
 879                                 self.waterlevel = WATERLEVEL_NONE;
 880                                 self.watertype = CONTENT_EMPTY;
 881                         }
 882                 }
 883                 // acceleration
 884                 wishdir = normalize(wishvel);
 885                 wishspeed = vlen(wishvel);
 886                 if (wishspeed > sv_maxspeed*maxspd_mod)
 887                         wishspeed = sv_maxspeed*maxspd_mod;
 888                 if (time >= self.teleport_time)
 889                 {
 890                         // water acceleration
 891                         PM_Accelerate(wishdir, wishspeed, wishspeed, sv_accelerate*maxspd_mod, 1, 0);
 892                 }
 893         }
 894         else if ((self.items & IT_JETPACK) && self.BUTTON_HOOK && (!cvar("g_jetpack_fuel") || self.ammo_fuel >= 0.01 || self.items & IT_UNLIMITED_WEAPON_AMMO))
 895         {
 896                 //makevectors(self.v_angle_y * '0 1 0');
 897                 makevectors(self.v_angle);
 898                 wishvel = v_forward * self.movement_x + v_right * self.movement_y;
 899                 // add remaining speed as Z component
 900                 maxairspd = sv_maxairspeed*max(1, maxspd_mod);
 901                 // fix speedhacks :P
 902                 wishvel = normalize(wishvel) * min(vlen(wishvel) / maxairspd, 1);
 903                 // add the unused velocity as up component
 904                 wishvel_z = 0;
 905
 906                 // if(self.BUTTON_JUMP)
 907                         wishvel_z = sqrt(max(0, 1 - wishvel * wishvel));
 908
 909                 // it is now normalized, so...
 910                 float a_side, a_up, a_add, a_diff;
 911                 a_side = cvar("g_jetpack_acceleration_side");
 912                 a_up = cvar("g_jetpack_acceleration_up");
 913                 a_add = cvar("g_jetpack_antigravity") * sv_gravity;
 914
 915                 wishvel_x *= a_side;
 916                 wishvel_y *= a_side;
 917                 wishvel_z *= a_up;
 918                 wishvel_z += a_add;
 919
 920                 float best;
 921                 best = 0;
 922                 //////////////////////////////////////////////////////////////////////////////////////
 923                 // finding the maximum over all vectors of above form
 924                 // with wishvel having an absolute value of 1
 925                 //////////////////////////////////////////////////////////////////////////////////////
 926                 // we're finding the maximum over
 927                 //   f(a_side, a_up, a_add, z) := a_side * (1 - z^2) + (a_add + a_up * z)^2;
 928                 // for z in the range from -1 to 1
 929                 //////////////////////////////////////////////////////////////////////////////////////
 930                 // maximum is EITHER attained at the single extreme point:
 931                 a_diff = a_side * a_side - a_up * a_up;
 932                 if(a_diff != 0)
 933                 {
 934                         f = a_add * a_up / a_diff; // this is the zero of diff(f(a_side, a_up, a_add, z), z)
 935                         if(f > -1 && f < 1) // can it be attained?
 936                         {
 937                                 best = (a_diff + a_add * a_add) * (a_diff + a_up * a_up) / a_diff;
 938                                 //print("middle\n");
 939                         }
 940                 }
 941                 // OR attained at z = 1:
 942                 f = (a_up + a_add) * (a_up + a_add);
 943                 if(f > best)
 944                 {
 945                         best = f;
 946                         //print("top\n");
 947                 }
 948                 // OR attained at z = -1:
 949                 f = (a_up - a_add) * (a_up - a_add);
 950                 if(f > best)
 951                 {
 952                         best = f;
 953                         //print("bottom\n");
 954                 }
 955                 best = sqrt(best);
 956                 //////////////////////////////////////////////////////////////////////////////////////
 957
 958                 //print("best possible acceleration: ", ftos(best), "\n");
 959
 960                 float fxy, fz;
 961                 fxy = bound(0, 1 - (self.velocity * normalize(wishvel_x * '1 0 0' + wishvel_y * '0 1 0')) / cvar("g_jetpack_maxspeed_side"), 1);
 962                 if(wishvel_z - sv_gravity > 0)
 963                         fz = bound(0, 1 - self.velocity_z / cvar("g_jetpack_maxspeed_up"), 1);
 964                 else
 965                         fz = bound(0, 1 + self.velocity_z / cvar("g_jetpack_maxspeed_up"), 1);
 966
 967                 float fvel;
 968                 fvel = vlen(wishvel);
 969                 wishvel_x *= fxy;
 970                 wishvel_y *= fxy;
 971                 wishvel_z = (wishvel_z - sv_gravity) * fz + sv_gravity;
 972
 973                 fvel = min(1, vlen(wishvel) / best);
 974                 if(cvar("g_jetpack_fuel") && !(self.items & IT_UNLIMITED_WEAPON_AMMO))
 975                         f = min(1, self.ammo_fuel / (cvar("g_jetpack_fuel") * frametime * fvel));
 976                 else
 977                         f = 1;
 978
 979                 //print("this acceleration: ", ftos(vlen(wishvel) * f), "\n");
 980
 981                 if (f > 0 && wishvel != '0 0 0')
 982                 {
 983                         self.velocity = self.velocity + wishvel * f * frametime;
 984                         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
 985                                 self.ammo_fuel -= cvar("g_jetpack_fuel") * frametime * fvel * f;
 986                         self.flags &~= FL_ONGROUND;
 987                         self.items |= IT_USING_JETPACK;
 988
 989                         // jetpack also inhibits health regeneration, but only for 1 second
 990                         self.pauseregen_finished = max(self.pauseregen_finished, time + cvar("g_balance_pause_fuel_regen"));
 991                 }
 992         }
 993         else if (self.flags & FL_ONGROUND)
 994         {
 995                 // we get here if we ran out of ammo
 996                 if((self.items & IT_JETPACK) && self.BUTTON_HOOK && !(buttons_prev & 32))
 997                         sprint(self, "You don't have any fuel for the ^2Jetpack\n");
 998
 999                 // walking
1000                 makevectors(self.v_angle_y * '0 1 0');
1001                 wishvel = v_forward * self.movement_x + v_right * self.movement_y;
1002
1003                 if(!(self.lastflags & FL_ONGROUND))
1004                 {
1005                         if(cvar("speedmeter"))
1006                                 dprint(strcat("landing velocity: ", vtos(self.velocity), " (abs: ", ftos(vlen(self.velocity)), ")\n"));
1007                         if(self.lastground < time - 0.3)
1008                                 self.velocity = self.velocity * (1 - cvar("sv_friction_on_land"));
1009                         if(self.jumppadcount > 1)
1010                                 dprint(strcat(ftos(self.jumppadcount), "x jumppad combo\n"));
1011                         self.jumppadcount = 0;
1012                 }
1013
1014 #ifdef LETS_TEST_FTEQCC
1015                 if(self.velocity_x || self.velocity_y)
1016                 {
1017                         // good
1018                 }
1019                 else
1020                 {
1021                         if(self.velocity_x)
1022                                 checkclient();
1023                         if(self.velocity_y)
1024                                 checkclient();
1025                 }
1026 #endif
1027
1028                 v = self.velocity;
1029                 v_z = 0;
1030                 f = vlen(v);
1031                 if(f > 0)
1032                 {
1033                         if (f < sv_stopspeed)
1034                                 f = 1 - frametime * (sv_stopspeed / f) * sv_friction;
1035                         else
1036                                 f = 1 - frametime * sv_friction;
1037                         if (f > 0)
1038                                 self.velocity = self.velocity * f;
1039                         else
1040                                 self.velocity = '0 0 0';
1041                 }
1042
1043                 // acceleration
1044                 wishdir = normalize(wishvel);
1045                 wishspeed = vlen(wishvel);
1046                 if (wishspeed > sv_maxspeed*maxspd_mod)
1047                         wishspeed = sv_maxspeed*maxspd_mod;
1048                 if (self.crouch)
1049                         wishspeed = wishspeed * 0.5;
1050                 if (time >= self.teleport_time)
1051                         PM_Accelerate(wishdir, wishspeed, wishspeed, sv_accelerate*maxspd_mod, 1, 0);
1052         }
1053         else
1054         {
1055                 float wishspeed0;
1056                 // we get here if we ran out of ammo
1057                 if((self.items & IT_JETPACK) && self.BUTTON_HOOK && !(buttons_prev & 32))
1058                         sprint(self, "You don't have any fuel for the ^2Jetpack\n");
1059
1060                 if(maxspd_mod < 1)
1061                 {
1062                         maxairspd = sv_maxairspeed*maxspd_mod;
1063                         airaccel = sv_airaccelerate*maxspd_mod;
1064                 }
1065                 else
1066                 {
1067                         maxairspd = sv_maxairspeed;
1068                         airaccel = sv_airaccelerate;
1069                 }
1070                 // airborn
1071                 makevectors(self.v_angle_y * '0 1 0');
1072                 wishvel = v_forward * self.movement_x + v_right * self.movement_y;
1073                 // acceleration
1074                 wishdir = normalize(wishvel);
1075                 wishspeed = wishspeed0 = vlen(wishvel);
1076                 if (wishspeed0 > sv_maxspeed*maxspd_mod)
1077                         wishspeed0 = sv_maxspeed*maxspd_mod;
1078                 if (wishspeed > maxairspd)
1079                         wishspeed = maxairspd;
1080                 if (self.crouch)
1081                         wishspeed = wishspeed * 0.5;
1082                 if (time >= self.teleport_time)
1083                 {
1084                         float accelerating;
1085                         float wishspeed2;
1086                         float airaccelqw;
1087
1088                         airaccelqw = sv_airaccel_qw;
1089                         accelerating = (self.velocity * wishdir > 0);
1090                         wishspeed2 = wishspeed;
1091
1092                         // CPM
1093                         if(sv_airstopaccelerate)
1094                                 if(self.velocity * wishdir < 0)
1095                                         airaccel = sv_airstopaccelerate*maxspd_mod;
1096                         if(self.movement_x == 0 && self.movement_y != 0)
1097                         {
1098                                 if(sv_maxairstrafespeed)
1099                                 {
1100                                         wishspeed = min(wishspeed, sv_maxairstrafespeed*maxspd_mod);
1101                                         if(sv_maxairstrafespeed < sv_maxairspeed)
1102                                                 airaccelqw = 1;
1103                                 }
1104                                 if(sv_airstrafeaccelerate)
1105                                 {
1106                                         airaccel = sv_airstrafeaccelerate*maxspd_mod;
1107                                         if(sv_airstrafeaccelerate > sv_airaccelerate)
1108                                                 airaccelqw = 1;
1109                                 }
1110                         }
1111                         // !CPM
1112
1113                         if(sv_warsowbunny_turnaccel && accelerating && self.movement_y == 0 && self.movement_x != 0)
1114                                 PM_AirAccelerate(wishdir, wishspeed);
1115                         else
1116                                 PM_Accelerate(wishdir, wishspeed, wishspeed0, airaccel, airaccelqw, sv_airaccel_sideways_friction / maxairspd);
1117
1118                         if(sv_aircontrol)
1119                                 CPM_PM_Aircontrol(wishdir, wishspeed2);
1120                 }
1121         }
1122
1123         if((g_cts || g_race) && self.classname != "observer") {
1124                 if(vlen(self.velocity - self.velocity_z * '0 0 1') > speedaward_speed) {
1125                         speedaward_speed = vlen(self.velocity - self.velocity_z * '0 0 1');
1126                         speedaward_holder = self.netname;
1127                         speedaward_lastupdate = time;
1128                 }
1129                 if(speedaward_speed > speedaward_lastsent && time - speedaward_lastupdate > 1) {
1130                         string rr;
1131                         if(g_cts)
1132                                 rr = CTS_RECORD;
1133                         else
1134                                 rr = RACE_RECORD;
1135                         race_send_speedaward(MSG_ALL);
1136                         speedaward_lastsent = speedaward_speed;
1137                         if (speedaward_speed > speedaward_alltimebest) {
1138                                 speedaward_alltimebest = speedaward_speed;
1139                                 speedaward_alltimebest_holder = speedaward_holder;
1140                                 db_put(ServerProgsDB, strcat(GetMapname(), rr, "speed/speed"), ftos(speedaward_alltimebest));
1141                                 db_put(ServerProgsDB, strcat(GetMapname(), rr, "speed/netname"), speedaward_alltimebest_holder);
1142                                 race_send_speedaward_alltimebest(MSG_ALL);
1143                         }
1144                 }
1145         }
1146 :end
1147         if(self.flags & FL_ONGROUND)
1148                 self.lastground = time;
1149
1150         self.lastflags = self.flags;
1151         self.lastclassname = self.classname;
1152 };