data/qcsrc/server/cl_client.qc

   1 .float spectatee_status;
   2 .float zoomstate;
   3 .float bloodloss_timer;
   4 .float restriction;
   5
   6 .entity clientdata;
   7 float ClientData_Send(entity to, float sf)
   8 {
   9         if(to != self.owner)
  10         {
  11                 error("wtf");
  12                 return FALSE;
  13         }
  14
  15         entity e;
  16
  17         e = to;
  18         if(to.classname == "spectator")
  19                 e = to.enemy;
  20
  21         sf = 0;
  22
  23         if(e.race_completed)
  24                 sf |= 1; // forced scoreboard
  25         if(to.spectatee_status)
  26                 sf |= 2; // spectator ent number follows
  27         if(e.zoomstate)
  28                 sf |= 4; // zoomed
  29         if(e.porto_v_angle_held)
  30                 sf |= 8; // angles held
  31
  32         WriteByte(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
  33         WriteByte(MSG_ENTITY, sf);
  34
  35         if(sf & 2)
  36                 WriteByte(MSG_ENTITY, to.spectatee_status);
  37
  38         if(sf & 8)
  39         {
  40                 WriteAngle(MSG_ENTITY, e.v_angle_x);
  41                 WriteAngle(MSG_ENTITY, e.v_angle_y);
  42         }
  43
  44         return TRUE;
  45 }
  46
  47 void ClientData_Attach()
  48 {
  49         Net_LinkEntity(self.clientdata = spawn(), FALSE, 0, ClientData_Send);
  50         self.clientdata.drawonlytoclient = self;
  51         self.clientdata.owner = self;
  52 }
  53
  54 void ClientData_Detach()
  55 {
  56         remove(self.clientdata);
  57         self.clientdata = world;
  58 }
  59
  60 void ClientData_Touch(entity e)
  61 {
  62         e.clientdata.SendFlags = 1;
  63
  64         // make it spectatable
  65         entity e2;
  66         FOR_EACH_REALCLIENT(e2)
  67         {
  68                 if(e2 != e)
  69                         if(e2.classname == "spectator")
  70                                 if(e2.enemy == e)
  71                                         e2.clientdata.SendFlags = 1;
  72         }
  73 }
  74
  75
  76 #define SPAWNPOINT_SCORE frags
  77
  78 .string netname_previous;
  79
  80 void spawnfunc_info_player_survivor (void)
  81 {
  82         spawnfunc_info_player_deathmatch();
  83 }
  84
  85 void spawnfunc_info_player_start (void)
  86 {
  87         spawnfunc_info_player_deathmatch();
  88 }
  89
  90 void spawnfunc_info_player_deathmatch (void)
  91 {
  92         self.classname = "info_player_deathmatch";
  93         relocate_spawnpoint();
  94 }
  95
  96 void spawnpoint_use()
  97 {
  98         if(teams_matter)
  99         if(have_team_spawns)
 100         {
 101                 self.team = activator.team;
 102                 some_spawn_has_been_used = 1;
 103         }
 104 };
 105
 106 // Returns:
 107 //   -1 if a spawn can't be used
 108 //   otherwise, a weight of the spawnpoint
 109 float Spawn_Score(entity spot, entity playerlist, float teamcheck)
 110 {
 111         float shortest, thisdist;
 112         entity player;
 113
 114         // filter out spots for the wrong team
 115         if(teamcheck)
 116         if(spot.team != teamcheck)
 117                 return -1;
 118
 119         if(race_spawns)
 120                 if(spot.target == "")
 121                         return -1;
 122
 123         if(clienttype(self) == CLIENTTYPE_REAL)
 124         {
 125                 if(spot.restriction == 1)
 126                         return -1;
 127         }
 128         else
 129         {
 130                 if(spot.restriction == 2)
 131                         return -1;
 132         }
 133
 134         // filter out spots for assault
 135         if(spot.target != "") {
 136                 local entity ent;
 137                 float good, found;
 138                 ent = find(world, targetname, spot.target);
 139                 while(ent) {
 140                         if(ent.classname == "target_objective")
 141                         {
 142                                 found = 1;
 143                                 if(ent.health < 0 || ent.health >= ASSAULT_VALUE_INACTIVE)
 144                                         return -1;
 145                                 good = 1;
 146                         }
 147                         else if(ent.classname == "trigger_race_checkpoint")
 148                         {
 149                                 found = 1;
 150                                 if(self.classname == "player") // spectators may spawn everywhere
 151                                 {
 152                                         if(g_race_qualifying)
 153                                         {
 154                                                 // spawn at first
 155                                                 if(ent.race_checkpoint != 0)
 156                                                         return -1;
 157                                                 if(spot.race_place != race_lowest_place_spawn)
 158                                                         return -1;
 159                                         }
 160                                         else
 161                                         {
 162                                                 if(ent.race_checkpoint != race_PreviousCheckpoint(self.race_checkpoint))
 163                                                         return -1;
 164                                                 float pl;
 165                                                 pl = self.race_place;
 166                                                 if(pl > race_highest_place_spawn)
 167                                                         pl = 0;
 168                                                 if(spot.race_place != pl)
 169                                                         return -1;
 170                                         }
 171                                 }
 172                                 good = 1;
 173                         }
 174                         ent = find(ent, targetname, spot.target);
 175                 }
 176
 177                 if(found && !good)
 178                         return -1;
 179         }
 180
 181         player = playerlist;
 182         shortest = vlen(world.maxs - world.mins);
 183         for(player = playerlist; player; player = player.chain)
 184                 if (player != self)
 185                 {
 186                         thisdist = vlen(player.origin - spot.origin);
 187                         if (thisdist < shortest)
 188                                 shortest = thisdist;
 189                 }
 190         return shortest;
 191 }
 192
 193 float spawn_allbad;
 194 float spawn_allgood;
 195 entity Spawn_FilterOutBadSpots(entity firstspot, entity playerlist, float mindist, float teamcheck)
 196 {
 197         local entity spot, spotlist, spotlistend;
 198         spawn_allgood = TRUE;
 199         spawn_allbad = TRUE;
 200
 201         spotlist = world;
 202         spotlistend = world;
 203
 204         for(spot = firstspot; spot; spot = spot.chain)
 205         {
 206                 spot.SPAWNPOINT_SCORE = Spawn_Score(spot, playerlist, teamcheck);
 207
 208                 if(cvar("spawn_debugview"))
 209                 {
 210                         setmodel(spot, "models/runematch/rune.mdl");
 211                         if(spot.SPAWNPOINT_SCORE < mindist)
 212                         {
 213                                 spot.colormod = '1 0 0';
 214                                 spot.scale = 1;
 215                         }
 216                         else
 217                         {
 218                                 spot.colormod = '0 1 0';
 219                                 spot.scale = spot.SPAWNPOINT_SCORE / mindist;
 220                         }
 221                 }
 222
 223                 if(spot.SPAWNPOINT_SCORE >= 0) // spawning allowed here
 224                 {
 225                         if(spot.SPAWNPOINT_SCORE < mindist)
 226                         {
 227                                 // too short distance
 228                                 spawn_allgood = FALSE;
 229                         }
 230                         else
 231                         {
 232                                 // perfect
 233                                 spawn_allbad = FALSE;
 234
 235                                 if(spotlistend)
 236                                         spotlistend.chain = spot;
 237                                 spotlistend = spot;
 238                                 if(!spotlist)
 239                                         spotlist = spot;
 240
 241                                 /*
 242                                 if(teamcheck)
 243                                 if(spot.team != teamcheck)
 244                                         error("invalid spawn added");
 245
 246                                 print("added ", etos(spot), "\n");
 247                                 */
 248                         }
 249                 }
 250         }
 251         if(spotlistend)
 252                 spotlistend.chain = world;
 253
 254         /*
 255                 entity e;
 256                 if(teamcheck)
 257                         for(e = spotlist; e; e = e.chain)
 258                         {
 259                                 print("seen ", etos(e), "\n");
 260                                 if(e.team != teamcheck)
 261                                         error("invalid spawn found");
 262                         }
 263         */
 264
 265         return spotlist;
 266 }
 267
 268 entity Spawn_WeightedPoint(entity firstspot, float lower, float upper, float exponent)
 269 {
 270         // weight of a point: bound(lower, mindisttoplayer, upper)^exponent
 271         // multiplied by spot.cnt (useful if you distribute many spawnpoints in a small area)
 272         local entity spot;
 273
 274         RandomSelection_Init();
 275         for(spot = firstspot; spot; spot = spot.chain)
 276                 RandomSelection_Add(spot, 0, string_null, pow(bound(lower, spot.SPAWNPOINT_SCORE, upper), exponent) * spot.cnt, spot.SPAWNPOINT_SCORE >= lower);
 277
 278         return RandomSelection_chosen_ent;
 279 }
 280
 281 /*
 282 =============
 283 SelectSpawnPoint
 284
 285 Finds a point to respawn
 286 =============
 287 */
 288 entity SelectSpawnPoint (float anypoint)
 289 {
 290         local float teamcheck;
 291         local entity firstspot_new;
 292         local entity spot, firstspot, playerlist;
 293
 294         spot = find (world, classname, "testplayerstart");
 295         if (spot)
 296                 return spot;
 297
 298         teamcheck = 0;
 299
 300         if(!anypoint && have_team_spawns)
 301                 teamcheck = self.team;
 302
 303         // get the list of players
 304         playerlist = findchain(classname, "player");
 305         // get the entire list of spots
 306         firstspot = findchain(classname, "info_player_deathmatch");
 307         // filter out the bad ones
 308         // (note this returns the original list if none survived)
 309         if(anypoint)
 310         {
 311                 spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 312         }
 313         else
 314         {
 315                 firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, 100, teamcheck);
 316                 if(!firstspot_new)
 317                         firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, -1, teamcheck);
 318                 firstspot = firstspot_new;
 319
 320                 // there is 50/50 chance of choosing a random spot or the furthest spot
 321                 // (this means that roughly every other spawn will be furthest, so you
 322                 // usually won't get fragged at spawn twice in a row)
 323                 if (arena_roundbased)
 324                 {
 325                         firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, 800, teamcheck);
 326                         if(firstspot_new)
 327                                 firstspot = firstspot_new;
 328                         spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 329                 }
 330                 else if (random() > cvar("g_spawn_furthest"))
 331                         spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 332                 else
 333                         spot = Spawn_WeightedPoint(firstspot, 1, 5000, 5); // chooses a far far away spawnpoint
 334         }
 335
 336         if(cvar("spawn_debugview"))
 337         {
 338                 print("spot mindistance: ", ftos(spot.SPAWNPOINT_SCORE), "\n");
 339
 340                 entity e;
 341                 if(teamcheck)
 342                         for(e = firstspot; e; e = e.chain)
 343                                 if(e.team != teamcheck)
 344                                         error("invalid spawn found");
 345         }
 346
 347         if (!spot)
 348         {
 349                 if(cvar("spawn_debug"))
 350                         GotoNextMap();
 351                 else
 352                 {
 353                         if(some_spawn_has_been_used)
 354                                 return world; // team can't spawn any more, because of actions of other team
 355                         else
 356                                 error("Cannot find a spawn point - please fix the map!");
 357                 }
 358         }
 359
 360         return spot;
 361 }
 362
 363 /*
 364 =============
 365 CheckPlayerModel
 366
 367 Checks if the argument string can be a valid playermodel.
 368 Returns a valid one in doubt.
 369 =============
 370 */
 371 string FallbackPlayerModel = "models/player/marine.zym";
 372 string CheckPlayerModel(string plyermodel) {
 373         if(strlen(plyermodel) < 4)
 374                 return FallbackPlayerModel;
 375         if( substring(plyermodel,0,14) != "models/player/")
 376                 return FallbackPlayerModel;
 377         else if(cvar("sv_servermodelsonly"))
 378         {
 379                 if(substring(plyermodel,-4,4) != ".zym")
 380                 if(substring(plyermodel,-4,4) != ".dpm")
 381                 if(substring(plyermodel,-4,4) != ".md3")
 382                 if(substring(plyermodel,-4,4) != ".psk")
 383                         return FallbackPlayerModel;
 384                 // forbid the LOD models
 385                 if(substring(plyermodel, -9,5) == "_lod1")
 386                         return FallbackPlayerModel;
 387                 if(substring(plyermodel, -9,5) == "_lod2")
 388                         return FallbackPlayerModel;
 389                 if(plyermodel != strtolower(plyermodel))
 390                         return FallbackPlayerModel;
 391                 if(!fexists(plyermodel))
 392                         return FallbackPlayerModel;
 393         }
 394         return plyermodel;
 395 }
 396
 397 /*
 398 =============
 399 Client_customizeentityforclient
 400
 401 LOD reduction
 402 =============
 403 */
 404 void Client_uncustomizeentityforclient()
 405 {
 406         if(self.modelindex == 0) // no need to uncustomize then
 407                 return;
 408         self.modelindex = self.modelindex_lod0;
 409         self.skin = self.skinindex;
 410 }
 411
 412 float Client_customizeentityforclient()
 413 {
 414         entity modelsource;
 415
 416         if(self.modelindex == 0)
 417                 return TRUE;
 418
 419         // forcemodel stuff
 420
 421 #ifdef PROFILING
 422         float t0;
 423         t0 = gettime(GETTIME_HIRES); // reference
 424 #endif
 425
 426         modelsource = self;
 427
 428 #ifdef ALLOW_FORCEMODELS
 429         if(other.cvar_cl_forceplayermodelsfromnexuiz)
 430                 if not(self.modelindex_lod0_from_nexuiz)
 431                         modelsource = other;
 432         if(other.cvar_cl_forceplayermodels && sv_clforceplayermodels)
 433                 modelsource = other;
 434 #endif
 435
 436         self.skin = modelsource.skinindex;
 437
 438 #if 0
 439         if(modelsource == self)
 440                 self.skin = modelsource.skinindex;
 441         else
 442                 self.skin = mod(modelsource.skinindex, 3); // forbid the fbskins as forced skins
 443 #endif
 444
 445         // self: me
 446         // other: the player viewing me
 447         float distance;
 448         float f;
 449
 450         if(other.cvar_cl_playerdetailreduction <= 0)
 451         {
 452                 if(other.cvar_cl_playerdetailreduction <= -2)
 453                         self.modelindex = modelsource.modelindex_lod2;
 454                 else if(other.cvar_cl_playerdetailreduction <= -1)
 455                         self.modelindex = modelsource.modelindex_lod1;
 456                 else
 457                         self.modelindex = modelsource.modelindex_lod0;
 458         }
 459         else
 460         {
 461                 distance = vlen(self.origin - other.origin);
 462                 f = (distance + 100.0) * other.cvar_cl_playerdetailreduction;
 463                 if(f > sv_loddistance2)
 464                         self.modelindex = modelsource.modelindex_lod2;
 465                 else if(f > sv_loddistance1)
 466                         self.modelindex = modelsource.modelindex_lod1;
 467                 else
 468                         self.modelindex = modelsource.modelindex_lod0;
 469         }
 470
 471 #ifdef PROFILING
 472         float t1;
 473         t1 = gettime(GETTIME_HIRES); // reference
 474         client_cefc_accumulator += (t1 - t0);
 475 #endif
 476
 477         return TRUE;
 478 }
 479
 480 void UpdatePlayerSounds();
 481 void setmodel_lod(entity e, string modelname)
 482 {
 483         string s;
 484
 485         if(sv_loddistance1)
 486         {
 487                 // FIXME: this only supports 3-letter extensions
 488                 s = strcat(substring(modelname, 0, strlen(modelname)-4), "_lod1", substring(modelname, -4, 4));
 489                 if(fexists(s))
 490                 {
 491                         setmodel(e, s); // players have high precision
 492                         self.modelindex_lod1 = self.modelindex;
 493                 }
 494                 else
 495                         self.modelindex_lod1 = -1;
 496
 497                 s = strcat(substring(modelname, 0, strlen(modelname)-4), "_lod2", substring(modelname, -4, 4));
 498                 if(fexists(s))
 499                 {
 500                         setmodel(e, s); // players have high precision
 501                         self.modelindex_lod2 = self.modelindex;
 502                 }
 503                 else
 504                         self.modelindex_lod2 = -1;
 505
 506                 precache_model(modelname);
 507                 setmodel(e, modelname); // players have high precision
 508                 self.modelindex_lod0 = self.modelindex;
 509
 510                 if(self.modelindex_lod1 < 0)
 511                         self.modelindex_lod1 = self.modelindex;
 512
 513                 if(self.modelindex_lod2 < 0)
 514                         self.modelindex_lod2 = self.modelindex;
 515         }
 516         else
 517         {
 518                 precache_model(modelname);
 519                 setmodel(e, modelname); // players have high precision
 520                 self.modelindex_lod0 = self.modelindex;
 521                         // save it for possible player model forcing
 522         }
 523
 524         s = whichpack(self.model);
 525         self.modelindex_lod0_from_nexuiz = ((s == "") || (substring(s, 0, 4) == "data"));
 526
 527         player_setupanimsformodel();
 528         UpdatePlayerSounds();
 529 }
 530
 531 /*
 532 =============
 533 PutObserverInServer
 534
 535 putting a client as observer in the server
 536 =============
 537 */
 538 void FixPlayermodel();
 539 void PutObserverInServer (void)
 540 {
 541         entity  spot;
 542
 543         race_PreSpawnObserver();
 544
 545         spot = SelectSpawnPoint (TRUE);
 546         if(!spot)
 547                 error("No spawnpoints for observers?!?\n");
 548         RemoveGrapplingHook(self); // Wazat's Grappling Hook
 549
 550         if(clienttype(self) == CLIENTTYPE_REAL)
 551         {
 552                 msg_entity = self;
 553                 WriteByte(MSG_ONE, SVC_SETVIEW);
 554                 WriteEntity(MSG_ONE, self);
 555         }
 556
 557         DropAllRunes(self);
 558         kh_Key_DropAll(self, TRUE);
 559
 560         Portal_ClearAll(self);
 561
 562         if(self.flagcarried)
 563                 DropFlag(self.flagcarried, world, world);
 564         if(self.ballcarried)
 565                 DropBall(self.ballcarried, self.origin + self.ballcarried.origin, self.velocity);
 566
 567         WaypointSprite_PlayerDead();
 568
 569         if(self.killcount != -666)
 570         {
 571                 if(g_lms)
 572                 {
 573                         if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
 574                                 bprint ("^4", self.netname, "^4 has no more lives left\n");
 575                         else
 576                                 bprint ("^4", self.netname, "^4 is spectating now\n"); // TODO turn this into a proper forfeit?
 577                 }
 578                 else
 579                         bprint ("^4", self.netname, "^4 is spectating now\n");
 580         }
 581
 582         PlayerScore_Clear(self); // clear scores when needed
 583
 584         self.spectatortime = time;
 585
 586         self.classname = "observer";
 587         self.iscreature = FALSE;
 588         self.health = -666;
 589         self.takedamage = DAMAGE_NO;
 590         self.solid = SOLID_NOT;
 591         self.movetype = MOVETYPE_NOCLIP;
 592         self.flags = FL_CLIENT | FL_NOTARGET;
 593         self.armorvalue = 666;
 594         self.effects = 0;
 595         self.armorvalue = cvar("g_balance_armor_start");
 596         self.pauserotarmor_finished = 0;
 597         self.pauserothealth_finished = 0;
 598         self.pauseregen_finished = 0;
 599         self.damageforcescale = 0;
 600         self.death_time = 0;
 601         self.dead_frame = 0;
 602         self.alpha = 0;
 603         self.scale = 0;
 604         self.fade_time = 0;
 605         self.pain_frame = 0;
 606         self.pain_finished = 0;
 607         self.strength_finished = 0;
 608         self.invincible_finished = 0;
 609         self.pushltime = 0;
 610         self.think = SUB_Null;
 611         self.nextthink = 0;
 612         self.hook_time = 0;
 613         self.runes = 0;
 614         self.deadflag = DEAD_NO;
 615         self.angles = spot.angles;
 616         self.angles_z = 0;
 617         self.fixangle = TRUE;
 618         self.crouch = FALSE;
 619
 620         self.view_ofs = PL_VIEW_OFS;
 621         setorigin (self, spot.origin);
 622         setsize (self, '0 0 0', '0 0 0');
 623         self.prevorigin = self.origin;
 624         self.items = 0;
 625         self.weapons = 0;
 626         self.model = "";
 627         FixPlayermodel();
 628         self.model = "";
 629         self.modelindex = 0;
 630         self.weapon = 0;
 631         self.weaponmodel = "";
 632         self.weaponentity = world;
 633         self.exteriorweaponentity = world;
 634         self.killcount = -666;
 635         self.velocity = '0 0 0';
 636         self.avelocity = '0 0 0';
 637         self.punchangle = '0 0 0';
 638         self.punchvector = '0 0 0';
 639         self.oldvelocity = self.velocity;
 640
 641         if(sv_loddistance1)
 642                 SetCustomizer(self, Client_customizeentityforclient, Client_uncustomizeentityforclient);
 643
 644         self.team = -1;
 645
 646         if(g_arena)
 647         {
 648                 if(self.version_mismatch)
 649                 {
 650                         Spawnqueue_Unmark(self);
 651                         Spawnqueue_Remove(self);
 652                 }
 653                 else
 654                 {
 655                         Spawnqueue_Insert(self);
 656                 }
 657         }
 658         else if(g_lms)
 659         {
 660                 // Only if the player cannot play at all
 661                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) == 666)
 662                         self.frags = FRAGS_SPECTATOR;
 663                 else
 664                         self.frags = FRAGS_LMS_LOSER;
 665         }
 666         else
 667                 self.frags = FRAGS_SPECTATOR;
 668 }
 669
 670 float RestrictSkin(float s)
 671 {
 672         if(!teams_matter)
 673                 return s;
 674         if(s == 6)
 675                 return 6;
 676         return mod(s, 3);
 677 }
 678
 679 void FixPlayermodel()
 680 {
 681         local string defaultmodel;
 682         local float defaultskin, chmdl, oldskin;
 683         local vector m1, m2;
 684
 685         defaultmodel = "";
 686
 687         if(cvar("sv_defaultcharacter") == 1) {
 688                 defaultskin = 0;
 689
 690                 if(teams_matter)
 691                 {
 692                         defaultmodel = cvar_string(strcat("sv_defaultplayermodel_", Team_ColorNameLowerCase(self.team)));
 693                         defaultskin = cvar(strcat("sv_defaultplayerskin_", Team_ColorNameLowerCase(self.team)));
 694                 }
 695
 696                 if(defaultmodel == "")
 697                 {
 698                         defaultmodel = cvar_string("sv_defaultplayermodel");
 699                         defaultskin = cvar("sv_defaultplayerskin");
 700                 }
 701         }
 702
 703         if(self.modelindex == 0 && self.deadflag == DEAD_NO)
 704         {
 705                 if(self.model != "")
 706                         bprint("\{1}^1Player ", self.netname, "^1 has a zero modelindex, trying to fix...\n");
 707                 self.model = ""; // force the != checks to return true
 708         }
 709
 710         if(defaultmodel != "")
 711         {
 712                 if (defaultmodel != self.model)
 713                 {
 714                         m1 = self.mins;
 715                         m2 = self.maxs;
 716                         setmodel_lod (self, defaultmodel);
 717                         setsize (self, m1, m2);
 718                         chmdl = TRUE;
 719                 }
 720
 721                 oldskin = self.skinindex;
 722                 self.skinindex = defaultskin;
 723         } else {
 724                 if (self.playermodel != self.model)
 725                 {
 726                         self.playermodel = CheckPlayerModel(self.playermodel);
 727                         m1 = self.mins;
 728                         m2 = self.maxs;
 729                         setmodel_lod (self, self.playermodel);
 730                         setsize (self, m1, m2);
 731                         chmdl = TRUE;
 732                 }
 733
 734                 oldskin = self.skinindex;
 735                 self.skinindex = RestrictSkin(stof(self.playerskin));
 736         }
 737
 738         if(chmdl || oldskin != self.skinindex)
 739                 self.species = player_getspecies(); // model or skin has changed
 740
 741         if(!teams_matter)
 742                 if(strlen(cvar_string("sv_defaultplayercolors")))
 743                         if(self.clientcolors != cvar("sv_defaultplayercolors"))
 744                                 setcolor(self, cvar("sv_defaultplayercolors"));
 745 }
 746
 747 void PlayerTouchExplode(entity p1, entity p2)
 748 {
 749         vector org;
 750         org = (p1.origin + p2.origin) * 0.5;
 751         org_z += (p1.mins_z + p2.mins_z) * 0.5;
 752
 753         te_explosion(org);
 754
 755         entity e;
 756         e = spawn();
 757         setorigin(e, org);
 758         RadiusDamage(e, world, g_touchexplode_damage, g_touchexplode_edgedamage, g_touchexplode_radius, world, g_touchexplode_force, DEATH_TOUCHEXPLODE, world);
 759         remove(e);
 760 }
 761
 762 /*
 763 =============
 764 PutClientInServer
 765
 766 Called when a client spawns in the server
 767 =============
 768 */
 769 //void() ctf_playerchanged;
 770 void PutClientInServer (void)
 771 {
 772         if(clienttype(self) == CLIENTTYPE_BOT)
 773         {
 774                 self.classname = "player";
 775         }
 776         else if(clienttype(self) == CLIENTTYPE_REAL)
 777         {
 778                 msg_entity = self;
 779                 WriteByte(MSG_ONE, SVC_SETVIEW);
 780                 WriteEntity(MSG_ONE, self);
 781         }
 782
 783         // player is dead and becomes observer
 784         // FIXME fix LMS scoring for new system
 785         if(g_lms)
 786         {
 787                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
 788                         self.classname = "observer";
 789         }
 790
 791         if(g_arena)
 792         if(!self.spawned)
 793                 self.classname = "observer";
 794
 795         if(gameover)
 796                 self.classname = "observer";
 797
 798         if(self.classname == "player") {
 799                 entity spot, oldself;
 800
 801                 if(self.team < 0)
 802                         JoinBestTeam(self, FALSE, TRUE);
 803
 804                 race_PreSpawn();
 805
 806                 spot = SelectSpawnPoint (FALSE);
 807                 if(!spot)
 808                 {
 809                         centerprint(self, "Sorry, no spawnpoints available!\nHope your team can fix it...");
 810                         return; // spawn failed
 811                 }
 812
 813                 RemoveGrapplingHook(self); // Wazat's Grappling Hook
 814                 self.campingrifle_bulletcounter = cvar("g_balance_campingrifle_magazinecapacity");
 815
 816                 self.classname = "player";
 817                 self.wasplayer = TRUE;
 818                 self.iscreature = TRUE;
 819                 self.movetype = MOVETYPE_WALK;
 820                 self.solid = SOLID_SLIDEBOX;
 821                 self.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP;
 822                 self.frags = FRAGS_PLAYER;
 823                 if(independent_players)
 824                         MAKE_INDEPENDENT_PLAYER(self);
 825                 self.flags = FL_CLIENT;
 826                 self.takedamage = DAMAGE_AIM;
 827                 if(g_minstagib)
 828                         self.effects = EF_FULLBRIGHT;
 829                 else
 830                         self.effects = 0;
 831                 self.air_finished = time + 12;
 832                 self.dmg = 2;
 833
 834                 if(inWarmupStage)
 835                 {
 836                         self.ammo_shells = warmup_start_ammo_shells;
 837                         self.ammo_nails = warmup_start_ammo_nails;
 838                         self.ammo_rockets = warmup_start_ammo_rockets;
 839                         self.ammo_cells = warmup_start_ammo_cells;
 840                         self.ammo_fuel = warmup_start_ammo_fuel;
 841                         self.health = warmup_start_health;
 842                         self.armorvalue = warmup_start_armorvalue;
 843                         self.weapons = warmup_start_weapons;
 844                 }
 845                 else
 846                 {
 847                         self.ammo_shells = start_ammo_shells;
 848                         self.ammo_nails = start_ammo_nails;
 849                         self.ammo_rockets = start_ammo_rockets;
 850                         self.ammo_cells = start_ammo_cells;
 851                         self.ammo_fuel = start_ammo_fuel;
 852                         self.health = start_health;
 853                         self.armorvalue = start_armorvalue;
 854                         self.weapons = start_weapons;
 855                 }
 856                 self.items = start_items;
 857                 self.switchweapon = w_getbestweapon(self);
 858                 self.cnt = self.switchweapon;
 859                 self.weapon = 0;
 860                 self.jump_interval = time;
 861
 862                 self.spawnshieldtime = time + cvar("g_spawnshieldtime");
 863                 self.pauserotarmor_finished = time + cvar("g_balance_pause_armor_rot_spawn");
 864                 self.pauserothealth_finished = time + cvar("g_balance_pause_health_rot_spawn");
 865                 self.pauserotfuel_finished = time + cvar("g_balance_pause_fuel_rot_spawn");
 866                 self.pauseregen_finished = time + cvar("g_balance_pause_health_regen_spawn");
 867                 //extend the pause of rotting if client was reset at the beginning of the countdown
 868                 if(!cvar("sv_ready_restart_after_countdown") && time < game_starttime) { // TODO why is this cvar NOTted?
 869                         self.spawnshieldtime += game_starttime - time;
 870                         self.pauserotarmor_finished += game_starttime - time;
 871                         self.pauserothealth_finished += game_starttime - time;
 872                         self.pauseregen_finished += game_starttime - time;
 873                 }
 874                 self.damageforcescale = 2;
 875                 self.death_time = 0;
 876                 self.dead_frame = 0;
 877                 self.alpha = 0;
 878                 self.scale = 0;
 879                 self.fade_time = 0;
 880                 self.pain_frame = 0;
 881                 self.pain_finished = 0;
 882                 self.strength_finished = 0;
 883                 self.invincible_finished = 0;
 884                 self.pushltime = 0;
 885                 //self.speed_finished = 0;
 886                 //self.slowmo_finished = 0;
 887                 // players have no think function
 888                 self.think = SUB_Null;
 889                 self.nextthink = 0;
 890                 self.hook_time = 0;
 891                 self.dmg_team = 0;
 892
 893                 self.metertime = 0;
 894
 895                 self.runes = 0;
 896
 897                 self.deadflag = DEAD_NO;
 898
 899                 self.angles = spot.angles;
 900
 901                 self.angles_z = 0; // never spawn tilted even if the spot says to
 902                 self.fixangle = TRUE; // turn this way immediately
 903                 self.velocity = '0 0 0';
 904                 self.avelocity = '0 0 0';
 905                 self.punchangle = '0 0 0';
 906                 self.punchvector = '0 0 0';
 907                 self.oldvelocity = self.velocity;
 908
 909                 msg_entity = self;
 910                 WRITESPECTATABLE_MSG_ONE({
 911                         WriteByte(MSG_ONE, SVC_TEMPENTITY);
 912                         WriteByte(MSG_ONE, TE_CSQC_SPAWN);
 913                 });
 914
 915                 if(sv_loddistance1)
 916                         SetCustomizer(self, Client_customizeentityforclient, Client_uncustomizeentityforclient);
 917
 918                 self.model = "";
 919                 FixPlayermodel();
 920
 921                 self.crouch = FALSE;
 922                 self.view_ofs = PL_VIEW_OFS;
 923                 setsize (self, PL_MIN, PL_MAX);
 924                 self.spawnorigin = spot.origin;
 925                 setorigin (self, spot.origin + '0 0 1' * (1 - self.mins_z - 24));
 926                 // don't reset back to last position, even if new position is stuck in solid
 927                 self.oldorigin = self.origin;
 928                 self.prevorigin = self.origin;
 929                 self.lastrocket = world; // stop rocket guiding, no revenge from the grave!
 930
 931                 if(g_arena)
 932                 {
 933                         Spawnqueue_Remove(self);
 934                         Spawnqueue_Mark(self);
 935                 }
 936
 937                 self.event_damage = PlayerDamage;
 938
 939                 self.bot_attack = TRUE;
 940
 941                 self.statdraintime = time + 5;
 942                 self.BUTTON_ATCK = self.BUTTON_JUMP = self.BUTTON_ATCK2 = 0;
 943
 944                 if(self.killcount == -666) {
 945                         PlayerScore_Clear(self);
 946                         self.killcount = 0;
 947                 }
 948
 949                 self.cnt = WEP_LASER;
 950                 self.nixnex_lastchange_id = -1;
 951
 952                 CL_SpawnWeaponentity();
 953                 self.alpha = default_player_alpha;
 954                 self.colormod = '1 1 1' * cvar("g_player_brightness");
 955                 self.exteriorweaponentity.alpha = default_weapon_alpha;
 956
 957                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval")*2;
 958                 self.lms_traveled_distance = 0;
 959                 self.speedrunning = FALSE;
 960
 961                 race_PostSpawn(spot);
 962
 963                 if(cvar("spawn_debug"))
 964                 {
 965                         sprint(self, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 966                         remove(spot);   // usefull for checking if there are spawnpoints, that let drop through the floor
 967                 }
 968
 969                 //stuffcmd(self, "chase_active 0");
 970                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
 971
 972                 if (cvar("g_spawnsound"))
 973                         sound (self, CHAN_TRIGGER, "misc/spawn.wav", VOL_BASE, ATTN_NORM);
 974
 975                 if(g_assault) {
 976                         if(self.team == assault_attacker_team)
 977                                 centerprint(self, "You are attacking!");
 978                         else
 979                                 centerprint(self, "You are defending!");
 980                 }
 981
 982                 target_voicescript_clear(self);
 983
 984                 oldself = self;
 985                 self = spot;
 986                         activator = oldself;
 987                                 SUB_UseTargets();
 988                         activator = world;
 989                 self = oldself;
 990
 991         } else if(self.classname == "observer") {
 992                 PutObserverInServer ();
 993         }
 994
 995         //if(g_ctf)
 996         //      ctf_playerchanged();
 997 }
 998
 999 float ClientInit_SendEntity(entity to, float sf)
1000 {
1001         float i;
1002         WriteByte(MSG_ENTITY, ENT_CLIENT_INIT);
1003         WriteByte(MSG_ENTITY, g_nexball_meter_period * 32);
1004         for(i = 1; i <= 24; ++i)
1005                 WriteByte(MSG_ENTITY, (get_weaponinfo(i)).impulse + 1);
1006         WriteCoord(MSG_ENTITY, hook_shotorigin_x);
1007         WriteCoord(MSG_ENTITY, hook_shotorigin_y);
1008         WriteCoord(MSG_ENTITY, hook_shotorigin_z);
1009
1010         if(sv_foginterval && world.fog != "")
1011                 WriteString(MSG_ENTITY, world.fog);
1012         else
1013                 WriteString(MSG_ENTITY, "");
1014         WriteByte(MSG_ENTITY, cvar("g_balance_armor_blockpercent") * 255.0);
1015         return TRUE;
1016 }
1017
1018 void ClientInit_Spawn()
1019 {
1020         Net_LinkEntity(spawn(), FALSE, 0, ClientInit_SendEntity);
1021 }
1022
1023 /*
1024 =============
1025 SetNewParms
1026 =============
1027 */
1028 void SetNewParms (void)
1029 {
1030         // initialize parms for a new player
1031         parm1 = -(86400 * 366);
1032 }
1033
1034 /*
1035 =============
1036 SetChangeParms
1037 =============
1038 */
1039 void SetChangeParms (void)
1040 {
1041         // save parms for level change
1042         parm1 = self.parm_idlesince - time;
1043 }
1044
1045 /*
1046 =============
1047 DecodeLevelParms
1048 =============
1049 */
1050 void DecodeLevelParms (void)
1051 {
1052         // load parms
1053         self.parm_idlesince = parm1;
1054         if(self.parm_idlesince == -(86400 * 366))
1055                 self.parm_idlesince = time;
1056
1057         // whatever happens, allow 60 seconds of idling directly after connect for map loading
1058         self.parm_idlesince = max(self.parm_idlesince, time - sv_maxidle + 60);
1059 }
1060
1061 /*
1062 =============
1063 ClientKill
1064
1065 Called when a client types 'kill' in the console
1066 =============
1067 */
1068
1069 void ClientKill_Now_TeamChange()
1070 {
1071         if(self.killindicator_teamchange == -1)
1072         {
1073                 self.team = -1;
1074                 JoinBestTeam( self, FALSE, FALSE );
1075         }
1076         else
1077                 SV_ChangeTeam(self.killindicator_teamchange - 1);
1078 }
1079
1080 void ClientKill_Now()
1081 {
1082         if(self.killindicator_teamchange)
1083                 ClientKill_Now_TeamChange();
1084
1085         // in any case:
1086         Damage(self, self, self, 100000, DEATH_KILL, self.origin, '0 0 0');
1087
1088         if(self.killindicator)
1089         {
1090                 dprint("Cleaned up after a leaked kill indicator.\n");
1091                 remove(self.killindicator);
1092                 self.killindicator = world;
1093         }
1094 }
1095 void KillIndicator_Think()
1096 {
1097         if (!self.owner.modelindex)
1098         {
1099                 self.owner.killindicator = world;
1100                 remove(self);
1101                 return;
1102         }
1103
1104         if(self.cnt <= 0)
1105         {
1106                 self = self.owner;
1107                 ClientKill_Now(); // no oldself needed
1108                 return;
1109         }
1110         else
1111         {
1112                 if(self.cnt <= 10)
1113                         setmodel(self, strcat("models/sprites/", ftos(self.cnt), ".spr32"));
1114                 if(clienttype(self.owner) == CLIENTTYPE_REAL)
1115                 {
1116                         if(self.cnt <= 10)
1117                                 announce(self.owner, strcat("announcer/robotic/", ftos(self.cnt), ".wav"));
1118                         if(self.owner.killindicator_teamchange)
1119                         {
1120                                 if(self.owner.killindicator_teamchange == -1)
1121                                         centerprint(self.owner, strcat("Changing team in ", ftos(self.cnt), " seconds"));
1122                                 else
1123                                         centerprint(self.owner, strcat("Changing to ", ColoredTeamName(self.owner.killindicator_teamchange), " in ", ftos(self.cnt), " seconds"));
1124                         }
1125                         else
1126                                 centerprint(self.owner, strcat("^1Suicide in ", ftos(self.cnt), " seconds"));
1127                 }
1128                 self.nextthink = time + 1;
1129                 self.cnt -= 1;
1130         }
1131 }
1132
1133 void ClientKill_TeamChange (float targetteam) // 0 = don't change, -1 = auto
1134 {
1135         float killtime;
1136         entity e;
1137         killtime = cvar("g_balance_kill_delay");
1138
1139         if(g_race_qualifying)
1140                 killtime = 0;
1141
1142         self.killindicator_teamchange = targetteam;
1143
1144         if(!self.killindicator)
1145         {
1146                 if(killtime <= 0 || !self.modelindex || self.deadflag != DEAD_NO)
1147                 {
1148                         ClientKill_Now();
1149                 }
1150                 else
1151                 {
1152                         self.killindicator = spawn();
1153                         self.killindicator.owner = self;
1154                         self.killindicator.scale = 0.5;
1155                         setattachment(self.killindicator, self, "");
1156                         setorigin(self.killindicator, '0 0 52');
1157                         self.killindicator.think = KillIndicator_Think;
1158                         self.killindicator.nextthink = time + (self.lip) * 0.05;
1159                         self.killindicator.cnt = ceil(killtime);
1160                         self.killindicator.count = bound(0, ceil(killtime), 10);
1161                         sprint(self, strcat("^1You'll be dead in ", ftos(self.killindicator.cnt), " seconds\n"));
1162
1163                         for(e = world; (e = find(e, classname, "body")) != world; )
1164                         {
1165                                 if(e.enemy != self)
1166                                         continue;
1167                                 e.killindicator = spawn();
1168                                 e.killindicator.owner = e;
1169                                 e.killindicator.scale = 0.5;
1170                                 setattachment(e.killindicator, e, "");
1171                                 setorigin(e.killindicator, '0 0 52');
1172                                 e.killindicator.think = KillIndicator_Think;
1173                                 e.killindicator.nextthink = time + (e.lip) * 0.05;
1174                                 e.killindicator.cnt = ceil(killtime);
1175                         }
1176                         self.lip = 0;
1177                 }
1178         }
1179         if(self.killindicator)
1180         {
1181                 if(targetteam)
1182                         self.killindicator.colormod = TeamColor(targetteam);
1183                 else
1184                         self.killindicator.colormod = '0 0 0';
1185         }
1186 }
1187
1188 void ClientKill (void)
1189 {
1190         ClientKill_TeamChange(0);
1191 }
1192
1193 void DoTeamChange(float destteam)
1194 {
1195         float t, c0;
1196         if(!teams_matter)
1197         {
1198                 if(destteam >= 0)
1199                         SetPlayerColors(self, destteam);
1200                 return;
1201         }
1202         if(self.classname == "player")
1203         if(destteam == -1)
1204         {
1205                 CheckAllowedTeams(self);
1206                 t = FindSmallestTeam(self, TRUE);
1207                 switch(self.team)
1208                 {
1209                         case COLOR_TEAM1: c0 = c1; break;
1210                         case COLOR_TEAM2: c0 = c2; break;
1211                         case COLOR_TEAM3: c0 = c3; break;
1212                         case COLOR_TEAM4: c0 = c4; break;
1213                         default:          c0 = 999;
1214                 }
1215                 switch(t)
1216                 {
1217                         case 1:
1218                                 if(c0 > c1)
1219                                         destteam = COLOR_TEAM1;
1220                                 break;
1221                         case 2:
1222                                 if(c0 > c2)
1223                                         destteam = COLOR_TEAM2;
1224                                 break;
1225                         case 3:
1226                                 if(c0 > c3)
1227                                         destteam = COLOR_TEAM3;
1228                                 break;
1229                         case 4:
1230                                 if(c0 > c4)
1231                                         destteam = COLOR_TEAM4;
1232                                 break;
1233                 }
1234                 if(destteam == -1)
1235                         return;
1236         }
1237         if(destteam == self.team && destteam >= 0 && !self.killindicator)
1238                 return;
1239         ClientKill_TeamChange(destteam);
1240 }
1241
1242 void FixClientCvars(entity e)
1243 {
1244         // send prediction settings to the client
1245         stuffcmd(e, "\nin_bindmap 0 0\n");
1246         if(g_race || g_cts)
1247                 stuffcmd(e, "cl_cmd settemp cl_movecliptokeyboard 2\n");
1248         /*
1249          * we no longer need to stuff this. Remove this comment block if you feel
1250          * 2.3 and higher (or was it 2.2.3?) don't need these any more
1251         stuffcmd(e, strcat("cl_gravity ", ftos(cvar("sv_gravity")), "\n"));
1252         stuffcmd(e, strcat("cl_movement_accelerate ", ftos(cvar("sv_accelerate")), "\n"));
1253         stuffcmd(e, strcat("cl_movement_friction ", ftos(cvar("sv_friction")), "\n"));
1254         stuffcmd(e, strcat("cl_movement_maxspeed ", ftos(cvar("sv_maxspeed")), "\n"));
1255         stuffcmd(e, strcat("cl_movement_airaccelerate ", ftos(cvar("sv_airaccelerate")), "\n"));
1256         stuffcmd(e, strcat("cl_movement_maxairspeed ", ftos(cvar("sv_maxairspeed")), "\n"));
1257         stuffcmd(e, strcat("cl_movement_stopspeed ", ftos(cvar("sv_stopspeed")), "\n"));
1258         stuffcmd(e, strcat("cl_movement_jumpvelocity ", ftos(cvar("sv_jumpvelocity")), "\n"));
1259         stuffcmd(e, strcat("cl_movement_stepheight ", ftos(cvar("sv_stepheight")), "\n"));
1260         stuffcmd(e, strcat("set cl_movement_friction_on_land ", ftos(cvar("sv_friction_on_land")), "\n"));
1261         stuffcmd(e, strcat("set cl_movement_airaccel_qw ", ftos(cvar("sv_airaccel_qw")), "\n"));
1262         stuffcmd(e, strcat("set cl_movement_airaccel_sideways_friction ", ftos(cvar("sv_airaccel_sideways_friction")), "\n"));
1263         stuffcmd(e, "cl_movement_edgefriction 1\n");
1264          */
1265 }
1266
1267 /*
1268 =============
1269 ClientConnect
1270
1271 Called when a client connects to the server
1272 =============
1273 */
1274 //void ctf_clientconnect();
1275 string ColoredTeamName(float t);
1276 void DecodeLevelParms (void);
1277 //void dom_player_join_team(entity pl);
1278 void ClientConnect (void)
1279 {
1280         local string s;
1281         float t;
1282
1283         if(self.flags & FL_CLIENT)
1284         {
1285                 print("Warning: ClientConnect, but already connected!\n");
1286                 return;
1287         }
1288
1289         if(Ban_MaybeEnforceBan(self))
1290                 return;
1291
1292         DecodeLevelParms();
1293
1294         self.classname = "player_joining";
1295
1296         self.flags = FL_CLIENT;
1297         self.version_nagtime = time + 10 + random() * 10;
1298
1299         if(player_count<0)
1300         {
1301                 dprint("BUG player count is lower than zero, this cannot happen!\n");
1302                 player_count = 0;
1303         }
1304
1305         PlayerScore_Attach(self);
1306         ClientData_Attach();
1307
1308         bot_clientconnect();
1309
1310         race_PreSpawnObserver();
1311
1312         //if(g_domination)
1313         //      dom_player_join_team(self);
1314
1315         JoinBestTeam(self, FALSE, FALSE); // if the team number is valid, keep it
1316
1317         if((cvar("sv_spectate") == 1 && !g_lms) || cvar("g_campaign")) {
1318                 self.classname = "observer";
1319         } else {
1320                 if(teams_matter)
1321                 {
1322                         if(cvar("g_balance_teams") || cvar("g_balance_teams_force"))
1323                         {
1324                                 self.classname = "player";
1325                                 campaign_bots_may_start = 1;
1326                         }
1327                         else
1328                         {
1329                                 self.classname = "observer"; // do it anyway
1330                         }
1331                 }
1332                 else
1333                 {
1334                         self.classname = "player";
1335                         campaign_bots_may_start = 1;
1336                 }
1337         }
1338
1339         self.playerid = (playerid_last = playerid_last + 1);
1340         if(cvar("sv_eventlog"))
1341         {
1342                 if(clienttype(self) == CLIENTTYPE_REAL)
1343                         GameLogEcho(strcat(":join:", ftos(self.playerid), ":", ftos(num_for_edict(self)), ":", self.netaddress, ":", self.netname));
1344                 else
1345                         GameLogEcho(strcat(":join:", ftos(self.playerid), ":", ftos(num_for_edict(self)), ":bot:", self.netname));
1346                 s = strcat(":team:", ftos(self.playerid), ":");
1347                 s = strcat(s, ftos(self.team));
1348                 GameLogEcho(s);
1349         }
1350         self.netname_previous = strzone(self.netname);
1351
1352         //stuffcmd(self, "set tmpviewsize $viewsize \n");
1353
1354         bprint ("^4",self.netname);
1355         bprint ("^4 connected");
1356
1357         if(g_domination || g_ctf)
1358         {
1359                 bprint(" and joined the ");
1360                 bprint(ColoredTeamName(self.team));
1361         }
1362
1363         bprint("\n");
1364
1365         self.welcomemessage_time = 0;
1366
1367         stuffcmd(self, strcat(clientstuff, "\n"));
1368         stuffcmd(self, strcat("exec maps/", mapname, ".cfg\n"));
1369         stuffcmd(self, "cl_particles_reloadeffects\n");
1370
1371         FixClientCvars(self);
1372
1373         // spawnfunc_waypoint sprites
1374         WaypointSprite_InitClient(self);
1375
1376         // Wazat's grappling hook
1377         SetGrappleHookBindings();
1378
1379         // get autoswitch state from player when he toggles it
1380         stuffcmd(self, "alias autoswitch \"set cl_autoswitch $1 ; cmd autoswitch $1\"\n"); // default.cfg-ed in 2.4.1
1381
1382         // get version info from player
1383         stuffcmd(self, "cmd clientversion $gameversion\n");
1384
1385         // get other cvars from player
1386         GetCvars(0);
1387
1388         // set cvar for team scoreboard
1389         stuffcmd(self, strcat("set teamplay ", ftos(teamplay), "\n"));
1390
1391         // notify about available teams
1392         if(teams_matter)
1393         {
1394                 CheckAllowedTeams(self);
1395                 t = 0; if(c1 >= 0) t |= 1; if(c2 >= 0) t |= 2; if(c3 >= 0) t |= 4; if(c4 >= 0) t |= 8;
1396                 stuffcmd(self, strcat("set _teams_available ", ftos(t), "\n"));
1397         }
1398         else
1399                 stuffcmd(self, "set _teams_available 0\n");
1400
1401         stuffcmd(self, strcat("set gametype ", ftos(game), "\n"));
1402
1403         if(g_arena)
1404         {
1405                 self.classname = "observer";
1406                 Spawnqueue_Insert(self);
1407         }
1408         /*else if(g_ctf)
1409         {
1410                 ctf_clientconnect();
1411         }*/
1412
1413         if(teams_matter || sv_cheats)
1414                 attach_entcs();
1415
1416         bot_relinkplayerlist();
1417
1418         self.spectatortime = time;
1419         if(blockSpectators)
1420         {
1421                 sprint(self, strcat("^7You have to become a player within the next ", ftos(cvar("g_maxplayers_spectator_blocktime")), " seconds, otherwise you will be kicked, because spectators aren't allowed at this time!\n"));
1422         }
1423
1424         self.jointime = time;
1425         self.allowedTimeouts = cvar("sv_timeout_number");
1426
1427         if(clienttype(self) == CLIENTTYPE_REAL)
1428         {
1429                 if(cvar("g_bugrigs") || g_weaponarena == WEPBIT_TUBA)
1430                         stuffcmd(self, "cl_cmd settemp chase_active 1\n");
1431         }
1432
1433         if(g_lms)
1434         {
1435                 if(PlayerScore_Add(self, SP_LMS_LIVES, LMS_NewPlayerLives()) <= 0)
1436                 {
1437                         PlayerScore_Add(self, SP_LMS_RANK, 666);
1438                         self.frags = FRAGS_SPECTATOR;
1439                 }
1440         }
1441
1442         if(!sv_foginterval && world.fog != "")
1443                 stuffcmd(self, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1444
1445         SoundEntity_Attach(self);
1446
1447         if(cvar("g_hitplots"))
1448         {
1449                 self.hitplotfh = fopen(strcat("hits-", matchid, "-", ftos(self.playerid), ".plot"), FILE_WRITE);
1450                 fputs(self.hitplotfh, strcat("#name ", self.netname, "\n"));
1451         }
1452         else
1453                 self.hitplotfh = -1;
1454 }
1455
1456 /*
1457 =============
1458 ClientDisconnect
1459
1460 Called when a client disconnects from the server
1461 =============
1462 */
1463 .entity chatbubbleentity;
1464 .entity teambubbleentity;
1465 void ReadyCount();
1466 void ClientDisconnect (void)
1467 {
1468         if not(self.flags & FL_CLIENT)
1469         {
1470                 print("Warning: ClientDisconnect without ClientConnect\n");
1471                 return;
1472         }
1473
1474         if(self.hitplotfh >= 0)
1475         {
1476                 fclose(self.hitplotfh);
1477                 self.hitplotfh = -1;
1478         }
1479
1480         bot_clientdisconnect();
1481
1482         if(self.entcs)
1483                 detach_entcs();
1484
1485         if(cvar("sv_eventlog"))
1486                 GameLogEcho(strcat(":part:", ftos(self.playerid)));
1487         bprint ("^4",self.netname);
1488         bprint ("^4 disconnected\n");
1489
1490         SoundEntity_Detach(self);
1491
1492         DropAllRunes(self);
1493         kh_Key_DropAll(self, TRUE);
1494
1495         Portal_ClearAll(self);
1496
1497         if(self.flagcarried)
1498                 DropFlag(self.flagcarried, world, world);
1499         if(self.ballcarried)
1500                 DropBall(self.ballcarried, self.origin + self.ballcarried.origin, self.velocity);
1501
1502         // Here, everything has been done that requires this player to be a client.
1503
1504         self.flags &~= FL_CLIENT;
1505
1506         if (self.chatbubbleentity)
1507                 remove (self.chatbubbleentity);
1508
1509         if (self.teambubbleentity)
1510                 remove (self.teambubbleentity);
1511
1512         if (self.killindicator)
1513                 remove (self.killindicator);
1514
1515         WaypointSprite_PlayerGone();
1516
1517         bot_relinkplayerlist();
1518
1519         // remove laserdot
1520         if(self.weaponentity)
1521                 if(self.weaponentity.lasertarget)
1522                         remove(self.weaponentity.lasertarget);
1523
1524         if(g_arena)
1525         {
1526                 Spawnqueue_Unmark(self);
1527                 Spawnqueue_Remove(self);
1528         }
1529
1530         ClientData_Detach();
1531         PlayerScore_Detach(self);
1532
1533         if(self.netname_previous)
1534                 strunzone(self.netname_previous);
1535         if(self.clientstatus)
1536                 strunzone(self.clientstatus);
1537
1538         ClearPlayerSounds();
1539
1540         self.playerid = 0;
1541         ReadyCount();
1542
1543         // free cvars
1544         GetCvars(-1);
1545 }
1546
1547 .float BUTTON_CHAT;
1548 void ChatBubbleThink()
1549 {
1550         self.nextthink = time;
1551         if (!self.owner.modelindex || self.owner.chatbubbleentity != self)
1552         {
1553                 if(self.owner) // but why can that ever be world?
1554                         self.owner.chatbubbleentity = world;
1555                 remove(self);
1556                 return;
1557         }
1558         if ((self.owner.BUTTON_CHAT && !self.owner.deadflag)
1559 #ifdef TETRIS
1560                 || self.owner.tetris_on
1561 #endif
1562         )
1563                 self.model = self.mdl;
1564         else
1565                 self.model = "";
1566 };
1567
1568 void UpdateChatBubble()
1569 {
1570         if (!self.modelindex)
1571                 return;
1572         // spawn a chatbubble entity if needed
1573         if (!self.chatbubbleentity)
1574         {
1575                 self.chatbubbleentity = spawn();
1576                 self.chatbubbleentity.owner = self;
1577                 self.chatbubbleentity.exteriormodeltoclient = self;
1578                 self.chatbubbleentity.think = ChatBubbleThink;
1579                 self.chatbubbleentity.nextthink = time;
1580                 setmodel(self.chatbubbleentity, "models/misc/chatbubble.spr"); // precision set below
1581                 //setorigin(self.chatbubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1582                 setorigin(self.chatbubbleentity, '0 0 15' + self.maxs_z * '0 0 1');
1583                 setattachment(self.chatbubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1584                 self.chatbubbleentity.mdl = self.chatbubbleentity.model;
1585                 self.chatbubbleentity.model = "";
1586                 self.chatbubbleentity.effects = EF_LOWPRECISION;
1587         }
1588 }
1589
1590
1591 void TeamBubbleThink()
1592 {
1593         self.nextthink = time;
1594         if (!self.owner.modelindex || self.owner.teambubbleentity != self)
1595         {
1596                 if(self.owner) // but why can that ever be world?
1597                         self.owner.teambubbleentity = world;
1598                 remove(self);
1599                 return;
1600         }
1601 //      setorigin(self, self.owner.origin + '0 0 15' + self.owner.maxs_z * '0 0 1');  // bandwidth hog. setattachment does this now
1602         if (self.owner.BUTTON_CHAT || self.owner.deadflag || self.owner.killindicator)
1603                 self.model = "";
1604         else
1605                 self.model = self.mdl;
1606
1607 };
1608
1609 float TeamBubble_customizeentityforclient()
1610 {
1611         return (self.owner != other && self.owner.team == other.team && other.killcount > -666);
1612 }
1613
1614 void UpdateTeamBubble()
1615 {
1616         if (!self.modelindex || !teams_matter)
1617                 return;
1618         // spawn a teambubble entity if needed
1619         if (!self.teambubbleentity && teams_matter)
1620         {
1621                 self.teambubbleentity = spawn();
1622                 self.teambubbleentity.owner = self;
1623                 self.teambubbleentity.exteriormodeltoclient = self;
1624                 self.teambubbleentity.think = TeamBubbleThink;
1625                 self.teambubbleentity.nextthink = time;
1626                 setmodel(self.teambubbleentity, "models/misc/teambubble.spr"); // precision set below
1627 //              setorigin(self.teambubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1628                 setorigin(self.teambubbleentity, '0 0 15' + self.maxs_z * '0 0 1');
1629                 setattachment(self.teambubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1630                 self.teambubbleentity.mdl = self.teambubbleentity.model;
1631                 self.teambubbleentity.model = self.teambubbleentity.mdl;
1632                 self.teambubbleentity.customizeentityforclient = TeamBubble_customizeentityforclient;
1633                 self.teambubbleentity.effects = EF_LOWPRECISION;
1634         }
1635 }
1636
1637 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1638 // added to the model skins
1639 /*void UpdateColorModHack()
1640 {
1641         local float c;
1642         c = self.clientcolors & 15;
1643         // LordHavoc: only bothering to support white, green, red, yellow, blue
1644              if (!teams_matter) self.colormod = '0 0 0';
1645         else if (c ==  0) self.colormod = '1.00 1.00 1.00';
1646         else if (c ==  3) self.colormod = '0.10 1.73 0.10';
1647         else if (c ==  4) self.colormod = '1.73 0.10 0.10';
1648         else if (c == 12) self.colormod = '1.22 1.22 0.10';
1649         else if (c == 13) self.colormod = '0.10 0.10 1.73';
1650         else self.colormod = '1 1 1';
1651 };*/
1652
1653 void respawn(void)
1654 {
1655         CopyBody(1);
1656         self.effects |= EF_NODRAW; // prevent another CopyBody
1657         PutClientInServer();
1658 }
1659
1660 void play_countdown(float finished, string samp)
1661 {
1662         if(clienttype(self) == CLIENTTYPE_REAL)
1663                 if(floor(finished - time - frametime) != floor(finished - time))
1664                         if(finished - time < 6)
1665                                 sound (self, CHAN_AUTO, samp, VOL_BASE, ATTN_NORM);
1666 }
1667
1668 /**
1669  * When sv_timeout is used this function returs strings like
1670  * "Timeout begins in 2 seconds!\n" or "Timeout ends in 23 seconds!\n".
1671  * Called by centerprint functions
1672  * @param addOneSecond boolean, set to 1 if the welcome-message centerprint asks for the text
1673  */
1674 string getTimeoutText(float addOneSecond) {
1675         if (!cvar("sv_timeout") || !timeoutStatus)
1676                 return "";
1677
1678         local string retStr;
1679         if (timeoutStatus == 1) {
1680                 if (addOneSecond == 1) {
1681                         retStr = strcat("Timeout begins in ", ftos(remainingLeadTime + 1), " seconds!\n");
1682                 }
1683                 else {
1684                         retStr = strcat("Timeout begins in ", ftos(remainingLeadTime), " seconds!\n");
1685                 }
1686                 return retStr;
1687         }
1688         else if (timeoutStatus == 2) {
1689                 if (addOneSecond) {
1690                         retStr = strcat("Timeout ends in ", ftos(remainingTimeoutTime + 1), " seconds!\n");
1691                         //don't show messages like "Timeout ends in 0 seconds"...
1692                         if ((remainingTimeoutTime + 1) > 0)
1693                                 return retStr;
1694                         else
1695                                 return "";
1696                 }
1697                 else {
1698                         retStr = strcat("Timeout ends in ", ftos(remainingTimeoutTime), " seconds!\n");
1699                         //don't show messages like "Timeout ends in 0 seconds"...
1700                         if (remainingTimeoutTime > 0)
1701                                 return retStr;
1702                         else
1703                                 return "";
1704                 }
1705         }
1706         else return "";
1707 }
1708
1709 void player_powerups (void)
1710 {
1711         if((self.items & IT_USING_JETPACK) && !self.deadflag)
1712         {
1713                 SoundEntity_StartSound(self, CHAN_PLAYER, "misc/jetpack_fly.wav", VOL_BASE, cvar("g_jetpack_attenuation"));
1714                 self.modelflags |= MF_ROCKET;
1715         }
1716         else
1717         {
1718                 SoundEntity_StopSound(self, CHAN_PLAYER);
1719                 self.modelflags &~= MF_ROCKET;
1720         }
1721
1722         self.effects &~= (EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1723
1724         if(!self.modelindex || self.deadflag) // don't apply the flags if the player is gibbed
1725                 return;
1726
1727         if (g_minstagib)
1728         {
1729                 self.effects |= EF_FULLBRIGHT;
1730
1731                 if (self.items & IT_STRENGTH)
1732                 {
1733                         play_countdown(self.strength_finished, "misc/poweroff.wav");
1734                         if (time > self.strength_finished)
1735                         {
1736                                 self.alpha = default_player_alpha;
1737                                 self.exteriorweaponentity.alpha = default_weapon_alpha;
1738                                 self.items &~= IT_STRENGTH;
1739                                 sprint(self, "^3Invisibility has worn off\n");
1740                         }
1741                 }
1742                 else
1743                 {
1744                         if (time < self.strength_finished)
1745                         {
1746                                 self.alpha = g_minstagib_invis_alpha;
1747                                 self.exteriorweaponentity.alpha = g_minstagib_invis_alpha;
1748                                 self.items |= IT_STRENGTH;
1749                                 sprint(self, "^3You are invisible\n");
1750                         }
1751                 }
1752
1753                 if (self.items & IT_INVINCIBLE)
1754                 {
1755                         play_countdown(self.invincible_finished, "misc/poweroff.wav");
1756                         if (time > self.invincible_finished)
1757                         {
1758                                 self.items = self.items - (self.items & IT_INVINCIBLE);
1759                                 sprint(self, "^3Speed has worn off\n");
1760                         }
1761                 }
1762                 else
1763                 {
1764                         if (time < self.invincible_finished)
1765                         {
1766                                 self.items = self.items | IT_INVINCIBLE;
1767                                 sprint(self, "^3You are on speed\n");
1768                         }
1769                 }
1770                 return;
1771         }
1772
1773         if (self.items & IT_STRENGTH)
1774         {
1775                 play_countdown(self.strength_finished, "misc/poweroff.wav");
1776                 self.effects = self.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1777                 if (time > self.strength_finished)
1778                 {
1779                         self.items = self.items - (self.items & IT_STRENGTH);
1780                         sprint(self, "^3Strength has worn off\n");
1781                 }
1782         }
1783         else
1784         {
1785                 if (time < self.strength_finished)
1786                 {
1787                         self.items = self.items | IT_STRENGTH;
1788                         sprint(self, "^3Strength infuses your weapons with devastating power\n");
1789                 }
1790         }
1791         if (self.items & IT_INVINCIBLE)
1792         {
1793                 play_countdown(self.invincible_finished, "misc/poweroff.wav");
1794                 self.effects = self.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1795                 if (time > self.invincible_finished)
1796                 {
1797                         self.items = self.items - (self.items & IT_INVINCIBLE);
1798                         sprint(self, "^3Shield has worn off\n");
1799                 }
1800         }
1801         else
1802         {
1803                 if (time < self.invincible_finished)
1804                 {
1805                         self.items = self.items | IT_INVINCIBLE;
1806                         sprint(self, "^3Shield surrounds you\n");
1807                 }
1808         }
1809
1810         if (cvar("g_fullbrightplayers"))
1811                 self.effects = self.effects | EF_FULLBRIGHT;
1812
1813         // midair gamemode: damage only while in the air
1814         // if in midair mode, being on ground grants temporary invulnerability
1815         // (this is so that multishot weapon don't clear the ground flag on the
1816         // first damage in the frame, leaving the player vulnerable to the
1817         // remaining hits in the same frame)
1818         if (self.flags & FL_ONGROUND)
1819         if (g_midair)
1820                 self.spawnshieldtime = max(self.spawnshieldtime, time + cvar("g_midair_shieldtime"));
1821
1822         if (time >= game_starttime)
1823         if (time < self.spawnshieldtime)
1824                 self.effects = self.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1825 }
1826
1827 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
1828 {
1829         if(current > stable)
1830                 return current;
1831         else if(current > stable - 0.25) // when close enough, "snap"
1832                 return stable;
1833         else
1834                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
1835 }
1836
1837 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
1838 {
1839         if(current < stable)
1840                 return current;
1841         else if(current < stable + 0.25) // when close enough, "snap"
1842                 return stable;
1843         else
1844                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
1845 }
1846
1847 float CalcRotRegen(float current, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit)
1848 {
1849         if(current > rotstable)
1850         {
1851                 if(rotframetime > 0)
1852                 {
1853                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
1854                         current = max(rotstable, current - rotlinear * rotframetime);
1855                 }
1856         }
1857         else if(current < regenstable)
1858         {
1859                 if(regenframetime > 0)
1860                 {
1861                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
1862                         current = min(regenstable, current + regenlinear * regenframetime);
1863                 }
1864         }
1865
1866         if(current > limit)
1867                 current = limit;
1868
1869         return current;
1870 }
1871
1872 void player_regen (void)
1873 {
1874         float minh, mina, minf, maxh, maxa, maxf, limith, limita, limitf, max_mod, regen_mod, rot_mod, limit_mod;
1875         maxh = cvar("g_balance_health_rotstable");
1876         maxa = cvar("g_balance_armor_rotstable");
1877         maxf = cvar("g_balance_fuel_rotstable");
1878         minh = cvar("g_balance_health_regenstable");
1879         mina = cvar("g_balance_armor_regenstable");
1880         minf = cvar("g_balance_fuel_regenstable");
1881         limith = cvar("g_balance_health_limit");
1882         limita = cvar("g_balance_armor_limit");
1883         limitf = cvar("g_balance_fuel_limit");
1884
1885         max_mod = regen_mod = rot_mod = limit_mod = 1;
1886
1887         if (self.runes & RUNE_REGEN)
1888         {
1889                 if (self.runes & CURSE_VENOM) // do we have both rune/curse?
1890                 {
1891                         regen_mod = cvar("g_balance_rune_regen_combo_regenrate");
1892                         max_mod = cvar("g_balance_rune_regen_combo_hpmod");
1893                         limit_mod = cvar("g_balance_rune_regen_combo_limitmod");
1894                 }
1895                 else
1896                 {
1897                         regen_mod = cvar("g_balance_rune_regen_regenrate");
1898                         max_mod = cvar("g_balance_rune_regen_hpmod");
1899                         limit_mod = cvar("g_balance_rune_regen_limitmod");
1900                 }
1901         }
1902         else if (self.runes & CURSE_VENOM)
1903         {
1904                 max_mod = cvar("g_balance_curse_venom_hpmod");
1905                 if (self.runes & RUNE_REGEN) // do we have both rune/curse?
1906                         rot_mod = cvar("g_balance_rune_regen_combo_rotrate");
1907                 else
1908                         rot_mod = cvar("g_balance_curse_venom_rotrate");
1909                 limit_mod = cvar("g_balance_curse_venom_limitmod");
1910                 //if (!self.runes & RUNE_REGEN)
1911                 //      rot_mod = cvar("g_balance_curse_venom_rotrate");
1912         }
1913         maxh = maxh * max_mod;
1914         //maxa = maxa * max_mod;
1915         //maxf = maxf * max_mod;
1916         minh = minh * max_mod;
1917         //mina = mina * max_mod;
1918         //minf = minf * max_mod;
1919         limith = limith * limit_mod;
1920         limita = limita * limit_mod;
1921         //limitf = limitf * limit_mod;
1922
1923         if(g_lms)
1924                 rot_mod = 0;
1925
1926         if (!g_minstagib && (!g_lms || cvar("g_lms_regenerate")))
1927         {
1928                 self.armorvalue = CalcRotRegen(self.armorvalue, mina, cvar("g_balance_armor_regen"), cvar("g_balance_armor_regenlinear"), regen_mod * frametime * (time > self.pauseregen_finished), maxa, cvar("g_balance_armor_rot"), cvar("g_balance_armor_rotlinear"), rot_mod * frametime * (time > self.pauserotarmor_finished), limita);
1929                 self.health = CalcRotRegen(self.health, minh, cvar("g_balance_health_regen"), cvar("g_balance_health_regenlinear"), regen_mod * frametime * (time > self.pauseregen_finished), maxh, cvar("g_balance_health_rot"), cvar("g_balance_health_rotlinear"), rot_mod * frametime * (time > self.pauserothealth_finished), limith);
1930
1931                 // if player rotted to death...  die!
1932                 if(self.health < 1)
1933                         self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
1934         }
1935
1936         self.ammo_fuel = CalcRotRegen(self.ammo_fuel, minf, cvar("g_balance_fuel_regen"), cvar("g_balance_fuel_regenlinear"), regen_mod * frametime * (time > self.pauseregen_finished) * (self.items & IT_FUEL_REGEN != 0), maxf, cvar("g_balance_fuel_rot"), cvar("g_balance_fuel_rotlinear"), rot_mod * frametime * (time > self.pauserotfuel_finished), limitf);
1937 }
1938
1939 float zoomstate_set;
1940 void SetZoomState(float z)
1941 {
1942         if(z != self.zoomstate)
1943         {
1944                 self.zoomstate = z;
1945                 ClientData_Touch(self);
1946         }
1947         zoomstate_set = 1;
1948 }
1949
1950 void GetPressedKeys(void) {
1951         if (self.movement_x > 0) // get if movement keys are pressed
1952         {       // forward key pressed
1953                 self.pressedkeys |= KEY_FORWARD;
1954                 self.pressedkeys &~= KEY_BACKWARD;
1955         }
1956         else if (self.movement_x < 0)
1957         {       // backward key pressed
1958                 self.pressedkeys |= KEY_BACKWARD;
1959                 self.pressedkeys &~= KEY_FORWARD;
1960         }
1961         else
1962         {       // no x input
1963                 self.pressedkeys &~= KEY_FORWARD;
1964                 self.pressedkeys &~= KEY_BACKWARD;
1965         }
1966
1967         if (self.movement_y > 0)
1968         {       // right key pressed
1969                 self.pressedkeys |= KEY_RIGHT;
1970                 self.pressedkeys &~= KEY_LEFT;
1971         }
1972         else if (self.movement_y < 0)
1973         {       // left key pressed
1974                 self.pressedkeys |= KEY_LEFT;
1975                 self.pressedkeys &~= KEY_RIGHT;
1976         }
1977         else
1978         {       // no y input
1979                 self.pressedkeys &~= KEY_RIGHT;
1980                 self.pressedkeys &~= KEY_LEFT;
1981         }
1982
1983         if (self.BUTTON_JUMP) // get if jump and crouch keys are pressed
1984                 self.pressedkeys |= KEY_JUMP;
1985         else
1986                 self.pressedkeys &~= KEY_JUMP;
1987         if (self.BUTTON_CROUCH)
1988                 self.pressedkeys |= KEY_CROUCH;
1989         else
1990                 self.pressedkeys &~= KEY_CROUCH;
1991 }
1992
1993 /*
1994 ======================
1995 spectate mode routines
1996 ======================
1997 */
1998 void SpectateCopy(entity spectatee) {
1999         self.armortype = spectatee.armortype;
2000         self.armorvalue = spectatee.armorvalue;
2001         self.ammo_cells = spectatee.ammo_cells;
2002         self.ammo_shells = spectatee.ammo_shells;
2003         self.ammo_nails = spectatee.ammo_nails;
2004         self.ammo_rockets = spectatee.ammo_rockets;
2005         self.ammo_fuel = spectatee.ammo_fuel;
2006         self.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
2007         self.health = spectatee.health;
2008         self.impulse = 0;
2009         self.items = spectatee.items;
2010         self.metertime = spectatee.metertime;
2011         self.strength_finished = spectatee.strength_finished;
2012         self.invincible_finished = spectatee.invincible_finished;
2013         self.pressedkeys = spectatee.pressedkeys;
2014         self.weapons = spectatee.weapons;
2015         self.switchweapon = spectatee.switchweapon;
2016         self.weapon = spectatee.weapon;
2017         self.punchangle = spectatee.punchangle;
2018         self.view_ofs = spectatee.view_ofs;
2019         self.v_angle = spectatee.v_angle;
2020         self.velocity = spectatee.velocity;
2021         self.dmg_take = spectatee.dmg_take;
2022         self.dmg_save = spectatee.dmg_save;
2023         self.dmg_inflictor = spectatee.dmg_inflictor;
2024         self.angles = spectatee.v_angle;
2025         self.fixangle = TRUE;
2026         setorigin(self, spectatee.origin);
2027         setsize(self, spectatee.mins, spectatee.maxs);
2028         SetZoomState(spectatee.zoomstate);
2029 }
2030
2031 float SpectateUpdate() {
2032         if(!self.enemy)
2033                 return 0;
2034
2035         if (self == self.enemy)
2036                 return 0;
2037
2038         if(self.enemy.classname != "player")
2039                 return 0;
2040
2041         SpectateCopy(self.enemy);
2042
2043         return 1;
2044 }
2045
2046 float SpectateNext() {
2047         other = find(self.enemy, classname, "player");
2048         if (!other) {
2049                 other = find(other, classname, "player");
2050         }
2051         if (other) {
2052                 self.enemy = other;
2053         }
2054         if(self.enemy.classname == "player") {
2055                 msg_entity = self;
2056                 WriteByte(MSG_ONE, SVC_SETVIEW);
2057                 WriteEntity(MSG_ONE, self.enemy);
2058                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
2059                 self.movetype = MOVETYPE_NONE;
2060                 if(!SpectateUpdate())
2061                         PutObserverInServer();
2062                 return 1;
2063         } else {
2064                 return 0;
2065         }
2066 }
2067
2068 /*
2069 =============
2070 ShowRespawnCountdown()
2071
2072 Update a respawn countdown display.
2073 =============
2074 */
2075 void ShowRespawnCountdown()
2076 {
2077         float number;
2078         if(self.deadflag == DEAD_NO) // just respawned?
2079                 return;
2080         else
2081         {
2082                 number = ceil(self.death_time - time);
2083                 if(number <= 0)
2084                         return;
2085                 if(number <= self.respawn_countdown)
2086                 {
2087                         self.respawn_countdown = number - 1;
2088                         if(ceil(self.death_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
2089                                 announce(self, strcat("announcer/robotic/", ftos(number), ".wav"));
2090                 }
2091         }
2092 }
2093
2094 void LeaveSpectatorMode()
2095 {
2096         if(isJoinAllowed()) {
2097                 if(!teams_matter || cvar("g_campaign") || cvar("g_balance_teams") || (self.wasplayer && cvar("g_changeteam_banned"))) {
2098                         self.classname = "player";
2099                         if(cvar("g_campaign") || cvar("g_balance_teams") || cvar("g_balance_teams_force"))
2100                                 JoinBestTeam(self, FALSE, TRUE);
2101                         if(cvar("g_campaign"))
2102                                 campaign_bots_may_start = 1;
2103                         PutClientInServer();
2104                         if(self.classname == "player")
2105                                 bprint ("^4", self.netname, "^4 is playing now\n");
2106                         if(!cvar("g_campaign"))
2107                                 centerprint(self,""); // clear MOTD
2108                         return;
2109                 } else {
2110                         stuffcmd(self,"menu_showteamselect\n");
2111                         return;
2112                 }
2113         }
2114         else {
2115                 //player may not join because of g_maxplayers is set
2116                 centerprint_atprio(self, CENTERPRIO_MAPVOTE, PREVENT_JOIN_TEXT);
2117         }
2118 }
2119
2120 /**
2121  * Determines whether the player is allowed to join. This depends on cvar
2122  * g_maxplayers, if it isn't used this function always return TRUE, otherwise
2123  * it checks whether the number of currently playing players exceeds g_maxplayers.
2124  * @return bool TRUE if the player is allowed to join, false otherwise
2125  */
2126 float isJoinAllowed() {
2127         if (!cvar("g_maxplayers"))
2128                 return TRUE;
2129
2130         local entity e;
2131         local float currentlyPlaying;
2132         FOR_EACH_REALPLAYER(e) {
2133                 if(e.classname == "player")
2134                         currentlyPlaying += 1;
2135         }
2136         if(currentlyPlaying < cvar("g_maxplayers"))
2137                 return TRUE;
2138
2139         return FALSE;
2140 }
2141
2142 /**
2143  * Checks whether the client is an observer or spectator, if so, he will get kicked after
2144  * g_maxplayers_spectator_blocktime seconds
2145  */
2146 void checkSpectatorBlock() {
2147         if(self.classname == "spectator" || self.classname == "observer") {
2148                 if( time > (self.spectatortime + cvar("g_maxplayers_spectator_blocktime")) ) {
2149                         sprint(self, "^7You were kicked from the server because you are spectator and spectators aren't allowed at the moment.\n");
2150                         dropclient(self);
2151                 }
2152         }
2153 }
2154
2155 float vercmp_recursive(string v1, string v2)
2156 {
2157         float dot1, dot2;
2158         string s1, s2;
2159         float r;
2160
2161         dot1 = strstrofs(v1, ".", 0);
2162         dot2 = strstrofs(v2, ".", 0);
2163         if(dot1 == -1)
2164                 s1 = v1;
2165         else
2166                 s1 = substring(v1, 0, dot1);
2167         if(dot2 == -1)
2168                 s2 = v2;
2169         else
2170                 s2 = substring(v2, 0, dot2);
2171
2172         r = stof(s1) - stof(s2);
2173         if(r != 0)
2174                 return r;
2175
2176         r = strcasecmp(s1, s2);
2177         if(r != 0)
2178                 return r;
2179
2180         if(dot1 == -1)
2181                 if(dot2 == -1)
2182                         return 0;
2183                 else
2184                         return -1;
2185         else
2186                 if(dot2 == -1)
2187                         return 1;
2188                 else
2189                         return vercmp_recursive(substring(v1, dot1 + 1, 999), substring(v2, dot2 + 1, 999));
2190 }
2191
2192 float vercmp(string v1, string v2)
2193 {
2194         if(strcasecmp(v1, v2) == 0) // early out check
2195                 return 0;
2196         return vercmp_recursive(v1, v2);
2197 }
2198
2199 void ObserverThink()
2200 {
2201         if (self.flags & FL_JUMPRELEASED) {
2202                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2203                         self.welcomemessage_time = 0;
2204                         self.flags &~= FL_JUMPRELEASED;
2205                         self.flags |= FL_SPAWNING;
2206                 } else if(self.BUTTON_ATCK && !self.version_mismatch) {
2207                         self.welcomemessage_time = 0;
2208                         self.flags &~= FL_JUMPRELEASED;
2209                         if(SpectateNext() == 1) {
2210                                 self.classname = "spectator";
2211                         }
2212                 }
2213         } else {
2214                 if (!(self.BUTTON_ATCK || self.BUTTON_JUMP)) {
2215                         self.flags |= FL_JUMPRELEASED;
2216                         if(self.flags & FL_SPAWNING)
2217                         {
2218                                 self.flags &~= FL_SPAWNING;
2219                                 LeaveSpectatorMode();
2220                                 return;
2221                         }
2222                 }
2223         }
2224         PrintWelcomeMessage(self);
2225 }
2226
2227 void SpectatorThink()
2228 {
2229         if (self.flags & FL_JUMPRELEASED) {
2230                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2231                         self.welcomemessage_time = 0;
2232                         self.flags &~= FL_JUMPRELEASED;
2233                         self.flags |= FL_SPAWNING;
2234                 } else if(self.BUTTON_ATCK) {
2235                         self.welcomemessage_time = 0;
2236                         self.flags &~= FL_JUMPRELEASED;
2237                         if(SpectateNext() == 1) {
2238                                 self.classname = "spectator";
2239                         } else {
2240                                 self.classname = "observer";
2241                                 PutClientInServer();
2242                         }
2243                 } else if (self.BUTTON_ATCK2) {
2244                         self.welcomemessage_time = 0;
2245                         self.flags &~= FL_JUMPRELEASED;
2246                         self.classname = "observer";
2247                         PutClientInServer();
2248                 } else {
2249                         if(!SpectateUpdate())
2250                                 PutObserverInServer();
2251                 }
2252         } else {
2253                 if (!(self.BUTTON_ATCK || self.BUTTON_ATCK2)) {
2254                         self.flags |= FL_JUMPRELEASED;
2255                         if(self.flags & FL_SPAWNING)
2256                         {
2257                                 self.flags &~= FL_SPAWNING;
2258                                 LeaveSpectatorMode();
2259                                 return;
2260                         }
2261                 }
2262         }
2263         PrintWelcomeMessage(self);
2264         self.flags |= FL_CLIENT | FL_NOTARGET;
2265 }
2266
2267 .float touchexplode_time;
2268
2269 /*
2270 =============
2271 PlayerPreThink
2272
2273 Called every frame for each client before the physics are run
2274 =============
2275 */
2276 void() ctf_setstatus;
2277 void() nexball_setstatus;
2278 .float items_added;
2279 void PlayerPreThink (void)
2280 {
2281         self.stat_game_starttime = game_starttime;
2282         self.stat_allow_oldnexbeam = cvar("g_allow_oldnexbeam");
2283         self.stat_leadlimit = cvar("leadlimit");
2284
2285         if(blockSpectators && frametime)
2286                 // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2287                 checkSpectatorBlock();
2288
2289         zoomstate_set = 0;
2290
2291         if(self.netname_previous != self.netname)
2292         {
2293                 if(cvar("sv_eventlog"))
2294                         GameLogEcho(strcat(":name:", ftos(self.playerid), ":", self.netname));
2295                 if(self.netname_previous)
2296                         strunzone(self.netname_previous);
2297                 self.netname_previous = strzone(self.netname);
2298         }
2299
2300         // version nagging
2301         if(self.version_nagtime)
2302                 if(self.cvar_g_nexuizversion)
2303                         if(time > self.version_nagtime)
2304                         {
2305                                 if(strstr(self.cvar_g_nexuizversion, "svn", 0) < 0)
2306                                 {
2307                                         if(strstr(cvar_string("g_nexuizversion"), "svn", 0) >= 0)
2308                                         {
2309                                                 dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Nexuiz ", cvar_string("g_nexuizversion"), " (beta)^7, you have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1\n");
2310                                                 sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Nexuiz ", cvar_string("g_nexuizversion"), " (beta)^7, you have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1\n"));
2311                                         }
2312                                         else
2313                                         {
2314                                                 float r;
2315                                                 r = vercmp(self.cvar_g_nexuizversion, cvar_string("g_nexuizversion"));
2316                                                 if(r < 0)
2317                                                 {
2318                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - ^3Nexuiz ", cvar_string("g_nexuizversion"), "^7 is out, and you still have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1 - get the update from ^4http://www.nexuiz.com/^1!\n");
2319                                                         sprint(self, strcat("\{1}^1NOTE: ^3Nexuiz ", cvar_string("g_nexuizversion"), "^7 is out, and you still have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1 - get the update from ^4http://www.nexuiz.com/^1!\n"));
2320                                                 }
2321                                                 else if(r > 0)
2322                                                 {
2323                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Nexuiz ", cvar_string("g_nexuizversion"), "^7, you have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1\n");
2324                                                         sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Nexuiz ", cvar_string("g_nexuizversion"), "^7, you have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1\n"));
2325                                                 }
2326                                         }
2327                                 }
2328                                 self.version_nagtime = 0;
2329                         }
2330
2331         // GOD MODE info
2332         if(!(self.flags & FL_GODMODE)) if(self.max_armorvalue)
2333         {
2334                 sprint(self, strcat("godmode saved you ", ftos(self.max_armorvalue), " units of damage, cheater!\n"));
2335                 self.max_armorvalue = 0;
2336         }
2337
2338 #ifdef TETRIS
2339         if (TetrisPreFrame())
2340                 return;
2341 #endif
2342
2343         if(frametime)
2344                 antilag_record(self);
2345
2346         if(self.classname == "player") {
2347 //              if(self.netname == "Wazat")
2348 //                      bprint(self.classname, "\n");
2349
2350                 CheckRules_Player();
2351
2352                 PrintWelcomeMessage(self);
2353
2354                 if (intermission_running)
2355                 {
2356                         IntermissionThink ();   // otherwise a button could be missed between
2357                         return;                                 // the think tics
2358                 }
2359
2360                 if(self.teleport_time)
2361                 if(time > self.teleport_time)
2362                 {
2363                         self.teleport_time = 0;
2364                         self.effects = self.effects - (self.effects & EF_NODRAW);
2365                 }
2366
2367                 Nixnex_GiveCurrentWeapon();
2368
2369                 if(frametime > 0) // don't do this in cl_movement frames, just in server ticks
2370                         UpdateSelectedPlayer();
2371
2372                 //don't allow the player to turn around while game is paused!
2373                 if(timeoutStatus == 2) {
2374                         self.v_angle = self.lastV_angle;
2375                         self.angles = self.lastV_angle;
2376                         self.fixangle = TRUE;
2377                 }
2378
2379                 if(frametime)
2380                         player_powerups();
2381
2382                 if (self.deadflag != DEAD_NO)
2383                 {
2384                         float button_pressed, force_respawn;
2385                         if(frametime)
2386                                 player_anim();
2387                         button_pressed = (self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE);
2388                         force_respawn = (g_lms || cvar("g_forced_respawn"));
2389                         if (self.deadflag == DEAD_DYING)
2390                         {
2391                                 if(force_respawn)
2392                                         self.deadflag = DEAD_RESPAWNING;
2393                                 else if(!button_pressed)
2394                                         self.deadflag = DEAD_DEAD;
2395                         }
2396                         else if (self.deadflag == DEAD_DEAD)
2397                         {
2398                                 if(button_pressed)
2399                                         self.deadflag = DEAD_RESPAWNABLE;
2400                         }
2401                         else if (self.deadflag == DEAD_RESPAWNABLE)
2402                         {
2403                                 if(!button_pressed)
2404                                         self.deadflag = DEAD_RESPAWNING;
2405                         }
2406                         else if (self.deadflag == DEAD_RESPAWNING)
2407                         {
2408                                 if(time > self.death_time)
2409                                 {
2410                                         self.death_time = time + 1; // only retry once a second
2411                                         respawn();
2412                                 }
2413                         }
2414                         ShowRespawnCountdown();
2415                         return;
2416                 }
2417
2418                 if(g_touchexplode)
2419                 if(time > self.touchexplode_time)
2420                 if(self.classname == "player")
2421                 if(self.deadflag == DEAD_NO)
2422                 if not(IS_INDEPENDENT_PLAYER(self))
2423                 FOR_EACH_PLAYER(other) if(self != other)
2424                 {
2425                         if(time > other.touchexplode_time)
2426                         if(other.classname == "player")
2427                         if(other.deadflag == DEAD_NO)
2428                         if not(IS_INDEPENDENT_PLAYER(other))
2429                         if(boxesoverlap(self.absmin, self.absmax, other.absmin, other.absmax))
2430                         {
2431                                 PlayerTouchExplode(self, other);
2432                                 self.touchexplode_time = other.touchexplode_time = time + 0.2;
2433                         }
2434                 }
2435
2436                 if(g_lms && !self.deadflag && cvar("g_lms_campcheck_interval"))
2437                 {
2438                         vector dist;
2439
2440                         // calculate player movement (in 2 dimensions only, so jumping on one spot doesn't count as movement)
2441                         dist = self.prevorigin - self.origin;
2442                         dist_z = 0;
2443                         self.lms_traveled_distance += fabs(vlen(dist));
2444
2445                         if((cvar("g_campaign") && !campaign_bots_may_start) || (time < game_starttime))
2446                         {
2447                                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval")*2;
2448                                 self.lms_traveled_distance = 0;
2449                         }
2450
2451                         if(time > self.lms_nextcheck)
2452                         {
2453                                 //sprint(self, "distance: ", ftos(self.lms_traveled_distance), "\n");
2454                                 if(self.lms_traveled_distance < cvar("g_lms_campcheck_distance"))
2455                                 {
2456                                         centerprint(self, cvar_string("g_lms_campcheck_message"));
2457                                         // FIXME KadaverJack: gibbing player here causes playermodel to bounce around, instead of eye.md3
2458                                         // I wasn't able to find out WHY that happens, so I put a workaround in place that shall prevent players from being gibbed :(
2459                                         Damage(self, self, self, bound(0, cvar("g_lms_campcheck_damage"), self.health + self.armorvalue * cvar("g_balance_armor_blockpercent") + 5), DEATH_CAMP, self.origin, '0 0 0');
2460                                 }
2461                                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval");
2462                                 self.lms_traveled_distance = 0;
2463                         }
2464                 }
2465
2466                 self.prevorigin = self.origin;
2467
2468                 if ((self.BUTTON_CROUCH && !self.hook.state) || self.health <= g_bloodloss)
2469                 {
2470                         if (!self.crouch)
2471                         {
2472                                 self.crouch = TRUE;
2473                                 self.view_ofs = PL_CROUCH_VIEW_OFS;
2474                                 setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX);
2475                                 setanim(self, self.anim_duck, FALSE, TRUE, TRUE);
2476                         }
2477                 }
2478                 else
2479                 {
2480                         if (self.crouch)
2481                         {
2482                                 tracebox(self.origin, PL_MIN, PL_MAX, self.origin, FALSE, self);
2483                                 if (!trace_startsolid)
2484                                 {
2485                                         self.crouch = FALSE;
2486                                         self.view_ofs = PL_VIEW_OFS;
2487                                         setsize (self, PL_MIN, PL_MAX);
2488                                 }
2489                         }
2490                 }
2491
2492                 if(self.health <= g_bloodloss && self.deadflag == DEAD_NO)
2493                 {
2494                         if(self.bloodloss_timer < time)
2495                         {
2496                                 self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
2497                                 self.bloodloss_timer = time + 0.5 + random() * 0.5;
2498                         }
2499                 }
2500
2501                 FixPlayermodel();
2502
2503                 GrapplingHookFrame();
2504
2505                 if(frametime)
2506                 {
2507                         self.items &~= self.items_added;
2508
2509                         W_WeaponFrame();
2510
2511                         self.items_added = 0;
2512                         if(self.items & IT_JETPACK)
2513                                 if(self.items & IT_FUEL_REGEN || self.ammo_fuel >= 0.01)
2514                                         self.items_added |= IT_FUEL;
2515
2516                         self.items |= self.items_added;
2517                 }
2518
2519                 player_regen();
2520                 if(frametime)
2521                         player_anim();
2522
2523                 if (g_minstagib)
2524                         minstagib_ammocheck();
2525
2526                 ctf_setstatus();
2527                 kh_setstatus();
2528                 nexball_setstatus();
2529
2530                 self.dmg_team = max(0, self.dmg_team - cvar("g_teamdamage_resetspeed") * frametime);
2531
2532                 //self.angles_y=self.v_angle_y + 90;   // temp
2533         } else if(gameover) {
2534                 if (intermission_running)
2535                         IntermissionThink ();   // otherwise a button could be missed between
2536                 return;
2537         } else if(self.classname == "observer") {
2538                 ObserverThink();
2539         } else if(self.classname == "spectator") {
2540                 SpectatorThink();
2541         }
2542
2543         if(!zoomstate_set)
2544                 SetZoomState(self.BUTTON_ZOOM || (self.BUTTON_ATCK2 && self.weapon == WEP_NEX));
2545
2546         float oldspectatee_status;
2547         oldspectatee_status = self.spectatee_status;
2548         if(self.classname == "spectator")
2549                 self.spectatee_status = num_for_edict(self.enemy);
2550         else if(self.classname == "observer")
2551                 self.spectatee_status = num_for_edict(self);
2552         else
2553                 self.spectatee_status = 0;
2554         if(self.spectatee_status != oldspectatee_status)
2555         {
2556                 ClientData_Touch(self);
2557                 if(g_race || g_cts)
2558                         race_InitSpectator();
2559         }
2560
2561         if(self.teamkill_soundtime)
2562         if(time > self.teamkill_soundtime)
2563         {
2564                 self.teamkill_soundtime = 0;
2565
2566                 entity oldpusher, oldself;
2567
2568                 oldself = self; self = self.teamkill_soundsource;
2569                 oldpusher = self.pusher; self.pusher = oldself;
2570
2571                 PlayerSound(playersound_teamshoot, CHAN_VOICE, VOICETYPE_LASTATTACKER_ONLY);
2572
2573                 self.pusher = oldpusher;
2574                 self = oldself;
2575         }
2576
2577         if(self.taunt_soundtime)
2578         if(time > self.taunt_soundtime)
2579         {
2580                 self.taunt_soundtime = 0;
2581                 PlayerSound(playersound_taunt, CHAN_VOICE, VOICETYPE_AUTOTAUNT);
2582         }
2583
2584         target_voicescript_next(self);
2585 }
2586
2587 // on dragger:
2588 .entity dragentity;
2589 .float draggravity;
2590 .float dragspeed; // speed of mouse wheel action
2591 .float dragdistance; // distance of dragentity's draglocalvector from view_ofs
2592 .vector draglocalvector; // local attachment vector of the dragentity
2593 .float draglocalangle;
2594 // on draggee:
2595 .entity draggedby;
2596 .float dragmovetype;
2597 void Drag_Begin(entity dragger, entity draggee, vector touchpoint)
2598 {
2599         float tagscale;
2600
2601         draggee.dragmovetype = draggee.movetype;
2602         draggee.draggravity = draggee.gravity;
2603         draggee.movetype = MOVETYPE_WALK;
2604         draggee.gravity = 0.00001;
2605         draggee.flags &~= FL_ONGROUND;
2606         draggee.draggedby = dragger;
2607
2608         dragger.dragentity = draggee;
2609
2610         dragger.dragdistance = vlen(touchpoint - dragger.origin - dragger.view_ofs);
2611         dragger.draglocalangle = draggee.angles_y - dragger.v_angle_y;
2612         touchpoint = touchpoint - gettaginfo(draggee, 0);
2613         tagscale = pow(vlen(v_forward), -2);
2614         dragger.draglocalvector_x = touchpoint * v_forward * tagscale;
2615         dragger.draglocalvector_y = touchpoint * v_right * tagscale;
2616         dragger.draglocalvector_z = touchpoint * v_up * tagscale;
2617
2618         dragger.dragspeed = 64;
2619 }
2620
2621 void Drag_Finish(entity dragger)
2622 {
2623         entity draggee;
2624         draggee = dragger.dragentity;
2625         if(dragger)
2626                 dragger.dragentity = world;
2627         draggee.draggedby = world;
2628         draggee.movetype = draggee.dragmovetype;
2629         draggee.gravity = draggee.draggravity;
2630
2631         switch(draggee.movetype)
2632         {
2633                 case MOVETYPE_TOSS:
2634                 case MOVETYPE_WALK:
2635                 case MOVETYPE_STEP:
2636                 case MOVETYPE_FLYMISSILE:
2637                 case MOVETYPE_BOUNCE:
2638                 case MOVETYPE_BOUNCEMISSILE:
2639                         break;
2640                 default:
2641                         draggee.velocity = '0 0 0';
2642                         break;
2643         }
2644
2645         if((draggee.flags & FL_ITEM) && (vlen(draggee.velocity) < 32))
2646         {
2647                 draggee.velocity = '0 0 0';
2648                 draggee.flags |= FL_ONGROUND; // floating items are FUN
2649         }
2650 }
2651
2652 float Drag_IsDraggable(entity draggee)
2653 {
2654         // TODO add more checks for bad stuff here
2655         if(draggee.classname == "func_bobbing")
2656                 return FALSE;
2657         if(draggee.classname == "door") // FIXME find out why these must be excluded, or work around the problem (trying to drag these causes like 4 fps)
2658                 return FALSE;
2659         if(draggee.classname == "plat")
2660                 return FALSE;
2661         if(draggee.classname == "func_button")
2662                 return FALSE;
2663         if(draggee.model == "")
2664                 return FALSE;
2665         if(draggee.classname == "spectator")
2666                 return FALSE;
2667         if(draggee.classname == "observer")
2668                 return FALSE;
2669         if(draggee.classname == "exteriorweaponentity")
2670                 return FALSE;
2671
2672         return TRUE;
2673 }
2674
2675 float Drag_MayChangeAngles(entity draggee)
2676 {
2677         // TODO add more checks for bad stuff here
2678         if(substring(draggee.model, 0, 1) == "*")
2679                 return FALSE;
2680         return TRUE;
2681 }
2682
2683 void Drag_MoveForward(entity dragger)
2684 {
2685         dragger.dragdistance += dragger.dragspeed;
2686 }
2687
2688 void Drag_SetSpeed(entity dragger, float s)
2689 {
2690         dragger.dragspeed = pow(2, s);
2691 }
2692
2693 void Drag_MoveBackward(entity dragger)
2694 {
2695         dragger.dragdistance = max(0, dragger.dragdistance - dragger.dragspeed);
2696 }
2697
2698 void Drag_Update(entity dragger)
2699 {
2700         vector curorigin, neworigin, goodvelocity;
2701         float f;
2702         entity draggee;
2703
2704         draggee = dragger.dragentity;
2705         draggee.flags &~= FL_ONGROUND;
2706
2707         curorigin = gettaginfo(draggee, 0);
2708         curorigin = curorigin + v_forward * dragger.draglocalvector_x + v_right * dragger.draglocalvector_y + v_up * dragger.draglocalvector_z;
2709         makevectors(dragger.v_angle);
2710         neworigin = dragger.origin + dragger.view_ofs + v_forward * dragger.dragdistance;
2711         goodvelocity = (neworigin - curorigin) * (1 / frametime);
2712
2713         while(draggee.angles_y - dragger.v_angle_y - dragger.draglocalangle > 180)
2714                 dragger.draglocalangle += 360;
2715         while(draggee.angles_y - dragger.v_angle_y - dragger.draglocalangle <= -180)
2716                 dragger.draglocalangle -= 360;
2717
2718         f = min(frametime * 10, 1);
2719         draggee.velocity = draggee.velocity * (1 - f) + goodvelocity * f;
2720
2721         if(Drag_MayChangeAngles(draggee))
2722                 draggee.angles_y = draggee.angles_y * (1 - f) + (dragger.v_angle_y + dragger.draglocalangle) * f;
2723
2724         draggee.ltime = max(servertime + serverframetime, draggee.ltime); // fixes func_train breakage
2725
2726         te_lightning1(dragger, dragger.origin + dragger.view_ofs, curorigin);
2727 }
2728
2729 float Drag_CanDrag(entity dragger)
2730 {
2731         return (dragger.deadflag == DEAD_NO) || (dragger.classname == "player");
2732 }
2733
2734 float Drag_IsDragging(entity dragger)
2735 {
2736         if(!dragger.dragentity)
2737                 return FALSE;
2738         if(wasfreed(dragger.dragentity) || dragger.dragentity.draggedby != dragger)
2739         {
2740                 dragger.dragentity = world;
2741                 return FALSE;
2742         }
2743         if(!Drag_CanDrag(dragger) || !Drag_IsDraggable(dragger.dragentity))
2744         {
2745                 Drag_Finish(dragger);
2746                 return FALSE;
2747         }
2748         return TRUE;
2749 }
2750
2751 void Drag_MoveDrag(entity from, entity to)
2752 {
2753         if(from.draggedby)
2754         {
2755                 to.draggedby = from.draggedby;
2756                 to.draggedby.dragentity = to;
2757                 from.draggedby = world;
2758         }
2759 }
2760
2761 /*
2762 =============
2763 PlayerPostThink
2764
2765 Called every frame for each client after the physics are run
2766 =============
2767 */
2768 .float idlekick_lasttimeleft;
2769 void PlayerPostThink (void)
2770 {
2771         // Savage: Check for nameless players
2772         if (strlen(self.netname) < 1) {
2773                 self.netname = "Player";
2774                 stuffcmd(self, "seta _cl_name Player\n");
2775         }
2776
2777         if(sv_maxidle && frametime)
2778         {
2779                 // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2780                 float timeleft;
2781                 timeleft = ceil(sv_maxidle - (time - self.parm_idlesince));
2782                 if(timeleft <= 0)
2783                 {
2784                         bprint("^3", self.netname, "^3 was kicked for idling.\n");
2785                         announce(self, "announcer/robotic/terminated.wav");
2786                         dropclient(self);
2787                         return;
2788                 }
2789                 else if(timeleft <= 10)
2790                 {
2791                         if(timeleft != self.idlekick_lasttimeleft)
2792                         {
2793                                 centerprint_atprio(self, CENTERPRIO_IDLEKICK, strcat("^3Stop idling!\n^3Disconnecting in ", ftos(timeleft), "..."));
2794                                 announce(self, strcat("announcer/robotic/", ftos(timeleft), ".wav"));
2795                         }
2796                 }
2797                 else
2798                 {
2799                         centerprint_expire(self, CENTERPRIO_IDLEKICK);
2800                 }
2801                 self.idlekick_lasttimeleft = timeleft;
2802         }
2803
2804 #ifdef TETRIS
2805         if(self.impulse == 100)
2806                 ImpulseCommands();
2807         if (TetrisPostFrame())
2808                 return;
2809 #endif
2810
2811         if(sv_cheats || self.maycheat)
2812                 if(Drag_CanDrag(self))
2813                         if(self.BUTTON_DRAG)
2814                                 if(!self.dragentity)
2815                                         if(self.cursor_trace_ent)
2816                                                 if(Drag_IsDraggable(self.cursor_trace_ent))
2817                                                 {
2818                                                         if(self.cursor_trace_ent.draggedby)
2819                                                                 Drag_Finish(self.cursor_trace_ent.draggedby);
2820                                                         if(self.cursor_trace_ent.tag_entity)
2821                                                                 detach_sameorigin(self.cursor_trace_ent);
2822                                                         Drag_Begin(self, self.cursor_trace_ent, self.cursor_trace_endpos);
2823                                                 }
2824
2825         if(Drag_IsDragging(self))
2826         {
2827                 if(self.BUTTON_DRAG)
2828                 {
2829                         if(self.impulse == 10 || self.impulse == 15 || self.impulse == 18)
2830                         {
2831                                 Drag_MoveForward(self);
2832                                 self.impulse = 0;
2833                         }
2834                         else if(self.impulse == 12 || self.impulse == 16 || self.impulse == 19)
2835                         {
2836                                 Drag_MoveBackward(self);
2837                                 self.impulse = 0;
2838                         }
2839                         else if(self.impulse >= 1 && self.impulse <= 9)
2840                         {
2841                                 Drag_SetSpeed(self, self.impulse - 1);
2842                         }
2843                         else if(self.impulse == 14)
2844                         {
2845                                 Drag_SetSpeed(self, 9);
2846                         }
2847
2848                         if(frametime)
2849                                 Drag_Update(self);
2850                 }
2851                 else
2852                 {
2853                         Drag_Finish(self);
2854                 }
2855         }
2856
2857         if(self.classname == "player") {
2858                 CheckRules_Player();
2859                 UpdateChatBubble();
2860                 UpdateTeamBubble();
2861                 if (self.impulse)
2862                         ImpulseCommands();
2863                 if (intermission_running)
2864                         return;         // intermission or finale
2865
2866                 GetPressedKeys();
2867         } else if (self.classname == "observer") {
2868                 //do nothing
2869         } else if (self.classname == "spectator") {
2870                 //do nothing
2871         }
2872
2873         /*
2874         float i;
2875         for(i = 0; i < 1000; ++i)
2876         {
2877                 vector end;
2878                 end = self.origin + '0 0 1024' + 512 * randomvec();
2879                 tracebox(self.origin, self.mins, self.maxs, end, MOVE_NORMAL, self);
2880                 if(trace_fraction < 1)
2881                 if(!(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
2882                 {
2883                         print("I HIT SOLID: ", vtos(self.origin), " -> ", vtos(end), "\n");
2884                         break;
2885                 }
2886         }
2887         */
2888
2889         Arena_Warmup();
2890
2891         //pointparticles(particleeffectnum("machinegun_impact"), self.origin + self.view_ofs + '0 0 7', '0 0 0', 1);
2892
2893         if(self.waypointsprite_attachedforcarrier)
2894                 WaypointSprite_UpdateHealth(self.waypointsprite_attachedforcarrier, '1 0 0' * healtharmor_maxdamage(self.health, self.armorvalue, cvar("g_balance_armor_blockpercent")));
2895 }