data/qcsrc/server/cl_client.qc

   1 void info_player_start (void)
   2 {
   3         self.classname = "info_player_deathmatch";
   4         relocate_spawnpoint();
   5 }
   6
   7 void info_player_deathmatch (void)
   8 {
   9         relocate_spawnpoint();
  10 }
  11
  12 float spawn_allbad;
  13 float spawn_allgood;
  14 entity Spawn_FilterOutBadSpots(entity firstspot, entity playerlist, float mindist, float teamcheck)
  15 {
  16         local entity spot, player, nextspot, previousspot, newfirstspot;
  17         local float pcount;
  18         spot = firstspot;
  19         newfirstspot = world;
  20         previousspot = world;
  21         spawn_allgood = TRUE;
  22         spawn_allbad = TRUE;
  23         while (spot)
  24         {
  25                 nextspot = spot.chain;
  26                 // count team mismatches as bad spots
  27                 if (spot.team == teamcheck)
  28                 {
  29                         pcount = 0;
  30                         player = playerlist;
  31                         while (player)
  32                         {
  33                                 if (player != self)
  34                                 if (vlen(player.origin - spot.origin) < mindist)
  35                                         pcount = pcount + 1;
  36                                 player = player.chain;
  37                         }
  38                         if (!pcount)
  39                         {
  40                                 spawn_allbad = FALSE;
  41                                 if (newfirstspot)
  42                                         previousspot.chain = spot;
  43                                 else
  44                                         newfirstspot = spot;
  45                                 previousspot = spot;
  46                                 spot.chain = world;
  47                         }
  48                         else
  49                                 spawn_allgood = FALSE;
  50                 }
  51                 spot = nextspot;
  52         }
  53         // if we couldn't find ANY good points, return the original list
  54         if (!newfirstspot)
  55                 newfirstspot = firstspot;
  56         return newfirstspot;
  57 }
  58
  59 entity Spawn_RandomPoint(entity firstspot)
  60 {
  61         local entity spot;
  62         local float numspots;
  63         // count number of spots
  64         numspots = 0;
  65         spot = firstspot;
  66         while (spot)
  67         {
  68                 numspots = numspots + 1;
  69                 spot = spot.chain;
  70         }
  71         // pick a random one
  72         numspots = numspots * random();
  73         spot = firstspot;
  74         while (spot.chain && numspots >= 1)
  75         {
  76                 numspots = numspots - 1;
  77                 spot = spot.chain;
  78         }
  79         return spot;
  80 }
  81
  82 entity Spawn_FurthestPoint(entity firstspot, entity playerlist)
  83 {
  84         local entity best, spot, player;
  85         local float bestrating, rating;
  86         best = world;
  87         bestrating = -1000000;
  88         spot = firstspot;
  89         while (spot)
  90         {
  91                 rating = 1000000000;
  92                 player = playerlist;
  93                 while (player)
  94                 {
  95                         if (player != self)
  96                                 rating = min(rating, vlen(player.origin - spot.origin));
  97                         player = player.chain;
  98                 }
  99                 rating = rating + random() * 16;
 100                 if (bestrating < rating)
 101                 {
 102                         best = spot;
 103                         bestrating = rating;
 104                 }
 105                 spot = spot.chain;
 106         }
 107         return best;
 108 }
 109
 110 /*
 111 =============
 112 SelectSpawnPoint
 113
 114 Finds a point to respawn
 115 =============
 116 */
 117 entity SelectSpawnPoint (float anypoint)
 118 {
 119         local float teamcheck;
 120         local entity spot, firstspot, playerlist;
 121
 122         spot = find (world, classname, "testplayerstart");
 123         if (spot)
 124                 return spot;
 125
 126         teamcheck = 0;
 127
 128         if(!anypoint && cvar("g_ctf") )
 129                 teamcheck = self.team;
 130
 131         // get the list of players
 132         playerlist = findchain(classname, "player");
 133         // get the entire list of spots
 134         firstspot = findchain(classname, "info_player_deathmatch");
 135         // filter out the bad ones
 136         // (note this returns the original list if none survived)
 137         firstspot = Spawn_FilterOutBadSpots(firstspot, playerlist, 100, teamcheck);
 138
 139         // there is 50/50 chance of choosing a random spot or the furthest spot
 140         // (this means that roughly every other spawn will be furthest, so you
 141         // usually won't get fragged at spawn twice in a row)
 142         if (arena_roundbased)
 143         {
 144                 firstspot = Spawn_FilterOutBadSpots(firstspot, playerlist, 800, teamcheck);
 145                 spot = Spawn_RandomPoint(firstspot);
 146         }
 147         else if (random() > 0.5 || spawn_allbad || spawn_allgood)
 148                 spot = Spawn_RandomPoint(firstspot);
 149         else
 150                 spot = Spawn_FurthestPoint(firstspot, playerlist);
 151
 152         if (!spot)
 153         {
 154                 if(cvar("spawn_debug"))
 155                         GotoNextMap();
 156                 else
 157                         error ("PutClientInServer: no start points on level");
 158         }
 159
 160         return spot;
 161 }
 162
 163 /*
 164 =============
 165 CheckPlayerModel
 166
 167 Checks if the argument string can be a valid playermodel.
 168 Returns a valid one in doubt.
 169 =============
 170 */
 171 string FallbackPlayerModel = "models/player/marine.zym";
 172 string CheckPlayerModel(string plyermodel) {
 173         if(strlen(plyermodel) < 4)
 174                 return FallbackPlayerModel;
 175         if( substring(plyermodel,0,14) != "models/player/")
 176                 return FallbackPlayerModel;
 177         else if(cvar("sv_servermodelsonly"))
 178         {
 179                 if(substring(plyermodel,strlen(plyermodel)-4,4) != ".zym")
 180                         return FallbackPlayerModel;
 181                 if(!fexists(plyermodel))
 182                         return FallbackPlayerModel;
 183         }
 184         return plyermodel;
 185 }
 186
 187 /*
 188 =============
 189 Client_customizeentityforclient
 190
 191 LOD reduction
 192 =============
 193 */
 194 float Client_customizeentityforclient()
 195 {
 196 #ifdef ALLOW_VARIABLE_LOD
 197         // self: me
 198         // other: the player viewing me
 199         float distance;
 200         float f;
 201
 202         if(self.flags & FL_NOTARGET) // we don't need LOD for spectators
 203                 return TRUE;
 204
 205         if(other.cvar_cl_playerdetailreduction <= 0)
 206         {
 207                 if(other.cvar_cl_playerdetailreduction <= -2)
 208                         self.modelindex = self.modelindex_lod2;
 209                 else if(other.cvar_cl_playerdetailreduction <= -1)
 210                         self.modelindex = self.modelindex_lod1;
 211                 else
 212                         self.modelindex = self.modelindex_lod0;
 213         }
 214         else
 215         {
 216                 distance = vlen(self.origin - other.origin);
 217                 f = (distance + 100.0) * other.cvar_cl_playerdetailreduction;
 218                 if(f > 10000)
 219                         self.modelindex = self.modelindex_lod2;
 220                 else if(f > 5000)
 221                         self.modelindex = self.modelindex_lod1;
 222                 else
 223                         self.modelindex = self.modelindex_lod0;
 224         }
 225 #endif
 226
 227         return TRUE;
 228 }
 229
 230 void setmodel_lod(entity e, string modelname)
 231 {
 232 #ifdef ALLOW_VARIABLE_LOD
 233         string s;
 234
 235         s = strcat(substring(modelname, 0, strlen(modelname) - 4), "_1.zym");
 236         if(fexists(s))
 237         {
 238                 precache_model(s);
 239                 setmodel(e, s);
 240                 self.modelindex_lod1 = self.modelindex;
 241         }
 242         else
 243                 self.modelindex_lod1 = -1;
 244
 245         s = strcat(substring(modelname, 0, strlen(modelname) - 4), "_2.zym");
 246         if(fexists(s))
 247         {
 248                 precache_model(s);
 249                 setmodel(e, s);
 250                 self.modelindex_lod2 = self.modelindex;
 251         }
 252         else
 253                 self.modelindex_lod2 = -1;
 254
 255         precache_model(modelname);
 256         setmodel(e, modelname);
 257         self.modelindex_lod0 = self.modelindex;
 258
 259         if(self.modelindex_lod1 < 0)
 260                 self.modelindex_lod1 = self.modelindex;
 261
 262         if(self.modelindex_lod2 < 0)
 263                 self.modelindex_lod2 = self.modelindex;
 264 #else
 265         precache_model(modelname);
 266         setmodel(e, modelname);
 267 #endif
 268 }
 269
 270 /*
 271 =============
 272 PutObserverInServer
 273
 274 putting a client as observer in the server
 275 =============
 276 */
 277 void PutObserverInServer (void)
 278 {
 279         entity  spot;
 280         spot = SelectSpawnPoint (FALSE);
 281         RemoveGrapplingHook(self); // Wazat's Grappling Hook
 282
 283         if(clienttype(self) == CLIENTTYPE_REAL)
 284         {
 285                 msg_entity = self;
 286                 WriteByte(MSG_ONE, SVC_SETVIEW);
 287                 WriteEntity(MSG_ONE, self);
 288         }
 289
 290         DropAllRunes(self);
 291
 292         if(self.flagcarried)
 293                 DropFlag(self.flagcarried);
 294
 295         DistributeFragsAmongTeam(self, self.team, 1);
 296
 297         if(self.frags <= 0 && self.frags > -666 && cvar("g_lms") && self.killcount != -666)
 298                 bprint (strcat("^4", self.netname, "^4 has no more lives left\n"));
 299         else if(self.killcount != -666)
 300                 bprint (strcat("^4", self.netname, "^4 is spectating now\n"));
 301
 302         self.classname = "observer";
 303         self.health = -666;
 304         self.takedamage = DAMAGE_NO;
 305         self.solid = SOLID_NOT;
 306         self.movetype = MOVETYPE_NOCLIP;
 307         self.flags = FL_CLIENT | FL_NOTARGET;
 308         self.armorvalue = 666;
 309         self.effects = 0;
 310         self.armorvalue = cvar("g_balance_armor_start");
 311         self.pauserotarmor_finished = 0;
 312         self.pauserothealth_finished = 0;
 313         self.pauseregen_finished = 0;
 314         self.damageforcescale = 0;
 315         self.death_time = 0;
 316         self.dead_time = 0;
 317         self.dead_frame = 0;
 318         self.die_frame = 0;
 319         self.deaths = 0;
 320         self.alpha = 0;
 321         self.scale = 0;
 322         self.fade_time = 0;
 323         self.pain_frame = 0;
 324         self.pain_finished = 0;
 325         self.strength_finished = 0;
 326         self.invincible_finished = 0;
 327         self.pushltime = 0;
 328         self.think = SUB_Null;
 329         self.nextthink = 0;
 330         self.hook_time = 0;
 331         self.runes = 0;
 332         self.deadflag = DEAD_NO;
 333         self.angles = spot.angles;
 334         self.angles_z = 0;
 335         self.fixangle = TRUE;
 336         self.crouch = FALSE;
 337
 338         self.view_ofs = PL_VIEW_OFS;
 339         setorigin (self, spot.origin);
 340         setsize (self, '0 0 0', '0 0 0');
 341         self.oldorigin = self.origin;
 342         self.items = 0;
 343         self.model = "";
 344         self.modelindex = 0;
 345         self.weapon = 0;
 346         self.weaponmodel = "";
 347         self.weaponentity = world;
 348         self.killcount = -666;
 349         self.velocity = '0 0 0';
 350         self.avelocity = '0 0 0';
 351         self.punchangle = '0 0 0';
 352         self.punchvector = '0 0 0';
 353         self.oldvelocity = self.velocity;
 354         self.customizeentityforclient = Client_customizeentityforclient;
 355
 356         if(cvar("g_arena"))
 357         {
 358                 if(self.frags != -2)
 359                 {
 360                         Spawnqueue_Insert(self);
 361                 }
 362                 else
 363                 {
 364                         Spawnqueue_Unmark(self);
 365                         Spawnqueue_Remove(self);
 366                 }
 367         }
 368         else if(!cvar("g_lms"))
 369                 self.frags = -666;
 370 }
 371
 372
 373 /*
 374 =============
 375 PutClientInServer
 376
 377 Called when a client spawns in the server
 378 =============
 379 */
 380 void PutClientInServer (void)
 381 {
 382         if(clienttype(self) == CLIENTTYPE_BOT)
 383         {
 384                 self.classname = "player";
 385         }
 386         else if(clienttype(self) == CLIENTTYPE_REAL)
 387         {
 388                 msg_entity = self;
 389                 WriteByte(MSG_ONE, SVC_SETVIEW);
 390                 WriteEntity(MSG_ONE, self);
 391         }
 392
 393         // player is dead and becomes observer
 394         if(cvar("g_lms") && self.frags < 1)
 395                 self.classname = "observer";
 396
 397         if(cvar("g_arena"))
 398         if(!self.spawned)
 399                 self.classname = "observer";
 400
 401         if(self.classname == "player") {
 402                 entity  spot;
 403
 404                 spot = SelectSpawnPoint (FALSE);
 405
 406                 RemoveGrapplingHook(self); // Wazat's Grappling Hook
 407
 408                 self.classname = "player";
 409                 self.iscreature = TRUE;
 410                 self.movetype = MOVETYPE_WALK;
 411                 self.solid = SOLID_SLIDEBOX;
 412                 self.flags = FL_CLIENT;
 413                 self.takedamage = DAMAGE_AIM;
 414                 self.effects = 0;
 415                 self.health = cvar("g_balance_health_start");
 416                 self.armorvalue = cvar("g_balance_armor_start");
 417                 self.spawnshieldtime = time + cvar("g_spawnshieldtime");
 418                 self.pauserotarmor_finished = time + cvar("g_balance_pause_armor_rot_spawn");
 419                 self.pauserothealth_finished = time + cvar("g_balance_pause_health_rot_spawn");
 420                 self.pauseregen_finished = time + cvar("g_balance_pause_health_regen_spawn");
 421                 self.damageforcescale = 2;
 422                 self.death_time = 0;
 423                 self.dead_time = 0;
 424                 self.dead_frame = 0;
 425                 self.die_frame = 0;
 426                 self.alpha = 0;
 427                 self.scale = 0;
 428                 self.fade_time = 0;
 429                 self.pain_frame = 0;
 430                 self.pain_finished = 0;
 431                 self.strength_finished = 0;
 432                 self.invincible_finished = 0;
 433                 self.pushltime = 0;
 434                 //self.speed_finished = 0;
 435                 //self.slowmo_finished = 0;
 436                 // players have no think function
 437                 self.think = SUB_Null;
 438                 self.nextthink = 0;
 439                 self.weapon = 0;
 440                 self.switchweapon = 0;
 441                 self.hook_time = 0;
 442
 443                 self.runes = 0;
 444
 445                 self.deadflag = DEAD_NO;
 446
 447                 self.angles = spot.angles;
 448
 449                 self.angles_z = 0; // never spawn tilted even if the spot says to
 450                 self.fixangle = TRUE; // turn this way immediately
 451                 self.velocity = '0 0 0';
 452                 self.avelocity = '0 0 0';
 453                 self.punchangle = '0 0 0';
 454                 self.punchvector = '0 0 0';
 455                 self.oldvelocity = self.velocity;
 456
 457                 self.viewzoom = 0.6;
 458
 459                 self.customizeentityforclient = Client_customizeentityforclient;
 460
 461                 if(cvar("sv_defaultcharacter") == 1 && !teams_matter) {
 462                         local string defaultmodel;
 463                         defaultmodel = CheckPlayerModel(cvar_string("sv_defaultplayermodel"));
 464                         setmodel_lod (self, defaultmodel);
 465                         self.skin = stof(cvar_string("sv_defaultplayerskin"));
 466                 } else {
 467                         self.playermodel = CheckPlayerModel(self.playermodel);
 468                         setmodel_lod (self, self.playermodel);
 469                         if(teams_matter)
 470                                 self.skin = math_mod(stof(self.playerskin), NUM_PLAYERSKINS_TEAMPLAY);
 471                         else
 472                                 self.skin = stof(self.playerskin);
 473                 }
 474
 475                 self.crouch = FALSE;
 476                 self.view_ofs = PL_VIEW_OFS;
 477                 setsize (self, PL_MIN, PL_MAX);
 478                 self.spawnorigin = spot.origin;
 479                 setorigin (self, spot.origin + '0 0 1' * (1 - self.mins_z - 24));
 480                 // don't reset back to last position, even if new position is stuck in solid
 481                 self.oldorigin = self.origin;
 482
 483                 if(cvar("g_lms"))
 484                 {
 485                         self.ammo_shells = cvar("g_lms_start_ammo_shells");
 486                         self.ammo_nails = cvar("g_lms_start_ammo_nails");
 487                         self.ammo_rockets = cvar("g_lms_start_ammo_rockets");
 488                         self.ammo_cells = cvar("g_lms_start_ammo_cells");
 489                         self.health = cvar("g_lms_start_health");
 490                         self.armorvalue = cvar("g_lms_start_armor");
 491                 }
 492                 else if (cvar("g_use_ammunition")) {
 493                         self.ammo_shells = cvar("g_start_ammo_shells");
 494                         self.ammo_nails = cvar("g_start_ammo_nails");
 495                         self.ammo_rockets = cvar("g_start_ammo_rockets");
 496                         self.ammo_cells = cvar("g_start_ammo_cells");
 497                 } else {
 498                         self.ammo_shells = 999;
 499                         self.ammo_nails = 999;
 500                         self.ammo_rockets = 999;
 501                         self.ammo_cells = 999;
 502                 }
 503
 504                 self.items = 0;
 505                 if (cvar("g_start_weapon_laser") || cvar("g_lms"))
 506                 {
 507                         self.items = self.items | IT_LASER;
 508                         self.switchweapon = WEP_LASER;
 509                 }
 510                 if (cvar("g_start_weapon_shotgun") || cvar("g_lms"))
 511                 {
 512                         self.items = self.items | IT_SHOTGUN;
 513                         self.switchweapon = WEP_SHOTGUN;
 514                 }
 515                 if (cvar("g_start_weapon_uzi") || cvar("g_lms"))
 516                 {
 517                         self.items = self.items | IT_UZI;
 518                         self.switchweapon = WEP_UZI;
 519                 }
 520                 if (cvar("g_start_weapon_grenadelauncher") || cvar("g_lms"))
 521                 {
 522                         self.items = self.items | IT_GRENADE_LAUNCHER;
 523                         self.switchweapon = WEP_GRENADE_LAUNCHER;
 524                 }
 525                 if (cvar("g_start_weapon_electro") || cvar("g_lms"))
 526                 {
 527                         self.items = self.items | IT_ELECTRO;
 528                         self.switchweapon = WEP_ELECTRO;
 529                 }
 530                 if (cvar("g_start_weapon_crylink") || cvar("g_lms"))
 531                 {
 532                         self.items = self.items | IT_CRYLINK;
 533                         self.switchweapon = WEP_CRYLINK;
 534                 }
 535                 if (cvar("g_start_weapon_nex") || cvar("g_lms"))
 536                 {
 537                         self.items = self.items | IT_NEX;
 538                         self.switchweapon = WEP_NEX;
 539                 }
 540                 if (cvar("g_start_weapon_hagar") || cvar("g_lms"))
 541                 {
 542                         self.items = self.items | IT_HAGAR;
 543                         self.switchweapon = WEP_HAGAR;
 544                 }
 545                 if (cvar("g_start_weapon_rocketlauncher") || cvar("g_lms"))
 546                 {
 547                         self.items = self.items | IT_ROCKET_LAUNCHER;
 548                         self.switchweapon = WEP_ROCKET_LAUNCHER;
 549                 }
 550
 551                 if(cvar("g_instagib"))
 552                 {
 553                         self.items = IT_NEX;
 554                         self.switchweapon = WEP_NEX;
 555                         self.ammo_cells = 999;
 556                 }
 557
 558                 if(cvar("g_rocketarena"))
 559                 {
 560                         self.items = IT_ROCKET_LAUNCHER;
 561                         self.switchweapon = WEP_ROCKET_LAUNCHER;
 562                         self.ammo_rockets = 999;
 563                 }
 564
 565                 if(cvar("g_nixnex"))
 566                 {
 567                         self.items = 0;
 568                         // will be done later
 569                 }
 570
 571                 if(cvar("g_minstagib"))
 572                 {
 573                         self.health = 100;
 574                         self.armorvalue = 0;
 575                         self.items = IT_NEX;
 576                         self.switchweapon = WEP_NEX;
 577                         self.ammo_cells = cvar("g_minstagib_ammo_start");
 578                         self.jump_interval = time;
 579                 }
 580
 581                 if(cvar("g_arena"))
 582                 {
 583                         Spawnqueue_Remove(self);
 584                         Spawnqueue_Mark(self);
 585                 }
 586
 587                 self.event_damage = PlayerDamage;
 588
 589                 self.bot_attack = TRUE;
 590
 591                 self.statdraintime = time + 5;
 592                 self.button0 = self.button1 = self.button2 = self.button3 = 0;
 593
 594                 if(self.killcount == -666) {
 595                         self.killcount = 0;
 596                         if(!cvar("g_arena"))
 597                         if(!cvar("g_lms"))
 598                                 self.frags = 0;
 599                 }
 600
 601                 self.cnt = WEP_LASER;
 602                 self.nixnex_lastchange_id = -1;
 603
 604                 CL_SpawnWeaponentity();
 605                 self.alpha = default_player_alpha;
 606                 self.exteriorweaponentity.alpha = default_weapon_alpha;
 607
 608                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval")*2;
 609                 self.lms_traveled_distance = 0;
 610
 611                 if(cvar("spawn_debug"))
 612                 {
 613                                 sprint(self, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 614                                 remove(spot);   // usefull for checking if there are spawnpoints, that let drop through the floor
 615                 }
 616
 617                 //stuffcmd(self, "chase_active 0");
 618                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
 619         } else if(self.classname == "observer") {
 620                 PutObserverInServer ();
 621         }
 622 }
 623
 624 /*
 625 =============
 626 SetNewParms
 627 =============
 628 */
 629 void SetNewParms (void)
 630 {
 631
 632 }
 633
 634 /*
 635 =============
 636 SetChangeParms
 637 =============
 638 */
 639 void SetChangeParms (void)
 640 {
 641
 642 }
 643
 644 /*
 645 =============
 646 ClientKill
 647
 648 Called when a client types 'kill' in the console
 649 =============
 650 */
 651 void ClientKill (void)
 652 {
 653         Damage(self, self, self, 100000, DEATH_KILL, self.origin, '0 0 0');
 654 }
 655
 656 /*
 657 =============
 658 ClientConnect
 659
 660 Called when a client connects to the server
 661 =============
 662 */
 663 string ColoredTeamName(float t);
 664 //void dom_player_join_team(entity pl);
 665 void ClientConnect (void)
 666 {
 667         local string s;
 668
 669         self.classname = "player_joining";
 670         self.flags = self.flags | FL_CLIENT;
 671         self.version_nagtime = time + 10 + random() * 10;
 672
 673         if(player_count<0)
 674         {
 675                 dprint("BUG player count is lower than zero, this cannot happen!\n");
 676                 player_count = 0;
 677         }
 678
 679         bot_clientconnect();
 680
 681         //if(cvar("g_domination"))
 682         //      dom_player_join_team(self);
 683
 684         //JoinBestTeam(self, FALSE);
 685
 686         if((cvar("sv_spectate") == 1 && !cvar("g_lms")) || cvar("g_campaign")) {
 687                 self.classname = "observer";
 688         } else {
 689                 self.classname = "player";
 690                 campaign_bots_may_start = 1;
 691         }
 692
 693         self.playerid = (playerid_last = playerid_last + 1);
 694         if(cvar("sv_eventlog"))
 695         {
 696                 if(clienttype(self) == CLIENTTYPE_REAL)
 697                         s = "player";
 698                 else
 699                         s = "bot";
 700                 GameLogEcho(strcat(":join:", ftos(self.playerid), ":", s, ":", self.netname), TRUE);
 701                 s = strcat(":team:", ftos(self.playerid), ":");
 702                 s = strcat(s, ftos(self.team));
 703                 GameLogEcho(s, FALSE);
 704         }
 705
 706         //stuffcmd(self, "set tmpviewsize $viewsize \n");
 707
 708         bprint ("^4",self.netname);
 709         bprint ("^4 connected");
 710
 711         if(cvar("g_domination") || cvar("g_ctf"))
 712         {
 713                 bprint(" and joined the ");
 714                 bprint(ColoredTeamName(self.team));
 715         }
 716
 717         bprint("\n");
 718
 719         self.welcomemessage_time = time + cvar("welcome_message_time");
 720         self.welcomemessage_time2 = 0;
 721
 722         stuffcmd(self, strcat("exec maps/", mapname, ".cfg\n"));
 723         // TODO: is this being used for anything else than cd tracks?
 724         // Remember: SVC_CDTRACK exists. Maybe it should be used.
 725
 726         // send prediction settings to the client
 727         stuffcmd(self, strcat("cl_movement_accelerate ", ftos(cvar("sv_accelerate")), "\n"));
 728         stuffcmd(self, strcat("cl_movement_friction ", ftos(cvar("sv_friction")), "\n"));
 729         stuffcmd(self, strcat("cl_movement_maxspeed ", ftos(cvar("sv_maxspeed")), "\n"));
 730         stuffcmd(self, strcat("cl_movement_airaccelerate ", ftos(cvar("sv_airaccelerate")), "\n"));
 731         stuffcmd(self, strcat("cl_movement_maxairspeed ", ftos(cvar("sv_maxairspeed")), "\n"));
 732         stuffcmd(self, strcat("cl_movement_stopspeed ", ftos(cvar("sv_stopspeed")), "\n"));
 733         stuffcmd(self, strcat("cl_movement_jumpvelocity ", ftos(cvar("g_balance_jumpheight")), "\n"));
 734         stuffcmd(self, strcat("cl_movement_stepheight ", ftos(cvar("sv_stepheight")), "\n"));
 735         stuffcmd(self, strcat("set cl_movement_friction_on_land ", ftos(cvar("sv_friction_on_land")), "\n"));
 736         stuffcmd(self, strcat("set cl_movement_airaccel_qw ", ftos(cvar("sv_airaccel_qw")), "\n"));
 737         stuffcmd(self, strcat("set cl_movement_airaccel_sideways_friction ", ftos(cvar("sv_airaccel_sideways_friction")), "\n"));
 738         stuffcmd(self, strcat("cl_movement_edgefriction 0\n"));
 739         // Wazat's grappling hook
 740         SetGrappleHookBindings();
 741
 742         // get autoswitch state from player
 743         stuffcmd(self, "alias autoswitch \"set cl_autoswitch $1; cmd autoswitch $1\"\n");
 744         stuffcmd(self, "cmd autoswitch $cl_autoswitch\n");
 745
 746         // get version info from player
 747         stuffcmd(self, "cmd clientversion $gameversion\n");
 748
 749         // get other cvars from player
 750         GetCvars(0);
 751
 752         // set cvar for team scoreboard
 753         if (teams_matter)
 754         {
 755                 local float t;
 756                 t = cvar("teamplay");
 757                 // we have to stuff the correct teamplay value because if this is a listen server, this changes the teamplay mode of the server itself, which is bad
 758                 stuffcmd(self, strcat("set teamplay ", ftos(t), "\n"));
 759         }
 760         else
 761                 stuffcmd(self, strcat("set teamplay 0\n"));
 762
 763         if(cvar("g_lms"))
 764         {
 765                 self.frags = cvar("fraglimit");
 766                 // no fraglimit was set, so player gets 999 lives
 767                 if(self.frags < 1)
 768                         self.frags = 999;
 769
 770                 self.frags = LMS_NewPlayerLives();
 771                 if(!self.frags)
 772                 {
 773                         self.frags = -666;
 774                 }
 775         }
 776         else if(cvar("g_arena"))
 777         {
 778                 self.classname = "observer";
 779                 Spawnqueue_Insert(self);
 780         }
 781
 782         bot_relinkplayerlist();
 783
 784         self.jointime = time;
 785 }
 786
 787 /*
 788 =============
 789 ClientDisconnect
 790
 791 Called when a client disconnects from the server
 792 =============
 793 */
 794 void(entity e) DropFlag;
 795 .entity chatbubbleentity;
 796 .entity teambubbleentity;
 797 void ClientDisconnect (void)
 798 {
 799         float save;
 800         if(cvar("sv_eventlog"))
 801                 GameLogEcho(strcat(":part:", ftos(self.playerid)), FALSE);
 802         bprint ("^4",self.netname);
 803         bprint ("^4 disconnected\n");
 804
 805         if (self.chatbubbleentity)
 806         {
 807                 remove (self.chatbubbleentity);
 808                 self.chatbubbleentity = world;
 809         }
 810
 811         if (self.teambubbleentity)
 812         {
 813                 remove (self.teambubbleentity);
 814                 self.teambubbleentity = world;
 815         }
 816
 817         DropAllRunes(self);
 818
 819         if(self.flagcarried)
 820                 DropFlag(self.flagcarried);
 821
 822         DistributeFragsAmongTeam(self, self.team, 1);
 823
 824         save = self.flags;
 825         self.flags = self.flags - (self.flags & FL_CLIENT);
 826         bot_relinkplayerlist();
 827         self.flags = save;
 828
 829         // remove laserdot
 830         if(self.weaponentity)
 831                 if(self.weaponentity.lasertarget)
 832                         remove(self.weaponentity.lasertarget);
 833
 834         if(cvar("g_arena"))
 835         {
 836                 Spawnqueue_Unmark(self);
 837                 Spawnqueue_Remove(self);
 838         }
 839
 840         // free cvars
 841         GetCvars(-1);
 842 }
 843
 844 .float buttonchat;
 845 void() ChatBubbleThink =
 846 {
 847         self.nextthink = time;
 848         if (!self.owner.modelindex || self.owner.chatbubbleentity != self)
 849         {
 850                 self.owner.chatbubbleentity = world;
 851                 remove(self);
 852                 return;
 853         }
 854         setorigin(self, self.owner.origin + '0 0 15' + self.owner.maxs_z * '0 0 1');
 855         if (self.owner.buttonchat && !self.owner.deadflag)
 856                 self.model = self.mdl;
 857         else
 858                 self.model = "";
 859 };
 860
 861 void() UpdateChatBubble =
 862 {
 863         if (!self.modelindex)
 864                 return;
 865         // spawn a chatbubble entity if needed
 866         if (!self.chatbubbleentity)
 867         {
 868                 self.chatbubbleentity = spawn();
 869                 self.chatbubbleentity.owner = self;
 870                 self.chatbubbleentity.exteriormodeltoclient = self;
 871                 self.chatbubbleentity.think = ChatBubbleThink;
 872                 self.chatbubbleentity.nextthink = time;
 873                 setmodel(self.chatbubbleentity, "models/misc/chatbubble.spr");
 874                 setorigin(self.chatbubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
 875                 self.chatbubbleentity.mdl = self.chatbubbleentity.model;
 876                 self.chatbubbleentity.model = "";
 877         }
 878 }
 879
 880
 881 void() TeamBubbleThink =
 882 {
 883         self.nextthink = time;
 884         if (!self.owner.modelindex || self.owner.teambubbleentity != self)
 885         {
 886                 self.owner.teambubbleentity = world;
 887                 remove(self);
 888                 return;
 889         }
 890 //      setorigin(self, self.owner.origin + '0 0 15' + self.owner.maxs_z * '0 0 1');  // bandwidth hog. setattachment does this now
 891         if (self.owner.buttonchat || self.owner.deadflag)
 892                 self.model = "";
 893         else
 894                 self.model = self.mdl;
 895
 896 };
 897
 898 float() TeamBubble_customizeentityforclient
 899 {
 900         return (self.owner != other && self.owner.team == other.team && other.killcount > -666);
 901 }
 902
 903 void() UpdateTeamBubble =
 904 {
 905         if (!self.modelindex || !cvar("teamplay"))
 906                 return;
 907         // spawn a teambubble entity if needed
 908         if (!self.teambubbleentity && cvar("teamplay"))
 909         {
 910                 self.teambubbleentity = spawn();
 911                 self.teambubbleentity.owner = self;
 912                 self.teambubbleentity.exteriormodeltoclient = self;
 913                 self.teambubbleentity.think = TeamBubbleThink;
 914                 self.teambubbleentity.nextthink = time;
 915                 setmodel(self.teambubbleentity, "models/misc/teambubble.spr");
 916 //              setorigin(self.teambubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
 917                 setorigin(self.teambubbleentity, self.teambubbleentity.origin + '0 0 15' + self.maxs_z * '0 0 1');
 918                 setattachment(self.teambubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
 919                 self.teambubbleentity.mdl = self.teambubbleentity.model;
 920                 self.teambubbleentity.model = self.teambubbleentity.mdl;
 921                 self.teambubbleentity.customizeentityforclient = TeamBubble_customizeentityforclient;
 922         }
 923 }
 924
 925 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
 926 // added to the model skins
 927 /*void() UpdateColorModHack =
 928 {
 929         local float c;
 930         c = self.clientcolors & 15;
 931         // LordHavoc: only bothering to support white, green, red, yellow, blue
 932              if (teamplay == 0) self.colormod = '0 0 0';
 933         else if (c ==  0) self.colormod = '1.00 1.00 1.00';
 934         else if (c ==  3) self.colormod = '0.10 1.73 0.10';
 935         else if (c ==  4) self.colormod = '1.73 0.10 0.10';
 936         else if (c == 12) self.colormod = '1.22 1.22 0.10';
 937         else if (c == 13) self.colormod = '0.10 0.10 1.73';
 938         else self.colormod = '1 1 1';
 939 };*/
 940
 941 /*
 942 =============
 943 PlayerJump
 944
 945 When you press the jump key
 946 =============
 947 */
 948 void PlayerJump (void)
 949 {
 950         float mjumpheight;
 951
 952         mjumpheight = cvar("g_balance_jumpheight");
 953         if (self.waterlevel >= 2)
 954         {
 955                 if (self.watertype == CONTENT_WATER)
 956                         self.velocity_z = 200;
 957                 else if (self.watertype == CONTENT_SLIME)
 958                         self.velocity_z = 80;
 959                 else
 960                         self.velocity_z = 50;
 961
 962                 return;
 963         }
 964
 965
 966         if (!(self.flags & FL_ONGROUND))
 967                 return;
 968
 969         if (!(self.flags & FL_JUMPRELEASED))
 970                 return;
 971
 972         if(cvar("g_runematch"))
 973         {
 974                 if(self.runes & RUNE_SPEED)
 975                 {
 976                         if(self.runes & CURSE_SLOW)
 977                                 mjumpheight = mjumpheight * cvar("g_balance_rune_speed_combo_jumpheight");
 978                         else
 979                                 mjumpheight = mjumpheight * cvar("g_balance_rune_speed_jumpheight");
 980                 }
 981                 else if(self.runes & CURSE_SLOW)
 982                 {
 983                         mjumpheight = mjumpheight * cvar("g_balance_curse_slow_jumpheight");
 984                 }
 985         }
 986
 987         if(cvar("g_minstagib") && (self.items & IT_INVINCIBLE))
 988         {
 989                 mjumpheight = mjumpheight * cvar("g_balance_rune_speed_jumpheight");
 990         }
 991
 992         self.velocity_z = self.velocity_z + mjumpheight;
 993         self.oldvelocity_z = self.velocity_z;
 994
 995         self.flags = self.flags - FL_ONGROUND;
 996         self.flags = self.flags - FL_JUMPRELEASED;
 997 }
 998
 999 void() CheckWaterJump =
1000 {
1001         local vector start, end;
1002
1003 // check for a jump-out-of-water
1004         makevectors (self.angles);
1005         start = self.origin;
1006         start_z = start_z + 8;
1007         v_forward_z = 0;
1008         normalize(v_forward);
1009         end = start + v_forward*24;
1010         traceline (start, end, TRUE, self);
1011         if (trace_fraction < 1)
1012         {       // solid at waist
1013                 start_z = start_z + self.maxs_z - 8;
1014                 end = start + v_forward*24;
1015                 self.movedir = trace_plane_normal * -50;
1016                 traceline (start, end, TRUE, self);
1017                 if (trace_fraction == 1)
1018                 {       // open at eye level
1019                         self.flags = self.flags | FL_WATERJUMP;
1020                         self.velocity_z = 225;
1021                         self.flags = self.flags - (self.flags & FL_JUMPRELEASED);
1022                         self.teleport_time = time + 2;  // safety net
1023                         return;
1024                 }
1025         }
1026 };
1027
1028
1029 void respawn(void)
1030 {
1031         CopyBody(1);
1032         PutClientInServer();
1033 }
1034
1035 void player_powerups (void)
1036 {
1037         if (cvar("g_minstagib"))
1038         {
1039                 self.effects = EF_FULLBRIGHT;
1040                 if (self.items & IT_STRENGTH)
1041                 {
1042                         if (time > self.strength_finished)
1043                         {
1044                                 self.alpha = default_player_alpha;
1045                                 self.exteriorweaponentity.alpha = default_weapon_alpha;
1046                                 self.items = self.items - (self.items & IT_STRENGTH);
1047                                 sprint(self, "^3Invisibility has worn off\n");
1048                         }
1049                 }
1050                 else
1051                 {
1052                         if (time < self.strength_finished)
1053                         {
1054                                 self.alpha = cvar("g_minstagib_invis_alpha");
1055                                 self.exteriorweaponentity.alpha = cvar("g_minstagib_invis_alpha");
1056                                 self.items = self.items | IT_STRENGTH;
1057                                 sprint(self, "^3You are invisible\n");
1058                         }
1059                 }
1060
1061                 if (self.items & IT_INVINCIBLE)
1062                 {
1063                         if (time > self.invincible_finished)
1064                         {
1065                                 self.items = self.items - (self.items & IT_INVINCIBLE);
1066                                 sprint(self, "^3Speed has worn off\n");
1067                         }
1068                 }
1069                 else
1070                 {
1071                         if (time < self.invincible_finished)
1072                         {
1073                                 self.items = self.items | IT_INVINCIBLE;
1074                                 sprint(self, "^3You are on speed\n");
1075                         }
1076                 }
1077                 return;
1078         }
1079
1080         self.effects = self.effects - (self.effects & (EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT));
1081         if (self.items & IT_STRENGTH)
1082         {
1083                 self.effects = self.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1084                 if (time > self.strength_finished)
1085                 {
1086                         self.items = self.items - (self.items & IT_STRENGTH);
1087                         sprint(self, "^3Strength has worn off\n");
1088                 }
1089         }
1090         else
1091         {
1092                 if (time < self.strength_finished)
1093                 {
1094                         self.items = self.items | IT_STRENGTH;
1095                         sprint(self, "^3Strength infuses your weapons with devastating power\n");
1096                 }
1097         }
1098         if (self.items & IT_INVINCIBLE)
1099         {
1100                 self.effects = self.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1101                 if (time > self.invincible_finished)
1102                 {
1103                         self.items = self.items - (self.items & IT_INVINCIBLE);
1104                         sprint(self, "^3Shield has worn off\n");
1105                 }
1106         }
1107         else
1108         {
1109                 if (time < self.invincible_finished)
1110                 {
1111                         self.items = self.items | IT_INVINCIBLE;
1112                         sprint(self, "^3Shield surrounds you\n");
1113                 }
1114         }
1115
1116         if (cvar("g_fullbrightplayers"))
1117                 self.effects = self.effects | EF_FULLBRIGHT;
1118
1119         // midair gamemode: damage only while in the air
1120         // if in midair mode, being on ground grants temporary invulnerability
1121         // (this is so that multishot weapon don't clear the ground flag on the
1122         // first damage in the frame, leaving the player vulnerable to the
1123         // remaining hits in the same frame)
1124         if (self.flags & FL_ONGROUND)
1125         if (cvar("g_midair"))
1126                 self.spawnshieldtime = max(self.spawnshieldtime, time + cvar("g_midair_shieldtime"));
1127
1128         if (time < self.spawnshieldtime)
1129                 self.effects = self.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1130 }
1131
1132 float CalcRegen(float current, float stable, float maxv, float regenfactor)
1133 {
1134         if(current > stable)
1135                 return current;
1136         else if(current > stable - 0.25) // when close enough, "snap"
1137                 return stable;
1138         else
1139                 return bound(0, current + (stable - current) * regenfactor * frametime, maxv);
1140 }
1141
1142 void player_regen (void)
1143 {
1144         float maxh, maxa, limith, limita, max_mod, regen_mod, rot_mod, limit_mod;
1145         maxh = cvar("g_balance_health_stable");
1146         maxa = cvar("g_balance_armor_stable");
1147         limith = cvar("g_balance_health_limit");
1148         limita = cvar("g_balance_armor_limit");
1149
1150         if (cvar("g_minstagib") || (cvar("g_lms") && !cvar("g_lms_regenerate")))
1151                 return;
1152
1153         if(cvar("g_runematch"))
1154         {
1155                 max_mod = regen_mod = rot_mod = limit_mod = 1;
1156                 if (self.runes & RUNE_REGEN)
1157                 {
1158                         if (self.runes & CURSE_VENOM) // do we have both rune/curse?
1159                         {
1160                                 regen_mod = cvar("g_balance_rune_regen_combo_regenrate");
1161                                 max_mod = cvar("g_balance_rune_regen_combo_hpmod");
1162                                 limit_mod = cvar("g_balance_rune_regen_combo_limitmod");
1163                         }
1164                         else
1165                         {
1166                                 regen_mod = cvar("g_balance_rune_regen_regenrate");
1167                                 max_mod = cvar("g_balance_rune_regen_hpmod");
1168                                 limit_mod = cvar("g_balance_rune_regen_limitmod");
1169                         }
1170                 }
1171                 else if (self.runes & CURSE_VENOM)
1172                 {
1173                         max_mod = cvar("g_balance_curse_venom_hpmod");
1174                         if (self.runes & RUNE_REGEN) // do we have both rune/curse?
1175                                 rot_mod = cvar("g_balance_rune_regen_combo_rotrate");
1176                         else
1177                                 rot_mod = cvar("g_balance_curse_venom_rotrate");
1178                         limit_mod = cvar("g_balance_curse_venom_limitmod");
1179                         //if (!self.runes & RUNE_REGEN)
1180                         //      rot_mod = cvar("g_balance_curse_venom_rotrate");
1181                 }
1182                 maxh = maxh * max_mod;
1183                 //maxa = maxa * max_mod;
1184
1185                 if (time > self.pauserotarmor_finished)
1186                 {
1187                         if (self.armorvalue > maxa)
1188                                 self.armorvalue = bound(0, self.armorvalue + (maxa - self.armorvalue) * cvar("g_balance_armor_rot") * frametime, 1000);
1189                 }
1190                 if (time > self.pauserothealth_finished)
1191                 {
1192                         if (self.health > maxh)
1193                                 self.health = bound(0, self.health + (maxh - self.health) * rot_mod*cvar("g_balance_health_rot") * frametime, 1000);
1194                 }
1195                 if (time > self.pauseregen_finished)
1196                 {
1197                         self.health = CalcRegen(self.health, maxh, 1000, regen_mod * cvar("g_balance_health_regen"));
1198                         self.armorvalue = CalcRegen(self.armorvalue, maxa, 1000, cvar("g_balance_armor_regen"));
1199                 }
1200         }
1201         else
1202         {
1203                 if (time > self.pauserothealth_finished)
1204                 if (self.health > maxh)
1205                         self.health = bound(0, self.health + (maxh - self.health) * cvar("g_balance_health_rot") * frametime, 1000);
1206                 if (time > self.pauserotarmor_finished)
1207                 if (self.armorvalue > maxa)
1208                         self.armorvalue = bound(0, self.armorvalue + (maxa - self.armorvalue) * cvar("g_balance_armor_rot") * frametime, 1000);
1209                 if (time > self.pauseregen_finished)
1210                 {
1211                         self.health = CalcRegen(self.health, maxh, 1000, cvar("g_balance_health_regen"));
1212                         self.armorvalue = CalcRegen(self.armorvalue, maxa, 1000, cvar("g_balance_armor_regen"));
1213                 }
1214         }
1215
1216         if (self.health > limith)
1217                 self.health = limith;
1218         if(self.health < 1)
1219                 self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
1220         if (self.armorvalue > limita)
1221                 self.armorvalue = limita;
1222 }
1223
1224 /*
1225 ======================
1226 spectate mode routines
1227 ======================
1228 */
1229 void SpectateCopy(entity spectatee) {
1230         self.armortype = spectatee.armortype;
1231         self.armorvalue = spectatee.armorvalue;
1232         self.currentammo = spectatee.currentammo;
1233         self.effects = spectatee.effects;
1234         self.health = spectatee.health;
1235         self.impulse = 0;
1236         self.items = spectatee.items;
1237         self.punchangle = spectatee.punchangle;
1238         self.view_ofs = spectatee.view_ofs;
1239         self.v_angle = spectatee.v_angle;
1240         self.viewzoom = spectatee.viewzoom;
1241         setorigin(self, spectatee.origin);
1242         setsize(self, spectatee.mins, spectatee.maxs);
1243 }
1244
1245 void SpectateUpdate() {
1246         if(!self.enemy)
1247                         PutObserverInServer();
1248
1249         if (self != self.enemy) {
1250                 if(self.enemy.flags & FL_NOTARGET)
1251                         PutObserverInServer();
1252                 SpectateCopy(self.enemy);
1253                 self.dmg_take = self.enemy.dmg_take;
1254                 self.dmg_save = self.enemy.dmg_save;
1255                 self.dmg_inflictor = self.enemy.dmg_inflictor;
1256                 self.fixangle = TRUE;
1257                 self.angles = self.enemy.v_angle;
1258                 //msg_entity = self;
1259                 //WriteByte(MSG_ONE, SVC_SETANGLE);
1260                 //WriteAngle(MSG_ONE, self.enemy.v_angle_x);
1261                 //WriteAngle(MSG_ONE, self.enemy.v_angle_y);
1262                 //WriteAngle(MSG_ONE, self.enemy.v_angle_z);
1263         }
1264 }
1265
1266 float SpectateNext() {
1267         other = find(self.enemy, classname, "player");
1268         if (!other) {
1269                 other = find(other, classname, "player");
1270         }
1271         if (other) {
1272                 self.enemy = other;
1273         }
1274         if(self.enemy.classname == "player") {
1275                 msg_entity = self;
1276                 WriteByte(MSG_ONE, SVC_SETVIEW);
1277                 WriteEntity(MSG_ONE, self.enemy);
1278                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
1279                 SpectateUpdate();
1280                 return 1;
1281         } else {
1282                 return 0;
1283         }
1284 }
1285
1286 /*
1287 =============
1288 ShowRespawnCountdown()
1289
1290 Update a respawn countdown display.
1291 =============
1292 */
1293 void ShowRespawnCountdown()
1294 {
1295         float number;
1296         if(self.deadflag == DEAD_NO) // just respawned?
1297                 return;
1298         else
1299         {
1300                 number = ceil(self.death_time - time);
1301                 if(number <= 0)
1302                         return;
1303                 if(number <= self.respawn_countdown)
1304                 {
1305                         self.respawn_countdown = number - 1;
1306                         if(ceil(self.death_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
1307                                 stuffcmd(self, strcat("play2 announcer/robotic/", ftos(number), ".ogg\n"));
1308                 }
1309         }
1310 }
1311
1312 void LeaveSpectatorMode()
1313 {
1314         if(!cvar("teamplay") || cvar("g_campaign") || cvar("g_balance_teams")) {
1315                 self.classname = "player";
1316                 if(cvar("g_campaign") || cvar("g_balance_teams"))
1317                         JoinBestTeam(self, 0);
1318                 if(cvar("g_campaign"))
1319                         campaign_bots_may_start = 1;
1320                 PutClientInServer();
1321                 if(!(self.flags & FL_NOTARGET))
1322                         bprint (strcat("^4", self.netname, "^4 is playing now\n"));
1323                 centerprint(self,"");
1324                 return;
1325         } else {
1326                 stuffcmd(self,"menu_showteamselect\n");
1327                 return;
1328         }
1329 }
1330
1331 /*
1332 =============
1333 PlayerPreThink
1334
1335 Called every frame for each client before the physics are run
1336 =============
1337 */
1338 void() ctf_setstatus;
1339 void PlayerPreThink (void)
1340 {
1341         // version nagging
1342         if(self.version_nagtime)
1343                 if(self.cvar_g_nexuizversion)
1344                         if(time > self.version_nagtime)
1345                         {
1346                                 if(strstr(self.cvar_g_nexuizversion, "svn", 0) < 0)
1347                                         if(self.cvar_g_nexuizversion != cvar_string("g_nexuizversion"))
1348                                         {
1349                                                 dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Nexuiz ", cvar_string("g_nexuizversion"), "^7, you have ^3Nexuiz ", self.cvar_g_nexuizversion, "\n");
1350                                                 sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Nexuiz ", cvar_string("g_nexuizversion"), "^7, you have ^3Nexuiz ", self.cvar_g_nexuizversion, "\n"));
1351                                         }
1352                                 self.version_nagtime = 0;
1353                         }
1354
1355         if(self.classname == "player") {
1356                 local vector m1, m2;
1357
1358 //              if(self.netname == "Wazat")
1359 //                      bprint(strcat(self.classname, "\n"));
1360
1361                 CheckRules_Player();
1362
1363                 Nixnex_GiveCurrentWeapon();
1364
1365                 if(self.button7)
1366                         PrintWelcomeMessage(self);
1367
1368                 if(cvar("g_lms") || !cvar("sv_spectate"))
1369                 if((time - self.jointime) <= cvar("welcome_message_time"))
1370                         PrintWelcomeMessage(self);
1371
1372                 if (intermission_running)
1373                 {
1374                         IntermissionThink ();   // otherwise a button could be missed between
1375                         return;                                 // the think tics
1376                 }
1377
1378                 if (self.deadflag != DEAD_NO)
1379                 {
1380                         float button_pressed, force_respawn;
1381                         player_anim();
1382                         button_pressed = (self.button0 || self.button2 || self.button3 || self.button6 || self.buttonuse);
1383                         force_respawn = (cvar("g_lms") || cvar("g_forced_respawn"));
1384                         if (self.deadflag == DEAD_DYING)
1385                         {
1386                                 if(force_respawn)
1387                                         self.deadflag = DEAD_RESPAWNING;
1388                                 else if(!button_pressed)
1389                                         self.deadflag = DEAD_DEAD;
1390                         }
1391                         else if (self.deadflag == DEAD_DEAD)
1392                         {
1393                                 if(button_pressed)
1394                                         self.deadflag = DEAD_RESPAWNABLE;
1395                         }
1396                         else if (self.deadflag == DEAD_RESPAWNABLE)
1397                         {
1398                                 if(!button_pressed)
1399                                         self.deadflag = DEAD_RESPAWNING;
1400                         }
1401                         else if (self.deadflag == DEAD_RESPAWNING)
1402                         {
1403                                 if(time > self.death_time)
1404                                         respawn();
1405                         }
1406                         ShowRespawnCountdown();
1407                         return;
1408                 }
1409
1410                 if(cvar("g_lms") && !self.deadflag && cvar("g_lms_campcheck_interval"))
1411                 {
1412                         vector dist;
1413
1414                         // calculate player movement (in 2 dimensions only, so jumping on one spot doesn't count as movement)
1415                         dist = self.oldorigin - self.origin;
1416                         dist_z = 0;
1417                         self.lms_traveled_distance += fabs(vlen(dist));
1418
1419                         if(cvar("g_campaign"))
1420                         if(!campaign_bots_may_start)
1421                         {
1422                                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval")*2;
1423                                 self.lms_traveled_distance = 0;
1424                         }
1425
1426                         if(time > self.lms_nextcheck)
1427                         {
1428                                 //sprint(self, "distance: ", ftos(self.lms_traveled_distance), "\n");
1429                                 if(self.lms_traveled_distance < cvar("g_lms_campcheck_distance"))
1430                                 {
1431                                         centerprint(self, cvar_string("g_lms_campcheck_message"));
1432                                         // FIXME KadaverJack: gibbing player here causes playermodel to bounce around, instead of eye.md3
1433                                         // I wasn't able to find out WHY that happens, so I put a workaround in place that shall prevent players from being gibbed :(
1434                                         Damage(self, self, self, bound(0, cvar("g_lms_campcheck_damage"), self.health + self.armorvalue * cvar("g_balance_armor_blockpercent") + 5), DEATH_CAMP, self.origin, '0 0 0');
1435                                 }
1436                                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval");
1437                                 self.lms_traveled_distance = 0;
1438                         }
1439                 }
1440
1441                 if (self.button5 && !self.hook.state)
1442                 {
1443                         if (!self.crouch)
1444                         {
1445                                 self.crouch = TRUE;
1446                                 self.view_ofs = PL_CROUCH_VIEW_OFS;
1447                                 setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX);
1448                         }
1449                 }
1450                 else
1451                 {
1452                         if (self.crouch)
1453                         {
1454                                 tracebox(self.origin, PL_MIN, PL_MAX, self.origin, FALSE, self);
1455                                 if (!trace_startsolid)
1456                                 {
1457                                         self.crouch = FALSE;
1458                                         self.view_ofs = PL_VIEW_OFS;
1459                                         setsize (self, PL_MIN, PL_MAX);
1460                                 }
1461                         }
1462                 }
1463
1464                 if(cvar("sv_defaultcharacter") == 1 && !teams_matter) {
1465                         local string defaultmodel;
1466                         defaultmodel = CheckPlayerModel(cvar_string("sv_defaultplayermodel"));
1467
1468                         if (defaultmodel != self.model)
1469                         {
1470                                 m1 = self.mins;
1471                                 m2 = self.maxs;
1472                                 setmodel_lod (self, defaultmodel);
1473                                 setsize (self, m1, m2);
1474                         }
1475
1476                         if (self.skin != cvar("sv_defaultplayerskin"))
1477                                 self.skin = cvar("sv_defaultplayerskin");
1478                 } else {
1479                         if (self.playermodel != self.model)
1480                         {
1481                                 self.playermodel = CheckPlayerModel(self.playermodel);
1482                                 m1 = self.mins;
1483                                 m2 = self.maxs;
1484                                 setmodel_lod (self, self.playermodel);
1485                                 setsize (self, m1, m2);
1486                         }
1487
1488                         if(teams_matter)
1489                         {
1490                                 if (self.skin != math_mod(stof(self.playerskin), NUM_PLAYERSKINS_TEAMPLAY))
1491                                         self.skin = math_mod(stof(self.playerskin), NUM_PLAYERSKINS_TEAMPLAY);
1492                         }
1493                         else
1494                         {
1495                                 if (self.skin != stof(self.playerskin))
1496                                         self.skin = stof(self.playerskin);
1497                         }
1498                 }
1499
1500                 GrapplingHookFrame();
1501
1502                 W_WeaponFrame();
1503
1504                 if (self.button4 || (self.weapon == WEP_NEX && self.button3))
1505                 {
1506                         if (cvar("g_minstagib") && self.button3)
1507                         {
1508                                 if (self.jump_interval <= (time + 0.1))
1509                                 {
1510                                         self.jump_interval = time + 1;
1511                                         W_Laser_Attack();
1512                                 }
1513                         }
1514                         else if (self.viewzoom > 0.4)
1515                                 self.viewzoom = max (0.4, self.viewzoom - frametime * 2);
1516                 }
1517                 else if (self.viewzoom < 1.0)
1518                         self.viewzoom = min (1.0, self.viewzoom + frametime);
1519
1520
1521                 if (self.button2)
1522                         PlayerJump ();
1523                 else
1524                         self.flags = self.flags | FL_JUMPRELEASED;
1525
1526                 player_powerups();
1527                 player_regen();
1528                 player_anim();
1529
1530                 if (cvar("g_minstagib"))
1531                         minstagib_ammocheck();
1532
1533                 ctf_setstatus();
1534
1535                 //self.angles_y=self.v_angle_y + 90;   // temp
1536
1537                 if (self.waterlevel == 2)
1538                         CheckWaterJump ();
1539
1540                 //if (TetrisPreFrame()) return;
1541         } else if(gameover) {
1542                 if (intermission_running)
1543                         IntermissionThink ();   // otherwise a button could be missed between
1544                 return;
1545         } else if(self.classname == "observer") {
1546
1547                 if (self.flags & FL_JUMPRELEASED) {
1548                         if (self.button2 && self.version == cvar("gameversion")) {
1549                                 self.flags = self.flags - FL_JUMPRELEASED;
1550                                 LeaveSpectatorMode();
1551                                 return;
1552                         } else if(self.button0 && self.version == cvar("gameversion")) {
1553                                 self.flags = self.flags - FL_JUMPRELEASED;
1554                                 if(SpectateNext() == 1) {
1555                                         self.classname = "spectator";
1556                                 }
1557                         }
1558                 } else {
1559                         if (!(self.button0 || self.button2)) {
1560                                 self.flags = self.flags | FL_JUMPRELEASED;
1561                         }
1562                 }
1563                 PrintWelcomeMessage(self);
1564         } else if(self.classname == "spectator") {
1565                 if (self.flags & FL_JUMPRELEASED) {
1566                         if (self.button2 && self.version == cvar("gameversion")) {
1567                                 self.flags = self.flags - FL_JUMPRELEASED;
1568                                 LeaveSpectatorMode();
1569                                 return;
1570                         } else if(self.button0) {
1571                                 self.flags = self.flags - FL_JUMPRELEASED;
1572                                 if(SpectateNext() == 1) {
1573                                         self.classname = "spectator";
1574                                 } else {
1575                                         self.classname = "observer";
1576                                         PutClientInServer();
1577                                 }
1578                         } else if (self.button3) {
1579                                 self.flags = self.flags - FL_JUMPRELEASED;
1580                                 self.classname = "observer";
1581                                 PutClientInServer();
1582                         } else {
1583                                 SpectateUpdate();
1584                         }
1585                 } else {
1586                         if (!(self.button0 || self.button3)) {
1587                                 self.flags = self.flags | FL_JUMPRELEASED;
1588                         }
1589                 }
1590                 PrintWelcomeMessage(self);
1591                 self.flags = self.flags | FL_CLIENT | FL_NOTARGET;
1592         }
1593 }
1594
1595
1596 /*
1597 =============
1598 PlayerPostThink
1599
1600 Called every frame for each client after the physics are run
1601 =============
1602 */
1603 void PlayerPostThink (void)
1604 {
1605         // Savage: Check for nameless players
1606         if (strlen(self.netname) < 1) {
1607                 self.netname = "Player";
1608                 stuffcmd(self, "seta _cl_name Player\n");
1609         }
1610
1611         if(self.classname == "player") {
1612                 CheckRules_Player();
1613                 UpdateChatBubble();
1614                 UpdateTeamBubble();
1615                 if (self.deadflag == DEAD_NO)
1616                 if (self.impulse)
1617                         ImpulseCommands ();
1618                 if (intermission_running)
1619                         return;         // intermission or finale
1620
1621                 //PrintWelcomeMessage(self);
1622                 //if (TetrisPostFrame()) return;
1623         } else if (self.classname == "observer") {
1624                 //do nothing
1625         } else if (self.classname == "spectator") {
1626                 //do nothing
1627         }
1628         Arena_Warmup();
1629 }