data/qcsrc/server/cl_client.qc

   1 // let's abuse an existing field
   2 #define SPAWNPOINT_SCORE frags
   3
   4 .float wantswelcomemessage;
   5 .string netname_previous;
   6
   7 void spawnfunc_info_player_survivor (void)
   8 {
   9         spawnfunc_info_player_deathmatch();
  10 }
  11
  12 void spawnfunc_info_player_start (void)
  13 {
  14         spawnfunc_info_player_deathmatch();
  15 }
  16
  17 void spawnfunc_info_player_deathmatch (void)
  18 {
  19         self.classname = "info_player_deathmatch";
  20         relocate_spawnpoint();
  21 }
  22
  23 void spawnpoint_use()
  24 {
  25         if(teams_matter)
  26         if(have_team_spawns)
  27         {
  28                 self.team = activator.team;
  29                 some_spawn_has_been_used = 1;
  30         }
  31 };
  32
  33 // Returns:
  34 //   -1 if a spawn can't be used
  35 //   otherwise, a weight of the spawnpoint
  36 float Spawn_Score(entity spot, entity playerlist, float teamcheck)
  37 {
  38         float shortest, thisdist;
  39         entity player;
  40
  41         // filter out spots for the wrong team
  42         if(teamcheck)
  43         if(spot.team != teamcheck)
  44                 return -1;
  45
  46         if(race_spawns)
  47                 if(spot.target == "")
  48                         return -1;
  49
  50         // filter out spots for assault
  51         if(spot.target != "") {
  52                 local entity ent;
  53                 float good;
  54                 ent = find(world, targetname, spot.target);
  55                 while(ent) {
  56                         if(ent.classname == "target_objective")
  57                         {
  58                                 if(ent.health < 0 || ent.health >= ASSAULT_VALUE_INACTIVE)
  59                                         return -1;
  60                                 good = 1;
  61                         }
  62                         else if(ent.classname == "trigger_race_checkpoint")
  63                         {
  64                                 if(self.classname == "player") // spectators may spawn everywhere
  65                                 {
  66                                         if(ent.race_checkpoint != race_PreviousCheckpoint(self.race_checkpoint))
  67                                                 return -1;
  68                                         float pl;
  69                                         pl = self.race_place;
  70                                         if(pl > race_highest_place_spawn)
  71                                                 pl = 0;
  72                                         if(spot.race_place != pl)
  73                                                 return -1;
  74                                 }
  75                                 good = 1;
  76                         }
  77                         else
  78                         {
  79                         }
  80                         ent = find(ent, targetname, spot.target);
  81                 }
  82
  83                 if(!good)
  84                         return -1;
  85         }
  86
  87         player = playerlist;
  88         shortest = vlen(world.maxs - world.mins);
  89         for(player = playerlist; player; player = player.chain)
  90                 if (player != self)
  91                 {
  92                         thisdist = vlen(player.origin - spot.origin);
  93                         if (thisdist < shortest)
  94                                 shortest = thisdist;
  95                 }
  96         return shortest;
  97 }
  98
  99 float spawn_allbad;
 100 float spawn_allgood;
 101 entity Spawn_FilterOutBadSpots(entity firstspot, entity playerlist, float mindist, float teamcheck)
 102 {
 103         local entity spot, spotlist, spotlistend;
 104         spawn_allgood = TRUE;
 105         spawn_allbad = TRUE;
 106
 107         spotlist = world;
 108         spotlistend = world;
 109
 110         for(spot = firstspot; spot; spot = spot.chain)
 111         {
 112                 spot.SPAWNPOINT_SCORE = Spawn_Score(spot, playerlist, teamcheck);
 113
 114                 if(cvar("spawn_debugview"))
 115                 {
 116                         setmodel(spot, "models/runematch/rune.mdl");
 117                         if(spot.SPAWNPOINT_SCORE < mindist)
 118                         {
 119                                 spot.colormod = '1 0 0';
 120                                 spot.scale = 1;
 121                         }
 122                         else
 123                         {
 124                                 spot.colormod = '0 1 0';
 125                                 spot.scale = spot.SPAWNPOINT_SCORE / mindist;
 126                         }
 127                 }
 128
 129                 if(spot.SPAWNPOINT_SCORE >= 0) // spawning allowed here
 130                 {
 131                         if(spot.SPAWNPOINT_SCORE < mindist)
 132                         {
 133                                 // too short distance
 134                                 spawn_allgood = FALSE;
 135                         }
 136                         else
 137                         {
 138                                 // perfect
 139                                 spawn_allbad = FALSE;
 140
 141                                 if(spotlistend)
 142                                         spotlistend.chain = spot;
 143                                 spotlistend = spot;
 144                                 if(!spotlist)
 145                                         spotlist = spot;
 146
 147                                 /*
 148                                 if(teamcheck)
 149                                 if(spot.team != teamcheck)
 150                                         error("invalid spawn added");
 151
 152                                 print("added ", etos(spot), "\n");
 153                                 */
 154                         }
 155                 }
 156         }
 157         if(spotlistend)
 158                 spotlistend.chain = world;
 159
 160         /*
 161                 entity e;
 162                 if(teamcheck)
 163                         for(e = spotlist; e; e = e.chain)
 164                         {
 165                                 print("seen ", etos(e), "\n");
 166                                 if(e.team != teamcheck)
 167                                         error("invalid spawn found");
 168                         }
 169         */
 170
 171         return spotlist;
 172 }
 173
 174 entity Spawn_WeightedPoint(entity firstspot, float lower, float upper, float exponent)
 175 {
 176         // weight of a point: bound(lower, mindisttoplayer, upper)^exponent
 177         // multiplied by spot.cnt (useful if you distribute many spawnpoints in a small area)
 178         local entity spot;
 179
 180         RandomSelection_Init();
 181         for(spot = firstspot; spot; spot = spot.chain)
 182                 RandomSelection_Add(spot, 0, pow(bound(lower, spot.SPAWNPOINT_SCORE, upper), exponent) * spot.cnt, spot.SPAWNPOINT_SCORE >= lower);
 183
 184         return RandomSelection_chosen_ent;
 185 }
 186
 187 /*
 188 =============
 189 SelectSpawnPoint
 190
 191 Finds a point to respawn
 192 =============
 193 */
 194 entity SelectSpawnPoint (float anypoint)
 195 {
 196         local float teamcheck;
 197         local entity firstspot_new;
 198         local entity spot, firstspot, playerlist;
 199
 200         spot = find (world, classname, "testplayerstart");
 201         if (spot)
 202                 return spot;
 203
 204         teamcheck = 0;
 205
 206         if(!anypoint && have_team_spawns)
 207                 teamcheck = self.team;
 208
 209         // get the list of players
 210         playerlist = findchain(classname, "player");
 211         // get the entire list of spots
 212         firstspot = findchain(classname, "info_player_deathmatch");
 213         // filter out the bad ones
 214         // (note this returns the original list if none survived)
 215         firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, 100, teamcheck);
 216         if(!firstspot_new)
 217                 firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, -1, teamcheck);
 218         firstspot = firstspot_new;
 219
 220         // there is 50/50 chance of choosing a random spot or the furthest spot
 221         // (this means that roughly every other spawn will be furthest, so you
 222         // usually won't get fragged at spawn twice in a row)
 223         if (arena_roundbased)
 224         {
 225                 firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, 800, teamcheck);
 226                 if(firstspot_new)
 227                         firstspot = firstspot_new;
 228                 spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 229         }
 230         else if (random() > cvar("g_spawn_furthest"))
 231                 spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 232         else
 233                 spot = Spawn_WeightedPoint(firstspot, 1, 5000, 5); // chooses a far far away spawnpoint
 234
 235         if(cvar("spawn_debugview"))
 236         {
 237                 print("spot mindistance: ", ftos(spot.SPAWNPOINT_SCORE), "\n");
 238
 239                 entity e;
 240                 if(teamcheck)
 241                         for(e = firstspot; e; e = e.chain)
 242                                 if(e.team != teamcheck)
 243                                         error("invalid spawn found");
 244         }
 245
 246         if (!spot)
 247         {
 248                 if(cvar("spawn_debug"))
 249                         GotoNextMap();
 250                 else
 251                 {
 252                         if(some_spawn_has_been_used)
 253                                 return world; // team can't spawn any more, because of actions of other team
 254                         else
 255                                 error("Cannot find a spawn point - please fix the map!");
 256                 }
 257         }
 258
 259         return spot;
 260 }
 261
 262 /*
 263 =============
 264 CheckPlayerModel
 265
 266 Checks if the argument string can be a valid playermodel.
 267 Returns a valid one in doubt.
 268 =============
 269 */
 270 string FallbackPlayerModel = "models/player/marine.zym";
 271 string CheckPlayerModel(string plyermodel) {
 272         if(strlen(plyermodel) < 4)
 273                 return FallbackPlayerModel;
 274         if( substring(plyermodel,0,14) != "models/player/")
 275                 return FallbackPlayerModel;
 276         else if(cvar("sv_servermodelsonly"))
 277         {
 278                 if(substring(plyermodel,strlen(plyermodel)-4,4) != ".zym")
 279                 if(substring(plyermodel,strlen(plyermodel)-4,4) != ".dpm")
 280                 if(substring(plyermodel,strlen(plyermodel)-4,4) != ".md3")
 281                 if(substring(plyermodel,strlen(plyermodel)-4,4) != ".psk")
 282                         return FallbackPlayerModel;
 283                 if(plyermodel != strtolower(plyermodel))
 284                         return FallbackPlayerModel;
 285                 if(!fexists(plyermodel))
 286                         return FallbackPlayerModel;
 287         }
 288         return plyermodel;
 289 }
 290
 291 /*
 292 =============
 293 Client_customizeentityforclient
 294
 295 LOD reduction
 296 =============
 297 */
 298 float Client_customizeentityforclient()
 299 {
 300 #ifdef ALLOW_VARIABLE_LOD
 301         // self: me
 302         // other: the player viewing me
 303         float distance;
 304         float f;
 305
 306         if(self.flags & FL_NOTARGET) // we don't need LOD for spectators
 307                 return TRUE;
 308
 309         if(other.cvar_cl_playerdetailreduction <= 0)
 310         {
 311                 if(other.cvar_cl_playerdetailreduction <= -2)
 312                         self.modelindex = self.modelindex_lod2;
 313                 else if(other.cvar_cl_playerdetailreduction <= -1)
 314                         self.modelindex = self.modelindex_lod1;
 315                 else
 316                         self.modelindex = self.modelindex_lod0;
 317         }
 318         else
 319         {
 320                 distance = vlen(self.origin - other.origin);
 321                 f = (distance + 100.0) * other.cvar_cl_playerdetailreduction;
 322                 if(f > 10000)
 323                         self.modelindex = self.modelindex_lod2;
 324                 else if(f > 5000)
 325                         self.modelindex = self.modelindex_lod1;
 326                 else
 327                         self.modelindex = self.modelindex_lod0;
 328         }
 329 #endif
 330
 331         return TRUE;
 332 }
 333
 334 void UpdatePlayerSounds();
 335 void setmodel_lod(entity e, string modelname)
 336 {
 337 #ifdef ALLOW_VARIABLE_LOD
 338         string s;
 339
 340         // FIXME: this only supports 3-letter extensions
 341         s = strcat(substring(modelname, 0, strlen(modelname) - 4), "_1", substring(modelname, 0, strlen(modelname) - 4));
 342         if(fexists(s))
 343         {
 344                 precache_model(s);
 345                 setmodel(e, s); // players have high precision
 346                 self.modelindex_lod1 = self.modelindex;
 347         }
 348         else
 349                 self.modelindex_lod1 = -1;
 350
 351         s = strcat(substring(modelname, 0, strlen(modelname) - 4), "_2", substring(modelname, 0, strlen(modelname) - 4));
 352         if(fexists(s))
 353         {
 354                 precache_model(s);
 355                 setmodel(e, s); // players have high precision
 356                 self.modelindex_lod2 = self.modelindex;
 357         }
 358         else
 359                 self.modelindex_lod2 = -1;
 360
 361         precache_model(modelname);
 362         setmodel(e, modelname); // players have high precision
 363         self.modelindex_lod0 = self.modelindex;
 364
 365         if(self.modelindex_lod1 < 0)
 366                 self.modelindex_lod1 = self.modelindex;
 367
 368         if(self.modelindex_lod2 < 0)
 369                 self.modelindex_lod2 = self.modelindex;
 370 #else
 371         precache_model(modelname);
 372         setmodel(e, modelname); // players have high precision
 373 #endif
 374         player_setupanimsformodel();
 375         UpdatePlayerSounds();
 376 }
 377
 378 /*
 379 =============
 380 PutObserverInServer
 381
 382 putting a client as observer in the server
 383 =============
 384 */
 385 void PutObserverInServer (void)
 386 {
 387         entity  spot;
 388
 389         race_PreSpawnObserver();
 390
 391         spot = SelectSpawnPoint (TRUE);
 392         if(!spot)
 393                 error("No spawnpoints for observers?!?\n");
 394         RemoveGrapplingHook(self); // Wazat's Grappling Hook
 395
 396         if(clienttype(self) == CLIENTTYPE_REAL)
 397         {
 398                 msg_entity = self;
 399                 WriteByte(MSG_ONE, SVC_SETVIEW);
 400                 WriteEntity(MSG_ONE, self);
 401         }
 402
 403         DropAllRunes(self);
 404         kh_Key_DropAll(self, TRUE);
 405
 406         Portal_ClearAll(self);
 407
 408         if(self.flagcarried)
 409                 DropFlag(self.flagcarried);
 410
 411         WaypointSprite_PlayerDead();
 412
 413         if(self.killcount != -666)
 414         {
 415                 if(g_lms)
 416                 {
 417                         if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
 418                                 bprint ("^4", self.netname, "^4 has no more lives left\n");
 419                         else
 420                                 bprint ("^4", self.netname, "^4 is spectating now\n"); // TODO turn this into a proper forfeit?
 421                 }
 422                 else
 423                         bprint ("^4", self.netname, "^4 is spectating now\n");
 424         }
 425
 426         PlayerScore_Clear(self); // clear scores when needed
 427
 428         self.spectatortime = time;
 429
 430         self.classname = "observer";
 431         self.health = -666;
 432         self.takedamage = DAMAGE_NO;
 433         self.solid = SOLID_NOT;
 434         self.movetype = MOVETYPE_NOCLIP;
 435         self.flags = FL_CLIENT | FL_NOTARGET;
 436         self.armorvalue = 666;
 437         self.effects = 0;
 438         self.armorvalue = cvar("g_balance_armor_start");
 439         self.pauserotarmor_finished = 0;
 440         self.pauserothealth_finished = 0;
 441         self.pauseregen_finished = 0;
 442         self.damageforcescale = 0;
 443         self.death_time = 0;
 444         self.dead_frame = 0;
 445         self.alpha = 0;
 446         self.scale = 0;
 447         self.fade_time = 0;
 448         self.pain_frame = 0;
 449         self.pain_finished = 0;
 450         self.strength_finished = 0;
 451         self.invincible_finished = 0;
 452         self.pushltime = 0;
 453         self.think = SUB_Null;
 454         self.nextthink = 0;
 455         self.hook_time = 0;
 456         self.runes = 0;
 457         self.deadflag = DEAD_NO;
 458         self.angles = spot.angles;
 459         self.angles_z = 0;
 460         self.fixangle = TRUE;
 461         self.crouch = FALSE;
 462
 463         self.view_ofs = PL_VIEW_OFS;
 464         setorigin (self, spot.origin);
 465         setsize (self, '0 0 0', '0 0 0');
 466         self.oldorigin = self.origin;
 467         self.items = 0;
 468         self.weapons = 0;
 469         self.model = "";
 470         self.modelindex = 0;
 471         self.weapon = 0;
 472         self.weaponmodel = "";
 473         self.weaponentity = world;
 474         self.killcount = -666;
 475         self.velocity = '0 0 0';
 476         self.avelocity = '0 0 0';
 477         self.punchangle = '0 0 0';
 478         self.punchvector = '0 0 0';
 479         self.oldvelocity = self.velocity;
 480         self.customizeentityforclient = Client_customizeentityforclient;
 481         self.wantswelcomemessage = 1;
 482
 483         if(g_arena)
 484         {
 485                 if(self.version_mismatch)
 486                 {
 487                         Spawnqueue_Unmark(self);
 488                         Spawnqueue_Remove(self);
 489                 }
 490                 else
 491                 {
 492                         Spawnqueue_Insert(self);
 493                 }
 494         }
 495         else if(g_lms)
 496         {
 497                 // Only if the player cannot play at all
 498                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) == 666)
 499                         self.frags = -666;
 500                 else
 501                         self.frags = -667;
 502         }
 503         else
 504                 self.frags = -666;
 505 }
 506
 507 float RestrictSkin(float s)
 508 {
 509         if(!teams_matter)
 510                 return s;
 511         if(s == 6)
 512                 return 6;
 513         return mod(s, 3);
 514 }
 515
 516 void FixPlayermodel()
 517 {
 518         local string defaultmodel;
 519         local float defaultskin;
 520         local vector m1, m2;
 521
 522         defaultmodel = "";
 523
 524         if(cvar("sv_defaultcharacter") == 1) {
 525                 defaultskin = 0;
 526
 527                 if(teams_matter)
 528                 {
 529                         defaultmodel = cvar_string(strcat("sv_defaultplayermodel_", Team_ColorNameLowerCase(self.team)));
 530                         defaultskin = cvar(strcat("sv_defaultplayerskin_", Team_ColorNameLowerCase(self.team)));
 531                 }
 532
 533                 if(defaultmodel == "")
 534                 {
 535                         defaultmodel = cvar_string("sv_defaultplayermodel");
 536                         defaultskin = cvar("sv_defaultplayerskin");
 537                 }
 538         }
 539
 540         if(defaultmodel != "")
 541         {
 542                 if (defaultmodel != self.model)
 543                 {
 544                         m1 = self.mins;
 545                         m2 = self.maxs;
 546                         setmodel_lod (self, defaultmodel);
 547                         setsize (self, m1, m2);
 548                 }
 549
 550                 self.skin = defaultskin;
 551         } else {
 552                 if (self.playermodel != self.model)
 553                 {
 554                         self.playermodel = CheckPlayerModel(self.playermodel);
 555                         m1 = self.mins;
 556                         m2 = self.maxs;
 557                         setmodel_lod (self, self.playermodel);
 558                         setsize (self, m1, m2);
 559                 }
 560
 561                 self.skin = RestrictSkin(stof(self.playerskin));
 562         }
 563
 564         if(!teams_matter)
 565                 if(strlen(cvar_string("sv_defaultplayercolors")))
 566                         if(self.clientcolors != cvar("sv_defaultplayercolors"))
 567                                 setcolor(self, cvar("sv_defaultplayercolors"));
 568 }
 569
 570 /*
 571 =============
 572 PutClientInServer
 573
 574 Called when a client spawns in the server
 575 =============
 576 */
 577 //void() ctf_playerchanged;
 578 void PutClientInServer (void)
 579 {
 580         if(clienttype(self) == CLIENTTYPE_BOT)
 581         {
 582                 self.classname = "player";
 583         }
 584         else if(clienttype(self) == CLIENTTYPE_REAL)
 585         {
 586                 msg_entity = self;
 587                 WriteByte(MSG_ONE, SVC_SETVIEW);
 588                 WriteEntity(MSG_ONE, self);
 589         }
 590
 591         // player is dead and becomes observer
 592         // FIXME fix LMS scoring for new system
 593         if(g_lms)
 594         {
 595                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
 596                         self.classname = "observer";
 597         }
 598
 599         if(g_arena)
 600         if(!self.spawned)
 601                 self.classname = "observer";
 602
 603         if(self.classname == "player") {
 604                 entity  spot;
 605
 606                 race_PreSpawn();
 607
 608                 spot = SelectSpawnPoint (FALSE);
 609                 if(!spot)
 610                 {
 611                         centerprint(self, "Sorry, no spawnpoints available!\nHope your team can fix it...");
 612                         return; // spawn failed
 613                 }
 614
 615                 RemoveGrapplingHook(self); // Wazat's Grappling Hook
 616
 617                 self.classname = "player";
 618                 self.iscreature = TRUE;
 619                 self.movetype = MOVETYPE_WALK;
 620                 self.solid = SOLID_SLIDEBOX;
 621                 if(independent_players)
 622                         MAKE_INDEPENDENT_PLAYER(self);
 623                 self.flags = FL_CLIENT;
 624                 self.takedamage = DAMAGE_AIM;
 625                 if(g_minstagib)
 626                         self.effects = EF_FULLBRIGHT;
 627                 else
 628                         self.effects = 0;
 629                 self.air_finished = time + 12;
 630                 self.dmg = 2;
 631
 632                 if(inWarmupStage)
 633                 {
 634                         self.ammo_shells = warmup_start_ammo_shells;
 635                         self.ammo_nails = warmup_start_ammo_nails;
 636                         self.ammo_rockets = warmup_start_ammo_rockets;
 637                         self.ammo_cells = warmup_start_ammo_cells;
 638                         self.health = warmup_start_health;
 639                         self.armorvalue = warmup_start_armorvalue;
 640                         self.weapons = warmup_start_weapons;
 641                 }
 642                 else
 643                 {
 644                         self.ammo_shells = start_ammo_shells;
 645                         self.ammo_nails = start_ammo_nails;
 646                         self.ammo_rockets = start_ammo_rockets;
 647                         self.ammo_cells = start_ammo_cells;
 648                         self.health = start_health;
 649                         self.armorvalue = start_armorvalue;
 650                         self.weapons = start_weapons;
 651                 }
 652                 self.items = start_items;
 653                 self.switchweapon = w_getbestweapon(self);
 654                 self.cnt = self.switchweapon;
 655                 self.weapon = 0;
 656                 self.jump_interval = time;
 657
 658                 self.spawnshieldtime = time + cvar("g_spawnshieldtime");
 659                 self.pauserotarmor_finished = time + cvar("g_balance_pause_armor_rot_spawn");
 660                 self.pauserothealth_finished = time + cvar("g_balance_pause_health_rot_spawn");
 661                 self.pauseregen_finished = time + cvar("g_balance_pause_health_regen_spawn");
 662                 //extend the pause of rotting if client was reset at the beginning of the countdown
 663                 if(!cvar("sv_ready_restart_after_countdown") && time < restart_countdown) {
 664                         self.spawnshieldtime += RESTART_COUNTDOWN;
 665                         self.pauserotarmor_finished += RESTART_COUNTDOWN;
 666                         self.pauserothealth_finished += RESTART_COUNTDOWN;
 667                         self.pauseregen_finished += RESTART_COUNTDOWN;
 668                 }
 669                 self.damageforcescale = 2;
 670                 self.death_time = 0;
 671                 self.dead_frame = 0;
 672                 self.alpha = 0;
 673                 self.scale = 0;
 674                 self.fade_time = 0;
 675                 self.pain_frame = 0;
 676                 self.pain_finished = 0;
 677                 self.strength_finished = 0;
 678                 self.invincible_finished = 0;
 679                 self.pushltime = 0;
 680                 //self.speed_finished = 0;
 681                 //self.slowmo_finished = 0;
 682                 // players have no think function
 683                 self.think = SUB_Null;
 684                 self.nextthink = 0;
 685                 self.hook_time = 0;
 686
 687                 self.runes = 0;
 688
 689                 self.deadflag = DEAD_NO;
 690
 691                 self.angles = spot.angles;
 692
 693                 self.angles_z = 0; // never spawn tilted even if the spot says to
 694                 self.fixangle = TRUE; // turn this way immediately
 695                 self.velocity = '0 0 0';
 696                 self.avelocity = '0 0 0';
 697                 self.punchangle = '0 0 0';
 698                 self.punchvector = '0 0 0';
 699                 self.oldvelocity = self.velocity;
 700
 701                 msg_entity = self;
 702                 WRITESPECTATABLE_MSG_ONE({
 703                         WriteByte(MSG_ONE, SVC_TEMPENTITY);
 704                         WriteByte(MSG_ONE, TE_CSQC_SPAWN);
 705                 });
 706
 707                 self.customizeentityforclient = Client_customizeentityforclient;
 708
 709                 self.model = "";
 710                 FixPlayermodel();
 711
 712                 self.crouch = FALSE;
 713                 self.view_ofs = PL_VIEW_OFS;
 714                 setsize (self, PL_MIN, PL_MAX);
 715                 self.spawnorigin = spot.origin;
 716                 setorigin (self, spot.origin + '0 0 1' * (1 - self.mins_z - 24));
 717                 // don't reset back to last position, even if new position is stuck in solid
 718                 self.oldorigin = self.origin;
 719
 720                 if(g_arena)
 721                 {
 722                         Spawnqueue_Remove(self);
 723                         Spawnqueue_Mark(self);
 724                 }
 725
 726                 self.event_damage = PlayerDamage;
 727
 728                 self.bot_attack = TRUE;
 729
 730                 self.statdraintime = time + 5;
 731                 self.BUTTON_ATCK = self.BUTTON_JUMP = self.BUTTON_ATCK2 = 0;
 732
 733                 if(self.killcount == -666) {
 734                         PlayerScore_Clear(self);
 735                         self.killcount = 0;
 736                         self.frags = 0;
 737                 }
 738
 739                 self.cnt = WEP_LASER;
 740                 self.nixnex_lastchange_id = -1;
 741
 742                 CL_SpawnWeaponentity();
 743                 self.alpha = default_player_alpha;
 744                 self.colormod = '1 1 1' * cvar("g_player_brightness");
 745                 self.exteriorweaponentity.alpha = default_weapon_alpha;
 746
 747                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval")*2;
 748                 self.lms_traveled_distance = 0;
 749                 self.speedrunning = FALSE;
 750
 751                 race_PostSpawn(spot);
 752
 753                 if(cvar("spawn_debug"))
 754                 {
 755                         sprint(self, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 756                         remove(spot);   // usefull for checking if there are spawnpoints, that let drop through the floor
 757                 }
 758
 759                 //stuffcmd(self, "chase_active 0");
 760                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
 761
 762                 if (cvar("g_spawnsound"))
 763                         sound (self, CHAN_TRIGGER, "misc/spawn.wav", VOL_BASE, ATTN_NORM);
 764
 765                 if(g_assault) {
 766                         if(self.team == assault_attacker_team)
 767                                 centerprint(self, "You are attacking!\n");
 768                         else
 769                                 centerprint(self, "You are defending!\n");
 770                 }
 771
 772         } else if(self.classname == "observer") {
 773                 PutObserverInServer ();
 774         }
 775
 776         //if(g_ctf)
 777         //      ctf_playerchanged();
 778 }
 779
 780 /*
 781 =============
 782 SendCSQCInfo
 783
 784 Send whatever CSQC needs NOW and cannot wait for SendServerInfo to happen...
 785 =============
 786 */
 787 void SendCSQCInfo(void)
 788 {
 789         float i;
 790         if(clienttype(self) != CLIENTTYPE_REAL)
 791                 return;
 792         msg_entity = self;
 793         WriteByte(MSG_ONE, SVC_TEMPENTITY);
 794         WriteByte(MSG_ONE, TE_CSQC_INIT);
 795         WriteShort(MSG_ONE, CSQC_REVISION);
 796         WriteByte(MSG_ONE, maxclients);
 797         for(i = 1; i <= 24; ++i)
 798                 WriteByte(MSG_ONE, (get_weaponinfo(i)).impulse + 1);
 799 }
 800
 801 /*
 802 =============
 803 SetNewParms
 804 =============
 805 */
 806 void SetNewParms (void)
 807 {
 808         // initialize parms for a new player
 809         parm1 = -(86400 * 366);
 810 }
 811
 812 /*
 813 =============
 814 SetChangeParms
 815 =============
 816 */
 817 void SetChangeParms (void)
 818 {
 819         // save parms for level change
 820         parm1 = self.parm_idlesince - time;
 821 }
 822
 823 /*
 824 =============
 825 DecodeLevelParms
 826 =============
 827 */
 828 void DecodeLevelParms (void)
 829 {
 830         // load parms
 831         self.parm_idlesince = parm1;
 832         if(self.parm_idlesince == -(86400 * 366))
 833                 self.parm_idlesince = time;
 834 }
 835
 836 /*
 837 =============
 838 ClientKill
 839
 840 Called when a client types 'kill' in the console
 841 =============
 842 */
 843
 844 void ClientKill_Now_TeamChange()
 845 {
 846         if(self.killindicator_teamchange == -1)
 847         {
 848                 self.team = -1;
 849                 JoinBestTeam( self, FALSE, FALSE );
 850         }
 851         else
 852         {
 853                 SV_ChangeTeam(self.killindicator_teamchange - 1);
 854         }
 855 }
 856
 857 void ClientKill_Now()
 858 {
 859         if(self.killindicator_teamchange)
 860                 ClientKill_Now_TeamChange();
 861
 862         // in any case:
 863         Damage(self, self, self, 100000, DEATH_KILL, self.origin, '0 0 0');
 864
 865         if(self.killindicator)
 866         {
 867                 dprint("Cleaned up after a leaked kill indicator.\n");
 868                 remove(self.killindicator);
 869                 self.killindicator = world;
 870         }
 871 }
 872 void KillIndicator_Think()
 873 {
 874         if (!self.owner.modelindex)
 875         {
 876                 self.owner.killindicator = world;
 877                 remove(self);
 878                 return;
 879         }
 880
 881         if(self.cnt <= 0)
 882         {
 883                 self = self.owner;
 884                 ClientKill_Now(); // no oldself needed
 885                 return;
 886         }
 887         else
 888         {
 889                 if(self.cnt <= 10)
 890                         setmodel(self, strcat("models/sprites/", ftos(self.cnt), ".spr32"));
 891                 if(clienttype(self.owner) == CLIENTTYPE_REAL)
 892                 {
 893                         if(self.cnt <= 10)
 894                                 announce(self.owner, strcat("announcer/robotic/", ftos(self.cnt), ".ogg"));
 895                         if(self.owner.killindicator_teamchange)
 896                         {
 897                                 if(self.owner.killindicator_teamchange == -1)
 898                                         centerprint(self.owner, strcat("Changing team in ", ftos(self.cnt), " seconds"));
 899                                 else
 900                                         centerprint(self.owner, strcat("Changing to ", ColoredTeamName(self.owner.killindicator_teamchange), " in ", ftos(self.cnt), " seconds"));
 901                         }
 902                         else
 903                                 centerprint(self.owner, strcat("^1Suicide in ", ftos(self.cnt), " seconds"));
 904                 }
 905                 self.nextthink = time + 1;
 906                 self.cnt -= 1;
 907         }
 908 }
 909
 910 void ClientKill_TeamChange (float targetteam) // 0 = don't change, -1 = auto
 911 {
 912         float killtime;
 913         entity e;
 914         killtime = cvar("g_balance_kill_delay");
 915
 916         self.killindicator_teamchange = targetteam;
 917
 918         if(!self.killindicator)
 919         {
 920                 if(killtime <= 0 || !self.modelindex || self.deadflag != DEAD_NO)
 921                 {
 922                         ClientKill_Now();
 923                 }
 924                 else
 925                 {
 926                         self.killindicator = spawn();
 927                         self.killindicator.owner = self;
 928                         self.killindicator.scale = 0.5;
 929                         setattachment(self.killindicator, self, "");
 930                         setorigin(self.killindicator, '0 0 52');
 931                         self.killindicator.think = KillIndicator_Think;
 932                         self.killindicator.nextthink = time + (self.lip) * 0.05;
 933                         self.killindicator.cnt = ceil(killtime);
 934                         self.killindicator.count = bound(0, ceil(killtime), 10);
 935                         sprint(self, strcat("^1You'll be dead in ", ftos(self.killindicator.cnt), " seconds\n"));
 936
 937                         for(e = world; (e = find(e, classname, "body")) != world; )
 938                         {
 939                                 if(e.enemy != self)
 940                                         continue;
 941                                 e.killindicator = spawn();
 942                                 e.killindicator.owner = e;
 943                                 e.killindicator.scale = 0.5;
 944                                 setattachment(e.killindicator, e, "");
 945                                 setorigin(e.killindicator, '0 0 52');
 946                                 e.killindicator.think = KillIndicator_Think;
 947                                 e.killindicator.nextthink = time + (e.lip) * 0.05;
 948                                 e.killindicator.cnt = ceil(killtime);
 949                         }
 950                         self.lip = 0;
 951                 }
 952         }
 953         if(self.killindicator)
 954         {
 955                 if(targetteam)
 956                         self.killindicator.colormod = TeamColor(targetteam);
 957                 else
 958                         self.killindicator.colormod = '0 0 0';
 959         }
 960 }
 961
 962 void ClientKill (void)
 963 {
 964         ClientKill_TeamChange(0);
 965 }
 966
 967 void DoTeamChange(float destteam)
 968 {
 969         float t, c0;
 970         if(!cvar("teamplay"))
 971         {
 972                 if(destteam >= 0)
 973                         SetPlayerColors(self, destteam);
 974                 return;
 975         }
 976         if(self.classname == "player")
 977         if(destteam == -1)
 978         {
 979                 CheckAllowedTeams(self);
 980                 t = FindSmallestTeam(self, TRUE);
 981                 switch(self.team)
 982                 {
 983                         case COLOR_TEAM1: c0 = c1; break;
 984                         case COLOR_TEAM2: c0 = c2; break;
 985                         case COLOR_TEAM3: c0 = c3; break;
 986                         case COLOR_TEAM4: c0 = c4; break;
 987                         default:          c0 = 999;
 988                 }
 989                 switch(t)
 990                 {
 991                         case 1:
 992                                 if(c0 > c1)
 993                                         destteam = COLOR_TEAM1;
 994                                 break;
 995                         case 2:
 996                                 if(c0 > c2)
 997                                         destteam = COLOR_TEAM2;
 998                                 break;
 999                         case 3:
1000                                 if(c0 > c3)
1001                                         destteam = COLOR_TEAM3;
1002                                 break;
1003                         case 4:
1004                                 if(c0 > c4)
1005                                         destteam = COLOR_TEAM4;
1006                                 break;
1007                 }
1008                 if(destteam == -1)
1009                         return;
1010         }
1011         if(destteam == self.team && !self.killindicator)
1012                 return;
1013         ClientKill_TeamChange(destteam);
1014 }
1015
1016 void FixClientCvars(entity e)
1017 {
1018         // send prediction settings to the client
1019         stuffcmd(e, "\nin_bindmap 0 0\n");
1020         /*
1021          * we no longer need to stuff this. Remove this comment block if you feel
1022          * 2.3 and higher (or was it 2.2.3?) don't need these any more
1023         stuffcmd(e, strcat("cl_gravity ", ftos(cvar("sv_gravity")), "\n"));
1024         stuffcmd(e, strcat("cl_movement_accelerate ", ftos(cvar("sv_accelerate")), "\n"));
1025         stuffcmd(e, strcat("cl_movement_friction ", ftos(cvar("sv_friction")), "\n"));
1026         stuffcmd(e, strcat("cl_movement_maxspeed ", ftos(cvar("sv_maxspeed")), "\n"));
1027         stuffcmd(e, strcat("cl_movement_airaccelerate ", ftos(cvar("sv_airaccelerate")), "\n"));
1028         stuffcmd(e, strcat("cl_movement_maxairspeed ", ftos(cvar("sv_maxairspeed")), "\n"));
1029         stuffcmd(e, strcat("cl_movement_stopspeed ", ftos(cvar("sv_stopspeed")), "\n"));
1030         stuffcmd(e, strcat("cl_movement_jumpvelocity ", ftos(cvar("sv_jumpvelocity")), "\n"));
1031         stuffcmd(e, strcat("cl_movement_stepheight ", ftos(cvar("sv_stepheight")), "\n"));
1032         stuffcmd(e, strcat("set cl_movement_friction_on_land ", ftos(cvar("sv_friction_on_land")), "\n"));
1033         stuffcmd(e, strcat("set cl_movement_airaccel_qw ", ftos(cvar("sv_airaccel_qw")), "\n"));
1034         stuffcmd(e, strcat("set cl_movement_airaccel_sideways_friction ", ftos(cvar("sv_airaccel_sideways_friction")), "\n"));
1035         stuffcmd(e, "cl_movement_edgefriction 1\n");
1036          */
1037 }
1038
1039 /*
1040 =============
1041 ClientConnect
1042
1043 Called when a client connects to the server
1044 =============
1045 */
1046 //void ctf_clientconnect();
1047 string ColoredTeamName(float t);
1048 void DecodeLevelParms (void);
1049 //void dom_player_join_team(entity pl);
1050 void ClientConnect (void)
1051 {
1052         local string s;
1053
1054         if(self.flags & FL_CLIENT)
1055         {
1056                 print("Warning: ClientConnect, but already connected!\n");
1057                 return;
1058         }
1059
1060         if(Ban_IsClientBanned(self))
1061         {
1062                 s = strcat("^1NOTE:^7 banned client ", self.netaddress, " just tried to enter\n");
1063                 dropclient(self);
1064                 bprint(s);
1065                 return;
1066         }
1067
1068         DecodeLevelParms();
1069
1070         self.classname = "player_joining";
1071
1072         self.flags = self.flags | FL_CLIENT;
1073         self.version_nagtime = time + 10 + random() * 10;
1074
1075         if(player_count<0)
1076         {
1077                 dprint("BUG player count is lower than zero, this cannot happen!\n");
1078                 player_count = 0;
1079         }
1080
1081         PlayerScore_Attach(self);
1082
1083         bot_clientconnect();
1084
1085         race_PreSpawnObserver();
1086
1087         //if(g_domination)
1088         //      dom_player_join_team(self);
1089
1090         //JoinBestTeam(self, FALSE, FALSE);
1091         //
1092         if((cvar("sv_spectate") == 1 && !g_lms) || cvar("g_campaign")) {
1093                 self.classname = "observer";
1094         } else {
1095                 self.classname = "player";
1096                 campaign_bots_may_start = 1;
1097         }
1098
1099         self.playerid = (playerid_last = playerid_last + 1);
1100         if(cvar("sv_eventlog"))
1101         {
1102                 if(clienttype(self) == CLIENTTYPE_REAL)
1103                         GameLogEcho(strcat(":join:", ftos(self.playerid), ":", ftos(num_for_edict(self)), ":", self.netaddress, ":", self.netname));
1104                 else
1105                         GameLogEcho(strcat(":join:", ftos(self.playerid), ":", ftos(num_for_edict(self)), ":bot:", self.netname));
1106                 s = strcat(":team:", ftos(self.playerid), ":");
1107                 s = strcat(s, ftos(self.team));
1108                 GameLogEcho(s);
1109         }
1110         self.netname_previous = strzone(self.netname);
1111
1112         //stuffcmd(self, "set tmpviewsize $viewsize \n");
1113
1114         bprint ("^4",self.netname);
1115         bprint ("^4 connected");
1116
1117         if(g_domination || g_ctf)
1118         {
1119                 bprint(" and joined the ");
1120                 bprint(ColoredTeamName(self.team));
1121         }
1122
1123         bprint("\n");
1124
1125         self.welcomemessage_time = 0;
1126
1127         stuffcmd(self, strcat(clientstuff, "\n"));
1128         stuffcmd(self, strcat("exec maps/", mapname, ".cfg\n"));
1129         stuffcmd(self, "cl_particles_reloadeffects\n");
1130
1131         FixClientCvars(self);
1132
1133         // spawnfunc_waypoint sprites
1134         WaypointSprite_InitClient(self);
1135
1136         // Wazat's grappling hook
1137         SetGrappleHookBindings();
1138
1139         // get autoswitch state from player when he toggles it
1140         stuffcmd(self, "alias autoswitch \"set cl_autoswitch $1 ; cmd autoswitch $1\"\n"); // default.cfg-ed in 2.4.1
1141
1142         // get version info from player
1143         stuffcmd(self, "cmd clientversion $gameversion\n");
1144
1145         // get other cvars from player
1146         GetCvars(0);
1147
1148         // set cvar for team scoreboard
1149         if (teams_matter)
1150         {
1151                 local float t;
1152                 t = cvar("teamplay");
1153                 // we have to stuff the correct teamplay value because if this is a listen server, this changes the teamplay mode of the server itself, which is bad
1154                 stuffcmd(self, strcat("set teamplay ", ftos(t), "\n"));
1155         }
1156         else
1157                 stuffcmd(self, "set teamplay 0\n");
1158
1159         // notify about available teams
1160         if(teamplay)
1161         {
1162                 CheckAllowedTeams(self);
1163                 t = 0; if(c1 >= 0) t |= 1; if(c2 >= 0) t |= 2; if(c3 >= 0) t |= 4; if(c4 >= 0) t |= 8;
1164                 stuffcmd(self, strcat("set _teams_available ", ftos(t), "\n"));
1165         }
1166         else
1167                 stuffcmd(self, "set _teams_available 0\n");
1168
1169         stuffcmd(self, strcat("set gametype ", ftos(game), "\n"));
1170
1171         if(g_arena)
1172         {
1173                 self.classname = "observer";
1174                 Spawnqueue_Insert(self);
1175         }
1176         /*else if(g_ctf)
1177         {
1178                 ctf_clientconnect();
1179         }*/
1180
1181         if(entcs_start)
1182                 attach_entcs();
1183
1184         bot_relinkplayerlist();
1185
1186         self.spectatortime = time;
1187         if(blockSpectators)
1188         {
1189                 sprint(self, strcat("^7You have to become a player within the next ", ftos(cvar("g_maxplayers_spectator_blocktime")), " seconds, otherwise you will be kicked, because spectators aren't allowed at this time!\n"));
1190         }
1191
1192         self.jointime = time;
1193         self.allowedTimeouts = cvar("sv_timeout_number");
1194
1195         if(clienttype(self) == CLIENTTYPE_REAL)
1196         {
1197                 sprint(self, strcat("nexuiz-csqc protocol ", ftos(CSQC_REVISION), "\n"));
1198                 SendCSQCInfo();
1199                 msg_entity = self;
1200                 if(mapvote_initialized && !cvar("g_maplist_textonly"))
1201                 {
1202                         MapVote_SendData(MSG_ONE);
1203                         MapVote_UpdateData(MSG_ONE);
1204                 }
1205                 ScoreInfo_Write(MSG_ONE);
1206         }
1207
1208         if(inWarmupStage)
1209         {
1210                 msg_entity = self;
1211                 WriteByte(MSG_ONE, SVC_TEMPENTITY);
1212                 WriteByte(MSG_ONE, TE_CSQC_WARMUP);
1213                 WriteByte(MSG_ONE, 1);
1214         }
1215
1216         if(g_lms)
1217         {
1218                 if(PlayerScore_Add(self, SP_LMS_LIVES, LMS_NewPlayerLives()) <= 0)
1219                 {
1220                         PlayerScore_Add(self, SP_LMS_RANK, 666);
1221                         self.frags = -666; // FIXME do we still need this?
1222                 }
1223         }
1224 }
1225
1226 /*
1227 =============
1228 ClientDisconnect
1229
1230 Called when a client disconnects from the server
1231 =============
1232 */
1233 void(entity e) DropFlag;
1234 .entity chatbubbleentity;
1235 .entity teambubbleentity;
1236 void ReadyCount();
1237 //void() ctf_clientdisconnect;
1238 void ClientDisconnect (void)
1239 {
1240         float save;
1241
1242         if not(self.flags & FL_CLIENT)
1243         {
1244                 print("Warning: ClientDisconnect without ClientConnect\n");
1245                 return;
1246         }
1247
1248         bot_clientdisconnect();
1249
1250         if(entcs_start)
1251                 detach_entcs();
1252
1253         if(cvar("sv_eventlog"))
1254                 GameLogEcho(strcat(":part:", ftos(self.playerid)));
1255         bprint ("^4",self.netname);
1256         bprint ("^4 disconnected\n");
1257
1258         if (self.chatbubbleentity)
1259         {
1260                 remove (self.chatbubbleentity);
1261                 self.chatbubbleentity = world;
1262         }
1263
1264         if (self.teambubbleentity)
1265         {
1266                 remove (self.teambubbleentity);
1267                 self.teambubbleentity = world;
1268         }
1269
1270         if (self.killindicator)
1271         {
1272                 remove (self.killindicator);
1273                 self.killindicator = world;
1274         }
1275
1276         WaypointSprite_PlayerGone();
1277
1278         DropAllRunes(self);
1279         kh_Key_DropAll(self, TRUE);
1280
1281         Portal_ClearAll(self);
1282
1283         if(self.flagcarried)
1284                 DropFlag(self.flagcarried);
1285
1286         save = self.flags;
1287         self.flags = self.flags - (self.flags & FL_CLIENT);
1288         bot_relinkplayerlist();
1289         self.flags = save;
1290
1291         // remove laserdot
1292         if(self.weaponentity)
1293                 if(self.weaponentity.lasertarget)
1294                         remove(self.weaponentity.lasertarget);
1295
1296         if(g_arena)
1297         {
1298                 Spawnqueue_Unmark(self);
1299                 Spawnqueue_Remove(self);
1300         }
1301         /*if(g_ctf)
1302         {
1303                 ctf_clientdisconnect();
1304         }
1305         */
1306
1307         PlayerScore_Detach(self);
1308
1309         if(self.netname_previous)
1310                 strunzone(self.netname_previous);
1311
1312         ClearPlayerSounds();
1313
1314         // free cvars
1315         GetCvars(-1);
1316         self.playerid = 0;
1317
1318         ReadyCount();
1319 }
1320
1321 .float BUTTON_CHAT;
1322 void ChatBubbleThink()
1323 {
1324         self.nextthink = time;
1325         if (!self.owner.modelindex || self.owner.chatbubbleentity != self)
1326         {
1327                 self.owner.chatbubbleentity = world;
1328                 remove(self);
1329                 return;
1330         }
1331         setorigin(self, self.owner.origin + '0 0 15' + self.owner.maxs_z * '0 0 1');
1332         if (self.owner.BUTTON_CHAT && !self.owner.deadflag)
1333                 self.model = self.mdl;
1334         else
1335                 self.model = "";
1336 };
1337
1338 void UpdateChatBubble()
1339 {
1340         if (!self.modelindex)
1341                 return;
1342         // spawn a chatbubble entity if needed
1343         if (!self.chatbubbleentity)
1344         {
1345                 self.chatbubbleentity = spawn();
1346                 self.chatbubbleentity.owner = self;
1347                 self.chatbubbleentity.exteriormodeltoclient = self;
1348                 self.chatbubbleentity.think = ChatBubbleThink;
1349                 self.chatbubbleentity.nextthink = time;
1350                 setmodel(self.chatbubbleentity, "models/misc/chatbubble.spr"); // precision set below
1351                 setorigin(self.chatbubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1352                 self.chatbubbleentity.mdl = self.chatbubbleentity.model;
1353                 self.chatbubbleentity.model = "";
1354                 self.chatbubbleentity.effects = EF_LOWPRECISION;
1355         }
1356 }
1357
1358
1359 void TeamBubbleThink()
1360 {
1361         self.nextthink = time;
1362         if (!self.owner.modelindex || self.owner.teambubbleentity != self)
1363         {
1364                 self.owner.teambubbleentity = world;
1365                 remove(self);
1366                 return;
1367         }
1368 //      setorigin(self, self.owner.origin + '0 0 15' + self.owner.maxs_z * '0 0 1');  // bandwidth hog. setattachment does this now
1369         if (self.owner.BUTTON_CHAT || self.owner.deadflag || self.owner.killindicator)
1370                 self.model = "";
1371         else
1372                 self.model = self.mdl;
1373
1374 };
1375
1376 float TeamBubble_customizeentityforclient()
1377 {
1378         return (self.owner != other && self.owner.team == other.team && other.killcount > -666);
1379 }
1380
1381 void UpdateTeamBubble()
1382 {
1383         if (!self.modelindex || !cvar("teamplay"))
1384                 return;
1385         // spawn a teambubble entity if needed
1386         if (!self.teambubbleentity && cvar("teamplay"))
1387         {
1388                 self.teambubbleentity = spawn();
1389                 self.teambubbleentity.owner = self;
1390                 self.teambubbleentity.exteriormodeltoclient = self;
1391                 self.teambubbleentity.think = TeamBubbleThink;
1392                 self.teambubbleentity.nextthink = time;
1393                 setmodel(self.teambubbleentity, "models/misc/teambubble.spr"); // precision set below
1394 //              setorigin(self.teambubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1395                 setorigin(self.teambubbleentity, self.teambubbleentity.origin + '0 0 15' + self.maxs_z * '0 0 1');
1396                 setattachment(self.teambubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1397                 self.teambubbleentity.mdl = self.teambubbleentity.model;
1398                 self.teambubbleentity.model = self.teambubbleentity.mdl;
1399                 self.teambubbleentity.customizeentityforclient = TeamBubble_customizeentityforclient;
1400                 self.teambubbleentity.effects = EF_LOWPRECISION;
1401         }
1402 }
1403
1404 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1405 // added to the model skins
1406 /*void UpdateColorModHack()
1407 {
1408         local float c;
1409         c = self.clientcolors & 15;
1410         // LordHavoc: only bothering to support white, green, red, yellow, blue
1411              if (teamplay == 0) self.colormod = '0 0 0';
1412         else if (c ==  0) self.colormod = '1.00 1.00 1.00';
1413         else if (c ==  3) self.colormod = '0.10 1.73 0.10';
1414         else if (c ==  4) self.colormod = '1.73 0.10 0.10';
1415         else if (c == 12) self.colormod = '1.22 1.22 0.10';
1416         else if (c == 13) self.colormod = '0.10 0.10 1.73';
1417         else self.colormod = '1 1 1';
1418 };*/
1419
1420 void respawn(void)
1421 {
1422         CopyBody(1);
1423         self.effects |= EF_NODRAW; // prevent another CopyBody
1424         PutClientInServer();
1425 }
1426
1427 /**
1428  * When sv_timeout is used this function returs strings like
1429  * "Timeout begins in 2 seconds!\n" or "Timeout ends in 23 seconds!\n".
1430  * Called by centerprint functions
1431  * @param addOneSecond boolean, set to 1 if the welcome-message centerprint asks for the text
1432  */
1433 string getTimeoutText(float addOneSecond) {
1434         if (!cvar("sv_timeout") || !timeoutStatus)
1435                 return "";
1436
1437         local string retStr;
1438         if (timeoutStatus == 1) {
1439                 if (addOneSecond == 1) {
1440                         retStr = strcat("Timeout begins in ", ftos(remainingLeadTime + 1), " seconds!\n");
1441                 }
1442                 else {
1443                         retStr = strcat("Timeout begins in ", ftos(remainingLeadTime), " seconds!\n");
1444                 }
1445                 return retStr;
1446         }
1447         else if (timeoutStatus == 2) {
1448                 if (addOneSecond) {
1449                         retStr = strcat("Timeout ends in ", ftos(remainingTimeoutTime + 1), " seconds!\n");
1450                         //don't show messages like "Timeout ends in 0 seconds"...
1451                         if ((remainingTimeoutTime + 1) > 0)
1452                                 return retStr;
1453                         else
1454                                 return "";
1455                 }
1456                 else {
1457                         retStr = strcat("Timeout ends in ", ftos(remainingTimeoutTime), " seconds!\n");
1458                         //don't show messages like "Timeout ends in 0 seconds"...
1459                         if (remainingTimeoutTime > 0)
1460                                 return retStr;
1461                         else
1462                                 return "";
1463                 }
1464         }
1465         else return "";
1466 }
1467
1468 void player_powerups (void)
1469 {
1470         if (g_minstagib)
1471         {
1472                 if (self.items & IT_STRENGTH)
1473                 {
1474                         if (time > self.strength_finished)
1475                         {
1476                                 if (g_minstagib_invis_alpha > 0)
1477                                 {
1478                                         self.alpha = default_player_alpha;
1479                                         self.exteriorweaponentity.alpha = default_weapon_alpha;
1480                                         self.effects = self.effects | EF_FULLBRIGHT;
1481                                 }
1482                                 else
1483                                 {
1484                                         self.effects -= self.effects & EF_NODRAW;
1485                                 }
1486                                 self.items = self.items - (self.items & IT_STRENGTH);
1487                                 sprint(self, "^3Invisibility has worn off\n");
1488                         }
1489                 }
1490                 else
1491                 {
1492                         if (time < self.strength_finished)
1493                         {
1494                                 if (g_minstagib_invis_alpha > 0)
1495                                 {
1496                                         self.alpha = g_minstagib_invis_alpha;
1497                                         self.exteriorweaponentity.alpha = g_minstagib_invis_alpha;
1498                                         self.effects -= self.effects & EF_FULLBRIGHT;
1499                                 }
1500                                 else
1501                                 {
1502                                         self.effects = self.effects | EF_NODRAW;
1503                                 }
1504                                 self.items = self.items | IT_STRENGTH;
1505                                 sprint(self, "^3You are invisible\n");
1506                         }
1507                 }
1508
1509                 if (self.items & IT_INVINCIBLE)
1510                 {
1511                         if (time > self.invincible_finished)
1512                         {
1513                                 self.items = self.items - (self.items & IT_INVINCIBLE);
1514                                 sprint(self, "^3Speed has worn off\n");
1515                         }
1516                 }
1517                 else
1518                 {
1519                         if (time < self.invincible_finished)
1520                         {
1521                                 self.items = self.items | IT_INVINCIBLE;
1522                                 sprint(self, "^3You are on speed\n");
1523                         }
1524                 }
1525                 return;
1526         }
1527
1528         self.effects = self.effects - (self.effects & (EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT));
1529         if (self.items & IT_STRENGTH)
1530         {
1531                 self.effects = self.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1532                 if (time > self.strength_finished)
1533                 {
1534                         self.items = self.items - (self.items & IT_STRENGTH);
1535                         sprint(self, "^3Strength has worn off\n");
1536                 }
1537         }
1538         else
1539         {
1540                 if (time < self.strength_finished)
1541                 {
1542                         self.items = self.items | IT_STRENGTH;
1543                         sprint(self, "^3Strength infuses your weapons with devastating power\n");
1544                 }
1545         }
1546         if (self.items & IT_INVINCIBLE)
1547         {
1548                 self.effects = self.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1549                 if (time > self.invincible_finished)
1550                 {
1551                         self.items = self.items - (self.items & IT_INVINCIBLE);
1552                         sprint(self, "^3Shield has worn off\n");
1553                 }
1554         }
1555         else
1556         {
1557                 if (time < self.invincible_finished)
1558                 {
1559                         self.items = self.items | IT_INVINCIBLE;
1560                         sprint(self, "^3Shield surrounds you\n");
1561                 }
1562         }
1563
1564         if (cvar("g_fullbrightplayers"))
1565                 self.effects = self.effects | EF_FULLBRIGHT;
1566
1567         // midair gamemode: damage only while in the air
1568         // if in midair mode, being on ground grants temporary invulnerability
1569         // (this is so that multishot weapon don't clear the ground flag on the
1570         // first damage in the frame, leaving the player vulnerable to the
1571         // remaining hits in the same frame)
1572         if (self.flags & FL_ONGROUND)
1573         if (g_midair)
1574                 self.spawnshieldtime = max(self.spawnshieldtime, time + cvar("g_midair_shieldtime"));
1575
1576         if (time > restart_countdown)
1577         if (time < self.spawnshieldtime)
1578                 self.effects = self.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1579 }
1580
1581 float CalcRegen(float current, float stable, float regenfactor)
1582 {
1583         if(current > stable)
1584                 return current;
1585         else if(current > stable - 0.25) // when close enough, "snap"
1586                 return stable;
1587         else
1588                 return min(stable, current + (stable - current) * regenfactor * frametime);
1589 }
1590
1591 void player_regen (void)
1592 {
1593         float maxh, maxa, limith, limita, max_mod, regen_mod, rot_mod, limit_mod;
1594         maxh = cvar("g_balance_health_stable");
1595         maxa = cvar("g_balance_armor_stable");
1596         limith = cvar("g_balance_health_limit");
1597         limita = cvar("g_balance_armor_limit");
1598
1599         if (g_minstagib || (g_lms && !cvar("g_lms_regenerate")))
1600                 return;
1601
1602         max_mod = regen_mod = rot_mod = limit_mod = 1;
1603
1604         if (self.runes & RUNE_REGEN)
1605         {
1606                 if (self.runes & CURSE_VENOM) // do we have both rune/curse?
1607                 {
1608                         regen_mod = cvar("g_balance_rune_regen_combo_regenrate");
1609                         max_mod = cvar("g_balance_rune_regen_combo_hpmod");
1610                         limit_mod = cvar("g_balance_rune_regen_combo_limitmod");
1611                 }
1612                 else
1613                 {
1614                         regen_mod = cvar("g_balance_rune_regen_regenrate");
1615                         max_mod = cvar("g_balance_rune_regen_hpmod");
1616                         limit_mod = cvar("g_balance_rune_regen_limitmod");
1617                 }
1618         }
1619         else if (self.runes & CURSE_VENOM)
1620         {
1621                 max_mod = cvar("g_balance_curse_venom_hpmod");
1622                 if (self.runes & RUNE_REGEN) // do we have both rune/curse?
1623                         rot_mod = cvar("g_balance_rune_regen_combo_rotrate");
1624                 else
1625                         rot_mod = cvar("g_balance_curse_venom_rotrate");
1626                 limit_mod = cvar("g_balance_curse_venom_limitmod");
1627                 //if (!self.runes & RUNE_REGEN)
1628                 //      rot_mod = cvar("g_balance_curse_venom_rotrate");
1629         }
1630         maxh = maxh * max_mod;
1631         //maxa = maxa * max_mod;
1632         limith = limith * limit_mod;
1633         limita = limita * limit_mod;
1634
1635         if (self.armorvalue > maxa)
1636         {
1637                 if (time > self.pauserotarmor_finished)
1638                 {
1639                         self.armorvalue = max(maxa, self.armorvalue + (maxa - self.armorvalue) * cvar("g_balance_armor_rot") * frametime);
1640                         self.armorvalue = max(maxa, self.armorvalue - cvar("g_balance_armor_rotlinear") * frametime);
1641                 }
1642         }
1643         else if (self.armorvalue < maxa)
1644         {
1645                 if (time > self.pauseregen_finished)
1646                 {
1647                         self.armorvalue = CalcRegen(self.armorvalue, maxa, cvar("g_balance_armor_regen"));
1648                         self.armorvalue = min(maxa, self.armorvalue + cvar("g_balance_armor_regenlinear") * frametime);
1649                 }
1650         }
1651         if (self.health > maxh)
1652         {
1653                 if (time > self.pauserothealth_finished)
1654                 {
1655                         self.health = max(maxh, self.health + (maxh - self.health) * rot_mod*cvar("g_balance_health_rot") * frametime);
1656                         self.health = max(maxh, self.health - rot_mod*cvar("g_balance_health_rotlinear") * frametime);
1657                 }
1658         }
1659         else if (self.health < maxh)
1660         {
1661                 if (time > self.pauseregen_finished)
1662                 {
1663                         self.health = CalcRegen(self.health, maxh, regen_mod * cvar("g_balance_health_regen"));
1664                         self.health = min(maxh, self.health + regen_mod*cvar("g_balance_health_regenlinear") * frametime);
1665                 }
1666         }
1667
1668         if (self.health > limith)
1669                 self.health = limith;
1670         if (self.armorvalue > limita)
1671                 self.armorvalue = limita;
1672
1673         // if player rotted to death...  die!
1674         if(self.health < 1)
1675                 self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
1676 }
1677
1678 .float zoomstate;
1679 float zoomstate_set;
1680 void SetZoomState(float z)
1681 {
1682         if(z != self.zoomstate)
1683         {
1684                 msg_entity = self;
1685                 WriteByte(MSG_ONE, SVC_TEMPENTITY);
1686                 WriteByte(MSG_ONE, TE_CSQC_ZOOMNOTIFY);
1687                 WriteByte(MSG_ONE, z);
1688                 self.zoomstate = z;
1689         }
1690         zoomstate_set = 1;
1691 }
1692
1693 /*
1694 ======================
1695 spectate mode routines
1696 ======================
1697 */
1698 void SpectateCopy(entity spectatee) {
1699         self.armortype = spectatee.armortype;
1700         self.armorvalue = spectatee.armorvalue;
1701         self.currentammo = spectatee.currentammo;
1702         self.effects = spectatee.effects;
1703         self.health = spectatee.health;
1704         self.impulse = 0;
1705         self.items = spectatee.items;
1706         self.weapons = spectatee.weapons;
1707         self.punchangle = spectatee.punchangle;
1708         self.view_ofs = spectatee.view_ofs;
1709         self.v_angle = spectatee.v_angle;
1710         self.velocity = spectatee.velocity;
1711         self.dmg_take = spectatee.dmg_take;
1712         self.dmg_save = spectatee.dmg_save;
1713         self.dmg_inflictor = spectatee.dmg_inflictor;
1714         self.angles = spectatee.v_angle;
1715         self.fixangle = TRUE;
1716         setorigin(self, spectatee.origin);
1717         setsize(self, spectatee.mins, spectatee.maxs);
1718         SetZoomState(spectatee.zoomstate);
1719 }
1720
1721 float SpectateUpdate() {
1722         if(!self.enemy)
1723                 return 0;
1724
1725         if (self == self.enemy)
1726                 return 0;
1727
1728         if(self.enemy.flags & FL_NOTARGET)
1729                 return 0;
1730
1731         SpectateCopy(self.enemy);
1732
1733         return 1;
1734 }
1735
1736 float SpectateNext() {
1737         other = find(self.enemy, classname, "player");
1738         if (!other) {
1739                 other = find(other, classname, "player");
1740         }
1741         if (other) {
1742                 self.enemy = other;
1743         }
1744         if(self.enemy.classname == "player") {
1745                 msg_entity = self;
1746                 WriteByte(MSG_ONE, SVC_SETVIEW);
1747                 WriteEntity(MSG_ONE, self.enemy);
1748                 self.wantswelcomemessage = 1;
1749                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
1750                 if(!SpectateUpdate())
1751                         PutObserverInServer();
1752                 return 1;
1753         } else {
1754                 return 0;
1755         }
1756 }
1757
1758 /*
1759 =============
1760 ShowRespawnCountdown()
1761
1762 Update a respawn countdown display.
1763 =============
1764 */
1765 void ShowRespawnCountdown()
1766 {
1767         float number;
1768         if(self.deadflag == DEAD_NO) // just respawned?
1769                 return;
1770         else
1771         {
1772                 number = ceil(self.death_time - time);
1773                 if(number <= 0)
1774                         return;
1775                 if(number <= self.respawn_countdown)
1776                 {
1777                         self.respawn_countdown = number - 1;
1778                         if(ceil(self.death_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
1779                                 announce(self, strcat("announcer/robotic/", ftos(number), ".ogg"));
1780                 }
1781         }
1782 }
1783
1784 void LeaveSpectatorMode()
1785 {
1786         if(isJoinAllowed()) {
1787                 if(!cvar("teamplay") || cvar("g_campaign") || cvar("g_balance_teams")) {
1788                         self.classname = "player";
1789                         if(cvar("g_campaign") || cvar("g_balance_teams") || cvar("g_balance_teams_force"))
1790                                 JoinBestTeam(self, FALSE, TRUE);
1791                         if(cvar("g_campaign"))
1792                                 campaign_bots_may_start = 1;
1793                         PutClientInServer();
1794                         if(!(self.flags & FL_NOTARGET))
1795                                 bprint ("^4", self.netname, "^4 is playing now\n");
1796                         centerprint(self,"");
1797                         return;
1798                 } else {
1799                         stuffcmd(self,"menu_showteamselect\n");
1800                         return;
1801                 }
1802         }
1803         else {
1804                 //player may not join because of g_maxplayers is set
1805                 centerprint_atprio(self, CENTERPRIO_MAPVOTE, PREVENT_JOIN_TEXT);
1806         }
1807 }
1808
1809 /**
1810  * Determines whether the player is allowed to join. This depends on cvar
1811  * g_maxplayers, if it isn't used this function always return TRUE, otherwise
1812  * it checks whether the number of currently playing players exceeds g_maxplayers.
1813  * @return bool TRUE if the player is allowed to join, false otherwise
1814  */
1815 float isJoinAllowed() {
1816         if (!cvar("g_maxplayers"))
1817                 return TRUE;
1818
1819         local entity e;
1820         local float currentlyPlaying;
1821         FOR_EACH_REALPLAYER(e) {
1822                 if(e.classname == "player")
1823                         currentlyPlaying += 1;
1824         }
1825         if(currentlyPlaying < cvar("g_maxplayers"))
1826                 return TRUE;
1827
1828         return FALSE;
1829 }
1830
1831 /**
1832  * Checks whether the client is an observer or spectator, if so, he will get kicked after
1833  * g_maxplayers_spectator_blocktime seconds
1834  */
1835 void checkSpectatorBlock() {
1836         if(self.classname == "spectator" || self.classname == "observer") {
1837                 if( time > (self.spectatortime + cvar("g_maxplayers_spectator_blocktime")) ) {
1838                         sprint(self, "^7You were kicked from the server because you are spectator and spectators aren't allowed at the moment.\n");
1839                         dropclient(self);
1840                 }
1841         }
1842 }
1843
1844 float vercmp_recursive(string v1, string v2)
1845 {
1846         float dot1, dot2;
1847         string s1, s2;
1848         float r;
1849
1850         dot1 = strstrofs(v1, ".", 0);
1851         dot2 = strstrofs(v2, ".", 0);
1852         if(dot1 == -1)
1853                 s1 = v1;
1854         else
1855                 s1 = substring(v1, 0, dot1);
1856         if(dot2 == -1)
1857                 s2 = v2;
1858         else
1859                 s2 = substring(v2, 0, dot2);
1860
1861         r = stof(s1) - stof(s2);
1862         if(r != 0)
1863                 return r;
1864
1865         r = strcasecmp(s1, s2);
1866         if(r != 0)
1867                 return r;
1868
1869         if(dot1 == -1)
1870                 if(dot2 == -1)
1871                         return 0;
1872                 else
1873                         return -1;
1874         else
1875                 if(dot2 == -1)
1876                         return 1;
1877                 else
1878                         return vercmp_recursive(substring(v1, dot1 + 1, 999), substring(v2, dot2 + 1, 999));
1879 }
1880
1881 float vercmp(string v1, string v2)
1882 {
1883         if(strcasecmp(v1, v2) == 0) // early out check
1884                 return 0;
1885         return vercmp_recursive(v1, v2);
1886 }
1887
1888 void ObserverThink()
1889 {
1890         if (self.flags & FL_JUMPRELEASED) {
1891                 if (self.BUTTON_JUMP && !self.version_mismatch) {
1892                         self.welcomemessage_time = 0;
1893                         self.flags = self.flags - FL_JUMPRELEASED;
1894                         LeaveSpectatorMode();
1895                         return;
1896                 } else if(self.BUTTON_ATCK && !self.version_mismatch) {
1897                         self.welcomemessage_time = 0;
1898                         self.flags = self.flags - FL_JUMPRELEASED;
1899                         if(SpectateNext() == 1) {
1900                                 self.classname = "spectator";
1901                         }
1902                 }
1903         } else {
1904                 if (!(self.BUTTON_ATCK || self.BUTTON_JUMP)) {
1905                         self.flags = self.flags | FL_JUMPRELEASED;
1906                 }
1907         }
1908         if(self.BUTTON_ZOOM)
1909                 self.wantswelcomemessage = 0;
1910         if(self.wantswelcomemessage)
1911                 PrintWelcomeMessage(self);
1912 }
1913
1914 void SpectatorThink()
1915 {
1916         if (self.flags & FL_JUMPRELEASED) {
1917                 if (self.BUTTON_JUMP && !self.version_mismatch) {
1918                         self.welcomemessage_time = 0;
1919                         self.flags = self.flags - FL_JUMPRELEASED;
1920                         LeaveSpectatorMode();
1921                         return;
1922                 } else if(self.BUTTON_ATCK) {
1923                         self.welcomemessage_time = 0;
1924                         self.flags = self.flags - FL_JUMPRELEASED;
1925                         if(SpectateNext() == 1) {
1926                                 self.classname = "spectator";
1927                         } else {
1928                                 self.classname = "observer";
1929                                 PutClientInServer();
1930                         }
1931                 } else if (self.BUTTON_ATCK2) {
1932                         self.welcomemessage_time = 0;
1933                         self.flags = self.flags - FL_JUMPRELEASED;
1934                         self.classname = "observer";
1935                         PutClientInServer();
1936                 } else {
1937                         if(!SpectateUpdate())
1938                                 PutObserverInServer();
1939                 }
1940         } else {
1941                 if (!(self.BUTTON_ATCK || self.BUTTON_ATCK2)) {
1942                         self.flags = self.flags | FL_JUMPRELEASED;
1943                 }
1944         }
1945         if(self.BUTTON_ZOOM)
1946                 self.wantswelcomemessage = 0;
1947         if(self.wantswelcomemessage)
1948                 PrintWelcomeMessage(self);
1949         self.flags = self.flags | FL_CLIENT | FL_NOTARGET;
1950 }
1951
1952 /*
1953 =============
1954 PlayerPreThink
1955
1956 Called every frame for each client before the physics are run
1957 =============
1958 */
1959 void() ctf_setstatus;
1960 .float vote_nagtime;
1961 .float spectatee_status;
1962 void PlayerPreThink (void)
1963 {
1964         self.stat_sys_ticrate = cvar("sys_ticrate");
1965         if(blockSpectators)
1966                 checkSpectatorBlock();
1967
1968         zoomstate_set = 0;
1969
1970         if(self.netname_previous != self.netname)
1971         {
1972                 if(cvar("sv_eventlog"))
1973                         GameLogEcho(strcat(":name:", ftos(self.playerid), ":", self.netname));
1974                 if(self.netname_previous)
1975                         strunzone(self.netname_previous);
1976                 self.netname_previous = strzone(self.netname);
1977         }
1978
1979         // version nagging
1980         if(self.version_nagtime)
1981                 if(self.cvar_g_nexuizversion)
1982                         if(time > self.version_nagtime)
1983                         {
1984                                 if(strstr(self.cvar_g_nexuizversion, "svn", 0) < 0)
1985                                 {
1986                                         if(strstr(cvar_string("g_nexuizversion"), "svn", 0) >= 0)
1987                                         {
1988                                                 dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Nexuiz ", cvar_string("g_nexuizversion"), " (beta)^7, you have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1\n");
1989                                                 sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Nexuiz ", cvar_string("g_nexuizversion"), " (beta)^7, you have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1\n"));
1990                                         }
1991                                         else
1992                                         {
1993                                                 float r;
1994                                                 r = vercmp(self.cvar_g_nexuizversion, cvar_string("g_nexuizversion"));
1995                                                 if(r < 0)
1996                                                 {
1997                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - ^3Nexuiz ", cvar_string("g_nexuizversion"), "^7 is out, and you still have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1 - get the update from ^4http://www.nexuiz.com/^1!\n");
1998                                                         sprint(self, strcat("\{1}^1NOTE: ^3Nexuiz ", cvar_string("g_nexuizversion"), "^7 is out, and you still have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1 - get the update from ^4http://www.nexuiz.com/^1!\n"));
1999                                                 }
2000                                                 else if(r > 0)
2001                                                 {
2002                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Nexuiz ", cvar_string("g_nexuizversion"), "^7, you have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1\n");
2003                                                         sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Nexuiz ", cvar_string("g_nexuizversion"), "^7, you have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1\n"));
2004                                                 }
2005                                         }
2006                                 }
2007                                 self.version_nagtime = 0;
2008                         }
2009
2010         // vote nagging
2011         if(self.cvar_scr_centertime)
2012                 if(time > self.vote_nagtime)
2013                 {
2014                         VoteNag();
2015                         self.vote_nagtime = time + self.cvar_scr_centertime * 0.6;
2016                 }
2017
2018         // GOD MODE info
2019         if(!(self.flags & FL_GODMODE)) if(self.max_armorvalue)
2020         {
2021                 sprint(self, strcat("godmode saved you ", ftos(self.max_armorvalue), " units of damage, cheater!\n"));
2022                 self.max_armorvalue = 0;
2023         }
2024
2025         if(frametime)
2026                 antilag_record(self);
2027
2028         if(self.classname == "player") {
2029 //              if(self.netname == "Wazat")
2030 //                      bprint(self.classname, "\n");
2031
2032                 CheckRules_Player();
2033
2034                 if(self.BUTTON_INFO)
2035                         PrintWelcomeMessage(self);
2036
2037                 if(g_lms || !cvar("sv_spectate"))
2038                 if((time - self.jointime) <= cvar("welcome_message_time"))
2039                         PrintWelcomeMessage(self);
2040
2041                 if (intermission_running)
2042                 {
2043                         IntermissionThink ();   // otherwise a button could be missed between
2044                         return;                                 // the think tics
2045                 }
2046
2047                 if(self.teleport_time)
2048                 if(time > self.teleport_time)
2049                 {
2050                         self.teleport_time = 0;
2051                         self.effects = self.effects - (self.effects & EF_NODRAW);
2052                         if(self.weaponentity)
2053                                 self.weaponentity.flags = self.weaponentity.flags - (self.weaponentity.flags & EF_NODRAW);
2054                 }
2055
2056                 Nixnex_GiveCurrentWeapon();
2057
2058                 if(frametime > 0) // don't do this in cl_movement frames, just in server ticks
2059                         UpdateSelectedPlayer();
2060
2061                 //don't allow the player to turn around while game is paused!
2062                 if(timeoutStatus == 2) {
2063                         self.v_angle = self.lastV_angle;
2064                         self.angles = self.lastV_angle;
2065                         self.fixangle = TRUE;
2066                 }
2067
2068                 if (self.deadflag != DEAD_NO)
2069                 {
2070                         float button_pressed, force_respawn;
2071                         player_anim();
2072                         button_pressed = (self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE);
2073                         force_respawn = (g_lms || cvar("g_forced_respawn"));
2074                         if (self.deadflag == DEAD_DYING)
2075                         {
2076                                 if(force_respawn)
2077                                         self.deadflag = DEAD_RESPAWNING;
2078                                 else if(!button_pressed)
2079                                         self.deadflag = DEAD_DEAD;
2080                         }
2081                         else if (self.deadflag == DEAD_DEAD)
2082                         {
2083                                 if(button_pressed)
2084                                         self.deadflag = DEAD_RESPAWNABLE;
2085                         }
2086                         else if (self.deadflag == DEAD_RESPAWNABLE)
2087                         {
2088                                 if(!button_pressed)
2089                                         self.deadflag = DEAD_RESPAWNING;
2090                         }
2091                         else if (self.deadflag == DEAD_RESPAWNING)
2092                         {
2093                                 if(time > self.death_time)
2094                                 {
2095                                         self.death_time = time + 1; // only retry once a second
2096                                         respawn();
2097                                 }
2098                         }
2099                         ShowRespawnCountdown();
2100                         return;
2101                 }
2102
2103                 if(g_lms && !self.deadflag && cvar("g_lms_campcheck_interval"))
2104                 {
2105                         vector dist;
2106
2107                         // calculate player movement (in 2 dimensions only, so jumping on one spot doesn't count as movement)
2108                         dist = self.oldorigin - self.origin;
2109                         dist_z = 0;
2110                         self.lms_traveled_distance += fabs(vlen(dist));
2111
2112                         if((cvar("g_campaign") && !campaign_bots_may_start) || (time < restart_countdown))
2113                         {
2114                                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval")*2;
2115                                 self.lms_traveled_distance = 0;
2116                         }
2117
2118                         if(time > self.lms_nextcheck)
2119                         {
2120                                 //sprint(self, "distance: ", ftos(self.lms_traveled_distance), "\n");
2121                                 if(self.lms_traveled_distance < cvar("g_lms_campcheck_distance"))
2122                                 {
2123                                         centerprint(self, cvar_string("g_lms_campcheck_message"));
2124                                         // FIXME KadaverJack: gibbing player here causes playermodel to bounce around, instead of eye.md3
2125                                         // I wasn't able to find out WHY that happens, so I put a workaround in place that shall prevent players from being gibbed :(
2126                                         Damage(self, self, self, bound(0, cvar("g_lms_campcheck_damage"), self.health + self.armorvalue * cvar("g_balance_armor_blockpercent") + 5), DEATH_CAMP, self.origin, '0 0 0');
2127                                 }
2128                                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval");
2129                                 self.lms_traveled_distance = 0;
2130                         }
2131                 }
2132
2133                 if (self.BUTTON_CROUCH && !self.hook.state)
2134                 {
2135                         if (!self.crouch)
2136                         {
2137                                 self.crouch = TRUE;
2138                                 self.view_ofs = PL_CROUCH_VIEW_OFS;
2139                                 setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX);
2140                                 player_setanim(self.anim_duck, FALSE, TRUE, TRUE);
2141                         }
2142                 }
2143                 else
2144                 {
2145                         if (self.crouch)
2146                         {
2147                                 tracebox(self.origin, PL_MIN, PL_MAX, self.origin, FALSE, self);
2148                                 if (!trace_startsolid)
2149                                 {
2150                                         self.crouch = FALSE;
2151                                         self.view_ofs = PL_VIEW_OFS;
2152                                         setsize (self, PL_MIN, PL_MAX);
2153                                 }
2154                         }
2155                 }
2156
2157                 FixPlayermodel();
2158
2159                 GrapplingHookFrame();
2160
2161                 W_WeaponFrame();
2162
2163                 player_powerups();
2164                 player_regen();
2165                 player_anim();
2166
2167                 if (g_minstagib)
2168                         minstagib_ammocheck();
2169
2170                 ctf_setstatus();
2171                 kh_setstatus();
2172
2173                 //self.angles_y=self.v_angle_y + 90;   // temp
2174
2175                 //if (TetrisPreFrame()) return;
2176         } else if(gameover) {
2177                 if (intermission_running)
2178                         IntermissionThink ();   // otherwise a button could be missed between
2179                 return;
2180         } else if(self.classname == "observer") {
2181                 ObserverThink();
2182         } else if(self.classname == "spectator") {
2183                 SpectatorThink();
2184         }
2185
2186         if(!zoomstate_set)
2187                 SetZoomState(self.BUTTON_ZOOM || (self.BUTTON_ATCK2 && self.weapon == WEP_NEX));
2188
2189         float oldspectatee_status;
2190         oldspectatee_status = self.spectatee_status;
2191         if(self.classname == "spectator")
2192                 self.spectatee_status = num_for_edict(self.enemy);
2193         else if(self.classname == "observer")
2194                 self.spectatee_status = num_for_edict(self);
2195         else
2196                 self.spectatee_status = 0;
2197         if(self.spectatee_status != oldspectatee_status)
2198         {
2199                 msg_entity = self;
2200                 WriteByte(MSG_ONE, SVC_TEMPENTITY);
2201                 WriteByte(MSG_ONE, TE_CSQC_SPECTATING);
2202                 WriteByte(MSG_ONE, self.spectatee_status);
2203                 if(g_race)
2204                         race_InitSpectator();
2205         }
2206 }
2207
2208
2209 /*
2210 =============
2211 PlayerPostThink
2212
2213 Called every frame for each client after the physics are run
2214 =============
2215 */
2216 .float idlekick_lasttimeleft;
2217 .float race_penalty;
2218 .float race_penalty_nagged;
2219 void PlayerPostThink (void)
2220 {
2221         // Savage: Check for nameless players
2222         if (strlen(self.netname) < 1) {
2223                 self.netname = "Player";
2224                 stuffcmd(self, "seta _cl_name Player\n");
2225         }
2226
2227         if(sv_maxidle)
2228         {
2229                 float timeleft;
2230                 timeleft = ceil(sv_maxidle - (time - self.parm_idlesince));
2231                 if(timeleft <= 0)
2232                 {
2233                         bprint("^3", self.netname, "^3 was kicked for idling.\n");
2234                         announce(self, "announcer/robotic/terminated.ogg");
2235                         dropclient(self);
2236                         return;
2237                 }
2238                 else if(timeleft <= 10)
2239                 {
2240                         if(timeleft != self.idlekick_lasttimeleft)
2241                         {
2242                                 centerprint_atprio(self, CENTERPRIO_IDLEKICK, strcat("^3Stop idling!\n^3Disconnecting in ", ftos(timeleft), "..."));
2243                                 announce(self, strcat("announcer/robotic/", ftos(timeleft), ".ogg"));
2244                         }
2245                 }
2246                 else
2247                 {
2248                         centerprint_expire(self, CENTERPRIO_IDLEKICK);
2249                 }
2250                 self.idlekick_lasttimeleft = timeleft;
2251         }
2252
2253         if(self.classname == "player") {
2254                 CheckRules_Player();
2255                 UpdateChatBubble();
2256                 UpdateTeamBubble();
2257                 if (self.impulse)
2258                         ImpulseCommands();
2259                 if (intermission_running)
2260                         return;         // intermission or finale
2261
2262                 //PrintWelcomeMessage(self);
2263                 //if (TetrisPostFrame()) return;
2264
2265                 // restart countdown
2266                 if (restart_countdown) {
2267                         if(time < restart_countdown) {
2268                                 if (!cvar("sv_ready_restart_after_countdown"))
2269                                 {
2270                                         if(self.movement != '0 0 0' && g_race && !g_race_qualifying)
2271                                         {
2272                                                 if(time < restart_countdown - 2)
2273                                                 {
2274                                                         if(!self.race_penalty_nagged)
2275                                                         {
2276                                                                 centerprint_atprio(self, CENTERPRIO_IDLEKICK, "^1DO NOT MOVE DURING THE COUNTDOWN.");
2277                                                                 self.race_penalty_nagged = 1;
2278                                                         }
2279                                                 }
2280                                                 else if(!self.race_penalty)
2281                                                 {
2282                                                         centerprint_atprio(self, CENTERPRIO_IDLEKICK, "^1FIVE SECONDS PENALTY.");
2283                                                         self.race_penalty = time + 5;
2284                                                 }
2285                                         }
2286                                         self.movetype = MOVETYPE_NONE;
2287                                         self.velocity = '0 0 0';
2288                                         self.avelocity = '0 0 0';
2289                                         self.movement = '0 0 0';
2290                                 }
2291                         }
2292                         else if (time < self.race_penalty)
2293                         {
2294                                 self.movetype = MOVETYPE_NONE;
2295                                 self.velocity = '0 0 0';
2296                                 self.avelocity = '0 0 0';
2297                                 self.movement = '0 0 0';
2298                         }
2299                         else
2300                         {
2301                                 //allow the player to move again if sv_ready_restart_after_countdown is not used and countdown is over
2302                                 if (!cvar("sv_ready_restart_after_countdown"))
2303                                 {
2304                                         if(self.movetype == MOVETYPE_NONE)
2305                                         {
2306                                                 self.movetype = MOVETYPE_WALK;
2307                                         }
2308                                         self.race_penalty = 0;
2309                                         self.race_penalty_nagged = 0;
2310                                 }
2311                         }
2312                 }
2313
2314         } else if (self.classname == "observer") {
2315                 //do nothing
2316         } else if (self.classname == "spectator") {
2317                 //do nothing
2318         }
2319
2320         /*
2321         float i;
2322         for(i = 0; i < 1000; ++i)
2323         {
2324                 vector end;
2325                 end = self.origin + '0 0 1024' + 512 * randomvec();
2326                 tracebox(self.origin, self.mins, self.maxs, end, MOVE_NORMAL, self);
2327                 if(trace_fraction < 1)
2328                 if(!(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
2329                 {
2330                         print("I HIT SOLID: ", vtos(self.origin), " -> ", vtos(end), "\n");
2331                         break;
2332                 }
2333         }
2334         */
2335
2336         Arena_Warmup();
2337 }