data/qcsrc/server/cl_client.qc

   1 // let's abuse an existing field
   2 #define SPAWNPOINT_SCORE frags
   3
   4 .float wantswelcomemessage;
   5 .string netname_previous;
   6
   7 void spawnfunc_info_player_survivor (void)
   8 {
   9         spawnfunc_info_player_deathmatch();
  10 }
  11
  12 void spawnfunc_info_player_start (void)
  13 {
  14         spawnfunc_info_player_deathmatch();
  15 }
  16
  17 void spawnfunc_info_player_deathmatch (void)
  18 {
  19         self.classname = "info_player_deathmatch";
  20         relocate_spawnpoint();
  21 }
  22
  23 void spawnpoint_use()
  24 {
  25         if(teams_matter)
  26         if(have_team_spawns)
  27         {
  28                 self.team = activator.team;
  29                 some_spawn_has_been_used = 1;
  30         }
  31 };
  32
  33 // Returns:
  34 //   -1 if a spawn can't be used
  35 //   otherwise, a weight of the spawnpoint
  36 float Spawn_Score(entity spot, entity playerlist, float teamcheck)
  37 {
  38         float shortest, thisdist;
  39         entity player;
  40
  41         // filter out spots for the wrong team
  42         if(teamcheck)
  43         if(spot.team != teamcheck)
  44                 return -1;
  45
  46         if(race_spawns)
  47                 if(spot.target == "")
  48                         return -1;
  49
  50         // filter out spots for assault
  51         if(spot.target != "") {
  52                 local entity ent;
  53                 float good;
  54                 ent = find(world, targetname, spot.target);
  55                 while(ent) {
  56                         if(ent.classname == "target_objective")
  57                         {
  58                                 if(ent.health < 0 || ent.health >= ASSAULT_VALUE_INACTIVE)
  59                                         return -1;
  60                                 good = 1;
  61                         }
  62                         else if(ent.classname == "trigger_race_checkpoint")
  63                         {
  64                                 if(self.classname == "player") // spectators may spawn everywhere
  65                                 {
  66                                         if(ent.race_checkpoint != race_PreviousCheckpoint(self.race_checkpoint))
  67                                                 return -1;
  68                                         float pl;
  69                                         pl = self.race_place;
  70                                         if(pl > race_highest_place_spawn)
  71                                                 pl = 0;
  72                                         if(spot.race_place != pl)
  73                                                 return -1;
  74                                 }
  75                                 good = 1;
  76                         }
  77                         else
  78                         {
  79                         }
  80                         ent = find(ent, targetname, spot.target);
  81                 }
  82
  83                 if(!good)
  84                         return -1;
  85         }
  86
  87         player = playerlist;
  88         shortest = vlen(world.maxs - world.mins);
  89         for(player = playerlist; player; player = player.chain)
  90                 if (player != self)
  91                 {
  92                         thisdist = vlen(player.origin - spot.origin);
  93                         if (thisdist < shortest)
  94                                 shortest = thisdist;
  95                 }
  96         return shortest;
  97 }
  98
  99 float spawn_allbad;
 100 float spawn_allgood;
 101 entity Spawn_FilterOutBadSpots(entity firstspot, entity playerlist, float mindist, float teamcheck)
 102 {
 103         local entity spot, spotlist, spotlistend;
 104         spawn_allgood = TRUE;
 105         spawn_allbad = TRUE;
 106
 107         spotlist = world;
 108         spotlistend = world;
 109
 110         for(spot = firstspot; spot; spot = spot.chain)
 111         {
 112                 spot.SPAWNPOINT_SCORE = Spawn_Score(spot, playerlist, teamcheck);
 113
 114                 if(cvar("spawn_debugview"))
 115                 {
 116                         setmodel(spot, "models/runematch/rune.mdl");
 117                         if(spot.SPAWNPOINT_SCORE < mindist)
 118                         {
 119                                 spot.colormod = '1 0 0';
 120                                 spot.scale = 1;
 121                         }
 122                         else
 123                         {
 124                                 spot.colormod = '0 1 0';
 125                                 spot.scale = spot.SPAWNPOINT_SCORE / mindist;
 126                         }
 127                 }
 128
 129                 if(spot.SPAWNPOINT_SCORE >= 0) // spawning allowed here
 130                 {
 131                         if(spot.SPAWNPOINT_SCORE < mindist)
 132                         {
 133                                 // too short distance
 134                                 spawn_allgood = FALSE;
 135                         }
 136                         else
 137                         {
 138                                 // perfect
 139                                 spawn_allbad = FALSE;
 140
 141                                 if(spotlistend)
 142                                         spotlistend.chain = spot;
 143                                 spotlistend = spot;
 144                                 if(!spotlist)
 145                                         spotlist = spot;
 146
 147                                 /*
 148                                 if(teamcheck)
 149                                 if(spot.team != teamcheck)
 150                                         error("invalid spawn added");
 151
 152                                 print("added ", etos(spot), "\n");
 153                                 */
 154                         }
 155                 }
 156         }
 157         if(spotlistend)
 158                 spotlistend.chain = world;
 159
 160         /*
 161                 entity e;
 162                 if(teamcheck)
 163                         for(e = spotlist; e; e = e.chain)
 164                         {
 165                                 print("seen ", etos(e), "\n");
 166                                 if(e.team != teamcheck)
 167                                         error("invalid spawn found");
 168                         }
 169         */
 170
 171         return spotlist;
 172 }
 173
 174 entity Spawn_WeightedPoint(entity firstspot, float lower, float upper, float exponent)
 175 {
 176         // weight of a point: bound(lower, mindisttoplayer, upper)^exponent
 177         // multiplied by spot.cnt (useful if you distribute many spawnpoints in a small area)
 178         local entity spot;
 179
 180         RandomSelection_Init();
 181         for(spot = firstspot; spot; spot = spot.chain)
 182                 RandomSelection_Add(spot, 0, pow(bound(lower, spot.SPAWNPOINT_SCORE, upper), exponent) * spot.cnt, spot.SPAWNPOINT_SCORE >= lower);
 183
 184         return RandomSelection_chosen_ent;
 185 }
 186
 187 /*
 188 =============
 189 SelectSpawnPoint
 190
 191 Finds a point to respawn
 192 =============
 193 */
 194 entity SelectSpawnPoint (float anypoint)
 195 {
 196         local float teamcheck;
 197         local entity firstspot_new;
 198         local entity spot, firstspot, playerlist;
 199
 200         spot = find (world, classname, "testplayerstart");
 201         if (spot)
 202                 return spot;
 203
 204         teamcheck = 0;
 205
 206         if(!anypoint && have_team_spawns)
 207                 teamcheck = self.team;
 208
 209         // get the list of players
 210         playerlist = findchain(classname, "player");
 211         // get the entire list of spots
 212         firstspot = findchain(classname, "info_player_deathmatch");
 213         // filter out the bad ones
 214         // (note this returns the original list if none survived)
 215         firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, 100, teamcheck);
 216         if(!firstspot_new)
 217                 firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, -1, teamcheck);
 218         firstspot = firstspot_new;
 219
 220         // there is 50/50 chance of choosing a random spot or the furthest spot
 221         // (this means that roughly every other spawn will be furthest, so you
 222         // usually won't get fragged at spawn twice in a row)
 223         if (arena_roundbased)
 224         {
 225                 firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, 800, teamcheck);
 226                 if(firstspot_new)
 227                         firstspot = firstspot_new;
 228                 spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 229         }
 230         else if (random() > cvar("g_spawn_furthest"))
 231                 spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 232         else
 233                 spot = Spawn_WeightedPoint(firstspot, 1, 5000, 5); // chooses a far far away spawnpoint
 234
 235         if(cvar("spawn_debugview"))
 236         {
 237                 print("spot mindistance: ", ftos(spot.SPAWNPOINT_SCORE), "\n");
 238
 239                 entity e;
 240                 if(teamcheck)
 241                         for(e = firstspot; e; e = e.chain)
 242                                 if(e.team != teamcheck)
 243                                         error("invalid spawn found");
 244         }
 245
 246         if (!spot)
 247         {
 248                 if(cvar("spawn_debug"))
 249                         GotoNextMap();
 250                 else
 251                 {
 252                         if(some_spawn_has_been_used)
 253                                 return world; // team can't spawn any more, because of actions of other team
 254                         else
 255                                 error("Cannot find a spawn point - please fix the map!");
 256                 }
 257         }
 258
 259         return spot;
 260 }
 261
 262 /*
 263 =============
 264 CheckPlayerModel
 265
 266 Checks if the argument string can be a valid playermodel.
 267 Returns a valid one in doubt.
 268 =============
 269 */
 270 string FallbackPlayerModel = "models/player/marine.zym";
 271 string CheckPlayerModel(string plyermodel) {
 272         if(strlen(plyermodel) < 4)
 273                 return FallbackPlayerModel;
 274         if( substring(plyermodel,0,14) != "models/player/")
 275                 return FallbackPlayerModel;
 276         else if(cvar("sv_servermodelsonly"))
 277         {
 278                 if(substring(plyermodel,strlen(plyermodel)-4,4) != ".zym")
 279                 if(substring(plyermodel,strlen(plyermodel)-4,4) != ".dpm")
 280                 if(substring(plyermodel,strlen(plyermodel)-4,4) != ".md3")
 281                 if(substring(plyermodel,strlen(plyermodel)-4,4) != ".psk")
 282                         return FallbackPlayerModel;
 283                 if(!fexists(plyermodel))
 284                         return FallbackPlayerModel;
 285         }
 286         return plyermodel;
 287 }
 288
 289 /*
 290 =============
 291 Client_customizeentityforclient
 292
 293 LOD reduction
 294 =============
 295 */
 296 float Client_customizeentityforclient()
 297 {
 298 #ifdef ALLOW_VARIABLE_LOD
 299         // self: me
 300         // other: the player viewing me
 301         float distance;
 302         float f;
 303
 304         if(self.flags & FL_NOTARGET) // we don't need LOD for spectators
 305                 return TRUE;
 306
 307         if(other.cvar_cl_playerdetailreduction <= 0)
 308         {
 309                 if(other.cvar_cl_playerdetailreduction <= -2)
 310                         self.modelindex = self.modelindex_lod2;
 311                 else if(other.cvar_cl_playerdetailreduction <= -1)
 312                         self.modelindex = self.modelindex_lod1;
 313                 else
 314                         self.modelindex = self.modelindex_lod0;
 315         }
 316         else
 317         {
 318                 distance = vlen(self.origin - other.origin);
 319                 f = (distance + 100.0) * other.cvar_cl_playerdetailreduction;
 320                 if(f > 10000)
 321                         self.modelindex = self.modelindex_lod2;
 322                 else if(f > 5000)
 323                         self.modelindex = self.modelindex_lod1;
 324                 else
 325                         self.modelindex = self.modelindex_lod0;
 326         }
 327 #endif
 328
 329         return TRUE;
 330 }
 331
 332 void UpdatePlayerSounds();
 333 void setmodel_lod(entity e, string modelname)
 334 {
 335 #ifdef ALLOW_VARIABLE_LOD
 336         string s;
 337
 338         // FIXME: this only supports 3-letter extensions
 339         s = strcat(substring(modelname, 0, strlen(modelname) - 4), "_1", substring(modelname, 0, strlen(modelname) - 4));
 340         if(fexists(s))
 341         {
 342                 precache_model(s);
 343                 setmodel(e, s); // players have high precision
 344                 self.modelindex_lod1 = self.modelindex;
 345         }
 346         else
 347                 self.modelindex_lod1 = -1;
 348
 349         s = strcat(substring(modelname, 0, strlen(modelname) - 4), "_2", substring(modelname, 0, strlen(modelname) - 4));
 350         if(fexists(s))
 351         {
 352                 precache_model(s);
 353                 setmodel(e, s); // players have high precision
 354                 self.modelindex_lod2 = self.modelindex;
 355         }
 356         else
 357                 self.modelindex_lod2 = -1;
 358
 359         precache_model(modelname);
 360         setmodel(e, modelname); // players have high precision
 361         self.modelindex_lod0 = self.modelindex;
 362
 363         if(self.modelindex_lod1 < 0)
 364                 self.modelindex_lod1 = self.modelindex;
 365
 366         if(self.modelindex_lod2 < 0)
 367                 self.modelindex_lod2 = self.modelindex;
 368 #else
 369         precache_model(modelname);
 370         setmodel(e, modelname); // players have high precision
 371 #endif
 372         player_setupanimsformodel();
 373         UpdatePlayerSounds();
 374 }
 375
 376 /*
 377 =============
 378 PutObserverInServer
 379
 380 putting a client as observer in the server
 381 =============
 382 */
 383 void PutObserverInServer (void)
 384 {
 385         entity  spot;
 386
 387         race_PreSpawnObserver();
 388
 389         spot = SelectSpawnPoint (TRUE);
 390         if(!spot)
 391                 error("No spawnpoints for observers?!?\n");
 392         RemoveGrapplingHook(self); // Wazat's Grappling Hook
 393
 394         if(clienttype(self) == CLIENTTYPE_REAL)
 395         {
 396                 msg_entity = self;
 397                 WriteByte(MSG_ONE, SVC_SETVIEW);
 398                 WriteEntity(MSG_ONE, self);
 399         }
 400
 401         DropAllRunes(self);
 402         kh_Key_DropAll(self, TRUE);
 403
 404         if(self.flagcarried)
 405                 DropFlag(self.flagcarried);
 406
 407         WaypointSprite_PlayerDead();
 408
 409         if(self.killcount != -666)
 410         {
 411                 if(g_lms)
 412                 {
 413                         if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
 414                                 bprint ("^4", self.netname, "^4 has no more lives left\n");
 415                         else
 416                                 bprint ("^4", self.netname, "^4 is spectating now\n"); // TODO turn this into a proper forfeit?
 417                 }
 418                 else
 419                         bprint ("^4", self.netname, "^4 is spectating now\n");
 420         }
 421
 422         PlayerScore_Clear(self); // clear scores when needed
 423
 424         self.spectatortime = time;
 425
 426         self.classname = "observer";
 427         self.health = -666;
 428         self.takedamage = DAMAGE_NO;
 429         self.solid = SOLID_NOT;
 430         self.movetype = MOVETYPE_NOCLIP;
 431         self.flags = FL_CLIENT | FL_NOTARGET;
 432         self.armorvalue = 666;
 433         self.effects = 0;
 434         self.armorvalue = cvar("g_balance_armor_start");
 435         self.pauserotarmor_finished = 0;
 436         self.pauserothealth_finished = 0;
 437         self.pauseregen_finished = 0;
 438         self.damageforcescale = 0;
 439         self.death_time = 0;
 440         self.dead_frame = 0;
 441         self.alpha = 0;
 442         self.scale = 0;
 443         self.fade_time = 0;
 444         self.pain_frame = 0;
 445         self.pain_finished = 0;
 446         self.strength_finished = 0;
 447         self.invincible_finished = 0;
 448         self.pushltime = 0;
 449         self.think = SUB_Null;
 450         self.nextthink = 0;
 451         self.hook_time = 0;
 452         self.runes = 0;
 453         self.deadflag = DEAD_NO;
 454         self.angles = spot.angles;
 455         self.angles_z = 0;
 456         self.fixangle = TRUE;
 457         self.crouch = FALSE;
 458
 459         self.view_ofs = PL_VIEW_OFS;
 460         setorigin (self, spot.origin);
 461         setsize (self, '0 0 0', '0 0 0');
 462         self.oldorigin = self.origin;
 463         self.items = 0;
 464         self.weapons = 0;
 465         self.model = "";
 466         self.modelindex = 0;
 467         self.weapon = 0;
 468         self.weaponmodel = "";
 469         self.weaponentity = world;
 470         self.killcount = -666;
 471         self.velocity = '0 0 0';
 472         self.avelocity = '0 0 0';
 473         self.punchangle = '0 0 0';
 474         self.punchvector = '0 0 0';
 475         self.oldvelocity = self.velocity;
 476         self.customizeentityforclient = Client_customizeentityforclient;
 477         self.wantswelcomemessage = 1;
 478
 479         if(g_arena)
 480         {
 481                 if(self.version_mismatch)
 482                 {
 483                         Spawnqueue_Unmark(self);
 484                         Spawnqueue_Remove(self);
 485                 }
 486                 else
 487                 {
 488                         Spawnqueue_Insert(self);
 489                 }
 490         }
 491         else if(g_lms)
 492         {
 493                 // Only if the player cannot play at all
 494                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) == 666)
 495                         self.frags = -666;
 496                 else
 497                         self.frags = -667;
 498         }
 499         else
 500                 self.frags = -666;
 501 }
 502
 503 float RestrictSkin(float s)
 504 {
 505         if(!teams_matter)
 506                 return s;
 507         if(s == 6)
 508                 return 6;
 509         return mod(s, 3);
 510 }
 511
 512 void FixPlayermodel()
 513 {
 514         local string defaultmodel;
 515         local float defaultskin;
 516         local vector m1, m2;
 517
 518         defaultmodel = "";
 519
 520         if(cvar("sv_defaultcharacter") == 1) {
 521                 defaultskin = 0;
 522
 523                 if(teams_matter)
 524                 {
 525                         defaultmodel = cvar_string(strcat("sv_defaultplayermodel_", Team_ColorNameLowerCase(self.team)));
 526                         defaultskin = cvar(strcat("sv_defaultplayerskin_", Team_ColorNameLowerCase(self.team)));
 527                 }
 528
 529                 if(defaultmodel == "")
 530                 {
 531                         defaultmodel = cvar_string("sv_defaultplayermodel");
 532                         defaultskin = cvar("sv_defaultplayerskin");
 533                 }
 534         }
 535
 536         if(defaultmodel != "")
 537         {
 538                 if (defaultmodel != self.model)
 539                 {
 540                         m1 = self.mins;
 541                         m2 = self.maxs;
 542                         setmodel_lod (self, defaultmodel);
 543                         setsize (self, m1, m2);
 544                 }
 545
 546                 self.skin = defaultskin;
 547         } else {
 548                 if (self.playermodel != self.model)
 549                 {
 550                         self.playermodel = CheckPlayerModel(self.playermodel);
 551                         m1 = self.mins;
 552                         m2 = self.maxs;
 553                         setmodel_lod (self, self.playermodel);
 554                         setsize (self, m1, m2);
 555                 }
 556
 557                 self.skin = RestrictSkin(stof(self.playerskin));
 558         }
 559
 560         if(!teams_matter)
 561                 if(strlen(cvar_string("sv_defaultplayercolors")))
 562                         if(self.clientcolors != cvar("sv_defaultplayercolors"))
 563                                 setcolor(self, cvar("sv_defaultplayercolors"));
 564 }
 565
 566 /*
 567 =============
 568 PutClientInServer
 569
 570 Called when a client spawns in the server
 571 =============
 572 */
 573 //void() ctf_playerchanged;
 574 void PutClientInServer (void)
 575 {
 576         if(clienttype(self) == CLIENTTYPE_BOT)
 577         {
 578                 self.classname = "player";
 579         }
 580         else if(clienttype(self) == CLIENTTYPE_REAL)
 581         {
 582                 msg_entity = self;
 583                 WriteByte(MSG_ONE, SVC_SETVIEW);
 584                 WriteEntity(MSG_ONE, self);
 585         }
 586
 587         // player is dead and becomes observer
 588         // FIXME fix LMS scoring for new system
 589         if(g_lms)
 590         {
 591                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
 592                         self.classname = "observer";
 593         }
 594
 595         if(g_arena)
 596         if(!self.spawned)
 597                 self.classname = "observer";
 598
 599         if(self.classname == "player") {
 600                 entity  spot;
 601
 602                 race_PreSpawn();
 603
 604                 spot = SelectSpawnPoint (FALSE);
 605                 if(!spot)
 606                 {
 607                         centerprint(self, "Sorry, no spawnpoints available!\nHope your team can fix it...");
 608                         return; // spawn failed
 609                 }
 610
 611                 RemoveGrapplingHook(self); // Wazat's Grappling Hook
 612
 613                 self.classname = "player";
 614                 self.iscreature = TRUE;
 615                 self.movetype = MOVETYPE_WALK;
 616                 self.solid = SOLID_SLIDEBOX;
 617                 if(independent_players)
 618                         MAKE_INDEPENDENT_PLAYER(self);
 619                 self.flags = FL_CLIENT;
 620                 self.takedamage = DAMAGE_AIM;
 621                 if(g_minstagib)
 622                         self.effects = EF_FULLBRIGHT;
 623                 else
 624                         self.effects = 0;
 625                 self.air_finished = time + 12;
 626                 self.dmg = 2;
 627
 628                 self.ammo_shells = start_ammo_shells;
 629                 self.ammo_nails = start_ammo_nails;
 630                 self.ammo_rockets = start_ammo_rockets;
 631                 self.ammo_cells = start_ammo_cells;
 632                 self.health = start_health;
 633                 self.armorvalue = start_armorvalue;
 634                 self.items = 0;
 635                 self.weapons = start_weapons;
 636                 self.switchweapon = start_switchweapon;
 637                 self.cnt = start_switchweapon;
 638                 self.weapon = 0;
 639                 self.jump_interval = time;
 640
 641                 self.spawnshieldtime = time + cvar("g_spawnshieldtime");
 642                 self.pauserotarmor_finished = time + cvar("g_balance_pause_armor_rot_spawn");
 643                 self.pauserothealth_finished = time + cvar("g_balance_pause_health_rot_spawn");
 644                 self.pauseregen_finished = time + cvar("g_balance_pause_health_regen_spawn");
 645                 //extend the pause of rotting if client was reset at the beginning of the countdown
 646                 if(!cvar("sv_ready_restart_after_countdown") && time < restart_countdown) {
 647                         self.spawnshieldtime += RESTART_COUNTDOWN;
 648                         self.pauserotarmor_finished += RESTART_COUNTDOWN;
 649                         self.pauserothealth_finished += RESTART_COUNTDOWN;
 650                         self.pauseregen_finished += RESTART_COUNTDOWN;
 651                 }
 652                 self.damageforcescale = 2;
 653                 self.death_time = 0;
 654                 self.dead_frame = 0;
 655                 self.alpha = 0;
 656                 self.scale = 0;
 657                 self.fade_time = 0;
 658                 self.pain_frame = 0;
 659                 self.pain_finished = 0;
 660                 self.strength_finished = 0;
 661                 self.invincible_finished = 0;
 662                 self.pushltime = 0;
 663                 //self.speed_finished = 0;
 664                 //self.slowmo_finished = 0;
 665                 // players have no think function
 666                 self.think = SUB_Null;
 667                 self.nextthink = 0;
 668                 self.hook_time = 0;
 669
 670                 self.runes = 0;
 671
 672                 self.deadflag = DEAD_NO;
 673
 674                 self.angles = spot.angles;
 675
 676                 self.angles_z = 0; // never spawn tilted even if the spot says to
 677                 self.fixangle = TRUE; // turn this way immediately
 678                 self.velocity = '0 0 0';
 679                 self.avelocity = '0 0 0';
 680                 self.punchangle = '0 0 0';
 681                 self.punchvector = '0 0 0';
 682                 self.oldvelocity = self.velocity;
 683
 684                 msg_entity = self;
 685                 WRITESPECTATABLE_MSG_ONE({
 686                         WriteByte(MSG_ONE, SVC_TEMPENTITY);
 687                         WriteByte(MSG_ONE, TE_CSQC_SPAWN);
 688                 });
 689
 690                 self.customizeentityforclient = Client_customizeentityforclient;
 691
 692                 self.model = "";
 693                 FixPlayermodel();
 694
 695                 self.crouch = FALSE;
 696                 self.view_ofs = PL_VIEW_OFS;
 697                 setsize (self, PL_MIN, PL_MAX);
 698                 self.spawnorigin = spot.origin;
 699                 setorigin (self, spot.origin + '0 0 1' * (1 - self.mins_z - 24));
 700                 // don't reset back to last position, even if new position is stuck in solid
 701                 self.oldorigin = self.origin;
 702
 703                 if(g_arena)
 704                 {
 705                         Spawnqueue_Remove(self);
 706                         Spawnqueue_Mark(self);
 707                 }
 708
 709                 self.event_damage = PlayerDamage;
 710
 711                 self.bot_attack = TRUE;
 712
 713                 self.statdraintime = time + 5;
 714                 self.BUTTON_ATCK = self.BUTTON_JUMP = self.BUTTON_ATCK2 = 0;
 715
 716                 if(self.killcount == -666) {
 717                         PlayerScore_Clear(self);
 718                         self.killcount = 0;
 719                         self.frags = 0;
 720                 }
 721
 722                 self.cnt = WEP_LASER;
 723                 self.nixnex_lastchange_id = -1;
 724
 725                 CL_SpawnWeaponentity();
 726                 self.alpha = default_player_alpha;
 727                 self.colormod = '1 1 1' * cvar("g_player_brightness");
 728                 self.exteriorweaponentity.alpha = default_weapon_alpha;
 729
 730                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval")*2;
 731                 self.lms_traveled_distance = 0;
 732                 self.speedrunning = FALSE;
 733
 734                 race_PostSpawn(spot);
 735
 736                 if(cvar("spawn_debug"))
 737                 {
 738                         sprint(self, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 739                         remove(spot);   // usefull for checking if there are spawnpoints, that let drop through the floor
 740                 }
 741
 742                 //stuffcmd(self, "chase_active 0");
 743                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
 744
 745                 if (cvar("g_spawnsound"))
 746                         sound (self, CHAN_TRIGGER, "misc/spawn.wav", VOL_BASE, ATTN_NORM);
 747
 748                 if(g_assault) {
 749                         if(self.team == assault_attacker_team)
 750                                 centerprint(self, "You are attacking!\n");
 751                         else
 752                                 centerprint(self, "You are defending!\n");
 753                 }
 754
 755         } else if(self.classname == "observer") {
 756                 PutObserverInServer ();
 757         }
 758
 759         //if(g_ctf)
 760         //      ctf_playerchanged();
 761 }
 762
 763 /*
 764 =============
 765 SendCSQCInfo
 766
 767 Send whatever CSQC needs NOW and cannot wait for SendServerInfo to happen...
 768 =============
 769 */
 770 void SendCSQCInfo(void)
 771 {
 772         if(clienttype(self) != CLIENTTYPE_REAL)
 773                 return;
 774         msg_entity = self;
 775         WriteByte(MSG_ONE, SVC_TEMPENTITY);
 776         WriteByte(MSG_ONE, TE_CSQC_INIT);
 777         WriteShort(MSG_ONE, CSQC_REVISION);
 778         WriteByte(MSG_ONE, maxclients);
 779         WriteByte(MSG_ONE, g_minstagib);
 780 }
 781
 782 /*
 783 =============
 784 SetNewParms
 785 =============
 786 */
 787 void SetNewParms (void)
 788 {
 789         // initialize parms for a new player
 790         parm1 = -(86400 * 366);
 791 }
 792
 793 /*
 794 =============
 795 SetChangeParms
 796 =============
 797 */
 798 void SetChangeParms (void)
 799 {
 800         // save parms for level change
 801         parm1 = self.parm_idlesince - time;
 802 }
 803
 804 /*
 805 =============
 806 DecodeLevelParms
 807 =============
 808 */
 809 void DecodeLevelParms (void)
 810 {
 811         // load parms
 812         self.parm_idlesince = parm1;
 813         if(self.parm_idlesince == -(86400 * 366))
 814                 self.parm_idlesince = time;
 815 }
 816
 817 /*
 818 =============
 819 ClientKill
 820
 821 Called when a client types 'kill' in the console
 822 =============
 823 */
 824
 825 void ClientKill_Now_TeamChange()
 826 {
 827         if(self.killindicator_teamchange == -1)
 828         {
 829                 self.team = -1;
 830                 JoinBestTeam( self, FALSE, FALSE );
 831         }
 832         else
 833         {
 834                 SV_ChangeTeam(self.killindicator_teamchange - 1);
 835         }
 836 }
 837
 838 void ClientKill_Now()
 839 {
 840         if(self.killindicator_teamchange)
 841                 ClientKill_Now_TeamChange();
 842
 843         // in any case:
 844         Damage(self, self, self, 100000, DEATH_KILL, self.origin, '0 0 0');
 845
 846         if(self.killindicator)
 847         {
 848                 dprint("Cleaned up after a leaked kill indicator.\n");
 849                 remove(self.killindicator);
 850                 self.killindicator = world;
 851         }
 852 }
 853 void KillIndicator_Think()
 854 {
 855         if (!self.owner.modelindex)
 856         {
 857                 self.owner.killindicator = world;
 858                 remove(self);
 859                 return;
 860         }
 861
 862         if(self.cnt <= 0)
 863         {
 864                 self = self.owner;
 865                 ClientKill_Now(); // no oldself needed
 866                 return;
 867         }
 868         else
 869         {
 870                 if(self.cnt <= 10)
 871                         setmodel(self, strcat("models/sprites/", ftos(self.cnt), ".spr32"));
 872                 if(clienttype(self.owner) == CLIENTTYPE_REAL)
 873                 {
 874                         if(self.cnt <= 10)
 875                                 announce(self.owner, strcat("announcer/robotic/", ftos(self.cnt), ".ogg"));
 876                         if(self.owner.killindicator_teamchange)
 877                         {
 878                                 if(self.owner.killindicator_teamchange == -1)
 879                                         centerprint(self.owner, strcat("Changing team in ", ftos(self.cnt), " seconds"));
 880                                 else
 881                                         centerprint(self.owner, strcat("Changing to ", ColoredTeamName(self.owner.killindicator_teamchange), " in ", ftos(self.cnt), " seconds"));
 882                         }
 883                         else
 884                                 centerprint(self.owner, strcat("^1Suicide in ", ftos(self.cnt), " seconds"));
 885                 }
 886                 self.nextthink = time + 1;
 887                 self.cnt -= 1;
 888         }
 889 }
 890
 891 void ClientKill_TeamChange (float targetteam) // 0 = don't change, -1 = auto
 892 {
 893         float killtime;
 894         entity e;
 895         killtime = cvar("g_balance_kill_delay");
 896
 897         self.killindicator_teamchange = targetteam;
 898
 899         if(!self.killindicator)
 900         {
 901                 if(killtime <= 0 || !self.modelindex || self.deadflag != DEAD_NO)
 902                 {
 903                         ClientKill_Now();
 904                 }
 905                 else
 906                 {
 907                         self.killindicator = spawn();
 908                         self.killindicator.owner = self;
 909                         self.killindicator.scale = 0.5;
 910                         setattachment(self.killindicator, self, "");
 911                         setorigin(self.killindicator, '0 0 52');
 912                         self.killindicator.think = KillIndicator_Think;
 913                         self.killindicator.nextthink = time + (self.lip) * 0.05;
 914                         self.killindicator.cnt = ceil(killtime);
 915                         self.killindicator.count = bound(0, ceil(killtime), 10);
 916                         sprint(self, strcat("^1You'll be dead in ", ftos(self.killindicator.cnt), " seconds\n"));
 917
 918                         for(e = world; (e = find(e, classname, "body")) != world; )
 919                         {
 920                                 if(e.enemy != self)
 921                                         continue;
 922                                 e.killindicator = spawn();
 923                                 e.killindicator.owner = e;
 924                                 e.killindicator.scale = 0.5;
 925                                 setattachment(e.killindicator, e, "");
 926                                 setorigin(e.killindicator, '0 0 52');
 927                                 e.killindicator.think = KillIndicator_Think;
 928                                 e.killindicator.nextthink = time + (e.lip) * 0.05;
 929                                 e.killindicator.cnt = ceil(killtime);
 930                         }
 931                         self.lip = 0;
 932                 }
 933         }
 934         if(self.killindicator)
 935         {
 936                 if(targetteam)
 937                         self.killindicator.colormod = TeamColor(targetteam);
 938                 else
 939                         self.killindicator.colormod = '0 0 0';
 940         }
 941 }
 942
 943 void ClientKill (void)
 944 {
 945         ClientKill_TeamChange(0);
 946 }
 947
 948 void DoTeamChange(float destteam)
 949 {
 950         float t, c0;
 951         if(!cvar("teamplay"))
 952         {
 953                 if(destteam >= 0)
 954                         SetPlayerColors(self, destteam);
 955                 return;
 956         }
 957         if(self.classname == "player")
 958         if(destteam == -1)
 959         {
 960                 CheckAllowedTeams(self);
 961                 t = FindSmallestTeam(self, TRUE);
 962                 switch(self.team)
 963                 {
 964                         case COLOR_TEAM1: c0 = c1; break;
 965                         case COLOR_TEAM2: c0 = c2; break;
 966                         case COLOR_TEAM3: c0 = c3; break;
 967                         case COLOR_TEAM4: c0 = c4; break;
 968                         default:          c0 = 999;
 969                 }
 970                 switch(t)
 971                 {
 972                         case 1:
 973                                 if(c0 > c1)
 974                                         destteam = COLOR_TEAM1;
 975                                 break;
 976                         case 2:
 977                                 if(c0 > c2)
 978                                         destteam = COLOR_TEAM2;
 979                                 break;
 980                         case 3:
 981                                 if(c0 > c3)
 982                                         destteam = COLOR_TEAM3;
 983                                 break;
 984                         case 4:
 985                                 if(c0 > c4)
 986                                         destteam = COLOR_TEAM4;
 987                                 break;
 988                 }
 989                 if(destteam == -1)
 990                         return;
 991         }
 992         if(destteam == self.team && !self.killindicator)
 993                 return;
 994         ClientKill_TeamChange(destteam);
 995 }
 996
 997 void FixClientCvars(entity e)
 998 {
 999         // send prediction settings to the client
1000         stuffcmd(e, "\nin_bindmap 0 0\n");
1001         /*
1002          * we no longer need to stuff this. Remove this comment block if you feel
1003          * 2.3 and higher (or was it 2.2.3?) don't need these any more
1004         stuffcmd(e, strcat("cl_gravity ", ftos(cvar("sv_gravity")), "\n"));
1005         stuffcmd(e, strcat("cl_movement_accelerate ", ftos(cvar("sv_accelerate")), "\n"));
1006         stuffcmd(e, strcat("cl_movement_friction ", ftos(cvar("sv_friction")), "\n"));
1007         stuffcmd(e, strcat("cl_movement_maxspeed ", ftos(cvar("sv_maxspeed")), "\n"));
1008         stuffcmd(e, strcat("cl_movement_airaccelerate ", ftos(cvar("sv_airaccelerate")), "\n"));
1009         stuffcmd(e, strcat("cl_movement_maxairspeed ", ftos(cvar("sv_maxairspeed")), "\n"));
1010         stuffcmd(e, strcat("cl_movement_stopspeed ", ftos(cvar("sv_stopspeed")), "\n"));
1011         stuffcmd(e, strcat("cl_movement_jumpvelocity ", ftos(cvar("sv_jumpvelocity")), "\n"));
1012         stuffcmd(e, strcat("cl_movement_stepheight ", ftos(cvar("sv_stepheight")), "\n"));
1013         stuffcmd(e, strcat("set cl_movement_friction_on_land ", ftos(cvar("sv_friction_on_land")), "\n"));
1014         stuffcmd(e, strcat("set cl_movement_airaccel_qw ", ftos(cvar("sv_airaccel_qw")), "\n"));
1015         stuffcmd(e, strcat("set cl_movement_airaccel_sideways_friction ", ftos(cvar("sv_airaccel_sideways_friction")), "\n"));
1016         stuffcmd(e, "cl_movement_edgefriction 1\n");
1017          */
1018 }
1019
1020 /*
1021 =============
1022 ClientConnect
1023
1024 Called when a client connects to the server
1025 =============
1026 */
1027 //void ctf_clientconnect();
1028 string ColoredTeamName(float t);
1029 void DecodeLevelParms (void);
1030 //void dom_player_join_team(entity pl);
1031 void ClientConnect (void)
1032 {
1033         local string s;
1034
1035         if(self.flags & FL_CLIENT)
1036         {
1037                 print("Warning: ClientConnect, but already connected!\n");
1038                 return;
1039         }
1040
1041         if(Ban_IsClientBanned(self))
1042         {
1043                 s = strcat("^1NOTE:^7 banned client ", self.netaddress, " just tried to enter\n");
1044                 dropclient(self);
1045                 bprint(s);
1046                 return;
1047         }
1048
1049         DecodeLevelParms();
1050
1051         self.classname = "player_joining";
1052
1053         self.flags = self.flags | FL_CLIENT;
1054         self.version_nagtime = time + 10 + random() * 10;
1055
1056         if(player_count<0)
1057         {
1058                 dprint("BUG player count is lower than zero, this cannot happen!\n");
1059                 player_count = 0;
1060         }
1061
1062         PlayerScore_Attach(self);
1063
1064         bot_clientconnect();
1065
1066         race_PreSpawnObserver();
1067
1068         //if(g_domination)
1069         //      dom_player_join_team(self);
1070
1071         //JoinBestTeam(self, FALSE, FALSE);
1072
1073         if((cvar("sv_spectate") == 1 && !g_lms) || cvar("g_campaign")) {
1074                 self.classname = "observer";
1075         } else {
1076                 self.classname = "player";
1077                 campaign_bots_may_start = 1;
1078         }
1079
1080         self.playerid = (playerid_last = playerid_last + 1);
1081         if(cvar("sv_eventlog"))
1082         {
1083                 if(clienttype(self) == CLIENTTYPE_REAL)
1084                         s = "player";
1085                 else
1086                         s = "bot";
1087                 GameLogEcho(strcat(":join:", ftos(self.playerid), ":", s, ":", self.netname));
1088                 s = strcat(":team:", ftos(self.playerid), ":");
1089                 s = strcat(s, ftos(self.team));
1090                 GameLogEcho(s);
1091         }
1092         self.netname_previous = strzone(self.netname);
1093
1094         //stuffcmd(self, "set tmpviewsize $viewsize \n");
1095
1096         bprint ("^4",self.netname);
1097         bprint ("^4 connected");
1098
1099         if(g_domination || g_ctf)
1100         {
1101                 bprint(" and joined the ");
1102                 bprint(ColoredTeamName(self.team));
1103         }
1104
1105         bprint("\n");
1106
1107         self.welcomemessage_time = 0;
1108
1109         stuffcmd(self, strcat(clientstuff, "\n"));
1110         stuffcmd(self, strcat("exec maps/", mapname, ".cfg\n"));
1111         stuffcmd(self, "cl_particles_reloadeffects\n");
1112
1113         FixClientCvars(self);
1114
1115         // spawnfunc_waypoint sprites
1116         WaypointSprite_InitClient(self);
1117
1118         // Wazat's grappling hook
1119         SetGrappleHookBindings();
1120
1121         // get autoswitch state from player when he toggles it
1122         stuffcmd(self, "alias autoswitch \"set cl_autoswitch $1 ; cmd autoswitch $1\"\n"); // default.cfg-ed in 2.4.1
1123
1124         // get version info from player
1125         stuffcmd(self, "cmd clientversion $gameversion\n");
1126
1127         // get other cvars from player
1128         GetCvars(0);
1129
1130         // set cvar for team scoreboard
1131         if (teams_matter)
1132         {
1133                 local float t;
1134                 t = cvar("teamplay");
1135                 // we have to stuff the correct teamplay value because if this is a listen server, this changes the teamplay mode of the server itself, which is bad
1136                 stuffcmd(self, strcat("set teamplay ", ftos(t), "\n"));
1137         }
1138         else
1139                 stuffcmd(self, "set teamplay 0\n");
1140
1141         // notify about available teams
1142         if(teamplay)
1143         {
1144                 CheckAllowedTeams(self);
1145                 t = 0; if(c1 >= 0) t |= 1; if(c2 >= 0) t |= 2; if(c3 >= 0) t |= 4; if(c4 >= 0) t |= 8;
1146                 stuffcmd(self, strcat("set _teams_available ", ftos(t), "\n"));
1147         }
1148         else
1149                 stuffcmd(self, "set _teams_available 0\n");
1150
1151         stuffcmd(self, strcat("set gametype ", ftos(game), "\n"));
1152
1153         if(g_arena)
1154         {
1155                 self.classname = "observer";
1156                 Spawnqueue_Insert(self);
1157         }
1158         /*else if(g_ctf)
1159         {
1160                 ctf_clientconnect();
1161         }*/
1162
1163         if(entcs_start)
1164                 attach_entcs();
1165
1166         bot_relinkplayerlist();
1167
1168         self.spectatortime = time;
1169         if(blockSpectators)
1170         {
1171                 sprint(self, strcat("^7You have to become a player within the next ", ftos(cvar("g_maxplayers_spectator_blocktime")), " seconds, otherwise you will be kicked, because spectators aren't allowed at this time!\n"));
1172         }
1173
1174         self.jointime = time;
1175         self.allowedTimeouts = cvar("sv_timeout_number");
1176
1177         if(clienttype(self) == CLIENTTYPE_REAL)
1178         {
1179                 sprint(self, strcat("nexuiz-csqc protocol ", ftos(CSQC_REVISION), "\n"));
1180                 SendCSQCInfo();
1181                 msg_entity = self;
1182                 if(mapvote_initialized && !cvar("g_maplist_textonly"))
1183                 {
1184                         MapVote_SendData(MSG_ONE);
1185                         MapVote_UpdateData(MSG_ONE);
1186                 }
1187                 ScoreInfo_Write(MSG_ONE);
1188         }
1189
1190         if(g_lms)
1191         {
1192                 if(PlayerScore_Add(self, SP_LMS_LIVES, LMS_NewPlayerLives()) <= 0)
1193                 {
1194                         PlayerScore_Add(self, SP_LMS_RANK, 666);
1195                         self.frags = -666; // FIXME do we still need this?
1196                 }
1197         }
1198 }
1199
1200 /*
1201 =============
1202 ClientDisconnect
1203
1204 Called when a client disconnects from the server
1205 =============
1206 */
1207 void(entity e) DropFlag;
1208 .entity chatbubbleentity;
1209 .entity teambubbleentity;
1210 void ReadyCount();
1211 //void() ctf_clientdisconnect;
1212 void ClientDisconnect (void)
1213 {
1214         float save;
1215
1216         if not(self.flags & FL_CLIENT)
1217         {
1218                 print("Warning: ClientDisconnect without ClientConnect\n");
1219                 return;
1220         }
1221
1222         bot_clientdisconnect();
1223
1224         if(entcs_start)
1225                 detach_entcs();
1226
1227         if(cvar("sv_eventlog"))
1228                 GameLogEcho(strcat(":part:", ftos(self.playerid)));
1229         bprint ("^4",self.netname);
1230         bprint ("^4 disconnected\n");
1231
1232         if (self.chatbubbleentity)
1233         {
1234                 remove (self.chatbubbleentity);
1235                 self.chatbubbleentity = world;
1236         }
1237
1238         if (self.teambubbleentity)
1239         {
1240                 remove (self.teambubbleentity);
1241                 self.teambubbleentity = world;
1242         }
1243
1244         if (self.killindicator)
1245         {
1246                 remove (self.killindicator);
1247                 self.killindicator = world;
1248         }
1249
1250         WaypointSprite_PlayerGone();
1251
1252         DropAllRunes(self);
1253         kh_Key_DropAll(self, TRUE);
1254
1255         if(self.flagcarried)
1256                 DropFlag(self.flagcarried);
1257
1258         save = self.flags;
1259         self.flags = self.flags - (self.flags & FL_CLIENT);
1260         bot_relinkplayerlist();
1261         self.flags = save;
1262
1263         // remove laserdot
1264         if(self.weaponentity)
1265                 if(self.weaponentity.lasertarget)
1266                         remove(self.weaponentity.lasertarget);
1267
1268         if(g_arena)
1269         {
1270                 Spawnqueue_Unmark(self);
1271                 Spawnqueue_Remove(self);
1272         }
1273         /*if(g_ctf)
1274         {
1275                 ctf_clientdisconnect();
1276         }
1277         */
1278
1279         PlayerScore_Detach(self);
1280
1281         if(self.netname_previous)
1282                 strunzone(self.netname_previous);
1283
1284         ClearPlayerSounds();
1285
1286         // free cvars
1287         GetCvars(-1);
1288         self.playerid = 0;
1289
1290         ReadyCount();
1291 }
1292
1293 .float BUTTON_CHAT;
1294 void ChatBubbleThink()
1295 {
1296         self.nextthink = time;
1297         if (!self.owner.modelindex || self.owner.chatbubbleentity != self)
1298         {
1299                 self.owner.chatbubbleentity = world;
1300                 remove(self);
1301                 return;
1302         }
1303         setorigin(self, self.owner.origin + '0 0 15' + self.owner.maxs_z * '0 0 1');
1304         if (self.owner.BUTTON_CHAT && !self.owner.deadflag)
1305                 self.model = self.mdl;
1306         else
1307                 self.model = "";
1308 };
1309
1310 void UpdateChatBubble()
1311 {
1312         if (!self.modelindex)
1313                 return;
1314         // spawn a chatbubble entity if needed
1315         if (!self.chatbubbleentity)
1316         {
1317                 self.chatbubbleentity = spawn();
1318                 self.chatbubbleentity.owner = self;
1319                 self.chatbubbleentity.exteriormodeltoclient = self;
1320                 self.chatbubbleentity.think = ChatBubbleThink;
1321                 self.chatbubbleentity.nextthink = time;
1322                 setmodel(self.chatbubbleentity, "models/misc/chatbubble.spr"); // precision set below
1323                 setorigin(self.chatbubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1324                 self.chatbubbleentity.mdl = self.chatbubbleentity.model;
1325                 self.chatbubbleentity.model = "";
1326                 self.chatbubbleentity.effects = EF_LOWPRECISION;
1327         }
1328 }
1329
1330
1331 void TeamBubbleThink()
1332 {
1333         self.nextthink = time;
1334         if (!self.owner.modelindex || self.owner.teambubbleentity != self)
1335         {
1336                 self.owner.teambubbleentity = world;
1337                 remove(self);
1338                 return;
1339         }
1340 //      setorigin(self, self.owner.origin + '0 0 15' + self.owner.maxs_z * '0 0 1');  // bandwidth hog. setattachment does this now
1341         if (self.owner.BUTTON_CHAT || self.owner.deadflag || self.owner.killindicator)
1342                 self.model = "";
1343         else
1344                 self.model = self.mdl;
1345
1346 };
1347
1348 float TeamBubble_customizeentityforclient()
1349 {
1350         return (self.owner != other && self.owner.team == other.team && other.killcount > -666);
1351 }
1352
1353 void UpdateTeamBubble()
1354 {
1355         if (!self.modelindex || !cvar("teamplay"))
1356                 return;
1357         // spawn a teambubble entity if needed
1358         if (!self.teambubbleentity && cvar("teamplay"))
1359         {
1360                 self.teambubbleentity = spawn();
1361                 self.teambubbleentity.owner = self;
1362                 self.teambubbleentity.exteriormodeltoclient = self;
1363                 self.teambubbleentity.think = TeamBubbleThink;
1364                 self.teambubbleentity.nextthink = time;
1365                 setmodel(self.teambubbleentity, "models/misc/teambubble.spr"); // precision set below
1366 //              setorigin(self.teambubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1367                 setorigin(self.teambubbleentity, self.teambubbleentity.origin + '0 0 15' + self.maxs_z * '0 0 1');
1368                 setattachment(self.teambubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1369                 self.teambubbleentity.mdl = self.teambubbleentity.model;
1370                 self.teambubbleentity.model = self.teambubbleentity.mdl;
1371                 self.teambubbleentity.customizeentityforclient = TeamBubble_customizeentityforclient;
1372                 self.teambubbleentity.effects = EF_LOWPRECISION;
1373         }
1374 }
1375
1376 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1377 // added to the model skins
1378 /*void UpdateColorModHack()
1379 {
1380         local float c;
1381         c = self.clientcolors & 15;
1382         // LordHavoc: only bothering to support white, green, red, yellow, blue
1383              if (teamplay == 0) self.colormod = '0 0 0';
1384         else if (c ==  0) self.colormod = '1.00 1.00 1.00';
1385         else if (c ==  3) self.colormod = '0.10 1.73 0.10';
1386         else if (c ==  4) self.colormod = '1.73 0.10 0.10';
1387         else if (c == 12) self.colormod = '1.22 1.22 0.10';
1388         else if (c == 13) self.colormod = '0.10 0.10 1.73';
1389         else self.colormod = '1 1 1';
1390 };*/
1391
1392 void respawn(void)
1393 {
1394         CopyBody(1);
1395         self.effects |= EF_NODRAW; // prevent another CopyBody
1396         PutClientInServer();
1397 }
1398
1399 /**
1400  * When sv_timeout is used this function returs strings like
1401  * "Timeout begins in 2 seconds!\n" or "Timeout ends in 23 seconds!\n".
1402  * Called by centerprint functions
1403  * @param addOneSecond boolean, set to 1 if the welcome-message centerprint asks for the text
1404  */
1405 string getTimeoutText(float addOneSecond) {
1406         if (!cvar("sv_timeout") || !timeoutStatus)
1407                 return "";
1408
1409         local string retStr;
1410         if (timeoutStatus == 1) {
1411                 if (addOneSecond == 1) {
1412                         retStr = strcat("Timeout begins in ", ftos(remainingLeadTime + 1), " seconds!\n");
1413                 }
1414                 else {
1415                         retStr = strcat("Timeout begins in ", ftos(remainingLeadTime), " seconds!\n");
1416                 }
1417                 return retStr;
1418         }
1419         else if (timeoutStatus == 2) {
1420                 if (addOneSecond) {
1421                         retStr = strcat("Timeout ends in ", ftos(remainingTimeoutTime + 1), " seconds!\n");
1422                         //don't show messages like "Timeout ends in 0 seconds"...
1423                         if ((remainingTimeoutTime + 1) > 0)
1424                                 return retStr;
1425                         else
1426                                 return "";
1427                 }
1428                 else {
1429                         retStr = strcat("Timeout ends in ", ftos(remainingTimeoutTime), " seconds!\n");
1430                         //don't show messages like "Timeout ends in 0 seconds"...
1431                         if (remainingTimeoutTime > 0)
1432                                 return retStr;
1433                         else
1434                                 return "";
1435                 }
1436         }
1437         else return "";
1438 }
1439
1440 void player_powerups (void)
1441 {
1442         if (g_minstagib)
1443         {
1444                 if (self.items & IT_STRENGTH)
1445                 {
1446                         if (time > self.strength_finished)
1447                         {
1448                                 if (g_minstagib_invis_alpha > 0)
1449                                 {
1450                                         self.alpha = default_player_alpha;
1451                                         self.exteriorweaponentity.alpha = default_weapon_alpha;
1452                                         self.effects = self.effects | EF_FULLBRIGHT;
1453                                 }
1454                                 else
1455                                 {
1456                                         self.effects -= self.effects & EF_NODRAW;
1457                                 }
1458                                 self.items = self.items - (self.items & IT_STRENGTH);
1459                                 sprint(self, "^3Invisibility has worn off\n");
1460                         }
1461                 }
1462                 else
1463                 {
1464                         if (time < self.strength_finished)
1465                         {
1466                                 if (g_minstagib_invis_alpha > 0)
1467                                 {
1468                                         self.alpha = g_minstagib_invis_alpha;
1469                                         self.exteriorweaponentity.alpha = g_minstagib_invis_alpha;
1470                                         self.effects -= self.effects & EF_FULLBRIGHT;
1471                                 }
1472                                 else
1473                                 {
1474                                         self.effects = self.effects | EF_NODRAW;
1475                                 }
1476                                 self.items = self.items | IT_STRENGTH;
1477                                 sprint(self, "^3You are invisible\n");
1478                         }
1479                 }
1480
1481                 if (self.items & IT_INVINCIBLE)
1482                 {
1483                         if (time > self.invincible_finished)
1484                         {
1485                                 self.items = self.items - (self.items & IT_INVINCIBLE);
1486                                 sprint(self, "^3Speed has worn off\n");
1487                         }
1488                 }
1489                 else
1490                 {
1491                         if (time < self.invincible_finished)
1492                         {
1493                                 self.items = self.items | IT_INVINCIBLE;
1494                                 sprint(self, "^3You are on speed\n");
1495                         }
1496                 }
1497                 return;
1498         }
1499
1500         self.effects = self.effects - (self.effects & (EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT));
1501         if (self.items & IT_STRENGTH)
1502         {
1503                 self.effects = self.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1504                 if (time > self.strength_finished)
1505                 {
1506                         self.items = self.items - (self.items & IT_STRENGTH);
1507                         sprint(self, "^3Strength has worn off\n");
1508                 }
1509         }
1510         else
1511         {
1512                 if (time < self.strength_finished)
1513                 {
1514                         self.items = self.items | IT_STRENGTH;
1515                         sprint(self, "^3Strength infuses your weapons with devastating power\n");
1516                 }
1517         }
1518         if (self.items & IT_INVINCIBLE)
1519         {
1520                 self.effects = self.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1521                 if (time > self.invincible_finished)
1522                 {
1523                         self.items = self.items - (self.items & IT_INVINCIBLE);
1524                         sprint(self, "^3Shield has worn off\n");
1525                 }
1526         }
1527         else
1528         {
1529                 if (time < self.invincible_finished)
1530                 {
1531                         self.items = self.items | IT_INVINCIBLE;
1532                         sprint(self, "^3Shield surrounds you\n");
1533                 }
1534         }
1535
1536         if (cvar("g_fullbrightplayers"))
1537                 self.effects = self.effects | EF_FULLBRIGHT;
1538
1539         // midair gamemode: damage only while in the air
1540         // if in midair mode, being on ground grants temporary invulnerability
1541         // (this is so that multishot weapon don't clear the ground flag on the
1542         // first damage in the frame, leaving the player vulnerable to the
1543         // remaining hits in the same frame)
1544         if (self.flags & FL_ONGROUND)
1545         if (g_midair)
1546                 self.spawnshieldtime = max(self.spawnshieldtime, time + cvar("g_midair_shieldtime"));
1547
1548         if (time > restart_countdown)
1549         if (time < self.spawnshieldtime)
1550                 self.effects = self.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1551 }
1552
1553 float CalcRegen(float current, float stable, float regenfactor)
1554 {
1555         if(current > stable)
1556                 return current;
1557         else if(current > stable - 0.25) // when close enough, "snap"
1558                 return stable;
1559         else
1560                 return min(stable, current + (stable - current) * regenfactor * frametime);
1561 }
1562
1563 void player_regen (void)
1564 {
1565         float maxh, maxa, limith, limita, max_mod, regen_mod, rot_mod, limit_mod;
1566         maxh = cvar("g_balance_health_stable");
1567         maxa = cvar("g_balance_armor_stable");
1568         limith = cvar("g_balance_health_limit");
1569         limita = cvar("g_balance_armor_limit");
1570
1571         if (g_minstagib || (g_lms && !cvar("g_lms_regenerate")))
1572                 return;
1573
1574         max_mod = regen_mod = rot_mod = limit_mod = 1;
1575
1576         if (self.runes & RUNE_REGEN)
1577         {
1578                 if (self.runes & CURSE_VENOM) // do we have both rune/curse?
1579                 {
1580                         regen_mod = cvar("g_balance_rune_regen_combo_regenrate");
1581                         max_mod = cvar("g_balance_rune_regen_combo_hpmod");
1582                         limit_mod = cvar("g_balance_rune_regen_combo_limitmod");
1583                 }
1584                 else
1585                 {
1586                         regen_mod = cvar("g_balance_rune_regen_regenrate");
1587                         max_mod = cvar("g_balance_rune_regen_hpmod");
1588                         limit_mod = cvar("g_balance_rune_regen_limitmod");
1589                 }
1590         }
1591         else if (self.runes & CURSE_VENOM)
1592         {
1593                 max_mod = cvar("g_balance_curse_venom_hpmod");
1594                 if (self.runes & RUNE_REGEN) // do we have both rune/curse?
1595                         rot_mod = cvar("g_balance_rune_regen_combo_rotrate");
1596                 else
1597                         rot_mod = cvar("g_balance_curse_venom_rotrate");
1598                 limit_mod = cvar("g_balance_curse_venom_limitmod");
1599                 //if (!self.runes & RUNE_REGEN)
1600                 //      rot_mod = cvar("g_balance_curse_venom_rotrate");
1601         }
1602         maxh = maxh * max_mod;
1603         //maxa = maxa * max_mod;
1604         limith = limith * limit_mod;
1605         limita = limita * limit_mod;
1606
1607         if (self.armorvalue > maxa)
1608         {
1609                 if (time > self.pauserotarmor_finished)
1610                 {
1611                         self.armorvalue = max(maxa, self.armorvalue + (maxa - self.armorvalue) * cvar("g_balance_armor_rot") * frametime);
1612                         self.armorvalue = max(maxa, self.armorvalue - cvar("g_balance_armor_rotlinear") * frametime);
1613                 }
1614         }
1615         else if (self.armorvalue < maxa)
1616         {
1617                 if (time > self.pauseregen_finished)
1618                 {
1619                         self.armorvalue = CalcRegen(self.armorvalue, maxa, cvar("g_balance_armor_regen"));
1620                         self.armorvalue = min(maxa, self.armorvalue + cvar("g_balance_armor_regenlinear") * frametime);
1621                 }
1622         }
1623         if (self.health > maxh)
1624         {
1625                 if (time > self.pauserothealth_finished)
1626                 {
1627                         self.health = max(maxh, self.health + (maxh - self.health) * rot_mod*cvar("g_balance_health_rot") * frametime);
1628                         self.health = max(maxh, self.health - rot_mod*cvar("g_balance_health_rotlinear") * frametime);
1629                 }
1630         }
1631         else if (self.health < maxh)
1632         {
1633                 if (time > self.pauseregen_finished)
1634                 {
1635                         self.health = CalcRegen(self.health, maxh, regen_mod * cvar("g_balance_health_regen"));
1636                         self.health = min(maxh, self.health + regen_mod*cvar("g_balance_health_regenlinear") * frametime);
1637                 }
1638         }
1639
1640         if (self.health > limith)
1641                 self.health = limith;
1642         if (self.armorvalue > limita)
1643                 self.armorvalue = limita;
1644
1645         // if player rotted to death...  die!
1646         if(self.health < 1)
1647                 self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
1648 }
1649
1650 .float zoomstate;
1651 float zoomstate_set;
1652 void SetZoomState(float z)
1653 {
1654         if(z != self.zoomstate)
1655         {
1656                 msg_entity = self;
1657                 WriteByte(MSG_ONE, SVC_TEMPENTITY);
1658                 WriteByte(MSG_ONE, TE_CSQC_ZOOMNOTIFY);
1659                 WriteByte(MSG_ONE, z);
1660                 self.zoomstate = z;
1661         }
1662         zoomstate_set = 1;
1663 }
1664
1665 /*
1666 ======================
1667 spectate mode routines
1668 ======================
1669 */
1670 void SpectateCopy(entity spectatee) {
1671         self.armortype = spectatee.armortype;
1672         self.armorvalue = spectatee.armorvalue;
1673         self.currentammo = spectatee.currentammo;
1674         self.effects = spectatee.effects;
1675         self.health = spectatee.health;
1676         self.impulse = 0;
1677         self.items = spectatee.items;
1678         self.weapons = spectatee.weapons;
1679         self.punchangle = spectatee.punchangle;
1680         self.view_ofs = spectatee.view_ofs;
1681         self.v_angle = spectatee.v_angle;
1682         self.velocity = spectatee.velocity;
1683         self.dmg_take = spectatee.dmg_take;
1684         self.dmg_save = spectatee.dmg_save;
1685         self.dmg_inflictor = spectatee.dmg_inflictor;
1686         self.angles = spectatee.v_angle;
1687         self.fixangle = TRUE;
1688         setorigin(self, spectatee.origin);
1689         setsize(self, spectatee.mins, spectatee.maxs);
1690         SetZoomState(spectatee.zoomstate);
1691 }
1692
1693 float SpectateUpdate() {
1694         if(!self.enemy)
1695                 return 0;
1696
1697         if (self == self.enemy)
1698                 return 0;
1699
1700         if(self.enemy.flags & FL_NOTARGET)
1701                 return 0;
1702
1703         SpectateCopy(self.enemy);
1704
1705         return 1;
1706 }
1707
1708 float SpectateNext() {
1709         other = find(self.enemy, classname, "player");
1710         if (!other) {
1711                 other = find(other, classname, "player");
1712         }
1713         if (other) {
1714                 self.enemy = other;
1715         }
1716         if(self.enemy.classname == "player") {
1717                 msg_entity = self;
1718                 WriteByte(MSG_ONE, SVC_SETVIEW);
1719                 WriteEntity(MSG_ONE, self.enemy);
1720                 self.wantswelcomemessage = 1;
1721                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
1722                 if(!SpectateUpdate())
1723                         PutObserverInServer();
1724                 return 1;
1725         } else {
1726                 return 0;
1727         }
1728 }
1729
1730 /*
1731 =============
1732 ShowRespawnCountdown()
1733
1734 Update a respawn countdown display.
1735 =============
1736 */
1737 void ShowRespawnCountdown()
1738 {
1739         float number;
1740         if(self.deadflag == DEAD_NO) // just respawned?
1741                 return;
1742         else
1743         {
1744                 number = ceil(self.death_time - time);
1745                 if(number <= 0)
1746                         return;
1747                 if(number <= self.respawn_countdown)
1748                 {
1749                         self.respawn_countdown = number - 1;
1750                         if(ceil(self.death_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
1751                                 announce(self, strcat("announcer/robotic/", ftos(number), ".ogg"));
1752                 }
1753         }
1754 }
1755
1756 void LeaveSpectatorMode()
1757 {
1758         if(isJoinAllowed()) {
1759                 if(!cvar("teamplay") || cvar("g_campaign") || cvar("g_balance_teams")) {
1760                         self.classname = "player";
1761                         if(cvar("g_campaign") || cvar("g_balance_teams") || cvar("g_balance_teams_force"))
1762                                 JoinBestTeam(self, FALSE, TRUE);
1763                         if(cvar("g_campaign"))
1764                                 campaign_bots_may_start = 1;
1765                         PutClientInServer();
1766                         if(!(self.flags & FL_NOTARGET))
1767                                 bprint ("^4", self.netname, "^4 is playing now\n");
1768                         centerprint(self,"");
1769                         return;
1770                 } else {
1771                         stuffcmd(self,"menu_showteamselect\n");
1772                         return;
1773                 }
1774         }
1775         else {
1776                 //player may not join because of g_maxplayers is set
1777                 centerprint_atprio(self, CENTERPRIO_MAPVOTE, PREVENT_JOIN_TEXT);
1778         }
1779 }
1780
1781 /**
1782  * Determines whether the player is allowed to join. This depends on cvar
1783  * g_maxplayers, if it isn't used this function always return TRUE, otherwise
1784  * it checks whether the number of currently playing players exceeds g_maxplayers.
1785  * @return bool TRUE if the player is allowed to join, false otherwise
1786  */
1787 float isJoinAllowed() {
1788         if (!cvar("g_maxplayers"))
1789                 return TRUE;
1790
1791         local entity e;
1792         local float currentlyPlaying;
1793         FOR_EACH_REALPLAYER(e) {
1794                 if(e.classname == "player")
1795                         currentlyPlaying += 1;
1796         }
1797         if(currentlyPlaying < cvar("g_maxplayers"))
1798                 return TRUE;
1799
1800         return FALSE;
1801 }
1802
1803 /**
1804  * Checks whether the client is an observer or spectator, if so, he will get kicked after
1805  * g_maxplayers_spectator_blocktime seconds
1806  */
1807 void checkSpectatorBlock() {
1808         if(self.classname == "spectator" || self.classname == "observer") {
1809                 if( time > (self.spectatortime + cvar("g_maxplayers_spectator_blocktime")) ) {
1810                         sprint(self, "^7You were kicked from the server because you are spectator and spectators aren't allowed at the moment.\n");
1811                         dropclient(self);
1812                 }
1813         }
1814 }
1815
1816 float vercmp_recursive(string v1, string v2)
1817 {
1818         float dot1, dot2;
1819         string s1, s2;
1820         float r;
1821
1822         dot1 = strstrofs(v1, ".", 0);
1823         dot2 = strstrofs(v2, ".", 0);
1824         if(dot1 == -1)
1825                 s1 = v1;
1826         else
1827                 s1 = substring(v1, 0, dot1);
1828         if(dot2 == -1)
1829                 s2 = v2;
1830         else
1831                 s2 = substring(v2, 0, dot2);
1832
1833         r = stof(s1) - stof(s2);
1834         if(r != 0)
1835                 return r;
1836
1837         r = strcasecmp(s1, s2);
1838         if(r != 0)
1839                 return r;
1840
1841         if(dot1 == -1)
1842                 if(dot2 == -1)
1843                         return 0;
1844                 else
1845                         return -1;
1846         else
1847                 if(dot2 == -1)
1848                         return 1;
1849                 else
1850                         return vercmp_recursive(substring(v1, dot1 + 1, 999), substring(v2, dot2 + 1, 999));
1851 }
1852
1853 float vercmp(string v1, string v2)
1854 {
1855         if(strcasecmp(v1, v2) == 0) // early out check
1856                 return 0;
1857         return vercmp_recursive(v1, v2);
1858 }
1859
1860 void ObserverThink()
1861 {
1862         if (self.flags & FL_JUMPRELEASED) {
1863                 if (self.BUTTON_JUMP && !self.version_mismatch) {
1864                         self.welcomemessage_time = 0;
1865                         self.flags = self.flags - FL_JUMPRELEASED;
1866                         LeaveSpectatorMode();
1867                         return;
1868                 } else if(self.BUTTON_ATCK && !self.version_mismatch) {
1869                         self.welcomemessage_time = 0;
1870                         self.flags = self.flags - FL_JUMPRELEASED;
1871                         if(SpectateNext() == 1) {
1872                                 self.classname = "spectator";
1873                         }
1874                 }
1875         } else {
1876                 if (!(self.BUTTON_ATCK || self.BUTTON_JUMP)) {
1877                         self.flags = self.flags | FL_JUMPRELEASED;
1878                 }
1879         }
1880         if(self.BUTTON_ZOOM)
1881                 self.wantswelcomemessage = 0;
1882         if(self.wantswelcomemessage)
1883                 PrintWelcomeMessage(self);
1884 }
1885
1886 void SpectatorThink()
1887 {
1888         if (self.flags & FL_JUMPRELEASED) {
1889                 if (self.BUTTON_JUMP && !self.version_mismatch) {
1890                         self.welcomemessage_time = 0;
1891                         self.flags = self.flags - FL_JUMPRELEASED;
1892                         LeaveSpectatorMode();
1893                         return;
1894                 } else if(self.BUTTON_ATCK) {
1895                         self.welcomemessage_time = 0;
1896                         self.flags = self.flags - FL_JUMPRELEASED;
1897                         if(SpectateNext() == 1) {
1898                                 self.classname = "spectator";
1899                         } else {
1900                                 self.classname = "observer";
1901                                 PutClientInServer();
1902                         }
1903                 } else if (self.BUTTON_ATCK2) {
1904                         self.welcomemessage_time = 0;
1905                         self.flags = self.flags - FL_JUMPRELEASED;
1906                         self.classname = "observer";
1907                         PutClientInServer();
1908                 } else {
1909                         if(!SpectateUpdate())
1910                                 PutObserverInServer();
1911                 }
1912         } else {
1913                 if (!(self.BUTTON_ATCK || self.BUTTON_ATCK2)) {
1914                         self.flags = self.flags | FL_JUMPRELEASED;
1915                 }
1916         }
1917         if(self.BUTTON_ZOOM)
1918                 self.wantswelcomemessage = 0;
1919         if(self.wantswelcomemessage)
1920                 PrintWelcomeMessage(self);
1921         self.flags = self.flags | FL_CLIENT | FL_NOTARGET;
1922 }
1923
1924 /*
1925 =============
1926 PlayerPreThink
1927
1928 Called every frame for each client before the physics are run
1929 =============
1930 */
1931 void() ctf_setstatus;
1932 .float vote_nagtime;
1933 .float spectatee_status;
1934 void PlayerPreThink (void)
1935 {
1936         self.stat_sys_ticrate = cvar("sys_ticrate");
1937         if(blockSpectators)
1938                 checkSpectatorBlock();
1939
1940         zoomstate_set = 0;
1941
1942         if(self.netname_previous != self.netname)
1943         {
1944                 if(cvar("sv_eventlog"))
1945                         GameLogEcho(strcat(":name:", ftos(self.playerid), ":", self.netname));
1946                 if(self.netname_previous)
1947                         strunzone(self.netname_previous);
1948                 self.netname_previous = strzone(self.netname);
1949         }
1950
1951         // version nagging
1952         if(self.version_nagtime)
1953                 if(self.cvar_g_nexuizversion)
1954                         if(time > self.version_nagtime)
1955                         {
1956                                 if(strstr(self.cvar_g_nexuizversion, "svn", 0) < 0)
1957                                 {
1958                                         if(strstr(cvar_string("g_nexuizversion"), "svn", 0) >= 0)
1959                                         {
1960                                                 dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Nexuiz ", cvar_string("g_nexuizversion"), " (beta)^7, you have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1\n");
1961                                                 sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Nexuiz ", cvar_string("g_nexuizversion"), " (beta)^7, you have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1\n"));
1962                                         }
1963                                         else
1964                                         {
1965                                                 float r;
1966                                                 r = vercmp(self.cvar_g_nexuizversion, cvar_string("g_nexuizversion"));
1967                                                 if(r < 0)
1968                                                 {
1969                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - ^3Nexuiz ", cvar_string("g_nexuizversion"), "^7 is out, and you still have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1 - get the update from ^4http://www.nexuiz.com/^1!\n");
1970                                                         sprint(self, strcat("\{1}^1NOTE: ^3Nexuiz ", cvar_string("g_nexuizversion"), "^7 is out, and you still have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1 - get the update from ^4http://www.nexuiz.com/^1!\n"));
1971                                                 }
1972                                                 else if(r > 0)
1973                                                 {
1974                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Nexuiz ", cvar_string("g_nexuizversion"), "^7, you have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1\n");
1975                                                         sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Nexuiz ", cvar_string("g_nexuizversion"), "^7, you have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1\n"));
1976                                                 }
1977                                         }
1978                                 }
1979                                 self.version_nagtime = 0;
1980                         }
1981
1982         // vote nagging
1983         if(self.cvar_scr_centertime)
1984                 if(time > self.vote_nagtime)
1985                 {
1986                         VoteNag();
1987                         self.vote_nagtime = time + self.cvar_scr_centertime * 0.6;
1988                 }
1989
1990         // GOD MODE info
1991         if(!(self.flags & FL_GODMODE)) if(self.max_armorvalue)
1992         {
1993                 sprint(self, strcat("godmode saved you ", ftos(self.max_armorvalue), " units of damage, cheater!\n"));
1994                 self.max_armorvalue = 0;
1995         }
1996
1997         if(frametime)
1998                 antilag_record(self);
1999
2000         if(self.classname == "player") {
2001 //              if(self.netname == "Wazat")
2002 //                      bprint(self.classname, "\n");
2003
2004                 CheckRules_Player();
2005
2006                 if(self.BUTTON_INFO)
2007                         PrintWelcomeMessage(self);
2008
2009                 if(g_lms || !cvar("sv_spectate"))
2010                 if((time - self.jointime) <= cvar("welcome_message_time"))
2011                         PrintWelcomeMessage(self);
2012
2013                 if (intermission_running)
2014                 {
2015                         IntermissionThink ();   // otherwise a button could be missed between
2016                         return;                                 // the think tics
2017                 }
2018
2019                 if(self.teleport_time)
2020                 if(time > self.teleport_time)
2021                 {
2022                         self.teleport_time = 0;
2023                         self.effects = self.effects - (self.effects & EF_NODRAW);
2024                         if(self.weaponentity)
2025                                 self.weaponentity.flags = self.weaponentity.flags - (self.weaponentity.flags & EF_NODRAW);
2026                 }
2027
2028                 Nixnex_GiveCurrentWeapon();
2029
2030                 if(frametime > 0) // don't do this in cl_movement frames, just in server ticks
2031                         UpdateSelectedPlayer();
2032
2033                 //don't allow the player to turn around while game is paused!
2034                 if(timeoutStatus == 2) {
2035                         self.v_angle = self.lastV_angle;
2036                         self.angles = self.lastV_angle;
2037                         self.fixangle = TRUE;
2038                 }
2039
2040                 if (self.deadflag != DEAD_NO)
2041                 {
2042                         float button_pressed, force_respawn;
2043                         player_anim();
2044                         button_pressed = (self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE);
2045                         force_respawn = (g_lms || cvar("g_forced_respawn"));
2046                         if (self.deadflag == DEAD_DYING)
2047                         {
2048                                 if(force_respawn)
2049                                         self.deadflag = DEAD_RESPAWNING;
2050                                 else if(!button_pressed)
2051                                         self.deadflag = DEAD_DEAD;
2052                         }
2053                         else if (self.deadflag == DEAD_DEAD)
2054                         {
2055                                 if(button_pressed)
2056                                         self.deadflag = DEAD_RESPAWNABLE;
2057                         }
2058                         else if (self.deadflag == DEAD_RESPAWNABLE)
2059                         {
2060                                 if(!button_pressed)
2061                                         self.deadflag = DEAD_RESPAWNING;
2062                         }
2063                         else if (self.deadflag == DEAD_RESPAWNING)
2064                         {
2065                                 if(time > self.death_time)
2066                                 {
2067                                         self.death_time = time + 1; // only retry once a second
2068                                         respawn();
2069                                 }
2070                         }
2071                         ShowRespawnCountdown();
2072                         return;
2073                 }
2074
2075                 if(g_lms && !self.deadflag && cvar("g_lms_campcheck_interval"))
2076                 {
2077                         vector dist;
2078
2079                         // calculate player movement (in 2 dimensions only, so jumping on one spot doesn't count as movement)
2080                         dist = self.oldorigin - self.origin;
2081                         dist_z = 0;
2082                         self.lms_traveled_distance += fabs(vlen(dist));
2083
2084                         if((cvar("g_campaign") && !campaign_bots_may_start) || (time < restart_countdown))
2085                         {
2086                                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval")*2;
2087                                 self.lms_traveled_distance = 0;
2088                         }
2089
2090                         if(time > self.lms_nextcheck)
2091                         {
2092                                 //sprint(self, "distance: ", ftos(self.lms_traveled_distance), "\n");
2093                                 if(self.lms_traveled_distance < cvar("g_lms_campcheck_distance"))
2094                                 {
2095                                         centerprint(self, cvar_string("g_lms_campcheck_message"));
2096                                         // FIXME KadaverJack: gibbing player here causes playermodel to bounce around, instead of eye.md3
2097                                         // I wasn't able to find out WHY that happens, so I put a workaround in place that shall prevent players from being gibbed :(
2098                                         Damage(self, self, self, bound(0, cvar("g_lms_campcheck_damage"), self.health + self.armorvalue * cvar("g_balance_armor_blockpercent") + 5), DEATH_CAMP, self.origin, '0 0 0');
2099                                 }
2100                                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval");
2101                                 self.lms_traveled_distance = 0;
2102                         }
2103                 }
2104
2105                 if (self.BUTTON_CROUCH && !self.hook.state)
2106                 {
2107                         if (!self.crouch)
2108                         {
2109                                 self.crouch = TRUE;
2110                                 self.view_ofs = PL_CROUCH_VIEW_OFS;
2111                                 setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX);
2112                                 player_setanim(self.anim_duck, FALSE, TRUE, TRUE);
2113                         }
2114                 }
2115                 else
2116                 {
2117                         if (self.crouch)
2118                         {
2119                                 tracebox(self.origin, PL_MIN, PL_MAX, self.origin, FALSE, self);
2120                                 if (!trace_startsolid)
2121                                 {
2122                                         self.crouch = FALSE;
2123                                         self.view_ofs = PL_VIEW_OFS;
2124                                         setsize (self, PL_MIN, PL_MAX);
2125                                 }
2126                         }
2127                 }
2128
2129                 FixPlayermodel();
2130
2131                 GrapplingHookFrame();
2132
2133                 W_WeaponFrame();
2134
2135                 player_powerups();
2136                 player_regen();
2137                 player_anim();
2138
2139                 if (g_minstagib)
2140                         minstagib_ammocheck();
2141
2142                 ctf_setstatus();
2143                 kh_setstatus();
2144
2145                 //self.angles_y=self.v_angle_y + 90;   // temp
2146
2147                 //if (TetrisPreFrame()) return;
2148         } else if(gameover) {
2149                 if (intermission_running)
2150                         IntermissionThink ();   // otherwise a button could be missed between
2151                 return;
2152         } else if(self.classname == "observer") {
2153                 ObserverThink();
2154         } else if(self.classname == "spectator") {
2155                 SpectatorThink();
2156         }
2157
2158         if(!zoomstate_set)
2159                 SetZoomState(self.BUTTON_ZOOM || (self.BUTTON_ATCK2 && !g_minstagib && self.weapon == WEP_NEX));
2160
2161         float oldspectatee_status;
2162         oldspectatee_status = self.spectatee_status;
2163         if(self.classname == "spectator")
2164                 self.spectatee_status = num_for_edict(self.enemy);
2165         else if(self.classname == "observer")
2166                 self.spectatee_status = num_for_edict(self);
2167         else
2168                 self.spectatee_status = 0;
2169         if(self.spectatee_status != oldspectatee_status)
2170         {
2171                 msg_entity = self;
2172                 WriteByte(MSG_ONE, SVC_TEMPENTITY);
2173                 WriteByte(MSG_ONE, TE_CSQC_SPECTATING);
2174                 WriteByte(MSG_ONE, self.spectatee_status);
2175                 if(g_race)
2176                         race_InitSpectator();
2177         }
2178 }
2179
2180
2181 /*
2182 =============
2183 PlayerPostThink
2184
2185 Called every frame for each client after the physics are run
2186 =============
2187 */
2188 .float idlekick_lasttimeleft;
2189 .float race_penalty;
2190 .float race_penalty_nagged;
2191 void PlayerPostThink (void)
2192 {
2193         // Savage: Check for nameless players
2194         if (strlen(self.netname) < 1) {
2195                 self.netname = "Player";
2196                 stuffcmd(self, "seta _cl_name Player\n");
2197         }
2198
2199         if(sv_maxidle)
2200         {
2201                 float timeleft;
2202                 timeleft = ceil(sv_maxidle - (time - self.parm_idlesince));
2203                 if(timeleft <= 0)
2204                 {
2205                         bprint("^3", self.netname, "^3 was kicked for idling.\n");
2206                         announce(self, "announcer/robotic/terminated.ogg");
2207                         dropclient(self);
2208                         return;
2209                 }
2210                 else if(timeleft <= 10)
2211                 {
2212                         if(timeleft != self.idlekick_lasttimeleft)
2213                         {
2214                                 centerprint_atprio(self, CENTERPRIO_IDLEKICK, strcat("^3Stop idling!\n^3Disconnecting in ", ftos(timeleft), "..."));
2215                                 announce(self, strcat("announcer/robotic/", ftos(timeleft), ".ogg"));
2216                         }
2217                 }
2218                 else
2219                 {
2220                         centerprint_expire(self, CENTERPRIO_IDLEKICK);
2221                 }
2222                 self.idlekick_lasttimeleft = timeleft;
2223         }
2224
2225         if(self.classname == "player") {
2226                 CheckRules_Player();
2227                 UpdateChatBubble();
2228                 UpdateTeamBubble();
2229                 if (self.impulse)
2230                         ImpulseCommands();
2231                 if (intermission_running)
2232                         return;         // intermission or finale
2233
2234                 //PrintWelcomeMessage(self);
2235                 //if (TetrisPostFrame()) return;
2236
2237                 // restart countdown
2238                 if (restart_countdown) {
2239                         if(time < restart_countdown) {
2240                                 if (!cvar("sv_ready_restart_after_countdown"))
2241                                 {
2242                                         if(self.movement != '0 0 0' && g_race && !g_race_qualifying)
2243                                         {
2244                                                 if(time < restart_countdown - 2)
2245                                                 {
2246                                                         if(!self.race_penalty_nagged)
2247                                                         {
2248                                                                 centerprint_atprio(self, CENTERPRIO_IDLEKICK, "^1DO NOT MOVE DURING THE COUNTDOWN.");
2249                                                                 self.race_penalty_nagged = 1;
2250                                                         }
2251                                                 }
2252                                                 else if(!self.race_penalty)
2253                                                 {
2254                                                         centerprint_atprio(self, CENTERPRIO_IDLEKICK, "^1FIVE SECONDS PENALTY.");
2255                                                         self.race_penalty = time + 5;
2256                                                 }
2257                                         }
2258                                         self.movetype = MOVETYPE_NONE;
2259                                         self.velocity = '0 0 0';
2260                                         self.avelocity = '0 0 0';
2261                                         self.movement = '0 0 0';
2262                                 }
2263                         }
2264                         else if (time < self.race_penalty)
2265                         {
2266                                 self.movetype = MOVETYPE_NONE;
2267                                 self.velocity = '0 0 0';
2268                                 self.avelocity = '0 0 0';
2269                                 self.movement = '0 0 0';
2270                         }
2271                         else
2272                         {
2273                                 //allow the player to move again if sv_ready_restart_after_countdown is not used and countdown is over
2274                                 if (!cvar("sv_ready_restart_after_countdown"))
2275                                 {
2276                                         if(self.movetype == MOVETYPE_NONE)
2277                                         {
2278                                                 self.movetype = MOVETYPE_WALK;
2279                                         }
2280                                         self.race_penalty = 0;
2281                                         self.race_penalty_nagged = 0;
2282                                 }
2283                         }
2284                 }
2285
2286         } else if (self.classname == "observer") {
2287                 //do nothing
2288         } else if (self.classname == "spectator") {
2289                 //do nothing
2290         }
2291
2292         /*
2293         float i;
2294         for(i = 0; i < 1000; ++i)
2295         {
2296                 vector end;
2297                 end = self.origin + '0 0 1024' + 512 * randomvec();
2298                 tracebox(self.origin, self.mins, self.maxs, end, MOVE_NORMAL, self);
2299                 if(trace_fraction < 1)
2300                 if(!(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
2301                 {
2302                         print("I HIT SOLID: ", vtos(self.origin), " -> ", vtos(end), "\n");
2303                         break;
2304                 }
2305         }
2306         */
2307
2308         Arena_Warmup();
2309 }