data/qcsrc/server/cl_client.qc

   1 // let's abuse an existing field
   2 #define SPAWNPOINT_SCORE frags
   3
   4 .float wantswelcomemessage;
   5 .string netname_previous;
   6
   7 void spawnfunc_info_player_survivor (void)
   8 {
   9         spawnfunc_info_player_deathmatch();
  10 }
  11
  12 void spawnfunc_info_player_start (void)
  13 {
  14         spawnfunc_info_player_deathmatch();
  15 }
  16
  17 void spawnfunc_info_player_deathmatch (void)
  18 {
  19         self.classname = "info_player_deathmatch";
  20         relocate_spawnpoint();
  21 }
  22
  23 void spawnpoint_use()
  24 {
  25         if(teams_matter)
  26         if(have_team_spawns)
  27         {
  28                 self.team = activator.team;
  29                 some_spawn_has_been_used = 1;
  30         }
  31 };
  32
  33 // Returns:
  34 //   -1 if a spawn can't be used
  35 //   otherwise, a weight of the spawnpoint
  36 float Spawn_Score(entity spot, entity playerlist, float teamcheck)
  37 {
  38         float shortest, thisdist;
  39         entity player;
  40
  41         // filter out spots for the wrong team
  42         if(teamcheck)
  43         if(spot.team != teamcheck)
  44                 return -1;
  45
  46         if(race_spawns)
  47                 if(spot.target == "")
  48                         return -1;
  49
  50         // filter out spots for assault
  51         if(spot.target != "") {
  52                 local entity ent;
  53                 float good;
  54                 ent = find(world, targetname, spot.target);
  55                 while(ent) {
  56                         if(ent.classname == "target_objective")
  57                         {
  58                                 if(ent.health < 0 || ent.health >= ASSAULT_VALUE_INACTIVE)
  59                                         return -1;
  60                                 good = 1;
  61                         }
  62                         else if(ent.classname == "trigger_race_checkpoint")
  63                         {
  64                                 if(self.classname == "player") // spectators may spawn everywhere
  65                                 {
  66                                         if(ent.race_checkpoint != race_PreviousCheckpoint(self.race_checkpoint))
  67                                                 return -1;
  68                                         if(race_place_valid && (spot.race_place != self.race_place))
  69                                                 return -1;
  70                                         if(!race_place_valid && (spot.race_place != 0))
  71                                                 return -1;
  72                                 }
  73                                 good = 1;
  74                         }
  75                         else
  76                         {
  77                         }
  78                         ent = find(ent, targetname, spot.target);
  79                 }
  80
  81                 if(!good)
  82                         return -1;
  83         }
  84
  85         player = playerlist;
  86         shortest = vlen(world.maxs - world.mins);
  87         for(player = playerlist; player; player = player.chain)
  88                 if (player != self)
  89                 {
  90                         thisdist = vlen(player.origin - spot.origin);
  91                         if (thisdist < shortest)
  92                                 shortest = thisdist;
  93                 }
  94         return shortest;
  95 }
  96
  97 float spawn_allbad;
  98 float spawn_allgood;
  99 entity Spawn_FilterOutBadSpots(entity firstspot, entity playerlist, float mindist, float teamcheck)
 100 {
 101         local entity spot, spotlist, spotlistend;
 102         spawn_allgood = TRUE;
 103         spawn_allbad = TRUE;
 104
 105         spotlist = world;
 106         spotlistend = world;
 107
 108         for(spot = firstspot; spot; spot = spot.chain)
 109         {
 110                 spot.SPAWNPOINT_SCORE = Spawn_Score(spot, playerlist, teamcheck);
 111
 112                 if(cvar("spawn_debugview"))
 113                 {
 114                         setmodel(spot, "models/runematch/rune.mdl");
 115                         if(spot.SPAWNPOINT_SCORE < mindist)
 116                         {
 117                                 spot.colormod = '1 0 0';
 118                                 spot.scale = 1;
 119                         }
 120                         else
 121                         {
 122                                 spot.colormod = '0 1 0';
 123                                 spot.scale = spot.SPAWNPOINT_SCORE / mindist;
 124                         }
 125                 }
 126
 127                 if(spot.SPAWNPOINT_SCORE >= 0) // spawning allowed here
 128                 {
 129                         if(spot.SPAWNPOINT_SCORE < mindist)
 130                         {
 131                                 // too short distance
 132                                 spawn_allgood = FALSE;
 133                         }
 134                         else
 135                         {
 136                                 // perfect
 137                                 spawn_allbad = FALSE;
 138
 139                                 if(spotlistend)
 140                                         spotlistend.chain = spot;
 141                                 spotlistend = spot;
 142                                 if(!spotlist)
 143                                         spotlist = spot;
 144
 145                                 /*
 146                                 if(teamcheck)
 147                                 if(spot.team != teamcheck)
 148                                         error("invalid spawn added");
 149
 150                                 print("added ", etos(spot), "\n");
 151                                 */
 152                         }
 153                 }
 154         }
 155         if(spotlistend)
 156                 spotlistend.chain = world;
 157
 158         /*
 159                 entity e;
 160                 if(teamcheck)
 161                         for(e = spotlist; e; e = e.chain)
 162                         {
 163                                 print("seen ", etos(e), "\n");
 164                                 if(e.team != teamcheck)
 165                                         error("invalid spawn found");
 166                         }
 167         */
 168
 169         return spotlist;
 170 }
 171
 172 entity Spawn_WeightedPoint(entity firstspot, float lower, float upper, float exponent)
 173 {
 174         // weight of a point: bound(lower, mindisttoplayer, upper)^exponent
 175         // multiplied by spot.cnt (useful if you distribute many spawnpoints in a small area)
 176         local entity spot;
 177
 178         RandomSelection_Init();
 179         for(spot = firstspot; spot; spot = spot.chain)
 180                 RandomSelection_Add(spot, 0, pow(bound(lower, spot.SPAWNPOINT_SCORE, upper), exponent) * spot.cnt, spot.SPAWNPOINT_SCORE >= lower);
 181
 182         return RandomSelection_chosen_ent;
 183 }
 184
 185 /*
 186 =============
 187 SelectSpawnPoint
 188
 189 Finds a point to respawn
 190 =============
 191 */
 192 entity SelectSpawnPoint (float anypoint)
 193 {
 194         local float teamcheck;
 195         local entity firstspot_new;
 196         local entity spot, firstspot, playerlist;
 197
 198         spot = find (world, classname, "testplayerstart");
 199         if (spot)
 200                 return spot;
 201
 202         teamcheck = 0;
 203
 204         if(!anypoint && have_team_spawns)
 205                 teamcheck = self.team;
 206
 207         // get the list of players
 208         playerlist = findchain(classname, "player");
 209         // get the entire list of spots
 210         firstspot = findchain(classname, "info_player_deathmatch");
 211         // filter out the bad ones
 212         // (note this returns the original list if none survived)
 213         firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, 100, teamcheck);
 214         if(!firstspot_new)
 215                 firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, -1, teamcheck);
 216         firstspot = firstspot_new;
 217
 218         // there is 50/50 chance of choosing a random spot or the furthest spot
 219         // (this means that roughly every other spawn will be furthest, so you
 220         // usually won't get fragged at spawn twice in a row)
 221         if (arena_roundbased)
 222         {
 223                 firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, 800, teamcheck);
 224                 if(firstspot_new)
 225                         firstspot = firstspot_new;
 226                 spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 227         }
 228         else if (random() > cvar("g_spawn_furthest"))
 229                 spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 230         else
 231                 spot = Spawn_WeightedPoint(firstspot, 1, 5000, 5); // chooses a far far away spawnpoint
 232
 233         if(cvar("spawn_debugview"))
 234         {
 235                 print("spot mindistance: ", ftos(spot.SPAWNPOINT_SCORE), "\n");
 236
 237                 entity e;
 238                 if(teamcheck)
 239                         for(e = firstspot; e; e = e.chain)
 240                                 if(e.team != teamcheck)
 241                                         error("invalid spawn found");
 242         }
 243
 244         if (!spot)
 245         {
 246                 if(cvar("spawn_debug"))
 247                         GotoNextMap();
 248                 else
 249                 {
 250                         if(some_spawn_has_been_used)
 251                                 return world; // team can't spawn any more, because of actions of other team
 252                         else
 253                                 error("Cannot find a spawn point - please fix the map!");
 254                 }
 255         }
 256
 257         return spot;
 258 }
 259
 260 /*
 261 =============
 262 CheckPlayerModel
 263
 264 Checks if the argument string can be a valid playermodel.
 265 Returns a valid one in doubt.
 266 =============
 267 */
 268 string FallbackPlayerModel = "models/player/marine.zym";
 269 string CheckPlayerModel(string plyermodel) {
 270         if(strlen(plyermodel) < 4)
 271                 return FallbackPlayerModel;
 272         if( substring(plyermodel,0,14) != "models/player/")
 273                 return FallbackPlayerModel;
 274         else if(cvar("sv_servermodelsonly"))
 275         {
 276                 if(substring(plyermodel,strlen(plyermodel)-4,4) != ".zym")
 277                 if(substring(plyermodel,strlen(plyermodel)-4,4) != ".dpm")
 278                 if(substring(plyermodel,strlen(plyermodel)-4,4) != ".md3")
 279                 if(substring(plyermodel,strlen(plyermodel)-4,4) != ".psk")
 280                         return FallbackPlayerModel;
 281                 if(!fexists(plyermodel))
 282                         return FallbackPlayerModel;
 283         }
 284         return plyermodel;
 285 }
 286
 287 /*
 288 =============
 289 Client_customizeentityforclient
 290
 291 LOD reduction
 292 =============
 293 */
 294 float Client_customizeentityforclient()
 295 {
 296 #ifdef ALLOW_VARIABLE_LOD
 297         // self: me
 298         // other: the player viewing me
 299         float distance;
 300         float f;
 301
 302         if(self.flags & FL_NOTARGET) // we don't need LOD for spectators
 303                 return TRUE;
 304
 305         if(other.cvar_cl_playerdetailreduction <= 0)
 306         {
 307                 if(other.cvar_cl_playerdetailreduction <= -2)
 308                         self.modelindex = self.modelindex_lod2;
 309                 else if(other.cvar_cl_playerdetailreduction <= -1)
 310                         self.modelindex = self.modelindex_lod1;
 311                 else
 312                         self.modelindex = self.modelindex_lod0;
 313         }
 314         else
 315         {
 316                 distance = vlen(self.origin - other.origin);
 317                 f = (distance + 100.0) * other.cvar_cl_playerdetailreduction;
 318                 if(f > 10000)
 319                         self.modelindex = self.modelindex_lod2;
 320                 else if(f > 5000)
 321                         self.modelindex = self.modelindex_lod1;
 322                 else
 323                         self.modelindex = self.modelindex_lod0;
 324         }
 325 #endif
 326
 327         return TRUE;
 328 }
 329
 330 void UpdatePlayerSounds();
 331 void setmodel_lod(entity e, string modelname)
 332 {
 333 #ifdef ALLOW_VARIABLE_LOD
 334         string s;
 335
 336         // FIXME: this only supports 3-letter extensions
 337         s = strcat(substring(modelname, 0, strlen(modelname) - 4), "_1", substring(modelname, 0, strlen(modelname) - 4));
 338         if(fexists(s))
 339         {
 340                 precache_model(s);
 341                 setmodel(e, s); // players have high precision
 342                 self.modelindex_lod1 = self.modelindex;
 343         }
 344         else
 345                 self.modelindex_lod1 = -1;
 346
 347         s = strcat(substring(modelname, 0, strlen(modelname) - 4), "_2", substring(modelname, 0, strlen(modelname) - 4));
 348         if(fexists(s))
 349         {
 350                 precache_model(s);
 351                 setmodel(e, s); // players have high precision
 352                 self.modelindex_lod2 = self.modelindex;
 353         }
 354         else
 355                 self.modelindex_lod2 = -1;
 356
 357         precache_model(modelname);
 358         setmodel(e, modelname); // players have high precision
 359         self.modelindex_lod0 = self.modelindex;
 360
 361         if(self.modelindex_lod1 < 0)
 362                 self.modelindex_lod1 = self.modelindex;
 363
 364         if(self.modelindex_lod2 < 0)
 365                 self.modelindex_lod2 = self.modelindex;
 366 #else
 367         precache_model(modelname);
 368         setmodel(e, modelname); // players have high precision
 369 #endif
 370         player_setupanimsformodel();
 371         UpdatePlayerSounds();
 372 }
 373
 374 /*
 375 =============
 376 PutObserverInServer
 377
 378 putting a client as observer in the server
 379 =============
 380 */
 381 void PutObserverInServer (void)
 382 {
 383         entity  spot;
 384
 385         race_PreSpawnObserver();
 386
 387         spot = SelectSpawnPoint (TRUE);
 388         if(!spot)
 389                 error("No spawnpoints for observers?!?\n");
 390         RemoveGrapplingHook(self); // Wazat's Grappling Hook
 391
 392         if(clienttype(self) == CLIENTTYPE_REAL)
 393         {
 394                 msg_entity = self;
 395                 WriteByte(MSG_ONE, SVC_SETVIEW);
 396                 WriteEntity(MSG_ONE, self);
 397         }
 398
 399         DropAllRunes(self);
 400         kh_Key_DropAll(self, TRUE);
 401
 402         if(self.flagcarried)
 403                 DropFlag(self.flagcarried);
 404
 405         WaypointSprite_PlayerDead();
 406
 407         if(self.killcount != -666)
 408         {
 409                 if(g_lms)
 410                 {
 411                         if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
 412                                 bprint ("^4", self.netname, "^4 has no more lives left\n");
 413                         else
 414                                 bprint ("^4", self.netname, "^4 is spectating now\n"); // TODO turn this into a proper forfeit?
 415                 }
 416                 else
 417                         bprint ("^4", self.netname, "^4 is spectating now\n");
 418         }
 419
 420         PlayerScore_Clear(self); // clear scores when needed
 421
 422         self.spectatortime = time;
 423
 424         self.classname = "observer";
 425         self.health = -666;
 426         self.takedamage = DAMAGE_NO;
 427         self.solid = SOLID_NOT;
 428         self.movetype = MOVETYPE_NOCLIP;
 429         self.flags = FL_CLIENT | FL_NOTARGET;
 430         self.armorvalue = 666;
 431         self.effects = 0;
 432         self.armorvalue = cvar("g_balance_armor_start");
 433         self.pauserotarmor_finished = 0;
 434         self.pauserothealth_finished = 0;
 435         self.pauseregen_finished = 0;
 436         self.damageforcescale = 0;
 437         self.death_time = 0;
 438         self.dead_frame = 0;
 439         self.alpha = 0;
 440         self.scale = 0;
 441         self.fade_time = 0;
 442         self.pain_frame = 0;
 443         self.pain_finished = 0;
 444         self.strength_finished = 0;
 445         self.invincible_finished = 0;
 446         self.pushltime = 0;
 447         self.think = SUB_Null;
 448         self.nextthink = 0;
 449         self.hook_time = 0;
 450         self.runes = 0;
 451         self.deadflag = DEAD_NO;
 452         self.angles = spot.angles;
 453         self.angles_z = 0;
 454         self.fixangle = TRUE;
 455         self.crouch = FALSE;
 456
 457         self.view_ofs = PL_VIEW_OFS;
 458         setorigin (self, spot.origin);
 459         setsize (self, '0 0 0', '0 0 0');
 460         self.oldorigin = self.origin;
 461         self.items = 0;
 462         self.model = "";
 463         self.modelindex = 0;
 464         self.weapon = 0;
 465         self.weaponmodel = "";
 466         self.weaponentity = world;
 467         self.killcount = -666;
 468         self.velocity = '0 0 0';
 469         self.avelocity = '0 0 0';
 470         self.punchangle = '0 0 0';
 471         self.punchvector = '0 0 0';
 472         self.oldvelocity = self.velocity;
 473         self.customizeentityforclient = Client_customizeentityforclient;
 474         self.viewzoom = 1;
 475         self.wantswelcomemessage = 1;
 476
 477         if(g_arena)
 478         {
 479                 if(self.version_mismatch)
 480                 {
 481                         Spawnqueue_Unmark(self);
 482                         Spawnqueue_Remove(self);
 483                 }
 484                 else
 485                 {
 486                         Spawnqueue_Insert(self);
 487                 }
 488         }
 489         else if(g_lms)
 490         {
 491                 // Only if the player cannot play at all
 492                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) == 666)
 493                         self.frags = -666;
 494                 else
 495                         self.frags = -667;
 496         }
 497         else
 498                 self.frags = -666;
 499 }
 500
 501 float RestrictSkin(float s)
 502 {
 503         if(!teams_matter)
 504                 return s;
 505         if(s == 6)
 506                 return 6;
 507         return mod(s, 3);
 508 }
 509
 510 void FixPlayermodel()
 511 {
 512         local string defaultmodel;
 513         local float defaultskin;
 514         local vector m1, m2;
 515
 516         defaultmodel = "";
 517
 518         if(cvar("sv_defaultcharacter") == 1) {
 519                 defaultskin = 0;
 520
 521                 if(teams_matter)
 522                 {
 523                         defaultmodel = cvar_string(strcat("sv_defaultplayermodel_", Team_ColorNameLowerCase(self.team)));
 524                         defaultskin = cvar(strcat("sv_defaultplayerskin_", Team_ColorNameLowerCase(self.team)));
 525                 }
 526
 527                 if(defaultmodel == "")
 528                 {
 529                         defaultmodel = cvar_string("sv_defaultplayermodel");
 530                         defaultskin = cvar("sv_defaultplayerskin");
 531                 }
 532         }
 533
 534         if(defaultmodel != "")
 535         {
 536                 if (defaultmodel != self.model)
 537                 {
 538                         m1 = self.mins;
 539                         m2 = self.maxs;
 540                         setmodel_lod (self, defaultmodel);
 541                         setsize (self, m1, m2);
 542                 }
 543
 544                 self.skin = defaultskin;
 545         } else {
 546                 if (self.playermodel != self.model)
 547                 {
 548                         self.playermodel = CheckPlayerModel(self.playermodel);
 549                         m1 = self.mins;
 550                         m2 = self.maxs;
 551                         setmodel_lod (self, self.playermodel);
 552                         setsize (self, m1, m2);
 553                 }
 554
 555                 self.skin = RestrictSkin(stof(self.playerskin));
 556         }
 557
 558         if(!teams_matter)
 559                 if(strlen(cvar_string("sv_defaultplayercolors")))
 560                         if(self.clientcolors != cvar("sv_defaultplayercolors"))
 561                                 setcolor(self, cvar("sv_defaultplayercolors"));
 562 }
 563
 564 /*
 565 =============
 566 PutClientInServer
 567
 568 Called when a client spawns in the server
 569 =============
 570 */
 571 //void() ctf_playerchanged;
 572 void PutClientInServer (void)
 573 {
 574         if(clienttype(self) == CLIENTTYPE_BOT)
 575         {
 576                 self.classname = "player";
 577         }
 578         else if(clienttype(self) == CLIENTTYPE_REAL)
 579         {
 580                 msg_entity = self;
 581                 WriteByte(MSG_ONE, SVC_SETVIEW);
 582                 WriteEntity(MSG_ONE, self);
 583         }
 584
 585         // player is dead and becomes observer
 586         // FIXME fix LMS scoring for new system
 587         if(g_lms)
 588         {
 589                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
 590                         self.classname = "observer";
 591         }
 592
 593         if(g_arena)
 594         if(!self.spawned)
 595                 self.classname = "observer";
 596
 597         if(self.classname == "player") {
 598                 entity  spot;
 599
 600                 race_PreSpawn();
 601
 602                 spot = SelectSpawnPoint (FALSE);
 603                 if(!spot)
 604                 {
 605                         centerprint(self, "Sorry, no spawnpoints available!\nHope your team can fix it...");
 606                         return; // spawn failed
 607                 }
 608
 609                 RemoveGrapplingHook(self); // Wazat's Grappling Hook
 610
 611                 self.classname = "player";
 612                 self.iscreature = TRUE;
 613                 self.movetype = MOVETYPE_WALK;
 614                 if(independent_players)
 615                         self.solid = SOLID_TRIGGER;
 616                 else
 617                         self.solid = SOLID_SLIDEBOX;
 618                 self.flags = FL_CLIENT;
 619                 self.takedamage = DAMAGE_AIM;
 620                 if(g_minstagib)
 621                         self.effects = EF_FULLBRIGHT;
 622                 else
 623                         self.effects = 0;
 624                 self.air_finished = time + 12;
 625                 self.dmg = 2;
 626
 627                 self.ammo_shells = start_ammo_shells;
 628                 self.ammo_nails = start_ammo_nails;
 629                 self.ammo_rockets = start_ammo_rockets;
 630                 self.ammo_cells = start_ammo_cells;
 631                 self.health = start_health;
 632                 self.armorvalue = start_armorvalue;
 633                 self.items = start_items;
 634                 self.switchweapon = start_switchweapon;
 635                 self.cnt = start_switchweapon;
 636                 self.weapon = 0;
 637                 self.jump_interval = time;
 638
 639                 self.spawnshieldtime = time + cvar("g_spawnshieldtime");
 640                 self.pauserotarmor_finished = time + cvar("g_balance_pause_armor_rot_spawn");
 641                 self.pauserothealth_finished = time + cvar("g_balance_pause_health_rot_spawn");
 642                 self.pauseregen_finished = time + cvar("g_balance_pause_health_regen_spawn");
 643                 //extend the pause of rotting if client was reset at the beginning of the countdown
 644                 if(!cvar("sv_ready_restart_after_countdown") && time < restart_countdown) {
 645                         self.spawnshieldtime += RESTART_COUNTDOWN;
 646                         self.pauserotarmor_finished += RESTART_COUNTDOWN;
 647                         self.pauserothealth_finished += RESTART_COUNTDOWN;
 648                         self.pauseregen_finished += RESTART_COUNTDOWN;
 649                 }
 650                 self.damageforcescale = 2;
 651                 self.death_time = 0;
 652                 self.dead_frame = 0;
 653                 self.alpha = 0;
 654                 self.scale = 0;
 655                 self.fade_time = 0;
 656                 self.pain_frame = 0;
 657                 self.pain_finished = 0;
 658                 self.strength_finished = 0;
 659                 self.invincible_finished = 0;
 660                 self.pushltime = 0;
 661                 //self.speed_finished = 0;
 662                 //self.slowmo_finished = 0;
 663                 // players have no think function
 664                 self.think = SUB_Null;
 665                 self.nextthink = 0;
 666                 self.hook_time = 0;
 667
 668                 self.runes = 0;
 669
 670                 self.deadflag = DEAD_NO;
 671
 672                 self.angles = spot.angles;
 673
 674                 self.angles_z = 0; // never spawn tilted even if the spot says to
 675                 self.fixangle = TRUE; // turn this way immediately
 676                 self.velocity = '0 0 0';
 677                 self.avelocity = '0 0 0';
 678                 self.punchangle = '0 0 0';
 679                 self.punchvector = '0 0 0';
 680                 self.oldvelocity = self.velocity;
 681
 682                 self.viewzoom = 0.6;
 683                 self.has_zoomed = 0;
 684
 685                 self.customizeentityforclient = Client_customizeentityforclient;
 686
 687                 self.model = "";
 688                 FixPlayermodel();
 689
 690                 self.crouch = FALSE;
 691                 self.view_ofs = PL_VIEW_OFS;
 692                 setsize (self, PL_MIN, PL_MAX);
 693                 self.spawnorigin = spot.origin;
 694                 setorigin (self, spot.origin + '0 0 1' * (1 - self.mins_z - 24));
 695                 // don't reset back to last position, even if new position is stuck in solid
 696                 self.oldorigin = self.origin;
 697
 698                 if(g_arena)
 699                 {
 700                         Spawnqueue_Remove(self);
 701                         Spawnqueue_Mark(self);
 702                 }
 703
 704                 self.event_damage = PlayerDamage;
 705
 706                 self.bot_attack = TRUE;
 707
 708                 self.statdraintime = time + 5;
 709                 self.BUTTON_ATCK = self.BUTTON_JUMP = self.BUTTON_ATCK2 = 0;
 710
 711                 if(self.killcount == -666) {
 712                         PlayerScore_Clear(self);
 713                         self.killcount = 0;
 714                         self.frags = 0;
 715                 }
 716
 717                 self.cnt = WEP_LASER;
 718                 self.nixnex_lastchange_id = -1;
 719
 720                 CL_SpawnWeaponentity();
 721                 self.alpha = default_player_alpha;
 722                 self.colormod = '1 1 1' * cvar("g_player_brightness");
 723                 self.exteriorweaponentity.alpha = default_weapon_alpha;
 724
 725                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval")*2;
 726                 self.lms_traveled_distance = 0;
 727                 self.speedrunning = FALSE;
 728
 729                 race_PostSpawn(spot);
 730
 731                 if(cvar("spawn_debug"))
 732                 {
 733                         sprint(self, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 734                         remove(spot);   // usefull for checking if there are spawnpoints, that let drop through the floor
 735                 }
 736
 737                 //stuffcmd(self, "chase_active 0");
 738                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
 739
 740                 if (cvar("g_spawnsound"))
 741                         sound (self, CHAN_TRIGGER, "misc/spawn.wav", VOL_BASE, ATTN_NORM);
 742
 743                 if(g_assault) {
 744                         if(self.team == assault_attacker_team)
 745                                 centerprint(self, "You are attacking!\n");
 746                         else
 747                                 centerprint(self, "You are defending!\n");
 748                 }
 749
 750         } else if(self.classname == "observer") {
 751                 PutObserverInServer ();
 752         }
 753
 754         //if(g_ctf)
 755         //      ctf_playerchanged();
 756 }
 757
 758 /*
 759 =============
 760 SendCSQCInfo
 761
 762 Send whatever CSQC needs NOW and cannot wait for SendServerInfo to happen...
 763 =============
 764 */
 765 void SendCSQCInfo(void)
 766 {
 767         if(clienttype(self) != CLIENTTYPE_REAL)
 768                 return;
 769         msg_entity = self;
 770         WriteByte(MSG_ONE, SVC_TEMPENTITY);
 771         WriteByte(MSG_ONE, TE_CSQC_INIT);
 772         WriteShort(MSG_ONE, CSQC_REVISION);
 773         WriteByte(MSG_ONE, maxclients);
 774 }
 775
 776 /*
 777 =============
 778 SetNewParms
 779 =============
 780 */
 781 void SetNewParms (void)
 782 {
 783         // initialize parms for a new player
 784         parm1 = -(86400 * 366);
 785 }
 786
 787 /*
 788 =============
 789 SetChangeParms
 790 =============
 791 */
 792 void SetChangeParms (void)
 793 {
 794         // save parms for level change
 795         parm1 = self.parm_idlesince - time;
 796 }
 797
 798 /*
 799 =============
 800 DecodeLevelParms
 801 =============
 802 */
 803 void DecodeLevelParms (void)
 804 {
 805         // load parms
 806         self.parm_idlesince = parm1;
 807         if(self.parm_idlesince == -(86400 * 366))
 808                 self.parm_idlesince = time;
 809 }
 810
 811 /*
 812 =============
 813 ClientKill
 814
 815 Called when a client types 'kill' in the console
 816 =============
 817 */
 818
 819 void ClientKill_Now_TeamChange()
 820 {
 821         if(self.killindicator_teamchange == -1)
 822         {
 823                 self.team = -1;
 824                 JoinBestTeam( self, FALSE, FALSE );
 825         }
 826         else
 827         {
 828                 SV_ChangeTeam(self.killindicator_teamchange - 1);
 829         }
 830 }
 831
 832 void ClientKill_Now()
 833 {
 834         if(self.killindicator_teamchange)
 835                 ClientKill_Now_TeamChange();
 836
 837         // in any case:
 838         Damage(self, self, self, 100000, DEATH_KILL, self.origin, '0 0 0');
 839
 840         if(self.killindicator)
 841         {
 842                 dprint("Cleaned up after a leaked kill indicator.\n");
 843                 remove(self.killindicator);
 844                 self.killindicator = world;
 845         }
 846 }
 847 void KillIndicator_Think()
 848 {
 849         if (!self.owner.modelindex)
 850         {
 851                 self.owner.killindicator = world;
 852                 remove(self);
 853                 return;
 854         }
 855
 856         if(self.cnt <= 0)
 857         {
 858                 self = self.owner;
 859                 ClientKill_Now(); // no oldself needed
 860                 return;
 861         }
 862         else
 863         {
 864                 if(self.cnt <= 10)
 865                         setmodel(self, strcat("models/sprites/", ftos(self.cnt), ".spr32"));
 866                 if(clienttype(self.owner) == CLIENTTYPE_REAL)
 867                 {
 868                         if(self.cnt <= 10)
 869                                 announce(self.owner, strcat("announcer/robotic/", ftos(self.cnt), ".ogg"));
 870                         if(self.owner.killindicator_teamchange)
 871                         {
 872                                 if(self.owner.killindicator_teamchange == -1)
 873                                         centerprint(self.owner, strcat("Changing team in ", ftos(self.cnt), " seconds"));
 874                                 else
 875                                         centerprint(self.owner, strcat("Changing to ", ColoredTeamName(self.owner.killindicator_teamchange), " in ", ftos(self.cnt), " seconds"));
 876                         }
 877                         else
 878                                 centerprint(self.owner, strcat("^1Suicide in ", ftos(self.cnt), " seconds"));
 879                 }
 880                 self.nextthink = time + 1;
 881                 self.cnt -= 1;
 882         }
 883 }
 884
 885 void ClientKill_TeamChange (float targetteam) // 0 = don't change, -1 = auto
 886 {
 887         float killtime;
 888         entity e;
 889         killtime = cvar("g_balance_kill_delay");
 890
 891         self.killindicator_teamchange = targetteam;
 892
 893         if(!self.killindicator)
 894         {
 895                 if(killtime <= 0 || !self.modelindex || self.deadflag != DEAD_NO)
 896                 {
 897                         ClientKill_Now();
 898                 }
 899                 else
 900                 {
 901                         self.killindicator = spawn();
 902                         self.killindicator.owner = self;
 903                         self.killindicator.scale = 0.5;
 904                         setattachment(self.killindicator, self, "");
 905                         setorigin(self.killindicator, '0 0 52');
 906                         self.killindicator.think = KillIndicator_Think;
 907                         self.killindicator.nextthink = time + (self.lip) * 0.05;
 908                         self.killindicator.cnt = ceil(killtime);
 909                         self.killindicator.count = bound(0, ceil(killtime), 10);
 910                         sprint(self, strcat("^1You'll be dead in ", ftos(self.killindicator.cnt), " seconds\n"));
 911
 912                         for(e = world; (e = find(e, classname, "body")) != world; )
 913                         {
 914                                 if(e.enemy != self)
 915                                         continue;
 916                                 e.killindicator = spawn();
 917                                 e.killindicator.owner = e;
 918                                 e.killindicator.scale = 0.5;
 919                                 setattachment(e.killindicator, e, "");
 920                                 setorigin(e.killindicator, '0 0 52');
 921                                 e.killindicator.think = KillIndicator_Think;
 922                                 e.killindicator.nextthink = time + (e.lip) * 0.05;
 923                                 e.killindicator.cnt = ceil(killtime);
 924                         }
 925                         self.lip = 0;
 926                 }
 927         }
 928         if(self.killindicator)
 929         {
 930                 if(targetteam)
 931                         self.killindicator.colormod = TeamColor(targetteam);
 932                 else
 933                         self.killindicator.colormod = '0 0 0';
 934         }
 935 }
 936
 937 void ClientKill (void)
 938 {
 939         ClientKill_TeamChange(0);
 940 }
 941
 942 void DoTeamChange(float destteam)
 943 {
 944         float t, c0;
 945         if(!cvar("teamplay"))
 946         {
 947                 if(destteam >= 0)
 948                         SetPlayerColors(self, destteam);
 949                 return;
 950         }
 951         if(self.classname == "player")
 952         if(destteam == -1)
 953         {
 954                 CheckAllowedTeams(self);
 955                 t = FindSmallestTeam(self, TRUE);
 956                 switch(self.team)
 957                 {
 958                         case COLOR_TEAM1: c0 = c1; break;
 959                         case COLOR_TEAM2: c0 = c2; break;
 960                         case COLOR_TEAM3: c0 = c3; break;
 961                         case COLOR_TEAM4: c0 = c4; break;
 962                         default:          c0 = 999;
 963                 }
 964                 switch(t)
 965                 {
 966                         case 1:
 967                                 if(c0 > c1)
 968                                         destteam = COLOR_TEAM1;
 969                                 break;
 970                         case 2:
 971                                 if(c0 > c2)
 972                                         destteam = COLOR_TEAM2;
 973                                 break;
 974                         case 3:
 975                                 if(c0 > c3)
 976                                         destteam = COLOR_TEAM3;
 977                                 break;
 978                         case 4:
 979                                 if(c0 > c4)
 980                                         destteam = COLOR_TEAM4;
 981                                 break;
 982                 }
 983                 if(destteam == -1)
 984                         return;
 985         }
 986         if(destteam == self.team && !self.killindicator)
 987                 return;
 988         ClientKill_TeamChange(destteam);
 989 }
 990
 991 void FixClientCvars(entity e)
 992 {
 993         // send prediction settings to the client
 994         stuffcmd(e, "\nin_bindmap 0 0\n");
 995         /*
 996          * we no longer need to stuff this. Remove this comment block if you feel
 997          * 2.3 and higher (or was it 2.2.3?) don't need these any more
 998         stuffcmd(e, strcat("cl_gravity ", ftos(cvar("sv_gravity")), "\n"));
 999         stuffcmd(e, strcat("cl_movement_accelerate ", ftos(cvar("sv_accelerate")), "\n"));
1000         stuffcmd(e, strcat("cl_movement_friction ", ftos(cvar("sv_friction")), "\n"));
1001         stuffcmd(e, strcat("cl_movement_maxspeed ", ftos(cvar("sv_maxspeed")), "\n"));
1002         stuffcmd(e, strcat("cl_movement_airaccelerate ", ftos(cvar("sv_airaccelerate")), "\n"));
1003         stuffcmd(e, strcat("cl_movement_maxairspeed ", ftos(cvar("sv_maxairspeed")), "\n"));
1004         stuffcmd(e, strcat("cl_movement_stopspeed ", ftos(cvar("sv_stopspeed")), "\n"));
1005         stuffcmd(e, strcat("cl_movement_jumpvelocity ", ftos(cvar("sv_jumpvelocity")), "\n"));
1006         stuffcmd(e, strcat("cl_movement_stepheight ", ftos(cvar("sv_stepheight")), "\n"));
1007         stuffcmd(e, strcat("set cl_movement_friction_on_land ", ftos(cvar("sv_friction_on_land")), "\n"));
1008         stuffcmd(e, strcat("set cl_movement_airaccel_qw ", ftos(cvar("sv_airaccel_qw")), "\n"));
1009         stuffcmd(e, strcat("set cl_movement_airaccel_sideways_friction ", ftos(cvar("sv_airaccel_sideways_friction")), "\n"));
1010         stuffcmd(e, "cl_movement_edgefriction 1\n");
1011          */
1012 }
1013
1014 /*
1015 =============
1016 ClientConnect
1017
1018 Called when a client connects to the server
1019 =============
1020 */
1021 //void ctf_clientconnect();
1022 string ColoredTeamName(float t);
1023 void DecodeLevelParms (void);
1024 //void dom_player_join_team(entity pl);
1025 void ClientConnect (void)
1026 {
1027         local string s;
1028         float wep;
1029
1030         if(self.flags & FL_CLIENT)
1031         {
1032                 print("Warning: ClientConnect, but already connected!\n");
1033                 return;
1034         }
1035
1036         if(Ban_IsClientBanned(self))
1037         {
1038                 s = strcat("^1NOTE:^7 banned client ", self.netaddress, " just tried to enter\n");
1039                 dropclient(self);
1040                 bprint(s);
1041                 return;
1042         }
1043
1044         DecodeLevelParms();
1045
1046         self.classname = "player_joining";
1047
1048         self.flags = self.flags | FL_CLIENT;
1049         self.version_nagtime = time + 10 + random() * 10;
1050
1051         if(player_count<0)
1052         {
1053                 dprint("BUG player count is lower than zero, this cannot happen!\n");
1054                 player_count = 0;
1055         }
1056
1057         PlayerScore_Attach(self);
1058
1059         bot_clientconnect();
1060
1061         race_PreSpawnObserver();
1062
1063         //if(g_domination)
1064         //      dom_player_join_team(self);
1065
1066         //JoinBestTeam(self, FALSE, FALSE);
1067
1068         if((cvar("sv_spectate") == 1 && !g_lms) || cvar("g_campaign")) {
1069                 self.classname = "observer";
1070         } else {
1071                 self.classname = "player";
1072                 campaign_bots_may_start = 1;
1073         }
1074
1075         self.playerid = (playerid_last = playerid_last + 1);
1076         if(cvar("sv_eventlog"))
1077         {
1078                 if(clienttype(self) == CLIENTTYPE_REAL)
1079                         s = "player";
1080                 else
1081                         s = "bot";
1082                 GameLogEcho(strcat(":join:", ftos(self.playerid), ":", s, ":", self.netname), TRUE);
1083                 s = strcat(":team:", ftos(self.playerid), ":");
1084                 s = strcat(s, ftos(self.team));
1085                 GameLogEcho(s, FALSE);
1086         }
1087         self.netname_previous = strzone(self.netname);
1088
1089         //stuffcmd(self, "set tmpviewsize $viewsize \n");
1090
1091         bprint ("^4",self.netname);
1092         bprint ("^4 connected");
1093
1094         if(g_domination || g_ctf)
1095         {
1096                 bprint(" and joined the ");
1097                 bprint(ColoredTeamName(self.team));
1098         }
1099
1100         bprint("\n");
1101
1102         self.welcomemessage_time = 0;
1103
1104         stuffcmd(self, strcat("exec maps/", mapname, ".cfg\n"));
1105         // TODO: is this being used for anything else than cd tracks?
1106         // Remember: SVC_CDTRACK exists. Maybe it should be used.
1107         //
1108         stuffcmd(self, "cl_particles_reloadeffects\n");
1109
1110         FixClientCvars(self);
1111
1112         // spawnfunc_waypoint sprites
1113         WaypointSprite_InitClient(self);
1114
1115         // Wazat's grappling hook
1116         SetGrappleHookBindings();
1117
1118         // get autoswitch state from player when he toggles it
1119         stuffcmd(self, "alias autoswitch \"set cl_autoswitch $1 ; cmd autoswitch $1\"\n"); // default.cfg-ed in 2.4.1
1120
1121         // get version info from player
1122         stuffcmd(self, "cmd clientversion $gameversion\n");
1123
1124         // send all weapon info strings
1125         stuffcmd(self, "register_bestweapon clear\n"); // clear the Quake stuff
1126         wep = WEP_FIRST;
1127         while (wep <= WEP_LAST)
1128         {
1129                 weapon_action(wep, WR_REGISTER);
1130                 wep = wep + 1;
1131         }
1132
1133         // get other cvars from player
1134         GetCvars(0);
1135
1136         // set cvar for team scoreboard
1137         if (teams_matter)
1138         {
1139                 local float t;
1140                 t = cvar("teamplay");
1141                 // we have to stuff the correct teamplay value because if this is a listen server, this changes the teamplay mode of the server itself, which is bad
1142                 stuffcmd(self, strcat("set teamplay ", ftos(t), "\n"));
1143         }
1144         else
1145                 stuffcmd(self, "set teamplay 0\n");
1146
1147         // notify about available teams
1148         if(teamplay)
1149         {
1150                 CheckAllowedTeams(self);
1151                 t = 0; if(c1 >= 0) t |= 1; if(c2 >= 0) t |= 2; if(c3 >= 0) t |= 4; if(c4 >= 0) t |= 8;
1152                 stuffcmd(self, strcat("set _teams_available ", ftos(t), "\n"));
1153         }
1154         else
1155                 stuffcmd(self, "set _teams_available 0\n");
1156
1157         stuffcmd(self, strcat("set gametype ", ftos(game), "\n"));
1158
1159         if(g_arena)
1160         {
1161                 self.classname = "observer";
1162                 Spawnqueue_Insert(self);
1163         }
1164         /*else if(g_ctf)
1165         {
1166                 ctf_clientconnect();
1167         }*/
1168
1169         if(entcs_start)
1170                 attach_entcs();
1171
1172         bot_relinkplayerlist();
1173
1174         self.spectatortime = time;
1175         if(blockSpectators)
1176         {
1177                 sprint(self, strcat("^7You have to become a player within the next ", ftos(cvar("g_maxplayers_spectator_blocktime")), " seconds, otherwise you will be kicked, because spectators aren't allowed at this time!\n"));
1178         }
1179
1180         self.jointime = time;
1181         self.allowedTimeouts = cvar("sv_timeout_number");
1182
1183         if(clienttype(self) == CLIENTTYPE_REAL)
1184         {
1185                 sprint(self, strcat("nexuiz-csqc protocol ", ftos(CSQC_REVISION), "\n"));
1186                 SendCSQCInfo();
1187                 msg_entity = self;
1188                 if(mapvote_initialized && !cvar("g_maplist_textonly"))
1189                 {
1190                         MapVote_SendData(MSG_ONE);
1191                         MapVote_UpdateData(MSG_ONE);
1192                 }
1193                 ScoreInfo_Write(MSG_ONE);
1194         }
1195
1196         if(g_lms)
1197         {
1198                 if(PlayerScore_Add(self, SP_LMS_LIVES, LMS_NewPlayerLives()) <= 0)
1199                 {
1200                         PlayerScore_Add(self, SP_LMS_RANK, 666);
1201                         self.frags = -666; // FIXME do we still need this?
1202                 }
1203         }
1204 }
1205
1206 /*
1207 =============
1208 ClientDisconnect
1209
1210 Called when a client disconnects from the server
1211 =============
1212 */
1213 void(entity e) DropFlag;
1214 .entity chatbubbleentity;
1215 .entity teambubbleentity;
1216 //void() ctf_clientdisconnect;
1217 void ClientDisconnect (void)
1218 {
1219         float save;
1220
1221         if not(self.flags & FL_CLIENT)
1222         {
1223                 print("Warning: ClientDisconnect without ClientConnect\n");
1224                 return;
1225         }
1226
1227         bot_clientdisconnect();
1228
1229         if(entcs_start)
1230                 detach_entcs();
1231
1232         if(cvar("sv_eventlog"))
1233                 GameLogEcho(strcat(":part:", ftos(self.playerid)), FALSE);
1234         bprint ("^4",self.netname);
1235         bprint ("^4 disconnected\n");
1236
1237         if (self.chatbubbleentity)
1238         {
1239                 remove (self.chatbubbleentity);
1240                 self.chatbubbleentity = world;
1241         }
1242
1243         if (self.teambubbleentity)
1244         {
1245                 remove (self.teambubbleentity);
1246                 self.teambubbleentity = world;
1247         }
1248
1249         if (self.killindicator)
1250         {
1251                 remove (self.killindicator);
1252                 self.killindicator = world;
1253         }
1254
1255         WaypointSprite_PlayerGone();
1256
1257         DropAllRunes(self);
1258         kh_Key_DropAll(self, TRUE);
1259
1260         if(self.flagcarried)
1261                 DropFlag(self.flagcarried);
1262
1263         save = self.flags;
1264         self.flags = self.flags - (self.flags & FL_CLIENT);
1265         bot_relinkplayerlist();
1266         self.flags = save;
1267
1268         // remove laserdot
1269         if(self.weaponentity)
1270                 if(self.weaponentity.lasertarget)
1271                         remove(self.weaponentity.lasertarget);
1272
1273         if(g_arena)
1274         {
1275                 Spawnqueue_Unmark(self);
1276                 Spawnqueue_Remove(self);
1277         }
1278         /*if(g_ctf)
1279         {
1280                 ctf_clientdisconnect();
1281         }
1282         */
1283
1284         PlayerScore_Detach(self);
1285
1286         if(self.netname_previous)
1287                 strunzone(self.netname_previous);
1288
1289         ClearPlayerSounds();
1290
1291         // free cvars
1292         GetCvars(-1);
1293         self.playerid = 0;
1294 }
1295
1296 .float BUTTON_CHAT;
1297 void ChatBubbleThink()
1298 {
1299         self.nextthink = time;
1300         if (!self.owner.modelindex || self.owner.chatbubbleentity != self)
1301         {
1302                 self.owner.chatbubbleentity = world;
1303                 remove(self);
1304                 return;
1305         }
1306         setorigin(self, self.owner.origin + '0 0 15' + self.owner.maxs_z * '0 0 1');
1307         if (self.owner.BUTTON_CHAT && !self.owner.deadflag)
1308                 self.model = self.mdl;
1309         else
1310                 self.model = "";
1311 };
1312
1313 void UpdateChatBubble()
1314 {
1315         if (!self.modelindex)
1316                 return;
1317         // spawn a chatbubble entity if needed
1318         if (!self.chatbubbleentity)
1319         {
1320                 self.chatbubbleentity = spawn();
1321                 self.chatbubbleentity.owner = self;
1322                 self.chatbubbleentity.exteriormodeltoclient = self;
1323                 self.chatbubbleentity.think = ChatBubbleThink;
1324                 self.chatbubbleentity.nextthink = time;
1325                 setmodel(self.chatbubbleentity, "models/misc/chatbubble.spr"); // precision set below
1326                 setorigin(self.chatbubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1327                 self.chatbubbleentity.mdl = self.chatbubbleentity.model;
1328                 self.chatbubbleentity.model = "";
1329                 self.chatbubbleentity.effects = EF_LOWPRECISION;
1330         }
1331 }
1332
1333
1334 void TeamBubbleThink()
1335 {
1336         self.nextthink = time;
1337         if (!self.owner.modelindex || self.owner.teambubbleentity != self)
1338         {
1339                 self.owner.teambubbleentity = world;
1340                 remove(self);
1341                 return;
1342         }
1343 //      setorigin(self, self.owner.origin + '0 0 15' + self.owner.maxs_z * '0 0 1');  // bandwidth hog. setattachment does this now
1344         if (self.owner.BUTTON_CHAT || self.owner.deadflag || self.owner.killindicator)
1345                 self.model = "";
1346         else
1347                 self.model = self.mdl;
1348
1349 };
1350
1351 float TeamBubble_customizeentityforclient()
1352 {
1353         return (self.owner != other && self.owner.team == other.team && other.killcount > -666);
1354 }
1355
1356 void UpdateTeamBubble()
1357 {
1358         if (!self.modelindex || !cvar("teamplay"))
1359                 return;
1360         // spawn a teambubble entity if needed
1361         if (!self.teambubbleentity && cvar("teamplay"))
1362         {
1363                 self.teambubbleentity = spawn();
1364                 self.teambubbleentity.owner = self;
1365                 self.teambubbleentity.exteriormodeltoclient = self;
1366                 self.teambubbleentity.think = TeamBubbleThink;
1367                 self.teambubbleentity.nextthink = time;
1368                 setmodel(self.teambubbleentity, "models/misc/teambubble.spr"); // precision set below
1369 //              setorigin(self.teambubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1370                 setorigin(self.teambubbleentity, self.teambubbleentity.origin + '0 0 15' + self.maxs_z * '0 0 1');
1371                 setattachment(self.teambubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1372                 self.teambubbleentity.mdl = self.teambubbleentity.model;
1373                 self.teambubbleentity.model = self.teambubbleentity.mdl;
1374                 self.teambubbleentity.customizeentityforclient = TeamBubble_customizeentityforclient;
1375                 self.teambubbleentity.effects = EF_LOWPRECISION;
1376         }
1377 }
1378
1379 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1380 // added to the model skins
1381 /*void UpdateColorModHack()
1382 {
1383         local float c;
1384         c = self.clientcolors & 15;
1385         // LordHavoc: only bothering to support white, green, red, yellow, blue
1386              if (teamplay == 0) self.colormod = '0 0 0';
1387         else if (c ==  0) self.colormod = '1.00 1.00 1.00';
1388         else if (c ==  3) self.colormod = '0.10 1.73 0.10';
1389         else if (c ==  4) self.colormod = '1.73 0.10 0.10';
1390         else if (c == 12) self.colormod = '1.22 1.22 0.10';
1391         else if (c == 13) self.colormod = '0.10 0.10 1.73';
1392         else self.colormod = '1 1 1';
1393 };*/
1394
1395 void respawn(void)
1396 {
1397         CopyBody(1);
1398         self.effects |= EF_NODRAW; // prevent another CopyBody
1399         PutClientInServer();
1400 }
1401
1402 /**
1403  * When sv_timeout is used this function returs strings like
1404  * "Timeout begins in 2 seconds!\n" or "Timeout ends in 23 seconds!\n".
1405  * Called by centerprint functions
1406  * @param addOneSecond boolean, set to 1 if the welcome-message centerprint asks for the text
1407  */
1408 string getTimeoutText(float addOneSecond) {
1409         if (!cvar("sv_timeout") || !timeoutStatus)
1410                 return "";
1411
1412         local string retStr;
1413         if (timeoutStatus == 1) {
1414                 if (addOneSecond == 1) {
1415                         retStr = strcat("Timeout begins in ", ftos(remainingLeadTime + 1), " seconds!\n");
1416                 }
1417                 else {
1418                         retStr = strcat("Timeout begins in ", ftos(remainingLeadTime), " seconds!\n");
1419                 }
1420                 return retStr;
1421         }
1422         else if (timeoutStatus == 2) {
1423                 if (addOneSecond) {
1424                         retStr = strcat("Timeout ends in ", ftos(remainingTimeoutTime + 1), " seconds!\n");
1425                         //don't show messages like "Timeout ends in 0 seconds"...
1426                         if ((remainingTimeoutTime + 1) > 0)
1427                                 return retStr;
1428                         else
1429                                 return "";
1430                 }
1431                 else {
1432                         retStr = strcat("Timeout ends in ", ftos(remainingTimeoutTime), " seconds!\n");
1433                         //don't show messages like "Timeout ends in 0 seconds"...
1434                         if (remainingTimeoutTime > 0)
1435                                 return retStr;
1436                         else
1437                                 return "";
1438                 }
1439         }
1440         else return "";
1441 }
1442
1443 void player_powerups (void)
1444 {
1445         if (g_minstagib)
1446         {
1447                 if (self.items & IT_STRENGTH)
1448                 {
1449                         if (time > self.strength_finished)
1450                         {
1451                                 if (g_minstagib_invis_alpha > 0)
1452                                 {
1453                                         self.alpha = default_player_alpha;
1454                                         self.exteriorweaponentity.alpha = default_weapon_alpha;
1455                                         self.effects = self.effects | EF_FULLBRIGHT;
1456                                 }
1457                                 else
1458                                 {
1459                                         self.effects -= self.effects & EF_NODRAW;
1460                                 }
1461                                 self.items = self.items - (self.items & IT_STRENGTH);
1462                                 sprint(self, "^3Invisibility has worn off\n");
1463                         }
1464                 }
1465                 else
1466                 {
1467                         if (time < self.strength_finished)
1468                         {
1469                                 if (g_minstagib_invis_alpha > 0)
1470                                 {
1471                                         self.alpha = g_minstagib_invis_alpha;
1472                                         self.exteriorweaponentity.alpha = g_minstagib_invis_alpha;
1473                                         self.effects -= self.effects & EF_FULLBRIGHT;
1474                                 }
1475                                 else
1476                                 {
1477                                         self.effects = self.effects | EF_NODRAW;
1478                                 }
1479                                 self.items = self.items | IT_STRENGTH;
1480                                 sprint(self, "^3You are invisible\n");
1481                         }
1482                 }
1483
1484                 if (self.items & IT_INVINCIBLE)
1485                 {
1486                         if (time > self.invincible_finished)
1487                         {
1488                                 self.items = self.items - (self.items & IT_INVINCIBLE);
1489                                 sprint(self, "^3Speed has worn off\n");
1490                         }
1491                 }
1492                 else
1493                 {
1494                         if (time < self.invincible_finished)
1495                         {
1496                                 self.items = self.items | IT_INVINCIBLE;
1497                                 sprint(self, "^3You are on speed\n");
1498                         }
1499                 }
1500                 return;
1501         }
1502
1503         self.effects = self.effects - (self.effects & (EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT));
1504         if (self.items & IT_STRENGTH)
1505         {
1506                 self.effects = self.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1507                 if (time > self.strength_finished)
1508                 {
1509                         self.items = self.items - (self.items & IT_STRENGTH);
1510                         sprint(self, "^3Strength has worn off\n");
1511                 }
1512         }
1513         else
1514         {
1515                 if (time < self.strength_finished)
1516                 {
1517                         self.items = self.items | IT_STRENGTH;
1518                         sprint(self, "^3Strength infuses your weapons with devastating power\n");
1519                 }
1520         }
1521         if (self.items & IT_INVINCIBLE)
1522         {
1523                 self.effects = self.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1524                 if (time > self.invincible_finished)
1525                 {
1526                         self.items = self.items - (self.items & IT_INVINCIBLE);
1527                         sprint(self, "^3Shield has worn off\n");
1528                 }
1529         }
1530         else
1531         {
1532                 if (time < self.invincible_finished)
1533                 {
1534                         self.items = self.items | IT_INVINCIBLE;
1535                         sprint(self, "^3Shield surrounds you\n");
1536                 }
1537         }
1538
1539         if (cvar("g_fullbrightplayers"))
1540                 self.effects = self.effects | EF_FULLBRIGHT;
1541
1542         // midair gamemode: damage only while in the air
1543         // if in midair mode, being on ground grants temporary invulnerability
1544         // (this is so that multishot weapon don't clear the ground flag on the
1545         // first damage in the frame, leaving the player vulnerable to the
1546         // remaining hits in the same frame)
1547         if (self.flags & FL_ONGROUND)
1548         if (g_midair)
1549                 self.spawnshieldtime = max(self.spawnshieldtime, time + cvar("g_midair_shieldtime"));
1550
1551         if (time < self.spawnshieldtime)
1552                 self.effects = self.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1553 }
1554
1555 float CalcRegen(float current, float stable, float regenfactor)
1556 {
1557         if(current > stable)
1558                 return current;
1559         else if(current > stable - 0.25) // when close enough, "snap"
1560                 return stable;
1561         else
1562                 return min(stable, current + (stable - current) * regenfactor * frametime);
1563 }
1564
1565 void player_regen (void)
1566 {
1567         float maxh, maxa, limith, limita, max_mod, regen_mod, rot_mod, limit_mod;
1568         maxh = cvar("g_balance_health_stable");
1569         maxa = cvar("g_balance_armor_stable");
1570         limith = cvar("g_balance_health_limit");
1571         limita = cvar("g_balance_armor_limit");
1572
1573         if (g_minstagib || (g_lms && !cvar("g_lms_regenerate")))
1574                 return;
1575
1576         max_mod = regen_mod = rot_mod = limit_mod = 1;
1577
1578         if (self.runes & RUNE_REGEN)
1579         {
1580                 if (self.runes & CURSE_VENOM) // do we have both rune/curse?
1581                 {
1582                         regen_mod = cvar("g_balance_rune_regen_combo_regenrate");
1583                         max_mod = cvar("g_balance_rune_regen_combo_hpmod");
1584                         limit_mod = cvar("g_balance_rune_regen_combo_limitmod");
1585                 }
1586                 else
1587                 {
1588                         regen_mod = cvar("g_balance_rune_regen_regenrate");
1589                         max_mod = cvar("g_balance_rune_regen_hpmod");
1590                         limit_mod = cvar("g_balance_rune_regen_limitmod");
1591                 }
1592         }
1593         else if (self.runes & CURSE_VENOM)
1594         {
1595                 max_mod = cvar("g_balance_curse_venom_hpmod");
1596                 if (self.runes & RUNE_REGEN) // do we have both rune/curse?
1597                         rot_mod = cvar("g_balance_rune_regen_combo_rotrate");
1598                 else
1599                         rot_mod = cvar("g_balance_curse_venom_rotrate");
1600                 limit_mod = cvar("g_balance_curse_venom_limitmod");
1601                 //if (!self.runes & RUNE_REGEN)
1602                 //      rot_mod = cvar("g_balance_curse_venom_rotrate");
1603         }
1604         maxh = maxh * max_mod;
1605         //maxa = maxa * max_mod;
1606         limith = limith * limit_mod;
1607         limita = limita * limit_mod;
1608
1609         if (self.armorvalue > maxa)
1610         {
1611                 if (time > self.pauserotarmor_finished)
1612                 {
1613                         self.armorvalue = max(maxa, self.armorvalue + (maxa - self.armorvalue) * cvar("g_balance_armor_rot") * frametime);
1614                         self.armorvalue = max(maxa, self.armorvalue - cvar("g_balance_armor_rotlinear") * frametime);
1615                 }
1616         }
1617         else if (self.armorvalue < maxa)
1618         {
1619                 if (time > self.pauseregen_finished)
1620                 {
1621                         self.armorvalue = CalcRegen(self.armorvalue, maxa, cvar("g_balance_armor_regen"));
1622                         self.armorvalue = min(maxa, self.armorvalue + cvar("g_balance_armor_regenlinear") * frametime);
1623                 }
1624         }
1625         if (self.health > maxh)
1626         {
1627                 if (time > self.pauserothealth_finished)
1628                 {
1629                         self.health = max(maxh, self.health + (maxh - self.health) * rot_mod*cvar("g_balance_health_rot") * frametime);
1630                         self.health = max(maxh, self.health - rot_mod*cvar("g_balance_health_rotlinear") * frametime);
1631                 }
1632         }
1633         else if (self.health < maxh)
1634         {
1635                 if (time > self.pauseregen_finished)
1636                 {
1637                         self.health = CalcRegen(self.health, maxh, regen_mod * cvar("g_balance_health_regen"));
1638                         self.health = min(maxh, self.health + regen_mod*cvar("g_balance_health_regenlinear") * frametime);
1639                 }
1640         }
1641
1642         if (self.health > limith)
1643                 self.health = limith;
1644         if (self.armorvalue > limita)
1645                 self.armorvalue = limita;
1646
1647         // if player rotted to death...  die!
1648         if(self.health < 1)
1649                 self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
1650 }
1651
1652 /*
1653 ======================
1654 spectate mode routines
1655 ======================
1656 */
1657 void SpectateCopy(entity spectatee) {
1658         self.armortype = spectatee.armortype;
1659         self.armorvalue = spectatee.armorvalue;
1660         self.currentammo = spectatee.currentammo;
1661         self.effects = spectatee.effects;
1662         self.health = spectatee.health;
1663         self.impulse = 0;
1664         self.items = spectatee.items;
1665         self.punchangle = spectatee.punchangle;
1666         self.view_ofs = spectatee.view_ofs;
1667         self.v_angle = spectatee.v_angle;
1668         self.viewzoom = spectatee.viewzoom;
1669         self.velocity = spectatee.velocity;
1670         self.dmg_take = spectatee.dmg_take;
1671         self.dmg_save = spectatee.dmg_save;
1672         self.dmg_inflictor = spectatee.dmg_inflictor;
1673         self.angles = spectatee.v_angle;
1674         self.fixangle = TRUE;
1675         setorigin(self, spectatee.origin);
1676         setsize(self, spectatee.mins, spectatee.maxs);
1677 }
1678
1679 float SpectateUpdate() {
1680         if(!self.enemy)
1681                 return 0;
1682
1683         if (self == self.enemy)
1684                 return 0;
1685
1686         if(self.enemy.flags & FL_NOTARGET)
1687                 return 0;
1688
1689         SpectateCopy(self.enemy);
1690
1691         return 1;
1692 }
1693
1694 float SpectateNext() {
1695         other = find(self.enemy, classname, "player");
1696         if (!other) {
1697                 other = find(other, classname, "player");
1698         }
1699         if (other) {
1700                 self.enemy = other;
1701         }
1702         if(self.enemy.classname == "player") {
1703                 msg_entity = self;
1704                 WriteByte(MSG_ONE, SVC_SETVIEW);
1705                 WriteEntity(MSG_ONE, self.enemy);
1706                 self.wantswelcomemessage = 1;
1707                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
1708                 if(!SpectateUpdate())
1709                         PutObserverInServer();
1710                 return 1;
1711         } else {
1712                 return 0;
1713         }
1714 }
1715
1716 /*
1717 =============
1718 ShowRespawnCountdown()
1719
1720 Update a respawn countdown display.
1721 =============
1722 */
1723 void ShowRespawnCountdown()
1724 {
1725         float number;
1726         if(self.deadflag == DEAD_NO) // just respawned?
1727                 return;
1728         else
1729         {
1730                 number = ceil(self.death_time - time);
1731                 if(number <= 0)
1732                         return;
1733                 if(number <= self.respawn_countdown)
1734                 {
1735                         self.respawn_countdown = number - 1;
1736                         if(ceil(self.death_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
1737                                 announce(self, strcat("announcer/robotic/", ftos(number), ".ogg"));
1738                 }
1739         }
1740 }
1741
1742 void LeaveSpectatorMode()
1743 {
1744         if(isJoinAllowed()) {
1745                 if(!cvar("teamplay") || cvar("g_campaign") || cvar("g_balance_teams")) {
1746                         self.classname = "player";
1747                         if(cvar("g_campaign") || cvar("g_balance_teams") || cvar("g_balance_teams_force"))
1748                                 JoinBestTeam(self, FALSE, TRUE);
1749                         if(cvar("g_campaign"))
1750                                 campaign_bots_may_start = 1;
1751                         PutClientInServer();
1752                         if(!(self.flags & FL_NOTARGET))
1753                                 bprint ("^4", self.netname, "^4 is playing now\n");
1754                         centerprint(self,"");
1755                         return;
1756                 } else {
1757                         stuffcmd(self,"menu_showteamselect\n");
1758                         return;
1759                 }
1760         }
1761         else {
1762                 //player may not join because of g_maxplayers is set
1763                 centerprint_atprio(self, CENTERPRIO_MAPVOTE, PREVENT_JOIN_TEXT);
1764         }
1765 }
1766
1767 /**
1768  * Determines whether the player is allowed to join. This depends on cvar
1769  * g_maxplayers, if it isn't used this function always return TRUE, otherwise
1770  * it checks whether the number of currently playing players exceeds g_maxplayers.
1771  * @return bool TRUE if the player is allowed to join, false otherwise
1772  */
1773 float isJoinAllowed() {
1774         if (!cvar("g_maxplayers"))
1775                 return TRUE;
1776
1777         local entity e;
1778         local float currentlyPlaying;
1779         FOR_EACH_REALPLAYER(e) {
1780                 if(e.classname == "player")
1781                         currentlyPlaying += 1;
1782         }
1783         if(currentlyPlaying < cvar("g_maxplayers"))
1784                 return TRUE;
1785
1786         return FALSE;
1787 }
1788
1789 /**
1790  * Checks whether the client is an observer or spectator, if so, he will get kicked after
1791  * g_maxplayers_spectator_blocktime seconds
1792  */
1793 void checkSpectatorBlock() {
1794         if(self.classname == "spectator" || self.classname == "observer") {
1795                 if( time > (self.spectatortime + cvar("g_maxplayers_spectator_blocktime")) ) {
1796                         sprint(self, "^7You were kicked from the server because you are spectator and spectators aren't allowed at the moment.\n");
1797                         dropclient(self);
1798                 }
1799         }
1800 }
1801
1802 float vercmp_recursive(string v1, string v2)
1803 {
1804         float dot1, dot2;
1805         string s1, s2;
1806         float r;
1807
1808         dot1 = strstrofs(v1, ".", 0);
1809         dot2 = strstrofs(v2, ".", 0);
1810         if(dot1 == -1)
1811                 s1 = v1;
1812         else
1813                 s1 = substring(v1, 0, dot1);
1814         if(dot2 == -1)
1815                 s2 = v2;
1816         else
1817                 s2 = substring(v2, 0, dot2);
1818
1819         r = stof(s1) - stof(s2);
1820         if(r != 0)
1821                 return r;
1822
1823         r = strcasecmp(s1, s2);
1824         if(r != 0)
1825                 return r;
1826
1827         if(dot1 == -1)
1828                 if(dot2 == -1)
1829                         return 0;
1830                 else
1831                         return -1;
1832         else
1833                 if(dot2 == -1)
1834                         return 1;
1835                 else
1836                         return vercmp_recursive(substring(v1, dot1 + 1, 999), substring(v2, dot2 + 1, 999));
1837 }
1838
1839 float vercmp(string v1, string v2)
1840 {
1841         if(strcasecmp(v1, v2) == 0) // early out check
1842                 return 0;
1843         return vercmp_recursive(v1, v2);
1844 }
1845
1846 void ObserverThink()
1847 {
1848         if (self.flags & FL_JUMPRELEASED) {
1849                 if (self.BUTTON_JUMP && !self.version_mismatch) {
1850                         self.welcomemessage_time = 0;
1851                         self.flags = self.flags - FL_JUMPRELEASED;
1852                         LeaveSpectatorMode();
1853                         return;
1854                 } else if(self.BUTTON_ATCK && !self.version_mismatch) {
1855                         self.welcomemessage_time = 0;
1856                         self.flags = self.flags - FL_JUMPRELEASED;
1857                         if(SpectateNext() == 1) {
1858                                 self.classname = "spectator";
1859                         }
1860                 }
1861         } else {
1862                 if (!(self.BUTTON_ATCK || self.BUTTON_JUMP)) {
1863                         self.flags = self.flags | FL_JUMPRELEASED;
1864                 }
1865         }
1866         if(self.BUTTON_ZOOM)
1867                 self.wantswelcomemessage = 0;
1868         if(self.wantswelcomemessage)
1869                 PrintWelcomeMessage(self);
1870 }
1871
1872 void SpectatorThink()
1873 {
1874         if (self.flags & FL_JUMPRELEASED) {
1875                 if (self.BUTTON_JUMP && !self.version_mismatch) {
1876                         self.welcomemessage_time = 0;
1877                         self.flags = self.flags - FL_JUMPRELEASED;
1878                         LeaveSpectatorMode();
1879                         return;
1880                 } else if(self.BUTTON_ATCK) {
1881                         self.welcomemessage_time = 0;
1882                         self.flags = self.flags - FL_JUMPRELEASED;
1883                         if(SpectateNext() == 1) {
1884                                 self.classname = "spectator";
1885                         } else {
1886                                 self.classname = "observer";
1887                                 PutClientInServer();
1888                         }
1889                 } else if (self.BUTTON_ATCK2) {
1890                         self.welcomemessage_time = 0;
1891                         self.flags = self.flags - FL_JUMPRELEASED;
1892                         self.classname = "observer";
1893                         PutClientInServer();
1894                 } else {
1895                         if(!SpectateUpdate())
1896                                 PutObserverInServer();
1897                 }
1898         } else {
1899                 if (!(self.BUTTON_ATCK || self.BUTTON_ATCK2)) {
1900                         self.flags = self.flags | FL_JUMPRELEASED;
1901                 }
1902         }
1903         if(self.BUTTON_ZOOM)
1904                 self.wantswelcomemessage = 0;
1905         if(self.wantswelcomemessage)
1906                 PrintWelcomeMessage(self);
1907         self.flags = self.flags | FL_CLIENT | FL_NOTARGET;
1908 }
1909
1910 /*
1911 =============
1912 PlayerPreThink
1913
1914 Called every frame for each client before the physics are run
1915 =============
1916 */
1917 void() ctf_setstatus;
1918 .float vote_nagtime;
1919 void PlayerPreThink (void)
1920 {
1921         if(blockSpectators)
1922                 checkSpectatorBlock();
1923
1924         if(self.netname_previous != self.netname)
1925         {
1926                 if(cvar("sv_eventlog"))
1927                         GameLogEcho(strcat(":name:", ftos(self.playerid), ":", self.netname), TRUE);
1928                 if(self.netname_previous)
1929                         strunzone(self.netname_previous);
1930                 self.netname_previous = strzone(self.netname);
1931         }
1932
1933         // version nagging
1934         if(self.version_nagtime)
1935                 if(self.cvar_g_nexuizversion)
1936                         if(time > self.version_nagtime)
1937                         {
1938                                 if(strstr(self.cvar_g_nexuizversion, "svn", 0) < 0)
1939                                 {
1940                                         if(strstr(cvar_string("g_nexuizversion"), "svn", 0) >= 0)
1941                                         {
1942                                                 dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Nexuiz ", cvar_string("g_nexuizversion"), " (beta)^7, you have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1\n");
1943                                                 sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Nexuiz ", cvar_string("g_nexuizversion"), " (beta)^7, you have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1\n"));
1944                                         }
1945                                         else
1946                                         {
1947                                                 float r;
1948                                                 r = vercmp(self.cvar_g_nexuizversion, cvar_string("g_nexuizversion"));
1949                                                 if(r < 0)
1950                                                 {
1951                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - ^3Nexuiz ", cvar_string("g_nexuizversion"), "^7 is out, and you still have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1 - get the update from ^4http://www.nexuiz.com/^1!\n");
1952                                                         sprint(self, strcat("\{1}^1NOTE: ^3Nexuiz ", cvar_string("g_nexuizversion"), "^7 is out, and you still have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1 - get the update from ^4http://www.nexuiz.com/^1!\n"));
1953                                                 }
1954                                                 else if(r > 0)
1955                                                 {
1956                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Nexuiz ", cvar_string("g_nexuizversion"), "^7, you have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1\n");
1957                                                         sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Nexuiz ", cvar_string("g_nexuizversion"), "^7, you have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1\n"));
1958                                                 }
1959                                         }
1960                                 }
1961                                 self.version_nagtime = 0;
1962                         }
1963
1964         // vote nagging
1965         if(self.cvar_scr_centertime)
1966                 if(time > self.vote_nagtime)
1967                 {
1968                         VoteNag();
1969                         self.vote_nagtime = time + self.cvar_scr_centertime * 0.6;
1970                 }
1971
1972         // GOD MODE info
1973         if(!(self.flags & FL_GODMODE)) if(self.max_armorvalue)
1974         {
1975                 sprint(self, strcat("godmode saved you ", ftos(self.max_armorvalue), " units of damage, cheater!\n"));
1976                 self.max_armorvalue = 0;
1977         }
1978
1979         if(frametime)
1980                 antilag_record(self);
1981
1982         if(self.classname == "player") {
1983 //              if(self.netname == "Wazat")
1984 //                      bprint(self.classname, "\n");
1985
1986                 CheckRules_Player();
1987
1988                 if(self.BUTTON_INFO)
1989                         PrintWelcomeMessage(self);
1990
1991                 if(g_lms || !cvar("sv_spectate"))
1992                 if((time - self.jointime) <= cvar("welcome_message_time"))
1993                         PrintWelcomeMessage(self);
1994
1995                 if (intermission_running)
1996                 {
1997                         IntermissionThink ();   // otherwise a button could be missed between
1998                         return;                                 // the think tics
1999                 }
2000
2001                 if(self.teleport_time)
2002                 if(time > self.teleport_time)
2003                 {
2004                         self.teleport_time = 0;
2005                         self.effects = self.effects - (self.effects & EF_NODRAW);
2006                         if(self.weaponentity)
2007                                 self.weaponentity.flags = self.weaponentity.flags - (self.weaponentity.flags & EF_NODRAW);
2008                 }
2009
2010                 Nixnex_GiveCurrentWeapon();
2011
2012                 if(frametime > 0) // don't do this in cl_movement frames, just in server ticks
2013                         UpdateSelectedPlayer();
2014
2015                 //don't allow the player to turn around while game is paused!
2016                 if(timeoutStatus == 2) {
2017                         self.v_angle = self.lastV_angle;
2018                         self.angles = self.lastV_angle;
2019                         self.fixangle = TRUE;
2020                 }
2021
2022                 if (self.deadflag != DEAD_NO)
2023                 {
2024                         float button_pressed, force_respawn;
2025                         player_anim();
2026                         button_pressed = (self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE);
2027                         force_respawn = (g_lms || cvar("g_forced_respawn"));
2028                         if (self.deadflag == DEAD_DYING)
2029                         {
2030                                 if(force_respawn)
2031                                         self.deadflag = DEAD_RESPAWNING;
2032                                 else if(!button_pressed)
2033                                         self.deadflag = DEAD_DEAD;
2034                         }
2035                         else if (self.deadflag == DEAD_DEAD)
2036                         {
2037                                 if(button_pressed)
2038                                         self.deadflag = DEAD_RESPAWNABLE;
2039                         }
2040                         else if (self.deadflag == DEAD_RESPAWNABLE)
2041                         {
2042                                 if(!button_pressed)
2043                                         self.deadflag = DEAD_RESPAWNING;
2044                         }
2045                         else if (self.deadflag == DEAD_RESPAWNING)
2046                         {
2047                                 if(time > self.death_time)
2048                                 {
2049                                         self.death_time = time + 1; // only retry once a second
2050                                         respawn();
2051                                 }
2052                         }
2053                         ShowRespawnCountdown();
2054                         return;
2055                 }
2056
2057                 if((g_race || g_lms) && !self.deadflag && cvar("g_lms_campcheck_interval"))
2058                 {
2059                         vector dist;
2060
2061                         // calculate player movement (in 2 dimensions only, so jumping on one spot doesn't count as movement)
2062                         dist = self.oldorigin - self.origin;
2063                         dist_z = 0;
2064                         self.lms_traveled_distance += fabs(vlen(dist));
2065
2066                         if((cvar("g_campaign") && !campaign_bots_may_start) || (time < restart_countdown))
2067                         {
2068                                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval")*2;
2069                                 self.lms_traveled_distance = 0;
2070                         }
2071
2072                         if(time > self.lms_nextcheck)
2073                         {
2074                                 //sprint(self, "distance: ", ftos(self.lms_traveled_distance), "\n");
2075                                 if(self.lms_traveled_distance < cvar("g_lms_campcheck_distance"))
2076                                 {
2077                                         centerprint(self, cvar_string("g_lms_campcheck_message"));
2078                                         // FIXME KadaverJack: gibbing player here causes playermodel to bounce around, instead of eye.md3
2079                                         // I wasn't able to find out WHY that happens, so I put a workaround in place that shall prevent players from being gibbed :(
2080                                         Damage(self, self, self, bound(0, cvar("g_lms_campcheck_damage"), self.health + self.armorvalue * cvar("g_balance_armor_blockpercent") + 5), DEATH_CAMP, self.origin, '0 0 0');
2081                                 }
2082                                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval");
2083                                 self.lms_traveled_distance = 0;
2084                         }
2085                 }
2086
2087                 if (self.BUTTON_CROUCH && !self.hook.state)
2088                 {
2089                         if (!self.crouch)
2090                         {
2091                                 self.crouch = TRUE;
2092                                 self.view_ofs = PL_CROUCH_VIEW_OFS;
2093                                 setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX);
2094                                 player_setanim(self.anim_duck, FALSE, TRUE, TRUE);
2095                         }
2096                 }
2097                 else
2098                 {
2099                         if (self.crouch)
2100                         {
2101                                 tracebox(self.origin, PL_MIN, PL_MAX, self.origin, FALSE, self);
2102                                 if (!trace_startsolid)
2103                                 {
2104                                         self.crouch = FALSE;
2105                                         self.view_ofs = PL_VIEW_OFS;
2106                                         setsize (self, PL_MIN, PL_MAX);
2107                                 }
2108                         }
2109                 }
2110
2111                 FixPlayermodel();
2112
2113                 GrapplingHookFrame();
2114
2115                 W_WeaponFrame();
2116
2117                 {
2118                         float zoomfactor, zoomspeed, zoomdir;
2119                         zoomfactor = self.cvar_cl_zoomfactor;
2120                         if(zoomfactor < 1 || zoomfactor > 16)
2121                                 zoomfactor = 2.5;
2122                         zoomspeed = self.cvar_cl_zoomspeed;
2123                         if(zoomspeed >= 0) // < 0 is instant zoom
2124                                 if(zoomspeed < 0.5 || zoomspeed > 16)
2125                                         zoomspeed = 3.5;
2126
2127                         zoomdir = self.BUTTON_ZOOM;
2128                         if(self.BUTTON_ATCK2)
2129                                 if(self.weapon == WEP_NEX)
2130                                         if(!g_minstagib)
2131                                                 zoomdir = 1;
2132
2133                         if(zoomdir)
2134                                 self.has_zoomed = 1;
2135
2136                         if(self.has_zoomed)
2137                         {
2138                                 if(zoomspeed <= 0) // instant zoom
2139                                 {
2140                                         if(zoomdir)
2141                                                 self.viewzoom = 1 / zoomfactor;
2142                                         else
2143                                                 self.viewzoom = 1;
2144                                 }
2145                                 else
2146                                 {
2147                                         // geometric zoom would be:
2148                                         //   self.viewzoom = bound(1 / zoomfactor, self.viewzoom * pow(zoomfactor, (zoomdir ? -1 : 1) * frametime * zoomspeed), 1);
2149                                         // however, testing showed that arithmetic/harmonic zoom works better
2150                                         if(zoomdir)
2151                                                 // self.viewzoom = 1 / bound(1, 1 / self.viewzoom + (zoomdir ? 1 : -1) * frametime * zoomspeed * (zoomfactor - 1), zoomfactor);
2152                                                 // zoom in = arithmetic: 1x, 2x, 3x, 4x, ..., 8x
2153                                                 self.viewzoom = 1 / bound(1, 1 / self.viewzoom + frametime * zoomspeed * (zoomfactor - 1), zoomfactor);
2154                                         else
2155                                                 // self.viewzoom = bound(1 / zoomfactor, self.viewzoom + (zoomdir ? -1 : 1) * frametime * zoomspeed * (1 - 1 / zoomfactor), 1);
2156                                                 // zoom out = harmonic: 8/1x, 8/2x, 8/3x, 8/4x, ..., 8/8x
2157                                                 self.viewzoom = bound(1 / zoomfactor, self.viewzoom + frametime * zoomspeed * (1 - 1 / zoomfactor), 1);
2158                                 }
2159                         }
2160                         else
2161                                 self.viewzoom = min(1, self.viewzoom + frametime); // spawn zoom-in
2162                 }
2163
2164                 player_powerups();
2165                 player_regen();
2166                 player_anim();
2167
2168                 if (g_minstagib)
2169                         minstagib_ammocheck();
2170
2171                 ctf_setstatus();
2172                 kh_setstatus();
2173
2174                 //self.angles_y=self.v_angle_y + 90;   // temp
2175
2176                 //if (TetrisPreFrame()) return;
2177         } else if(gameover) {
2178                 if (intermission_running)
2179                         IntermissionThink ();   // otherwise a button could be missed between
2180                 return;
2181         } else if(self.classname == "observer") {
2182                 ObserverThink();
2183         } else if(self.classname == "spectator") {
2184                 SpectatorThink();
2185         }
2186 }
2187
2188
2189 /*
2190 =============
2191 PlayerPostThink
2192
2193 Called every frame for each client after the physics are run
2194 =============
2195 */
2196 .float idlekick_lasttimeleft;
2197 .float race_penalty;
2198 .float race_penalty_nagged;
2199 void PlayerPostThink (void)
2200 {
2201         // Savage: Check for nameless players
2202         if (strlen(self.netname) < 1) {
2203                 self.netname = "Player";
2204                 stuffcmd(self, "seta _cl_name Player\n");
2205         }
2206
2207         if(sv_maxidle)
2208         {
2209                 float timeleft;
2210                 timeleft = ceil(sv_maxidle - (time - self.parm_idlesince));
2211                 if(timeleft <= 0)
2212                 {
2213                         bprint("^3", self.netname, "^3 was kicked for idling.\n");
2214                         announce(self, "announcer/robotic/terminated.ogg");
2215                         dropclient(self);
2216                         return;
2217                 }
2218                 else if(timeleft <= 10)
2219                 {
2220                         if(timeleft != self.idlekick_lasttimeleft)
2221                         {
2222                                 centerprint_atprio(self, CENTERPRIO_IDLEKICK, strcat("^3Stop idling!\n^3Disconnecting in ", ftos(timeleft), "..."));
2223                                 announce(self, strcat("announcer/robotic/", ftos(timeleft), ".ogg"));
2224                         }
2225                 }
2226                 else
2227                 {
2228                         centerprint_expire(self, CENTERPRIO_IDLEKICK);
2229                 }
2230                 self.idlekick_lasttimeleft = timeleft;
2231         }
2232
2233         if(self.classname == "player") {
2234                 CheckRules_Player();
2235                 UpdateChatBubble();
2236                 UpdateTeamBubble();
2237                 if (self.impulse)
2238                         ImpulseCommands();
2239                 if (intermission_running)
2240                         return;         // intermission or finale
2241
2242                 //PrintWelcomeMessage(self);
2243                 //if (TetrisPostFrame()) return;
2244
2245                 // restart countdown
2246                 if (restart_countdown) {
2247                         if(time < restart_countdown) {
2248                                 if (!cvar("sv_ready_restart_after_countdown"))
2249                                 {
2250                                         if(self.movement != '0 0 0' && g_race && !g_race_qualifying)
2251                                         {
2252                                                 if(time < restart_countdown - 2)
2253                                                 {
2254                                                         if(!self.race_penalty_nagged)
2255                                                         {
2256                                                                 centerprint_atprio(self, CENTERPRIO_IDLEKICK, "^1DO NOT MOVE DURING THE COUNTDOWN.");
2257                                                                 self.race_penalty_nagged = 1;
2258                                                         }
2259                                                 }
2260                                                 else if(!self.race_penalty)
2261                                                 {
2262                                                         centerprint_atprio(self, CENTERPRIO_IDLEKICK, "^1FIVE SECONDS PENALTY.");
2263                                                         self.race_penalty = time + 5;
2264                                                 }
2265                                         }
2266                                         self.movetype = MOVETYPE_NONE;
2267                                         self.velocity = '0 0 0';
2268                                         self.avelocity = '0 0 0';
2269                                         self.movement = '0 0 0';
2270                                 }
2271                         }
2272                         else if (time < self.race_penalty)
2273                         {
2274                                 self.movetype = MOVETYPE_NONE;
2275                                 self.velocity = '0 0 0';
2276                                 self.avelocity = '0 0 0';
2277                                 self.movement = '0 0 0';
2278                         }
2279                         else
2280                         {
2281                                 //allow the player to move again if sv_ready_restart_after_countdown is not used and countdown is over
2282                                 if (!cvar("sv_ready_restart_after_countdown"))
2283                                 {
2284                                         if(self.movetype == MOVETYPE_NONE)
2285                                         {
2286                                                 self.movetype = MOVETYPE_WALK;
2287                                         }
2288                                         self.race_penalty = 0;
2289                                         self.race_penalty_nagged = 0;
2290                                 }
2291                         }
2292                 }
2293
2294         } else if (self.classname == "observer") {
2295                 //do nothing
2296         } else if (self.classname == "spectator") {
2297                 //do nothing
2298         }
2299
2300         /*
2301         float i;
2302         for(i = 0; i < 1000; ++i)
2303         {
2304                 vector end;
2305                 end = self.origin + '0 0 1024' + 512 * randomvec();
2306                 tracebox(self.origin, self.mins, self.maxs, end, MOVE_NORMAL, self);
2307                 if(trace_fraction < 1)
2308                 if(!(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
2309                 {
2310                         print("I HIT SOLID: ", vtos(self.origin), " -> ", vtos(end), "\n");
2311                         break;
2312                 }
2313         }
2314         */
2315
2316         Arena_Warmup();
2317 }