data/qcsrc/server/cl_client.qc

   1 // let's abuse an existing field
   2 #define SPAWNPOINT_SCORE frags
   3
   4 .float wantswelcomemessage;
   5 .string netname_previous;
   6
   7 void spawnfunc_info_player_survivor (void)
   8 {
   9         spawnfunc_info_player_deathmatch();
  10 }
  11
  12 void spawnfunc_info_player_start (void)
  13 {
  14         spawnfunc_info_player_deathmatch();
  15 }
  16
  17 void spawnfunc_info_player_deathmatch (void)
  18 {
  19         self.classname = "info_player_deathmatch";
  20         relocate_spawnpoint();
  21 }
  22
  23 void spawnpoint_use()
  24 {
  25         if(teams_matter)
  26         if(have_team_spawns)
  27         {
  28                 self.team = activator.team;
  29                 some_spawn_has_been_used = 1;
  30         }
  31 };
  32
  33 // Returns:
  34 //   -1 if a spawn can't be used
  35 //   otherwise, a weight of the spawnpoint
  36 float Spawn_Score(entity spot, entity playerlist, float teamcheck)
  37 {
  38         float shortest, thisdist;
  39         entity player;
  40
  41         // filter out spots for the wrong team
  42         if(teamcheck)
  43         if(spot.team != teamcheck)
  44                 return -1;
  45
  46         if(race_spawns)
  47                 if(spot.target == "")
  48                         return -1;
  49
  50         // filter out spots for assault
  51         if(spot.target != "") {
  52                 local entity ent;
  53                 float good;
  54                 ent = find(world, targetname, spot.target);
  55                 while(ent) {
  56                         if(ent.classname == "target_objective")
  57                         {
  58                                 if(ent.health < 0 || ent.health >= ASSAULT_VALUE_INACTIVE)
  59                                         return -1;
  60                                 good = 1;
  61                         }
  62                         else if(ent.classname == "trigger_race_checkpoint")
  63                         {
  64                                 if(self.classname == "player") // spectators may spawn everywhere
  65                                 {
  66                                         if(ent.race_checkpoint != race_PreviousCheckpoint(self.race_checkpoint))
  67                                                 return -1;
  68                                         float pl;
  69                                         pl = self.race_place;
  70                                         if(pl > race_highest_place_spawn)
  71                                                 pl = 0;
  72                                         if(spot.race_place != pl)
  73                                                 return -1;
  74                                 }
  75                                 good = 1;
  76                         }
  77                         else
  78                         {
  79                         }
  80                         ent = find(ent, targetname, spot.target);
  81                 }
  82
  83                 if(!good)
  84                         return -1;
  85         }
  86
  87         player = playerlist;
  88         shortest = vlen(world.maxs - world.mins);
  89         for(player = playerlist; player; player = player.chain)
  90                 if (player != self)
  91                 {
  92                         thisdist = vlen(player.origin - spot.origin);
  93                         if (thisdist < shortest)
  94                                 shortest = thisdist;
  95                 }
  96         return shortest;
  97 }
  98
  99 float spawn_allbad;
 100 float spawn_allgood;
 101 entity Spawn_FilterOutBadSpots(entity firstspot, entity playerlist, float mindist, float teamcheck)
 102 {
 103         local entity spot, spotlist, spotlistend;
 104         spawn_allgood = TRUE;
 105         spawn_allbad = TRUE;
 106
 107         spotlist = world;
 108         spotlistend = world;
 109
 110         for(spot = firstspot; spot; spot = spot.chain)
 111         {
 112                 spot.SPAWNPOINT_SCORE = Spawn_Score(spot, playerlist, teamcheck);
 113
 114                 if(cvar("spawn_debugview"))
 115                 {
 116                         setmodel(spot, "models/runematch/rune.mdl");
 117                         if(spot.SPAWNPOINT_SCORE < mindist)
 118                         {
 119                                 spot.colormod = '1 0 0';
 120                                 spot.scale = 1;
 121                         }
 122                         else
 123                         {
 124                                 spot.colormod = '0 1 0';
 125                                 spot.scale = spot.SPAWNPOINT_SCORE / mindist;
 126                         }
 127                 }
 128
 129                 if(spot.SPAWNPOINT_SCORE >= 0) // spawning allowed here
 130                 {
 131                         if(spot.SPAWNPOINT_SCORE < mindist)
 132                         {
 133                                 // too short distance
 134                                 spawn_allgood = FALSE;
 135                         }
 136                         else
 137                         {
 138                                 // perfect
 139                                 spawn_allbad = FALSE;
 140
 141                                 if(spotlistend)
 142                                         spotlistend.chain = spot;
 143                                 spotlistend = spot;
 144                                 if(!spotlist)
 145                                         spotlist = spot;
 146
 147                                 /*
 148                                 if(teamcheck)
 149                                 if(spot.team != teamcheck)
 150                                         error("invalid spawn added");
 151
 152                                 print("added ", etos(spot), "\n");
 153                                 */
 154                         }
 155                 }
 156         }
 157         if(spotlistend)
 158                 spotlistend.chain = world;
 159
 160         /*
 161                 entity e;
 162                 if(teamcheck)
 163                         for(e = spotlist; e; e = e.chain)
 164                         {
 165                                 print("seen ", etos(e), "\n");
 166                                 if(e.team != teamcheck)
 167                                         error("invalid spawn found");
 168                         }
 169         */
 170
 171         return spotlist;
 172 }
 173
 174 entity Spawn_WeightedPoint(entity firstspot, float lower, float upper, float exponent)
 175 {
 176         // weight of a point: bound(lower, mindisttoplayer, upper)^exponent
 177         // multiplied by spot.cnt (useful if you distribute many spawnpoints in a small area)
 178         local entity spot;
 179
 180         RandomSelection_Init();
 181         for(spot = firstspot; spot; spot = spot.chain)
 182                 RandomSelection_Add(spot, 0, pow(bound(lower, spot.SPAWNPOINT_SCORE, upper), exponent) * spot.cnt, spot.SPAWNPOINT_SCORE >= lower);
 183
 184         return RandomSelection_chosen_ent;
 185 }
 186
 187 /*
 188 =============
 189 SelectSpawnPoint
 190
 191 Finds a point to respawn
 192 =============
 193 */
 194 entity SelectSpawnPoint (float anypoint)
 195 {
 196         local float teamcheck;
 197         local entity firstspot_new;
 198         local entity spot, firstspot, playerlist;
 199
 200         spot = find (world, classname, "testplayerstart");
 201         if (spot)
 202                 return spot;
 203
 204         teamcheck = 0;
 205
 206         if(!anypoint && have_team_spawns)
 207                 teamcheck = self.team;
 208
 209         // get the list of players
 210         playerlist = findchain(classname, "player");
 211         // get the entire list of spots
 212         firstspot = findchain(classname, "info_player_deathmatch");
 213         // filter out the bad ones
 214         // (note this returns the original list if none survived)
 215         firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, 100, teamcheck);
 216         if(!firstspot_new)
 217                 firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, -1, teamcheck);
 218         firstspot = firstspot_new;
 219
 220         // there is 50/50 chance of choosing a random spot or the furthest spot
 221         // (this means that roughly every other spawn will be furthest, so you
 222         // usually won't get fragged at spawn twice in a row)
 223         if (arena_roundbased)
 224         {
 225                 firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, 800, teamcheck);
 226                 if(firstspot_new)
 227                         firstspot = firstspot_new;
 228                 spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 229         }
 230         else if (random() > cvar("g_spawn_furthest"))
 231                 spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 232         else
 233                 spot = Spawn_WeightedPoint(firstspot, 1, 5000, 5); // chooses a far far away spawnpoint
 234
 235         if(cvar("spawn_debugview"))
 236         {
 237                 print("spot mindistance: ", ftos(spot.SPAWNPOINT_SCORE), "\n");
 238
 239                 entity e;
 240                 if(teamcheck)
 241                         for(e = firstspot; e; e = e.chain)
 242                                 if(e.team != teamcheck)
 243                                         error("invalid spawn found");
 244         }
 245
 246         if (!spot)
 247         {
 248                 if(cvar("spawn_debug"))
 249                         GotoNextMap();
 250                 else
 251                 {
 252                         if(some_spawn_has_been_used)
 253                                 return world; // team can't spawn any more, because of actions of other team
 254                         else
 255                                 error("Cannot find a spawn point - please fix the map!");
 256                 }
 257         }
 258
 259         return spot;
 260 }
 261
 262 /*
 263 =============
 264 CheckPlayerModel
 265
 266 Checks if the argument string can be a valid playermodel.
 267 Returns a valid one in doubt.
 268 =============
 269 */
 270 string FallbackPlayerModel = "models/player/marine.zym";
 271 string CheckPlayerModel(string plyermodel) {
 272         if(strlen(plyermodel) < 4)
 273                 return FallbackPlayerModel;
 274         if( substring(plyermodel,0,14) != "models/player/")
 275                 return FallbackPlayerModel;
 276         else if(cvar("sv_servermodelsonly"))
 277         {
 278                 if(substring(plyermodel,strlen(plyermodel)-4,4) != ".zym")
 279                 if(substring(plyermodel,strlen(plyermodel)-4,4) != ".dpm")
 280                 if(substring(plyermodel,strlen(plyermodel)-4,4) != ".md3")
 281                 if(substring(plyermodel,strlen(plyermodel)-4,4) != ".psk")
 282                         return FallbackPlayerModel;
 283                 if(!fexists(plyermodel))
 284                         return FallbackPlayerModel;
 285         }
 286         return plyermodel;
 287 }
 288
 289 /*
 290 =============
 291 Client_customizeentityforclient
 292
 293 LOD reduction
 294 =============
 295 */
 296 float Client_customizeentityforclient()
 297 {
 298 #ifdef ALLOW_VARIABLE_LOD
 299         // self: me
 300         // other: the player viewing me
 301         float distance;
 302         float f;
 303
 304         if(self.flags & FL_NOTARGET) // we don't need LOD for spectators
 305                 return TRUE;
 306
 307         if(other.cvar_cl_playerdetailreduction <= 0)
 308         {
 309                 if(other.cvar_cl_playerdetailreduction <= -2)
 310                         self.modelindex = self.modelindex_lod2;
 311                 else if(other.cvar_cl_playerdetailreduction <= -1)
 312                         self.modelindex = self.modelindex_lod1;
 313                 else
 314                         self.modelindex = self.modelindex_lod0;
 315         }
 316         else
 317         {
 318                 distance = vlen(self.origin - other.origin);
 319                 f = (distance + 100.0) * other.cvar_cl_playerdetailreduction;
 320                 if(f > 10000)
 321                         self.modelindex = self.modelindex_lod2;
 322                 else if(f > 5000)
 323                         self.modelindex = self.modelindex_lod1;
 324                 else
 325                         self.modelindex = self.modelindex_lod0;
 326         }
 327 #endif
 328
 329         return TRUE;
 330 }
 331
 332 void UpdatePlayerSounds();
 333 void setmodel_lod(entity e, string modelname)
 334 {
 335 #ifdef ALLOW_VARIABLE_LOD
 336         string s;
 337
 338         // FIXME: this only supports 3-letter extensions
 339         s = strcat(substring(modelname, 0, strlen(modelname) - 4), "_1", substring(modelname, 0, strlen(modelname) - 4));
 340         if(fexists(s))
 341         {
 342                 precache_model(s);
 343                 setmodel(e, s); // players have high precision
 344                 self.modelindex_lod1 = self.modelindex;
 345         }
 346         else
 347                 self.modelindex_lod1 = -1;
 348
 349         s = strcat(substring(modelname, 0, strlen(modelname) - 4), "_2", substring(modelname, 0, strlen(modelname) - 4));
 350         if(fexists(s))
 351         {
 352                 precache_model(s);
 353                 setmodel(e, s); // players have high precision
 354                 self.modelindex_lod2 = self.modelindex;
 355         }
 356         else
 357                 self.modelindex_lod2 = -1;
 358
 359         precache_model(modelname);
 360         setmodel(e, modelname); // players have high precision
 361         self.modelindex_lod0 = self.modelindex;
 362
 363         if(self.modelindex_lod1 < 0)
 364                 self.modelindex_lod1 = self.modelindex;
 365
 366         if(self.modelindex_lod2 < 0)
 367                 self.modelindex_lod2 = self.modelindex;
 368 #else
 369         precache_model(modelname);
 370         setmodel(e, modelname); // players have high precision
 371 #endif
 372         player_setupanimsformodel();
 373         UpdatePlayerSounds();
 374 }
 375
 376 /*
 377 =============
 378 PutObserverInServer
 379
 380 putting a client as observer in the server
 381 =============
 382 */
 383 void PutObserverInServer (void)
 384 {
 385         entity  spot;
 386
 387         race_PreSpawnObserver();
 388
 389         spot = SelectSpawnPoint (TRUE);
 390         if(!spot)
 391                 error("No spawnpoints for observers?!?\n");
 392         RemoveGrapplingHook(self); // Wazat's Grappling Hook
 393
 394         if(clienttype(self) == CLIENTTYPE_REAL)
 395         {
 396                 msg_entity = self;
 397                 WriteByte(MSG_ONE, SVC_SETVIEW);
 398                 WriteEntity(MSG_ONE, self);
 399         }
 400
 401         DropAllRunes(self);
 402         kh_Key_DropAll(self, TRUE);
 403
 404         if(self.flagcarried)
 405                 DropFlag(self.flagcarried);
 406
 407         WaypointSprite_PlayerDead();
 408
 409         if(self.killcount != -666)
 410         {
 411                 if(g_lms)
 412                 {
 413                         if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
 414                                 bprint ("^4", self.netname, "^4 has no more lives left\n");
 415                         else
 416                                 bprint ("^4", self.netname, "^4 is spectating now\n"); // TODO turn this into a proper forfeit?
 417                 }
 418                 else
 419                         bprint ("^4", self.netname, "^4 is spectating now\n");
 420         }
 421
 422         PlayerScore_Clear(self); // clear scores when needed
 423
 424         self.spectatortime = time;
 425
 426         self.classname = "observer";
 427         self.health = -666;
 428         self.takedamage = DAMAGE_NO;
 429         self.solid = SOLID_NOT;
 430         self.movetype = MOVETYPE_NOCLIP;
 431         self.flags = FL_CLIENT | FL_NOTARGET;
 432         self.armorvalue = 666;
 433         self.effects = 0;
 434         self.armorvalue = cvar("g_balance_armor_start");
 435         self.pauserotarmor_finished = 0;
 436         self.pauserothealth_finished = 0;
 437         self.pauseregen_finished = 0;
 438         self.damageforcescale = 0;
 439         self.death_time = 0;
 440         self.dead_frame = 0;
 441         self.alpha = 0;
 442         self.scale = 0;
 443         self.fade_time = 0;
 444         self.pain_frame = 0;
 445         self.pain_finished = 0;
 446         self.strength_finished = 0;
 447         self.invincible_finished = 0;
 448         self.pushltime = 0;
 449         self.think = SUB_Null;
 450         self.nextthink = 0;
 451         self.hook_time = 0;
 452         self.runes = 0;
 453         self.deadflag = DEAD_NO;
 454         self.angles = spot.angles;
 455         self.angles_z = 0;
 456         self.fixangle = TRUE;
 457         self.crouch = FALSE;
 458
 459         self.view_ofs = PL_VIEW_OFS;
 460         setorigin (self, spot.origin);
 461         setsize (self, '0 0 0', '0 0 0');
 462         self.oldorigin = self.origin;
 463         self.items = 0;
 464         self.model = "";
 465         self.modelindex = 0;
 466         self.weapon = 0;
 467         self.weaponmodel = "";
 468         self.weaponentity = world;
 469         self.killcount = -666;
 470         self.velocity = '0 0 0';
 471         self.avelocity = '0 0 0';
 472         self.punchangle = '0 0 0';
 473         self.punchvector = '0 0 0';
 474         self.oldvelocity = self.velocity;
 475         self.customizeentityforclient = Client_customizeentityforclient;
 476         self.viewzoom = 1;
 477         self.wantswelcomemessage = 1;
 478
 479         if(g_arena)
 480         {
 481                 if(self.version_mismatch)
 482                 {
 483                         Spawnqueue_Unmark(self);
 484                         Spawnqueue_Remove(self);
 485                 }
 486                 else
 487                 {
 488                         Spawnqueue_Insert(self);
 489                 }
 490         }
 491         else if(g_lms)
 492         {
 493                 // Only if the player cannot play at all
 494                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) == 666)
 495                         self.frags = -666;
 496                 else
 497                         self.frags = -667;
 498         }
 499         else
 500                 self.frags = -666;
 501 }
 502
 503 float RestrictSkin(float s)
 504 {
 505         if(!teams_matter)
 506                 return s;
 507         if(s == 6)
 508                 return 6;
 509         return mod(s, 3);
 510 }
 511
 512 void FixPlayermodel()
 513 {
 514         local string defaultmodel;
 515         local float defaultskin;
 516         local vector m1, m2;
 517
 518         defaultmodel = "";
 519
 520         if(cvar("sv_defaultcharacter") == 1) {
 521                 defaultskin = 0;
 522
 523                 if(teams_matter)
 524                 {
 525                         defaultmodel = cvar_string(strcat("sv_defaultplayermodel_", Team_ColorNameLowerCase(self.team)));
 526                         defaultskin = cvar(strcat("sv_defaultplayerskin_", Team_ColorNameLowerCase(self.team)));
 527                 }
 528
 529                 if(defaultmodel == "")
 530                 {
 531                         defaultmodel = cvar_string("sv_defaultplayermodel");
 532                         defaultskin = cvar("sv_defaultplayerskin");
 533                 }
 534         }
 535
 536         if(defaultmodel != "")
 537         {
 538                 if (defaultmodel != self.model)
 539                 {
 540                         m1 = self.mins;
 541                         m2 = self.maxs;
 542                         setmodel_lod (self, defaultmodel);
 543                         setsize (self, m1, m2);
 544                 }
 545
 546                 self.skin = defaultskin;
 547         } else {
 548                 if (self.playermodel != self.model)
 549                 {
 550                         self.playermodel = CheckPlayerModel(self.playermodel);
 551                         m1 = self.mins;
 552                         m2 = self.maxs;
 553                         setmodel_lod (self, self.playermodel);
 554                         setsize (self, m1, m2);
 555                 }
 556
 557                 self.skin = RestrictSkin(stof(self.playerskin));
 558         }
 559
 560         if(!teams_matter)
 561                 if(strlen(cvar_string("sv_defaultplayercolors")))
 562                         if(self.clientcolors != cvar("sv_defaultplayercolors"))
 563                                 setcolor(self, cvar("sv_defaultplayercolors"));
 564 }
 565
 566 /*
 567 =============
 568 PutClientInServer
 569
 570 Called when a client spawns in the server
 571 =============
 572 */
 573 //void() ctf_playerchanged;
 574 void PutClientInServer (void)
 575 {
 576         if(clienttype(self) == CLIENTTYPE_BOT)
 577         {
 578                 self.classname = "player";
 579         }
 580         else if(clienttype(self) == CLIENTTYPE_REAL)
 581         {
 582                 msg_entity = self;
 583                 WriteByte(MSG_ONE, SVC_SETVIEW);
 584                 WriteEntity(MSG_ONE, self);
 585         }
 586
 587         // player is dead and becomes observer
 588         // FIXME fix LMS scoring for new system
 589         if(g_lms)
 590         {
 591                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
 592                         self.classname = "observer";
 593         }
 594
 595         if(g_arena)
 596         if(!self.spawned)
 597                 self.classname = "observer";
 598
 599         if(self.classname == "player") {
 600                 entity  spot;
 601
 602                 race_PreSpawn();
 603
 604                 spot = SelectSpawnPoint (FALSE);
 605                 if(!spot)
 606                 {
 607                         centerprint(self, "Sorry, no spawnpoints available!\nHope your team can fix it...");
 608                         return; // spawn failed
 609                 }
 610
 611                 RemoveGrapplingHook(self); // Wazat's Grappling Hook
 612
 613                 self.classname = "player";
 614                 self.iscreature = TRUE;
 615                 self.movetype = MOVETYPE_WALK;
 616                 self.solid = SOLID_SLIDEBOX;
 617                 if(independent_players)
 618                         MAKE_INDEPENDENT_PLAYER(self);
 619                 self.flags = FL_CLIENT;
 620                 self.takedamage = DAMAGE_AIM;
 621                 if(g_minstagib)
 622                         self.effects = EF_FULLBRIGHT;
 623                 else
 624                         self.effects = 0;
 625                 self.air_finished = time + 12;
 626                 self.dmg = 2;
 627
 628                 self.ammo_shells = start_ammo_shells;
 629                 self.ammo_nails = start_ammo_nails;
 630                 self.ammo_rockets = start_ammo_rockets;
 631                 self.ammo_cells = start_ammo_cells;
 632                 self.health = start_health;
 633                 self.armorvalue = start_armorvalue;
 634                 self.items = start_items;
 635                 self.switchweapon = start_switchweapon;
 636                 self.cnt = start_switchweapon;
 637                 self.weapon = 0;
 638                 self.jump_interval = time;
 639
 640                 self.spawnshieldtime = time + cvar("g_spawnshieldtime");
 641                 self.pauserotarmor_finished = time + cvar("g_balance_pause_armor_rot_spawn");
 642                 self.pauserothealth_finished = time + cvar("g_balance_pause_health_rot_spawn");
 643                 self.pauseregen_finished = time + cvar("g_balance_pause_health_regen_spawn");
 644                 //extend the pause of rotting if client was reset at the beginning of the countdown
 645                 if(!cvar("sv_ready_restart_after_countdown") && time < restart_countdown) {
 646                         self.spawnshieldtime += RESTART_COUNTDOWN;
 647                         self.pauserotarmor_finished += RESTART_COUNTDOWN;
 648                         self.pauserothealth_finished += RESTART_COUNTDOWN;
 649                         self.pauseregen_finished += RESTART_COUNTDOWN;
 650                 }
 651                 self.damageforcescale = 2;
 652                 self.death_time = 0;
 653                 self.dead_frame = 0;
 654                 self.alpha = 0;
 655                 self.scale = 0;
 656                 self.fade_time = 0;
 657                 self.pain_frame = 0;
 658                 self.pain_finished = 0;
 659                 self.strength_finished = 0;
 660                 self.invincible_finished = 0;
 661                 self.pushltime = 0;
 662                 //self.speed_finished = 0;
 663                 //self.slowmo_finished = 0;
 664                 // players have no think function
 665                 self.think = SUB_Null;
 666                 self.nextthink = 0;
 667                 self.hook_time = 0;
 668
 669                 self.runes = 0;
 670
 671                 self.deadflag = DEAD_NO;
 672
 673                 self.angles = spot.angles;
 674
 675                 self.angles_z = 0; // never spawn tilted even if the spot says to
 676                 self.fixangle = TRUE; // turn this way immediately
 677                 self.velocity = '0 0 0';
 678                 self.avelocity = '0 0 0';
 679                 self.punchangle = '0 0 0';
 680                 self.punchvector = '0 0 0';
 681                 self.oldvelocity = self.velocity;
 682
 683                 self.viewzoom = 0.6;
 684                 self.has_zoomed = 0;
 685
 686                 self.customizeentityforclient = Client_customizeentityforclient;
 687
 688                 self.model = "";
 689                 FixPlayermodel();
 690
 691                 self.crouch = FALSE;
 692                 self.view_ofs = PL_VIEW_OFS;
 693                 setsize (self, PL_MIN, PL_MAX);
 694                 self.spawnorigin = spot.origin;
 695                 setorigin (self, spot.origin + '0 0 1' * (1 - self.mins_z - 24));
 696                 // don't reset back to last position, even if new position is stuck in solid
 697                 self.oldorigin = self.origin;
 698
 699                 if(g_arena)
 700                 {
 701                         Spawnqueue_Remove(self);
 702                         Spawnqueue_Mark(self);
 703                 }
 704
 705                 self.event_damage = PlayerDamage;
 706
 707                 self.bot_attack = TRUE;
 708
 709                 self.statdraintime = time + 5;
 710                 self.BUTTON_ATCK = self.BUTTON_JUMP = self.BUTTON_ATCK2 = 0;
 711
 712                 if(self.killcount == -666) {
 713                         PlayerScore_Clear(self);
 714                         self.killcount = 0;
 715                         self.frags = 0;
 716                 }
 717
 718                 self.cnt = WEP_LASER;
 719                 self.nixnex_lastchange_id = -1;
 720
 721                 CL_SpawnWeaponentity();
 722                 self.alpha = default_player_alpha;
 723                 self.colormod = '1 1 1' * cvar("g_player_brightness");
 724                 self.exteriorweaponentity.alpha = default_weapon_alpha;
 725
 726                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval")*2;
 727                 self.lms_traveled_distance = 0;
 728                 self.speedrunning = FALSE;
 729
 730                 race_PostSpawn(spot);
 731
 732                 if(cvar("spawn_debug"))
 733                 {
 734                         sprint(self, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 735                         remove(spot);   // usefull for checking if there are spawnpoints, that let drop through the floor
 736                 }
 737
 738                 //stuffcmd(self, "chase_active 0");
 739                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
 740
 741                 if (cvar("g_spawnsound"))
 742                         sound (self, CHAN_TRIGGER, "misc/spawn.wav", VOL_BASE, ATTN_NORM);
 743
 744                 if(g_assault) {
 745                         if(self.team == assault_attacker_team)
 746                                 centerprint(self, "You are attacking!\n");
 747                         else
 748                                 centerprint(self, "You are defending!\n");
 749                 }
 750
 751         } else if(self.classname == "observer") {
 752                 PutObserverInServer ();
 753         }
 754
 755         //if(g_ctf)
 756         //      ctf_playerchanged();
 757 }
 758
 759 /*
 760 =============
 761 SendCSQCInfo
 762
 763 Send whatever CSQC needs NOW and cannot wait for SendServerInfo to happen...
 764 =============
 765 */
 766 void SendCSQCInfo(void)
 767 {
 768         if(clienttype(self) != CLIENTTYPE_REAL)
 769                 return;
 770         msg_entity = self;
 771         WriteByte(MSG_ONE, SVC_TEMPENTITY);
 772         WriteByte(MSG_ONE, TE_CSQC_INIT);
 773         WriteShort(MSG_ONE, CSQC_REVISION);
 774         WriteByte(MSG_ONE, maxclients);
 775 }
 776
 777 /*
 778 =============
 779 SetNewParms
 780 =============
 781 */
 782 void SetNewParms (void)
 783 {
 784         // initialize parms for a new player
 785         parm1 = -(86400 * 366);
 786 }
 787
 788 /*
 789 =============
 790 SetChangeParms
 791 =============
 792 */
 793 void SetChangeParms (void)
 794 {
 795         // save parms for level change
 796         parm1 = self.parm_idlesince - time;
 797 }
 798
 799 /*
 800 =============
 801 DecodeLevelParms
 802 =============
 803 */
 804 void DecodeLevelParms (void)
 805 {
 806         // load parms
 807         self.parm_idlesince = parm1;
 808         if(self.parm_idlesince == -(86400 * 366))
 809                 self.parm_idlesince = time;
 810 }
 811
 812 /*
 813 =============
 814 ClientKill
 815
 816 Called when a client types 'kill' in the console
 817 =============
 818 */
 819
 820 void ClientKill_Now_TeamChange()
 821 {
 822         if(self.killindicator_teamchange == -1)
 823         {
 824                 self.team = -1;
 825                 JoinBestTeam( self, FALSE, FALSE );
 826         }
 827         else
 828         {
 829                 SV_ChangeTeam(self.killindicator_teamchange - 1);
 830         }
 831 }
 832
 833 void ClientKill_Now()
 834 {
 835         if(self.killindicator_teamchange)
 836                 ClientKill_Now_TeamChange();
 837
 838         // in any case:
 839         Damage(self, self, self, 100000, DEATH_KILL, self.origin, '0 0 0');
 840
 841         if(self.killindicator)
 842         {
 843                 dprint("Cleaned up after a leaked kill indicator.\n");
 844                 remove(self.killindicator);
 845                 self.killindicator = world;
 846         }
 847 }
 848 void KillIndicator_Think()
 849 {
 850         if (!self.owner.modelindex)
 851         {
 852                 self.owner.killindicator = world;
 853                 remove(self);
 854                 return;
 855         }
 856
 857         if(self.cnt <= 0)
 858         {
 859                 self = self.owner;
 860                 ClientKill_Now(); // no oldself needed
 861                 return;
 862         }
 863         else
 864         {
 865                 if(self.cnt <= 10)
 866                         setmodel(self, strcat("models/sprites/", ftos(self.cnt), ".spr32"));
 867                 if(clienttype(self.owner) == CLIENTTYPE_REAL)
 868                 {
 869                         if(self.cnt <= 10)
 870                                 announce(self.owner, strcat("announcer/robotic/", ftos(self.cnt), ".ogg"));
 871                         if(self.owner.killindicator_teamchange)
 872                         {
 873                                 if(self.owner.killindicator_teamchange == -1)
 874                                         centerprint(self.owner, strcat("Changing team in ", ftos(self.cnt), " seconds"));
 875                                 else
 876                                         centerprint(self.owner, strcat("Changing to ", ColoredTeamName(self.owner.killindicator_teamchange), " in ", ftos(self.cnt), " seconds"));
 877                         }
 878                         else
 879                                 centerprint(self.owner, strcat("^1Suicide in ", ftos(self.cnt), " seconds"));
 880                 }
 881                 self.nextthink = time + 1;
 882                 self.cnt -= 1;
 883         }
 884 }
 885
 886 void ClientKill_TeamChange (float targetteam) // 0 = don't change, -1 = auto
 887 {
 888         float killtime;
 889         entity e;
 890         killtime = cvar("g_balance_kill_delay");
 891
 892         self.killindicator_teamchange = targetteam;
 893
 894         if(!self.killindicator)
 895         {
 896                 if(killtime <= 0 || !self.modelindex || self.deadflag != DEAD_NO)
 897                 {
 898                         ClientKill_Now();
 899                 }
 900                 else
 901                 {
 902                         self.killindicator = spawn();
 903                         self.killindicator.owner = self;
 904                         self.killindicator.scale = 0.5;
 905                         setattachment(self.killindicator, self, "");
 906                         setorigin(self.killindicator, '0 0 52');
 907                         self.killindicator.think = KillIndicator_Think;
 908                         self.killindicator.nextthink = time + (self.lip) * 0.05;
 909                         self.killindicator.cnt = ceil(killtime);
 910                         self.killindicator.count = bound(0, ceil(killtime), 10);
 911                         sprint(self, strcat("^1You'll be dead in ", ftos(self.killindicator.cnt), " seconds\n"));
 912
 913                         for(e = world; (e = find(e, classname, "body")) != world; )
 914                         {
 915                                 if(e.enemy != self)
 916                                         continue;
 917                                 e.killindicator = spawn();
 918                                 e.killindicator.owner = e;
 919                                 e.killindicator.scale = 0.5;
 920                                 setattachment(e.killindicator, e, "");
 921                                 setorigin(e.killindicator, '0 0 52');
 922                                 e.killindicator.think = KillIndicator_Think;
 923                                 e.killindicator.nextthink = time + (e.lip) * 0.05;
 924                                 e.killindicator.cnt = ceil(killtime);
 925                         }
 926                         self.lip = 0;
 927                 }
 928         }
 929         if(self.killindicator)
 930         {
 931                 if(targetteam)
 932                         self.killindicator.colormod = TeamColor(targetteam);
 933                 else
 934                         self.killindicator.colormod = '0 0 0';
 935         }
 936 }
 937
 938 void ClientKill (void)
 939 {
 940         ClientKill_TeamChange(0);
 941 }
 942
 943 void DoTeamChange(float destteam)
 944 {
 945         float t, c0;
 946         if(!cvar("teamplay"))
 947         {
 948                 if(destteam >= 0)
 949                         SetPlayerColors(self, destteam);
 950                 return;
 951         }
 952         if(self.classname == "player")
 953         if(destteam == -1)
 954         {
 955                 CheckAllowedTeams(self);
 956                 t = FindSmallestTeam(self, TRUE);
 957                 switch(self.team)
 958                 {
 959                         case COLOR_TEAM1: c0 = c1; break;
 960                         case COLOR_TEAM2: c0 = c2; break;
 961                         case COLOR_TEAM3: c0 = c3; break;
 962                         case COLOR_TEAM4: c0 = c4; break;
 963                         default:          c0 = 999;
 964                 }
 965                 switch(t)
 966                 {
 967                         case 1:
 968                                 if(c0 > c1)
 969                                         destteam = COLOR_TEAM1;
 970                                 break;
 971                         case 2:
 972                                 if(c0 > c2)
 973                                         destteam = COLOR_TEAM2;
 974                                 break;
 975                         case 3:
 976                                 if(c0 > c3)
 977                                         destteam = COLOR_TEAM3;
 978                                 break;
 979                         case 4:
 980                                 if(c0 > c4)
 981                                         destteam = COLOR_TEAM4;
 982                                 break;
 983                 }
 984                 if(destteam == -1)
 985                         return;
 986         }
 987         if(destteam == self.team && !self.killindicator)
 988                 return;
 989         ClientKill_TeamChange(destteam);
 990 }
 991
 992 void FixClientCvars(entity e)
 993 {
 994         // send prediction settings to the client
 995         stuffcmd(e, "\nin_bindmap 0 0\n");
 996         /*
 997          * we no longer need to stuff this. Remove this comment block if you feel
 998          * 2.3 and higher (or was it 2.2.3?) don't need these any more
 999         stuffcmd(e, strcat("cl_gravity ", ftos(cvar("sv_gravity")), "\n"));
1000         stuffcmd(e, strcat("cl_movement_accelerate ", ftos(cvar("sv_accelerate")), "\n"));
1001         stuffcmd(e, strcat("cl_movement_friction ", ftos(cvar("sv_friction")), "\n"));
1002         stuffcmd(e, strcat("cl_movement_maxspeed ", ftos(cvar("sv_maxspeed")), "\n"));
1003         stuffcmd(e, strcat("cl_movement_airaccelerate ", ftos(cvar("sv_airaccelerate")), "\n"));
1004         stuffcmd(e, strcat("cl_movement_maxairspeed ", ftos(cvar("sv_maxairspeed")), "\n"));
1005         stuffcmd(e, strcat("cl_movement_stopspeed ", ftos(cvar("sv_stopspeed")), "\n"));
1006         stuffcmd(e, strcat("cl_movement_jumpvelocity ", ftos(cvar("sv_jumpvelocity")), "\n"));
1007         stuffcmd(e, strcat("cl_movement_stepheight ", ftos(cvar("sv_stepheight")), "\n"));
1008         stuffcmd(e, strcat("set cl_movement_friction_on_land ", ftos(cvar("sv_friction_on_land")), "\n"));
1009         stuffcmd(e, strcat("set cl_movement_airaccel_qw ", ftos(cvar("sv_airaccel_qw")), "\n"));
1010         stuffcmd(e, strcat("set cl_movement_airaccel_sideways_friction ", ftos(cvar("sv_airaccel_sideways_friction")), "\n"));
1011         stuffcmd(e, "cl_movement_edgefriction 1\n");
1012          */
1013 }
1014
1015 /*
1016 =============
1017 ClientConnect
1018
1019 Called when a client connects to the server
1020 =============
1021 */
1022 //void ctf_clientconnect();
1023 string ColoredTeamName(float t);
1024 void DecodeLevelParms (void);
1025 //void dom_player_join_team(entity pl);
1026 void ClientConnect (void)
1027 {
1028         local string s;
1029         float wep;
1030
1031         if(self.flags & FL_CLIENT)
1032         {
1033                 print("Warning: ClientConnect, but already connected!\n");
1034                 return;
1035         }
1036
1037         if(Ban_IsClientBanned(self))
1038         {
1039                 s = strcat("^1NOTE:^7 banned client ", self.netaddress, " just tried to enter\n");
1040                 dropclient(self);
1041                 bprint(s);
1042                 return;
1043         }
1044
1045         DecodeLevelParms();
1046
1047         self.classname = "player_joining";
1048
1049         self.flags = self.flags | FL_CLIENT;
1050         self.version_nagtime = time + 10 + random() * 10;
1051
1052         if(player_count<0)
1053         {
1054                 dprint("BUG player count is lower than zero, this cannot happen!\n");
1055                 player_count = 0;
1056         }
1057
1058         PlayerScore_Attach(self);
1059
1060         bot_clientconnect();
1061
1062         race_PreSpawnObserver();
1063
1064         //if(g_domination)
1065         //      dom_player_join_team(self);
1066
1067         //JoinBestTeam(self, FALSE, FALSE);
1068
1069         if((cvar("sv_spectate") == 1 && !g_lms) || cvar("g_campaign")) {
1070                 self.classname = "observer";
1071         } else {
1072                 self.classname = "player";
1073                 campaign_bots_may_start = 1;
1074         }
1075
1076         self.playerid = (playerid_last = playerid_last + 1);
1077         if(cvar("sv_eventlog"))
1078         {
1079                 if(clienttype(self) == CLIENTTYPE_REAL)
1080                         s = "player";
1081                 else
1082                         s = "bot";
1083                 GameLogEcho(strcat(":join:", ftos(self.playerid), ":", s, ":", self.netname), TRUE);
1084                 s = strcat(":team:", ftos(self.playerid), ":");
1085                 s = strcat(s, ftos(self.team));
1086                 GameLogEcho(s, FALSE);
1087         }
1088         self.netname_previous = strzone(self.netname);
1089
1090         //stuffcmd(self, "set tmpviewsize $viewsize \n");
1091
1092         bprint ("^4",self.netname);
1093         bprint ("^4 connected");
1094
1095         if(g_domination || g_ctf)
1096         {
1097                 bprint(" and joined the ");
1098                 bprint(ColoredTeamName(self.team));
1099         }
1100
1101         bprint("\n");
1102
1103         self.welcomemessage_time = 0;
1104
1105         stuffcmd(self, strcat(clientstuff, "\n"));
1106         stuffcmd(self, strcat("exec maps/", mapname, ".cfg\n"));
1107         stuffcmd(self, "cl_particles_reloadeffects\n");
1108
1109         FixClientCvars(self);
1110
1111         // spawnfunc_waypoint sprites
1112         WaypointSprite_InitClient(self);
1113
1114         // Wazat's grappling hook
1115         SetGrappleHookBindings();
1116
1117         // get autoswitch state from player when he toggles it
1118         stuffcmd(self, "alias autoswitch \"set cl_autoswitch $1 ; cmd autoswitch $1\"\n"); // default.cfg-ed in 2.4.1
1119
1120         // get version info from player
1121         stuffcmd(self, "cmd clientversion $gameversion\n");
1122
1123         // send all weapon info strings
1124         stuffcmd(self, "register_bestweapon clear\n"); // clear the Quake stuff
1125         wep = WEP_FIRST;
1126         while (wep <= WEP_LAST)
1127         {
1128                 weapon_action(wep, WR_REGISTER);
1129                 wep = wep + 1;
1130         }
1131
1132         // get other cvars from player
1133         GetCvars(0);
1134
1135         // set cvar for team scoreboard
1136         if (teams_matter)
1137         {
1138                 local float t;
1139                 t = cvar("teamplay");
1140                 // we have to stuff the correct teamplay value because if this is a listen server, this changes the teamplay mode of the server itself, which is bad
1141                 stuffcmd(self, strcat("set teamplay ", ftos(t), "\n"));
1142         }
1143         else
1144                 stuffcmd(self, "set teamplay 0\n");
1145
1146         // notify about available teams
1147         if(teamplay)
1148         {
1149                 CheckAllowedTeams(self);
1150                 t = 0; if(c1 >= 0) t |= 1; if(c2 >= 0) t |= 2; if(c3 >= 0) t |= 4; if(c4 >= 0) t |= 8;
1151                 stuffcmd(self, strcat("set _teams_available ", ftos(t), "\n"));
1152         }
1153         else
1154                 stuffcmd(self, "set _teams_available 0\n");
1155
1156         stuffcmd(self, strcat("set gametype ", ftos(game), "\n"));
1157
1158         if(g_arena)
1159         {
1160                 self.classname = "observer";
1161                 Spawnqueue_Insert(self);
1162         }
1163         /*else if(g_ctf)
1164         {
1165                 ctf_clientconnect();
1166         }*/
1167
1168         if(entcs_start)
1169                 attach_entcs();
1170
1171         bot_relinkplayerlist();
1172
1173         self.spectatortime = time;
1174         if(blockSpectators)
1175         {
1176                 sprint(self, strcat("^7You have to become a player within the next ", ftos(cvar("g_maxplayers_spectator_blocktime")), " seconds, otherwise you will be kicked, because spectators aren't allowed at this time!\n"));
1177         }
1178
1179         self.jointime = time;
1180         self.allowedTimeouts = cvar("sv_timeout_number");
1181
1182         if(clienttype(self) == CLIENTTYPE_REAL)
1183         {
1184                 sprint(self, strcat("nexuiz-csqc protocol ", ftos(CSQC_REVISION), "\n"));
1185                 SendCSQCInfo();
1186                 msg_entity = self;
1187                 if(mapvote_initialized && !cvar("g_maplist_textonly"))
1188                 {
1189                         MapVote_SendData(MSG_ONE);
1190                         MapVote_UpdateData(MSG_ONE);
1191                 }
1192                 ScoreInfo_Write(MSG_ONE);
1193         }
1194
1195         if(g_lms)
1196         {
1197                 if(PlayerScore_Add(self, SP_LMS_LIVES, LMS_NewPlayerLives()) <= 0)
1198                 {
1199                         PlayerScore_Add(self, SP_LMS_RANK, 666);
1200                         self.frags = -666; // FIXME do we still need this?
1201                 }
1202         }
1203 }
1204
1205 /*
1206 =============
1207 ClientDisconnect
1208
1209 Called when a client disconnects from the server
1210 =============
1211 */
1212 void(entity e) DropFlag;
1213 .entity chatbubbleentity;
1214 .entity teambubbleentity;
1215 void ReadyCount();
1216 //void() ctf_clientdisconnect;
1217 void ClientDisconnect (void)
1218 {
1219         float save;
1220
1221         if not(self.flags & FL_CLIENT)
1222         {
1223                 print("Warning: ClientDisconnect without ClientConnect\n");
1224                 return;
1225         }
1226
1227         bot_clientdisconnect();
1228
1229         if(entcs_start)
1230                 detach_entcs();
1231
1232         if(cvar("sv_eventlog"))
1233                 GameLogEcho(strcat(":part:", ftos(self.playerid)), FALSE);
1234         bprint ("^4",self.netname);
1235         bprint ("^4 disconnected\n");
1236
1237         if (self.chatbubbleentity)
1238         {
1239                 remove (self.chatbubbleentity);
1240                 self.chatbubbleentity = world;
1241         }
1242
1243         if (self.teambubbleentity)
1244         {
1245                 remove (self.teambubbleentity);
1246                 self.teambubbleentity = world;
1247         }
1248
1249         if (self.killindicator)
1250         {
1251                 remove (self.killindicator);
1252                 self.killindicator = world;
1253         }
1254
1255         WaypointSprite_PlayerGone();
1256
1257         DropAllRunes(self);
1258         kh_Key_DropAll(self, TRUE);
1259
1260         if(self.flagcarried)
1261                 DropFlag(self.flagcarried);
1262
1263         save = self.flags;
1264         self.flags = self.flags - (self.flags & FL_CLIENT);
1265         bot_relinkplayerlist();
1266         self.flags = save;
1267
1268         // remove laserdot
1269         if(self.weaponentity)
1270                 if(self.weaponentity.lasertarget)
1271                         remove(self.weaponentity.lasertarget);
1272
1273         if(g_arena)
1274         {
1275                 Spawnqueue_Unmark(self);
1276                 Spawnqueue_Remove(self);
1277         }
1278         /*if(g_ctf)
1279         {
1280                 ctf_clientdisconnect();
1281         }
1282         */
1283
1284         PlayerScore_Detach(self);
1285
1286         if(self.netname_previous)
1287                 strunzone(self.netname_previous);
1288
1289         ClearPlayerSounds();
1290
1291         // free cvars
1292         GetCvars(-1);
1293         self.playerid = 0;
1294
1295         ReadyCount();
1296 }
1297
1298 .float BUTTON_CHAT;
1299 void ChatBubbleThink()
1300 {
1301         self.nextthink = time;
1302         if (!self.owner.modelindex || self.owner.chatbubbleentity != self)
1303         {
1304                 self.owner.chatbubbleentity = world;
1305                 remove(self);
1306                 return;
1307         }
1308         setorigin(self, self.owner.origin + '0 0 15' + self.owner.maxs_z * '0 0 1');
1309         if (self.owner.BUTTON_CHAT && !self.owner.deadflag)
1310                 self.model = self.mdl;
1311         else
1312                 self.model = "";
1313 };
1314
1315 void UpdateChatBubble()
1316 {
1317         if (!self.modelindex)
1318                 return;
1319         // spawn a chatbubble entity if needed
1320         if (!self.chatbubbleentity)
1321         {
1322                 self.chatbubbleentity = spawn();
1323                 self.chatbubbleentity.owner = self;
1324                 self.chatbubbleentity.exteriormodeltoclient = self;
1325                 self.chatbubbleentity.think = ChatBubbleThink;
1326                 self.chatbubbleentity.nextthink = time;
1327                 setmodel(self.chatbubbleentity, "models/misc/chatbubble.spr"); // precision set below
1328                 setorigin(self.chatbubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1329                 self.chatbubbleentity.mdl = self.chatbubbleentity.model;
1330                 self.chatbubbleentity.model = "";
1331                 self.chatbubbleentity.effects = EF_LOWPRECISION;
1332         }
1333 }
1334
1335
1336 void TeamBubbleThink()
1337 {
1338         self.nextthink = time;
1339         if (!self.owner.modelindex || self.owner.teambubbleentity != self)
1340         {
1341                 self.owner.teambubbleentity = world;
1342                 remove(self);
1343                 return;
1344         }
1345 //      setorigin(self, self.owner.origin + '0 0 15' + self.owner.maxs_z * '0 0 1');  // bandwidth hog. setattachment does this now
1346         if (self.owner.BUTTON_CHAT || self.owner.deadflag || self.owner.killindicator)
1347                 self.model = "";
1348         else
1349                 self.model = self.mdl;
1350
1351 };
1352
1353 float TeamBubble_customizeentityforclient()
1354 {
1355         return (self.owner != other && self.owner.team == other.team && other.killcount > -666);
1356 }
1357
1358 void UpdateTeamBubble()
1359 {
1360         if (!self.modelindex || !cvar("teamplay"))
1361                 return;
1362         // spawn a teambubble entity if needed
1363         if (!self.teambubbleentity && cvar("teamplay"))
1364         {
1365                 self.teambubbleentity = spawn();
1366                 self.teambubbleentity.owner = self;
1367                 self.teambubbleentity.exteriormodeltoclient = self;
1368                 self.teambubbleentity.think = TeamBubbleThink;
1369                 self.teambubbleentity.nextthink = time;
1370                 setmodel(self.teambubbleentity, "models/misc/teambubble.spr"); // precision set below
1371 //              setorigin(self.teambubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1372                 setorigin(self.teambubbleentity, self.teambubbleentity.origin + '0 0 15' + self.maxs_z * '0 0 1');
1373                 setattachment(self.teambubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1374                 self.teambubbleentity.mdl = self.teambubbleentity.model;
1375                 self.teambubbleentity.model = self.teambubbleentity.mdl;
1376                 self.teambubbleentity.customizeentityforclient = TeamBubble_customizeentityforclient;
1377                 self.teambubbleentity.effects = EF_LOWPRECISION;
1378         }
1379 }
1380
1381 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1382 // added to the model skins
1383 /*void UpdateColorModHack()
1384 {
1385         local float c;
1386         c = self.clientcolors & 15;
1387         // LordHavoc: only bothering to support white, green, red, yellow, blue
1388              if (teamplay == 0) self.colormod = '0 0 0';
1389         else if (c ==  0) self.colormod = '1.00 1.00 1.00';
1390         else if (c ==  3) self.colormod = '0.10 1.73 0.10';
1391         else if (c ==  4) self.colormod = '1.73 0.10 0.10';
1392         else if (c == 12) self.colormod = '1.22 1.22 0.10';
1393         else if (c == 13) self.colormod = '0.10 0.10 1.73';
1394         else self.colormod = '1 1 1';
1395 };*/
1396
1397 void respawn(void)
1398 {
1399         CopyBody(1);
1400         self.effects |= EF_NODRAW; // prevent another CopyBody
1401         PutClientInServer();
1402 }
1403
1404 /**
1405  * When sv_timeout is used this function returs strings like
1406  * "Timeout begins in 2 seconds!\n" or "Timeout ends in 23 seconds!\n".
1407  * Called by centerprint functions
1408  * @param addOneSecond boolean, set to 1 if the welcome-message centerprint asks for the text
1409  */
1410 string getTimeoutText(float addOneSecond) {
1411         if (!cvar("sv_timeout") || !timeoutStatus)
1412                 return "";
1413
1414         local string retStr;
1415         if (timeoutStatus == 1) {
1416                 if (addOneSecond == 1) {
1417                         retStr = strcat("Timeout begins in ", ftos(remainingLeadTime + 1), " seconds!\n");
1418                 }
1419                 else {
1420                         retStr = strcat("Timeout begins in ", ftos(remainingLeadTime), " seconds!\n");
1421                 }
1422                 return retStr;
1423         }
1424         else if (timeoutStatus == 2) {
1425                 if (addOneSecond) {
1426                         retStr = strcat("Timeout ends in ", ftos(remainingTimeoutTime + 1), " seconds!\n");
1427                         //don't show messages like "Timeout ends in 0 seconds"...
1428                         if ((remainingTimeoutTime + 1) > 0)
1429                                 return retStr;
1430                         else
1431                                 return "";
1432                 }
1433                 else {
1434                         retStr = strcat("Timeout ends in ", ftos(remainingTimeoutTime), " seconds!\n");
1435                         //don't show messages like "Timeout ends in 0 seconds"...
1436                         if (remainingTimeoutTime > 0)
1437                                 return retStr;
1438                         else
1439                                 return "";
1440                 }
1441         }
1442         else return "";
1443 }
1444
1445 void player_powerups (void)
1446 {
1447         if (g_minstagib)
1448         {
1449                 if (self.items & IT_STRENGTH)
1450                 {
1451                         if (time > self.strength_finished)
1452                         {
1453                                 if (g_minstagib_invis_alpha > 0)
1454                                 {
1455                                         self.alpha = default_player_alpha;
1456                                         self.exteriorweaponentity.alpha = default_weapon_alpha;
1457                                         self.effects = self.effects | EF_FULLBRIGHT;
1458                                 }
1459                                 else
1460                                 {
1461                                         self.effects -= self.effects & EF_NODRAW;
1462                                 }
1463                                 self.items = self.items - (self.items & IT_STRENGTH);
1464                                 sprint(self, "^3Invisibility has worn off\n");
1465                         }
1466                 }
1467                 else
1468                 {
1469                         if (time < self.strength_finished)
1470                         {
1471                                 if (g_minstagib_invis_alpha > 0)
1472                                 {
1473                                         self.alpha = g_minstagib_invis_alpha;
1474                                         self.exteriorweaponentity.alpha = g_minstagib_invis_alpha;
1475                                         self.effects -= self.effects & EF_FULLBRIGHT;
1476                                 }
1477                                 else
1478                                 {
1479                                         self.effects = self.effects | EF_NODRAW;
1480                                 }
1481                                 self.items = self.items | IT_STRENGTH;
1482                                 sprint(self, "^3You are invisible\n");
1483                         }
1484                 }
1485
1486                 if (self.items & IT_INVINCIBLE)
1487                 {
1488                         if (time > self.invincible_finished)
1489                         {
1490                                 self.items = self.items - (self.items & IT_INVINCIBLE);
1491                                 sprint(self, "^3Speed has worn off\n");
1492                         }
1493                 }
1494                 else
1495                 {
1496                         if (time < self.invincible_finished)
1497                         {
1498                                 self.items = self.items | IT_INVINCIBLE;
1499                                 sprint(self, "^3You are on speed\n");
1500                         }
1501                 }
1502                 return;
1503         }
1504
1505         self.effects = self.effects - (self.effects & (EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT));
1506         if (self.items & IT_STRENGTH)
1507         {
1508                 self.effects = self.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1509                 if (time > self.strength_finished)
1510                 {
1511                         self.items = self.items - (self.items & IT_STRENGTH);
1512                         sprint(self, "^3Strength has worn off\n");
1513                 }
1514         }
1515         else
1516         {
1517                 if (time < self.strength_finished)
1518                 {
1519                         self.items = self.items | IT_STRENGTH;
1520                         sprint(self, "^3Strength infuses your weapons with devastating power\n");
1521                 }
1522         }
1523         if (self.items & IT_INVINCIBLE)
1524         {
1525                 self.effects = self.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1526                 if (time > self.invincible_finished)
1527                 {
1528                         self.items = self.items - (self.items & IT_INVINCIBLE);
1529                         sprint(self, "^3Shield has worn off\n");
1530                 }
1531         }
1532         else
1533         {
1534                 if (time < self.invincible_finished)
1535                 {
1536                         self.items = self.items | IT_INVINCIBLE;
1537                         sprint(self, "^3Shield surrounds you\n");
1538                 }
1539         }
1540
1541         if (cvar("g_fullbrightplayers"))
1542                 self.effects = self.effects | EF_FULLBRIGHT;
1543
1544         // midair gamemode: damage only while in the air
1545         // if in midair mode, being on ground grants temporary invulnerability
1546         // (this is so that multishot weapon don't clear the ground flag on the
1547         // first damage in the frame, leaving the player vulnerable to the
1548         // remaining hits in the same frame)
1549         if (self.flags & FL_ONGROUND)
1550         if (g_midair)
1551                 self.spawnshieldtime = max(self.spawnshieldtime, time + cvar("g_midair_shieldtime"));
1552
1553         if (time > restart_countdown)
1554         if (time < self.spawnshieldtime)
1555                 self.effects = self.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1556 }
1557
1558 float CalcRegen(float current, float stable, float regenfactor)
1559 {
1560         if(current > stable)
1561                 return current;
1562         else if(current > stable - 0.25) // when close enough, "snap"
1563                 return stable;
1564         else
1565                 return min(stable, current + (stable - current) * regenfactor * frametime);
1566 }
1567
1568 void player_regen (void)
1569 {
1570         float maxh, maxa, limith, limita, max_mod, regen_mod, rot_mod, limit_mod;
1571         maxh = cvar("g_balance_health_stable");
1572         maxa = cvar("g_balance_armor_stable");
1573         limith = cvar("g_balance_health_limit");
1574         limita = cvar("g_balance_armor_limit");
1575
1576         if (g_minstagib || (g_lms && !cvar("g_lms_regenerate")))
1577                 return;
1578
1579         max_mod = regen_mod = rot_mod = limit_mod = 1;
1580
1581         if (self.runes & RUNE_REGEN)
1582         {
1583                 if (self.runes & CURSE_VENOM) // do we have both rune/curse?
1584                 {
1585                         regen_mod = cvar("g_balance_rune_regen_combo_regenrate");
1586                         max_mod = cvar("g_balance_rune_regen_combo_hpmod");
1587                         limit_mod = cvar("g_balance_rune_regen_combo_limitmod");
1588                 }
1589                 else
1590                 {
1591                         regen_mod = cvar("g_balance_rune_regen_regenrate");
1592                         max_mod = cvar("g_balance_rune_regen_hpmod");
1593                         limit_mod = cvar("g_balance_rune_regen_limitmod");
1594                 }
1595         }
1596         else if (self.runes & CURSE_VENOM)
1597         {
1598                 max_mod = cvar("g_balance_curse_venom_hpmod");
1599                 if (self.runes & RUNE_REGEN) // do we have both rune/curse?
1600                         rot_mod = cvar("g_balance_rune_regen_combo_rotrate");
1601                 else
1602                         rot_mod = cvar("g_balance_curse_venom_rotrate");
1603                 limit_mod = cvar("g_balance_curse_venom_limitmod");
1604                 //if (!self.runes & RUNE_REGEN)
1605                 //      rot_mod = cvar("g_balance_curse_venom_rotrate");
1606         }
1607         maxh = maxh * max_mod;
1608         //maxa = maxa * max_mod;
1609         limith = limith * limit_mod;
1610         limita = limita * limit_mod;
1611
1612         if (self.armorvalue > maxa)
1613         {
1614                 if (time > self.pauserotarmor_finished)
1615                 {
1616                         self.armorvalue = max(maxa, self.armorvalue + (maxa - self.armorvalue) * cvar("g_balance_armor_rot") * frametime);
1617                         self.armorvalue = max(maxa, self.armorvalue - cvar("g_balance_armor_rotlinear") * frametime);
1618                 }
1619         }
1620         else if (self.armorvalue < maxa)
1621         {
1622                 if (time > self.pauseregen_finished)
1623                 {
1624                         self.armorvalue = CalcRegen(self.armorvalue, maxa, cvar("g_balance_armor_regen"));
1625                         self.armorvalue = min(maxa, self.armorvalue + cvar("g_balance_armor_regenlinear") * frametime);
1626                 }
1627         }
1628         if (self.health > maxh)
1629         {
1630                 if (time > self.pauserothealth_finished)
1631                 {
1632                         self.health = max(maxh, self.health + (maxh - self.health) * rot_mod*cvar("g_balance_health_rot") * frametime);
1633                         self.health = max(maxh, self.health - rot_mod*cvar("g_balance_health_rotlinear") * frametime);
1634                 }
1635         }
1636         else if (self.health < maxh)
1637         {
1638                 if (time > self.pauseregen_finished)
1639                 {
1640                         self.health = CalcRegen(self.health, maxh, regen_mod * cvar("g_balance_health_regen"));
1641                         self.health = min(maxh, self.health + regen_mod*cvar("g_balance_health_regenlinear") * frametime);
1642                 }
1643         }
1644
1645         if (self.health > limith)
1646                 self.health = limith;
1647         if (self.armorvalue > limita)
1648                 self.armorvalue = limita;
1649
1650         // if player rotted to death...  die!
1651         if(self.health < 1)
1652                 self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
1653 }
1654
1655 /*
1656 ======================
1657 spectate mode routines
1658 ======================
1659 */
1660 void SpectateCopy(entity spectatee) {
1661         self.armortype = spectatee.armortype;
1662         self.armorvalue = spectatee.armorvalue;
1663         self.currentammo = spectatee.currentammo;
1664         self.effects = spectatee.effects;
1665         self.health = spectatee.health;
1666         self.impulse = 0;
1667         self.items = spectatee.items;
1668         self.punchangle = spectatee.punchangle;
1669         self.view_ofs = spectatee.view_ofs;
1670         self.v_angle = spectatee.v_angle;
1671         self.viewzoom = spectatee.viewzoom;
1672         self.velocity = spectatee.velocity;
1673         self.dmg_take = spectatee.dmg_take;
1674         self.dmg_save = spectatee.dmg_save;
1675         self.dmg_inflictor = spectatee.dmg_inflictor;
1676         self.angles = spectatee.v_angle;
1677         self.fixangle = TRUE;
1678         setorigin(self, spectatee.origin);
1679         setsize(self, spectatee.mins, spectatee.maxs);
1680 }
1681
1682 float SpectateUpdate() {
1683         if(!self.enemy)
1684                 return 0;
1685
1686         if (self == self.enemy)
1687                 return 0;
1688
1689         if(self.enemy.flags & FL_NOTARGET)
1690                 return 0;
1691
1692         SpectateCopy(self.enemy);
1693
1694         return 1;
1695 }
1696
1697 float SpectateNext() {
1698         other = find(self.enemy, classname, "player");
1699         if (!other) {
1700                 other = find(other, classname, "player");
1701         }
1702         if (other) {
1703                 self.enemy = other;
1704         }
1705         if(self.enemy.classname == "player") {
1706                 msg_entity = self;
1707                 WriteByte(MSG_ONE, SVC_SETVIEW);
1708                 WriteEntity(MSG_ONE, self.enemy);
1709                 self.wantswelcomemessage = 1;
1710                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
1711                 if(!SpectateUpdate())
1712                         PutObserverInServer();
1713                 return 1;
1714         } else {
1715                 return 0;
1716         }
1717 }
1718
1719 /*
1720 =============
1721 ShowRespawnCountdown()
1722
1723 Update a respawn countdown display.
1724 =============
1725 */
1726 void ShowRespawnCountdown()
1727 {
1728         float number;
1729         if(self.deadflag == DEAD_NO) // just respawned?
1730                 return;
1731         else
1732         {
1733                 number = ceil(self.death_time - time);
1734                 if(number <= 0)
1735                         return;
1736                 if(number <= self.respawn_countdown)
1737                 {
1738                         self.respawn_countdown = number - 1;
1739                         if(ceil(self.death_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
1740                                 announce(self, strcat("announcer/robotic/", ftos(number), ".ogg"));
1741                 }
1742         }
1743 }
1744
1745 void LeaveSpectatorMode()
1746 {
1747         if(isJoinAllowed()) {
1748                 if(!cvar("teamplay") || cvar("g_campaign") || cvar("g_balance_teams")) {
1749                         self.classname = "player";
1750                         if(cvar("g_campaign") || cvar("g_balance_teams") || cvar("g_balance_teams_force"))
1751                                 JoinBestTeam(self, FALSE, TRUE);
1752                         if(cvar("g_campaign"))
1753                                 campaign_bots_may_start = 1;
1754                         PutClientInServer();
1755                         if(!(self.flags & FL_NOTARGET))
1756                                 bprint ("^4", self.netname, "^4 is playing now\n");
1757                         centerprint(self,"");
1758                         return;
1759                 } else {
1760                         stuffcmd(self,"menu_showteamselect\n");
1761                         return;
1762                 }
1763         }
1764         else {
1765                 //player may not join because of g_maxplayers is set
1766                 centerprint_atprio(self, CENTERPRIO_MAPVOTE, PREVENT_JOIN_TEXT);
1767         }
1768 }
1769
1770 /**
1771  * Determines whether the player is allowed to join. This depends on cvar
1772  * g_maxplayers, if it isn't used this function always return TRUE, otherwise
1773  * it checks whether the number of currently playing players exceeds g_maxplayers.
1774  * @return bool TRUE if the player is allowed to join, false otherwise
1775  */
1776 float isJoinAllowed() {
1777         if (!cvar("g_maxplayers"))
1778                 return TRUE;
1779
1780         local entity e;
1781         local float currentlyPlaying;
1782         FOR_EACH_REALPLAYER(e) {
1783                 if(e.classname == "player")
1784                         currentlyPlaying += 1;
1785         }
1786         if(currentlyPlaying < cvar("g_maxplayers"))
1787                 return TRUE;
1788
1789         return FALSE;
1790 }
1791
1792 /**
1793  * Checks whether the client is an observer or spectator, if so, he will get kicked after
1794  * g_maxplayers_spectator_blocktime seconds
1795  */
1796 void checkSpectatorBlock() {
1797         if(self.classname == "spectator" || self.classname == "observer") {
1798                 if( time > (self.spectatortime + cvar("g_maxplayers_spectator_blocktime")) ) {
1799                         sprint(self, "^7You were kicked from the server because you are spectator and spectators aren't allowed at the moment.\n");
1800                         dropclient(self);
1801                 }
1802         }
1803 }
1804
1805 float vercmp_recursive(string v1, string v2)
1806 {
1807         float dot1, dot2;
1808         string s1, s2;
1809         float r;
1810
1811         dot1 = strstrofs(v1, ".", 0);
1812         dot2 = strstrofs(v2, ".", 0);
1813         if(dot1 == -1)
1814                 s1 = v1;
1815         else
1816                 s1 = substring(v1, 0, dot1);
1817         if(dot2 == -1)
1818                 s2 = v2;
1819         else
1820                 s2 = substring(v2, 0, dot2);
1821
1822         r = stof(s1) - stof(s2);
1823         if(r != 0)
1824                 return r;
1825
1826         r = strcasecmp(s1, s2);
1827         if(r != 0)
1828                 return r;
1829
1830         if(dot1 == -1)
1831                 if(dot2 == -1)
1832                         return 0;
1833                 else
1834                         return -1;
1835         else
1836                 if(dot2 == -1)
1837                         return 1;
1838                 else
1839                         return vercmp_recursive(substring(v1, dot1 + 1, 999), substring(v2, dot2 + 1, 999));
1840 }
1841
1842 float vercmp(string v1, string v2)
1843 {
1844         if(strcasecmp(v1, v2) == 0) // early out check
1845                 return 0;
1846         return vercmp_recursive(v1, v2);
1847 }
1848
1849 void ObserverThink()
1850 {
1851         if (self.flags & FL_JUMPRELEASED) {
1852                 if (self.BUTTON_JUMP && !self.version_mismatch) {
1853                         self.welcomemessage_time = 0;
1854                         self.flags = self.flags - FL_JUMPRELEASED;
1855                         LeaveSpectatorMode();
1856                         return;
1857                 } else if(self.BUTTON_ATCK && !self.version_mismatch) {
1858                         self.welcomemessage_time = 0;
1859                         self.flags = self.flags - FL_JUMPRELEASED;
1860                         if(SpectateNext() == 1) {
1861                                 self.classname = "spectator";
1862                         }
1863                 }
1864         } else {
1865                 if (!(self.BUTTON_ATCK || self.BUTTON_JUMP)) {
1866                         self.flags = self.flags | FL_JUMPRELEASED;
1867                 }
1868         }
1869         if(self.BUTTON_ZOOM)
1870                 self.wantswelcomemessage = 0;
1871         if(self.wantswelcomemessage)
1872                 PrintWelcomeMessage(self);
1873 }
1874
1875 void SpectatorThink()
1876 {
1877         if (self.flags & FL_JUMPRELEASED) {
1878                 if (self.BUTTON_JUMP && !self.version_mismatch) {
1879                         self.welcomemessage_time = 0;
1880                         self.flags = self.flags - FL_JUMPRELEASED;
1881                         LeaveSpectatorMode();
1882                         return;
1883                 } else if(self.BUTTON_ATCK) {
1884                         self.welcomemessage_time = 0;
1885                         self.flags = self.flags - FL_JUMPRELEASED;
1886                         if(SpectateNext() == 1) {
1887                                 self.classname = "spectator";
1888                         } else {
1889                                 self.classname = "observer";
1890                                 PutClientInServer();
1891                         }
1892                 } else if (self.BUTTON_ATCK2) {
1893                         self.welcomemessage_time = 0;
1894                         self.flags = self.flags - FL_JUMPRELEASED;
1895                         self.classname = "observer";
1896                         PutClientInServer();
1897                 } else {
1898                         if(!SpectateUpdate())
1899                                 PutObserverInServer();
1900                 }
1901         } else {
1902                 if (!(self.BUTTON_ATCK || self.BUTTON_ATCK2)) {
1903                         self.flags = self.flags | FL_JUMPRELEASED;
1904                 }
1905         }
1906         if(self.BUTTON_ZOOM)
1907                 self.wantswelcomemessage = 0;
1908         if(self.wantswelcomemessage)
1909                 PrintWelcomeMessage(self);
1910         self.flags = self.flags | FL_CLIENT | FL_NOTARGET;
1911 }
1912
1913 /*
1914 =============
1915 PlayerPreThink
1916
1917 Called every frame for each client before the physics are run
1918 =============
1919 */
1920 void() ctf_setstatus;
1921 .float vote_nagtime;
1922 .float spectatee_status;
1923 void PlayerPreThink (void)
1924 {
1925         self.stat_sys_ticrate = cvar("sys_ticrate");
1926         if(blockSpectators)
1927                 checkSpectatorBlock();
1928
1929         if(self.netname_previous != self.netname)
1930         {
1931                 if(cvar("sv_eventlog"))
1932                         GameLogEcho(strcat(":name:", ftos(self.playerid), ":", self.netname), TRUE);
1933                 if(self.netname_previous)
1934                         strunzone(self.netname_previous);
1935                 self.netname_previous = strzone(self.netname);
1936         }
1937
1938         // version nagging
1939         if(self.version_nagtime)
1940                 if(self.cvar_g_nexuizversion)
1941                         if(time > self.version_nagtime)
1942                         {
1943                                 if(strstr(self.cvar_g_nexuizversion, "svn", 0) < 0)
1944                                 {
1945                                         if(strstr(cvar_string("g_nexuizversion"), "svn", 0) >= 0)
1946                                         {
1947                                                 dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Nexuiz ", cvar_string("g_nexuizversion"), " (beta)^7, you have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1\n");
1948                                                 sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Nexuiz ", cvar_string("g_nexuizversion"), " (beta)^7, you have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1\n"));
1949                                         }
1950                                         else
1951                                         {
1952                                                 float r;
1953                                                 r = vercmp(self.cvar_g_nexuizversion, cvar_string("g_nexuizversion"));
1954                                                 if(r < 0)
1955                                                 {
1956                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - ^3Nexuiz ", cvar_string("g_nexuizversion"), "^7 is out, and you still have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1 - get the update from ^4http://www.nexuiz.com/^1!\n");
1957                                                         sprint(self, strcat("\{1}^1NOTE: ^3Nexuiz ", cvar_string("g_nexuizversion"), "^7 is out, and you still have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1 - get the update from ^4http://www.nexuiz.com/^1!\n"));
1958                                                 }
1959                                                 else if(r > 0)
1960                                                 {
1961                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Nexuiz ", cvar_string("g_nexuizversion"), "^7, you have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1\n");
1962                                                         sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Nexuiz ", cvar_string("g_nexuizversion"), "^7, you have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1\n"));
1963                                                 }
1964                                         }
1965                                 }
1966                                 self.version_nagtime = 0;
1967                         }
1968
1969         // vote nagging
1970         if(self.cvar_scr_centertime)
1971                 if(time > self.vote_nagtime)
1972                 {
1973                         VoteNag();
1974                         self.vote_nagtime = time + self.cvar_scr_centertime * 0.6;
1975                 }
1976
1977         // GOD MODE info
1978         if(!(self.flags & FL_GODMODE)) if(self.max_armorvalue)
1979         {
1980                 sprint(self, strcat("godmode saved you ", ftos(self.max_armorvalue), " units of damage, cheater!\n"));
1981                 self.max_armorvalue = 0;
1982         }
1983
1984         if(frametime)
1985                 antilag_record(self);
1986
1987         if(self.classname == "player") {
1988 //              if(self.netname == "Wazat")
1989 //                      bprint(self.classname, "\n");
1990
1991                 CheckRules_Player();
1992
1993                 if(self.BUTTON_INFO)
1994                         PrintWelcomeMessage(self);
1995
1996                 if(g_lms || !cvar("sv_spectate"))
1997                 if((time - self.jointime) <= cvar("welcome_message_time"))
1998                         PrintWelcomeMessage(self);
1999
2000                 if (intermission_running)
2001                 {
2002                         IntermissionThink ();   // otherwise a button could be missed between
2003                         return;                                 // the think tics
2004                 }
2005
2006                 if(self.teleport_time)
2007                 if(time > self.teleport_time)
2008                 {
2009                         self.teleport_time = 0;
2010                         self.effects = self.effects - (self.effects & EF_NODRAW);
2011                         if(self.weaponentity)
2012                                 self.weaponentity.flags = self.weaponentity.flags - (self.weaponentity.flags & EF_NODRAW);
2013                 }
2014
2015                 Nixnex_GiveCurrentWeapon();
2016
2017                 if(frametime > 0) // don't do this in cl_movement frames, just in server ticks
2018                         UpdateSelectedPlayer();
2019
2020                 //don't allow the player to turn around while game is paused!
2021                 if(timeoutStatus == 2) {
2022                         self.v_angle = self.lastV_angle;
2023                         self.angles = self.lastV_angle;
2024                         self.fixangle = TRUE;
2025                 }
2026
2027                 if (self.deadflag != DEAD_NO)
2028                 {
2029                         float button_pressed, force_respawn;
2030                         player_anim();
2031                         button_pressed = (self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE);
2032                         force_respawn = (g_lms || cvar("g_forced_respawn"));
2033                         if (self.deadflag == DEAD_DYING)
2034                         {
2035                                 if(force_respawn)
2036                                         self.deadflag = DEAD_RESPAWNING;
2037                                 else if(!button_pressed)
2038                                         self.deadflag = DEAD_DEAD;
2039                         }
2040                         else if (self.deadflag == DEAD_DEAD)
2041                         {
2042                                 if(button_pressed)
2043                                         self.deadflag = DEAD_RESPAWNABLE;
2044                         }
2045                         else if (self.deadflag == DEAD_RESPAWNABLE)
2046                         {
2047                                 if(!button_pressed)
2048                                         self.deadflag = DEAD_RESPAWNING;
2049                         }
2050                         else if (self.deadflag == DEAD_RESPAWNING)
2051                         {
2052                                 if(time > self.death_time)
2053                                 {
2054                                         self.death_time = time + 1; // only retry once a second
2055                                         respawn();
2056                                 }
2057                         }
2058                         ShowRespawnCountdown();
2059                         return;
2060                 }
2061
2062                 if(g_lms && !self.deadflag && cvar("g_lms_campcheck_interval"))
2063                 {
2064                         vector dist;
2065
2066                         // calculate player movement (in 2 dimensions only, so jumping on one spot doesn't count as movement)
2067                         dist = self.oldorigin - self.origin;
2068                         dist_z = 0;
2069                         self.lms_traveled_distance += fabs(vlen(dist));
2070
2071                         if((cvar("g_campaign") && !campaign_bots_may_start) || (time < restart_countdown))
2072                         {
2073                                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval")*2;
2074                                 self.lms_traveled_distance = 0;
2075                         }
2076
2077                         if(time > self.lms_nextcheck)
2078                         {
2079                                 //sprint(self, "distance: ", ftos(self.lms_traveled_distance), "\n");
2080                                 if(self.lms_traveled_distance < cvar("g_lms_campcheck_distance"))
2081                                 {
2082                                         centerprint(self, cvar_string("g_lms_campcheck_message"));
2083                                         // FIXME KadaverJack: gibbing player here causes playermodel to bounce around, instead of eye.md3
2084                                         // I wasn't able to find out WHY that happens, so I put a workaround in place that shall prevent players from being gibbed :(
2085                                         Damage(self, self, self, bound(0, cvar("g_lms_campcheck_damage"), self.health + self.armorvalue * cvar("g_balance_armor_blockpercent") + 5), DEATH_CAMP, self.origin, '0 0 0');
2086                                 }
2087                                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval");
2088                                 self.lms_traveled_distance = 0;
2089                         }
2090                 }
2091
2092                 if (self.BUTTON_CROUCH && !self.hook.state)
2093                 {
2094                         if (!self.crouch)
2095                         {
2096                                 self.crouch = TRUE;
2097                                 self.view_ofs = PL_CROUCH_VIEW_OFS;
2098                                 setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX);
2099                                 player_setanim(self.anim_duck, FALSE, TRUE, TRUE);
2100                         }
2101                 }
2102                 else
2103                 {
2104                         if (self.crouch)
2105                         {
2106                                 tracebox(self.origin, PL_MIN, PL_MAX, self.origin, FALSE, self);
2107                                 if (!trace_startsolid)
2108                                 {
2109                                         self.crouch = FALSE;
2110                                         self.view_ofs = PL_VIEW_OFS;
2111                                         setsize (self, PL_MIN, PL_MAX);
2112                                 }
2113                         }
2114                 }
2115
2116                 FixPlayermodel();
2117
2118                 GrapplingHookFrame();
2119
2120                 W_WeaponFrame();
2121
2122                 {
2123                         float zoomfactor, zoomspeed, zoomdir;
2124                         zoomfactor = self.cvar_cl_zoomfactor;
2125                         if(zoomfactor < 1 || zoomfactor > 16)
2126                                 zoomfactor = 2.5;
2127                         zoomspeed = self.cvar_cl_zoomspeed;
2128                         if(zoomspeed >= 0) // < 0 is instant zoom
2129                                 if(zoomspeed < 0.5 || zoomspeed > 16)
2130                                         zoomspeed = 3.5;
2131
2132                         zoomdir = self.BUTTON_ZOOM;
2133                         if(self.BUTTON_ATCK2)
2134                                 if(self.weapon == WEP_NEX)
2135                                         if(!g_minstagib)
2136                                                 zoomdir = 1;
2137
2138                         if(zoomdir)
2139                                 self.has_zoomed = 1;
2140
2141                         if(self.has_zoomed)
2142                         {
2143                                 if(zoomspeed <= 0) // instant zoom
2144                                 {
2145                                         if(zoomdir)
2146                                                 self.viewzoom = 1 / zoomfactor;
2147                                         else
2148                                                 self.viewzoom = 1;
2149                                 }
2150                                 else
2151                                 {
2152                                         // geometric zoom would be:
2153                                         //   self.viewzoom = bound(1 / zoomfactor, self.viewzoom * pow(zoomfactor, (zoomdir ? -1 : 1) * frametime * zoomspeed), 1);
2154                                         // however, testing showed that arithmetic/harmonic zoom works better
2155                                         if(zoomdir)
2156                                                 // self.viewzoom = 1 / bound(1, 1 / self.viewzoom + (zoomdir ? 1 : -1) * frametime * zoomspeed * (zoomfactor - 1), zoomfactor);
2157                                                 // zoom in = arithmetic: 1x, 2x, 3x, 4x, ..., 8x
2158                                                 self.viewzoom = 1 / bound(1, 1 / self.viewzoom + frametime * zoomspeed * (zoomfactor - 1), zoomfactor);
2159                                         else
2160                                                 // self.viewzoom = bound(1 / zoomfactor, self.viewzoom + (zoomdir ? -1 : 1) * frametime * zoomspeed * (1 - 1 / zoomfactor), 1);
2161                                                 // zoom out = harmonic: 8/1x, 8/2x, 8/3x, 8/4x, ..., 8/8x
2162                                                 self.viewzoom = bound(1 / zoomfactor, self.viewzoom + frametime * zoomspeed * (1 - 1 / zoomfactor), 1);
2163                                 }
2164                         }
2165                         else
2166                                 self.viewzoom = min(1, self.viewzoom + frametime); // spawn zoom-in
2167                 }
2168
2169                 player_powerups();
2170                 player_regen();
2171                 player_anim();
2172
2173                 if (g_minstagib)
2174                         minstagib_ammocheck();
2175
2176                 ctf_setstatus();
2177                 kh_setstatus();
2178
2179                 //self.angles_y=self.v_angle_y + 90;   // temp
2180
2181                 //if (TetrisPreFrame()) return;
2182         } else if(gameover) {
2183                 if (intermission_running)
2184                         IntermissionThink ();   // otherwise a button could be missed between
2185                 return;
2186         } else if(self.classname == "observer") {
2187                 ObserverThink();
2188         } else if(self.classname == "spectator") {
2189                 SpectatorThink();
2190         }
2191
2192         float oldspectatee_status;
2193         oldspectatee_status = self.spectatee_status;
2194         if(self.classname == "spectator")
2195                 self.spectatee_status = num_for_edict(self.enemy);
2196         else if(self.classname == "observer")
2197                 self.spectatee_status = num_for_edict(self);
2198         else
2199                 self.spectatee_status = 0;
2200         if(self.spectatee_status != oldspectatee_status)
2201         {
2202                 msg_entity = self;
2203                 WriteByte(MSG_ONE, SVC_TEMPENTITY);
2204                 WriteByte(MSG_ONE, TE_CSQC_SPECTATING);
2205                 WriteByte(MSG_ONE, self.spectatee_status);
2206                 if(g_race)
2207                         race_InitSpectator();
2208         }
2209 }
2210
2211
2212 /*
2213 =============
2214 PlayerPostThink
2215
2216 Called every frame for each client after the physics are run
2217 =============
2218 */
2219 .float idlekick_lasttimeleft;
2220 .float race_penalty;
2221 .float race_penalty_nagged;
2222 void PlayerPostThink (void)
2223 {
2224         // Savage: Check for nameless players
2225         if (strlen(self.netname) < 1) {
2226                 self.netname = "Player";
2227                 stuffcmd(self, "seta _cl_name Player\n");
2228         }
2229
2230         if(sv_maxidle)
2231         {
2232                 float timeleft;
2233                 timeleft = ceil(sv_maxidle - (time - self.parm_idlesince));
2234                 if(timeleft <= 0)
2235                 {
2236                         bprint("^3", self.netname, "^3 was kicked for idling.\n");
2237                         announce(self, "announcer/robotic/terminated.ogg");
2238                         dropclient(self);
2239                         return;
2240                 }
2241                 else if(timeleft <= 10)
2242                 {
2243                         if(timeleft != self.idlekick_lasttimeleft)
2244                         {
2245                                 centerprint_atprio(self, CENTERPRIO_IDLEKICK, strcat("^3Stop idling!\n^3Disconnecting in ", ftos(timeleft), "..."));
2246                                 announce(self, strcat("announcer/robotic/", ftos(timeleft), ".ogg"));
2247                         }
2248                 }
2249                 else
2250                 {
2251                         centerprint_expire(self, CENTERPRIO_IDLEKICK);
2252                 }
2253                 self.idlekick_lasttimeleft = timeleft;
2254         }
2255
2256         if(self.classname == "player") {
2257                 CheckRules_Player();
2258                 UpdateChatBubble();
2259                 UpdateTeamBubble();
2260                 if (self.impulse)
2261                         ImpulseCommands();
2262                 if (intermission_running)
2263                         return;         // intermission or finale
2264
2265                 //PrintWelcomeMessage(self);
2266                 //if (TetrisPostFrame()) return;
2267
2268                 // restart countdown
2269                 if (restart_countdown) {
2270                         if(time < restart_countdown) {
2271                                 if (!cvar("sv_ready_restart_after_countdown"))
2272                                 {
2273                                         if(self.movement != '0 0 0' && g_race && !g_race_qualifying)
2274                                         {
2275                                                 if(time < restart_countdown - 2)
2276                                                 {
2277                                                         if(!self.race_penalty_nagged)
2278                                                         {
2279                                                                 centerprint_atprio(self, CENTERPRIO_IDLEKICK, "^1DO NOT MOVE DURING THE COUNTDOWN.");
2280                                                                 self.race_penalty_nagged = 1;
2281                                                         }
2282                                                 }
2283                                                 else if(!self.race_penalty)
2284                                                 {
2285                                                         centerprint_atprio(self, CENTERPRIO_IDLEKICK, "^1FIVE SECONDS PENALTY.");
2286                                                         self.race_penalty = time + 5;
2287                                                 }
2288                                         }
2289                                         self.movetype = MOVETYPE_NONE;
2290                                         self.velocity = '0 0 0';
2291                                         self.avelocity = '0 0 0';
2292                                         self.movement = '0 0 0';
2293                                 }
2294                         }
2295                         else if (time < self.race_penalty)
2296                         {
2297                                 self.movetype = MOVETYPE_NONE;
2298                                 self.velocity = '0 0 0';
2299                                 self.avelocity = '0 0 0';
2300                                 self.movement = '0 0 0';
2301                         }
2302                         else
2303                         {
2304                                 //allow the player to move again if sv_ready_restart_after_countdown is not used and countdown is over
2305                                 if (!cvar("sv_ready_restart_after_countdown"))
2306                                 {
2307                                         if(self.movetype == MOVETYPE_NONE)
2308                                         {
2309                                                 self.movetype = MOVETYPE_WALK;
2310                                         }
2311                                         self.race_penalty = 0;
2312                                         self.race_penalty_nagged = 0;
2313                                 }
2314                         }
2315                 }
2316
2317         } else if (self.classname == "observer") {
2318                 //do nothing
2319         } else if (self.classname == "spectator") {
2320                 //do nothing
2321         }
2322
2323         /*
2324         float i;
2325         for(i = 0; i < 1000; ++i)
2326         {
2327                 vector end;
2328                 end = self.origin + '0 0 1024' + 512 * randomvec();
2329                 tracebox(self.origin, self.mins, self.maxs, end, MOVE_NORMAL, self);
2330                 if(trace_fraction < 1)
2331                 if(!(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
2332                 {
2333                         print("I HIT SOLID: ", vtos(self.origin), " -> ", vtos(end), "\n");
2334                         break;
2335                 }
2336         }
2337         */
2338
2339         Arena_Warmup();
2340 }