data/qcsrc/server/cl_client.qc

   1 .float spectatee_status;
   2 .float zoomstate;
   3 .float bloodloss_timer;
   4 .float restriction;
   5
   6 .entity clientdata;
   7 float ClientData_Send(entity to, float sf)
   8 {
   9         if(to != self.owner)
  10         {
  11                 error("wtf");
  12                 return FALSE;
  13         }
  14
  15         entity e;
  16
  17         e = to;
  18         if(to.classname == "spectator")
  19                 e = to.enemy;
  20
  21         sf = 0;
  22
  23         if(e.race_completed)
  24                 sf |= 1; // forced scoreboard
  25         if(to.spectatee_status)
  26                 sf |= 2; // spectator ent number follows
  27         if(e.zoomstate)
  28                 sf |= 4; // zoomed
  29         if(e.porto_v_angle_held)
  30                 sf |= 8; // angles held
  31
  32         WriteByte(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
  33         WriteByte(MSG_ENTITY, sf);
  34
  35         if(sf & 2)
  36                 WriteByte(MSG_ENTITY, to.spectatee_status);
  37
  38         if(sf & 8)
  39         {
  40                 WriteAngle(MSG_ENTITY, e.v_angle_x);
  41                 WriteAngle(MSG_ENTITY, e.v_angle_y);
  42         }
  43
  44         return TRUE;
  45 }
  46
  47 void ClientData_Attach()
  48 {
  49         Net_LinkEntity(self.clientdata = spawn(), FALSE, 0, ClientData_Send);
  50         self.clientdata.drawonlytoclient = self;
  51         self.clientdata.owner = self;
  52 }
  53
  54 void ClientData_Detach()
  55 {
  56         remove(self.clientdata);
  57         self.clientdata = world;
  58 }
  59
  60 void ClientData_Touch(entity e)
  61 {
  62         e.clientdata.SendFlags = 1;
  63
  64         // make it spectatable
  65         entity e2;
  66         FOR_EACH_REALCLIENT(e2)
  67         {
  68                 if(e2 != e)
  69                         if(e2.classname == "spectator")
  70                                 if(e2.enemy == e)
  71                                         e2.clientdata.SendFlags = 1;
  72         }
  73 }
  74
  75
  76 #define SPAWNPOINT_SCORE frags
  77
  78 .string netname_previous;
  79
  80 void spawnfunc_info_player_survivor (void)
  81 {
  82         spawnfunc_info_player_deathmatch();
  83 }
  84
  85 void spawnfunc_info_player_start (void)
  86 {
  87         spawnfunc_info_player_deathmatch();
  88 }
  89
  90 void spawnfunc_info_player_deathmatch (void)
  91 {
  92         self.classname = "info_player_deathmatch";
  93         relocate_spawnpoint();
  94 }
  95
  96 void spawnpoint_use()
  97 {
  98         if(teams_matter)
  99         if(have_team_spawns)
 100         {
 101                 self.team = activator.team;
 102                 some_spawn_has_been_used = 1;
 103         }
 104 };
 105
 106 // Returns:
 107 //   -1 if a spawn can't be used
 108 //   otherwise, a weight of the spawnpoint
 109 float Spawn_Score(entity spot, entity playerlist, float teamcheck)
 110 {
 111         float shortest, thisdist;
 112         entity player;
 113
 114         // filter out spots for the wrong team
 115         if(teamcheck)
 116         if(spot.team != teamcheck)
 117                 return -1;
 118
 119         if(race_spawns)
 120                 if(spot.target == "")
 121                         return -1;
 122
 123         if(clienttype(self) == CLIENTTYPE_REAL)
 124         {
 125                 if(spot.restriction == 1)
 126                         return -1;
 127         }
 128         else
 129         {
 130                 if(spot.restriction == 2)
 131                         return -1;
 132         }
 133
 134         // filter out spots for assault
 135         if(spot.target != "") {
 136                 local entity ent;
 137                 float good, found;
 138                 ent = find(world, targetname, spot.target);
 139                 while(ent) {
 140                         if(ent.classname == "target_objective")
 141                         {
 142                                 found = 1;
 143                                 if(ent.health < 0 || ent.health >= ASSAULT_VALUE_INACTIVE)
 144                                         return -1;
 145                                 good = 1;
 146                         }
 147                         else if(ent.classname == "trigger_race_checkpoint")
 148                         {
 149                                 found = 1;
 150                                 if(self.classname == "player") // spectators may spawn everywhere
 151                                 {
 152                                         if(g_race_qualifying)
 153                                         {
 154                                                 // spawn at first
 155                                                 if(ent.race_checkpoint != 0)
 156                                                         return -1;
 157                                                 if(spot.race_place != race_lowest_place_spawn)
 158                                                         return -1;
 159                                         }
 160                                         else
 161                                         {
 162                                                 if(ent.race_checkpoint != race_PreviousCheckpoint(self.race_checkpoint))
 163                                                         return -1;
 164                                                 float pl;
 165                                                 pl = self.race_place;
 166                                                 if(pl > race_highest_place_spawn)
 167                                                         pl = 0;
 168                                                 if(spot.race_place != pl)
 169                                                         return -1;
 170                                         }
 171                                 }
 172                                 good = 1;
 173                         }
 174                         ent = find(ent, targetname, spot.target);
 175                 }
 176
 177                 if(found && !good)
 178                         return -1;
 179         }
 180
 181         player = playerlist;
 182         shortest = vlen(world.maxs - world.mins);
 183         for(player = playerlist; player; player = player.chain)
 184                 if (player != self)
 185                 {
 186                         thisdist = vlen(player.origin - spot.origin);
 187                         if (thisdist < shortest)
 188                                 shortest = thisdist;
 189                 }
 190         return shortest;
 191 }
 192
 193 float spawn_allbad;
 194 float spawn_allgood;
 195 entity Spawn_FilterOutBadSpots(entity firstspot, entity playerlist, float mindist, float teamcheck)
 196 {
 197         local entity spot, spotlist, spotlistend;
 198         spawn_allgood = TRUE;
 199         spawn_allbad = TRUE;
 200
 201         spotlist = world;
 202         spotlistend = world;
 203
 204         for(spot = firstspot; spot; spot = spot.chain)
 205         {
 206                 spot.SPAWNPOINT_SCORE = Spawn_Score(spot, playerlist, teamcheck);
 207
 208                 if(cvar("spawn_debugview"))
 209                 {
 210                         setmodel(spot, "models/runematch/rune.mdl");
 211                         if(spot.SPAWNPOINT_SCORE < mindist)
 212                         {
 213                                 spot.colormod = '1 0 0';
 214                                 spot.scale = 1;
 215                         }
 216                         else
 217                         {
 218                                 spot.colormod = '0 1 0';
 219                                 spot.scale = spot.SPAWNPOINT_SCORE / mindist;
 220                         }
 221                 }
 222
 223                 if(spot.SPAWNPOINT_SCORE >= 0) // spawning allowed here
 224                 {
 225                         if(spot.SPAWNPOINT_SCORE < mindist)
 226                         {
 227                                 // too short distance
 228                                 spawn_allgood = FALSE;
 229                         }
 230                         else
 231                         {
 232                                 // perfect
 233                                 spawn_allbad = FALSE;
 234
 235                                 if(spotlistend)
 236                                         spotlistend.chain = spot;
 237                                 spotlistend = spot;
 238                                 if(!spotlist)
 239                                         spotlist = spot;
 240
 241                                 /*
 242                                 if(teamcheck)
 243                                 if(spot.team != teamcheck)
 244                                         error("invalid spawn added");
 245
 246                                 print("added ", etos(spot), "\n");
 247                                 */
 248                         }
 249                 }
 250         }
 251         if(spotlistend)
 252                 spotlistend.chain = world;
 253
 254         /*
 255                 entity e;
 256                 if(teamcheck)
 257                         for(e = spotlist; e; e = e.chain)
 258                         {
 259                                 print("seen ", etos(e), "\n");
 260                                 if(e.team != teamcheck)
 261                                         error("invalid spawn found");
 262                         }
 263         */
 264
 265         return spotlist;
 266 }
 267
 268 entity Spawn_WeightedPoint(entity firstspot, float lower, float upper, float exponent)
 269 {
 270         // weight of a point: bound(lower, mindisttoplayer, upper)^exponent
 271         // multiplied by spot.cnt (useful if you distribute many spawnpoints in a small area)
 272         local entity spot;
 273
 274         RandomSelection_Init();
 275         for(spot = firstspot; spot; spot = spot.chain)
 276                 RandomSelection_Add(spot, 0, string_null, pow(bound(lower, spot.SPAWNPOINT_SCORE, upper), exponent) * spot.cnt, spot.SPAWNPOINT_SCORE >= lower);
 277
 278         return RandomSelection_chosen_ent;
 279 }
 280
 281 /*
 282 =============
 283 SelectSpawnPoint
 284
 285 Finds a point to respawn
 286 =============
 287 */
 288 entity SelectSpawnPoint (float anypoint)
 289 {
 290         local float teamcheck;
 291         local entity firstspot_new;
 292         local entity spot, firstspot, playerlist;
 293
 294         spot = find (world, classname, "testplayerstart");
 295         if (spot)
 296                 return spot;
 297
 298         teamcheck = 0;
 299
 300         if(!anypoint && have_team_spawns)
 301                 teamcheck = self.team;
 302
 303         // get the list of players
 304         playerlist = findchain(classname, "player");
 305         // get the entire list of spots
 306         firstspot = findchain(classname, "info_player_deathmatch");
 307         // filter out the bad ones
 308         // (note this returns the original list if none survived)
 309         if(anypoint)
 310         {
 311                 spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 312         }
 313         else
 314         {
 315                 firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, 100, teamcheck);
 316                 if(!firstspot_new)
 317                         firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, -1, teamcheck);
 318                 firstspot = firstspot_new;
 319
 320                 // there is 50/50 chance of choosing a random spot or the furthest spot
 321                 // (this means that roughly every other spawn will be furthest, so you
 322                 // usually won't get fragged at spawn twice in a row)
 323                 if (arena_roundbased)
 324                 {
 325                         firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, 800, teamcheck);
 326                         if(firstspot_new)
 327                                 firstspot = firstspot_new;
 328                         spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 329                 }
 330                 else if (random() > cvar("g_spawn_furthest"))
 331                         spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 332                 else
 333                         spot = Spawn_WeightedPoint(firstspot, 1, 5000, 5); // chooses a far far away spawnpoint
 334         }
 335
 336         if(cvar("spawn_debugview"))
 337         {
 338                 print("spot mindistance: ", ftos(spot.SPAWNPOINT_SCORE), "\n");
 339
 340                 entity e;
 341                 if(teamcheck)
 342                         for(e = firstspot; e; e = e.chain)
 343                                 if(e.team != teamcheck)
 344                                         error("invalid spawn found");
 345         }
 346
 347         if (!spot)
 348         {
 349                 if(cvar("spawn_debug"))
 350                         GotoNextMap();
 351                 else
 352                 {
 353                         if(some_spawn_has_been_used)
 354                                 return world; // team can't spawn any more, because of actions of other team
 355                         else
 356                                 error("Cannot find a spawn point - please fix the map!");
 357                 }
 358         }
 359
 360         return spot;
 361 }
 362
 363 /*
 364 =============
 365 CheckPlayerModel
 366
 367 Checks if the argument string can be a valid playermodel.
 368 Returns a valid one in doubt.
 369 =============
 370 */
 371 string FallbackPlayerModel = "models/player/marine.zym";
 372 string CheckPlayerModel(string plyermodel) {
 373         if(strlen(plyermodel) < 4)
 374                 return FallbackPlayerModel;
 375         if( substring(plyermodel,0,14) != "models/player/")
 376                 return FallbackPlayerModel;
 377         else if(cvar("sv_servermodelsonly"))
 378         {
 379                 if(substring(plyermodel,-4,4) != ".zym")
 380                 if(substring(plyermodel,-4,4) != ".dpm")
 381                 if(substring(plyermodel,-4,4) != ".md3")
 382                 if(substring(plyermodel,-4,4) != ".psk")
 383                         return FallbackPlayerModel;
 384                 // forbid the LOD models
 385                 if(substring(plyermodel, -9,5) == "_lod1")
 386                         return FallbackPlayerModel;
 387                 if(substring(plyermodel, -9,5) == "_lod2")
 388                         return FallbackPlayerModel;
 389                 if(plyermodel != strtolower(plyermodel))
 390                         return FallbackPlayerModel;
 391                 if(!fexists(plyermodel))
 392                         return FallbackPlayerModel;
 393         }
 394         return plyermodel;
 395 }
 396
 397 /*
 398 =============
 399 Client_customizeentityforclient
 400
 401 LOD reduction
 402 =============
 403 */
 404 void Client_uncustomizeentityforclient()
 405 {
 406         if(self.modelindex == 0) // no need to uncustomize then
 407                 return;
 408         self.modelindex = self.modelindex_lod0;
 409         self.skin = self.skinindex;
 410 }
 411
 412 float Client_customizeentityforclient()
 413 {
 414         entity modelsource;
 415
 416         if(self.modelindex == 0)
 417                 return TRUE;
 418
 419         // forcemodel stuff
 420
 421 #ifdef PROFILING
 422         float t0;
 423         t0 = gettime(GETTIME_HIRES); // reference
 424 #endif
 425
 426         modelsource = self;
 427
 428 #ifdef ALLOW_FORCEMODELS
 429         if(other.cvar_cl_forceplayermodelsfromnexuiz)
 430                 if not(self.modelindex_lod0_from_nexuiz)
 431                         modelsource = other;
 432         if(other.cvar_cl_forceplayermodels && sv_clforceplayermodels)
 433                 modelsource = other;
 434 #endif
 435
 436         self.skin = modelsource.skinindex;
 437
 438 #if 0
 439         if(modelsource == self)
 440                 self.skin = modelsource.skinindex;
 441         else
 442                 self.skin = mod(modelsource.skinindex, 3); // forbid the fbskins as forced skins
 443 #endif
 444
 445         // self: me
 446         // other: the player viewing me
 447         float distance;
 448         float f;
 449
 450         if(other.cvar_cl_playerdetailreduction <= 0)
 451         {
 452                 if(other.cvar_cl_playerdetailreduction <= -2)
 453                         self.modelindex = modelsource.modelindex_lod2;
 454                 else if(other.cvar_cl_playerdetailreduction <= -1)
 455                         self.modelindex = modelsource.modelindex_lod1;
 456                 else
 457                         self.modelindex = modelsource.modelindex_lod0;
 458         }
 459         else
 460         {
 461                 distance = vlen(self.origin - other.origin);
 462                 f = (distance + 100.0) * other.cvar_cl_playerdetailreduction;
 463                 if(f > sv_loddistance2)
 464                         self.modelindex = modelsource.modelindex_lod2;
 465                 else if(f > sv_loddistance1)
 466                         self.modelindex = modelsource.modelindex_lod1;
 467                 else
 468                         self.modelindex = modelsource.modelindex_lod0;
 469         }
 470
 471 #ifdef PROFILING
 472         float t1;
 473         t1 = gettime(GETTIME_HIRES); // reference
 474         client_cefc_accumulator += (t1 - t0);
 475 #endif
 476
 477         return TRUE;
 478 }
 479
 480 void UpdatePlayerSounds();
 481 void setmodel_lod(entity e, string modelname)
 482 {
 483         string s;
 484
 485         if(sv_loddistance1)
 486         {
 487                 // FIXME: this only supports 3-letter extensions
 488                 s = strcat(substring(modelname, 0, strlen(modelname)-4), "_lod1", substring(modelname, -4, 4));
 489                 if(fexists(s))
 490                 {
 491                         setmodel(e, s); // players have high precision
 492                         self.modelindex_lod1 = self.modelindex;
 493                 }
 494                 else
 495                         self.modelindex_lod1 = -1;
 496
 497                 s = strcat(substring(modelname, 0, strlen(modelname)-4), "_lod2", substring(modelname, -4, 4));
 498                 if(fexists(s))
 499                 {
 500                         setmodel(e, s); // players have high precision
 501                         self.modelindex_lod2 = self.modelindex;
 502                 }
 503                 else
 504                         self.modelindex_lod2 = -1;
 505
 506                 precache_model(modelname);
 507                 setmodel(e, modelname); // players have high precision
 508                 self.modelindex_lod0 = self.modelindex;
 509
 510                 if(self.modelindex_lod1 < 0)
 511                         self.modelindex_lod1 = self.modelindex;
 512
 513                 if(self.modelindex_lod2 < 0)
 514                         self.modelindex_lod2 = self.modelindex;
 515         }
 516         else
 517         {
 518                 precache_model(modelname);
 519                 setmodel(e, modelname); // players have high precision
 520                 self.modelindex_lod0 = self.modelindex;
 521                         // save it for possible player model forcing
 522         }
 523
 524         s = whichpack(self.model);
 525         self.modelindex_lod0_from_nexuiz = ((s == "") || (substring(s, 0, 4) == "data"));
 526
 527         player_setupanimsformodel();
 528         UpdatePlayerSounds();
 529 }
 530
 531 /*
 532 =============
 533 PutObserverInServer
 534
 535 putting a client as observer in the server
 536 =============
 537 */
 538 void FixPlayermodel();
 539 void PutObserverInServer (void)
 540 {
 541         entity  spot;
 542
 543         race_PreSpawnObserver();
 544
 545         spot = SelectSpawnPoint (TRUE);
 546         if(!spot)
 547                 error("No spawnpoints for observers?!?\n");
 548         RemoveGrapplingHook(self); // Wazat's Grappling Hook
 549
 550         if(clienttype(self) == CLIENTTYPE_REAL)
 551         {
 552                 msg_entity = self;
 553                 WriteByte(MSG_ONE, SVC_SETVIEW);
 554                 WriteEntity(MSG_ONE, self);
 555         }
 556
 557         DropAllRunes(self);
 558         kh_Key_DropAll(self, TRUE);
 559
 560         Portal_ClearAll(self);
 561
 562         if(self.flagcarried)
 563                 DropFlag(self.flagcarried, world, world);
 564         if(self.ballcarried)
 565                 DropBall(self.ballcarried, self.origin + self.ballcarried.origin, self.velocity);
 566
 567         WaypointSprite_PlayerDead();
 568
 569         if(self.killcount != -666)
 570         {
 571                 if(g_lms)
 572                 {
 573                         if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
 574                                 bprint ("^4", self.netname, "^4 has no more lives left\n");
 575                         else
 576                                 bprint ("^4", self.netname, "^4 is spectating now\n"); // TODO turn this into a proper forfeit?
 577                 }
 578                 else
 579                         bprint ("^4", self.netname, "^4 is spectating now\n");
 580         }
 581
 582         PlayerScore_Clear(self); // clear scores when needed
 583
 584         self.spectatortime = time;
 585
 586         self.classname = "observer";
 587         self.iscreature = FALSE;
 588         self.health = -666;
 589         self.takedamage = DAMAGE_NO;
 590         self.solid = SOLID_NOT;
 591         self.movetype = MOVETYPE_NOCLIP;
 592         self.flags = FL_CLIENT | FL_NOTARGET;
 593         self.armorvalue = 666;
 594         self.effects = 0;
 595         self.armorvalue = cvar("g_balance_armor_start");
 596         self.pauserotarmor_finished = 0;
 597         self.pauserothealth_finished = 0;
 598         self.pauseregen_finished = 0;
 599         self.damageforcescale = 0;
 600         self.death_time = 0;
 601         self.dead_frame = 0;
 602         self.alpha = 0;
 603         self.scale = 0;
 604         self.fade_time = 0;
 605         self.pain_frame = 0;
 606         self.pain_finished = 0;
 607         self.strength_finished = 0;
 608         self.invincible_finished = 0;
 609         self.pushltime = 0;
 610         self.think = SUB_Null;
 611         self.nextthink = 0;
 612         self.hook_time = 0;
 613         self.runes = 0;
 614         self.deadflag = DEAD_NO;
 615         self.angles = spot.angles;
 616         self.angles_z = 0;
 617         self.fixangle = TRUE;
 618         self.crouch = FALSE;
 619
 620         self.view_ofs = PL_VIEW_OFS;
 621         setorigin (self, spot.origin);
 622         setsize (self, '0 0 0', '0 0 0');
 623         self.prevorigin = self.origin;
 624         self.items = 0;
 625         self.weapons = 0;
 626         self.model = "";
 627         FixPlayermodel();
 628         self.model = "";
 629         self.modelindex = 0;
 630         self.weapon = 0;
 631         self.weaponmodel = "";
 632         self.weaponentity = world;
 633         self.exteriorweaponentity = world;
 634         self.killcount = -666;
 635         self.velocity = '0 0 0';
 636         self.avelocity = '0 0 0';
 637         self.punchangle = '0 0 0';
 638         self.punchvector = '0 0 0';
 639         self.oldvelocity = self.velocity;
 640
 641         if(sv_loddistance1)
 642                 SetCustomizer(self, Client_customizeentityforclient, Client_uncustomizeentityforclient);
 643
 644         self.team = -1;
 645
 646         if(g_arena)
 647         {
 648                 if(self.version_mismatch)
 649                 {
 650                         Spawnqueue_Unmark(self);
 651                         Spawnqueue_Remove(self);
 652                 }
 653                 else
 654                 {
 655                         Spawnqueue_Insert(self);
 656                 }
 657         }
 658         else if(g_lms)
 659         {
 660                 // Only if the player cannot play at all
 661                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) == 666)
 662                         self.frags = FRAGS_SPECTATOR;
 663                 else
 664                         self.frags = FRAGS_LMS_LOSER;
 665         }
 666         else
 667                 self.frags = FRAGS_SPECTATOR;
 668 }
 669
 670 float RestrictSkin(float s)
 671 {
 672         if(!teams_matter)
 673                 return s;
 674         if(s == 6)
 675                 return 6;
 676         return mod(s, 3);
 677 }
 678
 679 void FixPlayermodel()
 680 {
 681         local string defaultmodel;
 682         local float defaultskin, chmdl, oldskin;
 683         local vector m1, m2;
 684
 685         defaultmodel = "";
 686
 687         if(cvar("sv_defaultcharacter") == 1) {
 688                 defaultskin = 0;
 689
 690                 if(teams_matter)
 691                 {
 692                         defaultmodel = cvar_string(strcat("sv_defaultplayermodel_", Team_ColorNameLowerCase(self.team)));
 693                         defaultskin = cvar(strcat("sv_defaultplayerskin_", Team_ColorNameLowerCase(self.team)));
 694                 }
 695
 696                 if(defaultmodel == "")
 697                 {
 698                         defaultmodel = cvar_string("sv_defaultplayermodel");
 699                         defaultskin = cvar("sv_defaultplayerskin");
 700                 }
 701         }
 702
 703         if(self.modelindex == 0 && self.deadflag == DEAD_NO)
 704         {
 705                 if(self.model != "")
 706                         bprint("\{1}^1Player ", self.netname, "^1 has a zero modelindex, trying to fix...\n");
 707                 self.model = ""; // force the != checks to return true
 708         }
 709
 710         if(defaultmodel != "")
 711         {
 712                 if (defaultmodel != self.model)
 713                 {
 714                         m1 = self.mins;
 715                         m2 = self.maxs;
 716                         setmodel_lod (self, defaultmodel);
 717                         setsize (self, m1, m2);
 718                         chmdl = TRUE;
 719                 }
 720
 721                 oldskin = self.skinindex;
 722                 self.skinindex = defaultskin;
 723         } else {
 724                 if (self.playermodel != self.model)
 725                 {
 726                         self.playermodel = CheckPlayerModel(self.playermodel);
 727                         m1 = self.mins;
 728                         m2 = self.maxs;
 729                         setmodel_lod (self, self.playermodel);
 730                         setsize (self, m1, m2);
 731                         chmdl = TRUE;
 732                 }
 733
 734                 oldskin = self.skinindex;
 735                 self.skinindex = RestrictSkin(stof(self.playerskin));
 736         }
 737
 738         if(chmdl || oldskin != self.skinindex)
 739                 self.species = player_getspecies(); // model or skin has changed
 740
 741         if(!teams_matter)
 742                 if(strlen(cvar_string("sv_defaultplayercolors")))
 743                         if(self.clientcolors != cvar("sv_defaultplayercolors"))
 744                                 setcolor(self, cvar("sv_defaultplayercolors"));
 745 }
 746
 747 void PlayerTouchExplode(entity p1, entity p2)
 748 {
 749         vector org;
 750         org = (p1.origin + p2.origin) * 0.5;
 751         org_z += (p1.mins_z + p2.mins_z) * 0.5;
 752
 753         te_explosion(org);
 754
 755         entity e;
 756         e = spawn();
 757         setorigin(e, org);
 758         RadiusDamage(e, world, g_touchexplode_damage, g_touchexplode_edgedamage, g_touchexplode_radius, world, g_touchexplode_force, DEATH_TOUCHEXPLODE, world);
 759         remove(e);
 760 }
 761
 762 /*
 763 =============
 764 PutClientInServer
 765
 766 Called when a client spawns in the server
 767 =============
 768 */
 769 //void() ctf_playerchanged;
 770 void PutClientInServer (void)
 771 {
 772         if(clienttype(self) == CLIENTTYPE_BOT)
 773         {
 774                 self.classname = "player";
 775         }
 776         else if(clienttype(self) == CLIENTTYPE_REAL)
 777         {
 778                 msg_entity = self;
 779                 WriteByte(MSG_ONE, SVC_SETVIEW);
 780                 WriteEntity(MSG_ONE, self);
 781         }
 782
 783         // player is dead and becomes observer
 784         // FIXME fix LMS scoring for new system
 785         if(g_lms)
 786         {
 787                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
 788                         self.classname = "observer";
 789         }
 790
 791         if(g_arena)
 792         if(!self.spawned)
 793                 self.classname = "observer";
 794
 795         if(gameover)
 796                 self.classname = "observer";
 797
 798         if(self.classname == "player") {
 799                 entity spot, oldself;
 800
 801                 if(self.team < 0)
 802                         JoinBestTeam(self, FALSE, TRUE);
 803
 804                 race_PreSpawn();
 805
 806                 spot = SelectSpawnPoint (FALSE);
 807                 if(!spot)
 808                 {
 809                         centerprint(self, "Sorry, no spawnpoints available!\nHope your team can fix it...");
 810                         return; // spawn failed
 811                 }
 812
 813                 RemoveGrapplingHook(self); // Wazat's Grappling Hook
 814                 self.campingrifle_bulletcounter = cvar("g_balance_campingrifle_magazinecapacity");
 815
 816                 self.classname = "player";
 817                 self.wasplayer = TRUE;
 818                 self.iscreature = TRUE;
 819                 self.movetype = MOVETYPE_WALK;
 820                 self.solid = SOLID_SLIDEBOX;
 821                 self.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP;
 822                 self.frags = FRAGS_PLAYER;
 823                 if(independent_players)
 824                         MAKE_INDEPENDENT_PLAYER(self);
 825                 self.flags = FL_CLIENT;
 826                 self.takedamage = DAMAGE_AIM;
 827                 if(g_minstagib)
 828                         self.effects = EF_FULLBRIGHT;
 829                 else
 830                         self.effects = 0;
 831                 self.air_finished = time + 12;
 832                 self.dmg = 2;
 833
 834                 if(inWarmupStage)
 835                 {
 836                         self.ammo_shells = warmup_start_ammo_shells;
 837                         self.ammo_nails = warmup_start_ammo_nails;
 838                         self.ammo_rockets = warmup_start_ammo_rockets;
 839                         self.ammo_cells = warmup_start_ammo_cells;
 840                         self.ammo_fuel = warmup_start_ammo_fuel;
 841                         self.health = warmup_start_health;
 842                         self.armorvalue = warmup_start_armorvalue;
 843                         self.weapons = warmup_start_weapons;
 844                 }
 845                 else
 846                 {
 847                         self.ammo_shells = start_ammo_shells;
 848                         self.ammo_nails = start_ammo_nails;
 849                         self.ammo_rockets = start_ammo_rockets;
 850                         self.ammo_cells = start_ammo_cells;
 851                         self.ammo_fuel = start_ammo_fuel;
 852                         self.health = start_health;
 853                         self.armorvalue = start_armorvalue;
 854                         self.weapons = start_weapons;
 855                 }
 856                 self.items = start_items;
 857                 self.switchweapon = w_getbestweapon(self);
 858                 self.cnt = self.switchweapon;
 859                 self.weapon = 0;
 860                 self.jump_interval = time;
 861
 862                 self.spawnshieldtime = time + cvar("g_spawnshieldtime");
 863                 self.pauserotarmor_finished = time + cvar("g_balance_pause_armor_rot_spawn");
 864                 self.pauserothealth_finished = time + cvar("g_balance_pause_health_rot_spawn");
 865                 self.pauserotfuel_finished = time + cvar("g_balance_pause_fuel_rot_spawn");
 866                 self.pauseregen_finished = time + cvar("g_balance_pause_health_regen_spawn");
 867                 //extend the pause of rotting if client was reset at the beginning of the countdown
 868                 if(!cvar("sv_ready_restart_after_countdown") && time < game_starttime) { // TODO why is this cvar NOTted?
 869                         self.spawnshieldtime += game_starttime - time;
 870                         self.pauserotarmor_finished += game_starttime - time;
 871                         self.pauserothealth_finished += game_starttime - time;
 872                         self.pauseregen_finished += game_starttime - time;
 873                 }
 874                 self.damageforcescale = 2;
 875                 self.death_time = 0;
 876                 self.dead_frame = 0;
 877                 self.alpha = 0;
 878                 self.scale = 0;
 879                 self.fade_time = 0;
 880                 self.pain_frame = 0;
 881                 self.pain_finished = 0;
 882                 self.strength_finished = 0;
 883                 self.invincible_finished = 0;
 884                 self.pushltime = 0;
 885                 //self.speed_finished = 0;
 886                 //self.slowmo_finished = 0;
 887                 // players have no think function
 888                 self.think = SUB_Null;
 889                 self.nextthink = 0;
 890                 self.hook_time = 0;
 891                 self.dmg_team = 0;
 892
 893                 self.metertime = 0;
 894
 895                 self.runes = 0;
 896
 897                 self.deadflag = DEAD_NO;
 898
 899                 self.angles = spot.angles;
 900
 901                 self.angles_z = 0; // never spawn tilted even if the spot says to
 902                 self.fixangle = TRUE; // turn this way immediately
 903                 self.velocity = '0 0 0';
 904                 self.avelocity = '0 0 0';
 905                 self.punchangle = '0 0 0';
 906                 self.punchvector = '0 0 0';
 907                 self.oldvelocity = self.velocity;
 908
 909                 msg_entity = self;
 910                 WRITESPECTATABLE_MSG_ONE({
 911                         WriteByte(MSG_ONE, SVC_TEMPENTITY);
 912                         WriteByte(MSG_ONE, TE_CSQC_SPAWN);
 913                 });
 914
 915                 if(sv_loddistance1)
 916                         SetCustomizer(self, Client_customizeentityforclient, Client_uncustomizeentityforclient);
 917
 918                 self.model = "";
 919                 FixPlayermodel();
 920
 921                 self.crouch = FALSE;
 922                 self.view_ofs = PL_VIEW_OFS;
 923                 setsize (self, PL_MIN, PL_MAX);
 924                 self.spawnorigin = spot.origin;
 925                 setorigin (self, spot.origin + '0 0 1' * (1 - self.mins_z - 24));
 926                 // don't reset back to last position, even if new position is stuck in solid
 927                 self.oldorigin = self.origin;
 928                 self.prevorigin = self.origin;
 929                 self.lastrocket = world; // stop rocket guiding, no revenge from the grave!
 930
 931                 if(g_arena)
 932                 {
 933                         Spawnqueue_Remove(self);
 934                         Spawnqueue_Mark(self);
 935                 }
 936
 937                 self.event_damage = PlayerDamage;
 938
 939                 self.bot_attack = TRUE;
 940
 941                 self.statdraintime = time + 5;
 942                 self.BUTTON_ATCK = self.BUTTON_JUMP = self.BUTTON_ATCK2 = 0;
 943
 944                 if(self.killcount == -666) {
 945                         PlayerScore_Clear(self);
 946                         self.killcount = 0;
 947                 }
 948
 949                 self.cnt = WEP_LASER;
 950                 self.nixnex_lastchange_id = -1;
 951
 952                 CL_SpawnWeaponentity();
 953                 self.alpha = default_player_alpha;
 954                 self.colormod = '1 1 1' * cvar("g_player_brightness");
 955                 self.exteriorweaponentity.alpha = default_weapon_alpha;
 956
 957                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval")*2;
 958                 self.lms_traveled_distance = 0;
 959                 self.speedrunning = FALSE;
 960
 961                 race_PostSpawn(spot);
 962
 963                 if(cvar("spawn_debug"))
 964                 {
 965                         sprint(self, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 966                         remove(spot);   // usefull for checking if there are spawnpoints, that let drop through the floor
 967                 }
 968
 969                 //stuffcmd(self, "chase_active 0");
 970                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
 971
 972                 if (cvar("g_spawnsound"))
 973                         sound (self, CHAN_TRIGGER, "misc/spawn.wav", VOL_BASE, ATTN_NORM);
 974
 975                 if(g_assault) {
 976                         if(self.team == assault_attacker_team)
 977                                 centerprint(self, "You are attacking!");
 978                         else
 979                                 centerprint(self, "You are defending!");
 980                 }
 981
 982                 target_voicescript_clear(self);
 983
 984                 oldself = self;
 985                 self = spot;
 986                         activator = oldself;
 987                                 SUB_UseTargets();
 988                         activator = world;
 989                 self = oldself;
 990
 991         } else if(self.classname == "observer") {
 992                 PutObserverInServer ();
 993         }
 994
 995         //if(g_ctf)
 996         //      ctf_playerchanged();
 997 }
 998
 999 float ClientInit_SendEntity(entity to, float sf)
1000 {
1001         float i;
1002         WriteByte(MSG_ENTITY, ENT_CLIENT_INIT);
1003         WriteByte(MSG_ENTITY, g_nexball_meter_period * 32);
1004         for(i = 1; i <= 24; ++i)
1005                 WriteByte(MSG_ENTITY, (get_weaponinfo(i)).impulse + 1);
1006         WriteCoord(MSG_ENTITY, hook_shotorigin_x);
1007         WriteCoord(MSG_ENTITY, hook_shotorigin_y);
1008         WriteCoord(MSG_ENTITY, hook_shotorigin_z);
1009
1010         if(sv_foginterval && world.fog != "")
1011                 WriteString(MSG_ENTITY, world.fog);
1012         else
1013                 WriteString(MSG_ENTITY, "");
1014         WriteByte(MSG_ENTITY, cvar("g_balance_armor_blockpercent") * 255.0);
1015         return TRUE;
1016 }
1017
1018 void ClientInit_Spawn()
1019 {
1020         Net_LinkEntity(spawn(), FALSE, 0, ClientInit_SendEntity);
1021 }
1022
1023 /*
1024 =============
1025 SetNewParms
1026 =============
1027 */
1028 void SetNewParms (void)
1029 {
1030         // initialize parms for a new player
1031         parm1 = -(86400 * 366);
1032 }
1033
1034 /*
1035 =============
1036 SetChangeParms
1037 =============
1038 */
1039 void SetChangeParms (void)
1040 {
1041         // save parms for level change
1042         parm1 = self.parm_idlesince - time;
1043 }
1044
1045 /*
1046 =============
1047 DecodeLevelParms
1048 =============
1049 */
1050 void DecodeLevelParms (void)
1051 {
1052         // load parms
1053         self.parm_idlesince = parm1;
1054         if(self.parm_idlesince == -(86400 * 366))
1055                 self.parm_idlesince = time;
1056
1057         // whatever happens, allow 60 seconds of idling directly after connect for map loading
1058         self.parm_idlesince = max(self.parm_idlesince, time - sv_maxidle + 60);
1059 }
1060
1061 /*
1062 =============
1063 ClientKill
1064
1065 Called when a client types 'kill' in the console
1066 =============
1067 */
1068
1069 void ClientKill_Now_TeamChange()
1070 {
1071         if(self.killindicator_teamchange == -1)
1072         {
1073                 self.team = -1;
1074                 JoinBestTeam( self, FALSE, FALSE );
1075         }
1076         else
1077                 SV_ChangeTeam(self.killindicator_teamchange - 1);
1078 }
1079
1080 void ClientKill_Now()
1081 {
1082         if(self.killindicator_teamchange)
1083                 ClientKill_Now_TeamChange();
1084
1085         // in any case:
1086         Damage(self, self, self, 100000, DEATH_KILL, self.origin, '0 0 0');
1087
1088         if(self.killindicator)
1089         {
1090                 dprint("Cleaned up after a leaked kill indicator.\n");
1091                 remove(self.killindicator);
1092                 self.killindicator = world;
1093         }
1094 }
1095 void KillIndicator_Think()
1096 {
1097         if (!self.owner.modelindex)
1098         {
1099                 self.owner.killindicator = world;
1100                 remove(self);
1101                 return;
1102         }
1103
1104         if(self.cnt <= 0)
1105         {
1106                 self = self.owner;
1107                 ClientKill_Now(); // no oldself needed
1108                 return;
1109         }
1110         else
1111         {
1112                 if(self.cnt <= 10)
1113                         setmodel(self, strcat("models/sprites/", ftos(self.cnt), ".spr32"));
1114                 if(clienttype(self.owner) == CLIENTTYPE_REAL)
1115                 {
1116                         if(self.cnt <= 10)
1117                                 announce(self.owner, strcat("announcer/robotic/", ftos(self.cnt), ".wav"));
1118                         if(self.owner.killindicator_teamchange)
1119                         {
1120                                 if(self.owner.killindicator_teamchange == -1)
1121                                         centerprint(self.owner, strcat("Changing team in ", ftos(self.cnt), " seconds"));
1122                                 else
1123                                         centerprint(self.owner, strcat("Changing to ", ColoredTeamName(self.owner.killindicator_teamchange), " in ", ftos(self.cnt), " seconds"));
1124                         }
1125                         else
1126                                 centerprint(self.owner, strcat("^1Suicide in ", ftos(self.cnt), " seconds"));
1127                 }
1128                 self.nextthink = time + 1;
1129                 self.cnt -= 1;
1130         }
1131 }
1132
1133 void ClientKill_TeamChange (float targetteam) // 0 = don't change, -1 = auto
1134 {
1135         float killtime;
1136         entity e;
1137         killtime = cvar("g_balance_kill_delay");
1138
1139         if(g_race_qualifying)
1140                 killtime = 0;
1141
1142         self.killindicator_teamchange = targetteam;
1143
1144         if(!self.killindicator)
1145         {
1146                 if(killtime <= 0 || !self.modelindex || self.deadflag != DEAD_NO)
1147                 {
1148                         ClientKill_Now();
1149                 }
1150                 else
1151                 {
1152                         self.killindicator = spawn();
1153                         self.killindicator.owner = self;
1154                         self.killindicator.scale = 0.5;
1155                         setattachment(self.killindicator, self, "");
1156                         setorigin(self.killindicator, '0 0 52');
1157                         self.killindicator.think = KillIndicator_Think;
1158                         self.killindicator.nextthink = time + (self.lip) * 0.05;
1159                         self.killindicator.cnt = ceil(killtime);
1160                         self.killindicator.count = bound(0, ceil(killtime), 10);
1161                         sprint(self, strcat("^1You'll be dead in ", ftos(self.killindicator.cnt), " seconds\n"));
1162
1163                         for(e = world; (e = find(e, classname, "body")) != world; )
1164                         {
1165                                 if(e.enemy != self)
1166                                         continue;
1167                                 e.killindicator = spawn();
1168                                 e.killindicator.owner = e;
1169                                 e.killindicator.scale = 0.5;
1170                                 setattachment(e.killindicator, e, "");
1171                                 setorigin(e.killindicator, '0 0 52');
1172                                 e.killindicator.think = KillIndicator_Think;
1173                                 e.killindicator.nextthink = time + (e.lip) * 0.05;
1174                                 e.killindicator.cnt = ceil(killtime);
1175                         }
1176                         self.lip = 0;
1177                 }
1178         }
1179         if(self.killindicator)
1180         {
1181                 if(targetteam)
1182                         self.killindicator.colormod = TeamColor(targetteam);
1183                 else
1184                         self.killindicator.colormod = '0 0 0';
1185         }
1186 }
1187
1188 void ClientKill (void)
1189 {
1190         ClientKill_TeamChange(0);
1191 }
1192
1193 void DoTeamChange(float destteam)
1194 {
1195         float t, c0;
1196         if(!teams_matter)
1197         {
1198                 if(destteam >= 0)
1199                         SetPlayerColors(self, destteam);
1200                 return;
1201         }
1202         if(self.classname == "player")
1203         if(destteam == -1)
1204         {
1205                 CheckAllowedTeams(self);
1206                 t = FindSmallestTeam(self, TRUE);
1207                 switch(self.team)
1208                 {
1209                         case COLOR_TEAM1: c0 = c1; break;
1210                         case COLOR_TEAM2: c0 = c2; break;
1211                         case COLOR_TEAM3: c0 = c3; break;
1212                         case COLOR_TEAM4: c0 = c4; break;
1213                         default:          c0 = 999;
1214                 }
1215                 switch(t)
1216                 {
1217                         case 1:
1218                                 if(c0 > c1)
1219                                         destteam = COLOR_TEAM1;
1220                                 break;
1221                         case 2:
1222                                 if(c0 > c2)
1223                                         destteam = COLOR_TEAM2;
1224                                 break;
1225                         case 3:
1226                                 if(c0 > c3)
1227                                         destteam = COLOR_TEAM3;
1228                                 break;
1229                         case 4:
1230                                 if(c0 > c4)
1231                                         destteam = COLOR_TEAM4;
1232                                 break;
1233                 }
1234                 if(destteam == -1)
1235                         return;
1236         }
1237         if(destteam == self.team && destteam >= 0 && !self.killindicator)
1238                 return;
1239         ClientKill_TeamChange(destteam);
1240 }
1241
1242 void FixClientCvars(entity e)
1243 {
1244         // send prediction settings to the client
1245         stuffcmd(e, "\nin_bindmap 0 0\n");
1246         /*
1247          * we no longer need to stuff this. Remove this comment block if you feel
1248          * 2.3 and higher (or was it 2.2.3?) don't need these any more
1249         stuffcmd(e, strcat("cl_gravity ", ftos(cvar("sv_gravity")), "\n"));
1250         stuffcmd(e, strcat("cl_movement_accelerate ", ftos(cvar("sv_accelerate")), "\n"));
1251         stuffcmd(e, strcat("cl_movement_friction ", ftos(cvar("sv_friction")), "\n"));
1252         stuffcmd(e, strcat("cl_movement_maxspeed ", ftos(cvar("sv_maxspeed")), "\n"));
1253         stuffcmd(e, strcat("cl_movement_airaccelerate ", ftos(cvar("sv_airaccelerate")), "\n"));
1254         stuffcmd(e, strcat("cl_movement_maxairspeed ", ftos(cvar("sv_maxairspeed")), "\n"));
1255         stuffcmd(e, strcat("cl_movement_stopspeed ", ftos(cvar("sv_stopspeed")), "\n"));
1256         stuffcmd(e, strcat("cl_movement_jumpvelocity ", ftos(cvar("sv_jumpvelocity")), "\n"));
1257         stuffcmd(e, strcat("cl_movement_stepheight ", ftos(cvar("sv_stepheight")), "\n"));
1258         stuffcmd(e, strcat("set cl_movement_friction_on_land ", ftos(cvar("sv_friction_on_land")), "\n"));
1259         stuffcmd(e, strcat("set cl_movement_airaccel_qw ", ftos(cvar("sv_airaccel_qw")), "\n"));
1260         stuffcmd(e, strcat("set cl_movement_airaccel_sideways_friction ", ftos(cvar("sv_airaccel_sideways_friction")), "\n"));
1261         stuffcmd(e, "cl_movement_edgefriction 1\n");
1262          */
1263 }
1264
1265 /*
1266 =============
1267 ClientConnect
1268
1269 Called when a client connects to the server
1270 =============
1271 */
1272 //void ctf_clientconnect();
1273 string ColoredTeamName(float t);
1274 void DecodeLevelParms (void);
1275 //void dom_player_join_team(entity pl);
1276 void ClientConnect (void)
1277 {
1278         local string s;
1279         float t;
1280
1281         if(self.flags & FL_CLIENT)
1282         {
1283                 print("Warning: ClientConnect, but already connected!\n");
1284                 return;
1285         }
1286
1287         if(Ban_MaybeEnforceBan(self))
1288                 return;
1289
1290         DecodeLevelParms();
1291
1292         self.classname = "player_joining";
1293
1294         self.flags = FL_CLIENT;
1295         self.version_nagtime = time + 10 + random() * 10;
1296
1297         if(player_count<0)
1298         {
1299                 dprint("BUG player count is lower than zero, this cannot happen!\n");
1300                 player_count = 0;
1301         }
1302
1303         PlayerScore_Attach(self);
1304         ClientData_Attach();
1305
1306         bot_clientconnect();
1307
1308         race_PreSpawnObserver();
1309
1310         //if(g_domination)
1311         //      dom_player_join_team(self);
1312
1313         JoinBestTeam(self, FALSE, FALSE); // if the team number is valid, keep it
1314
1315         if((cvar("sv_spectate") == 1 && !g_lms) || cvar("g_campaign")) {
1316                 self.classname = "observer";
1317         } else {
1318                 if(teams_matter)
1319                 {
1320                         if(cvar("g_balance_teams") || cvar("g_balance_teams_force"))
1321                         {
1322                                 self.classname = "player";
1323                                 campaign_bots_may_start = 1;
1324                         }
1325                         else
1326                         {
1327                                 self.classname = "observer"; // do it anyway
1328                         }
1329                 }
1330                 else
1331                 {
1332                         self.classname = "player";
1333                         campaign_bots_may_start = 1;
1334                 }
1335         }
1336
1337         self.playerid = (playerid_last = playerid_last + 1);
1338         if(cvar("sv_eventlog"))
1339         {
1340                 if(clienttype(self) == CLIENTTYPE_REAL)
1341                         GameLogEcho(strcat(":join:", ftos(self.playerid), ":", ftos(num_for_edict(self)), ":", self.netaddress, ":", self.netname));
1342                 else
1343                         GameLogEcho(strcat(":join:", ftos(self.playerid), ":", ftos(num_for_edict(self)), ":bot:", self.netname));
1344                 s = strcat(":team:", ftos(self.playerid), ":");
1345                 s = strcat(s, ftos(self.team));
1346                 GameLogEcho(s);
1347         }
1348         self.netname_previous = strzone(self.netname);
1349
1350         //stuffcmd(self, "set tmpviewsize $viewsize \n");
1351
1352         bprint ("^4",self.netname);
1353         bprint ("^4 connected");
1354
1355         if(g_domination || g_ctf)
1356         {
1357                 bprint(" and joined the ");
1358                 bprint(ColoredTeamName(self.team));
1359         }
1360
1361         bprint("\n");
1362
1363         self.welcomemessage_time = 0;
1364
1365         stuffcmd(self, strcat(clientstuff, "\n"));
1366         stuffcmd(self, strcat("exec maps/", mapname, ".cfg\n"));
1367         stuffcmd(self, "cl_particles_reloadeffects\n");
1368
1369         FixClientCvars(self);
1370
1371         // spawnfunc_waypoint sprites
1372         WaypointSprite_InitClient(self);
1373
1374         // Wazat's grappling hook
1375         SetGrappleHookBindings();
1376
1377         // get autoswitch state from player when he toggles it
1378         stuffcmd(self, "alias autoswitch \"set cl_autoswitch $1 ; cmd autoswitch $1\"\n"); // default.cfg-ed in 2.4.1
1379
1380         // get version info from player
1381         stuffcmd(self, "cmd clientversion $gameversion\n");
1382
1383         // get other cvars from player
1384         GetCvars(0);
1385
1386         // set cvar for team scoreboard
1387         stuffcmd(self, strcat("set teamplay ", ftos(teamplay), "\n"));
1388
1389         // notify about available teams
1390         if(teams_matter)
1391         {
1392                 CheckAllowedTeams(self);
1393                 t = 0; if(c1 >= 0) t |= 1; if(c2 >= 0) t |= 2; if(c3 >= 0) t |= 4; if(c4 >= 0) t |= 8;
1394                 stuffcmd(self, strcat("set _teams_available ", ftos(t), "\n"));
1395         }
1396         else
1397                 stuffcmd(self, "set _teams_available 0\n");
1398
1399         stuffcmd(self, strcat("set gametype ", ftos(game), "\n"));
1400
1401         if(g_arena)
1402         {
1403                 self.classname = "observer";
1404                 Spawnqueue_Insert(self);
1405         }
1406         /*else if(g_ctf)
1407         {
1408                 ctf_clientconnect();
1409         }*/
1410
1411         if(teams_matter || sv_cheats)
1412                 attach_entcs();
1413
1414         bot_relinkplayerlist();
1415
1416         self.spectatortime = time;
1417         if(blockSpectators)
1418         {
1419                 sprint(self, strcat("^7You have to become a player within the next ", ftos(cvar("g_maxplayers_spectator_blocktime")), " seconds, otherwise you will be kicked, because spectators aren't allowed at this time!\n"));
1420         }
1421
1422         self.jointime = time;
1423         self.allowedTimeouts = cvar("sv_timeout_number");
1424
1425         if(clienttype(self) == CLIENTTYPE_REAL)
1426         {
1427                 if(cvar("g_bugrigs") || g_weaponarena == WEPBIT_TUBA)
1428                         stuffcmd(self, "cl_cmd settemp chase_active 1\n");
1429         }
1430
1431         if(g_lms)
1432         {
1433                 if(PlayerScore_Add(self, SP_LMS_LIVES, LMS_NewPlayerLives()) <= 0)
1434                 {
1435                         PlayerScore_Add(self, SP_LMS_RANK, 666);
1436                         self.frags = FRAGS_SPECTATOR;
1437                 }
1438         }
1439
1440         if(!sv_foginterval && world.fog != "")
1441                 stuffcmd(self, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1442
1443         SoundEntity_Attach(self);
1444
1445         if(cvar("g_hitplots"))
1446         {
1447                 self.hitplotfh = fopen(strcat("hits-", matchid, "-", ftos(self.playerid), ".plot"), FILE_WRITE);
1448                 fputs(self.hitplotfh, strcat("#name ", self.netname, "\n"));
1449         }
1450         else
1451                 self.hitplotfh = -1;
1452 }
1453
1454 /*
1455 =============
1456 ClientDisconnect
1457
1458 Called when a client disconnects from the server
1459 =============
1460 */
1461 .entity chatbubbleentity;
1462 .entity teambubbleentity;
1463 void ReadyCount();
1464 void ClientDisconnect (void)
1465 {
1466         if not(self.flags & FL_CLIENT)
1467         {
1468                 print("Warning: ClientDisconnect without ClientConnect\n");
1469                 return;
1470         }
1471
1472         if(self.hitplotfh >= 0)
1473         {
1474                 fclose(self.hitplotfh);
1475                 self.hitplotfh = -1;
1476         }
1477
1478         bot_clientdisconnect();
1479
1480         if(self.entcs)
1481                 detach_entcs();
1482
1483         if(cvar("sv_eventlog"))
1484                 GameLogEcho(strcat(":part:", ftos(self.playerid)));
1485         bprint ("^4",self.netname);
1486         bprint ("^4 disconnected\n");
1487
1488         SoundEntity_Detach(self);
1489
1490         DropAllRunes(self);
1491         kh_Key_DropAll(self, TRUE);
1492
1493         Portal_ClearAll(self);
1494
1495         if(self.flagcarried)
1496                 DropFlag(self.flagcarried, world, world);
1497         if(self.ballcarried)
1498                 DropBall(self.ballcarried, self.origin + self.ballcarried.origin, self.velocity);
1499
1500         // Here, everything has been done that requires this player to be a client.
1501
1502         self.flags &~= FL_CLIENT;
1503
1504         if (self.chatbubbleentity)
1505                 remove (self.chatbubbleentity);
1506
1507         if (self.teambubbleentity)
1508                 remove (self.teambubbleentity);
1509
1510         if (self.killindicator)
1511                 remove (self.killindicator);
1512
1513         WaypointSprite_PlayerGone();
1514
1515         bot_relinkplayerlist();
1516
1517         // remove laserdot
1518         if(self.weaponentity)
1519                 if(self.weaponentity.lasertarget)
1520                         remove(self.weaponentity.lasertarget);
1521
1522         if(g_arena)
1523         {
1524                 Spawnqueue_Unmark(self);
1525                 Spawnqueue_Remove(self);
1526         }
1527
1528         ClientData_Detach();
1529         PlayerScore_Detach(self);
1530
1531         if(self.netname_previous)
1532                 strunzone(self.netname_previous);
1533         if(self.clientstatus)
1534                 strunzone(self.clientstatus);
1535
1536         ClearPlayerSounds();
1537
1538         self.playerid = 0;
1539         ReadyCount();
1540
1541         // free cvars
1542         GetCvars(-1);
1543 }
1544
1545 .float BUTTON_CHAT;
1546 void ChatBubbleThink()
1547 {
1548         self.nextthink = time;
1549         if (!self.owner.modelindex || self.owner.chatbubbleentity != self)
1550         {
1551                 if(self.owner) // but why can that ever be world?
1552                         self.owner.chatbubbleentity = world;
1553                 remove(self);
1554                 return;
1555         }
1556         if (self.owner.BUTTON_CHAT && !self.owner.deadflag)
1557                 self.model = self.mdl;
1558         else
1559                 self.model = "";
1560 };
1561
1562 void UpdateChatBubble()
1563 {
1564         if (!self.modelindex)
1565                 return;
1566         // spawn a chatbubble entity if needed
1567         if (!self.chatbubbleentity)
1568         {
1569                 self.chatbubbleentity = spawn();
1570                 self.chatbubbleentity.owner = self;
1571                 self.chatbubbleentity.exteriormodeltoclient = self;
1572                 self.chatbubbleentity.think = ChatBubbleThink;
1573                 self.chatbubbleentity.nextthink = time;
1574                 setmodel(self.chatbubbleentity, "models/misc/chatbubble.spr"); // precision set below
1575                 //setorigin(self.chatbubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1576                 setorigin(self.chatbubbleentity, '0 0 15' + self.maxs_z * '0 0 1');
1577                 setattachment(self.chatbubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1578                 self.chatbubbleentity.mdl = self.chatbubbleentity.model;
1579                 self.chatbubbleentity.model = "";
1580                 self.chatbubbleentity.effects = EF_LOWPRECISION;
1581         }
1582 }
1583
1584
1585 void TeamBubbleThink()
1586 {
1587         self.nextthink = time;
1588         if (!self.owner.modelindex || self.owner.teambubbleentity != self)
1589         {
1590                 if(self.owner) // but why can that ever be world?
1591                         self.owner.teambubbleentity = world;
1592                 remove(self);
1593                 return;
1594         }
1595 //      setorigin(self, self.owner.origin + '0 0 15' + self.owner.maxs_z * '0 0 1');  // bandwidth hog. setattachment does this now
1596         if (self.owner.BUTTON_CHAT || self.owner.deadflag || self.owner.killindicator)
1597                 self.model = "";
1598         else
1599                 self.model = self.mdl;
1600
1601 };
1602
1603 float TeamBubble_customizeentityforclient()
1604 {
1605         return (self.owner != other && self.owner.team == other.team && other.killcount > -666);
1606 }
1607
1608 void UpdateTeamBubble()
1609 {
1610         if (!self.modelindex || !teams_matter)
1611                 return;
1612         // spawn a teambubble entity if needed
1613         if (!self.teambubbleentity && teams_matter)
1614         {
1615                 self.teambubbleentity = spawn();
1616                 self.teambubbleentity.owner = self;
1617                 self.teambubbleentity.exteriormodeltoclient = self;
1618                 self.teambubbleentity.think = TeamBubbleThink;
1619                 self.teambubbleentity.nextthink = time;
1620                 setmodel(self.teambubbleentity, "models/misc/teambubble.spr"); // precision set below
1621 //              setorigin(self.teambubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1622                 setorigin(self.teambubbleentity, '0 0 15' + self.maxs_z * '0 0 1');
1623                 setattachment(self.teambubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1624                 self.teambubbleentity.mdl = self.teambubbleentity.model;
1625                 self.teambubbleentity.model = self.teambubbleentity.mdl;
1626                 self.teambubbleentity.customizeentityforclient = TeamBubble_customizeentityforclient;
1627                 self.teambubbleentity.effects = EF_LOWPRECISION;
1628         }
1629 }
1630
1631 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1632 // added to the model skins
1633 /*void UpdateColorModHack()
1634 {
1635         local float c;
1636         c = self.clientcolors & 15;
1637         // LordHavoc: only bothering to support white, green, red, yellow, blue
1638              if (!teams_matter) self.colormod = '0 0 0';
1639         else if (c ==  0) self.colormod = '1.00 1.00 1.00';
1640         else if (c ==  3) self.colormod = '0.10 1.73 0.10';
1641         else if (c ==  4) self.colormod = '1.73 0.10 0.10';
1642         else if (c == 12) self.colormod = '1.22 1.22 0.10';
1643         else if (c == 13) self.colormod = '0.10 0.10 1.73';
1644         else self.colormod = '1 1 1';
1645 };*/
1646
1647 void respawn(void)
1648 {
1649         CopyBody(1);
1650         self.effects |= EF_NODRAW; // prevent another CopyBody
1651         PutClientInServer();
1652 }
1653
1654 void play_countdown(float finished, string samp)
1655 {
1656         if(clienttype(self) == CLIENTTYPE_REAL)
1657                 if(floor(finished - time - frametime) != floor(finished - time))
1658                         if(finished - time < 6)
1659                                 sound (self, CHAN_AUTO, samp, VOL_BASE, ATTN_NORM);
1660 }
1661
1662 /**
1663  * When sv_timeout is used this function returs strings like
1664  * "Timeout begins in 2 seconds!\n" or "Timeout ends in 23 seconds!\n".
1665  * Called by centerprint functions
1666  * @param addOneSecond boolean, set to 1 if the welcome-message centerprint asks for the text
1667  */
1668 string getTimeoutText(float addOneSecond) {
1669         if (!cvar("sv_timeout") || !timeoutStatus)
1670                 return "";
1671
1672         local string retStr;
1673         if (timeoutStatus == 1) {
1674                 if (addOneSecond == 1) {
1675                         retStr = strcat("Timeout begins in ", ftos(remainingLeadTime + 1), " seconds!\n");
1676                 }
1677                 else {
1678                         retStr = strcat("Timeout begins in ", ftos(remainingLeadTime), " seconds!\n");
1679                 }
1680                 return retStr;
1681         }
1682         else if (timeoutStatus == 2) {
1683                 if (addOneSecond) {
1684                         retStr = strcat("Timeout ends in ", ftos(remainingTimeoutTime + 1), " seconds!\n");
1685                         //don't show messages like "Timeout ends in 0 seconds"...
1686                         if ((remainingTimeoutTime + 1) > 0)
1687                                 return retStr;
1688                         else
1689                                 return "";
1690                 }
1691                 else {
1692                         retStr = strcat("Timeout ends in ", ftos(remainingTimeoutTime), " seconds!\n");
1693                         //don't show messages like "Timeout ends in 0 seconds"...
1694                         if (remainingTimeoutTime > 0)
1695                                 return retStr;
1696                         else
1697                                 return "";
1698                 }
1699         }
1700         else return "";
1701 }
1702
1703 void player_powerups (void)
1704 {
1705         if((self.items & IT_USING_JETPACK) && !self.deadflag)
1706         {
1707                 SoundEntity_StartSound(self, CHAN_PLAYER, "misc/jetpack_fly.wav", VOL_BASE, cvar("g_jetpack_attenuation"));
1708                 self.modelflags |= MF_ROCKET;
1709         }
1710         else
1711         {
1712                 SoundEntity_StopSound(self, CHAN_PLAYER);
1713                 self.modelflags &~= MF_ROCKET;
1714         }
1715
1716         self.effects &~= (EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1717
1718         if(!self.modelindex || self.deadflag) // don't apply the flags if the player is gibbed
1719                 return;
1720
1721         if (g_minstagib)
1722         {
1723                 self.effects |= EF_FULLBRIGHT;
1724
1725                 if (self.items & IT_STRENGTH)
1726                 {
1727                         play_countdown(self.strength_finished, "misc/poweroff.wav");
1728                         if (time > self.strength_finished)
1729                         {
1730                                 self.alpha = default_player_alpha;
1731                                 self.exteriorweaponentity.alpha = default_weapon_alpha;
1732                                 self.items &~= IT_STRENGTH;
1733                                 sprint(self, "^3Invisibility has worn off\n");
1734                         }
1735                 }
1736                 else
1737                 {
1738                         if (time < self.strength_finished)
1739                         {
1740                                 self.alpha = g_minstagib_invis_alpha;
1741                                 self.exteriorweaponentity.alpha = g_minstagib_invis_alpha;
1742                                 self.items |= IT_STRENGTH;
1743                                 sprint(self, "^3You are invisible\n");
1744                         }
1745                 }
1746
1747                 if (self.items & IT_INVINCIBLE)
1748                 {
1749                         play_countdown(self.invincible_finished, "misc/poweroff.wav");
1750                         if (time > self.invincible_finished)
1751                         {
1752                                 self.items = self.items - (self.items & IT_INVINCIBLE);
1753                                 sprint(self, "^3Speed has worn off\n");
1754                         }
1755                 }
1756                 else
1757                 {
1758                         if (time < self.invincible_finished)
1759                         {
1760                                 self.items = self.items | IT_INVINCIBLE;
1761                                 sprint(self, "^3You are on speed\n");
1762                         }
1763                 }
1764                 return;
1765         }
1766
1767         if (self.items & IT_STRENGTH)
1768         {
1769                 play_countdown(self.strength_finished, "misc/poweroff.wav");
1770                 self.effects = self.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1771                 if (time > self.strength_finished)
1772                 {
1773                         self.items = self.items - (self.items & IT_STRENGTH);
1774                         sprint(self, "^3Strength has worn off\n");
1775                 }
1776         }
1777         else
1778         {
1779                 if (time < self.strength_finished)
1780                 {
1781                         self.items = self.items | IT_STRENGTH;
1782                         sprint(self, "^3Strength infuses your weapons with devastating power\n");
1783                 }
1784         }
1785         if (self.items & IT_INVINCIBLE)
1786         {
1787                 play_countdown(self.invincible_finished, "misc/poweroff.wav");
1788                 self.effects = self.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1789                 if (time > self.invincible_finished)
1790                 {
1791                         self.items = self.items - (self.items & IT_INVINCIBLE);
1792                         sprint(self, "^3Shield has worn off\n");
1793                 }
1794         }
1795         else
1796         {
1797                 if (time < self.invincible_finished)
1798                 {
1799                         self.items = self.items | IT_INVINCIBLE;
1800                         sprint(self, "^3Shield surrounds you\n");
1801                 }
1802         }
1803
1804         if (cvar("g_fullbrightplayers"))
1805                 self.effects = self.effects | EF_FULLBRIGHT;
1806
1807         // midair gamemode: damage only while in the air
1808         // if in midair mode, being on ground grants temporary invulnerability
1809         // (this is so that multishot weapon don't clear the ground flag on the
1810         // first damage in the frame, leaving the player vulnerable to the
1811         // remaining hits in the same frame)
1812         if (self.flags & FL_ONGROUND)
1813         if (g_midair)
1814                 self.spawnshieldtime = max(self.spawnshieldtime, time + cvar("g_midair_shieldtime"));
1815
1816         if (time >= game_starttime)
1817         if (time < self.spawnshieldtime)
1818                 self.effects = self.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1819 }
1820
1821 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
1822 {
1823         if(current > stable)
1824                 return current;
1825         else if(current > stable - 0.25) // when close enough, "snap"
1826                 return stable;
1827         else
1828                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
1829 }
1830
1831 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
1832 {
1833         if(current < stable)
1834                 return current;
1835         else if(current < stable + 0.25) // when close enough, "snap"
1836                 return stable;
1837         else
1838                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
1839 }
1840
1841 float CalcRotRegen(float current, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit)
1842 {
1843         if(current > rotstable)
1844         {
1845                 if(rotframetime > 0)
1846                 {
1847                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
1848                         current = max(rotstable, current - rotlinear * rotframetime);
1849                 }
1850         }
1851         else if(current < regenstable)
1852         {
1853                 if(regenframetime > 0)
1854                 {
1855                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
1856                         current = min(regenstable, current + regenlinear * regenframetime);
1857                 }
1858         }
1859
1860         if(current > limit)
1861                 current = limit;
1862
1863         return current;
1864 }
1865
1866 void player_regen (void)
1867 {
1868         float minh, mina, minf, maxh, maxa, maxf, limith, limita, limitf, max_mod, regen_mod, rot_mod, limit_mod;
1869         maxh = cvar("g_balance_health_rotstable");
1870         maxa = cvar("g_balance_armor_rotstable");
1871         maxf = cvar("g_balance_fuel_rotstable");
1872         minh = cvar("g_balance_health_regenstable");
1873         mina = cvar("g_balance_armor_regenstable");
1874         minf = cvar("g_balance_fuel_regenstable");
1875         limith = cvar("g_balance_health_limit");
1876         limita = cvar("g_balance_armor_limit");
1877         limitf = cvar("g_balance_fuel_limit");
1878
1879         max_mod = regen_mod = rot_mod = limit_mod = 1;
1880
1881         if (self.runes & RUNE_REGEN)
1882         {
1883                 if (self.runes & CURSE_VENOM) // do we have both rune/curse?
1884                 {
1885                         regen_mod = cvar("g_balance_rune_regen_combo_regenrate");
1886                         max_mod = cvar("g_balance_rune_regen_combo_hpmod");
1887                         limit_mod = cvar("g_balance_rune_regen_combo_limitmod");
1888                 }
1889                 else
1890                 {
1891                         regen_mod = cvar("g_balance_rune_regen_regenrate");
1892                         max_mod = cvar("g_balance_rune_regen_hpmod");
1893                         limit_mod = cvar("g_balance_rune_regen_limitmod");
1894                 }
1895         }
1896         else if (self.runes & CURSE_VENOM)
1897         {
1898                 max_mod = cvar("g_balance_curse_venom_hpmod");
1899                 if (self.runes & RUNE_REGEN) // do we have both rune/curse?
1900                         rot_mod = cvar("g_balance_rune_regen_combo_rotrate");
1901                 else
1902                         rot_mod = cvar("g_balance_curse_venom_rotrate");
1903                 limit_mod = cvar("g_balance_curse_venom_limitmod");
1904                 //if (!self.runes & RUNE_REGEN)
1905                 //      rot_mod = cvar("g_balance_curse_venom_rotrate");
1906         }
1907         maxh = maxh * max_mod;
1908         //maxa = maxa * max_mod;
1909         //maxf = maxf * max_mod;
1910         minh = minh * max_mod;
1911         //mina = mina * max_mod;
1912         //minf = minf * max_mod;
1913         limith = limith * limit_mod;
1914         limita = limita * limit_mod;
1915         //limitf = limitf * limit_mod;
1916
1917         if(g_lms)
1918                 rot_mod = 0;
1919
1920         if (!g_minstagib && (!g_lms || cvar("g_lms_regenerate")))
1921         {
1922                 self.armorvalue = CalcRotRegen(self.armorvalue, mina, cvar("g_balance_armor_regen"), cvar("g_balance_armor_regenlinear"), regen_mod * frametime * (time > self.pauseregen_finished), maxa, cvar("g_balance_armor_rot"), cvar("g_balance_armor_rotlinear"), rot_mod * frametime * (time > self.pauserotarmor_finished), limita);
1923                 self.health = CalcRotRegen(self.health, minh, cvar("g_balance_health_regen"), cvar("g_balance_health_regenlinear"), regen_mod * frametime * (time > self.pauseregen_finished), maxh, cvar("g_balance_health_rot"), cvar("g_balance_health_rotlinear"), rot_mod * frametime * (time > self.pauserothealth_finished), limith);
1924
1925                 // if player rotted to death...  die!
1926                 if(self.health < 1)
1927                         self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
1928         }
1929
1930         self.ammo_fuel = CalcRotRegen(self.ammo_fuel, minf, cvar("g_balance_fuel_regen"), cvar("g_balance_fuel_regenlinear"), regen_mod * frametime * (time > self.pauseregen_finished) * (self.items & IT_FUEL_REGEN != 0), maxf, cvar("g_balance_fuel_rot"), cvar("g_balance_fuel_rotlinear"), rot_mod * frametime * (time > self.pauserotfuel_finished), limitf);
1931 }
1932
1933 float zoomstate_set;
1934 void SetZoomState(float z)
1935 {
1936         if(z != self.zoomstate)
1937         {
1938                 self.zoomstate = z;
1939                 ClientData_Touch(self);
1940         }
1941         zoomstate_set = 1;
1942 }
1943
1944 void GetPressedKeys(void) {
1945         if (self.movement_x > 0) // get if movement keys are pressed
1946         {       // forward key pressed
1947                 self.pressedkeys |= KEY_FORWARD;
1948                 self.pressedkeys &~= KEY_BACKWARD;
1949         }
1950         else if (self.movement_x < 0)
1951         {       // backward key pressed
1952                 self.pressedkeys |= KEY_BACKWARD;
1953                 self.pressedkeys &~= KEY_FORWARD;
1954         }
1955         else
1956         {       // no x input
1957                 self.pressedkeys &~= KEY_FORWARD;
1958                 self.pressedkeys &~= KEY_BACKWARD;
1959         }
1960
1961         if (self.movement_y > 0)
1962         {       // right key pressed
1963                 self.pressedkeys |= KEY_RIGHT;
1964                 self.pressedkeys &~= KEY_LEFT;
1965         }
1966         else if (self.movement_y < 0)
1967         {       // left key pressed
1968                 self.pressedkeys |= KEY_LEFT;
1969                 self.pressedkeys &~= KEY_RIGHT;
1970         }
1971         else
1972         {       // no y input
1973                 self.pressedkeys &~= KEY_RIGHT;
1974                 self.pressedkeys &~= KEY_LEFT;
1975         }
1976
1977         if (self.BUTTON_JUMP) // get if jump and crouch keys are pressed
1978                 self.pressedkeys |= KEY_JUMP;
1979         else
1980                 self.pressedkeys &~= KEY_JUMP;
1981         if (self.BUTTON_CROUCH)
1982                 self.pressedkeys |= KEY_CROUCH;
1983         else
1984                 self.pressedkeys &~= KEY_CROUCH;
1985 }
1986
1987 /*
1988 ======================
1989 spectate mode routines
1990 ======================
1991 */
1992 void SpectateCopy(entity spectatee) {
1993         self.armortype = spectatee.armortype;
1994         self.armorvalue = spectatee.armorvalue;
1995         self.ammo_cells = spectatee.ammo_cells;
1996         self.ammo_shells = spectatee.ammo_shells;
1997         self.ammo_nails = spectatee.ammo_nails;
1998         self.ammo_rockets = spectatee.ammo_rockets;
1999         self.ammo_fuel = spectatee.ammo_fuel;
2000         self.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
2001         self.health = spectatee.health;
2002         self.impulse = 0;
2003         self.items = spectatee.items;
2004         self.metertime = spectatee.metertime;
2005         self.strength_finished = spectatee.strength_finished;
2006         self.invincible_finished = spectatee.invincible_finished;
2007         self.pressedkeys = spectatee.pressedkeys;
2008         self.weapons = spectatee.weapons;
2009         self.switchweapon = spectatee.switchweapon;
2010         self.weapon = spectatee.weapon;
2011         self.punchangle = spectatee.punchangle;
2012         self.view_ofs = spectatee.view_ofs;
2013         self.v_angle = spectatee.v_angle;
2014         self.velocity = spectatee.velocity;
2015         self.dmg_take = spectatee.dmg_take;
2016         self.dmg_save = spectatee.dmg_save;
2017         self.dmg_inflictor = spectatee.dmg_inflictor;
2018         self.angles = spectatee.v_angle;
2019         self.fixangle = TRUE;
2020         setorigin(self, spectatee.origin);
2021         setsize(self, spectatee.mins, spectatee.maxs);
2022         SetZoomState(spectatee.zoomstate);
2023 }
2024
2025 float SpectateUpdate() {
2026         if(!self.enemy)
2027                 return 0;
2028
2029         if (self == self.enemy)
2030                 return 0;
2031
2032         if(self.enemy.classname != "player")
2033                 return 0;
2034
2035         SpectateCopy(self.enemy);
2036
2037         return 1;
2038 }
2039
2040 float SpectateNext() {
2041         other = find(self.enemy, classname, "player");
2042         if (!other) {
2043                 other = find(other, classname, "player");
2044         }
2045         if (other) {
2046                 self.enemy = other;
2047         }
2048         if(self.enemy.classname == "player") {
2049                 msg_entity = self;
2050                 WriteByte(MSG_ONE, SVC_SETVIEW);
2051                 WriteEntity(MSG_ONE, self.enemy);
2052                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
2053                 self.movetype = MOVETYPE_NONE;
2054                 if(!SpectateUpdate())
2055                         PutObserverInServer();
2056                 return 1;
2057         } else {
2058                 return 0;
2059         }
2060 }
2061
2062 /*
2063 =============
2064 ShowRespawnCountdown()
2065
2066 Update a respawn countdown display.
2067 =============
2068 */
2069 void ShowRespawnCountdown()
2070 {
2071         float number;
2072         if(self.deadflag == DEAD_NO) // just respawned?
2073                 return;
2074         else
2075         {
2076                 number = ceil(self.death_time - time);
2077                 if(number <= 0)
2078                         return;
2079                 if(number <= self.respawn_countdown)
2080                 {
2081                         self.respawn_countdown = number - 1;
2082                         if(ceil(self.death_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
2083                                 announce(self, strcat("announcer/robotic/", ftos(number), ".wav"));
2084                 }
2085         }
2086 }
2087
2088 void LeaveSpectatorMode()
2089 {
2090         if(isJoinAllowed()) {
2091                 if(!teams_matter || cvar("g_campaign") || cvar("g_balance_teams") || (self.wasplayer && cvar("g_changeteam_banned"))) {
2092                         self.classname = "player";
2093                         if(cvar("g_campaign") || cvar("g_balance_teams") || cvar("g_balance_teams_force"))
2094                                 JoinBestTeam(self, FALSE, TRUE);
2095                         if(cvar("g_campaign"))
2096                                 campaign_bots_may_start = 1;
2097                         PutClientInServer();
2098                         if(self.classname == "player")
2099                                 bprint ("^4", self.netname, "^4 is playing now\n");
2100                         if(!cvar("g_campaign"))
2101                                 centerprint(self,""); // clear MOTD
2102                         return;
2103                 } else {
2104                         stuffcmd(self,"menu_showteamselect\n");
2105                         return;
2106                 }
2107         }
2108         else {
2109                 //player may not join because of g_maxplayers is set
2110                 centerprint_atprio(self, CENTERPRIO_MAPVOTE, PREVENT_JOIN_TEXT);
2111         }
2112 }
2113
2114 /**
2115  * Determines whether the player is allowed to join. This depends on cvar
2116  * g_maxplayers, if it isn't used this function always return TRUE, otherwise
2117  * it checks whether the number of currently playing players exceeds g_maxplayers.
2118  * @return bool TRUE if the player is allowed to join, false otherwise
2119  */
2120 float isJoinAllowed() {
2121         if (!cvar("g_maxplayers"))
2122                 return TRUE;
2123
2124         local entity e;
2125         local float currentlyPlaying;
2126         FOR_EACH_REALPLAYER(e) {
2127                 if(e.classname == "player")
2128                         currentlyPlaying += 1;
2129         }
2130         if(currentlyPlaying < cvar("g_maxplayers"))
2131                 return TRUE;
2132
2133         return FALSE;
2134 }
2135
2136 /**
2137  * Checks whether the client is an observer or spectator, if so, he will get kicked after
2138  * g_maxplayers_spectator_blocktime seconds
2139  */
2140 void checkSpectatorBlock() {
2141         if(self.classname == "spectator" || self.classname == "observer") {
2142                 if( time > (self.spectatortime + cvar("g_maxplayers_spectator_blocktime")) ) {
2143                         sprint(self, "^7You were kicked from the server because you are spectator and spectators aren't allowed at the moment.\n");
2144                         dropclient(self);
2145                 }
2146         }
2147 }
2148
2149 float vercmp_recursive(string v1, string v2)
2150 {
2151         float dot1, dot2;
2152         string s1, s2;
2153         float r;
2154
2155         dot1 = strstrofs(v1, ".", 0);
2156         dot2 = strstrofs(v2, ".", 0);
2157         if(dot1 == -1)
2158                 s1 = v1;
2159         else
2160                 s1 = substring(v1, 0, dot1);
2161         if(dot2 == -1)
2162                 s2 = v2;
2163         else
2164                 s2 = substring(v2, 0, dot2);
2165
2166         r = stof(s1) - stof(s2);
2167         if(r != 0)
2168                 return r;
2169
2170         r = strcasecmp(s1, s2);
2171         if(r != 0)
2172                 return r;
2173
2174         if(dot1 == -1)
2175                 if(dot2 == -1)
2176                         return 0;
2177                 else
2178                         return -1;
2179         else
2180                 if(dot2 == -1)
2181                         return 1;
2182                 else
2183                         return vercmp_recursive(substring(v1, dot1 + 1, 999), substring(v2, dot2 + 1, 999));
2184 }
2185
2186 float vercmp(string v1, string v2)
2187 {
2188         if(strcasecmp(v1, v2) == 0) // early out check
2189                 return 0;
2190         return vercmp_recursive(v1, v2);
2191 }
2192
2193 void ObserverThink()
2194 {
2195         if (self.flags & FL_JUMPRELEASED) {
2196                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2197                         self.welcomemessage_time = 0;
2198                         self.flags &~= FL_JUMPRELEASED;
2199                         self.flags |= FL_SPAWNING;
2200                 } else if(self.BUTTON_ATCK && !self.version_mismatch) {
2201                         self.welcomemessage_time = 0;
2202                         self.flags &~= FL_JUMPRELEASED;
2203                         if(SpectateNext() == 1) {
2204                                 self.classname = "spectator";
2205                         }
2206                 }
2207         } else {
2208                 if (!(self.BUTTON_ATCK || self.BUTTON_JUMP)) {
2209                         self.flags |= FL_JUMPRELEASED;
2210                         if(self.flags & FL_SPAWNING)
2211                         {
2212                                 self.flags &~= FL_SPAWNING;
2213                                 LeaveSpectatorMode();
2214                                 return;
2215                         }
2216                 }
2217         }
2218         PrintWelcomeMessage(self);
2219 }
2220
2221 void SpectatorThink()
2222 {
2223         if (self.flags & FL_JUMPRELEASED) {
2224                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2225                         self.welcomemessage_time = 0;
2226                         self.flags &~= FL_JUMPRELEASED;
2227                         self.flags |= FL_SPAWNING;
2228                 } else if(self.BUTTON_ATCK) {
2229                         self.welcomemessage_time = 0;
2230                         self.flags &~= FL_JUMPRELEASED;
2231                         if(SpectateNext() == 1) {
2232                                 self.classname = "spectator";
2233                         } else {
2234                                 self.classname = "observer";
2235                                 PutClientInServer();
2236                         }
2237                 } else if (self.BUTTON_ATCK2) {
2238                         self.welcomemessage_time = 0;
2239                         self.flags &~= FL_JUMPRELEASED;
2240                         self.classname = "observer";
2241                         PutClientInServer();
2242                 } else {
2243                         if(!SpectateUpdate())
2244                                 PutObserverInServer();
2245                 }
2246         } else {
2247                 if (!(self.BUTTON_ATCK || self.BUTTON_ATCK2)) {
2248                         self.flags |= FL_JUMPRELEASED;
2249                         if(self.flags & FL_SPAWNING)
2250                         {
2251                                 self.flags &~= FL_SPAWNING;
2252                                 LeaveSpectatorMode();
2253                                 return;
2254                         }
2255                 }
2256         }
2257         PrintWelcomeMessage(self);
2258         self.flags |= FL_CLIENT | FL_NOTARGET;
2259 }
2260
2261 .float touchexplode_time;
2262
2263 /*
2264 =============
2265 PlayerPreThink
2266
2267 Called every frame for each client before the physics are run
2268 =============
2269 */
2270 void() ctf_setstatus;
2271 void() nexball_setstatus;
2272 .float items_added;
2273 void PlayerPreThink (void)
2274 {
2275         self.stat_game_starttime = game_starttime;
2276         self.stat_allow_oldnexbeam = cvar("g_allow_oldnexbeam");
2277         self.stat_leadlimit = cvar("leadlimit");
2278
2279         if(blockSpectators && frametime)
2280                 // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2281                 checkSpectatorBlock();
2282
2283         zoomstate_set = 0;
2284
2285         if(self.netname_previous != self.netname)
2286         {
2287                 if(cvar("sv_eventlog"))
2288                         GameLogEcho(strcat(":name:", ftos(self.playerid), ":", self.netname));
2289                 if(self.netname_previous)
2290                         strunzone(self.netname_previous);
2291                 self.netname_previous = strzone(self.netname);
2292         }
2293
2294         // version nagging
2295         if(self.version_nagtime)
2296                 if(self.cvar_g_nexuizversion)
2297                         if(time > self.version_nagtime)
2298                         {
2299                                 if(strstr(self.cvar_g_nexuizversion, "svn", 0) < 0)
2300                                 {
2301                                         if(strstr(cvar_string("g_nexuizversion"), "svn", 0) >= 0)
2302                                         {
2303                                                 dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Nexuiz ", cvar_string("g_nexuizversion"), " (beta)^7, you have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1\n");
2304                                                 sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Nexuiz ", cvar_string("g_nexuizversion"), " (beta)^7, you have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1\n"));
2305                                         }
2306                                         else
2307                                         {
2308                                                 float r;
2309                                                 r = vercmp(self.cvar_g_nexuizversion, cvar_string("g_nexuizversion"));
2310                                                 if(r < 0)
2311                                                 {
2312                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - ^3Nexuiz ", cvar_string("g_nexuizversion"), "^7 is out, and you still have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1 - get the update from ^4http://www.nexuiz.com/^1!\n");
2313                                                         sprint(self, strcat("\{1}^1NOTE: ^3Nexuiz ", cvar_string("g_nexuizversion"), "^7 is out, and you still have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1 - get the update from ^4http://www.nexuiz.com/^1!\n"));
2314                                                 }
2315                                                 else if(r > 0)
2316                                                 {
2317                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Nexuiz ", cvar_string("g_nexuizversion"), "^7, you have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1\n");
2318                                                         sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Nexuiz ", cvar_string("g_nexuizversion"), "^7, you have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1\n"));
2319                                                 }
2320                                         }
2321                                 }
2322                                 self.version_nagtime = 0;
2323                         }
2324
2325         // GOD MODE info
2326         if(!(self.flags & FL_GODMODE)) if(self.max_armorvalue)
2327         {
2328                 sprint(self, strcat("godmode saved you ", ftos(self.max_armorvalue), " units of damage, cheater!\n"));
2329                 self.max_armorvalue = 0;
2330         }
2331
2332         if(frametime)
2333                 antilag_record(self);
2334
2335         if(self.classname == "player") {
2336 //              if(self.netname == "Wazat")
2337 //                      bprint(self.classname, "\n");
2338
2339                 CheckRules_Player();
2340
2341                 PrintWelcomeMessage(self);
2342
2343                 if (intermission_running)
2344                 {
2345                         IntermissionThink ();   // otherwise a button could be missed between
2346                         return;                                 // the think tics
2347                 }
2348
2349                 if(self.teleport_time)
2350                 if(time > self.teleport_time)
2351                 {
2352                         self.teleport_time = 0;
2353                         self.effects = self.effects - (self.effects & EF_NODRAW);
2354                 }
2355
2356                 Nixnex_GiveCurrentWeapon();
2357
2358                 if(frametime > 0) // don't do this in cl_movement frames, just in server ticks
2359                         UpdateSelectedPlayer();
2360
2361                 //don't allow the player to turn around while game is paused!
2362                 if(timeoutStatus == 2) {
2363                         self.v_angle = self.lastV_angle;
2364                         self.angles = self.lastV_angle;
2365                         self.fixangle = TRUE;
2366                 }
2367
2368                 if(frametime)
2369                         player_powerups();
2370
2371                 if (self.deadflag != DEAD_NO)
2372                 {
2373                         float button_pressed, force_respawn;
2374                         if(frametime)
2375                                 player_anim();
2376                         button_pressed = (self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE);
2377                         force_respawn = (g_lms || cvar("g_forced_respawn"));
2378                         if (self.deadflag == DEAD_DYING)
2379                         {
2380                                 if(force_respawn)
2381                                         self.deadflag = DEAD_RESPAWNING;
2382                                 else if(!button_pressed)
2383                                         self.deadflag = DEAD_DEAD;
2384                         }
2385                         else if (self.deadflag == DEAD_DEAD)
2386                         {
2387                                 if(button_pressed)
2388                                         self.deadflag = DEAD_RESPAWNABLE;
2389                         }
2390                         else if (self.deadflag == DEAD_RESPAWNABLE)
2391                         {
2392                                 if(!button_pressed)
2393                                         self.deadflag = DEAD_RESPAWNING;
2394                         }
2395                         else if (self.deadflag == DEAD_RESPAWNING)
2396                         {
2397                                 if(time > self.death_time)
2398                                 {
2399                                         self.death_time = time + 1; // only retry once a second
2400                                         respawn();
2401                                 }
2402                         }
2403                         ShowRespawnCountdown();
2404                         return;
2405                 }
2406
2407                 if(g_touchexplode)
2408                 if(time > self.touchexplode_time)
2409                 if(self.classname == "player")
2410                 if(self.deadflag == DEAD_NO)
2411                 if not(IS_INDEPENDENT_PLAYER(self))
2412                 FOR_EACH_PLAYER(other) if(self != other)
2413                 {
2414                         if(time > other.touchexplode_time)
2415                         if(other.classname == "player")
2416                         if(other.deadflag == DEAD_NO)
2417                         if not(IS_INDEPENDENT_PLAYER(other))
2418                         if(boxesoverlap(self.absmin, self.absmax, other.absmin, other.absmax))
2419                         {
2420                                 PlayerTouchExplode(self, other);
2421                                 self.touchexplode_time = other.touchexplode_time = time + 0.2;
2422                         }
2423                 }
2424
2425                 if(g_lms && !self.deadflag && cvar("g_lms_campcheck_interval"))
2426                 {
2427                         vector dist;
2428
2429                         // calculate player movement (in 2 dimensions only, so jumping on one spot doesn't count as movement)
2430                         dist = self.prevorigin - self.origin;
2431                         dist_z = 0;
2432                         self.lms_traveled_distance += fabs(vlen(dist));
2433
2434                         if((cvar("g_campaign") && !campaign_bots_may_start) || (time < game_starttime))
2435                         {
2436                                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval")*2;
2437                                 self.lms_traveled_distance = 0;
2438                         }
2439
2440                         if(time > self.lms_nextcheck)
2441                         {
2442                                 //sprint(self, "distance: ", ftos(self.lms_traveled_distance), "\n");
2443                                 if(self.lms_traveled_distance < cvar("g_lms_campcheck_distance"))
2444                                 {
2445                                         centerprint(self, cvar_string("g_lms_campcheck_message"));
2446                                         // FIXME KadaverJack: gibbing player here causes playermodel to bounce around, instead of eye.md3
2447                                         // I wasn't able to find out WHY that happens, so I put a workaround in place that shall prevent players from being gibbed :(
2448                                         Damage(self, self, self, bound(0, cvar("g_lms_campcheck_damage"), self.health + self.armorvalue * cvar("g_balance_armor_blockpercent") + 5), DEATH_CAMP, self.origin, '0 0 0');
2449                                 }
2450                                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval");
2451                                 self.lms_traveled_distance = 0;
2452                         }
2453                 }
2454
2455                 self.prevorigin = self.origin;
2456
2457                 if ((self.BUTTON_CROUCH && !self.hook.state) || self.health <= g_bloodloss)
2458                 {
2459                         if (!self.crouch)
2460                         {
2461                                 self.crouch = TRUE;
2462                                 self.view_ofs = PL_CROUCH_VIEW_OFS;
2463                                 setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX);
2464                                 setanim(self, self.anim_duck, FALSE, TRUE, TRUE);
2465                         }
2466                 }
2467                 else
2468                 {
2469                         if (self.crouch)
2470                         {
2471                                 tracebox(self.origin, PL_MIN, PL_MAX, self.origin, FALSE, self);
2472                                 if (!trace_startsolid)
2473                                 {
2474                                         self.crouch = FALSE;
2475                                         self.view_ofs = PL_VIEW_OFS;
2476                                         setsize (self, PL_MIN, PL_MAX);
2477                                 }
2478                         }
2479                 }
2480
2481                 if(self.health <= g_bloodloss && self.deadflag == DEAD_NO)
2482                 {
2483                         if(self.bloodloss_timer < time)
2484                         {
2485                                 self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
2486                                 self.bloodloss_timer = time + 0.5 + random() * 0.5;
2487                         }
2488                 }
2489
2490                 FixPlayermodel();
2491
2492                 GrapplingHookFrame();
2493
2494                 if(frametime)
2495                 {
2496                         self.items &~= self.items_added;
2497
2498                         W_WeaponFrame();
2499
2500                         self.items_added = 0;
2501                         if(self.items & IT_JETPACK)
2502                                 if(self.items & IT_FUEL_REGEN || self.ammo_fuel >= 0.01)
2503                                         self.items_added |= IT_FUEL;
2504
2505                         self.items |= self.items_added;
2506                 }
2507
2508                 player_regen();
2509                 if(frametime)
2510                         player_anim();
2511
2512                 if (g_minstagib)
2513                         minstagib_ammocheck();
2514
2515                 ctf_setstatus();
2516                 kh_setstatus();
2517                 nexball_setstatus();
2518
2519                 self.dmg_team = max(0, self.dmg_team - cvar("g_teamdamage_resetspeed") * frametime);
2520
2521                 //self.angles_y=self.v_angle_y + 90;   // temp
2522
2523                 //if (TetrisPreFrame()) return;
2524         } else if(gameover) {
2525                 if (intermission_running)
2526                         IntermissionThink ();   // otherwise a button could be missed between
2527                 return;
2528         } else if(self.classname == "observer") {
2529                 ObserverThink();
2530         } else if(self.classname == "spectator") {
2531                 SpectatorThink();
2532         }
2533
2534         if(!zoomstate_set)
2535                 SetZoomState(self.BUTTON_ZOOM || (self.BUTTON_ATCK2 && self.weapon == WEP_NEX));
2536
2537         float oldspectatee_status;
2538         oldspectatee_status = self.spectatee_status;
2539         if(self.classname == "spectator")
2540                 self.spectatee_status = num_for_edict(self.enemy);
2541         else if(self.classname == "observer")
2542                 self.spectatee_status = num_for_edict(self);
2543         else
2544                 self.spectatee_status = 0;
2545         if(self.spectatee_status != oldspectatee_status)
2546         {
2547                 ClientData_Touch(self);
2548                 if(g_race || g_cts)
2549                         race_InitSpectator();
2550         }
2551
2552         if(self.teamkill_soundtime)
2553         if(time > self.teamkill_soundtime)
2554         {
2555                 self.teamkill_soundtime = 0;
2556
2557                 entity oldpusher, oldself;
2558
2559                 oldself = self; self = self.teamkill_soundsource;
2560                 oldpusher = self.pusher; self.pusher = oldself;
2561
2562                 PlayerSound(playersound_teamshoot, CHAN_VOICE, VOICETYPE_LASTATTACKER_ONLY);
2563
2564                 self.pusher = oldpusher;
2565                 self = oldself;
2566         }
2567
2568         if(self.taunt_soundtime)
2569         if(time > self.taunt_soundtime)
2570         {
2571                 self.taunt_soundtime = 0;
2572                 PlayerSound(playersound_taunt, CHAN_VOICE, VOICETYPE_AUTOTAUNT);
2573         }
2574
2575         target_voicescript_next(self);
2576 }
2577
2578 // on dragger:
2579 .entity dragentity;
2580 .float draggravity;
2581 .float dragspeed; // speed of mouse wheel action
2582 .float dragdistance; // distance of dragentity's draglocalvector from view_ofs
2583 .vector draglocalvector; // local attachment vector of the dragentity
2584 .float draglocalangle;
2585 // on draggee:
2586 .entity draggedby;
2587 .float dragmovetype;
2588 void Drag_Begin(entity dragger, entity draggee, vector touchpoint)
2589 {
2590         float tagscale;
2591
2592         draggee.dragmovetype = draggee.movetype;
2593         draggee.draggravity = draggee.gravity;
2594         draggee.movetype = MOVETYPE_WALK;
2595         draggee.gravity = 0.00001;
2596         draggee.flags &~= FL_ONGROUND;
2597         draggee.draggedby = dragger;
2598
2599         dragger.dragentity = draggee;
2600
2601         dragger.dragdistance = vlen(touchpoint - dragger.origin - dragger.view_ofs);
2602         dragger.draglocalangle = draggee.angles_y - dragger.v_angle_y;
2603         touchpoint = touchpoint - gettaginfo(draggee, 0);
2604         tagscale = pow(vlen(v_forward), -2);
2605         dragger.draglocalvector_x = touchpoint * v_forward * tagscale;
2606         dragger.draglocalvector_y = touchpoint * v_right * tagscale;
2607         dragger.draglocalvector_z = touchpoint * v_up * tagscale;
2608
2609         dragger.dragspeed = 64;
2610 }
2611
2612 void Drag_Finish(entity dragger)
2613 {
2614         entity draggee;
2615         draggee = dragger.dragentity;
2616         if(dragger)
2617                 dragger.dragentity = world;
2618         draggee.draggedby = world;
2619         draggee.movetype = draggee.dragmovetype;
2620         draggee.gravity = draggee.draggravity;
2621
2622         switch(draggee.movetype)
2623         {
2624                 case MOVETYPE_TOSS:
2625                 case MOVETYPE_WALK:
2626                 case MOVETYPE_STEP:
2627                 case MOVETYPE_FLYMISSILE:
2628                 case MOVETYPE_BOUNCE:
2629                 case MOVETYPE_BOUNCEMISSILE:
2630                         break;
2631                 default:
2632                         draggee.velocity = '0 0 0';
2633                         break;
2634         }
2635
2636         if((draggee.flags & FL_ITEM) && (vlen(draggee.velocity) < 32))
2637         {
2638                 draggee.velocity = '0 0 0';
2639                 draggee.flags |= FL_ONGROUND; // floating items are FUN
2640         }
2641 }
2642
2643 float Drag_IsDraggable(entity draggee)
2644 {
2645         // TODO add more checks for bad stuff here
2646         if(draggee.classname == "func_bobbing")
2647                 return FALSE;
2648         if(draggee.classname == "door") // FIXME find out why these must be excluded, or work around the problem (trying to drag these causes like 4 fps)
2649                 return FALSE;
2650         if(draggee.classname == "plat")
2651                 return FALSE;
2652         if(draggee.classname == "func_button")
2653                 return FALSE;
2654         if(draggee.model == "")
2655                 return FALSE;
2656         if(draggee.classname == "spectator")
2657                 return FALSE;
2658         if(draggee.classname == "observer")
2659                 return FALSE;
2660         if(draggee.classname == "exteriorweaponentity")
2661                 return FALSE;
2662
2663         return TRUE;
2664 }
2665
2666 float Drag_MayChangeAngles(entity draggee)
2667 {
2668         // TODO add more checks for bad stuff here
2669         if(substring(draggee.model, 0, 1) == "*")
2670                 return FALSE;
2671         return TRUE;
2672 }
2673
2674 void Drag_MoveForward(entity dragger)
2675 {
2676         dragger.dragdistance += dragger.dragspeed;
2677 }
2678
2679 void Drag_SetSpeed(entity dragger, float s)
2680 {
2681         dragger.dragspeed = pow(2, s);
2682 }
2683
2684 void Drag_MoveBackward(entity dragger)
2685 {
2686         dragger.dragdistance = max(0, dragger.dragdistance - dragger.dragspeed);
2687 }
2688
2689 void Drag_Update(entity dragger)
2690 {
2691         vector curorigin, neworigin, goodvelocity;
2692         float f;
2693         entity draggee;
2694
2695         draggee = dragger.dragentity;
2696         draggee.flags &~= FL_ONGROUND;
2697
2698         curorigin = gettaginfo(draggee, 0);
2699         curorigin = curorigin + v_forward * dragger.draglocalvector_x + v_right * dragger.draglocalvector_y + v_up * dragger.draglocalvector_z;
2700         makevectors(dragger.v_angle);
2701         neworigin = dragger.origin + dragger.view_ofs + v_forward * dragger.dragdistance;
2702         goodvelocity = (neworigin - curorigin) * (1 / frametime);
2703
2704         while(draggee.angles_y - dragger.v_angle_y - dragger.draglocalangle > 180)
2705                 dragger.draglocalangle += 360;
2706         while(draggee.angles_y - dragger.v_angle_y - dragger.draglocalangle <= -180)
2707                 dragger.draglocalangle -= 360;
2708
2709         f = min(frametime * 10, 1);
2710         draggee.velocity = draggee.velocity * (1 - f) + goodvelocity * f;
2711
2712         if(Drag_MayChangeAngles(draggee))
2713                 draggee.angles_y = draggee.angles_y * (1 - f) + (dragger.v_angle_y + dragger.draglocalangle) * f;
2714
2715         draggee.ltime = max(servertime + serverframetime, draggee.ltime); // fixes func_train breakage
2716
2717         te_lightning1(dragger, dragger.origin + dragger.view_ofs, curorigin);
2718 }
2719
2720 float Drag_CanDrag(entity dragger)
2721 {
2722         return (dragger.deadflag == DEAD_NO) || (dragger.classname == "player");
2723 }
2724
2725 float Drag_IsDragging(entity dragger)
2726 {
2727         if(!dragger.dragentity)
2728                 return FALSE;
2729         if(wasfreed(dragger.dragentity) || dragger.dragentity.draggedby != dragger)
2730         {
2731                 dragger.dragentity = world;
2732                 return FALSE;
2733         }
2734         if(!Drag_CanDrag(dragger) || !Drag_IsDraggable(dragger.dragentity))
2735         {
2736                 Drag_Finish(dragger);
2737                 return FALSE;
2738         }
2739         return TRUE;
2740 }
2741
2742 void Drag_MoveDrag(entity from, entity to)
2743 {
2744         if(from.draggedby)
2745         {
2746                 to.draggedby = from.draggedby;
2747                 to.draggedby.dragentity = to;
2748                 from.draggedby = world;
2749         }
2750 }
2751
2752 /*
2753 =============
2754 PlayerPostThink
2755
2756 Called every frame for each client after the physics are run
2757 =============
2758 */
2759 .float idlekick_lasttimeleft;
2760 void PlayerPostThink (void)
2761 {
2762         // Savage: Check for nameless players
2763         if (strlen(self.netname) < 1) {
2764                 self.netname = "Player";
2765                 stuffcmd(self, "seta _cl_name Player\n");
2766         }
2767
2768         if(sv_maxidle && frametime)
2769         {
2770                 // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2771                 float timeleft;
2772                 timeleft = ceil(sv_maxidle - (time - self.parm_idlesince));
2773                 if(timeleft <= 0)
2774                 {
2775                         bprint("^3", self.netname, "^3 was kicked for idling.\n");
2776                         announce(self, "announcer/robotic/terminated.wav");
2777                         dropclient(self);
2778                         return;
2779                 }
2780                 else if(timeleft <= 10)
2781                 {
2782                         if(timeleft != self.idlekick_lasttimeleft)
2783                         {
2784                                 centerprint_atprio(self, CENTERPRIO_IDLEKICK, strcat("^3Stop idling!\n^3Disconnecting in ", ftos(timeleft), "..."));
2785                                 announce(self, strcat("announcer/robotic/", ftos(timeleft), ".wav"));
2786                         }
2787                 }
2788                 else
2789                 {
2790                         centerprint_expire(self, CENTERPRIO_IDLEKICK);
2791                 }
2792                 self.idlekick_lasttimeleft = timeleft;
2793         }
2794
2795         if(sv_cheats || self.maycheat)
2796                 if(Drag_CanDrag(self))
2797                         if(self.BUTTON_DRAG)
2798                                 if(!self.dragentity)
2799                                         if(self.cursor_trace_ent)
2800                                                 if(Drag_IsDraggable(self.cursor_trace_ent))
2801                                                 {
2802                                                         if(self.cursor_trace_ent.draggedby)
2803                                                                 Drag_Finish(self.cursor_trace_ent.draggedby);
2804                                                         if(self.cursor_trace_ent.tag_entity)
2805                                                                 detach_sameorigin(self.cursor_trace_ent);
2806                                                         Drag_Begin(self, self.cursor_trace_ent, self.cursor_trace_endpos);
2807                                                 }
2808
2809         if(Drag_IsDragging(self))
2810         {
2811                 if(self.BUTTON_DRAG)
2812                 {
2813                         if(self.impulse == 10 || self.impulse == 15 || self.impulse == 18)
2814                         {
2815                                 Drag_MoveForward(self);
2816                                 self.impulse = 0;
2817                         }
2818                         else if(self.impulse == 12 || self.impulse == 16 || self.impulse == 19)
2819                         {
2820                                 Drag_MoveBackward(self);
2821                                 self.impulse = 0;
2822                         }
2823                         else if(self.impulse >= 1 && self.impulse <= 9)
2824                         {
2825                                 Drag_SetSpeed(self, self.impulse - 1);
2826                         }
2827                         else if(self.impulse == 14)
2828                         {
2829                                 Drag_SetSpeed(self, 9);
2830                         }
2831
2832                         if(frametime)
2833                                 Drag_Update(self);
2834                 }
2835                 else
2836                 {
2837                         Drag_Finish(self);
2838                 }
2839         }
2840
2841         if(self.classname == "player") {
2842                 CheckRules_Player();
2843                 UpdateChatBubble();
2844                 UpdateTeamBubble();
2845                 if (self.impulse)
2846                         ImpulseCommands();
2847                 if (intermission_running)
2848                         return;         // intermission or finale
2849
2850                 //if (TetrisPostFrame()) return;
2851
2852                 GetPressedKeys();
2853         } else if (self.classname == "observer") {
2854                 //do nothing
2855         } else if (self.classname == "spectator") {
2856                 //do nothing
2857         }
2858
2859         /*
2860         float i;
2861         for(i = 0; i < 1000; ++i)
2862         {
2863                 vector end;
2864                 end = self.origin + '0 0 1024' + 512 * randomvec();
2865                 tracebox(self.origin, self.mins, self.maxs, end, MOVE_NORMAL, self);
2866                 if(trace_fraction < 1)
2867                 if(!(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
2868                 {
2869                         print("I HIT SOLID: ", vtos(self.origin), " -> ", vtos(end), "\n");
2870                         break;
2871                 }
2872         }
2873         */
2874
2875         Arena_Warmup();
2876
2877         //pointparticles(particleeffectnum("machinegun_impact"), self.origin + self.view_ofs + '0 0 7', '0 0 0', 1);
2878
2879         if(self.waypointsprite_attachedforcarrier)
2880                 WaypointSprite_UpdateHealth(self.waypointsprite_attachedforcarrier, '1 0 0' * healtharmor_maxdamage(self.health, self.armorvalue, cvar("g_balance_armor_blockpercent")));
2881 }