data/qcsrc/server/cl_client.qc

   1 void info_player_start (void)
   2 {
   3         self.classname = "info_player_deathmatch";
   4         relocate_spawnpoint();
   5 }
   6
   7 void info_player_deathmatch (void)
   8 {
   9         relocate_spawnpoint();
  10 }
  11
  12 float spawn_allbad;
  13 float spawn_allgood;
  14 entity Spawn_FilterOutBadSpots(entity firstspot, entity playerlist, float mindist, float teamcheck)
  15 {
  16         local entity spot, player, nextspot, previousspot, newfirstspot;
  17         local float pcount;
  18         spot = firstspot;
  19         newfirstspot = world;
  20         previousspot = world;
  21         spawn_allgood = TRUE;
  22         spawn_allbad = TRUE;
  23         while (spot)
  24         {
  25                 nextspot = spot.chain;
  26                 // count team mismatches as bad spots
  27                 if (spot.team == teamcheck)
  28                 {
  29                         pcount = 0;
  30                         player = playerlist;
  31                         while (player)
  32                         {
  33                                 if (player != self)
  34                                 if (vlen(player.origin - spot.origin) < mindist)
  35                                         pcount = pcount + 1;
  36                                 player = player.chain;
  37                         }
  38                         if (!pcount)
  39                         {
  40                                 spawn_allbad = FALSE;
  41                                 if (newfirstspot)
  42                                         previousspot.chain = spot;
  43                                 else
  44                                         newfirstspot = spot;
  45                                 previousspot = spot;
  46                                 spot.chain = world;
  47                         }
  48                         else
  49                                 spawn_allgood = FALSE;
  50                 }
  51                 spot = nextspot;
  52         }
  53         // if we couldn't find ANY good points, return the original list
  54         if (!newfirstspot)
  55                 newfirstspot = firstspot;
  56         return newfirstspot;
  57 }
  58
  59 entity Spawn_RandomPoint(entity firstspot)
  60 {
  61         local entity spot;
  62         local float numspots;
  63         // count number of spots
  64         numspots = 0;
  65         spot = firstspot;
  66         while (spot)
  67         {
  68                 numspots = numspots + 1;
  69                 spot = spot.chain;
  70         }
  71         // pick a random one
  72         numspots = numspots * random();
  73         spot = firstspot;
  74         while (spot.chain && numspots >= 1)
  75         {
  76                 numspots = numspots - 1;
  77                 spot = spot.chain;
  78         }
  79         return spot;
  80 }
  81
  82 entity Spawn_FurthestPoint(entity firstspot, entity playerlist)
  83 {
  84         local entity best, spot, player;
  85         local float bestrating, rating;
  86         best = world;
  87         bestrating = -1000000;
  88         spot = firstspot;
  89         while (spot)
  90         {
  91                 rating = 1000000000;
  92                 player = playerlist;
  93                 while (player)
  94                 {
  95                         if (player != self)
  96                                 rating = min(rating, vlen(player.origin - spot.origin));
  97                         player = player.chain;
  98                 }
  99                 rating = rating + random() * 16;
 100                 if (bestrating < rating)
 101                 {
 102                         best = spot;
 103                         bestrating = rating;
 104                 }
 105                 spot = spot.chain;
 106         }
 107         return best;
 108 }
 109
 110 /*
 111 =============
 112 SelectSpawnPoint
 113
 114 Finds a point to respawn
 115 =============
 116 */
 117 entity SelectSpawnPoint (float anypoint)
 118 {
 119         local float teamcheck;
 120         local entity spot, firstspot, playerlist;
 121
 122         spot = find (world, classname, "testplayerstart");
 123         if (spot)
 124                 return spot;
 125
 126         teamcheck = 0;
 127
 128         if(!anypoint && cvar("g_ctf") )
 129                 teamcheck = self.team;
 130
 131         // get the list of players
 132         playerlist = findchain(classname, "player");
 133         // get the entire list of spots
 134         firstspot = findchain(classname, "info_player_deathmatch");
 135         // filter out the bad ones
 136         // (note this returns the original list if none survived)
 137         firstspot = Spawn_FilterOutBadSpots(firstspot, playerlist, 100, teamcheck);
 138
 139         // there is 50/50 chance of choosing a random spot or the furthest spot
 140         // (this means that roughly every other spawn will be furthest, so you
 141         // usually won't get fragged at spawn twice in a row)
 142         if (arena_roundbased)
 143         {
 144                 firstspot = Spawn_FilterOutBadSpots(firstspot, playerlist, 800, teamcheck);
 145                 spot = Spawn_RandomPoint(firstspot);
 146         }
 147         else if (random() > 0.5 || spawn_allbad || spawn_allgood)
 148                 spot = Spawn_RandomPoint(firstspot);
 149         else
 150                 spot = Spawn_FurthestPoint(firstspot, playerlist);
 151
 152         if (!spot)
 153         {
 154                 if(cvar("spawn_debug"))
 155                         GotoNextMap();
 156                 else
 157                         error ("PutClientInServer: no start points on level");
 158         }
 159
 160         return spot;
 161 }
 162
 163 /*
 164 =============
 165 CheckPlayerModel
 166
 167 Checks if the argument string can be a valid playermodel.
 168 Returns a valid one in doubt.
 169 =============
 170 */
 171 string FallbackPlayerModel = "models/player/marine.zym";
 172 string CheckPlayerModel(string plyermodel) {
 173         if(strlen(plyermodel) < 4)
 174                 return FallbackPlayerModel;
 175         if( substring(plyermodel,0,14) != "models/player/")
 176                 return FallbackPlayerModel;
 177         else if(cvar("sv_servermodelsonly"))
 178         {
 179                 if(substring(plyermodel,strlen(plyermodel)-4,4) != ".zym")
 180                         return FallbackPlayerModel;
 181                 if(!fexists(plyermodel))
 182                         return FallbackPlayerModel;
 183         }
 184         return plyermodel;
 185 }
 186
 187 /*
 188 =============
 189 Client_customizeentityforclient
 190
 191 LOD reduction
 192 =============
 193 */
 194 float Client_customizeentityforclient()
 195 {
 196 #ifdef ALLOW_VARIABLE_LOD
 197         // self: me
 198         // other: the player viewing me
 199         float distance;
 200         float f;
 201
 202         if(self.flags & FL_NOTARGET) // we don't need LOD for spectators
 203                 return TRUE;
 204
 205         if(other.cvar_cl_playerdetailreduction <= 0)
 206         {
 207                 if(other.cvar_cl_playerdetailreduction <= -2)
 208                         self.modelindex = self.modelindex_lod2;
 209                 else if(other.cvar_cl_playerdetailreduction <= -1)
 210                         self.modelindex = self.modelindex_lod1;
 211                 else
 212                         self.modelindex = self.modelindex_lod0;
 213         }
 214         else
 215         {
 216                 distance = vlen(self.origin - other.origin);
 217                 f = (distance + 100.0) * other.cvar_cl_playerdetailreduction;
 218                 if(f > 10000)
 219                         self.modelindex = self.modelindex_lod2;
 220                 else if(f > 5000)
 221                         self.modelindex = self.modelindex_lod1;
 222                 else
 223                         self.modelindex = self.modelindex_lod0;
 224         }
 225 #endif
 226
 227         return TRUE;
 228 }
 229
 230 void setmodel_lod(entity e, string modelname)
 231 {
 232 #ifdef ALLOW_VARIABLE_LOD
 233         string s;
 234
 235         s = strcat(substring(modelname, 0, strlen(modelname) - 4), "_1.zym");
 236         if(fexists(s))
 237         {
 238                 precache_model(s);
 239                 setmodel(e, s);
 240                 self.modelindex_lod1 = self.modelindex;
 241         }
 242         else
 243                 self.modelindex_lod1 = -1;
 244
 245         s = strcat(substring(modelname, 0, strlen(modelname) - 4), "_2.zym");
 246         if(fexists(s))
 247         {
 248                 precache_model(s);
 249                 setmodel(e, s);
 250                 self.modelindex_lod2 = self.modelindex;
 251         }
 252         else
 253                 self.modelindex_lod2 = -1;
 254
 255         precache_model(modelname);
 256         setmodel(e, modelname);
 257         self.modelindex_lod0 = self.modelindex;
 258
 259         if(self.modelindex_lod1 < 0)
 260                 self.modelindex_lod1 = self.modelindex;
 261
 262         if(self.modelindex_lod2 < 0)
 263                 self.modelindex_lod2 = self.modelindex;
 264 #else
 265         precache_model(modelname);
 266         setmodel(e, modelname);
 267 #endif
 268 }
 269
 270 /*
 271 =============
 272 PutObserverInServer
 273
 274 putting a client as observer in the server
 275 =============
 276 */
 277 void PutObserverInServer (void)
 278 {
 279         entity  spot;
 280         spot = SelectSpawnPoint (FALSE);
 281         RemoveGrapplingHook(self); // Wazat's Grappling Hook
 282
 283         if(clienttype(self) == CLIENTTYPE_REAL)
 284         {
 285                 msg_entity = self;
 286                 WriteByte(MSG_ONE, SVC_SETVIEW);
 287                 WriteEntity(MSG_ONE, self);
 288         }
 289
 290         DropAllRunes(self);
 291
 292         if(self.flagcarried)
 293                 DropFlag(self.flagcarried);
 294
 295         DistributeFragsAmongTeam(self, self.team, 1);
 296
 297         if(self.frags <= 0 && self.frags > -666 && cvar("g_lms") && self.killcount != -666)
 298                 bprint (strcat("^4", self.netname, "^4 has no more lives left\n"));
 299         else if(self.killcount != -666)
 300                 bprint (strcat("^4", self.netname, "^4 is spectating now\n"));
 301
 302         self.classname = "observer";
 303         self.health = -666;
 304         self.takedamage = DAMAGE_NO;
 305         self.solid = SOLID_NOT;
 306         self.movetype = MOVETYPE_NOCLIP;
 307         self.flags = FL_CLIENT | FL_NOTARGET;
 308         self.armorvalue = 666;
 309         self.effects = 0;
 310         self.armorvalue = cvar("g_balance_armor_start");
 311         self.pauserotarmor_finished = 0;
 312         self.pauserothealth_finished = 0;
 313         self.pauseregen_finished = 0;
 314         self.damageforcescale = 0;
 315         self.death_time = 0;
 316         self.dead_time = 0;
 317         self.dead_frame = 0;
 318         self.die_frame = 0;
 319         self.deaths = 0;
 320         self.alpha = 0;
 321         self.scale = 0;
 322         self.fade_time = 0;
 323         self.pain_frame = 0;
 324         self.pain_finished = 0;
 325         self.strength_finished = 0;
 326         self.invincible_finished = 0;
 327         self.pushltime = 0;
 328         self.think = SUB_Null;
 329         self.nextthink = 0;
 330         self.hook_time = 0;
 331         self.runes = 0;
 332         self.deadflag = DEAD_NO;
 333         self.angles = spot.angles;
 334         self.angles_z = 0;
 335         self.fixangle = TRUE;
 336         self.crouch = FALSE;
 337
 338         self.view_ofs = PL_VIEW_OFS;
 339         setorigin (self, spot.origin);
 340         setsize (self, '0 0 0', '0 0 0');
 341         self.oldorigin = self.origin;
 342         self.items = 0;
 343         self.model = "";
 344         self.modelindex = 0;
 345         self.weapon = 0;
 346         self.weaponmodel = "";
 347         self.weaponentity = world;
 348         self.killcount = -666;
 349         self.velocity = '0 0 0';
 350         self.avelocity = '0 0 0';
 351         self.punchangle = '0 0 0';
 352         self.punchvector = '0 0 0';
 353         self.oldvelocity = self.velocity;
 354         self.customizeentityforclient = Client_customizeentityforclient;
 355
 356         if(cvar("g_arena"))
 357         {
 358                 if(self.frags != -2)
 359                 {
 360                         Spawnqueue_Insert(self);
 361                 }
 362                 else
 363                 {
 364                         Spawnqueue_Unmark(self);
 365                         Spawnqueue_Remove(self);
 366                 }
 367         }
 368         else if(!cvar("g_lms"))
 369                 self.frags = -666;
 370 }
 371
 372
 373 /*
 374 =============
 375 PutClientInServer
 376
 377 Called when a client spawns in the server
 378 =============
 379 */
 380 void PutClientInServer (void)
 381 {
 382         if(clienttype(self) == CLIENTTYPE_BOT)
 383         {
 384                 self.classname = "player";
 385         }
 386         else if(clienttype(self) == CLIENTTYPE_REAL)
 387         {
 388                 msg_entity = self;
 389                 WriteByte(MSG_ONE, SVC_SETVIEW);
 390                 WriteEntity(MSG_ONE, self);
 391         }
 392
 393         // player is dead and becomes observer
 394         if(cvar("g_lms") && self.frags < 1)
 395                 self.classname = "observer";
 396
 397         if(cvar("g_arena"))
 398         if(!self.spawned)
 399                 self.classname = "observer";
 400
 401         if(self.classname == "player") {
 402                 entity  spot;
 403
 404                 spot = SelectSpawnPoint (FALSE);
 405
 406                 RemoveGrapplingHook(self); // Wazat's Grappling Hook
 407
 408                 self.classname = "player";
 409                 self.iscreature = TRUE;
 410                 self.movetype = MOVETYPE_WALK;
 411                 self.solid = SOLID_SLIDEBOX;
 412                 self.flags = FL_CLIENT;
 413                 self.takedamage = DAMAGE_AIM;
 414                 self.effects = 0;
 415                 self.health = cvar("g_balance_health_start");
 416                 self.armorvalue = cvar("g_balance_armor_start");
 417                 self.spawnshieldtime = time + cvar("g_spawnshieldtime");
 418                 self.pauserotarmor_finished = time + cvar("g_balance_pause_armor_rot_spawn");
 419                 self.pauserothealth_finished = time + cvar("g_balance_pause_health_rot_spawn");
 420                 self.pauseregen_finished = time + cvar("g_balance_pause_health_regen_spawn");
 421                 self.damageforcescale = 2;
 422                 self.death_time = 0;
 423                 self.dead_time = 0;
 424                 self.dead_frame = 0;
 425                 self.die_frame = 0;
 426                 self.alpha = 0;
 427                 self.scale = 0;
 428                 self.fade_time = 0;
 429                 self.pain_frame = 0;
 430                 self.pain_finished = 0;
 431                 self.strength_finished = 0;
 432                 self.invincible_finished = 0;
 433                 self.pushltime = 0;
 434                 //self.speed_finished = 0;
 435                 //self.slowmo_finished = 0;
 436                 // players have no think function
 437                 self.think = SUB_Null;
 438                 self.nextthink = 0;
 439                 self.weapon = 0;
 440                 self.switchweapon = 0;
 441                 self.hook_time = 0;
 442
 443                 self.runes = 0;
 444
 445                 self.deadflag = DEAD_NO;
 446
 447                 self.angles = spot.angles;
 448
 449                 self.angles_z = 0; // never spawn tilted even if the spot says to
 450                 self.fixangle = TRUE; // turn this way immediately
 451                 self.velocity = '0 0 0';
 452                 self.avelocity = '0 0 0';
 453                 self.punchangle = '0 0 0';
 454                 self.punchvector = '0 0 0';
 455                 self.oldvelocity = self.velocity;
 456
 457                 self.viewzoom = 0.6;
 458
 459                 self.customizeentityforclient = Client_customizeentityforclient;
 460
 461                 if(cvar("sv_defaultcharacter") == 1 && !teams_matter) {
 462                         local string defaultmodel;
 463                         defaultmodel = CheckPlayerModel(cvar_string("sv_defaultplayermodel"));
 464                         setmodel_lod (self, defaultmodel);
 465                         self.skin = stof(cvar_string("sv_defaultplayerskin"));
 466                 } else {
 467                         self.playermodel = CheckPlayerModel(self.playermodel);
 468                         setmodel_lod (self, self.playermodel);
 469                         if(teams_matter)
 470                                 self.skin = math_mod(stof(self.playerskin), NUM_PLAYERSKINS_TEAMPLAY);
 471                         else
 472                                 self.skin = stof(self.playerskin);
 473                 }
 474
 475                 self.crouch = FALSE;
 476                 self.view_ofs = PL_VIEW_OFS;
 477                 setsize (self, PL_MIN, PL_MAX);
 478                 self.spawnorigin = spot.origin;
 479                 setorigin (self, spot.origin + '0 0 1' * (1 - self.mins_z - 24));
 480                 // don't reset back to last position, even if new position is stuck in solid
 481                 self.oldorigin = self.origin;
 482
 483                 if(cvar("g_lms"))
 484                 {
 485                         self.ammo_shells = cvar("g_lms_start_ammo_shells");
 486                         self.ammo_nails = cvar("g_lms_start_ammo_nails");
 487                         self.ammo_rockets = cvar("g_lms_start_ammo_rockets");
 488                         self.ammo_cells = cvar("g_lms_start_ammo_cells");
 489                         self.health = cvar("g_lms_start_health");
 490                         self.armorvalue = cvar("g_lms_start_armor");
 491                 }
 492                 else if (cvar("g_use_ammunition")) {
 493                         self.ammo_shells = cvar("g_start_ammo_shells");
 494                         self.ammo_nails = cvar("g_start_ammo_nails");
 495                         self.ammo_rockets = cvar("g_start_ammo_rockets");
 496                         self.ammo_cells = cvar("g_start_ammo_cells");
 497                 } else {
 498                         self.ammo_shells = 999;
 499                         self.ammo_nails = 999;
 500                         self.ammo_rockets = 999;
 501                         self.ammo_cells = 999;
 502                 }
 503
 504                 self.items = 0;
 505                 if (cvar("g_start_weapon_laser") || cvar("g_lms"))
 506                 {
 507                         self.items = self.items | IT_LASER;
 508                         self.switchweapon = WEP_LASER;
 509                 }
 510                 if (cvar("g_start_weapon_shotgun") || cvar("g_lms"))
 511                 {
 512                         self.items = self.items | IT_SHOTGUN;
 513                         self.switchweapon = WEP_SHOTGUN;
 514                 }
 515                 if (cvar("g_start_weapon_uzi") || cvar("g_lms"))
 516                 {
 517                         self.items = self.items | IT_UZI;
 518                         self.switchweapon = WEP_UZI;
 519                 }
 520                 if (cvar("g_start_weapon_grenadelauncher") || cvar("g_lms"))
 521                 {
 522                         self.items = self.items | IT_GRENADE_LAUNCHER;
 523                         self.switchweapon = WEP_GRENADE_LAUNCHER;
 524                 }
 525                 if (cvar("g_start_weapon_electro") || cvar("g_lms"))
 526                 {
 527                         self.items = self.items | IT_ELECTRO;
 528                         self.switchweapon = WEP_ELECTRO;
 529                 }
 530                 if (cvar("g_start_weapon_crylink") || cvar("g_lms"))
 531                 {
 532                         self.items = self.items | IT_CRYLINK;
 533                         self.switchweapon = WEP_CRYLINK;
 534                 }
 535                 if (cvar("g_start_weapon_nex") || cvar("g_lms"))
 536                 {
 537                         self.items = self.items | IT_NEX;
 538                         self.switchweapon = WEP_NEX;
 539                 }
 540                 if (cvar("g_start_weapon_hagar") || cvar("g_lms"))
 541                 {
 542                         self.items = self.items | IT_HAGAR;
 543                         self.switchweapon = WEP_HAGAR;
 544                 }
 545                 if (cvar("g_start_weapon_rocketlauncher") || cvar("g_lms"))
 546                 {
 547                         self.items = self.items | IT_ROCKET_LAUNCHER;
 548                         self.switchweapon = WEP_ROCKET_LAUNCHER;
 549                 }
 550
 551                 if(cvar("g_instagib"))
 552                 {
 553                         self.items = IT_NEX;
 554                         self.switchweapon = WEP_NEX;
 555                         self.ammo_cells = 999;
 556                 }
 557
 558                 if(cvar("g_rocketarena"))
 559                 {
 560                         self.items = IT_ROCKET_LAUNCHER;
 561                         self.switchweapon = WEP_ROCKET_LAUNCHER;
 562                         self.ammo_rockets = 999;
 563                 }
 564
 565                 if(cvar("g_nixnex"))
 566                 {
 567                         self.items = 0;
 568                         // will be done later
 569                 }
 570
 571                 if(cvar("g_minstagib"))
 572                 {
 573                         self.health = 100;
 574                         self.armorvalue = 0;
 575                         self.items = IT_NEX;
 576                         self.switchweapon = WEP_NEX;
 577                         self.ammo_cells = cvar("g_minstagib_ammo_start");
 578                         self.jump_interval = time;
 579                 }
 580
 581                 if(cvar("g_arena"))
 582                 {
 583                         Spawnqueue_Remove(self);
 584                         Spawnqueue_Mark(self);
 585                 }
 586
 587                 self.event_damage = PlayerDamage;
 588
 589                 self.bot_attack = TRUE;
 590
 591                 self.statdraintime = time + 5;
 592                 self.button0 = self.button1 = self.button2 = self.button3 = 0;
 593
 594                 if(self.killcount == -666) {
 595                         self.killcount = 0;
 596                         if(!cvar("g_arena"))
 597                         if(!cvar("g_lms"))
 598                                 self.frags = 0;
 599                 }
 600
 601                 self.cnt = WEP_LASER;
 602                 self.nixnex_lastchange_id = -1;
 603
 604                 CL_SpawnWeaponentity();
 605                 self.alpha = default_player_alpha;
 606                 self.exteriorweaponentity.alpha = default_weapon_alpha;
 607
 608                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval")*2;
 609                 self.lms_traveled_distance = 0;
 610
 611                 if(cvar("spawn_debug"))
 612                 {
 613                                 sprint(self, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 614                                 remove(spot);   // usefull for checking if there are spawnpoints, that let drop through the floor
 615                 }
 616
 617                 //stuffcmd(self, "chase_active 0");
 618                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
 619         } else if(self.classname == "observer") {
 620                 PutObserverInServer ();
 621         }
 622 }
 623
 624 /*
 625 =============
 626 SetNewParms
 627 =============
 628 */
 629 void SetNewParms (void)
 630 {
 631
 632 }
 633
 634 /*
 635 =============
 636 SetChangeParms
 637 =============
 638 */
 639 void SetChangeParms (void)
 640 {
 641
 642 }
 643
 644 /*
 645 =============
 646 ClientKill
 647
 648 Called when a client types 'kill' in the console
 649 =============
 650 */
 651 void ClientKill (void)
 652 {
 653         Damage(self, self, self, 100000, DEATH_KILL, self.origin, '0 0 0');
 654 }
 655
 656 /*
 657 =============
 658 ClientConnect
 659
 660 Called when a client connects to the server
 661 =============
 662 */
 663 string ColoredTeamName(float t);
 664 //void dom_player_join_team(entity pl);
 665 void ClientConnect (void)
 666 {
 667         //local float fh;
 668         local string s;
 669
 670         self.classname = "player_joining";
 671         self.flags = self.flags | FL_CLIENT;
 672         self.version_nagtime = time + 10 + random() * 10;
 673
 674         if(player_count<0)
 675         {
 676                 dprint("BUG player count is lower than zero, this cannot happen!\n");
 677                 player_count = 0;
 678         }
 679
 680         bot_clientconnect();
 681
 682         //if(cvar("g_domination"))
 683         //      dom_player_join_team(self);
 684
 685         //JoinBestTeam(self, FALSE);
 686
 687         if((cvar("sv_spectate") == 1 && !cvar("g_lms")) || cvar("g_campaign")) {
 688                 self.classname = "observer";
 689         } else {
 690                 self.classname = "player";
 691                 campaign_bots_may_start = 1;
 692         }
 693
 694         self.playerid = (playerid_last = playerid_last + 1);
 695         if(cvar("sv_eventlog"))
 696         {
 697                 if(clienttype(self) == CLIENTTYPE_REAL)
 698                         s = "player";
 699                 else
 700                         s = "bot";
 701                 GameLogEcho(strcat(":join:", ftos(self.playerid), ":", s, ":", self.netname), TRUE);
 702                 s = strcat(":team:", ftos(self.playerid), ":");
 703                 s = strcat(s, ftos(self.team));
 704                 GameLogEcho(s, FALSE);
 705         }
 706
 707         //stuffcmd(self, "set tmpviewsize $viewsize \n");
 708
 709         bprint ("^4",self.netname);
 710         bprint ("^4 connected");
 711
 712         if(cvar("g_domination") || cvar("g_ctf"))
 713         {
 714                 bprint(" and joined the ");
 715                 bprint(ColoredTeamName(self.team));
 716         }
 717
 718         bprint("\n");
 719
 720         self.welcomemessage_time = time + cvar("welcome_message_time");
 721         self.welcomemessage_time2 = 0;
 722
 723         /*
 724         // the client might not have his maps/%s.cfg file yet!
 725         // so send the one from the server...
 726         fh = fopen(strcat("maps/", mapname, ".cfg"), FILE_READ);
 727         if(fh >= 0)
 728         {
 729                 while((s = fgets(fh)))
 730                         stuffcmd(self, strcat(s, "\n"));
 731                 fclose(fh);
 732         }
 733         // and then execute the client's so he can still override CD tracks
 734
 735         not needed any more: current map download system disconnects and reconnects
 736         after the download, and then the file will be there
 737         */
 738         stuffcmd(self, strcat("exec maps/", mapname, ".cfg\n"));
 739
 740         // TODO: is this being used for anything else than cd tracks?
 741         // Remember: SVC_CDTRACK exists. Maybe it should be used.
 742
 743         // send prediction settings to the client
 744         stuffcmd(self, strcat("cl_movement_accelerate ", ftos(cvar("sv_accelerate")), "\n"));
 745         stuffcmd(self, strcat("cl_movement_friction ", ftos(cvar("sv_friction")), "\n"));
 746         stuffcmd(self, strcat("cl_movement_maxspeed ", ftos(cvar("sv_maxspeed")), "\n"));
 747         stuffcmd(self, strcat("cl_movement_airaccelerate ", ftos(cvar("sv_airaccelerate")), "\n"));
 748         stuffcmd(self, strcat("cl_movement_maxairspeed ", ftos(cvar("sv_maxairspeed")), "\n"));
 749         stuffcmd(self, strcat("cl_movement_stopspeed ", ftos(cvar("sv_stopspeed")), "\n"));
 750         stuffcmd(self, strcat("cl_movement_jumpvelocity ", ftos(cvar("g_balance_jumpheight")), "\n"));
 751         stuffcmd(self, strcat("cl_movement_stepheight ", ftos(cvar("sv_stepheight")), "\n"));
 752         stuffcmd(self, strcat("set cl_movement_friction_on_land ", ftos(cvar("sv_friction_on_land")), "\n"));
 753         stuffcmd(self, strcat("set cl_movement_airaccel_qw ", ftos(cvar("sv_airaccel_qw")), "\n"));
 754         stuffcmd(self, strcat("set cl_movement_airaccel_sideways_friction ", ftos(cvar("sv_airaccel_sideways_friction")), "\n"));
 755         stuffcmd(self, strcat("cl_movement_edgefriction 0\n"));
 756         // Wazat's grappling hook
 757         SetGrappleHookBindings();
 758
 759         // get autoswitch state from player
 760         stuffcmd(self, "alias autoswitch \"set cl_autoswitch $1; cmd autoswitch $1\"\n");
 761         stuffcmd(self, "cmd autoswitch $cl_autoswitch\n");
 762
 763         // get version info from player
 764         stuffcmd(self, "cmd clientversion $gameversion\n");
 765
 766         // get other cvars from player
 767         GetCvars(0);
 768
 769         // set cvar for team scoreboard
 770         if (teams_matter)
 771         {
 772                 local float t;
 773                 t = cvar("teamplay");
 774                 // we have to stuff the correct teamplay value because if this is a listen server, this changes the teamplay mode of the server itself, which is bad
 775                 stuffcmd(self, strcat("set teamplay ", ftos(t), "\n"));
 776         }
 777         else
 778                 stuffcmd(self, strcat("set teamplay 0\n"));
 779
 780         if(cvar("g_lms"))
 781         {
 782                 self.frags = cvar("fraglimit");
 783                 // no fraglimit was set, so player gets 999 lives
 784                 if(self.frags < 1)
 785                         self.frags = 999;
 786
 787                 self.frags = LMS_NewPlayerLives();
 788                 if(!self.frags)
 789                 {
 790                         self.frags = -666;
 791                 }
 792         }
 793         else if(cvar("g_arena"))
 794         {
 795                 self.classname = "observer";
 796                 Spawnqueue_Insert(self);
 797         }
 798
 799         bot_relinkplayerlist();
 800
 801         self.jointime = time;
 802 }
 803
 804 /*
 805 =============
 806 ClientDisconnect
 807
 808 Called when a client disconnects from the server
 809 =============
 810 */
 811 void(entity e) DropFlag;
 812 .entity chatbubbleentity;
 813 .entity teambubbleentity;
 814 void ClientDisconnect (void)
 815 {
 816         float save;
 817         if(cvar("sv_eventlog"))
 818                 GameLogEcho(strcat(":part:", ftos(self.playerid)), FALSE);
 819         bprint ("^4",self.netname);
 820         bprint ("^4 disconnected\n");
 821
 822         if (self.chatbubbleentity)
 823         {
 824                 remove (self.chatbubbleentity);
 825                 self.chatbubbleentity = world;
 826         }
 827
 828         if (self.teambubbleentity)
 829         {
 830                 remove (self.teambubbleentity);
 831                 self.teambubbleentity = world;
 832         }
 833
 834         DropAllRunes(self);
 835
 836         if(self.flagcarried)
 837                 DropFlag(self.flagcarried);
 838
 839         DistributeFragsAmongTeam(self, self.team, 1);
 840
 841         save = self.flags;
 842         self.flags = self.flags - (self.flags & FL_CLIENT);
 843         bot_relinkplayerlist();
 844         self.flags = save;
 845
 846         // remove laserdot
 847         if(self.weaponentity)
 848                 if(self.weaponentity.lasertarget)
 849                         remove(self.weaponentity.lasertarget);
 850
 851         if(cvar("g_arena"))
 852         {
 853                 Spawnqueue_Unmark(self);
 854                 Spawnqueue_Remove(self);
 855         }
 856
 857         // free cvars
 858         GetCvars(-1);
 859 }
 860
 861 .float buttonchat;
 862 void() ChatBubbleThink =
 863 {
 864         self.nextthink = time;
 865         if (!self.owner.modelindex || self.owner.chatbubbleentity != self)
 866         {
 867                 self.owner.chatbubbleentity = world;
 868                 remove(self);
 869                 return;
 870         }
 871         setorigin(self, self.owner.origin + '0 0 15' + self.owner.maxs_z * '0 0 1');
 872         if (self.owner.buttonchat && !self.owner.deadflag)
 873                 self.model = self.mdl;
 874         else
 875                 self.model = "";
 876 };
 877
 878 void() UpdateChatBubble =
 879 {
 880         if (!self.modelindex)
 881                 return;
 882         // spawn a chatbubble entity if needed
 883         if (!self.chatbubbleentity)
 884         {
 885                 self.chatbubbleentity = spawn();
 886                 self.chatbubbleentity.owner = self;
 887                 self.chatbubbleentity.exteriormodeltoclient = self;
 888                 self.chatbubbleentity.think = ChatBubbleThink;
 889                 self.chatbubbleentity.nextthink = time;
 890                 setmodel(self.chatbubbleentity, "models/misc/chatbubble.spr");
 891                 setorigin(self.chatbubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
 892                 self.chatbubbleentity.mdl = self.chatbubbleentity.model;
 893                 self.chatbubbleentity.model = "";
 894         }
 895 }
 896
 897
 898 void() TeamBubbleThink =
 899 {
 900         self.nextthink = time;
 901         if (!self.owner.modelindex || self.owner.teambubbleentity != self)
 902         {
 903                 self.owner.teambubbleentity = world;
 904                 remove(self);
 905                 return;
 906         }
 907 //      setorigin(self, self.owner.origin + '0 0 15' + self.owner.maxs_z * '0 0 1');  // bandwidth hog. setattachment does this now
 908         if (self.owner.buttonchat || self.owner.deadflag)
 909                 self.model = "";
 910         else
 911                 self.model = self.mdl;
 912
 913 };
 914
 915 float() TeamBubble_customizeentityforclient
 916 {
 917         return (self.owner != other && self.owner.team == other.team && other.killcount > -666);
 918 }
 919
 920 void() UpdateTeamBubble =
 921 {
 922         if (!self.modelindex || !cvar("teamplay"))
 923                 return;
 924         // spawn a teambubble entity if needed
 925         if (!self.teambubbleentity && cvar("teamplay"))
 926         {
 927                 self.teambubbleentity = spawn();
 928                 self.teambubbleentity.owner = self;
 929                 self.teambubbleentity.exteriormodeltoclient = self;
 930                 self.teambubbleentity.think = TeamBubbleThink;
 931                 self.teambubbleentity.nextthink = time;
 932                 setmodel(self.teambubbleentity, "models/misc/teambubble.spr");
 933 //              setorigin(self.teambubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
 934                 setorigin(self.teambubbleentity, self.teambubbleentity.origin + '0 0 15' + self.maxs_z * '0 0 1');
 935                 setattachment(self.teambubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
 936                 self.teambubbleentity.mdl = self.teambubbleentity.model;
 937                 self.teambubbleentity.model = self.teambubbleentity.mdl;
 938                 self.teambubbleentity.customizeentityforclient = TeamBubble_customizeentityforclient;
 939         }
 940 }
 941
 942 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
 943 // added to the model skins
 944 /*void() UpdateColorModHack =
 945 {
 946         local float c;
 947         c = self.clientcolors & 15;
 948         // LordHavoc: only bothering to support white, green, red, yellow, blue
 949              if (teamplay == 0) self.colormod = '0 0 0';
 950         else if (c ==  0) self.colormod = '1.00 1.00 1.00';
 951         else if (c ==  3) self.colormod = '0.10 1.73 0.10';
 952         else if (c ==  4) self.colormod = '1.73 0.10 0.10';
 953         else if (c == 12) self.colormod = '1.22 1.22 0.10';
 954         else if (c == 13) self.colormod = '0.10 0.10 1.73';
 955         else self.colormod = '1 1 1';
 956 };*/
 957
 958 /*
 959 =============
 960 PlayerJump
 961
 962 When you press the jump key
 963 =============
 964 */
 965 void PlayerJump (void)
 966 {
 967         float mjumpheight;
 968
 969         mjumpheight = cvar("g_balance_jumpheight");
 970         if (self.waterlevel >= 2)
 971         {
 972                 if (self.watertype == CONTENT_WATER)
 973                         self.velocity_z = 200;
 974                 else if (self.watertype == CONTENT_SLIME)
 975                         self.velocity_z = 80;
 976                 else
 977                         self.velocity_z = 50;
 978
 979                 return;
 980         }
 981
 982
 983         if (!(self.flags & FL_ONGROUND))
 984                 return;
 985
 986         if (!(self.flags & FL_JUMPRELEASED))
 987                 return;
 988
 989         if(cvar("g_runematch"))
 990         {
 991                 if(self.runes & RUNE_SPEED)
 992                 {
 993                         if(self.runes & CURSE_SLOW)
 994                                 mjumpheight = mjumpheight * cvar("g_balance_rune_speed_combo_jumpheight");
 995                         else
 996                                 mjumpheight = mjumpheight * cvar("g_balance_rune_speed_jumpheight");
 997                 }
 998                 else if(self.runes & CURSE_SLOW)
 999                 {
1000                         mjumpheight = mjumpheight * cvar("g_balance_curse_slow_jumpheight");
1001                 }
1002         }
1003
1004         if(cvar("g_minstagib") && (self.items & IT_INVINCIBLE))
1005         {
1006                 mjumpheight = mjumpheight * cvar("g_balance_rune_speed_jumpheight");
1007         }
1008
1009         self.velocity_z = self.velocity_z + mjumpheight;
1010         self.oldvelocity_z = self.velocity_z;
1011
1012         self.flags = self.flags - FL_ONGROUND;
1013         self.flags = self.flags - FL_JUMPRELEASED;
1014 }
1015
1016 void() CheckWaterJump =
1017 {
1018         local vector start, end;
1019
1020 // check for a jump-out-of-water
1021         makevectors (self.angles);
1022         start = self.origin;
1023         start_z = start_z + 8;
1024         v_forward_z = 0;
1025         normalize(v_forward);
1026         end = start + v_forward*24;
1027         traceline (start, end, TRUE, self);
1028         if (trace_fraction < 1)
1029         {       // solid at waist
1030                 start_z = start_z + self.maxs_z - 8;
1031                 end = start + v_forward*24;
1032                 self.movedir = trace_plane_normal * -50;
1033                 traceline (start, end, TRUE, self);
1034                 if (trace_fraction == 1)
1035                 {       // open at eye level
1036                         self.flags = self.flags | FL_WATERJUMP;
1037                         self.velocity_z = 225;
1038                         self.flags = self.flags - (self.flags & FL_JUMPRELEASED);
1039                         self.teleport_time = time + 2;  // safety net
1040                         return;
1041                 }
1042         }
1043 };
1044
1045
1046 void respawn(void)
1047 {
1048         CopyBody(1);
1049         PutClientInServer();
1050 }
1051
1052 void player_powerups (void)
1053 {
1054         if (cvar("g_minstagib"))
1055         {
1056                 self.effects = EF_FULLBRIGHT;
1057                 if (self.items & IT_STRENGTH)
1058                 {
1059                         if (time > self.strength_finished)
1060                         {
1061                                 self.alpha = default_player_alpha;
1062                                 self.exteriorweaponentity.alpha = default_weapon_alpha;
1063                                 self.items = self.items - (self.items & IT_STRENGTH);
1064                                 sprint(self, "^3Invisibility has worn off\n");
1065                         }
1066                 }
1067                 else
1068                 {
1069                         if (time < self.strength_finished)
1070                         {
1071                                 self.alpha = cvar("g_minstagib_invis_alpha");
1072                                 self.exteriorweaponentity.alpha = cvar("g_minstagib_invis_alpha");
1073                                 self.items = self.items | IT_STRENGTH;
1074                                 sprint(self, "^3You are invisible\n");
1075                         }
1076                 }
1077
1078                 if (self.items & IT_INVINCIBLE)
1079                 {
1080                         if (time > self.invincible_finished)
1081                         {
1082                                 self.items = self.items - (self.items & IT_INVINCIBLE);
1083                                 sprint(self, "^3Speed has worn off\n");
1084                         }
1085                 }
1086                 else
1087                 {
1088                         if (time < self.invincible_finished)
1089                         {
1090                                 self.items = self.items | IT_INVINCIBLE;
1091                                 sprint(self, "^3You are on speed\n");
1092                         }
1093                 }
1094                 return;
1095         }
1096
1097         self.effects = self.effects - (self.effects & (EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT));
1098         if (self.items & IT_STRENGTH)
1099         {
1100                 self.effects = self.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1101                 if (time > self.strength_finished)
1102                 {
1103                         self.items = self.items - (self.items & IT_STRENGTH);
1104                         sprint(self, "^3Strength has worn off\n");
1105                 }
1106         }
1107         else
1108         {
1109                 if (time < self.strength_finished)
1110                 {
1111                         self.items = self.items | IT_STRENGTH;
1112                         sprint(self, "^3Strength infuses your weapons with devastating power\n");
1113                 }
1114         }
1115         if (self.items & IT_INVINCIBLE)
1116         {
1117                 self.effects = self.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1118                 if (time > self.invincible_finished)
1119                 {
1120                         self.items = self.items - (self.items & IT_INVINCIBLE);
1121                         sprint(self, "^3Shield has worn off\n");
1122                 }
1123         }
1124         else
1125         {
1126                 if (time < self.invincible_finished)
1127                 {
1128                         self.items = self.items | IT_INVINCIBLE;
1129                         sprint(self, "^3Shield surrounds you\n");
1130                 }
1131         }
1132
1133         if (cvar("g_fullbrightplayers"))
1134                 self.effects = self.effects | EF_FULLBRIGHT;
1135
1136         // midair gamemode: damage only while in the air
1137         // if in midair mode, being on ground grants temporary invulnerability
1138         // (this is so that multishot weapon don't clear the ground flag on the
1139         // first damage in the frame, leaving the player vulnerable to the
1140         // remaining hits in the same frame)
1141         if (self.flags & FL_ONGROUND)
1142         if (cvar("g_midair"))
1143                 self.spawnshieldtime = max(self.spawnshieldtime, time + cvar("g_midair_shieldtime"));
1144
1145         if (time < self.spawnshieldtime)
1146                 self.effects = self.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1147 }
1148
1149 float CalcRegen(float current, float stable, float maxv, float regenfactor)
1150 {
1151         if(current > stable)
1152                 return current;
1153         else if(current > stable - 0.25) // when close enough, "snap"
1154                 return stable;
1155         else
1156                 return bound(0, current + (stable - current) * regenfactor * frametime, maxv);
1157 }
1158
1159 void player_regen (void)
1160 {
1161         float maxh, maxa, limith, limita, max_mod, regen_mod, rot_mod, limit_mod;
1162         maxh = cvar("g_balance_health_stable");
1163         maxa = cvar("g_balance_armor_stable");
1164         limith = cvar("g_balance_health_limit");
1165         limita = cvar("g_balance_armor_limit");
1166
1167         if (cvar("g_minstagib") || (cvar("g_lms") && !cvar("g_lms_regenerate")))
1168                 return;
1169
1170         if(cvar("g_runematch"))
1171         {
1172                 max_mod = regen_mod = rot_mod = limit_mod = 1;
1173                 if (self.runes & RUNE_REGEN)
1174                 {
1175                         if (self.runes & CURSE_VENOM) // do we have both rune/curse?
1176                         {
1177                                 regen_mod = cvar("g_balance_rune_regen_combo_regenrate");
1178                                 max_mod = cvar("g_balance_rune_regen_combo_hpmod");
1179                                 limit_mod = cvar("g_balance_rune_regen_combo_limitmod");
1180                         }
1181                         else
1182                         {
1183                                 regen_mod = cvar("g_balance_rune_regen_regenrate");
1184                                 max_mod = cvar("g_balance_rune_regen_hpmod");
1185                                 limit_mod = cvar("g_balance_rune_regen_limitmod");
1186                         }
1187                 }
1188                 else if (self.runes & CURSE_VENOM)
1189                 {
1190                         max_mod = cvar("g_balance_curse_venom_hpmod");
1191                         if (self.runes & RUNE_REGEN) // do we have both rune/curse?
1192                                 rot_mod = cvar("g_balance_rune_regen_combo_rotrate");
1193                         else
1194                                 rot_mod = cvar("g_balance_curse_venom_rotrate");
1195                         limit_mod = cvar("g_balance_curse_venom_limitmod");
1196                         //if (!self.runes & RUNE_REGEN)
1197                         //      rot_mod = cvar("g_balance_curse_venom_rotrate");
1198                 }
1199                 maxh = maxh * max_mod;
1200                 //maxa = maxa * max_mod;
1201
1202                 if (time > self.pauserotarmor_finished)
1203                 {
1204                         if (self.armorvalue > maxa)
1205                                 self.armorvalue = bound(0, self.armorvalue + (maxa - self.armorvalue) * cvar("g_balance_armor_rot") * frametime, 1000);
1206                 }
1207                 if (time > self.pauserothealth_finished)
1208                 {
1209                         if (self.health > maxh)
1210                                 self.health = bound(0, self.health + (maxh - self.health) * rot_mod*cvar("g_balance_health_rot") * frametime, 1000);
1211                 }
1212                 if (time > self.pauseregen_finished)
1213                 {
1214                         self.health = CalcRegen(self.health, maxh, 1000, regen_mod * cvar("g_balance_health_regen"));
1215                         self.armorvalue = CalcRegen(self.armorvalue, maxa, 1000, cvar("g_balance_armor_regen"));
1216                 }
1217         }
1218         else
1219         {
1220                 if (time > self.pauserothealth_finished)
1221                 if (self.health > maxh)
1222                         self.health = bound(0, self.health + (maxh - self.health) * cvar("g_balance_health_rot") * frametime, 1000);
1223                 if (time > self.pauserotarmor_finished)
1224                 if (self.armorvalue > maxa)
1225                         self.armorvalue = bound(0, self.armorvalue + (maxa - self.armorvalue) * cvar("g_balance_armor_rot") * frametime, 1000);
1226                 if (time > self.pauseregen_finished)
1227                 {
1228                         self.health = CalcRegen(self.health, maxh, 1000, cvar("g_balance_health_regen"));
1229                         self.armorvalue = CalcRegen(self.armorvalue, maxa, 1000, cvar("g_balance_armor_regen"));
1230                 }
1231         }
1232
1233         if (self.health > limith)
1234                 self.health = limith;
1235         if(self.health < 1)
1236                 self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
1237         if (self.armorvalue > limita)
1238                 self.armorvalue = limita;
1239 }
1240
1241 /*
1242 ======================
1243 spectate mode routines
1244 ======================
1245 */
1246 void SpectateCopy(entity spectatee) {
1247         self.armortype = spectatee.armortype;
1248         self.armorvalue = spectatee.armorvalue;
1249         self.currentammo = spectatee.currentammo;
1250         self.effects = spectatee.effects;
1251         self.health = spectatee.health;
1252         self.impulse = 0;
1253         self.items = spectatee.items;
1254         self.punchangle = spectatee.punchangle;
1255         self.view_ofs = spectatee.view_ofs;
1256         self.v_angle = spectatee.v_angle;
1257         self.viewzoom = spectatee.viewzoom;
1258         setorigin(self, spectatee.origin);
1259         setsize(self, spectatee.mins, spectatee.maxs);
1260 }
1261
1262 void SpectateUpdate() {
1263         if(!self.enemy)
1264                         PutObserverInServer();
1265
1266         if (self != self.enemy) {
1267                 if(self.enemy.flags & FL_NOTARGET)
1268                         PutObserverInServer();
1269                 SpectateCopy(self.enemy);
1270                 self.dmg_take = self.enemy.dmg_take;
1271                 self.dmg_save = self.enemy.dmg_save;
1272                 self.dmg_inflictor = self.enemy.dmg_inflictor;
1273                 self.fixangle = TRUE;
1274                 self.angles = self.enemy.v_angle;
1275                 //msg_entity = self;
1276                 //WriteByte(MSG_ONE, SVC_SETANGLE);
1277                 //WriteAngle(MSG_ONE, self.enemy.v_angle_x);
1278                 //WriteAngle(MSG_ONE, self.enemy.v_angle_y);
1279                 //WriteAngle(MSG_ONE, self.enemy.v_angle_z);
1280         }
1281 }
1282
1283 float SpectateNext() {
1284         other = find(self.enemy, classname, "player");
1285         if (!other) {
1286                 other = find(other, classname, "player");
1287         }
1288         if (other) {
1289                 self.enemy = other;
1290         }
1291         if(self.enemy.classname == "player") {
1292                 msg_entity = self;
1293                 WriteByte(MSG_ONE, SVC_SETVIEW);
1294                 WriteEntity(MSG_ONE, self.enemy);
1295                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
1296                 SpectateUpdate();
1297                 return 1;
1298         } else {
1299                 return 0;
1300         }
1301 }
1302
1303 /*
1304 =============
1305 ShowRespawnCountdown()
1306
1307 Update a respawn countdown display.
1308 =============
1309 */
1310 void ShowRespawnCountdown()
1311 {
1312         float number;
1313         if(self.deadflag == DEAD_NO) // just respawned?
1314                 return;
1315         else
1316         {
1317                 number = ceil(self.death_time - time);
1318                 if(number <= 0)
1319                         return;
1320                 if(number <= self.respawn_countdown)
1321                 {
1322                         self.respawn_countdown = number - 1;
1323                         stuffcmd(self, strcat("play2 announcer/robotic/", ftos(number), ".ogg\n"));
1324                 }
1325         }
1326 }
1327
1328 /*
1329 =============
1330 PlayerPreThink
1331
1332 Called every frame for each client before the physics are run
1333 =============
1334 */
1335 void() ctf_setstatus;
1336 void PlayerPreThink (void)
1337 {
1338         // version nagging
1339         if(self.version_nagtime)
1340                 if(self.cvar_g_nexuizversion)
1341                         if(time > self.version_nagtime)
1342                         {
1343                                 if(strstr(self.cvar_g_nexuizversion, "svn", 0) < 0)
1344                                         if(self.cvar_g_nexuizversion != cvar_string("g_nexuizversion"))
1345                                         {
1346                                                 dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Nexuiz ", cvar_string("g_nexuizversion"), "^7, you have ^3Nexuiz ", self.cvar_g_nexuizversion, "\n");
1347                                                 sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Nexuiz ", cvar_string("g_nexuizversion"), "^7, you have ^3Nexuiz ", self.cvar_g_nexuizversion, "\n"));
1348                                         }
1349                                 self.version_nagtime = 0;
1350                         }
1351
1352         if(self.classname == "player") {
1353                 local vector m1, m2;
1354
1355 //              if(self.netname == "Wazat")
1356 //                      bprint(strcat(self.classname, "\n"));
1357
1358                 CheckRules_Player();
1359
1360                 Nixnex_GiveCurrentWeapon();
1361
1362                 if(self.button7)
1363                         PrintWelcomeMessage(self);
1364
1365                 if(cvar("g_lms") || !cvar("sv_spectate"))
1366                 if((time - self.jointime) <= cvar("welcome_message_time"))
1367                         PrintWelcomeMessage(self);
1368
1369                 if (intermission_running)
1370                 {
1371                         IntermissionThink ();   // otherwise a button could be missed between
1372                         return;                                 // the think tics
1373                 }
1374
1375                 if (self.deadflag != DEAD_NO)
1376                 {
1377                         float button_pressed, force_respawn;
1378                         player_anim();
1379                         button_pressed = self.button0 || self.button2 || self.button3 || self.button4 || self.button5 || self.button6 || self.button7 || self.button8 || self.buttonuse;
1380                         force_respawn = cvar("g_lms") || cvar("g_forced_respawn");
1381                         if (self.deadflag == DEAD_DYING)
1382                         {
1383                                 if(force_respawn)
1384                                         self.deadflag = DEAD_RESPAWNING;
1385                                 else if(!button_pressed)
1386                                         self.deadflag = DEAD_DEAD;
1387                         }
1388                         else if (self.deadflag == DEAD_DEAD)
1389                         {
1390                                 if(button_pressed)
1391                                         self.deadflag = DEAD_RESPAWNABLE;
1392                         }
1393                         else if (self.deadflag == DEAD_RESPAWNABLE)
1394                         {
1395                                 if(!button_pressed)
1396                                         self.deadflag = DEAD_RESPAWNING;
1397                         }
1398                         else if (self.deadflag == DEAD_RESPAWNING)
1399                         {
1400                                 if(time > self.death_time)
1401                                         respawn();
1402                         }
1403                         ShowRespawnCountdown();
1404                         return;
1405                 }
1406
1407                 if(cvar("g_lms") && !self.deadflag && cvar("g_lms_campcheck_interval"))
1408                 {
1409                         vector dist;
1410
1411                         // calculate player movement (in 2 dimensions only, so jumping on one spot doesn't count as movement)
1412                         dist = self.oldorigin - self.origin;
1413                         dist_z = 0;
1414                         self.lms_traveled_distance += fabs(vlen(dist));
1415
1416                         if(cvar("g_campaign"))
1417                         if(!campaign_bots_may_start)
1418                         {
1419                                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval")*2;
1420                                 self.lms_traveled_distance = 0;
1421                         }
1422
1423                         if(time > self.lms_nextcheck)
1424                         {
1425                                 //sprint(self, "distance: ", ftos(self.lms_traveled_distance), "\n");
1426                                 if(self.lms_traveled_distance < cvar("g_lms_campcheck_distance"))
1427                                 {
1428                                         centermsg_set(CENTERMSG_CAMP, cvar_string("g_lms_campcheck_message"));
1429                                         // FIXME KadaverJack: gibbing player here causes playermodel to bounce around, instead of eye.md3
1430                                         // I wasn't able to find out WHY that happens, so I put a workaround in place that shall prevent players from being gibbed :(
1431                                         Damage(self, self, self, bound(0, cvar("g_lms_campcheck_damage"), self.health + self.armorvalue * cvar("g_balance_armor_blockpercent") + 5), DEATH_CAMP, self.origin, '0 0 0');
1432                                 }
1433                                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval");
1434                                 self.lms_traveled_distance = 0;
1435                         }
1436                 }
1437
1438                 if (self.button5 && !self.hook.state)
1439                 {
1440                         if (!self.crouch)
1441                         {
1442                                 self.crouch = TRUE;
1443                                 self.view_ofs = PL_CROUCH_VIEW_OFS;
1444                                 setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX);
1445                         }
1446                 }
1447                 else
1448                 {
1449                         if (self.crouch)
1450                         {
1451                                 tracebox(self.origin, PL_MIN, PL_MAX, self.origin, FALSE, self);
1452                                 if (!trace_startsolid)
1453                                 {
1454                                         self.crouch = FALSE;
1455                                         self.view_ofs = PL_VIEW_OFS;
1456                                         setsize (self, PL_MIN, PL_MAX);
1457                                 }
1458                         }
1459                 }
1460
1461                 if(cvar("sv_defaultcharacter") == 1 && !teams_matter) {
1462                         local string defaultmodel;
1463                         defaultmodel = CheckPlayerModel(cvar_string("sv_defaultplayermodel"));
1464
1465                         if (defaultmodel != self.model)
1466                         {
1467                                 m1 = self.mins;
1468                                 m2 = self.maxs;
1469                                 setmodel_lod (self, defaultmodel);
1470                                 setsize (self, m1, m2);
1471                         }
1472
1473                         if (self.skin != cvar("sv_defaultplayerskin"))
1474                                 self.skin = cvar("sv_defaultplayerskin");
1475                 } else {
1476                         if (self.playermodel != self.model)
1477                         {
1478                                 self.playermodel = CheckPlayerModel(self.playermodel);
1479                                 m1 = self.mins;
1480                                 m2 = self.maxs;
1481                                 setmodel_lod (self, self.playermodel);
1482                                 setsize (self, m1, m2);
1483                         }
1484
1485                         if(teams_matter)
1486                         {
1487                                 if (self.skin != math_mod(stof(self.playerskin), NUM_PLAYERSKINS_TEAMPLAY))
1488                                         self.skin = math_mod(stof(self.playerskin), NUM_PLAYERSKINS_TEAMPLAY);
1489                         }
1490                         else
1491                         {
1492                                 if (self.skin != stof(self.playerskin))
1493                                         self.skin = stof(self.playerskin);
1494                         }
1495                 }
1496
1497                 GrapplingHookFrame();
1498
1499                 W_WeaponFrame();
1500
1501                 if (self.button4 || (self.weapon == WEP_NEX && self.button3))
1502                 {
1503                         if (cvar("g_minstagib") && self.button3)
1504                         {
1505                                 if (self.jump_interval <= (time + 0.1))
1506                                 {
1507                                         self.jump_interval = time + 1;
1508                                         W_Laser_Attack();
1509                                 }
1510                         }
1511                         else if (self.viewzoom > 0.4)
1512                                 self.viewzoom = max (0.4, self.viewzoom - frametime * 2);
1513                 }
1514                 else if (self.viewzoom < 1.0)
1515                         self.viewzoom = min (1.0, self.viewzoom + frametime);
1516
1517
1518                 if (self.button2)
1519                         PlayerJump ();
1520                 else
1521                         self.flags = self.flags | FL_JUMPRELEASED;
1522
1523                 player_powerups();
1524                 player_regen();
1525                 player_anim();
1526
1527                 if (cvar("g_minstagib"))
1528                         minstagib_ammocheck();
1529
1530                 ctf_setstatus();
1531
1532                 //self.angles_y=self.v_angle_y + 90;   // temp
1533
1534                 if (self.waterlevel == 2)
1535                         CheckWaterJump ();
1536
1537                 //if (TetrisPreFrame()) return;
1538         } else if(gameover) {
1539                 if (intermission_running)
1540                         IntermissionThink ();   // otherwise a button could be missed between
1541                 return;
1542         } else if(self.classname == "observer") {
1543
1544                 if (self.flags & FL_JUMPRELEASED) {
1545                         if (self.button2 && self.version == cvar("gameversion")) {
1546                                 if(!cvar("teamplay") || cvar("g_campaign") || cvar("g_balance_teams")) {
1547                                         self.flags = self.flags & !FL_JUMPRELEASED;
1548                                         self.classname = "player";
1549                                         if(cvar("g_campaign") || cvar("g_balance_teams"))
1550                                                 JoinBestTeam(self, 0);
1551                                         if(cvar("g_campaign"))
1552                                                 campaign_bots_may_start = 1;
1553                                         PutClientInServer();
1554                                         if(self.flags & !FL_NOTARGET)
1555                                                 bprint (strcat("^4", self.netname, "^4 is playing now\n"));
1556                                         centermsg_reset();
1557                                         return;
1558                                 } else {
1559                                         self.flags = self.flags & !FL_JUMPRELEASED;
1560                                         stuffcmd(self,"menu_showteamselect\n");
1561                                         return;
1562                                 }
1563                         } else if(self.button0 && self.version == cvar("gameversion")) {
1564                                 self.flags = self.flags & !FL_JUMPRELEASED;
1565                                 if(SpectateNext() == 1) {
1566                                         self.classname = "spectator";
1567                                 }
1568                         }
1569                 } else {
1570                         if (!(self.button0 || self.button2)) {
1571                                 self.flags = self.flags | FL_JUMPRELEASED;
1572                         }
1573                 }
1574                 PrintWelcomeMessage(self);
1575         } else if(self.classname == "spectator") {
1576                 if (self.flags & FL_JUMPRELEASED) {
1577                         if (self.button2 && self.version == cvar("gameversion")) {
1578                                 if(!cvar("teamplay") || cvar("g_campaign") || cvar("g_balance_teams")) {
1579                                         self.flags = self.flags & !FL_JUMPRELEASED;
1580                                         self.classname = "player";
1581                                         if(!cvar("g_lms"))
1582                                                 bprint (strcat("^4", self.netname, "^4 is playing now\n"));
1583
1584                                         if(cvar("g_campaign") || cvar("g_balance_teams"))
1585                                                 JoinBestTeam(self, 0);
1586                                         if(cvar("g_campaign"))
1587                                                 campaign_bots_may_start = 1;
1588                                         PutClientInServer();
1589                                         centermsg_reset();
1590                                         return;
1591                                 } else {
1592                                         self.flags = self.flags & !FL_JUMPRELEASED;
1593                                         stuffcmd(self,"menu_showteamselect\n");
1594                                         return;
1595                                 }
1596                         } else if(self.button0) {
1597                                 self.flags = self.flags & !FL_JUMPRELEASED;
1598                                 if(SpectateNext() == 1) {
1599                                         self.classname = "spectator";
1600                                 } else {
1601                                         self.classname = "observer";
1602                                         PutClientInServer();
1603                                 }
1604                         } else if (self.button3) {
1605                                 self.flags = self.flags & !FL_JUMPRELEASED;
1606                                 self.classname = "observer";
1607                                 PutClientInServer();
1608                         } else {
1609                                 SpectateUpdate();
1610                         }
1611                 } else {
1612                         if (!(self.button0 || self.button3)) {
1613                                 self.flags = self.flags | FL_JUMPRELEASED;
1614                         }
1615                 }
1616                 PrintWelcomeMessage(self);
1617                 self.flags = self.flags | FL_CLIENT | FL_NOTARGET;
1618         }
1619 }
1620
1621
1622 /*
1623 =============
1624 PlayerPostThink
1625
1626 Called every frame for each client after the physics are run
1627 =============
1628 */
1629 void PlayerPostThink (void)
1630 {
1631         // Savage: Check for nameless players
1632         if (strlen(self.netname) < 1) {
1633                 self.netname = "Player";
1634                 stuffcmd(self, "seta _cl_name Player\n");
1635         }
1636
1637         if(self.classname == "player") {
1638                 CheckRules_Player();
1639                 UpdateChatBubble();
1640                 UpdateTeamBubble();
1641                 if (self.deadflag == DEAD_NO)
1642                 if (self.impulse)
1643                         ImpulseCommands ();
1644                 if (intermission_running)
1645                         return;         // intermission or finale
1646
1647                 //PrintWelcomeMessage(self);
1648                 //if (TetrisPostFrame()) return;
1649         } else if (self.classname == "observer") {
1650                 //do nothing
1651         } else if (self.classname == "spectator") {
1652                 //do nothing
1653         }
1654         Arena_Warmup();
1655 }