data/qcsrc/server/cl_client.qc

   1 void info_player_start (void)
   2 {
   3         self.classname = "info_player_deathmatch";
   4         relocate_spawnpoint();
   5 }
   6
   7 void info_player_deathmatch (void)
   8 {
   9         relocate_spawnpoint();
  10 }
  11
  12 float spawn_allbad;
  13 float spawn_allgood;
  14 entity Spawn_FilterOutBadSpots(entity firstspot, entity playerlist, float mindist, float teamcheck)
  15 {
  16         local entity spot, player, nextspot, previousspot, newfirstspot;
  17         local float pcount;
  18         spot = firstspot;
  19         newfirstspot = world;
  20         previousspot = world;
  21         spawn_allgood = TRUE;
  22         spawn_allbad = TRUE;
  23         while (spot)
  24         {
  25                 nextspot = spot.chain;
  26                 // count team mismatches as bad spots
  27                 if (spot.team == teamcheck)
  28                 {
  29                         pcount = 0;
  30                         player = playerlist;
  31                         while (player)
  32                         {
  33                                 if (player != self)
  34                                 if (vlen(player.origin - spot.origin) < mindist)
  35                                         pcount = pcount + 1;
  36                                 player = player.chain;
  37                         }
  38                         if (!pcount)
  39                         {
  40                                 spawn_allbad = FALSE;
  41                                 if (newfirstspot)
  42                                         previousspot.chain = spot;
  43                                 else
  44                                         newfirstspot = spot;
  45                                 previousspot = spot;
  46                                 spot.chain = world;
  47                         }
  48                         else
  49                                 spawn_allgood = FALSE;
  50                 }
  51                 spot = nextspot;
  52         }
  53         // if we couldn't find ANY good points, return the original list
  54         if (!newfirstspot)
  55                 newfirstspot = firstspot;
  56         return newfirstspot;
  57 }
  58
  59 entity Spawn_RandomPoint(entity firstspot)
  60 {
  61         local entity spot;
  62         local float numspots;
  63         // count number of spots
  64         numspots = 0;
  65         spot = firstspot;
  66         while (spot)
  67         {
  68                 numspots = numspots + 1;
  69                 spot = spot.chain;
  70         }
  71         // pick a random one
  72         numspots = numspots * random();
  73         spot = firstspot;
  74         while (spot.chain && numspots >= 1)
  75         {
  76                 numspots = numspots - 1;
  77                 spot = spot.chain;
  78         }
  79         return spot;
  80 }
  81
  82 entity Spawn_FurthestPoint(entity firstspot, entity playerlist)
  83 {
  84         local entity best, spot, player;
  85         local float bestrating, rating;
  86         best = world;
  87         bestrating = -1000000;
  88         spot = firstspot;
  89         while (spot)
  90         {
  91                 rating = 1000000000;
  92                 player = playerlist;
  93                 while (player)
  94                 {
  95                         if (player != self)
  96                                 rating = min(rating, vlen(player.origin - spot.origin));
  97                         player = player.chain;
  98                 }
  99                 rating = rating + random() * 16;
 100                 if (bestrating < rating)
 101                 {
 102                         best = spot;
 103                         bestrating = rating;
 104                 }
 105                 spot = spot.chain;
 106         }
 107         return best;
 108 }
 109
 110 /*
 111 =============
 112 SelectSpawnPoint
 113
 114 Finds a point to respawn
 115 =============
 116 */
 117 entity SelectSpawnPoint (float anypoint)
 118 {
 119         local float teamcheck;
 120         local entity spot, firstspot, playerlist;
 121
 122         spot = find (world, classname, "testplayerstart");
 123         if (spot)
 124                 return spot;
 125
 126         teamcheck = 0;
 127
 128         if(!anypoint && cvar("g_ctf") )
 129                 teamcheck = self.team;
 130
 131         // get the list of players
 132         playerlist = findchain(classname, "player");
 133         // get the entire list of spots
 134         firstspot = findchain(classname, "info_player_deathmatch");
 135         // filter out the bad ones
 136         // (note this returns the original list if none survived)
 137         firstspot = Spawn_FilterOutBadSpots(firstspot, playerlist, 100, teamcheck);
 138
 139         // there is 50/50 chance of choosing a random spot or the furthest spot
 140         // (this means that roughly every other spawn will be furthest, so you
 141         // usually won't get fragged at spawn twice in a row)
 142         if (arena_roundbased)
 143         {
 144                 firstspot = Spawn_FilterOutBadSpots(firstspot, playerlist, 800, teamcheck);
 145                 spot = Spawn_RandomPoint(firstspot);
 146         }
 147         else if (random() > 0.5 || spawn_allbad || spawn_allgood)
 148                 spot = Spawn_RandomPoint(firstspot);
 149         else
 150                 spot = Spawn_FurthestPoint(firstspot, playerlist);
 151
 152         if (!spot)
 153         {
 154                 if(cvar("spawn_debug"))
 155                         GotoNextMap();
 156                 else
 157                         error ("PutClientInServer: no start points on level");
 158         }
 159
 160         return spot;
 161 }
 162
 163 /*
 164 =============
 165 CheckPlayerModel
 166
 167 Checks if the argument string can be a valid playermodel.
 168 Returns a valid one in doubt.
 169 =============
 170 */
 171 string FallbackPlayerModel = "models/player/marine.zym";
 172 string CheckPlayerModel(string plyermodel) {
 173         if(strlen(plyermodel) < 4)
 174                 return FallbackPlayerModel;
 175         if( substring(plyermodel,0,14) != "models/player/")
 176                 return FallbackPlayerModel;
 177         else if(cvar("sv_servermodelsonly"))
 178         {
 179                 if(substring(plyermodel,strlen(plyermodel)-4,4) != ".zym")
 180                         return FallbackPlayerModel;
 181                 if(!fexists(plyermodel))
 182                         return FallbackPlayerModel;
 183         }
 184         return plyermodel;
 185 }
 186
 187 /*
 188 =============
 189 Client_customizeentityforclient
 190
 191 LOD reduction
 192 =============
 193 */
 194 float Client_customizeentityforclient()
 195 {
 196 #ifdef ALLOW_VARIABLE_LOD
 197         // self: me
 198         // other: the player viewing me
 199         float distance;
 200         float f;
 201
 202         if(self.flags & FL_NOTARGET) // we don't need LOD for spectators
 203                 return TRUE;
 204
 205         if(other.cvar_cl_playerdetailreduction <= 0)
 206         {
 207                 if(other.cvar_cl_playerdetailreduction <= -2)
 208                         self.modelindex = self.modelindex_lod2;
 209                 else if(other.cvar_cl_playerdetailreduction <= -1)
 210                         self.modelindex = self.modelindex_lod1;
 211                 else
 212                         self.modelindex = self.modelindex_lod0;
 213         }
 214         else
 215         {
 216                 distance = vlen(self.origin - other.origin);
 217                 f = (distance + 100.0) * other.cvar_cl_playerdetailreduction;
 218                 if(f > 10000)
 219                         self.modelindex = self.modelindex_lod2;
 220                 else if(f > 5000)
 221                         self.modelindex = self.modelindex_lod1;
 222                 else
 223                         self.modelindex = self.modelindex_lod0;
 224         }
 225 #endif
 226
 227         return TRUE;
 228 }
 229
 230 void setmodel_lod(entity e, string modelname)
 231 {
 232 #ifdef ALLOW_VARIABLE_LOD
 233         string s;
 234
 235         s = strcat(substring(modelname, 0, strlen(modelname) - 4), "_1.zym");
 236         if(fexists(s))
 237         {
 238                 precache_model(s);
 239                 setmodel(e, s);
 240                 self.modelindex_lod1 = self.modelindex;
 241         }
 242         else
 243                 self.modelindex_lod1 = -1;
 244
 245         s = strcat(substring(modelname, 0, strlen(modelname) - 4), "_2.zym");
 246         if(fexists(s))
 247         {
 248                 precache_model(s);
 249                 setmodel(e, s);
 250                 self.modelindex_lod2 = self.modelindex;
 251         }
 252         else
 253                 self.modelindex_lod2 = -1;
 254
 255         precache_model(modelname);
 256         setmodel(e, modelname);
 257         self.modelindex_lod0 = self.modelindex;
 258
 259         if(self.modelindex_lod1 < 0)
 260                 self.modelindex_lod1 = self.modelindex;
 261
 262         if(self.modelindex_lod2 < 0)
 263                 self.modelindex_lod2 = self.modelindex;
 264 #else
 265         precache_model(modelname);
 266         setmodel(e, modelname);
 267 #endif
 268 }
 269
 270 /*
 271 =============
 272 PutObserverInServer
 273
 274 putting a client as observer in the server
 275 =============
 276 */
 277 void PutObserverInServer (void)
 278 {
 279         entity  spot;
 280         spot = SelectSpawnPoint (FALSE);
 281         RemoveGrapplingHook(self); // Wazat's Grappling Hook
 282
 283         if(clienttype(self) == CLIENTTYPE_REAL)
 284         {
 285                 msg_entity = self;
 286                 WriteByte(MSG_ONE, SVC_SETVIEW);
 287                 WriteEntity(MSG_ONE, self);
 288         }
 289
 290         if (cvar("g_runematch"))
 291                 DropAllRunes(self);
 292
 293         if(self.frags <= 0 && self.frags > -666 && cvar("g_lms") && self.killcount != -666)
 294                 bprint (strcat("^4", self.netname, "^4 has no more lives left\n"));
 295         else if(self.killcount != -666)
 296                 bprint (strcat("^4", self.netname, "^4 is spectating now\n"));
 297
 298         self.classname = "observer";
 299         self.health = -666;
 300         self.takedamage = DAMAGE_NO;
 301         self.solid = SOLID_NOT;
 302         self.movetype = MOVETYPE_NOCLIP;
 303         self.flags = FL_CLIENT | FL_NOTARGET;
 304         self.armorvalue = 666;
 305         self.effects = 0;
 306         self.armorvalue = cvar("g_balance_armor_start");
 307         self.pauserotarmor_finished = 0;
 308         self.pauserothealth_finished = 0;
 309         self.pauseregen_finished = 0;
 310         self.damageforcescale = 0;
 311         self.death_time = 0;
 312         self.dead_time = 0;
 313         self.dead_frame = 0;
 314         self.die_frame = 0;
 315         self.deaths = 0;
 316         self.alpha = 0;
 317         self.scale = 0;
 318         self.fade_time = 0;
 319         self.pain_frame = 0;
 320         self.pain_finished = 0;
 321         self.strength_finished = 0;
 322         self.invincible_finished = 0;
 323         self.pushltime = 0;
 324         self.think = SUB_Null;
 325         self.nextthink = 0;
 326         self.hook_time = 0;
 327         self.runes = 0;
 328         self.deadflag = DEAD_NO;
 329         self.angles = spot.angles;
 330         self.angles_z = 0;
 331         self.fixangle = TRUE;
 332         self.crouch = FALSE;
 333
 334         self.view_ofs = PL_VIEW_OFS;
 335         setorigin (self, spot.origin);
 336         setsize (self, '0 0 0', '0 0 0');
 337         self.oldorigin = self.origin;
 338         self.items = 0;
 339         self.model = "";
 340         self.modelindex = 0;
 341         self.weapon = 0;
 342         self.weaponmodel = "";
 343         self.weaponentity = world;
 344         self.killcount = -666;
 345         self.velocity = '0 0 0';
 346         self.avelocity = '0 0 0';
 347         self.punchangle = '0 0 0';
 348         self.punchvector = '0 0 0';
 349         self.oldvelocity = self.velocity;
 350         self.customizeentityforclient = Client_customizeentityforclient;
 351
 352         if(cvar("g_arena"))
 353         {
 354                 if(self.frags != -2)
 355                 {
 356                         Spawnqueue_Insert(self);
 357                 }
 358                 else
 359                 {
 360                         Spawnqueue_Unmark(self);
 361                         Spawnqueue_Remove(self);
 362                 }
 363         }
 364         else if(!cvar("g_lms"))
 365                 self.frags = -666;
 366 }
 367
 368
 369 /*
 370 =============
 371 PutClientInServer
 372
 373 Called when a client spawns in the server
 374 =============
 375 */
 376 void PutClientInServer (void)
 377 {
 378         if(clienttype(self) == CLIENTTYPE_BOT)
 379         {
 380                 self.classname = "player";
 381         }
 382         else if(clienttype(self) == CLIENTTYPE_REAL)
 383         {
 384                 msg_entity = self;
 385                 WriteByte(MSG_ONE, SVC_SETVIEW);
 386                 WriteEntity(MSG_ONE, self);
 387         }
 388
 389         // player is dead and becomes observer
 390         if(cvar("g_lms") && self.frags < 1)
 391                 self.classname = "observer";
 392
 393         if(cvar("g_arena"))
 394         if(!self.spawned)
 395                 self.classname = "observer";
 396
 397         if(self.classname == "player") {
 398                 entity  spot;
 399
 400                 spot = SelectSpawnPoint (FALSE);
 401
 402                 RemoveGrapplingHook(self); // Wazat's Grappling Hook
 403
 404                 self.classname = "player";
 405                 self.iscreature = TRUE;
 406                 self.movetype = MOVETYPE_WALK;
 407                 self.solid = SOLID_SLIDEBOX;
 408                 self.flags = FL_CLIENT;
 409                 self.takedamage = DAMAGE_AIM;
 410                 self.effects = 0;
 411                 self.health = cvar("g_balance_health_start");
 412                 self.armorvalue = cvar("g_balance_armor_start");
 413                 self.spawnshieldtime = time + cvar("g_spawnshieldtime");
 414                 self.pauserotarmor_finished = time + cvar("g_balance_pause_armor_rot_spawn");
 415                 self.pauserothealth_finished = time + cvar("g_balance_pause_health_rot_spawn");
 416                 self.pauseregen_finished = time + cvar("g_balance_pause_health_regen_spawn");
 417                 self.damageforcescale = 2;
 418                 self.death_time = 0;
 419                 self.dead_time = 0;
 420                 self.dead_frame = 0;
 421                 self.die_frame = 0;
 422                 self.alpha = 0;
 423                 self.scale = 0;
 424                 self.fade_time = 0;
 425                 self.pain_frame = 0;
 426                 self.pain_finished = 0;
 427                 self.strength_finished = 0;
 428                 self.invincible_finished = 0;
 429                 self.pushltime = 0;
 430                 //self.speed_finished = 0;
 431                 //self.slowmo_finished = 0;
 432                 // players have no think function
 433                 self.think = SUB_Null;
 434                 self.nextthink = 0;
 435                 self.weapon = 0;
 436                 self.switchweapon = 0;
 437                 self.hook_time = 0;
 438
 439                 self.runes = 0;
 440
 441                 self.deadflag = DEAD_NO;
 442
 443                 self.angles = spot.angles;
 444
 445                 self.angles_z = 0; // never spawn tilted even if the spot says to
 446                 self.fixangle = TRUE; // turn this way immediately
 447                 self.velocity = '0 0 0';
 448                 self.avelocity = '0 0 0';
 449                 self.punchangle = '0 0 0';
 450                 self.punchvector = '0 0 0';
 451                 self.oldvelocity = self.velocity;
 452
 453                 self.viewzoom = 0.6;
 454
 455                 self.customizeentityforclient = Client_customizeentityforclient;
 456
 457                 if(cvar("sv_defaultcharacter") == 1 && !teams_matter) {
 458                         local string defaultmodel;
 459                         defaultmodel = CheckPlayerModel(cvar_string("sv_defaultplayermodel"));
 460                         setmodel_lod (self, defaultmodel);
 461                         self.skin = stof(cvar_string("sv_defaultplayerskin"));
 462                 } else {
 463                         self.playermodel = CheckPlayerModel(self.playermodel);
 464                         setmodel_lod (self, self.playermodel);
 465                         self.skin = stof(self.playerskin);
 466
 467                 }
 468
 469                 self.crouch = FALSE;
 470                 self.view_ofs = PL_VIEW_OFS;
 471                 setsize (self, PL_MIN, PL_MAX);
 472                 self.spawnorigin = spot.origin;
 473                 setorigin (self, spot.origin + '0 0 1' * (1 - self.mins_z - 24));
 474                 // don't reset back to last position, even if new position is stuck in solid
 475                 self.oldorigin = self.origin;
 476
 477                 if(cvar("g_lms"))
 478                 {
 479                         self.ammo_shells = cvar("g_lms_start_ammo_shells");
 480                         self.ammo_nails = cvar("g_lms_start_ammo_nails");
 481                         self.ammo_rockets = cvar("g_lms_start_ammo_rockets");
 482                         self.ammo_cells = cvar("g_lms_start_ammo_cells");
 483                         self.health = cvar("g_lms_start_health");
 484                         self.armorvalue = cvar("g_lms_start_armor");
 485                 }
 486                 else if (cvar("g_use_ammunition")) {
 487                         self.ammo_shells = cvar("g_start_ammo_shells");
 488                         self.ammo_nails = cvar("g_start_ammo_nails");
 489                         self.ammo_rockets = cvar("g_start_ammo_rockets");
 490                         self.ammo_cells = cvar("g_start_ammo_cells");
 491                 } else {
 492                         self.ammo_shells = 999;
 493                         self.ammo_nails = 999;
 494                         self.ammo_rockets = 999;
 495                         self.ammo_cells = 999;
 496                 }
 497
 498                 self.items = 0;
 499                 if (cvar("g_start_weapon_laser") || cvar("g_lms"))
 500                 {
 501                         self.items = self.items | IT_LASER;
 502                         self.switchweapon = WEP_LASER;
 503                 }
 504                 if (cvar("g_start_weapon_shotgun") || cvar("g_lms"))
 505                 {
 506                         self.items = self.items | IT_SHOTGUN;
 507                         self.switchweapon = WEP_SHOTGUN;
 508                 }
 509                 if (cvar("g_start_weapon_uzi") || cvar("g_lms"))
 510                 {
 511                         self.items = self.items | IT_UZI;
 512                         self.switchweapon = WEP_UZI;
 513                 }
 514                 if (cvar("g_start_weapon_grenadelauncher") || cvar("g_lms"))
 515                 {
 516                         self.items = self.items | IT_GRENADE_LAUNCHER;
 517                         self.switchweapon = WEP_GRENADE_LAUNCHER;
 518                 }
 519                 if (cvar("g_start_weapon_electro") || cvar("g_lms"))
 520                 {
 521                         self.items = self.items | IT_ELECTRO;
 522                         self.switchweapon = WEP_ELECTRO;
 523                 }
 524                 if (cvar("g_start_weapon_crylink") || cvar("g_lms"))
 525                 {
 526                         self.items = self.items | IT_CRYLINK;
 527                         self.switchweapon = WEP_CRYLINK;
 528                 }
 529                 if (cvar("g_start_weapon_nex") || cvar("g_lms"))
 530                 {
 531                         self.items = self.items | IT_NEX;
 532                         self.switchweapon = WEP_NEX;
 533                 }
 534                 if (cvar("g_start_weapon_hagar") || cvar("g_lms"))
 535                 {
 536                         self.items = self.items | IT_HAGAR;
 537                         self.switchweapon = WEP_HAGAR;
 538                 }
 539                 if (cvar("g_start_weapon_rocketlauncher") || cvar("g_lms"))
 540                 {
 541                         self.items = self.items | IT_ROCKET_LAUNCHER;
 542                         self.switchweapon = WEP_ROCKET_LAUNCHER;
 543                 }
 544
 545                 if(cvar("g_instagib"))
 546                 {
 547                         self.items = IT_NEX;
 548                         self.switchweapon = WEP_NEX;
 549                         self.ammo_cells = 999;
 550                 }
 551
 552                 if(cvar("g_rocketarena"))
 553                 {
 554                         self.items = IT_ROCKET_LAUNCHER;
 555                         self.switchweapon = WEP_ROCKET_LAUNCHER;
 556                         self.ammo_rockets = 999;
 557                 }
 558
 559                 if(cvar("g_nixnex"))
 560                 {
 561                         self.items = 0;
 562                         // will be done later
 563                 }
 564
 565                 if(cvar("g_minstagib"))
 566                 {
 567                         self.health = 100;
 568                         self.armorvalue = 0;
 569                         self.items = IT_NEX;
 570                         self.switchweapon = WEP_NEX;
 571                         self.ammo_cells = cvar("g_minstagib_ammo_start");
 572                         self.extralives = 0;
 573                         self.jump_interval = time;
 574                 }
 575
 576                 if(cvar("g_arena"))
 577                 {
 578                         Spawnqueue_Remove(self);
 579                         Spawnqueue_Mark(self);
 580                 }
 581
 582                 self.event_damage = PlayerDamage;
 583
 584                 self.bot_attack = TRUE;
 585
 586                 self.statdraintime = time + 5;
 587                 self.button0 = self.button1 = self.button2 = self.button3 = 0;
 588
 589                 if(self.killcount == -666) {
 590                         self.killcount = 0;
 591                         if(!cvar("g_arena"))
 592                         if(!cvar("g_lms"))
 593                                 self.frags = 0;
 594                 }
 595
 596                 self.cnt = WEP_LASER;
 597                 self.nixnex_lastchange_id = -1;
 598
 599                 CL_SpawnWeaponentity();
 600                 self.alpha = default_player_alpha;
 601                 self.exteriorweaponentity.alpha = default_player_alpha;
 602
 603                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval")*2;
 604                 self.lms_traveled_distance = 0;
 605
 606                 if(cvar("spawn_debug"))
 607                 {
 608                                 sprint(self, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 609                                 remove(spot);   // usefull for checking if there are spawnpoints, that let drop through the floor
 610                 }
 611
 612                 //stuffcmd(self, "chase_active 0");
 613                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
 614         } else if(self.classname == "observer") {
 615                 PutObserverInServer ();
 616         }
 617 }
 618
 619 /*
 620 =============
 621 SetNewParms
 622 =============
 623 */
 624 void SetNewParms (void)
 625 {
 626
 627 }
 628
 629 /*
 630 =============
 631 SetChangeParms
 632 =============
 633 */
 634 void SetChangeParms (void)
 635 {
 636
 637 }
 638
 639 /*
 640 =============
 641 ClientKill
 642
 643 Called when a client types 'kill' in the console
 644 =============
 645 */
 646 void ClientKill (void)
 647 {
 648         Damage(self, self, self, 100000, DEATH_KILL, self.origin, '0 0 0');
 649 }
 650
 651 /*
 652 =============
 653 ClientConnect
 654
 655 Called when a client connects to the server
 656 =============
 657 */
 658 string ColoredTeamName(float t);
 659 //void dom_player_join_team(entity pl);
 660 void ClientConnect (void)
 661 {
 662         local float fh;
 663         local string s;
 664
 665         self.classname = "player_joining";
 666         self.flags = self.flags | FL_CLIENT;
 667
 668         if(player_count<0) player_count = 0;
 669
 670         bot_clientconnect();
 671
 672         //if(cvar("g_domination"))
 673         //      dom_player_join_team(self);
 674
 675         //JoinBestTeam(self, FALSE);
 676
 677         if((cvar("sv_spectate") == 1 && !cvar("g_lms")) || cvar("g_campaign")) {
 678                 self.classname = "observer";
 679         } else {
 680                 self.classname = "player";
 681                 campaign_bots_may_start = 1;
 682         }
 683
 684         self.playerid = (playerid_last = playerid_last + 1);
 685         if(cvar("sv_eventlog"))
 686         {
 687                 if(clienttype(self) == CLIENTTYPE_REAL)
 688                         s = "player";
 689                 else
 690                         s = "bot";
 691                 GameLogEcho(strcat(":join:", ftos(self.playerid), ":", s, ":", self.netname), TRUE);
 692                 s = strcat(":team:", ftos(self.playerid), ":");
 693                 s = strcat(s, ftos(self.team));
 694                 GameLogEcho(s, FALSE);
 695         }
 696
 697         //stuffcmd(self, "set tmpviewsize $viewsize \n");
 698
 699         bprint ("^4",self.netname);
 700         bprint ("^4 connected");
 701
 702         if(cvar("g_domination") || cvar("g_ctf"))
 703         {
 704                 bprint(" and joined the ");
 705                 bprint(ColoredTeamName(self.team));
 706         }
 707
 708         bprint("\n");
 709
 710         self.welcomemessage_time = time + cvar("welcome_message_time");
 711         self.welcomemessage_time2 = 0;
 712
 713         // the client might not have his maps/%s.cfg file yet!
 714         // so send the one from the server...
 715         fh = fopen(strcat("maps/", mapname, ".cfg"), FILE_READ);
 716         if(fh >= 0)
 717         {
 718                 while((s = fgets(fh)))
 719                         stuffcmd(self, strcat(s, "\n"));
 720                 fclose(fh);
 721         }
 722         // and then execute the client's so he can still override CD tracks
 723         stuffcmd(self, strcat("exec maps/", mapname, ".cfg\n"));
 724
 725         // TODO: is this being used for anything else than cd tracks?
 726         // Remember: SVC_CDTRACK exists. Maybe it should be used.
 727
 728         // send prediction settings to the client
 729         stuffcmd(self, strcat("cl_movement_accelerate ", ftos(cvar("sv_accelerate")), "\n"));
 730         stuffcmd(self, strcat("cl_movement_friction ", ftos(cvar("sv_friction")), "\n"));
 731         stuffcmd(self, strcat("cl_movement_maxspeed ", ftos(cvar("sv_maxspeed")), "\n"));
 732         stuffcmd(self, strcat("cl_movement_airaccelerate ", ftos(cvar("sv_airaccelerate")), "\n"));
 733         stuffcmd(self, strcat("cl_movement_maxairspeed ", ftos(cvar("sv_maxairspeed")), "\n"));
 734         stuffcmd(self, strcat("cl_movement_stopspeed ", ftos(cvar("sv_stopspeed")), "\n"));
 735         stuffcmd(self, strcat("cl_movement_jumpvelocity ", ftos(cvar("g_balance_jumpheight")), "\n"));
 736         stuffcmd(self, strcat("cl_movement_stepheight ", ftos(cvar("sv_stepheight")), "\n"));
 737         stuffcmd(self, strcat("set cl_movement_friction_on_land ", ftos(cvar("sv_friction_on_land")), "\n"));
 738         stuffcmd(self, strcat("set cl_movement_airaccel_qw ", ftos(cvar("sv_airaccel_qw")), "\n"));
 739         stuffcmd(self, strcat("set cl_movement_airaccel_sideways_friction ", ftos(cvar("sv_airaccel_sideways_friction")), "\n"));
 740         stuffcmd(self, strcat("cl_movement_edgefriction 0\n"));
 741         // Wazat's grappling hook
 742         SetGrappleHookBindings();
 743
 744         // get autoswitch state from player
 745         stuffcmd(self, "alias autoswitch \"set cl_autoswitch $1; cmd autoswitch $1\"\n");
 746         stuffcmd(self, "cmd autoswitch $cl_autoswitch\n");
 747
 748         // get version info from player
 749         stuffcmd(self, "cmd clientversion $gameversion\n");
 750
 751         // get other cvars from player
 752         GetCvars(0);
 753
 754         // set cvar for team scoreboard
 755         if (teams_matter)
 756         {
 757                 local float t;
 758                 t = cvar("teamplay");
 759                 // we have to stuff the correct teamplay value because if this is a listen server, this changes the teamplay mode of the server itself, which is bad
 760                 stuffcmd(self, strcat("set teamplay ", ftos(t), "\n"));
 761         }
 762         else
 763                 stuffcmd(self, strcat("set teamplay 0\n"));
 764
 765         if(cvar("g_lms"))
 766         {
 767                 self.frags = cvar("fraglimit");
 768                 // no fraglimit was set, so player gets 999 lives
 769                 if(self.frags < 1)
 770                         self.frags = 999;
 771
 772                 // disallow player to join after the worst player has lost g_lms_last_join lives
 773                 // if "g_lms_join_anytime" new players spawn with same amount of lives as the worst active player
 774                 if(((cvar("fraglimit") - cvar("g_lms_last_join")) > lms_lowest_lives && !cvar("g_lms_join_anytime")) || lms_lowest_lives < 1)
 775                 {
 776                         self.frags = -666;
 777                         lms_dead_count += 1;
 778                 }
 779                 else if(cvar("fraglimit") > lms_lowest_lives)
 780                 {
 781                         self.frags = lms_lowest_lives;
 782                 }
 783         }
 784         else if(cvar("g_arena"))
 785         {
 786                 self.classname = "observer";
 787                 Spawnqueue_Insert(self);
 788         }
 789
 790         bot_relinkplayerlist();
 791
 792         self.jointime = time;
 793 }
 794
 795 /*
 796 =============
 797 ClientDisconnect
 798
 799 Called when a client disconnects from the server
 800 =============
 801 */
 802 void(entity e) DropFlag;
 803 .entity chatbubbleentity;
 804 .entity teambubbleentity;
 805 void ClientDisconnect (void)
 806 {
 807         float save;
 808         if(cvar("sv_eventlog"))
 809                 GameLogEcho(strcat(":part:", ftos(self.playerid)), FALSE);
 810         bprint ("^4",self.netname);
 811         bprint ("^4 disconnected\n");
 812
 813         if (self.chatbubbleentity)
 814         {
 815                 remove (self.chatbubbleentity);
 816                 self.chatbubbleentity = world;
 817         }
 818
 819         if (self.teambubbleentity)
 820         {
 821                 remove (self.teambubbleentity);
 822                 self.teambubbleentity = world;
 823         }
 824
 825         DropAllRunes(self);
 826
 827         if(self.flagcarried)
 828                 DropFlag(self.flagcarried);
 829
 830         save = self.flags;
 831         self.flags = self.flags - (self.flags & FL_CLIENT);
 832         bot_relinkplayerlist();
 833         self.flags = save;
 834
 835         // remove laserdot
 836         remove(self.weaponentity.lasertarget);
 837
 838         // player was dead, decrease dead count
 839         if(cvar("g_lms") && self.frags < 1)
 840                 lms_dead_count -= 1;
 841         else if(cvar("g_arena"))
 842         {
 843                 Spawnqueue_Unmark(self);
 844                 Spawnqueue_Remove(self);
 845         }
 846 }
 847
 848 .float buttonchat;
 849 void() ChatBubbleThink =
 850 {
 851         self.nextthink = time;
 852         if (!self.owner.modelindex || self.owner.chatbubbleentity != self)
 853         {
 854                 self.owner.chatbubbleentity = world;
 855                 remove(self);
 856                 return;
 857         }
 858         setorigin(self, self.owner.origin + '0 0 15' + self.owner.maxs_z * '0 0 1');
 859         if (self.owner.buttonchat && !self.owner.deadflag)
 860                 self.model = self.mdl;
 861         else
 862                 self.model = "";
 863 };
 864
 865 void() UpdateChatBubble =
 866 {
 867         if (!self.modelindex)
 868                 return;
 869         // spawn a chatbubble entity if needed
 870         if (!self.chatbubbleentity)
 871         {
 872                 self.chatbubbleentity = spawn();
 873                 self.chatbubbleentity.owner = self;
 874                 self.chatbubbleentity.exteriormodeltoclient = self;
 875                 self.chatbubbleentity.think = ChatBubbleThink;
 876                 self.chatbubbleentity.nextthink = time;
 877                 setmodel(self.chatbubbleentity, "models/misc/chatbubble.spr");
 878                 setorigin(self.chatbubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
 879                 self.chatbubbleentity.mdl = self.chatbubbleentity.model;
 880                 self.chatbubbleentity.model = "";
 881         }
 882 }
 883
 884
 885 void() TeamBubbleThink =
 886 {
 887         self.nextthink = time;
 888         if (!self.owner.modelindex || self.owner.teambubbleentity != self)
 889         {
 890                 self.owner.teambubbleentity = world;
 891                 remove(self);
 892                 return;
 893         }
 894 //      setorigin(self, self.owner.origin + '0 0 15' + self.owner.maxs_z * '0 0 1');  // bandwidth hog. setattachment does this now
 895         if (self.owner.buttonchat || self.owner.deadflag)
 896                 self.model = "";
 897         else
 898                 self.model = self.mdl;
 899
 900 };
 901
 902 float() ChatBubble_customizeentityforclient = {return (self.owner.team == other.team && other.killcount > -666);};
 903
 904 void() UpdateTeamBubble =
 905 {
 906         if (!self.modelindex || !cvar("teamplay"))
 907                 return;
 908         // spawn a teambubble entity if needed
 909         if (!self.teambubbleentity && cvar("teamplay"))
 910         {
 911                 self.teambubbleentity = spawn();
 912                 self.teambubbleentity.owner = self;
 913                 self.teambubbleentity.exteriormodeltoclient = self;
 914                 self.teambubbleentity.think = TeamBubbleThink;
 915                 self.teambubbleentity.nextthink = time;
 916                 setmodel(self.teambubbleentity, "models/misc/teambubble.spr");
 917 //              setorigin(self.teambubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
 918                 setorigin(self.teambubbleentity, self.teambubbleentity.origin + '0 0 15' + self.maxs_z * '0 0 1');
 919                 setattachment(self.teambubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
 920                 self.teambubbleentity.mdl = self.teambubbleentity.model;
 921                 self.teambubbleentity.model = self.teambubbleentity.mdl;
 922                 self.teambubbleentity.customizeentityforclient = ChatBubble_customizeentityforclient;
 923         }
 924 }
 925
 926 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
 927 // added to the model skins
 928 /*void() UpdateColorModHack =
 929 {
 930         local float c;
 931         c = self.clientcolors & 15;
 932         // LordHavoc: only bothering to support white, green, red, yellow, blue
 933              if (teamplay == 0) self.colormod = '0 0 0';
 934         else if (c ==  0) self.colormod = '1.00 1.00 1.00';
 935         else if (c ==  3) self.colormod = '0.10 1.73 0.10';
 936         else if (c ==  4) self.colormod = '1.73 0.10 0.10';
 937         else if (c == 12) self.colormod = '1.22 1.22 0.10';
 938         else if (c == 13) self.colormod = '0.10 0.10 1.73';
 939         else self.colormod = '1 1 1';
 940 };*/
 941
 942 /*
 943 =============
 944 PlayerJump
 945
 946 When you press the jump key
 947 =============
 948 */
 949 void PlayerJump (void)
 950 {
 951         float mjumpheight;
 952
 953         mjumpheight = cvar("g_balance_jumpheight");
 954         if (self.waterlevel >= 2)
 955         {
 956                 if (self.watertype == CONTENT_WATER)
 957                         self.velocity_z = 200;
 958                 else if (self.watertype == CONTENT_SLIME)
 959                         self.velocity_z = 80;
 960                 else
 961                         self.velocity_z = 50;
 962
 963                 return;
 964         }
 965
 966
 967         if (!(self.flags & FL_ONGROUND))
 968                 return;
 969
 970         if (!(self.flags & FL_JUMPRELEASED))
 971                 return;
 972
 973         if(cvar("g_runematch"))
 974         {
 975                 if(self.runes & RUNE_SPEED)
 976                 {
 977                         if(self.runes & CURSE_SLOW)
 978                                 mjumpheight = mjumpheight * cvar("g_balance_rune_speed_combo_jumpheight");
 979                         else
 980                                 mjumpheight = mjumpheight * cvar("g_balance_rune_speed_jumpheight");
 981                 }
 982                 else if(self.runes & CURSE_SLOW)
 983                 {
 984                         mjumpheight = mjumpheight * cvar("g_balance_curse_slow_jumpheight");
 985                 }
 986         }
 987
 988         if(cvar("g_minstagib") && (self.items & IT_INVINCIBLE))
 989         {
 990                 mjumpheight = mjumpheight * cvar("g_balance_rune_speed_jumpheight");
 991         }
 992
 993         self.velocity_z = self.velocity_z + mjumpheight;
 994         self.oldvelocity_z = self.velocity_z;
 995
 996         self.flags = self.flags - FL_ONGROUND;
 997         self.flags = self.flags - FL_JUMPRELEASED;
 998 }
 999
1000 void() CheckWaterJump =
1001 {
1002         local vector start, end;
1003
1004 // check for a jump-out-of-water
1005         makevectors (self.angles);
1006         start = self.origin;
1007         start_z = start_z + 8;
1008         v_forward_z = 0;
1009         normalize(v_forward);
1010         end = start + v_forward*24;
1011         traceline (start, end, TRUE, self);
1012         if (trace_fraction < 1)
1013         {       // solid at waist
1014                 start_z = start_z + self.maxs_z - 8;
1015                 end = start + v_forward*24;
1016                 self.movedir = trace_plane_normal * -50;
1017                 traceline (start, end, TRUE, self);
1018                 if (trace_fraction == 1)
1019                 {       // open at eye level
1020                         self.flags = self.flags | FL_WATERJUMP;
1021                         self.velocity_z = 225;
1022                         self.flags = self.flags - (self.flags & FL_JUMPRELEASED);
1023                         self.teleport_time = time + 2;  // safety net
1024                         return;
1025                 }
1026         }
1027 };
1028
1029
1030 void respawn(void)
1031 {
1032         CopyBody(1);
1033         PutClientInServer();
1034 }
1035
1036 void player_powerups (void)
1037 {
1038         if (cvar("g_minstagib"))
1039         {
1040                 self.effects = EF_FULLBRIGHT;
1041                 if (self.items & IT_STRENGTH)
1042                 {
1043                         if (time > self.strength_finished)
1044                         {
1045                                 self.alpha = default_player_alpha;
1046                                 self.exteriorweaponentity.alpha = default_player_alpha;
1047                                 self.items = self.items - (self.items & IT_STRENGTH);
1048                                 sprint(self, "^3Invisibility has worn off\n");
1049                         }
1050                 }
1051                 else
1052                 {
1053                         if (time < self.strength_finished)
1054                         {
1055                                 self.alpha = cvar("g_minstagib_invis_alpha");
1056                                 self.exteriorweaponentity.alpha = cvar("g_minstagib_invis_alpha");
1057                                 self.items = self.items | IT_STRENGTH;
1058                                 sprint(self, "^3You are invisible\n");
1059                         }
1060                 }
1061
1062                 if (self.items & IT_INVINCIBLE)
1063                 {
1064                         if (time > self.invincible_finished)
1065                         {
1066                                 self.items = self.items - (self.items & IT_INVINCIBLE);
1067                                 sprint(self, "^3Speed has worn off\n");
1068                         }
1069                 }
1070                 else
1071                 {
1072                         if (time < self.invincible_finished)
1073                         {
1074                                 self.items = self.items | IT_INVINCIBLE;
1075                                 sprint(self, "^3You are on speed\n");
1076                         }
1077                 }
1078                 return;
1079         }
1080
1081         self.effects = self.effects - (self.effects & (EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT));
1082         if (self.items & IT_STRENGTH)
1083         {
1084                 self.effects = self.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1085                 if (time > self.strength_finished)
1086                 {
1087                         self.items = self.items - (self.items & IT_STRENGTH);
1088                         sprint(self, "^3Strength has worn off\n");
1089                 }
1090         }
1091         else
1092         {
1093                 if (time < self.strength_finished)
1094                 {
1095                         self.items = self.items | IT_STRENGTH;
1096                         sprint(self, "^3Strength infuses your weapons with devastating power\n");
1097                 }
1098         }
1099         if (self.items & IT_INVINCIBLE)
1100         {
1101                 self.effects = self.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1102                 if (time > self.invincible_finished)
1103                 {
1104                         self.items = self.items - (self.items & IT_INVINCIBLE);
1105                         sprint(self, "^3Shield has worn off\n");
1106                 }
1107         }
1108         else
1109         {
1110                 if (time < self.invincible_finished)
1111                 {
1112                         self.items = self.items | IT_INVINCIBLE;
1113                         sprint(self, "^3Shield surrounds you\n");
1114                 }
1115         }
1116
1117         if (cvar("g_fullbrightplayers"))
1118                 self.effects = self.effects | EF_FULLBRIGHT;
1119
1120         // midair gamemode: damage only while in the air
1121         // if in midair mode, being on ground grants temporary invulnerability
1122         // (this is so that multishot weapon don't clear the ground flag on the
1123         // first damage in the frame, leaving the player vulnerable to the
1124         // remaining hits in the same frame)
1125         if (self.flags & FL_ONGROUND)
1126         if (cvar("g_midair"))
1127                 self.spawnshieldtime = max(self.spawnshieldtime, time + cvar("g_midair_shieldtime"));
1128
1129         if (time < self.spawnshieldtime)
1130                 self.effects = self.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1131 }
1132
1133 void player_regen (void)
1134 {
1135         float maxh, maxa, limith, limita, max_mod, regen_mod, rot_mod, limit_mod;
1136         maxh = cvar("g_balance_health_stable");
1137         maxa = cvar("g_balance_armor_stable");
1138         limith = cvar("g_balance_health_limit");
1139         limita = cvar("g_balance_armor_limit");
1140
1141         if (cvar("g_minstagib") || (cvar("g_lms") && !cvar("g_lms_regenerate")))
1142                 return;
1143
1144         if(cvar("g_runematch"))
1145         {
1146                 max_mod = regen_mod = rot_mod = limit_mod = 1;
1147                 if (self.runes & RUNE_REGEN)
1148                 {
1149                         if (self.runes & CURSE_VENOM) // do we have both rune/curse?
1150                         {
1151                                 regen_mod = cvar("g_balance_rune_regen_combo_regenrate");
1152                                 max_mod = cvar("g_balance_rune_regen_combo_hpmod");
1153                                 limit_mod = cvar("g_balance_rune_regen_combo_limitmod");
1154                         }
1155                         else
1156                         {
1157                                 regen_mod = cvar("g_balance_rune_regen_regenrate");
1158                                 max_mod = cvar("g_balance_rune_regen_hpmod");
1159                                 limit_mod = cvar("g_balance_rune_regen_limitmod");
1160                         }
1161                 }
1162                 else if (self.runes & CURSE_VENOM)
1163                 {
1164                         max_mod = cvar("g_balance_curse_venom_hpmod");
1165                         if (self.runes & RUNE_REGEN) // do we have both rune/curse?
1166                                 rot_mod = cvar("g_balance_rune_regen_combo_rotrate");
1167                         else
1168                                 rot_mod = cvar("g_balance_curse_venom_rotrate");
1169                         limit_mod = cvar("g_balance_curse_venom_limitmod");
1170                         //if (!self.runes & RUNE_REGEN)
1171                         //      rot_mod = cvar("g_balance_curse_venom_rotrate");
1172                 }
1173                 maxh = maxh * max_mod;
1174                 //maxa = maxa * max_mod;
1175
1176                 if (time > self.pauserotarmor_finished)
1177                 {
1178                         if (self.armorvalue > maxa)
1179                                 self.armorvalue = bound(0, self.armorvalue + (maxa - self.armorvalue) * cvar("g_balance_armor_rot") * frametime, 1000);
1180                 }
1181                 if (time > self.pauserothealth_finished)
1182                 {
1183                         if (self.health > maxh)
1184                                 self.health = bound(0, self.health + (maxh - self.health) * rot_mod*cvar("g_balance_health_rot") * frametime, 1000);
1185                 }
1186                 if (time > self.pauseregen_finished)
1187                 {
1188                         if (self.health < maxh)
1189                                 self.health = bound(0, self.health + (maxh- self.health) * regen_mod*cvar("g_balance_health_regen") * frametime  + 0.001, 1000);
1190                         if (self.armorvalue < maxa)
1191                                 self.armorvalue = bound(0, self.armorvalue + (maxa - self.armorvalue) * cvar("g_balance_armor_regen") * frametime  + 0.001, 1000);
1192                 }
1193         }
1194         else
1195         {
1196                 if (time > self.pauserothealth_finished)
1197                 if (self.health > maxh)
1198                         self.health = bound(0, self.health + (maxh - self.health) * cvar("g_balance_health_rot") * frametime, 1000);
1199                 if (time > self.pauserotarmor_finished)
1200                 if (self.armorvalue > maxa)
1201                         self.armorvalue = bound(0, self.armorvalue + (maxa - self.armorvalue) * cvar("g_balance_armor_rot") * frametime, 1000);
1202                 if (time > self.pauseregen_finished)
1203                 {
1204                         if (self.health < maxh)
1205                                  self.health = bound(0, self.health + (maxh - self.health) * cvar("g_balance_health_regen") * frametime + 0.001, 1000);
1206                         if (self.armorvalue < maxa)
1207                                 self.armorvalue = bound(0, self.armorvalue + (maxa - self.armorvalue) * cvar("g_balance_armor_regen") * frametime + 0.001, 1000);
1208                 }
1209         }
1210
1211         if (self.health > limith)
1212                 self.health = limith;
1213         if(self.health < 1)
1214                 self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
1215         if (self.armorvalue > limita)
1216                 self.armorvalue = limita;
1217 }
1218
1219 /*
1220 ======================
1221 spectate mode routines
1222 ======================
1223 */
1224 void SpectateCopy(entity spectatee) {
1225         self.armortype = spectatee.armortype;
1226         self.armorvalue = spectatee.armorvalue;
1227         self.currentammo = spectatee.currentammo;
1228         self.effects = spectatee.effects;
1229         self.health = spectatee.health;
1230         self.impulse = 0;
1231         self.items = spectatee.items;
1232         self.punchangle = spectatee.punchangle;
1233         self.view_ofs = spectatee.view_ofs;
1234         self.v_angle = spectatee.v_angle;
1235         self.viewzoom = spectatee.viewzoom;
1236         setorigin(self, spectatee.origin);
1237         setsize(self, spectatee.mins, spectatee.maxs);
1238 }
1239
1240 void SpectateUpdate() {
1241         if(!self.enemy)
1242                         PutObserverInServer();
1243
1244         if (self != self.enemy) {
1245                 if(self.enemy.flags & FL_NOTARGET)
1246                         PutObserverInServer();
1247                 SpectateCopy(self.enemy);
1248                 self.dmg_take = self.enemy.dmg_take;
1249                 self.dmg_save = self.enemy.dmg_save;
1250                 self.dmg_inflictor = self.enemy.dmg_inflictor;
1251                 self.fixangle = TRUE;
1252                 self.angles = self.enemy.v_angle;
1253                 //msg_entity = self;
1254                 //WriteByte(MSG_ONE, SVC_SETANGLE);
1255                 //WriteAngle(MSG_ONE, self.enemy.v_angle_x);
1256                 //WriteAngle(MSG_ONE, self.enemy.v_angle_y);
1257                 //WriteAngle(MSG_ONE, self.enemy.v_angle_z);
1258         }
1259 }
1260
1261 float SpectateNext() {
1262         other = find(self.enemy, classname, "player");
1263         if (!other) {
1264                 other = find(other, classname, "player");
1265         }
1266         if (other) {
1267                 self.enemy = other;
1268         }
1269         if(self.enemy.classname == "player") {
1270                 msg_entity = self;
1271                 WriteByte(MSG_ONE, SVC_SETVIEW);
1272                 WriteEntity(MSG_ONE, self.enemy);
1273                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
1274                 SpectateUpdate();
1275                 return 1;
1276         } else {
1277                 return 0;
1278         }
1279 }
1280
1281 /*
1282 =============
1283 PlayerPreThink
1284
1285 Called every frame for each client before the physics are run
1286 =============
1287 */
1288 void PlayerPreThink (void)
1289 {
1290         if(self.classname == "player") {
1291                 local vector m1, m2;
1292
1293 //              if(self.netname == "Wazat")
1294 //                      bprint(strcat(self.classname, "\n"));
1295
1296                 CheckRules_Player();
1297
1298                 Nixnex_GiveCurrentWeapon();
1299
1300                 if(self.button7)
1301                         PrintWelcomeMessage(self);
1302
1303                 if(cvar("g_lms") || !cvar("sv_spectate"))
1304                 if((time - self.jointime) <= cvar("welcome_message_time"))
1305                         PrintWelcomeMessage(self);
1306
1307                 if (intermission_running)
1308                 {
1309                         IntermissionThink ();   // otherwise a button could be missed between
1310                         return;                                 // the think tics
1311                 }
1312
1313                 if (self.deadflag != DEAD_NO)
1314                 {
1315                         player_anim();
1316                         if (self.deadflag == DEAD_DYING)
1317                         {
1318                                 if (time > self.dead_time)
1319                                         self.deadflag = DEAD_DEAD;
1320                         }
1321                         else if (self.deadflag == DEAD_DEAD)
1322                         {
1323                                 if (cvar("g_lms") || cvar("g_arena") || cvar("g_forced_respawn"))
1324                                         self.deadflag = DEAD_RESPAWNABLE;
1325                                 else if (!self.button0 && !self.button2 && !self.button3)
1326                                         self.deadflag = DEAD_RESPAWNABLE;
1327                         }
1328                         else if (self.deadflag == DEAD_RESPAWNABLE)
1329                         {
1330                                 if (self.button0  ||
1331                                     self.button2  ||
1332                                     self.button3  ||
1333                                     self.button4  ||
1334                                     self.button5  ||
1335                                     self.button6  ||
1336                                     self.button7  ||
1337                                     self.button8  ||
1338                                     self.buttonuse ||
1339                                     cvar("g_lms") ||
1340                                     cvar("g_forced_respawn"))
1341                                         respawn();
1342                         }
1343                         return;
1344                 }
1345
1346                 if(cvar("g_lms") && !self.deadflag && cvar("g_lms_campcheck_interval"))
1347                 {
1348                         vector dist;
1349
1350                         // calculate player movement (in 2 dimensions only, so jumping on one spot doesn't count as movement)
1351                         dist = self.oldorigin - self.origin;
1352                         dist_z = 0;
1353                         self.lms_traveled_distance += fabs(vlen(dist));
1354
1355                         if(cvar("g_campaign"))
1356                         if(!campaign_bots_may_start)
1357                         {
1358                                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval")*2;
1359                                 self.lms_traveled_distance = 0;
1360                         }
1361
1362                         if(time > self.lms_nextcheck)
1363                         {
1364                                 //sprint(self, "distance: ", ftos(self.lms_traveled_distance), "\n");
1365                                 if(self.lms_traveled_distance < cvar("g_lms_campcheck_distance"))
1366                                 {
1367                                         centermsg_set(CENTERMSG_CAMP, cvar_string("g_lms_campcheck_message"));
1368                                         // FIXME KadaverJack: gibbing player here causes playermodel to bounce around, instead of eye.md3
1369                                         // I wasn't able to find out WHY that happens, so I put a workaround in place that shall prevent players from being gibbed :(
1370                                         Damage(self, self, self, bound(0, cvar("g_lms_campcheck_damage"), self.health + self.armorvalue * cvar("g_balance_armor_blockpercent") + 5), DEATH_CAMP, self.origin, '0 0 0');
1371                                 }
1372                                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval");
1373                                 self.lms_traveled_distance = 0;
1374                         }
1375                 }
1376
1377                 if (self.button5 && !self.hook.state)
1378                 {
1379                         if (!self.crouch)
1380                         {
1381                                 self.crouch = TRUE;
1382                                 self.view_ofs = PL_CROUCH_VIEW_OFS;
1383                                 setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX);
1384                         }
1385                 }
1386                 else
1387                 {
1388                         if (self.crouch)
1389                         {
1390                                 tracebox(self.origin, PL_MIN, PL_MAX, self.origin, FALSE, self);
1391                                 if (!trace_startsolid)
1392                                 {
1393                                         self.crouch = FALSE;
1394                                         self.view_ofs = PL_VIEW_OFS;
1395                                         setsize (self, PL_MIN, PL_MAX);
1396                                 }
1397                         }
1398                 }
1399
1400                 if(cvar("sv_defaultcharacter") == 1 && !teams_matter) {
1401                         local string defaultmodel;
1402                         defaultmodel = CheckPlayerModel(cvar_string("sv_defaultplayermodel"));
1403
1404                         if (defaultmodel != self.model)
1405                         {
1406                                 m1 = self.mins;
1407                                 m2 = self.maxs;
1408                                 setmodel_lod (self, defaultmodel);
1409                                 setsize (self, m1, m2);
1410                         }
1411
1412                         if (self.skin != cvar("sv_defaultplayerskin"))
1413                                 self.skin = cvar("sv_defaultplayerskin");
1414                 } else {
1415                         if (self.playermodel != self.model)
1416                         {
1417                                 self.playermodel = CheckPlayerModel(self.playermodel);
1418                                 m1 = self.mins;
1419                                 m2 = self.maxs;
1420                                 setmodel_lod (self, self.playermodel);
1421                                 setsize (self, m1, m2);
1422                         }
1423
1424                         if (self.skin != stof(self.playerskin))
1425                                 self.skin = stof(self.playerskin);
1426                 }
1427                 // Savage: Check for nameless players
1428                 if (strlen(self.netname) < 1) {
1429                         self.netname = "Player";
1430                         stuffcmd(self, "name Player\n");
1431                 }
1432
1433                 GrapplingHookFrame();
1434
1435                 W_WeaponFrame();
1436
1437                 if (self.button4 || (self.weapon == WEP_NEX && self.button3))
1438                 {
1439                         if (cvar("g_minstagib") && self.button3)
1440                         {
1441                                 if (self.jump_interval <= (time + 0.1))
1442                                 {
1443                                         self.jump_interval = time + 1;
1444                                         W_Laser_Attack();
1445                                 }
1446                         }
1447                         else if (self.viewzoom > 0.4)
1448                                 self.viewzoom = max (0.4, self.viewzoom - frametime * 2);
1449                 }
1450                 else if (self.viewzoom < 1.0)
1451                         self.viewzoom = min (1.0, self.viewzoom + frametime);
1452
1453
1454                 if (self.button2)
1455                         PlayerJump ();
1456                 else
1457                         self.flags = self.flags | FL_JUMPRELEASED;
1458
1459                 player_powerups();
1460                 player_regen();
1461                 player_anim();
1462
1463                 if (cvar("g_minstagib"))
1464                         minstagib_ammocheck();
1465
1466                 //self.angles_y=self.v_angle_y + 90;   // temp
1467
1468                 if (self.waterlevel == 2)
1469                         CheckWaterJump ();
1470
1471                 //if (TetrisPreFrame()) return;
1472         } else if(gameover) {
1473                 if (intermission_running)
1474                         IntermissionThink ();   // otherwise a button could be missed between
1475                 return;
1476         } else if(self.classname == "observer") {
1477
1478                 if (self.flags & FL_JUMPRELEASED) {
1479                         if (self.button2 && self.version == cvar("gameversion")) {
1480                                 if(!cvar("teamplay") || cvar("g_campaign") || cvar("g_balance_teams")) {
1481                                         self.flags = self.flags & !FL_JUMPRELEASED;
1482                                         self.classname = "player";
1483                                         if(cvar("g_campaign") || cvar("g_balance_teams"))
1484                                                 JoinBestTeam(self, 0);
1485                                         if(cvar("g_campaign"))
1486                                                 campaign_bots_may_start = 1;
1487                                         PutClientInServer();
1488                                         if(self.flags & !FL_NOTARGET)
1489                                                 bprint (strcat("^4", self.netname, "^4 is playing now\n"));
1490                                         centermsg_reset();
1491                                         return;
1492                                 } else {
1493                                         self.flags = self.flags & !FL_JUMPRELEASED;
1494                                         stuffcmd(self,"menu_showteamselect\n");
1495                                         return;
1496                                 }
1497                         } else if(self.button0 && self.version == cvar("gameversion")) {
1498                                 self.flags = self.flags & !FL_JUMPRELEASED;
1499                                 if(SpectateNext() == 1) {
1500                                         self.classname = "spectator";
1501                                 }
1502                         }
1503                 } else {
1504                         if (!(self.button0 || self.button2)) {
1505                                 self.flags = self.flags | FL_JUMPRELEASED;
1506                         }
1507                 }
1508                 PrintWelcomeMessage(self);
1509         } else if(self.classname == "spectator") {
1510                 if (self.flags & FL_JUMPRELEASED) {
1511                         if (self.button2 && self.version == cvar("gameversion")) {
1512                                 if(!cvar("teamplay") || cvar("g_campaign") || cvar("g_balance_teams")) {
1513                                         self.flags = self.flags & !FL_JUMPRELEASED;
1514                                         self.classname = "player";
1515                                         if(!cvar("g_lms"))
1516                                                 bprint (strcat("^4", self.netname, "^4 is playing now\n"));
1517
1518                                         if(cvar("g_campaign") || cvar("g_balance_teams"))
1519                                                 JoinBestTeam(self, 0);
1520                                         if(cvar("g_campaign"))
1521                                                 campaign_bots_may_start = 1;
1522                                         PutClientInServer();
1523                                         centermsg_reset();
1524                                         return;
1525                                 } else {
1526                                         self.flags = self.flags & !FL_JUMPRELEASED;
1527                                         stuffcmd(self,"menu_showteamselect\n");
1528                                         return;
1529                                 }
1530                         } else if(self.button0) {
1531                                 self.flags = self.flags & !FL_JUMPRELEASED;
1532                                 if(SpectateNext() == 1) {
1533                                         self.classname = "spectator";
1534                                 } else {
1535                                         self.classname = "observer";
1536                                         PutClientInServer();
1537                                 }
1538                         } else if (self.button3) {
1539                                 self.flags = self.flags & !FL_JUMPRELEASED;
1540                                 self.classname = "observer";
1541                                 PutClientInServer();
1542                         } else {
1543                                 SpectateUpdate();
1544                         }
1545                 } else {
1546                         if (!(self.button0 || self.button3)) {
1547                                 self.flags = self.flags | FL_JUMPRELEASED;
1548                         }
1549                 }
1550                 PrintWelcomeMessage(self);
1551                 self.flags = self.flags | FL_CLIENT | FL_NOTARGET;
1552         }
1553 }
1554
1555
1556 /*
1557 =============
1558 PlayerPostThink
1559
1560 Called every frame for each client after the physics are run
1561 =============
1562 */
1563 void PlayerPostThink (void)
1564 {
1565         if(self.classname == "player") {
1566                 CheckRules_Player();
1567                 UpdateChatBubble();
1568                 UpdateTeamBubble();
1569                 if (self.deadflag == DEAD_NO)
1570                 if (self.impulse)
1571                         ImpulseCommands ();
1572                 if (intermission_running)
1573                         return;         // intermission or finale
1574
1575                 //PrintWelcomeMessage(self);
1576                 //if (TetrisPostFrame()) return;
1577         } else if (self.classname == "observer") {
1578                 //do nothing
1579         } else if (self.classname == "spectator") {
1580                 //do nothing
1581         }
1582         Arena_Warmup();
1583 }