data/qcsrc/server/cl_client.qc

   1 void race_send_recordtime(float msg);
   2 void race_SendRankings(float pos, float prevpos, float del, float msg);
   3
   4 void send_CSQC_teamnagger() {
   5         WriteByte(0, SVC_TEMPENTITY);
   6         WriteByte(0, TE_CSQC_TEAMNAGGER);
   7 }
   8
   9 float ClientData_Send(entity to, float sf)
  10 {
  11         if(to != self.owner)
  12         {
  13                 error("wtf");
  14                 return FALSE;
  15         }
  16
  17         entity e;
  18
  19         e = to;
  20         if(to.classname == "spectator")
  21                 e = to.enemy;
  22
  23         sf = 0;
  24
  25         if(e.race_completed)
  26                 sf |= 1; // forced scoreboard
  27         if(to.spectatee_status)
  28                 sf |= 2; // spectator ent number follows
  29         if(e.zoomstate)
  30                 sf |= 4; // zoomed
  31         if(e.porto_v_angle_held)
  32                 sf |= 8; // angles held
  33
  34         WriteByte(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
  35         WriteByte(MSG_ENTITY, sf);
  36
  37         if(sf & 2)
  38                 WriteByte(MSG_ENTITY, to.spectatee_status);
  39
  40         if(sf & 8)
  41         {
  42                 WriteAngle(MSG_ENTITY, e.v_angle_x);
  43                 WriteAngle(MSG_ENTITY, e.v_angle_y);
  44         }
  45
  46         return TRUE;
  47 }
  48
  49 void ClientData_Attach()
  50 {
  51         Net_LinkEntity(self.clientdata = spawn(), FALSE, 0, ClientData_Send);
  52         self.clientdata.drawonlytoclient = self;
  53         self.clientdata.owner = self;
  54 }
  55
  56 void ClientData_Detach()
  57 {
  58         remove(self.clientdata);
  59         self.clientdata = world;
  60 }
  61
  62 void ClientData_Touch(entity e)
  63 {
  64         e.clientdata.SendFlags = 1;
  65
  66         // make it spectatable
  67         entity e2;
  68         FOR_EACH_REALCLIENT(e2)
  69         {
  70                 if(e2 != e)
  71                         if(e2.classname == "spectator")
  72                                 if(e2.enemy == e)
  73                                         e2.clientdata.SendFlags = 1;
  74         }
  75 }
  76
  77
  78 .vector spawnpoint_score;
  79 .string netname_previous;
  80
  81 void spawnfunc_info_player_survivor (void)
  82 {
  83         spawnfunc_info_player_deathmatch();
  84 }
  85
  86 void spawnfunc_info_player_start (void)
  87 {
  88         spawnfunc_info_player_deathmatch();
  89 }
  90
  91 void spawnfunc_info_player_deathmatch (void)
  92 {
  93         self.classname = "info_player_deathmatch";
  94         relocate_spawnpoint();
  95 }
  96
  97 void spawnpoint_use()
  98 {
  99         if(teams_matter)
 100         if(have_team_spawns > 0)
 101         {
 102                 self.team = activator.team;
 103                 some_spawn_has_been_used = 1;
 104         }
 105 };
 106
 107 // Returns:
 108 //   _x: prio (-1 if unusable)
 109 //   _y: weight
 110 vector Spawn_Score(entity spot, entity playerlist, float teamcheck, float anypoint)
 111 {
 112         float shortest, thisdist;
 113         float prio;
 114         entity player;
 115
 116         prio = 0;
 117
 118         // filter out spots for the wrong team
 119         if(teamcheck)
 120         if(spot.team != teamcheck)
 121                 return '-1 0 0';
 122
 123         if(race_spawns)
 124                 if(spot.target == "")
 125                         return '-1 0 0';
 126
 127         if(clienttype(self) == CLIENTTYPE_REAL)
 128         {
 129                 if(spot.restriction == 1)
 130                         return '-1 0 0';
 131         }
 132         else
 133         {
 134                 if(spot.restriction == 2)
 135                         return '-1 0 0';
 136         }
 137
 138         // filter out spots for assault
 139         if(spot.target != "") {
 140                 local entity ent;
 141                 float good, found;
 142                 ent = find(world, targetname, spot.target);
 143
 144                 while(ent) {
 145                         if(ent.classname == "target_objective")
 146                         {
 147                                 found = 1;
 148                                 if(ent.health < 0 || ent.health >= ASSAULT_VALUE_INACTIVE)
 149                                         return '-1 0 0';
 150                                 good = 1;
 151                         }
 152                         else if(ent.classname == "trigger_race_checkpoint")
 153                         {
 154                                 found = 1;
 155                                 if(!anypoint) // spectators may spawn everywhere
 156
 157                                 {
 158                                         if(g_race_qualifying)
 159                                         {
 160                                                 // spawn at first
 161                                                 if(ent.race_checkpoint != 0)
 162                                                         return '-1 0 0';
 163                                                 if(spot.race_place != race_lowest_place_spawn)
 164                                                         return '-1 0 0';
 165                                         }
 166                                         else
 167                                         {
 168                                                 if(ent.race_checkpoint != self.race_respawn_checkpoint)
 169                                                         return '-1 0 0';
 170                                                 // try reusing the previous spawn
 171                                                 if(ent == self.race_respawn_spotref || spot == self.race_respawn_spotref)
 172                                                         prio += 1;
 173                                                 if(ent.race_checkpoint == 0)
 174                                                 {
 175                                                         float pl;
 176                                                         pl = self.race_place;
 177                                                         if(pl > race_highest_place_spawn)
 178                                                                 pl = 0;
 179                                                         if(pl == 0 && !self.race_started)
 180                                                                 pl = race_highest_place_spawn; // use last place if he has not even touched finish yet
 181                                                         if(spot.race_place != pl)
 182                                                                 return '-1 0 0';
 183                                                 }
 184                                         }
 185                                 }
 186                                 good = 1;
 187                         }
 188                         ent = find(ent, targetname, spot.target);
 189                 }
 190
 191                 if(found && !good)
 192                         return '-1 0 0';
 193         }
 194
 195         player = playerlist;
 196         shortest = vlen(world.maxs - world.mins);
 197         for(player = playerlist; player; player = player.chain)
 198                 if (player != self)
 199                 {
 200                         thisdist = vlen(player.origin - spot.origin);
 201                         if (thisdist < shortest)
 202                                 shortest = thisdist;
 203                 }
 204         return prio * '1 0 0' + shortest * '0 1 0';
 205 }
 206
 207 float spawn_allbad;
 208 float spawn_allgood;
 209 entity Spawn_FilterOutBadSpots(entity firstspot, entity playerlist, float mindist, float teamcheck, float anypoint)
 210 {
 211         local entity spot, spotlist, spotlistend;
 212         spawn_allgood = TRUE;
 213         spawn_allbad = TRUE;
 214
 215         spotlist = world;
 216         spotlistend = world;
 217
 218         for(spot = firstspot; spot; spot = spot.chain)
 219         {
 220                 spot.spawnpoint_score = Spawn_Score(spot, playerlist, teamcheck, anypoint);
 221
 222                 if(cvar("spawn_debugview"))
 223                 {
 224                         setmodel(spot, "models/runematch/rune.mdl");
 225                         if(spot.spawnpoint_score_y < mindist)
 226                         {
 227                                 spot.colormod = '1 0 0';
 228                                 spot.scale = 1;
 229                         }
 230                         else
 231                         {
 232                                 spot.colormod = '0 1 0';
 233                                 spot.scale = spot.spawnpoint_score_y / mindist;
 234                         }
 235                 }
 236
 237                 if(spot.spawnpoint_score_x >= 0) // spawning allowed here
 238                 {
 239                         if(spot.spawnpoint_score_y < mindist)
 240                         {
 241                                 // too short distance
 242                                 spawn_allgood = FALSE;
 243                         }
 244                         else
 245                         {
 246                                 // perfect
 247                                 spawn_allbad = FALSE;
 248
 249                                 if(spotlistend)
 250                                         spotlistend.chain = spot;
 251                                 spotlistend = spot;
 252                                 if(!spotlist)
 253                                         spotlist = spot;
 254
 255                                 /*
 256                                 if(teamcheck)
 257                                 if(spot.team != teamcheck)
 258                                         error("invalid spawn added");
 259
 260                                 print("added ", etos(spot), "\n");
 261                                 */
 262                         }
 263                 }
 264         }
 265         if(spotlistend)
 266                 spotlistend.chain = world;
 267
 268         /*
 269                 entity e;
 270                 if(teamcheck)
 271                         for(e = spotlist; e; e = e.chain)
 272                         {
 273                                 print("seen ", etos(e), "\n");
 274                                 if(e.team != teamcheck)
 275                                         error("invalid spawn found");
 276                         }
 277         */
 278
 279         return spotlist;
 280 }
 281
 282 entity Spawn_WeightedPoint(entity firstspot, float lower, float upper, float exponent)
 283 {
 284         // weight of a point: bound(lower, mindisttoplayer, upper)^exponent
 285         // multiplied by spot.cnt (useful if you distribute many spawnpoints in a small area)
 286         local entity spot;
 287
 288         RandomSelection_Init();
 289         for(spot = firstspot; spot; spot = spot.chain)
 290                 RandomSelection_Add(spot, 0, string_null, pow(bound(lower, spot.spawnpoint_score_y, upper), exponent) * spot.cnt, (spot.spawnpoint_score_y >= lower) * 0.5 + spot.spawnpoint_score_x);
 291
 292         return RandomSelection_chosen_ent;
 293 }
 294
 295 /*
 296 =============
 297 SelectSpawnPoint
 298
 299 Finds a point to respawn
 300 =============
 301 */
 302 entity SelectSpawnPoint (float anypoint)
 303 {
 304         local float teamcheck;
 305         local entity firstspot_new;
 306         local entity spot, firstspot, playerlist;
 307
 308         spot = find (world, classname, "testplayerstart");
 309         if (spot)
 310                 return spot;
 311
 312         teamcheck = 0;
 313
 314         if(!anypoint && have_team_spawns > 0)
 315                 teamcheck = self.team;
 316
 317         // get the list of players
 318         playerlist = findchain(classname, "player");
 319         // get the entire list of spots
 320         firstspot = findchain(classname, "info_player_deathmatch");
 321         // filter out the bad ones
 322         // (note this returns the original list if none survived)
 323         if(anypoint)
 324         {
 325                 spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 326         }
 327         else
 328         {
 329                 firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, 100, teamcheck, anypoint);
 330                 if(!firstspot_new)
 331                         firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, -1, teamcheck, anypoint);
 332                 firstspot = firstspot_new;
 333
 334                 // there is 50/50 chance of choosing a random spot or the furthest spot
 335                 // (this means that roughly every other spawn will be furthest, so you
 336                 // usually won't get fragged at spawn twice in a row)
 337                 if (arena_roundbased && !g_ca)
 338                 {
 339                         firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, 800, teamcheck, anypoint);
 340                         if(firstspot_new)
 341                                 firstspot = firstspot_new;
 342                         spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 343                 }
 344                 else if (random() > cvar("g_spawn_furthest"))
 345                         spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 346                 else
 347                         spot = Spawn_WeightedPoint(firstspot, 1, 5000, 5); // chooses a far far away spawnpoint
 348         }
 349
 350         if(cvar("spawn_debugview"))
 351         {
 352                 print("spot mindistance: ", vtos(spot.spawnpoint_score), "\n");
 353
 354                 entity e;
 355                 if(teamcheck)
 356                         for(e = firstspot; e; e = e.chain)
 357                                 if(e.team != teamcheck)
 358                                         error("invalid spawn found");
 359         }
 360
 361         if (!spot)
 362         {
 363                 if(cvar("spawn_debug"))
 364                         GotoNextMap();
 365                 else
 366                 {
 367                         if(some_spawn_has_been_used)
 368                                 return world; // team can't spawn any more, because of actions of other team
 369                         else
 370                                 error("Cannot find a spawn point - please fix the map!");
 371                 }
 372         }
 373
 374         return spot;
 375 }
 376
 377 /*
 378 =============
 379 CheckPlayerModel
 380
 381 Checks if the argument string can be a valid playermodel.
 382 Returns a valid one in doubt.
 383 =============
 384 */
 385 string FallbackPlayerModel = "models/player/marine.zym";
 386 string CheckPlayerModel(string plyermodel) {
 387         if(strlen(plyermodel) < 4)
 388                 return FallbackPlayerModel;
 389         if( substring(plyermodel,0,14) != "models/player/")
 390                 return FallbackPlayerModel;
 391         else if(cvar("sv_servermodelsonly"))
 392         {
 393                 if(substring(plyermodel,-4,4) != ".zym")
 394                 if(substring(plyermodel,-4,4) != ".dpm")
 395                 if(substring(plyermodel,-4,4) != ".md3")
 396                 if(substring(plyermodel,-4,4) != ".psk")
 397                         return FallbackPlayerModel;
 398                 // forbid the LOD models
 399                 if(substring(plyermodel, -9,5) == "_lod1")
 400                         return FallbackPlayerModel;
 401                 if(substring(plyermodel, -9,5) == "_lod2")
 402                         return FallbackPlayerModel;
 403                 if(plyermodel != strtolower(plyermodel))
 404                         return FallbackPlayerModel;
 405                 if(!fexists(plyermodel))
 406                         return FallbackPlayerModel;
 407         }
 408         return plyermodel;
 409 }
 410
 411 /*
 412 =============
 413 Client_customizeentityforclient
 414
 415 LOD reduction
 416 =============
 417 */
 418 void Client_uncustomizeentityforclient()
 419 {
 420         if(self.modelindex == 0) // no need to uncustomize then
 421                 return;
 422         self.modelindex = self.modelindex_lod0;
 423         self.skin = self.skinindex;
 424 }
 425
 426 float Client_customizeentityforclient()
 427 {
 428         entity modelsource;
 429
 430         if(self.modelindex == 0)
 431                 return TRUE;
 432
 433         // forcemodel stuff
 434
 435 #ifdef PROFILING
 436         float t0;
 437         t0 = gettime(GETTIME_HIRES); // reference
 438 #endif
 439
 440         modelsource = self;
 441
 442 #ifdef ALLOW_FORCEMODELS
 443         if(other.cvar_cl_forceplayermodelsfromnexuiz)
 444                 if not(self.modelindex_lod0_from_nexuiz)
 445                         modelsource = other;
 446         if(other.cvar_cl_forceplayermodels && sv_clforceplayermodels)
 447                 modelsource = other;
 448 #endif
 449
 450         self.skin = modelsource.skinindex;
 451
 452 #if 0
 453         if(modelsource == self)
 454                 self.skin = modelsource.skinindex;
 455         else
 456                 self.skin = mod(modelsource.skinindex, 3); // forbid the fbskins as forced skins
 457 #endif
 458
 459         // self: me
 460         // other: the player viewing me
 461         float distance;
 462         float f;
 463
 464         if(other.cvar_cl_playerdetailreduction <= 0)
 465         {
 466                 if(other.cvar_cl_playerdetailreduction <= -2)
 467                         self.modelindex = modelsource.modelindex_lod2;
 468                 else if(other.cvar_cl_playerdetailreduction <= -1)
 469                         self.modelindex = modelsource.modelindex_lod1;
 470                 else
 471                         self.modelindex = modelsource.modelindex_lod0;
 472         }
 473         else
 474         {
 475                 distance = vlen(self.origin - other.origin);
 476                 f = (distance + 100.0) * other.cvar_cl_playerdetailreduction;
 477                 if(f > sv_loddistance2)
 478                         self.modelindex = modelsource.modelindex_lod2;
 479                 else if(f > sv_loddistance1)
 480                         self.modelindex = modelsource.modelindex_lod1;
 481                 else
 482                         self.modelindex = modelsource.modelindex_lod0;
 483         }
 484
 485 #ifdef PROFILING
 486         float t1;
 487         t1 = gettime(GETTIME_HIRES); // reference
 488         client_cefc_accumulator += (t1 - t0);
 489 #endif
 490
 491         return TRUE;
 492 }
 493
 494 void UpdatePlayerSounds();
 495 void setmodel_lod(entity e, string modelname)
 496 {
 497         string s;
 498
 499         if(sv_loddistance1)
 500         {
 501                 // FIXME: this only supports 3-letter extensions
 502                 s = strcat(substring(modelname, 0, strlen(modelname)-4), "_lod1", substring(modelname, -4, 4));
 503                 if(fexists(s))
 504                 {
 505                         setmodel(e, s); // players have high precision
 506                         self.modelindex_lod1 = self.modelindex;
 507                 }
 508                 else
 509                         self.modelindex_lod1 = -1;
 510
 511                 s = strcat(substring(modelname, 0, strlen(modelname)-4), "_lod2", substring(modelname, -4, 4));
 512                 if(fexists(s))
 513                 {
 514                         setmodel(e, s); // players have high precision
 515                         self.modelindex_lod2 = self.modelindex;
 516                 }
 517                 else
 518                         self.modelindex_lod2 = -1;
 519
 520                 precache_model(modelname);
 521                 setmodel(e, modelname); // players have high precision
 522                 self.modelindex_lod0 = self.modelindex;
 523
 524                 if(self.modelindex_lod1 < 0)
 525                         self.modelindex_lod1 = self.modelindex;
 526
 527                 if(self.modelindex_lod2 < 0)
 528                         self.modelindex_lod2 = self.modelindex;
 529         }
 530         else
 531         {
 532                 precache_model(modelname);
 533                 setmodel(e, modelname); // players have high precision
 534                 self.modelindex_lod0 = self.modelindex;
 535                         // save it for possible player model forcing
 536         }
 537
 538         s = whichpack(self.model);
 539         self.modelindex_lod0_from_nexuiz = ((s == "") || (substring(s, 0, 4) == "data"));
 540
 541         player_setupanimsformodel();
 542         UpdatePlayerSounds();
 543 }
 544
 545 /*
 546 =============
 547 PutObserverInServer
 548
 549 putting a client as observer in the server
 550 =============
 551 */
 552 void FixPlayermodel();
 553 void PutObserverInServer (void)
 554 {
 555         entity  spot;
 556
 557         race_PreSpawnObserver();
 558
 559         spot = SelectSpawnPoint (TRUE);
 560         if(!spot)
 561                 error("No spawnpoints for observers?!?\n");
 562         RemoveGrapplingHook(self); // Wazat's Grappling Hook
 563
 564         if(clienttype(self) == CLIENTTYPE_REAL)
 565         {
 566                 msg_entity = self;
 567                 WriteByte(MSG_ONE, SVC_SETVIEW);
 568                 WriteEntity(MSG_ONE, self);
 569         }
 570
 571         DropAllRunes(self);
 572         kh_Key_DropAll(self, TRUE);
 573
 574         Portal_ClearAll(self);
 575
 576         if(self.flagcarried)
 577                 DropFlag(self.flagcarried, world, world);
 578
 579         if(self.ballcarried)
 580                 DropBall(self.ballcarried, self.origin + self.ballcarried.origin, self.velocity);
 581
 582         WaypointSprite_PlayerDead();
 583
 584         if not(g_ca)  // don't reset teams when moving a ca player to the spectators
 585                 self.team = -1;  // move this as it is needed to log the player spectating in eventlog
 586
 587         if(self.killcount != -666) {
 588                 if(g_lms) {
 589                         if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
 590                                 bprint ("^4", self.netname, "^4 has no more lives left\n");
 591                         else
 592                                 bprint ("^4", self.netname, "^4 is spectating now\n"); // TODO turn this into a proper forfeit?
 593                 } else
 594                         bprint ("^4", self.netname, "^4 is spectating now\n");
 595
 596                 if(self.just_joined == FALSE) {
 597                         LogTeamchange(self.playerid, -1, 4);
 598                 } else
 599                         self.just_joined = FALSE;
 600         }
 601
 602         PlayerScore_Clear(self); // clear scores when needed
 603
 604         self.spectatortime = time;
 605
 606         self.classname = "observer";
 607         self.iscreature = FALSE;
 608         self.health = -666;
 609         self.takedamage = DAMAGE_NO;
 610         self.solid = SOLID_NOT;
 611         self.movetype = MOVETYPE_NOCLIP;
 612         self.flags = FL_CLIENT | FL_NOTARGET;
 613         self.armorvalue = 666;
 614         self.effects = 0;
 615         self.armorvalue = cvar("g_balance_armor_start");
 616         self.pauserotarmor_finished = 0;
 617         self.pauserothealth_finished = 0;
 618         self.pauseregen_finished = 0;
 619         self.damageforcescale = 0;
 620         self.death_time = 0;
 621         self.dead_frame = 0;
 622         self.alpha = 0;
 623         self.scale = 0;
 624         self.fade_time = 0;
 625         self.pain_frame = 0;
 626         self.pain_finished = 0;
 627         self.strength_finished = 0;
 628         self.invincible_finished = 0;
 629         self.pushltime = 0;
 630         self.think = SUB_Null;
 631         self.nextthink = 0;
 632         self.hook_time = 0;
 633         self.runes = 0;
 634         self.deadflag = DEAD_NO;
 635         self.angles = spot.angles;
 636         self.angles_z = 0;
 637         self.fixangle = TRUE;
 638         self.crouch = FALSE;
 639
 640         self.view_ofs = PL_VIEW_OFS;
 641         setorigin (self, spot.origin);
 642         setsize (self, '0 0 0', '0 0 0');
 643         self.prevorigin = self.origin;
 644         self.items = 0;
 645         self.weapons = 0;
 646         self.model = "";
 647         FixPlayermodel();
 648         self.model = "";
 649         self.modelindex = 0;
 650         self.weapon = 0;
 651         self.weaponmodel = "";
 652         self.weaponentity = world;
 653         self.exteriorweaponentity = world;
 654         self.killcount = -666;
 655         self.velocity = '0 0 0';
 656         self.avelocity = '0 0 0';
 657         self.punchangle = '0 0 0';
 658         self.punchvector = '0 0 0';
 659         self.oldvelocity = self.velocity;
 660         self.fire_endtime = -1;
 661
 662         if(sv_loddistance1)
 663                 SetCustomizer(self, Client_customizeentityforclient, Client_uncustomizeentityforclient);
 664
 665         if(g_arena)
 666         {
 667                 if(self.version_mismatch)
 668                 {
 669                         Spawnqueue_Unmark(self);
 670                         Spawnqueue_Remove(self);
 671                 }
 672                 else
 673                 {
 674                         Spawnqueue_Insert(self);
 675                 }
 676         }
 677         else if(g_lms)
 678         {
 679                 // Only if the player cannot play at all
 680                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) == 666)
 681                         self.frags = FRAGS_SPECTATOR;
 682                 else
 683                         self.frags = FRAGS_LMS_LOSER;
 684         }
 685         else
 686                 self.frags = FRAGS_SPECTATOR;
 687 }
 688
 689 float RestrictSkin(float s)
 690 {
 691         if(!teams_matter)
 692                 return s;
 693         if(s == 6)
 694                 return 6;
 695         return mod(s, 3);
 696 }
 697
 698 void FixPlayermodel()
 699 {
 700         local string defaultmodel;
 701         local float defaultskin, chmdl, oldskin;
 702         local vector m1, m2;
 703
 704         defaultmodel = "";
 705
 706         if(cvar("sv_defaultcharacter") == 1) {
 707                 defaultskin = 0;
 708
 709                 if(teams_matter)
 710                 {
 711                         string s;
 712                         s = Team_ColorNameLowerCase(self.team);
 713                         if(s != "neutral")
 714                         {
 715                                 defaultmodel = cvar_string(strcat("sv_defaultplayermodel_", s));
 716                                 defaultskin = cvar(strcat("sv_defaultplayerskin_", s));
 717                         }
 718                 }
 719
 720                 if(defaultmodel == "")
 721                 {
 722                         defaultmodel = cvar_string("sv_defaultplayermodel");
 723                         defaultskin = cvar("sv_defaultplayerskin");
 724                 }
 725         }
 726
 727         if(self.modelindex == 0 && self.deadflag == DEAD_NO)
 728         {
 729                 if(self.model != "")
 730                         bprint("\{1}^1Player ", self.netname, "^1 has a zero modelindex, trying to fix...\n");
 731                 self.model = ""; // force the != checks to return true
 732         }
 733
 734         if(defaultmodel != "")
 735         {
 736                 if (defaultmodel != self.model)
 737                 {
 738                         m1 = self.mins;
 739                         m2 = self.maxs;
 740                         setmodel_lod (self, defaultmodel);
 741                         setsize (self, m1, m2);
 742                         chmdl = TRUE;
 743                 }
 744
 745                 oldskin = self.skinindex;
 746                 self.skinindex = defaultskin;
 747         } else {
 748                 if (self.playermodel != self.model || self.playermodel == "")
 749                 {
 750                         self.playermodel = CheckPlayerModel(self.playermodel); // this is never "", so no endless loop
 751                         m1 = self.mins;
 752                         m2 = self.maxs;
 753                         setmodel_lod (self, self.playermodel);
 754                         setsize (self, m1, m2);
 755                         chmdl = TRUE;
 756                 }
 757
 758                 oldskin = self.skinindex;
 759                 self.skinindex = RestrictSkin(stof(self.playerskin));
 760         }
 761
 762         if(chmdl || oldskin != self.skinindex)
 763                 self.species = player_getspecies(); // model or skin has changed
 764
 765         if(!teams_matter)
 766                 if(strlen(cvar_string("sv_defaultplayercolors")))
 767                         if(self.clientcolors != cvar("sv_defaultplayercolors"))
 768                                 setcolor(self, cvar("sv_defaultplayercolors"));
 769 }
 770
 771 void PlayerTouchExplode(entity p1, entity p2)
 772 {
 773         vector org;
 774         org = (p1.origin + p2.origin) * 0.5;
 775         org_z += (p1.mins_z + p2.mins_z) * 0.5;
 776
 777         te_explosion(org);
 778
 779         entity e;
 780         e = spawn();
 781         setorigin(e, org);
 782         RadiusDamage(e, world, g_touchexplode_damage, g_touchexplode_edgedamage, g_touchexplode_radius, world, g_touchexplode_force, DEATH_TOUCHEXPLODE, world);
 783         remove(e);
 784 }
 785
 786 /*
 787 =============
 788 PutClientInServer
 789
 790 Called when a client spawns in the server
 791 =============
 792 */
 793 //void() ctf_playerchanged;
 794 void PutClientInServer (void)
 795 {
 796         if(clienttype(self) == CLIENTTYPE_BOT)
 797         {
 798                 self.classname = "player";
 799         }
 800         else if(clienttype(self) == CLIENTTYPE_REAL)
 801         {
 802                 msg_entity = self;
 803                 WriteByte(MSG_ONE, SVC_SETVIEW);
 804                 WriteEntity(MSG_ONE, self);
 805         }
 806
 807         // player is dead and becomes observer
 808         // FIXME fix LMS scoring for new system
 809         if(g_lms)
 810         {
 811                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
 812                         self.classname = "observer";
 813         }
 814
 815         if(g_arena || (g_ca && !allowed_to_spawn))
 816         if(!self.spawned)
 817                 self.classname = "observer";
 818
 819         if(gameover)
 820                 self.classname = "observer";
 821
 822         if(self.classname == "player" && (!g_ca || (g_ca && allowed_to_spawn))) {
 823                 entity spot, oldself;
 824                 float j;
 825
 826                 if(self.team < 0)
 827                         JoinBestTeam(self, FALSE, TRUE);
 828
 829                 race_PreSpawn();
 830
 831                 spot = SelectSpawnPoint (FALSE);
 832                 if(!spot)
 833                 {
 834                         centerprint(self, "Sorry, no spawnpoints available!\nHope your team can fix it...");
 835                         return; // spawn failed
 836                 }
 837
 838                 RemoveGrapplingHook(self); // Wazat's Grappling Hook
 839
 840                 self.classname = "player";
 841                 self.wasplayer = TRUE;
 842                 self.iscreature = TRUE;
 843                 self.movetype = MOVETYPE_WALK;
 844                 self.solid = SOLID_SLIDEBOX;
 845                 if(cvar("g_playerclip_collisions"))
 846                         self.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP;
 847                 else
 848                         self.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY;
 849                 self.frags = FRAGS_PLAYER;
 850                 if(independent_players)
 851                         MAKE_INDEPENDENT_PLAYER(self);
 852                 self.flags = FL_CLIENT;
 853                 self.takedamage = DAMAGE_AIM;
 854                 if(g_minstagib)
 855                         self.effects = EF_FULLBRIGHT;
 856                 else
 857                         self.effects = 0;
 858                 self.air_finished = time + 12;
 859                 self.dmg = 2;
 860
 861                 if(inWarmupStage)
 862                 {
 863                         self.ammo_shells = warmup_start_ammo_shells;
 864                         self.ammo_nails = warmup_start_ammo_nails;
 865                         self.ammo_rockets = warmup_start_ammo_rockets;
 866                         self.ammo_cells = warmup_start_ammo_cells;
 867                         self.ammo_fuel = warmup_start_ammo_fuel;
 868                         self.health = warmup_start_health;
 869                         self.armorvalue = warmup_start_armorvalue;
 870                         self.weapons = warmup_start_weapons;
 871                 }
 872                 else
 873                 {
 874                         self.ammo_shells = start_ammo_shells;
 875                         self.ammo_nails = start_ammo_nails;
 876                         self.ammo_rockets = start_ammo_rockets;
 877                         self.ammo_cells = start_ammo_cells;
 878                         self.ammo_fuel = start_ammo_fuel;
 879                         self.health = start_health;
 880                         self.armorvalue = start_armorvalue;
 881                         self.weapons = start_weapons;
 882                 }
 883
 884                 if(g_weaponarena_random)
 885                         self.weapons = randombits(self.weapons, g_weaponarena_random, FALSE);
 886
 887                 self.items = start_items;
 888                 self.switchweapon = w_getbestweapon(self);
 889                 self.cnt = self.switchweapon;
 890                 self.weapon = 0;
 891                 self.jump_interval = time;
 892
 893                 self.spawnshieldtime = time + cvar("g_spawnshieldtime");
 894                 self.pauserotarmor_finished = time + cvar("g_balance_pause_armor_rot_spawn");
 895                 self.pauserothealth_finished = time + cvar("g_balance_pause_health_rot_spawn");
 896                 self.pauserotfuel_finished = time + cvar("g_balance_pause_fuel_rot_spawn");
 897                 self.pauseregen_finished = time + cvar("g_balance_pause_health_regen_spawn");
 898                 //extend the pause of rotting if client was reset at the beginning of the countdown
 899                 if(!cvar("sv_ready_restart_after_countdown") && time < game_starttime) { // TODO why is this cvar NOTted?
 900                         self.spawnshieldtime += game_starttime - time;
 901                         self.pauserotarmor_finished += game_starttime - time;
 902                         self.pauserothealth_finished += game_starttime - time;
 903                         self.pauseregen_finished += game_starttime - time;
 904                 }
 905                 self.damageforcescale = 2;
 906                 self.death_time = 0;
 907                 self.dead_frame = 0;
 908                 self.alpha = 0;
 909                 self.scale = 0;
 910                 self.fade_time = 0;
 911                 self.pain_frame = 0;
 912                 self.pain_finished = 0;
 913                 self.strength_finished = 0;
 914                 self.invincible_finished = 0;
 915                 self.pushltime = 0;
 916                 // players have no think function
 917                 self.think = SUB_Null;
 918                 self.nextthink = 0;
 919                 self.hook_time = 0;
 920                 self.dmg_team = 0;
 921
 922                 self.metertime = 0;
 923
 924                 self.runes = 0;
 925
 926                 self.deadflag = DEAD_NO;
 927
 928                 self.angles = spot.angles;
 929
 930                 self.angles_z = 0; // never spawn tilted even if the spot says to
 931                 self.fixangle = TRUE; // turn this way immediately
 932                 self.velocity = '0 0 0';
 933                 self.avelocity = '0 0 0';
 934                 self.punchangle = '0 0 0';
 935                 self.punchvector = '0 0 0';
 936                 self.oldvelocity = self.velocity;
 937                 self.fire_endtime = -1;
 938
 939                 msg_entity = self;
 940                 WRITESPECTATABLE_MSG_ONE({
 941                         WriteByte(MSG_ONE, SVC_TEMPENTITY);
 942                         WriteByte(MSG_ONE, TE_CSQC_SPAWN);
 943                 });
 944
 945                 if(sv_loddistance1)
 946                         SetCustomizer(self, Client_customizeentityforclient, Client_uncustomizeentityforclient);
 947
 948                 self.model = "";
 949                 FixPlayermodel();
 950
 951                 self.crouch = FALSE;
 952                 self.view_ofs = PL_VIEW_OFS;
 953                 setsize (self, PL_MIN, PL_MAX);
 954                 self.spawnorigin = spot.origin;
 955                 setorigin (self, spot.origin + '0 0 1' * (1 - self.mins_z - 24));
 956                 // don't reset back to last position, even if new position is stuck in solid
 957                 self.oldorigin = self.origin;
 958                 self.prevorigin = self.origin;
 959                 self.lastrocket = world; // stop rocket guiding, no revenge from the grave!
 960
 961                 if(g_arena)
 962                 {
 963                         Spawnqueue_Remove(self);
 964                         Spawnqueue_Mark(self);
 965                 }
 966
 967                 else if(g_ca)
 968                         self.caplayer = 1;
 969
 970                 self.event_damage = PlayerDamage;
 971
 972                 self.bot_attack = TRUE;
 973
 974                 self.statdraintime = time + 5;
 975                 self.BUTTON_ATCK = self.BUTTON_JUMP = self.BUTTON_ATCK2 = 0;
 976
 977                 if(self.killcount == -666) {
 978                         PlayerScore_Clear(self);
 979                         self.killcount = 0;
 980                 }
 981
 982                 self.cnt = WEP_LASER;
 983                 self.nixnex_lastchange_id = -1;
 984
 985                 CL_SpawnWeaponentity();
 986                 self.alpha = default_player_alpha;
 987                 self.colormod = '1 1 1' * cvar("g_player_brightness");
 988                 self.exteriorweaponentity.alpha = default_weapon_alpha;
 989
 990                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval")*2;
 991                 self.lms_traveled_distance = 0;
 992                 self.speedrunning = FALSE;
 993
 994                 race_PostSpawn(spot);
 995
 996                 if(cvar("spawn_debug"))
 997                 {
 998                         sprint(self, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 999                         remove(spot);   // usefull for checking if there are spawnpoints, that let drop through the floor
1000                 }
1001
1002                 //stuffcmd(self, "chase_active 0");
1003                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
1004
1005                 if (cvar("g_spawnsound"))
1006                         sound (self, CHAN_TRIGGER, "misc/spawn.wav", VOL_BASE, ATTN_NORM);
1007
1008                 if(g_assault) {
1009                         if(self.team == assault_attacker_team)
1010                                 centerprint(self, "You are attacking!");
1011                         else
1012                                 centerprint(self, "You are defending!");
1013                 }
1014
1015                 target_voicescript_clear(self);
1016
1017                 // reset fields the weapons may use
1018         for (j = WEP_FIRST; j <= WEP_LAST; ++j)
1019             weapon_action(j, WR_RESETPLAYER);
1020
1021                 oldself = self;
1022                 self = spot;
1023                         activator = oldself;
1024                                 SUB_UseTargets();
1025                         activator = world;
1026                 self = oldself;
1027         } else if(self.classname == "observer" || (g_ca && !allowed_to_spawn)) {
1028                 PutObserverInServer ();
1029         }
1030
1031         //if(g_ctf)
1032         //      ctf_playerchanged();
1033 }
1034
1035 float ClientInit_SendEntity(entity to, float sf)
1036 {
1037         float i;
1038         WriteByte(MSG_ENTITY, ENT_CLIENT_INIT);
1039         WriteByte(MSG_ENTITY, g_nexball_meter_period * 32);
1040         for(i = 1; i <= 24; ++i)
1041                 WriteByte(MSG_ENTITY, (get_weaponinfo(i)).impulse + 1);
1042         WriteCoord(MSG_ENTITY, hook_shotorigin_x);
1043         WriteCoord(MSG_ENTITY, hook_shotorigin_y);
1044         WriteCoord(MSG_ENTITY, hook_shotorigin_z);
1045
1046         if(sv_foginterval && world.fog != "")
1047                 WriteString(MSG_ENTITY, world.fog);
1048         else
1049                 WriteString(MSG_ENTITY, "");
1050         WriteByte(MSG_ENTITY, cvar("g_balance_armor_blockpercent") * 255.0);
1051         WriteByte(MSG_ENTITY, cvar("g_balance_weaponswitchdelay") * 255.0);
1052         return TRUE;
1053 }
1054
1055 void ClientInit_Spawn()
1056 {
1057         Net_LinkEntity(spawn(), FALSE, 0, ClientInit_SendEntity);
1058 }
1059
1060 /*
1061 =============
1062 SetNewParms
1063 =============
1064 */
1065 void SetNewParms (void)
1066 {
1067         // initialize parms for a new player
1068         parm1 = -(86400 * 366);
1069 }
1070
1071 /*
1072 =============
1073 SetChangeParms
1074 =============
1075 */
1076 void SetChangeParms (void)
1077 {
1078         // save parms for level change
1079         parm1 = self.parm_idlesince - time;
1080 }
1081
1082 /*
1083 =============
1084 DecodeLevelParms
1085 =============
1086 */
1087 void DecodeLevelParms (void)
1088 {
1089         // load parms
1090         self.parm_idlesince = parm1;
1091         if(self.parm_idlesince == -(86400 * 366))
1092                 self.parm_idlesince = time;
1093
1094         // whatever happens, allow 60 seconds of idling directly after connect for map loading
1095         self.parm_idlesince = max(self.parm_idlesince, time - sv_maxidle + 60);
1096 }
1097
1098 /*
1099 =============
1100 ClientKill
1101
1102 Called when a client types 'kill' in the console
1103 =============
1104 */
1105
1106 void ClientKill_Now_TeamChange()
1107 {
1108         if(self.killindicator_teamchange == -1)
1109         {
1110                 self.team = -1;
1111                 JoinBestTeam( self, FALSE, FALSE );
1112         }
1113         else
1114                 SV_ChangeTeam(self.killindicator_teamchange - 1);
1115 }
1116
1117 void ClientKill_Now()
1118 {
1119         if(self.killindicator_teamchange)
1120                 ClientKill_Now_TeamChange();
1121
1122         // in any case:
1123         Damage(self, self, self, 100000, DEATH_KILL, self.origin, '0 0 0');
1124
1125         if(self.killindicator)
1126         {
1127                 dprint("Cleaned up after a leaked kill indicator.\n");
1128                 remove(self.killindicator);
1129                 self.killindicator = world;
1130         }
1131 }
1132 void KillIndicator_Think()
1133 {
1134         if (!self.owner.modelindex)
1135         {
1136                 self.owner.killindicator = world;
1137                 remove(self);
1138                 return;
1139         }
1140
1141         if(self.cnt <= 0)
1142         {
1143                 self = self.owner;
1144                 ClientKill_Now(); // no oldself needed
1145                 return;
1146         }
1147         else
1148         {
1149                 if(self.cnt <= 10)
1150                         setmodel(self, strcat("models/sprites/", ftos(self.cnt), ".spr32"));
1151                 if(clienttype(self.owner) == CLIENTTYPE_REAL)
1152                 {
1153                         if(self.cnt <= 10)
1154                                 announce(self.owner, strcat("announcer/robotic/", ftos(self.cnt), ".wav"));
1155                         if(self.owner.killindicator_teamchange)
1156                         {
1157                                 if(self.owner.killindicator_teamchange == -1)
1158                                         centerprint(self.owner, strcat("Changing team in ", ftos(self.cnt), " seconds"));
1159                                 else
1160                                         centerprint(self.owner, strcat("Changing to ", ColoredTeamName(self.owner.killindicator_teamchange), " in ", ftos(self.cnt), " seconds"));
1161                         }
1162                         else
1163                                 centerprint(self.owner, strcat("^1Suicide in ", ftos(self.cnt), " seconds"));
1164                 }
1165                 self.nextthink = time + 1;
1166                 self.cnt -= 1;
1167         }
1168 }
1169
1170 void ClientKill_TeamChange (float targetteam) // 0 = don't change, -1 = auto
1171 {
1172         float killtime;
1173         entity e;
1174         killtime = cvar("g_balance_kill_delay");
1175
1176         if(g_race_qualifying)
1177                 killtime = 0;
1178
1179         self.killindicator_teamchange = targetteam;
1180
1181         if(!self.killindicator)
1182         {
1183                 if(killtime <= 0 || !self.modelindex || self.deadflag != DEAD_NO)
1184                 {
1185                         ClientKill_Now();
1186                 }
1187                 else
1188                 {
1189                         self.killindicator = spawn();
1190                         self.killindicator.owner = self;
1191                         self.killindicator.scale = 0.5;
1192                         setattachment(self.killindicator, self, "");
1193                         setorigin(self.killindicator, '0 0 52');
1194                         self.killindicator.think = KillIndicator_Think;
1195                         self.killindicator.nextthink = time + (self.lip) * 0.05;
1196                         self.killindicator.cnt = ceil(killtime);
1197                         self.killindicator.count = bound(0, ceil(killtime), 10);
1198                         sprint(self, strcat("^1You'll be dead in ", ftos(self.killindicator.cnt), " seconds\n"));
1199
1200                         for(e = world; (e = find(e, classname, "body")) != world; )
1201                         {
1202                                 if(e.enemy != self)
1203                                         continue;
1204                                 e.killindicator = spawn();
1205                                 e.killindicator.owner = e;
1206                                 e.killindicator.scale = 0.5;
1207                                 setattachment(e.killindicator, e, "");
1208                                 setorigin(e.killindicator, '0 0 52');
1209                                 e.killindicator.think = KillIndicator_Think;
1210                                 e.killindicator.nextthink = time + (e.lip) * 0.05;
1211                                 e.killindicator.cnt = ceil(killtime);
1212                         }
1213                         self.lip = 0;
1214                 }
1215         }
1216         if(self.killindicator)
1217         {
1218                 if(targetteam)
1219                         self.killindicator.colormod = TeamColor(targetteam);
1220                 else
1221                         self.killindicator.colormod = '0 0 0';
1222         }
1223 }
1224
1225 void ClientKill (void)
1226 {
1227         ClientKill_TeamChange(0);
1228 }
1229
1230 void DoTeamChange(float destteam)
1231 {
1232         float t, c0;
1233         if(!teams_matter)
1234         {
1235                 if(destteam >= 0)
1236                         SetPlayerColors(self, destteam);
1237                 return;
1238         }
1239         if(self.classname == "player")
1240         if(destteam == -1)
1241         {
1242                 CheckAllowedTeams(self);
1243                 t = FindSmallestTeam(self, TRUE);
1244                 switch(self.team)
1245                 {
1246                         case COLOR_TEAM1: c0 = c1; break;
1247                         case COLOR_TEAM2: c0 = c2; break;
1248                         case COLOR_TEAM3: c0 = c3; break;
1249                         case COLOR_TEAM4: c0 = c4; break;
1250                         default:          c0 = 999;
1251                 }
1252                 switch(t)
1253                 {
1254                         case 1:
1255                                 if(c0 > c1)
1256                                         destteam = COLOR_TEAM1;
1257                                 break;
1258                         case 2:
1259                                 if(c0 > c2)
1260                                         destteam = COLOR_TEAM2;
1261                                 break;
1262                         case 3:
1263                                 if(c0 > c3)
1264                                         destteam = COLOR_TEAM3;
1265                                 break;
1266                         case 4:
1267                                 if(c0 > c4)
1268                                         destteam = COLOR_TEAM4;
1269                                 break;
1270                 }
1271                 if(destteam == -1)
1272                         return;
1273         }
1274         if(destteam == self.team && destteam >= 0 && !self.killindicator)
1275                 return;
1276         ClientKill_TeamChange(destteam);
1277 }
1278
1279 void FixClientCvars(entity e)
1280 {
1281         // send prediction settings to the client
1282         stuffcmd(e, "\nin_bindmap 0 0\n");
1283         if(g_race || g_cts)
1284                 stuffcmd(e, "cl_cmd settemp cl_movecliptokeyboard 2\n");
1285         /*
1286          * we no longer need to stuff this. Remove this comment block if you feel
1287          * 2.3 and higher (or was it 2.2.3?) don't need these any more
1288         stuffcmd(e, strcat("cl_gravity ", ftos(cvar("sv_gravity")), "\n"));
1289         stuffcmd(e, strcat("cl_movement_accelerate ", ftos(cvar("sv_accelerate")), "\n"));
1290         stuffcmd(e, strcat("cl_movement_friction ", ftos(cvar("sv_friction")), "\n"));
1291         stuffcmd(e, strcat("cl_movement_maxspeed ", ftos(cvar("sv_maxspeed")), "\n"));
1292         stuffcmd(e, strcat("cl_movement_airaccelerate ", ftos(cvar("sv_airaccelerate")), "\n"));
1293         stuffcmd(e, strcat("cl_movement_maxairspeed ", ftos(cvar("sv_maxairspeed")), "\n"));
1294         stuffcmd(e, strcat("cl_movement_stopspeed ", ftos(cvar("sv_stopspeed")), "\n"));
1295         stuffcmd(e, strcat("cl_movement_jumpvelocity ", ftos(cvar("sv_jumpvelocity")), "\n"));
1296         stuffcmd(e, strcat("cl_movement_stepheight ", ftos(cvar("sv_stepheight")), "\n"));
1297         stuffcmd(e, strcat("set cl_movement_friction_on_land ", ftos(cvar("sv_friction_on_land")), "\n"));
1298         stuffcmd(e, strcat("set cl_movement_airaccel_qw ", ftos(cvar("sv_airaccel_qw")), "\n"));
1299         stuffcmd(e, strcat("set cl_movement_airaccel_sideways_friction ", ftos(cvar("sv_airaccel_sideways_friction")), "\n"));
1300         stuffcmd(e, "cl_movement_edgefriction 1\n");
1301          */
1302 }
1303
1304 /*
1305 =============
1306 ClientConnect
1307
1308 Called when a client connects to the server
1309 =============
1310 */
1311 //void ctf_clientconnect();
1312 string ColoredTeamName(float t);
1313 void DecodeLevelParms (void);
1314 //void dom_player_join_team(entity pl);
1315 #ifdef UID
1316 .float uid_kicktime;
1317 .string uid;
1318 #endif
1319 void ClientConnect (void)
1320 {
1321         float t;
1322
1323         if(self.flags & FL_CLIENT)
1324         {
1325                 print("Warning: ClientConnect, but already connected!\n");
1326                 return;
1327         }
1328
1329         if(Ban_MaybeEnforceBan(self))
1330                 return;
1331
1332         DecodeLevelParms();
1333
1334         self.classname = "player_joining";
1335
1336         self.flags = FL_CLIENT;
1337         self.version_nagtime = time + 10 + random() * 10;
1338
1339         if(player_count<0)
1340         {
1341                 dprint("BUG player count is lower than zero, this cannot happen!\n");
1342                 player_count = 0;
1343         }
1344
1345         PlayerScore_Attach(self);
1346         ClientData_Attach();
1347
1348         bot_clientconnect();
1349
1350         playerdemo_init();
1351
1352         anticheat_init();
1353
1354         race_PreSpawnObserver();
1355
1356         //if(g_domination)
1357         //      dom_player_join_team(self);
1358
1359         JoinBestTeam(self, FALSE, FALSE); // if the team number is valid, keep it
1360
1361         if((cvar("sv_spectate") == 1 && !g_lms) || cvar("g_campaign")) {
1362                 self.classname = "observer";
1363         } else {
1364                 if(teams_matter)
1365                 {
1366                         if(cvar("g_balance_teams") || cvar("g_balance_teams_force"))
1367                         {
1368                                 self.classname = "player";
1369                                 campaign_bots_may_start = 1;
1370                         }
1371                         else
1372                         {
1373                                 self.classname = "observer"; // do it anyway
1374                         }
1375                 }
1376                 else
1377                 {
1378                         self.classname = "player";
1379                         campaign_bots_may_start = 1;
1380                 }
1381         }
1382
1383         self.playerid = (playerid_last = playerid_last + 1);
1384
1385         if(cvar("sv_eventlog"))
1386                 GameLogEcho(strcat(":join:", ftos(self.playerid), ":", ftos(num_for_edict(self)), ":", ((clienttype(self) == CLIENTTYPE_REAL) ? self.netaddress : "bot"), ":", self.netname));
1387
1388         LogTeamchange(self.playerid, self.team, 1);
1389
1390         self.just_joined = TRUE;  // stop spamming the eventlog with additional lines when the client connects
1391
1392         self.netname_previous = strzone(self.netname);
1393
1394         bprint("^4", self.netname, "^4 connected");
1395
1396         if(self.classname != "observer" && (g_domination || g_ctf))
1397                 bprint(" and joined the ", ColoredTeamName(self.team));
1398
1399         bprint("\n");
1400
1401         self.welcomemessage_time = 0;
1402
1403         stuffcmd(self, strcat(clientstuff, "\n"));
1404         stuffcmd(self, strcat("exec maps/", mapname, ".cfg\n"));
1405         stuffcmd(self, "cl_particles_reloadeffects\n");
1406
1407         FixClientCvars(self);
1408
1409         // spawnfunc_waypoint sprites
1410         WaypointSprite_InitClient(self);
1411
1412         // Wazat's grappling hook
1413         SetGrappleHookBindings();
1414
1415         // get autoswitch state from player when he toggles it
1416         stuffcmd(self, "alias autoswitch \"set cl_autoswitch $1 ; cmd autoswitch $1\"\n"); // default.cfg-ed in 2.4.1
1417
1418         // get version info from player
1419         stuffcmd(self, "cmd clientversion $gameversion\n");
1420
1421         // get other cvars from player
1422         GetCvars(0);
1423
1424         // set cvar for team scoreboard
1425         stuffcmd(self, strcat("set teamplay ", ftos(teamplay), "\n"));
1426
1427         // notify about available teams
1428         if(teams_matter)
1429         {
1430                 CheckAllowedTeams(self);
1431                 t = 0; if(c1 >= 0) t |= 1; if(c2 >= 0) t |= 2; if(c3 >= 0) t |= 4; if(c4 >= 0) t |= 8;
1432                 stuffcmd(self, strcat("set _teams_available ", ftos(t), "\n"));
1433         }
1434         else
1435                 stuffcmd(self, "set _teams_available 0\n");
1436
1437         stuffcmd(self, strcat("set gametype ", ftos(game), "\n"));
1438
1439         if(g_arena || g_ca)
1440         {
1441                 self.classname = "observer";
1442                 if(g_arena)
1443                         Spawnqueue_Insert(self);
1444         }
1445         /*else if(g_ctf)
1446         {
1447                 ctf_clientconnect();
1448         }*/
1449
1450         if(teams_matter || radar_showennemies)
1451                 attach_entcs();
1452
1453         bot_relinkplayerlist();
1454
1455         self.spectatortime = time;
1456         if(blockSpectators)
1457         {
1458                 sprint(self, strcat("^7You have to become a player within the next ", ftos(cvar("g_maxplayers_spectator_blocktime")), " seconds, otherwise you will be kicked, because spectators aren't allowed at this time!\n"));
1459         }
1460
1461         self.jointime = time;
1462         self.allowedTimeouts = cvar("sv_timeout_number");
1463
1464         if(clienttype(self) == CLIENTTYPE_REAL)
1465         {
1466                 if(cvar("g_bugrigs") || g_weaponarena == WEPBIT_TUBA)
1467                         stuffcmd(self, "cl_cmd settemp chase_active 1\n");
1468         }
1469
1470         if(g_lms)
1471         {
1472                 if(PlayerScore_Add(self, SP_LMS_LIVES, LMS_NewPlayerLives()) <= 0)
1473                 {
1474                         PlayerScore_Add(self, SP_LMS_RANK, 666);
1475                         self.frags = FRAGS_SPECTATOR;
1476                 }
1477         }
1478
1479         if(!sv_foginterval && world.fog != "")
1480                 stuffcmd(self, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1481
1482         SoundEntity_Attach(self);
1483
1484         if(cvar("g_hitplots") || strstrofs(strcat(" ", cvar_string("g_hitplots_individuals"), " "), strcat(" ", self.netaddress, " "), 0) >= 0)
1485         {
1486                 self.hitplotfh = fopen(strcat("hits-", matchid, "-", self.netaddress, "-", ftos(self.playerid), ".plot"), FILE_WRITE);
1487                 fputs(self.hitplotfh, strcat("#name ", self.netname, "\n"));
1488         }
1489         else
1490                 self.hitplotfh = -1;
1491
1492 #ifdef UID
1493         if(clienttype(self) == CLIENTTYPE_REAL)
1494         if not(self.uid)
1495                 self.uid_kicktime = time + 60;
1496 #endif
1497
1498         if(g_race || g_cts) {
1499                 string rr;
1500                 if(g_cts)
1501                         rr = CTS_RECORD;
1502                 else
1503                         rr = RACE_RECORD;
1504                 t = stof(db_get(ServerProgsDB, strcat(GetMapname(), rr, "time")));
1505
1506                 race_send_recordtime(MSG_ONE);
1507                 race_send_speedaward(MSG_ONE);
1508
1509                 speedaward_alltimebest = stof(db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/speed")));
1510                 speedaward_alltimebest_holder = db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/netname"));
1511                 race_send_speedaward_alltimebest(MSG_ONE);
1512
1513                 float i;
1514                 for (i = 1; i <= RANKINGS_CNT; ++i) {
1515                         race_SendRankings(i, 0, 0, MSG_ONE);
1516                 }
1517         }
1518         else if(cvar("sv_teamnagger") && !g_ca) // teamnagger is currently bad for ca
1519                 send_CSQC_teamnagger();
1520
1521         CheatInitClient();
1522 }
1523
1524 /*
1525 =============
1526 ClientDisconnect
1527
1528 Called when a client disconnects from the server
1529 =============
1530 */
1531 .entity chatbubbleentity;
1532 .entity teambubbleentity;
1533 void ReadyCount();
1534 void ClientDisconnect (void)
1535 {
1536         if not(self.flags & FL_CLIENT)
1537         {
1538                 print("Warning: ClientDisconnect without ClientConnect\n");
1539                 return;
1540         }
1541
1542         CheatShutdownClient();
1543
1544         if(self.hitplotfh >= 0)
1545         {
1546                 fclose(self.hitplotfh);
1547                 self.hitplotfh = -1;
1548         }
1549
1550         anticheat_report();
1551         anticheat_shutdown();
1552
1553         playerdemo_shutdown();
1554
1555         bot_clientdisconnect();
1556
1557         if(self.entcs)
1558                 detach_entcs();
1559
1560         if(cvar("sv_eventlog"))
1561                 GameLogEcho(strcat(":part:", ftos(self.playerid)));
1562         bprint ("^4",self.netname);
1563         bprint ("^4 disconnected\n");
1564
1565         SoundEntity_Detach(self);
1566
1567         DropAllRunes(self);
1568         kh_Key_DropAll(self, TRUE);
1569
1570         Portal_ClearAll(self);
1571
1572         if(self.flagcarried)
1573                 DropFlag(self.flagcarried, world, world);
1574         if(self.ballcarried)
1575                 DropBall(self.ballcarried, self.origin + self.ballcarried.origin, self.velocity);
1576
1577         // Here, everything has been done that requires this player to be a client.
1578
1579         self.flags &~= FL_CLIENT;
1580
1581         if (self.chatbubbleentity)
1582                 remove (self.chatbubbleentity);
1583
1584         if (self.teambubbleentity)
1585                 remove (self.teambubbleentity);
1586
1587         if (self.killindicator)
1588                 remove (self.killindicator);
1589
1590         WaypointSprite_PlayerGone();
1591
1592         bot_relinkplayerlist();
1593
1594         // remove laserdot
1595         if(self.weaponentity)
1596                 if(self.weaponentity.lasertarget)
1597                         remove(self.weaponentity.lasertarget);
1598
1599         if(g_arena)
1600         {
1601                 Spawnqueue_Unmark(self);
1602                 Spawnqueue_Remove(self);
1603         }
1604
1605         ClientData_Detach();
1606         PlayerScore_Detach(self);
1607
1608         if(self.netname_previous)
1609                 strunzone(self.netname_previous);
1610         if(self.clientstatus)
1611                 strunzone(self.clientstatus);
1612
1613         ClearPlayerSounds();
1614
1615         if(self.personal)
1616                 remove(self.personal);
1617
1618         self.playerid = 0;
1619         ReadyCount();
1620
1621         // free cvars
1622         GetCvars(-1);
1623 }
1624
1625 .float BUTTON_CHAT;
1626 void ChatBubbleThink()
1627 {
1628         self.nextthink = time;
1629         if (!self.owner.modelindex || self.owner.chatbubbleentity != self)
1630         {
1631                 if(self.owner) // but why can that ever be world?
1632                         self.owner.chatbubbleentity = world;
1633                 remove(self);
1634                 return;
1635         }
1636         if ((self.owner.BUTTON_CHAT && !self.owner.deadflag)
1637 #ifdef TETRIS
1638                 || self.owner.tetris_on
1639 #endif
1640         )
1641                 self.model = self.mdl;
1642         else
1643                 self.model = "";
1644 };
1645
1646 void UpdateChatBubble()
1647 {
1648         if (!self.modelindex)
1649                 return;
1650         // spawn a chatbubble entity if needed
1651         if (!self.chatbubbleentity)
1652         {
1653                 self.chatbubbleentity = spawn();
1654                 self.chatbubbleentity.owner = self;
1655                 self.chatbubbleentity.exteriormodeltoclient = self;
1656                 self.chatbubbleentity.think = ChatBubbleThink;
1657                 self.chatbubbleentity.nextthink = time;
1658                 setmodel(self.chatbubbleentity, "models/misc/chatbubble.spr"); // precision set below
1659                 //setorigin(self.chatbubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1660                 setorigin(self.chatbubbleentity, '0 0 15' + self.maxs_z * '0 0 1');
1661                 setattachment(self.chatbubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1662                 self.chatbubbleentity.mdl = self.chatbubbleentity.model;
1663                 self.chatbubbleentity.model = "";
1664                 self.chatbubbleentity.effects = EF_LOWPRECISION;
1665         }
1666 }
1667
1668
1669 void TeamBubbleThink()
1670 {
1671         self.nextthink = time;
1672         if (!self.owner.modelindex || self.owner.teambubbleentity != self)
1673         {
1674                 if(self.owner) // but why can that ever be world?
1675                         self.owner.teambubbleentity = world;
1676                 remove(self);
1677                 return;
1678         }
1679 //      setorigin(self, self.owner.origin + '0 0 15' + self.owner.maxs_z * '0 0 1');  // bandwidth hog. setattachment does this now
1680         if (self.owner.BUTTON_CHAT || self.owner.deadflag || self.owner.killindicator)
1681                 self.model = "";
1682         else
1683                 self.model = self.mdl;
1684
1685 };
1686
1687 float TeamBubble_customizeentityforclient()
1688 {
1689         return (self.owner != other && self.owner.team == other.team && other.killcount > -666);
1690 }
1691
1692 void UpdateTeamBubble()
1693 {
1694         if (!self.modelindex || !teams_matter)
1695                 return;
1696         // spawn a teambubble entity if needed
1697         if (!self.teambubbleentity && teams_matter)
1698         {
1699                 self.teambubbleentity = spawn();
1700                 self.teambubbleentity.owner = self;
1701                 self.teambubbleentity.exteriormodeltoclient = self;
1702                 self.teambubbleentity.think = TeamBubbleThink;
1703                 self.teambubbleentity.nextthink = time;
1704                 setmodel(self.teambubbleentity, "models/misc/teambubble.spr"); // precision set below
1705 //              setorigin(self.teambubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1706                 setorigin(self.teambubbleentity, '0 0 15' + self.maxs_z * '0 0 1');
1707                 setattachment(self.teambubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1708                 self.teambubbleentity.mdl = self.teambubbleentity.model;
1709                 self.teambubbleentity.model = self.teambubbleentity.mdl;
1710                 self.teambubbleentity.customizeentityforclient = TeamBubble_customizeentityforclient;
1711                 self.teambubbleentity.effects = EF_LOWPRECISION;
1712         }
1713 }
1714
1715 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1716 // added to the model skins
1717 /*void UpdateColorModHack()
1718 {
1719         local float c;
1720         c = self.clientcolors & 15;
1721         // LordHavoc: only bothering to support white, green, red, yellow, blue
1722              if (!teams_matter) self.colormod = '0 0 0';
1723         else if (c ==  0) self.colormod = '1.00 1.00 1.00';
1724         else if (c ==  3) self.colormod = '0.10 1.73 0.10';
1725         else if (c ==  4) self.colormod = '1.73 0.10 0.10';
1726         else if (c == 12) self.colormod = '1.22 1.22 0.10';
1727         else if (c == 13) self.colormod = '0.10 0.10 1.73';
1728         else self.colormod = '1 1 1';
1729 };*/
1730
1731 void respawn(void)
1732 {
1733         CopyBody(1);
1734         self.effects |= EF_NODRAW; // prevent another CopyBody
1735         PutClientInServer();
1736 }
1737
1738 void play_countdown(float finished, string samp)
1739 {
1740         if(clienttype(self) == CLIENTTYPE_REAL)
1741                 if(floor(finished - time - frametime) != floor(finished - time))
1742                         if(finished - time < 6)
1743                                 sound (self, CHAN_AUTO, samp, VOL_BASE, ATTN_NORM);
1744 }
1745
1746 /**
1747  * When sv_timeout is used this function returs strings like
1748  * "Timeout begins in 2 seconds!\n" or "Timeout ends in 23 seconds!\n".
1749  * Called by centerprint functions
1750  * @param addOneSecond boolean, set to 1 if the welcome-message centerprint asks for the text
1751  */
1752 string getTimeoutText(float addOneSecond) {
1753         if (!cvar("sv_timeout") || !timeoutStatus)
1754                 return "";
1755
1756         local string retStr;
1757         if (timeoutStatus == 1) {
1758                 if (addOneSecond == 1) {
1759                         retStr = strcat("Timeout begins in ", ftos(remainingLeadTime + 1), " seconds!\n");
1760                 }
1761                 else {
1762                         retStr = strcat("Timeout begins in ", ftos(remainingLeadTime), " seconds!\n");
1763                 }
1764                 return retStr;
1765         }
1766         else if (timeoutStatus == 2) {
1767                 if (addOneSecond) {
1768                         retStr = strcat("Timeout ends in ", ftos(remainingTimeoutTime + 1), " seconds!\n");
1769                         //don't show messages like "Timeout ends in 0 seconds"...
1770                         if ((remainingTimeoutTime + 1) > 0)
1771                                 return retStr;
1772                         else
1773                                 return "";
1774                 }
1775                 else {
1776                         retStr = strcat("Timeout ends in ", ftos(remainingTimeoutTime), " seconds!\n");
1777                         //don't show messages like "Timeout ends in 0 seconds"...
1778                         if (remainingTimeoutTime > 0)
1779                                 return retStr;
1780                         else
1781                                 return "";
1782                 }
1783         }
1784         else return "";
1785 }
1786
1787 void player_powerups (void)
1788 {
1789         if((self.items & IT_USING_JETPACK) && !self.deadflag)
1790         {
1791                 SoundEntity_StartSound(self, CHAN_PLAYER, "misc/jetpack_fly.wav", VOL_BASE, cvar("g_jetpack_attenuation"));
1792                 self.modelflags |= MF_ROCKET;
1793         }
1794         else
1795         {
1796                 SoundEntity_StopSound(self, CHAN_PLAYER);
1797                 self.modelflags &~= MF_ROCKET;
1798         }
1799
1800         self.effects &~= (EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
1801
1802         if(!self.modelindex || self.deadflag) // don't apply the flags if the player is gibbed
1803                 return;
1804
1805         Fire_ApplyDamage(self);
1806         Fire_ApplyEffect(self);
1807
1808         if (g_minstagib)
1809         {
1810                 self.effects |= EF_FULLBRIGHT;
1811
1812                 if (self.items & IT_STRENGTH)
1813                 {
1814                         play_countdown(self.strength_finished, "misc/poweroff.wav");
1815                         if (time > self.strength_finished)
1816                         {
1817                                 self.alpha = default_player_alpha;
1818                                 self.exteriorweaponentity.alpha = default_weapon_alpha;
1819                                 self.items &~= IT_STRENGTH;
1820                                 sprint(self, "^3Invisibility has worn off\n");
1821                         }
1822                 }
1823                 else
1824                 {
1825                         if (time < self.strength_finished)
1826                         {
1827                                 self.alpha = g_minstagib_invis_alpha;
1828                                 self.exteriorweaponentity.alpha = g_minstagib_invis_alpha;
1829                                 self.items |= IT_STRENGTH;
1830                                 sprint(self, "^3You are invisible\n");
1831                         }
1832                 }
1833
1834                 if (self.items & IT_INVINCIBLE)
1835                 {
1836                         play_countdown(self.invincible_finished, "misc/poweroff.wav");
1837                         if (time > self.invincible_finished && cvar("g_balance_powerup_timer"))
1838                         {
1839                                 self.items = self.items - (self.items & IT_INVINCIBLE);
1840                                 sprint(self, "^3Speed has worn off\n");
1841                         }
1842                 }
1843                 else
1844                 {
1845                         if (time < self.invincible_finished)
1846                         {
1847                                 self.items = self.items | IT_INVINCIBLE;
1848                                 sprint(self, "^3You are on speed\n");
1849                         }
1850                 }
1851                 return;
1852         }
1853
1854         if (self.items & IT_STRENGTH)
1855         {
1856                 play_countdown(self.strength_finished, "misc/poweroff.wav");
1857                 self.effects = self.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1858                 if (time > self.strength_finished && cvar("g_balance_powerup_timer"))
1859                 {
1860                         self.items = self.items - (self.items & IT_STRENGTH);
1861                         sprint(self, "^3Strength has worn off\n");
1862                 }
1863         }
1864         else
1865         {
1866                 if (time < self.strength_finished)
1867                 {
1868                         self.items = self.items | IT_STRENGTH;
1869                         sprint(self, "^3Strength infuses your weapons with devastating power\n");
1870                 }
1871         }
1872         if (self.items & IT_INVINCIBLE)
1873         {
1874                 play_countdown(self.invincible_finished, "misc/poweroff.wav");
1875                 self.effects = self.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1876                 if (time > self.invincible_finished && cvar("g_balance_powerup_timer"))
1877                 {
1878                         self.items = self.items - (self.items & IT_INVINCIBLE);
1879                         sprint(self, "^3Shield has worn off\n");
1880                 }
1881         }
1882         else
1883         {
1884                 if (time < self.invincible_finished)
1885                 {
1886                         self.items = self.items | IT_INVINCIBLE;
1887                         sprint(self, "^3Shield surrounds you\n");
1888                 }
1889         }
1890
1891         if(cvar("g_nodepthtestplayers"))
1892                 self.effects = self.effects | EF_NODEPTHTEST;
1893
1894         if(cvar("g_fullbrightplayers"))
1895                 self.effects = self.effects | EF_FULLBRIGHT;
1896
1897         // midair gamemode: damage only while in the air
1898         // if in midair mode, being on ground grants temporary invulnerability
1899         // (this is so that multishot weapon don't clear the ground flag on the
1900         // first damage in the frame, leaving the player vulnerable to the
1901         // remaining hits in the same frame)
1902         if (self.flags & FL_ONGROUND)
1903         if (g_midair)
1904                 self.spawnshieldtime = max(self.spawnshieldtime, time + cvar("g_midair_shieldtime"));
1905
1906         if (time >= game_starttime)
1907         if (time < self.spawnshieldtime)
1908                 self.effects = self.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1909 }
1910
1911 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
1912 {
1913         if(current > stable)
1914                 return current;
1915         else if(current > stable - 0.25) // when close enough, "snap"
1916                 return stable;
1917         else
1918                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
1919 }
1920
1921 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
1922 {
1923         if(current < stable)
1924                 return current;
1925         else if(current < stable + 0.25) // when close enough, "snap"
1926                 return stable;
1927         else
1928                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
1929 }
1930
1931 float CalcRotRegen(float current, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit)
1932 {
1933         if(current > rotstable)
1934         {
1935                 if(rotframetime > 0)
1936                 {
1937                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
1938                         current = max(rotstable, current - rotlinear * rotframetime);
1939                 }
1940         }
1941         else if(current < regenstable)
1942         {
1943                 if(regenframetime > 0)
1944                 {
1945                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
1946                         current = min(regenstable, current + regenlinear * regenframetime);
1947                 }
1948         }
1949
1950         if(current > limit)
1951                 current = limit;
1952
1953         return current;
1954 }
1955
1956 void player_regen (void)
1957 {
1958         float minh, mina, minf, maxh, maxa, maxf, limith, limita, limitf, max_mod, regen_mod, rot_mod, limit_mod;
1959         maxh = cvar("g_balance_health_rotstable");
1960         maxa = cvar("g_balance_armor_rotstable");
1961         maxf = cvar("g_balance_fuel_rotstable");
1962         minh = cvar("g_balance_health_regenstable");
1963         mina = cvar("g_balance_armor_regenstable");
1964         minf = cvar("g_balance_fuel_regenstable");
1965         limith = cvar("g_balance_health_limit");
1966         limita = cvar("g_balance_armor_limit");
1967         limitf = cvar("g_balance_fuel_limit");
1968
1969         max_mod = regen_mod = rot_mod = limit_mod = 1;
1970
1971         if (self.runes & RUNE_REGEN)
1972         {
1973                 if (self.runes & CURSE_VENOM) // do we have both rune/curse?
1974                 {
1975                         regen_mod = cvar("g_balance_rune_regen_combo_regenrate");
1976                         max_mod = cvar("g_balance_rune_regen_combo_hpmod");
1977                         limit_mod = cvar("g_balance_rune_regen_combo_limitmod");
1978                 }
1979                 else
1980                 {
1981                         regen_mod = cvar("g_balance_rune_regen_regenrate");
1982                         max_mod = cvar("g_balance_rune_regen_hpmod");
1983                         limit_mod = cvar("g_balance_rune_regen_limitmod");
1984                 }
1985         }
1986         else if (self.runes & CURSE_VENOM)
1987         {
1988                 max_mod = cvar("g_balance_curse_venom_hpmod");
1989                 if (self.runes & RUNE_REGEN) // do we have both rune/curse?
1990                         rot_mod = cvar("g_balance_rune_regen_combo_rotrate");
1991                 else
1992                         rot_mod = cvar("g_balance_curse_venom_rotrate");
1993                 limit_mod = cvar("g_balance_curse_venom_limitmod");
1994                 //if (!self.runes & RUNE_REGEN)
1995                 //      rot_mod = cvar("g_balance_curse_venom_rotrate");
1996         }
1997         maxh = maxh * max_mod;
1998         //maxa = maxa * max_mod;
1999         //maxf = maxf * max_mod;
2000         minh = minh * max_mod;
2001         //mina = mina * max_mod;
2002         //minf = minf * max_mod;
2003         limith = limith * limit_mod;
2004         limita = limita * limit_mod;
2005         //limitf = limitf * limit_mod;
2006
2007         if(g_lms && g_ca)
2008                 rot_mod = 0;
2009
2010         if (!g_minstagib && !g_ca && (!g_lms || cvar("g_lms_regenerate")))
2011         {
2012                 self.armorvalue = CalcRotRegen(self.armorvalue, mina, cvar("g_balance_armor_regen"), cvar("g_balance_armor_regenlinear"), regen_mod * frametime * (time > self.pauseregen_finished), maxa, cvar("g_balance_armor_rot"), cvar("g_balance_armor_rotlinear"), rot_mod * frametime * (time > self.pauserotarmor_finished), limita);
2013                 self.health = CalcRotRegen(self.health, minh, cvar("g_balance_health_regen"), cvar("g_balance_health_regenlinear"), regen_mod * frametime * (time > self.pauseregen_finished), maxh, cvar("g_balance_health_rot"), cvar("g_balance_health_rotlinear"), rot_mod * frametime * (time > self.pauserothealth_finished), limith);
2014
2015                 // if player rotted to death...  die!
2016                 if(self.health < 1)
2017                         self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
2018         }
2019
2020         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
2021                 self.ammo_fuel = CalcRotRegen(self.ammo_fuel, minf, cvar("g_balance_fuel_regen"), cvar("g_balance_fuel_regenlinear"), regen_mod * frametime * (time > self.pauseregen_finished) * (self.items & IT_FUEL_REGEN != 0), maxf, cvar("g_balance_fuel_rot"), cvar("g_balance_fuel_rotlinear"), rot_mod * frametime * (time > self.pauserotfuel_finished), limitf);
2022 }
2023
2024 float zoomstate_set;
2025 void SetZoomState(float z)
2026 {
2027         if(z != self.zoomstate)
2028         {
2029                 self.zoomstate = z;
2030                 ClientData_Touch(self);
2031         }
2032         zoomstate_set = 1;
2033 }
2034
2035 void GetPressedKeys(void) {
2036         if (self.movement_x > 0) // get if movement keys are pressed
2037         {       // forward key pressed
2038                 self.pressedkeys |= KEY_FORWARD;
2039                 self.pressedkeys &~= KEY_BACKWARD;
2040         }
2041         else if (self.movement_x < 0)
2042         {       // backward key pressed
2043                 self.pressedkeys |= KEY_BACKWARD;
2044                 self.pressedkeys &~= KEY_FORWARD;
2045         }
2046         else
2047         {       // no x input
2048                 self.pressedkeys &~= KEY_FORWARD;
2049                 self.pressedkeys &~= KEY_BACKWARD;
2050         }
2051
2052         if (self.movement_y > 0)
2053         {       // right key pressed
2054                 self.pressedkeys |= KEY_RIGHT;
2055                 self.pressedkeys &~= KEY_LEFT;
2056         }
2057         else if (self.movement_y < 0)
2058         {       // left key pressed
2059                 self.pressedkeys |= KEY_LEFT;
2060                 self.pressedkeys &~= KEY_RIGHT;
2061         }
2062         else
2063         {       // no y input
2064                 self.pressedkeys &~= KEY_RIGHT;
2065                 self.pressedkeys &~= KEY_LEFT;
2066         }
2067
2068         if (self.BUTTON_JUMP) // get if jump and crouch keys are pressed
2069                 self.pressedkeys |= KEY_JUMP;
2070         else
2071                 self.pressedkeys &~= KEY_JUMP;
2072         if (self.BUTTON_CROUCH)
2073                 self.pressedkeys |= KEY_CROUCH;
2074         else
2075                 self.pressedkeys &~= KEY_CROUCH;
2076 }
2077
2078 void update_stats (float number, float hit, float fired) {
2079 // self.stat_hit   = number + ((number==0) ? 1 : 64) * hit   * sv_accuracy_data_share;
2080 // self.stat_fired = number + ((number==0) ? 1 : 64) * fired * sv_accuracy_data_share;
2081
2082         if(number) {
2083                 self.stat_hit = number + 64 * hit * sv_accuracy_data_share;
2084                 self.stat_fired = number + 64 * fired * sv_accuracy_data_share;
2085         } else {
2086                 self.stat_hit = hit * sv_accuracy_data_share;
2087                 self.stat_fired = fired * sv_accuracy_data_share;
2088         }
2089 }
2090
2091 /*
2092 ======================
2093 spectate mode routines
2094 ======================
2095 */
2096
2097 .float weapon_count;
2098 void SpectateCopy(entity spectatee) {
2099         if(spectatee.weapon_count < WEP_LAST) {
2100                 update_stats (spectatee.weapon_count, spectatee.cvar_cl_accuracy_data_share * floor(spectatee.stats_hit[spectatee.weapon_count - 1]), spectatee.cvar_cl_accuracy_data_share * floor(spectatee.stats_fired[spectatee.weapon_count - 1]));
2101                 spectatee.weapon_count ++;
2102         } else
2103                 update_stats (0, spectatee.cvar_cl_accuracy_data_share * spectatee.stat_hit, spectatee.cvar_cl_accuracy_data_share * spectatee.stat_fired);
2104
2105         self.kh_state = spectatee.kh_state;
2106         self.armortype = spectatee.armortype;
2107         self.armorvalue = spectatee.armorvalue;
2108         self.ammo_cells = spectatee.ammo_cells;
2109         self.ammo_shells = spectatee.ammo_shells;
2110         self.ammo_nails = spectatee.ammo_nails;
2111         self.ammo_rockets = spectatee.ammo_rockets;
2112         self.ammo_fuel = spectatee.ammo_fuel;
2113         self.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
2114         self.health = spectatee.health;
2115         self.impulse = 0;
2116         self.items = spectatee.items;
2117         self.metertime = spectatee.metertime;
2118         self.strength_finished = spectatee.strength_finished;
2119         self.invincible_finished = spectatee.invincible_finished;
2120         self.pressedkeys = spectatee.pressedkeys;
2121         self.weapons = spectatee.weapons;
2122         self.switchweapon = spectatee.switchweapon;
2123         self.weapon = spectatee.weapon;
2124         self.punchangle = spectatee.punchangle;
2125         self.view_ofs = spectatee.view_ofs;
2126         self.v_angle = spectatee.v_angle;
2127         self.velocity = spectatee.velocity;
2128         self.dmg_take = spectatee.dmg_take;
2129         self.dmg_save = spectatee.dmg_save;
2130         self.dmg_inflictor = spectatee.dmg_inflictor;
2131         self.angles = spectatee.v_angle;
2132         self.fixangle = TRUE;
2133         setorigin(self, spectatee.origin);
2134         setsize(self, spectatee.mins, spectatee.maxs);
2135         SetZoomState(spectatee.zoomstate);
2136
2137         anticheat_spectatecopy(spectatee);
2138 }
2139
2140 float SpectateUpdate() {
2141         if(!self.enemy)
2142                 return 0;
2143
2144         if (self == self.enemy)
2145                 return 0;
2146
2147         if(self.enemy.classname != "player")
2148                 return 0;
2149
2150         SpectateCopy(self.enemy);
2151
2152         return 1;
2153 }
2154
2155 float SpectateNext() {
2156         other = find(self.enemy, classname, "player");
2157
2158         if (!other)
2159                 other = find(other, classname, "player");
2160
2161         if (other)
2162                 self.enemy = other;
2163
2164         if(self.enemy.classname == "player") {
2165                 msg_entity = self;
2166                 WriteByte(MSG_ONE, SVC_SETVIEW);
2167                 WriteEntity(MSG_ONE, self.enemy);
2168                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
2169                 self.movetype = MOVETYPE_NONE;
2170
2171                 self.enemy.weapon_count = 0;
2172
2173                 if(!SpectateUpdate())
2174                         PutObserverInServer();
2175
2176                 return 1;
2177         } else {
2178                 return 0;
2179         }
2180 }
2181
2182 /*
2183 =============
2184 ShowRespawnCountdown()
2185
2186 Update a respawn countdown display.
2187 =============
2188 */
2189 void ShowRespawnCountdown()
2190 {
2191         float number;
2192         if(self.deadflag == DEAD_NO) // just respawned?
2193                 return;
2194         else
2195         {
2196                 number = ceil(self.death_time - time);
2197                 if(number <= 0)
2198                         return;
2199                 if(number <= self.respawn_countdown)
2200                 {
2201                         self.respawn_countdown = number - 1;
2202                         if(ceil(self.death_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
2203                                 announce(self, strcat("announcer/robotic/", ftos(number), ".wav"));
2204                 }
2205         }
2206 }
2207
2208 void LeaveSpectatorMode()
2209 {
2210         if(isJoinAllowed()) {
2211                 if(!teams_matter || cvar("g_campaign") || cvar("g_balance_teams") || (self.wasplayer && cvar("g_changeteam_banned"))) {
2212                         self.classname = "player";
2213
2214                         if(cvar("g_campaign") || cvar("g_balance_teams") || cvar("g_balance_teams_force"))
2215                                 JoinBestTeam(self, FALSE, TRUE);
2216
2217                         if(cvar("g_campaign"))
2218                                 campaign_bots_may_start = 1;
2219
2220                         self.stat_count = WEP_LAST;
2221
2222                         PutClientInServer();
2223
2224                         if(self.classname == "player")
2225                                 bprint ("^4", self.netname, "^4 is playing now\n");
2226
2227                         if(!cvar("g_campaign"))
2228                                 centerprint(self,""); // clear MOTD
2229
2230                         return;
2231                 } else {
2232                         if (g_ca && self.caplayer) {
2233                         }       // do nothing
2234                         else
2235                                 stuffcmd(self,"menu_showteamselect\n");
2236                         return;
2237                 }
2238         }
2239         else {
2240                 //player may not join because of g_maxplayers is set
2241                 centerprint_atprio(self, CENTERPRIO_MAPVOTE, PREVENT_JOIN_TEXT);
2242         }
2243 }
2244
2245 /**
2246  * Determines whether the player is allowed to join. This depends on cvar
2247  * g_maxplayers, if it isn't used this function always return TRUE, otherwise
2248  * it checks whether the number of currently playing players exceeds g_maxplayers.
2249  * @return bool TRUE if the player is allowed to join, false otherwise
2250  */
2251 float isJoinAllowed() {
2252         if (!cvar("g_maxplayers"))
2253                 return TRUE;
2254
2255         local entity e;
2256         local float currentlyPlaying;
2257         FOR_EACH_REALPLAYER(e) {
2258                 if(e.classname == "player")
2259                         currentlyPlaying += 1;
2260         }
2261         if(currentlyPlaying < cvar("g_maxplayers"))
2262                 return TRUE;
2263
2264         return FALSE;
2265 }
2266
2267 /**
2268  * Checks whether the client is an observer or spectator, if so, he will get kicked after
2269  * g_maxplayers_spectator_blocktime seconds
2270  */
2271 void checkSpectatorBlock() {
2272         if(self.classname == "spectator" || self.classname == "observer") {
2273                 if( time > (self.spectatortime + cvar("g_maxplayers_spectator_blocktime")) ) {
2274                         sprint(self, "^7You were kicked from the server because you are spectator and spectators aren't allowed at the moment.\n");
2275                         dropclient(self);
2276                 }
2277         }
2278 }
2279
2280 float vercmp_recursive(string v1, string v2)
2281 {
2282         float dot1, dot2;
2283         string s1, s2;
2284         float r;
2285
2286         dot1 = strstrofs(v1, ".", 0);
2287         dot2 = strstrofs(v2, ".", 0);
2288         if(dot1 == -1)
2289                 s1 = v1;
2290         else
2291                 s1 = substring(v1, 0, dot1);
2292         if(dot2 == -1)
2293                 s2 = v2;
2294         else
2295                 s2 = substring(v2, 0, dot2);
2296
2297         r = stof(s1) - stof(s2);
2298         if(r != 0)
2299                 return r;
2300
2301         r = strcasecmp(s1, s2);
2302         if(r != 0)
2303                 return r;
2304
2305         if(dot1 == -1)
2306                 if(dot2 == -1)
2307                         return 0;
2308                 else
2309                         return -1;
2310         else
2311                 if(dot2 == -1)
2312                         return 1;
2313                 else
2314                         return vercmp_recursive(substring(v1, dot1 + 1, 999), substring(v2, dot2 + 1, 999));
2315 }
2316
2317 float vercmp(string v1, string v2)
2318 {
2319         if(strcasecmp(v1, v2) == 0) // early out check
2320                 return 0;
2321         return vercmp_recursive(v1, v2);
2322 }
2323
2324 void ObserverThink()
2325 {
2326         if (self.flags & FL_JUMPRELEASED) {
2327                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2328                         self.welcomemessage_time = 0;
2329                         self.flags &~= FL_JUMPRELEASED;
2330                         self.flags |= FL_SPAWNING;
2331                 } else if(self.BUTTON_ATCK && !self.version_mismatch) {
2332                         self.welcomemessage_time = 0;
2333                         self.flags &~= FL_JUMPRELEASED;
2334                         if(SpectateNext() == 1) {
2335                                 self.classname = "spectator";
2336                         }
2337                 }
2338         } else {
2339                 if (!(self.BUTTON_ATCK || self.BUTTON_JUMP)) {
2340                         self.flags |= FL_JUMPRELEASED;
2341                         if(self.flags & FL_SPAWNING)
2342                         {
2343                                 self.flags &~= FL_SPAWNING;
2344                                 LeaveSpectatorMode();
2345                                 return;
2346                         }
2347                 }
2348         }
2349         PrintWelcomeMessage(self);
2350 }
2351
2352 void SpectatorThink()
2353 {
2354         if (self.flags & FL_JUMPRELEASED) {
2355                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2356                         self.welcomemessage_time = 0;
2357                         self.flags &~= FL_JUMPRELEASED;
2358                         self.flags |= FL_SPAWNING;
2359                 } else if(self.BUTTON_ATCK) {
2360                         self.welcomemessage_time = 0;
2361                         self.flags &~= FL_JUMPRELEASED;
2362                         if(SpectateNext() == 1) {
2363                                 self.classname = "spectator";
2364                         } else {
2365                                 self.classname = "observer";
2366                                 self.stat_count = WEP_LAST;
2367                                 PutClientInServer();
2368                         }
2369                 } else if (self.BUTTON_ATCK2) {
2370                         self.welcomemessage_time = 0;
2371                         self.flags &~= FL_JUMPRELEASED;
2372                         self.classname = "observer";
2373                         self.stat_count = WEP_LAST;
2374                         PutClientInServer();
2375                 } else {
2376                         if(!SpectateUpdate())
2377                                 PutObserverInServer();
2378                 }
2379         } else {
2380                 if (!(self.BUTTON_ATCK || self.BUTTON_ATCK2)) {
2381                         self.flags |= FL_JUMPRELEASED;
2382                         if(self.flags & FL_SPAWNING)
2383                         {
2384                                 self.flags &~= FL_SPAWNING;
2385                                 LeaveSpectatorMode();
2386                                 return;
2387                         }
2388                 }
2389         }
2390
2391         PrintWelcomeMessage(self);
2392         self.flags |= FL_CLIENT | FL_NOTARGET;
2393 }
2394
2395 .float touchexplode_time;
2396
2397 /*
2398 =============
2399 PlayerPreThink
2400
2401 Called every frame for each client before the physics are run
2402 =============
2403 */
2404 void() ctf_setstatus;
2405 void() nexball_setstatus;
2406 .float items_added;
2407 void PlayerPreThink (void)
2408 {
2409         self.stat_game_starttime = game_starttime;
2410         self.stat_allow_oldnexbeam = cvar("g_allow_oldnexbeam");
2411         self.stat_leadlimit = cvar("leadlimit");
2412
2413         if(frametime)
2414         {
2415                 // physics frames: update anticheat stuff
2416                 anticheat_prethink();
2417         }
2418
2419         if(blockSpectators && frametime)
2420                 // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2421                 checkSpectatorBlock();
2422
2423         zoomstate_set = 0;
2424
2425         if(self.netname_previous != self.netname)
2426         {
2427                 if(cvar("sv_eventlog"))
2428                         GameLogEcho(strcat(":name:", ftos(self.playerid), ":", self.netname));
2429                 if(self.netname_previous)
2430                         strunzone(self.netname_previous);
2431                 self.netname_previous = strzone(self.netname);
2432         }
2433
2434         // version nagging
2435         if(self.version_nagtime)
2436                 if(self.cvar_g_nexuizversion)
2437                         if(time > self.version_nagtime)
2438                         {
2439                                 if(strstr(self.cvar_g_nexuizversion, "svn", 0) < 0)
2440                                 {
2441                                         if(strstr(cvar_string("g_nexuizversion"), "svn", 0) >= 0)
2442                                         {
2443                                                 dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Nexuiz ", cvar_string("g_nexuizversion"), " (beta)^7, you have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1\n");
2444                                                 sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Nexuiz ", cvar_string("g_nexuizversion"), " (beta)^7, you have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1\n"));
2445                                         }
2446                                         else
2447                                         {
2448                                                 float r;
2449                                                 r = vercmp(self.cvar_g_nexuizversion, cvar_string("g_nexuizversion"));
2450                                                 if(r < 0)
2451                                                 {
2452                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - ^3Nexuiz ", cvar_string("g_nexuizversion"), "^7 is out, and you still have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1 - get the update from ^4http://www.nexuiz.com/^1!\n");
2453                                                         sprint(self, strcat("\{1}^1NOTE: ^3Nexuiz ", cvar_string("g_nexuizversion"), "^7 is out, and you still have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1 - get the update from ^4http://www.nexuiz.com/^1!\n"));
2454                                                 }
2455                                                 else if(r > 0)
2456                                                 {
2457                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Nexuiz ", cvar_string("g_nexuizversion"), "^7, you have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1\n");
2458                                                         sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Nexuiz ", cvar_string("g_nexuizversion"), "^7, you have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1\n"));
2459                                                 }
2460                                         }
2461                                 }
2462                                 self.version_nagtime = 0;
2463                         }
2464
2465         // GOD MODE info
2466         if(!(self.flags & FL_GODMODE)) if(self.max_armorvalue)
2467         {
2468                 sprint(self, strcat("godmode saved you ", ftos(self.max_armorvalue), " units of damage, cheater!\n"));
2469                 self.max_armorvalue = 0;
2470         }
2471
2472 #ifdef TETRIS
2473         if (TetrisPreFrame())
2474                 return;
2475 #endif
2476
2477         if(self.classname == "player") {
2478 //              if(self.netname == "Wazat")
2479 //                      bprint(self.classname, "\n");
2480
2481                 CheckRules_Player();
2482
2483                 PrintWelcomeMessage(self);
2484
2485                 if (intermission_running)
2486                 {
2487                         IntermissionThink ();   // otherwise a button could be missed between
2488                         return;                                 // the think tics
2489                 }
2490
2491                 if(self.teleport_time)
2492                 if(time > self.teleport_time)
2493                 {
2494                         self.teleport_time = 0;
2495                         self.effects = self.effects - (self.effects & EF_NODRAW);
2496                 }
2497
2498                 Nixnex_GiveCurrentWeapon();
2499
2500                 if(frametime > 0) // don't do this in cl_movement frames, just in server ticks
2501                         UpdateSelectedPlayer();
2502
2503                 //don't allow the player to turn around while game is paused!
2504                 if(timeoutStatus == 2) {
2505                         self.v_angle = self.lastV_angle;
2506                         self.angles = self.lastV_angle;
2507                         self.fixangle = TRUE;
2508                 }
2509
2510                 if(frametime)
2511                 {
2512                         if(cvar("gameversion") >= 20600) // only do this for 2.6 and above FIXME remove this check when making 2.6
2513                                 self.glowmod = colormapPaletteColor(self.clientcolors & 0x0F, TRUE) * 2;
2514                         player_powerups();
2515                 }
2516
2517                 if (self.deadflag != DEAD_NO)
2518                 {
2519                         float button_pressed, force_respawn;
2520                         if(self.personal && g_race_qualifying)
2521                         {
2522                                 if(time > self.death_time)
2523                                 {
2524                                         self.death_time = time + 1; // only retry once a second
2525                                         respawn();
2526                                         self.impulse = 141;
2527                                 }
2528                         }
2529                         else
2530                         {
2531                                 if(frametime)
2532                                         player_anim();
2533                                 button_pressed = (self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE);
2534                                 force_respawn = (g_lms || (g_ca) || cvar("g_forced_respawn"));
2535                                 if (self.deadflag == DEAD_DYING)
2536                                 {
2537                                         if(force_respawn)
2538                                                 self.deadflag = DEAD_RESPAWNING;
2539                                         else if(!button_pressed)
2540                                                 self.deadflag = DEAD_DEAD;
2541                                 }
2542                                 else if (self.deadflag == DEAD_DEAD)
2543                                 {
2544                                         if(button_pressed)
2545                                                 self.deadflag = DEAD_RESPAWNABLE;
2546                                 }
2547                                 else if (self.deadflag == DEAD_RESPAWNABLE)
2548                                 {
2549                                         if(!button_pressed)
2550                                                 self.deadflag = DEAD_RESPAWNING;
2551                                 }
2552                                 else if (self.deadflag == DEAD_RESPAWNING)
2553                                 {
2554                                         if(time > self.death_time)
2555                                         {
2556                                                 self.death_time = time + 1; // only retry once a second
2557                                                 respawn();
2558                                         }
2559                                 }
2560                                 ShowRespawnCountdown();
2561                         }
2562                         return;
2563                 }
2564
2565                 if(g_touchexplode)
2566                 if(time > self.touchexplode_time)
2567                 if(self.classname == "player")
2568                 if(self.deadflag == DEAD_NO)
2569                 if not(IS_INDEPENDENT_PLAYER(self))
2570                 FOR_EACH_PLAYER(other) if(self != other)
2571                 {
2572                         if(time > other.touchexplode_time)
2573                         if(other.classname == "player")
2574                         if(other.deadflag == DEAD_NO)
2575                         if not(IS_INDEPENDENT_PLAYER(other))
2576                         if(boxesoverlap(self.absmin, self.absmax, other.absmin, other.absmax))
2577                         {
2578                                 PlayerTouchExplode(self, other);
2579                                 self.touchexplode_time = other.touchexplode_time = time + 0.2;
2580                         }
2581                 }
2582
2583                 if(g_lms && !self.deadflag && cvar("g_lms_campcheck_interval"))
2584                 {
2585                         vector dist;
2586
2587                         // calculate player movement (in 2 dimensions only, so jumping on one spot doesn't count as movement)
2588                         dist = self.prevorigin - self.origin;
2589                         dist_z = 0;
2590                         self.lms_traveled_distance += fabs(vlen(dist));
2591
2592                         if((cvar("g_campaign") && !campaign_bots_may_start) || (time < game_starttime))
2593                         {
2594                                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval")*2;
2595                                 self.lms_traveled_distance = 0;
2596                         }
2597
2598                         if(time > self.lms_nextcheck)
2599                         {
2600                                 //sprint(self, "distance: ", ftos(self.lms_traveled_distance), "\n");
2601                                 if(self.lms_traveled_distance < cvar("g_lms_campcheck_distance"))
2602                                 {
2603                                         centerprint(self, cvar_string("g_lms_campcheck_message"));
2604                                         // FIXME KadaverJack: gibbing player here causes playermodel to bounce around, instead of eye.md3
2605                                         // I wasn't able to find out WHY that happens, so I put a workaround in place that shall prevent players from being gibbed :(
2606                                         Damage(self, self, self, bound(0, cvar("g_lms_campcheck_damage"), self.health + self.armorvalue * cvar("g_balance_armor_blockpercent") + 5), DEATH_CAMP, self.origin, '0 0 0');
2607                                 }
2608                                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval");
2609                                 self.lms_traveled_distance = 0;
2610                         }
2611                 }
2612
2613                 self.prevorigin = self.origin;
2614
2615                 if ((self.BUTTON_CROUCH && !self.hook.state) || self.health <= g_bloodloss)
2616                 {
2617                         if (!self.crouch)
2618                         {
2619                                 self.crouch = TRUE;
2620                                 self.view_ofs = PL_CROUCH_VIEW_OFS;
2621                                 setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX);
2622                                 setanim(self, self.anim_duck, FALSE, TRUE, TRUE);
2623                         }
2624                 }
2625                 else
2626                 {
2627                         if (self.crouch)
2628                         {
2629                                 tracebox(self.origin, PL_MIN, PL_MAX, self.origin, FALSE, self);
2630                                 if (!trace_startsolid)
2631                                 {
2632                                         self.crouch = FALSE;
2633                                         self.view_ofs = PL_VIEW_OFS;
2634                                         setsize (self, PL_MIN, PL_MAX);
2635                                 }
2636                         }
2637                 }
2638
2639                 if(self.health <= g_bloodloss && self.deadflag == DEAD_NO)
2640                 {
2641                         if(self.bloodloss_timer < time)
2642                         {
2643                                 self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
2644                                 self.bloodloss_timer = time + 0.5 + random() * 0.5;
2645                         }
2646                 }
2647
2648                 FixPlayermodel();
2649
2650                 GrapplingHookFrame();
2651
2652                 // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2653                 //if(frametime)
2654                 {
2655                         self.items &~= self.items_added;
2656
2657                         W_WeaponFrame();
2658
2659                         self.items_added = 0;
2660                         if(self.items & IT_JETPACK)
2661                                 if(self.items & IT_FUEL_REGEN || self.ammo_fuel >= 0.01)
2662                                         self.items_added |= IT_FUEL;
2663
2664                         self.items |= self.items_added;
2665                 }
2666
2667                 player_regen();
2668                 if(frametime)
2669                         player_anim();
2670
2671                 if (g_minstagib)
2672                         minstagib_ammocheck();
2673
2674                 ctf_setstatus();
2675                 nexball_setstatus();
2676
2677                 self.dmg_team = max(0, self.dmg_team - cvar("g_teamdamage_resetspeed") * frametime);
2678
2679                 //self.angles_y=self.v_angle_y + 90;   // temp
2680         } else if(gameover) {
2681                 if (intermission_running)
2682                         IntermissionThink ();   // otherwise a button could be missed between
2683                 return;
2684         } else if(self.classname == "observer") {
2685                 ObserverThink();
2686         } else if(self.classname == "spectator") {
2687                 SpectatorThink();
2688         }
2689
2690         if(!zoomstate_set)
2691                 SetZoomState(self.BUTTON_ZOOM || (self.BUTTON_ATCK2 && self.weapon == WEP_NEX));
2692
2693         float oldspectatee_status;
2694         oldspectatee_status = self.spectatee_status;
2695         if(self.classname == "spectator")
2696                 self.spectatee_status = num_for_edict(self.enemy);
2697         else if(self.classname == "observer")
2698                 self.spectatee_status = num_for_edict(self);
2699         else
2700                 self.spectatee_status = 0;
2701         if(self.spectatee_status != oldspectatee_status)
2702         {
2703                 ClientData_Touch(self);
2704                 if(g_race || g_cts)
2705                         race_InitSpectator();
2706         }
2707
2708         if(self.teamkill_soundtime)
2709         if(time > self.teamkill_soundtime)
2710         {
2711                 self.teamkill_soundtime = 0;
2712
2713                 entity oldpusher, oldself;
2714
2715                 oldself = self; self = self.teamkill_soundsource;
2716                 oldpusher = self.pusher; self.pusher = oldself;
2717
2718                 PlayerSound(playersound_teamshoot, CHAN_VOICE, VOICETYPE_LASTATTACKER_ONLY);
2719
2720                 self.pusher = oldpusher;
2721                 self = oldself;
2722         }
2723
2724         if(self.taunt_soundtime)
2725         if(time > self.taunt_soundtime)
2726         {
2727                 self.taunt_soundtime = 0;
2728                 PlayerSound(playersound_taunt, CHAN_VOICE, VOICETYPE_AUTOTAUNT);
2729         }
2730
2731         target_voicescript_next(self);
2732 }
2733
2734 float isInvisibleString(string s)
2735 {
2736         float i, n, c;
2737         s = strdecolorize(s);
2738         for((i = 0), (n = strlen(s)); i < n; ++i)
2739         {
2740                 c = str2chr(s, i);
2741                 switch(c)
2742                 {
2743                         case 0:
2744                         case 32:
2745                         case 160:
2746                                 break;
2747                         default:
2748                                 return FALSE;
2749                 }
2750         }
2751         return TRUE;
2752 }
2753
2754 /*
2755 =============
2756 PlayerPostThink
2757
2758 Called every frame for each client after the physics are run
2759 =============
2760 */
2761 .float idlekick_lasttimeleft;
2762 void PlayerPostThink (void)
2763 {
2764         // Savage: Check for nameless players
2765         if (isInvisibleString(self.netname)) {
2766                 self.netname = "Player";
2767                 stuffcmd(self, strcat("name ", self.netname, substring(ftos(random()), 2, -1), "\n"));
2768         }
2769
2770         // send the clients accuracy stats to the client
2771         if(self.stat_count > 0)
2772         if(frametime)
2773         {
2774                 self.stat_hit = self.stat_count + 64 * floor(self.(stats_hit[self.stat_count - 1]));
2775                 self.stat_fired = self.stat_count + 64 * floor(self.(stats_fired[self.stat_count - 1]));
2776                 self.stat_count -= 1;
2777         }
2778
2779 #ifdef UID
2780         if(self.uid_kicktime)
2781         if(time > self.uid_kicktime)
2782         {
2783                 bprint("^3", self.netname, "^3 was kicked for missing UID.\n");
2784                 dropclient(self);
2785                 return;
2786         }
2787 #endif
2788
2789         if(sv_maxidle && frametime)
2790         {
2791                 // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2792                 float timeleft;
2793                 timeleft = ceil(sv_maxidle - (time - self.parm_idlesince));
2794                 if(timeleft <= 0)
2795                 {
2796                         bprint("^3", self.netname, "^3 was kicked for idling.\n");
2797                         announce(self, "announcer/robotic/terminated.wav");
2798                         dropclient(self);
2799                         return;
2800                 }
2801                 else if(timeleft <= 10)
2802                 {
2803                         if(timeleft != self.idlekick_lasttimeleft)
2804                         {
2805                                 centerprint_atprio(self, CENTERPRIO_IDLEKICK, strcat("^3Stop idling!\n^3Disconnecting in ", ftos(timeleft), "..."));
2806                                 announce(self, strcat("announcer/robotic/", ftos(timeleft), ".wav"));
2807                         }
2808                 }
2809                 else
2810                 {
2811                         centerprint_expire(self, CENTERPRIO_IDLEKICK);
2812                 }
2813                 self.idlekick_lasttimeleft = timeleft;
2814         }
2815
2816 #ifdef TETRIS
2817         if(self.impulse == 100)
2818                 ImpulseCommands();
2819         if (TetrisPostFrame())
2820                 return;
2821 #endif
2822
2823         CheatFrame();
2824
2825         if(self.classname == "player") {
2826                 CheckRules_Player();
2827                 UpdateChatBubble();
2828                 UpdateTeamBubble();
2829                 if (self.impulse)
2830                         ImpulseCommands();
2831                 if (intermission_running)
2832                         return;         // intermission or finale
2833
2834                 GetPressedKeys();
2835         } else if (self.classname == "observer") {
2836                 //do nothing
2837         } else if (self.classname == "spectator") {
2838                 //do nothing
2839         }
2840
2841         /*
2842         float i;
2843         for(i = 0; i < 1000; ++i)
2844         {
2845                 vector end;
2846                 end = self.origin + '0 0 1024' + 512 * randomvec();
2847                 tracebox(self.origin, self.mins, self.maxs, end, MOVE_NORMAL, self);
2848                 if(trace_fraction < 1)
2849                 if(!(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
2850                 {
2851                         print("I HIT SOLID: ", vtos(self.origin), " -> ", vtos(end), "\n");
2852                         break;
2853                 }
2854         }
2855         */
2856
2857         Arena_Warmup();
2858
2859         //pointparticles(particleeffectnum("machinegun_impact"), self.origin + self.view_ofs + '0 0 7', '0 0 0', 1);
2860
2861         if(self.waypointsprite_attachedforcarrier)
2862                 WaypointSprite_UpdateHealth(self.waypointsprite_attachedforcarrier, '1 0 0' * healtharmor_maxdamage(self.health, self.armorvalue, cvar("g_balance_armor_blockpercent")));
2863
2864         playerdemo_write();
2865
2866         /*
2867         if(g_race)
2868                 dprint(sprintf("%f %.6f\n", time, race_GetFractionalLapCount(self)));
2869         */
2870 }