data/qcsrc/server/cl_client.qc

   1 .float wantswelcomemessage;
   2 .string netname_previous;
   3
   4 void spawnfunc_info_player_survivor (void)
   5 {
   6         spawnfunc_info_player_deathmatch();
   7 }
   8
   9 void spawnfunc_info_player_start (void)
  10 {
  11         spawnfunc_info_player_deathmatch();
  12 }
  13
  14 void spawnfunc_info_player_deathmatch (void)
  15 {
  16         self.classname = "info_player_deathmatch";
  17         relocate_spawnpoint();
  18 }
  19
  20 void() spawnpoint_use =
  21 {
  22         if(teams_matter)
  23         if(have_team_spawns)
  24         {
  25                 self.team = activator.team;
  26                 some_spawn_has_been_used = 1;
  27         }
  28 };
  29
  30 // Returns:
  31 //   -1 if a spawn can't be used
  32 //   otherwise, a weight of the spawnpoint
  33 float Spawn_Score(entity spot, entity playerlist, float teamcheck)
  34 {
  35         float shortest, thisdist;
  36         entity player;
  37
  38         // filter out spots for the wrong team
  39         if(teamcheck)
  40         if(spot.team != teamcheck)
  41                 return -1;
  42
  43         // filter out spots for assault
  44         if(spot.target != "") {
  45                 local entity ent;
  46                 ent = find(world, targetname, spot.target);
  47                 while(ent) {
  48                         if(ent.classname == "target_objective")
  49                                 if(ent.health < 0 || ent.health >= ASSAULT_VALUE_INACTIVE)
  50                                         return -1;
  51                         ent = find(ent, targetname, spot.target);
  52                 }
  53         }
  54
  55         player = playerlist;
  56         shortest = vlen(world.maxs - world.mins);
  57         for(player = playerlist; player; player = player.chain)
  58                 if (player != self)
  59                 {
  60                         thisdist = vlen(player.origin - spot.origin);
  61                         if (thisdist < shortest)
  62                                 shortest = thisdist;
  63                 }
  64         return shortest;
  65 }
  66
  67 float spawn_allbad;
  68 float spawn_allgood;
  69 entity Spawn_FilterOutBadSpots(entity firstspot, entity playerlist, float mindist, float teamcheck)
  70 {
  71         local entity spot, spotlist, spotlistend;
  72         spawn_allgood = TRUE;
  73         spawn_allbad = TRUE;
  74
  75         spotlist = world;
  76         spotlistend = world;
  77
  78         for(spot = firstspot; spot; spot = spot.chain)
  79         {
  80                 spot.frags = Spawn_Score(spot, playerlist, teamcheck);
  81
  82                 if(cvar("spawn_debugview"))
  83                 {
  84                         setmodel(spot, "models/runematch/rune.mdl");
  85                         if(spot.frags < mindist)
  86                         {
  87                                 spot.colormod = '1 0 0';
  88                                 spot.scale = 1;
  89                         }
  90                         else
  91                         {
  92                                 spot.colormod = '0 1 0';
  93                                 spot.scale = spot.frags / mindist;
  94                         }
  95                 }
  96
  97                 if(spot.frags >= 0) // spawning allowed here
  98                 {
  99                         if(spot.frags < mindist)
 100                         {
 101                                 // too short distance
 102                                 spawn_allgood = FALSE;
 103                         }
 104                         else
 105                         {
 106                                 // perfect
 107                                 spawn_allbad = FALSE;
 108
 109                                 if(spotlistend)
 110                                         spotlistend.chain = spot;
 111                                 spotlistend = spot;
 112                                 if(!spotlist)
 113                                         spotlist = spot;
 114
 115                                 /*
 116                                 if(teamcheck)
 117                                 if(spot.team != teamcheck)
 118                                         error("invalid spawn added");
 119                                 */
 120
 121                                 print("added ", etos(spot), "\n");
 122                         }
 123                 }
 124         }
 125         spotlistend.chain = world;
 126
 127         /*
 128                 entity e;
 129                 if(teamcheck)
 130                         for(e = spotlist; e; e = e.chain)
 131                         {
 132                                 print("seen ", etos(e), "\n");
 133                                 if(e.team != teamcheck)
 134                                         error("invalid spawn found");
 135                         }
 136         */
 137
 138         return spotlist;
 139 }
 140
 141 entity Spawn_WeightedPoint(entity firstspot, float lower, float upper, float exponent)
 142 {
 143         // weight of a point: bound(lower, mindisttoplayer, upper)^exponent
 144         // multiplied by spot.cnt (useful if you distribute many spawnpoints in a small area)
 145         local entity spot;
 146
 147         RandomSelection_Init();
 148         for(spot = firstspot; spot; spot = spot.chain)
 149                 RandomSelection_Add(spot, 0, pow(bound(lower, spot.frags, upper), exponent) * spot.cnt);
 150
 151         return RandomSelection_chosen_ent;
 152 }
 153
 154 /*
 155 =============
 156 SelectSpawnPoint
 157
 158 Finds a point to respawn
 159 =============
 160 */
 161 entity SelectSpawnPoint (float anypoint)
 162 {
 163         local float teamcheck;
 164         local entity firstspot_new;
 165         local entity spot, firstspot, playerlist;
 166
 167         spot = find (world, classname, "testplayerstart");
 168         if (spot)
 169                 return spot;
 170
 171         teamcheck = 0;
 172
 173         if(!anypoint && have_team_spawns)
 174                 teamcheck = self.team;
 175
 176         // get the list of players
 177         playerlist = findchain(classname, "player");
 178         // get the entire list of spots
 179         firstspot = findchain(classname, "info_player_deathmatch");
 180         // filter out the bad ones
 181         // (note this returns the original list if none survived)
 182         firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, 100, teamcheck);
 183         if(!firstspot_new)
 184                 firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, -1, teamcheck);
 185         firstspot = firstspot_new;
 186
 187         // there is 50/50 chance of choosing a random spot or the furthest spot
 188         // (this means that roughly every other spawn will be furthest, so you
 189         // usually won't get fragged at spawn twice in a row)
 190         if (arena_roundbased)
 191         {
 192                 firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, 800, teamcheck);
 193                 if(firstspot_new)
 194                         firstspot = firstspot_new;
 195                 spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 196         }
 197         else if (random() > cvar("g_spawn_furthest"))
 198                 spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 199         else
 200                 spot = Spawn_WeightedPoint(firstspot, 1, 5000, 5); // chooses a far far away spawnpoint
 201
 202         if(cvar("spawn_debugview"))
 203         {
 204                 print("spot mindistance: ", ftos(spot.frags), "\n");
 205
 206                 entity e;
 207                 if(teamcheck)
 208                         for(e = firstspot; e; e = e.chain)
 209                                 if(e.team != teamcheck)
 210                                         error("invalid spawn found");
 211         }
 212
 213         if (!spot)
 214         {
 215                 if(cvar("spawn_debug"))
 216                         GotoNextMap();
 217                 else
 218                 {
 219                         if(some_spawn_has_been_used)
 220                                 return world; // team can't spawn any more, because of actions of other team
 221                         else
 222                                 error("Cannot find a spawn point - please fix the map!");
 223                 }
 224         }
 225
 226         return spot;
 227 }
 228
 229 /*
 230 =============
 231 CheckPlayerModel
 232
 233 Checks if the argument string can be a valid playermodel.
 234 Returns a valid one in doubt.
 235 =============
 236 */
 237 string FallbackPlayerModel = "models/player/marine.zym";
 238 string CheckPlayerModel(string plyermodel) {
 239         if(strlen(plyermodel) < 4)
 240                 return FallbackPlayerModel;
 241         if( substring(plyermodel,0,14) != "models/player/")
 242                 return FallbackPlayerModel;
 243         else if(cvar("sv_servermodelsonly"))
 244         {
 245                 if(substring(plyermodel,strlen(plyermodel)-4,4) != ".zym")
 246                 if(substring(plyermodel,strlen(plyermodel)-4,4) != ".dpm")
 247                 if(substring(plyermodel,strlen(plyermodel)-4,4) != ".md3")
 248                 if(substring(plyermodel,strlen(plyermodel)-4,4) != ".psk")
 249                         return FallbackPlayerModel;
 250                 if(!fexists(plyermodel))
 251                         return FallbackPlayerModel;
 252         }
 253         return plyermodel;
 254 }
 255
 256 /*
 257 =============
 258 Client_customizeentityforclient
 259
 260 LOD reduction
 261 =============
 262 */
 263 float Client_customizeentityforclient()
 264 {
 265 #ifdef ALLOW_VARIABLE_LOD
 266         // self: me
 267         // other: the player viewing me
 268         float distance;
 269         float f;
 270
 271         if(self.flags & FL_NOTARGET) // we don't need LOD for spectators
 272                 return TRUE;
 273
 274         if(other.cvar_cl_playerdetailreduction <= 0)
 275         {
 276                 if(other.cvar_cl_playerdetailreduction <= -2)
 277                         self.modelindex = self.modelindex_lod2;
 278                 else if(other.cvar_cl_playerdetailreduction <= -1)
 279                         self.modelindex = self.modelindex_lod1;
 280                 else
 281                         self.modelindex = self.modelindex_lod0;
 282         }
 283         else
 284         {
 285                 distance = vlen(self.origin - other.origin);
 286                 f = (distance + 100.0) * other.cvar_cl_playerdetailreduction;
 287                 if(f > 10000)
 288                         self.modelindex = self.modelindex_lod2;
 289                 else if(f > 5000)
 290                         self.modelindex = self.modelindex_lod1;
 291                 else
 292                         self.modelindex = self.modelindex_lod0;
 293         }
 294 #endif
 295
 296         return TRUE;
 297 }
 298
 299 void UpdatePlayerSounds();
 300 void setmodel_lod(entity e, string modelname)
 301 {
 302 #ifdef ALLOW_VARIABLE_LOD
 303         string s;
 304
 305         // FIXME: this only supports 3-letter extensions
 306         s = strcat(substring(modelname, 0, strlen(modelname) - 4), "_1", substring(modelname, 0, strlen(modelname) - 4));
 307         if(fexists(s))
 308         {
 309                 precache_model(s);
 310                 setmodel(e, s); // players have high precision
 311                 self.modelindex_lod1 = self.modelindex;
 312         }
 313         else
 314                 self.modelindex_lod1 = -1;
 315
 316         s = strcat(substring(modelname, 0, strlen(modelname) - 4), "_2", substring(modelname, 0, strlen(modelname) - 4));
 317         if(fexists(s))
 318         {
 319                 precache_model(s);
 320                 setmodel(e, s); // players have high precision
 321                 self.modelindex_lod2 = self.modelindex;
 322         }
 323         else
 324                 self.modelindex_lod2 = -1;
 325
 326         precache_model(modelname);
 327         setmodel(e, modelname); // players have high precision
 328         self.modelindex_lod0 = self.modelindex;
 329
 330         if(self.modelindex_lod1 < 0)
 331                 self.modelindex_lod1 = self.modelindex;
 332
 333         if(self.modelindex_lod2 < 0)
 334                 self.modelindex_lod2 = self.modelindex;
 335 #else
 336         precache_model(modelname);
 337         setmodel(e, modelname); // players have high precision
 338 #endif
 339         player_setupanimsformodel();
 340         UpdatePlayerSounds();
 341 }
 342
 343 /*
 344 =============
 345 PutObserverInServer
 346
 347 putting a client as observer in the server
 348 =============
 349 */
 350 void PutObserverInServer (void)
 351 {
 352         entity  spot;
 353         spot = SelectSpawnPoint (TRUE);
 354         if(!spot)
 355                 error("No spawnpoints for observers?!?\n");
 356         RemoveGrapplingHook(self); // Wazat's Grappling Hook
 357
 358         if(clienttype(self) == CLIENTTYPE_REAL)
 359         {
 360                 msg_entity = self;
 361                 WriteByte(MSG_ONE, SVC_SETVIEW);
 362                 WriteEntity(MSG_ONE, self);
 363         }
 364
 365         DropAllRunes(self);
 366         kh_Key_DropAll(self, TRUE);
 367
 368         if(self.flagcarried)
 369                 DropFlag(self.flagcarried);
 370
 371         WaypointSprite_PlayerDead();
 372
 373         DistributeFragsAmongTeam(self, self.team, 1);
 374
 375         if(self.frags <= 0 && self.frags > -666 && g_lms && self.killcount != -666)
 376                 bprint ("^4", self.netname, "^4 has no more lives left\n");
 377         else if(self.killcount != -666)
 378                 bprint ("^4", self.netname, "^4 is spectating now\n");
 379
 380         self.spectatortime = time;
 381
 382         self.classname = "observer";
 383         self.health = -666;
 384         self.takedamage = DAMAGE_NO;
 385         self.solid = SOLID_NOT;
 386         self.movetype = MOVETYPE_NOCLIP;
 387         self.flags = FL_CLIENT | FL_NOTARGET;
 388         self.armorvalue = 666;
 389         self.effects = 0;
 390         self.armorvalue = cvar("g_balance_armor_start");
 391         self.pauserotarmor_finished = 0;
 392         self.pauserothealth_finished = 0;
 393         self.pauseregen_finished = 0;
 394         self.damageforcescale = 0;
 395         self.death_time = 0;
 396         self.dead_frame = 0;
 397         self.deaths = 0;
 398         self.alpha = 0;
 399         self.scale = 0;
 400         self.fade_time = 0;
 401         self.pain_frame = 0;
 402         self.pain_finished = 0;
 403         self.strength_finished = 0;
 404         self.invincible_finished = 0;
 405         self.pushltime = 0;
 406         self.think = SUB_Null;
 407         self.nextthink = 0;
 408         self.hook_time = 0;
 409         self.runes = 0;
 410         self.deadflag = DEAD_NO;
 411         self.angles = spot.angles;
 412         self.angles_z = 0;
 413         self.fixangle = TRUE;
 414         self.crouch = FALSE;
 415
 416         self.view_ofs = PL_VIEW_OFS;
 417         setorigin (self, spot.origin);
 418         setsize (self, '0 0 0', '0 0 0');
 419         self.oldorigin = self.origin;
 420         self.items = 0;
 421         self.model = "";
 422         self.modelindex = 0;
 423         self.weapon = 0;
 424         self.weaponmodel = "";
 425         self.weaponentity = world;
 426         self.killcount = -666;
 427         self.velocity = '0 0 0';
 428         self.avelocity = '0 0 0';
 429         self.punchangle = '0 0 0';
 430         self.punchvector = '0 0 0';
 431         self.oldvelocity = self.velocity;
 432         self.customizeentityforclient = Client_customizeentityforclient;
 433         self.viewzoom = 1;
 434         self.wantswelcomemessage = 1;
 435
 436         if(g_arena)
 437         {
 438                 if(self.frags != -2)
 439                 {
 440                         Spawnqueue_Insert(self);
 441                 }
 442                 else
 443                 {
 444                         Spawnqueue_Unmark(self);
 445                         Spawnqueue_Remove(self);
 446                 }
 447         }
 448         else if(!g_lms)
 449                 self.frags = -666;
 450 }
 451
 452 float RestrictSkin(float s)
 453 {
 454         if(!teams_matter)
 455                 return s;
 456         if(s == 6)
 457                 return 6;
 458         return mod(s, 3);
 459 }
 460
 461 void FixPlayermodel()
 462 {
 463         local string defaultmodel;
 464         local float defaultskin;
 465         local vector m1, m2;
 466
 467         defaultmodel = "";
 468
 469         if(cvar("sv_defaultcharacter") == 1) {
 470                 defaultskin = 0;
 471
 472                 if(teams_matter)
 473                 {
 474                         defaultmodel = cvar_string(strcat("sv_defaultplayermodel_", Team_ColorNameLowerCase(self.team)));
 475                         defaultskin = cvar(strcat("sv_defaultplayerskin_", Team_ColorNameLowerCase(self.team)));
 476                 }
 477
 478                 if(defaultmodel == "")
 479                 {
 480                         defaultmodel = cvar_string("sv_defaultplayermodel");
 481                         defaultskin = cvar("sv_defaultplayerskin");
 482                 }
 483         }
 484
 485         if(defaultmodel != "")
 486         {
 487                 if (defaultmodel != self.model)
 488                 {
 489                         m1 = self.mins;
 490                         m2 = self.maxs;
 491                         setmodel_lod (self, defaultmodel);
 492                         setsize (self, m1, m2);
 493                 }
 494
 495                 self.skin = defaultskin;
 496         } else {
 497                 if (self.playermodel != self.model)
 498                 {
 499                         self.playermodel = CheckPlayerModel(self.playermodel);
 500                         m1 = self.mins;
 501                         m2 = self.maxs;
 502                         setmodel_lod (self, self.playermodel);
 503                         setsize (self, m1, m2);
 504                 }
 505
 506                 self.skin = RestrictSkin(stof(self.playerskin));
 507         }
 508
 509         if(!teams_matter)
 510                 if(strlen(cvar_string("sv_defaultplayercolors")))
 511                         if(self.clientcolors != cvar("sv_defaultplayercolors"))
 512                                 setcolor(self, cvar("sv_defaultplayercolors"));
 513 }
 514
 515 /*
 516 =============
 517 PutClientInServer
 518
 519 Called when a client spawns in the server
 520 =============
 521 */
 522 void PutClientInServer (void)
 523 {
 524         if(clienttype(self) == CLIENTTYPE_BOT)
 525         {
 526                 self.classname = "player";
 527         }
 528         else if(clienttype(self) == CLIENTTYPE_REAL)
 529         {
 530                 msg_entity = self;
 531                 WriteByte(MSG_ONE, SVC_SETVIEW);
 532                 WriteEntity(MSG_ONE, self);
 533         }
 534
 535         // player is dead and becomes observer
 536         if(g_lms && self.frags < 1)
 537                 self.classname = "observer";
 538
 539         if(g_arena)
 540         if(!self.spawned)
 541                 self.classname = "observer";
 542
 543         if(self.classname == "player") {
 544                 entity  spot;
 545
 546                 spot = SelectSpawnPoint (FALSE);
 547                 if(!spot)
 548                 {
 549                         centerprint(self, "Sorry, no spawnpoints available!\nHope your team can fix it...");
 550                         return; // spawn failed
 551                 }
 552
 553                 RemoveGrapplingHook(self); // Wazat's Grappling Hook
 554
 555                 self.classname = "player";
 556                 self.iscreature = TRUE;
 557                 self.movetype = MOVETYPE_WALK;
 558                 self.solid = SOLID_SLIDEBOX;
 559                 self.flags = FL_CLIENT;
 560                 self.takedamage = DAMAGE_AIM;
 561                 if(g_minstagib)
 562                         self.effects = EF_FULLBRIGHT;
 563                 else
 564                         self.effects = 0;
 565                 self.air_finished = time + 12;
 566                 self.dmg = 2;
 567
 568                 self.ammo_shells = start_ammo_shells;
 569                 self.ammo_nails = start_ammo_nails;
 570                 self.ammo_rockets = start_ammo_rockets;
 571                 self.ammo_cells = start_ammo_cells;
 572                 self.health = start_health;
 573                 self.armorvalue = start_armorvalue;
 574                 self.items = start_items;
 575                 self.switchweapon = start_switchweapon;
 576                 self.cnt = start_switchweapon;
 577                 self.weapon = 0;
 578                 self.jump_interval = time;
 579
 580                 self.spawnshieldtime = time + cvar("g_spawnshieldtime");
 581                 self.pauserotarmor_finished = time + cvar("g_balance_pause_armor_rot_spawn");
 582                 self.pauserothealth_finished = time + cvar("g_balance_pause_health_rot_spawn");
 583                 self.pauseregen_finished = time + cvar("g_balance_pause_health_regen_spawn");
 584                 //extend the pause of rotting if client was reset at the beginning of the countdown
 585                 if(!cvar("sv_ready_restart_after_countdown") && time < restart_countdown) {
 586                         self.spawnshieldtime += RESTART_COUNTDOWN;
 587                         self.pauserotarmor_finished += RESTART_COUNTDOWN;
 588                         self.pauserothealth_finished += RESTART_COUNTDOWN;
 589                         self.pauseregen_finished += RESTART_COUNTDOWN;
 590                 }
 591                 self.damageforcescale = 2;
 592                 self.death_time = 0;
 593                 self.dead_frame = 0;
 594                 self.alpha = 0;
 595                 self.scale = 0;
 596                 self.fade_time = 0;
 597                 self.pain_frame = 0;
 598                 self.pain_finished = 0;
 599                 self.strength_finished = 0;
 600                 self.invincible_finished = 0;
 601                 self.pushltime = 0;
 602                 //self.speed_finished = 0;
 603                 //self.slowmo_finished = 0;
 604                 // players have no think function
 605                 self.think = SUB_Null;
 606                 self.nextthink = 0;
 607                 self.hook_time = 0;
 608
 609                 self.runes = 0;
 610
 611                 self.deadflag = DEAD_NO;
 612
 613                 self.angles = spot.angles;
 614
 615                 self.angles_z = 0; // never spawn tilted even if the spot says to
 616                 self.fixangle = TRUE; // turn this way immediately
 617                 self.velocity = '0 0 0';
 618                 self.avelocity = '0 0 0';
 619                 self.punchangle = '0 0 0';
 620                 self.punchvector = '0 0 0';
 621                 self.oldvelocity = self.velocity;
 622
 623                 self.viewzoom = 0.6;
 624                 self.has_zoomed = 0;
 625
 626                 self.customizeentityforclient = Client_customizeentityforclient;
 627
 628                 self.model = "";
 629                 FixPlayermodel();
 630
 631                 self.crouch = FALSE;
 632                 self.view_ofs = PL_VIEW_OFS;
 633                 setsize (self, PL_MIN, PL_MAX);
 634                 self.spawnorigin = spot.origin;
 635                 setorigin (self, spot.origin + '0 0 1' * (1 - self.mins_z - 24));
 636                 // don't reset back to last position, even if new position is stuck in solid
 637                 self.oldorigin = self.origin;
 638
 639                 if(g_arena)
 640                 {
 641                         Spawnqueue_Remove(self);
 642                         Spawnqueue_Mark(self);
 643                 }
 644
 645                 self.event_damage = PlayerDamage;
 646
 647                 self.bot_attack = TRUE;
 648
 649                 self.statdraintime = time + 5;
 650                 self.button0 = self.button1 = self.button2 = self.button3 = 0;
 651
 652                 if(self.killcount == -666) {
 653                         self.killcount = 0;
 654                         if(!g_arena)
 655                         if(!g_lms)
 656                                 self.frags = 0;
 657                 }
 658
 659                 self.cnt = WEP_LASER;
 660                 self.nixnex_lastchange_id = -1;
 661
 662                 CL_SpawnWeaponentity();
 663                 self.alpha = default_player_alpha;
 664                 self.colormod = '1 1 1' * cvar("g_player_brightness");
 665                 self.exteriorweaponentity.alpha = default_weapon_alpha;
 666
 667                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval")*2;
 668                 self.lms_traveled_distance = 0;
 669                 self.speedrunning = FALSE;
 670
 671                 if(cvar("spawn_debug"))
 672                 {
 673                         sprint(self, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 674                         remove(spot);   // usefull for checking if there are spawnpoints, that let drop through the floor
 675                 }
 676
 677                 //stuffcmd(self, "chase_active 0");
 678                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
 679
 680                 if (cvar("g_spawnsound"))
 681                         sound (self, CHAN_AUTO, "misc/spawn.wav", 1, ATTN_NORM);
 682
 683                 if(g_assault) {
 684                         if(self.team == assault_attacker_team)
 685                                 centerprint(self, "You are attacking!\n");
 686                         else
 687                                 centerprint(self, "You are defending!\n");
 688                 }
 689
 690         } else if(self.classname == "observer") {
 691                 PutObserverInServer ();
 692         }
 693 }
 694
 695 /*
 696 =============
 697 SetNewParms
 698 =============
 699 */
 700 void SetNewParms (void)
 701 {
 702
 703 }
 704
 705 /*
 706 =============
 707 SetChangeParms
 708 =============
 709 */
 710 void SetChangeParms (void)
 711 {
 712
 713 }
 714
 715 /*
 716 =============
 717 ClientKill
 718
 719 Called when a client types 'kill' in the console
 720 =============
 721 */
 722
 723 void ClientKill_Now_TeamChange()
 724 {
 725         if(self.killindicator_teamchange == -1)
 726         {
 727                 self.team = -1;
 728                 JoinBestTeam( self, FALSE, FALSE );
 729         }
 730         else
 731         {
 732                 SV_ChangeTeam(self.killindicator_teamchange - 1);
 733         }
 734 }
 735
 736 void ClientKill_Now()
 737 {
 738         if(self.killindicator_teamchange)
 739                 ClientKill_Now_TeamChange();
 740
 741         // in any case:
 742         Damage(self, self, self, 100000, DEATH_KILL, self.origin, '0 0 0');
 743 }
 744 void KillIndicator_Think()
 745 {
 746         if (!self.owner.modelindex)
 747         {
 748                 self.owner.killindicator = world;
 749                 remove(self);
 750                 return;
 751         }
 752
 753         if(self.cnt <= 0)
 754         {
 755                 self = self.owner;
 756                 ClientKill_Now(); // no oldself needed
 757                 return;
 758         }
 759         else
 760         {
 761                 if(self.cnt <= 10)
 762                         setmodel(self, strcat("models/sprites/", ftos(self.cnt), ".spr32"));
 763                 if(clienttype(self.owner) == CLIENTTYPE_REAL)
 764                 {
 765                         if(self.cnt <= 10)
 766                                 play2(self.owner, strcat("announcer/robotic/", ftos(self.cnt), ".ogg"));
 767                         if(self.owner.killindicator_teamchange)
 768                         {
 769                                 if(self.owner.killindicator_teamchange == -1)
 770                                         centerprint(self.owner, strcat("Changing team in ", ftos(self.cnt), " seconds"));
 771                                 else
 772                                         centerprint(self.owner, strcat("Changing to ", ColoredTeamName(self.owner.killindicator_teamchange), " in ", ftos(self.cnt), " seconds"));
 773                         }
 774                         else
 775                                 centerprint(self.owner, strcat("^1Suicide in ", ftos(self.cnt), " seconds"));
 776                 }
 777                 self.nextthink = time + 1;
 778                 self.cnt -= 1;
 779         }
 780 }
 781
 782 void ClientKill_TeamChange (float targetteam) // 0 = don't change, -1 = auto
 783 {
 784         float killtime;
 785         entity e;
 786         killtime = cvar("g_balance_kill_delay");
 787
 788         self.killindicator_teamchange = targetteam;
 789
 790         if(!self.killindicator)
 791         {
 792                 if(killtime <= 0 || !self.modelindex || self.deadflag != DEAD_NO)
 793                 {
 794                         ClientKill_Now();
 795                 }
 796                 else
 797                 {
 798                         self.killindicator = spawn();
 799                         self.killindicator.owner = self;
 800                         self.killindicator.scale = 0.5;
 801                         setattachment(self.killindicator, self, "");
 802                         setorigin(self.killindicator, '0 0 52');
 803                         self.killindicator.think = KillIndicator_Think;
 804                         self.killindicator.nextthink = time + (self.lip) * 0.05;
 805                         self.killindicator.cnt = ceil(killtime);
 806                         self.killindicator.count = bound(0, ceil(killtime), 10);
 807                         sprint(self, strcat("^1You'll be dead in ", ftos(self.killindicator.cnt), " seconds\n"));
 808
 809                         for(e = world; (e = find(e, classname, "body")) != world; )
 810                         {
 811                                 if(e.enemy != self)
 812                                         continue;
 813                                 e.killindicator = spawn();
 814                                 e.killindicator.owner = e;
 815                                 e.killindicator.scale = 0.5;
 816                                 setattachment(e.killindicator, e, "");
 817                                 setorigin(e.killindicator, '0 0 52');
 818                                 e.killindicator.think = KillIndicator_Think;
 819                                 e.killindicator.nextthink = time + (e.lip) * 0.05;
 820                                 e.killindicator.cnt = ceil(killtime);
 821                         }
 822                         self.lip = 0;
 823                 }
 824         }
 825         if(self.killindicator)
 826         {
 827                 if(targetteam)
 828                         self.killindicator.colormod = TeamColor(targetteam);
 829                 else
 830                         self.killindicator.colormod = '0 0 0';
 831         }
 832 }
 833
 834 void ClientKill (void)
 835 {
 836         ClientKill_TeamChange(0);
 837 }
 838
 839 void DoTeamChange(float destteam)
 840 {
 841         float t, c0;
 842         if(!cvar("teamplay"))
 843         {
 844                 if(destteam >= 0)
 845                         SetPlayerColors(self, destteam);
 846                 return;
 847         }
 848         if(self.classname == "player")
 849         if(destteam == -1)
 850         {
 851                 CheckAllowedTeams(self);
 852                 t = FindSmallestTeam(self, TRUE);
 853                 switch(self.team)
 854                 {
 855                         case COLOR_TEAM1: c0 = c1; break;
 856                         case COLOR_TEAM2: c0 = c2; break;
 857                         case COLOR_TEAM3: c0 = c3; break;
 858                         case COLOR_TEAM4: c0 = c4; break;
 859                         default:          c0 = 999;
 860                 }
 861                 switch(t)
 862                 {
 863                         case 1:
 864                                 if(c0 > c1)
 865                                         destteam = COLOR_TEAM1;
 866                                 break;
 867                         case 2:
 868                                 if(c0 > c2)
 869                                         destteam = COLOR_TEAM2;
 870                                 break;
 871                         case 3:
 872                                 if(c0 > c3)
 873                                         destteam = COLOR_TEAM3;
 874                                 break;
 875                         case 4:
 876                                 if(c0 > c4)
 877                                         destteam = COLOR_TEAM4;
 878                                 break;
 879                 }
 880                 if(destteam == -1)
 881                         return;
 882         }
 883         if(destteam == self.team && !self.killindicator)
 884                 return;
 885         ClientKill_TeamChange(destteam);
 886 }
 887
 888 void FixClientCvars(entity e)
 889 {
 890         // send prediction settings to the client
 891         stuffcmd(e, "\nin_bindmap 0 0\n");
 892         /*
 893          * we no longer need to stuff this. Remove this comment block if you feel
 894          * 2.3 and higher (or was it 2.2.3?) don't need these any more
 895         stuffcmd(e, strcat("cl_gravity ", ftos(cvar("sv_gravity")), "\n"));
 896         stuffcmd(e, strcat("cl_movement_accelerate ", ftos(cvar("sv_accelerate")), "\n"));
 897         stuffcmd(e, strcat("cl_movement_friction ", ftos(cvar("sv_friction")), "\n"));
 898         stuffcmd(e, strcat("cl_movement_maxspeed ", ftos(cvar("sv_maxspeed")), "\n"));
 899         stuffcmd(e, strcat("cl_movement_airaccelerate ", ftos(cvar("sv_airaccelerate")), "\n"));
 900         stuffcmd(e, strcat("cl_movement_maxairspeed ", ftos(cvar("sv_maxairspeed")), "\n"));
 901         stuffcmd(e, strcat("cl_movement_stopspeed ", ftos(cvar("sv_stopspeed")), "\n"));
 902         stuffcmd(e, strcat("cl_movement_jumpvelocity ", ftos(cvar("sv_jumpvelocity")), "\n"));
 903         stuffcmd(e, strcat("cl_movement_stepheight ", ftos(cvar("sv_stepheight")), "\n"));
 904         stuffcmd(e, strcat("set cl_movement_friction_on_land ", ftos(cvar("sv_friction_on_land")), "\n"));
 905         stuffcmd(e, strcat("set cl_movement_airaccel_qw ", ftos(cvar("sv_airaccel_qw")), "\n"));
 906         stuffcmd(e, strcat("set cl_movement_airaccel_sideways_friction ", ftos(cvar("sv_airaccel_sideways_friction")), "\n"));
 907         stuffcmd(e, "cl_movement_edgefriction 1\n");
 908          */
 909 }
 910
 911 /*
 912 =============
 913 ClientConnect
 914
 915 Called when a client connects to the server
 916 =============
 917 */
 918 string ColoredTeamName(float t);
 919 //void dom_player_join_team(entity pl);
 920 void ClientConnect (void)
 921 {
 922         local string s;
 923         float wep;
 924
 925         if(Ban_IsClientBanned(self))
 926         {
 927                 s = strcat("^1NOTE:^7 banned client ", self.netaddress, " just tried to enter\n");
 928                 dropclient(self);
 929                 bprint(s);
 930                 return;
 931         }
 932
 933         self.classname = "player_joining";
 934         self.flags = self.flags | FL_CLIENT;
 935         self.version_nagtime = time + 10 + random() * 10;
 936
 937         if(player_count<0)
 938         {
 939                 dprint("BUG player count is lower than zero, this cannot happen!\n");
 940                 player_count = 0;
 941         }
 942
 943         bot_clientconnect();
 944
 945         //if(g_domination)
 946         //      dom_player_join_team(self);
 947
 948         //JoinBestTeam(self, FALSE, FALSE);
 949
 950         if((cvar("sv_spectate") == 1 && !g_lms) || cvar("g_campaign")) {
 951                 self.classname = "observer";
 952         } else {
 953                 self.classname = "player";
 954                 campaign_bots_may_start = 1;
 955         }
 956
 957         self.playerid = (playerid_last = playerid_last + 1);
 958         if(cvar("sv_eventlog"))
 959         {
 960                 if(clienttype(self) == CLIENTTYPE_REAL)
 961                         s = "player";
 962                 else
 963                         s = "bot";
 964                 GameLogEcho(strcat(":join:", ftos(self.playerid), ":", s, ":", self.netname), TRUE);
 965                 s = strcat(":team:", ftos(self.playerid), ":");
 966                 s = strcat(s, ftos(self.team));
 967                 GameLogEcho(s, FALSE);
 968         }
 969         self.netname_previous = strzone(self.netname);
 970
 971         //stuffcmd(self, "set tmpviewsize $viewsize \n");
 972
 973         bprint ("^4",self.netname);
 974         bprint ("^4 connected");
 975
 976         if(g_domination || g_ctf)
 977         {
 978                 bprint(" and joined the ");
 979                 bprint(ColoredTeamName(self.team));
 980         }
 981
 982         bprint("\n");
 983
 984         self.welcomemessage_time = 0;
 985
 986         stuffcmd(self, strcat("exec maps/", mapname, ".cfg\n"));
 987         // TODO: is this being used for anything else than cd tracks?
 988         // Remember: SVC_CDTRACK exists. Maybe it should be used.
 989         //
 990         stuffcmd(self, "cl_particles_reloadeffects\n");
 991
 992         FixClientCvars(self);
 993
 994         // spawnfunc_waypoint sprites
 995         WaypointSprite_InitClient(self);
 996
 997         // Wazat's grappling hook
 998         SetGrappleHookBindings();
 999
1000         // get autoswitch state from player when he toggles it
1001         stuffcmd(self, "alias autoswitch \"set cl_autoswitch $1 ; cmd autoswitch $1\"\n"); // default.cfg-ed in 2.4.1
1002
1003         // get version info from player
1004         stuffcmd(self, "cmd clientversion $gameversion\n");
1005
1006         // send all weapon info strings
1007         stuffcmd(self, "register_bestweapon clear\n"); // clear the Quake stuff
1008         wep = WEP_FIRST;
1009         while (wep <= WEP_LAST)
1010         {
1011                 weapon_action(wep, WR_REGISTER);
1012                 wep = wep + 1;
1013         }
1014
1015         // get other cvars from player
1016         GetCvars(0);
1017
1018         // set cvar for team scoreboard
1019         if (teams_matter)
1020         {
1021                 local float t;
1022                 t = cvar("teamplay");
1023                 // we have to stuff the correct teamplay value because if this is a listen server, this changes the teamplay mode of the server itself, which is bad
1024                 stuffcmd(self, strcat("set teamplay ", ftos(t), "\n"));
1025         }
1026         else
1027                 stuffcmd(self, "set teamplay 0\n");
1028
1029         // notify about available teams
1030         if(teamplay)
1031         {
1032                 CheckAllowedTeams(self);
1033                 t = 0; if(c1 >= 0) t |= 1; if(c2 >= 0) t |= 2; if(c3 >= 0) t |= 4; if(c4 >= 0) t |= 8;
1034                 stuffcmd(self, strcat("set _teams_available ", ftos(t), "\n"));
1035         }
1036         else
1037                 stuffcmd(self, "set _teams_available 0\n");
1038
1039         stuffcmd(self, strcat("set gametype ", ftos(game), "\n"));
1040
1041         if(g_lms)
1042         {
1043                 self.frags = LMS_NewPlayerLives();
1044                 if(!self.frags)
1045                         self.frags = -666;
1046         }
1047         else if(g_arena)
1048         {
1049                 self.classname = "observer";
1050                 Spawnqueue_Insert(self);
1051         }
1052
1053         bot_relinkplayerlist();
1054
1055         self.spectatortime = time;
1056         if(blockSpectators)
1057         {
1058                 sprint(self, strcat("^7You have to become a player within the next ", ftos(cvar("g_maxplayers_spectator_blocktime")), " seconds, otherwise you will be kicked, because spectators aren't allowed at this time!\n"));
1059         }
1060
1061         self.jointime = time;
1062         self.allowedTimeouts = cvar("sv_timeout_number");
1063 }
1064
1065 /*
1066 =============
1067 ClientDisconnect
1068
1069 Called when a client disconnects from the server
1070 =============
1071 */
1072 void(entity e) DropFlag;
1073 .entity chatbubbleentity;
1074 .entity teambubbleentity;
1075 void ClientDisconnect (void)
1076 {
1077         float save;
1078         if(cvar("sv_eventlog"))
1079                 GameLogEcho(strcat(":part:", ftos(self.playerid)), FALSE);
1080         bprint ("^4",self.netname);
1081         bprint ("^4 disconnected\n");
1082
1083         if (self.chatbubbleentity)
1084         {
1085                 remove (self.chatbubbleentity);
1086                 self.chatbubbleentity = world;
1087         }
1088
1089         if (self.teambubbleentity)
1090         {
1091                 remove (self.teambubbleentity);
1092                 self.teambubbleentity = world;
1093         }
1094
1095         if (self.killindicator)
1096         {
1097                 remove (self.killindicator);
1098                 self.killindicator = world;
1099         }
1100
1101         WaypointSprite_PlayerGone();
1102
1103         DropAllRunes(self);
1104         kh_Key_DropAll(self, TRUE);
1105
1106         if(self.flagcarried)
1107                 DropFlag(self.flagcarried);
1108
1109         DistributeFragsAmongTeam(self, self.team, 1);
1110
1111         save = self.flags;
1112         self.flags = self.flags - (self.flags & FL_CLIENT);
1113         bot_relinkplayerlist();
1114         self.flags = save;
1115
1116         // remove laserdot
1117         if(self.weaponentity)
1118                 if(self.weaponentity.lasertarget)
1119                         remove(self.weaponentity.lasertarget);
1120
1121         if(g_arena)
1122         {
1123                 Spawnqueue_Unmark(self);
1124                 Spawnqueue_Remove(self);
1125         }
1126
1127         if(self.netname_previous)
1128                 strunzone(self.netname_previous);
1129
1130         // free cvars
1131         GetCvars(-1);
1132 }
1133
1134 .float buttonchat;
1135 void() ChatBubbleThink =
1136 {
1137         self.nextthink = time;
1138         if (!self.owner.modelindex || self.owner.chatbubbleentity != self)
1139         {
1140                 self.owner.chatbubbleentity = world;
1141                 remove(self);
1142                 return;
1143         }
1144         setorigin(self, self.owner.origin + '0 0 15' + self.owner.maxs_z * '0 0 1');
1145         if (self.owner.buttonchat && !self.owner.deadflag)
1146                 self.model = self.mdl;
1147         else
1148                 self.model = "";
1149 };
1150
1151 void() UpdateChatBubble =
1152 {
1153         if (!self.modelindex)
1154                 return;
1155         // spawn a chatbubble entity if needed
1156         if (!self.chatbubbleentity)
1157         {
1158                 self.chatbubbleentity = spawn();
1159                 self.chatbubbleentity.owner = self;
1160                 self.chatbubbleentity.exteriormodeltoclient = self;
1161                 self.chatbubbleentity.think = ChatBubbleThink;
1162                 self.chatbubbleentity.nextthink = time;
1163                 setmodel(self.chatbubbleentity, "models/misc/chatbubble.spr"); // precision set below
1164                 setorigin(self.chatbubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1165                 self.chatbubbleentity.mdl = self.chatbubbleentity.model;
1166                 self.chatbubbleentity.model = "";
1167                 self.chatbubbleentity.effects = EF_LOWPRECISION;
1168         }
1169 }
1170
1171
1172 void() TeamBubbleThink =
1173 {
1174         self.nextthink = time;
1175         if (!self.owner.modelindex || self.owner.teambubbleentity != self)
1176         {
1177                 self.owner.teambubbleentity = world;
1178                 remove(self);
1179                 return;
1180         }
1181 //      setorigin(self, self.owner.origin + '0 0 15' + self.owner.maxs_z * '0 0 1');  // bandwidth hog. setattachment does this now
1182         if (self.owner.buttonchat || self.owner.deadflag || self.owner.killindicator)
1183                 self.model = "";
1184         else
1185                 self.model = self.mdl;
1186
1187 };
1188
1189 float() TeamBubble_customizeentityforclient
1190 {
1191         return (self.owner != other && self.owner.team == other.team && other.killcount > -666);
1192 }
1193
1194 void() UpdateTeamBubble =
1195 {
1196         if (!self.modelindex || !cvar("teamplay"))
1197                 return;
1198         // spawn a teambubble entity if needed
1199         if (!self.teambubbleentity && cvar("teamplay"))
1200         {
1201                 self.teambubbleentity = spawn();
1202                 self.teambubbleentity.owner = self;
1203                 self.teambubbleentity.exteriormodeltoclient = self;
1204                 self.teambubbleentity.think = TeamBubbleThink;
1205                 self.teambubbleentity.nextthink = time;
1206                 setmodel(self.teambubbleentity, "models/misc/teambubble.spr"); // precision set below
1207 //              setorigin(self.teambubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1208                 setorigin(self.teambubbleentity, self.teambubbleentity.origin + '0 0 15' + self.maxs_z * '0 0 1');
1209                 setattachment(self.teambubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1210                 self.teambubbleentity.mdl = self.teambubbleentity.model;
1211                 self.teambubbleentity.model = self.teambubbleentity.mdl;
1212                 self.teambubbleentity.customizeentityforclient = TeamBubble_customizeentityforclient;
1213                 self.teambubbleentity.effects = EF_LOWPRECISION;
1214         }
1215 }
1216
1217 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1218 // added to the model skins
1219 /*void() UpdateColorModHack =
1220 {
1221         local float c;
1222         c = self.clientcolors & 15;
1223         // LordHavoc: only bothering to support white, green, red, yellow, blue
1224              if (teamplay == 0) self.colormod = '0 0 0';
1225         else if (c ==  0) self.colormod = '1.00 1.00 1.00';
1226         else if (c ==  3) self.colormod = '0.10 1.73 0.10';
1227         else if (c ==  4) self.colormod = '1.73 0.10 0.10';
1228         else if (c == 12) self.colormod = '1.22 1.22 0.10';
1229         else if (c == 13) self.colormod = '0.10 0.10 1.73';
1230         else self.colormod = '1 1 1';
1231 };*/
1232
1233 void respawn(void)
1234 {
1235         CopyBody(1);
1236         self.effects |= EF_NODRAW; // prevent another CopyBody
1237         PutClientInServer();
1238 }
1239
1240 /**
1241  * When sv_timeout is used this function returs strings like
1242  * "Timeout begins in 2 seconds!\n" or "Timeout ends in 23 seconds!\n".
1243  * Called by centerprint functions
1244  * @param addOneSecond boolean, set to 1 if the welcome-message centerprint asks for the text
1245  */
1246 string getTimeoutText(float addOneSecond) {
1247         if (!cvar("sv_timeout") || !timeoutStatus)
1248                 return "";
1249
1250         local string retStr;
1251         if (timeoutStatus == 1) {
1252                 if (addOneSecond == 1) {
1253                         retStr = strcat("Timeout begins in ", ftos(remainingLeadTime + 1), " seconds!\n");
1254                 }
1255                 else {
1256                         retStr = strcat("Timeout begins in ", ftos(remainingLeadTime), " seconds!\n");
1257                 }
1258                 return retStr;
1259         }
1260         else if (timeoutStatus == 2) {
1261                 if (addOneSecond) {
1262                         retStr = strcat("Timeout ends in ", ftos(remainingTimeoutTime + 1), " seconds!\n");
1263                         //don't show messages like "Timeout ends in 0 seconds"...
1264                         if ((remainingTimeoutTime + 1) > 0)
1265                                 return retStr;
1266                         else
1267                                 return "";
1268                 }
1269                 else {
1270                         retStr = strcat("Timeout ends in ", ftos(remainingTimeoutTime), " seconds!\n");
1271                         //don't show messages like "Timeout ends in 0 seconds"...
1272                         if (remainingTimeoutTime > 0)
1273                                 return retStr;
1274                         else
1275                                 return "";
1276                 }
1277         }
1278         else return "";
1279 }
1280
1281 void player_powerups (void)
1282 {
1283         if (g_minstagib)
1284         {
1285                 if (self.items & IT_STRENGTH)
1286                 {
1287                         if (time > self.strength_finished)
1288                         {
1289                                 if (g_minstagib_invis_alpha > 0)
1290                                 {
1291                                         self.alpha = default_player_alpha;
1292                                         self.exteriorweaponentity.alpha = default_weapon_alpha;
1293                                         self.effects = self.effects | EF_FULLBRIGHT;
1294                                 }
1295                                 else
1296                                 {
1297                                         self.effects -= self.effects & EF_NODRAW;
1298                                 }
1299                                 self.items = self.items - (self.items & IT_STRENGTH);
1300                                 sprint(self, "^3Invisibility has worn off\n");
1301                         }
1302                 }
1303                 else
1304                 {
1305                         if (time < self.strength_finished)
1306                         {
1307                                 if (g_minstagib_invis_alpha > 0)
1308                                 {
1309                                         self.alpha = g_minstagib_invis_alpha;
1310                                         self.exteriorweaponentity.alpha = g_minstagib_invis_alpha;
1311                                         self.effects -= self.effects & EF_FULLBRIGHT;
1312                                 }
1313                                 else
1314                                 {
1315                                         self.effects = self.effects | EF_NODRAW;
1316                                 }
1317                                 self.items = self.items | IT_STRENGTH;
1318                                 sprint(self, "^3You are invisible\n");
1319                         }
1320                 }
1321
1322                 if (self.items & IT_INVINCIBLE)
1323                 {
1324                         if (time > self.invincible_finished)
1325                         {
1326                                 self.items = self.items - (self.items & IT_INVINCIBLE);
1327                                 sprint(self, "^3Speed has worn off\n");
1328                         }
1329                 }
1330                 else
1331                 {
1332                         if (time < self.invincible_finished)
1333                         {
1334                                 self.items = self.items | IT_INVINCIBLE;
1335                                 sprint(self, "^3You are on speed\n");
1336                         }
1337                 }
1338                 return;
1339         }
1340
1341         self.effects = self.effects - (self.effects & (EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT));
1342         if (self.items & IT_STRENGTH)
1343         {
1344                 self.effects = self.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1345                 if (time > self.strength_finished)
1346                 {
1347                         self.items = self.items - (self.items & IT_STRENGTH);
1348                         sprint(self, "^3Strength has worn off\n");
1349                 }
1350         }
1351         else
1352         {
1353                 if (time < self.strength_finished)
1354                 {
1355                         self.items = self.items | IT_STRENGTH;
1356                         sprint(self, "^3Strength infuses your weapons with devastating power\n");
1357                 }
1358         }
1359         if (self.items & IT_INVINCIBLE)
1360         {
1361                 self.effects = self.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1362                 if (time > self.invincible_finished)
1363                 {
1364                         self.items = self.items - (self.items & IT_INVINCIBLE);
1365                         sprint(self, "^3Shield has worn off\n");
1366                 }
1367         }
1368         else
1369         {
1370                 if (time < self.invincible_finished)
1371                 {
1372                         self.items = self.items | IT_INVINCIBLE;
1373                         sprint(self, "^3Shield surrounds you\n");
1374                 }
1375         }
1376
1377         if (cvar("g_fullbrightplayers"))
1378                 self.effects = self.effects | EF_FULLBRIGHT;
1379
1380         // midair gamemode: damage only while in the air
1381         // if in midair mode, being on ground grants temporary invulnerability
1382         // (this is so that multishot weapon don't clear the ground flag on the
1383         // first damage in the frame, leaving the player vulnerable to the
1384         // remaining hits in the same frame)
1385         if (self.flags & FL_ONGROUND)
1386         if (g_midair)
1387                 self.spawnshieldtime = max(self.spawnshieldtime, time + cvar("g_midair_shieldtime"));
1388
1389         if (time < self.spawnshieldtime)
1390                 self.effects = self.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1391 }
1392
1393 float CalcRegen(float current, float stable, float regenfactor)
1394 {
1395         if(current > stable)
1396                 return current;
1397         else if(current > stable - 0.25) // when close enough, "snap"
1398                 return stable;
1399         else
1400                 return min(stable, current + (stable - current) * regenfactor * frametime);
1401 }
1402
1403 void player_regen (void)
1404 {
1405         float maxh, maxa, limith, limita, max_mod, regen_mod, rot_mod, limit_mod;
1406         maxh = cvar("g_balance_health_stable");
1407         maxa = cvar("g_balance_armor_stable");
1408         limith = cvar("g_balance_health_limit");
1409         limita = cvar("g_balance_armor_limit");
1410
1411         if (g_minstagib || (g_lms && !cvar("g_lms_regenerate")))
1412                 return;
1413
1414         max_mod = regen_mod = rot_mod = limit_mod = 1;
1415
1416         if (self.runes & RUNE_REGEN)
1417         {
1418                 if (self.runes & CURSE_VENOM) // do we have both rune/curse?
1419                 {
1420                         regen_mod = cvar("g_balance_rune_regen_combo_regenrate");
1421                         max_mod = cvar("g_balance_rune_regen_combo_hpmod");
1422                         limit_mod = cvar("g_balance_rune_regen_combo_limitmod");
1423                 }
1424                 else
1425                 {
1426                         regen_mod = cvar("g_balance_rune_regen_regenrate");
1427                         max_mod = cvar("g_balance_rune_regen_hpmod");
1428                         limit_mod = cvar("g_balance_rune_regen_limitmod");
1429                 }
1430         }
1431         else if (self.runes & CURSE_VENOM)
1432         {
1433                 max_mod = cvar("g_balance_curse_venom_hpmod");
1434                 if (self.runes & RUNE_REGEN) // do we have both rune/curse?
1435                         rot_mod = cvar("g_balance_rune_regen_combo_rotrate");
1436                 else
1437                         rot_mod = cvar("g_balance_curse_venom_rotrate");
1438                 limit_mod = cvar("g_balance_curse_venom_limitmod");
1439                 //if (!self.runes & RUNE_REGEN)
1440                 //      rot_mod = cvar("g_balance_curse_venom_rotrate");
1441         }
1442         maxh = maxh * max_mod;
1443         //maxa = maxa * max_mod;
1444         limith = limith * limit_mod;
1445         limita = limita * limit_mod;
1446
1447         if (self.armorvalue > maxa)
1448         {
1449                 if (time > self.pauserotarmor_finished)
1450                 {
1451                         self.armorvalue = max(maxa, self.armorvalue + (maxa - self.armorvalue) * cvar("g_balance_armor_rot") * frametime);
1452                         self.armorvalue = max(maxa, self.armorvalue - cvar("g_balance_armor_rotlinear") * frametime);
1453                 }
1454         }
1455         else if (self.armorvalue < maxa)
1456         {
1457                 if (time > self.pauseregen_finished)
1458                 {
1459                         self.armorvalue = CalcRegen(self.armorvalue, maxa, cvar("g_balance_armor_regen"));
1460                         self.armorvalue = min(maxa, self.armorvalue + cvar("g_balance_armor_regenlinear") * frametime);
1461                 }
1462         }
1463         if (self.health > maxh)
1464         {
1465                 if (time > self.pauserothealth_finished)
1466                 {
1467                         self.health = max(maxh, self.health + (maxh - self.health) * rot_mod*cvar("g_balance_health_rot") * frametime);
1468                         self.health = max(maxh, self.health - rot_mod*cvar("g_balance_health_rotlinear") * frametime);
1469                 }
1470         }
1471         else if (self.health < maxh)
1472         {
1473                 if (time > self.pauseregen_finished)
1474                 {
1475                         self.health = CalcRegen(self.health, maxh, regen_mod * cvar("g_balance_health_regen"));
1476                         self.health = min(maxh, self.health + regen_mod*cvar("g_balance_health_regenlinear") * frametime);
1477                 }
1478         }
1479
1480         if (self.health > limith)
1481                 self.health = limith;
1482         if (self.armorvalue > limita)
1483                 self.armorvalue = limita;
1484
1485         // if player rotted to death...  die!
1486         if(self.health < 1)
1487                 self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
1488 }
1489
1490 /*
1491 ======================
1492 spectate mode routines
1493 ======================
1494 */
1495 void SpectateCopy(entity spectatee) {
1496         self.armortype = spectatee.armortype;
1497         self.armorvalue = spectatee.armorvalue;
1498         self.currentammo = spectatee.currentammo;
1499         self.effects = spectatee.effects;
1500         self.health = spectatee.health;
1501         self.impulse = 0;
1502         self.items = spectatee.items;
1503         self.punchangle = spectatee.punchangle;
1504         self.view_ofs = spectatee.view_ofs;
1505         self.v_angle = spectatee.v_angle;
1506         self.viewzoom = spectatee.viewzoom;
1507         self.velocity = spectatee.velocity;
1508         self.dmg_take = spectatee.dmg_take;
1509         self.dmg_save = spectatee.dmg_save;
1510         self.dmg_inflictor = spectatee.dmg_inflictor;
1511         self.angles = spectatee.v_angle;
1512         self.fixangle = TRUE;
1513         setorigin(self, spectatee.origin);
1514         setsize(self, spectatee.mins, spectatee.maxs);
1515 }
1516
1517 float SpectateUpdate() {
1518         if(!self.enemy)
1519                 return 0;
1520
1521         if (self == self.enemy)
1522                 return 0;
1523
1524         if(self.enemy.flags & FL_NOTARGET)
1525                 return 0;
1526
1527         SpectateCopy(self.enemy);
1528
1529         return 1;
1530 }
1531
1532 float SpectateNext() {
1533         other = find(self.enemy, classname, "player");
1534         if (!other) {
1535                 other = find(other, classname, "player");
1536         }
1537         if (other) {
1538                 self.enemy = other;
1539         }
1540         if(self.enemy.classname == "player") {
1541                 msg_entity = self;
1542                 WriteByte(MSG_ONE, SVC_SETVIEW);
1543                 WriteEntity(MSG_ONE, self.enemy);
1544                 self.wantswelcomemessage = 1;
1545                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
1546                 if(!SpectateUpdate())
1547                         PutObserverInServer();
1548                 return 1;
1549         } else {
1550                 return 0;
1551         }
1552 }
1553
1554 /*
1555 =============
1556 ShowRespawnCountdown()
1557
1558 Update a respawn countdown display.
1559 =============
1560 */
1561 void ShowRespawnCountdown()
1562 {
1563         float number;
1564         if(self.deadflag == DEAD_NO) // just respawned?
1565                 return;
1566         else
1567         {
1568                 number = ceil(self.death_time - time);
1569                 if(number <= 0)
1570                         return;
1571                 if(number <= self.respawn_countdown)
1572                 {
1573                         self.respawn_countdown = number - 1;
1574                         if(ceil(self.death_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
1575                                 play2(self, strcat("announcer/robotic/", ftos(number), ".ogg"));
1576                 }
1577         }
1578 }
1579
1580 void LeaveSpectatorMode()
1581 {
1582         if(isJoinAllowed()) {
1583                 if(!cvar("teamplay") || cvar("g_campaign") || cvar("g_balance_teams")) {
1584                         self.classname = "player";
1585                         if(cvar("g_campaign") || cvar("g_balance_teams") || cvar("g_balance_teams_force"))
1586                                 JoinBestTeam(self, FALSE, TRUE);
1587                         if(cvar("g_campaign"))
1588                                 campaign_bots_may_start = 1;
1589                         PutClientInServer();
1590                         if(!(self.flags & FL_NOTARGET))
1591                                 bprint ("^4", self.netname, "^4 is playing now\n");
1592                         centerprint(self,"");
1593                         return;
1594                 } else {
1595                         stuffcmd(self,"menu_showteamselect\n");
1596                         return;
1597                 }
1598         }
1599         else {
1600                 //player may not join because of g_maxplayers is set
1601                 centerprint_atprio(self, CENTERPRIO_MAPVOTE, PREVENT_JOIN_TEXT);
1602         }
1603 }
1604
1605 /**
1606  * Determines whether the player is allowed to join. This depends on cvar
1607  * g_maxplayers, if it isn't used this function always return TRUE, otherwise
1608  * it checks whether the number of currently playing players exceeds g_maxplayers.
1609  * @return bool TRUE if the player is allowed to join, false otherwise
1610  */
1611 float isJoinAllowed() {
1612         if (!cvar("g_maxplayers"))
1613                 return TRUE;
1614
1615         local entity e;
1616         local float currentlyPlaying;
1617         FOR_EACH_REALPLAYER(e) {
1618                 if(e.classname == "player")
1619                         currentlyPlaying += 1;
1620         }
1621         if(currentlyPlaying < cvar("g_maxplayers"))
1622                 return TRUE;
1623
1624         return FALSE;
1625 }
1626
1627 /**
1628  * Checks whether the client is an observer or spectator, if so, he will get kicked after
1629  * g_maxplayers_spectator_blocktime seconds
1630  */
1631 void checkSpectatorBlock() {
1632         if(self.classname == "spectator" || self.classname == "observer") {
1633                 if( time > (self.spectatortime + cvar("g_maxplayers_spectator_blocktime")) ) {
1634                         sprint(self, "^7You were kicked from the server because you are spectator and spectators aren't allowed at the moment.\n");
1635                         dropclient(self);
1636                 }
1637         }
1638 }
1639
1640 float vercmp_recursive(string v1, string v2)
1641 {
1642         float dot1, dot2;
1643         string s1, s2;
1644         float r;
1645
1646         dot1 = strstrofs(v1, ".", 0);
1647         dot2 = strstrofs(v2, ".", 0);
1648         if(dot1 == -1)
1649                 s1 = v1;
1650         else
1651                 s1 = substring(v1, 0, dot1);
1652         if(dot2 == -1)
1653                 s2 = v2;
1654         else
1655                 s2 = substring(v2, 0, dot2);
1656
1657         r = stof(s1) - stof(s2);
1658         if(r != 0)
1659                 return r;
1660
1661         r = strcasecmp(s1, s2);
1662         if(r != 0)
1663                 return r;
1664
1665         if(dot1 == -1)
1666                 if(dot2 == -1)
1667                         return 0;
1668                 else
1669                         return -1;
1670         else
1671                 if(dot2 == -1)
1672                         return 1;
1673                 else
1674                         return vercmp_recursive(substring(v1, dot1 + 1, 999), substring(v2, dot2 + 1, 999));
1675 }
1676
1677 float vercmp(string v1, string v2)
1678 {
1679         if(strcasecmp(v1, v2) == 0) // early out check
1680                 return 0;
1681         return vercmp_recursive(v1, v2);
1682 }
1683
1684 void ObserverThink()
1685 {
1686         if (self.flags & FL_JUMPRELEASED) {
1687                 if (self.button2 && self.version == cvar("gameversion")) {
1688                         self.welcomemessage_time = 0;
1689                         self.flags = self.flags - FL_JUMPRELEASED;
1690                         LeaveSpectatorMode();
1691                         return;
1692                 } else if(self.button0 && self.version == cvar("gameversion")) {
1693                         self.welcomemessage_time = 0;
1694                         self.flags = self.flags - FL_JUMPRELEASED;
1695                         if(SpectateNext() == 1) {
1696                                 self.classname = "spectator";
1697                         }
1698                 }
1699         } else {
1700                 if (!(self.button0 || self.button2)) {
1701                         self.flags = self.flags | FL_JUMPRELEASED;
1702                 }
1703         }
1704         if(self.button4)
1705                 self.wantswelcomemessage = 0;
1706         if(self.wantswelcomemessage)
1707                 PrintWelcomeMessage(self);
1708 }
1709
1710 void SpectatorThink()
1711 {
1712         if (self.flags & FL_JUMPRELEASED) {
1713                 if (self.button2 && self.version == cvar("gameversion")) {
1714                         self.welcomemessage_time = 0;
1715                         self.flags = self.flags - FL_JUMPRELEASED;
1716                         LeaveSpectatorMode();
1717                         return;
1718                 } else if(self.button0) {
1719                         self.welcomemessage_time = 0;
1720                         self.flags = self.flags - FL_JUMPRELEASED;
1721                         if(SpectateNext() == 1) {
1722                                 self.classname = "spectator";
1723                         } else {
1724                                 self.classname = "observer";
1725                                 PutClientInServer();
1726                         }
1727                 } else if (self.button3) {
1728                         self.welcomemessage_time = 0;
1729                         self.flags = self.flags - FL_JUMPRELEASED;
1730                         self.classname = "observer";
1731                         PutClientInServer();
1732                 } else {
1733                         if(!SpectateUpdate())
1734                                 PutObserverInServer();
1735                 }
1736         } else {
1737                 if (!(self.button0 || self.button3)) {
1738                         self.flags = self.flags | FL_JUMPRELEASED;
1739                 }
1740         }
1741         if(self.button4)
1742                 self.wantswelcomemessage = 0;
1743         if(self.wantswelcomemessage)
1744                 PrintWelcomeMessage(self);
1745         self.flags = self.flags | FL_CLIENT | FL_NOTARGET;
1746 }
1747
1748 /*
1749 =============
1750 PlayerPreThink
1751
1752 Called every frame for each client before the physics are run
1753 =============
1754 */
1755 void() ctf_setstatus;
1756 .float vote_nagtime;
1757 void PlayerPreThink (void)
1758 {
1759         if(blockSpectators)
1760                 checkSpectatorBlock();
1761
1762         if(self.netname_previous != self.netname)
1763         {
1764                 if(cvar("sv_eventlog"))
1765                         GameLogEcho(strcat(":name:", ftos(self.playerid), ":", self.netname), TRUE);
1766                 if(self.netname_previous)
1767                         strunzone(self.netname_previous);
1768                 self.netname_previous = strzone(self.netname);
1769         }
1770
1771         // version nagging
1772         if(self.version_nagtime)
1773                 if(self.cvar_g_nexuizversion)
1774                         if(time > self.version_nagtime)
1775                         {
1776                                 if(strstr(self.cvar_g_nexuizversion, "svn", 0) < 0)
1777                                 {
1778                                         if(strstr(cvar_string("g_nexuizversion"), "svn", 0) >= 0)
1779                                         {
1780                                                 dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Nexuiz ", cvar_string("g_nexuizversion"), " (beta)^7, you have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1\n");
1781                                                 sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Nexuiz ", cvar_string("g_nexuizversion"), " (beta)^7, you have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1\n"));
1782                                         }
1783                                         else
1784                                         {
1785                                                 float r;
1786                                                 r = vercmp(self.cvar_g_nexuizversion, cvar_string("g_nexuizversion"));
1787                                                 if(r < 0)
1788                                                 {
1789                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - ^3Nexuiz ", cvar_string("g_nexuizversion"), "^7 is out, and you still have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1 - get the update from ^4http://www.nexuiz.com/^1!\n");
1790                                                         sprint(self, strcat("\{1}^1NOTE: ^3Nexuiz ", cvar_string("g_nexuizversion"), "^7 is out, and you still have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1 - get the update from ^4http://www.nexuiz.com/^1!\n"));
1791                                                 }
1792                                                 else if(r > 0)
1793                                                 {
1794                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Nexuiz ", cvar_string("g_nexuizversion"), "^7, you have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1\n");
1795                                                         sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Nexuiz ", cvar_string("g_nexuizversion"), "^7, you have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1\n"));
1796                                                 }
1797                                         }
1798                                 }
1799                                 self.version_nagtime = 0;
1800                         }
1801
1802         // vote nagging
1803         if(self.cvar_scr_centertime)
1804                 if(time > self.vote_nagtime)
1805                 {
1806                         VoteNag();
1807                         self.vote_nagtime = time + self.cvar_scr_centertime * 0.6;
1808                 }
1809
1810         // GOD MODE info
1811         if(!(self.flags & FL_GODMODE)) if(self.max_armorvalue)
1812         {
1813                 sprint(self, strcat("godmode saved you ", ftos(self.max_armorvalue), " units of damage, cheater!\n"));
1814                 self.max_armorvalue = 0;
1815         }
1816
1817         if(frametime)
1818                 antilag_record(self);
1819
1820         if(self.classname == "player") {
1821 //              if(self.netname == "Wazat")
1822 //                      bprint(self.classname, "\n");
1823
1824                 CheckRules_Player();
1825
1826                 if(self.button7)
1827                         PrintWelcomeMessage(self);
1828
1829                 if(g_lms || !cvar("sv_spectate"))
1830                 if((time - self.jointime) <= cvar("welcome_message_time"))
1831                         PrintWelcomeMessage(self);
1832
1833                 if (intermission_running)
1834                 {
1835                         IntermissionThink ();   // otherwise a button could be missed between
1836                         return;                                 // the think tics
1837                 }
1838
1839                 if(self.teleport_time)
1840                 if(time > self.teleport_time)
1841                 {
1842                         self.teleport_time = 0;
1843                         self.effects = self.effects - (self.effects & EF_NODRAW);
1844                         if(self.weaponentity)
1845                                 self.weaponentity.flags = self.weaponentity.flags - (self.weaponentity.flags & EF_NODRAW);
1846                 }
1847
1848                 Nixnex_GiveCurrentWeapon();
1849
1850                 if(frametime > 0) // don't do this in cl_movement frames, just in server ticks
1851                         UpdateSelectedPlayer();
1852
1853                 //don't allow the player to turn around while game is paused!
1854                 if(timeoutStatus == 2) {
1855                         self.v_angle = self.lastV_angle;
1856                         self.angles = self.lastV_angle;
1857                         self.fixangle = TRUE;
1858                 }
1859
1860                 if (self.deadflag != DEAD_NO)
1861                 {
1862                         float button_pressed, force_respawn;
1863                         player_anim();
1864                         button_pressed = (self.button0 || self.button2 || self.button3 || self.button6 || self.buttonuse);
1865                         force_respawn = (g_lms || cvar("g_forced_respawn"));
1866                         if (self.deadflag == DEAD_DYING)
1867                         {
1868                                 if(force_respawn)
1869                                         self.deadflag = DEAD_RESPAWNING;
1870                                 else if(!button_pressed)
1871                                         self.deadflag = DEAD_DEAD;
1872                         }
1873                         else if (self.deadflag == DEAD_DEAD)
1874                         {
1875                                 if(button_pressed)
1876                                         self.deadflag = DEAD_RESPAWNABLE;
1877                         }
1878                         else if (self.deadflag == DEAD_RESPAWNABLE)
1879                         {
1880                                 if(!button_pressed)
1881                                         self.deadflag = DEAD_RESPAWNING;
1882                         }
1883                         else if (self.deadflag == DEAD_RESPAWNING)
1884                         {
1885                                 if(time > self.death_time)
1886                                 {
1887                                         self.death_time = time + 1; // only retry once a second
1888                                         respawn();
1889                                 }
1890                         }
1891                         ShowRespawnCountdown();
1892                         return;
1893                 }
1894
1895                 if(g_lms && !self.deadflag && cvar("g_lms_campcheck_interval"))
1896                 {
1897                         vector dist;
1898
1899                         // calculate player movement (in 2 dimensions only, so jumping on one spot doesn't count as movement)
1900                         dist = self.oldorigin - self.origin;
1901                         dist_z = 0;
1902                         self.lms_traveled_distance += fabs(vlen(dist));
1903
1904                         if((cvar("g_campaign") && !campaign_bots_may_start) || (time < restart_countdown))
1905                         {
1906                                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval")*2;
1907                                 self.lms_traveled_distance = 0;
1908                         }
1909
1910                         if(time > self.lms_nextcheck)
1911                         {
1912                                 //sprint(self, "distance: ", ftos(self.lms_traveled_distance), "\n");
1913                                 if(self.lms_traveled_distance < cvar("g_lms_campcheck_distance"))
1914                                 {
1915                                         centerprint(self, cvar_string("g_lms_campcheck_message"));
1916                                         // FIXME KadaverJack: gibbing player here causes playermodel to bounce around, instead of eye.md3
1917                                         // I wasn't able to find out WHY that happens, so I put a workaround in place that shall prevent players from being gibbed :(
1918                                         Damage(self, self, self, bound(0, cvar("g_lms_campcheck_damage"), self.health + self.armorvalue * cvar("g_balance_armor_blockpercent") + 5), DEATH_CAMP, self.origin, '0 0 0');
1919                                 }
1920                                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval");
1921                                 self.lms_traveled_distance = 0;
1922                         }
1923                 }
1924
1925                 if (self.button5 && !self.hook.state)
1926                 {
1927                         if (!self.crouch)
1928                         {
1929                                 self.crouch = TRUE;
1930                                 self.view_ofs = PL_CROUCH_VIEW_OFS;
1931                                 setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX);
1932                                 player_setanim(self.anim_duck, FALSE, TRUE, TRUE);
1933                         }
1934                 }
1935                 else
1936                 {
1937                         if (self.crouch)
1938                         {
1939                                 tracebox(self.origin, PL_MIN, PL_MAX, self.origin, FALSE, self);
1940                                 if (!trace_startsolid)
1941                                 {
1942                                         self.crouch = FALSE;
1943                                         self.view_ofs = PL_VIEW_OFS;
1944                                         setsize (self, PL_MIN, PL_MAX);
1945                                 }
1946                         }
1947                 }
1948
1949                 FixPlayermodel();
1950
1951                 GrapplingHookFrame();
1952
1953                 W_WeaponFrame();
1954
1955                 {
1956                         float zoomfactor, zoomspeed, zoomdir;
1957                         zoomfactor = self.cvar_cl_zoomfactor;
1958                         if(zoomfactor < 1 || zoomfactor > 16)
1959                                 zoomfactor = 2.5;
1960                         zoomspeed = self.cvar_cl_zoomspeed;
1961                         if(zoomspeed >= 0) // < 0 is instant zoom
1962                                 if(zoomspeed < 0.5 || zoomspeed > 16)
1963                                         zoomspeed = 3.5;
1964
1965                         zoomdir = self.button4;
1966                         if(self.button3)
1967                                 if(self.weapon == WEP_NEX)
1968                                         if(!g_minstagib)
1969                                                 zoomdir = 1;
1970
1971                         if(zoomdir)
1972                                 self.has_zoomed = 1;
1973
1974                         if(self.has_zoomed)
1975                         {
1976                                 if(zoomspeed <= 0) // instant zoom
1977                                 {
1978                                         if(zoomdir)
1979                                                 self.viewzoom = 1 / zoomfactor;
1980                                         else
1981                                                 self.viewzoom = 1;
1982                                 }
1983                                 else
1984                                 {
1985                                         // geometric zoom would be:
1986                                         //   self.viewzoom = bound(1 / zoomfactor, self.viewzoom * pow(zoomfactor, (zoomdir ? -1 : 1) * frametime * zoomspeed), 1);
1987                                         // however, testing showed that arithmetic/harmonic zoom works better
1988                                         if(zoomdir)
1989                                                 // self.viewzoom = 1 / bound(1, 1 / self.viewzoom + (zoomdir ? 1 : -1) * frametime * zoomspeed * (zoomfactor - 1), zoomfactor);
1990                                                 // zoom in = arithmetic: 1x, 2x, 3x, 4x, ..., 8x
1991                                                 self.viewzoom = 1 / bound(1, 1 / self.viewzoom + frametime * zoomspeed * (zoomfactor - 1), zoomfactor);
1992                                         else
1993                                                 // self.viewzoom = bound(1 / zoomfactor, self.viewzoom + (zoomdir ? -1 : 1) * frametime * zoomspeed * (1 - 1 / zoomfactor), 1);
1994                                                 // zoom out = harmonic: 8/1x, 8/2x, 8/3x, 8/4x, ..., 8/8x
1995                                                 self.viewzoom = bound(1 / zoomfactor, self.viewzoom + frametime * zoomspeed * (1 - 1 / zoomfactor), 1);
1996                                 }
1997                         }
1998                         else
1999                                 self.viewzoom = min(1, self.viewzoom + frametime); // spawn zoom-in
2000                 }
2001
2002                 player_powerups();
2003                 player_regen();
2004                 player_anim();
2005
2006                 if (g_minstagib)
2007                         minstagib_ammocheck();
2008
2009                 ctf_setstatus();
2010                 kh_setstatus();
2011
2012                 //self.angles_y=self.v_angle_y + 90;   // temp
2013
2014                 //if (TetrisPreFrame()) return;
2015         } else if(gameover) {
2016                 if (intermission_running)
2017                         IntermissionThink ();   // otherwise a button could be missed between
2018                 return;
2019         } else if(self.classname == "observer") {
2020                 ObserverThink();
2021         } else if(self.classname == "spectator") {
2022                 SpectatorThink();
2023         }
2024 }
2025
2026
2027 /*
2028 =============
2029 PlayerPostThink
2030
2031 Called every frame for each client after the physics are run
2032 =============
2033 */
2034 void PlayerPostThink (void)
2035 {
2036         // Savage: Check for nameless players
2037         if (strlen(self.netname) < 1) {
2038                 self.netname = "Player";
2039                 stuffcmd(self, "seta _cl_name Player\n");
2040         }
2041
2042         if(self.classname == "player") {
2043                 CheckRules_Player();
2044                 UpdateChatBubble();
2045                 UpdateTeamBubble();
2046                 if (self.impulse)
2047                         ImpulseCommands();
2048                 if (intermission_running)
2049                         return;         // intermission or finale
2050
2051                 //PrintWelcomeMessage(self);
2052                 //if (TetrisPostFrame()) return;
2053
2054                 // restart countdown
2055                 if (restart_countdown) {
2056                         if(time < restart_countdown) {
2057                                 if (!cvar("sv_ready_restart_after_countdown"))
2058                                 {
2059                                         self.movetype = MOVETYPE_NONE;
2060                                         self.velocity = '0 0 0';
2061                                         self.avelocity = '0 0 0';
2062                                         self.movement = '0 0 0';
2063                                 }
2064                         }
2065                         else
2066                         {
2067                                 //allow the player to move again if sv_ready_restart_after_countdown is not used and countdown is over
2068                                 if (!cvar("sv_ready_restart_after_countdown"))
2069                                 {
2070                                         if(self.movetype == MOVETYPE_NONE)
2071                                         {
2072                                                 self.movetype = MOVETYPE_WALK;
2073                                         }
2074                                 }
2075                         }
2076                 }
2077
2078         } else if (self.classname == "observer") {
2079                 //do nothing
2080         } else if (self.classname == "spectator") {
2081                 //do nothing
2082         }
2083
2084         Arena_Warmup();
2085 }