data/qcsrc/server/cl_client.qc

   1 // let's abuse an existing field
   2 #define SPAWNPOINT_SCORE frags
   3
   4 .float wantswelcomemessage;
   5 .string netname_previous;
   6
   7 void spawnfunc_info_player_survivor (void)
   8 {
   9         spawnfunc_info_player_deathmatch();
  10 }
  11
  12 void spawnfunc_info_player_start (void)
  13 {
  14         spawnfunc_info_player_deathmatch();
  15 }
  16
  17 void spawnfunc_info_player_deathmatch (void)
  18 {
  19         self.classname = "info_player_deathmatch";
  20         relocate_spawnpoint();
  21 }
  22
  23 void spawnpoint_use()
  24 {
  25         if(teams_matter)
  26         if(have_team_spawns)
  27         {
  28                 self.team = activator.team;
  29                 some_spawn_has_been_used = 1;
  30         }
  31 };
  32
  33 // Returns:
  34 //   -1 if a spawn can't be used
  35 //   otherwise, a weight of the spawnpoint
  36 float Spawn_Score(entity spot, entity playerlist, float teamcheck)
  37 {
  38         float shortest, thisdist;
  39         entity player;
  40
  41         // filter out spots for the wrong team
  42         if(teamcheck)
  43         if(spot.team != teamcheck)
  44                 return -1;
  45
  46         if(race_spawns)
  47                 if(spot.target == "")
  48                         return -1;
  49
  50         // filter out spots for assault
  51         if(spot.target != "") {
  52                 local entity ent;
  53                 float good;
  54                 ent = find(world, targetname, spot.target);
  55                 while(ent) {
  56                         if(ent.classname == "target_objective")
  57                         {
  58                                 if(ent.health < 0 || ent.health >= ASSAULT_VALUE_INACTIVE)
  59                                         return -1;
  60                                 good = 1;
  61                         }
  62                         else if(ent.classname == "trigger_race_checkpoint")
  63                         {
  64                                 if(self.classname == "player") // spectators may spawn everywhere
  65                                 {
  66                                         if(ent.race_checkpoint != race_PreviousCheckpoint(self.race_checkpoint))
  67                                                 return -1;
  68                                         float pl;
  69                                         pl = self.race_place;
  70                                         if(pl > race_highest_place_spawn)
  71                                                 pl = 0;
  72                                         if(spot.race_place != pl)
  73                                                 return -1;
  74                                 }
  75                                 good = 1;
  76                         }
  77                         else
  78                         {
  79                         }
  80                         ent = find(ent, targetname, spot.target);
  81                 }
  82
  83                 if(!good)
  84                         return -1;
  85         }
  86
  87         player = playerlist;
  88         shortest = vlen(world.maxs - world.mins);
  89         for(player = playerlist; player; player = player.chain)
  90                 if (player != self)
  91                 {
  92                         thisdist = vlen(player.origin - spot.origin);
  93                         if (thisdist < shortest)
  94                                 shortest = thisdist;
  95                 }
  96         return shortest;
  97 }
  98
  99 float spawn_allbad;
 100 float spawn_allgood;
 101 entity Spawn_FilterOutBadSpots(entity firstspot, entity playerlist, float mindist, float teamcheck)
 102 {
 103         local entity spot, spotlist, spotlistend;
 104         spawn_allgood = TRUE;
 105         spawn_allbad = TRUE;
 106
 107         spotlist = world;
 108         spotlistend = world;
 109
 110         for(spot = firstspot; spot; spot = spot.chain)
 111         {
 112                 spot.SPAWNPOINT_SCORE = Spawn_Score(spot, playerlist, teamcheck);
 113
 114                 if(cvar("spawn_debugview"))
 115                 {
 116                         setmodel(spot, "models/runematch/rune.mdl");
 117                         if(spot.SPAWNPOINT_SCORE < mindist)
 118                         {
 119                                 spot.colormod = '1 0 0';
 120                                 spot.scale = 1;
 121                         }
 122                         else
 123                         {
 124                                 spot.colormod = '0 1 0';
 125                                 spot.scale = spot.SPAWNPOINT_SCORE / mindist;
 126                         }
 127                 }
 128
 129                 if(spot.SPAWNPOINT_SCORE >= 0) // spawning allowed here
 130                 {
 131                         if(spot.SPAWNPOINT_SCORE < mindist)
 132                         {
 133                                 // too short distance
 134                                 spawn_allgood = FALSE;
 135                         }
 136                         else
 137                         {
 138                                 // perfect
 139                                 spawn_allbad = FALSE;
 140
 141                                 if(spotlistend)
 142                                         spotlistend.chain = spot;
 143                                 spotlistend = spot;
 144                                 if(!spotlist)
 145                                         spotlist = spot;
 146
 147                                 /*
 148                                 if(teamcheck)
 149                                 if(spot.team != teamcheck)
 150                                         error("invalid spawn added");
 151
 152                                 print("added ", etos(spot), "\n");
 153                                 */
 154                         }
 155                 }
 156         }
 157         if(spotlistend)
 158                 spotlistend.chain = world;
 159
 160         /*
 161                 entity e;
 162                 if(teamcheck)
 163                         for(e = spotlist; e; e = e.chain)
 164                         {
 165                                 print("seen ", etos(e), "\n");
 166                                 if(e.team != teamcheck)
 167                                         error("invalid spawn found");
 168                         }
 169         */
 170
 171         return spotlist;
 172 }
 173
 174 entity Spawn_WeightedPoint(entity firstspot, float lower, float upper, float exponent)
 175 {
 176         // weight of a point: bound(lower, mindisttoplayer, upper)^exponent
 177         // multiplied by spot.cnt (useful if you distribute many spawnpoints in a small area)
 178         local entity spot;
 179
 180         RandomSelection_Init();
 181         for(spot = firstspot; spot; spot = spot.chain)
 182                 RandomSelection_Add(spot, 0, pow(bound(lower, spot.SPAWNPOINT_SCORE, upper), exponent) * spot.cnt, spot.SPAWNPOINT_SCORE >= lower);
 183
 184         return RandomSelection_chosen_ent;
 185 }
 186
 187 /*
 188 =============
 189 SelectSpawnPoint
 190
 191 Finds a point to respawn
 192 =============
 193 */
 194 entity SelectSpawnPoint (float anypoint)
 195 {
 196         local float teamcheck;
 197         local entity firstspot_new;
 198         local entity spot, firstspot, playerlist;
 199
 200         spot = find (world, classname, "testplayerstart");
 201         if (spot)
 202                 return spot;
 203
 204         teamcheck = 0;
 205
 206         if(!anypoint && have_team_spawns)
 207                 teamcheck = self.team;
 208
 209         // get the list of players
 210         playerlist = findchain(classname, "player");
 211         // get the entire list of spots
 212         firstspot = findchain(classname, "info_player_deathmatch");
 213         // filter out the bad ones
 214         // (note this returns the original list if none survived)
 215         firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, 100, teamcheck);
 216         if(!firstspot_new)
 217                 firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, -1, teamcheck);
 218         firstspot = firstspot_new;
 219
 220         // there is 50/50 chance of choosing a random spot or the furthest spot
 221         // (this means that roughly every other spawn will be furthest, so you
 222         // usually won't get fragged at spawn twice in a row)
 223         if (arena_roundbased)
 224         {
 225                 firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, 800, teamcheck);
 226                 if(firstspot_new)
 227                         firstspot = firstspot_new;
 228                 spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 229         }
 230         else if (random() > cvar("g_spawn_furthest"))
 231                 spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 232         else
 233                 spot = Spawn_WeightedPoint(firstspot, 1, 5000, 5); // chooses a far far away spawnpoint
 234
 235         if(cvar("spawn_debugview"))
 236         {
 237                 print("spot mindistance: ", ftos(spot.SPAWNPOINT_SCORE), "\n");
 238
 239                 entity e;
 240                 if(teamcheck)
 241                         for(e = firstspot; e; e = e.chain)
 242                                 if(e.team != teamcheck)
 243                                         error("invalid spawn found");
 244         }
 245
 246         if (!spot)
 247         {
 248                 if(cvar("spawn_debug"))
 249                         GotoNextMap();
 250                 else
 251                 {
 252                         if(some_spawn_has_been_used)
 253                                 return world; // team can't spawn any more, because of actions of other team
 254                         else
 255                                 error("Cannot find a spawn point - please fix the map!");
 256                 }
 257         }
 258
 259         return spot;
 260 }
 261
 262 /*
 263 =============
 264 CheckPlayerModel
 265
 266 Checks if the argument string can be a valid playermodel.
 267 Returns a valid one in doubt.
 268 =============
 269 */
 270 string FallbackPlayerModel = "models/player/marine.zym";
 271 string CheckPlayerModel(string plyermodel) {
 272         if(strlen(plyermodel) < 4)
 273                 return FallbackPlayerModel;
 274         if( substring(plyermodel,0,14) != "models/player/")
 275                 return FallbackPlayerModel;
 276         else if(cvar("sv_servermodelsonly"))
 277         {
 278                 if(substring(plyermodel,strlen(plyermodel)-4,4) != ".zym")
 279                 if(substring(plyermodel,strlen(plyermodel)-4,4) != ".dpm")
 280                 if(substring(plyermodel,strlen(plyermodel)-4,4) != ".md3")
 281                 if(substring(plyermodel,strlen(plyermodel)-4,4) != ".psk")
 282                         return FallbackPlayerModel;
 283                 if(!fexists(plyermodel))
 284                         return FallbackPlayerModel;
 285         }
 286         return plyermodel;
 287 }
 288
 289 /*
 290 =============
 291 Client_customizeentityforclient
 292
 293 LOD reduction
 294 =============
 295 */
 296 float Client_customizeentityforclient()
 297 {
 298 #ifdef ALLOW_VARIABLE_LOD
 299         // self: me
 300         // other: the player viewing me
 301         float distance;
 302         float f;
 303
 304         if(self.flags & FL_NOTARGET) // we don't need LOD for spectators
 305                 return TRUE;
 306
 307         if(other.cvar_cl_playerdetailreduction <= 0)
 308         {
 309                 if(other.cvar_cl_playerdetailreduction <= -2)
 310                         self.modelindex = self.modelindex_lod2;
 311                 else if(other.cvar_cl_playerdetailreduction <= -1)
 312                         self.modelindex = self.modelindex_lod1;
 313                 else
 314                         self.modelindex = self.modelindex_lod0;
 315         }
 316         else
 317         {
 318                 distance = vlen(self.origin - other.origin);
 319                 f = (distance + 100.0) * other.cvar_cl_playerdetailreduction;
 320                 if(f > 10000)
 321                         self.modelindex = self.modelindex_lod2;
 322                 else if(f > 5000)
 323                         self.modelindex = self.modelindex_lod1;
 324                 else
 325                         self.modelindex = self.modelindex_lod0;
 326         }
 327 #endif
 328
 329         return TRUE;
 330 }
 331
 332 void UpdatePlayerSounds();
 333 void setmodel_lod(entity e, string modelname)
 334 {
 335 #ifdef ALLOW_VARIABLE_LOD
 336         string s;
 337
 338         // FIXME: this only supports 3-letter extensions
 339         s = strcat(substring(modelname, 0, strlen(modelname) - 4), "_1", substring(modelname, 0, strlen(modelname) - 4));
 340         if(fexists(s))
 341         {
 342                 precache_model(s);
 343                 setmodel(e, s); // players have high precision
 344                 self.modelindex_lod1 = self.modelindex;
 345         }
 346         else
 347                 self.modelindex_lod1 = -1;
 348
 349         s = strcat(substring(modelname, 0, strlen(modelname) - 4), "_2", substring(modelname, 0, strlen(modelname) - 4));
 350         if(fexists(s))
 351         {
 352                 precache_model(s);
 353                 setmodel(e, s); // players have high precision
 354                 self.modelindex_lod2 = self.modelindex;
 355         }
 356         else
 357                 self.modelindex_lod2 = -1;
 358
 359         precache_model(modelname);
 360         setmodel(e, modelname); // players have high precision
 361         self.modelindex_lod0 = self.modelindex;
 362
 363         if(self.modelindex_lod1 < 0)
 364                 self.modelindex_lod1 = self.modelindex;
 365
 366         if(self.modelindex_lod2 < 0)
 367                 self.modelindex_lod2 = self.modelindex;
 368 #else
 369         precache_model(modelname);
 370         setmodel(e, modelname); // players have high precision
 371 #endif
 372         player_setupanimsformodel();
 373         UpdatePlayerSounds();
 374 }
 375
 376 /*
 377 =============
 378 PutObserverInServer
 379
 380 putting a client as observer in the server
 381 =============
 382 */
 383 void PutObserverInServer (void)
 384 {
 385         entity  spot;
 386
 387         race_PreSpawnObserver();
 388
 389         spot = SelectSpawnPoint (TRUE);
 390         if(!spot)
 391                 error("No spawnpoints for observers?!?\n");
 392         RemoveGrapplingHook(self); // Wazat's Grappling Hook
 393
 394         if(clienttype(self) == CLIENTTYPE_REAL)
 395         {
 396                 msg_entity = self;
 397                 WriteByte(MSG_ONE, SVC_SETVIEW);
 398                 WriteEntity(MSG_ONE, self);
 399         }
 400
 401         DropAllRunes(self);
 402         kh_Key_DropAll(self, TRUE);
 403
 404         Portal_ClearAll(self);
 405
 406         if(self.flagcarried)
 407                 DropFlag(self.flagcarried);
 408
 409         WaypointSprite_PlayerDead();
 410
 411         if(self.killcount != -666)
 412         {
 413                 if(g_lms)
 414                 {
 415                         if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
 416                                 bprint ("^4", self.netname, "^4 has no more lives left\n");
 417                         else
 418                                 bprint ("^4", self.netname, "^4 is spectating now\n"); // TODO turn this into a proper forfeit?
 419                 }
 420                 else
 421                         bprint ("^4", self.netname, "^4 is spectating now\n");
 422         }
 423
 424         PlayerScore_Clear(self); // clear scores when needed
 425
 426         self.spectatortime = time;
 427
 428         self.classname = "observer";
 429         self.health = -666;
 430         self.takedamage = DAMAGE_NO;
 431         self.solid = SOLID_NOT;
 432         self.movetype = MOVETYPE_NOCLIP;
 433         self.flags = FL_CLIENT | FL_NOTARGET;
 434         self.armorvalue = 666;
 435         self.effects = 0;
 436         self.armorvalue = cvar("g_balance_armor_start");
 437         self.pauserotarmor_finished = 0;
 438         self.pauserothealth_finished = 0;
 439         self.pauseregen_finished = 0;
 440         self.damageforcescale = 0;
 441         self.death_time = 0;
 442         self.dead_frame = 0;
 443         self.alpha = 0;
 444         self.scale = 0;
 445         self.fade_time = 0;
 446         self.pain_frame = 0;
 447         self.pain_finished = 0;
 448         self.strength_finished = 0;
 449         self.invincible_finished = 0;
 450         self.pushltime = 0;
 451         self.think = SUB_Null;
 452         self.nextthink = 0;
 453         self.hook_time = 0;
 454         self.runes = 0;
 455         self.deadflag = DEAD_NO;
 456         self.angles = spot.angles;
 457         self.angles_z = 0;
 458         self.fixangle = TRUE;
 459         self.crouch = FALSE;
 460
 461         self.view_ofs = PL_VIEW_OFS;
 462         setorigin (self, spot.origin);
 463         setsize (self, '0 0 0', '0 0 0');
 464         self.oldorigin = self.origin;
 465         self.items = 0;
 466         self.weapons = 0;
 467         self.model = "";
 468         self.modelindex = 0;
 469         self.weapon = 0;
 470         self.weaponmodel = "";
 471         self.weaponentity = world;
 472         self.killcount = -666;
 473         self.velocity = '0 0 0';
 474         self.avelocity = '0 0 0';
 475         self.punchangle = '0 0 0';
 476         self.punchvector = '0 0 0';
 477         self.oldvelocity = self.velocity;
 478         self.customizeentityforclient = Client_customizeentityforclient;
 479         self.wantswelcomemessage = 1;
 480
 481         if(g_arena)
 482         {
 483                 if(self.version_mismatch)
 484                 {
 485                         Spawnqueue_Unmark(self);
 486                         Spawnqueue_Remove(self);
 487                 }
 488                 else
 489                 {
 490                         Spawnqueue_Insert(self);
 491                 }
 492         }
 493         else if(g_lms)
 494         {
 495                 // Only if the player cannot play at all
 496                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) == 666)
 497                         self.frags = -666;
 498                 else
 499                         self.frags = -667;
 500         }
 501         else
 502                 self.frags = -666;
 503 }
 504
 505 float RestrictSkin(float s)
 506 {
 507         if(!teams_matter)
 508                 return s;
 509         if(s == 6)
 510                 return 6;
 511         return mod(s, 3);
 512 }
 513
 514 void FixPlayermodel()
 515 {
 516         local string defaultmodel;
 517         local float defaultskin;
 518         local vector m1, m2;
 519
 520         defaultmodel = "";
 521
 522         if(cvar("sv_defaultcharacter") == 1) {
 523                 defaultskin = 0;
 524
 525                 if(teams_matter)
 526                 {
 527                         defaultmodel = cvar_string(strcat("sv_defaultplayermodel_", Team_ColorNameLowerCase(self.team)));
 528                         defaultskin = cvar(strcat("sv_defaultplayerskin_", Team_ColorNameLowerCase(self.team)));
 529                 }
 530
 531                 if(defaultmodel == "")
 532                 {
 533                         defaultmodel = cvar_string("sv_defaultplayermodel");
 534                         defaultskin = cvar("sv_defaultplayerskin");
 535                 }
 536         }
 537
 538         if(defaultmodel != "")
 539         {
 540                 if (defaultmodel != self.model)
 541                 {
 542                         m1 = self.mins;
 543                         m2 = self.maxs;
 544                         setmodel_lod (self, defaultmodel);
 545                         setsize (self, m1, m2);
 546                 }
 547
 548                 self.skin = defaultskin;
 549         } else {
 550                 if (self.playermodel != self.model)
 551                 {
 552                         self.playermodel = CheckPlayerModel(self.playermodel);
 553                         m1 = self.mins;
 554                         m2 = self.maxs;
 555                         setmodel_lod (self, self.playermodel);
 556                         setsize (self, m1, m2);
 557                 }
 558
 559                 self.skin = RestrictSkin(stof(self.playerskin));
 560         }
 561
 562         if(!teams_matter)
 563                 if(strlen(cvar_string("sv_defaultplayercolors")))
 564                         if(self.clientcolors != cvar("sv_defaultplayercolors"))
 565                                 setcolor(self, cvar("sv_defaultplayercolors"));
 566 }
 567
 568 /*
 569 =============
 570 PutClientInServer
 571
 572 Called when a client spawns in the server
 573 =============
 574 */
 575 //void() ctf_playerchanged;
 576 void PutClientInServer (void)
 577 {
 578         if(clienttype(self) == CLIENTTYPE_BOT)
 579         {
 580                 self.classname = "player";
 581         }
 582         else if(clienttype(self) == CLIENTTYPE_REAL)
 583         {
 584                 msg_entity = self;
 585                 WriteByte(MSG_ONE, SVC_SETVIEW);
 586                 WriteEntity(MSG_ONE, self);
 587         }
 588
 589         // player is dead and becomes observer
 590         // FIXME fix LMS scoring for new system
 591         if(g_lms)
 592         {
 593                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
 594                         self.classname = "observer";
 595         }
 596
 597         if(g_arena)
 598         if(!self.spawned)
 599                 self.classname = "observer";
 600
 601         if(self.classname == "player") {
 602                 entity  spot;
 603
 604                 race_PreSpawn();
 605
 606                 spot = SelectSpawnPoint (FALSE);
 607                 if(!spot)
 608                 {
 609                         centerprint(self, "Sorry, no spawnpoints available!\nHope your team can fix it...");
 610                         return; // spawn failed
 611                 }
 612
 613                 RemoveGrapplingHook(self); // Wazat's Grappling Hook
 614
 615                 self.classname = "player";
 616                 self.iscreature = TRUE;
 617                 self.movetype = MOVETYPE_WALK;
 618                 self.solid = SOLID_SLIDEBOX;
 619                 if(independent_players)
 620                         MAKE_INDEPENDENT_PLAYER(self);
 621                 self.flags = FL_CLIENT;
 622                 self.takedamage = DAMAGE_AIM;
 623                 if(g_minstagib)
 624                         self.effects = EF_FULLBRIGHT;
 625                 else
 626                         self.effects = 0;
 627                 self.air_finished = time + 12;
 628                 self.dmg = 2;
 629
 630                 if(inWarmupStage)
 631                 {
 632                         self.ammo_shells = warmup_start_ammo_shells;
 633                         self.ammo_nails = warmup_start_ammo_nails;
 634                         self.ammo_rockets = warmup_start_ammo_rockets;
 635                         self.ammo_cells = warmup_start_ammo_cells;
 636                         self.health = warmup_start_health;
 637                         self.armorvalue = warmup_start_armorvalue;
 638                         self.weapons = warmup_start_weapons;
 639                 }
 640                 else
 641                 {
 642                         self.ammo_shells = start_ammo_shells;
 643                         self.ammo_nails = start_ammo_nails;
 644                         self.ammo_rockets = start_ammo_rockets;
 645                         self.ammo_cells = start_ammo_cells;
 646                         self.health = start_health;
 647                         self.armorvalue = start_armorvalue;
 648                         self.weapons = start_weapons;
 649                 }
 650                 self.items = start_items;
 651                 self.switchweapon = w_getbestweapon(self);
 652                 self.cnt = self.switchweapon;
 653                 self.weapon = 0;
 654                 self.jump_interval = time;
 655
 656                 self.spawnshieldtime = time + cvar("g_spawnshieldtime");
 657                 self.pauserotarmor_finished = time + cvar("g_balance_pause_armor_rot_spawn");
 658                 self.pauserothealth_finished = time + cvar("g_balance_pause_health_rot_spawn");
 659                 self.pauseregen_finished = time + cvar("g_balance_pause_health_regen_spawn");
 660                 //extend the pause of rotting if client was reset at the beginning of the countdown
 661                 if(!cvar("sv_ready_restart_after_countdown") && time < restart_countdown) {
 662                         self.spawnshieldtime += RESTART_COUNTDOWN;
 663                         self.pauserotarmor_finished += RESTART_COUNTDOWN;
 664                         self.pauserothealth_finished += RESTART_COUNTDOWN;
 665                         self.pauseregen_finished += RESTART_COUNTDOWN;
 666                 }
 667                 self.damageforcescale = 2;
 668                 self.death_time = 0;
 669                 self.dead_frame = 0;
 670                 self.alpha = 0;
 671                 self.scale = 0;
 672                 self.fade_time = 0;
 673                 self.pain_frame = 0;
 674                 self.pain_finished = 0;
 675                 self.strength_finished = 0;
 676                 self.invincible_finished = 0;
 677                 self.pushltime = 0;
 678                 //self.speed_finished = 0;
 679                 //self.slowmo_finished = 0;
 680                 // players have no think function
 681                 self.think = SUB_Null;
 682                 self.nextthink = 0;
 683                 self.hook_time = 0;
 684
 685                 self.runes = 0;
 686
 687                 self.deadflag = DEAD_NO;
 688
 689                 self.angles = spot.angles;
 690
 691                 self.angles_z = 0; // never spawn tilted even if the spot says to
 692                 self.fixangle = TRUE; // turn this way immediately
 693                 self.velocity = '0 0 0';
 694                 self.avelocity = '0 0 0';
 695                 self.punchangle = '0 0 0';
 696                 self.punchvector = '0 0 0';
 697                 self.oldvelocity = self.velocity;
 698
 699                 msg_entity = self;
 700                 WRITESPECTATABLE_MSG_ONE({
 701                         WriteByte(MSG_ONE, SVC_TEMPENTITY);
 702                         WriteByte(MSG_ONE, TE_CSQC_SPAWN);
 703                 });
 704
 705                 self.customizeentityforclient = Client_customizeentityforclient;
 706
 707                 self.model = "";
 708                 FixPlayermodel();
 709
 710                 self.crouch = FALSE;
 711                 self.view_ofs = PL_VIEW_OFS;
 712                 setsize (self, PL_MIN, PL_MAX);
 713                 self.spawnorigin = spot.origin;
 714                 setorigin (self, spot.origin + '0 0 1' * (1 - self.mins_z - 24));
 715                 // don't reset back to last position, even if new position is stuck in solid
 716                 self.oldorigin = self.origin;
 717
 718                 if(g_arena)
 719                 {
 720                         Spawnqueue_Remove(self);
 721                         Spawnqueue_Mark(self);
 722                 }
 723
 724                 self.event_damage = PlayerDamage;
 725
 726                 self.bot_attack = TRUE;
 727
 728                 self.statdraintime = time + 5;
 729                 self.BUTTON_ATCK = self.BUTTON_JUMP = self.BUTTON_ATCK2 = 0;
 730
 731                 if(self.killcount == -666) {
 732                         PlayerScore_Clear(self);
 733                         self.killcount = 0;
 734                         self.frags = 0;
 735                 }
 736
 737                 self.cnt = WEP_LASER;
 738                 self.nixnex_lastchange_id = -1;
 739
 740                 CL_SpawnWeaponentity();
 741                 self.alpha = default_player_alpha;
 742                 self.colormod = '1 1 1' * cvar("g_player_brightness");
 743                 self.exteriorweaponentity.alpha = default_weapon_alpha;
 744
 745                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval")*2;
 746                 self.lms_traveled_distance = 0;
 747                 self.speedrunning = FALSE;
 748
 749                 race_PostSpawn(spot);
 750
 751                 if(cvar("spawn_debug"))
 752                 {
 753                         sprint(self, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 754                         remove(spot);   // usefull for checking if there are spawnpoints, that let drop through the floor
 755                 }
 756
 757                 //stuffcmd(self, "chase_active 0");
 758                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
 759
 760                 if (cvar("g_spawnsound"))
 761                         sound (self, CHAN_TRIGGER, "misc/spawn.wav", VOL_BASE, ATTN_NORM);
 762
 763                 if(g_assault) {
 764                         if(self.team == assault_attacker_team)
 765                                 centerprint(self, "You are attacking!\n");
 766                         else
 767                                 centerprint(self, "You are defending!\n");
 768                 }
 769
 770         } else if(self.classname == "observer") {
 771                 PutObserverInServer ();
 772         }
 773
 774         //if(g_ctf)
 775         //      ctf_playerchanged();
 776 }
 777
 778 /*
 779 =============
 780 SendCSQCInfo
 781
 782 Send whatever CSQC needs NOW and cannot wait for SendServerInfo to happen...
 783 =============
 784 */
 785 void SendCSQCInfo(void)
 786 {
 787         float i;
 788         if(clienttype(self) != CLIENTTYPE_REAL)
 789                 return;
 790         msg_entity = self;
 791         WriteByte(MSG_ONE, SVC_TEMPENTITY);
 792         WriteByte(MSG_ONE, TE_CSQC_INIT);
 793         WriteShort(MSG_ONE, CSQC_REVISION);
 794         WriteByte(MSG_ONE, maxclients);
 795         for(i = 1; i <= 24; ++i)
 796                 WriteByte(MSG_ONE, (get_weaponinfo(i)).impulse + 1);
 797 }
 798
 799 /*
 800 =============
 801 SetNewParms
 802 =============
 803 */
 804 void SetNewParms (void)
 805 {
 806         // initialize parms for a new player
 807         parm1 = -(86400 * 366);
 808 }
 809
 810 /*
 811 =============
 812 SetChangeParms
 813 =============
 814 */
 815 void SetChangeParms (void)
 816 {
 817         // save parms for level change
 818         parm1 = self.parm_idlesince - time;
 819 }
 820
 821 /*
 822 =============
 823 DecodeLevelParms
 824 =============
 825 */
 826 void DecodeLevelParms (void)
 827 {
 828         // load parms
 829         self.parm_idlesince = parm1;
 830         if(self.parm_idlesince == -(86400 * 366))
 831                 self.parm_idlesince = time;
 832 }
 833
 834 /*
 835 =============
 836 ClientKill
 837
 838 Called when a client types 'kill' in the console
 839 =============
 840 */
 841
 842 void ClientKill_Now_TeamChange()
 843 {
 844         if(self.killindicator_teamchange == -1)
 845         {
 846                 self.team = -1;
 847                 JoinBestTeam( self, FALSE, FALSE );
 848         }
 849         else
 850         {
 851                 SV_ChangeTeam(self.killindicator_teamchange - 1);
 852         }
 853 }
 854
 855 void ClientKill_Now()
 856 {
 857         if(self.killindicator_teamchange)
 858                 ClientKill_Now_TeamChange();
 859
 860         // in any case:
 861         Damage(self, self, self, 100000, DEATH_KILL, self.origin, '0 0 0');
 862
 863         if(self.killindicator)
 864         {
 865                 dprint("Cleaned up after a leaked kill indicator.\n");
 866                 remove(self.killindicator);
 867                 self.killindicator = world;
 868         }
 869 }
 870 void KillIndicator_Think()
 871 {
 872         if (!self.owner.modelindex)
 873         {
 874                 self.owner.killindicator = world;
 875                 remove(self);
 876                 return;
 877         }
 878
 879         if(self.cnt <= 0)
 880         {
 881                 self = self.owner;
 882                 ClientKill_Now(); // no oldself needed
 883                 return;
 884         }
 885         else
 886         {
 887                 if(self.cnt <= 10)
 888                         setmodel(self, strcat("models/sprites/", ftos(self.cnt), ".spr32"));
 889                 if(clienttype(self.owner) == CLIENTTYPE_REAL)
 890                 {
 891                         if(self.cnt <= 10)
 892                                 announce(self.owner, strcat("announcer/robotic/", ftos(self.cnt), ".ogg"));
 893                         if(self.owner.killindicator_teamchange)
 894                         {
 895                                 if(self.owner.killindicator_teamchange == -1)
 896                                         centerprint(self.owner, strcat("Changing team in ", ftos(self.cnt), " seconds"));
 897                                 else
 898                                         centerprint(self.owner, strcat("Changing to ", ColoredTeamName(self.owner.killindicator_teamchange), " in ", ftos(self.cnt), " seconds"));
 899                         }
 900                         else
 901                                 centerprint(self.owner, strcat("^1Suicide in ", ftos(self.cnt), " seconds"));
 902                 }
 903                 self.nextthink = time + 1;
 904                 self.cnt -= 1;
 905         }
 906 }
 907
 908 void ClientKill_TeamChange (float targetteam) // 0 = don't change, -1 = auto
 909 {
 910         float killtime;
 911         entity e;
 912         killtime = cvar("g_balance_kill_delay");
 913
 914         self.killindicator_teamchange = targetteam;
 915
 916         if(!self.killindicator)
 917         {
 918                 if(killtime <= 0 || !self.modelindex || self.deadflag != DEAD_NO)
 919                 {
 920                         ClientKill_Now();
 921                 }
 922                 else
 923                 {
 924                         self.killindicator = spawn();
 925                         self.killindicator.owner = self;
 926                         self.killindicator.scale = 0.5;
 927                         setattachment(self.killindicator, self, "");
 928                         setorigin(self.killindicator, '0 0 52');
 929                         self.killindicator.think = KillIndicator_Think;
 930                         self.killindicator.nextthink = time + (self.lip) * 0.05;
 931                         self.killindicator.cnt = ceil(killtime);
 932                         self.killindicator.count = bound(0, ceil(killtime), 10);
 933                         sprint(self, strcat("^1You'll be dead in ", ftos(self.killindicator.cnt), " seconds\n"));
 934
 935                         for(e = world; (e = find(e, classname, "body")) != world; )
 936                         {
 937                                 if(e.enemy != self)
 938                                         continue;
 939                                 e.killindicator = spawn();
 940                                 e.killindicator.owner = e;
 941                                 e.killindicator.scale = 0.5;
 942                                 setattachment(e.killindicator, e, "");
 943                                 setorigin(e.killindicator, '0 0 52');
 944                                 e.killindicator.think = KillIndicator_Think;
 945                                 e.killindicator.nextthink = time + (e.lip) * 0.05;
 946                                 e.killindicator.cnt = ceil(killtime);
 947                         }
 948                         self.lip = 0;
 949                 }
 950         }
 951         if(self.killindicator)
 952         {
 953                 if(targetteam)
 954                         self.killindicator.colormod = TeamColor(targetteam);
 955                 else
 956                         self.killindicator.colormod = '0 0 0';
 957         }
 958 }
 959
 960 void ClientKill (void)
 961 {
 962         ClientKill_TeamChange(0);
 963 }
 964
 965 void DoTeamChange(float destteam)
 966 {
 967         float t, c0;
 968         if(!cvar("teamplay"))
 969         {
 970                 if(destteam >= 0)
 971                         SetPlayerColors(self, destteam);
 972                 return;
 973         }
 974         if(self.classname == "player")
 975         if(destteam == -1)
 976         {
 977                 CheckAllowedTeams(self);
 978                 t = FindSmallestTeam(self, TRUE);
 979                 switch(self.team)
 980                 {
 981                         case COLOR_TEAM1: c0 = c1; break;
 982                         case COLOR_TEAM2: c0 = c2; break;
 983                         case COLOR_TEAM3: c0 = c3; break;
 984                         case COLOR_TEAM4: c0 = c4; break;
 985                         default:          c0 = 999;
 986                 }
 987                 switch(t)
 988                 {
 989                         case 1:
 990                                 if(c0 > c1)
 991                                         destteam = COLOR_TEAM1;
 992                                 break;
 993                         case 2:
 994                                 if(c0 > c2)
 995                                         destteam = COLOR_TEAM2;
 996                                 break;
 997                         case 3:
 998                                 if(c0 > c3)
 999                                         destteam = COLOR_TEAM3;
1000                                 break;
1001                         case 4:
1002                                 if(c0 > c4)
1003                                         destteam = COLOR_TEAM4;
1004                                 break;
1005                 }
1006                 if(destteam == -1)
1007                         return;
1008         }
1009         if(destteam == self.team && !self.killindicator)
1010                 return;
1011         ClientKill_TeamChange(destteam);
1012 }
1013
1014 void FixClientCvars(entity e)
1015 {
1016         // send prediction settings to the client
1017         stuffcmd(e, "\nin_bindmap 0 0\n");
1018         /*
1019          * we no longer need to stuff this. Remove this comment block if you feel
1020          * 2.3 and higher (or was it 2.2.3?) don't need these any more
1021         stuffcmd(e, strcat("cl_gravity ", ftos(cvar("sv_gravity")), "\n"));
1022         stuffcmd(e, strcat("cl_movement_accelerate ", ftos(cvar("sv_accelerate")), "\n"));
1023         stuffcmd(e, strcat("cl_movement_friction ", ftos(cvar("sv_friction")), "\n"));
1024         stuffcmd(e, strcat("cl_movement_maxspeed ", ftos(cvar("sv_maxspeed")), "\n"));
1025         stuffcmd(e, strcat("cl_movement_airaccelerate ", ftos(cvar("sv_airaccelerate")), "\n"));
1026         stuffcmd(e, strcat("cl_movement_maxairspeed ", ftos(cvar("sv_maxairspeed")), "\n"));
1027         stuffcmd(e, strcat("cl_movement_stopspeed ", ftos(cvar("sv_stopspeed")), "\n"));
1028         stuffcmd(e, strcat("cl_movement_jumpvelocity ", ftos(cvar("sv_jumpvelocity")), "\n"));
1029         stuffcmd(e, strcat("cl_movement_stepheight ", ftos(cvar("sv_stepheight")), "\n"));
1030         stuffcmd(e, strcat("set cl_movement_friction_on_land ", ftos(cvar("sv_friction_on_land")), "\n"));
1031         stuffcmd(e, strcat("set cl_movement_airaccel_qw ", ftos(cvar("sv_airaccel_qw")), "\n"));
1032         stuffcmd(e, strcat("set cl_movement_airaccel_sideways_friction ", ftos(cvar("sv_airaccel_sideways_friction")), "\n"));
1033         stuffcmd(e, "cl_movement_edgefriction 1\n");
1034          */
1035 }
1036
1037 /*
1038 =============
1039 ClientConnect
1040
1041 Called when a client connects to the server
1042 =============
1043 */
1044 //void ctf_clientconnect();
1045 string ColoredTeamName(float t);
1046 void DecodeLevelParms (void);
1047 //void dom_player_join_team(entity pl);
1048 void ClientConnect (void)
1049 {
1050         local string s;
1051
1052         if(self.flags & FL_CLIENT)
1053         {
1054                 print("Warning: ClientConnect, but already connected!\n");
1055                 return;
1056         }
1057
1058         if(Ban_IsClientBanned(self))
1059         {
1060                 s = strcat("^1NOTE:^7 banned client ", self.netaddress, " just tried to enter\n");
1061                 dropclient(self);
1062                 bprint(s);
1063                 return;
1064         }
1065
1066         DecodeLevelParms();
1067
1068         self.classname = "player_joining";
1069
1070         self.flags = self.flags | FL_CLIENT;
1071         self.version_nagtime = time + 10 + random() * 10;
1072
1073         if(player_count<0)
1074         {
1075                 dprint("BUG player count is lower than zero, this cannot happen!\n");
1076                 player_count = 0;
1077         }
1078
1079         PlayerScore_Attach(self);
1080
1081         bot_clientconnect();
1082
1083         race_PreSpawnObserver();
1084
1085         //if(g_domination)
1086         //      dom_player_join_team(self);
1087
1088         //JoinBestTeam(self, FALSE, FALSE);
1089         //
1090         if((cvar("sv_spectate") == 1 && !g_lms) || cvar("g_campaign")) {
1091                 self.classname = "observer";
1092         } else {
1093                 self.classname = "player";
1094                 campaign_bots_may_start = 1;
1095         }
1096
1097         self.playerid = (playerid_last = playerid_last + 1);
1098         if(cvar("sv_eventlog"))
1099         {
1100                 if(clienttype(self) == CLIENTTYPE_REAL)
1101                         GameLogEcho(strcat(":join:", ftos(self.playerid), ":", ftos(num_for_edict(self)), ":", self.netaddress, ":", self.netname));
1102                 else
1103                         GameLogEcho(strcat(":join:", ftos(self.playerid), ":", ftos(num_for_edict(self)), ":bot:", self.netname));
1104                 s = strcat(":team:", ftos(self.playerid), ":");
1105                 s = strcat(s, ftos(self.team));
1106                 GameLogEcho(s);
1107         }
1108         self.netname_previous = strzone(self.netname);
1109
1110         //stuffcmd(self, "set tmpviewsize $viewsize \n");
1111
1112         bprint ("^4",self.netname);
1113         bprint ("^4 connected");
1114
1115         if(g_domination || g_ctf)
1116         {
1117                 bprint(" and joined the ");
1118                 bprint(ColoredTeamName(self.team));
1119         }
1120
1121         bprint("\n");
1122
1123         self.welcomemessage_time = 0;
1124
1125         stuffcmd(self, strcat(clientstuff, "\n"));
1126         stuffcmd(self, strcat("exec maps/", mapname, ".cfg\n"));
1127         stuffcmd(self, "cl_particles_reloadeffects\n");
1128
1129         FixClientCvars(self);
1130
1131         // spawnfunc_waypoint sprites
1132         WaypointSprite_InitClient(self);
1133
1134         // Wazat's grappling hook
1135         SetGrappleHookBindings();
1136
1137         // get autoswitch state from player when he toggles it
1138         stuffcmd(self, "alias autoswitch \"set cl_autoswitch $1 ; cmd autoswitch $1\"\n"); // default.cfg-ed in 2.4.1
1139
1140         // get version info from player
1141         stuffcmd(self, "cmd clientversion $gameversion\n");
1142
1143         // get other cvars from player
1144         GetCvars(0);
1145
1146         // set cvar for team scoreboard
1147         if (teams_matter)
1148         {
1149                 local float t;
1150                 t = cvar("teamplay");
1151                 // we have to stuff the correct teamplay value because if this is a listen server, this changes the teamplay mode of the server itself, which is bad
1152                 stuffcmd(self, strcat("set teamplay ", ftos(t), "\n"));
1153         }
1154         else
1155                 stuffcmd(self, "set teamplay 0\n");
1156
1157         // notify about available teams
1158         if(teamplay)
1159         {
1160                 CheckAllowedTeams(self);
1161                 t = 0; if(c1 >= 0) t |= 1; if(c2 >= 0) t |= 2; if(c3 >= 0) t |= 4; if(c4 >= 0) t |= 8;
1162                 stuffcmd(self, strcat("set _teams_available ", ftos(t), "\n"));
1163         }
1164         else
1165                 stuffcmd(self, "set _teams_available 0\n");
1166
1167         stuffcmd(self, strcat("set gametype ", ftos(game), "\n"));
1168
1169         if(g_arena)
1170         {
1171                 self.classname = "observer";
1172                 Spawnqueue_Insert(self);
1173         }
1174         /*else if(g_ctf)
1175         {
1176                 ctf_clientconnect();
1177         }*/
1178
1179         if(entcs_start)
1180                 attach_entcs();
1181
1182         bot_relinkplayerlist();
1183
1184         self.spectatortime = time;
1185         if(blockSpectators)
1186         {
1187                 sprint(self, strcat("^7You have to become a player within the next ", ftos(cvar("g_maxplayers_spectator_blocktime")), " seconds, otherwise you will be kicked, because spectators aren't allowed at this time!\n"));
1188         }
1189
1190         self.jointime = time;
1191         self.allowedTimeouts = cvar("sv_timeout_number");
1192
1193         if(clienttype(self) == CLIENTTYPE_REAL)
1194         {
1195                 sprint(self, strcat("nexuiz-csqc protocol ", ftos(CSQC_REVISION), "\n"));
1196                 SendCSQCInfo();
1197                 msg_entity = self;
1198                 if(mapvote_initialized && !cvar("g_maplist_textonly"))
1199                 {
1200                         MapVote_SendData(MSG_ONE);
1201                         MapVote_UpdateData(MSG_ONE);
1202                 }
1203                 ScoreInfo_Write(MSG_ONE);
1204         }
1205
1206         if(inWarmupStage)
1207         {
1208                 msg_entity = self;
1209                 WriteByte(MSG_ONE, SVC_TEMPENTITY);
1210                 WriteByte(MSG_ONE, TE_CSQC_WARMUP);
1211                 WriteByte(MSG_ONE, 1);
1212         }
1213
1214         if(g_lms)
1215         {
1216                 if(PlayerScore_Add(self, SP_LMS_LIVES, LMS_NewPlayerLives()) <= 0)
1217                 {
1218                         PlayerScore_Add(self, SP_LMS_RANK, 666);
1219                         self.frags = -666; // FIXME do we still need this?
1220                 }
1221         }
1222 }
1223
1224 /*
1225 =============
1226 ClientDisconnect
1227
1228 Called when a client disconnects from the server
1229 =============
1230 */
1231 void(entity e) DropFlag;
1232 .entity chatbubbleentity;
1233 .entity teambubbleentity;
1234 void ReadyCount();
1235 //void() ctf_clientdisconnect;
1236 void ClientDisconnect (void)
1237 {
1238         float save;
1239
1240         if not(self.flags & FL_CLIENT)
1241         {
1242                 print("Warning: ClientDisconnect without ClientConnect\n");
1243                 return;
1244         }
1245
1246         bot_clientdisconnect();
1247
1248         if(entcs_start)
1249                 detach_entcs();
1250
1251         if(cvar("sv_eventlog"))
1252                 GameLogEcho(strcat(":part:", ftos(self.playerid)));
1253         bprint ("^4",self.netname);
1254         bprint ("^4 disconnected\n");
1255
1256         if (self.chatbubbleentity)
1257         {
1258                 remove (self.chatbubbleentity);
1259                 self.chatbubbleentity = world;
1260         }
1261
1262         if (self.teambubbleentity)
1263         {
1264                 remove (self.teambubbleentity);
1265                 self.teambubbleentity = world;
1266         }
1267
1268         if (self.killindicator)
1269         {
1270                 remove (self.killindicator);
1271                 self.killindicator = world;
1272         }
1273
1274         WaypointSprite_PlayerGone();
1275
1276         DropAllRunes(self);
1277         kh_Key_DropAll(self, TRUE);
1278
1279         Portal_ClearAll(self);
1280
1281         if(self.flagcarried)
1282                 DropFlag(self.flagcarried);
1283
1284         save = self.flags;
1285         self.flags = self.flags - (self.flags & FL_CLIENT);
1286         bot_relinkplayerlist();
1287         self.flags = save;
1288
1289         // remove laserdot
1290         if(self.weaponentity)
1291                 if(self.weaponentity.lasertarget)
1292                         remove(self.weaponentity.lasertarget);
1293
1294         if(g_arena)
1295         {
1296                 Spawnqueue_Unmark(self);
1297                 Spawnqueue_Remove(self);
1298         }
1299         /*if(g_ctf)
1300         {
1301                 ctf_clientdisconnect();
1302         }
1303         */
1304
1305         PlayerScore_Detach(self);
1306
1307         if(self.netname_previous)
1308                 strunzone(self.netname_previous);
1309
1310         ClearPlayerSounds();
1311
1312         // free cvars
1313         GetCvars(-1);
1314         self.playerid = 0;
1315
1316         ReadyCount();
1317 }
1318
1319 .float BUTTON_CHAT;
1320 void ChatBubbleThink()
1321 {
1322         self.nextthink = time;
1323         if (!self.owner.modelindex || self.owner.chatbubbleentity != self)
1324         {
1325                 self.owner.chatbubbleentity = world;
1326                 remove(self);
1327                 return;
1328         }
1329         setorigin(self, self.owner.origin + '0 0 15' + self.owner.maxs_z * '0 0 1');
1330         if (self.owner.BUTTON_CHAT && !self.owner.deadflag)
1331                 self.model = self.mdl;
1332         else
1333                 self.model = "";
1334 };
1335
1336 void UpdateChatBubble()
1337 {
1338         if (!self.modelindex)
1339                 return;
1340         // spawn a chatbubble entity if needed
1341         if (!self.chatbubbleentity)
1342         {
1343                 self.chatbubbleentity = spawn();
1344                 self.chatbubbleentity.owner = self;
1345                 self.chatbubbleentity.exteriormodeltoclient = self;
1346                 self.chatbubbleentity.think = ChatBubbleThink;
1347                 self.chatbubbleentity.nextthink = time;
1348                 setmodel(self.chatbubbleentity, "models/misc/chatbubble.spr"); // precision set below
1349                 setorigin(self.chatbubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1350                 self.chatbubbleentity.mdl = self.chatbubbleentity.model;
1351                 self.chatbubbleentity.model = "";
1352                 self.chatbubbleentity.effects = EF_LOWPRECISION;
1353         }
1354 }
1355
1356
1357 void TeamBubbleThink()
1358 {
1359         self.nextthink = time;
1360         if (!self.owner.modelindex || self.owner.teambubbleentity != self)
1361         {
1362                 self.owner.teambubbleentity = world;
1363                 remove(self);
1364                 return;
1365         }
1366 //      setorigin(self, self.owner.origin + '0 0 15' + self.owner.maxs_z * '0 0 1');  // bandwidth hog. setattachment does this now
1367         if (self.owner.BUTTON_CHAT || self.owner.deadflag || self.owner.killindicator)
1368                 self.model = "";
1369         else
1370                 self.model = self.mdl;
1371
1372 };
1373
1374 float TeamBubble_customizeentityforclient()
1375 {
1376         return (self.owner != other && self.owner.team == other.team && other.killcount > -666);
1377 }
1378
1379 void UpdateTeamBubble()
1380 {
1381         if (!self.modelindex || !cvar("teamplay"))
1382                 return;
1383         // spawn a teambubble entity if needed
1384         if (!self.teambubbleentity && cvar("teamplay"))
1385         {
1386                 self.teambubbleentity = spawn();
1387                 self.teambubbleentity.owner = self;
1388                 self.teambubbleentity.exteriormodeltoclient = self;
1389                 self.teambubbleentity.think = TeamBubbleThink;
1390                 self.teambubbleentity.nextthink = time;
1391                 setmodel(self.teambubbleentity, "models/misc/teambubble.spr"); // precision set below
1392 //              setorigin(self.teambubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1393                 setorigin(self.teambubbleentity, self.teambubbleentity.origin + '0 0 15' + self.maxs_z * '0 0 1');
1394                 setattachment(self.teambubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1395                 self.teambubbleentity.mdl = self.teambubbleentity.model;
1396                 self.teambubbleentity.model = self.teambubbleentity.mdl;
1397                 self.teambubbleentity.customizeentityforclient = TeamBubble_customizeentityforclient;
1398                 self.teambubbleentity.effects = EF_LOWPRECISION;
1399         }
1400 }
1401
1402 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1403 // added to the model skins
1404 /*void UpdateColorModHack()
1405 {
1406         local float c;
1407         c = self.clientcolors & 15;
1408         // LordHavoc: only bothering to support white, green, red, yellow, blue
1409              if (teamplay == 0) self.colormod = '0 0 0';
1410         else if (c ==  0) self.colormod = '1.00 1.00 1.00';
1411         else if (c ==  3) self.colormod = '0.10 1.73 0.10';
1412         else if (c ==  4) self.colormod = '1.73 0.10 0.10';
1413         else if (c == 12) self.colormod = '1.22 1.22 0.10';
1414         else if (c == 13) self.colormod = '0.10 0.10 1.73';
1415         else self.colormod = '1 1 1';
1416 };*/
1417
1418 void respawn(void)
1419 {
1420         CopyBody(1);
1421         self.effects |= EF_NODRAW; // prevent another CopyBody
1422         PutClientInServer();
1423 }
1424
1425 /**
1426  * When sv_timeout is used this function returs strings like
1427  * "Timeout begins in 2 seconds!\n" or "Timeout ends in 23 seconds!\n".
1428  * Called by centerprint functions
1429  * @param addOneSecond boolean, set to 1 if the welcome-message centerprint asks for the text
1430  */
1431 string getTimeoutText(float addOneSecond) {
1432         if (!cvar("sv_timeout") || !timeoutStatus)
1433                 return "";
1434
1435         local string retStr;
1436         if (timeoutStatus == 1) {
1437                 if (addOneSecond == 1) {
1438                         retStr = strcat("Timeout begins in ", ftos(remainingLeadTime + 1), " seconds!\n");
1439                 }
1440                 else {
1441                         retStr = strcat("Timeout begins in ", ftos(remainingLeadTime), " seconds!\n");
1442                 }
1443                 return retStr;
1444         }
1445         else if (timeoutStatus == 2) {
1446                 if (addOneSecond) {
1447                         retStr = strcat("Timeout ends in ", ftos(remainingTimeoutTime + 1), " seconds!\n");
1448                         //don't show messages like "Timeout ends in 0 seconds"...
1449                         if ((remainingTimeoutTime + 1) > 0)
1450                                 return retStr;
1451                         else
1452                                 return "";
1453                 }
1454                 else {
1455                         retStr = strcat("Timeout ends in ", ftos(remainingTimeoutTime), " seconds!\n");
1456                         //don't show messages like "Timeout ends in 0 seconds"...
1457                         if (remainingTimeoutTime > 0)
1458                                 return retStr;
1459                         else
1460                                 return "";
1461                 }
1462         }
1463         else return "";
1464 }
1465
1466 void player_powerups (void)
1467 {
1468         if (g_minstagib)
1469         {
1470                 if (self.items & IT_STRENGTH)
1471                 {
1472                         if (time > self.strength_finished)
1473                         {
1474                                 if (g_minstagib_invis_alpha > 0)
1475                                 {
1476                                         self.alpha = default_player_alpha;
1477                                         self.exteriorweaponentity.alpha = default_weapon_alpha;
1478                                         self.effects = self.effects | EF_FULLBRIGHT;
1479                                 }
1480                                 else
1481                                 {
1482                                         self.effects -= self.effects & EF_NODRAW;
1483                                 }
1484                                 self.items = self.items - (self.items & IT_STRENGTH);
1485                                 sprint(self, "^3Invisibility has worn off\n");
1486                         }
1487                 }
1488                 else
1489                 {
1490                         if (time < self.strength_finished)
1491                         {
1492                                 if (g_minstagib_invis_alpha > 0)
1493                                 {
1494                                         self.alpha = g_minstagib_invis_alpha;
1495                                         self.exteriorweaponentity.alpha = g_minstagib_invis_alpha;
1496                                         self.effects -= self.effects & EF_FULLBRIGHT;
1497                                 }
1498                                 else
1499                                 {
1500                                         self.effects = self.effects | EF_NODRAW;
1501                                 }
1502                                 self.items = self.items | IT_STRENGTH;
1503                                 sprint(self, "^3You are invisible\n");
1504                         }
1505                 }
1506
1507                 if (self.items & IT_INVINCIBLE)
1508                 {
1509                         if (time > self.invincible_finished)
1510                         {
1511                                 self.items = self.items - (self.items & IT_INVINCIBLE);
1512                                 sprint(self, "^3Speed has worn off\n");
1513                         }
1514                 }
1515                 else
1516                 {
1517                         if (time < self.invincible_finished)
1518                         {
1519                                 self.items = self.items | IT_INVINCIBLE;
1520                                 sprint(self, "^3You are on speed\n");
1521                         }
1522                 }
1523                 return;
1524         }
1525
1526         self.effects = self.effects - (self.effects & (EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT));
1527         if (self.items & IT_STRENGTH)
1528         {
1529                 self.effects = self.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1530                 if (time > self.strength_finished)
1531                 {
1532                         self.items = self.items - (self.items & IT_STRENGTH);
1533                         sprint(self, "^3Strength has worn off\n");
1534                 }
1535         }
1536         else
1537         {
1538                 if (time < self.strength_finished)
1539                 {
1540                         self.items = self.items | IT_STRENGTH;
1541                         sprint(self, "^3Strength infuses your weapons with devastating power\n");
1542                 }
1543         }
1544         if (self.items & IT_INVINCIBLE)
1545         {
1546                 self.effects = self.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1547                 if (time > self.invincible_finished)
1548                 {
1549                         self.items = self.items - (self.items & IT_INVINCIBLE);
1550                         sprint(self, "^3Shield has worn off\n");
1551                 }
1552         }
1553         else
1554         {
1555                 if (time < self.invincible_finished)
1556                 {
1557                         self.items = self.items | IT_INVINCIBLE;
1558                         sprint(self, "^3Shield surrounds you\n");
1559                 }
1560         }
1561
1562         if (cvar("g_fullbrightplayers"))
1563                 self.effects = self.effects | EF_FULLBRIGHT;
1564
1565         // midair gamemode: damage only while in the air
1566         // if in midair mode, being on ground grants temporary invulnerability
1567         // (this is so that multishot weapon don't clear the ground flag on the
1568         // first damage in the frame, leaving the player vulnerable to the
1569         // remaining hits in the same frame)
1570         if (self.flags & FL_ONGROUND)
1571         if (g_midair)
1572                 self.spawnshieldtime = max(self.spawnshieldtime, time + cvar("g_midair_shieldtime"));
1573
1574         if (time > restart_countdown)
1575         if (time < self.spawnshieldtime)
1576                 self.effects = self.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1577 }
1578
1579 float CalcRegen(float current, float stable, float regenfactor)
1580 {
1581         if(current > stable)
1582                 return current;
1583         else if(current > stable - 0.25) // when close enough, "snap"
1584                 return stable;
1585         else
1586                 return min(stable, current + (stable - current) * regenfactor * frametime);
1587 }
1588
1589 void player_regen (void)
1590 {
1591         float maxh, maxa, limith, limita, max_mod, regen_mod, rot_mod, limit_mod;
1592         maxh = cvar("g_balance_health_stable");
1593         maxa = cvar("g_balance_armor_stable");
1594         limith = cvar("g_balance_health_limit");
1595         limita = cvar("g_balance_armor_limit");
1596
1597         if (g_minstagib || (g_lms && !cvar("g_lms_regenerate")))
1598                 return;
1599
1600         max_mod = regen_mod = rot_mod = limit_mod = 1;
1601
1602         if (self.runes & RUNE_REGEN)
1603         {
1604                 if (self.runes & CURSE_VENOM) // do we have both rune/curse?
1605                 {
1606                         regen_mod = cvar("g_balance_rune_regen_combo_regenrate");
1607                         max_mod = cvar("g_balance_rune_regen_combo_hpmod");
1608                         limit_mod = cvar("g_balance_rune_regen_combo_limitmod");
1609                 }
1610                 else
1611                 {
1612                         regen_mod = cvar("g_balance_rune_regen_regenrate");
1613                         max_mod = cvar("g_balance_rune_regen_hpmod");
1614                         limit_mod = cvar("g_balance_rune_regen_limitmod");
1615                 }
1616         }
1617         else if (self.runes & CURSE_VENOM)
1618         {
1619                 max_mod = cvar("g_balance_curse_venom_hpmod");
1620                 if (self.runes & RUNE_REGEN) // do we have both rune/curse?
1621                         rot_mod = cvar("g_balance_rune_regen_combo_rotrate");
1622                 else
1623                         rot_mod = cvar("g_balance_curse_venom_rotrate");
1624                 limit_mod = cvar("g_balance_curse_venom_limitmod");
1625                 //if (!self.runes & RUNE_REGEN)
1626                 //      rot_mod = cvar("g_balance_curse_venom_rotrate");
1627         }
1628         maxh = maxh * max_mod;
1629         //maxa = maxa * max_mod;
1630         limith = limith * limit_mod;
1631         limita = limita * limit_mod;
1632
1633         if (self.armorvalue > maxa)
1634         {
1635                 if (time > self.pauserotarmor_finished)
1636                 {
1637                         self.armorvalue = max(maxa, self.armorvalue + (maxa - self.armorvalue) * cvar("g_balance_armor_rot") * frametime);
1638                         self.armorvalue = max(maxa, self.armorvalue - cvar("g_balance_armor_rotlinear") * frametime);
1639                 }
1640         }
1641         else if (self.armorvalue < maxa)
1642         {
1643                 if (time > self.pauseregen_finished)
1644                 {
1645                         self.armorvalue = CalcRegen(self.armorvalue, maxa, cvar("g_balance_armor_regen"));
1646                         self.armorvalue = min(maxa, self.armorvalue + cvar("g_balance_armor_regenlinear") * frametime);
1647                 }
1648         }
1649         if (self.health > maxh)
1650         {
1651                 if (time > self.pauserothealth_finished)
1652                 {
1653                         self.health = max(maxh, self.health + (maxh - self.health) * rot_mod*cvar("g_balance_health_rot") * frametime);
1654                         self.health = max(maxh, self.health - rot_mod*cvar("g_balance_health_rotlinear") * frametime);
1655                 }
1656         }
1657         else if (self.health < maxh)
1658         {
1659                 if (time > self.pauseregen_finished)
1660                 {
1661                         self.health = CalcRegen(self.health, maxh, regen_mod * cvar("g_balance_health_regen"));
1662                         self.health = min(maxh, self.health + regen_mod*cvar("g_balance_health_regenlinear") * frametime);
1663                 }
1664         }
1665
1666         if (self.health > limith)
1667                 self.health = limith;
1668         if (self.armorvalue > limita)
1669                 self.armorvalue = limita;
1670
1671         // if player rotted to death...  die!
1672         if(self.health < 1)
1673                 self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
1674 }
1675
1676 .float zoomstate;
1677 float zoomstate_set;
1678 void SetZoomState(float z)
1679 {
1680         if(z != self.zoomstate)
1681         {
1682                 msg_entity = self;
1683                 WriteByte(MSG_ONE, SVC_TEMPENTITY);
1684                 WriteByte(MSG_ONE, TE_CSQC_ZOOMNOTIFY);
1685                 WriteByte(MSG_ONE, z);
1686                 self.zoomstate = z;
1687         }
1688         zoomstate_set = 1;
1689 }
1690
1691 /*
1692 ======================
1693 spectate mode routines
1694 ======================
1695 */
1696 void SpectateCopy(entity spectatee) {
1697         self.armortype = spectatee.armortype;
1698         self.armorvalue = spectatee.armorvalue;
1699         self.currentammo = spectatee.currentammo;
1700         self.effects = spectatee.effects;
1701         self.health = spectatee.health;
1702         self.impulse = 0;
1703         self.items = spectatee.items;
1704         self.weapons = spectatee.weapons;
1705         self.punchangle = spectatee.punchangle;
1706         self.view_ofs = spectatee.view_ofs;
1707         self.v_angle = spectatee.v_angle;
1708         self.velocity = spectatee.velocity;
1709         self.dmg_take = spectatee.dmg_take;
1710         self.dmg_save = spectatee.dmg_save;
1711         self.dmg_inflictor = spectatee.dmg_inflictor;
1712         self.angles = spectatee.v_angle;
1713         self.fixangle = TRUE;
1714         setorigin(self, spectatee.origin);
1715         setsize(self, spectatee.mins, spectatee.maxs);
1716         SetZoomState(spectatee.zoomstate);
1717 }
1718
1719 float SpectateUpdate() {
1720         if(!self.enemy)
1721                 return 0;
1722
1723         if (self == self.enemy)
1724                 return 0;
1725
1726         if(self.enemy.flags & FL_NOTARGET)
1727                 return 0;
1728
1729         SpectateCopy(self.enemy);
1730
1731         return 1;
1732 }
1733
1734 float SpectateNext() {
1735         other = find(self.enemy, classname, "player");
1736         if (!other) {
1737                 other = find(other, classname, "player");
1738         }
1739         if (other) {
1740                 self.enemy = other;
1741         }
1742         if(self.enemy.classname == "player") {
1743                 msg_entity = self;
1744                 WriteByte(MSG_ONE, SVC_SETVIEW);
1745                 WriteEntity(MSG_ONE, self.enemy);
1746                 self.wantswelcomemessage = 1;
1747                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
1748                 if(!SpectateUpdate())
1749                         PutObserverInServer();
1750                 return 1;
1751         } else {
1752                 return 0;
1753         }
1754 }
1755
1756 /*
1757 =============
1758 ShowRespawnCountdown()
1759
1760 Update a respawn countdown display.
1761 =============
1762 */
1763 void ShowRespawnCountdown()
1764 {
1765         float number;
1766         if(self.deadflag == DEAD_NO) // just respawned?
1767                 return;
1768         else
1769         {
1770                 number = ceil(self.death_time - time);
1771                 if(number <= 0)
1772                         return;
1773                 if(number <= self.respawn_countdown)
1774                 {
1775                         self.respawn_countdown = number - 1;
1776                         if(ceil(self.death_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
1777                                 announce(self, strcat("announcer/robotic/", ftos(number), ".ogg"));
1778                 }
1779         }
1780 }
1781
1782 void LeaveSpectatorMode()
1783 {
1784         if(isJoinAllowed()) {
1785                 if(!cvar("teamplay") || cvar("g_campaign") || cvar("g_balance_teams")) {
1786                         self.classname = "player";
1787                         if(cvar("g_campaign") || cvar("g_balance_teams") || cvar("g_balance_teams_force"))
1788                                 JoinBestTeam(self, FALSE, TRUE);
1789                         if(cvar("g_campaign"))
1790                                 campaign_bots_may_start = 1;
1791                         PutClientInServer();
1792                         if(!(self.flags & FL_NOTARGET))
1793                                 bprint ("^4", self.netname, "^4 is playing now\n");
1794                         centerprint(self,"");
1795                         return;
1796                 } else {
1797                         stuffcmd(self,"menu_showteamselect\n");
1798                         return;
1799                 }
1800         }
1801         else {
1802                 //player may not join because of g_maxplayers is set
1803                 centerprint_atprio(self, CENTERPRIO_MAPVOTE, PREVENT_JOIN_TEXT);
1804         }
1805 }
1806
1807 /**
1808  * Determines whether the player is allowed to join. This depends on cvar
1809  * g_maxplayers, if it isn't used this function always return TRUE, otherwise
1810  * it checks whether the number of currently playing players exceeds g_maxplayers.
1811  * @return bool TRUE if the player is allowed to join, false otherwise
1812  */
1813 float isJoinAllowed() {
1814         if (!cvar("g_maxplayers"))
1815                 return TRUE;
1816
1817         local entity e;
1818         local float currentlyPlaying;
1819         FOR_EACH_REALPLAYER(e) {
1820                 if(e.classname == "player")
1821                         currentlyPlaying += 1;
1822         }
1823         if(currentlyPlaying < cvar("g_maxplayers"))
1824                 return TRUE;
1825
1826         return FALSE;
1827 }
1828
1829 /**
1830  * Checks whether the client is an observer or spectator, if so, he will get kicked after
1831  * g_maxplayers_spectator_blocktime seconds
1832  */
1833 void checkSpectatorBlock() {
1834         if(self.classname == "spectator" || self.classname == "observer") {
1835                 if( time > (self.spectatortime + cvar("g_maxplayers_spectator_blocktime")) ) {
1836                         sprint(self, "^7You were kicked from the server because you are spectator and spectators aren't allowed at the moment.\n");
1837                         dropclient(self);
1838                 }
1839         }
1840 }
1841
1842 float vercmp_recursive(string v1, string v2)
1843 {
1844         float dot1, dot2;
1845         string s1, s2;
1846         float r;
1847
1848         dot1 = strstrofs(v1, ".", 0);
1849         dot2 = strstrofs(v2, ".", 0);
1850         if(dot1 == -1)
1851                 s1 = v1;
1852         else
1853                 s1 = substring(v1, 0, dot1);
1854         if(dot2 == -1)
1855                 s2 = v2;
1856         else
1857                 s2 = substring(v2, 0, dot2);
1858
1859         r = stof(s1) - stof(s2);
1860         if(r != 0)
1861                 return r;
1862
1863         r = strcasecmp(s1, s2);
1864         if(r != 0)
1865                 return r;
1866
1867         if(dot1 == -1)
1868                 if(dot2 == -1)
1869                         return 0;
1870                 else
1871                         return -1;
1872         else
1873                 if(dot2 == -1)
1874                         return 1;
1875                 else
1876                         return vercmp_recursive(substring(v1, dot1 + 1, 999), substring(v2, dot2 + 1, 999));
1877 }
1878
1879 float vercmp(string v1, string v2)
1880 {
1881         if(strcasecmp(v1, v2) == 0) // early out check
1882                 return 0;
1883         return vercmp_recursive(v1, v2);
1884 }
1885
1886 void ObserverThink()
1887 {
1888         if (self.flags & FL_JUMPRELEASED) {
1889                 if (self.BUTTON_JUMP && !self.version_mismatch) {
1890                         self.welcomemessage_time = 0;
1891                         self.flags = self.flags - FL_JUMPRELEASED;
1892                         LeaveSpectatorMode();
1893                         return;
1894                 } else if(self.BUTTON_ATCK && !self.version_mismatch) {
1895                         self.welcomemessage_time = 0;
1896                         self.flags = self.flags - FL_JUMPRELEASED;
1897                         if(SpectateNext() == 1) {
1898                                 self.classname = "spectator";
1899                         }
1900                 }
1901         } else {
1902                 if (!(self.BUTTON_ATCK || self.BUTTON_JUMP)) {
1903                         self.flags = self.flags | FL_JUMPRELEASED;
1904                 }
1905         }
1906         if(self.BUTTON_ZOOM)
1907                 self.wantswelcomemessage = 0;
1908         if(self.wantswelcomemessage)
1909                 PrintWelcomeMessage(self);
1910 }
1911
1912 void SpectatorThink()
1913 {
1914         if (self.flags & FL_JUMPRELEASED) {
1915                 if (self.BUTTON_JUMP && !self.version_mismatch) {
1916                         self.welcomemessage_time = 0;
1917                         self.flags = self.flags - FL_JUMPRELEASED;
1918                         LeaveSpectatorMode();
1919                         return;
1920                 } else if(self.BUTTON_ATCK) {
1921                         self.welcomemessage_time = 0;
1922                         self.flags = self.flags - FL_JUMPRELEASED;
1923                         if(SpectateNext() == 1) {
1924                                 self.classname = "spectator";
1925                         } else {
1926                                 self.classname = "observer";
1927                                 PutClientInServer();
1928                         }
1929                 } else if (self.BUTTON_ATCK2) {
1930                         self.welcomemessage_time = 0;
1931                         self.flags = self.flags - FL_JUMPRELEASED;
1932                         self.classname = "observer";
1933                         PutClientInServer();
1934                 } else {
1935                         if(!SpectateUpdate())
1936                                 PutObserverInServer();
1937                 }
1938         } else {
1939                 if (!(self.BUTTON_ATCK || self.BUTTON_ATCK2)) {
1940                         self.flags = self.flags | FL_JUMPRELEASED;
1941                 }
1942         }
1943         if(self.BUTTON_ZOOM)
1944                 self.wantswelcomemessage = 0;
1945         if(self.wantswelcomemessage)
1946                 PrintWelcomeMessage(self);
1947         self.flags = self.flags | FL_CLIENT | FL_NOTARGET;
1948 }
1949
1950 /*
1951 =============
1952 PlayerPreThink
1953
1954 Called every frame for each client before the physics are run
1955 =============
1956 */
1957 void() ctf_setstatus;
1958 .float vote_nagtime;
1959 .float spectatee_status;
1960 void PlayerPreThink (void)
1961 {
1962         self.stat_sys_ticrate = cvar("sys_ticrate");
1963         if(blockSpectators)
1964                 checkSpectatorBlock();
1965
1966         zoomstate_set = 0;
1967
1968         if(self.netname_previous != self.netname)
1969         {
1970                 if(cvar("sv_eventlog"))
1971                         GameLogEcho(strcat(":name:", ftos(self.playerid), ":", self.netname));
1972                 if(self.netname_previous)
1973                         strunzone(self.netname_previous);
1974                 self.netname_previous = strzone(self.netname);
1975         }
1976
1977         // version nagging
1978         if(self.version_nagtime)
1979                 if(self.cvar_g_nexuizversion)
1980                         if(time > self.version_nagtime)
1981                         {
1982                                 if(strstr(self.cvar_g_nexuizversion, "svn", 0) < 0)
1983                                 {
1984                                         if(strstr(cvar_string("g_nexuizversion"), "svn", 0) >= 0)
1985                                         {
1986                                                 dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Nexuiz ", cvar_string("g_nexuizversion"), " (beta)^7, you have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1\n");
1987                                                 sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Nexuiz ", cvar_string("g_nexuizversion"), " (beta)^7, you have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1\n"));
1988                                         }
1989                                         else
1990                                         {
1991                                                 float r;
1992                                                 r = vercmp(self.cvar_g_nexuizversion, cvar_string("g_nexuizversion"));
1993                                                 if(r < 0)
1994                                                 {
1995                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - ^3Nexuiz ", cvar_string("g_nexuizversion"), "^7 is out, and you still have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1 - get the update from ^4http://www.nexuiz.com/^1!\n");
1996                                                         sprint(self, strcat("\{1}^1NOTE: ^3Nexuiz ", cvar_string("g_nexuizversion"), "^7 is out, and you still have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1 - get the update from ^4http://www.nexuiz.com/^1!\n"));
1997                                                 }
1998                                                 else if(r > 0)
1999                                                 {
2000                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Nexuiz ", cvar_string("g_nexuizversion"), "^7, you have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1\n");
2001                                                         sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Nexuiz ", cvar_string("g_nexuizversion"), "^7, you have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1\n"));
2002                                                 }
2003                                         }
2004                                 }
2005                                 self.version_nagtime = 0;
2006                         }
2007
2008         // vote nagging
2009         if(self.cvar_scr_centertime)
2010                 if(time > self.vote_nagtime)
2011                 {
2012                         VoteNag();
2013                         self.vote_nagtime = time + self.cvar_scr_centertime * 0.6;
2014                 }
2015
2016         // GOD MODE info
2017         if(!(self.flags & FL_GODMODE)) if(self.max_armorvalue)
2018         {
2019                 sprint(self, strcat("godmode saved you ", ftos(self.max_armorvalue), " units of damage, cheater!\n"));
2020                 self.max_armorvalue = 0;
2021         }
2022
2023         if(frametime)
2024                 antilag_record(self);
2025
2026         if(self.classname == "player") {
2027 //              if(self.netname == "Wazat")
2028 //                      bprint(self.classname, "\n");
2029
2030                 CheckRules_Player();
2031
2032                 if(self.BUTTON_INFO)
2033                         PrintWelcomeMessage(self);
2034
2035                 if(g_lms || !cvar("sv_spectate"))
2036                 if((time - self.jointime) <= cvar("welcome_message_time"))
2037                         PrintWelcomeMessage(self);
2038
2039                 if (intermission_running)
2040                 {
2041                         IntermissionThink ();   // otherwise a button could be missed between
2042                         return;                                 // the think tics
2043                 }
2044
2045                 if(self.teleport_time)
2046                 if(time > self.teleport_time)
2047                 {
2048                         self.teleport_time = 0;
2049                         self.effects = self.effects - (self.effects & EF_NODRAW);
2050                         if(self.weaponentity)
2051                                 self.weaponentity.flags = self.weaponentity.flags - (self.weaponentity.flags & EF_NODRAW);
2052                 }
2053
2054                 Nixnex_GiveCurrentWeapon();
2055
2056                 if(frametime > 0) // don't do this in cl_movement frames, just in server ticks
2057                         UpdateSelectedPlayer();
2058
2059                 //don't allow the player to turn around while game is paused!
2060                 if(timeoutStatus == 2) {
2061                         self.v_angle = self.lastV_angle;
2062                         self.angles = self.lastV_angle;
2063                         self.fixangle = TRUE;
2064                 }
2065
2066                 if (self.deadflag != DEAD_NO)
2067                 {
2068                         float button_pressed, force_respawn;
2069                         player_anim();
2070                         button_pressed = (self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE);
2071                         force_respawn = (g_lms || cvar("g_forced_respawn"));
2072                         if (self.deadflag == DEAD_DYING)
2073                         {
2074                                 if(force_respawn)
2075                                         self.deadflag = DEAD_RESPAWNING;
2076                                 else if(!button_pressed)
2077                                         self.deadflag = DEAD_DEAD;
2078                         }
2079                         else if (self.deadflag == DEAD_DEAD)
2080                         {
2081                                 if(button_pressed)
2082                                         self.deadflag = DEAD_RESPAWNABLE;
2083                         }
2084                         else if (self.deadflag == DEAD_RESPAWNABLE)
2085                         {
2086                                 if(!button_pressed)
2087                                         self.deadflag = DEAD_RESPAWNING;
2088                         }
2089                         else if (self.deadflag == DEAD_RESPAWNING)
2090                         {
2091                                 if(time > self.death_time)
2092                                 {
2093                                         self.death_time = time + 1; // only retry once a second
2094                                         respawn();
2095                                 }
2096                         }
2097                         ShowRespawnCountdown();
2098                         return;
2099                 }
2100
2101                 if(g_lms && !self.deadflag && cvar("g_lms_campcheck_interval"))
2102                 {
2103                         vector dist;
2104
2105                         // calculate player movement (in 2 dimensions only, so jumping on one spot doesn't count as movement)
2106                         dist = self.oldorigin - self.origin;
2107                         dist_z = 0;
2108                         self.lms_traveled_distance += fabs(vlen(dist));
2109
2110                         if((cvar("g_campaign") && !campaign_bots_may_start) || (time < restart_countdown))
2111                         {
2112                                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval")*2;
2113                                 self.lms_traveled_distance = 0;
2114                         }
2115
2116                         if(time > self.lms_nextcheck)
2117                         {
2118                                 //sprint(self, "distance: ", ftos(self.lms_traveled_distance), "\n");
2119                                 if(self.lms_traveled_distance < cvar("g_lms_campcheck_distance"))
2120                                 {
2121                                         centerprint(self, cvar_string("g_lms_campcheck_message"));
2122                                         // FIXME KadaverJack: gibbing player here causes playermodel to bounce around, instead of eye.md3
2123                                         // I wasn't able to find out WHY that happens, so I put a workaround in place that shall prevent players from being gibbed :(
2124                                         Damage(self, self, self, bound(0, cvar("g_lms_campcheck_damage"), self.health + self.armorvalue * cvar("g_balance_armor_blockpercent") + 5), DEATH_CAMP, self.origin, '0 0 0');
2125                                 }
2126                                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval");
2127                                 self.lms_traveled_distance = 0;
2128                         }
2129                 }
2130
2131                 if (self.BUTTON_CROUCH && !self.hook.state)
2132                 {
2133                         if (!self.crouch)
2134                         {
2135                                 self.crouch = TRUE;
2136                                 self.view_ofs = PL_CROUCH_VIEW_OFS;
2137                                 setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX);
2138                                 player_setanim(self.anim_duck, FALSE, TRUE, TRUE);
2139                         }
2140                 }
2141                 else
2142                 {
2143                         if (self.crouch)
2144                         {
2145                                 tracebox(self.origin, PL_MIN, PL_MAX, self.origin, FALSE, self);
2146                                 if (!trace_startsolid)
2147                                 {
2148                                         self.crouch = FALSE;
2149                                         self.view_ofs = PL_VIEW_OFS;
2150                                         setsize (self, PL_MIN, PL_MAX);
2151                                 }
2152                         }
2153                 }
2154
2155                 FixPlayermodel();
2156
2157                 GrapplingHookFrame();
2158
2159                 W_WeaponFrame();
2160
2161                 player_powerups();
2162                 player_regen();
2163                 player_anim();
2164
2165                 if (g_minstagib)
2166                         minstagib_ammocheck();
2167
2168                 ctf_setstatus();
2169                 kh_setstatus();
2170
2171                 //self.angles_y=self.v_angle_y + 90;   // temp
2172
2173                 //if (TetrisPreFrame()) return;
2174         } else if(gameover) {
2175                 if (intermission_running)
2176                         IntermissionThink ();   // otherwise a button could be missed between
2177                 return;
2178         } else if(self.classname == "observer") {
2179                 ObserverThink();
2180         } else if(self.classname == "spectator") {
2181                 SpectatorThink();
2182         }
2183
2184         if(!zoomstate_set)
2185                 SetZoomState(self.BUTTON_ZOOM || (self.BUTTON_ATCK2 && self.weapon == WEP_NEX));
2186
2187         float oldspectatee_status;
2188         oldspectatee_status = self.spectatee_status;
2189         if(self.classname == "spectator")
2190                 self.spectatee_status = num_for_edict(self.enemy);
2191         else if(self.classname == "observer")
2192                 self.spectatee_status = num_for_edict(self);
2193         else
2194                 self.spectatee_status = 0;
2195         if(self.spectatee_status != oldspectatee_status)
2196         {
2197                 msg_entity = self;
2198                 WriteByte(MSG_ONE, SVC_TEMPENTITY);
2199                 WriteByte(MSG_ONE, TE_CSQC_SPECTATING);
2200                 WriteByte(MSG_ONE, self.spectatee_status);
2201                 if(g_race)
2202                         race_InitSpectator();
2203         }
2204 }
2205
2206
2207 /*
2208 =============
2209 PlayerPostThink
2210
2211 Called every frame for each client after the physics are run
2212 =============
2213 */
2214 .float idlekick_lasttimeleft;
2215 .float race_penalty;
2216 .float race_penalty_nagged;
2217 void PlayerPostThink (void)
2218 {
2219         // Savage: Check for nameless players
2220         if (strlen(self.netname) < 1) {
2221                 self.netname = "Player";
2222                 stuffcmd(self, "seta _cl_name Player\n");
2223         }
2224
2225         if(sv_maxidle)
2226         {
2227                 float timeleft;
2228                 timeleft = ceil(sv_maxidle - (time - self.parm_idlesince));
2229                 if(timeleft <= 0)
2230                 {
2231                         bprint("^3", self.netname, "^3 was kicked for idling.\n");
2232                         announce(self, "announcer/robotic/terminated.ogg");
2233                         dropclient(self);
2234                         return;
2235                 }
2236                 else if(timeleft <= 10)
2237                 {
2238                         if(timeleft != self.idlekick_lasttimeleft)
2239                         {
2240                                 centerprint_atprio(self, CENTERPRIO_IDLEKICK, strcat("^3Stop idling!\n^3Disconnecting in ", ftos(timeleft), "..."));
2241                                 announce(self, strcat("announcer/robotic/", ftos(timeleft), ".ogg"));
2242                         }
2243                 }
2244                 else
2245                 {
2246                         centerprint_expire(self, CENTERPRIO_IDLEKICK);
2247                 }
2248                 self.idlekick_lasttimeleft = timeleft;
2249         }
2250
2251         if(self.classname == "player") {
2252                 CheckRules_Player();
2253                 UpdateChatBubble();
2254                 UpdateTeamBubble();
2255                 if (self.impulse)
2256                         ImpulseCommands();
2257                 if (intermission_running)
2258                         return;         // intermission or finale
2259
2260                 //PrintWelcomeMessage(self);
2261                 //if (TetrisPostFrame()) return;
2262
2263                 // restart countdown
2264                 if (restart_countdown) {
2265                         if(time < restart_countdown) {
2266                                 if (!cvar("sv_ready_restart_after_countdown"))
2267                                 {
2268                                         if(self.movement != '0 0 0' && g_race && !g_race_qualifying)
2269                                         {
2270                                                 if(time < restart_countdown - 2)
2271                                                 {
2272                                                         if(!self.race_penalty_nagged)
2273                                                         {
2274                                                                 centerprint_atprio(self, CENTERPRIO_IDLEKICK, "^1DO NOT MOVE DURING THE COUNTDOWN.");
2275                                                                 self.race_penalty_nagged = 1;
2276                                                         }
2277                                                 }
2278                                                 else if(!self.race_penalty)
2279                                                 {
2280                                                         centerprint_atprio(self, CENTERPRIO_IDLEKICK, "^1FIVE SECONDS PENALTY.");
2281                                                         self.race_penalty = time + 5;
2282                                                 }
2283                                         }
2284                                         self.movetype = MOVETYPE_NONE;
2285                                         self.velocity = '0 0 0';
2286                                         self.avelocity = '0 0 0';
2287                                         self.movement = '0 0 0';
2288                                 }
2289                         }
2290                         else if (time < self.race_penalty)
2291                         {
2292                                 self.movetype = MOVETYPE_NONE;
2293                                 self.velocity = '0 0 0';
2294                                 self.avelocity = '0 0 0';
2295                                 self.movement = '0 0 0';
2296                         }
2297                         else
2298                         {
2299                                 //allow the player to move again if sv_ready_restart_after_countdown is not used and countdown is over
2300                                 if (!cvar("sv_ready_restart_after_countdown"))
2301                                 {
2302                                         if(self.movetype == MOVETYPE_NONE)
2303                                         {
2304                                                 self.movetype = MOVETYPE_WALK;
2305                                         }
2306                                         self.race_penalty = 0;
2307                                         self.race_penalty_nagged = 0;
2308                                 }
2309                         }
2310                 }
2311
2312         } else if (self.classname == "observer") {
2313                 //do nothing
2314         } else if (self.classname == "spectator") {
2315                 //do nothing
2316         }
2317
2318         /*
2319         float i;
2320         for(i = 0; i < 1000; ++i)
2321         {
2322                 vector end;
2323                 end = self.origin + '0 0 1024' + 512 * randomvec();
2324                 tracebox(self.origin, self.mins, self.maxs, end, MOVE_NORMAL, self);
2325                 if(trace_fraction < 1)
2326                 if(!(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
2327                 {
2328                         print("I HIT SOLID: ", vtos(self.origin), " -> ", vtos(end), "\n");
2329                         break;
2330                 }
2331         }
2332         */
2333
2334         Arena_Warmup();
2335 }