data/qcsrc/server/cl_client.qc

   1 void info_player_start (void)
   2 {
   3         self.classname = "info_player_deathmatch";
   4         relocate_spawnpoint();
   5 }
   6
   7 void info_player_deathmatch (void)
   8 {
   9         relocate_spawnpoint();
  10 }
  11
  12 float spawn_allbad;
  13 float spawn_allgood;
  14 entity Spawn_FilterOutBadSpots(entity firstspot, entity playerlist, float mindist, float teamcheck)
  15 {
  16         local entity spot, player, nextspot, previousspot, newfirstspot;
  17         local float pcount;
  18         spot = firstspot;
  19         newfirstspot = world;
  20         previousspot = world;
  21         spawn_allgood = TRUE;
  22         spawn_allbad = TRUE;
  23         while (spot)
  24         {
  25                 nextspot = spot.chain;
  26                 // count team mismatches as bad spots
  27                 if (spot.team == teamcheck)
  28                 {
  29                         pcount = 0;
  30                         player = playerlist;
  31                         while (player)
  32                         {
  33                                 if (player != self)
  34                                 if (vlen(player.origin - spot.origin) < mindist)
  35                                         pcount = pcount + 1;
  36                                 player = player.chain;
  37                         }
  38                         if (!pcount)
  39                         {
  40                                 spawn_allbad = FALSE;
  41                                 if (newfirstspot)
  42                                         previousspot.chain = spot;
  43                                 else
  44                                         newfirstspot = spot;
  45                                 previousspot = spot;
  46                                 spot.chain = world;
  47                         }
  48                         else
  49                                 spawn_allgood = FALSE;
  50                 }
  51                 spot = nextspot;
  52         }
  53         // if we couldn't find ANY good points, return the original list
  54         if (!newfirstspot)
  55                 newfirstspot = firstspot;
  56         return newfirstspot;
  57 }
  58
  59 entity Spawn_RandomPoint(entity firstspot)
  60 {
  61         local entity spot;
  62         local float numspots;
  63         // count number of spots
  64         numspots = 0;
  65         spot = firstspot;
  66         while (spot)
  67         {
  68                 numspots = numspots + 1;
  69                 spot = spot.chain;
  70         }
  71         // pick a random one
  72         numspots = numspots * random();
  73         spot = firstspot;
  74         while (spot.chain && numspots >= 1)
  75         {
  76                 numspots = numspots - 1;
  77                 spot = spot.chain;
  78         }
  79         return spot;
  80 }
  81
  82 entity Spawn_FurthestPoint(entity firstspot, entity playerlist)
  83 {
  84         local entity best, spot, player;
  85         local float bestrating, rating;
  86         best = world;
  87         bestrating = -1000000;
  88         spot = firstspot;
  89         while (spot)
  90         {
  91                 rating = 1000000000;
  92                 player = playerlist;
  93                 while (player)
  94                 {
  95                         if (player != self)
  96                                 rating = min(rating, vlen(player.origin - spot.origin));
  97                         player = player.chain;
  98                 }
  99                 rating = rating + random() * 16;
 100                 if (bestrating < rating)
 101                 {
 102                         best = spot;
 103                         bestrating = rating;
 104                 }
 105                 spot = spot.chain;
 106         }
 107         return best;
 108 }
 109
 110 /*
 111 =============
 112 SelectSpawnPoint
 113
 114 Finds a point to respawn
 115 =============
 116 */
 117 entity SelectSpawnPoint (float anypoint)
 118 {
 119         local float teamcheck;
 120         local entity spot, firstspot, playerlist;
 121
 122         spot = find (world, classname, "testplayerstart");
 123         if (spot)
 124                 return spot;
 125
 126         teamcheck = 0;
 127
 128         if(!anypoint && cvar("g_ctf") )
 129                 teamcheck = self.team;
 130
 131         // get the list of players
 132         playerlist = findchain(classname, "player");
 133         // get the entire list of spots
 134         firstspot = findchain(classname, "info_player_deathmatch");
 135         // filter out the bad ones
 136         // (note this returns the original list if none survived)
 137         firstspot = Spawn_FilterOutBadSpots(firstspot, playerlist, 100, teamcheck);
 138
 139         // there is 50/50 chance of choosing a random spot or the furthest spot
 140         // (this means that roughly every other spawn will be furthest, so you
 141         // usually won't get fragged at spawn twice in a row)
 142         if (arena_roundbased)
 143         {
 144                 firstspot = Spawn_FilterOutBadSpots(firstspot, playerlist, 800, teamcheck);
 145                 spot = Spawn_RandomPoint(firstspot);
 146         }
 147         else if (random() > 0.5 || spawn_allbad || spawn_allgood)
 148                 spot = Spawn_RandomPoint(firstspot);
 149         else
 150                 spot = Spawn_FurthestPoint(firstspot, playerlist);
 151
 152         if (!spot)
 153         {
 154                 if(cvar("spawn_debug"))
 155                         GotoNextMap();
 156                 else
 157                         error ("PutClientInServer: no start points on level");
 158         }
 159
 160         return spot;
 161 }
 162
 163 /*
 164 =============
 165 CheckPlayerModel
 166
 167 Checks if the argument string can be a valid playermodel.
 168 Returns a valid one in doubt.
 169 =============
 170 */
 171 string FallbackPlayerModel = "models/player/marine.zym";
 172 string CheckPlayerModel(string plyermodel) {
 173         if(strlen(plyermodel) < 4)
 174                 return FallbackPlayerModel;
 175         if( substring(plyermodel,0,14) != "models/player/")
 176                 return FallbackPlayerModel;
 177         else if(cvar("sv_servermodelsonly"))
 178         {
 179                 if(substring(plyermodel,strlen(plyermodel)-4,4) != ".zym")
 180                         return FallbackPlayerModel;
 181                 if(!fexists(plyermodel))
 182                         return FallbackPlayerModel;
 183         }
 184         return plyermodel;
 185 }
 186
 187 /*
 188 =============
 189 Client_customizeentityforclient
 190
 191 LOD reduction
 192 =============
 193 */
 194 float Client_customizeentityforclient()
 195 {
 196 #ifdef ALLOW_VARIABLE_LOD
 197         // self: me
 198         // other: the player viewing me
 199         float distance;
 200         float f;
 201
 202         if(self.flags & FL_NOTARGET) // we don't need LOD for spectators
 203                 return TRUE;
 204
 205         if(other.cvar_cl_playerdetailreduction <= 0)
 206         {
 207                 if(other.cvar_cl_playerdetailreduction <= -2)
 208                         self.modelindex = self.modelindex_lod2;
 209                 else if(other.cvar_cl_playerdetailreduction <= -1)
 210                         self.modelindex = self.modelindex_lod1;
 211                 else
 212                         self.modelindex = self.modelindex_lod0;
 213         }
 214         else
 215         {
 216                 distance = vlen(self.origin - other.origin);
 217                 f = (distance + 100.0) * other.cvar_cl_playerdetailreduction;
 218                 if(f > 10000)
 219                         self.modelindex = self.modelindex_lod2;
 220                 else if(f > 5000)
 221                         self.modelindex = self.modelindex_lod1;
 222                 else
 223                         self.modelindex = self.modelindex_lod0;
 224         }
 225 #endif
 226
 227         return TRUE;
 228 }
 229
 230 void setmodel_lod(entity e, string modelname)
 231 {
 232 #ifdef ALLOW_VARIABLE_LOD
 233         string s;
 234
 235         s = strcat(substring(modelname, 0, strlen(modelname) - 4), "_1.zym");
 236         if(fexists(s))
 237         {
 238                 precache_model(s);
 239                 setmodel(e, s);
 240                 self.modelindex_lod1 = self.modelindex;
 241         }
 242         else
 243                 self.modelindex_lod1 = -1;
 244
 245         s = strcat(substring(modelname, 0, strlen(modelname) - 4), "_2.zym");
 246         if(fexists(s))
 247         {
 248                 precache_model(s);
 249                 setmodel(e, s);
 250                 self.modelindex_lod2 = self.modelindex;
 251         }
 252         else
 253                 self.modelindex_lod2 = -1;
 254
 255         precache_model(modelname);
 256         setmodel(e, modelname);
 257         self.modelindex_lod0 = self.modelindex;
 258
 259         if(self.modelindex_lod1 < 0)
 260                 self.modelindex_lod1 = self.modelindex;
 261
 262         if(self.modelindex_lod2 < 0)
 263                 self.modelindex_lod2 = self.modelindex;
 264 #else
 265         precache_model(modelname);
 266         setmodel(e, modelname);
 267 #endif
 268 }
 269
 270 /*
 271 =============
 272 PutObserverInServer
 273
 274 putting a client as observer in the server
 275 =============
 276 */
 277 void PutObserverInServer (void)
 278 {
 279         entity  spot;
 280         spot = SelectSpawnPoint (FALSE);
 281         RemoveGrapplingHook(self); // Wazat's Grappling Hook
 282
 283         if(clienttype(self) == CLIENTTYPE_REAL)
 284         {
 285                 msg_entity = self;
 286                 WriteByte(MSG_ONE, SVC_SETVIEW);
 287                 WriteEntity(MSG_ONE, self);
 288         }
 289
 290         WaypointSprite_PlayerDead();
 291
 292         DropAllRunes(self);
 293
 294         if(self.flagcarried)
 295                 DropFlag(self.flagcarried);
 296
 297         DistributeFragsAmongTeam(self, self.team, 1);
 298
 299         if(self.frags <= 0 && self.frags > -666 && cvar("g_lms") && self.killcount != -666)
 300                 bprint ("^4", self.netname, "^4 has no more lives left\n");
 301         else if(self.killcount != -666)
 302                 bprint ("^4", self.netname, "^4 is spectating now\n");
 303
 304         self.classname = "observer";
 305         self.health = -666;
 306         self.takedamage = DAMAGE_NO;
 307         self.solid = SOLID_NOT;
 308         self.movetype = MOVETYPE_NOCLIP;
 309         self.flags = FL_CLIENT | FL_NOTARGET;
 310         self.armorvalue = 666;
 311         self.effects = 0;
 312         self.armorvalue = cvar("g_balance_armor_start");
 313         self.pauserotarmor_finished = 0;
 314         self.pauserothealth_finished = 0;
 315         self.pauseregen_finished = 0;
 316         self.damageforcescale = 0;
 317         self.death_time = 0;
 318         self.dead_time = 0;
 319         self.dead_frame = 0;
 320         self.die_frame = 0;
 321         self.deaths = 0;
 322         self.alpha = 0;
 323         self.scale = 0;
 324         self.fade_time = 0;
 325         self.pain_frame = 0;
 326         self.pain_finished = 0;
 327         self.strength_finished = 0;
 328         self.invincible_finished = 0;
 329         self.pushltime = 0;
 330         self.think = SUB_Null;
 331         self.nextthink = 0;
 332         self.hook_time = 0;
 333         self.runes = 0;
 334         self.deadflag = DEAD_NO;
 335         self.angles = spot.angles;
 336         self.angles_z = 0;
 337         self.fixangle = TRUE;
 338         self.crouch = FALSE;
 339
 340         self.view_ofs = PL_VIEW_OFS;
 341         setorigin (self, spot.origin);
 342         setsize (self, '0 0 0', '0 0 0');
 343         self.oldorigin = self.origin;
 344         self.items = 0;
 345         self.model = "";
 346         self.modelindex = 0;
 347         self.weapon = 0;
 348         self.weaponmodel = "";
 349         self.weaponentity = world;
 350         self.killcount = -666;
 351         self.velocity = '0 0 0';
 352         self.avelocity = '0 0 0';
 353         self.punchangle = '0 0 0';
 354         self.punchvector = '0 0 0';
 355         self.oldvelocity = self.velocity;
 356         self.customizeentityforclient = Client_customizeentityforclient;
 357
 358         if(cvar("g_arena"))
 359         {
 360                 if(self.frags != -2)
 361                 {
 362                         Spawnqueue_Insert(self);
 363                 }
 364                 else
 365                 {
 366                         Spawnqueue_Unmark(self);
 367                         Spawnqueue_Remove(self);
 368                 }
 369         }
 370         else if(!cvar("g_lms"))
 371                 self.frags = -666;
 372 }
 373
 374
 375 /*
 376 =============
 377 PutClientInServer
 378
 379 Called when a client spawns in the server
 380 =============
 381 */
 382 void PutClientInServer (void)
 383 {
 384         if(clienttype(self) == CLIENTTYPE_BOT)
 385         {
 386                 self.classname = "player";
 387         }
 388         else if(clienttype(self) == CLIENTTYPE_REAL)
 389         {
 390                 msg_entity = self;
 391                 WriteByte(MSG_ONE, SVC_SETVIEW);
 392                 WriteEntity(MSG_ONE, self);
 393         }
 394
 395         // player is dead and becomes observer
 396         if(cvar("g_lms") && self.frags < 1)
 397                 self.classname = "observer";
 398
 399         if(cvar("g_arena"))
 400         if(!self.spawned)
 401                 self.classname = "observer";
 402
 403         if(self.classname == "player") {
 404                 entity  spot;
 405
 406                 spot = SelectSpawnPoint (FALSE);
 407
 408                 RemoveGrapplingHook(self); // Wazat's Grappling Hook
 409
 410                 self.classname = "player";
 411                 self.iscreature = TRUE;
 412                 self.movetype = MOVETYPE_WALK;
 413                 self.solid = SOLID_SLIDEBOX;
 414                 self.flags = FL_CLIENT;
 415                 self.takedamage = DAMAGE_AIM;
 416                 self.effects = 0;
 417                 self.health = cvar("g_balance_health_start");
 418                 self.air_finished = time + 12;
 419                 self.dmg = 2;
 420                 self.armorvalue = cvar("g_balance_armor_start");
 421                 self.spawnshieldtime = time + cvar("g_spawnshieldtime");
 422                 self.pauserotarmor_finished = time + cvar("g_balance_pause_armor_rot_spawn");
 423                 self.pauserothealth_finished = time + cvar("g_balance_pause_health_rot_spawn");
 424                 self.pauseregen_finished = time + cvar("g_balance_pause_health_regen_spawn");
 425                 self.damageforcescale = 2;
 426                 self.death_time = 0;
 427                 self.dead_time = 0;
 428                 self.dead_frame = 0;
 429                 self.die_frame = 0;
 430                 self.alpha = 0;
 431                 self.scale = 0;
 432                 self.fade_time = 0;
 433                 self.pain_frame = 0;
 434                 self.pain_finished = 0;
 435                 self.strength_finished = 0;
 436                 self.invincible_finished = 0;
 437                 self.pushltime = 0;
 438                 //self.speed_finished = 0;
 439                 //self.slowmo_finished = 0;
 440                 // players have no think function
 441                 self.think = SUB_Null;
 442                 self.nextthink = 0;
 443                 self.weapon = 0;
 444                 self.switchweapon = 0;
 445                 self.hook_time = 0;
 446
 447                 self.runes = 0;
 448
 449                 self.deadflag = DEAD_NO;
 450
 451                 self.angles = spot.angles;
 452
 453                 self.angles_z = 0; // never spawn tilted even if the spot says to
 454                 self.fixangle = TRUE; // turn this way immediately
 455                 self.velocity = '0 0 0';
 456                 self.avelocity = '0 0 0';
 457                 self.punchangle = '0 0 0';
 458                 self.punchvector = '0 0 0';
 459                 self.oldvelocity = self.velocity;
 460
 461                 self.viewzoom = 0.6;
 462                 self.has_zoomed = 0;
 463
 464                 self.customizeentityforclient = Client_customizeentityforclient;
 465
 466                 if(cvar("sv_defaultcharacter") == 1 && !teams_matter) {
 467                         local string defaultmodel;
 468                         defaultmodel = CheckPlayerModel(cvar_string("sv_defaultplayermodel"));
 469                         setmodel_lod (self, defaultmodel);
 470                         self.skin = stof(cvar_string("sv_defaultplayerskin"));
 471                 } else {
 472                         self.playermodel = CheckPlayerModel(self.playermodel);
 473                         setmodel_lod (self, self.playermodel);
 474                         if(teams_matter)
 475                                 self.skin = math_mod(stof(self.playerskin), NUM_PLAYERSKINS_TEAMPLAY);
 476                         else
 477                                 self.skin = stof(self.playerskin);
 478                 }
 479
 480                 self.crouch = FALSE;
 481                 self.view_ofs = PL_VIEW_OFS;
 482                 setsize (self, PL_MIN, PL_MAX);
 483                 self.spawnorigin = spot.origin;
 484                 setorigin (self, spot.origin + '0 0 1' * (1 - self.mins_z - 24));
 485                 // don't reset back to last position, even if new position is stuck in solid
 486                 self.oldorigin = self.origin;
 487
 488                 if(cvar("g_lms"))
 489                 {
 490                         self.ammo_shells = cvar("g_lms_start_ammo_shells");
 491                         self.ammo_nails = cvar("g_lms_start_ammo_nails");
 492                         self.ammo_rockets = cvar("g_lms_start_ammo_rockets");
 493                         self.ammo_cells = cvar("g_lms_start_ammo_cells");
 494                         self.health = cvar("g_lms_start_health");
 495                         self.armorvalue = cvar("g_lms_start_armor");
 496                 }
 497                 else if (cvar("g_use_ammunition")) {
 498                         self.ammo_shells = cvar("g_start_ammo_shells");
 499                         self.ammo_nails = cvar("g_start_ammo_nails");
 500                         self.ammo_rockets = cvar("g_start_ammo_rockets");
 501                         self.ammo_cells = cvar("g_start_ammo_cells");
 502                 } else {
 503                         self.ammo_shells = 999;
 504                         self.ammo_nails = 999;
 505                         self.ammo_rockets = 999;
 506                         self.ammo_cells = 999;
 507                 }
 508
 509                 self.items = 0;
 510                 if (cvar("g_start_weapon_laser") || cvar("g_lms"))
 511                 {
 512                         self.items = self.items | IT_LASER;
 513                         self.switchweapon = WEP_LASER;
 514                 }
 515                 if (cvar("g_start_weapon_shotgun") || cvar("g_lms"))
 516                 {
 517                         self.items = self.items | IT_SHOTGUN;
 518                         self.switchweapon = WEP_SHOTGUN;
 519                 }
 520                 if (cvar("g_start_weapon_uzi") || cvar("g_lms"))
 521                 {
 522                         self.items = self.items | IT_UZI;
 523                         self.switchweapon = WEP_UZI;
 524                 }
 525                 if (cvar("g_start_weapon_grenadelauncher") || cvar("g_lms"))
 526                 {
 527                         self.items = self.items | IT_GRENADE_LAUNCHER;
 528                         self.switchweapon = WEP_GRENADE_LAUNCHER;
 529                 }
 530                 if (cvar("g_start_weapon_electro") || cvar("g_lms"))
 531                 {
 532                         self.items = self.items | IT_ELECTRO;
 533                         self.switchweapon = WEP_ELECTRO;
 534                 }
 535                 if (cvar("g_start_weapon_crylink") || cvar("g_lms"))
 536                 {
 537                         self.items = self.items | IT_CRYLINK;
 538                         self.switchweapon = WEP_CRYLINK;
 539                 }
 540                 if (cvar("g_start_weapon_nex") || cvar("g_lms"))
 541                 {
 542                         self.items = self.items | IT_NEX;
 543                         self.switchweapon = WEP_NEX;
 544                 }
 545                 if (cvar("g_start_weapon_hagar") || cvar("g_lms"))
 546                 {
 547                         self.items = self.items | IT_HAGAR;
 548                         self.switchweapon = WEP_HAGAR;
 549                 }
 550                 if (cvar("g_start_weapon_rocketlauncher") || cvar("g_lms"))
 551                 {
 552                         self.items = self.items | IT_ROCKET_LAUNCHER;
 553                         self.switchweapon = WEP_ROCKET_LAUNCHER;
 554                 }
 555
 556                 if(cvar("g_instagib"))
 557                 {
 558                         self.items = IT_NEX;
 559                         self.switchweapon = WEP_NEX;
 560                         self.ammo_cells = 999;
 561                 }
 562
 563                 if(cvar("g_rocketarena"))
 564                 {
 565                         self.items = IT_ROCKET_LAUNCHER;
 566                         self.switchweapon = WEP_ROCKET_LAUNCHER;
 567                         self.ammo_rockets = 999;
 568                 }
 569
 570                 if(cvar("g_nixnex"))
 571                 {
 572                         self.items = 0;
 573                         // will be done later
 574                 }
 575
 576                 if(cvar("g_minstagib"))
 577                 {
 578                         self.health = 100;
 579                         self.armorvalue = 0;
 580                         self.items = IT_NEX;
 581                         self.switchweapon = WEP_NEX;
 582                         self.ammo_cells = cvar("g_minstagib_ammo_start");
 583                         self.jump_interval = time;
 584                 }
 585
 586                 if(cvar("g_arena"))
 587                 {
 588                         Spawnqueue_Remove(self);
 589                         Spawnqueue_Mark(self);
 590                 }
 591
 592                 self.event_damage = PlayerDamage;
 593
 594                 self.bot_attack = TRUE;
 595
 596                 self.statdraintime = time + 5;
 597                 self.button0 = self.button1 = self.button2 = self.button3 = 0;
 598
 599                 if(self.killcount == -666) {
 600                         self.killcount = 0;
 601                         if(!cvar("g_arena"))
 602                         if(!cvar("g_lms"))
 603                                 self.frags = 0;
 604                 }
 605
 606                 self.cnt = WEP_LASER;
 607                 self.nixnex_lastchange_id = -1;
 608
 609                 CL_SpawnWeaponentity();
 610                 self.alpha = default_player_alpha;
 611                 self.exteriorweaponentity.alpha = default_weapon_alpha;
 612
 613                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval")*2;
 614                 self.lms_traveled_distance = 0;
 615
 616                 if(cvar("spawn_debug"))
 617                 {
 618                                 sprint(self, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 619                                 remove(spot);   // usefull for checking if there are spawnpoints, that let drop through the floor
 620                 }
 621
 622                 //stuffcmd(self, "chase_active 0");
 623                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
 624         } else if(self.classname == "observer") {
 625                 PutObserverInServer ();
 626         }
 627 }
 628
 629 /*
 630 =============
 631 SetNewParms
 632 =============
 633 */
 634 void SetNewParms (void)
 635 {
 636
 637 }
 638
 639 /*
 640 =============
 641 SetChangeParms
 642 =============
 643 */
 644 void SetChangeParms (void)
 645 {
 646
 647 }
 648
 649 /*
 650 =============
 651 ClientKill
 652
 653 Called when a client types 'kill' in the console
 654 =============
 655 */
 656 void ClientKill (void)
 657 {
 658         Damage(self, self, self, 100000, DEATH_KILL, self.origin, '0 0 0');
 659 }
 660
 661 void FixClientCvars(entity e)
 662 {
 663         // send prediction settings to the client
 664         stuffcmd(e, "\nin_bindmap 0 0\n");
 665         stuffcmd(e, strcat("cl_gravity ", ftos(cvar("sv_gravity")), "\n"));
 666         stuffcmd(e, strcat("cl_movement_accelerate ", ftos(cvar("sv_accelerate")), "\n"));
 667         stuffcmd(e, strcat("cl_movement_friction ", ftos(cvar("sv_friction")), "\n"));
 668         stuffcmd(e, strcat("cl_movement_maxspeed ", ftos(cvar("sv_maxspeed")), "\n"));
 669         stuffcmd(e, strcat("cl_movement_airaccelerate ", ftos(cvar("sv_airaccelerate")), "\n"));
 670         stuffcmd(e, strcat("cl_movement_maxairspeed ", ftos(cvar("sv_maxairspeed")), "\n"));
 671         stuffcmd(e, strcat("cl_movement_stopspeed ", ftos(cvar("sv_stopspeed")), "\n"));
 672         stuffcmd(e, strcat("cl_movement_jumpvelocity ", ftos(cvar("g_balance_jumpheight")), "\n"));
 673         stuffcmd(e, strcat("cl_movement_stepheight ", ftos(cvar("sv_stepheight")), "\n"));
 674         stuffcmd(e, strcat("set cl_movement_friction_on_land ", ftos(cvar("sv_friction_on_land")), "\n"));
 675         stuffcmd(e, strcat("set cl_movement_airaccel_qw ", ftos(cvar("sv_airaccel_qw")), "\n"));
 676         stuffcmd(e, strcat("set cl_movement_airaccel_sideways_friction ", ftos(cvar("sv_airaccel_sideways_friction")), "\n"));
 677         stuffcmd(e, "cl_movement_edgefriction 1\n");
 678 }
 679
 680 /*
 681 =============
 682 ClientConnect
 683
 684 Called when a client connects to the server
 685 =============
 686 */
 687 string ColoredTeamName(float t);
 688 //void dom_player_join_team(entity pl);
 689 void ClientConnect (void)
 690 {
 691         local string s;
 692
 693         self.classname = "player_joining";
 694         self.flags = self.flags | FL_CLIENT;
 695         self.version_nagtime = time + 10 + random() * 10;
 696
 697         if(player_count<0)
 698         {
 699                 dprint("BUG player count is lower than zero, this cannot happen!\n");
 700                 player_count = 0;
 701         }
 702
 703         bot_clientconnect();
 704
 705         //if(cvar("g_domination"))
 706         //      dom_player_join_team(self);
 707
 708         //JoinBestTeam(self, FALSE);
 709
 710         if((cvar("sv_spectate") == 1 && !cvar("g_lms")) || cvar("g_campaign")) {
 711                 self.classname = "observer";
 712         } else {
 713                 self.classname = "player";
 714                 campaign_bots_may_start = 1;
 715         }
 716
 717         self.playerid = (playerid_last = playerid_last + 1);
 718         if(cvar("sv_eventlog"))
 719         {
 720                 if(clienttype(self) == CLIENTTYPE_REAL)
 721                         s = "player";
 722                 else
 723                         s = "bot";
 724                 GameLogEcho(strcat(":join:", ftos(self.playerid), ":", s, ":", self.netname), TRUE);
 725                 s = strcat(":team:", ftos(self.playerid), ":");
 726                 s = strcat(s, ftos(self.team));
 727                 GameLogEcho(s, FALSE);
 728         }
 729
 730         //stuffcmd(self, "set tmpviewsize $viewsize \n");
 731
 732         bprint ("^4",self.netname);
 733         bprint ("^4 connected");
 734
 735         if(cvar("g_domination") || cvar("g_ctf"))
 736         {
 737                 bprint(" and joined the ");
 738                 bprint(ColoredTeamName(self.team));
 739         }
 740
 741         bprint("\n");
 742
 743         self.welcomemessage_time = 0;
 744
 745         stuffcmd(self, strcat("exec maps/", mapname, ".cfg\n"));
 746         // TODO: is this being used for anything else than cd tracks?
 747         // Remember: SVC_CDTRACK exists. Maybe it should be used.
 748
 749         FixClientCvars(self);
 750
 751         // waypoint sprites
 752         WaypointSprite_InitClient(self);
 753
 754         // Wazat's grappling hook
 755         SetGrappleHookBindings();
 756
 757         // get autoswitch state from player when he toggles it
 758         stuffcmd(self, "alias autoswitch \"set cl_autoswitch $1 ; cmd autoswitch $1\"\n");
 759
 760         // get version info from player
 761         stuffcmd(self, "cmd clientversion $gameversion\n");
 762
 763         // get other cvars from player
 764         GetCvars(0);
 765
 766         // set cvar for team scoreboard
 767         if (teams_matter)
 768         {
 769                 local float t;
 770                 t = cvar("teamplay");
 771                 // we have to stuff the correct teamplay value because if this is a listen server, this changes the teamplay mode of the server itself, which is bad
 772                 stuffcmd(self, strcat("set teamplay ", ftos(t), "\n"));
 773         }
 774         else
 775                 stuffcmd(self, "set teamplay 0\n");
 776
 777         if(cvar("g_lms"))
 778         {
 779                 self.frags = cvar("fraglimit");
 780                 // no fraglimit was set, so player gets 999 lives
 781                 if(self.frags < 1)
 782                         self.frags = 999;
 783
 784                 self.frags = LMS_NewPlayerLives();
 785                 if(!self.frags)
 786                 {
 787                         self.frags = -666;
 788                 }
 789         }
 790         else if(cvar("g_arena"))
 791         {
 792                 self.classname = "observer";
 793                 Spawnqueue_Insert(self);
 794         }
 795
 796         bot_relinkplayerlist();
 797
 798         self.jointime = time;
 799 }
 800
 801 /*
 802 =============
 803 ClientDisconnect
 804
 805 Called when a client disconnects from the server
 806 =============
 807 */
 808 void(entity e) DropFlag;
 809 .entity chatbubbleentity;
 810 .entity teambubbleentity;
 811 void ClientDisconnect (void)
 812 {
 813         float save;
 814         if(cvar("sv_eventlog"))
 815                 GameLogEcho(strcat(":part:", ftos(self.playerid)), FALSE);
 816         bprint ("^4",self.netname);
 817         bprint ("^4 disconnected\n");
 818
 819         if (self.chatbubbleentity)
 820         {
 821                 remove (self.chatbubbleentity);
 822                 self.chatbubbleentity = world;
 823         }
 824
 825         if (self.teambubbleentity)
 826         {
 827                 remove (self.teambubbleentity);
 828                 self.teambubbleentity = world;
 829         }
 830
 831         WaypointSprite_PlayerGone();
 832
 833         DropAllRunes(self);
 834
 835         if(self.flagcarried)
 836                 DropFlag(self.flagcarried);
 837
 838         DistributeFragsAmongTeam(self, self.team, 1);
 839
 840         save = self.flags;
 841         self.flags = self.flags - (self.flags & FL_CLIENT);
 842         bot_relinkplayerlist();
 843         self.flags = save;
 844
 845         // remove laserdot
 846         if(self.weaponentity)
 847                 if(self.weaponentity.lasertarget)
 848                         remove(self.weaponentity.lasertarget);
 849
 850         if(cvar("g_arena"))
 851         {
 852                 Spawnqueue_Unmark(self);
 853                 Spawnqueue_Remove(self);
 854         }
 855
 856         // free cvars
 857         GetCvars(-1);
 858 }
 859
 860 .float buttonchat;
 861 void() ChatBubbleThink =
 862 {
 863         self.nextthink = time;
 864         if (!self.owner.modelindex || self.owner.chatbubbleentity != self)
 865         {
 866                 self.owner.chatbubbleentity = world;
 867                 remove(self);
 868                 return;
 869         }
 870         setorigin(self, self.owner.origin + '0 0 15' + self.owner.maxs_z * '0 0 1');
 871         if (self.owner.buttonchat && !self.owner.deadflag)
 872                 self.model = self.mdl;
 873         else
 874                 self.model = "";
 875 };
 876
 877 void() UpdateChatBubble =
 878 {
 879         if (!self.modelindex)
 880                 return;
 881         // spawn a chatbubble entity if needed
 882         if (!self.chatbubbleentity)
 883         {
 884                 self.chatbubbleentity = spawn();
 885                 self.chatbubbleentity.owner = self;
 886                 self.chatbubbleentity.exteriormodeltoclient = self;
 887                 self.chatbubbleentity.think = ChatBubbleThink;
 888                 self.chatbubbleentity.nextthink = time;
 889                 setmodel(self.chatbubbleentity, "models/misc/chatbubble.spr");
 890                 setorigin(self.chatbubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
 891                 self.chatbubbleentity.mdl = self.chatbubbleentity.model;
 892                 self.chatbubbleentity.model = "";
 893         }
 894 }
 895
 896
 897 void() TeamBubbleThink =
 898 {
 899         self.nextthink = time;
 900         if (!self.owner.modelindex || self.owner.teambubbleentity != self)
 901         {
 902                 self.owner.teambubbleentity = world;
 903                 remove(self);
 904                 return;
 905         }
 906 //      setorigin(self, self.owner.origin + '0 0 15' + self.owner.maxs_z * '0 0 1');  // bandwidth hog. setattachment does this now
 907         if (self.owner.buttonchat || self.owner.deadflag)
 908                 self.model = "";
 909         else
 910                 self.model = self.mdl;
 911
 912 };
 913
 914 float() TeamBubble_customizeentityforclient
 915 {
 916         return (self.owner != other && self.owner.team == other.team && other.killcount > -666);
 917 }
 918
 919 void() UpdateTeamBubble =
 920 {
 921         if (!self.modelindex || !cvar("teamplay"))
 922                 return;
 923         // spawn a teambubble entity if needed
 924         if (!self.teambubbleentity && cvar("teamplay"))
 925         {
 926                 self.teambubbleentity = spawn();
 927                 self.teambubbleentity.owner = self;
 928                 self.teambubbleentity.exteriormodeltoclient = self;
 929                 self.teambubbleentity.think = TeamBubbleThink;
 930                 self.teambubbleentity.nextthink = time;
 931                 setmodel(self.teambubbleentity, "models/misc/teambubble.spr");
 932 //              setorigin(self.teambubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
 933                 setorigin(self.teambubbleentity, self.teambubbleentity.origin + '0 0 15' + self.maxs_z * '0 0 1');
 934                 setattachment(self.teambubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
 935                 self.teambubbleentity.mdl = self.teambubbleentity.model;
 936                 self.teambubbleentity.model = self.teambubbleentity.mdl;
 937                 self.teambubbleentity.customizeentityforclient = TeamBubble_customizeentityforclient;
 938         }
 939 }
 940
 941 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
 942 // added to the model skins
 943 /*void() UpdateColorModHack =
 944 {
 945         local float c;
 946         c = self.clientcolors & 15;
 947         // LordHavoc: only bothering to support white, green, red, yellow, blue
 948              if (teamplay == 0) self.colormod = '0 0 0';
 949         else if (c ==  0) self.colormod = '1.00 1.00 1.00';
 950         else if (c ==  3) self.colormod = '0.10 1.73 0.10';
 951         else if (c ==  4) self.colormod = '1.73 0.10 0.10';
 952         else if (c == 12) self.colormod = '1.22 1.22 0.10';
 953         else if (c == 13) self.colormod = '0.10 0.10 1.73';
 954         else self.colormod = '1 1 1';
 955 };*/
 956
 957 void respawn(void)
 958 {
 959         CopyBody(1);
 960         PutClientInServer();
 961 }
 962
 963 void player_powerups (void)
 964 {
 965         if (cvar("g_minstagib"))
 966         {
 967                 self.effects = EF_FULLBRIGHT;
 968                 if (self.items & IT_STRENGTH)
 969                 {
 970                         if (time > self.strength_finished)
 971                         {
 972                                 self.alpha = default_player_alpha;
 973                                 self.exteriorweaponentity.alpha = default_weapon_alpha;
 974                                 self.items = self.items - (self.items & IT_STRENGTH);
 975                                 sprint(self, "^3Invisibility has worn off\n");
 976                         }
 977                 }
 978                 else
 979                 {
 980                         if (time < self.strength_finished)
 981                         {
 982                                 self.alpha = cvar("g_minstagib_invis_alpha");
 983                                 self.exteriorweaponentity.alpha = cvar("g_minstagib_invis_alpha");
 984                                 self.items = self.items | IT_STRENGTH;
 985                                 sprint(self, "^3You are invisible\n");
 986                         }
 987                 }
 988
 989                 if (self.items & IT_INVINCIBLE)
 990                 {
 991                         if (time > self.invincible_finished)
 992                         {
 993                                 self.items = self.items - (self.items & IT_INVINCIBLE);
 994                                 sprint(self, "^3Speed has worn off\n");
 995                         }
 996                 }
 997                 else
 998                 {
 999                         if (time < self.invincible_finished)
1000                         {
1001                                 self.items = self.items | IT_INVINCIBLE;
1002                                 sprint(self, "^3You are on speed\n");
1003                         }
1004                 }
1005                 return;
1006         }
1007
1008         self.effects = self.effects - (self.effects & (EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT));
1009         if (self.items & IT_STRENGTH)
1010         {
1011                 self.effects = self.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1012                 if (time > self.strength_finished)
1013                 {
1014                         self.items = self.items - (self.items & IT_STRENGTH);
1015                         sprint(self, "^3Strength has worn off\n");
1016                 }
1017         }
1018         else
1019         {
1020                 if (time < self.strength_finished)
1021                 {
1022                         self.items = self.items | IT_STRENGTH;
1023                         sprint(self, "^3Strength infuses your weapons with devastating power\n");
1024                 }
1025         }
1026         if (self.items & IT_INVINCIBLE)
1027         {
1028                 self.effects = self.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1029                 if (time > self.invincible_finished)
1030                 {
1031                         self.items = self.items - (self.items & IT_INVINCIBLE);
1032                         sprint(self, "^3Shield has worn off\n");
1033                 }
1034         }
1035         else
1036         {
1037                 if (time < self.invincible_finished)
1038                 {
1039                         self.items = self.items | IT_INVINCIBLE;
1040                         sprint(self, "^3Shield surrounds you\n");
1041                 }
1042         }
1043
1044         if (cvar("g_fullbrightplayers"))
1045                 self.effects = self.effects | EF_FULLBRIGHT;
1046
1047         // midair gamemode: damage only while in the air
1048         // if in midair mode, being on ground grants temporary invulnerability
1049         // (this is so that multishot weapon don't clear the ground flag on the
1050         // first damage in the frame, leaving the player vulnerable to the
1051         // remaining hits in the same frame)
1052         if (self.flags & FL_ONGROUND)
1053         if (cvar("g_midair"))
1054                 self.spawnshieldtime = max(self.spawnshieldtime, time + cvar("g_midair_shieldtime"));
1055
1056         if (time < self.spawnshieldtime)
1057                 self.effects = self.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1058 }
1059
1060 float CalcRegen(float current, float stable, float regenfactor)
1061 {
1062         if(current > stable)
1063                 return current;
1064         else if(current > stable - 0.25) // when close enough, "snap"
1065                 return stable;
1066         else
1067                 return min(stable, current + (stable - current) * regenfactor * frametime);
1068 }
1069
1070 void player_regen (void)
1071 {
1072         float maxh, maxa, limith, limita, max_mod, regen_mod, rot_mod, limit_mod;
1073         maxh = cvar("g_balance_health_stable");
1074         maxa = cvar("g_balance_armor_stable");
1075         limith = cvar("g_balance_health_limit");
1076         limita = cvar("g_balance_armor_limit");
1077
1078         if (cvar("g_minstagib") || (cvar("g_lms") && !cvar("g_lms_regenerate")))
1079                 return;
1080
1081         max_mod = regen_mod = rot_mod = limit_mod = 1;
1082
1083         if (self.runes & RUNE_REGEN)
1084         {
1085                 if (self.runes & CURSE_VENOM) // do we have both rune/curse?
1086                 {
1087                         regen_mod = cvar("g_balance_rune_regen_combo_regenrate");
1088                         max_mod = cvar("g_balance_rune_regen_combo_hpmod");
1089                         limit_mod = cvar("g_balance_rune_regen_combo_limitmod");
1090                 }
1091                 else
1092                 {
1093                         regen_mod = cvar("g_balance_rune_regen_regenrate");
1094                         max_mod = cvar("g_balance_rune_regen_hpmod");
1095                         limit_mod = cvar("g_balance_rune_regen_limitmod");
1096                 }
1097         }
1098         else if (self.runes & CURSE_VENOM)
1099         {
1100                 max_mod = cvar("g_balance_curse_venom_hpmod");
1101                 if (self.runes & RUNE_REGEN) // do we have both rune/curse?
1102                         rot_mod = cvar("g_balance_rune_regen_combo_rotrate");
1103                 else
1104                         rot_mod = cvar("g_balance_curse_venom_rotrate");
1105                 limit_mod = cvar("g_balance_curse_venom_limitmod");
1106                 //if (!self.runes & RUNE_REGEN)
1107                 //      rot_mod = cvar("g_balance_curse_venom_rotrate");
1108         }
1109         maxh = maxh * max_mod;
1110         //maxa = maxa * max_mod;
1111         limith = limith * limit_mod;
1112         limita = limita * limit_mod;
1113
1114         if (self.armorvalue > maxa)
1115         {
1116                 if (time > self.pauserotarmor_finished)
1117                 {
1118                         self.armorvalue = max(maxa, self.armorvalue + (maxa - self.armorvalue) * cvar("g_balance_armor_rot") * frametime);
1119                         self.armorvalue = max(maxa, self.armorvalue - cvar("g_balance_armor_rotlinear") * frametime);
1120                 }
1121         }
1122         else if (self.armorvalue < maxa)
1123         {
1124                 if (time > self.pauseregen_finished)
1125                 {
1126                         self.armorvalue = CalcRegen(self.armorvalue, maxa, cvar("g_balance_armor_regen"));
1127                         self.armorvalue = min(maxa, self.armorvalue + cvar("g_balance_armor_regenlinear") * frametime);
1128                 }
1129         }
1130         if (self.health > maxh)
1131         {
1132                 if (time > self.pauserothealth_finished)
1133                 {
1134                         self.health = max(maxh, self.health + (maxh - self.health) * rot_mod*cvar("g_balance_health_rot") * frametime);
1135                         self.health = max(maxh, self.health - rot_mod*cvar("g_balance_health_rotlinear") * frametime);
1136                 }
1137         }
1138         else if (self.health < maxh)
1139         {
1140                 if (time > self.pauseregen_finished)
1141                 {
1142                         self.health = CalcRegen(self.health, maxh, regen_mod * cvar("g_balance_health_regen"));
1143                         self.health = min(maxh, self.health + regen_mod*cvar("g_balance_health_regenlinear") * frametime);
1144                 }
1145         }
1146
1147         if (self.health > limith)
1148                 self.health = limith;
1149         if (self.armorvalue > limita)
1150                 self.armorvalue = limita;
1151
1152         // if player rotted to death...  die!
1153         if(self.health < 1)
1154                 self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
1155 }
1156
1157 /*
1158 ======================
1159 spectate mode routines
1160 ======================
1161 */
1162 void SpectateCopy(entity spectatee) {
1163         self.armortype = spectatee.armortype;
1164         self.armorvalue = spectatee.armorvalue;
1165         self.currentammo = spectatee.currentammo;
1166         self.effects = spectatee.effects;
1167         self.health = spectatee.health;
1168         self.impulse = 0;
1169         self.items = spectatee.items;
1170         self.punchangle = spectatee.punchangle;
1171         self.view_ofs = spectatee.view_ofs;
1172         self.v_angle = spectatee.v_angle;
1173         self.viewzoom = spectatee.viewzoom;
1174         setorigin(self, spectatee.origin);
1175         setsize(self, spectatee.mins, spectatee.maxs);
1176 }
1177
1178 void SpectateUpdate() {
1179         if(!self.enemy)
1180                         PutObserverInServer();
1181
1182         if (self != self.enemy) {
1183                 if(self.enemy.flags & FL_NOTARGET)
1184                         PutObserverInServer();
1185                 SpectateCopy(self.enemy);
1186                 self.dmg_take = self.enemy.dmg_take;
1187                 self.dmg_save = self.enemy.dmg_save;
1188                 self.dmg_inflictor = self.enemy.dmg_inflictor;
1189                 self.fixangle = TRUE;
1190                 self.angles = self.enemy.v_angle;
1191                 //msg_entity = self;
1192                 //WriteByte(MSG_ONE, SVC_SETANGLE);
1193                 //WriteAngle(MSG_ONE, self.enemy.v_angle_x);
1194                 //WriteAngle(MSG_ONE, self.enemy.v_angle_y);
1195                 //WriteAngle(MSG_ONE, self.enemy.v_angle_z);
1196         }
1197 }
1198
1199 float SpectateNext() {
1200         other = find(self.enemy, classname, "player");
1201         if (!other) {
1202                 other = find(other, classname, "player");
1203         }
1204         if (other) {
1205                 self.enemy = other;
1206         }
1207         if(self.enemy.classname == "player") {
1208                 msg_entity = self;
1209                 WriteByte(MSG_ONE, SVC_SETVIEW);
1210                 WriteEntity(MSG_ONE, self.enemy);
1211                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
1212                 SpectateUpdate();
1213                 return 1;
1214         } else {
1215                 return 0;
1216         }
1217 }
1218
1219 /*
1220 =============
1221 ShowRespawnCountdown()
1222
1223 Update a respawn countdown display.
1224 =============
1225 */
1226 void ShowRespawnCountdown()
1227 {
1228         float number;
1229         if(self.deadflag == DEAD_NO) // just respawned?
1230                 return;
1231         else
1232         {
1233                 number = ceil(self.death_time - time);
1234                 if(number <= 0)
1235                         return;
1236                 if(number <= self.respawn_countdown)
1237                 {
1238                         self.respawn_countdown = number - 1;
1239                         if(ceil(self.death_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
1240                                 stuffcmd(self, strcat("play2 announcer/robotic/", ftos(number), ".ogg\n"));
1241                 }
1242         }
1243 }
1244
1245 void LeaveSpectatorMode()
1246 {
1247         if(!cvar("teamplay") || cvar("g_campaign") || cvar("g_balance_teams")) {
1248                 self.classname = "player";
1249                 if(cvar("g_campaign") || cvar("g_balance_teams"))
1250                         JoinBestTeam(self, 0);
1251                 if(cvar("g_campaign"))
1252                         campaign_bots_may_start = 1;
1253                 PutClientInServer();
1254                 if(!(self.flags & FL_NOTARGET))
1255                         bprint ("^4", self.netname, "^4 is playing now\n");
1256                 centerprint(self,"");
1257                 return;
1258         } else {
1259                 stuffcmd(self,"menu_showteamselect\n");
1260                 return;
1261         }
1262 }
1263
1264 /*
1265 =============
1266 PlayerPreThink
1267
1268 Called every frame for each client before the physics are run
1269 =============
1270 */
1271 void() ctf_setstatus;
1272 .float vote_nagtime;
1273 void PlayerPreThink (void)
1274 {
1275         if(strlen(self.netname) > 0)
1276                 if(substring(self.netname, strlen(self.netname) - 1, 1) == "^")
1277                         self.netname = strzone(strcat(substring(self.netname, 0, strlen(self.netname) - 1), " ")); // BROKEN COLORS can be annoying!
1278
1279         // version nagging
1280         if(self.version_nagtime)
1281                 if(self.cvar_g_nexuizversion)
1282                         if(time > self.version_nagtime)
1283                         {
1284                                 if(strstr(self.cvar_g_nexuizversion, "svn", 0) < 0)
1285                                         if(self.cvar_g_nexuizversion != cvar_string("g_nexuizversion"))
1286                                         {
1287                                                 dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Nexuiz ", cvar_string("g_nexuizversion"), "^7, you have ^3Nexuiz ", self.cvar_g_nexuizversion, "\n");
1288                                                 sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Nexuiz ", cvar_string("g_nexuizversion"), "^7, you have ^3Nexuiz ", self.cvar_g_nexuizversion, "\n"));
1289                                         }
1290                                 self.version_nagtime = 0;
1291                         }
1292
1293         // vote nagging
1294         if(self.cvar_scr_centertime)
1295                 if(time > self.vote_nagtime)
1296                 {
1297                         VoteNag();
1298                         self.vote_nagtime = time + self.cvar_scr_centertime * 0.6;
1299                 }
1300
1301         if(self.classname == "player") {
1302                 local vector m1, m2;
1303
1304 //              if(self.netname == "Wazat")
1305 //                      bprint(self.classname, "\n");
1306
1307                 CheckRules_Player();
1308
1309                 if(self.button7)
1310                         PrintWelcomeMessage(self);
1311
1312                 if(cvar("g_lms") || !cvar("sv_spectate"))
1313                 if((time - self.jointime) <= cvar("welcome_message_time"))
1314                         PrintWelcomeMessage(self);
1315
1316                 if (intermission_running)
1317                 {
1318                         IntermissionThink ();   // otherwise a button could be missed between
1319                         return;                                 // the think tics
1320                 }
1321
1322                 if(time > self.teleport_time)
1323                 {
1324                         self.effects = self.effects - (self.effects & EF_NODRAW);
1325                         if(self.weaponentity)
1326                                 self.weaponentity.flags = self.weaponentity.flags - (self.weaponentity.flags & EF_NODRAW);
1327                 }
1328
1329                 Nixnex_GiveCurrentWeapon();
1330                 UpdateSelectedPlayer();
1331
1332                 if (self.deadflag != DEAD_NO)
1333                 {
1334                         float button_pressed, force_respawn;
1335                         player_anim();
1336                         button_pressed = (self.button0 || self.button2 || self.button3 || self.button6 || self.buttonuse);
1337                         force_respawn = (cvar("g_lms") || cvar("g_forced_respawn"));
1338                         if (self.deadflag == DEAD_DYING)
1339                         {
1340                                 if(force_respawn)
1341                                         self.deadflag = DEAD_RESPAWNING;
1342                                 else if(!button_pressed)
1343                                         self.deadflag = DEAD_DEAD;
1344                         }
1345                         else if (self.deadflag == DEAD_DEAD)
1346                         {
1347                                 if(button_pressed)
1348                                         self.deadflag = DEAD_RESPAWNABLE;
1349                         }
1350                         else if (self.deadflag == DEAD_RESPAWNABLE)
1351                         {
1352                                 if(!button_pressed)
1353                                         self.deadflag = DEAD_RESPAWNING;
1354                         }
1355                         else if (self.deadflag == DEAD_RESPAWNING)
1356                         {
1357                                 if(time > self.death_time)
1358                                         respawn();
1359                         }
1360                         ShowRespawnCountdown();
1361                         return;
1362                 }
1363
1364                 if(cvar("g_lms") && !self.deadflag && cvar("g_lms_campcheck_interval"))
1365                 {
1366                         vector dist;
1367
1368                         // calculate player movement (in 2 dimensions only, so jumping on one spot doesn't count as movement)
1369                         dist = self.oldorigin - self.origin;
1370                         dist_z = 0;
1371                         self.lms_traveled_distance += fabs(vlen(dist));
1372
1373                         if(cvar("g_campaign"))
1374                         if(!campaign_bots_may_start)
1375                         {
1376                                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval")*2;
1377                                 self.lms_traveled_distance = 0;
1378                         }
1379
1380                         if(time > self.lms_nextcheck)
1381                         {
1382                                 //sprint(self, "distance: ", ftos(self.lms_traveled_distance), "\n");
1383                                 if(self.lms_traveled_distance < cvar("g_lms_campcheck_distance"))
1384                                 {
1385                                         centerprint(self, cvar_string("g_lms_campcheck_message"));
1386                                         // FIXME KadaverJack: gibbing player here causes playermodel to bounce around, instead of eye.md3
1387                                         // I wasn't able to find out WHY that happens, so I put a workaround in place that shall prevent players from being gibbed :(
1388                                         Damage(self, self, self, bound(0, cvar("g_lms_campcheck_damage"), self.health + self.armorvalue * cvar("g_balance_armor_blockpercent") + 5), DEATH_CAMP, self.origin, '0 0 0');
1389                                 }
1390                                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval");
1391                                 self.lms_traveled_distance = 0;
1392                         }
1393                 }
1394
1395                 if (self.button5 && !self.hook.state)
1396                 {
1397                         if (!self.crouch)
1398                         {
1399                                 self.crouch = TRUE;
1400                                 self.view_ofs = PL_CROUCH_VIEW_OFS;
1401                                 setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX);
1402                         }
1403                 }
1404                 else
1405                 {
1406                         if (self.crouch)
1407                         {
1408                                 tracebox(self.origin, PL_MIN, PL_MAX, self.origin, FALSE, self);
1409                                 if (!trace_startsolid)
1410                                 {
1411                                         self.crouch = FALSE;
1412                                         self.view_ofs = PL_VIEW_OFS;
1413                                         setsize (self, PL_MIN, PL_MAX);
1414                                 }
1415                         }
1416                 }
1417
1418                 if(cvar("sv_defaultcharacter") == 1 && !teams_matter) {
1419                         local string defaultmodel;
1420                         defaultmodel = CheckPlayerModel(cvar_string("sv_defaultplayermodel"));
1421
1422                         if (defaultmodel != self.model)
1423                         {
1424                                 m1 = self.mins;
1425                                 m2 = self.maxs;
1426                                 setmodel_lod (self, defaultmodel);
1427                                 setsize (self, m1, m2);
1428                         }
1429
1430                         if (self.skin != cvar("sv_defaultplayerskin"))
1431                                 self.skin = cvar("sv_defaultplayerskin");
1432                 } else {
1433                         if (self.playermodel != self.model)
1434                         {
1435                                 self.playermodel = CheckPlayerModel(self.playermodel);
1436                                 m1 = self.mins;
1437                                 m2 = self.maxs;
1438                                 setmodel_lod (self, self.playermodel);
1439                                 setsize (self, m1, m2);
1440                         }
1441
1442                         if(teams_matter)
1443                         {
1444                                 if (self.skin != math_mod(stof(self.playerskin), NUM_PLAYERSKINS_TEAMPLAY))
1445                                         self.skin = math_mod(stof(self.playerskin), NUM_PLAYERSKINS_TEAMPLAY);
1446                         }
1447                         else
1448                         {
1449                                 if (self.skin != stof(self.playerskin))
1450                                         self.skin = stof(self.playerskin);
1451                         }
1452                 }
1453
1454                 GrapplingHookFrame();
1455
1456                 W_WeaponFrame();
1457
1458                 {
1459                         float zoomfactor, zoomspeed, zoomdir;
1460                         zoomfactor = self.cvar_cl_zoomfactor;
1461                         if(zoomfactor < 1 || zoomfactor > 16)
1462                                 zoomfactor = 3.1;
1463                         zoomspeed = self.cvar_cl_zoomspeed;
1464                         if(zoomspeed >= 0) // < 0 is instant zoom
1465                                 if(zoomspeed < 0.5 || zoomspeed > 16)
1466                                         zoomspeed = 3.5;
1467
1468                         zoomdir = self.button4;
1469                         if(self.button3)
1470                                 if(self.weapon == WEP_NEX)
1471                                         if(!cvar("g_minstagib"))
1472                                                 zoomdir = 1;
1473
1474                         if(zoomdir)
1475                                 self.has_zoomed = 1;
1476
1477                         if(self.has_zoomed)
1478                         {
1479                                 if(zoomspeed <= 0) // instant zoom
1480                                 {
1481                                         if(zoomdir)
1482                                                 self.viewzoom = 1 / zoomfactor;
1483                                         else
1484                                                 self.viewzoom = 1;
1485                                 }
1486                                 else
1487                                 {
1488                                         // geometric zoom would be:
1489                                         //   self.viewzoom = bound(1 / zoomfactor, self.viewzoom * pow(zoomfactor, (zoomdir ? -1 : 1) * frametime * zoomspeed), 1);
1490                                         // however, testing showed that arithmetic/harmonic zoom works better
1491                                         if(zoomdir)
1492                                                 // self.viewzoom = 1 / bound(1, 1 / self.viewzoom + (zoomdir ? 1 : -1) * frametime * zoomspeed * (zoomfactor - 1), zoomfactor);
1493                                                 // zoom in = arithmetic: 1x, 2x, 3x, 4x, ..., 8x
1494                                                 self.viewzoom = 1 / bound(1, 1 / self.viewzoom + frametime * zoomspeed * (zoomfactor - 1), zoomfactor);
1495                                         else
1496                                                 // self.viewzoom = bound(1 / zoomfactor, self.viewzoom + (zoomdir ? -1 : 1) * frametime * zoomspeed * (1 - 1 / zoomfactor), 1);
1497                                                 // zoom out = harmonic: 8/1x, 8/2x, 8/3x, 8/4x, ..., 8/8x
1498                                                 self.viewzoom = bound(1 / zoomfactor, self.viewzoom + frametime * zoomspeed * (1 - 1 / zoomfactor), 1);
1499                                 }
1500                         }
1501                         else
1502                                 self.viewzoom = min(1, self.viewzoom + frametime); // spawn zoom-in
1503                 }
1504
1505                 player_powerups();
1506                 player_regen();
1507                 player_anim();
1508
1509                 if (cvar("g_minstagib"))
1510                         minstagib_ammocheck();
1511
1512                 ctf_setstatus();
1513
1514                 //self.angles_y=self.v_angle_y + 90;   // temp
1515
1516                 //if (TetrisPreFrame()) return;
1517         } else if(gameover) {
1518                 if (intermission_running)
1519                         IntermissionThink ();   // otherwise a button could be missed between
1520                 return;
1521         } else if(self.classname == "observer") {
1522
1523                 if (self.flags & FL_JUMPRELEASED) {
1524                         if (self.button2 && self.version == cvar("gameversion")) {
1525                                 self.welcomemessage_time = 0;
1526                                 self.flags = self.flags - FL_JUMPRELEASED;
1527                                 LeaveSpectatorMode();
1528                                 return;
1529                         } else if(self.button0 && self.version == cvar("gameversion")) {
1530                                 self.welcomemessage_time = 0;
1531                                 self.flags = self.flags - FL_JUMPRELEASED;
1532                                 if(SpectateNext() == 1) {
1533                                         self.classname = "spectator";
1534                                 }
1535                         }
1536                 } else {
1537                         if (!(self.button0 || self.button2)) {
1538                                 self.flags = self.flags | FL_JUMPRELEASED;
1539                         }
1540                 }
1541                 PrintWelcomeMessage(self);
1542         } else if(self.classname == "spectator") {
1543                 if (self.flags & FL_JUMPRELEASED) {
1544                         if (self.button2 && self.version == cvar("gameversion")) {
1545                                 self.welcomemessage_time = 0;
1546                                 self.flags = self.flags - FL_JUMPRELEASED;
1547                                 LeaveSpectatorMode();
1548                                 return;
1549                         } else if(self.button0) {
1550                                 self.welcomemessage_time = 0;
1551                                 self.flags = self.flags - FL_JUMPRELEASED;
1552                                 if(SpectateNext() == 1) {
1553                                         self.classname = "spectator";
1554                                 } else {
1555                                         self.classname = "observer";
1556                                         PutClientInServer();
1557                                 }
1558                         } else if (self.button3) {
1559                                 self.welcomemessage_time = 0;
1560                                 self.flags = self.flags - FL_JUMPRELEASED;
1561                                 self.classname = "observer";
1562                                 PutClientInServer();
1563                         } else {
1564                                 SpectateUpdate();
1565                         }
1566                 } else {
1567                         if (!(self.button0 || self.button3)) {
1568                                 self.flags = self.flags | FL_JUMPRELEASED;
1569                         }
1570                 }
1571                 PrintWelcomeMessage(self);
1572                 self.flags = self.flags | FL_CLIENT | FL_NOTARGET;
1573         }
1574 }
1575
1576
1577 /*
1578 =============
1579 PlayerPostThink
1580
1581 Called every frame for each client after the physics are run
1582 =============
1583 */
1584 void PlayerPostThink (void)
1585 {
1586         // Savage: Check for nameless players
1587         if (strlen(self.netname) < 1) {
1588                 self.netname = "Player";
1589                 stuffcmd(self, "seta _cl_name Player\n");
1590         }
1591
1592         if(self.classname == "player") {
1593                 CheckRules_Player();
1594                 UpdateChatBubble();
1595                 UpdateTeamBubble();
1596                 if (self.impulse)
1597                         ImpulseCommands ();
1598                 if (intermission_running)
1599                         return;         // intermission or finale
1600
1601                 //PrintWelcomeMessage(self);
1602                 //if (TetrisPostFrame()) return;
1603         } else if (self.classname == "observer") {
1604                 //do nothing
1605         } else if (self.classname == "spectator") {
1606                 //do nothing
1607         }
1608         Arena_Warmup();
1609 }