data/qcsrc/server/cl_client.qc

   1 .float wantswelcomemessage;
   2
   3 void info_player_survivor (void)
   4 {
   5         info_player_deathmatch();
   6 }
   7
   8 void info_player_start (void)
   9 {
  10         info_player_deathmatch();
  11 }
  12
  13 void info_player_deathmatch (void)
  14 {
  15         self.classname = "info_player_deathmatch";
  16         relocate_spawnpoint();
  17 }
  18
  19 void() spawnpoint_use =
  20 {
  21         if(teams_matter)
  22         if(have_team_spawns)
  23         {
  24                 self.team = activator.team;
  25                 some_spawn_has_been_used = 1;
  26         }
  27 };
  28
  29 float spawn_allbad;
  30 float spawn_allgood;
  31 entity Spawn_FilterOutBadSpots(entity firstspot, entity playerlist, float mindist, float teamcheck)
  32 {
  33         local entity spot, player, nextspot, previousspot, newfirstspot;
  34         local float pcount;
  35         spot = firstspot;
  36         newfirstspot = world;
  37         previousspot = world;
  38         spawn_allgood = TRUE;
  39         spawn_allbad = TRUE;
  40         while (spot)
  41         {
  42                 nextspot = spot.chain;
  43                 // count team mismatches as bad spots
  44
  45                 local float spotactive;
  46                 spotactive = 1;
  47
  48                 // filter out spots for assault
  49                 if(spot.target != "") {
  50                         local entity ent;
  51                         ent = find(world, targetname, spot.target);
  52                         while(ent) {
  53                                 if(ent.classname == "target_objective")
  54                                         if(ent.health < 0 || ent.health >= ASSAULT_VALUE_INACTIVE)
  55                                                 spotactive = 0;
  56                                 ent = find(ent, targetname, spot.target);
  57                         }
  58                 }
  59
  60                 if ((!teamcheck || spot.team == teamcheck) && spotactive > 0)
  61                 {
  62                         pcount = 0;
  63                         player = playerlist;
  64                         while (player)
  65                         {
  66                                 if (player != self)
  67                                 if (vlen(player.origin - spot.origin) < mindist)
  68                                         pcount = pcount + 1;
  69                                 player = player.chain;
  70                         }
  71                         if (!pcount)
  72                         {
  73                                 spawn_allbad = FALSE;
  74                                 if (newfirstspot)
  75                                         previousspot.chain = spot;
  76                                 else
  77                                         newfirstspot = spot;
  78                                 previousspot = spot;
  79                                 spot.chain = world;
  80                         }
  81                         else
  82                                 spawn_allgood = FALSE;
  83                 }
  84                 spot = nextspot;
  85         }
  86         // if we couldn't find ANY good points, return world
  87         return newfirstspot;
  88 }
  89
  90 entity Spawn_RandomPoint(entity firstspot)
  91 {
  92         local entity spot;
  93         local float numspots;
  94         // count number of spots
  95         numspots = 0;
  96         spot = firstspot;
  97         while (spot)
  98         {
  99                 numspots = numspots + 1;
 100                 spot = spot.chain;
 101         }
 102         // pick a random one
 103         numspots = numspots * random();
 104         spot = firstspot;
 105         while (spot.chain && numspots >= 1)
 106         {
 107                 numspots = numspots - 1;
 108                 spot = spot.chain;
 109         }
 110         return spot;
 111 }
 112
 113 entity Spawn_FurthestPoint(entity firstspot, entity playerlist)
 114 {
 115         local entity best, spot, player;
 116         local float bestrating, rating;
 117         best = world;
 118         bestrating = -1000000;
 119         spot = firstspot;
 120         while (spot)
 121         {
 122                 rating = 1000000000;
 123                 player = playerlist;
 124                 while (player)
 125                 {
 126                         if (player != self)
 127                                 rating = min(rating, vlen(player.origin - spot.origin));
 128                         player = player.chain;
 129                 }
 130                 rating = rating + random() * 16;
 131                 if (bestrating < rating)
 132                 {
 133                         best = spot;
 134                         bestrating = rating;
 135                 }
 136                 spot = spot.chain;
 137         }
 138         return best;
 139 }
 140
 141 /*
 142 =============
 143 SelectSpawnPoint
 144
 145 Finds a point to respawn
 146 =============
 147 */
 148 entity SelectSpawnPoint (float anypoint)
 149 {
 150         local float teamcheck;
 151         local entity firstspot_new;
 152         local entity spot, firstspot, playerlist;
 153
 154         spot = find (world, classname, "testplayerstart");
 155         if (spot)
 156                 return spot;
 157
 158         teamcheck = 0;
 159
 160         if(!anypoint && have_team_spawns)
 161                 teamcheck = self.team;
 162
 163         // get the list of players
 164         playerlist = findchain(classname, "player");
 165         // get the entire list of spots
 166         firstspot = findchain(classname, "info_player_deathmatch");
 167         // filter out the bad ones
 168         // (note this returns the original list if none survived)
 169         firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, 100, teamcheck);
 170         if(!firstspot_new)
 171                 firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, -1, teamcheck);
 172         firstspot = firstspot_new;
 173
 174         // there is 50/50 chance of choosing a random spot or the furthest spot
 175         // (this means that roughly every other spawn will be furthest, so you
 176         // usually won't get fragged at spawn twice in a row)
 177         if (arena_roundbased)
 178         {
 179                 firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, 800, teamcheck);
 180                 if(firstspot_new)
 181                         firstspot = firstspot_new;
 182                 spot = Spawn_RandomPoint(firstspot);
 183         }
 184         else if (random() > 0.5 || spawn_allbad || spawn_allgood)
 185                 spot = Spawn_RandomPoint(firstspot);
 186         else
 187                 spot = Spawn_FurthestPoint(firstspot, playerlist);
 188
 189         if (!spot)
 190         {
 191                 if(cvar("spawn_debug"))
 192                         GotoNextMap();
 193                 else
 194                 {
 195                         if(some_spawn_has_been_used)
 196                                 return world; // team can't spawn any more, because of actions of other team
 197                         else
 198                                 error("Cannot find a spawn point - please fix the map!");
 199                 }
 200         }
 201
 202         return spot;
 203 }
 204
 205 /*
 206 =============
 207 CheckPlayerModel
 208
 209 Checks if the argument string can be a valid playermodel.
 210 Returns a valid one in doubt.
 211 =============
 212 */
 213 string FallbackPlayerModel = "models/player/marine.zym";
 214 string CheckPlayerModel(string plyermodel) {
 215         if(strlen(plyermodel) < 4)
 216                 return FallbackPlayerModel;
 217         if( substring(plyermodel,0,14) != "models/player/")
 218                 return FallbackPlayerModel;
 219         else if(cvar("sv_servermodelsonly"))
 220         {
 221                 if(substring(plyermodel,strlen(plyermodel)-4,4) != ".zym")
 222                 if(substring(plyermodel,strlen(plyermodel)-4,4) != ".dpm")
 223                 if(substring(plyermodel,strlen(plyermodel)-4,4) != ".md3")
 224                 if(substring(plyermodel,strlen(plyermodel)-4,4) != ".psk")
 225                         return FallbackPlayerModel;
 226                 if(!fexists(plyermodel))
 227                         return FallbackPlayerModel;
 228         }
 229         return plyermodel;
 230 }
 231
 232 /*
 233 =============
 234 Client_customizeentityforclient
 235
 236 LOD reduction
 237 =============
 238 */
 239 float Client_customizeentityforclient()
 240 {
 241 #ifdef ALLOW_VARIABLE_LOD
 242         // self: me
 243         // other: the player viewing me
 244         float distance;
 245         float f;
 246
 247         if(self.flags & FL_NOTARGET) // we don't need LOD for spectators
 248                 return TRUE;
 249
 250         if(other.cvar_cl_playerdetailreduction <= 0)
 251         {
 252                 if(other.cvar_cl_playerdetailreduction <= -2)
 253                         self.modelindex = self.modelindex_lod2;
 254                 else if(other.cvar_cl_playerdetailreduction <= -1)
 255                         self.modelindex = self.modelindex_lod1;
 256                 else
 257                         self.modelindex = self.modelindex_lod0;
 258         }
 259         else
 260         {
 261                 distance = vlen(self.origin - other.origin);
 262                 f = (distance + 100.0) * other.cvar_cl_playerdetailreduction;
 263                 if(f > 10000)
 264                         self.modelindex = self.modelindex_lod2;
 265                 else if(f > 5000)
 266                         self.modelindex = self.modelindex_lod1;
 267                 else
 268                         self.modelindex = self.modelindex_lod0;
 269         }
 270 #endif
 271
 272         return TRUE;
 273 }
 274
 275 void UpdatePlayerSounds();
 276 void setmodel_lod(entity e, string modelname)
 277 {
 278 #ifdef ALLOW_VARIABLE_LOD
 279         string s;
 280
 281         // FIXME: this only supports 3-letter extensions
 282         s = strcat(substring(modelname, 0, strlen(modelname) - 4), "_1", substring(modelname, 0, strlen(modelname) - 4));
 283         if(fexists(s))
 284         {
 285                 precache_model(s);
 286                 setmodel(e, s); // players have high precision
 287                 self.modelindex_lod1 = self.modelindex;
 288         }
 289         else
 290                 self.modelindex_lod1 = -1;
 291
 292         s = strcat(substring(modelname, 0, strlen(modelname) - 4), "_2", substring(modelname, 0, strlen(modelname) - 4));
 293         if(fexists(s))
 294         {
 295                 precache_model(s);
 296                 setmodel(e, s); // players have high precision
 297                 self.modelindex_lod2 = self.modelindex;
 298         }
 299         else
 300                 self.modelindex_lod2 = -1;
 301
 302         precache_model(modelname);
 303         setmodel(e, modelname); // players have high precision
 304         self.modelindex_lod0 = self.modelindex;
 305
 306         if(self.modelindex_lod1 < 0)
 307                 self.modelindex_lod1 = self.modelindex;
 308
 309         if(self.modelindex_lod2 < 0)
 310                 self.modelindex_lod2 = self.modelindex;
 311 #else
 312         precache_model(modelname);
 313         setmodel(e, modelname); // players have high precision
 314 #endif
 315         player_setupanimsformodel();
 316         UpdatePlayerSounds();
 317 }
 318
 319 /*
 320 =============
 321 PutObserverInServer
 322
 323 putting a client as observer in the server
 324 =============
 325 */
 326 void PutObserverInServer (void)
 327 {
 328         entity  spot;
 329         spot = SelectSpawnPoint (TRUE);
 330         if(!spot)
 331                 error("No spawnpoints for observers?!?\n");
 332         RemoveGrapplingHook(self); // Wazat's Grappling Hook
 333
 334         if(clienttype(self) == CLIENTTYPE_REAL)
 335         {
 336                 msg_entity = self;
 337                 WriteByte(MSG_ONE, SVC_SETVIEW);
 338                 WriteEntity(MSG_ONE, self);
 339         }
 340
 341         DropAllRunes(self);
 342         kh_Key_DropAll(self, TRUE);
 343
 344         if(self.flagcarried)
 345                 DropFlag(self.flagcarried);
 346
 347         WaypointSprite_PlayerDead();
 348
 349         DistributeFragsAmongTeam(self, self.team, 1);
 350
 351         if(self.frags <= 0 && self.frags > -666 && g_lms && self.killcount != -666)
 352                 bprint ("^4", self.netname, "^4 has no more lives left\n");
 353         else if(self.killcount != -666)
 354                 bprint ("^4", self.netname, "^4 is spectating now\n");
 355
 356         self.classname = "observer";
 357         self.health = -666;
 358         self.takedamage = DAMAGE_NO;
 359         self.solid = SOLID_NOT;
 360         self.movetype = MOVETYPE_NOCLIP;
 361         self.flags = FL_CLIENT | FL_NOTARGET;
 362         self.armorvalue = 666;
 363         self.effects = 0;
 364         self.armorvalue = cvar("g_balance_armor_start");
 365         self.pauserotarmor_finished = 0;
 366         self.pauserothealth_finished = 0;
 367         self.pauseregen_finished = 0;
 368         self.damageforcescale = 0;
 369         self.death_time = 0;
 370         self.dead_frame = 0;
 371         self.deaths = 0;
 372         self.alpha = 0;
 373         self.scale = 0;
 374         self.fade_time = 0;
 375         self.pain_frame = 0;
 376         self.pain_finished = 0;
 377         self.strength_finished = 0;
 378         self.invincible_finished = 0;
 379         self.pushltime = 0;
 380         self.think = SUB_Null;
 381         self.nextthink = 0;
 382         self.hook_time = 0;
 383         self.runes = 0;
 384         self.deadflag = DEAD_NO;
 385         self.angles = spot.angles;
 386         self.angles_z = 0;
 387         self.fixangle = TRUE;
 388         self.crouch = FALSE;
 389
 390         self.view_ofs = PL_VIEW_OFS;
 391         setorigin (self, spot.origin);
 392         setsize (self, '0 0 0', '0 0 0');
 393         self.oldorigin = self.origin;
 394         self.items = 0;
 395         self.model = "";
 396         self.modelindex = 0;
 397         self.weapon = 0;
 398         self.weaponmodel = "";
 399         self.weaponentity = world;
 400         self.killcount = -666;
 401         self.velocity = '0 0 0';
 402         self.avelocity = '0 0 0';
 403         self.punchangle = '0 0 0';
 404         self.punchvector = '0 0 0';
 405         self.oldvelocity = self.velocity;
 406         self.customizeentityforclient = Client_customizeentityforclient;
 407         self.viewzoom = 1;
 408         self.wantswelcomemessage = 1;
 409
 410         if(g_arena)
 411         {
 412                 if(self.frags != -2)
 413                 {
 414                         Spawnqueue_Insert(self);
 415                 }
 416                 else
 417                 {
 418                         Spawnqueue_Unmark(self);
 419                         Spawnqueue_Remove(self);
 420                 }
 421         }
 422         else if(!g_lms)
 423                 self.frags = -666;
 424 }
 425
 426 float RestrictSkin(float s)
 427 {
 428         if(!teams_matter)
 429                 return s;
 430         if(s == 6)
 431                 return 6;
 432         return mod(s, 3);
 433 }
 434
 435 void FixPlayermodel()
 436 {
 437         local string defaultmodel;
 438         local float defaultskin;
 439         local vector m1, m2;
 440
 441         defaultmodel = "";
 442
 443         if(cvar("sv_defaultcharacter") == 1) {
 444                 defaultskin = 0;
 445
 446                 if(teams_matter)
 447                 {
 448                         defaultmodel = cvar_string(strcat("sv_defaultplayermodel_", Team_ColorNameLowerCase(self.team)));
 449                         defaultskin = cvar(strcat("sv_defaultplayerskin_", Team_ColorNameLowerCase(self.team)));
 450                 }
 451
 452                 if(defaultmodel == "")
 453                 {
 454                         defaultmodel = cvar_string("sv_defaultplayermodel");
 455                         defaultskin = cvar("sv_defaultplayerskin");
 456                 }
 457         }
 458
 459         if(defaultmodel != "")
 460         {
 461                 if (defaultmodel != self.model)
 462                 {
 463                         m1 = self.mins;
 464                         m2 = self.maxs;
 465                         setmodel_lod (self, defaultmodel);
 466                         setsize (self, m1, m2);
 467                 }
 468
 469                 self.skin = defaultskin;
 470         } else {
 471                 if (self.playermodel != self.model)
 472                 {
 473                         self.playermodel = CheckPlayerModel(self.playermodel);
 474                         m1 = self.mins;
 475                         m2 = self.maxs;
 476                         setmodel_lod (self, self.playermodel);
 477                         setsize (self, m1, m2);
 478                 }
 479
 480                 self.skin = RestrictSkin(stof(self.playerskin));
 481         }
 482
 483         if(!teams_matter)
 484                 if(strlen(cvar_string("sv_defaultplayercolors")))
 485                         if(self.clientcolors != cvar("sv_defaultplayercolors"))
 486                                 setcolor(self, cvar("sv_defaultplayercolors"));
 487 }
 488
 489 /*
 490 =============
 491 PutClientInServer
 492
 493 Called when a client spawns in the server
 494 =============
 495 */
 496 void PutClientInServer (void)
 497 {
 498         if(clienttype(self) == CLIENTTYPE_BOT)
 499         {
 500                 self.classname = "player";
 501         }
 502         else if(clienttype(self) == CLIENTTYPE_REAL)
 503         {
 504                 msg_entity = self;
 505                 WriteByte(MSG_ONE, SVC_SETVIEW);
 506                 WriteEntity(MSG_ONE, self);
 507         }
 508
 509         // player is dead and becomes observer
 510         if(g_lms && self.frags < 1)
 511                 self.classname = "observer";
 512
 513         if(g_arena)
 514         if(!self.spawned)
 515                 self.classname = "observer";
 516
 517         if(self.classname == "player") {
 518                 entity  spot;
 519
 520                 spot = SelectSpawnPoint (FALSE);
 521                 if(!spot)
 522                 {
 523                         centerprint(self, "Sorry, no spawnpoints available!\nHope your team can fix it...");
 524                         return; // spawn failed
 525                 }
 526
 527                 RemoveGrapplingHook(self); // Wazat's Grappling Hook
 528
 529                 self.classname = "player";
 530                 self.iscreature = TRUE;
 531                 self.movetype = MOVETYPE_WALK;
 532                 self.solid = SOLID_SLIDEBOX;
 533                 self.flags = FL_CLIENT;
 534                 self.takedamage = DAMAGE_AIM;
 535                 if(g_minstagib)
 536                         self.effects = EF_FULLBRIGHT;
 537                 else
 538                         self.effects = 0;
 539                 self.air_finished = time + 12;
 540                 self.dmg = 2;
 541
 542                 self.ammo_shells = start_ammo_shells;
 543                 self.ammo_nails = start_ammo_nails;
 544                 self.ammo_rockets = start_ammo_rockets;
 545                 self.ammo_cells = start_ammo_cells;
 546                 self.health = start_health;
 547                 self.armorvalue = start_armorvalue;
 548                 self.items = start_items;
 549                 self.switchweapon = start_switchweapon;
 550                 self.cnt = start_switchweapon;
 551                 self.weapon = 0;
 552                 self.jump_interval = time;
 553
 554                 self.spawnshieldtime = time + cvar("g_spawnshieldtime");
 555                 self.pauserotarmor_finished = time + cvar("g_balance_pause_armor_rot_spawn");
 556                 self.pauserothealth_finished = time + cvar("g_balance_pause_health_rot_spawn");
 557                 self.pauseregen_finished = time + cvar("g_balance_pause_health_regen_spawn");
 558                 self.damageforcescale = 2;
 559                 self.death_time = 0;
 560                 self.dead_frame = 0;
 561                 self.alpha = 0;
 562                 self.scale = 0;
 563                 self.fade_time = 0;
 564                 self.pain_frame = 0;
 565                 self.pain_finished = 0;
 566                 self.strength_finished = 0;
 567                 self.invincible_finished = 0;
 568                 self.pushltime = 0;
 569                 //self.speed_finished = 0;
 570                 //self.slowmo_finished = 0;
 571                 // players have no think function
 572                 self.think = SUB_Null;
 573                 self.nextthink = 0;
 574                 self.hook_time = 0;
 575
 576                 self.runes = 0;
 577
 578                 self.deadflag = DEAD_NO;
 579
 580                 self.angles = spot.angles;
 581
 582                 self.angles_z = 0; // never spawn tilted even if the spot says to
 583                 self.fixangle = TRUE; // turn this way immediately
 584                 self.velocity = '0 0 0';
 585                 self.avelocity = '0 0 0';
 586                 self.punchangle = '0 0 0';
 587                 self.punchvector = '0 0 0';
 588                 self.oldvelocity = self.velocity;
 589
 590                 self.viewzoom = 0.6;
 591                 self.has_zoomed = 0;
 592
 593                 self.customizeentityforclient = Client_customizeentityforclient;
 594
 595                 self.model = "";
 596                 FixPlayermodel();
 597
 598                 self.crouch = FALSE;
 599                 self.view_ofs = PL_VIEW_OFS;
 600                 setsize (self, PL_MIN, PL_MAX);
 601                 self.spawnorigin = spot.origin;
 602                 setorigin (self, spot.origin + '0 0 1' * (1 - self.mins_z - 24));
 603                 // don't reset back to last position, even if new position is stuck in solid
 604                 self.oldorigin = self.origin;
 605
 606                 if(g_arena)
 607                 {
 608                         Spawnqueue_Remove(self);
 609                         Spawnqueue_Mark(self);
 610                 }
 611
 612                 self.event_damage = PlayerDamage;
 613
 614                 self.bot_attack = TRUE;
 615
 616                 self.statdraintime = time + 5;
 617                 self.button0 = self.button1 = self.button2 = self.button3 = 0;
 618
 619                 if(self.killcount == -666) {
 620                         self.killcount = 0;
 621                         if(!g_arena)
 622                         if(!g_lms)
 623                                 self.frags = 0;
 624                 }
 625
 626                 self.cnt = WEP_LASER;
 627                 self.nixnex_lastchange_id = -1;
 628
 629                 CL_SpawnWeaponentity();
 630                 self.alpha = default_player_alpha;
 631                 self.colormod = '1 1 1' * cvar("g_player_brightness");
 632                 self.exteriorweaponentity.alpha = default_weapon_alpha;
 633
 634                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval")*2;
 635                 self.lms_traveled_distance = 0;
 636                 self.speedrunning = FALSE;
 637
 638                 if(cvar("spawn_debug"))
 639                 {
 640                         sprint(self, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 641                         remove(spot);   // usefull for checking if there are spawnpoints, that let drop through the floor
 642                 }
 643
 644                 //stuffcmd(self, "chase_active 0");
 645                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
 646
 647                 if (cvar("g_spawnsound"))
 648                         sound (self, CHAN_AUTO, "misc/spawn.wav", 1, ATTN_NORM);
 649
 650                 if(g_assault) {
 651                         if(self.team == assault_attacker_team)
 652                                 centerprint(self, "You are attacking!\n");
 653                         else
 654                                 centerprint(self, "You are defending!\n");
 655                 }
 656
 657         } else if(self.classname == "observer") {
 658                 PutObserverInServer ();
 659         }
 660 }
 661
 662 /*
 663 =============
 664 SetNewParms
 665 =============
 666 */
 667 void SetNewParms (void)
 668 {
 669
 670 }
 671
 672 /*
 673 =============
 674 SetChangeParms
 675 =============
 676 */
 677 void SetChangeParms (void)
 678 {
 679
 680 }
 681
 682 /*
 683 =============
 684 ClientKill
 685
 686 Called when a client types 'kill' in the console
 687 =============
 688 */
 689
 690 void ClientKill_Now_TeamChange()
 691 {
 692         if(self.killindicator_teamchange == -1)
 693         {
 694                 self.team = -1;
 695                 JoinBestTeam( self, 0 );
 696         }
 697         else
 698         {
 699                 SV_ChangeTeam(self.killindicator_teamchange - 1);
 700         }
 701 }
 702
 703 void ClientKill_Now()
 704 {
 705         if(self.killindicator_teamchange)
 706                 ClientKill_Now_TeamChange();
 707
 708         // in any case:
 709         Damage(self, self, self, 100000, DEATH_KILL, self.origin, '0 0 0');
 710 }
 711 void KillIndicator_Think()
 712 {
 713         if (!self.owner.modelindex)
 714         {
 715                 self.owner.killindicator = world;
 716                 remove(self);
 717                 return;
 718         }
 719
 720         if(self.cnt <= 0)
 721         {
 722                 self = self.owner;
 723                 ClientKill_Now(); // no oldself needed
 724                 return;
 725         }
 726         else
 727         {
 728                 if(self.cnt <= 10)
 729                 {
 730                         setmodel(self, strcat("models/sprites/", ftos(self.cnt), ".spr32"));
 731                         play2(self.owner, strcat("sound/announce/robotoic/", ftos(self.cnt), ".ogg"));
 732                 }
 733                 if(self.owner.killindicator_teamchange)
 734                 {
 735                         if(self.owner.killindicator_teamchange == -1)
 736                                 centerprint(self.owner, strcat("Changing team in ", ftos(self.cnt), " seconds"));
 737                         else
 738                                 centerprint(self.owner, strcat("Changing to ", ColoredTeamName(self.owner.killindicator_teamchange), " in ", ftos(self.cnt), " seconds"));
 739                 }
 740                 else
 741                         centerprint(self.owner, strcat("^1Suicide in ", ftos(self.cnt), " seconds"));
 742                 play2(self.owner, strcat("announcer/robotoc/", ftos(self.cnt), ".ogg"));
 743                 self.nextthink = time + 1;
 744                 self.cnt -= 1;
 745         }
 746 }
 747
 748 void ClientKill_TeamChange (float targetteam) // 0 = don't change, -1 = auto
 749 {
 750         float killtime;
 751         killtime = cvar("g_balance_kill_delay");
 752
 753         self.killindicator_teamchange = targetteam;
 754
 755         if(!self.killindicator)
 756         {
 757                 if(killtime <= 0 || !self.modelindex || self.deadflag != DEAD_NO)
 758                 {
 759                         ClientKill_Now();
 760                 }
 761                 else
 762                 {
 763                         self.killindicator = spawn();
 764                         self.killindicator.owner = self;
 765                         self.killindicator.scale = 0.5;
 766                         setattachment(self.killindicator, self, "");
 767                         setorigin(self.killindicator, '0 0 52');
 768                         self.killindicator.think = KillIndicator_Think;
 769                         self.killindicator.nextthink = time;
 770                         self.killindicator.cnt = ceil(killtime);
 771                         sprint(self, strcat("^1You'll be dead in ", ftos(self.killindicator.cnt), " seconds\n"));
 772                 }
 773         }
 774         if(self.killindicator)
 775         {
 776                 if(targetteam)
 777                         self.killindicator.colormod = TeamColor(targetteam);
 778                 else
 779                         self.killindicator.colormod = '0 0 0';
 780         }
 781 }
 782
 783 void ClientKill (void)
 784 {
 785         ClientKill_TeamChange(0);
 786 }
 787
 788 void DoTeamChange(float destteam)
 789 {
 790         if(!cvar("teamplay"))
 791         {
 792                 if(destteam >= 0)
 793                         SetPlayerColors(self, destteam);
 794                 return;
 795         }
 796         if(destteam == self.team && !self.killindicator)
 797                 return;
 798         ClientKill_TeamChange(destteam);
 799 }
 800
 801 void FixClientCvars(entity e)
 802 {
 803         float t;
 804         // send prediction settings to the client
 805         stuffcmd(e, "\nin_bindmap 0 0\n");
 806         stuffcmd(e, strcat("cl_gravity ", ftos(cvar("sv_gravity")), "\n"));
 807         stuffcmd(e, strcat("cl_movement_accelerate ", ftos(cvar("sv_accelerate")), "\n"));
 808         stuffcmd(e, strcat("cl_movement_friction ", ftos(cvar("sv_friction")), "\n"));
 809         stuffcmd(e, strcat("cl_movement_maxspeed ", ftos(cvar("sv_maxspeed")), "\n"));
 810         stuffcmd(e, strcat("cl_movement_airaccelerate ", ftos(cvar("sv_airaccelerate")), "\n"));
 811         stuffcmd(e, strcat("cl_movement_maxairspeed ", ftos(cvar("sv_maxairspeed")), "\n"));
 812         stuffcmd(e, strcat("cl_movement_stopspeed ", ftos(cvar("sv_stopspeed")), "\n"));
 813         stuffcmd(e, strcat("cl_movement_jumpvelocity ", ftos(cvar("sv_jumpvelocity")), "\n"));
 814         stuffcmd(e, strcat("cl_movement_stepheight ", ftos(cvar("sv_stepheight")), "\n"));
 815         stuffcmd(e, strcat("set cl_movement_friction_on_land ", ftos(cvar("sv_friction_on_land")), "\n"));
 816         stuffcmd(e, strcat("set cl_movement_airaccel_qw ", ftos(cvar("sv_airaccel_qw")), "\n"));
 817         stuffcmd(e, strcat("set cl_movement_airaccel_sideways_friction ", ftos(cvar("sv_airaccel_sideways_friction")), "\n"));
 818         stuffcmd(e, "cl_movement_edgefriction 1\n");
 819
 820         // notify about available teams
 821         if(teamplay)
 822         {
 823                 CheckAllowedTeams(e);
 824                 t = 0; if(c1 >= 0) t |= 1; if(c2 >= 0) t |= 2; if(c3 >= 0) t |= 4; if(c4 >= 0) t |= 8;
 825                 stuffcmd(e, strcat("set _teams_available ", ftos(t), "\n"));
 826         }
 827         else
 828                 stuffcmd(e, "set _teams_available 0\n");
 829 }
 830
 831 /*
 832 =============
 833 ClientConnect
 834
 835 Called when a client connects to the server
 836 =============
 837 */
 838 string ColoredTeamName(float t);
 839 //void dom_player_join_team(entity pl);
 840 void ClientConnect (void)
 841 {
 842         local string s;
 843         float wep;
 844
 845         if(Ban_IsClientBanned(self))
 846         {
 847                 s = strcat("^1NOTE:^7 banned client ", self.netaddress, " just tried to enter\n");
 848                 dropclient(self);
 849                 bprint(s);
 850                 return;
 851         }
 852
 853         self.classname = "player_joining";
 854         self.flags = self.flags | FL_CLIENT;
 855         self.version_nagtime = time + 10 + random() * 10;
 856
 857         if(player_count<0)
 858         {
 859                 dprint("BUG player count is lower than zero, this cannot happen!\n");
 860                 player_count = 0;
 861         }
 862
 863         bot_clientconnect();
 864
 865         //if(g_domination)
 866         //      dom_player_join_team(self);
 867
 868         //JoinBestTeam(self, FALSE);
 869
 870         if((cvar("sv_spectate") == 1 && !g_lms) || cvar("g_campaign")) {
 871                 self.classname = "observer";
 872         } else {
 873                 self.classname = "player";
 874                 campaign_bots_may_start = 1;
 875         }
 876
 877         self.playerid = (playerid_last = playerid_last + 1);
 878         if(cvar("sv_eventlog"))
 879         {
 880                 if(clienttype(self) == CLIENTTYPE_REAL)
 881                         s = "player";
 882                 else
 883                         s = "bot";
 884                 GameLogEcho(strcat(":join:", ftos(self.playerid), ":", s, ":", self.netname), TRUE);
 885                 s = strcat(":team:", ftos(self.playerid), ":");
 886                 s = strcat(s, ftos(self.team));
 887                 GameLogEcho(s, FALSE);
 888         }
 889
 890         //stuffcmd(self, "set tmpviewsize $viewsize \n");
 891
 892         bprint ("^4",self.netname);
 893         bprint ("^4 connected");
 894
 895         if(g_domination || g_ctf)
 896         {
 897                 bprint(" and joined the ");
 898                 bprint(ColoredTeamName(self.team));
 899         }
 900
 901         bprint("\n");
 902
 903         self.welcomemessage_time = 0;
 904
 905         stuffcmd(self, strcat("exec maps/", mapname, ".cfg\n"));
 906         // TODO: is this being used for anything else than cd tracks?
 907         // Remember: SVC_CDTRACK exists. Maybe it should be used.
 908
 909         FixClientCvars(self);
 910
 911         // waypoint sprites
 912         WaypointSprite_InitClient(self);
 913
 914         // Wazat's grappling hook
 915         SetGrappleHookBindings();
 916
 917         // get autoswitch state from player when he toggles it
 918         stuffcmd(self, "alias autoswitch \"set cl_autoswitch $1 ; cmd autoswitch $1\"\n");
 919
 920         // get version info from player
 921         stuffcmd(self, "cmd clientversion $gameversion\n");
 922
 923         // send all weapon info strings
 924         stuffcmd(self, "register_bestweapon clear\n"); // clear the Quake stuff
 925         wep = WEP_FIRST;
 926         while (wep <= WEP_LAST)
 927         {
 928                 weapon_action(wep, WR_REGISTER);
 929                 wep = wep + 1;
 930         }
 931
 932         // get other cvars from player
 933         GetCvars(0);
 934
 935         // set cvar for team scoreboard
 936         if (teams_matter)
 937         {
 938                 local float t;
 939                 t = cvar("teamplay");
 940                 // we have to stuff the correct teamplay value because if this is a listen server, this changes the teamplay mode of the server itself, which is bad
 941                 stuffcmd(self, strcat("set teamplay ", ftos(t), "\n"));
 942         }
 943         else
 944                 stuffcmd(self, "set teamplay 0\n");
 945
 946         if(g_lms)
 947         {
 948                 self.frags = LMS_NewPlayerLives();
 949                 if(!self.frags)
 950                         self.frags = -666;
 951         }
 952         else if(g_arena)
 953         {
 954                 self.classname = "observer";
 955                 Spawnqueue_Insert(self);
 956         }
 957
 958         bot_relinkplayerlist();
 959
 960         self.jointime = time;
 961 }
 962
 963 /*
 964 =============
 965 ClientDisconnect
 966
 967 Called when a client disconnects from the server
 968 =============
 969 */
 970 void(entity e) DropFlag;
 971 .entity chatbubbleentity;
 972 .entity teambubbleentity;
 973 void ClientDisconnect (void)
 974 {
 975         float save;
 976         if(cvar("sv_eventlog"))
 977                 GameLogEcho(strcat(":part:", ftos(self.playerid)), FALSE);
 978         bprint ("^4",self.netname);
 979         bprint ("^4 disconnected\n");
 980
 981         if (self.chatbubbleentity)
 982         {
 983                 remove (self.chatbubbleentity);
 984                 self.chatbubbleentity = world;
 985         }
 986
 987         if (self.teambubbleentity)
 988         {
 989                 remove (self.teambubbleentity);
 990                 self.teambubbleentity = world;
 991         }
 992
 993         if (self.killindicator)
 994         {
 995                 remove (self.killindicator);
 996                 self.killindicator = world;
 997         }
 998
 999         WaypointSprite_PlayerGone();
1000
1001         DropAllRunes(self);
1002         kh_Key_DropAll(self, TRUE);
1003
1004         if(self.flagcarried)
1005                 DropFlag(self.flagcarried);
1006
1007         DistributeFragsAmongTeam(self, self.team, 1);
1008
1009         save = self.flags;
1010         self.flags = self.flags - (self.flags & FL_CLIENT);
1011         bot_relinkplayerlist();
1012         self.flags = save;
1013
1014         // remove laserdot
1015         if(self.weaponentity)
1016                 if(self.weaponentity.lasertarget)
1017                         remove(self.weaponentity.lasertarget);
1018
1019         if(g_arena)
1020         {
1021                 Spawnqueue_Unmark(self);
1022                 Spawnqueue_Remove(self);
1023         }
1024
1025         // free cvars
1026         GetCvars(-1);
1027 }
1028
1029 .float buttonchat;
1030 void() ChatBubbleThink =
1031 {
1032         self.nextthink = time;
1033         if (!self.owner.modelindex || self.owner.chatbubbleentity != self)
1034         {
1035                 self.owner.chatbubbleentity = world;
1036                 remove(self);
1037                 return;
1038         }
1039         setorigin(self, self.owner.origin + '0 0 15' + self.owner.maxs_z * '0 0 1');
1040         if (self.owner.buttonchat && !self.owner.deadflag)
1041                 self.model = self.mdl;
1042         else
1043                 self.model = "";
1044 };
1045
1046 void() UpdateChatBubble =
1047 {
1048         if (!self.modelindex)
1049                 return;
1050         // spawn a chatbubble entity if needed
1051         if (!self.chatbubbleentity)
1052         {
1053                 self.chatbubbleentity = spawn();
1054                 self.chatbubbleentity.owner = self;
1055                 self.chatbubbleentity.exteriormodeltoclient = self;
1056                 self.chatbubbleentity.think = ChatBubbleThink;
1057                 self.chatbubbleentity.nextthink = time;
1058                 setmodel(self.chatbubbleentity, "models/misc/chatbubble.spr"); // precision set below
1059                 setorigin(self.chatbubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1060                 self.chatbubbleentity.mdl = self.chatbubbleentity.model;
1061                 self.chatbubbleentity.model = "";
1062                 self.chatbubbleentity.effects = EF_LOWPRECISION;
1063         }
1064 }
1065
1066
1067 void() TeamBubbleThink =
1068 {
1069         self.nextthink = time;
1070         if (!self.owner.modelindex || self.owner.teambubbleentity != self)
1071         {
1072                 self.owner.teambubbleentity = world;
1073                 remove(self);
1074                 return;
1075         }
1076 //      setorigin(self, self.owner.origin + '0 0 15' + self.owner.maxs_z * '0 0 1');  // bandwidth hog. setattachment does this now
1077         if (self.owner.buttonchat || self.owner.deadflag || self.owner.killindicator)
1078                 self.model = "";
1079         else
1080                 self.model = self.mdl;
1081
1082 };
1083
1084 float() TeamBubble_customizeentityforclient
1085 {
1086         return (self.owner != other && self.owner.team == other.team && other.killcount > -666);
1087 }
1088
1089 void() UpdateTeamBubble =
1090 {
1091         if (!self.modelindex || !cvar("teamplay"))
1092                 return;
1093         // spawn a teambubble entity if needed
1094         if (!self.teambubbleentity && cvar("teamplay"))
1095         {
1096                 self.teambubbleentity = spawn();
1097                 self.teambubbleentity.owner = self;
1098                 self.teambubbleentity.exteriormodeltoclient = self;
1099                 self.teambubbleentity.think = TeamBubbleThink;
1100                 self.teambubbleentity.nextthink = time;
1101                 setmodel(self.teambubbleentity, "models/misc/teambubble.spr"); // precision set below
1102 //              setorigin(self.teambubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1103                 setorigin(self.teambubbleentity, self.teambubbleentity.origin + '0 0 15' + self.maxs_z * '0 0 1');
1104                 setattachment(self.teambubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1105                 self.teambubbleentity.mdl = self.teambubbleentity.model;
1106                 self.teambubbleentity.model = self.teambubbleentity.mdl;
1107                 self.teambubbleentity.customizeentityforclient = TeamBubble_customizeentityforclient;
1108                 self.teambubbleentity.effects = EF_LOWPRECISION;
1109         }
1110 }
1111
1112 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1113 // added to the model skins
1114 /*void() UpdateColorModHack =
1115 {
1116         local float c;
1117         c = self.clientcolors & 15;
1118         // LordHavoc: only bothering to support white, green, red, yellow, blue
1119              if (teamplay == 0) self.colormod = '0 0 0';
1120         else if (c ==  0) self.colormod = '1.00 1.00 1.00';
1121         else if (c ==  3) self.colormod = '0.10 1.73 0.10';
1122         else if (c ==  4) self.colormod = '1.73 0.10 0.10';
1123         else if (c == 12) self.colormod = '1.22 1.22 0.10';
1124         else if (c == 13) self.colormod = '0.10 0.10 1.73';
1125         else self.colormod = '1 1 1';
1126 };*/
1127
1128 void respawn(void)
1129 {
1130         CopyBody(1);
1131         self.effects |= EF_NODRAW; // prevent another CopyBody
1132         PutClientInServer();
1133 }
1134
1135 void player_powerups (void)
1136 {
1137         if (g_minstagib)
1138         {
1139                 if (self.items & IT_STRENGTH)
1140                 {
1141                         if (time > self.strength_finished)
1142                         {
1143                                 if (g_minstagib_invis_alpha > 0)
1144                                 {
1145                                         self.alpha = default_player_alpha;
1146                                         self.exteriorweaponentity.alpha = default_weapon_alpha;
1147                                         self.effects = self.effects | EF_FULLBRIGHT;
1148                                 }
1149                                 else
1150                                 {
1151                                         self.effects -= self.effects & EF_NODRAW;
1152                                 }
1153                                 self.items = self.items - (self.items & IT_STRENGTH);
1154                                 sprint(self, "^3Invisibility has worn off\n");
1155                         }
1156                 }
1157                 else
1158                 {
1159                         if (time < self.strength_finished)
1160                         {
1161                                 if (g_minstagib_invis_alpha > 0)
1162                                 {
1163                                         self.alpha = g_minstagib_invis_alpha;
1164                                         self.exteriorweaponentity.alpha = g_minstagib_invis_alpha;
1165                                         self.effects -= self.effects & EF_FULLBRIGHT;
1166                                 }
1167                                 else
1168                                 {
1169                                         self.effects = self.effects | EF_NODRAW;
1170                                 }
1171                                 self.items = self.items | IT_STRENGTH;
1172                                 sprint(self, "^3You are invisible\n");
1173                         }
1174                 }
1175
1176                 if (self.items & IT_INVINCIBLE)
1177                 {
1178                         if (time > self.invincible_finished)
1179                         {
1180                                 self.items = self.items - (self.items & IT_INVINCIBLE);
1181                                 sprint(self, "^3Speed has worn off\n");
1182                         }
1183                 }
1184                 else
1185                 {
1186                         if (time < self.invincible_finished)
1187                         {
1188                                 self.items = self.items | IT_INVINCIBLE;
1189                                 sprint(self, "^3You are on speed\n");
1190                         }
1191                 }
1192                 return;
1193         }
1194
1195         self.effects = self.effects - (self.effects & (EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT));
1196         if (self.items & IT_STRENGTH)
1197         {
1198                 self.effects = self.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1199                 if (time > self.strength_finished)
1200                 {
1201                         self.items = self.items - (self.items & IT_STRENGTH);
1202                         sprint(self, "^3Strength has worn off\n");
1203                 }
1204         }
1205         else
1206         {
1207                 if (time < self.strength_finished)
1208                 {
1209                         self.items = self.items | IT_STRENGTH;
1210                         sprint(self, "^3Strength infuses your weapons with devastating power\n");
1211                 }
1212         }
1213         if (self.items & IT_INVINCIBLE)
1214         {
1215                 self.effects = self.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1216                 if (time > self.invincible_finished)
1217                 {
1218                         self.items = self.items - (self.items & IT_INVINCIBLE);
1219                         sprint(self, "^3Shield has worn off\n");
1220                 }
1221         }
1222         else
1223         {
1224                 if (time < self.invincible_finished)
1225                 {
1226                         self.items = self.items | IT_INVINCIBLE;
1227                         sprint(self, "^3Shield surrounds you\n");
1228                 }
1229         }
1230
1231         if (cvar("g_fullbrightplayers"))
1232                 self.effects = self.effects | EF_FULLBRIGHT;
1233
1234         // midair gamemode: damage only while in the air
1235         // if in midair mode, being on ground grants temporary invulnerability
1236         // (this is so that multishot weapon don't clear the ground flag on the
1237         // first damage in the frame, leaving the player vulnerable to the
1238         // remaining hits in the same frame)
1239         if (self.flags & FL_ONGROUND)
1240         if (g_midair)
1241                 self.spawnshieldtime = max(self.spawnshieldtime, time + cvar("g_midair_shieldtime"));
1242
1243         if (time < self.spawnshieldtime)
1244                 self.effects = self.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1245 }
1246
1247 float CalcRegen(float current, float stable, float regenfactor)
1248 {
1249         if(current > stable)
1250                 return current;
1251         else if(current > stable - 0.25) // when close enough, "snap"
1252                 return stable;
1253         else
1254                 return min(stable, current + (stable - current) * regenfactor * frametime);
1255 }
1256
1257 void player_regen (void)
1258 {
1259         float maxh, maxa, limith, limita, max_mod, regen_mod, rot_mod, limit_mod;
1260         maxh = cvar("g_balance_health_stable");
1261         maxa = cvar("g_balance_armor_stable");
1262         limith = cvar("g_balance_health_limit");
1263         limita = cvar("g_balance_armor_limit");
1264
1265         if (g_minstagib || (g_lms && !cvar("g_lms_regenerate")))
1266                 return;
1267
1268         max_mod = regen_mod = rot_mod = limit_mod = 1;
1269
1270         if (self.runes & RUNE_REGEN)
1271         {
1272                 if (self.runes & CURSE_VENOM) // do we have both rune/curse?
1273                 {
1274                         regen_mod = cvar("g_balance_rune_regen_combo_regenrate");
1275                         max_mod = cvar("g_balance_rune_regen_combo_hpmod");
1276                         limit_mod = cvar("g_balance_rune_regen_combo_limitmod");
1277                 }
1278                 else
1279                 {
1280                         regen_mod = cvar("g_balance_rune_regen_regenrate");
1281                         max_mod = cvar("g_balance_rune_regen_hpmod");
1282                         limit_mod = cvar("g_balance_rune_regen_limitmod");
1283                 }
1284         }
1285         else if (self.runes & CURSE_VENOM)
1286         {
1287                 max_mod = cvar("g_balance_curse_venom_hpmod");
1288                 if (self.runes & RUNE_REGEN) // do we have both rune/curse?
1289                         rot_mod = cvar("g_balance_rune_regen_combo_rotrate");
1290                 else
1291                         rot_mod = cvar("g_balance_curse_venom_rotrate");
1292                 limit_mod = cvar("g_balance_curse_venom_limitmod");
1293                 //if (!self.runes & RUNE_REGEN)
1294                 //      rot_mod = cvar("g_balance_curse_venom_rotrate");
1295         }
1296         maxh = maxh * max_mod;
1297         //maxa = maxa * max_mod;
1298         limith = limith * limit_mod;
1299         limita = limita * limit_mod;
1300
1301         if (self.armorvalue > maxa)
1302         {
1303                 if (time > self.pauserotarmor_finished)
1304                 {
1305                         self.armorvalue = max(maxa, self.armorvalue + (maxa - self.armorvalue) * cvar("g_balance_armor_rot") * frametime);
1306                         self.armorvalue = max(maxa, self.armorvalue - cvar("g_balance_armor_rotlinear") * frametime);
1307                 }
1308         }
1309         else if (self.armorvalue < maxa)
1310         {
1311                 if (time > self.pauseregen_finished)
1312                 {
1313                         self.armorvalue = CalcRegen(self.armorvalue, maxa, cvar("g_balance_armor_regen"));
1314                         self.armorvalue = min(maxa, self.armorvalue + cvar("g_balance_armor_regenlinear") * frametime);
1315                 }
1316         }
1317         if (self.health > maxh)
1318         {
1319                 if (time > self.pauserothealth_finished)
1320                 {
1321                         self.health = max(maxh, self.health + (maxh - self.health) * rot_mod*cvar("g_balance_health_rot") * frametime);
1322                         self.health = max(maxh, self.health - rot_mod*cvar("g_balance_health_rotlinear") * frametime);
1323                 }
1324         }
1325         else if (self.health < maxh)
1326         {
1327                 if (time > self.pauseregen_finished)
1328                 {
1329                         self.health = CalcRegen(self.health, maxh, regen_mod * cvar("g_balance_health_regen"));
1330                         self.health = min(maxh, self.health + regen_mod*cvar("g_balance_health_regenlinear") * frametime);
1331                 }
1332         }
1333
1334         if (self.health > limith)
1335                 self.health = limith;
1336         if (self.armorvalue > limita)
1337                 self.armorvalue = limita;
1338
1339         // if player rotted to death...  die!
1340         if(self.health < 1)
1341                 self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
1342 }
1343
1344 /*
1345 ======================
1346 spectate mode routines
1347 ======================
1348 */
1349 void SpectateCopy(entity spectatee) {
1350         self.armortype = spectatee.armortype;
1351         self.armorvalue = spectatee.armorvalue;
1352         self.currentammo = spectatee.currentammo;
1353         self.effects = spectatee.effects;
1354         self.health = spectatee.health;
1355         self.impulse = 0;
1356         self.items = spectatee.items;
1357         self.punchangle = spectatee.punchangle;
1358         self.view_ofs = spectatee.view_ofs;
1359         self.v_angle = spectatee.v_angle;
1360         self.viewzoom = spectatee.viewzoom;
1361         self.velocity = spectatee.velocity;
1362         self.dmg_take = spectatee.dmg_take;
1363         self.dmg_save = spectatee.dmg_save;
1364         self.dmg_inflictor = spectatee.dmg_inflictor;
1365         self.angles = spectatee.v_angle;
1366         self.fixangle = TRUE;
1367         setorigin(self, spectatee.origin);
1368         setsize(self, spectatee.mins, spectatee.maxs);
1369 }
1370
1371 void SpectateUpdate() {
1372         if(!self.enemy)
1373                         PutObserverInServer();
1374
1375         if (self != self.enemy) {
1376                 if(self.enemy.flags & FL_NOTARGET)
1377                         PutObserverInServer();
1378                 SpectateCopy(self.enemy);
1379                 //msg_entity = self;
1380                 //WriteByte(MSG_ONE, SVC_SETANGLE);
1381                 //WriteAngle(MSG_ONE, self.enemy.v_angle_x);
1382                 //WriteAngle(MSG_ONE, self.enemy.v_angle_y);
1383                 //WriteAngle(MSG_ONE, self.enemy.v_angle_z);
1384         }
1385 }
1386
1387 float SpectateNext() {
1388         other = find(self.enemy, classname, "player");
1389         if (!other) {
1390                 other = find(other, classname, "player");
1391         }
1392         if (other) {
1393                 self.enemy = other;
1394         }
1395         if(self.enemy.classname == "player") {
1396                 msg_entity = self;
1397                 WriteByte(MSG_ONE, SVC_SETVIEW);
1398                 WriteEntity(MSG_ONE, self.enemy);
1399                 self.wantswelcomemessage = 1;
1400                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
1401                 SpectateUpdate();
1402                 return 1;
1403         } else {
1404                 return 0;
1405         }
1406 }
1407
1408 /*
1409 =============
1410 ShowRespawnCountdown()
1411
1412 Update a respawn countdown display.
1413 =============
1414 */
1415 void ShowRespawnCountdown()
1416 {
1417         float number;
1418         if(self.deadflag == DEAD_NO) // just respawned?
1419                 return;
1420         else
1421         {
1422                 number = ceil(self.death_time - time);
1423                 if(number <= 0)
1424                         return;
1425                 if(number <= self.respawn_countdown)
1426                 {
1427                         self.respawn_countdown = number - 1;
1428                         if(ceil(self.death_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
1429                                 play2(self, strcat("announcer/robotic/", ftos(number), ".ogg"));
1430                 }
1431         }
1432 }
1433
1434 void LeaveSpectatorMode()
1435 {
1436         if(!cvar("teamplay") || cvar("g_campaign") || cvar("g_balance_teams")) {
1437                 self.classname = "player";
1438                 if(cvar("g_campaign") || cvar("g_balance_teams"))
1439                         JoinBestTeam(self, 0);
1440                 if(cvar("g_campaign"))
1441                         campaign_bots_may_start = 1;
1442                 PutClientInServer();
1443                 if(!(self.flags & FL_NOTARGET))
1444                         bprint ("^4", self.netname, "^4 is playing now\n");
1445                 centerprint(self,"");
1446                 return;
1447         } else {
1448                 stuffcmd(self,"menu_showteamselect\n");
1449                 return;
1450         }
1451 }
1452
1453 /*
1454 =============
1455 PlayerPreThink
1456
1457 Called every frame for each client before the physics are run
1458 =============
1459 */
1460 void() ctf_setstatus;
1461 .float vote_nagtime;
1462 void PlayerPreThink (void)
1463 {
1464         // version nagging
1465         if(self.version_nagtime)
1466                 if(self.cvar_g_nexuizversion)
1467                         if(time > self.version_nagtime)
1468                         {
1469                                 if(strstr(self.cvar_g_nexuizversion, "svn", 0) < 0)
1470                                         if(self.cvar_g_nexuizversion != cvar_string("g_nexuizversion"))
1471                                         {
1472                                                 dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Nexuiz ", cvar_string("g_nexuizversion"), "^7, you have ^3Nexuiz ", self.cvar_g_nexuizversion, "\n");
1473                                                 sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Nexuiz ", cvar_string("g_nexuizversion"), "^7, you have ^3Nexuiz ", self.cvar_g_nexuizversion, "\n"));
1474                                         }
1475                                 self.version_nagtime = 0;
1476                         }
1477
1478         // vote nagging
1479         if(self.cvar_scr_centertime)
1480                 if(time > self.vote_nagtime)
1481                 {
1482                         VoteNag();
1483                         self.vote_nagtime = time + self.cvar_scr_centertime * 0.6;
1484                 }
1485
1486         // GOD MODE info
1487         if(!(self.flags & FL_GODMODE)) if(self.max_armorvalue)
1488         {
1489                 sprint(self, strcat("godmode saved you ", ftos(self.max_armorvalue), " units of damage, cheater!\n"));
1490                 self.max_armorvalue = 0;
1491         }
1492
1493         if(frametime)
1494                 antilag_record(self);
1495
1496         if(self.classname == "player") {
1497 //              if(self.netname == "Wazat")
1498 //                      bprint(self.classname, "\n");
1499
1500                 CheckRules_Player();
1501
1502                 if(self.button7)
1503                         PrintWelcomeMessage(self);
1504
1505                 if(g_lms || !cvar("sv_spectate"))
1506                 if((time - self.jointime) <= cvar("welcome_message_time"))
1507                         PrintWelcomeMessage(self);
1508
1509                 if (intermission_running)
1510                 {
1511                         IntermissionThink ();   // otherwise a button could be missed between
1512                         return;                                 // the think tics
1513                 }
1514
1515                 if(self.teleport_time)
1516                 if(time > self.teleport_time)
1517                 {
1518                         self.teleport_time = 0;
1519                         self.effects = self.effects - (self.effects & EF_NODRAW);
1520                         if(self.weaponentity)
1521                                 self.weaponentity.flags = self.weaponentity.flags - (self.weaponentity.flags & EF_NODRAW);
1522                 }
1523
1524                 Nixnex_GiveCurrentWeapon();
1525
1526                 if(frametime > 0) // don't do this in cl_movement frames, just in server ticks
1527                         UpdateSelectedPlayer();
1528
1529                 if (self.deadflag != DEAD_NO)
1530                 {
1531                         float button_pressed, force_respawn;
1532                         player_anim();
1533                         button_pressed = (self.button0 || self.button2 || self.button3 || self.button6 || self.buttonuse);
1534                         force_respawn = (g_lms || cvar("g_forced_respawn"));
1535                         if (self.deadflag == DEAD_DYING)
1536                         {
1537                                 if(force_respawn)
1538                                         self.deadflag = DEAD_RESPAWNING;
1539                                 else if(!button_pressed)
1540                                         self.deadflag = DEAD_DEAD;
1541                         }
1542                         else if (self.deadflag == DEAD_DEAD)
1543                         {
1544                                 if(button_pressed)
1545                                         self.deadflag = DEAD_RESPAWNABLE;
1546                         }
1547                         else if (self.deadflag == DEAD_RESPAWNABLE)
1548                         {
1549                                 if(!button_pressed)
1550                                         self.deadflag = DEAD_RESPAWNING;
1551                         }
1552                         else if (self.deadflag == DEAD_RESPAWNING)
1553                         {
1554                                 if(time > self.death_time)
1555                                 {
1556                                         self.death_time = time + 1; // only retry once a second
1557                                         respawn();
1558                                 }
1559                         }
1560                         ShowRespawnCountdown();
1561                         return;
1562                 }
1563
1564                 if(g_lms && !self.deadflag && cvar("g_lms_campcheck_interval"))
1565                 {
1566                         vector dist;
1567
1568                         // calculate player movement (in 2 dimensions only, so jumping on one spot doesn't count as movement)
1569                         dist = self.oldorigin - self.origin;
1570                         dist_z = 0;
1571                         self.lms_traveled_distance += fabs(vlen(dist));
1572
1573                         if((cvar("g_campaign") && !campaign_bots_may_start) || (time < restart_countdown))
1574                         {
1575                                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval")*2;
1576                                 self.lms_traveled_distance = 0;
1577                         }
1578
1579                         if(time > self.lms_nextcheck)
1580                         {
1581                                 //sprint(self, "distance: ", ftos(self.lms_traveled_distance), "\n");
1582                                 if(self.lms_traveled_distance < cvar("g_lms_campcheck_distance"))
1583                                 {
1584                                         centerprint(self, cvar_string("g_lms_campcheck_message"));
1585                                         // FIXME KadaverJack: gibbing player here causes playermodel to bounce around, instead of eye.md3
1586                                         // I wasn't able to find out WHY that happens, so I put a workaround in place that shall prevent players from being gibbed :(
1587                                         Damage(self, self, self, bound(0, cvar("g_lms_campcheck_damage"), self.health + self.armorvalue * cvar("g_balance_armor_blockpercent") + 5), DEATH_CAMP, self.origin, '0 0 0');
1588                                 }
1589                                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval");
1590                                 self.lms_traveled_distance = 0;
1591                         }
1592                 }
1593
1594                 if (self.button5 && !self.hook.state)
1595                 {
1596                         if (!self.crouch)
1597                         {
1598                                 self.crouch = TRUE;
1599                                 self.view_ofs = PL_CROUCH_VIEW_OFS;
1600                                 setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX);
1601                                 player_setanim(self.anim_duck, FALSE, TRUE, TRUE);
1602                         }
1603                 }
1604                 else
1605                 {
1606                         if (self.crouch)
1607                         {
1608                                 tracebox(self.origin, PL_MIN, PL_MAX, self.origin, FALSE, self);
1609                                 if (!trace_startsolid)
1610                                 {
1611                                         self.crouch = FALSE;
1612                                         self.view_ofs = PL_VIEW_OFS;
1613                                         setsize (self, PL_MIN, PL_MAX);
1614                                 }
1615                         }
1616                 }
1617
1618                 FixPlayermodel();
1619
1620                 GrapplingHookFrame();
1621
1622                 W_WeaponFrame();
1623
1624                 {
1625                         float zoomfactor, zoomspeed, zoomdir;
1626                         zoomfactor = self.cvar_cl_zoomfactor;
1627                         if(zoomfactor < 1 || zoomfactor > 16)
1628                                 zoomfactor = 2.5;
1629                         zoomspeed = self.cvar_cl_zoomspeed;
1630                         if(zoomspeed >= 0) // < 0 is instant zoom
1631                                 if(zoomspeed < 0.5 || zoomspeed > 16)
1632                                         zoomspeed = 3.5;
1633
1634                         zoomdir = self.button4;
1635                         if(self.button3)
1636                                 if(self.weapon == WEP_NEX)
1637                                         if(!g_minstagib)
1638                                                 zoomdir = 1;
1639
1640                         if(zoomdir)
1641                                 self.has_zoomed = 1;
1642
1643                         if(self.has_zoomed)
1644                         {
1645                                 if(zoomspeed <= 0) // instant zoom
1646                                 {
1647                                         if(zoomdir)
1648                                                 self.viewzoom = 1 / zoomfactor;
1649                                         else
1650                                                 self.viewzoom = 1;
1651                                 }
1652                                 else
1653                                 {
1654                                         // geometric zoom would be:
1655                                         //   self.viewzoom = bound(1 / zoomfactor, self.viewzoom * pow(zoomfactor, (zoomdir ? -1 : 1) * frametime * zoomspeed), 1);
1656                                         // however, testing showed that arithmetic/harmonic zoom works better
1657                                         if(zoomdir)
1658                                                 // self.viewzoom = 1 / bound(1, 1 / self.viewzoom + (zoomdir ? 1 : -1) * frametime * zoomspeed * (zoomfactor - 1), zoomfactor);
1659                                                 // zoom in = arithmetic: 1x, 2x, 3x, 4x, ..., 8x
1660                                                 self.viewzoom = 1 / bound(1, 1 / self.viewzoom + frametime * zoomspeed * (zoomfactor - 1), zoomfactor);
1661                                         else
1662                                                 // self.viewzoom = bound(1 / zoomfactor, self.viewzoom + (zoomdir ? -1 : 1) * frametime * zoomspeed * (1 - 1 / zoomfactor), 1);
1663                                                 // zoom out = harmonic: 8/1x, 8/2x, 8/3x, 8/4x, ..., 8/8x
1664                                                 self.viewzoom = bound(1 / zoomfactor, self.viewzoom + frametime * zoomspeed * (1 - 1 / zoomfactor), 1);
1665                                 }
1666                         }
1667                         else
1668                                 self.viewzoom = min(1, self.viewzoom + frametime); // spawn zoom-in
1669                 }
1670
1671                 player_powerups();
1672                 player_regen();
1673                 player_anim();
1674
1675                 if (g_minstagib)
1676                         minstagib_ammocheck();
1677
1678                 ctf_setstatus();
1679                 kh_setstatus();
1680
1681                 //self.angles_y=self.v_angle_y + 90;   // temp
1682
1683                 //if (TetrisPreFrame()) return;
1684         } else if(gameover) {
1685                 if (intermission_running)
1686                         IntermissionThink ();   // otherwise a button could be missed between
1687                 return;
1688         } else if(self.classname == "observer") {
1689                 if (self.flags & FL_JUMPRELEASED) {
1690                         if (self.button2 && self.version == cvar("gameversion")) {
1691                                 self.welcomemessage_time = 0;
1692                                 self.flags = self.flags - FL_JUMPRELEASED;
1693                                 LeaveSpectatorMode();
1694                                 return;
1695                         } else if(self.button0 && self.version == cvar("gameversion")) {
1696                                 self.welcomemessage_time = 0;
1697                                 self.flags = self.flags - FL_JUMPRELEASED;
1698                                 if(SpectateNext() == 1) {
1699                                         self.classname = "spectator";
1700                                 }
1701                         }
1702                 } else {
1703                         if (!(self.button0 || self.button2)) {
1704                                 self.flags = self.flags | FL_JUMPRELEASED;
1705                         }
1706                 }
1707                 if(self.button4)
1708                         self.wantswelcomemessage = 0;
1709                 if(self.wantswelcomemessage)
1710                         PrintWelcomeMessage(self);
1711         } else if(self.classname == "spectator") {
1712                 if (self.flags & FL_JUMPRELEASED) {
1713                         if (self.button2 && self.version == cvar("gameversion")) {
1714                                 self.welcomemessage_time = 0;
1715                                 self.flags = self.flags - FL_JUMPRELEASED;
1716                                 LeaveSpectatorMode();
1717                                 return;
1718                         } else if(self.button0) {
1719                                 self.welcomemessage_time = 0;
1720                                 self.flags = self.flags - FL_JUMPRELEASED;
1721                                 if(SpectateNext() == 1) {
1722                                         self.classname = "spectator";
1723                                 } else {
1724                                         self.classname = "observer";
1725                                         PutClientInServer();
1726                                 }
1727                         } else if (self.button3) {
1728                                 self.welcomemessage_time = 0;
1729                                 self.flags = self.flags - FL_JUMPRELEASED;
1730                                 self.classname = "observer";
1731                                 PutClientInServer();
1732                         } else {
1733                                 SpectateUpdate();
1734                         }
1735                 } else {
1736                         if (!(self.button0 || self.button3)) {
1737                                 self.flags = self.flags | FL_JUMPRELEASED;
1738                         }
1739                 }
1740                 if(self.button4)
1741                         self.wantswelcomemessage = 0;
1742                 if(self.wantswelcomemessage)
1743                         PrintWelcomeMessage(self);
1744                 self.flags = self.flags | FL_CLIENT | FL_NOTARGET;
1745         }
1746 }
1747
1748
1749 /*
1750 =============
1751 PlayerPostThink
1752
1753 Called every frame for each client after the physics are run
1754 =============
1755 */
1756 void PlayerPostThink (void)
1757 {
1758         // Savage: Check for nameless players
1759         if (strlen(self.netname) < 1) {
1760                 self.netname = "Player";
1761                 stuffcmd(self, "seta _cl_name Player\n");
1762         }
1763
1764         if(self.classname == "player") {
1765                 CheckRules_Player();
1766                 UpdateChatBubble();
1767                 UpdateTeamBubble();
1768                 if (self.impulse)
1769                         ImpulseCommands();
1770                 if (intermission_running)
1771                         return;         // intermission or finale
1772
1773                 //PrintWelcomeMessage(self);
1774                 //if (TetrisPostFrame()) return;
1775
1776                 // restart countdown
1777                 if(time < restart_countdown)
1778                 {
1779                         string s;
1780                         float sec;
1781
1782                         sec = ceil(restart_countdown-time);
1783                         s = strcat(NEWLINES, "^1Game starts in ", ftos(sec), " seconds");
1784                         centerprint(self, s);
1785                         self.movetype = MOVETYPE_NONE;
1786                         self.velocity = '0 0 0';
1787                         self.avelocity = '0 0 0';
1788                         self.movement = '0 0 0';
1789                 }
1790                 else if(self.movetype == MOVETYPE_NONE)
1791                 {
1792                         self.movetype = MOVETYPE_WALK;
1793                         centerprint(self, "\n");
1794                 }
1795         } else if (self.classname == "observer") {
1796                 //do nothing
1797         } else if (self.classname == "spectator") {
1798                 //do nothing
1799         }
1800
1801         Arena_Warmup();
1802 }