data/qcsrc/server/cl_client.qc

   1 void info_player_start (void)
   2 {
   3         self.classname = "info_player_deathmatch";
   4         relocate_spawnpoint();
   5 }
   6
   7 void info_player_deathmatch (void)
   8 {
   9         relocate_spawnpoint();
  10 }
  11
  12 float spawn_allbad;
  13 float spawn_allgood;
  14 entity Spawn_FilterOutBadSpots(entity firstspot, entity playerlist, float mindist, float teamcheck)
  15 {
  16         local entity spot, player, nextspot, previousspot, newfirstspot;
  17         local float pcount;
  18         spot = firstspot;
  19         newfirstspot = world;
  20         previousspot = world;
  21         spawn_allgood = TRUE;
  22         spawn_allbad = TRUE;
  23         while (spot)
  24         {
  25                 nextspot = spot.chain;
  26                 // count team mismatches as bad spots
  27                 if (spot.team == teamcheck)
  28                 {
  29                         pcount = 0;
  30                         player = playerlist;
  31                         while (player)
  32                         {
  33                                 if (player != self)
  34                                 if (vlen(player.origin - spot.origin) < mindist)
  35                                         pcount = pcount + 1;
  36                                 player = player.chain;
  37                         }
  38                         if (!pcount)
  39                         {
  40                                 spawn_allbad = FALSE;
  41                                 if (newfirstspot)
  42                                         previousspot.chain = spot;
  43                                 else
  44                                         newfirstspot = spot;
  45                                 previousspot = spot;
  46                                 spot.chain = world;
  47                         }
  48                         else
  49                                 spawn_allgood = FALSE;
  50                 }
  51                 spot = nextspot;
  52         }
  53         // if we couldn't find ANY good points, return the original list
  54         if (!newfirstspot)
  55                 newfirstspot = firstspot;
  56         return newfirstspot;
  57 }
  58
  59 entity Spawn_RandomPoint(entity firstspot)
  60 {
  61         local entity spot;
  62         local float numspots;
  63         // count number of spots
  64         numspots = 0;
  65         spot = firstspot;
  66         while (spot)
  67         {
  68                 numspots = numspots + 1;
  69                 spot = spot.chain;
  70         }
  71         // pick a random one
  72         numspots = numspots * random();
  73         spot = firstspot;
  74         while (spot.chain && numspots >= 1)
  75         {
  76                 numspots = numspots - 1;
  77                 spot = spot.chain;
  78         }
  79         return spot;
  80 }
  81
  82 entity Spawn_FurthestPoint(entity firstspot, entity playerlist)
  83 {
  84         local entity best, spot, player;
  85         local float bestrating, rating;
  86         best = world;
  87         bestrating = -1000000;
  88         spot = firstspot;
  89         while (spot)
  90         {
  91                 rating = 1000000000;
  92                 player = playerlist;
  93                 while (player)
  94                 {
  95                         if (player != self)
  96                                 rating = min(rating, vlen(player.origin - spot.origin));
  97                         player = player.chain;
  98                 }
  99                 rating = rating + random() * 16;
 100                 if (bestrating < rating)
 101                 {
 102                         best = spot;
 103                         bestrating = rating;
 104                 }
 105                 spot = spot.chain;
 106         }
 107         return best;
 108 }
 109
 110 /*
 111 =============
 112 SelectSpawnPoint
 113
 114 Finds a point to respawn
 115 =============
 116 */
 117 entity SelectSpawnPoint (float anypoint)
 118 {
 119         local float teamcheck;
 120         local entity spot, firstspot, playerlist;
 121
 122         spot = find (world, classname, "testplayerstart");
 123         if (spot)
 124                 return spot;
 125
 126         teamcheck = 0;
 127
 128         if(!anypoint && cvar("g_ctf") )
 129                 teamcheck = self.team;
 130
 131         // get the list of players
 132         playerlist = findchain(classname, "player");
 133         // get the entire list of spots
 134         firstspot = findchain(classname, "info_player_deathmatch");
 135         // filter out the bad ones
 136         // (note this returns the original list if none survived)
 137         firstspot = Spawn_FilterOutBadSpots(firstspot, playerlist, 100, teamcheck);
 138
 139         // there is 50/50 chance of choosing a random spot or the furthest spot
 140         // (this means that roughly every other spawn will be furthest, so you
 141         // usually won't get fragged at spawn twice in a row)
 142         if (arena_roundbased)
 143         {
 144                 firstspot = Spawn_FilterOutBadSpots(firstspot, playerlist, 800, teamcheck);
 145                 spot = Spawn_RandomPoint(firstspot);
 146         }
 147         else if (random() > 0.5 || spawn_allbad || spawn_allgood)
 148                 spot = Spawn_RandomPoint(firstspot);
 149         else
 150                 spot = Spawn_FurthestPoint(firstspot, playerlist);
 151
 152         if (!spot)
 153         {
 154                 if(cvar("spawn_debug"))
 155                         GotoNextMap();
 156                 else
 157                         error ("PutClientInServer: no start points on level");
 158         }
 159
 160         return spot;
 161 }
 162
 163 /*
 164 =============
 165 CheckPlayerModel
 166
 167 Checks if the argument string can be a valid playermodel.
 168 Returns a valid one in doubt.
 169 =============
 170 */
 171 string FallbackPlayerModel = "models/player/marine.zym";
 172 string CheckPlayerModel(string plyermodel) {
 173         if(strlen(plyermodel) < 4)
 174                 return FallbackPlayerModel;
 175         if( substring(plyermodel,0,14) != "models/player/")
 176                 return FallbackPlayerModel;
 177         else if(cvar("sv_servermodelsonly"))
 178         {
 179                 if(substring(plyermodel,strlen(plyermodel)-4,4) != ".zym")
 180                         return FallbackPlayerModel;
 181                 if(!fexists(plyermodel))
 182                         return FallbackPlayerModel;
 183         }
 184         return plyermodel;
 185 }
 186
 187 /*
 188 =============
 189 Client_customizeentityforclient
 190
 191 LOD reduction
 192 =============
 193 */
 194 float Client_customizeentityforclient()
 195 {
 196 #ifdef ALLOW_VARIABLE_LOD
 197         // self: me
 198         // other: the player viewing me
 199         float distance;
 200         float f;
 201
 202         if(self.flags & FL_NOTARGET) // we don't need LOD for spectators
 203                 return TRUE;
 204
 205         if(other.cvar_cl_playerdetailreduction <= 0)
 206         {
 207                 if(other.cvar_cl_playerdetailreduction <= -2)
 208                         self.modelindex = self.modelindex_lod2;
 209                 else if(other.cvar_cl_playerdetailreduction <= -1)
 210                         self.modelindex = self.modelindex_lod1;
 211                 else
 212                         self.modelindex = self.modelindex_lod0;
 213         }
 214         else
 215         {
 216                 distance = vlen(self.origin - other.origin);
 217                 f = (distance + 100.0) * other.cvar_cl_playerdetailreduction;
 218                 if(f > 10000)
 219                         self.modelindex = self.modelindex_lod2;
 220                 else if(f > 5000)
 221                         self.modelindex = self.modelindex_lod1;
 222                 else
 223                         self.modelindex = self.modelindex_lod0;
 224         }
 225 #endif
 226
 227         return TRUE;
 228 }
 229
 230 void setmodel_lod(entity e, string modelname)
 231 {
 232 #ifdef ALLOW_VARIABLE_LOD
 233         string s;
 234
 235         s = strcat(substring(modelname, 0, strlen(modelname) - 4), "_1.zym");
 236         if(fexists(s))
 237         {
 238                 precache_model(s);
 239                 setmodel(e, s);
 240                 self.modelindex_lod1 = self.modelindex;
 241         }
 242         else
 243                 self.modelindex_lod1 = -1;
 244
 245         s = strcat(substring(modelname, 0, strlen(modelname) - 4), "_2.zym");
 246         if(fexists(s))
 247         {
 248                 precache_model(s);
 249                 setmodel(e, s);
 250                 self.modelindex_lod2 = self.modelindex;
 251         }
 252         else
 253                 self.modelindex_lod2 = -1;
 254
 255         precache_model(modelname);
 256         setmodel(e, modelname);
 257         self.modelindex_lod0 = self.modelindex;
 258
 259         if(self.modelindex_lod1 < 0)
 260                 self.modelindex_lod1 = self.modelindex;
 261
 262         if(self.modelindex_lod2 < 0)
 263                 self.modelindex_lod2 = self.modelindex;
 264 #else
 265         precache_model(modelname);
 266         setmodel(e, modelname);
 267 #endif
 268 }
 269
 270 /*
 271 =============
 272 PutObserverInServer
 273
 274 putting a client as observer in the server
 275 =============
 276 */
 277 void PutObserverInServer (void)
 278 {
 279         entity  spot;
 280         spot = SelectSpawnPoint (FALSE);
 281         RemoveGrapplingHook(self); // Wazat's Grappling Hook
 282
 283         if(clienttype(self) == CLIENTTYPE_REAL)
 284         {
 285                 msg_entity = self;
 286                 WriteByte(MSG_ONE, SVC_SETVIEW);
 287                 WriteEntity(MSG_ONE, self);
 288         }
 289
 290         if (cvar("g_runematch"))
 291                 DropAllRunes(self);
 292
 293         DistributeFragsAmongTeam(self, self.team, 1);
 294
 295         if(self.frags <= 0 && self.frags > -666 && cvar("g_lms") && self.killcount != -666)
 296                 bprint (strcat("^4", self.netname, "^4 has no more lives left\n"));
 297         else if(self.killcount != -666)
 298                 bprint (strcat("^4", self.netname, "^4 is spectating now\n"));
 299
 300         self.classname = "observer";
 301         self.health = -666;
 302         self.takedamage = DAMAGE_NO;
 303         self.solid = SOLID_NOT;
 304         self.movetype = MOVETYPE_NOCLIP;
 305         self.flags = FL_CLIENT | FL_NOTARGET;
 306         self.armorvalue = 666;
 307         self.effects = 0;
 308         self.armorvalue = cvar("g_balance_armor_start");
 309         self.pauserotarmor_finished = 0;
 310         self.pauserothealth_finished = 0;
 311         self.pauseregen_finished = 0;
 312         self.damageforcescale = 0;
 313         self.death_time = 0;
 314         self.dead_time = 0;
 315         self.dead_frame = 0;
 316         self.die_frame = 0;
 317         self.deaths = 0;
 318         self.alpha = 0;
 319         self.scale = 0;
 320         self.fade_time = 0;
 321         self.pain_frame = 0;
 322         self.pain_finished = 0;
 323         self.strength_finished = 0;
 324         self.invincible_finished = 0;
 325         self.pushltime = 0;
 326         self.think = SUB_Null;
 327         self.nextthink = 0;
 328         self.hook_time = 0;
 329         self.runes = 0;
 330         self.deadflag = DEAD_NO;
 331         self.angles = spot.angles;
 332         self.angles_z = 0;
 333         self.fixangle = TRUE;
 334         self.crouch = FALSE;
 335
 336         self.view_ofs = PL_VIEW_OFS;
 337         setorigin (self, spot.origin);
 338         setsize (self, '0 0 0', '0 0 0');
 339         self.oldorigin = self.origin;
 340         self.items = 0;
 341         self.model = "";
 342         self.modelindex = 0;
 343         self.weapon = 0;
 344         self.weaponmodel = "";
 345         self.weaponentity = world;
 346         self.killcount = -666;
 347         self.velocity = '0 0 0';
 348         self.avelocity = '0 0 0';
 349         self.punchangle = '0 0 0';
 350         self.punchvector = '0 0 0';
 351         self.oldvelocity = self.velocity;
 352         self.customizeentityforclient = Client_customizeentityforclient;
 353
 354         if(cvar("g_arena"))
 355         {
 356                 if(self.frags != -2)
 357                 {
 358                         Spawnqueue_Insert(self);
 359                 }
 360                 else
 361                 {
 362                         Spawnqueue_Unmark(self);
 363                         Spawnqueue_Remove(self);
 364                 }
 365         }
 366         else if(!cvar("g_lms"))
 367                 self.frags = -666;
 368 }
 369
 370
 371 /*
 372 =============
 373 PutClientInServer
 374
 375 Called when a client spawns in the server
 376 =============
 377 */
 378 void PutClientInServer (void)
 379 {
 380         if(clienttype(self) == CLIENTTYPE_BOT)
 381         {
 382                 self.classname = "player";
 383         }
 384         else if(clienttype(self) == CLIENTTYPE_REAL)
 385         {
 386                 msg_entity = self;
 387                 WriteByte(MSG_ONE, SVC_SETVIEW);
 388                 WriteEntity(MSG_ONE, self);
 389         }
 390
 391         // player is dead and becomes observer
 392         if(cvar("g_lms") && self.frags < 1)
 393                 self.classname = "observer";
 394
 395         if(cvar("g_arena"))
 396         if(!self.spawned)
 397                 self.classname = "observer";
 398
 399         if(self.classname == "player") {
 400                 entity  spot;
 401
 402                 spot = SelectSpawnPoint (FALSE);
 403
 404                 RemoveGrapplingHook(self); // Wazat's Grappling Hook
 405
 406                 self.classname = "player";
 407                 self.iscreature = TRUE;
 408                 self.movetype = MOVETYPE_WALK;
 409                 self.solid = SOLID_SLIDEBOX;
 410                 self.flags = FL_CLIENT;
 411                 self.takedamage = DAMAGE_AIM;
 412                 self.effects = 0;
 413                 self.health = cvar("g_balance_health_start");
 414                 self.armorvalue = cvar("g_balance_armor_start");
 415                 self.spawnshieldtime = time + cvar("g_spawnshieldtime");
 416                 self.pauserotarmor_finished = time + cvar("g_balance_pause_armor_rot_spawn");
 417                 self.pauserothealth_finished = time + cvar("g_balance_pause_health_rot_spawn");
 418                 self.pauseregen_finished = time + cvar("g_balance_pause_health_regen_spawn");
 419                 self.damageforcescale = 2;
 420                 self.death_time = 0;
 421                 self.dead_time = 0;
 422                 self.dead_frame = 0;
 423                 self.die_frame = 0;
 424                 self.alpha = 0;
 425                 self.scale = 0;
 426                 self.fade_time = 0;
 427                 self.pain_frame = 0;
 428                 self.pain_finished = 0;
 429                 self.strength_finished = 0;
 430                 self.invincible_finished = 0;
 431                 self.pushltime = 0;
 432                 //self.speed_finished = 0;
 433                 //self.slowmo_finished = 0;
 434                 // players have no think function
 435                 self.think = SUB_Null;
 436                 self.nextthink = 0;
 437                 self.weapon = 0;
 438                 self.switchweapon = 0;
 439                 self.hook_time = 0;
 440
 441                 self.runes = 0;
 442
 443                 self.deadflag = DEAD_NO;
 444
 445                 self.angles = spot.angles;
 446
 447                 self.angles_z = 0; // never spawn tilted even if the spot says to
 448                 self.fixangle = TRUE; // turn this way immediately
 449                 self.velocity = '0 0 0';
 450                 self.avelocity = '0 0 0';
 451                 self.punchangle = '0 0 0';
 452                 self.punchvector = '0 0 0';
 453                 self.oldvelocity = self.velocity;
 454
 455                 self.viewzoom = 0.6;
 456
 457                 self.customizeentityforclient = Client_customizeentityforclient;
 458
 459                 if(cvar("sv_defaultcharacter") == 1 && !teams_matter) {
 460                         local string defaultmodel;
 461                         defaultmodel = CheckPlayerModel(cvar_string("sv_defaultplayermodel"));
 462                         setmodel_lod (self, defaultmodel);
 463                         self.skin = stof(cvar_string("sv_defaultplayerskin"));
 464                 } else {
 465                         self.playermodel = CheckPlayerModel(self.playermodel);
 466                         setmodel_lod (self, self.playermodel);
 467                         self.skin = stof(self.playerskin);
 468
 469                 }
 470
 471                 self.crouch = FALSE;
 472                 self.view_ofs = PL_VIEW_OFS;
 473                 setsize (self, PL_MIN, PL_MAX);
 474                 self.spawnorigin = spot.origin;
 475                 setorigin (self, spot.origin + '0 0 1' * (1 - self.mins_z - 24));
 476                 // don't reset back to last position, even if new position is stuck in solid
 477                 self.oldorigin = self.origin;
 478
 479                 if(cvar("g_lms"))
 480                 {
 481                         self.ammo_shells = cvar("g_lms_start_ammo_shells");
 482                         self.ammo_nails = cvar("g_lms_start_ammo_nails");
 483                         self.ammo_rockets = cvar("g_lms_start_ammo_rockets");
 484                         self.ammo_cells = cvar("g_lms_start_ammo_cells");
 485                         self.health = cvar("g_lms_start_health");
 486                         self.armorvalue = cvar("g_lms_start_armor");
 487                 }
 488                 else if (cvar("g_use_ammunition")) {
 489                         self.ammo_shells = cvar("g_start_ammo_shells");
 490                         self.ammo_nails = cvar("g_start_ammo_nails");
 491                         self.ammo_rockets = cvar("g_start_ammo_rockets");
 492                         self.ammo_cells = cvar("g_start_ammo_cells");
 493                 } else {
 494                         self.ammo_shells = 999;
 495                         self.ammo_nails = 999;
 496                         self.ammo_rockets = 999;
 497                         self.ammo_cells = 999;
 498                 }
 499
 500                 self.items = 0;
 501                 if (cvar("g_start_weapon_laser") || cvar("g_lms"))
 502                 {
 503                         self.items = self.items | IT_LASER;
 504                         self.switchweapon = WEP_LASER;
 505                 }
 506                 if (cvar("g_start_weapon_shotgun") || cvar("g_lms"))
 507                 {
 508                         self.items = self.items | IT_SHOTGUN;
 509                         self.switchweapon = WEP_SHOTGUN;
 510                 }
 511                 if (cvar("g_start_weapon_uzi") || cvar("g_lms"))
 512                 {
 513                         self.items = self.items | IT_UZI;
 514                         self.switchweapon = WEP_UZI;
 515                 }
 516                 if (cvar("g_start_weapon_grenadelauncher") || cvar("g_lms"))
 517                 {
 518                         self.items = self.items | IT_GRENADE_LAUNCHER;
 519                         self.switchweapon = WEP_GRENADE_LAUNCHER;
 520                 }
 521                 if (cvar("g_start_weapon_electro") || cvar("g_lms"))
 522                 {
 523                         self.items = self.items | IT_ELECTRO;
 524                         self.switchweapon = WEP_ELECTRO;
 525                 }
 526                 if (cvar("g_start_weapon_crylink") || cvar("g_lms"))
 527                 {
 528                         self.items = self.items | IT_CRYLINK;
 529                         self.switchweapon = WEP_CRYLINK;
 530                 }
 531                 if (cvar("g_start_weapon_nex") || cvar("g_lms"))
 532                 {
 533                         self.items = self.items | IT_NEX;
 534                         self.switchweapon = WEP_NEX;
 535                 }
 536                 if (cvar("g_start_weapon_hagar") || cvar("g_lms"))
 537                 {
 538                         self.items = self.items | IT_HAGAR;
 539                         self.switchweapon = WEP_HAGAR;
 540                 }
 541                 if (cvar("g_start_weapon_rocketlauncher") || cvar("g_lms"))
 542                 {
 543                         self.items = self.items | IT_ROCKET_LAUNCHER;
 544                         self.switchweapon = WEP_ROCKET_LAUNCHER;
 545                 }
 546
 547                 if(cvar("g_instagib"))
 548                 {
 549                         self.items = IT_NEX;
 550                         self.switchweapon = WEP_NEX;
 551                         self.ammo_cells = 999;
 552                 }
 553
 554                 if(cvar("g_rocketarena"))
 555                 {
 556                         self.items = IT_ROCKET_LAUNCHER;
 557                         self.switchweapon = WEP_ROCKET_LAUNCHER;
 558                         self.ammo_rockets = 999;
 559                 }
 560
 561                 if(cvar("g_nixnex"))
 562                 {
 563                         self.items = 0;
 564                         // will be done later
 565                 }
 566
 567                 if(cvar("g_minstagib"))
 568                 {
 569                         self.health = 100;
 570                         self.armorvalue = 0;
 571                         self.items = IT_NEX;
 572                         self.switchweapon = WEP_NEX;
 573                         self.ammo_cells = cvar("g_minstagib_ammo_start");
 574                         self.jump_interval = time;
 575                 }
 576
 577                 if(cvar("g_arena"))
 578                 {
 579                         Spawnqueue_Remove(self);
 580                         Spawnqueue_Mark(self);
 581                 }
 582
 583                 self.event_damage = PlayerDamage;
 584
 585                 self.bot_attack = TRUE;
 586
 587                 self.statdraintime = time + 5;
 588                 self.button0 = self.button1 = self.button2 = self.button3 = 0;
 589
 590                 if(self.killcount == -666) {
 591                         self.killcount = 0;
 592                         if(!cvar("g_arena"))
 593                         if(!cvar("g_lms"))
 594                                 self.frags = 0;
 595                 }
 596
 597                 self.cnt = WEP_LASER;
 598                 self.nixnex_lastchange_id = -1;
 599
 600                 CL_SpawnWeaponentity();
 601                 self.alpha = default_player_alpha;
 602                 self.exteriorweaponentity.alpha = default_weapon_alpha;
 603
 604                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval")*2;
 605                 self.lms_traveled_distance = 0;
 606
 607                 if(cvar("spawn_debug"))
 608                 {
 609                                 sprint(self, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 610                                 remove(spot);   // usefull for checking if there are spawnpoints, that let drop through the floor
 611                 }
 612
 613                 //stuffcmd(self, "chase_active 0");
 614                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
 615         } else if(self.classname == "observer") {
 616                 PutObserverInServer ();
 617         }
 618 }
 619
 620 /*
 621 =============
 622 SetNewParms
 623 =============
 624 */
 625 void SetNewParms (void)
 626 {
 627
 628 }
 629
 630 /*
 631 =============
 632 SetChangeParms
 633 =============
 634 */
 635 void SetChangeParms (void)
 636 {
 637
 638 }
 639
 640 /*
 641 =============
 642 ClientKill
 643
 644 Called when a client types 'kill' in the console
 645 =============
 646 */
 647 void ClientKill (void)
 648 {
 649         Damage(self, self, self, 100000, DEATH_KILL, self.origin, '0 0 0');
 650 }
 651
 652 /*
 653 =============
 654 ClientConnect
 655
 656 Called when a client connects to the server
 657 =============
 658 */
 659 string ColoredTeamName(float t);
 660 //void dom_player_join_team(entity pl);
 661 void ClientConnect (void)
 662 {
 663         //local float fh;
 664         local string s;
 665
 666         self.classname = "player_joining";
 667         self.flags = self.flags | FL_CLIENT;
 668
 669         if(player_count<0) player_count = 0;
 670
 671         bot_clientconnect();
 672
 673         //if(cvar("g_domination"))
 674         //      dom_player_join_team(self);
 675
 676         //JoinBestTeam(self, FALSE);
 677
 678         if((cvar("sv_spectate") == 1 && !cvar("g_lms")) || cvar("g_campaign")) {
 679                 self.classname = "observer";
 680         } else {
 681                 self.classname = "player";
 682                 campaign_bots_may_start = 1;
 683         }
 684
 685         self.playerid = (playerid_last = playerid_last + 1);
 686         if(cvar("sv_eventlog"))
 687         {
 688                 if(clienttype(self) == CLIENTTYPE_REAL)
 689                         s = "player";
 690                 else
 691                         s = "bot";
 692                 GameLogEcho(strcat(":join:", ftos(self.playerid), ":", s, ":", self.netname), TRUE);
 693                 s = strcat(":team:", ftos(self.playerid), ":");
 694                 s = strcat(s, ftos(self.team));
 695                 GameLogEcho(s, FALSE);
 696         }
 697
 698         //stuffcmd(self, "set tmpviewsize $viewsize \n");
 699
 700         bprint ("^4",self.netname);
 701         bprint ("^4 connected");
 702
 703         if(cvar("g_domination") || cvar("g_ctf"))
 704         {
 705                 bprint(" and joined the ");
 706                 bprint(ColoredTeamName(self.team));
 707         }
 708
 709         bprint("\n");
 710
 711         self.welcomemessage_time = time + cvar("welcome_message_time");
 712         self.welcomemessage_time2 = 0;
 713
 714         /*
 715         // the client might not have his maps/%s.cfg file yet!
 716         // so send the one from the server...
 717         fh = fopen(strcat("maps/", mapname, ".cfg"), FILE_READ);
 718         if(fh >= 0)
 719         {
 720                 while((s = fgets(fh)))
 721                         stuffcmd(self, strcat(s, "\n"));
 722                 fclose(fh);
 723         }
 724         // and then execute the client's so he can still override CD tracks
 725
 726         not needed any more: current map download system disconnects and reconnects
 727         after the download, and then the file will be there
 728         */
 729         stuffcmd(self, strcat("exec maps/", mapname, ".cfg\n"));
 730
 731         // TODO: is this being used for anything else than cd tracks?
 732         // Remember: SVC_CDTRACK exists. Maybe it should be used.
 733
 734         // send prediction settings to the client
 735         stuffcmd(self, strcat("cl_movement_accelerate ", ftos(cvar("sv_accelerate")), "\n"));
 736         stuffcmd(self, strcat("cl_movement_friction ", ftos(cvar("sv_friction")), "\n"));
 737         stuffcmd(self, strcat("cl_movement_maxspeed ", ftos(cvar("sv_maxspeed")), "\n"));
 738         stuffcmd(self, strcat("cl_movement_airaccelerate ", ftos(cvar("sv_airaccelerate")), "\n"));
 739         stuffcmd(self, strcat("cl_movement_maxairspeed ", ftos(cvar("sv_maxairspeed")), "\n"));
 740         stuffcmd(self, strcat("cl_movement_stopspeed ", ftos(cvar("sv_stopspeed")), "\n"));
 741         stuffcmd(self, strcat("cl_movement_jumpvelocity ", ftos(cvar("g_balance_jumpheight")), "\n"));
 742         stuffcmd(self, strcat("cl_movement_stepheight ", ftos(cvar("sv_stepheight")), "\n"));
 743         stuffcmd(self, strcat("set cl_movement_friction_on_land ", ftos(cvar("sv_friction_on_land")), "\n"));
 744         stuffcmd(self, strcat("set cl_movement_airaccel_qw ", ftos(cvar("sv_airaccel_qw")), "\n"));
 745         stuffcmd(self, strcat("set cl_movement_airaccel_sideways_friction ", ftos(cvar("sv_airaccel_sideways_friction")), "\n"));
 746         stuffcmd(self, strcat("cl_movement_edgefriction 0\n"));
 747         // Wazat's grappling hook
 748         SetGrappleHookBindings();
 749
 750         // get autoswitch state from player
 751         stuffcmd(self, "alias autoswitch \"set cl_autoswitch $1; cmd autoswitch $1\"\n");
 752         stuffcmd(self, "cmd autoswitch $cl_autoswitch\n");
 753
 754         // get version info from player
 755         stuffcmd(self, "cmd clientversion $gameversion\n");
 756
 757         // get other cvars from player
 758         GetCvars(0);
 759
 760         // set cvar for team scoreboard
 761         if (teams_matter)
 762         {
 763                 local float t;
 764                 t = cvar("teamplay");
 765                 // we have to stuff the correct teamplay value because if this is a listen server, this changes the teamplay mode of the server itself, which is bad
 766                 stuffcmd(self, strcat("set teamplay ", ftos(t), "\n"));
 767         }
 768         else
 769                 stuffcmd(self, strcat("set teamplay 0\n"));
 770
 771         if(cvar("g_lms"))
 772         {
 773                 self.frags = cvar("fraglimit");
 774                 // no fraglimit was set, so player gets 999 lives
 775                 if(self.frags < 1)
 776                         self.frags = 999;
 777
 778                 // disallow player to join after the worst player has lost g_lms_last_join lives
 779                 // if "g_lms_join_anytime" new players spawn with same amount of lives as the worst active player
 780                 if(((cvar("fraglimit") - cvar("g_lms_last_join")) > lms_lowest_lives && !cvar("g_lms_join_anytime")) || lms_lowest_lives < 1)
 781                 {
 782                         self.frags = -666;
 783                         lms_dead_count += 1;
 784                 }
 785                 else if(cvar("fraglimit") > lms_lowest_lives)
 786                 {
 787                         self.frags = lms_lowest_lives;
 788                 }
 789         }
 790         else if(cvar("g_arena"))
 791         {
 792                 self.classname = "observer";
 793                 Spawnqueue_Insert(self);
 794         }
 795
 796         bot_relinkplayerlist();
 797
 798         self.jointime = time;
 799 }
 800
 801 /*
 802 =============
 803 ClientDisconnect
 804
 805 Called when a client disconnects from the server
 806 =============
 807 */
 808 void(entity e) DropFlag;
 809 .entity chatbubbleentity;
 810 .entity teambubbleentity;
 811 void ClientDisconnect (void)
 812 {
 813         float save;
 814         if(cvar("sv_eventlog"))
 815                 GameLogEcho(strcat(":part:", ftos(self.playerid)), FALSE);
 816         bprint ("^4",self.netname);
 817         bprint ("^4 disconnected\n");
 818
 819         if (self.chatbubbleentity)
 820         {
 821                 remove (self.chatbubbleentity);
 822                 self.chatbubbleentity = world;
 823         }
 824
 825         if (self.teambubbleentity)
 826         {
 827                 remove (self.teambubbleentity);
 828                 self.teambubbleentity = world;
 829         }
 830
 831         DropAllRunes(self);
 832
 833         if(self.flagcarried)
 834                 DropFlag(self.flagcarried);
 835
 836         DistributeFragsAmongTeam(self, self.team, 1);
 837
 838         save = self.flags;
 839         self.flags = self.flags - (self.flags & FL_CLIENT);
 840         bot_relinkplayerlist();
 841         self.flags = save;
 842
 843         // remove laserdot
 844         if(self.weaponentity)
 845                 if(self.weaponentity.lasertarget)
 846                         remove(self.weaponentity.lasertarget);
 847
 848         // player was dead, decrease dead count
 849         if(cvar("g_lms") && self.frags < 1)
 850                 lms_dead_count -= 1;
 851         else if(cvar("g_arena"))
 852         {
 853                 Spawnqueue_Unmark(self);
 854                 Spawnqueue_Remove(self);
 855         }
 856 }
 857
 858 .float buttonchat;
 859 void() ChatBubbleThink =
 860 {
 861         self.nextthink = time;
 862         if (!self.owner.modelindex || self.owner.chatbubbleentity != self)
 863         {
 864                 self.owner.chatbubbleentity = world;
 865                 remove(self);
 866                 return;
 867         }
 868         setorigin(self, self.owner.origin + '0 0 15' + self.owner.maxs_z * '0 0 1');
 869         if (self.owner.buttonchat && !self.owner.deadflag)
 870                 self.model = self.mdl;
 871         else
 872                 self.model = "";
 873 };
 874
 875 void() UpdateChatBubble =
 876 {
 877         if (!self.modelindex)
 878                 return;
 879         // spawn a chatbubble entity if needed
 880         if (!self.chatbubbleentity)
 881         {
 882                 self.chatbubbleentity = spawn();
 883                 self.chatbubbleentity.owner = self;
 884                 self.chatbubbleentity.exteriormodeltoclient = self;
 885                 self.chatbubbleentity.think = ChatBubbleThink;
 886                 self.chatbubbleentity.nextthink = time;
 887                 setmodel(self.chatbubbleentity, "models/misc/chatbubble.spr");
 888                 setorigin(self.chatbubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
 889                 self.chatbubbleentity.mdl = self.chatbubbleentity.model;
 890                 self.chatbubbleentity.model = "";
 891         }
 892 }
 893
 894
 895 void() TeamBubbleThink =
 896 {
 897         self.nextthink = time;
 898         if (!self.owner.modelindex || self.owner.teambubbleentity != self)
 899         {
 900                 self.owner.teambubbleentity = world;
 901                 remove(self);
 902                 return;
 903         }
 904 //      setorigin(self, self.owner.origin + '0 0 15' + self.owner.maxs_z * '0 0 1');  // bandwidth hog. setattachment does this now
 905         if (self.owner.buttonchat || self.owner.deadflag)
 906                 self.model = "";
 907         else
 908                 self.model = self.mdl;
 909
 910 };
 911
 912 float() TeamBubble_customizeentityforclient
 913 {
 914         return (self.owner != other && self.owner.team == other.team && other.killcount > -666);
 915 }
 916
 917 void() UpdateTeamBubble =
 918 {
 919         if (!self.modelindex || !cvar("teamplay"))
 920                 return;
 921         // spawn a teambubble entity if needed
 922         if (!self.teambubbleentity && cvar("teamplay"))
 923         {
 924                 self.teambubbleentity = spawn();
 925                 self.teambubbleentity.owner = self;
 926                 self.teambubbleentity.exteriormodeltoclient = self;
 927                 self.teambubbleentity.think = TeamBubbleThink;
 928                 self.teambubbleentity.nextthink = time;
 929                 setmodel(self.teambubbleentity, "models/misc/teambubble.spr");
 930 //              setorigin(self.teambubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
 931                 setorigin(self.teambubbleentity, self.teambubbleentity.origin + '0 0 15' + self.maxs_z * '0 0 1');
 932                 setattachment(self.teambubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
 933                 self.teambubbleentity.mdl = self.teambubbleentity.model;
 934                 self.teambubbleentity.model = self.teambubbleentity.mdl;
 935                 self.teambubbleentity.customizeentityforclient = TeamBubble_customizeentityforclient;
 936         }
 937 }
 938
 939 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
 940 // added to the model skins
 941 /*void() UpdateColorModHack =
 942 {
 943         local float c;
 944         c = self.clientcolors & 15;
 945         // LordHavoc: only bothering to support white, green, red, yellow, blue
 946              if (teamplay == 0) self.colormod = '0 0 0';
 947         else if (c ==  0) self.colormod = '1.00 1.00 1.00';
 948         else if (c ==  3) self.colormod = '0.10 1.73 0.10';
 949         else if (c ==  4) self.colormod = '1.73 0.10 0.10';
 950         else if (c == 12) self.colormod = '1.22 1.22 0.10';
 951         else if (c == 13) self.colormod = '0.10 0.10 1.73';
 952         else self.colormod = '1 1 1';
 953 };*/
 954
 955 /*
 956 =============
 957 PlayerJump
 958
 959 When you press the jump key
 960 =============
 961 */
 962 void PlayerJump (void)
 963 {
 964         float mjumpheight;
 965
 966         mjumpheight = cvar("g_balance_jumpheight");
 967         if (self.waterlevel >= 2)
 968         {
 969                 if (self.watertype == CONTENT_WATER)
 970                         self.velocity_z = 200;
 971                 else if (self.watertype == CONTENT_SLIME)
 972                         self.velocity_z = 80;
 973                 else
 974                         self.velocity_z = 50;
 975
 976                 return;
 977         }
 978
 979
 980         if (!(self.flags & FL_ONGROUND))
 981                 return;
 982
 983         if (!(self.flags & FL_JUMPRELEASED))
 984                 return;
 985
 986         if(cvar("g_runematch"))
 987         {
 988                 if(self.runes & RUNE_SPEED)
 989                 {
 990                         if(self.runes & CURSE_SLOW)
 991                                 mjumpheight = mjumpheight * cvar("g_balance_rune_speed_combo_jumpheight");
 992                         else
 993                                 mjumpheight = mjumpheight * cvar("g_balance_rune_speed_jumpheight");
 994                 }
 995                 else if(self.runes & CURSE_SLOW)
 996                 {
 997                         mjumpheight = mjumpheight * cvar("g_balance_curse_slow_jumpheight");
 998                 }
 999         }
1000
1001         if(cvar("g_minstagib") && (self.items & IT_INVINCIBLE))
1002         {
1003                 mjumpheight = mjumpheight * cvar("g_balance_rune_speed_jumpheight");
1004         }
1005
1006         self.velocity_z = self.velocity_z + mjumpheight;
1007         self.oldvelocity_z = self.velocity_z;
1008
1009         self.flags = self.flags - FL_ONGROUND;
1010         self.flags = self.flags - FL_JUMPRELEASED;
1011 }
1012
1013 void() CheckWaterJump =
1014 {
1015         local vector start, end;
1016
1017 // check for a jump-out-of-water
1018         makevectors (self.angles);
1019         start = self.origin;
1020         start_z = start_z + 8;
1021         v_forward_z = 0;
1022         normalize(v_forward);
1023         end = start + v_forward*24;
1024         traceline (start, end, TRUE, self);
1025         if (trace_fraction < 1)
1026         {       // solid at waist
1027                 start_z = start_z + self.maxs_z - 8;
1028                 end = start + v_forward*24;
1029                 self.movedir = trace_plane_normal * -50;
1030                 traceline (start, end, TRUE, self);
1031                 if (trace_fraction == 1)
1032                 {       // open at eye level
1033                         self.flags = self.flags | FL_WATERJUMP;
1034                         self.velocity_z = 225;
1035                         self.flags = self.flags - (self.flags & FL_JUMPRELEASED);
1036                         self.teleport_time = time + 2;  // safety net
1037                         return;
1038                 }
1039         }
1040 };
1041
1042
1043 void respawn(void)
1044 {
1045         CopyBody(1);
1046         PutClientInServer();
1047 }
1048
1049 void player_powerups (void)
1050 {
1051         if (cvar("g_minstagib"))
1052         {
1053                 self.effects = EF_FULLBRIGHT;
1054                 if (self.items & IT_STRENGTH)
1055                 {
1056                         if (time > self.strength_finished)
1057                         {
1058                                 self.alpha = default_player_alpha;
1059                                 self.exteriorweaponentity.alpha = default_weapon_alpha;
1060                                 self.items = self.items - (self.items & IT_STRENGTH);
1061                                 sprint(self, "^3Invisibility has worn off\n");
1062                         }
1063                 }
1064                 else
1065                 {
1066                         if (time < self.strength_finished)
1067                         {
1068                                 self.alpha = cvar("g_minstagib_invis_alpha");
1069                                 self.exteriorweaponentity.alpha = cvar("g_minstagib_invis_alpha");
1070                                 self.items = self.items | IT_STRENGTH;
1071                                 sprint(self, "^3You are invisible\n");
1072                         }
1073                 }
1074
1075                 if (self.items & IT_INVINCIBLE)
1076                 {
1077                         if (time > self.invincible_finished)
1078                         {
1079                                 self.items = self.items - (self.items & IT_INVINCIBLE);
1080                                 sprint(self, "^3Speed has worn off\n");
1081                         }
1082                 }
1083                 else
1084                 {
1085                         if (time < self.invincible_finished)
1086                         {
1087                                 self.items = self.items | IT_INVINCIBLE;
1088                                 sprint(self, "^3You are on speed\n");
1089                         }
1090                 }
1091                 return;
1092         }
1093
1094         self.effects = self.effects - (self.effects & (EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT));
1095         if (self.items & IT_STRENGTH)
1096         {
1097                 self.effects = self.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1098                 if (time > self.strength_finished)
1099                 {
1100                         self.items = self.items - (self.items & IT_STRENGTH);
1101                         sprint(self, "^3Strength has worn off\n");
1102                 }
1103         }
1104         else
1105         {
1106                 if (time < self.strength_finished)
1107                 {
1108                         self.items = self.items | IT_STRENGTH;
1109                         sprint(self, "^3Strength infuses your weapons with devastating power\n");
1110                 }
1111         }
1112         if (self.items & IT_INVINCIBLE)
1113         {
1114                 self.effects = self.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1115                 if (time > self.invincible_finished)
1116                 {
1117                         self.items = self.items - (self.items & IT_INVINCIBLE);
1118                         sprint(self, "^3Shield has worn off\n");
1119                 }
1120         }
1121         else
1122         {
1123                 if (time < self.invincible_finished)
1124                 {
1125                         self.items = self.items | IT_INVINCIBLE;
1126                         sprint(self, "^3Shield surrounds you\n");
1127                 }
1128         }
1129
1130         if (cvar("g_fullbrightplayers"))
1131                 self.effects = self.effects | EF_FULLBRIGHT;
1132
1133         // midair gamemode: damage only while in the air
1134         // if in midair mode, being on ground grants temporary invulnerability
1135         // (this is so that multishot weapon don't clear the ground flag on the
1136         // first damage in the frame, leaving the player vulnerable to the
1137         // remaining hits in the same frame)
1138         if (self.flags & FL_ONGROUND)
1139         if (cvar("g_midair"))
1140                 self.spawnshieldtime = max(self.spawnshieldtime, time + cvar("g_midair_shieldtime"));
1141
1142         if (time < self.spawnshieldtime)
1143                 self.effects = self.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1144 }
1145
1146 float CalcRegen(float current, float stable, float maxv, float regenfactor)
1147 {
1148         if(current > stable)
1149                 return current;
1150         else if(current > stable - 0.25) // when close enough, "snap"
1151                 return stable;
1152         else
1153                 return bound(0, current + (stable - current) * regenfactor * frametime, maxv);
1154 }
1155
1156 void player_regen (void)
1157 {
1158         float maxh, maxa, limith, limita, max_mod, regen_mod, rot_mod, limit_mod;
1159         maxh = cvar("g_balance_health_stable");
1160         maxa = cvar("g_balance_armor_stable");
1161         limith = cvar("g_balance_health_limit");
1162         limita = cvar("g_balance_armor_limit");
1163
1164         if (cvar("g_minstagib") || (cvar("g_lms") && !cvar("g_lms_regenerate")))
1165                 return;
1166
1167         if(cvar("g_runematch"))
1168         {
1169                 max_mod = regen_mod = rot_mod = limit_mod = 1;
1170                 if (self.runes & RUNE_REGEN)
1171                 {
1172                         if (self.runes & CURSE_VENOM) // do we have both rune/curse?
1173                         {
1174                                 regen_mod = cvar("g_balance_rune_regen_combo_regenrate");
1175                                 max_mod = cvar("g_balance_rune_regen_combo_hpmod");
1176                                 limit_mod = cvar("g_balance_rune_regen_combo_limitmod");
1177                         }
1178                         else
1179                         {
1180                                 regen_mod = cvar("g_balance_rune_regen_regenrate");
1181                                 max_mod = cvar("g_balance_rune_regen_hpmod");
1182                                 limit_mod = cvar("g_balance_rune_regen_limitmod");
1183                         }
1184                 }
1185                 else if (self.runes & CURSE_VENOM)
1186                 {
1187                         max_mod = cvar("g_balance_curse_venom_hpmod");
1188                         if (self.runes & RUNE_REGEN) // do we have both rune/curse?
1189                                 rot_mod = cvar("g_balance_rune_regen_combo_rotrate");
1190                         else
1191                                 rot_mod = cvar("g_balance_curse_venom_rotrate");
1192                         limit_mod = cvar("g_balance_curse_venom_limitmod");
1193                         //if (!self.runes & RUNE_REGEN)
1194                         //      rot_mod = cvar("g_balance_curse_venom_rotrate");
1195                 }
1196                 maxh = maxh * max_mod;
1197                 //maxa = maxa * max_mod;
1198
1199                 if (time > self.pauserotarmor_finished)
1200                 {
1201                         if (self.armorvalue > maxa)
1202                                 self.armorvalue = bound(0, self.armorvalue + (maxa - self.armorvalue) * cvar("g_balance_armor_rot") * frametime, 1000);
1203                 }
1204                 if (time > self.pauserothealth_finished)
1205                 {
1206                         if (self.health > maxh)
1207                                 self.health = bound(0, self.health + (maxh - self.health) * rot_mod*cvar("g_balance_health_rot") * frametime, 1000);
1208                 }
1209                 if (time > self.pauseregen_finished)
1210                 {
1211                         self.health = CalcRegen(self.health, maxh, 1000, regen_mod * cvar("g_balance_health_regen"));
1212                         self.armorvalue = CalcRegen(self.armorvalue, maxa, 1000, cvar("g_balance_armor_regen"));
1213                 }
1214         }
1215         else
1216         {
1217                 if (time > self.pauserothealth_finished)
1218                 if (self.health > maxh)
1219                         self.health = bound(0, self.health + (maxh - self.health) * cvar("g_balance_health_rot") * frametime, 1000);
1220                 if (time > self.pauserotarmor_finished)
1221                 if (self.armorvalue > maxa)
1222                         self.armorvalue = bound(0, self.armorvalue + (maxa - self.armorvalue) * cvar("g_balance_armor_rot") * frametime, 1000);
1223                 if (time > self.pauseregen_finished)
1224                 {
1225                         self.health = CalcRegen(self.health, maxh, 1000, cvar("g_balance_health_regen"));
1226                         self.armorvalue = CalcRegen(self.armorvalue, maxa, 1000, cvar("g_balance_armor_regen"));
1227                 }
1228         }
1229
1230         if (self.health > limith)
1231                 self.health = limith;
1232         if(self.health < 1)
1233                 self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
1234         if (self.armorvalue > limita)
1235                 self.armorvalue = limita;
1236 }
1237
1238 /*
1239 ======================
1240 spectate mode routines
1241 ======================
1242 */
1243 void SpectateCopy(entity spectatee) {
1244         self.armortype = spectatee.armortype;
1245         self.armorvalue = spectatee.armorvalue;
1246         self.currentammo = spectatee.currentammo;
1247         self.effects = spectatee.effects;
1248         self.health = spectatee.health;
1249         self.impulse = 0;
1250         self.items = spectatee.items;
1251         self.punchangle = spectatee.punchangle;
1252         self.view_ofs = spectatee.view_ofs;
1253         self.v_angle = spectatee.v_angle;
1254         self.viewzoom = spectatee.viewzoom;
1255         setorigin(self, spectatee.origin);
1256         setsize(self, spectatee.mins, spectatee.maxs);
1257 }
1258
1259 void SpectateUpdate() {
1260         if(!self.enemy)
1261                         PutObserverInServer();
1262
1263         if (self != self.enemy) {
1264                 if(self.enemy.flags & FL_NOTARGET)
1265                         PutObserverInServer();
1266                 SpectateCopy(self.enemy);
1267                 self.dmg_take = self.enemy.dmg_take;
1268                 self.dmg_save = self.enemy.dmg_save;
1269                 self.dmg_inflictor = self.enemy.dmg_inflictor;
1270                 self.fixangle = TRUE;
1271                 self.angles = self.enemy.v_angle;
1272                 //msg_entity = self;
1273                 //WriteByte(MSG_ONE, SVC_SETANGLE);
1274                 //WriteAngle(MSG_ONE, self.enemy.v_angle_x);
1275                 //WriteAngle(MSG_ONE, self.enemy.v_angle_y);
1276                 //WriteAngle(MSG_ONE, self.enemy.v_angle_z);
1277         }
1278 }
1279
1280 float SpectateNext() {
1281         other = find(self.enemy, classname, "player");
1282         if (!other) {
1283                 other = find(other, classname, "player");
1284         }
1285         if (other) {
1286                 self.enemy = other;
1287         }
1288         if(self.enemy.classname == "player") {
1289                 msg_entity = self;
1290                 WriteByte(MSG_ONE, SVC_SETVIEW);
1291                 WriteEntity(MSG_ONE, self.enemy);
1292                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
1293                 SpectateUpdate();
1294                 return 1;
1295         } else {
1296                 return 0;
1297         }
1298 }
1299
1300 /*
1301 =============
1302 PlayerPreThink
1303
1304 Called every frame for each client before the physics are run
1305 =============
1306 */
1307 void() ctf_setstatus;
1308 void PlayerPreThink (void)
1309 {
1310         if(self.classname == "player") {
1311                 local vector m1, m2;
1312
1313 //              if(self.netname == "Wazat")
1314 //                      bprint(strcat(self.classname, "\n"));
1315
1316                 CheckRules_Player();
1317
1318                 Nixnex_GiveCurrentWeapon();
1319
1320                 if(self.button7)
1321                         PrintWelcomeMessage(self);
1322
1323                 if(cvar("g_lms") || !cvar("sv_spectate"))
1324                 if((time - self.jointime) <= cvar("welcome_message_time"))
1325                         PrintWelcomeMessage(self);
1326
1327                 if (intermission_running)
1328                 {
1329                         IntermissionThink ();   // otherwise a button could be missed between
1330                         return;                                 // the think tics
1331                 }
1332
1333                 if (self.deadflag != DEAD_NO)
1334                 {
1335                         player_anim();
1336                         if (self.deadflag == DEAD_DYING)
1337                         {
1338                                 if (time > self.dead_time)
1339                                         self.deadflag = DEAD_DEAD;
1340                         }
1341                         else if (self.deadflag == DEAD_DEAD)
1342                         {
1343                                 if (cvar("g_lms") || cvar("g_arena") || cvar("g_forced_respawn"))
1344                                         self.deadflag = DEAD_RESPAWNABLE;
1345                                 else if (!self.button0 && !self.button2 && !self.button3)
1346                                         self.deadflag = DEAD_RESPAWNABLE;
1347                         }
1348                         else if (self.deadflag == DEAD_RESPAWNABLE)
1349                         {
1350                                 if (self.button0  ||
1351                                     self.button2  ||
1352                                     self.button3  ||
1353                                     self.button4  ||
1354                                     self.button5  ||
1355                                     self.button6  ||
1356                                     self.button7  ||
1357                                     self.button8  ||
1358                                     self.buttonuse ||
1359                                     cvar("g_lms") ||
1360                                     cvar("g_forced_respawn"))
1361                                         respawn();
1362                         }
1363                         return;
1364                 }
1365
1366                 if(cvar("g_lms") && !self.deadflag && cvar("g_lms_campcheck_interval"))
1367                 {
1368                         vector dist;
1369
1370                         // calculate player movement (in 2 dimensions only, so jumping on one spot doesn't count as movement)
1371                         dist = self.oldorigin - self.origin;
1372                         dist_z = 0;
1373                         self.lms_traveled_distance += fabs(vlen(dist));
1374
1375                         if(cvar("g_campaign"))
1376                         if(!campaign_bots_may_start)
1377                         {
1378                                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval")*2;
1379                                 self.lms_traveled_distance = 0;
1380                         }
1381
1382                         if(time > self.lms_nextcheck)
1383                         {
1384                                 //sprint(self, "distance: ", ftos(self.lms_traveled_distance), "\n");
1385                                 if(self.lms_traveled_distance < cvar("g_lms_campcheck_distance"))
1386                                 {
1387                                         centermsg_set(CENTERMSG_CAMP, cvar_string("g_lms_campcheck_message"));
1388                                         // FIXME KadaverJack: gibbing player here causes playermodel to bounce around, instead of eye.md3
1389                                         // I wasn't able to find out WHY that happens, so I put a workaround in place that shall prevent players from being gibbed :(
1390                                         Damage(self, self, self, bound(0, cvar("g_lms_campcheck_damage"), self.health + self.armorvalue * cvar("g_balance_armor_blockpercent") + 5), DEATH_CAMP, self.origin, '0 0 0');
1391                                 }
1392                                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval");
1393                                 self.lms_traveled_distance = 0;
1394                         }
1395                 }
1396
1397                 if (self.button5 && !self.hook.state)
1398                 {
1399                         if (!self.crouch)
1400                         {
1401                                 self.crouch = TRUE;
1402                                 self.view_ofs = PL_CROUCH_VIEW_OFS;
1403                                 setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX);
1404                         }
1405                 }
1406                 else
1407                 {
1408                         if (self.crouch)
1409                         {
1410                                 tracebox(self.origin, PL_MIN, PL_MAX, self.origin, FALSE, self);
1411                                 if (!trace_startsolid)
1412                                 {
1413                                         self.crouch = FALSE;
1414                                         self.view_ofs = PL_VIEW_OFS;
1415                                         setsize (self, PL_MIN, PL_MAX);
1416                                 }
1417                         }
1418                 }
1419
1420                 if(cvar("sv_defaultcharacter") == 1 && !teams_matter) {
1421                         local string defaultmodel;
1422                         defaultmodel = CheckPlayerModel(cvar_string("sv_defaultplayermodel"));
1423
1424                         if (defaultmodel != self.model)
1425                         {
1426                                 m1 = self.mins;
1427                                 m2 = self.maxs;
1428                                 setmodel_lod (self, defaultmodel);
1429                                 setsize (self, m1, m2);
1430                         }
1431
1432                         if (self.skin != cvar("sv_defaultplayerskin"))
1433                                 self.skin = cvar("sv_defaultplayerskin");
1434                 } else {
1435                         if (self.playermodel != self.model)
1436                         {
1437                                 self.playermodel = CheckPlayerModel(self.playermodel);
1438                                 m1 = self.mins;
1439                                 m2 = self.maxs;
1440                                 setmodel_lod (self, self.playermodel);
1441                                 setsize (self, m1, m2);
1442                         }
1443
1444                         if (self.skin != stof(self.playerskin))
1445                                 self.skin = stof(self.playerskin);
1446                 }
1447                 // Savage: Check for nameless players
1448                 if (strlen(self.netname) < 1) {
1449                         self.netname = "Player";
1450                         stuffcmd(self, "name Player\n");
1451                 }
1452
1453                 GrapplingHookFrame();
1454
1455                 W_WeaponFrame();
1456
1457                 if (self.button4 || (self.weapon == WEP_NEX && self.button3))
1458                 {
1459                         if (cvar("g_minstagib") && self.button3)
1460                         {
1461                                 if (self.jump_interval <= (time + 0.1))
1462                                 {
1463                                         self.jump_interval = time + 1;
1464                                         W_Laser_Attack();
1465                                 }
1466                         }
1467                         else if (self.viewzoom > 0.4)
1468                                 self.viewzoom = max (0.4, self.viewzoom - frametime * 2);
1469                 }
1470                 else if (self.viewzoom < 1.0)
1471                         self.viewzoom = min (1.0, self.viewzoom + frametime);
1472
1473
1474                 if (self.button2)
1475                         PlayerJump ();
1476                 else
1477                         self.flags = self.flags | FL_JUMPRELEASED;
1478
1479                 player_powerups();
1480                 player_regen();
1481                 player_anim();
1482
1483                 if (cvar("g_minstagib"))
1484                         minstagib_ammocheck();
1485
1486                 ctf_setstatus();
1487
1488                 //self.angles_y=self.v_angle_y + 90;   // temp
1489
1490                 if (self.waterlevel == 2)
1491                         CheckWaterJump ();
1492
1493                 //if (TetrisPreFrame()) return;
1494         } else if(gameover) {
1495                 if (intermission_running)
1496                         IntermissionThink ();   // otherwise a button could be missed between
1497                 return;
1498         } else if(self.classname == "observer") {
1499
1500                 if (self.flags & FL_JUMPRELEASED) {
1501                         if (self.button2 && self.version == cvar("gameversion")) {
1502                                 if(!cvar("teamplay") || cvar("g_campaign") || cvar("g_balance_teams")) {
1503                                         self.flags = self.flags & !FL_JUMPRELEASED;
1504                                         self.classname = "player";
1505                                         if(cvar("g_campaign") || cvar("g_balance_teams"))
1506                                                 JoinBestTeam(self, 0);
1507                                         if(cvar("g_campaign"))
1508                                                 campaign_bots_may_start = 1;
1509                                         PutClientInServer();
1510                                         if(self.flags & !FL_NOTARGET)
1511                                                 bprint (strcat("^4", self.netname, "^4 is playing now\n"));
1512                                         centermsg_reset();
1513                                         return;
1514                                 } else {
1515                                         self.flags = self.flags & !FL_JUMPRELEASED;
1516                                         stuffcmd(self,"menu_showteamselect\n");
1517                                         return;
1518                                 }
1519                         } else if(self.button0 && self.version == cvar("gameversion")) {
1520                                 self.flags = self.flags & !FL_JUMPRELEASED;
1521                                 if(SpectateNext() == 1) {
1522                                         self.classname = "spectator";
1523                                 }
1524                         }
1525                 } else {
1526                         if (!(self.button0 || self.button2)) {
1527                                 self.flags = self.flags | FL_JUMPRELEASED;
1528                         }
1529                 }
1530                 PrintWelcomeMessage(self);
1531         } else if(self.classname == "spectator") {
1532                 if (self.flags & FL_JUMPRELEASED) {
1533                         if (self.button2 && self.version == cvar("gameversion")) {
1534                                 if(!cvar("teamplay") || cvar("g_campaign") || cvar("g_balance_teams")) {
1535                                         self.flags = self.flags & !FL_JUMPRELEASED;
1536                                         self.classname = "player";
1537                                         if(!cvar("g_lms"))
1538                                                 bprint (strcat("^4", self.netname, "^4 is playing now\n"));
1539
1540                                         if(cvar("g_campaign") || cvar("g_balance_teams"))
1541                                                 JoinBestTeam(self, 0);
1542                                         if(cvar("g_campaign"))
1543                                                 campaign_bots_may_start = 1;
1544                                         PutClientInServer();
1545                                         centermsg_reset();
1546                                         return;
1547                                 } else {
1548                                         self.flags = self.flags & !FL_JUMPRELEASED;
1549                                         stuffcmd(self,"menu_showteamselect\n");
1550                                         return;
1551                                 }
1552                         } else if(self.button0) {
1553                                 self.flags = self.flags & !FL_JUMPRELEASED;
1554                                 if(SpectateNext() == 1) {
1555                                         self.classname = "spectator";
1556                                 } else {
1557                                         self.classname = "observer";
1558                                         PutClientInServer();
1559                                 }
1560                         } else if (self.button3) {
1561                                 self.flags = self.flags & !FL_JUMPRELEASED;
1562                                 self.classname = "observer";
1563                                 PutClientInServer();
1564                         } else {
1565                                 SpectateUpdate();
1566                         }
1567                 } else {
1568                         if (!(self.button0 || self.button3)) {
1569                                 self.flags = self.flags | FL_JUMPRELEASED;
1570                         }
1571                 }
1572                 PrintWelcomeMessage(self);
1573                 self.flags = self.flags | FL_CLIENT | FL_NOTARGET;
1574         }
1575 }
1576
1577
1578 /*
1579 =============
1580 PlayerPostThink
1581
1582 Called every frame for each client after the physics are run
1583 =============
1584 */
1585 void PlayerPostThink (void)
1586 {
1587         if(self.classname == "player") {
1588                 CheckRules_Player();
1589                 UpdateChatBubble();
1590                 UpdateTeamBubble();
1591                 if (self.deadflag == DEAD_NO)
1592                 if (self.impulse)
1593                         ImpulseCommands ();
1594                 if (intermission_running)
1595                         return;         // intermission or finale
1596
1597                 //PrintWelcomeMessage(self);
1598                 //if (TetrisPostFrame()) return;
1599         } else if (self.classname == "observer") {
1600                 //do nothing
1601         } else if (self.classname == "spectator") {
1602                 //do nothing
1603         }
1604         Arena_Warmup();
1605 }