data/qcsrc/server/cl_client.qc

   1 // let's abuse an existing field
   2 #define SPAWNPOINT_SCORE frags
   3
   4 .float wantswelcomemessage;
   5 .string netname_previous;
   6
   7 void spawnfunc_info_player_survivor (void)
   8 {
   9         spawnfunc_info_player_deathmatch();
  10 }
  11
  12 void spawnfunc_info_player_start (void)
  13 {
  14         spawnfunc_info_player_deathmatch();
  15 }
  16
  17 void spawnfunc_info_player_deathmatch (void)
  18 {
  19         self.classname = "info_player_deathmatch";
  20         relocate_spawnpoint();
  21 }
  22
  23 void spawnpoint_use()
  24 {
  25         if(teams_matter)
  26         if(have_team_spawns)
  27         {
  28                 self.team = activator.team;
  29                 some_spawn_has_been_used = 1;
  30         }
  31 };
  32
  33 // Returns:
  34 //   -1 if a spawn can't be used
  35 //   otherwise, a weight of the spawnpoint
  36 float Spawn_Score(entity spot, entity playerlist, float teamcheck)
  37 {
  38         float shortest, thisdist;
  39         entity player;
  40
  41         // filter out spots for the wrong team
  42         if(teamcheck)
  43         if(spot.team != teamcheck)
  44                 return -1;
  45
  46         if(race_spawns)
  47                 if(spot.target == "")
  48                         return -1;
  49
  50         // filter out spots for assault
  51         if(spot.target != "") {
  52                 local entity ent;
  53                 float good;
  54                 ent = find(world, targetname, spot.target);
  55                 while(ent) {
  56                         if(ent.classname == "target_objective")
  57                         {
  58                                 if(ent.health < 0 || ent.health >= ASSAULT_VALUE_INACTIVE)
  59                                         return -1;
  60                                 good = 1;
  61                         }
  62                         else if(ent.classname == "trigger_race_checkpoint")
  63                         {
  64                                 if(self.classname == "player") // spectators may spawn everywhere
  65                                 {
  66                                         if(g_race_qualifying)
  67                                         {
  68                                                 // spawn at first
  69                                                 if(ent.race_checkpoint != 0)
  70                                                         return -1;
  71                                                 if(spot.race_place != race_lowest_place_spawn)
  72                                                         return -1;
  73                                         }
  74                                         else
  75                                         {
  76                                                 if(ent.race_checkpoint != race_PreviousCheckpoint(self.race_checkpoint))
  77                                                         return -1;
  78                                                 float pl;
  79                                                 pl = self.race_place;
  80                                                 if(pl > race_highest_place_spawn)
  81                                                         pl = 0;
  82                                                 if(spot.race_place != pl)
  83                                                         return -1;
  84                                         }
  85                                 }
  86                                 good = 1;
  87                         }
  88                         else
  89                         {
  90                         }
  91                         ent = find(ent, targetname, spot.target);
  92                 }
  93
  94                 if(!good)
  95                         return -1;
  96         }
  97
  98         player = playerlist;
  99         shortest = vlen(world.maxs - world.mins);
 100         for(player = playerlist; player; player = player.chain)
 101                 if (player != self)
 102                 {
 103                         thisdist = vlen(player.origin - spot.origin);
 104                         if (thisdist < shortest)
 105                                 shortest = thisdist;
 106                 }
 107         return shortest;
 108 }
 109
 110 float spawn_allbad;
 111 float spawn_allgood;
 112 entity Spawn_FilterOutBadSpots(entity firstspot, entity playerlist, float mindist, float teamcheck)
 113 {
 114         local entity spot, spotlist, spotlistend;
 115         spawn_allgood = TRUE;
 116         spawn_allbad = TRUE;
 117
 118         spotlist = world;
 119         spotlistend = world;
 120
 121         for(spot = firstspot; spot; spot = spot.chain)
 122         {
 123                 spot.SPAWNPOINT_SCORE = Spawn_Score(spot, playerlist, teamcheck);
 124
 125                 if(cvar("spawn_debugview"))
 126                 {
 127                         setmodel(spot, "models/runematch/rune.mdl");
 128                         if(spot.SPAWNPOINT_SCORE < mindist)
 129                         {
 130                                 spot.colormod = '1 0 0';
 131                                 spot.scale = 1;
 132                         }
 133                         else
 134                         {
 135                                 spot.colormod = '0 1 0';
 136                                 spot.scale = spot.SPAWNPOINT_SCORE / mindist;
 137                         }
 138                 }
 139
 140                 if(spot.SPAWNPOINT_SCORE >= 0) // spawning allowed here
 141                 {
 142                         if(spot.SPAWNPOINT_SCORE < mindist)
 143                         {
 144                                 // too short distance
 145                                 spawn_allgood = FALSE;
 146                         }
 147                         else
 148                         {
 149                                 // perfect
 150                                 spawn_allbad = FALSE;
 151
 152                                 if(spotlistend)
 153                                         spotlistend.chain = spot;
 154                                 spotlistend = spot;
 155                                 if(!spotlist)
 156                                         spotlist = spot;
 157
 158                                 /*
 159                                 if(teamcheck)
 160                                 if(spot.team != teamcheck)
 161                                         error("invalid spawn added");
 162
 163                                 print("added ", etos(spot), "\n");
 164                                 */
 165                         }
 166                 }
 167         }
 168         if(spotlistend)
 169                 spotlistend.chain = world;
 170
 171         /*
 172                 entity e;
 173                 if(teamcheck)
 174                         for(e = spotlist; e; e = e.chain)
 175                         {
 176                                 print("seen ", etos(e), "\n");
 177                                 if(e.team != teamcheck)
 178                                         error("invalid spawn found");
 179                         }
 180         */
 181
 182         return spotlist;
 183 }
 184
 185 entity Spawn_WeightedPoint(entity firstspot, float lower, float upper, float exponent)
 186 {
 187         // weight of a point: bound(lower, mindisttoplayer, upper)^exponent
 188         // multiplied by spot.cnt (useful if you distribute many spawnpoints in a small area)
 189         local entity spot;
 190
 191         RandomSelection_Init();
 192         for(spot = firstspot; spot; spot = spot.chain)
 193                 RandomSelection_Add(spot, 0, pow(bound(lower, spot.SPAWNPOINT_SCORE, upper), exponent) * spot.cnt, spot.SPAWNPOINT_SCORE >= lower);
 194
 195         return RandomSelection_chosen_ent;
 196 }
 197
 198 /*
 199 =============
 200 SelectSpawnPoint
 201
 202 Finds a point to respawn
 203 =============
 204 */
 205 entity SelectSpawnPoint (float anypoint)
 206 {
 207         local float teamcheck;
 208         local entity firstspot_new;
 209         local entity spot, firstspot, playerlist;
 210
 211         spot = find (world, classname, "testplayerstart");
 212         if (spot)
 213                 return spot;
 214
 215         teamcheck = 0;
 216
 217         if(!anypoint && have_team_spawns)
 218                 teamcheck = self.team;
 219
 220         // get the list of players
 221         playerlist = findchain(classname, "player");
 222         // get the entire list of spots
 223         firstspot = findchain(classname, "info_player_deathmatch");
 224         // filter out the bad ones
 225         // (note this returns the original list if none survived)
 226         firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, 100, teamcheck);
 227         if(!firstspot_new)
 228                 firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, -1, teamcheck);
 229         firstspot = firstspot_new;
 230
 231         // there is 50/50 chance of choosing a random spot or the furthest spot
 232         // (this means that roughly every other spawn will be furthest, so you
 233         // usually won't get fragged at spawn twice in a row)
 234         if (arena_roundbased)
 235         {
 236                 firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, 800, teamcheck);
 237                 if(firstspot_new)
 238                         firstspot = firstspot_new;
 239                 spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 240         }
 241         else if (random() > cvar("g_spawn_furthest"))
 242                 spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 243         else
 244                 spot = Spawn_WeightedPoint(firstspot, 1, 5000, 5); // chooses a far far away spawnpoint
 245
 246         if(cvar("spawn_debugview"))
 247         {
 248                 print("spot mindistance: ", ftos(spot.SPAWNPOINT_SCORE), "\n");
 249
 250                 entity e;
 251                 if(teamcheck)
 252                         for(e = firstspot; e; e = e.chain)
 253                                 if(e.team != teamcheck)
 254                                         error("invalid spawn found");
 255         }
 256
 257         if (!spot)
 258         {
 259                 if(cvar("spawn_debug"))
 260                         GotoNextMap();
 261                 else
 262                 {
 263                         if(some_spawn_has_been_used)
 264                                 return world; // team can't spawn any more, because of actions of other team
 265                         else
 266                                 error("Cannot find a spawn point - please fix the map!");
 267                 }
 268         }
 269
 270         return spot;
 271 }
 272
 273 /*
 274 =============
 275 CheckPlayerModel
 276
 277 Checks if the argument string can be a valid playermodel.
 278 Returns a valid one in doubt.
 279 =============
 280 */
 281 string FallbackPlayerModel = "models/player/marine.zym";
 282 string CheckPlayerModel(string plyermodel) {
 283         if(strlen(plyermodel) < 4)
 284                 return FallbackPlayerModel;
 285         if( substring(plyermodel,0,14) != "models/player/")
 286                 return FallbackPlayerModel;
 287         else if(cvar("sv_servermodelsonly"))
 288         {
 289                 if(substring(plyermodel,strlen(plyermodel)-4,4) != ".zym")
 290                 if(substring(plyermodel,strlen(plyermodel)-4,4) != ".dpm")
 291                 if(substring(plyermodel,strlen(plyermodel)-4,4) != ".md3")
 292                 if(substring(plyermodel,strlen(plyermodel)-4,4) != ".psk")
 293                         return FallbackPlayerModel;
 294                 if(plyermodel != strtolower(plyermodel))
 295                         return FallbackPlayerModel;
 296                 if(!fexists(plyermodel))
 297                         return FallbackPlayerModel;
 298         }
 299         return plyermodel;
 300 }
 301
 302 /*
 303 =============
 304 Client_customizeentityforclient
 305
 306 LOD reduction
 307 =============
 308 */
 309 float Client_customizeentityforclient()
 310 {
 311 #ifdef ALLOW_VARIABLE_LOD
 312         // self: me
 313         // other: the player viewing me
 314         float distance;
 315         float f;
 316
 317         if(self.flags & FL_NOTARGET) // we don't need LOD for spectators
 318                 return TRUE;
 319
 320         if(other.cvar_cl_playerdetailreduction <= 0)
 321         {
 322                 if(other.cvar_cl_playerdetailreduction <= -2)
 323                         self.modelindex = self.modelindex_lod2;
 324                 else if(other.cvar_cl_playerdetailreduction <= -1)
 325                         self.modelindex = self.modelindex_lod1;
 326                 else
 327                         self.modelindex = self.modelindex_lod0;
 328         }
 329         else
 330         {
 331                 distance = vlen(self.origin - other.origin);
 332                 f = (distance + 100.0) * other.cvar_cl_playerdetailreduction;
 333                 if(f > 10000)
 334                         self.modelindex = self.modelindex_lod2;
 335                 else if(f > 5000)
 336                         self.modelindex = self.modelindex_lod1;
 337                 else
 338                         self.modelindex = self.modelindex_lod0;
 339         }
 340 #endif
 341
 342         return TRUE;
 343 }
 344
 345 void UpdatePlayerSounds();
 346 void setmodel_lod(entity e, string modelname)
 347 {
 348 #ifdef ALLOW_VARIABLE_LOD
 349         string s;
 350
 351         // FIXME: this only supports 3-letter extensions
 352         s = strcat(substring(modelname, 0, strlen(modelname) - 4), "_1", substring(modelname, 0, strlen(modelname) - 4));
 353         if(fexists(s))
 354         {
 355                 precache_model(s);
 356                 setmodel(e, s); // players have high precision
 357                 self.modelindex_lod1 = self.modelindex;
 358         }
 359         else
 360                 self.modelindex_lod1 = -1;
 361
 362         s = strcat(substring(modelname, 0, strlen(modelname) - 4), "_2", substring(modelname, 0, strlen(modelname) - 4));
 363         if(fexists(s))
 364         {
 365                 precache_model(s);
 366                 setmodel(e, s); // players have high precision
 367                 self.modelindex_lod2 = self.modelindex;
 368         }
 369         else
 370                 self.modelindex_lod2 = -1;
 371
 372         precache_model(modelname);
 373         setmodel(e, modelname); // players have high precision
 374         self.modelindex_lod0 = self.modelindex;
 375
 376         if(self.modelindex_lod1 < 0)
 377                 self.modelindex_lod1 = self.modelindex;
 378
 379         if(self.modelindex_lod2 < 0)
 380                 self.modelindex_lod2 = self.modelindex;
 381 #else
 382         precache_model(modelname);
 383         setmodel(e, modelname); // players have high precision
 384 #endif
 385         player_setupanimsformodel();
 386         UpdatePlayerSounds();
 387 }
 388
 389 /*
 390 =============
 391 PutObserverInServer
 392
 393 putting a client as observer in the server
 394 =============
 395 */
 396 void PutObserverInServer (void)
 397 {
 398         entity  spot;
 399
 400         race_PreSpawnObserver();
 401
 402         spot = SelectSpawnPoint (TRUE);
 403         if(!spot)
 404                 error("No spawnpoints for observers?!?\n");
 405         RemoveGrapplingHook(self); // Wazat's Grappling Hook
 406
 407         if(clienttype(self) == CLIENTTYPE_REAL)
 408         {
 409                 msg_entity = self;
 410                 WriteByte(MSG_ONE, SVC_SETVIEW);
 411                 WriteEntity(MSG_ONE, self);
 412         }
 413
 414         DropAllRunes(self);
 415         kh_Key_DropAll(self, TRUE);
 416
 417         Portal_ClearAll(self);
 418
 419         if(self.flagcarried)
 420                 DropFlag(self.flagcarried, world, world);
 421
 422         WaypointSprite_PlayerDead();
 423
 424         if(self.killcount != -666)
 425         {
 426                 if(g_lms)
 427                 {
 428                         if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
 429                                 bprint ("^4", self.netname, "^4 has no more lives left\n");
 430                         else
 431                                 bprint ("^4", self.netname, "^4 is spectating now\n"); // TODO turn this into a proper forfeit?
 432                 }
 433                 else
 434                         bprint ("^4", self.netname, "^4 is spectating now\n");
 435         }
 436
 437         PlayerScore_Clear(self); // clear scores when needed
 438
 439         self.spectatortime = time;
 440
 441         self.classname = "observer";
 442         self.iscreature = FALSE;
 443         self.health = -666;
 444         self.takedamage = DAMAGE_NO;
 445         self.solid = SOLID_NOT;
 446         self.movetype = MOVETYPE_NOCLIP;
 447         self.flags = FL_CLIENT | FL_NOTARGET;
 448         self.armorvalue = 666;
 449         self.effects = 0;
 450         self.armorvalue = cvar("g_balance_armor_start");
 451         self.pauserotarmor_finished = 0;
 452         self.pauserothealth_finished = 0;
 453         self.pauseregen_finished = 0;
 454         self.damageforcescale = 0;
 455         self.death_time = 0;
 456         self.dead_frame = 0;
 457         self.alpha = 0;
 458         self.scale = 0;
 459         self.fade_time = 0;
 460         self.pain_frame = 0;
 461         self.pain_finished = 0;
 462         self.strength_finished = 0;
 463         self.invincible_finished = 0;
 464         self.pushltime = 0;
 465         self.think = SUB_Null;
 466         self.nextthink = 0;
 467         self.hook_time = 0;
 468         self.runes = 0;
 469         self.deadflag = DEAD_NO;
 470         self.angles = spot.angles;
 471         self.angles_z = 0;
 472         self.fixangle = TRUE;
 473         self.crouch = FALSE;
 474
 475         self.view_ofs = PL_VIEW_OFS;
 476         setorigin (self, spot.origin);
 477         setsize (self, '0 0 0', '0 0 0');
 478         self.oldorigin = self.origin;
 479         self.items = 0;
 480         self.weapons = 0;
 481         self.model = "";
 482         self.modelindex = 0;
 483         self.weapon = 0;
 484         self.weaponmodel = "";
 485         self.weaponentity = world;
 486         self.killcount = -666;
 487         self.velocity = '0 0 0';
 488         self.avelocity = '0 0 0';
 489         self.punchangle = '0 0 0';
 490         self.punchvector = '0 0 0';
 491         self.oldvelocity = self.velocity;
 492         self.customizeentityforclient = Client_customizeentityforclient;
 493         self.wantswelcomemessage = 1;
 494
 495         if(g_arena)
 496         {
 497                 if(self.version_mismatch)
 498                 {
 499                         Spawnqueue_Unmark(self);
 500                         Spawnqueue_Remove(self);
 501                 }
 502                 else
 503                 {
 504                         Spawnqueue_Insert(self);
 505                 }
 506         }
 507         else if(g_lms)
 508         {
 509                 // Only if the player cannot play at all
 510                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) == 666)
 511                         self.frags = -666;
 512                 else
 513                         self.frags = -667;
 514         }
 515         else
 516                 self.frags = -666;
 517 }
 518
 519 float RestrictSkin(float s)
 520 {
 521         if(!teams_matter)
 522                 return s;
 523         if(s == 6)
 524                 return 6;
 525         return mod(s, 3);
 526 }
 527
 528 void FixPlayermodel()
 529 {
 530         local string defaultmodel;
 531         local float defaultskin;
 532         local vector m1, m2;
 533
 534         defaultmodel = "";
 535
 536         if(cvar("sv_defaultcharacter") == 1) {
 537                 defaultskin = 0;
 538
 539                 if(teams_matter)
 540                 {
 541                         defaultmodel = cvar_string(strcat("sv_defaultplayermodel_", Team_ColorNameLowerCase(self.team)));
 542                         defaultskin = cvar(strcat("sv_defaultplayerskin_", Team_ColorNameLowerCase(self.team)));
 543                 }
 544
 545                 if(defaultmodel == "")
 546                 {
 547                         defaultmodel = cvar_string("sv_defaultplayermodel");
 548                         defaultskin = cvar("sv_defaultplayerskin");
 549                 }
 550         }
 551
 552         if(self.modelindex == 0)
 553         {
 554                 if(self.model != "")
 555                         bprint("\{1}^1Player ", self.netname, "^1 has a zero modelindex, trying to fix...\n");
 556                 self.model = ""; // force the != checks to return true
 557         }
 558
 559         if(defaultmodel != "")
 560         {
 561                 if (defaultmodel != self.model)
 562                 {
 563                         m1 = self.mins;
 564                         m2 = self.maxs;
 565                         setmodel_lod (self, defaultmodel);
 566                         setsize (self, m1, m2);
 567                 }
 568
 569                 self.skin = defaultskin;
 570         } else {
 571                 if (self.playermodel != self.model)
 572                 {
 573                         self.playermodel = CheckPlayerModel(self.playermodel);
 574                         m1 = self.mins;
 575                         m2 = self.maxs;
 576                         setmodel_lod (self, self.playermodel);
 577                         setsize (self, m1, m2);
 578                 }
 579
 580                 self.skin = RestrictSkin(stof(self.playerskin));
 581         }
 582
 583         if(!teams_matter)
 584                 if(strlen(cvar_string("sv_defaultplayercolors")))
 585                         if(self.clientcolors != cvar("sv_defaultplayercolors"))
 586                                 setcolor(self, cvar("sv_defaultplayercolors"));
 587 }
 588
 589 /*
 590 =============
 591 PutClientInServer
 592
 593 Called when a client spawns in the server
 594 =============
 595 */
 596 //void() ctf_playerchanged;
 597 void PutClientInServer (void)
 598 {
 599         if(clienttype(self) == CLIENTTYPE_BOT)
 600         {
 601                 self.classname = "player";
 602         }
 603         else if(clienttype(self) == CLIENTTYPE_REAL)
 604         {
 605                 msg_entity = self;
 606                 WriteByte(MSG_ONE, SVC_SETVIEW);
 607                 WriteEntity(MSG_ONE, self);
 608         }
 609
 610         // player is dead and becomes observer
 611         // FIXME fix LMS scoring for new system
 612         if(g_lms)
 613         {
 614                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
 615                         self.classname = "observer";
 616         }
 617
 618         if(g_arena)
 619         if(!self.spawned)
 620                 self.classname = "observer";
 621
 622         if(self.classname == "player") {
 623                 entity spot, oldself;
 624                 string s;
 625
 626                 race_PreSpawn();
 627
 628                 spot = SelectSpawnPoint (FALSE);
 629                 if(!spot)
 630                 {
 631                         centerprint(self, "Sorry, no spawnpoints available!\nHope your team can fix it...");
 632                         return; // spawn failed
 633                 }
 634
 635                 RemoveGrapplingHook(self); // Wazat's Grappling Hook
 636
 637                 self.classname = "player";
 638                 self.iscreature = TRUE;
 639                 self.movetype = MOVETYPE_WALK;
 640                 self.solid = SOLID_SLIDEBOX;
 641                 self.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP;
 642                 if(independent_players)
 643                         MAKE_INDEPENDENT_PLAYER(self);
 644                 self.flags = FL_CLIENT;
 645                 self.takedamage = DAMAGE_AIM;
 646                 if(g_minstagib)
 647                         self.effects = EF_FULLBRIGHT;
 648                 else
 649                         self.effects = 0;
 650                 self.air_finished = time + 12;
 651                 self.dmg = 2;
 652
 653                 if(inWarmupStage)
 654                 {
 655                         self.ammo_shells = warmup_start_ammo_shells;
 656                         self.ammo_nails = warmup_start_ammo_nails;
 657                         self.ammo_rockets = warmup_start_ammo_rockets;
 658                         self.ammo_cells = warmup_start_ammo_cells;
 659                         self.health = warmup_start_health;
 660                         self.armorvalue = warmup_start_armorvalue;
 661                         self.weapons = warmup_start_weapons;
 662                 }
 663                 else
 664                 {
 665                         self.ammo_shells = start_ammo_shells;
 666                         self.ammo_nails = start_ammo_nails;
 667                         self.ammo_rockets = start_ammo_rockets;
 668                         self.ammo_cells = start_ammo_cells;
 669                         self.health = start_health;
 670                         self.armorvalue = start_armorvalue;
 671                         self.weapons = start_weapons;
 672                 }
 673                 self.items = start_items;
 674                 self.switchweapon = w_getbestweapon(self);
 675                 self.cnt = self.switchweapon;
 676                 self.weapon = 0;
 677                 self.jump_interval = time;
 678
 679                 self.spawnshieldtime = time + cvar("g_spawnshieldtime");
 680                 self.pauserotarmor_finished = time + cvar("g_balance_pause_armor_rot_spawn");
 681                 self.pauserothealth_finished = time + cvar("g_balance_pause_health_rot_spawn");
 682                 self.pauseregen_finished = time + cvar("g_balance_pause_health_regen_spawn");
 683                 //extend the pause of rotting if client was reset at the beginning of the countdown
 684                 if(!cvar("sv_ready_restart_after_countdown") && time < game_starttime) { // TODO why is this cvar NOTted?
 685                         self.spawnshieldtime += game_starttime - time;
 686                         self.pauserotarmor_finished += game_starttime - time;
 687                         self.pauserothealth_finished += game_starttime - time;
 688                         self.pauseregen_finished += game_starttime - time;
 689                 }
 690                 self.damageforcescale = 2;
 691                 self.death_time = 0;
 692                 self.dead_frame = 0;
 693                 self.alpha = 0;
 694                 self.scale = 0;
 695                 self.fade_time = 0;
 696                 self.pain_frame = 0;
 697                 self.pain_finished = 0;
 698                 self.strength_finished = 0;
 699                 self.invincible_finished = 0;
 700                 self.pushltime = 0;
 701                 //self.speed_finished = 0;
 702                 //self.slowmo_finished = 0;
 703                 // players have no think function
 704                 self.think = SUB_Null;
 705                 self.nextthink = 0;
 706                 self.hook_time = 0;
 707
 708                 self.runes = 0;
 709
 710                 self.deadflag = DEAD_NO;
 711
 712                 self.angles = spot.angles;
 713
 714                 self.angles_z = 0; // never spawn tilted even if the spot says to
 715                 self.fixangle = TRUE; // turn this way immediately
 716                 self.velocity = '0 0 0';
 717                 self.avelocity = '0 0 0';
 718                 self.punchangle = '0 0 0';
 719                 self.punchvector = '0 0 0';
 720                 self.oldvelocity = self.velocity;
 721
 722                 msg_entity = self;
 723                 WRITESPECTATABLE_MSG_ONE({
 724                         WriteByte(MSG_ONE, SVC_TEMPENTITY);
 725                         WriteByte(MSG_ONE, TE_CSQC_SPAWN);
 726                 });
 727
 728                 self.customizeentityforclient = Client_customizeentityforclient;
 729
 730                 self.model = "";
 731                 FixPlayermodel();
 732
 733                 self.crouch = FALSE;
 734                 self.view_ofs = PL_VIEW_OFS;
 735                 setsize (self, PL_MIN, PL_MAX);
 736                 self.spawnorigin = spot.origin;
 737                 setorigin (self, spot.origin + '0 0 1' * (1 - self.mins_z - 24));
 738                 // don't reset back to last position, even if new position is stuck in solid
 739                 self.oldorigin = self.origin;
 740
 741                 if(g_arena)
 742                 {
 743                         Spawnqueue_Remove(self);
 744                         Spawnqueue_Mark(self);
 745                 }
 746
 747                 self.event_damage = PlayerDamage;
 748
 749                 self.bot_attack = TRUE;
 750
 751                 self.statdraintime = time + 5;
 752                 self.BUTTON_ATCK = self.BUTTON_JUMP = self.BUTTON_ATCK2 = 0;
 753
 754                 if(self.killcount == -666) {
 755                         PlayerScore_Clear(self);
 756                         self.killcount = 0;
 757                         self.frags = 0;
 758                 }
 759
 760                 self.cnt = WEP_LASER;
 761                 self.nixnex_lastchange_id = -1;
 762
 763                 CL_SpawnWeaponentity();
 764                 self.alpha = default_player_alpha;
 765                 self.colormod = '1 1 1' * cvar("g_player_brightness");
 766                 self.exteriorweaponentity.alpha = default_weapon_alpha;
 767
 768                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval")*2;
 769                 self.lms_traveled_distance = 0;
 770                 self.speedrunning = FALSE;
 771
 772                 race_PostSpawn(spot);
 773
 774                 if(cvar("spawn_debug"))
 775                 {
 776                         sprint(self, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 777                         remove(spot);   // usefull for checking if there are spawnpoints, that let drop through the floor
 778                 }
 779
 780                 //stuffcmd(self, "chase_active 0");
 781                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
 782
 783                 if (cvar("g_spawnsound"))
 784                         sound (self, CHAN_TRIGGER, "misc/spawn.wav", VOL_BASE, ATTN_NORM);
 785
 786                 if(g_assault) {
 787                         if(self.team == assault_attacker_team)
 788                                 centerprint(self, "You are attacking!\n");
 789                         else
 790                                 centerprint(self, "You are defending!\n");
 791                 }
 792
 793                 target_voicescript_clear(self);
 794
 795                 s = spot.target;
 796                 spot.target = string_null;
 797                         oldself = self;
 798                         self = spot;
 799                                 activator = oldself;
 800                                         SUB_UseTargets();
 801                                 activator = world;
 802                         self = oldself;
 803                 spot.target = s;
 804
 805         } else if(self.classname == "observer") {
 806                 PutObserverInServer ();
 807         }
 808
 809         //if(g_ctf)
 810         //      ctf_playerchanged();
 811 }
 812
 813 /*
 814 =============
 815 SendCSQCInfo
 816
 817 Send whatever CSQC needs NOW and cannot wait for SendServerInfo to happen...
 818 =============
 819 */
 820 void SendCSQCInfo(void)
 821 {
 822         float i;
 823         if(clienttype(self) != CLIENTTYPE_REAL)
 824                 return;
 825         msg_entity = self;
 826         WriteByte(MSG_ONE, SVC_TEMPENTITY);
 827         WriteByte(MSG_ONE, TE_CSQC_INIT);
 828         WriteShort(MSG_ONE, CSQC_REVISION);
 829         WriteByte(MSG_ONE, maxclients);
 830         for(i = 1; i <= 24; ++i)
 831                 WriteByte(MSG_ONE, (get_weaponinfo(i)).impulse + 1);
 832         WriteCoord(MSG_ONE, hook_shotorigin_x);
 833         WriteCoord(MSG_ONE, hook_shotorigin_y);
 834         WriteCoord(MSG_ONE, hook_shotorigin_z);
 835 }
 836
 837 /*
 838 =============
 839 SetNewParms
 840 =============
 841 */
 842 void SetNewParms (void)
 843 {
 844         // initialize parms for a new player
 845         parm1 = -(86400 * 366);
 846 }
 847
 848 /*
 849 =============
 850 SetChangeParms
 851 =============
 852 */
 853 void SetChangeParms (void)
 854 {
 855         // save parms for level change
 856         parm1 = self.parm_idlesince - time;
 857 }
 858
 859 /*
 860 =============
 861 DecodeLevelParms
 862 =============
 863 */
 864 void DecodeLevelParms (void)
 865 {
 866         // load parms
 867         self.parm_idlesince = parm1;
 868         if(self.parm_idlesince == -(86400 * 366))
 869                 self.parm_idlesince = time;
 870 }
 871
 872 /*
 873 =============
 874 ClientKill
 875
 876 Called when a client types 'kill' in the console
 877 =============
 878 */
 879
 880 void ClientKill_Now_TeamChange()
 881 {
 882         if(self.killindicator_teamchange == -1)
 883         {
 884                 self.team = -1;
 885                 JoinBestTeam( self, FALSE, FALSE );
 886         }
 887         else
 888         {
 889                 SV_ChangeTeam(self.killindicator_teamchange - 1);
 890         }
 891 }
 892
 893 void ClientKill_Now()
 894 {
 895         if(self.killindicator_teamchange)
 896                 ClientKill_Now_TeamChange();
 897
 898         // in any case:
 899         Damage(self, self, self, 100000, DEATH_KILL, self.origin, '0 0 0');
 900
 901         if(self.killindicator)
 902         {
 903                 dprint("Cleaned up after a leaked kill indicator.\n");
 904                 remove(self.killindicator);
 905                 self.killindicator = world;
 906         }
 907 }
 908 void KillIndicator_Think()
 909 {
 910         if (!self.owner.modelindex)
 911         {
 912                 self.owner.killindicator = world;
 913                 remove(self);
 914                 return;
 915         }
 916
 917         if(self.cnt <= 0)
 918         {
 919                 self = self.owner;
 920                 ClientKill_Now(); // no oldself needed
 921                 return;
 922         }
 923         else
 924         {
 925                 if(self.cnt <= 10)
 926                         setmodel(self, strcat("models/sprites/", ftos(self.cnt), ".spr32"));
 927                 if(clienttype(self.owner) == CLIENTTYPE_REAL)
 928                 {
 929                         if(self.cnt <= 10)
 930                                 announce(self.owner, strcat("announcer/robotic/", ftos(self.cnt), ".wav"));
 931                         if(self.owner.killindicator_teamchange)
 932                         {
 933                                 if(self.owner.killindicator_teamchange == -1)
 934                                         centerprint(self.owner, strcat("Changing team in ", ftos(self.cnt), " seconds"));
 935                                 else
 936                                         centerprint(self.owner, strcat("Changing to ", ColoredTeamName(self.owner.killindicator_teamchange), " in ", ftos(self.cnt), " seconds"));
 937                         }
 938                         else
 939                                 centerprint(self.owner, strcat("^1Suicide in ", ftos(self.cnt), " seconds"));
 940                 }
 941                 self.nextthink = time + 1;
 942                 self.cnt -= 1;
 943         }
 944 }
 945
 946 void ClientKill_TeamChange (float targetteam) // 0 = don't change, -1 = auto
 947 {
 948         float killtime;
 949         entity e;
 950         killtime = cvar("g_balance_kill_delay");
 951
 952         self.killindicator_teamchange = targetteam;
 953
 954         if(!self.killindicator)
 955         {
 956                 if(killtime <= 0 || !self.modelindex || self.deadflag != DEAD_NO)
 957                 {
 958                         ClientKill_Now();
 959                 }
 960                 else
 961                 {
 962                         self.killindicator = spawn();
 963                         self.killindicator.owner = self;
 964                         self.killindicator.scale = 0.5;
 965                         setattachment(self.killindicator, self, "");
 966                         setorigin(self.killindicator, '0 0 52');
 967                         self.killindicator.think = KillIndicator_Think;
 968                         self.killindicator.nextthink = time + (self.lip) * 0.05;
 969                         self.killindicator.cnt = ceil(killtime);
 970                         self.killindicator.count = bound(0, ceil(killtime), 10);
 971                         sprint(self, strcat("^1You'll be dead in ", ftos(self.killindicator.cnt), " seconds\n"));
 972
 973                         for(e = world; (e = find(e, classname, "body")) != world; )
 974                         {
 975                                 if(e.enemy != self)
 976                                         continue;
 977                                 e.killindicator = spawn();
 978                                 e.killindicator.owner = e;
 979                                 e.killindicator.scale = 0.5;
 980                                 setattachment(e.killindicator, e, "");
 981                                 setorigin(e.killindicator, '0 0 52');
 982                                 e.killindicator.think = KillIndicator_Think;
 983                                 e.killindicator.nextthink = time + (e.lip) * 0.05;
 984                                 e.killindicator.cnt = ceil(killtime);
 985                         }
 986                         self.lip = 0;
 987                 }
 988         }
 989         if(self.killindicator)
 990         {
 991                 if(targetteam)
 992                         self.killindicator.colormod = TeamColor(targetteam);
 993                 else
 994                         self.killindicator.colormod = '0 0 0';
 995         }
 996 }
 997
 998 void ClientKill (void)
 999 {
1000         ClientKill_TeamChange(0);
1001 }
1002
1003 void DoTeamChange(float destteam)
1004 {
1005         float t, c0;
1006         if(!cvar("teamplay"))
1007         {
1008                 if(destteam >= 0)
1009                         SetPlayerColors(self, destteam);
1010                 return;
1011         }
1012         if(self.classname == "player")
1013         if(destteam == -1)
1014         {
1015                 CheckAllowedTeams(self);
1016                 t = FindSmallestTeam(self, TRUE);
1017                 switch(self.team)
1018                 {
1019                         case COLOR_TEAM1: c0 = c1; break;
1020                         case COLOR_TEAM2: c0 = c2; break;
1021                         case COLOR_TEAM3: c0 = c3; break;
1022                         case COLOR_TEAM4: c0 = c4; break;
1023                         default:          c0 = 999;
1024                 }
1025                 switch(t)
1026                 {
1027                         case 1:
1028                                 if(c0 > c1)
1029                                         destteam = COLOR_TEAM1;
1030                                 break;
1031                         case 2:
1032                                 if(c0 > c2)
1033                                         destteam = COLOR_TEAM2;
1034                                 break;
1035                         case 3:
1036                                 if(c0 > c3)
1037                                         destteam = COLOR_TEAM3;
1038                                 break;
1039                         case 4:
1040                                 if(c0 > c4)
1041                                         destteam = COLOR_TEAM4;
1042                                 break;
1043                 }
1044                 if(destteam == -1)
1045                         return;
1046         }
1047         if(destteam == self.team && !self.killindicator)
1048                 return;
1049         ClientKill_TeamChange(destteam);
1050 }
1051
1052 void FixClientCvars(entity e)
1053 {
1054         // send prediction settings to the client
1055         stuffcmd(e, "\nin_bindmap 0 0\n");
1056         /*
1057          * we no longer need to stuff this. Remove this comment block if you feel
1058          * 2.3 and higher (or was it 2.2.3?) don't need these any more
1059         stuffcmd(e, strcat("cl_gravity ", ftos(cvar("sv_gravity")), "\n"));
1060         stuffcmd(e, strcat("cl_movement_accelerate ", ftos(cvar("sv_accelerate")), "\n"));
1061         stuffcmd(e, strcat("cl_movement_friction ", ftos(cvar("sv_friction")), "\n"));
1062         stuffcmd(e, strcat("cl_movement_maxspeed ", ftos(cvar("sv_maxspeed")), "\n"));
1063         stuffcmd(e, strcat("cl_movement_airaccelerate ", ftos(cvar("sv_airaccelerate")), "\n"));
1064         stuffcmd(e, strcat("cl_movement_maxairspeed ", ftos(cvar("sv_maxairspeed")), "\n"));
1065         stuffcmd(e, strcat("cl_movement_stopspeed ", ftos(cvar("sv_stopspeed")), "\n"));
1066         stuffcmd(e, strcat("cl_movement_jumpvelocity ", ftos(cvar("sv_jumpvelocity")), "\n"));
1067         stuffcmd(e, strcat("cl_movement_stepheight ", ftos(cvar("sv_stepheight")), "\n"));
1068         stuffcmd(e, strcat("set cl_movement_friction_on_land ", ftos(cvar("sv_friction_on_land")), "\n"));
1069         stuffcmd(e, strcat("set cl_movement_airaccel_qw ", ftos(cvar("sv_airaccel_qw")), "\n"));
1070         stuffcmd(e, strcat("set cl_movement_airaccel_sideways_friction ", ftos(cvar("sv_airaccel_sideways_friction")), "\n"));
1071         stuffcmd(e, "cl_movement_edgefriction 1\n");
1072          */
1073 }
1074
1075 .float fog_set;
1076 void SendFog()
1077 {
1078         if(clienttype(self) == CLIENTTYPE_REAL)
1079         if(world.fog) // NOT string_null!
1080         {
1081                 if(!self.fog_set)
1082                 {
1083                         if(sv_foginterval)
1084                         {
1085                                 msg_entity = self;
1086                                 WriteByte(MSG_ONE, SVC_TEMPENTITY);
1087                                 WriteByte(MSG_ONE, TE_CSQC_FOG);
1088                                 WriteCoord(MSG_ONE, sv_foginterval);
1089                                 WriteString(MSG_ONE, world.fog);
1090                         }
1091                         else
1092                                 // set it once
1093                                 stuffcmd(self, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1094
1095                         self.fog_set = 1;
1096                 }
1097         }
1098 }
1099
1100 /*
1101 =============
1102 ClientConnect
1103
1104 Called when a client connects to the server
1105 =============
1106 */
1107 //void ctf_clientconnect();
1108 string ColoredTeamName(float t);
1109 void DecodeLevelParms (void);
1110 //void dom_player_join_team(entity pl);
1111 void ClientConnect (void)
1112 {
1113         local string s;
1114
1115         if(self.flags & FL_CLIENT)
1116         {
1117                 print("Warning: ClientConnect, but already connected!\n");
1118                 return;
1119         }
1120
1121         if(Ban_MaybeEnforceBan(self))
1122                 return;
1123
1124         DecodeLevelParms();
1125
1126         self.classname = "player_joining";
1127
1128         self.flags = self.flags | FL_CLIENT;
1129         self.version_nagtime = time + 10 + random() * 10;
1130
1131         if(player_count<0)
1132         {
1133                 dprint("BUG player count is lower than zero, this cannot happen!\n");
1134                 player_count = 0;
1135         }
1136
1137         PlayerScore_Attach(self);
1138
1139         bot_clientconnect();
1140
1141         race_PreSpawnObserver();
1142
1143         //if(g_domination)
1144         //      dom_player_join_team(self);
1145
1146         //JoinBestTeam(self, FALSE, FALSE);
1147         //
1148         if((cvar("sv_spectate") == 1 && !g_lms) || cvar("g_campaign")) {
1149                 self.classname = "observer";
1150         } else {
1151                 self.classname = "player";
1152                 campaign_bots_may_start = 1;
1153         }
1154
1155         self.playerid = (playerid_last = playerid_last + 1);
1156         if(cvar("sv_eventlog"))
1157         {
1158                 if(clienttype(self) == CLIENTTYPE_REAL)
1159                         GameLogEcho(strcat(":join:", ftos(self.playerid), ":", ftos(num_for_edict(self)), ":", self.netaddress, ":", self.netname));
1160                 else
1161                         GameLogEcho(strcat(":join:", ftos(self.playerid), ":", ftos(num_for_edict(self)), ":bot:", self.netname));
1162                 s = strcat(":team:", ftos(self.playerid), ":");
1163                 s = strcat(s, ftos(self.team));
1164                 GameLogEcho(s);
1165         }
1166         self.netname_previous = strzone(self.netname);
1167
1168         //stuffcmd(self, "set tmpviewsize $viewsize \n");
1169
1170         bprint ("^4",self.netname);
1171         bprint ("^4 connected");
1172
1173         if(g_domination || g_ctf)
1174         {
1175                 bprint(" and joined the ");
1176                 bprint(ColoredTeamName(self.team));
1177         }
1178
1179         bprint("\n");
1180
1181         self.welcomemessage_time = 0;
1182
1183         stuffcmd(self, strcat(clientstuff, "\n"));
1184         stuffcmd(self, strcat("exec maps/", mapname, ".cfg\n"));
1185         stuffcmd(self, "cl_particles_reloadeffects\n");
1186
1187         FixClientCvars(self);
1188
1189         // spawnfunc_waypoint sprites
1190         WaypointSprite_InitClient(self);
1191
1192         // Wazat's grappling hook
1193         SetGrappleHookBindings();
1194
1195         // get autoswitch state from player when he toggles it
1196         stuffcmd(self, "alias autoswitch \"set cl_autoswitch $1 ; cmd autoswitch $1\"\n"); // default.cfg-ed in 2.4.1
1197
1198         // get version info from player
1199         stuffcmd(self, "cmd clientversion $gameversion\n");
1200
1201         // get other cvars from player
1202         GetCvars(0);
1203
1204         // set cvar for team scoreboard
1205         if (teams_matter)
1206         {
1207                 local float t;
1208                 t = cvar("teamplay");
1209                 // we have to stuff the correct teamplay value because if this is a listen server, this changes the teamplay mode of the server itself, which is bad
1210                 stuffcmd(self, strcat("set teamplay ", ftos(t), "\n"));
1211         }
1212         else
1213                 stuffcmd(self, "set teamplay 0\n");
1214
1215         // notify about available teams
1216         if(teamplay)
1217         {
1218                 CheckAllowedTeams(self);
1219                 t = 0; if(c1 >= 0) t |= 1; if(c2 >= 0) t |= 2; if(c3 >= 0) t |= 4; if(c4 >= 0) t |= 8;
1220                 stuffcmd(self, strcat("set _teams_available ", ftos(t), "\n"));
1221         }
1222         else
1223                 stuffcmd(self, "set _teams_available 0\n");
1224
1225         stuffcmd(self, strcat("set gametype ", ftos(game), "\n"));
1226
1227         if(g_arena)
1228         {
1229                 self.classname = "observer";
1230                 Spawnqueue_Insert(self);
1231         }
1232         /*else if(g_ctf)
1233         {
1234                 ctf_clientconnect();
1235         }*/
1236
1237         if(teams_matter)
1238                 attach_entcs();
1239
1240         bot_relinkplayerlist();
1241
1242         self.spectatortime = time;
1243         if(blockSpectators)
1244         {
1245                 sprint(self, strcat("^7You have to become a player within the next ", ftos(cvar("g_maxplayers_spectator_blocktime")), " seconds, otherwise you will be kicked, because spectators aren't allowed at this time!\n"));
1246         }
1247
1248         self.jointime = time;
1249         self.allowedTimeouts = cvar("sv_timeout_number");
1250
1251         if(clienttype(self) == CLIENTTYPE_REAL)
1252         {
1253                 sprint(self, strcat("nexuiz-csqc protocol ", ftos(CSQC_REVISION), "\n"));
1254                 SendCSQCInfo();
1255                 msg_entity = self;
1256                 if(mapvote_initialized && !cvar("g_maplist_textonly"))
1257                 {
1258                         MapVote_SendData(MSG_ONE);
1259                         MapVote_UpdateData(MSG_ONE);
1260                 }
1261                 ScoreInfo_Write(MSG_ONE);
1262         }
1263
1264         if(inWarmupStage)
1265         {
1266                 msg_entity = self;
1267                 WriteByte(MSG_ONE, SVC_TEMPENTITY);
1268                 WriteByte(MSG_ONE, TE_CSQC_WARMUP);
1269                 WriteByte(MSG_ONE, 1);
1270         }
1271
1272         if(g_lms)
1273         {
1274                 if(PlayerScore_Add(self, SP_LMS_LIVES, LMS_NewPlayerLives()) <= 0)
1275                 {
1276                         PlayerScore_Add(self, SP_LMS_RANK, 666);
1277                         self.frags = -666; // FIXME do we still need this?
1278                 }
1279         }
1280
1281         SendFog();
1282 }
1283
1284 /*
1285 =============
1286 ClientDisconnect
1287
1288 Called when a client disconnects from the server
1289 =============
1290 */
1291 .entity chatbubbleentity;
1292 .entity teambubbleentity;
1293 void ReadyCount();
1294 void ClientDisconnect (void)
1295 {
1296         if not(self.flags & FL_CLIENT)
1297         {
1298                 print("Warning: ClientDisconnect without ClientConnect\n");
1299                 return;
1300         }
1301
1302         bot_clientdisconnect();
1303
1304         if(teams_matter)
1305                 detach_entcs();
1306
1307         if(cvar("sv_eventlog"))
1308                 GameLogEcho(strcat(":part:", ftos(self.playerid)));
1309         bprint ("^4",self.netname);
1310         bprint ("^4 disconnected\n");
1311
1312         DropAllRunes(self);
1313         kh_Key_DropAll(self, TRUE);
1314
1315         Portal_ClearAll(self);
1316
1317         if(self.flagcarried)
1318                 DropFlag(self.flagcarried, world, world);
1319
1320         // Here, everything has been done that requires this player to be a client.
1321
1322         self.flags (-) FL_CLIENT;
1323
1324         if (self.chatbubbleentity)
1325                 remove (self.chatbubbleentity);
1326
1327         if (self.teambubbleentity)
1328                 remove (self.teambubbleentity);
1329
1330         if (self.killindicator)
1331                 remove (self.killindicator);
1332
1333         WaypointSprite_PlayerGone();
1334
1335         bot_relinkplayerlist();
1336
1337         // remove laserdot
1338         if(self.weaponentity)
1339                 if(self.weaponentity.lasertarget)
1340                         remove(self.weaponentity.lasertarget);
1341
1342         if(g_arena)
1343         {
1344                 Spawnqueue_Unmark(self);
1345                 Spawnqueue_Remove(self);
1346         }
1347
1348         PlayerScore_Detach(self);
1349
1350         if(self.netname_previous)
1351                 strunzone(self.netname_previous);
1352
1353         ClearPlayerSounds();
1354
1355         self.playerid = 0;
1356         ReadyCount();
1357
1358         // free cvars
1359         GetCvars(-1);
1360 }
1361
1362 .float BUTTON_CHAT;
1363 void ChatBubbleThink()
1364 {
1365         self.nextthink = time;
1366         if (!self.owner.modelindex || self.owner.chatbubbleentity != self)
1367         {
1368                 if(self.owner) // but why can that ever be world?
1369                         self.owner.chatbubbleentity = world;
1370                 remove(self);
1371                 return;
1372         }
1373         setorigin(self, self.owner.origin + '0 0 15' + self.owner.maxs_z * '0 0 1');
1374         if (self.owner.BUTTON_CHAT && !self.owner.deadflag)
1375                 self.model = self.mdl;
1376         else
1377                 self.model = "";
1378 };
1379
1380 void UpdateChatBubble()
1381 {
1382         if (!self.modelindex)
1383                 return;
1384         // spawn a chatbubble entity if needed
1385         if (!self.chatbubbleentity)
1386         {
1387                 self.chatbubbleentity = spawn();
1388                 self.chatbubbleentity.owner = self;
1389                 self.chatbubbleentity.exteriormodeltoclient = self;
1390                 self.chatbubbleentity.think = ChatBubbleThink;
1391                 self.chatbubbleentity.nextthink = time;
1392                 setmodel(self.chatbubbleentity, "models/misc/chatbubble.spr"); // precision set below
1393                 setorigin(self.chatbubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1394                 self.chatbubbleentity.mdl = self.chatbubbleentity.model;
1395                 self.chatbubbleentity.model = "";
1396                 self.chatbubbleentity.effects = EF_LOWPRECISION;
1397         }
1398 }
1399
1400
1401 void TeamBubbleThink()
1402 {
1403         self.nextthink = time;
1404         if (!self.owner.modelindex || self.owner.teambubbleentity != self)
1405         {
1406                 if(self.owner) // but why can that ever be world?
1407                         self.owner.teambubbleentity = world;
1408                 remove(self);
1409                 return;
1410         }
1411 //      setorigin(self, self.owner.origin + '0 0 15' + self.owner.maxs_z * '0 0 1');  // bandwidth hog. setattachment does this now
1412         if (self.owner.BUTTON_CHAT || self.owner.deadflag || self.owner.killindicator)
1413                 self.model = "";
1414         else
1415                 self.model = self.mdl;
1416
1417 };
1418
1419 float TeamBubble_customizeentityforclient()
1420 {
1421         return (self.owner != other && self.owner.team == other.team && other.killcount > -666);
1422 }
1423
1424 void UpdateTeamBubble()
1425 {
1426         if (!self.modelindex || !cvar("teamplay"))
1427                 return;
1428         // spawn a teambubble entity if needed
1429         if (!self.teambubbleentity && cvar("teamplay"))
1430         {
1431                 self.teambubbleentity = spawn();
1432                 self.teambubbleentity.owner = self;
1433                 self.teambubbleentity.exteriormodeltoclient = self;
1434                 self.teambubbleentity.think = TeamBubbleThink;
1435                 self.teambubbleentity.nextthink = time;
1436                 setmodel(self.teambubbleentity, "models/misc/teambubble.spr"); // precision set below
1437 //              setorigin(self.teambubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1438                 setorigin(self.teambubbleentity, self.teambubbleentity.origin + '0 0 15' + self.maxs_z * '0 0 1');
1439                 setattachment(self.teambubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1440                 self.teambubbleentity.mdl = self.teambubbleentity.model;
1441                 self.teambubbleentity.model = self.teambubbleentity.mdl;
1442                 self.teambubbleentity.customizeentityforclient = TeamBubble_customizeentityforclient;
1443                 self.teambubbleentity.effects = EF_LOWPRECISION;
1444         }
1445 }
1446
1447 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1448 // added to the model skins
1449 /*void UpdateColorModHack()
1450 {
1451         local float c;
1452         c = self.clientcolors & 15;
1453         // LordHavoc: only bothering to support white, green, red, yellow, blue
1454              if (teamplay == 0) self.colormod = '0 0 0';
1455         else if (c ==  0) self.colormod = '1.00 1.00 1.00';
1456         else if (c ==  3) self.colormod = '0.10 1.73 0.10';
1457         else if (c ==  4) self.colormod = '1.73 0.10 0.10';
1458         else if (c == 12) self.colormod = '1.22 1.22 0.10';
1459         else if (c == 13) self.colormod = '0.10 0.10 1.73';
1460         else self.colormod = '1 1 1';
1461 };*/
1462
1463 void respawn(void)
1464 {
1465         CopyBody(1);
1466         self.effects |= EF_NODRAW; // prevent another CopyBody
1467         PutClientInServer();
1468 }
1469
1470 /**
1471  * When sv_timeout is used this function returs strings like
1472  * "Timeout begins in 2 seconds!\n" or "Timeout ends in 23 seconds!\n".
1473  * Called by centerprint functions
1474  * @param addOneSecond boolean, set to 1 if the welcome-message centerprint asks for the text
1475  */
1476 string getTimeoutText(float addOneSecond) {
1477         if (!cvar("sv_timeout") || !timeoutStatus)
1478                 return "";
1479
1480         local string retStr;
1481         if (timeoutStatus == 1) {
1482                 if (addOneSecond == 1) {
1483                         retStr = strcat("Timeout begins in ", ftos(remainingLeadTime + 1), " seconds!\n");
1484                 }
1485                 else {
1486                         retStr = strcat("Timeout begins in ", ftos(remainingLeadTime), " seconds!\n");
1487                 }
1488                 return retStr;
1489         }
1490         else if (timeoutStatus == 2) {
1491                 if (addOneSecond) {
1492                         retStr = strcat("Timeout ends in ", ftos(remainingTimeoutTime + 1), " seconds!\n");
1493                         //don't show messages like "Timeout ends in 0 seconds"...
1494                         if ((remainingTimeoutTime + 1) > 0)
1495                                 return retStr;
1496                         else
1497                                 return "";
1498                 }
1499                 else {
1500                         retStr = strcat("Timeout ends in ", ftos(remainingTimeoutTime), " seconds!\n");
1501                         //don't show messages like "Timeout ends in 0 seconds"...
1502                         if (remainingTimeoutTime > 0)
1503                                 return retStr;
1504                         else
1505                                 return "";
1506                 }
1507         }
1508         else return "";
1509 }
1510
1511 void player_powerups (void)
1512 {
1513         if (g_minstagib)
1514         {
1515                 if (self.items & IT_STRENGTH)
1516                 {
1517                         if (time > self.strength_finished)
1518                         {
1519                                 if (g_minstagib_invis_alpha > 0)
1520                                 {
1521                                         self.alpha = default_player_alpha;
1522                                         self.exteriorweaponentity.alpha = default_weapon_alpha;
1523                                         self.effects = self.effects | EF_FULLBRIGHT;
1524                                 }
1525                                 else
1526                                 {
1527                                         self.effects -= self.effects & EF_NODRAW;
1528                                 }
1529                                 self.items = self.items - (self.items & IT_STRENGTH);
1530                                 sprint(self, "^3Invisibility has worn off\n");
1531                         }
1532                 }
1533                 else
1534                 {
1535                         if (time < self.strength_finished)
1536                         {
1537                                 if (g_minstagib_invis_alpha > 0)
1538                                 {
1539                                         self.alpha = g_minstagib_invis_alpha;
1540                                         self.exteriorweaponentity.alpha = g_minstagib_invis_alpha;
1541                                         self.effects -= self.effects & EF_FULLBRIGHT;
1542                                 }
1543                                 else
1544                                 {
1545                                         self.effects = self.effects | EF_NODRAW;
1546                                 }
1547                                 self.items = self.items | IT_STRENGTH;
1548                                 sprint(self, "^3You are invisible\n");
1549                         }
1550                 }
1551
1552                 if (self.items & IT_INVINCIBLE)
1553                 {
1554                         if (time > self.invincible_finished)
1555                         {
1556                                 self.items = self.items - (self.items & IT_INVINCIBLE);
1557                                 sprint(self, "^3Speed has worn off\n");
1558                         }
1559                 }
1560                 else
1561                 {
1562                         if (time < self.invincible_finished)
1563                         {
1564                                 self.items = self.items | IT_INVINCIBLE;
1565                                 sprint(self, "^3You are on speed\n");
1566                         }
1567                 }
1568                 return;
1569         }
1570
1571         self.effects = self.effects - (self.effects & (EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT));
1572         if (self.items & IT_STRENGTH)
1573         {
1574                 self.effects = self.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1575                 if (time > self.strength_finished)
1576                 {
1577                         self.items = self.items - (self.items & IT_STRENGTH);
1578                         sprint(self, "^3Strength has worn off\n");
1579                 }
1580         }
1581         else
1582         {
1583                 if (time < self.strength_finished)
1584                 {
1585                         self.items = self.items | IT_STRENGTH;
1586                         sprint(self, "^3Strength infuses your weapons with devastating power\n");
1587                 }
1588         }
1589         if (self.items & IT_INVINCIBLE)
1590         {
1591                 self.effects = self.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1592                 if (time > self.invincible_finished)
1593                 {
1594                         self.items = self.items - (self.items & IT_INVINCIBLE);
1595                         sprint(self, "^3Shield has worn off\n");
1596                 }
1597         }
1598         else
1599         {
1600                 if (time < self.invincible_finished)
1601                 {
1602                         self.items = self.items | IT_INVINCIBLE;
1603                         sprint(self, "^3Shield surrounds you\n");
1604                 }
1605         }
1606
1607         if (cvar("g_fullbrightplayers"))
1608                 self.effects = self.effects | EF_FULLBRIGHT;
1609
1610         // midair gamemode: damage only while in the air
1611         // if in midair mode, being on ground grants temporary invulnerability
1612         // (this is so that multishot weapon don't clear the ground flag on the
1613         // first damage in the frame, leaving the player vulnerable to the
1614         // remaining hits in the same frame)
1615         if (self.flags & FL_ONGROUND)
1616         if (g_midair)
1617                 self.spawnshieldtime = max(self.spawnshieldtime, time + cvar("g_midair_shieldtime"));
1618
1619         if (time >= game_starttime)
1620         if (time < self.spawnshieldtime)
1621                 self.effects = self.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1622 }
1623
1624 float CalcRegen(float current, float stable, float regenfactor)
1625 {
1626         if(current > stable)
1627                 return current;
1628         else if(current > stable - 0.25) // when close enough, "snap"
1629                 return stable;
1630         else
1631                 return min(stable, current + (stable - current) * regenfactor * frametime);
1632 }
1633
1634 void player_regen (void)
1635 {
1636         float maxh, maxa, limith, limita, max_mod, regen_mod, rot_mod, limit_mod;
1637         maxh = cvar("g_balance_health_stable");
1638         maxa = cvar("g_balance_armor_stable");
1639         limith = cvar("g_balance_health_limit");
1640         limita = cvar("g_balance_armor_limit");
1641
1642         if (g_minstagib || (g_lms && !cvar("g_lms_regenerate")))
1643                 return;
1644
1645         max_mod = regen_mod = rot_mod = limit_mod = 1;
1646
1647         if (self.runes & RUNE_REGEN)
1648         {
1649                 if (self.runes & CURSE_VENOM) // do we have both rune/curse?
1650                 {
1651                         regen_mod = cvar("g_balance_rune_regen_combo_regenrate");
1652                         max_mod = cvar("g_balance_rune_regen_combo_hpmod");
1653                         limit_mod = cvar("g_balance_rune_regen_combo_limitmod");
1654                 }
1655                 else
1656                 {
1657                         regen_mod = cvar("g_balance_rune_regen_regenrate");
1658                         max_mod = cvar("g_balance_rune_regen_hpmod");
1659                         limit_mod = cvar("g_balance_rune_regen_limitmod");
1660                 }
1661         }
1662         else if (self.runes & CURSE_VENOM)
1663         {
1664                 max_mod = cvar("g_balance_curse_venom_hpmod");
1665                 if (self.runes & RUNE_REGEN) // do we have both rune/curse?
1666                         rot_mod = cvar("g_balance_rune_regen_combo_rotrate");
1667                 else
1668                         rot_mod = cvar("g_balance_curse_venom_rotrate");
1669                 limit_mod = cvar("g_balance_curse_venom_limitmod");
1670                 //if (!self.runes & RUNE_REGEN)
1671                 //      rot_mod = cvar("g_balance_curse_venom_rotrate");
1672         }
1673         maxh = maxh * max_mod;
1674         //maxa = maxa * max_mod;
1675         limith = limith * limit_mod;
1676         limita = limita * limit_mod;
1677
1678         if (self.armorvalue > maxa)
1679         {
1680                 if (time > self.pauserotarmor_finished)
1681                 {
1682                         self.armorvalue = max(maxa, self.armorvalue + (maxa - self.armorvalue) * cvar("g_balance_armor_rot") * frametime);
1683                         self.armorvalue = max(maxa, self.armorvalue - cvar("g_balance_armor_rotlinear") * frametime);
1684                 }
1685         }
1686         else if (self.armorvalue < maxa)
1687         {
1688                 if (time > self.pauseregen_finished)
1689                 {
1690                         self.armorvalue = CalcRegen(self.armorvalue, maxa, cvar("g_balance_armor_regen"));
1691                         self.armorvalue = min(maxa, self.armorvalue + cvar("g_balance_armor_regenlinear") * frametime);
1692                 }
1693         }
1694         if (self.health > maxh)
1695         {
1696                 if (time > self.pauserothealth_finished)
1697                 {
1698                         self.health = max(maxh, self.health + (maxh - self.health) * rot_mod*cvar("g_balance_health_rot") * frametime);
1699                         self.health = max(maxh, self.health - rot_mod*cvar("g_balance_health_rotlinear") * frametime);
1700                 }
1701         }
1702         else if (self.health < maxh)
1703         {
1704                 if (time > self.pauseregen_finished)
1705                 {
1706                         self.health = CalcRegen(self.health, maxh, regen_mod * cvar("g_balance_health_regen"));
1707                         self.health = min(maxh, self.health + regen_mod*cvar("g_balance_health_regenlinear") * frametime);
1708                 }
1709         }
1710
1711         if (self.health > limith)
1712                 self.health = limith;
1713         if (self.armorvalue > limita)
1714                 self.armorvalue = limita;
1715
1716         // if player rotted to death...  die!
1717         if(self.health < 1)
1718                 self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
1719 }
1720
1721 .float zoomstate;
1722 float zoomstate_set;
1723 void SetZoomState(float z)
1724 {
1725         if(z != self.zoomstate)
1726         {
1727                 msg_entity = self;
1728                 WriteByte(MSG_ONE, SVC_TEMPENTITY);
1729                 WriteByte(MSG_ONE, TE_CSQC_ZOOMNOTIFY);
1730                 WriteByte(MSG_ONE, z);
1731                 self.zoomstate = z;
1732         }
1733         zoomstate_set = 1;
1734 }
1735
1736 /*
1737 ======================
1738 spectate mode routines
1739 ======================
1740 */
1741 void SpectateCopy(entity spectatee) {
1742         self.armortype = spectatee.armortype;
1743         self.armorvalue = spectatee.armorvalue;
1744         self.currentammo = spectatee.currentammo;
1745         self.effects = spectatee.effects;
1746         self.health = spectatee.health;
1747         self.impulse = 0;
1748         self.items = spectatee.items;
1749         self.weapons = spectatee.weapons;
1750         self.switchweapon = spectatee.switchweapon;
1751         self.weapon = spectatee.weapon;
1752         self.punchangle = spectatee.punchangle;
1753         self.view_ofs = spectatee.view_ofs;
1754         self.v_angle = spectatee.v_angle;
1755         self.velocity = spectatee.velocity;
1756         self.dmg_take = spectatee.dmg_take;
1757         self.dmg_save = spectatee.dmg_save;
1758         self.dmg_inflictor = spectatee.dmg_inflictor;
1759         self.angles = spectatee.v_angle;
1760         self.fixangle = TRUE;
1761         setorigin(self, spectatee.origin);
1762         setsize(self, spectatee.mins, spectatee.maxs);
1763         SetZoomState(spectatee.zoomstate);
1764 }
1765
1766 float SpectateUpdate() {
1767         if(!self.enemy)
1768                 return 0;
1769
1770         if (self == self.enemy)
1771                 return 0;
1772
1773         if(self.enemy.flags & FL_NOTARGET)
1774                 return 0;
1775
1776         SpectateCopy(self.enemy);
1777
1778         return 1;
1779 }
1780
1781 float SpectateNext() {
1782         other = find(self.enemy, classname, "player");
1783         if (!other) {
1784                 other = find(other, classname, "player");
1785         }
1786         if (other) {
1787                 self.enemy = other;
1788         }
1789         if(self.enemy.classname == "player") {
1790                 msg_entity = self;
1791                 WriteByte(MSG_ONE, SVC_SETVIEW);
1792                 WriteEntity(MSG_ONE, self.enemy);
1793                 self.wantswelcomemessage = 1;
1794                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
1795                 if(!SpectateUpdate())
1796                         PutObserverInServer();
1797                 return 1;
1798         } else {
1799                 return 0;
1800         }
1801 }
1802
1803 /*
1804 =============
1805 ShowRespawnCountdown()
1806
1807 Update a respawn countdown display.
1808 =============
1809 */
1810 void ShowRespawnCountdown()
1811 {
1812         float number;
1813         if(self.deadflag == DEAD_NO) // just respawned?
1814                 return;
1815         else
1816         {
1817                 number = ceil(self.death_time - time);
1818                 if(number <= 0)
1819                         return;
1820                 if(number <= self.respawn_countdown)
1821                 {
1822                         self.respawn_countdown = number - 1;
1823                         if(ceil(self.death_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
1824                                 announce(self, strcat("announcer/robotic/", ftos(number), ".wav"));
1825                 }
1826         }
1827 }
1828
1829 void LeaveSpectatorMode()
1830 {
1831         if(isJoinAllowed()) {
1832                 if(!cvar("teamplay") || cvar("g_campaign") || cvar("g_balance_teams")) {
1833                         self.classname = "player";
1834                         if(cvar("g_campaign") || cvar("g_balance_teams") || cvar("g_balance_teams_force"))
1835                                 JoinBestTeam(self, FALSE, TRUE);
1836                         if(cvar("g_campaign"))
1837                                 campaign_bots_may_start = 1;
1838                         PutClientInServer();
1839                         if(!(self.flags & FL_NOTARGET))
1840                                 bprint ("^4", self.netname, "^4 is playing now\n");
1841                         centerprint(self,"");
1842                         return;
1843                 } else {
1844                         stuffcmd(self,"menu_showteamselect\n");
1845                         return;
1846                 }
1847         }
1848         else {
1849                 //player may not join because of g_maxplayers is set
1850                 centerprint_atprio(self, CENTERPRIO_MAPVOTE, PREVENT_JOIN_TEXT);
1851         }
1852 }
1853
1854 /**
1855  * Determines whether the player is allowed to join. This depends on cvar
1856  * g_maxplayers, if it isn't used this function always return TRUE, otherwise
1857  * it checks whether the number of currently playing players exceeds g_maxplayers.
1858  * @return bool TRUE if the player is allowed to join, false otherwise
1859  */
1860 float isJoinAllowed() {
1861         if (!cvar("g_maxplayers"))
1862                 return TRUE;
1863
1864         local entity e;
1865         local float currentlyPlaying;
1866         FOR_EACH_REALPLAYER(e) {
1867                 if(e.classname == "player")
1868                         currentlyPlaying += 1;
1869         }
1870         if(currentlyPlaying < cvar("g_maxplayers"))
1871                 return TRUE;
1872
1873         return FALSE;
1874 }
1875
1876 /**
1877  * Checks whether the client is an observer or spectator, if so, he will get kicked after
1878  * g_maxplayers_spectator_blocktime seconds
1879  */
1880 void checkSpectatorBlock() {
1881         if(self.classname == "spectator" || self.classname == "observer") {
1882                 if( time > (self.spectatortime + cvar("g_maxplayers_spectator_blocktime")) ) {
1883                         sprint(self, "^7You were kicked from the server because you are spectator and spectators aren't allowed at the moment.\n");
1884                         dropclient(self);
1885                 }
1886         }
1887 }
1888
1889 float vercmp_recursive(string v1, string v2)
1890 {
1891         float dot1, dot2;
1892         string s1, s2;
1893         float r;
1894
1895         dot1 = strstrofs(v1, ".", 0);
1896         dot2 = strstrofs(v2, ".", 0);
1897         if(dot1 == -1)
1898                 s1 = v1;
1899         else
1900                 s1 = substring(v1, 0, dot1);
1901         if(dot2 == -1)
1902                 s2 = v2;
1903         else
1904                 s2 = substring(v2, 0, dot2);
1905
1906         r = stof(s1) - stof(s2);
1907         if(r != 0)
1908                 return r;
1909
1910         r = strcasecmp(s1, s2);
1911         if(r != 0)
1912                 return r;
1913
1914         if(dot1 == -1)
1915                 if(dot2 == -1)
1916                         return 0;
1917                 else
1918                         return -1;
1919         else
1920                 if(dot2 == -1)
1921                         return 1;
1922                 else
1923                         return vercmp_recursive(substring(v1, dot1 + 1, 999), substring(v2, dot2 + 1, 999));
1924 }
1925
1926 float vercmp(string v1, string v2)
1927 {
1928         if(strcasecmp(v1, v2) == 0) // early out check
1929                 return 0;
1930         return vercmp_recursive(v1, v2);
1931 }
1932
1933 void ObserverThink()
1934 {
1935         if (self.flags & FL_JUMPRELEASED) {
1936                 if (self.BUTTON_JUMP && !self.version_mismatch) {
1937                         self.welcomemessage_time = 0;
1938                         self.flags = self.flags - FL_JUMPRELEASED;
1939                         LeaveSpectatorMode();
1940                         return;
1941                 } else if(self.BUTTON_ATCK && !self.version_mismatch) {
1942                         self.welcomemessage_time = 0;
1943                         self.flags = self.flags - FL_JUMPRELEASED;
1944                         if(SpectateNext() == 1) {
1945                                 self.classname = "spectator";
1946                         }
1947                 }
1948         } else {
1949                 if (!(self.BUTTON_ATCK || self.BUTTON_JUMP)) {
1950                         self.flags = self.flags | FL_JUMPRELEASED;
1951                 }
1952         }
1953         /*
1954         if(self.BUTTON_ZOOM)
1955                 self.wantswelcomemessage = 0;
1956         */
1957         if(self.wantswelcomemessage)
1958                 PrintWelcomeMessage(self);
1959 }
1960
1961 void SpectatorThink()
1962 {
1963         if (self.flags & FL_JUMPRELEASED) {
1964                 if (self.BUTTON_JUMP && !self.version_mismatch) {
1965                         self.welcomemessage_time = 0;
1966                         self.flags = self.flags - FL_JUMPRELEASED;
1967                         LeaveSpectatorMode();
1968                         return;
1969                 } else if(self.BUTTON_ATCK) {
1970                         self.welcomemessage_time = 0;
1971                         self.flags = self.flags - FL_JUMPRELEASED;
1972                         if(SpectateNext() == 1) {
1973                                 self.classname = "spectator";
1974                         } else {
1975                                 self.classname = "observer";
1976                                 PutClientInServer();
1977                         }
1978                 } else if (self.BUTTON_ATCK2) {
1979                         self.welcomemessage_time = 0;
1980                         self.flags = self.flags - FL_JUMPRELEASED;
1981                         self.classname = "observer";
1982                         PutClientInServer();
1983                 } else {
1984                         if(!SpectateUpdate())
1985                                 PutObserverInServer();
1986                 }
1987         } else {
1988                 if (!(self.BUTTON_ATCK || self.BUTTON_ATCK2)) {
1989                         self.flags = self.flags | FL_JUMPRELEASED;
1990                 }
1991         }
1992         /*
1993         if(self.BUTTON_ZOOM)
1994                 self.wantswelcomemessage = 0;
1995         */
1996         if(self.wantswelcomemessage)
1997                 PrintWelcomeMessage(self);
1998         self.flags = self.flags | FL_CLIENT | FL_NOTARGET;
1999 }
2000
2001 /*
2002 =============
2003 PlayerPreThink
2004
2005 Called every frame for each client before the physics are run
2006 =============
2007 */
2008 void() ctf_setstatus;
2009 .float spectatee_status;
2010 void PlayerPreThink (void)
2011 {
2012         self.stat_sys_ticrate = cvar("sys_ticrate");
2013         self.stat_game_starttime = game_starttime;
2014
2015         if(blockSpectators)
2016                 checkSpectatorBlock();
2017
2018         zoomstate_set = 0;
2019
2020         if(self.netname_previous != self.netname)
2021         {
2022                 if(cvar("sv_eventlog"))
2023                         GameLogEcho(strcat(":name:", ftos(self.playerid), ":", self.netname));
2024                 if(self.netname_previous)
2025                         strunzone(self.netname_previous);
2026                 self.netname_previous = strzone(self.netname);
2027         }
2028
2029         // version nagging
2030         if(self.version_nagtime)
2031                 if(self.cvar_g_nexuizversion)
2032                         if(time > self.version_nagtime)
2033                         {
2034                                 if(strstr(self.cvar_g_nexuizversion, "svn", 0) < 0)
2035                                 {
2036                                         if(strstr(cvar_string("g_nexuizversion"), "svn", 0) >= 0)
2037                                         {
2038                                                 dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Nexuiz ", cvar_string("g_nexuizversion"), " (beta)^7, you have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1\n");
2039                                                 sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Nexuiz ", cvar_string("g_nexuizversion"), " (beta)^7, you have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1\n"));
2040                                         }
2041                                         else
2042                                         {
2043                                                 float r;
2044                                                 r = vercmp(self.cvar_g_nexuizversion, cvar_string("g_nexuizversion"));
2045                                                 if(r < 0)
2046                                                 {
2047                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - ^3Nexuiz ", cvar_string("g_nexuizversion"), "^7 is out, and you still have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1 - get the update from ^4http://www.nexuiz.com/^1!\n");
2048                                                         sprint(self, strcat("\{1}^1NOTE: ^3Nexuiz ", cvar_string("g_nexuizversion"), "^7 is out, and you still have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1 - get the update from ^4http://www.nexuiz.com/^1!\n"));
2049                                                 }
2050                                                 else if(r > 0)
2051                                                 {
2052                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Nexuiz ", cvar_string("g_nexuizversion"), "^7, you have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1\n");
2053                                                         sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Nexuiz ", cvar_string("g_nexuizversion"), "^7, you have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1\n"));
2054                                                 }
2055                                         }
2056                                 }
2057                                 self.version_nagtime = 0;
2058                         }
2059
2060         // GOD MODE info
2061         if(!(self.flags & FL_GODMODE)) if(self.max_armorvalue)
2062         {
2063                 sprint(self, strcat("godmode saved you ", ftos(self.max_armorvalue), " units of damage, cheater!\n"));
2064                 self.max_armorvalue = 0;
2065         }
2066
2067         if(frametime)
2068         {
2069                 SendFog();
2070                 antilag_record(self);
2071         }
2072
2073         if(self.classname == "player") {
2074 //              if(self.netname == "Wazat")
2075 //                      bprint(self.classname, "\n");
2076
2077                 CheckRules_Player();
2078
2079                 if(self.BUTTON_INFO)
2080                         PrintWelcomeMessage(self);
2081
2082                 if(g_lms || !cvar("sv_spectate"))
2083                 if((time - self.jointime) <= cvar("welcome_message_time"))
2084                         PrintWelcomeMessage(self);
2085
2086                 if (intermission_running)
2087                 {
2088                         IntermissionThink ();   // otherwise a button could be missed between
2089                         return;                                 // the think tics
2090                 }
2091
2092                 if(self.teleport_time)
2093                 if(time > self.teleport_time)
2094                 {
2095                         self.teleport_time = 0;
2096                         self.effects = self.effects - (self.effects & EF_NODRAW);
2097                         if(self.weaponentity)
2098                                 self.weaponentity.flags = self.weaponentity.flags - (self.weaponentity.flags & EF_NODRAW);
2099                 }
2100
2101                 Nixnex_GiveCurrentWeapon();
2102
2103                 if(frametime > 0) // don't do this in cl_movement frames, just in server ticks
2104                         UpdateSelectedPlayer();
2105
2106                 //don't allow the player to turn around while game is paused!
2107                 if(timeoutStatus == 2) {
2108                         self.v_angle = self.lastV_angle;
2109                         self.angles = self.lastV_angle;
2110                         self.fixangle = TRUE;
2111                 }
2112
2113                 if (self.deadflag != DEAD_NO)
2114                 {
2115                         float button_pressed, force_respawn;
2116                         player_anim();
2117                         button_pressed = (self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE);
2118                         force_respawn = (g_lms || cvar("g_forced_respawn"));
2119                         if (self.deadflag == DEAD_DYING)
2120                         {
2121                                 if(force_respawn)
2122                                         self.deadflag = DEAD_RESPAWNING;
2123                                 else if(!button_pressed)
2124                                         self.deadflag = DEAD_DEAD;
2125                         }
2126                         else if (self.deadflag == DEAD_DEAD)
2127                         {
2128                                 if(button_pressed)
2129                                         self.deadflag = DEAD_RESPAWNABLE;
2130                         }
2131                         else if (self.deadflag == DEAD_RESPAWNABLE)
2132                         {
2133                                 if(!button_pressed)
2134                                         self.deadflag = DEAD_RESPAWNING;
2135                         }
2136                         else if (self.deadflag == DEAD_RESPAWNING)
2137                         {
2138                                 if(time > self.death_time)
2139                                 {
2140                                         self.death_time = time + 1; // only retry once a second
2141                                         respawn();
2142                                 }
2143                         }
2144                         ShowRespawnCountdown();
2145                         return;
2146                 }
2147
2148                 if(g_lms && !self.deadflag && cvar("g_lms_campcheck_interval"))
2149                 {
2150                         vector dist;
2151
2152                         // calculate player movement (in 2 dimensions only, so jumping on one spot doesn't count as movement)
2153                         dist = self.oldorigin - self.origin;
2154                         dist_z = 0;
2155                         self.lms_traveled_distance += fabs(vlen(dist));
2156
2157                         if((cvar("g_campaign") && !campaign_bots_may_start) || (time < game_starttime))
2158                         {
2159                                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval")*2;
2160                                 self.lms_traveled_distance = 0;
2161                         }
2162
2163                         if(time > self.lms_nextcheck)
2164                         {
2165                                 //sprint(self, "distance: ", ftos(self.lms_traveled_distance), "\n");
2166                                 if(self.lms_traveled_distance < cvar("g_lms_campcheck_distance"))
2167                                 {
2168                                         centerprint(self, cvar_string("g_lms_campcheck_message"));
2169                                         // FIXME KadaverJack: gibbing player here causes playermodel to bounce around, instead of eye.md3
2170                                         // I wasn't able to find out WHY that happens, so I put a workaround in place that shall prevent players from being gibbed :(
2171                                         Damage(self, self, self, bound(0, cvar("g_lms_campcheck_damage"), self.health + self.armorvalue * cvar("g_balance_armor_blockpercent") + 5), DEATH_CAMP, self.origin, '0 0 0');
2172                                 }
2173                                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval");
2174                                 self.lms_traveled_distance = 0;
2175                         }
2176                 }
2177
2178                 if (self.BUTTON_CROUCH && !self.hook.state)
2179                 {
2180                         if (!self.crouch)
2181                         {
2182                                 self.crouch = TRUE;
2183                                 self.view_ofs = PL_CROUCH_VIEW_OFS;
2184                                 setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX);
2185                                 player_setanim(self.anim_duck, FALSE, TRUE, TRUE);
2186                         }
2187                 }
2188                 else
2189                 {
2190                         if (self.crouch)
2191                         {
2192                                 tracebox(self.origin, PL_MIN, PL_MAX, self.origin, FALSE, self);
2193                                 if (!trace_startsolid)
2194                                 {
2195                                         self.crouch = FALSE;
2196                                         self.view_ofs = PL_VIEW_OFS;
2197                                         setsize (self, PL_MIN, PL_MAX);
2198                                 }
2199                         }
2200                 }
2201
2202                 FixPlayermodel();
2203
2204                 GrapplingHookFrame();
2205
2206                 W_WeaponFrame();
2207
2208                 player_powerups();
2209                 player_regen();
2210                 player_anim();
2211
2212                 if (g_minstagib)
2213                         minstagib_ammocheck();
2214
2215                 ctf_setstatus();
2216                 kh_setstatus();
2217
2218                 //self.angles_y=self.v_angle_y + 90;   // temp
2219
2220                 //if (TetrisPreFrame()) return;
2221         } else if(gameover) {
2222                 if (intermission_running)
2223                         IntermissionThink ();   // otherwise a button could be missed between
2224                 return;
2225         } else if(self.classname == "observer") {
2226                 ObserverThink();
2227         } else if(self.classname == "spectator") {
2228                 SpectatorThink();
2229         }
2230
2231         if(!zoomstate_set)
2232                 SetZoomState(self.BUTTON_ZOOM || (self.BUTTON_ATCK2 && self.weapon == WEP_NEX));
2233
2234         float oldspectatee_status;
2235         oldspectatee_status = self.spectatee_status;
2236         if(self.classname == "spectator")
2237                 self.spectatee_status = num_for_edict(self.enemy);
2238         else if(self.classname == "observer")
2239                 self.spectatee_status = num_for_edict(self);
2240         else
2241                 self.spectatee_status = 0;
2242         if(self.spectatee_status != oldspectatee_status)
2243         {
2244                 msg_entity = self;
2245                 WriteByte(MSG_ONE, SVC_TEMPENTITY);
2246                 WriteByte(MSG_ONE, TE_CSQC_SPECTATING);
2247                 WriteByte(MSG_ONE, self.spectatee_status);
2248                 if(g_race)
2249                         race_InitSpectator();
2250         }
2251
2252         if(self.teamkill_soundtime)
2253         if(time > self.teamkill_soundtime)
2254         {
2255                 self.teamkill_soundtime = 0;
2256
2257                 entity oldpusher, oldself;
2258
2259                 oldself = self; self = self.teamkill_soundsource;
2260                 oldpusher = self.pusher; self.pusher = oldself;
2261
2262                 VoiceMessage("teamshoot_auto");
2263
2264                 self.pusher = oldpusher;
2265                 self = oldself;
2266         }
2267
2268         target_voicescript_next(self);
2269 }
2270
2271
2272 /*
2273 =============
2274 PlayerPostThink
2275
2276 Called every frame for each client after the physics are run
2277 =============
2278 */
2279 .float idlekick_lasttimeleft;
2280 .float race_penalty;
2281 .float race_penalty_nagged;
2282 .float race_penalty_nagtime;
2283 void PlayerPostThink (void)
2284 {
2285         // Savage: Check for nameless players
2286         if (strlen(self.netname) < 1) {
2287                 self.netname = "Player";
2288                 stuffcmd(self, "seta _cl_name Player\n");
2289         }
2290
2291         if(sv_maxidle)
2292         {
2293                 float timeleft;
2294                 timeleft = ceil(sv_maxidle - (time - self.parm_idlesince));
2295                 if(timeleft <= 0)
2296                 {
2297                         bprint("^3", self.netname, "^3 was kicked for idling.\n");
2298                         announce(self, "announcer/robotic/terminated.wav");
2299                         dropclient(self);
2300                         return;
2301                 }
2302                 else if(timeleft <= 10)
2303                 {
2304                         if(timeleft != self.idlekick_lasttimeleft)
2305                         {
2306                                 centerprint_atprio(self, CENTERPRIO_IDLEKICK, strcat("^3Stop idling!\n^3Disconnecting in ", ftos(timeleft), "..."));
2307                                 announce(self, strcat("announcer/robotic/", ftos(timeleft), ".wav"));
2308                         }
2309                 }
2310                 else
2311                 {
2312                         centerprint_expire(self, CENTERPRIO_IDLEKICK);
2313                 }
2314                 self.idlekick_lasttimeleft = timeleft;
2315         }
2316
2317         if(self.classname == "player") {
2318                 CheckRules_Player();
2319                 UpdateChatBubble();
2320                 UpdateTeamBubble();
2321                 if (self.impulse)
2322                         ImpulseCommands();
2323                 if (intermission_running)
2324                         return;         // intermission or finale
2325
2326                 //PrintWelcomeMessage(self);
2327                 //if (TetrisPostFrame()) return;
2328
2329                 // restart countdown
2330                         if(time < game_starttime) {
2331                                 if (!cvar("sv_ready_restart_after_countdown"))
2332                                 {
2333                                         if(self.movement != '0 0 0' && g_race && !g_race_qualifying)
2334                                         {
2335                                                 if(time < game_starttime - 2)
2336                                                 {
2337                                                         if(!self.race_penalty_nagged)
2338                                                         {
2339                                                                 // TODO better notification for this!
2340                                                                 self.race_penalty_nagtime = 0;
2341                                                                 self.race_penalty_nagged = 1;
2342                                                         }
2343                                                 }
2344                                                 else if(!self.race_penalty)
2345                                                 {
2346                                                         self.race_penalty_nagtime = 0;
2347                                                         self.race_penalty = time + 5;
2348                                                 }
2349                                         }
2350                                         if(time > self.race_penalty_nagtime)
2351                                         {
2352                                                 if(self.race_penalty > time)
2353                                                 {
2354                                                         centerprint_atprio(self, CENTERPRIO_IDLEKICK, "^1FIVE SECONDS PENALTY.");
2355                                                 }
2356                                                 else if(self.race_penalty_nagged && time < game_starttime - 2)
2357                                                 {
2358                                                         centerprint_atprio(self, CENTERPRIO_IDLEKICK, "^1DO NOT MOVE DURING THE COUNTDOWN.");
2359                                                 }
2360                                                 self.race_penalty_nagtime = time + self.cvar_scr_centertime * 0.6;
2361                                         }
2362                                         self.movetype = MOVETYPE_NONE;
2363                                         self.velocity = '0 0 0';
2364                                         self.avelocity = '0 0 0';
2365                                         self.movement = '0 0 0';
2366                                 }
2367                         }
2368                         else if (time < self.race_penalty)
2369                         {
2370                                 self.movetype = MOVETYPE_NONE;
2371                                 self.velocity = '0 0 0';
2372                                 self.avelocity = '0 0 0';
2373                                 self.movement = '0 0 0';
2374                         }
2375                         else
2376                         {
2377                                 //allow the player to move again if sv_ready_restart_after_countdown is not used and countdown is over
2378                                 if (!cvar("sv_ready_restart_after_countdown"))
2379                                 {
2380                                         if(self.movetype == MOVETYPE_NONE)
2381                                         {
2382                                                 self.movetype = MOVETYPE_WALK;
2383                                         }
2384                                         self.race_penalty = 0;
2385                                         self.race_penalty_nagged = 0;
2386                                 }
2387                         }
2388
2389         } else if (self.classname == "observer") {
2390                 //do nothing
2391         } else if (self.classname == "spectator") {
2392                 //do nothing
2393         }
2394
2395         /*
2396         float i;
2397         for(i = 0; i < 1000; ++i)
2398         {
2399                 vector end;
2400                 end = self.origin + '0 0 1024' + 512 * randomvec();
2401                 tracebox(self.origin, self.mins, self.maxs, end, MOVE_NORMAL, self);
2402                 if(trace_fraction < 1)
2403                 if(!(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
2404                 {
2405                         print("I HIT SOLID: ", vtos(self.origin), " -> ", vtos(end), "\n");
2406                         break;
2407                 }
2408         }
2409         */
2410
2411         Arena_Warmup();
2412
2413         //pointparticles(particleeffectnum("machinegun_impact"), self.origin + self.view_ofs + '0 0 7', '0 0 0', 1);
2414 }