data/qcsrc/server/cl_client.qc

   1 // let's abuse an existing field
   2 #define SPAWNPOINT_SCORE frags
   3
   4 .float wantswelcomemessage;
   5 .string netname_previous;
   6
   7 void spawnfunc_info_player_survivor (void)
   8 {
   9         spawnfunc_info_player_deathmatch();
  10 }
  11
  12 void spawnfunc_info_player_start (void)
  13 {
  14         spawnfunc_info_player_deathmatch();
  15 }
  16
  17 void spawnfunc_info_player_deathmatch (void)
  18 {
  19         self.classname = "info_player_deathmatch";
  20         relocate_spawnpoint();
  21 }
  22
  23 void spawnpoint_use()
  24 {
  25         if(teams_matter)
  26         if(have_team_spawns)
  27         {
  28                 self.team = activator.team;
  29                 some_spawn_has_been_used = 1;
  30         }
  31 };
  32
  33 // Returns:
  34 //   -1 if a spawn can't be used
  35 //   otherwise, a weight of the spawnpoint
  36 float Spawn_Score(entity spot, entity playerlist, float teamcheck)
  37 {
  38         float shortest, thisdist;
  39         entity player;
  40
  41         // filter out spots for the wrong team
  42         if(teamcheck)
  43         if(spot.team != teamcheck)
  44                 return -1;
  45
  46         if(race_spawns)
  47                 if(spot.target == "")
  48                         return -1;
  49
  50         // filter out spots for assault
  51         if(spot.target != "") {
  52                 local entity ent;
  53                 float good;
  54                 ent = find(world, targetname, spot.target);
  55                 while(ent) {
  56                         if(ent.classname == "target_objective")
  57                         {
  58                                 if(ent.health < 0 || ent.health >= ASSAULT_VALUE_INACTIVE)
  59                                         return -1;
  60                                 good = 1;
  61                         }
  62                         else if(ent.classname == "trigger_race_checkpoint")
  63                         {
  64                                 if(self.classname == "player") // spectators may spawn everywhere
  65                                 {
  66                                         if(g_race_qualifying)
  67                                         {
  68                                                 // spawn at first
  69                                                 if(ent.race_checkpoint != 0)
  70                                                         return -1;
  71                                                 if(spot.race_place != race_lowest_place_spawn)
  72                                                         return -1;
  73                                         }
  74                                         else
  75                                         {
  76                                                 if(ent.race_checkpoint != race_PreviousCheckpoint(self.race_checkpoint))
  77                                                         return -1;
  78                                                 float pl;
  79                                                 pl = self.race_place;
  80                                                 if(pl > race_highest_place_spawn)
  81                                                         pl = 0;
  82                                                 if(spot.race_place != pl)
  83                                                         return -1;
  84                                         }
  85                                 }
  86                                 good = 1;
  87                         }
  88                         else
  89                         {
  90                         }
  91                         ent = find(ent, targetname, spot.target);
  92                 }
  93
  94                 if(!good)
  95                         return -1;
  96         }
  97
  98         player = playerlist;
  99         shortest = vlen(world.maxs - world.mins);
 100         for(player = playerlist; player; player = player.chain)
 101                 if (player != self)
 102                 {
 103                         thisdist = vlen(player.origin - spot.origin);
 104                         if (thisdist < shortest)
 105                                 shortest = thisdist;
 106                 }
 107         return shortest;
 108 }
 109
 110 float spawn_allbad;
 111 float spawn_allgood;
 112 entity Spawn_FilterOutBadSpots(entity firstspot, entity playerlist, float mindist, float teamcheck)
 113 {
 114         local entity spot, spotlist, spotlistend;
 115         spawn_allgood = TRUE;
 116         spawn_allbad = TRUE;
 117
 118         spotlist = world;
 119         spotlistend = world;
 120
 121         for(spot = firstspot; spot; spot = spot.chain)
 122         {
 123                 spot.SPAWNPOINT_SCORE = Spawn_Score(spot, playerlist, teamcheck);
 124
 125                 if(cvar("spawn_debugview"))
 126                 {
 127                         setmodel(spot, "models/runematch/rune.mdl");
 128                         if(spot.SPAWNPOINT_SCORE < mindist)
 129                         {
 130                                 spot.colormod = '1 0 0';
 131                                 spot.scale = 1;
 132                         }
 133                         else
 134                         {
 135                                 spot.colormod = '0 1 0';
 136                                 spot.scale = spot.SPAWNPOINT_SCORE / mindist;
 137                         }
 138                 }
 139
 140                 if(spot.SPAWNPOINT_SCORE >= 0) // spawning allowed here
 141                 {
 142                         if(spot.SPAWNPOINT_SCORE < mindist)
 143                         {
 144                                 // too short distance
 145                                 spawn_allgood = FALSE;
 146                         }
 147                         else
 148                         {
 149                                 // perfect
 150                                 spawn_allbad = FALSE;
 151
 152                                 if(spotlistend)
 153                                         spotlistend.chain = spot;
 154                                 spotlistend = spot;
 155                                 if(!spotlist)
 156                                         spotlist = spot;
 157
 158                                 /*
 159                                 if(teamcheck)
 160                                 if(spot.team != teamcheck)
 161                                         error("invalid spawn added");
 162
 163                                 print("added ", etos(spot), "\n");
 164                                 */
 165                         }
 166                 }
 167         }
 168         if(spotlistend)
 169                 spotlistend.chain = world;
 170
 171         /*
 172                 entity e;
 173                 if(teamcheck)
 174                         for(e = spotlist; e; e = e.chain)
 175                         {
 176                                 print("seen ", etos(e), "\n");
 177                                 if(e.team != teamcheck)
 178                                         error("invalid spawn found");
 179                         }
 180         */
 181
 182         return spotlist;
 183 }
 184
 185 entity Spawn_WeightedPoint(entity firstspot, float lower, float upper, float exponent)
 186 {
 187         // weight of a point: bound(lower, mindisttoplayer, upper)^exponent
 188         // multiplied by spot.cnt (useful if you distribute many spawnpoints in a small area)
 189         local entity spot;
 190
 191         RandomSelection_Init();
 192         for(spot = firstspot; spot; spot = spot.chain)
 193                 RandomSelection_Add(spot, 0, pow(bound(lower, spot.SPAWNPOINT_SCORE, upper), exponent) * spot.cnt, spot.SPAWNPOINT_SCORE >= lower);
 194
 195         return RandomSelection_chosen_ent;
 196 }
 197
 198 /*
 199 =============
 200 SelectSpawnPoint
 201
 202 Finds a point to respawn
 203 =============
 204 */
 205 entity SelectSpawnPoint (float anypoint)
 206 {
 207         local float teamcheck;
 208         local entity firstspot_new;
 209         local entity spot, firstspot, playerlist;
 210
 211         spot = find (world, classname, "testplayerstart");
 212         if (spot)
 213                 return spot;
 214
 215         teamcheck = 0;
 216
 217         if(!anypoint && have_team_spawns)
 218                 teamcheck = self.team;
 219
 220         // get the list of players
 221         playerlist = findchain(classname, "player");
 222         // get the entire list of spots
 223         firstspot = findchain(classname, "info_player_deathmatch");
 224         // filter out the bad ones
 225         // (note this returns the original list if none survived)
 226         firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, 100, teamcheck);
 227         if(!firstspot_new)
 228                 firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, -1, teamcheck);
 229         firstspot = firstspot_new;
 230
 231         // there is 50/50 chance of choosing a random spot or the furthest spot
 232         // (this means that roughly every other spawn will be furthest, so you
 233         // usually won't get fragged at spawn twice in a row)
 234         if (arena_roundbased)
 235         {
 236                 firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, 800, teamcheck);
 237                 if(firstspot_new)
 238                         firstspot = firstspot_new;
 239                 spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 240         }
 241         else if (random() > cvar("g_spawn_furthest"))
 242                 spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 243         else
 244                 spot = Spawn_WeightedPoint(firstspot, 1, 5000, 5); // chooses a far far away spawnpoint
 245
 246         if(cvar("spawn_debugview"))
 247         {
 248                 print("spot mindistance: ", ftos(spot.SPAWNPOINT_SCORE), "\n");
 249
 250                 entity e;
 251                 if(teamcheck)
 252                         for(e = firstspot; e; e = e.chain)
 253                                 if(e.team != teamcheck)
 254                                         error("invalid spawn found");
 255         }
 256
 257         if (!spot)
 258         {
 259                 if(cvar("spawn_debug"))
 260                         GotoNextMap();
 261                 else
 262                 {
 263                         if(some_spawn_has_been_used)
 264                                 return world; // team can't spawn any more, because of actions of other team
 265                         else
 266                                 error("Cannot find a spawn point - please fix the map!");
 267                 }
 268         }
 269
 270         return spot;
 271 }
 272
 273 /*
 274 =============
 275 CheckPlayerModel
 276
 277 Checks if the argument string can be a valid playermodel.
 278 Returns a valid one in doubt.
 279 =============
 280 */
 281 string FallbackPlayerModel = "models/player/marine.zym";
 282 string CheckPlayerModel(string plyermodel) {
 283         if(strlen(plyermodel) < 4)
 284                 return FallbackPlayerModel;
 285         if( substring(plyermodel,0,14) != "models/player/")
 286                 return FallbackPlayerModel;
 287         else if(cvar("sv_servermodelsonly"))
 288         {
 289                 if(substring(plyermodel,strlen(plyermodel)-4,4) != ".zym")
 290                 if(substring(plyermodel,strlen(plyermodel)-4,4) != ".dpm")
 291                 if(substring(plyermodel,strlen(plyermodel)-4,4) != ".md3")
 292                 if(substring(plyermodel,strlen(plyermodel)-4,4) != ".psk")
 293                         return FallbackPlayerModel;
 294                 if(plyermodel != strtolower(plyermodel))
 295                         return FallbackPlayerModel;
 296                 if(!fexists(plyermodel))
 297                         return FallbackPlayerModel;
 298         }
 299         return plyermodel;
 300 }
 301
 302 /*
 303 =============
 304 Client_customizeentityforclient
 305
 306 LOD reduction
 307 =============
 308 */
 309 float Client_customizeentityforclient()
 310 {
 311 #ifdef ALLOW_VARIABLE_LOD
 312         // self: me
 313         // other: the player viewing me
 314         float distance;
 315         float f;
 316
 317         if(self.flags & FL_NOTARGET) // we don't need LOD for spectators
 318                 return TRUE;
 319
 320         if(other.cvar_cl_playerdetailreduction <= 0)
 321         {
 322                 if(other.cvar_cl_playerdetailreduction <= -2)
 323                         self.modelindex = self.modelindex_lod2;
 324                 else if(other.cvar_cl_playerdetailreduction <= -1)
 325                         self.modelindex = self.modelindex_lod1;
 326                 else
 327                         self.modelindex = self.modelindex_lod0;
 328         }
 329         else
 330         {
 331                 distance = vlen(self.origin - other.origin);
 332                 f = (distance + 100.0) * other.cvar_cl_playerdetailreduction;
 333                 if(f > 10000)
 334                         self.modelindex = self.modelindex_lod2;
 335                 else if(f > 5000)
 336                         self.modelindex = self.modelindex_lod1;
 337                 else
 338                         self.modelindex = self.modelindex_lod0;
 339         }
 340 #endif
 341
 342         return TRUE;
 343 }
 344
 345 void UpdatePlayerSounds();
 346 void setmodel_lod(entity e, string modelname)
 347 {
 348 #ifdef ALLOW_VARIABLE_LOD
 349         string s;
 350
 351         // FIXME: this only supports 3-letter extensions
 352         s = strcat(substring(modelname, 0, strlen(modelname) - 4), "_1", substring(modelname, 0, strlen(modelname) - 4));
 353         if(fexists(s))
 354         {
 355                 precache_model(s);
 356                 setmodel(e, s); // players have high precision
 357                 self.modelindex_lod1 = self.modelindex;
 358         }
 359         else
 360                 self.modelindex_lod1 = -1;
 361
 362         s = strcat(substring(modelname, 0, strlen(modelname) - 4), "_2", substring(modelname, 0, strlen(modelname) - 4));
 363         if(fexists(s))
 364         {
 365                 precache_model(s);
 366                 setmodel(e, s); // players have high precision
 367                 self.modelindex_lod2 = self.modelindex;
 368         }
 369         else
 370                 self.modelindex_lod2 = -1;
 371
 372         precache_model(modelname);
 373         setmodel(e, modelname); // players have high precision
 374         self.modelindex_lod0 = self.modelindex;
 375
 376         if(self.modelindex_lod1 < 0)
 377                 self.modelindex_lod1 = self.modelindex;
 378
 379         if(self.modelindex_lod2 < 0)
 380                 self.modelindex_lod2 = self.modelindex;
 381 #else
 382         precache_model(modelname);
 383         setmodel(e, modelname); // players have high precision
 384 #endif
 385         player_setupanimsformodel();
 386         UpdatePlayerSounds();
 387 }
 388
 389 /*
 390 =============
 391 PutObserverInServer
 392
 393 putting a client as observer in the server
 394 =============
 395 */
 396 void PutObserverInServer (void)
 397 {
 398         entity  spot;
 399
 400         race_PreSpawnObserver();
 401
 402         spot = SelectSpawnPoint (TRUE);
 403         if(!spot)
 404                 error("No spawnpoints for observers?!?\n");
 405         RemoveGrapplingHook(self); // Wazat's Grappling Hook
 406
 407         if(clienttype(self) == CLIENTTYPE_REAL)
 408         {
 409                 msg_entity = self;
 410                 WriteByte(MSG_ONE, SVC_SETVIEW);
 411                 WriteEntity(MSG_ONE, self);
 412         }
 413
 414         DropAllRunes(self);
 415         kh_Key_DropAll(self, TRUE);
 416
 417         Portal_ClearAll(self);
 418
 419         if(self.flagcarried)
 420                 DropFlag(self.flagcarried, world, world);
 421
 422         WaypointSprite_PlayerDead();
 423
 424         if(self.killcount != -666)
 425         {
 426                 if(g_lms)
 427                 {
 428                         if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
 429                                 bprint ("^4", self.netname, "^4 has no more lives left\n");
 430                         else
 431                                 bprint ("^4", self.netname, "^4 is spectating now\n"); // TODO turn this into a proper forfeit?
 432                 }
 433                 else
 434                         bprint ("^4", self.netname, "^4 is spectating now\n");
 435         }
 436
 437         PlayerScore_Clear(self); // clear scores when needed
 438
 439         self.spectatortime = time;
 440
 441         self.classname = "observer";
 442         self.health = -666;
 443         self.takedamage = DAMAGE_NO;
 444         self.solid = SOLID_NOT;
 445         self.movetype = MOVETYPE_NOCLIP;
 446         self.flags = FL_CLIENT | FL_NOTARGET;
 447         self.armorvalue = 666;
 448         self.effects = 0;
 449         self.armorvalue = cvar("g_balance_armor_start");
 450         self.pauserotarmor_finished = 0;
 451         self.pauserothealth_finished = 0;
 452         self.pauseregen_finished = 0;
 453         self.damageforcescale = 0;
 454         self.death_time = 0;
 455         self.dead_frame = 0;
 456         self.alpha = 0;
 457         self.scale = 0;
 458         self.fade_time = 0;
 459         self.pain_frame = 0;
 460         self.pain_finished = 0;
 461         self.strength_finished = 0;
 462         self.invincible_finished = 0;
 463         self.pushltime = 0;
 464         self.think = SUB_Null;
 465         self.nextthink = 0;
 466         self.hook_time = 0;
 467         self.runes = 0;
 468         self.deadflag = DEAD_NO;
 469         self.angles = spot.angles;
 470         self.angles_z = 0;
 471         self.fixangle = TRUE;
 472         self.crouch = FALSE;
 473
 474         self.view_ofs = PL_VIEW_OFS;
 475         setorigin (self, spot.origin);
 476         setsize (self, '0 0 0', '0 0 0');
 477         self.oldorigin = self.origin;
 478         self.items = 0;
 479         self.weapons = 0;
 480         self.model = "";
 481         self.modelindex = 0;
 482         self.weapon = 0;
 483         self.weaponmodel = "";
 484         self.weaponentity = world;
 485         self.killcount = -666;
 486         self.velocity = '0 0 0';
 487         self.avelocity = '0 0 0';
 488         self.punchangle = '0 0 0';
 489         self.punchvector = '0 0 0';
 490         self.oldvelocity = self.velocity;
 491         self.customizeentityforclient = Client_customizeentityforclient;
 492         self.wantswelcomemessage = 1;
 493
 494         if(g_arena)
 495         {
 496                 if(self.version_mismatch)
 497                 {
 498                         Spawnqueue_Unmark(self);
 499                         Spawnqueue_Remove(self);
 500                 }
 501                 else
 502                 {
 503                         Spawnqueue_Insert(self);
 504                 }
 505         }
 506         else if(g_lms)
 507         {
 508                 // Only if the player cannot play at all
 509                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) == 666)
 510                         self.frags = -666;
 511                 else
 512                         self.frags = -667;
 513         }
 514         else
 515                 self.frags = -666;
 516 }
 517
 518 float RestrictSkin(float s)
 519 {
 520         if(!teams_matter)
 521                 return s;
 522         if(s == 6)
 523                 return 6;
 524         return mod(s, 3);
 525 }
 526
 527 void FixPlayermodel()
 528 {
 529         local string defaultmodel;
 530         local float defaultskin;
 531         local vector m1, m2;
 532
 533         defaultmodel = "";
 534
 535         if(cvar("sv_defaultcharacter") == 1) {
 536                 defaultskin = 0;
 537
 538                 if(teams_matter)
 539                 {
 540                         defaultmodel = cvar_string(strcat("sv_defaultplayermodel_", Team_ColorNameLowerCase(self.team)));
 541                         defaultskin = cvar(strcat("sv_defaultplayerskin_", Team_ColorNameLowerCase(self.team)));
 542                 }
 543
 544                 if(defaultmodel == "")
 545                 {
 546                         defaultmodel = cvar_string("sv_defaultplayermodel");
 547                         defaultskin = cvar("sv_defaultplayerskin");
 548                 }
 549         }
 550
 551         if(defaultmodel != "")
 552         {
 553                 if (defaultmodel != self.model)
 554                 {
 555                         m1 = self.mins;
 556                         m2 = self.maxs;
 557                         setmodel_lod (self, defaultmodel);
 558                         setsize (self, m1, m2);
 559                 }
 560
 561                 self.skin = defaultskin;
 562         } else {
 563                 if (self.playermodel != self.model)
 564                 {
 565                         self.playermodel = CheckPlayerModel(self.playermodel);
 566                         m1 = self.mins;
 567                         m2 = self.maxs;
 568                         setmodel_lod (self, self.playermodel);
 569                         setsize (self, m1, m2);
 570                 }
 571
 572                 self.skin = RestrictSkin(stof(self.playerskin));
 573         }
 574
 575         if(!teams_matter)
 576                 if(strlen(cvar_string("sv_defaultplayercolors")))
 577                         if(self.clientcolors != cvar("sv_defaultplayercolors"))
 578                                 setcolor(self, cvar("sv_defaultplayercolors"));
 579 }
 580
 581 /*
 582 =============
 583 PutClientInServer
 584
 585 Called when a client spawns in the server
 586 =============
 587 */
 588 //void() ctf_playerchanged;
 589 void PutClientInServer (void)
 590 {
 591         if(clienttype(self) == CLIENTTYPE_BOT)
 592         {
 593                 self.classname = "player";
 594         }
 595         else if(clienttype(self) == CLIENTTYPE_REAL)
 596         {
 597                 msg_entity = self;
 598                 WriteByte(MSG_ONE, SVC_SETVIEW);
 599                 WriteEntity(MSG_ONE, self);
 600         }
 601
 602         // player is dead and becomes observer
 603         // FIXME fix LMS scoring for new system
 604         if(g_lms)
 605         {
 606                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
 607                         self.classname = "observer";
 608         }
 609
 610         if(g_arena)
 611         if(!self.spawned)
 612                 self.classname = "observer";
 613
 614         if(self.classname == "player") {
 615                 entity  spot;
 616
 617                 race_PreSpawn();
 618
 619                 spot = SelectSpawnPoint (FALSE);
 620                 if(!spot)
 621                 {
 622                         centerprint(self, "Sorry, no spawnpoints available!\nHope your team can fix it...");
 623                         return; // spawn failed
 624                 }
 625
 626                 RemoveGrapplingHook(self); // Wazat's Grappling Hook
 627
 628                 self.classname = "player";
 629                 self.iscreature = TRUE;
 630                 self.movetype = MOVETYPE_WALK;
 631                 self.solid = SOLID_SLIDEBOX;
 632                 if(independent_players)
 633                         MAKE_INDEPENDENT_PLAYER(self);
 634                 self.flags = FL_CLIENT;
 635                 self.takedamage = DAMAGE_AIM;
 636                 if(g_minstagib)
 637                         self.effects = EF_FULLBRIGHT;
 638                 else
 639                         self.effects = 0;
 640                 self.air_finished = time + 12;
 641                 self.dmg = 2;
 642
 643                 if(inWarmupStage)
 644                 {
 645                         self.ammo_shells = warmup_start_ammo_shells;
 646                         self.ammo_nails = warmup_start_ammo_nails;
 647                         self.ammo_rockets = warmup_start_ammo_rockets;
 648                         self.ammo_cells = warmup_start_ammo_cells;
 649                         self.health = warmup_start_health;
 650                         self.armorvalue = warmup_start_armorvalue;
 651                         self.weapons = warmup_start_weapons;
 652                 }
 653                 else
 654                 {
 655                         self.ammo_shells = start_ammo_shells;
 656                         self.ammo_nails = start_ammo_nails;
 657                         self.ammo_rockets = start_ammo_rockets;
 658                         self.ammo_cells = start_ammo_cells;
 659                         self.health = start_health;
 660                         self.armorvalue = start_armorvalue;
 661                         self.weapons = start_weapons;
 662                 }
 663                 self.items = start_items;
 664                 self.switchweapon = w_getbestweapon(self);
 665                 self.cnt = self.switchweapon;
 666                 self.weapon = 0;
 667                 self.jump_interval = time;
 668
 669                 self.spawnshieldtime = time + cvar("g_spawnshieldtime");
 670                 self.pauserotarmor_finished = time + cvar("g_balance_pause_armor_rot_spawn");
 671                 self.pauserothealth_finished = time + cvar("g_balance_pause_health_rot_spawn");
 672                 self.pauseregen_finished = time + cvar("g_balance_pause_health_regen_spawn");
 673                 //extend the pause of rotting if client was reset at the beginning of the countdown
 674                 if(!cvar("sv_ready_restart_after_countdown") && time < game_starttime) { // TODO why is this cvar NOTted?
 675                         self.spawnshieldtime += game_starttime - time;
 676                         self.pauserotarmor_finished += game_starttime - time;
 677                         self.pauserothealth_finished += game_starttime - time;
 678                         self.pauseregen_finished += game_starttime - time;
 679                 }
 680                 self.damageforcescale = 2;
 681                 self.death_time = 0;
 682                 self.dead_frame = 0;
 683                 self.alpha = 0;
 684                 self.scale = 0;
 685                 self.fade_time = 0;
 686                 self.pain_frame = 0;
 687                 self.pain_finished = 0;
 688                 self.strength_finished = 0;
 689                 self.invincible_finished = 0;
 690                 self.pushltime = 0;
 691                 //self.speed_finished = 0;
 692                 //self.slowmo_finished = 0;
 693                 // players have no think function
 694                 self.think = SUB_Null;
 695                 self.nextthink = 0;
 696                 self.hook_time = 0;
 697
 698                 self.runes = 0;
 699
 700                 self.deadflag = DEAD_NO;
 701
 702                 self.angles = spot.angles;
 703
 704                 self.angles_z = 0; // never spawn tilted even if the spot says to
 705                 self.fixangle = TRUE; // turn this way immediately
 706                 self.velocity = '0 0 0';
 707                 self.avelocity = '0 0 0';
 708                 self.punchangle = '0 0 0';
 709                 self.punchvector = '0 0 0';
 710                 self.oldvelocity = self.velocity;
 711
 712                 msg_entity = self;
 713                 WRITESPECTATABLE_MSG_ONE({
 714                         WriteByte(MSG_ONE, SVC_TEMPENTITY);
 715                         WriteByte(MSG_ONE, TE_CSQC_SPAWN);
 716                 });
 717
 718                 self.customizeentityforclient = Client_customizeentityforclient;
 719
 720                 self.model = "";
 721                 FixPlayermodel();
 722
 723                 self.crouch = FALSE;
 724                 self.view_ofs = PL_VIEW_OFS;
 725                 setsize (self, PL_MIN, PL_MAX);
 726                 self.spawnorigin = spot.origin;
 727                 setorigin (self, spot.origin + '0 0 1' * (1 - self.mins_z - 24));
 728                 // don't reset back to last position, even if new position is stuck in solid
 729                 self.oldorigin = self.origin;
 730
 731                 if(g_arena)
 732                 {
 733                         Spawnqueue_Remove(self);
 734                         Spawnqueue_Mark(self);
 735                 }
 736
 737                 self.event_damage = PlayerDamage;
 738
 739                 self.bot_attack = TRUE;
 740
 741                 self.statdraintime = time + 5;
 742                 self.BUTTON_ATCK = self.BUTTON_JUMP = self.BUTTON_ATCK2 = 0;
 743
 744                 if(self.killcount == -666) {
 745                         PlayerScore_Clear(self);
 746                         self.killcount = 0;
 747                         self.frags = 0;
 748                 }
 749
 750                 self.cnt = WEP_LASER;
 751                 self.nixnex_lastchange_id = -1;
 752
 753                 CL_SpawnWeaponentity();
 754                 self.alpha = default_player_alpha;
 755                 self.colormod = '1 1 1' * cvar("g_player_brightness");
 756                 self.exteriorweaponentity.alpha = default_weapon_alpha;
 757
 758                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval")*2;
 759                 self.lms_traveled_distance = 0;
 760                 self.speedrunning = FALSE;
 761
 762                 race_PostSpawn(spot);
 763
 764                 if(cvar("spawn_debug"))
 765                 {
 766                         sprint(self, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 767                         remove(spot);   // usefull for checking if there are spawnpoints, that let drop through the floor
 768                 }
 769
 770                 //stuffcmd(self, "chase_active 0");
 771                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
 772
 773                 if (cvar("g_spawnsound"))
 774                         sound (self, CHAN_TRIGGER, "misc/spawn.wav", VOL_BASE, ATTN_NORM);
 775
 776                 if(g_assault) {
 777                         if(self.team == assault_attacker_team)
 778                                 centerprint(self, "You are attacking!\n");
 779                         else
 780                                 centerprint(self, "You are defending!\n");
 781                 }
 782
 783         } else if(self.classname == "observer") {
 784                 PutObserverInServer ();
 785         }
 786
 787         //if(g_ctf)
 788         //      ctf_playerchanged();
 789 }
 790
 791 /*
 792 =============
 793 SendCSQCInfo
 794
 795 Send whatever CSQC needs NOW and cannot wait for SendServerInfo to happen...
 796 =============
 797 */
 798 void SendCSQCInfo(void)
 799 {
 800         float i;
 801         if(clienttype(self) != CLIENTTYPE_REAL)
 802                 return;
 803         msg_entity = self;
 804         WriteByte(MSG_ONE, SVC_TEMPENTITY);
 805         WriteByte(MSG_ONE, TE_CSQC_INIT);
 806         WriteShort(MSG_ONE, CSQC_REVISION);
 807         WriteByte(MSG_ONE, maxclients);
 808         for(i = 1; i <= 24; ++i)
 809                 WriteByte(MSG_ONE, (get_weaponinfo(i)).impulse + 1);
 810 }
 811
 812 /*
 813 =============
 814 SetNewParms
 815 =============
 816 */
 817 void SetNewParms (void)
 818 {
 819         // initialize parms for a new player
 820         parm1 = -(86400 * 366);
 821 }
 822
 823 /*
 824 =============
 825 SetChangeParms
 826 =============
 827 */
 828 void SetChangeParms (void)
 829 {
 830         // save parms for level change
 831         parm1 = self.parm_idlesince - time;
 832 }
 833
 834 /*
 835 =============
 836 DecodeLevelParms
 837 =============
 838 */
 839 void DecodeLevelParms (void)
 840 {
 841         // load parms
 842         self.parm_idlesince = parm1;
 843         if(self.parm_idlesince == -(86400 * 366))
 844                 self.parm_idlesince = time;
 845 }
 846
 847 /*
 848 =============
 849 ClientKill
 850
 851 Called when a client types 'kill' in the console
 852 =============
 853 */
 854
 855 void ClientKill_Now_TeamChange()
 856 {
 857         if(self.killindicator_teamchange == -1)
 858         {
 859                 self.team = -1;
 860                 JoinBestTeam( self, FALSE, FALSE );
 861         }
 862         else
 863         {
 864                 SV_ChangeTeam(self.killindicator_teamchange - 1);
 865         }
 866 }
 867
 868 void ClientKill_Now()
 869 {
 870         if(self.killindicator_teamchange)
 871                 ClientKill_Now_TeamChange();
 872
 873         // in any case:
 874         Damage(self, self, self, 100000, DEATH_KILL, self.origin, '0 0 0');
 875
 876         if(self.killindicator)
 877         {
 878                 dprint("Cleaned up after a leaked kill indicator.\n");
 879                 remove(self.killindicator);
 880                 self.killindicator = world;
 881         }
 882 }
 883 void KillIndicator_Think()
 884 {
 885         if (!self.owner.modelindex)
 886         {
 887                 self.owner.killindicator = world;
 888                 remove(self);
 889                 return;
 890         }
 891
 892         if(self.cnt <= 0)
 893         {
 894                 self = self.owner;
 895                 ClientKill_Now(); // no oldself needed
 896                 return;
 897         }
 898         else
 899         {
 900                 if(self.cnt <= 10)
 901                         setmodel(self, strcat("models/sprites/", ftos(self.cnt), ".spr32"));
 902                 if(clienttype(self.owner) == CLIENTTYPE_REAL)
 903                 {
 904                         if(self.cnt <= 10)
 905                                 announce(self.owner, strcat("announcer/robotic/", ftos(self.cnt), ".ogg"));
 906                         if(self.owner.killindicator_teamchange)
 907                         {
 908                                 if(self.owner.killindicator_teamchange == -1)
 909                                         centerprint(self.owner, strcat("Changing team in ", ftos(self.cnt), " seconds"));
 910                                 else
 911                                         centerprint(self.owner, strcat("Changing to ", ColoredTeamName(self.owner.killindicator_teamchange), " in ", ftos(self.cnt), " seconds"));
 912                         }
 913                         else
 914                                 centerprint(self.owner, strcat("^1Suicide in ", ftos(self.cnt), " seconds"));
 915                 }
 916                 self.nextthink = time + 1;
 917                 self.cnt -= 1;
 918         }
 919 }
 920
 921 void ClientKill_TeamChange (float targetteam) // 0 = don't change, -1 = auto
 922 {
 923         float killtime;
 924         entity e;
 925         killtime = cvar("g_balance_kill_delay");
 926
 927         self.killindicator_teamchange = targetteam;
 928
 929         if(!self.killindicator)
 930         {
 931                 if(killtime <= 0 || !self.modelindex || self.deadflag != DEAD_NO)
 932                 {
 933                         ClientKill_Now();
 934                 }
 935                 else
 936                 {
 937                         self.killindicator = spawn();
 938                         self.killindicator.owner = self;
 939                         self.killindicator.scale = 0.5;
 940                         setattachment(self.killindicator, self, "");
 941                         setorigin(self.killindicator, '0 0 52');
 942                         self.killindicator.think = KillIndicator_Think;
 943                         self.killindicator.nextthink = time + (self.lip) * 0.05;
 944                         self.killindicator.cnt = ceil(killtime);
 945                         self.killindicator.count = bound(0, ceil(killtime), 10);
 946                         sprint(self, strcat("^1You'll be dead in ", ftos(self.killindicator.cnt), " seconds\n"));
 947
 948                         for(e = world; (e = find(e, classname, "body")) != world; )
 949                         {
 950                                 if(e.enemy != self)
 951                                         continue;
 952                                 e.killindicator = spawn();
 953                                 e.killindicator.owner = e;
 954                                 e.killindicator.scale = 0.5;
 955                                 setattachment(e.killindicator, e, "");
 956                                 setorigin(e.killindicator, '0 0 52');
 957                                 e.killindicator.think = KillIndicator_Think;
 958                                 e.killindicator.nextthink = time + (e.lip) * 0.05;
 959                                 e.killindicator.cnt = ceil(killtime);
 960                         }
 961                         self.lip = 0;
 962                 }
 963         }
 964         if(self.killindicator)
 965         {
 966                 if(targetteam)
 967                         self.killindicator.colormod = TeamColor(targetteam);
 968                 else
 969                         self.killindicator.colormod = '0 0 0';
 970         }
 971 }
 972
 973 void ClientKill (void)
 974 {
 975         ClientKill_TeamChange(0);
 976 }
 977
 978 void DoTeamChange(float destteam)
 979 {
 980         float t, c0;
 981         if(!cvar("teamplay"))
 982         {
 983                 if(destteam >= 0)
 984                         SetPlayerColors(self, destteam);
 985                 return;
 986         }
 987         if(self.classname == "player")
 988         if(destteam == -1)
 989         {
 990                 CheckAllowedTeams(self);
 991                 t = FindSmallestTeam(self, TRUE);
 992                 switch(self.team)
 993                 {
 994                         case COLOR_TEAM1: c0 = c1; break;
 995                         case COLOR_TEAM2: c0 = c2; break;
 996                         case COLOR_TEAM3: c0 = c3; break;
 997                         case COLOR_TEAM4: c0 = c4; break;
 998                         default:          c0 = 999;
 999                 }
1000                 switch(t)
1001                 {
1002                         case 1:
1003                                 if(c0 > c1)
1004                                         destteam = COLOR_TEAM1;
1005                                 break;
1006                         case 2:
1007                                 if(c0 > c2)
1008                                         destteam = COLOR_TEAM2;
1009                                 break;
1010                         case 3:
1011                                 if(c0 > c3)
1012                                         destteam = COLOR_TEAM3;
1013                                 break;
1014                         case 4:
1015                                 if(c0 > c4)
1016                                         destteam = COLOR_TEAM4;
1017                                 break;
1018                 }
1019                 if(destteam == -1)
1020                         return;
1021         }
1022         if(destteam == self.team && !self.killindicator)
1023                 return;
1024         ClientKill_TeamChange(destteam);
1025 }
1026
1027 void FixClientCvars(entity e)
1028 {
1029         // send prediction settings to the client
1030         stuffcmd(e, "\nin_bindmap 0 0\n");
1031         /*
1032          * we no longer need to stuff this. Remove this comment block if you feel
1033          * 2.3 and higher (or was it 2.2.3?) don't need these any more
1034         stuffcmd(e, strcat("cl_gravity ", ftos(cvar("sv_gravity")), "\n"));
1035         stuffcmd(e, strcat("cl_movement_accelerate ", ftos(cvar("sv_accelerate")), "\n"));
1036         stuffcmd(e, strcat("cl_movement_friction ", ftos(cvar("sv_friction")), "\n"));
1037         stuffcmd(e, strcat("cl_movement_maxspeed ", ftos(cvar("sv_maxspeed")), "\n"));
1038         stuffcmd(e, strcat("cl_movement_airaccelerate ", ftos(cvar("sv_airaccelerate")), "\n"));
1039         stuffcmd(e, strcat("cl_movement_maxairspeed ", ftos(cvar("sv_maxairspeed")), "\n"));
1040         stuffcmd(e, strcat("cl_movement_stopspeed ", ftos(cvar("sv_stopspeed")), "\n"));
1041         stuffcmd(e, strcat("cl_movement_jumpvelocity ", ftos(cvar("sv_jumpvelocity")), "\n"));
1042         stuffcmd(e, strcat("cl_movement_stepheight ", ftos(cvar("sv_stepheight")), "\n"));
1043         stuffcmd(e, strcat("set cl_movement_friction_on_land ", ftos(cvar("sv_friction_on_land")), "\n"));
1044         stuffcmd(e, strcat("set cl_movement_airaccel_qw ", ftos(cvar("sv_airaccel_qw")), "\n"));
1045         stuffcmd(e, strcat("set cl_movement_airaccel_sideways_friction ", ftos(cvar("sv_airaccel_sideways_friction")), "\n"));
1046         stuffcmd(e, "cl_movement_edgefriction 1\n");
1047          */
1048 }
1049
1050 .float fog_set;
1051 void SendFog()
1052 {
1053         if(clienttype(self) == CLIENTTYPE_REAL)
1054         if(world.fog) // NOT string_null!
1055         {
1056                 if(!self.fog_set)
1057                 {
1058                         if(sv_foginterval)
1059                         {
1060                                 msg_entity = self;
1061                                 WriteByte(MSG_ONE, SVC_TEMPENTITY);
1062                                 WriteByte(MSG_ONE, TE_CSQC_FOG);
1063                                 WriteCoord(MSG_ONE, sv_foginterval);
1064                                 WriteString(MSG_ONE, world.fog);
1065                         }
1066                         else
1067                                 // set it once
1068                                 stuffcmd(self, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1069
1070                         self.fog_set = 1;
1071                 }
1072         }
1073 }
1074
1075 /*
1076 =============
1077 ClientConnect
1078
1079 Called when a client connects to the server
1080 =============
1081 */
1082 //void ctf_clientconnect();
1083 string ColoredTeamName(float t);
1084 void DecodeLevelParms (void);
1085 //void dom_player_join_team(entity pl);
1086 void ClientConnect (void)
1087 {
1088         local string s;
1089
1090         if(self.flags & FL_CLIENT)
1091         {
1092                 print("Warning: ClientConnect, but already connected!\n");
1093                 return;
1094         }
1095
1096         if(Ban_MaybeEnforceBan(self))
1097                 return;
1098
1099         DecodeLevelParms();
1100
1101         self.classname = "player_joining";
1102
1103         self.flags = self.flags | FL_CLIENT;
1104         self.version_nagtime = time + 10 + random() * 10;
1105
1106         if(player_count<0)
1107         {
1108                 dprint("BUG player count is lower than zero, this cannot happen!\n");
1109                 player_count = 0;
1110         }
1111
1112         PlayerScore_Attach(self);
1113
1114         bot_clientconnect();
1115
1116         race_PreSpawnObserver();
1117
1118         //if(g_domination)
1119         //      dom_player_join_team(self);
1120
1121         //JoinBestTeam(self, FALSE, FALSE);
1122         //
1123         if((cvar("sv_spectate") == 1 && !g_lms) || cvar("g_campaign")) {
1124                 self.classname = "observer";
1125         } else {
1126                 self.classname = "player";
1127                 campaign_bots_may_start = 1;
1128         }
1129
1130         self.playerid = (playerid_last = playerid_last + 1);
1131         if(cvar("sv_eventlog"))
1132         {
1133                 if(clienttype(self) == CLIENTTYPE_REAL)
1134                         GameLogEcho(strcat(":join:", ftos(self.playerid), ":", ftos(num_for_edict(self)), ":", self.netaddress, ":", self.netname));
1135                 else
1136                         GameLogEcho(strcat(":join:", ftos(self.playerid), ":", ftos(num_for_edict(self)), ":bot:", self.netname));
1137                 s = strcat(":team:", ftos(self.playerid), ":");
1138                 s = strcat(s, ftos(self.team));
1139                 GameLogEcho(s);
1140         }
1141         self.netname_previous = strzone(self.netname);
1142
1143         //stuffcmd(self, "set tmpviewsize $viewsize \n");
1144
1145         bprint ("^4",self.netname);
1146         bprint ("^4 connected");
1147
1148         if(g_domination || g_ctf)
1149         {
1150                 bprint(" and joined the ");
1151                 bprint(ColoredTeamName(self.team));
1152         }
1153
1154         bprint("\n");
1155
1156         self.welcomemessage_time = 0;
1157
1158         stuffcmd(self, strcat(clientstuff, "\n"));
1159         stuffcmd(self, strcat("exec maps/", mapname, ".cfg\n"));
1160         stuffcmd(self, "cl_particles_reloadeffects\n");
1161
1162         FixClientCvars(self);
1163
1164         // spawnfunc_waypoint sprites
1165         WaypointSprite_InitClient(self);
1166
1167         // Wazat's grappling hook
1168         SetGrappleHookBindings();
1169
1170         // get autoswitch state from player when he toggles it
1171         stuffcmd(self, "alias autoswitch \"set cl_autoswitch $1 ; cmd autoswitch $1\"\n"); // default.cfg-ed in 2.4.1
1172
1173         // get version info from player
1174         stuffcmd(self, "cmd clientversion $gameversion\n");
1175
1176         // get other cvars from player
1177         GetCvars(0);
1178
1179         // set cvar for team scoreboard
1180         if (teams_matter)
1181         {
1182                 local float t;
1183                 t = cvar("teamplay");
1184                 // we have to stuff the correct teamplay value because if this is a listen server, this changes the teamplay mode of the server itself, which is bad
1185                 stuffcmd(self, strcat("set teamplay ", ftos(t), "\n"));
1186         }
1187         else
1188                 stuffcmd(self, "set teamplay 0\n");
1189
1190         // notify about available teams
1191         if(teamplay)
1192         {
1193                 CheckAllowedTeams(self);
1194                 t = 0; if(c1 >= 0) t |= 1; if(c2 >= 0) t |= 2; if(c3 >= 0) t |= 4; if(c4 >= 0) t |= 8;
1195                 stuffcmd(self, strcat("set _teams_available ", ftos(t), "\n"));
1196         }
1197         else
1198                 stuffcmd(self, "set _teams_available 0\n");
1199
1200         stuffcmd(self, strcat("set gametype ", ftos(game), "\n"));
1201
1202         if(g_arena)
1203         {
1204                 self.classname = "observer";
1205                 Spawnqueue_Insert(self);
1206         }
1207         /*else if(g_ctf)
1208         {
1209                 ctf_clientconnect();
1210         }*/
1211
1212         if(teams_matter)
1213                 attach_entcs();
1214
1215         bot_relinkplayerlist();
1216
1217         self.spectatortime = time;
1218         if(blockSpectators)
1219         {
1220                 sprint(self, strcat("^7You have to become a player within the next ", ftos(cvar("g_maxplayers_spectator_blocktime")), " seconds, otherwise you will be kicked, because spectators aren't allowed at this time!\n"));
1221         }
1222
1223         self.jointime = time;
1224         self.allowedTimeouts = cvar("sv_timeout_number");
1225
1226         if(clienttype(self) == CLIENTTYPE_REAL)
1227         {
1228                 sprint(self, strcat("nexuiz-csqc protocol ", ftos(CSQC_REVISION), "\n"));
1229                 SendCSQCInfo();
1230                 msg_entity = self;
1231                 if(mapvote_initialized && !cvar("g_maplist_textonly"))
1232                 {
1233                         MapVote_SendData(MSG_ONE);
1234                         MapVote_UpdateData(MSG_ONE);
1235                 }
1236                 ScoreInfo_Write(MSG_ONE);
1237         }
1238
1239         if(inWarmupStage)
1240         {
1241                 msg_entity = self;
1242                 WriteByte(MSG_ONE, SVC_TEMPENTITY);
1243                 WriteByte(MSG_ONE, TE_CSQC_WARMUP);
1244                 WriteByte(MSG_ONE, 1);
1245         }
1246
1247         if(g_lms)
1248         {
1249                 if(PlayerScore_Add(self, SP_LMS_LIVES, LMS_NewPlayerLives()) <= 0)
1250                 {
1251                         PlayerScore_Add(self, SP_LMS_RANK, 666);
1252                         self.frags = -666; // FIXME do we still need this?
1253                 }
1254         }
1255
1256         SendFog();
1257 }
1258
1259 /*
1260 =============
1261 ClientDisconnect
1262
1263 Called when a client disconnects from the server
1264 =============
1265 */
1266 .entity chatbubbleentity;
1267 .entity teambubbleentity;
1268 void ReadyCount();
1269 //void() ctf_clientdisconnect;
1270 void ClientDisconnect (void)
1271 {
1272         float save;
1273
1274         if not(self.flags & FL_CLIENT)
1275         {
1276                 print("Warning: ClientDisconnect without ClientConnect\n");
1277                 return;
1278         }
1279
1280         bot_clientdisconnect();
1281
1282         if(teams_matter)
1283                 detach_entcs();
1284
1285         if(cvar("sv_eventlog"))
1286                 GameLogEcho(strcat(":part:", ftos(self.playerid)));
1287         bprint ("^4",self.netname);
1288         bprint ("^4 disconnected\n");
1289
1290         if (self.chatbubbleentity)
1291         {
1292                 remove (self.chatbubbleentity);
1293                 self.chatbubbleentity = world;
1294         }
1295
1296         if (self.teambubbleentity)
1297         {
1298                 remove (self.teambubbleentity);
1299                 self.teambubbleentity = world;
1300         }
1301
1302         if (self.killindicator)
1303         {
1304                 remove (self.killindicator);
1305                 self.killindicator = world;
1306         }
1307
1308         DropAllRunes(self);
1309         kh_Key_DropAll(self, TRUE);
1310
1311         Portal_ClearAll(self);
1312
1313         if(self.flagcarried)
1314                 DropFlag(self.flagcarried, world, world);
1315
1316         WaypointSprite_PlayerGone();
1317
1318         save = self.flags;
1319         self.flags = self.flags - (self.flags & FL_CLIENT);
1320         bot_relinkplayerlist();
1321         self.flags = save;
1322
1323         // remove laserdot
1324         if(self.weaponentity)
1325                 if(self.weaponentity.lasertarget)
1326                         remove(self.weaponentity.lasertarget);
1327
1328         if(g_arena)
1329         {
1330                 Spawnqueue_Unmark(self);
1331                 Spawnqueue_Remove(self);
1332         }
1333         /*if(g_ctf)
1334         {
1335                 ctf_clientdisconnect();
1336         }
1337         */
1338
1339         PlayerScore_Detach(self);
1340
1341         if(self.netname_previous)
1342                 strunzone(self.netname_previous);
1343
1344         ClearPlayerSounds();
1345
1346         // free cvars
1347         GetCvars(-1);
1348         self.playerid = 0;
1349
1350         ReadyCount();
1351 }
1352
1353 .float BUTTON_CHAT;
1354 void ChatBubbleThink()
1355 {
1356         self.nextthink = time;
1357         if (!self.owner.modelindex || self.owner.chatbubbleentity != self)
1358         {
1359                 self.owner.chatbubbleentity = world;
1360                 remove(self);
1361                 return;
1362         }
1363         setorigin(self, self.owner.origin + '0 0 15' + self.owner.maxs_z * '0 0 1');
1364         if (self.owner.BUTTON_CHAT && !self.owner.deadflag)
1365                 self.model = self.mdl;
1366         else
1367                 self.model = "";
1368 };
1369
1370 void UpdateChatBubble()
1371 {
1372         if (!self.modelindex)
1373                 return;
1374         // spawn a chatbubble entity if needed
1375         if (!self.chatbubbleentity)
1376         {
1377                 self.chatbubbleentity = spawn();
1378                 self.chatbubbleentity.owner = self;
1379                 self.chatbubbleentity.exteriormodeltoclient = self;
1380                 self.chatbubbleentity.think = ChatBubbleThink;
1381                 self.chatbubbleentity.nextthink = time;
1382                 setmodel(self.chatbubbleentity, "models/misc/chatbubble.spr"); // precision set below
1383                 setorigin(self.chatbubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1384                 self.chatbubbleentity.mdl = self.chatbubbleentity.model;
1385                 self.chatbubbleentity.model = "";
1386                 self.chatbubbleentity.effects = EF_LOWPRECISION;
1387         }
1388 }
1389
1390
1391 void TeamBubbleThink()
1392 {
1393         self.nextthink = time;
1394         if (!self.owner.modelindex || self.owner.teambubbleentity != self)
1395         {
1396                 self.owner.teambubbleentity = world;
1397                 remove(self);
1398                 return;
1399         }
1400 //      setorigin(self, self.owner.origin + '0 0 15' + self.owner.maxs_z * '0 0 1');  // bandwidth hog. setattachment does this now
1401         if (self.owner.BUTTON_CHAT || self.owner.deadflag || self.owner.killindicator)
1402                 self.model = "";
1403         else
1404                 self.model = self.mdl;
1405
1406 };
1407
1408 float TeamBubble_customizeentityforclient()
1409 {
1410         return (self.owner != other && self.owner.team == other.team && other.killcount > -666);
1411 }
1412
1413 void UpdateTeamBubble()
1414 {
1415         if (!self.modelindex || !cvar("teamplay"))
1416                 return;
1417         // spawn a teambubble entity if needed
1418         if (!self.teambubbleentity && cvar("teamplay"))
1419         {
1420                 self.teambubbleentity = spawn();
1421                 self.teambubbleentity.owner = self;
1422                 self.teambubbleentity.exteriormodeltoclient = self;
1423                 self.teambubbleentity.think = TeamBubbleThink;
1424                 self.teambubbleentity.nextthink = time;
1425                 setmodel(self.teambubbleentity, "models/misc/teambubble.spr"); // precision set below
1426 //              setorigin(self.teambubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1427                 setorigin(self.teambubbleentity, self.teambubbleentity.origin + '0 0 15' + self.maxs_z * '0 0 1');
1428                 setattachment(self.teambubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1429                 self.teambubbleentity.mdl = self.teambubbleentity.model;
1430                 self.teambubbleentity.model = self.teambubbleentity.mdl;
1431                 self.teambubbleentity.customizeentityforclient = TeamBubble_customizeentityforclient;
1432                 self.teambubbleentity.effects = EF_LOWPRECISION;
1433         }
1434 }
1435
1436 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1437 // added to the model skins
1438 /*void UpdateColorModHack()
1439 {
1440         local float c;
1441         c = self.clientcolors & 15;
1442         // LordHavoc: only bothering to support white, green, red, yellow, blue
1443              if (teamplay == 0) self.colormod = '0 0 0';
1444         else if (c ==  0) self.colormod = '1.00 1.00 1.00';
1445         else if (c ==  3) self.colormod = '0.10 1.73 0.10';
1446         else if (c ==  4) self.colormod = '1.73 0.10 0.10';
1447         else if (c == 12) self.colormod = '1.22 1.22 0.10';
1448         else if (c == 13) self.colormod = '0.10 0.10 1.73';
1449         else self.colormod = '1 1 1';
1450 };*/
1451
1452 void respawn(void)
1453 {
1454         CopyBody(1);
1455         self.effects |= EF_NODRAW; // prevent another CopyBody
1456         PutClientInServer();
1457 }
1458
1459 /**
1460  * When sv_timeout is used this function returs strings like
1461  * "Timeout begins in 2 seconds!\n" or "Timeout ends in 23 seconds!\n".
1462  * Called by centerprint functions
1463  * @param addOneSecond boolean, set to 1 if the welcome-message centerprint asks for the text
1464  */
1465 string getTimeoutText(float addOneSecond) {
1466         if (!cvar("sv_timeout") || !timeoutStatus)
1467                 return "";
1468
1469         local string retStr;
1470         if (timeoutStatus == 1) {
1471                 if (addOneSecond == 1) {
1472                         retStr = strcat("Timeout begins in ", ftos(remainingLeadTime + 1), " seconds!\n");
1473                 }
1474                 else {
1475                         retStr = strcat("Timeout begins in ", ftos(remainingLeadTime), " seconds!\n");
1476                 }
1477                 return retStr;
1478         }
1479         else if (timeoutStatus == 2) {
1480                 if (addOneSecond) {
1481                         retStr = strcat("Timeout ends in ", ftos(remainingTimeoutTime + 1), " seconds!\n");
1482                         //don't show messages like "Timeout ends in 0 seconds"...
1483                         if ((remainingTimeoutTime + 1) > 0)
1484                                 return retStr;
1485                         else
1486                                 return "";
1487                 }
1488                 else {
1489                         retStr = strcat("Timeout ends in ", ftos(remainingTimeoutTime), " seconds!\n");
1490                         //don't show messages like "Timeout ends in 0 seconds"...
1491                         if (remainingTimeoutTime > 0)
1492                                 return retStr;
1493                         else
1494                                 return "";
1495                 }
1496         }
1497         else return "";
1498 }
1499
1500 void player_powerups (void)
1501 {
1502         if (g_minstagib)
1503         {
1504                 if (self.items & IT_STRENGTH)
1505                 {
1506                         if (time > self.strength_finished)
1507                         {
1508                                 if (g_minstagib_invis_alpha > 0)
1509                                 {
1510                                         self.alpha = default_player_alpha;
1511                                         self.exteriorweaponentity.alpha = default_weapon_alpha;
1512                                         self.effects = self.effects | EF_FULLBRIGHT;
1513                                 }
1514                                 else
1515                                 {
1516                                         self.effects -= self.effects & EF_NODRAW;
1517                                 }
1518                                 self.items = self.items - (self.items & IT_STRENGTH);
1519                                 sprint(self, "^3Invisibility has worn off\n");
1520                         }
1521                 }
1522                 else
1523                 {
1524                         if (time < self.strength_finished)
1525                         {
1526                                 if (g_minstagib_invis_alpha > 0)
1527                                 {
1528                                         self.alpha = g_minstagib_invis_alpha;
1529                                         self.exteriorweaponentity.alpha = g_minstagib_invis_alpha;
1530                                         self.effects -= self.effects & EF_FULLBRIGHT;
1531                                 }
1532                                 else
1533                                 {
1534                                         self.effects = self.effects | EF_NODRAW;
1535                                 }
1536                                 self.items = self.items | IT_STRENGTH;
1537                                 sprint(self, "^3You are invisible\n");
1538                         }
1539                 }
1540
1541                 if (self.items & IT_INVINCIBLE)
1542                 {
1543                         if (time > self.invincible_finished)
1544                         {
1545                                 self.items = self.items - (self.items & IT_INVINCIBLE);
1546                                 sprint(self, "^3Speed has worn off\n");
1547                         }
1548                 }
1549                 else
1550                 {
1551                         if (time < self.invincible_finished)
1552                         {
1553                                 self.items = self.items | IT_INVINCIBLE;
1554                                 sprint(self, "^3You are on speed\n");
1555                         }
1556                 }
1557                 return;
1558         }
1559
1560         self.effects = self.effects - (self.effects & (EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT));
1561         if (self.items & IT_STRENGTH)
1562         {
1563                 self.effects = self.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1564                 if (time > self.strength_finished)
1565                 {
1566                         self.items = self.items - (self.items & IT_STRENGTH);
1567                         sprint(self, "^3Strength has worn off\n");
1568                 }
1569         }
1570         else
1571         {
1572                 if (time < self.strength_finished)
1573                 {
1574                         self.items = self.items | IT_STRENGTH;
1575                         sprint(self, "^3Strength infuses your weapons with devastating power\n");
1576                 }
1577         }
1578         if (self.items & IT_INVINCIBLE)
1579         {
1580                 self.effects = self.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1581                 if (time > self.invincible_finished)
1582                 {
1583                         self.items = self.items - (self.items & IT_INVINCIBLE);
1584                         sprint(self, "^3Shield has worn off\n");
1585                 }
1586         }
1587         else
1588         {
1589                 if (time < self.invincible_finished)
1590                 {
1591                         self.items = self.items | IT_INVINCIBLE;
1592                         sprint(self, "^3Shield surrounds you\n");
1593                 }
1594         }
1595
1596         if (cvar("g_fullbrightplayers"))
1597                 self.effects = self.effects | EF_FULLBRIGHT;
1598
1599         // midair gamemode: damage only while in the air
1600         // if in midair mode, being on ground grants temporary invulnerability
1601         // (this is so that multishot weapon don't clear the ground flag on the
1602         // first damage in the frame, leaving the player vulnerable to the
1603         // remaining hits in the same frame)
1604         if (self.flags & FL_ONGROUND)
1605         if (g_midair)
1606                 self.spawnshieldtime = max(self.spawnshieldtime, time + cvar("g_midair_shieldtime"));
1607
1608         if (time >= game_starttime)
1609         if (time < self.spawnshieldtime)
1610                 self.effects = self.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1611 }
1612
1613 float CalcRegen(float current, float stable, float regenfactor)
1614 {
1615         if(current > stable)
1616                 return current;
1617         else if(current > stable - 0.25) // when close enough, "snap"
1618                 return stable;
1619         else
1620                 return min(stable, current + (stable - current) * regenfactor * frametime);
1621 }
1622
1623 void player_regen (void)
1624 {
1625         float maxh, maxa, limith, limita, max_mod, regen_mod, rot_mod, limit_mod;
1626         maxh = cvar("g_balance_health_stable");
1627         maxa = cvar("g_balance_armor_stable");
1628         limith = cvar("g_balance_health_limit");
1629         limita = cvar("g_balance_armor_limit");
1630
1631         if (g_minstagib || (g_lms && !cvar("g_lms_regenerate")))
1632                 return;
1633
1634         max_mod = regen_mod = rot_mod = limit_mod = 1;
1635
1636         if (self.runes & RUNE_REGEN)
1637         {
1638                 if (self.runes & CURSE_VENOM) // do we have both rune/curse?
1639                 {
1640                         regen_mod = cvar("g_balance_rune_regen_combo_regenrate");
1641                         max_mod = cvar("g_balance_rune_regen_combo_hpmod");
1642                         limit_mod = cvar("g_balance_rune_regen_combo_limitmod");
1643                 }
1644                 else
1645                 {
1646                         regen_mod = cvar("g_balance_rune_regen_regenrate");
1647                         max_mod = cvar("g_balance_rune_regen_hpmod");
1648                         limit_mod = cvar("g_balance_rune_regen_limitmod");
1649                 }
1650         }
1651         else if (self.runes & CURSE_VENOM)
1652         {
1653                 max_mod = cvar("g_balance_curse_venom_hpmod");
1654                 if (self.runes & RUNE_REGEN) // do we have both rune/curse?
1655                         rot_mod = cvar("g_balance_rune_regen_combo_rotrate");
1656                 else
1657                         rot_mod = cvar("g_balance_curse_venom_rotrate");
1658                 limit_mod = cvar("g_balance_curse_venom_limitmod");
1659                 //if (!self.runes & RUNE_REGEN)
1660                 //      rot_mod = cvar("g_balance_curse_venom_rotrate");
1661         }
1662         maxh = maxh * max_mod;
1663         //maxa = maxa * max_mod;
1664         limith = limith * limit_mod;
1665         limita = limita * limit_mod;
1666
1667         if (self.armorvalue > maxa)
1668         {
1669                 if (time > self.pauserotarmor_finished)
1670                 {
1671                         self.armorvalue = max(maxa, self.armorvalue + (maxa - self.armorvalue) * cvar("g_balance_armor_rot") * frametime);
1672                         self.armorvalue = max(maxa, self.armorvalue - cvar("g_balance_armor_rotlinear") * frametime);
1673                 }
1674         }
1675         else if (self.armorvalue < maxa)
1676         {
1677                 if (time > self.pauseregen_finished)
1678                 {
1679                         self.armorvalue = CalcRegen(self.armorvalue, maxa, cvar("g_balance_armor_regen"));
1680                         self.armorvalue = min(maxa, self.armorvalue + cvar("g_balance_armor_regenlinear") * frametime);
1681                 }
1682         }
1683         if (self.health > maxh)
1684         {
1685                 if (time > self.pauserothealth_finished)
1686                 {
1687                         self.health = max(maxh, self.health + (maxh - self.health) * rot_mod*cvar("g_balance_health_rot") * frametime);
1688                         self.health = max(maxh, self.health - rot_mod*cvar("g_balance_health_rotlinear") * frametime);
1689                 }
1690         }
1691         else if (self.health < maxh)
1692         {
1693                 if (time > self.pauseregen_finished)
1694                 {
1695                         self.health = CalcRegen(self.health, maxh, regen_mod * cvar("g_balance_health_regen"));
1696                         self.health = min(maxh, self.health + regen_mod*cvar("g_balance_health_regenlinear") * frametime);
1697                 }
1698         }
1699
1700         if (self.health > limith)
1701                 self.health = limith;
1702         if (self.armorvalue > limita)
1703                 self.armorvalue = limita;
1704
1705         // if player rotted to death...  die!
1706         if(self.health < 1)
1707                 self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
1708 }
1709
1710 .float zoomstate;
1711 float zoomstate_set;
1712 void SetZoomState(float z)
1713 {
1714         if(z != self.zoomstate)
1715         {
1716                 msg_entity = self;
1717                 WriteByte(MSG_ONE, SVC_TEMPENTITY);
1718                 WriteByte(MSG_ONE, TE_CSQC_ZOOMNOTIFY);
1719                 WriteByte(MSG_ONE, z);
1720                 self.zoomstate = z;
1721         }
1722         zoomstate_set = 1;
1723 }
1724
1725 /*
1726 ======================
1727 spectate mode routines
1728 ======================
1729 */
1730 void SpectateCopy(entity spectatee) {
1731         self.armortype = spectatee.armortype;
1732         self.armorvalue = spectatee.armorvalue;
1733         self.currentammo = spectatee.currentammo;
1734         self.effects = spectatee.effects;
1735         self.health = spectatee.health;
1736         self.impulse = 0;
1737         self.items = spectatee.items;
1738         self.weapons = spectatee.weapons;
1739         self.switchweapon = spectatee.switchweapon;
1740         self.weapon = spectatee.weapon;
1741         self.punchangle = spectatee.punchangle;
1742         self.view_ofs = spectatee.view_ofs;
1743         self.v_angle = spectatee.v_angle;
1744         self.velocity = spectatee.velocity;
1745         self.dmg_take = spectatee.dmg_take;
1746         self.dmg_save = spectatee.dmg_save;
1747         self.dmg_inflictor = spectatee.dmg_inflictor;
1748         self.angles = spectatee.v_angle;
1749         self.fixangle = TRUE;
1750         setorigin(self, spectatee.origin);
1751         setsize(self, spectatee.mins, spectatee.maxs);
1752         SetZoomState(spectatee.zoomstate);
1753 }
1754
1755 float SpectateUpdate() {
1756         if(!self.enemy)
1757                 return 0;
1758
1759         if (self == self.enemy)
1760                 return 0;
1761
1762         if(self.enemy.flags & FL_NOTARGET)
1763                 return 0;
1764
1765         SpectateCopy(self.enemy);
1766
1767         return 1;
1768 }
1769
1770 float SpectateNext() {
1771         other = find(self.enemy, classname, "player");
1772         if (!other) {
1773                 other = find(other, classname, "player");
1774         }
1775         if (other) {
1776                 self.enemy = other;
1777         }
1778         if(self.enemy.classname == "player") {
1779                 msg_entity = self;
1780                 WriteByte(MSG_ONE, SVC_SETVIEW);
1781                 WriteEntity(MSG_ONE, self.enemy);
1782                 self.wantswelcomemessage = 1;
1783                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
1784                 if(!SpectateUpdate())
1785                         PutObserverInServer();
1786                 return 1;
1787         } else {
1788                 return 0;
1789         }
1790 }
1791
1792 /*
1793 =============
1794 ShowRespawnCountdown()
1795
1796 Update a respawn countdown display.
1797 =============
1798 */
1799 void ShowRespawnCountdown()
1800 {
1801         float number;
1802         if(self.deadflag == DEAD_NO) // just respawned?
1803                 return;
1804         else
1805         {
1806                 number = ceil(self.death_time - time);
1807                 if(number <= 0)
1808                         return;
1809                 if(number <= self.respawn_countdown)
1810                 {
1811                         self.respawn_countdown = number - 1;
1812                         if(ceil(self.death_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
1813                                 announce(self, strcat("announcer/robotic/", ftos(number), ".ogg"));
1814                 }
1815         }
1816 }
1817
1818 void LeaveSpectatorMode()
1819 {
1820         if(isJoinAllowed()) {
1821                 if(!cvar("teamplay") || cvar("g_campaign") || cvar("g_balance_teams")) {
1822                         self.classname = "player";
1823                         if(cvar("g_campaign") || cvar("g_balance_teams") || cvar("g_balance_teams_force"))
1824                                 JoinBestTeam(self, FALSE, TRUE);
1825                         if(cvar("g_campaign"))
1826                                 campaign_bots_may_start = 1;
1827                         PutClientInServer();
1828                         if(!(self.flags & FL_NOTARGET))
1829                                 bprint ("^4", self.netname, "^4 is playing now\n");
1830                         centerprint(self,"");
1831                         return;
1832                 } else {
1833                         stuffcmd(self,"menu_showteamselect\n");
1834                         return;
1835                 }
1836         }
1837         else {
1838                 //player may not join because of g_maxplayers is set
1839                 centerprint_atprio(self, CENTERPRIO_MAPVOTE, PREVENT_JOIN_TEXT);
1840         }
1841 }
1842
1843 /**
1844  * Determines whether the player is allowed to join. This depends on cvar
1845  * g_maxplayers, if it isn't used this function always return TRUE, otherwise
1846  * it checks whether the number of currently playing players exceeds g_maxplayers.
1847  * @return bool TRUE if the player is allowed to join, false otherwise
1848  */
1849 float isJoinAllowed() {
1850         if (!cvar("g_maxplayers"))
1851                 return TRUE;
1852
1853         local entity e;
1854         local float currentlyPlaying;
1855         FOR_EACH_REALPLAYER(e) {
1856                 if(e.classname == "player")
1857                         currentlyPlaying += 1;
1858         }
1859         if(currentlyPlaying < cvar("g_maxplayers"))
1860                 return TRUE;
1861
1862         return FALSE;
1863 }
1864
1865 /**
1866  * Checks whether the client is an observer or spectator, if so, he will get kicked after
1867  * g_maxplayers_spectator_blocktime seconds
1868  */
1869 void checkSpectatorBlock() {
1870         if(self.classname == "spectator" || self.classname == "observer") {
1871                 if( time > (self.spectatortime + cvar("g_maxplayers_spectator_blocktime")) ) {
1872                         sprint(self, "^7You were kicked from the server because you are spectator and spectators aren't allowed at the moment.\n");
1873                         dropclient(self);
1874                 }
1875         }
1876 }
1877
1878 float vercmp_recursive(string v1, string v2)
1879 {
1880         float dot1, dot2;
1881         string s1, s2;
1882         float r;
1883
1884         dot1 = strstrofs(v1, ".", 0);
1885         dot2 = strstrofs(v2, ".", 0);
1886         if(dot1 == -1)
1887                 s1 = v1;
1888         else
1889                 s1 = substring(v1, 0, dot1);
1890         if(dot2 == -1)
1891                 s2 = v2;
1892         else
1893                 s2 = substring(v2, 0, dot2);
1894
1895         r = stof(s1) - stof(s2);
1896         if(r != 0)
1897                 return r;
1898
1899         r = strcasecmp(s1, s2);
1900         if(r != 0)
1901                 return r;
1902
1903         if(dot1 == -1)
1904                 if(dot2 == -1)
1905                         return 0;
1906                 else
1907                         return -1;
1908         else
1909                 if(dot2 == -1)
1910                         return 1;
1911                 else
1912                         return vercmp_recursive(substring(v1, dot1 + 1, 999), substring(v2, dot2 + 1, 999));
1913 }
1914
1915 float vercmp(string v1, string v2)
1916 {
1917         if(strcasecmp(v1, v2) == 0) // early out check
1918                 return 0;
1919         return vercmp_recursive(v1, v2);
1920 }
1921
1922 void ObserverThink()
1923 {
1924         if (self.flags & FL_JUMPRELEASED) {
1925                 if (self.BUTTON_JUMP && !self.version_mismatch) {
1926                         self.welcomemessage_time = 0;
1927                         self.flags = self.flags - FL_JUMPRELEASED;
1928                         LeaveSpectatorMode();
1929                         return;
1930                 } else if(self.BUTTON_ATCK && !self.version_mismatch) {
1931                         self.welcomemessage_time = 0;
1932                         self.flags = self.flags - FL_JUMPRELEASED;
1933                         if(SpectateNext() == 1) {
1934                                 self.classname = "spectator";
1935                         }
1936                 }
1937         } else {
1938                 if (!(self.BUTTON_ATCK || self.BUTTON_JUMP)) {
1939                         self.flags = self.flags | FL_JUMPRELEASED;
1940                 }
1941         }
1942         /*
1943         if(self.BUTTON_ZOOM)
1944                 self.wantswelcomemessage = 0;
1945         */
1946         if(self.wantswelcomemessage)
1947                 PrintWelcomeMessage(self);
1948 }
1949
1950 void SpectatorThink()
1951 {
1952         if (self.flags & FL_JUMPRELEASED) {
1953                 if (self.BUTTON_JUMP && !self.version_mismatch) {
1954                         self.welcomemessage_time = 0;
1955                         self.flags = self.flags - FL_JUMPRELEASED;
1956                         LeaveSpectatorMode();
1957                         return;
1958                 } else if(self.BUTTON_ATCK) {
1959                         self.welcomemessage_time = 0;
1960                         self.flags = self.flags - FL_JUMPRELEASED;
1961                         if(SpectateNext() == 1) {
1962                                 self.classname = "spectator";
1963                         } else {
1964                                 self.classname = "observer";
1965                                 PutClientInServer();
1966                         }
1967                 } else if (self.BUTTON_ATCK2) {
1968                         self.welcomemessage_time = 0;
1969                         self.flags = self.flags - FL_JUMPRELEASED;
1970                         self.classname = "observer";
1971                         PutClientInServer();
1972                 } else {
1973                         if(!SpectateUpdate())
1974                                 PutObserverInServer();
1975                 }
1976         } else {
1977                 if (!(self.BUTTON_ATCK || self.BUTTON_ATCK2)) {
1978                         self.flags = self.flags | FL_JUMPRELEASED;
1979                 }
1980         }
1981         /*
1982         if(self.BUTTON_ZOOM)
1983                 self.wantswelcomemessage = 0;
1984         */
1985         if(self.wantswelcomemessage)
1986                 PrintWelcomeMessage(self);
1987         self.flags = self.flags | FL_CLIENT | FL_NOTARGET;
1988 }
1989
1990 /*
1991 =============
1992 PlayerPreThink
1993
1994 Called every frame for each client before the physics are run
1995 =============
1996 */
1997 void() ctf_setstatus;
1998 .float spectatee_status;
1999 void PlayerPreThink (void)
2000 {
2001         self.stat_sys_ticrate = cvar("sys_ticrate");
2002         self.stat_game_starttime = game_starttime;
2003
2004         if(blockSpectators)
2005                 checkSpectatorBlock();
2006
2007         zoomstate_set = 0;
2008
2009         if(self.netname_previous != self.netname)
2010         {
2011                 if(cvar("sv_eventlog"))
2012                         GameLogEcho(strcat(":name:", ftos(self.playerid), ":", self.netname));
2013                 if(self.netname_previous)
2014                         strunzone(self.netname_previous);
2015                 self.netname_previous = strzone(self.netname);
2016         }
2017
2018         // version nagging
2019         if(self.version_nagtime)
2020                 if(self.cvar_g_nexuizversion)
2021                         if(time > self.version_nagtime)
2022                         {
2023                                 if(strstr(self.cvar_g_nexuizversion, "svn", 0) < 0)
2024                                 {
2025                                         if(strstr(cvar_string("g_nexuizversion"), "svn", 0) >= 0)
2026                                         {
2027                                                 dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Nexuiz ", cvar_string("g_nexuizversion"), " (beta)^7, you have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1\n");
2028                                                 sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Nexuiz ", cvar_string("g_nexuizversion"), " (beta)^7, you have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1\n"));
2029                                         }
2030                                         else
2031                                         {
2032                                                 float r;
2033                                                 r = vercmp(self.cvar_g_nexuizversion, cvar_string("g_nexuizversion"));
2034                                                 if(r < 0)
2035                                                 {
2036                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - ^3Nexuiz ", cvar_string("g_nexuizversion"), "^7 is out, and you still have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1 - get the update from ^4http://www.nexuiz.com/^1!\n");
2037                                                         sprint(self, strcat("\{1}^1NOTE: ^3Nexuiz ", cvar_string("g_nexuizversion"), "^7 is out, and you still have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1 - get the update from ^4http://www.nexuiz.com/^1!\n"));
2038                                                 }
2039                                                 else if(r > 0)
2040                                                 {
2041                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Nexuiz ", cvar_string("g_nexuizversion"), "^7, you have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1\n");
2042                                                         sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Nexuiz ", cvar_string("g_nexuizversion"), "^7, you have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1\n"));
2043                                                 }
2044                                         }
2045                                 }
2046                                 self.version_nagtime = 0;
2047                         }
2048
2049         // GOD MODE info
2050         if(!(self.flags & FL_GODMODE)) if(self.max_armorvalue)
2051         {
2052                 sprint(self, strcat("godmode saved you ", ftos(self.max_armorvalue), " units of damage, cheater!\n"));
2053                 self.max_armorvalue = 0;
2054         }
2055
2056         if(frametime)
2057         {
2058                 antilag_record(self);
2059
2060                 SendFog();
2061         }
2062
2063         if(self.classname == "player") {
2064 //              if(self.netname == "Wazat")
2065 //                      bprint(self.classname, "\n");
2066
2067                 CheckRules_Player();
2068
2069                 if(self.BUTTON_INFO)
2070                         PrintWelcomeMessage(self);
2071
2072                 if(g_lms || !cvar("sv_spectate"))
2073                 if((time - self.jointime) <= cvar("welcome_message_time"))
2074                         PrintWelcomeMessage(self);
2075
2076                 if (intermission_running)
2077                 {
2078                         IntermissionThink ();   // otherwise a button could be missed between
2079                         return;                                 // the think tics
2080                 }
2081
2082                 if(self.teleport_time)
2083                 if(time > self.teleport_time)
2084                 {
2085                         self.teleport_time = 0;
2086                         self.effects = self.effects - (self.effects & EF_NODRAW);
2087                         if(self.weaponentity)
2088                                 self.weaponentity.flags = self.weaponentity.flags - (self.weaponentity.flags & EF_NODRAW);
2089                 }
2090
2091                 Nixnex_GiveCurrentWeapon();
2092
2093                 if(frametime > 0) // don't do this in cl_movement frames, just in server ticks
2094                         UpdateSelectedPlayer();
2095
2096                 //don't allow the player to turn around while game is paused!
2097                 if(timeoutStatus == 2) {
2098                         self.v_angle = self.lastV_angle;
2099                         self.angles = self.lastV_angle;
2100                         self.fixangle = TRUE;
2101                 }
2102
2103                 if (self.deadflag != DEAD_NO)
2104                 {
2105                         float button_pressed, force_respawn;
2106                         player_anim();
2107                         button_pressed = (self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE);
2108                         force_respawn = (g_lms || cvar("g_forced_respawn"));
2109                         if (self.deadflag == DEAD_DYING)
2110                         {
2111                                 if(force_respawn)
2112                                         self.deadflag = DEAD_RESPAWNING;
2113                                 else if(!button_pressed)
2114                                         self.deadflag = DEAD_DEAD;
2115                         }
2116                         else if (self.deadflag == DEAD_DEAD)
2117                         {
2118                                 if(button_pressed)
2119                                         self.deadflag = DEAD_RESPAWNABLE;
2120                         }
2121                         else if (self.deadflag == DEAD_RESPAWNABLE)
2122                         {
2123                                 if(!button_pressed)
2124                                         self.deadflag = DEAD_RESPAWNING;
2125                         }
2126                         else if (self.deadflag == DEAD_RESPAWNING)
2127                         {
2128                                 if(time > self.death_time)
2129                                 {
2130                                         self.death_time = time + 1; // only retry once a second
2131                                         respawn();
2132                                 }
2133                         }
2134                         ShowRespawnCountdown();
2135                         return;
2136                 }
2137
2138                 if(g_lms && !self.deadflag && cvar("g_lms_campcheck_interval"))
2139                 {
2140                         vector dist;
2141
2142                         // calculate player movement (in 2 dimensions only, so jumping on one spot doesn't count as movement)
2143                         dist = self.oldorigin - self.origin;
2144                         dist_z = 0;
2145                         self.lms_traveled_distance += fabs(vlen(dist));
2146
2147                         if((cvar("g_campaign") && !campaign_bots_may_start) || (time < game_starttime))
2148                         {
2149                                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval")*2;
2150                                 self.lms_traveled_distance = 0;
2151                         }
2152
2153                         if(time > self.lms_nextcheck)
2154                         {
2155                                 //sprint(self, "distance: ", ftos(self.lms_traveled_distance), "\n");
2156                                 if(self.lms_traveled_distance < cvar("g_lms_campcheck_distance"))
2157                                 {
2158                                         centerprint(self, cvar_string("g_lms_campcheck_message"));
2159                                         // FIXME KadaverJack: gibbing player here causes playermodel to bounce around, instead of eye.md3
2160                                         // I wasn't able to find out WHY that happens, so I put a workaround in place that shall prevent players from being gibbed :(
2161                                         Damage(self, self, self, bound(0, cvar("g_lms_campcheck_damage"), self.health + self.armorvalue * cvar("g_balance_armor_blockpercent") + 5), DEATH_CAMP, self.origin, '0 0 0');
2162                                 }
2163                                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval");
2164                                 self.lms_traveled_distance = 0;
2165                         }
2166                 }
2167
2168                 if (self.BUTTON_CROUCH && !self.hook.state)
2169                 {
2170                         if (!self.crouch)
2171                         {
2172                                 self.crouch = TRUE;
2173                                 self.view_ofs = PL_CROUCH_VIEW_OFS;
2174                                 setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX);
2175                                 player_setanim(self.anim_duck, FALSE, TRUE, TRUE);
2176                         }
2177                 }
2178                 else
2179                 {
2180                         if (self.crouch)
2181                         {
2182                                 tracebox(self.origin, PL_MIN, PL_MAX, self.origin, FALSE, self);
2183                                 if (!trace_startsolid)
2184                                 {
2185                                         self.crouch = FALSE;
2186                                         self.view_ofs = PL_VIEW_OFS;
2187                                         setsize (self, PL_MIN, PL_MAX);
2188                                 }
2189                         }
2190                 }
2191
2192                 FixPlayermodel();
2193
2194                 GrapplingHookFrame();
2195
2196                 W_WeaponFrame();
2197
2198                 player_powerups();
2199                 player_regen();
2200                 player_anim();
2201
2202                 if (g_minstagib)
2203                         minstagib_ammocheck();
2204
2205                 ctf_setstatus();
2206                 kh_setstatus();
2207
2208                 //self.angles_y=self.v_angle_y + 90;   // temp
2209
2210                 //if (TetrisPreFrame()) return;
2211         } else if(gameover) {
2212                 if (intermission_running)
2213                         IntermissionThink ();   // otherwise a button could be missed between
2214                 return;
2215         } else if(self.classname == "observer") {
2216                 ObserverThink();
2217         } else if(self.classname == "spectator") {
2218                 SpectatorThink();
2219         }
2220
2221         if(!zoomstate_set)
2222                 SetZoomState(self.BUTTON_ZOOM || (self.BUTTON_ATCK2 && self.weapon == WEP_NEX));
2223
2224         float oldspectatee_status;
2225         oldspectatee_status = self.spectatee_status;
2226         if(self.classname == "spectator")
2227                 self.spectatee_status = num_for_edict(self.enemy);
2228         else if(self.classname == "observer")
2229                 self.spectatee_status = num_for_edict(self);
2230         else
2231                 self.spectatee_status = 0;
2232         if(self.spectatee_status != oldspectatee_status)
2233         {
2234                 msg_entity = self;
2235                 WriteByte(MSG_ONE, SVC_TEMPENTITY);
2236                 WriteByte(MSG_ONE, TE_CSQC_SPECTATING);
2237                 WriteByte(MSG_ONE, self.spectatee_status);
2238                 if(g_race)
2239                         race_InitSpectator();
2240         }
2241 }
2242
2243
2244 /*
2245 =============
2246 PlayerPostThink
2247
2248 Called every frame for each client after the physics are run
2249 =============
2250 */
2251 .float idlekick_lasttimeleft;
2252 .float race_penalty;
2253 .float race_penalty_nagged;
2254 void PlayerPostThink (void)
2255 {
2256         // Savage: Check for nameless players
2257         if (strlen(self.netname) < 1) {
2258                 self.netname = "Player";
2259                 stuffcmd(self, "seta _cl_name Player\n");
2260         }
2261
2262         if(sv_maxidle)
2263         {
2264                 float timeleft;
2265                 timeleft = ceil(sv_maxidle - (time - self.parm_idlesince));
2266                 if(timeleft <= 0)
2267                 {
2268                         bprint("^3", self.netname, "^3 was kicked for idling.\n");
2269                         announce(self, "announcer/robotic/terminated.ogg");
2270                         dropclient(self);
2271                         return;
2272                 }
2273                 else if(timeleft <= 10)
2274                 {
2275                         if(timeleft != self.idlekick_lasttimeleft)
2276                         {
2277                                 centerprint_atprio(self, CENTERPRIO_IDLEKICK, strcat("^3Stop idling!\n^3Disconnecting in ", ftos(timeleft), "..."));
2278                                 announce(self, strcat("announcer/robotic/", ftos(timeleft), ".ogg"));
2279                         }
2280                 }
2281                 else
2282                 {
2283                         centerprint_expire(self, CENTERPRIO_IDLEKICK);
2284                 }
2285                 self.idlekick_lasttimeleft = timeleft;
2286         }
2287
2288         if(self.classname == "player") {
2289                 CheckRules_Player();
2290                 UpdateChatBubble();
2291                 UpdateTeamBubble();
2292                 if (self.impulse)
2293                         ImpulseCommands();
2294                 if (intermission_running)
2295                         return;         // intermission or finale
2296
2297                 //PrintWelcomeMessage(self);
2298                 //if (TetrisPostFrame()) return;
2299
2300                 // restart countdown
2301                         if(time < game_starttime) {
2302                                 if (!cvar("sv_ready_restart_after_countdown"))
2303                                 {
2304                                         if(self.movement != '0 0 0' && g_race && !g_race_qualifying)
2305                                         {
2306                                                 if(time < game_starttime - 2)
2307                                                 {
2308                                                         if(!self.race_penalty_nagged)
2309                                                         {
2310                                                                 // TODO better notification for this!
2311                                                                 centerprint_atprio(self, CENTERPRIO_IDLEKICK, "^1DO NOT MOVE DURING THE COUNTDOWN.");
2312                                                                 self.race_penalty_nagged = 1;
2313                                                         }
2314                                                 }
2315                                                 else if(!self.race_penalty)
2316                                                 {
2317                                                         centerprint_atprio(self, CENTERPRIO_IDLEKICK, "^1FIVE SECONDS PENALTY.");
2318                                                         self.race_penalty = time + 5;
2319                                                 }
2320                                         }
2321                                         self.movetype = MOVETYPE_NONE;
2322                                         self.velocity = '0 0 0';
2323                                         self.avelocity = '0 0 0';
2324                                         self.movement = '0 0 0';
2325                                 }
2326                         }
2327                         else if (time < self.race_penalty)
2328                         {
2329                                 self.movetype = MOVETYPE_NONE;
2330                                 self.velocity = '0 0 0';
2331                                 self.avelocity = '0 0 0';
2332                                 self.movement = '0 0 0';
2333                         }
2334                         else
2335                         {
2336                                 //allow the player to move again if sv_ready_restart_after_countdown is not used and countdown is over
2337                                 if (!cvar("sv_ready_restart_after_countdown"))
2338                                 {
2339                                         if(self.movetype == MOVETYPE_NONE)
2340                                         {
2341                                                 self.movetype = MOVETYPE_WALK;
2342                                         }
2343                                         self.race_penalty = 0;
2344                                         self.race_penalty_nagged = 0;
2345                                 }
2346                         }
2347
2348         } else if (self.classname == "observer") {
2349                 //do nothing
2350         } else if (self.classname == "spectator") {
2351                 //do nothing
2352         }
2353
2354         /*
2355         float i;
2356         for(i = 0; i < 1000; ++i)
2357         {
2358                 vector end;
2359                 end = self.origin + '0 0 1024' + 512 * randomvec();
2360                 tracebox(self.origin, self.mins, self.maxs, end, MOVE_NORMAL, self);
2361                 if(trace_fraction < 1)
2362                 if(!(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
2363                 {
2364                         print("I HIT SOLID: ", vtos(self.origin), " -> ", vtos(end), "\n");
2365                         break;
2366                 }
2367         }
2368         */
2369
2370         Arena_Warmup();
2371 }