data/qcsrc/server/cl_client.qc

   1 .float wantswelcomemessage;
   2 .string netname_previous;
   3
   4 void spawnfunc_info_player_survivor (void)
   5 {
   6         spawnfunc_info_player_deathmatch();
   7 }
   8
   9 void spawnfunc_info_player_start (void)
  10 {
  11         spawnfunc_info_player_deathmatch();
  12 }
  13
  14 void spawnfunc_info_player_deathmatch (void)
  15 {
  16         self.classname = "info_player_deathmatch";
  17         relocate_spawnpoint();
  18 }
  19
  20 void spawnpoint_use()
  21 {
  22         if(teams_matter)
  23         if(have_team_spawns)
  24         {
  25                 self.team = activator.team;
  26                 some_spawn_has_been_used = 1;
  27         }
  28 };
  29
  30 // Returns:
  31 //   -1 if a spawn can't be used
  32 //   otherwise, a weight of the spawnpoint
  33 float Spawn_Score(entity spot, entity playerlist, float teamcheck)
  34 {
  35         float shortest, thisdist;
  36         entity player;
  37
  38         // filter out spots for the wrong team
  39         if(teamcheck)
  40         if(spot.team != teamcheck)
  41                 return -1;
  42
  43         // filter out spots for assault
  44         if(spot.target != "") {
  45                 local entity ent;
  46                 ent = find(world, targetname, spot.target);
  47                 while(ent) {
  48                         if(ent.classname == "target_objective")
  49                                 if(ent.health < 0 || ent.health >= ASSAULT_VALUE_INACTIVE)
  50                                         return -1;
  51                         ent = find(ent, targetname, spot.target);
  52                 }
  53         }
  54
  55         player = playerlist;
  56         shortest = vlen(world.maxs - world.mins);
  57         for(player = playerlist; player; player = player.chain)
  58                 if (player != self)
  59                 {
  60                         thisdist = vlen(player.origin - spot.origin);
  61                         if (thisdist < shortest)
  62                                 shortest = thisdist;
  63                 }
  64         return shortest;
  65 }
  66
  67 float spawn_allbad;
  68 float spawn_allgood;
  69 entity Spawn_FilterOutBadSpots(entity firstspot, entity playerlist, float mindist, float teamcheck)
  70 {
  71         local entity spot, spotlist, spotlistend;
  72         spawn_allgood = TRUE;
  73         spawn_allbad = TRUE;
  74
  75         spotlist = world;
  76         spotlistend = world;
  77
  78         for(spot = firstspot; spot; spot = spot.chain)
  79         {
  80                 spot.frags = Spawn_Score(spot, playerlist, teamcheck);
  81
  82                 if(cvar("spawn_debugview"))
  83                 {
  84                         setmodel(spot, "models/runematch/rune.mdl");
  85                         if(spot.frags < mindist)
  86                         {
  87                                 spot.colormod = '1 0 0';
  88                                 spot.scale = 1;
  89                         }
  90                         else
  91                         {
  92                                 spot.colormod = '0 1 0';
  93                                 spot.scale = spot.frags / mindist;
  94                         }
  95                 }
  96
  97                 if(spot.frags >= 0) // spawning allowed here
  98                 {
  99                         if(spot.frags < mindist)
 100                         {
 101                                 // too short distance
 102                                 spawn_allgood = FALSE;
 103                         }
 104                         else
 105                         {
 106                                 // perfect
 107                                 spawn_allbad = FALSE;
 108
 109                                 if(spotlistend)
 110                                         spotlistend.chain = spot;
 111                                 spotlistend = spot;
 112                                 if(!spotlist)
 113                                         spotlist = spot;
 114
 115                                 /*
 116                                 if(teamcheck)
 117                                 if(spot.team != teamcheck)
 118                                         error("invalid spawn added");
 119
 120                                 print("added ", etos(spot), "\n");
 121                                 */
 122                         }
 123                 }
 124         }
 125         if(spotlistend)
 126                 spotlistend.chain = world;
 127
 128         /*
 129                 entity e;
 130                 if(teamcheck)
 131                         for(e = spotlist; e; e = e.chain)
 132                         {
 133                                 print("seen ", etos(e), "\n");
 134                                 if(e.team != teamcheck)
 135                                         error("invalid spawn found");
 136                         }
 137         */
 138
 139         return spotlist;
 140 }
 141
 142 entity Spawn_WeightedPoint(entity firstspot, float lower, float upper, float exponent)
 143 {
 144         // weight of a point: bound(lower, mindisttoplayer, upper)^exponent
 145         // multiplied by spot.cnt (useful if you distribute many spawnpoints in a small area)
 146         local entity spot;
 147
 148         RandomSelection_Init();
 149         for(spot = firstspot; spot; spot = spot.chain)
 150                 RandomSelection_Add(spot, 0, pow(bound(lower, spot.frags, upper), exponent) * spot.cnt);
 151
 152         return RandomSelection_chosen_ent;
 153 }
 154
 155 /*
 156 =============
 157 SelectSpawnPoint
 158
 159 Finds a point to respawn
 160 =============
 161 */
 162 entity SelectSpawnPoint (float anypoint)
 163 {
 164         local float teamcheck;
 165         local entity firstspot_new;
 166         local entity spot, firstspot, playerlist;
 167
 168         spot = find (world, classname, "testplayerstart");
 169         if (spot)
 170                 return spot;
 171
 172         teamcheck = 0;
 173
 174         if(!anypoint && have_team_spawns)
 175                 teamcheck = self.team;
 176
 177         // get the list of players
 178         playerlist = findchain(classname, "player");
 179         // get the entire list of spots
 180         firstspot = findchain(classname, "info_player_deathmatch");
 181         // filter out the bad ones
 182         // (note this returns the original list if none survived)
 183         firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, 100, teamcheck);
 184         if(!firstspot_new)
 185                 firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, -1, teamcheck);
 186         firstspot = firstspot_new;
 187
 188         // there is 50/50 chance of choosing a random spot or the furthest spot
 189         // (this means that roughly every other spawn will be furthest, so you
 190         // usually won't get fragged at spawn twice in a row)
 191         if (arena_roundbased)
 192         {
 193                 firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, 800, teamcheck);
 194                 if(firstspot_new)
 195                         firstspot = firstspot_new;
 196                 spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 197         }
 198         else if (random() > cvar("g_spawn_furthest"))
 199                 spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 200         else
 201                 spot = Spawn_WeightedPoint(firstspot, 1, 5000, 5); // chooses a far far away spawnpoint
 202
 203         if(cvar("spawn_debugview"))
 204         {
 205                 print("spot mindistance: ", ftos(spot.frags), "\n");
 206
 207                 entity e;
 208                 if(teamcheck)
 209                         for(e = firstspot; e; e = e.chain)
 210                                 if(e.team != teamcheck)
 211                                         error("invalid spawn found");
 212         }
 213
 214         if (!spot)
 215         {
 216                 if(cvar("spawn_debug"))
 217                         GotoNextMap();
 218                 else
 219                 {
 220                         if(some_spawn_has_been_used)
 221                                 return world; // team can't spawn any more, because of actions of other team
 222                         else
 223                                 error("Cannot find a spawn point - please fix the map!");
 224                 }
 225         }
 226
 227         return spot;
 228 }
 229
 230 /*
 231 =============
 232 CheckPlayerModel
 233
 234 Checks if the argument string can be a valid playermodel.
 235 Returns a valid one in doubt.
 236 =============
 237 */
 238 string FallbackPlayerModel = "models/player/marine.zym";
 239 string CheckPlayerModel(string plyermodel) {
 240         if(strlen(plyermodel) < 4)
 241                 return FallbackPlayerModel;
 242         if( substring(plyermodel,0,14) != "models/player/")
 243                 return FallbackPlayerModel;
 244         else if(cvar("sv_servermodelsonly"))
 245         {
 246                 if(substring(plyermodel,strlen(plyermodel)-4,4) != ".zym")
 247                 if(substring(plyermodel,strlen(plyermodel)-4,4) != ".dpm")
 248                 if(substring(plyermodel,strlen(plyermodel)-4,4) != ".md3")
 249                 if(substring(plyermodel,strlen(plyermodel)-4,4) != ".psk")
 250                         return FallbackPlayerModel;
 251                 if(!fexists(plyermodel))
 252                         return FallbackPlayerModel;
 253         }
 254         return plyermodel;
 255 }
 256
 257 /*
 258 =============
 259 Client_customizeentityforclient
 260
 261 LOD reduction
 262 =============
 263 */
 264 float Client_customizeentityforclient()
 265 {
 266 #ifdef ALLOW_VARIABLE_LOD
 267         // self: me
 268         // other: the player viewing me
 269         float distance;
 270         float f;
 271
 272         if(self.flags & FL_NOTARGET) // we don't need LOD for spectators
 273                 return TRUE;
 274
 275         if(other.cvar_cl_playerdetailreduction <= 0)
 276         {
 277                 if(other.cvar_cl_playerdetailreduction <= -2)
 278                         self.modelindex = self.modelindex_lod2;
 279                 else if(other.cvar_cl_playerdetailreduction <= -1)
 280                         self.modelindex = self.modelindex_lod1;
 281                 else
 282                         self.modelindex = self.modelindex_lod0;
 283         }
 284         else
 285         {
 286                 distance = vlen(self.origin - other.origin);
 287                 f = (distance + 100.0) * other.cvar_cl_playerdetailreduction;
 288                 if(f > 10000)
 289                         self.modelindex = self.modelindex_lod2;
 290                 else if(f > 5000)
 291                         self.modelindex = self.modelindex_lod1;
 292                 else
 293                         self.modelindex = self.modelindex_lod0;
 294         }
 295 #endif
 296
 297         return TRUE;
 298 }
 299
 300 void UpdatePlayerSounds();
 301 void setmodel_lod(entity e, string modelname)
 302 {
 303 #ifdef ALLOW_VARIABLE_LOD
 304         string s;
 305
 306         // FIXME: this only supports 3-letter extensions
 307         s = strcat(substring(modelname, 0, strlen(modelname) - 4), "_1", substring(modelname, 0, strlen(modelname) - 4));
 308         if(fexists(s))
 309         {
 310                 precache_model(s);
 311                 setmodel(e, s); // players have high precision
 312                 self.modelindex_lod1 = self.modelindex;
 313         }
 314         else
 315                 self.modelindex_lod1 = -1;
 316
 317         s = strcat(substring(modelname, 0, strlen(modelname) - 4), "_2", substring(modelname, 0, strlen(modelname) - 4));
 318         if(fexists(s))
 319         {
 320                 precache_model(s);
 321                 setmodel(e, s); // players have high precision
 322                 self.modelindex_lod2 = self.modelindex;
 323         }
 324         else
 325                 self.modelindex_lod2 = -1;
 326
 327         precache_model(modelname);
 328         setmodel(e, modelname); // players have high precision
 329         self.modelindex_lod0 = self.modelindex;
 330
 331         if(self.modelindex_lod1 < 0)
 332                 self.modelindex_lod1 = self.modelindex;
 333
 334         if(self.modelindex_lod2 < 0)
 335                 self.modelindex_lod2 = self.modelindex;
 336 #else
 337         precache_model(modelname);
 338         setmodel(e, modelname); // players have high precision
 339 #endif
 340         player_setupanimsformodel();
 341         UpdatePlayerSounds();
 342 }
 343
 344 /*
 345 =============
 346 PutObserverInServer
 347
 348 putting a client as observer in the server
 349 =============
 350 */
 351 void PutObserverInServer (void)
 352 {
 353         entity  spot;
 354         spot = SelectSpawnPoint (TRUE);
 355         if(!spot)
 356                 error("No spawnpoints for observers?!?\n");
 357         RemoveGrapplingHook(self); // Wazat's Grappling Hook
 358
 359         if(clienttype(self) == CLIENTTYPE_REAL)
 360         {
 361                 msg_entity = self;
 362                 WriteByte(MSG_ONE, SVC_SETVIEW);
 363                 WriteEntity(MSG_ONE, self);
 364         }
 365
 366         DropAllRunes(self);
 367         kh_Key_DropAll(self, TRUE);
 368
 369         if(self.flagcarried)
 370                 DropFlag(self.flagcarried);
 371
 372         WaypointSprite_PlayerDead();
 373
 374         DistributeFragsAmongTeam(self, self.team, 1);
 375
 376         if(self.frags <= 0 && self.frags > -666 && g_lms && self.killcount != -666)
 377                 bprint ("^4", self.netname, "^4 has no more lives left\n");
 378         else if(self.killcount != -666)
 379                 bprint ("^4", self.netname, "^4 is spectating now\n");
 380
 381         self.spectatortime = time;
 382
 383         self.classname = "observer";
 384         self.health = -666;
 385         self.takedamage = DAMAGE_NO;
 386         self.solid = SOLID_NOT;
 387         self.movetype = MOVETYPE_NOCLIP;
 388         self.flags = FL_CLIENT | FL_NOTARGET;
 389         self.armorvalue = 666;
 390         self.effects = 0;
 391         self.armorvalue = cvar("g_balance_armor_start");
 392         self.pauserotarmor_finished = 0;
 393         self.pauserothealth_finished = 0;
 394         self.pauseregen_finished = 0;
 395         self.damageforcescale = 0;
 396         self.death_time = 0;
 397         self.dead_frame = 0;
 398         self.deaths = 0;
 399         self.alpha = 0;
 400         self.scale = 0;
 401         self.fade_time = 0;
 402         self.pain_frame = 0;
 403         self.pain_finished = 0;
 404         self.strength_finished = 0;
 405         self.invincible_finished = 0;
 406         self.pushltime = 0;
 407         self.think = SUB_Null;
 408         self.nextthink = 0;
 409         self.hook_time = 0;
 410         self.runes = 0;
 411         self.deadflag = DEAD_NO;
 412         self.angles = spot.angles;
 413         self.angles_z = 0;
 414         self.fixangle = TRUE;
 415         self.crouch = FALSE;
 416
 417         self.view_ofs = PL_VIEW_OFS;
 418         setorigin (self, spot.origin);
 419         setsize (self, '0 0 0', '0 0 0');
 420         self.oldorigin = self.origin;
 421         self.items = 0;
 422         self.model = "";
 423         self.modelindex = 0;
 424         self.weapon = 0;
 425         self.weaponmodel = "";
 426         self.weaponentity = world;
 427         self.killcount = -666;
 428         self.velocity = '0 0 0';
 429         self.avelocity = '0 0 0';
 430         self.punchangle = '0 0 0';
 431         self.punchvector = '0 0 0';
 432         self.oldvelocity = self.velocity;
 433         self.customizeentityforclient = Client_customizeentityforclient;
 434         self.viewzoom = 1;
 435         self.wantswelcomemessage = 1;
 436
 437         if(g_arena)
 438         {
 439                 if(self.frags != -2)
 440                 {
 441                         Spawnqueue_Insert(self);
 442                 }
 443                 else
 444                 {
 445                         Spawnqueue_Unmark(self);
 446                         Spawnqueue_Remove(self);
 447                 }
 448         }
 449         else if(!g_lms)
 450                 self.frags = -666;
 451 }
 452
 453 float RestrictSkin(float s)
 454 {
 455         if(!teams_matter)
 456                 return s;
 457         if(s == 6)
 458                 return 6;
 459         return mod(s, 3);
 460 }
 461
 462 void FixPlayermodel()
 463 {
 464         local string defaultmodel;
 465         local float defaultskin;
 466         local vector m1, m2;
 467
 468         defaultmodel = "";
 469
 470         if(cvar("sv_defaultcharacter") == 1) {
 471                 defaultskin = 0;
 472
 473                 if(teams_matter)
 474                 {
 475                         defaultmodel = cvar_string(strcat("sv_defaultplayermodel_", Team_ColorNameLowerCase(self.team)));
 476                         defaultskin = cvar(strcat("sv_defaultplayerskin_", Team_ColorNameLowerCase(self.team)));
 477                 }
 478
 479                 if(defaultmodel == "")
 480                 {
 481                         defaultmodel = cvar_string("sv_defaultplayermodel");
 482                         defaultskin = cvar("sv_defaultplayerskin");
 483                 }
 484         }
 485
 486         if(defaultmodel != "")
 487         {
 488                 if (defaultmodel != self.model)
 489                 {
 490                         m1 = self.mins;
 491                         m2 = self.maxs;
 492                         setmodel_lod (self, defaultmodel);
 493                         setsize (self, m1, m2);
 494                 }
 495
 496                 self.skin = defaultskin;
 497         } else {
 498                 if (self.playermodel != self.model)
 499                 {
 500                         self.playermodel = CheckPlayerModel(self.playermodel);
 501                         m1 = self.mins;
 502                         m2 = self.maxs;
 503                         setmodel_lod (self, self.playermodel);
 504                         setsize (self, m1, m2);
 505                 }
 506
 507                 self.skin = RestrictSkin(stof(self.playerskin));
 508         }
 509
 510         if(!teams_matter)
 511                 if(strlen(cvar_string("sv_defaultplayercolors")))
 512                         if(self.clientcolors != cvar("sv_defaultplayercolors"))
 513                                 setcolor(self, cvar("sv_defaultplayercolors"));
 514 }
 515
 516 /*
 517 =============
 518 PutClientInServer
 519
 520 Called when a client spawns in the server
 521 =============
 522 */
 523 //void() ctf_playerchanged;
 524 void PutClientInServer (void)
 525 {
 526         if(clienttype(self) == CLIENTTYPE_BOT)
 527         {
 528                 self.classname = "player";
 529         }
 530         else if(clienttype(self) == CLIENTTYPE_REAL)
 531         {
 532                 msg_entity = self;
 533                 WriteByte(MSG_ONE, SVC_SETVIEW);
 534                 WriteEntity(MSG_ONE, self);
 535         }
 536
 537         // player is dead and becomes observer
 538         if(g_lms && self.frags < 1)
 539                 self.classname = "observer";
 540
 541         if(g_arena)
 542         if(!self.spawned)
 543                 self.classname = "observer";
 544
 545         if(self.classname == "player") {
 546                 entity  spot;
 547
 548                 spot = SelectSpawnPoint (FALSE);
 549                 if(!spot)
 550                 {
 551                         centerprint(self, "Sorry, no spawnpoints available!\nHope your team can fix it...");
 552                         return; // spawn failed
 553                 }
 554
 555                 RemoveGrapplingHook(self); // Wazat's Grappling Hook
 556
 557                 self.classname = "player";
 558                 self.iscreature = TRUE;
 559                 self.movetype = MOVETYPE_WALK;
 560                 self.solid = SOLID_SLIDEBOX;
 561                 self.flags = FL_CLIENT;
 562                 self.takedamage = DAMAGE_AIM;
 563                 if(g_minstagib)
 564                         self.effects = EF_FULLBRIGHT;
 565                 else
 566                         self.effects = 0;
 567                 self.air_finished = time + 12;
 568                 self.dmg = 2;
 569
 570                 self.ammo_shells = start_ammo_shells;
 571                 self.ammo_nails = start_ammo_nails;
 572                 self.ammo_rockets = start_ammo_rockets;
 573                 self.ammo_cells = start_ammo_cells;
 574                 self.health = start_health;
 575                 self.armorvalue = start_armorvalue;
 576                 self.items = start_items;
 577                 self.switchweapon = start_switchweapon;
 578                 self.cnt = start_switchweapon;
 579                 self.weapon = 0;
 580                 self.jump_interval = time;
 581
 582                 self.spawnshieldtime = time + cvar("g_spawnshieldtime");
 583                 self.pauserotarmor_finished = time + cvar("g_balance_pause_armor_rot_spawn");
 584                 self.pauserothealth_finished = time + cvar("g_balance_pause_health_rot_spawn");
 585                 self.pauseregen_finished = time + cvar("g_balance_pause_health_regen_spawn");
 586                 //extend the pause of rotting if client was reset at the beginning of the countdown
 587                 if(!cvar("sv_ready_restart_after_countdown") && time < restart_countdown) {
 588                         self.spawnshieldtime += RESTART_COUNTDOWN;
 589                         self.pauserotarmor_finished += RESTART_COUNTDOWN;
 590                         self.pauserothealth_finished += RESTART_COUNTDOWN;
 591                         self.pauseregen_finished += RESTART_COUNTDOWN;
 592                 }
 593                 self.damageforcescale = 2;
 594                 self.death_time = 0;
 595                 self.dead_frame = 0;
 596                 self.alpha = 0;
 597                 self.scale = 0;
 598                 self.fade_time = 0;
 599                 self.pain_frame = 0;
 600                 self.pain_finished = 0;
 601                 self.strength_finished = 0;
 602                 self.invincible_finished = 0;
 603                 self.pushltime = 0;
 604                 //self.speed_finished = 0;
 605                 //self.slowmo_finished = 0;
 606                 // players have no think function
 607                 self.think = SUB_Null;
 608                 self.nextthink = 0;
 609                 self.hook_time = 0;
 610
 611                 self.runes = 0;
 612
 613                 self.deadflag = DEAD_NO;
 614
 615                 self.angles = spot.angles;
 616
 617                 self.angles_z = 0; // never spawn tilted even if the spot says to
 618                 self.fixangle = TRUE; // turn this way immediately
 619                 self.velocity = '0 0 0';
 620                 self.avelocity = '0 0 0';
 621                 self.punchangle = '0 0 0';
 622                 self.punchvector = '0 0 0';
 623                 self.oldvelocity = self.velocity;
 624
 625                 self.viewzoom = 0.6;
 626                 self.has_zoomed = 0;
 627
 628                 self.customizeentityforclient = Client_customizeentityforclient;
 629
 630                 self.model = "";
 631                 FixPlayermodel();
 632
 633                 self.crouch = FALSE;
 634                 self.view_ofs = PL_VIEW_OFS;
 635                 setsize (self, PL_MIN, PL_MAX);
 636                 self.spawnorigin = spot.origin;
 637                 setorigin (self, spot.origin + '0 0 1' * (1 - self.mins_z - 24));
 638                 // don't reset back to last position, even if new position is stuck in solid
 639                 self.oldorigin = self.origin;
 640
 641                 if(g_arena)
 642                 {
 643                         Spawnqueue_Remove(self);
 644                         Spawnqueue_Mark(self);
 645                 }
 646
 647                 self.event_damage = PlayerDamage;
 648
 649                 self.bot_attack = TRUE;
 650
 651                 self.statdraintime = time + 5;
 652                 self.BUTTON_ATCK = self.BUTTON_JUMP = self.BUTTON_ATCK2 = 0;
 653
 654                 if(self.killcount == -666) {
 655                         self.killcount = 0;
 656                         if(!g_arena)
 657                         if(!g_lms)
 658                                 self.frags = 0;
 659                 }
 660
 661                 self.cnt = WEP_LASER;
 662                 self.nixnex_lastchange_id = -1;
 663
 664                 CL_SpawnWeaponentity();
 665                 self.alpha = default_player_alpha;
 666                 self.colormod = '1 1 1' * cvar("g_player_brightness");
 667                 self.exteriorweaponentity.alpha = default_weapon_alpha;
 668
 669                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval")*2;
 670                 self.lms_traveled_distance = 0;
 671                 self.speedrunning = FALSE;
 672
 673                 if(cvar("spawn_debug"))
 674                 {
 675                         sprint(self, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 676                         remove(spot);   // usefull for checking if there are spawnpoints, that let drop through the floor
 677                 }
 678
 679                 //stuffcmd(self, "chase_active 0");
 680                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
 681
 682                 if (cvar("g_spawnsound"))
 683                         sound (self, CHAN_AUTO, "misc/spawn.wav", 1, ATTN_NORM);
 684
 685                 if(g_assault) {
 686                         if(self.team == assault_attacker_team)
 687                                 centerprint(self, "You are attacking!\n");
 688                         else
 689                                 centerprint(self, "You are defending!\n");
 690                 }
 691
 692         } else if(self.classname == "observer") {
 693                 PutObserverInServer ();
 694         }
 695
 696         //if(g_ctf)
 697         //      ctf_playerchanged();
 698 }
 699
 700 /*
 701 =============
 702 SetNewParms
 703 =============
 704 */
 705 void SetNewParms (void)
 706 {
 707         // initialize parms for a new player
 708         print("SetNewParms\n");
 709         parm1 = -(86400 * 366);
 710 }
 711
 712 /*
 713 =============
 714 SetChangeParms
 715 =============
 716 */
 717 void SetChangeParms (void)
 718 {
 719         // save parms for level change
 720         print("SetChangeParms\n");
 721         parm1 = self.parm_idlesince - time;
 722 }
 723
 724 /*
 725 =============
 726 DecodeLevelParms
 727 =============
 728 */
 729 void DecodeLevelParms (void)
 730 {
 731         // load parms
 732         print("DecodeLevelParms\n");
 733         self.parm_idlesince = parm1;
 734         if(self.parm_idlesince == -(86400 * 366))
 735                 self.parm_idlesince = time;
 736 }
 737
 738 /*
 739 =============
 740 ClientKill
 741
 742 Called when a client types 'kill' in the console
 743 =============
 744 */
 745
 746 void ClientKill_Now_TeamChange()
 747 {
 748         if(self.killindicator_teamchange == -1)
 749         {
 750                 self.team = -1;
 751                 JoinBestTeam( self, FALSE, FALSE );
 752         }
 753         else
 754         {
 755                 SV_ChangeTeam(self.killindicator_teamchange - 1);
 756         }
 757 }
 758
 759 void ClientKill_Now()
 760 {
 761         if(self.killindicator_teamchange)
 762                 ClientKill_Now_TeamChange();
 763
 764         // in any case:
 765         Damage(self, self, self, 100000, DEATH_KILL, self.origin, '0 0 0');
 766 }
 767 void KillIndicator_Think()
 768 {
 769         if (!self.owner.modelindex)
 770         {
 771                 self.owner.killindicator = world;
 772                 remove(self);
 773                 return;
 774         }
 775
 776         if(self.cnt <= 0)
 777         {
 778                 self = self.owner;
 779                 ClientKill_Now(); // no oldself needed
 780                 return;
 781         }
 782         else
 783         {
 784                 if(self.cnt <= 10)
 785                         setmodel(self, strcat("models/sprites/", ftos(self.cnt), ".spr32"));
 786                 if(clienttype(self.owner) == CLIENTTYPE_REAL)
 787                 {
 788                         if(self.cnt <= 10)
 789                                 play2(self.owner, strcat("announcer/robotic/", ftos(self.cnt), ".ogg"));
 790                         if(self.owner.killindicator_teamchange)
 791                         {
 792                                 if(self.owner.killindicator_teamchange == -1)
 793                                         centerprint(self.owner, strcat("Changing team in ", ftos(self.cnt), " seconds"));
 794                                 else
 795                                         centerprint(self.owner, strcat("Changing to ", ColoredTeamName(self.owner.killindicator_teamchange), " in ", ftos(self.cnt), " seconds"));
 796                         }
 797                         else
 798                                 centerprint(self.owner, strcat("^1Suicide in ", ftos(self.cnt), " seconds"));
 799                 }
 800                 self.nextthink = time + 1;
 801                 self.cnt -= 1;
 802         }
 803 }
 804
 805 void ClientKill_TeamChange (float targetteam) // 0 = don't change, -1 = auto
 806 {
 807         float killtime;
 808         entity e;
 809         killtime = cvar("g_balance_kill_delay");
 810
 811         self.killindicator_teamchange = targetteam;
 812
 813         if(!self.killindicator)
 814         {
 815                 if(killtime <= 0 || !self.modelindex || self.deadflag != DEAD_NO)
 816                 {
 817                         ClientKill_Now();
 818                 }
 819                 else
 820                 {
 821                         self.killindicator = spawn();
 822                         self.killindicator.owner = self;
 823                         self.killindicator.scale = 0.5;
 824                         setattachment(self.killindicator, self, "");
 825                         setorigin(self.killindicator, '0 0 52');
 826                         self.killindicator.think = KillIndicator_Think;
 827                         self.killindicator.nextthink = time + (self.lip) * 0.05;
 828                         self.killindicator.cnt = ceil(killtime);
 829                         self.killindicator.count = bound(0, ceil(killtime), 10);
 830                         sprint(self, strcat("^1You'll be dead in ", ftos(self.killindicator.cnt), " seconds\n"));
 831
 832                         for(e = world; (e = find(e, classname, "body")) != world; )
 833                         {
 834                                 if(e.enemy != self)
 835                                         continue;
 836                                 e.killindicator = spawn();
 837                                 e.killindicator.owner = e;
 838                                 e.killindicator.scale = 0.5;
 839                                 setattachment(e.killindicator, e, "");
 840                                 setorigin(e.killindicator, '0 0 52');
 841                                 e.killindicator.think = KillIndicator_Think;
 842                                 e.killindicator.nextthink = time + (e.lip) * 0.05;
 843                                 e.killindicator.cnt = ceil(killtime);
 844                         }
 845                         self.lip = 0;
 846                 }
 847         }
 848         if(self.killindicator)
 849         {
 850                 if(targetteam)
 851                         self.killindicator.colormod = TeamColor(targetteam);
 852                 else
 853                         self.killindicator.colormod = '0 0 0';
 854         }
 855 }
 856
 857 void ClientKill (void)
 858 {
 859         ClientKill_TeamChange(0);
 860 }
 861
 862 void DoTeamChange(float destteam)
 863 {
 864         float t, c0;
 865         if(!cvar("teamplay"))
 866         {
 867                 if(destteam >= 0)
 868                         SetPlayerColors(self, destteam);
 869                 return;
 870         }
 871         if(self.classname == "player")
 872         if(destteam == -1)
 873         {
 874                 CheckAllowedTeams(self);
 875                 t = FindSmallestTeam(self, TRUE);
 876                 switch(self.team)
 877                 {
 878                         case COLOR_TEAM1: c0 = c1; break;
 879                         case COLOR_TEAM2: c0 = c2; break;
 880                         case COLOR_TEAM3: c0 = c3; break;
 881                         case COLOR_TEAM4: c0 = c4; break;
 882                         default:          c0 = 999;
 883                 }
 884                 switch(t)
 885                 {
 886                         case 1:
 887                                 if(c0 > c1)
 888                                         destteam = COLOR_TEAM1;
 889                                 break;
 890                         case 2:
 891                                 if(c0 > c2)
 892                                         destteam = COLOR_TEAM2;
 893                                 break;
 894                         case 3:
 895                                 if(c0 > c3)
 896                                         destteam = COLOR_TEAM3;
 897                                 break;
 898                         case 4:
 899                                 if(c0 > c4)
 900                                         destteam = COLOR_TEAM4;
 901                                 break;
 902                 }
 903                 if(destteam == -1)
 904                         return;
 905         }
 906         if(destteam == self.team && !self.killindicator)
 907                 return;
 908         ClientKill_TeamChange(destteam);
 909 }
 910
 911 void FixClientCvars(entity e)
 912 {
 913         // send prediction settings to the client
 914         stuffcmd(e, "\nin_bindmap 0 0\n");
 915         /*
 916          * we no longer need to stuff this. Remove this comment block if you feel
 917          * 2.3 and higher (or was it 2.2.3?) don't need these any more
 918         stuffcmd(e, strcat("cl_gravity ", ftos(cvar("sv_gravity")), "\n"));
 919         stuffcmd(e, strcat("cl_movement_accelerate ", ftos(cvar("sv_accelerate")), "\n"));
 920         stuffcmd(e, strcat("cl_movement_friction ", ftos(cvar("sv_friction")), "\n"));
 921         stuffcmd(e, strcat("cl_movement_maxspeed ", ftos(cvar("sv_maxspeed")), "\n"));
 922         stuffcmd(e, strcat("cl_movement_airaccelerate ", ftos(cvar("sv_airaccelerate")), "\n"));
 923         stuffcmd(e, strcat("cl_movement_maxairspeed ", ftos(cvar("sv_maxairspeed")), "\n"));
 924         stuffcmd(e, strcat("cl_movement_stopspeed ", ftos(cvar("sv_stopspeed")), "\n"));
 925         stuffcmd(e, strcat("cl_movement_jumpvelocity ", ftos(cvar("sv_jumpvelocity")), "\n"));
 926         stuffcmd(e, strcat("cl_movement_stepheight ", ftos(cvar("sv_stepheight")), "\n"));
 927         stuffcmd(e, strcat("set cl_movement_friction_on_land ", ftos(cvar("sv_friction_on_land")), "\n"));
 928         stuffcmd(e, strcat("set cl_movement_airaccel_qw ", ftos(cvar("sv_airaccel_qw")), "\n"));
 929         stuffcmd(e, strcat("set cl_movement_airaccel_sideways_friction ", ftos(cvar("sv_airaccel_sideways_friction")), "\n"));
 930         stuffcmd(e, "cl_movement_edgefriction 1\n");
 931          */
 932 }
 933
 934 /*
 935 =============
 936 ClientConnect
 937
 938 Called when a client connects to the server
 939 =============
 940 */
 941 //void ctf_clientconnect();
 942 string ColoredTeamName(float t);
 943 void DecodeLevelParms (void);
 944 //void dom_player_join_team(entity pl);
 945 void ClientConnect (void)
 946 {
 947         local string s;
 948         float wep;
 949
 950         if(Ban_IsClientBanned(self))
 951         {
 952                 s = strcat("^1NOTE:^7 banned client ", self.netaddress, " just tried to enter\n");
 953                 dropclient(self);
 954                 bprint(s);
 955                 return;
 956         }
 957
 958         DecodeLevelParms();
 959
 960         self.classname = "player_joining";
 961         self.flags = self.flags | FL_CLIENT;
 962         self.version_nagtime = time + 10 + random() * 10;
 963
 964         if(player_count<0)
 965         {
 966                 dprint("BUG player count is lower than zero, this cannot happen!\n");
 967                 player_count = 0;
 968         }
 969
 970         bot_clientconnect();
 971
 972         //if(g_domination)
 973         //      dom_player_join_team(self);
 974
 975         //JoinBestTeam(self, FALSE, FALSE);
 976
 977         if((cvar("sv_spectate") == 1 && !g_lms) || cvar("g_campaign")) {
 978                 self.classname = "observer";
 979         } else {
 980                 self.classname = "player";
 981                 campaign_bots_may_start = 1;
 982         }
 983
 984         self.playerid = (playerid_last = playerid_last + 1);
 985         if(cvar("sv_eventlog"))
 986         {
 987                 if(clienttype(self) == CLIENTTYPE_REAL)
 988                         s = "player";
 989                 else
 990                         s = "bot";
 991                 GameLogEcho(strcat(":join:", ftos(self.playerid), ":", s, ":", self.netname), TRUE);
 992                 s = strcat(":team:", ftos(self.playerid), ":");
 993                 s = strcat(s, ftos(self.team));
 994                 GameLogEcho(s, FALSE);
 995         }
 996         self.netname_previous = strzone(self.netname);
 997
 998         //stuffcmd(self, "set tmpviewsize $viewsize \n");
 999
1000         bprint ("^4",self.netname);
1001         bprint ("^4 connected");
1002
1003         if(g_domination || g_ctf)
1004         {
1005                 bprint(" and joined the ");
1006                 bprint(ColoredTeamName(self.team));
1007         }
1008
1009         bprint("\n");
1010
1011         self.welcomemessage_time = 0;
1012
1013         stuffcmd(self, strcat("exec maps/", mapname, ".cfg\n"));
1014         // TODO: is this being used for anything else than cd tracks?
1015         // Remember: SVC_CDTRACK exists. Maybe it should be used.
1016         //
1017         stuffcmd(self, "cl_particles_reloadeffects\n");
1018
1019         FixClientCvars(self);
1020
1021         // spawnfunc_waypoint sprites
1022         WaypointSprite_InitClient(self);
1023
1024         // Wazat's grappling hook
1025         SetGrappleHookBindings();
1026
1027         // get autoswitch state from player when he toggles it
1028         stuffcmd(self, "alias autoswitch \"set cl_autoswitch $1 ; cmd autoswitch $1\"\n"); // default.cfg-ed in 2.4.1
1029
1030         // get version info from player
1031         stuffcmd(self, "cmd clientversion $gameversion\n");
1032
1033         // send all weapon info strings
1034         stuffcmd(self, "register_bestweapon clear\n"); // clear the Quake stuff
1035         wep = WEP_FIRST;
1036         while (wep <= WEP_LAST)
1037         {
1038                 weapon_action(wep, WR_REGISTER);
1039                 wep = wep + 1;
1040         }
1041
1042         // get other cvars from player
1043         GetCvars(0);
1044
1045         // set cvar for team scoreboard
1046         if (teams_matter)
1047         {
1048                 local float t;
1049                 t = cvar("teamplay");
1050                 // we have to stuff the correct teamplay value because if this is a listen server, this changes the teamplay mode of the server itself, which is bad
1051                 stuffcmd(self, strcat("set teamplay ", ftos(t), "\n"));
1052         }
1053         else
1054                 stuffcmd(self, "set teamplay 0\n");
1055
1056         // notify about available teams
1057         if(teamplay)
1058         {
1059                 CheckAllowedTeams(self);
1060                 t = 0; if(c1 >= 0) t |= 1; if(c2 >= 0) t |= 2; if(c3 >= 0) t |= 4; if(c4 >= 0) t |= 8;
1061                 stuffcmd(self, strcat("set _teams_available ", ftos(t), "\n"));
1062         }
1063         else
1064                 stuffcmd(self, "set _teams_available 0\n");
1065
1066         stuffcmd(self, strcat("set gametype ", ftos(game), "\n"));
1067
1068         if(g_lms)
1069         {
1070                 self.frags = LMS_NewPlayerLives();
1071                 if(!self.frags)
1072                         self.frags = -666;
1073         }
1074         else if(g_arena)
1075         {
1076                 self.classname = "observer";
1077                 Spawnqueue_Insert(self);
1078         }
1079         /*else if(g_ctf)
1080         {
1081                 ctf_clientconnect();
1082         }*/
1083
1084         if(entcs_start)
1085                 attach_entcs();
1086
1087         bot_relinkplayerlist();
1088
1089         self.spectatortime = time;
1090         if(blockSpectators)
1091         {
1092                 sprint(self, strcat("^7You have to become a player within the next ", ftos(cvar("g_maxplayers_spectator_blocktime")), " seconds, otherwise you will be kicked, because spectators aren't allowed at this time!\n"));
1093         }
1094
1095         self.jointime = time;
1096         self.allowedTimeouts = cvar("sv_timeout_number");
1097 }
1098
1099 /*
1100 =============
1101 ClientDisconnect
1102
1103 Called when a client disconnects from the server
1104 =============
1105 */
1106 void(entity e) DropFlag;
1107 .entity chatbubbleentity;
1108 .entity teambubbleentity;
1109 //void() ctf_clientdisconnect;
1110 void ClientDisconnect (void)
1111 {
1112         float save;
1113
1114         if(entcs_start)
1115                 detach_entcs();
1116
1117         if(cvar("sv_eventlog"))
1118                 GameLogEcho(strcat(":part:", ftos(self.playerid)), FALSE);
1119         bprint ("^4",self.netname);
1120         bprint ("^4 disconnected\n");
1121
1122         if (self.chatbubbleentity)
1123         {
1124                 remove (self.chatbubbleentity);
1125                 self.chatbubbleentity = world;
1126         }
1127
1128         if (self.teambubbleentity)
1129         {
1130                 remove (self.teambubbleentity);
1131                 self.teambubbleentity = world;
1132         }
1133
1134         if (self.killindicator)
1135         {
1136                 remove (self.killindicator);
1137                 self.killindicator = world;
1138         }
1139
1140         WaypointSprite_PlayerGone();
1141
1142         DropAllRunes(self);
1143         kh_Key_DropAll(self, TRUE);
1144
1145         if(self.flagcarried)
1146                 DropFlag(self.flagcarried);
1147
1148         DistributeFragsAmongTeam(self, self.team, 1);
1149
1150         save = self.flags;
1151         self.flags = self.flags - (self.flags & FL_CLIENT);
1152         bot_relinkplayerlist();
1153         self.flags = save;
1154
1155         // remove laserdot
1156         if(self.weaponentity)
1157                 if(self.weaponentity.lasertarget)
1158                         remove(self.weaponentity.lasertarget);
1159
1160         if(g_arena)
1161         {
1162                 Spawnqueue_Unmark(self);
1163                 Spawnqueue_Remove(self);
1164         }
1165         /*if(g_ctf)
1166         {
1167                 ctf_clientdisconnect();
1168         }
1169         */
1170
1171         if(self.netname_previous)
1172                 strunzone(self.netname_previous);
1173
1174         // free cvars
1175         GetCvars(-1);
1176 }
1177
1178 .float BUTTON_CHAT;
1179 void ChatBubbleThink()
1180 {
1181         self.nextthink = time;
1182         if (!self.owner.modelindex || self.owner.chatbubbleentity != self)
1183         {
1184                 self.owner.chatbubbleentity = world;
1185                 remove(self);
1186                 return;
1187         }
1188         setorigin(self, self.owner.origin + '0 0 15' + self.owner.maxs_z * '0 0 1');
1189         if (self.owner.BUTTON_CHAT && !self.owner.deadflag)
1190                 self.model = self.mdl;
1191         else
1192                 self.model = "";
1193 };
1194
1195 void UpdateChatBubble()
1196 {
1197         if (!self.modelindex)
1198                 return;
1199         // spawn a chatbubble entity if needed
1200         if (!self.chatbubbleentity)
1201         {
1202                 self.chatbubbleentity = spawn();
1203                 self.chatbubbleentity.owner = self;
1204                 self.chatbubbleentity.exteriormodeltoclient = self;
1205                 self.chatbubbleentity.think = ChatBubbleThink;
1206                 self.chatbubbleentity.nextthink = time;
1207                 setmodel(self.chatbubbleentity, "models/misc/chatbubble.spr"); // precision set below
1208                 setorigin(self.chatbubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1209                 self.chatbubbleentity.mdl = self.chatbubbleentity.model;
1210                 self.chatbubbleentity.model = "";
1211                 self.chatbubbleentity.effects = EF_LOWPRECISION;
1212         }
1213 }
1214
1215
1216 void TeamBubbleThink()
1217 {
1218         self.nextthink = time;
1219         if (!self.owner.modelindex || self.owner.teambubbleentity != self)
1220         {
1221                 self.owner.teambubbleentity = world;
1222                 remove(self);
1223                 return;
1224         }
1225 //      setorigin(self, self.owner.origin + '0 0 15' + self.owner.maxs_z * '0 0 1');  // bandwidth hog. setattachment does this now
1226         if (self.owner.BUTTON_CHAT || self.owner.deadflag || self.owner.killindicator)
1227                 self.model = "";
1228         else
1229                 self.model = self.mdl;
1230
1231 };
1232
1233 float TeamBubble_customizeentityforclient()
1234 {
1235         return (self.owner != other && self.owner.team == other.team && other.killcount > -666);
1236 }
1237
1238 void UpdateTeamBubble()
1239 {
1240         if (!self.modelindex || !cvar("teamplay"))
1241                 return;
1242         // spawn a teambubble entity if needed
1243         if (!self.teambubbleentity && cvar("teamplay"))
1244         {
1245                 self.teambubbleentity = spawn();
1246                 self.teambubbleentity.owner = self;
1247                 self.teambubbleentity.exteriormodeltoclient = self;
1248                 self.teambubbleentity.think = TeamBubbleThink;
1249                 self.teambubbleentity.nextthink = time;
1250                 setmodel(self.teambubbleentity, "models/misc/teambubble.spr"); // precision set below
1251 //              setorigin(self.teambubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1252                 setorigin(self.teambubbleentity, self.teambubbleentity.origin + '0 0 15' + self.maxs_z * '0 0 1');
1253                 setattachment(self.teambubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1254                 self.teambubbleentity.mdl = self.teambubbleentity.model;
1255                 self.teambubbleentity.model = self.teambubbleentity.mdl;
1256                 self.teambubbleentity.customizeentityforclient = TeamBubble_customizeentityforclient;
1257                 self.teambubbleentity.effects = EF_LOWPRECISION;
1258         }
1259 }
1260
1261 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1262 // added to the model skins
1263 /*void UpdateColorModHack()
1264 {
1265         local float c;
1266         c = self.clientcolors & 15;
1267         // LordHavoc: only bothering to support white, green, red, yellow, blue
1268              if (teamplay == 0) self.colormod = '0 0 0';
1269         else if (c ==  0) self.colormod = '1.00 1.00 1.00';
1270         else if (c ==  3) self.colormod = '0.10 1.73 0.10';
1271         else if (c ==  4) self.colormod = '1.73 0.10 0.10';
1272         else if (c == 12) self.colormod = '1.22 1.22 0.10';
1273         else if (c == 13) self.colormod = '0.10 0.10 1.73';
1274         else self.colormod = '1 1 1';
1275 };*/
1276
1277 void respawn(void)
1278 {
1279         CopyBody(1);
1280         self.effects |= EF_NODRAW; // prevent another CopyBody
1281         PutClientInServer();
1282 }
1283
1284 /**
1285  * When sv_timeout is used this function returs strings like
1286  * "Timeout begins in 2 seconds!\n" or "Timeout ends in 23 seconds!\n".
1287  * Called by centerprint functions
1288  * @param addOneSecond boolean, set to 1 if the welcome-message centerprint asks for the text
1289  */
1290 string getTimeoutText(float addOneSecond) {
1291         if (!cvar("sv_timeout") || !timeoutStatus)
1292                 return "";
1293
1294         local string retStr;
1295         if (timeoutStatus == 1) {
1296                 if (addOneSecond == 1) {
1297                         retStr = strcat("Timeout begins in ", ftos(remainingLeadTime + 1), " seconds!\n");
1298                 }
1299                 else {
1300                         retStr = strcat("Timeout begins in ", ftos(remainingLeadTime), " seconds!\n");
1301                 }
1302                 return retStr;
1303         }
1304         else if (timeoutStatus == 2) {
1305                 if (addOneSecond) {
1306                         retStr = strcat("Timeout ends in ", ftos(remainingTimeoutTime + 1), " seconds!\n");
1307                         //don't show messages like "Timeout ends in 0 seconds"...
1308                         if ((remainingTimeoutTime + 1) > 0)
1309                                 return retStr;
1310                         else
1311                                 return "";
1312                 }
1313                 else {
1314                         retStr = strcat("Timeout ends in ", ftos(remainingTimeoutTime), " seconds!\n");
1315                         //don't show messages like "Timeout ends in 0 seconds"...
1316                         if (remainingTimeoutTime > 0)
1317                                 return retStr;
1318                         else
1319                                 return "";
1320                 }
1321         }
1322         else return "";
1323 }
1324
1325 void player_powerups (void)
1326 {
1327         if (g_minstagib)
1328         {
1329                 if (self.items & IT_STRENGTH)
1330                 {
1331                         if (time > self.strength_finished)
1332                         {
1333                                 if (g_minstagib_invis_alpha > 0)
1334                                 {
1335                                         self.alpha = default_player_alpha;
1336                                         self.exteriorweaponentity.alpha = default_weapon_alpha;
1337                                         self.effects = self.effects | EF_FULLBRIGHT;
1338                                 }
1339                                 else
1340                                 {
1341                                         self.effects -= self.effects & EF_NODRAW;
1342                                 }
1343                                 self.items = self.items - (self.items & IT_STRENGTH);
1344                                 sprint(self, "^3Invisibility has worn off\n");
1345                         }
1346                 }
1347                 else
1348                 {
1349                         if (time < self.strength_finished)
1350                         {
1351                                 if (g_minstagib_invis_alpha > 0)
1352                                 {
1353                                         self.alpha = g_minstagib_invis_alpha;
1354                                         self.exteriorweaponentity.alpha = g_minstagib_invis_alpha;
1355                                         self.effects -= self.effects & EF_FULLBRIGHT;
1356                                 }
1357                                 else
1358                                 {
1359                                         self.effects = self.effects | EF_NODRAW;
1360                                 }
1361                                 self.items = self.items | IT_STRENGTH;
1362                                 sprint(self, "^3You are invisible\n");
1363                         }
1364                 }
1365
1366                 if (self.items & IT_INVINCIBLE)
1367                 {
1368                         if (time > self.invincible_finished)
1369                         {
1370                                 self.items = self.items - (self.items & IT_INVINCIBLE);
1371                                 sprint(self, "^3Speed has worn off\n");
1372                         }
1373                 }
1374                 else
1375                 {
1376                         if (time < self.invincible_finished)
1377                         {
1378                                 self.items = self.items | IT_INVINCIBLE;
1379                                 sprint(self, "^3You are on speed\n");
1380                         }
1381                 }
1382                 return;
1383         }
1384
1385         self.effects = self.effects - (self.effects & (EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT));
1386         if (self.items & IT_STRENGTH)
1387         {
1388                 self.effects = self.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1389                 if (time > self.strength_finished)
1390                 {
1391                         self.items = self.items - (self.items & IT_STRENGTH);
1392                         sprint(self, "^3Strength has worn off\n");
1393                 }
1394         }
1395         else
1396         {
1397                 if (time < self.strength_finished)
1398                 {
1399                         self.items = self.items | IT_STRENGTH;
1400                         sprint(self, "^3Strength infuses your weapons with devastating power\n");
1401                 }
1402         }
1403         if (self.items & IT_INVINCIBLE)
1404         {
1405                 self.effects = self.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1406                 if (time > self.invincible_finished)
1407                 {
1408                         self.items = self.items - (self.items & IT_INVINCIBLE);
1409                         sprint(self, "^3Shield has worn off\n");
1410                 }
1411         }
1412         else
1413         {
1414                 if (time < self.invincible_finished)
1415                 {
1416                         self.items = self.items | IT_INVINCIBLE;
1417                         sprint(self, "^3Shield surrounds you\n");
1418                 }
1419         }
1420
1421         if (cvar("g_fullbrightplayers"))
1422                 self.effects = self.effects | EF_FULLBRIGHT;
1423
1424         // midair gamemode: damage only while in the air
1425         // if in midair mode, being on ground grants temporary invulnerability
1426         // (this is so that multishot weapon don't clear the ground flag on the
1427         // first damage in the frame, leaving the player vulnerable to the
1428         // remaining hits in the same frame)
1429         if (self.flags & FL_ONGROUND)
1430         if (g_midair)
1431                 self.spawnshieldtime = max(self.spawnshieldtime, time + cvar("g_midair_shieldtime"));
1432
1433         if (time < self.spawnshieldtime)
1434                 self.effects = self.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1435 }
1436
1437 float CalcRegen(float current, float stable, float regenfactor)
1438 {
1439         if(current > stable)
1440                 return current;
1441         else if(current > stable - 0.25) // when close enough, "snap"
1442                 return stable;
1443         else
1444                 return min(stable, current + (stable - current) * regenfactor * frametime);
1445 }
1446
1447 void player_regen (void)
1448 {
1449         float maxh, maxa, limith, limita, max_mod, regen_mod, rot_mod, limit_mod;
1450         maxh = cvar("g_balance_health_stable");
1451         maxa = cvar("g_balance_armor_stable");
1452         limith = cvar("g_balance_health_limit");
1453         limita = cvar("g_balance_armor_limit");
1454
1455         if (g_minstagib || (g_lms && !cvar("g_lms_regenerate")))
1456                 return;
1457
1458         max_mod = regen_mod = rot_mod = limit_mod = 1;
1459
1460         if (self.runes & RUNE_REGEN)
1461         {
1462                 if (self.runes & CURSE_VENOM) // do we have both rune/curse?
1463                 {
1464                         regen_mod = cvar("g_balance_rune_regen_combo_regenrate");
1465                         max_mod = cvar("g_balance_rune_regen_combo_hpmod");
1466                         limit_mod = cvar("g_balance_rune_regen_combo_limitmod");
1467                 }
1468                 else
1469                 {
1470                         regen_mod = cvar("g_balance_rune_regen_regenrate");
1471                         max_mod = cvar("g_balance_rune_regen_hpmod");
1472                         limit_mod = cvar("g_balance_rune_regen_limitmod");
1473                 }
1474         }
1475         else if (self.runes & CURSE_VENOM)
1476         {
1477                 max_mod = cvar("g_balance_curse_venom_hpmod");
1478                 if (self.runes & RUNE_REGEN) // do we have both rune/curse?
1479                         rot_mod = cvar("g_balance_rune_regen_combo_rotrate");
1480                 else
1481                         rot_mod = cvar("g_balance_curse_venom_rotrate");
1482                 limit_mod = cvar("g_balance_curse_venom_limitmod");
1483                 //if (!self.runes & RUNE_REGEN)
1484                 //      rot_mod = cvar("g_balance_curse_venom_rotrate");
1485         }
1486         maxh = maxh * max_mod;
1487         //maxa = maxa * max_mod;
1488         limith = limith * limit_mod;
1489         limita = limita * limit_mod;
1490
1491         if (self.armorvalue > maxa)
1492         {
1493                 if (time > self.pauserotarmor_finished)
1494                 {
1495                         self.armorvalue = max(maxa, self.armorvalue + (maxa - self.armorvalue) * cvar("g_balance_armor_rot") * frametime);
1496                         self.armorvalue = max(maxa, self.armorvalue - cvar("g_balance_armor_rotlinear") * frametime);
1497                 }
1498         }
1499         else if (self.armorvalue < maxa)
1500         {
1501                 if (time > self.pauseregen_finished)
1502                 {
1503                         self.armorvalue = CalcRegen(self.armorvalue, maxa, cvar("g_balance_armor_regen"));
1504                         self.armorvalue = min(maxa, self.armorvalue + cvar("g_balance_armor_regenlinear") * frametime);
1505                 }
1506         }
1507         if (self.health > maxh)
1508         {
1509                 if (time > self.pauserothealth_finished)
1510                 {
1511                         self.health = max(maxh, self.health + (maxh - self.health) * rot_mod*cvar("g_balance_health_rot") * frametime);
1512                         self.health = max(maxh, self.health - rot_mod*cvar("g_balance_health_rotlinear") * frametime);
1513                 }
1514         }
1515         else if (self.health < maxh)
1516         {
1517                 if (time > self.pauseregen_finished)
1518                 {
1519                         self.health = CalcRegen(self.health, maxh, regen_mod * cvar("g_balance_health_regen"));
1520                         self.health = min(maxh, self.health + regen_mod*cvar("g_balance_health_regenlinear") * frametime);
1521                 }
1522         }
1523
1524         if (self.health > limith)
1525                 self.health = limith;
1526         if (self.armorvalue > limita)
1527                 self.armorvalue = limita;
1528
1529         // if player rotted to death...  die!
1530         if(self.health < 1)
1531                 self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
1532 }
1533
1534 /*
1535 ======================
1536 spectate mode routines
1537 ======================
1538 */
1539 void SpectateCopy(entity spectatee) {
1540         self.armortype = spectatee.armortype;
1541         self.armorvalue = spectatee.armorvalue;
1542         self.currentammo = spectatee.currentammo;
1543         self.effects = spectatee.effects;
1544         self.health = spectatee.health;
1545         self.impulse = 0;
1546         self.items = spectatee.items;
1547         self.punchangle = spectatee.punchangle;
1548         self.view_ofs = spectatee.view_ofs;
1549         self.v_angle = spectatee.v_angle;
1550         self.viewzoom = spectatee.viewzoom;
1551         self.velocity = spectatee.velocity;
1552         self.dmg_take = spectatee.dmg_take;
1553         self.dmg_save = spectatee.dmg_save;
1554         self.dmg_inflictor = spectatee.dmg_inflictor;
1555         self.angles = spectatee.v_angle;
1556         self.fixangle = TRUE;
1557         setorigin(self, spectatee.origin);
1558         setsize(self, spectatee.mins, spectatee.maxs);
1559 }
1560
1561 float SpectateUpdate() {
1562         if(!self.enemy)
1563                 return 0;
1564
1565         if (self == self.enemy)
1566                 return 0;
1567
1568         if(self.enemy.flags & FL_NOTARGET)
1569                 return 0;
1570
1571         SpectateCopy(self.enemy);
1572
1573         return 1;
1574 }
1575
1576 float SpectateNext() {
1577         other = find(self.enemy, classname, "player");
1578         if (!other) {
1579                 other = find(other, classname, "player");
1580         }
1581         if (other) {
1582                 self.enemy = other;
1583         }
1584         if(self.enemy.classname == "player") {
1585                 msg_entity = self;
1586                 WriteByte(MSG_ONE, SVC_SETVIEW);
1587                 WriteEntity(MSG_ONE, self.enemy);
1588                 self.wantswelcomemessage = 1;
1589                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
1590                 if(!SpectateUpdate())
1591                         PutObserverInServer();
1592                 return 1;
1593         } else {
1594                 return 0;
1595         }
1596 }
1597
1598 /*
1599 =============
1600 ShowRespawnCountdown()
1601
1602 Update a respawn countdown display.
1603 =============
1604 */
1605 void ShowRespawnCountdown()
1606 {
1607         float number;
1608         if(self.deadflag == DEAD_NO) // just respawned?
1609                 return;
1610         else
1611         {
1612                 number = ceil(self.death_time - time);
1613                 if(number <= 0)
1614                         return;
1615                 if(number <= self.respawn_countdown)
1616                 {
1617                         self.respawn_countdown = number - 1;
1618                         if(ceil(self.death_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
1619                                 play2(self, strcat("announcer/robotic/", ftos(number), ".ogg"));
1620                 }
1621         }
1622 }
1623
1624 void LeaveSpectatorMode()
1625 {
1626         if(isJoinAllowed()) {
1627                 if(!cvar("teamplay") || cvar("g_campaign") || cvar("g_balance_teams")) {
1628                         self.classname = "player";
1629                         if(cvar("g_campaign") || cvar("g_balance_teams") || cvar("g_balance_teams_force"))
1630                                 JoinBestTeam(self, FALSE, TRUE);
1631                         if(cvar("g_campaign"))
1632                                 campaign_bots_may_start = 1;
1633                         PutClientInServer();
1634                         if(!(self.flags & FL_NOTARGET))
1635                                 bprint ("^4", self.netname, "^4 is playing now\n");
1636                         centerprint(self,"");
1637                         return;
1638                 } else {
1639                         stuffcmd(self,"menu_showteamselect\n");
1640                         return;
1641                 }
1642         }
1643         else {
1644                 //player may not join because of g_maxplayers is set
1645                 centerprint_atprio(self, CENTERPRIO_MAPVOTE, PREVENT_JOIN_TEXT);
1646         }
1647 }
1648
1649 /**
1650  * Determines whether the player is allowed to join. This depends on cvar
1651  * g_maxplayers, if it isn't used this function always return TRUE, otherwise
1652  * it checks whether the number of currently playing players exceeds g_maxplayers.
1653  * @return bool TRUE if the player is allowed to join, false otherwise
1654  */
1655 float isJoinAllowed() {
1656         if (!cvar("g_maxplayers"))
1657                 return TRUE;
1658
1659         local entity e;
1660         local float currentlyPlaying;
1661         FOR_EACH_REALPLAYER(e) {
1662                 if(e.classname == "player")
1663                         currentlyPlaying += 1;
1664         }
1665         if(currentlyPlaying < cvar("g_maxplayers"))
1666                 return TRUE;
1667
1668         return FALSE;
1669 }
1670
1671 /**
1672  * Checks whether the client is an observer or spectator, if so, he will get kicked after
1673  * g_maxplayers_spectator_blocktime seconds
1674  */
1675 void checkSpectatorBlock() {
1676         if(self.classname == "spectator" || self.classname == "observer") {
1677                 if( time > (self.spectatortime + cvar("g_maxplayers_spectator_blocktime")) ) {
1678                         sprint(self, "^7You were kicked from the server because you are spectator and spectators aren't allowed at the moment.\n");
1679                         dropclient(self);
1680                 }
1681         }
1682 }
1683
1684 float vercmp_recursive(string v1, string v2)
1685 {
1686         float dot1, dot2;
1687         string s1, s2;
1688         float r;
1689
1690         dot1 = strstrofs(v1, ".", 0);
1691         dot2 = strstrofs(v2, ".", 0);
1692         if(dot1 == -1)
1693                 s1 = v1;
1694         else
1695                 s1 = substring(v1, 0, dot1);
1696         if(dot2 == -1)
1697                 s2 = v2;
1698         else
1699                 s2 = substring(v2, 0, dot2);
1700
1701         r = stof(s1) - stof(s2);
1702         if(r != 0)
1703                 return r;
1704
1705         r = strcasecmp(s1, s2);
1706         if(r != 0)
1707                 return r;
1708
1709         if(dot1 == -1)
1710                 if(dot2 == -1)
1711                         return 0;
1712                 else
1713                         return -1;
1714         else
1715                 if(dot2 == -1)
1716                         return 1;
1717                 else
1718                         return vercmp_recursive(substring(v1, dot1 + 1, 999), substring(v2, dot2 + 1, 999));
1719 }
1720
1721 float vercmp(string v1, string v2)
1722 {
1723         if(strcasecmp(v1, v2) == 0) // early out check
1724                 return 0;
1725         return vercmp_recursive(v1, v2);
1726 }
1727
1728 void ObserverThink()
1729 {
1730         if (self.flags & FL_JUMPRELEASED) {
1731                 if (self.BUTTON_JUMP && self.version == cvar("gameversion")) {
1732                         self.welcomemessage_time = 0;
1733                         self.flags = self.flags - FL_JUMPRELEASED;
1734                         LeaveSpectatorMode();
1735                         return;
1736                 } else if(self.BUTTON_ATCK && self.version == cvar("gameversion")) {
1737                         self.welcomemessage_time = 0;
1738                         self.flags = self.flags - FL_JUMPRELEASED;
1739                         if(SpectateNext() == 1) {
1740                                 self.classname = "spectator";
1741                         }
1742                 }
1743         } else {
1744                 if (!(self.BUTTON_ATCK || self.BUTTON_JUMP)) {
1745                         self.flags = self.flags | FL_JUMPRELEASED;
1746                 }
1747         }
1748         if(self.BUTTON_ZOOM)
1749                 self.wantswelcomemessage = 0;
1750         if(self.wantswelcomemessage)
1751                 PrintWelcomeMessage(self);
1752 }
1753
1754 void SpectatorThink()
1755 {
1756         if (self.flags & FL_JUMPRELEASED) {
1757                 if (self.BUTTON_JUMP && self.version == cvar("gameversion")) {
1758                         self.welcomemessage_time = 0;
1759                         self.flags = self.flags - FL_JUMPRELEASED;
1760                         LeaveSpectatorMode();
1761                         return;
1762                 } else if(self.BUTTON_ATCK) {
1763                         self.welcomemessage_time = 0;
1764                         self.flags = self.flags - FL_JUMPRELEASED;
1765                         if(SpectateNext() == 1) {
1766                                 self.classname = "spectator";
1767                         } else {
1768                                 self.classname = "observer";
1769                                 PutClientInServer();
1770                         }
1771                 } else if (self.BUTTON_ATCK2) {
1772                         self.welcomemessage_time = 0;
1773                         self.flags = self.flags - FL_JUMPRELEASED;
1774                         self.classname = "observer";
1775                         PutClientInServer();
1776                 } else {
1777                         if(!SpectateUpdate())
1778                                 PutObserverInServer();
1779                 }
1780         } else {
1781                 if (!(self.BUTTON_ATCK || self.BUTTON_ATCK2)) {
1782                         self.flags = self.flags | FL_JUMPRELEASED;
1783                 }
1784         }
1785         if(self.BUTTON_ZOOM)
1786                 self.wantswelcomemessage = 0;
1787         if(self.wantswelcomemessage)
1788                 PrintWelcomeMessage(self);
1789         self.flags = self.flags | FL_CLIENT | FL_NOTARGET;
1790 }
1791
1792 /*
1793 =============
1794 PlayerPreThink
1795
1796 Called every frame for each client before the physics are run
1797 =============
1798 */
1799 void() ctf_setstatus;
1800 .float vote_nagtime;
1801 void PlayerPreThink (void)
1802 {
1803         if(blockSpectators)
1804                 checkSpectatorBlock();
1805
1806         if(self.netname_previous != self.netname)
1807         {
1808                 if(cvar("sv_eventlog"))
1809                         GameLogEcho(strcat(":name:", ftos(self.playerid), ":", self.netname), TRUE);
1810                 if(self.netname_previous)
1811                         strunzone(self.netname_previous);
1812                 self.netname_previous = strzone(self.netname);
1813         }
1814
1815         // version nagging
1816         if(self.version_nagtime)
1817                 if(self.cvar_g_nexuizversion)
1818                         if(time > self.version_nagtime)
1819                         {
1820                                 if(strstr(self.cvar_g_nexuizversion, "svn", 0) < 0)
1821                                 {
1822                                         if(strstr(cvar_string("g_nexuizversion"), "svn", 0) >= 0)
1823                                         {
1824                                                 dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Nexuiz ", cvar_string("g_nexuizversion"), " (beta)^7, you have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1\n");
1825                                                 sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Nexuiz ", cvar_string("g_nexuizversion"), " (beta)^7, you have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1\n"));
1826                                         }
1827                                         else
1828                                         {
1829                                                 float r;
1830                                                 r = vercmp(self.cvar_g_nexuizversion, cvar_string("g_nexuizversion"));
1831                                                 if(r < 0)
1832                                                 {
1833                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - ^3Nexuiz ", cvar_string("g_nexuizversion"), "^7 is out, and you still have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1 - get the update from ^4http://www.nexuiz.com/^1!\n");
1834                                                         sprint(self, strcat("\{1}^1NOTE: ^3Nexuiz ", cvar_string("g_nexuizversion"), "^7 is out, and you still have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1 - get the update from ^4http://www.nexuiz.com/^1!\n"));
1835                                                 }
1836                                                 else if(r > 0)
1837                                                 {
1838                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Nexuiz ", cvar_string("g_nexuizversion"), "^7, you have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1\n");
1839                                                         sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Nexuiz ", cvar_string("g_nexuizversion"), "^7, you have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1\n"));
1840                                                 }
1841                                         }
1842                                 }
1843                                 self.version_nagtime = 0;
1844                         }
1845
1846         // vote nagging
1847         if(self.cvar_scr_centertime)
1848                 if(time > self.vote_nagtime)
1849                 {
1850                         VoteNag();
1851                         self.vote_nagtime = time + self.cvar_scr_centertime * 0.6;
1852                 }
1853
1854         // GOD MODE info
1855         if(!(self.flags & FL_GODMODE)) if(self.max_armorvalue)
1856         {
1857                 sprint(self, strcat("godmode saved you ", ftos(self.max_armorvalue), " units of damage, cheater!\n"));
1858                 self.max_armorvalue = 0;
1859         }
1860
1861         if(frametime)
1862                 antilag_record(self);
1863
1864         if(self.classname == "player") {
1865 //              if(self.netname == "Wazat")
1866 //                      bprint(self.classname, "\n");
1867
1868                 CheckRules_Player();
1869
1870                 if(self.BUTTON_INFO)
1871                         PrintWelcomeMessage(self);
1872
1873                 if(g_lms || !cvar("sv_spectate"))
1874                 if((time - self.jointime) <= cvar("welcome_message_time"))
1875                         PrintWelcomeMessage(self);
1876
1877                 if (intermission_running)
1878                 {
1879                         IntermissionThink ();   // otherwise a button could be missed between
1880                         return;                                 // the think tics
1881                 }
1882
1883                 if(self.teleport_time)
1884                 if(time > self.teleport_time)
1885                 {
1886                         self.teleport_time = 0;
1887                         self.effects = self.effects - (self.effects & EF_NODRAW);
1888                         if(self.weaponentity)
1889                                 self.weaponentity.flags = self.weaponentity.flags - (self.weaponentity.flags & EF_NODRAW);
1890                 }
1891
1892                 Nixnex_GiveCurrentWeapon();
1893
1894                 if(frametime > 0) // don't do this in cl_movement frames, just in server ticks
1895                         UpdateSelectedPlayer();
1896
1897                 //don't allow the player to turn around while game is paused!
1898                 if(timeoutStatus == 2) {
1899                         self.v_angle = self.lastV_angle;
1900                         self.angles = self.lastV_angle;
1901                         self.fixangle = TRUE;
1902                 }
1903
1904                 if (self.deadflag != DEAD_NO)
1905                 {
1906                         float button_pressed, force_respawn;
1907                         player_anim();
1908                         button_pressed = (self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE);
1909                         force_respawn = (g_lms || cvar("g_forced_respawn"));
1910                         if (self.deadflag == DEAD_DYING)
1911                         {
1912                                 if(force_respawn)
1913                                         self.deadflag = DEAD_RESPAWNING;
1914                                 else if(!button_pressed)
1915                                         self.deadflag = DEAD_DEAD;
1916                         }
1917                         else if (self.deadflag == DEAD_DEAD)
1918                         {
1919                                 if(button_pressed)
1920                                         self.deadflag = DEAD_RESPAWNABLE;
1921                         }
1922                         else if (self.deadflag == DEAD_RESPAWNABLE)
1923                         {
1924                                 if(!button_pressed)
1925                                         self.deadflag = DEAD_RESPAWNING;
1926                         }
1927                         else if (self.deadflag == DEAD_RESPAWNING)
1928                         {
1929                                 if(time > self.death_time)
1930                                 {
1931                                         self.death_time = time + 1; // only retry once a second
1932                                         respawn();
1933                                 }
1934                         }
1935                         ShowRespawnCountdown();
1936                         return;
1937                 }
1938
1939                 if(g_lms && !self.deadflag && cvar("g_lms_campcheck_interval"))
1940                 {
1941                         vector dist;
1942
1943                         // calculate player movement (in 2 dimensions only, so jumping on one spot doesn't count as movement)
1944                         dist = self.oldorigin - self.origin;
1945                         dist_z = 0;
1946                         self.lms_traveled_distance += fabs(vlen(dist));
1947
1948                         if((cvar("g_campaign") && !campaign_bots_may_start) || (time < restart_countdown))
1949                         {
1950                                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval")*2;
1951                                 self.lms_traveled_distance = 0;
1952                         }
1953
1954                         if(time > self.lms_nextcheck)
1955                         {
1956                                 //sprint(self, "distance: ", ftos(self.lms_traveled_distance), "\n");
1957                                 if(self.lms_traveled_distance < cvar("g_lms_campcheck_distance"))
1958                                 {
1959                                         centerprint(self, cvar_string("g_lms_campcheck_message"));
1960                                         // FIXME KadaverJack: gibbing player here causes playermodel to bounce around, instead of eye.md3
1961                                         // I wasn't able to find out WHY that happens, so I put a workaround in place that shall prevent players from being gibbed :(
1962                                         Damage(self, self, self, bound(0, cvar("g_lms_campcheck_damage"), self.health + self.armorvalue * cvar("g_balance_armor_blockpercent") + 5), DEATH_CAMP, self.origin, '0 0 0');
1963                                 }
1964                                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval");
1965                                 self.lms_traveled_distance = 0;
1966                         }
1967                 }
1968
1969                 if (self.BUTTON_CROUCH && !self.hook.state)
1970                 {
1971                         if (!self.crouch)
1972                         {
1973                                 self.crouch = TRUE;
1974                                 self.view_ofs = PL_CROUCH_VIEW_OFS;
1975                                 setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX);
1976                                 player_setanim(self.anim_duck, FALSE, TRUE, TRUE);
1977                         }
1978                 }
1979                 else
1980                 {
1981                         if (self.crouch)
1982                         {
1983                                 tracebox(self.origin, PL_MIN, PL_MAX, self.origin, FALSE, self);
1984                                 if (!trace_startsolid)
1985                                 {
1986                                         self.crouch = FALSE;
1987                                         self.view_ofs = PL_VIEW_OFS;
1988                                         setsize (self, PL_MIN, PL_MAX);
1989                                 }
1990                         }
1991                 }
1992
1993                 FixPlayermodel();
1994
1995                 GrapplingHookFrame();
1996
1997                 W_WeaponFrame();
1998
1999                 {
2000                         float zoomfactor, zoomspeed, zoomdir;
2001                         zoomfactor = self.cvar_cl_zoomfactor;
2002                         if(zoomfactor < 1 || zoomfactor > 16)
2003                                 zoomfactor = 2.5;
2004                         zoomspeed = self.cvar_cl_zoomspeed;
2005                         if(zoomspeed >= 0) // < 0 is instant zoom
2006                                 if(zoomspeed < 0.5 || zoomspeed > 16)
2007                                         zoomspeed = 3.5;
2008
2009                         zoomdir = self.BUTTON_ZOOM;
2010                         if(self.BUTTON_ATCK2)
2011                                 if(self.weapon == WEP_NEX)
2012                                         if(!g_minstagib)
2013                                                 zoomdir = 1;
2014
2015                         if(zoomdir)
2016                                 self.has_zoomed = 1;
2017
2018                         if(self.has_zoomed)
2019                         {
2020                                 if(zoomspeed <= 0) // instant zoom
2021                                 {
2022                                         if(zoomdir)
2023                                                 self.viewzoom = 1 / zoomfactor;
2024                                         else
2025                                                 self.viewzoom = 1;
2026                                 }
2027                                 else
2028                                 {
2029                                         // geometric zoom would be:
2030                                         //   self.viewzoom = bound(1 / zoomfactor, self.viewzoom * pow(zoomfactor, (zoomdir ? -1 : 1) * frametime * zoomspeed), 1);
2031                                         // however, testing showed that arithmetic/harmonic zoom works better
2032                                         if(zoomdir)
2033                                                 // self.viewzoom = 1 / bound(1, 1 / self.viewzoom + (zoomdir ? 1 : -1) * frametime * zoomspeed * (zoomfactor - 1), zoomfactor);
2034                                                 // zoom in = arithmetic: 1x, 2x, 3x, 4x, ..., 8x
2035                                                 self.viewzoom = 1 / bound(1, 1 / self.viewzoom + frametime * zoomspeed * (zoomfactor - 1), zoomfactor);
2036                                         else
2037                                                 // self.viewzoom = bound(1 / zoomfactor, self.viewzoom + (zoomdir ? -1 : 1) * frametime * zoomspeed * (1 - 1 / zoomfactor), 1);
2038                                                 // zoom out = harmonic: 8/1x, 8/2x, 8/3x, 8/4x, ..., 8/8x
2039                                                 self.viewzoom = bound(1 / zoomfactor, self.viewzoom + frametime * zoomspeed * (1 - 1 / zoomfactor), 1);
2040                                 }
2041                         }
2042                         else
2043                                 self.viewzoom = min(1, self.viewzoom + frametime); // spawn zoom-in
2044                 }
2045
2046                 player_powerups();
2047                 player_regen();
2048                 player_anim();
2049
2050                 if (g_minstagib)
2051                         minstagib_ammocheck();
2052
2053                 ctf_setstatus();
2054                 kh_setstatus();
2055
2056                 //self.angles_y=self.v_angle_y + 90;   // temp
2057
2058                 //if (TetrisPreFrame()) return;
2059         } else if(gameover) {
2060                 if (intermission_running)
2061                         IntermissionThink ();   // otherwise a button could be missed between
2062                 return;
2063         } else if(self.classname == "observer") {
2064                 ObserverThink();
2065         } else if(self.classname == "spectator") {
2066                 SpectatorThink();
2067         }
2068 }
2069
2070
2071 /*
2072 =============
2073 PlayerPostThink
2074
2075 Called every frame for each client after the physics are run
2076 =============
2077 */
2078 .float idlekick_lasttimeleft;
2079 void PlayerPostThink (void)
2080 {
2081         // Savage: Check for nameless players
2082         if (strlen(self.netname) < 1) {
2083                 self.netname = "Player";
2084                 stuffcmd(self, "seta _cl_name Player\n");
2085         }
2086
2087         if(sv_maxidle)
2088         {
2089                 float timeleft;
2090                 timeleft = ceil(sv_maxidle - (time - self.parm_idlesince));
2091                 if(timeleft <= 0)
2092                 {
2093                         bprint("^3", self.netname, "^3 was kicked for idling.\n");
2094                         play2(self, "announcer/robotic/terminated.ogg");
2095                         dropclient(self);
2096                         return;
2097                 }
2098                 else if(timeleft <= 10)
2099                 {
2100                         if(timeleft != self.idlekick_lasttimeleft)
2101                         {
2102                                 centerprint_atprio(self, CENTERPRIO_IDLEKICK, strcat("^3Stop idling!\n^3Disconnecting in ", ftos(timeleft), "..."));
2103                                 play2(self, strcat("announcer/robotic/", ftos(timeleft), ".ogg"));
2104                         }
2105                 }
2106                 else
2107                 {
2108                         centerprint_expire(self, CENTERPRIO_IDLEKICK);
2109                 }
2110                 self.idlekick_lasttimeleft = timeleft;
2111         }
2112
2113         if(self.classname == "player") {
2114                 CheckRules_Player();
2115                 UpdateChatBubble();
2116                 UpdateTeamBubble();
2117                 if (self.impulse)
2118                         ImpulseCommands();
2119                 if (intermission_running)
2120                         return;         // intermission or finale
2121
2122                 //PrintWelcomeMessage(self);
2123                 //if (TetrisPostFrame()) return;
2124
2125                 // restart countdown
2126                 if (restart_countdown) {
2127                         if(time < restart_countdown) {
2128                                 if (!cvar("sv_ready_restart_after_countdown"))
2129                                 {
2130                                         self.movetype = MOVETYPE_NONE;
2131                                         self.velocity = '0 0 0';
2132                                         self.avelocity = '0 0 0';
2133                                         self.movement = '0 0 0';
2134                                 }
2135                         }
2136                         else
2137                         {
2138                                 //allow the player to move again if sv_ready_restart_after_countdown is not used and countdown is over
2139                                 if (!cvar("sv_ready_restart_after_countdown"))
2140                                 {
2141                                         if(self.movetype == MOVETYPE_NONE)
2142                                         {
2143                                                 self.movetype = MOVETYPE_WALK;
2144                                         }
2145                                 }
2146                         }
2147                 }
2148
2149         } else if (self.classname == "observer") {
2150                 //do nothing
2151         } else if (self.classname == "spectator") {
2152                 //do nothing
2153         }
2154
2155         Arena_Warmup();
2156 }