data/qcsrc/server/cl_client.qc

   1 void info_player_start (void)
   2 {
   3         self.classname = "info_player_deathmatch";
   4         relocate_spawnpoint();
   5 }
   6
   7 void info_player_deathmatch (void)
   8 {
   9         relocate_spawnpoint();
  10 }
  11
  12 float spawn_allbad;
  13 float spawn_allgood;
  14 entity Spawn_FilterOutBadSpots(entity firstspot, entity playerlist, float mindist, float teamcheck)
  15 {
  16         local entity spot, player, nextspot, previousspot, newfirstspot;
  17         local float pcount;
  18         spot = firstspot;
  19         newfirstspot = world;
  20         previousspot = world;
  21         spawn_allgood = TRUE;
  22         spawn_allbad = TRUE;
  23         while (spot)
  24         {
  25                 nextspot = spot.chain;
  26                 // count team mismatches as bad spots
  27                 if (spot.team == teamcheck)
  28                 {
  29                         pcount = 0;
  30                         player = playerlist;
  31                         while (player)
  32                         {
  33                                 if (player != self)
  34                                 if (vlen(player.origin - spot.origin) < mindist)
  35                                         pcount = pcount + 1;
  36                                 player = player.chain;
  37                         }
  38                         if (!pcount)
  39                         {
  40                                 spawn_allbad = FALSE;
  41                                 if (newfirstspot)
  42                                         previousspot.chain = spot;
  43                                 else
  44                                         newfirstspot = spot;
  45                                 previousspot = spot;
  46                                 spot.chain = world;
  47                         }
  48                         else
  49                                 spawn_allgood = FALSE;
  50                 }
  51                 spot = nextspot;
  52         }
  53         // if we couldn't find ANY good points, return the original list
  54         if (!newfirstspot)
  55                 newfirstspot = firstspot;
  56         return newfirstspot;
  57 }
  58
  59 entity Spawn_RandomPoint(entity firstspot)
  60 {
  61         local entity spot;
  62         local float numspots;
  63         // count number of spots
  64         numspots = 0;
  65         spot = firstspot;
  66         while (spot)
  67         {
  68                 numspots = numspots + 1;
  69                 spot = spot.chain;
  70         }
  71         // pick a random one
  72         numspots = numspots * random();
  73         spot = firstspot;
  74         while (spot.chain && numspots >= 1)
  75         {
  76                 numspots = numspots - 1;
  77                 spot = spot.chain;
  78         }
  79         return spot;
  80 }
  81
  82 entity Spawn_FurthestPoint(entity firstspot, entity playerlist)
  83 {
  84         local entity best, spot, player;
  85         local float bestrating, rating;
  86         best = world;
  87         bestrating = -1000000;
  88         spot = firstspot;
  89         while (spot)
  90         {
  91                 rating = 1000000000;
  92                 player = playerlist;
  93                 while (player)
  94                 {
  95                         if (player != self)
  96                                 rating = min(rating, vlen(player.origin - spot.origin));
  97                         player = player.chain;
  98                 }
  99                 rating = rating + random() * 16;
 100                 if (bestrating < rating)
 101                 {
 102                         best = spot;
 103                         bestrating = rating;
 104                 }
 105                 spot = spot.chain;
 106         }
 107         return best;
 108 }
 109
 110 /*
 111 =============
 112 SelectSpawnPoint
 113
 114 Finds a point to respawn
 115 =============
 116 */
 117 entity SelectSpawnPoint (float anypoint)
 118 {
 119         local float teamcheck;
 120         local entity spot, firstspot, playerlist;
 121
 122         spot = find (world, classname, "testplayerstart");
 123         if (spot)
 124                 return spot;
 125
 126         teamcheck = 0;
 127
 128         if(!anypoint && cvar("g_ctf") )
 129                 teamcheck = self.team;
 130
 131         // get the list of players
 132         playerlist = findchain(classname, "player");
 133         // get the entire list of spots
 134         firstspot = findchain(classname, "info_player_deathmatch");
 135         // filter out the bad ones
 136         // (note this returns the original list if none survived)
 137         firstspot = Spawn_FilterOutBadSpots(firstspot, playerlist, 100, teamcheck);
 138
 139         // there is 50/50 chance of choosing a random spot or the furthest spot
 140         // (this means that roughly every other spawn will be furthest, so you
 141         // usually won't get fragged at spawn twice in a row)
 142         if (arena_roundbased)
 143         {
 144                 firstspot = Spawn_FilterOutBadSpots(firstspot, playerlist, 800, teamcheck);
 145                 spot = Spawn_RandomPoint(firstspot);
 146         }
 147         else if (random() > 0.5 || spawn_allbad || spawn_allgood)
 148                 spot = Spawn_RandomPoint(firstspot);
 149         else
 150                 spot = Spawn_FurthestPoint(firstspot, playerlist);
 151
 152         if (!spot)
 153         {
 154                 if(cvar("spawn_debug"))
 155                         GotoNextMap();
 156                 else
 157                         error ("PutClientInServer: no start points on level");
 158         }
 159
 160         return spot;
 161 }
 162
 163 /*
 164 =============
 165 CheckPlayerModel
 166
 167 Checks if the argument string can be a valid playermodel.
 168 Returns a valid one in doubt.
 169 =============
 170 */
 171 string FallbackPlayerModel = "models/player/marine.zym";
 172 string CheckPlayerModel(string plyermodel) {
 173         if(strlen(plyermodel) < 4)
 174                 return FallbackPlayerModel;
 175         if( substring(plyermodel,0,14) != "models/player/")
 176                 return FallbackPlayerModel;
 177         else if(cvar("sv_servermodelsonly"))
 178         {
 179                 if(substring(plyermodel,strlen(plyermodel)-4,4) != ".zym")
 180                         return FallbackPlayerModel;
 181                 if(!fexists(plyermodel))
 182                         return FallbackPlayerModel;
 183         }
 184         return plyermodel;
 185 }
 186
 187 /*
 188 =============
 189 Client_customizeentityforclient
 190
 191 LOD reduction
 192 =============
 193 */
 194 float Client_customizeentityforclient()
 195 {
 196 #ifdef ALLOW_VARIABLE_LOD
 197         // self: me
 198         // other: the player viewing me
 199         float distance;
 200         float f;
 201
 202         if(self.flags & FL_NOTARGET) // we don't need LOD for spectators
 203                 return TRUE;
 204
 205         if(other.cvar_cl_playerdetailreduction <= 0)
 206         {
 207                 if(other.cvar_cl_playerdetailreduction <= -2)
 208                         self.modelindex = self.modelindex_lod2;
 209                 else if(other.cvar_cl_playerdetailreduction <= -1)
 210                         self.modelindex = self.modelindex_lod1;
 211                 else
 212                         self.modelindex = self.modelindex_lod0;
 213         }
 214         else
 215         {
 216                 distance = vlen(self.origin - other.origin);
 217                 f = (distance + 100.0) * other.cvar_cl_playerdetailreduction;
 218                 if(f > 10000)
 219                         self.modelindex = self.modelindex_lod2;
 220                 else if(f > 5000)
 221                         self.modelindex = self.modelindex_lod1;
 222                 else
 223                         self.modelindex = self.modelindex_lod0;
 224         }
 225 #endif
 226
 227         return TRUE;
 228 }
 229
 230 void setmodel_lod(entity e, string modelname)
 231 {
 232 #ifdef ALLOW_VARIABLE_LOD
 233         string s;
 234
 235         s = strcat(substring(modelname, 0, strlen(modelname) - 4), "_1.zym");
 236         if(fexists(s))
 237         {
 238                 precache_model(s);
 239                 setmodel(e, s);
 240                 self.modelindex_lod1 = self.modelindex;
 241         }
 242         else
 243                 self.modelindex_lod1 = -1;
 244
 245         s = strcat(substring(modelname, 0, strlen(modelname) - 4), "_2.zym");
 246         if(fexists(s))
 247         {
 248                 precache_model(s);
 249                 setmodel(e, s);
 250                 self.modelindex_lod2 = self.modelindex;
 251         }
 252         else
 253                 self.modelindex_lod2 = -1;
 254
 255         precache_model(modelname);
 256         setmodel(e, modelname);
 257         self.modelindex_lod0 = self.modelindex;
 258
 259         if(self.modelindex_lod1 < 0)
 260                 self.modelindex_lod1 = self.modelindex;
 261
 262         if(self.modelindex_lod2 < 0)
 263                 self.modelindex_lod2 = self.modelindex;
 264 #else
 265         precache_model(modelname);
 266         setmodel(e, modelname);
 267 #endif
 268 }
 269
 270 /*
 271 =============
 272 PutObserverInServer
 273
 274 putting a client as observer in the server
 275 =============
 276 */
 277 void PutObserverInServer (void)
 278 {
 279         entity  spot;
 280         spot = SelectSpawnPoint (FALSE);
 281         RemoveGrapplingHook(self); // Wazat's Grappling Hook
 282
 283         if(clienttype(self) == CLIENTTYPE_REAL)
 284         {
 285                 msg_entity = self;
 286                 WriteByte(MSG_ONE, SVC_SETVIEW);
 287                 WriteEntity(MSG_ONE, self);
 288         }
 289
 290         DropAllRunes(self);
 291
 292         if(self.flagcarried)
 293                 DropFlag(self.flagcarried);
 294
 295         DistributeFragsAmongTeam(self, self.team, 1);
 296
 297         if(self.frags <= 0 && self.frags > -666 && cvar("g_lms") && self.killcount != -666)
 298                 bprint (strcat("^4", self.netname, "^4 has no more lives left\n"));
 299         else if(self.killcount != -666)
 300                 bprint (strcat("^4", self.netname, "^4 is spectating now\n"));
 301
 302         self.classname = "observer";
 303         self.health = -666;
 304         self.takedamage = DAMAGE_NO;
 305         self.solid = SOLID_NOT;
 306         self.movetype = MOVETYPE_NOCLIP;
 307         self.flags = FL_CLIENT | FL_NOTARGET;
 308         self.armorvalue = 666;
 309         self.effects = 0;
 310         self.armorvalue = cvar("g_balance_armor_start");
 311         self.pauserotarmor_finished = 0;
 312         self.pauserothealth_finished = 0;
 313         self.pauseregen_finished = 0;
 314         self.damageforcescale = 0;
 315         self.death_time = 0;
 316         self.dead_time = 0;
 317         self.dead_frame = 0;
 318         self.die_frame = 0;
 319         self.deaths = 0;
 320         self.alpha = 0;
 321         self.scale = 0;
 322         self.fade_time = 0;
 323         self.pain_frame = 0;
 324         self.pain_finished = 0;
 325         self.strength_finished = 0;
 326         self.invincible_finished = 0;
 327         self.pushltime = 0;
 328         self.think = SUB_Null;
 329         self.nextthink = 0;
 330         self.hook_time = 0;
 331         self.runes = 0;
 332         self.deadflag = DEAD_NO;
 333         self.angles = spot.angles;
 334         self.angles_z = 0;
 335         self.fixangle = TRUE;
 336         self.crouch = FALSE;
 337
 338         self.view_ofs = PL_VIEW_OFS;
 339         setorigin (self, spot.origin);
 340         setsize (self, '0 0 0', '0 0 0');
 341         self.oldorigin = self.origin;
 342         self.items = 0;
 343         self.model = "";
 344         self.modelindex = 0;
 345         self.weapon = 0;
 346         self.weaponmodel = "";
 347         self.weaponentity = world;
 348         self.killcount = -666;
 349         self.velocity = '0 0 0';
 350         self.avelocity = '0 0 0';
 351         self.punchangle = '0 0 0';
 352         self.punchvector = '0 0 0';
 353         self.oldvelocity = self.velocity;
 354         self.customizeentityforclient = Client_customizeentityforclient;
 355
 356         if(cvar("g_arena"))
 357         {
 358                 if(self.frags != -2)
 359                 {
 360                         Spawnqueue_Insert(self);
 361                 }
 362                 else
 363                 {
 364                         Spawnqueue_Unmark(self);
 365                         Spawnqueue_Remove(self);
 366                 }
 367         }
 368         else if(!cvar("g_lms"))
 369                 self.frags = -666;
 370 }
 371
 372
 373 /*
 374 =============
 375 PutClientInServer
 376
 377 Called when a client spawns in the server
 378 =============
 379 */
 380 void PutClientInServer (void)
 381 {
 382         if(clienttype(self) == CLIENTTYPE_BOT)
 383         {
 384                 self.classname = "player";
 385         }
 386         else if(clienttype(self) == CLIENTTYPE_REAL)
 387         {
 388                 msg_entity = self;
 389                 WriteByte(MSG_ONE, SVC_SETVIEW);
 390                 WriteEntity(MSG_ONE, self);
 391         }
 392
 393         // player is dead and becomes observer
 394         if(cvar("g_lms") && self.frags < 1)
 395                 self.classname = "observer";
 396
 397         if(cvar("g_arena"))
 398         if(!self.spawned)
 399                 self.classname = "observer";
 400
 401         if(self.classname == "player") {
 402                 entity  spot;
 403
 404                 spot = SelectSpawnPoint (FALSE);
 405
 406                 RemoveGrapplingHook(self); // Wazat's Grappling Hook
 407
 408                 self.classname = "player";
 409                 self.iscreature = TRUE;
 410                 self.movetype = MOVETYPE_WALK;
 411                 self.solid = SOLID_SLIDEBOX;
 412                 self.flags = FL_CLIENT;
 413                 self.takedamage = DAMAGE_AIM;
 414                 self.effects = 0;
 415                 self.health = cvar("g_balance_health_start");
 416                 self.armorvalue = cvar("g_balance_armor_start");
 417                 self.spawnshieldtime = time + cvar("g_spawnshieldtime");
 418                 self.pauserotarmor_finished = time + cvar("g_balance_pause_armor_rot_spawn");
 419                 self.pauserothealth_finished = time + cvar("g_balance_pause_health_rot_spawn");
 420                 self.pauseregen_finished = time + cvar("g_balance_pause_health_regen_spawn");
 421                 self.damageforcescale = 2;
 422                 self.death_time = 0;
 423                 self.dead_time = 0;
 424                 self.dead_frame = 0;
 425                 self.die_frame = 0;
 426                 self.alpha = 0;
 427                 self.scale = 0;
 428                 self.fade_time = 0;
 429                 self.pain_frame = 0;
 430                 self.pain_finished = 0;
 431                 self.strength_finished = 0;
 432                 self.invincible_finished = 0;
 433                 self.pushltime = 0;
 434                 //self.speed_finished = 0;
 435                 //self.slowmo_finished = 0;
 436                 // players have no think function
 437                 self.think = SUB_Null;
 438                 self.nextthink = 0;
 439                 self.weapon = 0;
 440                 self.switchweapon = 0;
 441                 self.hook_time = 0;
 442
 443                 self.runes = 0;
 444
 445                 self.deadflag = DEAD_NO;
 446
 447                 self.angles = spot.angles;
 448
 449                 self.angles_z = 0; // never spawn tilted even if the spot says to
 450                 self.fixangle = TRUE; // turn this way immediately
 451                 self.velocity = '0 0 0';
 452                 self.avelocity = '0 0 0';
 453                 self.punchangle = '0 0 0';
 454                 self.punchvector = '0 0 0';
 455                 self.oldvelocity = self.velocity;
 456
 457                 self.viewzoom = 0.6;
 458
 459                 self.customizeentityforclient = Client_customizeentityforclient;
 460
 461                 if(cvar("sv_defaultcharacter") == 1 && !teams_matter) {
 462                         local string defaultmodel;
 463                         defaultmodel = CheckPlayerModel(cvar_string("sv_defaultplayermodel"));
 464                         setmodel_lod (self, defaultmodel);
 465                         self.skin = stof(cvar_string("sv_defaultplayerskin"));
 466                 } else {
 467                         self.playermodel = CheckPlayerModel(self.playermodel);
 468                         setmodel_lod (self, self.playermodel);
 469                         if(teams_matter)
 470                                 self.skin = math_mod(stof(self.playerskin), NUM_PLAYERSKINS_TEAMPLAY);
 471                         else
 472                                 self.skin = stof(self.playerskin);
 473                 }
 474
 475                 self.crouch = FALSE;
 476                 self.view_ofs = PL_VIEW_OFS;
 477                 setsize (self, PL_MIN, PL_MAX);
 478                 self.spawnorigin = spot.origin;
 479                 setorigin (self, spot.origin + '0 0 1' * (1 - self.mins_z - 24));
 480                 // don't reset back to last position, even if new position is stuck in solid
 481                 self.oldorigin = self.origin;
 482
 483                 if(cvar("g_lms"))
 484                 {
 485                         self.ammo_shells = cvar("g_lms_start_ammo_shells");
 486                         self.ammo_nails = cvar("g_lms_start_ammo_nails");
 487                         self.ammo_rockets = cvar("g_lms_start_ammo_rockets");
 488                         self.ammo_cells = cvar("g_lms_start_ammo_cells");
 489                         self.health = cvar("g_lms_start_health");
 490                         self.armorvalue = cvar("g_lms_start_armor");
 491                 }
 492                 else if (cvar("g_use_ammunition")) {
 493                         self.ammo_shells = cvar("g_start_ammo_shells");
 494                         self.ammo_nails = cvar("g_start_ammo_nails");
 495                         self.ammo_rockets = cvar("g_start_ammo_rockets");
 496                         self.ammo_cells = cvar("g_start_ammo_cells");
 497                 } else {
 498                         self.ammo_shells = 999;
 499                         self.ammo_nails = 999;
 500                         self.ammo_rockets = 999;
 501                         self.ammo_cells = 999;
 502                 }
 503
 504                 self.items = 0;
 505                 if (cvar("g_start_weapon_laser") || cvar("g_lms"))
 506                 {
 507                         self.items = self.items | IT_LASER;
 508                         self.switchweapon = WEP_LASER;
 509                 }
 510                 if (cvar("g_start_weapon_shotgun") || cvar("g_lms"))
 511                 {
 512                         self.items = self.items | IT_SHOTGUN;
 513                         self.switchweapon = WEP_SHOTGUN;
 514                 }
 515                 if (cvar("g_start_weapon_uzi") || cvar("g_lms"))
 516                 {
 517                         self.items = self.items | IT_UZI;
 518                         self.switchweapon = WEP_UZI;
 519                 }
 520                 if (cvar("g_start_weapon_grenadelauncher") || cvar("g_lms"))
 521                 {
 522                         self.items = self.items | IT_GRENADE_LAUNCHER;
 523                         self.switchweapon = WEP_GRENADE_LAUNCHER;
 524                 }
 525                 if (cvar("g_start_weapon_electro") || cvar("g_lms"))
 526                 {
 527                         self.items = self.items | IT_ELECTRO;
 528                         self.switchweapon = WEP_ELECTRO;
 529                 }
 530                 if (cvar("g_start_weapon_crylink") || cvar("g_lms"))
 531                 {
 532                         self.items = self.items | IT_CRYLINK;
 533                         self.switchweapon = WEP_CRYLINK;
 534                 }
 535                 if (cvar("g_start_weapon_nex") || cvar("g_lms"))
 536                 {
 537                         self.items = self.items | IT_NEX;
 538                         self.switchweapon = WEP_NEX;
 539                 }
 540                 if (cvar("g_start_weapon_hagar") || cvar("g_lms"))
 541                 {
 542                         self.items = self.items | IT_HAGAR;
 543                         self.switchweapon = WEP_HAGAR;
 544                 }
 545                 if (cvar("g_start_weapon_rocketlauncher") || cvar("g_lms"))
 546                 {
 547                         self.items = self.items | IT_ROCKET_LAUNCHER;
 548                         self.switchweapon = WEP_ROCKET_LAUNCHER;
 549                 }
 550
 551                 if(cvar("g_instagib"))
 552                 {
 553                         self.items = IT_NEX;
 554                         self.switchweapon = WEP_NEX;
 555                         self.ammo_cells = 999;
 556                 }
 557
 558                 if(cvar("g_rocketarena"))
 559                 {
 560                         self.items = IT_ROCKET_LAUNCHER;
 561                         self.switchweapon = WEP_ROCKET_LAUNCHER;
 562                         self.ammo_rockets = 999;
 563                 }
 564
 565                 if(cvar("g_nixnex"))
 566                 {
 567                         self.items = 0;
 568                         // will be done later
 569                 }
 570
 571                 if(cvar("g_minstagib"))
 572                 {
 573                         self.health = 100;
 574                         self.armorvalue = 0;
 575                         self.items = IT_NEX;
 576                         self.switchweapon = WEP_NEX;
 577                         self.ammo_cells = cvar("g_minstagib_ammo_start");
 578                         self.jump_interval = time;
 579                 }
 580
 581                 if(cvar("g_arena"))
 582                 {
 583                         Spawnqueue_Remove(self);
 584                         Spawnqueue_Mark(self);
 585                 }
 586
 587                 self.event_damage = PlayerDamage;
 588
 589                 self.bot_attack = TRUE;
 590
 591                 self.statdraintime = time + 5;
 592                 self.button0 = self.button1 = self.button2 = self.button3 = 0;
 593
 594                 if(self.killcount == -666) {
 595                         self.killcount = 0;
 596                         if(!cvar("g_arena"))
 597                         if(!cvar("g_lms"))
 598                                 self.frags = 0;
 599                 }
 600
 601                 self.cnt = WEP_LASER;
 602                 self.nixnex_lastchange_id = -1;
 603
 604                 CL_SpawnWeaponentity();
 605                 self.alpha = default_player_alpha;
 606                 self.exteriorweaponentity.alpha = default_weapon_alpha;
 607
 608                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval")*2;
 609                 self.lms_traveled_distance = 0;
 610
 611                 if(cvar("spawn_debug"))
 612                 {
 613                                 sprint(self, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 614                                 remove(spot);   // usefull for checking if there are spawnpoints, that let drop through the floor
 615                 }
 616
 617                 //stuffcmd(self, "chase_active 0");
 618                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
 619         } else if(self.classname == "observer") {
 620                 PutObserverInServer ();
 621         }
 622 }
 623
 624 /*
 625 =============
 626 SetNewParms
 627 =============
 628 */
 629 void SetNewParms (void)
 630 {
 631
 632 }
 633
 634 /*
 635 =============
 636 SetChangeParms
 637 =============
 638 */
 639 void SetChangeParms (void)
 640 {
 641
 642 }
 643
 644 /*
 645 =============
 646 ClientKill
 647
 648 Called when a client types 'kill' in the console
 649 =============
 650 */
 651 void ClientKill (void)
 652 {
 653         Damage(self, self, self, 100000, DEATH_KILL, self.origin, '0 0 0');
 654 }
 655
 656 void FixClientCvars(entity e)
 657 {
 658         // send prediction settings to the client
 659         stuffcmd(e, "\nin_bindmap 0 0\n");
 660         stuffcmd(e, strcat("cl_gravity ", ftos(cvar("sv_gravity")), "\n"));
 661         stuffcmd(e, strcat("cl_movement_accelerate ", ftos(cvar("sv_accelerate")), "\n"));
 662         stuffcmd(e, strcat("cl_movement_friction ", ftos(cvar("sv_friction")), "\n"));
 663         stuffcmd(e, strcat("cl_movement_maxspeed ", ftos(cvar("sv_maxspeed")), "\n"));
 664         stuffcmd(e, strcat("cl_movement_airaccelerate ", ftos(cvar("sv_airaccelerate")), "\n"));
 665         stuffcmd(e, strcat("cl_movement_maxairspeed ", ftos(cvar("sv_maxairspeed")), "\n"));
 666         stuffcmd(e, strcat("cl_movement_stopspeed ", ftos(cvar("sv_stopspeed")), "\n"));
 667         stuffcmd(e, strcat("cl_movement_jumpvelocity ", ftos(cvar("g_balance_jumpheight")), "\n"));
 668         stuffcmd(e, strcat("cl_movement_stepheight ", ftos(cvar("sv_stepheight")), "\n"));
 669         stuffcmd(e, strcat("set cl_movement_friction_on_land ", ftos(cvar("sv_friction_on_land")), "\n"));
 670         stuffcmd(e, strcat("set cl_movement_airaccel_qw ", ftos(cvar("sv_airaccel_qw")), "\n"));
 671         stuffcmd(e, strcat("set cl_movement_airaccel_sideways_friction ", ftos(cvar("sv_airaccel_sideways_friction")), "\n"));
 672         stuffcmd(e, strcat("cl_movement_edgefriction 0\n"));
 673 }
 674
 675 /*
 676 =============
 677 ClientConnect
 678
 679 Called when a client connects to the server
 680 =============
 681 */
 682 string ColoredTeamName(float t);
 683 //void dom_player_join_team(entity pl);
 684 void ClientConnect (void)
 685 {
 686         local string s;
 687
 688         self.classname = "player_joining";
 689         self.flags = self.flags | FL_CLIENT;
 690         self.version_nagtime = time + 10 + random() * 10;
 691
 692         if(player_count<0)
 693         {
 694                 dprint("BUG player count is lower than zero, this cannot happen!\n");
 695                 player_count = 0;
 696         }
 697
 698         bot_clientconnect();
 699
 700         //if(cvar("g_domination"))
 701         //      dom_player_join_team(self);
 702
 703         //JoinBestTeam(self, FALSE);
 704
 705         if((cvar("sv_spectate") == 1 && !cvar("g_lms")) || cvar("g_campaign")) {
 706                 self.classname = "observer";
 707         } else {
 708                 self.classname = "player";
 709                 campaign_bots_may_start = 1;
 710         }
 711
 712         self.playerid = (playerid_last = playerid_last + 1);
 713         if(cvar("sv_eventlog"))
 714         {
 715                 if(clienttype(self) == CLIENTTYPE_REAL)
 716                         s = "player";
 717                 else
 718                         s = "bot";
 719                 GameLogEcho(strcat(":join:", ftos(self.playerid), ":", s, ":", self.netname), TRUE);
 720                 s = strcat(":team:", ftos(self.playerid), ":");
 721                 s = strcat(s, ftos(self.team));
 722                 GameLogEcho(s, FALSE);
 723         }
 724
 725         //stuffcmd(self, "set tmpviewsize $viewsize \n");
 726
 727         bprint ("^4",self.netname);
 728         bprint ("^4 connected");
 729
 730         if(cvar("g_domination") || cvar("g_ctf"))
 731         {
 732                 bprint(" and joined the ");
 733                 bprint(ColoredTeamName(self.team));
 734         }
 735
 736         bprint("\n");
 737
 738         self.welcomemessage_time = 0;
 739
 740         stuffcmd(self, strcat("exec maps/", mapname, ".cfg\n"));
 741         // TODO: is this being used for anything else than cd tracks?
 742         // Remember: SVC_CDTRACK exists. Maybe it should be used.
 743
 744         FixClientCvars(self);
 745
 746         // Wazat's grappling hook
 747         SetGrappleHookBindings();
 748
 749         // get autoswitch state from player
 750         stuffcmd(self, "alias autoswitch \"set cl_autoswitch $1; cmd autoswitch $1\"\n");
 751         stuffcmd(self, "cmd autoswitch $cl_autoswitch\n");
 752
 753         // get version info from player
 754         stuffcmd(self, "cmd clientversion $gameversion\n");
 755
 756         // get other cvars from player
 757         GetCvars(0);
 758
 759         // set cvar for team scoreboard
 760         if (teams_matter)
 761         {
 762                 local float t;
 763                 t = cvar("teamplay");
 764                 // we have to stuff the correct teamplay value because if this is a listen server, this changes the teamplay mode of the server itself, which is bad
 765                 stuffcmd(self, strcat("set teamplay ", ftos(t), "\n"));
 766         }
 767         else
 768                 stuffcmd(self, strcat("set teamplay 0\n"));
 769
 770         if(cvar("g_lms"))
 771         {
 772                 self.frags = cvar("fraglimit");
 773                 // no fraglimit was set, so player gets 999 lives
 774                 if(self.frags < 1)
 775                         self.frags = 999;
 776
 777                 self.frags = LMS_NewPlayerLives();
 778                 if(!self.frags)
 779                 {
 780                         self.frags = -666;
 781                 }
 782         }
 783         else if(cvar("g_arena"))
 784         {
 785                 self.classname = "observer";
 786                 Spawnqueue_Insert(self);
 787         }
 788
 789         bot_relinkplayerlist();
 790
 791         self.jointime = time;
 792 }
 793
 794 /*
 795 =============
 796 ClientDisconnect
 797
 798 Called when a client disconnects from the server
 799 =============
 800 */
 801 void(entity e) DropFlag;
 802 .entity chatbubbleentity;
 803 .entity teambubbleentity;
 804 void ClientDisconnect (void)
 805 {
 806         float save;
 807         if(cvar("sv_eventlog"))
 808                 GameLogEcho(strcat(":part:", ftos(self.playerid)), FALSE);
 809         bprint ("^4",self.netname);
 810         bprint ("^4 disconnected\n");
 811
 812         if (self.chatbubbleentity)
 813         {
 814                 remove (self.chatbubbleentity);
 815                 self.chatbubbleentity = world;
 816         }
 817
 818         if (self.teambubbleentity)
 819         {
 820                 remove (self.teambubbleentity);
 821                 self.teambubbleentity = world;
 822         }
 823
 824         DropAllRunes(self);
 825
 826         if(self.flagcarried)
 827                 DropFlag(self.flagcarried);
 828
 829         DistributeFragsAmongTeam(self, self.team, 1);
 830
 831         save = self.flags;
 832         self.flags = self.flags - (self.flags & FL_CLIENT);
 833         bot_relinkplayerlist();
 834         self.flags = save;
 835
 836         // remove laserdot
 837         if(self.weaponentity)
 838                 if(self.weaponentity.lasertarget)
 839                         remove(self.weaponentity.lasertarget);
 840
 841         if(cvar("g_arena"))
 842         {
 843                 Spawnqueue_Unmark(self);
 844                 Spawnqueue_Remove(self);
 845         }
 846
 847         // free cvars
 848         GetCvars(-1);
 849 }
 850
 851 .float buttonchat;
 852 void() ChatBubbleThink =
 853 {
 854         self.nextthink = time;
 855         if (!self.owner.modelindex || self.owner.chatbubbleentity != self)
 856         {
 857                 self.owner.chatbubbleentity = world;
 858                 remove(self);
 859                 return;
 860         }
 861         setorigin(self, self.owner.origin + '0 0 15' + self.owner.maxs_z * '0 0 1');
 862         if (self.owner.buttonchat && !self.owner.deadflag)
 863                 self.model = self.mdl;
 864         else
 865                 self.model = "";
 866 };
 867
 868 void() UpdateChatBubble =
 869 {
 870         if (!self.modelindex)
 871                 return;
 872         // spawn a chatbubble entity if needed
 873         if (!self.chatbubbleentity)
 874         {
 875                 self.chatbubbleentity = spawn();
 876                 self.chatbubbleentity.owner = self;
 877                 self.chatbubbleentity.exteriormodeltoclient = self;
 878                 self.chatbubbleentity.think = ChatBubbleThink;
 879                 self.chatbubbleentity.nextthink = time;
 880                 setmodel(self.chatbubbleentity, "models/misc/chatbubble.spr");
 881                 setorigin(self.chatbubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
 882                 self.chatbubbleentity.mdl = self.chatbubbleentity.model;
 883                 self.chatbubbleentity.model = "";
 884         }
 885 }
 886
 887
 888 void() TeamBubbleThink =
 889 {
 890         self.nextthink = time;
 891         if (!self.owner.modelindex || self.owner.teambubbleentity != self)
 892         {
 893                 self.owner.teambubbleentity = world;
 894                 remove(self);
 895                 return;
 896         }
 897 //      setorigin(self, self.owner.origin + '0 0 15' + self.owner.maxs_z * '0 0 1');  // bandwidth hog. setattachment does this now
 898         if (self.owner.buttonchat || self.owner.deadflag)
 899                 self.model = "";
 900         else
 901                 self.model = self.mdl;
 902
 903 };
 904
 905 float() TeamBubble_customizeentityforclient
 906 {
 907         return (self.owner != other && self.owner.team == other.team && other.killcount > -666);
 908 }
 909
 910 void() UpdateTeamBubble =
 911 {
 912         if (!self.modelindex || !cvar("teamplay"))
 913                 return;
 914         // spawn a teambubble entity if needed
 915         if (!self.teambubbleentity && cvar("teamplay"))
 916         {
 917                 self.teambubbleentity = spawn();
 918                 self.teambubbleentity.owner = self;
 919                 self.teambubbleentity.exteriormodeltoclient = self;
 920                 self.teambubbleentity.think = TeamBubbleThink;
 921                 self.teambubbleentity.nextthink = time;
 922                 setmodel(self.teambubbleentity, "models/misc/teambubble.spr");
 923 //              setorigin(self.teambubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
 924                 setorigin(self.teambubbleentity, self.teambubbleentity.origin + '0 0 15' + self.maxs_z * '0 0 1');
 925                 setattachment(self.teambubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
 926                 self.teambubbleentity.mdl = self.teambubbleentity.model;
 927                 self.teambubbleentity.model = self.teambubbleentity.mdl;
 928                 self.teambubbleentity.customizeentityforclient = TeamBubble_customizeentityforclient;
 929         }
 930 }
 931
 932 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
 933 // added to the model skins
 934 /*void() UpdateColorModHack =
 935 {
 936         local float c;
 937         c = self.clientcolors & 15;
 938         // LordHavoc: only bothering to support white, green, red, yellow, blue
 939              if (teamplay == 0) self.colormod = '0 0 0';
 940         else if (c ==  0) self.colormod = '1.00 1.00 1.00';
 941         else if (c ==  3) self.colormod = '0.10 1.73 0.10';
 942         else if (c ==  4) self.colormod = '1.73 0.10 0.10';
 943         else if (c == 12) self.colormod = '1.22 1.22 0.10';
 944         else if (c == 13) self.colormod = '0.10 0.10 1.73';
 945         else self.colormod = '1 1 1';
 946 };*/
 947
 948 /*
 949 =============
 950 PlayerJump
 951
 952 When you press the jump key
 953 =============
 954 */
 955 void PlayerJump (void)
 956 {
 957         float mjumpheight;
 958
 959         mjumpheight = cvar("g_balance_jumpheight");
 960         if (self.waterlevel >= 2)
 961         {
 962                 if (self.watertype == CONTENT_WATER)
 963                         self.velocity_z = 200;
 964                 else if (self.watertype == CONTENT_SLIME)
 965                         self.velocity_z = 80;
 966                 else
 967                         self.velocity_z = 50;
 968
 969                 return;
 970         }
 971
 972
 973         if (!(self.flags & FL_ONGROUND))
 974                 return;
 975
 976         if (!(self.flags & FL_JUMPRELEASED))
 977                 return;
 978
 979         if(cvar("g_runematch"))
 980         {
 981                 if(self.runes & RUNE_SPEED)
 982                 {
 983                         if(self.runes & CURSE_SLOW)
 984                                 mjumpheight = mjumpheight * cvar("g_balance_rune_speed_combo_jumpheight");
 985                         else
 986                                 mjumpheight = mjumpheight * cvar("g_balance_rune_speed_jumpheight");
 987                 }
 988                 else if(self.runes & CURSE_SLOW)
 989                 {
 990                         mjumpheight = mjumpheight * cvar("g_balance_curse_slow_jumpheight");
 991                 }
 992         }
 993
 994         if(cvar("g_minstagib") && (self.items & IT_INVINCIBLE))
 995         {
 996                 mjumpheight = mjumpheight * cvar("g_balance_rune_speed_jumpheight");
 997         }
 998
 999         self.velocity_z = self.velocity_z + mjumpheight;
1000         self.oldvelocity_z = self.velocity_z;
1001
1002         self.flags = self.flags - FL_ONGROUND;
1003         self.flags = self.flags - FL_JUMPRELEASED;
1004 }
1005
1006 void() CheckWaterJump =
1007 {
1008         local vector start, end;
1009
1010 // check for a jump-out-of-water
1011         makevectors (self.angles);
1012         start = self.origin;
1013         start_z = start_z + 8;
1014         v_forward_z = 0;
1015         normalize(v_forward);
1016         end = start + v_forward*24;
1017         traceline (start, end, TRUE, self);
1018         if (trace_fraction < 1)
1019         {       // solid at waist
1020                 start_z = start_z + self.maxs_z - 8;
1021                 end = start + v_forward*24;
1022                 self.movedir = trace_plane_normal * -50;
1023                 traceline (start, end, TRUE, self);
1024                 if (trace_fraction == 1)
1025                 {       // open at eye level
1026                         self.flags = self.flags | FL_WATERJUMP;
1027                         self.velocity_z = 225;
1028                         self.flags = self.flags - (self.flags & FL_JUMPRELEASED);
1029                         self.teleport_time = time + 2;  // safety net
1030                         return;
1031                 }
1032         }
1033 };
1034
1035
1036 void respawn(void)
1037 {
1038         CopyBody(1);
1039         PutClientInServer();
1040 }
1041
1042 void player_powerups (void)
1043 {
1044         if (cvar("g_minstagib"))
1045         {
1046                 self.effects = EF_FULLBRIGHT;
1047                 if (self.items & IT_STRENGTH)
1048                 {
1049                         if (time > self.strength_finished)
1050                         {
1051                                 self.alpha = default_player_alpha;
1052                                 self.exteriorweaponentity.alpha = default_weapon_alpha;
1053                                 self.items = self.items - (self.items & IT_STRENGTH);
1054                                 sprint(self, "^3Invisibility has worn off\n");
1055                         }
1056                 }
1057                 else
1058                 {
1059                         if (time < self.strength_finished)
1060                         {
1061                                 self.alpha = cvar("g_minstagib_invis_alpha");
1062                                 self.exteriorweaponentity.alpha = cvar("g_minstagib_invis_alpha");
1063                                 self.items = self.items | IT_STRENGTH;
1064                                 sprint(self, "^3You are invisible\n");
1065                         }
1066                 }
1067
1068                 if (self.items & IT_INVINCIBLE)
1069                 {
1070                         if (time > self.invincible_finished)
1071                         {
1072                                 self.items = self.items - (self.items & IT_INVINCIBLE);
1073                                 sprint(self, "^3Speed has worn off\n");
1074                         }
1075                 }
1076                 else
1077                 {
1078                         if (time < self.invincible_finished)
1079                         {
1080                                 self.items = self.items | IT_INVINCIBLE;
1081                                 sprint(self, "^3You are on speed\n");
1082                         }
1083                 }
1084                 return;
1085         }
1086
1087         self.effects = self.effects - (self.effects & (EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT));
1088         if (self.items & IT_STRENGTH)
1089         {
1090                 self.effects = self.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1091                 if (time > self.strength_finished)
1092                 {
1093                         self.items = self.items - (self.items & IT_STRENGTH);
1094                         sprint(self, "^3Strength has worn off\n");
1095                 }
1096         }
1097         else
1098         {
1099                 if (time < self.strength_finished)
1100                 {
1101                         self.items = self.items | IT_STRENGTH;
1102                         sprint(self, "^3Strength infuses your weapons with devastating power\n");
1103                 }
1104         }
1105         if (self.items & IT_INVINCIBLE)
1106         {
1107                 self.effects = self.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1108                 if (time > self.invincible_finished)
1109                 {
1110                         self.items = self.items - (self.items & IT_INVINCIBLE);
1111                         sprint(self, "^3Shield has worn off\n");
1112                 }
1113         }
1114         else
1115         {
1116                 if (time < self.invincible_finished)
1117                 {
1118                         self.items = self.items | IT_INVINCIBLE;
1119                         sprint(self, "^3Shield surrounds you\n");
1120                 }
1121         }
1122
1123         if (cvar("g_fullbrightplayers"))
1124                 self.effects = self.effects | EF_FULLBRIGHT;
1125
1126         // midair gamemode: damage only while in the air
1127         // if in midair mode, being on ground grants temporary invulnerability
1128         // (this is so that multishot weapon don't clear the ground flag on the
1129         // first damage in the frame, leaving the player vulnerable to the
1130         // remaining hits in the same frame)
1131         if (self.flags & FL_ONGROUND)
1132         if (cvar("g_midair"))
1133                 self.spawnshieldtime = max(self.spawnshieldtime, time + cvar("g_midair_shieldtime"));
1134
1135         if (time < self.spawnshieldtime)
1136                 self.effects = self.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1137 }
1138
1139 float CalcRegen(float current, float stable, float maxv, float regenfactor)
1140 {
1141         if(current > stable)
1142                 return current;
1143         else if(current > stable - 0.25) // when close enough, "snap"
1144                 return stable;
1145         else
1146                 return bound(0, current + (stable - current) * regenfactor * frametime, maxv);
1147 }
1148
1149 void player_regen (void)
1150 {
1151         float maxh, maxa, limith, limita, max_mod, regen_mod, rot_mod, limit_mod;
1152         maxh = cvar("g_balance_health_stable");
1153         maxa = cvar("g_balance_armor_stable");
1154         limith = cvar("g_balance_health_limit");
1155         limita = cvar("g_balance_armor_limit");
1156
1157         if (cvar("g_minstagib") || (cvar("g_lms") && !cvar("g_lms_regenerate")))
1158                 return;
1159
1160         if(cvar("g_runematch"))
1161         {
1162                 max_mod = regen_mod = rot_mod = limit_mod = 1;
1163                 if (self.runes & RUNE_REGEN)
1164                 {
1165                         if (self.runes & CURSE_VENOM) // do we have both rune/curse?
1166                         {
1167                                 regen_mod = cvar("g_balance_rune_regen_combo_regenrate");
1168                                 max_mod = cvar("g_balance_rune_regen_combo_hpmod");
1169                                 limit_mod = cvar("g_balance_rune_regen_combo_limitmod");
1170                         }
1171                         else
1172                         {
1173                                 regen_mod = cvar("g_balance_rune_regen_regenrate");
1174                                 max_mod = cvar("g_balance_rune_regen_hpmod");
1175                                 limit_mod = cvar("g_balance_rune_regen_limitmod");
1176                         }
1177                 }
1178                 else if (self.runes & CURSE_VENOM)
1179                 {
1180                         max_mod = cvar("g_balance_curse_venom_hpmod");
1181                         if (self.runes & RUNE_REGEN) // do we have both rune/curse?
1182                                 rot_mod = cvar("g_balance_rune_regen_combo_rotrate");
1183                         else
1184                                 rot_mod = cvar("g_balance_curse_venom_rotrate");
1185                         limit_mod = cvar("g_balance_curse_venom_limitmod");
1186                         //if (!self.runes & RUNE_REGEN)
1187                         //      rot_mod = cvar("g_balance_curse_venom_rotrate");
1188                 }
1189                 maxh = maxh * max_mod;
1190                 //maxa = maxa * max_mod;
1191
1192                 if (time > self.pauserotarmor_finished)
1193                 {
1194                         if (self.armorvalue > maxa)
1195                                 self.armorvalue = bound(0, self.armorvalue + (maxa - self.armorvalue) * cvar("g_balance_armor_rot") * frametime, 1000);
1196                 }
1197                 if (time > self.pauserothealth_finished)
1198                 {
1199                         if (self.health > maxh)
1200                                 self.health = bound(0, self.health + (maxh - self.health) * rot_mod*cvar("g_balance_health_rot") * frametime, 1000);
1201                 }
1202                 if (time > self.pauseregen_finished)
1203                 {
1204                         self.health = CalcRegen(self.health, maxh, 1000, regen_mod * cvar("g_balance_health_regen"));
1205                         self.armorvalue = CalcRegen(self.armorvalue, maxa, 1000, cvar("g_balance_armor_regen"));
1206                 }
1207         }
1208         else
1209         {
1210                 if (time > self.pauserothealth_finished)
1211                 if (self.health > maxh)
1212                         self.health = bound(0, self.health + (maxh - self.health) * cvar("g_balance_health_rot") * frametime, 1000);
1213                 if (time > self.pauserotarmor_finished)
1214                 if (self.armorvalue > maxa)
1215                         self.armorvalue = bound(0, self.armorvalue + (maxa - self.armorvalue) * cvar("g_balance_armor_rot") * frametime, 1000);
1216                 if (time > self.pauseregen_finished)
1217                 {
1218                         self.health = CalcRegen(self.health, maxh, 1000, cvar("g_balance_health_regen"));
1219                         self.armorvalue = CalcRegen(self.armorvalue, maxa, 1000, cvar("g_balance_armor_regen"));
1220                 }
1221         }
1222
1223         if (self.health > limith)
1224                 self.health = limith;
1225         if(self.health < 1)
1226                 self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
1227         if (self.armorvalue > limita)
1228                 self.armorvalue = limita;
1229 }
1230
1231 /*
1232 ======================
1233 spectate mode routines
1234 ======================
1235 */
1236 void SpectateCopy(entity spectatee) {
1237         self.armortype = spectatee.armortype;
1238         self.armorvalue = spectatee.armorvalue;
1239         self.currentammo = spectatee.currentammo;
1240         self.effects = spectatee.effects;
1241         self.health = spectatee.health;
1242         self.impulse = 0;
1243         self.items = spectatee.items;
1244         self.punchangle = spectatee.punchangle;
1245         self.view_ofs = spectatee.view_ofs;
1246         self.v_angle = spectatee.v_angle;
1247         self.viewzoom = spectatee.viewzoom;
1248         setorigin(self, spectatee.origin);
1249         setsize(self, spectatee.mins, spectatee.maxs);
1250 }
1251
1252 void SpectateUpdate() {
1253         if(!self.enemy)
1254                         PutObserverInServer();
1255
1256         if (self != self.enemy) {
1257                 if(self.enemy.flags & FL_NOTARGET)
1258                         PutObserverInServer();
1259                 SpectateCopy(self.enemy);
1260                 self.dmg_take = self.enemy.dmg_take;
1261                 self.dmg_save = self.enemy.dmg_save;
1262                 self.dmg_inflictor = self.enemy.dmg_inflictor;
1263                 self.fixangle = TRUE;
1264                 self.angles = self.enemy.v_angle;
1265                 //msg_entity = self;
1266                 //WriteByte(MSG_ONE, SVC_SETANGLE);
1267                 //WriteAngle(MSG_ONE, self.enemy.v_angle_x);
1268                 //WriteAngle(MSG_ONE, self.enemy.v_angle_y);
1269                 //WriteAngle(MSG_ONE, self.enemy.v_angle_z);
1270         }
1271 }
1272
1273 float SpectateNext() {
1274         other = find(self.enemy, classname, "player");
1275         if (!other) {
1276                 other = find(other, classname, "player");
1277         }
1278         if (other) {
1279                 self.enemy = other;
1280         }
1281         if(self.enemy.classname == "player") {
1282                 msg_entity = self;
1283                 WriteByte(MSG_ONE, SVC_SETVIEW);
1284                 WriteEntity(MSG_ONE, self.enemy);
1285                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
1286                 SpectateUpdate();
1287                 return 1;
1288         } else {
1289                 return 0;
1290         }
1291 }
1292
1293 /*
1294 =============
1295 ShowRespawnCountdown()
1296
1297 Update a respawn countdown display.
1298 =============
1299 */
1300 void ShowRespawnCountdown()
1301 {
1302         float number;
1303         if(self.deadflag == DEAD_NO) // just respawned?
1304                 return;
1305         else
1306         {
1307                 number = ceil(self.death_time - time);
1308                 if(number <= 0)
1309                         return;
1310                 if(number <= self.respawn_countdown)
1311                 {
1312                         self.respawn_countdown = number - 1;
1313                         if(ceil(self.death_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
1314                                 stuffcmd(self, strcat("play2 announcer/robotic/", ftos(number), ".ogg\n"));
1315                 }
1316         }
1317 }
1318
1319 void LeaveSpectatorMode()
1320 {
1321         if(!cvar("teamplay") || cvar("g_campaign") || cvar("g_balance_teams")) {
1322                 self.classname = "player";
1323                 if(cvar("g_campaign") || cvar("g_balance_teams"))
1324                         JoinBestTeam(self, 0);
1325                 if(cvar("g_campaign"))
1326                         campaign_bots_may_start = 1;
1327                 PutClientInServer();
1328                 if(!(self.flags & FL_NOTARGET))
1329                         bprint (strcat("^4", self.netname, "^4 is playing now\n"));
1330                 centerprint(self,"");
1331                 return;
1332         } else {
1333                 stuffcmd(self,"menu_showteamselect\n");
1334                 return;
1335         }
1336 }
1337
1338 /*
1339 =============
1340 PlayerPreThink
1341
1342 Called every frame for each client before the physics are run
1343 =============
1344 */
1345 void() ctf_setstatus;
1346 .float vote_nagtime;
1347 void PlayerPreThink (void)
1348 {
1349         // version nagging
1350         if(self.version_nagtime)
1351                 if(self.cvar_g_nexuizversion)
1352                         if(time > self.version_nagtime)
1353                         {
1354                                 if(strstr(self.cvar_g_nexuizversion, "svn", 0) < 0)
1355                                         if(self.cvar_g_nexuizversion != cvar_string("g_nexuizversion"))
1356                                         {
1357                                                 dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Nexuiz ", cvar_string("g_nexuizversion"), "^7, you have ^3Nexuiz ", self.cvar_g_nexuizversion, "\n");
1358                                                 sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Nexuiz ", cvar_string("g_nexuizversion"), "^7, you have ^3Nexuiz ", self.cvar_g_nexuizversion, "\n"));
1359                                         }
1360                                 self.version_nagtime = 0;
1361                         }
1362
1363         // vote nagging
1364         if(self.cvar_scr_centertime)
1365                 if(time > self.vote_nagtime)
1366                 {
1367                         VoteNag();
1368                         self.vote_nagtime = time + self.cvar_scr_centertime * 0.6;
1369                 }
1370
1371         if(self.classname == "player") {
1372                 local vector m1, m2;
1373
1374 //              if(self.netname == "Wazat")
1375 //                      bprint(strcat(self.classname, "\n"));
1376
1377                 CheckRules_Player();
1378
1379                 Nixnex_GiveCurrentWeapon();
1380
1381                 if(self.button7)
1382                         PrintWelcomeMessage(self);
1383
1384                 if(cvar("g_lms") || !cvar("sv_spectate"))
1385                 if((time - self.jointime) <= cvar("welcome_message_time"))
1386                         PrintWelcomeMessage(self);
1387
1388                 if (intermission_running)
1389                 {
1390                         IntermissionThink ();   // otherwise a button could be missed between
1391                         return;                                 // the think tics
1392                 }
1393
1394                 if (self.deadflag != DEAD_NO)
1395                 {
1396                         float button_pressed, force_respawn;
1397                         player_anim();
1398                         button_pressed = (self.button0 || self.button2 || self.button3 || self.button6 || self.buttonuse);
1399                         force_respawn = (cvar("g_lms") || cvar("g_forced_respawn"));
1400                         if (self.deadflag == DEAD_DYING)
1401                         {
1402                                 if(force_respawn)
1403                                         self.deadflag = DEAD_RESPAWNING;
1404                                 else if(!button_pressed)
1405                                         self.deadflag = DEAD_DEAD;
1406                         }
1407                         else if (self.deadflag == DEAD_DEAD)
1408                         {
1409                                 if(button_pressed)
1410                                         self.deadflag = DEAD_RESPAWNABLE;
1411                         }
1412                         else if (self.deadflag == DEAD_RESPAWNABLE)
1413                         {
1414                                 if(!button_pressed)
1415                                         self.deadflag = DEAD_RESPAWNING;
1416                         }
1417                         else if (self.deadflag == DEAD_RESPAWNING)
1418                         {
1419                                 if(time > self.death_time)
1420                                         respawn();
1421                         }
1422                         ShowRespawnCountdown();
1423                         return;
1424                 }
1425
1426                 if(cvar("g_lms") && !self.deadflag && cvar("g_lms_campcheck_interval"))
1427                 {
1428                         vector dist;
1429
1430                         // calculate player movement (in 2 dimensions only, so jumping on one spot doesn't count as movement)
1431                         dist = self.oldorigin - self.origin;
1432                         dist_z = 0;
1433                         self.lms_traveled_distance += fabs(vlen(dist));
1434
1435                         if(cvar("g_campaign"))
1436                         if(!campaign_bots_may_start)
1437                         {
1438                                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval")*2;
1439                                 self.lms_traveled_distance = 0;
1440                         }
1441
1442                         if(time > self.lms_nextcheck)
1443                         {
1444                                 //sprint(self, "distance: ", ftos(self.lms_traveled_distance), "\n");
1445                                 if(self.lms_traveled_distance < cvar("g_lms_campcheck_distance"))
1446                                 {
1447                                         centerprint(self, cvar_string("g_lms_campcheck_message"));
1448                                         // FIXME KadaverJack: gibbing player here causes playermodel to bounce around, instead of eye.md3
1449                                         // I wasn't able to find out WHY that happens, so I put a workaround in place that shall prevent players from being gibbed :(
1450                                         Damage(self, self, self, bound(0, cvar("g_lms_campcheck_damage"), self.health + self.armorvalue * cvar("g_balance_armor_blockpercent") + 5), DEATH_CAMP, self.origin, '0 0 0');
1451                                 }
1452                                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval");
1453                                 self.lms_traveled_distance = 0;
1454                         }
1455                 }
1456
1457                 if (self.button5 && !self.hook.state)
1458                 {
1459                         if (!self.crouch)
1460                         {
1461                                 self.crouch = TRUE;
1462                                 self.view_ofs = PL_CROUCH_VIEW_OFS;
1463                                 setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX);
1464                         }
1465                 }
1466                 else
1467                 {
1468                         if (self.crouch)
1469                         {
1470                                 tracebox(self.origin, PL_MIN, PL_MAX, self.origin, FALSE, self);
1471                                 if (!trace_startsolid)
1472                                 {
1473                                         self.crouch = FALSE;
1474                                         self.view_ofs = PL_VIEW_OFS;
1475                                         setsize (self, PL_MIN, PL_MAX);
1476                                 }
1477                         }
1478                 }
1479
1480                 if(cvar("sv_defaultcharacter") == 1 && !teams_matter) {
1481                         local string defaultmodel;
1482                         defaultmodel = CheckPlayerModel(cvar_string("sv_defaultplayermodel"));
1483
1484                         if (defaultmodel != self.model)
1485                         {
1486                                 m1 = self.mins;
1487                                 m2 = self.maxs;
1488                                 setmodel_lod (self, defaultmodel);
1489                                 setsize (self, m1, m2);
1490                         }
1491
1492                         if (self.skin != cvar("sv_defaultplayerskin"))
1493                                 self.skin = cvar("sv_defaultplayerskin");
1494                 } else {
1495                         if (self.playermodel != self.model)
1496                         {
1497                                 self.playermodel = CheckPlayerModel(self.playermodel);
1498                                 m1 = self.mins;
1499                                 m2 = self.maxs;
1500                                 setmodel_lod (self, self.playermodel);
1501                                 setsize (self, m1, m2);
1502                         }
1503
1504                         if(teams_matter)
1505                         {
1506                                 if (self.skin != math_mod(stof(self.playerskin), NUM_PLAYERSKINS_TEAMPLAY))
1507                                         self.skin = math_mod(stof(self.playerskin), NUM_PLAYERSKINS_TEAMPLAY);
1508                         }
1509                         else
1510                         {
1511                                 if (self.skin != stof(self.playerskin))
1512                                         self.skin = stof(self.playerskin);
1513                         }
1514                 }
1515
1516                 GrapplingHookFrame();
1517
1518                 W_WeaponFrame();
1519
1520                 if (self.button4 || (self.weapon == WEP_NEX && self.button3))
1521                 {
1522                         if (cvar("g_minstagib") && self.button3)
1523                         {
1524                                 if (self.jump_interval <= (time + 0.1))
1525                                 {
1526                                         self.jump_interval = time + 1;
1527                                         W_Laser_Attack();
1528                                 }
1529                         }
1530                         else if (self.viewzoom > 0.4)
1531                                 self.viewzoom = max (0.4, self.viewzoom - frametime * 2);
1532                 }
1533                 else if (self.viewzoom < 1.0)
1534                         self.viewzoom = min (1.0, self.viewzoom + frametime);
1535
1536
1537                 if (self.button2)
1538                         PlayerJump ();
1539                 else
1540                         self.flags = self.flags | FL_JUMPRELEASED;
1541
1542                 player_powerups();
1543                 player_regen();
1544                 player_anim();
1545
1546                 if (cvar("g_minstagib"))
1547                         minstagib_ammocheck();
1548
1549                 ctf_setstatus();
1550
1551                 //self.angles_y=self.v_angle_y + 90;   // temp
1552
1553                 if (self.waterlevel == 2)
1554                         CheckWaterJump ();
1555
1556                 //if (TetrisPreFrame()) return;
1557         } else if(gameover) {
1558                 if (intermission_running)
1559                         IntermissionThink ();   // otherwise a button could be missed between
1560                 return;
1561         } else if(self.classname == "observer") {
1562
1563                 if (self.flags & FL_JUMPRELEASED) {
1564                         if (self.button2 && self.version == cvar("gameversion")) {
1565                                 self.welcomemessage_time = 0;
1566                                 self.flags = self.flags - FL_JUMPRELEASED;
1567                                 LeaveSpectatorMode();
1568                                 return;
1569                         } else if(self.button0 && self.version == cvar("gameversion")) {
1570                                 self.welcomemessage_time = 0;
1571                                 self.flags = self.flags - FL_JUMPRELEASED;
1572                                 if(SpectateNext() == 1) {
1573                                         self.classname = "spectator";
1574                                 }
1575                         }
1576                 } else {
1577                         if (!(self.button0 || self.button2)) {
1578                                 self.flags = self.flags | FL_JUMPRELEASED;
1579                         }
1580                 }
1581                 PrintWelcomeMessage(self);
1582         } else if(self.classname == "spectator") {
1583                 if (self.flags & FL_JUMPRELEASED) {
1584                         if (self.button2 && self.version == cvar("gameversion")) {
1585                                 self.welcomemessage_time = 0;
1586                                 self.flags = self.flags - FL_JUMPRELEASED;
1587                                 LeaveSpectatorMode();
1588                                 return;
1589                         } else if(self.button0) {
1590                                 self.welcomemessage_time = 0;
1591                                 self.flags = self.flags - FL_JUMPRELEASED;
1592                                 if(SpectateNext() == 1) {
1593                                         self.classname = "spectator";
1594                                 } else {
1595                                         self.classname = "observer";
1596                                         PutClientInServer();
1597                                 }
1598                         } else if (self.button3) {
1599                                 self.welcomemessage_time = 0;
1600                                 self.flags = self.flags - FL_JUMPRELEASED;
1601                                 self.classname = "observer";
1602                                 PutClientInServer();
1603                         } else {
1604                                 SpectateUpdate();
1605                         }
1606                 } else {
1607                         if (!(self.button0 || self.button3)) {
1608                                 self.flags = self.flags | FL_JUMPRELEASED;
1609                         }
1610                 }
1611                 PrintWelcomeMessage(self);
1612                 self.flags = self.flags | FL_CLIENT | FL_NOTARGET;
1613         }
1614 }
1615
1616
1617 /*
1618 =============
1619 PlayerPostThink
1620
1621 Called every frame for each client after the physics are run
1622 =============
1623 */
1624 void PlayerPostThink (void)
1625 {
1626         // Savage: Check for nameless players
1627         if (strlen(self.netname) < 1) {
1628                 self.netname = "Player";
1629                 stuffcmd(self, "seta _cl_name Player\n");
1630         }
1631
1632         if(self.classname == "player") {
1633                 CheckRules_Player();
1634                 UpdateChatBubble();
1635                 UpdateTeamBubble();
1636                 if (self.deadflag == DEAD_NO)
1637                 if (self.impulse)
1638                         ImpulseCommands ();
1639                 if (intermission_running)
1640                         return;         // intermission or finale
1641
1642                 //PrintWelcomeMessage(self);
1643                 //if (TetrisPostFrame()) return;
1644         } else if (self.classname == "observer") {
1645                 //do nothing
1646         } else if (self.classname == "spectator") {
1647                 //do nothing
1648         }
1649         Arena_Warmup();
1650 }