data/qcsrc/server/cl_client.qc

   1 void info_player_start (void)
   2 {
   3         info_player_deathmatch();
   4 }
   5
   6 void info_player_deathmatch (void)
   7 {
   8         self.classname = "info_player_deathmatch";
   9         relocate_spawnpoint();
  10 }
  11
  12 float spawn_allbad;
  13 float spawn_allgood;
  14 entity Spawn_FilterOutBadSpots(entity firstspot, entity playerlist, float mindist, float teamcheck)
  15 {
  16         local entity spot, player, nextspot, previousspot, newfirstspot;
  17         local float pcount;
  18         spot = firstspot;
  19         newfirstspot = world;
  20         previousspot = world;
  21         spawn_allgood = TRUE;
  22         spawn_allbad = TRUE;
  23         while (spot)
  24         {
  25                 nextspot = spot.chain;
  26                 // count team mismatches as bad spots
  27
  28                 local float spotactive;
  29                 spotactive = 1;
  30
  31                 // filter out spots for assault
  32                 if(spot.target != "") {
  33                         local entity ent;
  34                         ent = find(world, targetname, spot.target);
  35                         while(ent) {
  36                                 if(ent.classname == "target_objective")
  37                                         if(ent.health < 0 || ent.health >= ASSAULT_VALUE_INACTIVE)
  38                                                 spotactive = 0;
  39                                 ent = find(ent, targetname, spot.target);
  40                         }
  41                 }
  42
  43                 if (spot.team == teamcheck && spotactive > 0)
  44                 {
  45                         pcount = 0;
  46                         player = playerlist;
  47                         while (player)
  48                         {
  49                                 if (player != self)
  50                                 if (vlen(player.origin - spot.origin) < mindist)
  51                                         pcount = pcount + 1;
  52                                 player = player.chain;
  53                         }
  54                         if (!pcount)
  55                         {
  56                                 spawn_allbad = FALSE;
  57                                 if (newfirstspot)
  58                                         previousspot.chain = spot;
  59                                 else
  60                                         newfirstspot = spot;
  61                                 previousspot = spot;
  62                                 spot.chain = world;
  63                         }
  64                         else
  65                                 spawn_allgood = FALSE;
  66                 }
  67                 spot = nextspot;
  68         }
  69         // if we couldn't find ANY good points, return the original list
  70         if (!newfirstspot)
  71                 newfirstspot = firstspot;
  72         return newfirstspot;
  73 }
  74
  75 entity Spawn_RandomPoint(entity firstspot)
  76 {
  77         local entity spot;
  78         local float numspots;
  79         // count number of spots
  80         numspots = 0;
  81         spot = firstspot;
  82         while (spot)
  83         {
  84                 numspots = numspots + 1;
  85                 spot = spot.chain;
  86         }
  87         // pick a random one
  88         numspots = numspots * random();
  89         spot = firstspot;
  90         while (spot.chain && numspots >= 1)
  91         {
  92                 numspots = numspots - 1;
  93                 spot = spot.chain;
  94         }
  95         return spot;
  96 }
  97
  98 entity Spawn_FurthestPoint(entity firstspot, entity playerlist)
  99 {
 100         local entity best, spot, player;
 101         local float bestrating, rating;
 102         best = world;
 103         bestrating = -1000000;
 104         spot = firstspot;
 105         while (spot)
 106         {
 107                 rating = 1000000000;
 108                 player = playerlist;
 109                 while (player)
 110                 {
 111                         if (player != self)
 112                                 rating = min(rating, vlen(player.origin - spot.origin));
 113                         player = player.chain;
 114                 }
 115                 rating = rating + random() * 16;
 116                 if (bestrating < rating)
 117                 {
 118                         best = spot;
 119                         bestrating = rating;
 120                 }
 121                 spot = spot.chain;
 122         }
 123         return best;
 124 }
 125
 126 /*
 127 =============
 128 SelectSpawnPoint
 129
 130 Finds a point to respawn
 131 =============
 132 */
 133 entity SelectSpawnPoint (float anypoint)
 134 {
 135         local float teamcheck;
 136         local entity spot, firstspot, playerlist;
 137
 138         spot = find (world, classname, "testplayerstart");
 139         if (spot)
 140                 return spot;
 141
 142         teamcheck = 0;
 143
 144         if((!anypoint && cvar("g_ctf")) || cvar("g_assault") )
 145                 teamcheck = self.team;
 146
 147         // get the list of players
 148         playerlist = findchain(classname, "player");
 149         // get the entire list of spots
 150         firstspot = findchain(classname, "info_player_deathmatch");
 151         // filter out the bad ones
 152         // (note this returns the original list if none survived)
 153         firstspot = Spawn_FilterOutBadSpots(firstspot, playerlist, 100, teamcheck);
 154
 155         // there is 50/50 chance of choosing a random spot or the furthest spot
 156         // (this means that roughly every other spawn will be furthest, so you
 157         // usually won't get fragged at spawn twice in a row)
 158         if (arena_roundbased)
 159         {
 160                 firstspot = Spawn_FilterOutBadSpots(firstspot, playerlist, 800, teamcheck);
 161                 spot = Spawn_RandomPoint(firstspot);
 162         }
 163         else if (random() > 0.5 || spawn_allbad || spawn_allgood)
 164                 spot = Spawn_RandomPoint(firstspot);
 165         else
 166                 spot = Spawn_FurthestPoint(firstspot, playerlist);
 167
 168         if (!spot)
 169         {
 170                 if(cvar("spawn_debug"))
 171                         GotoNextMap();
 172                 else
 173                         error ("PutClientInServer: no start points on level");
 174         }
 175
 176         return spot;
 177 }
 178
 179 /*
 180 =============
 181 CheckPlayerModel
 182
 183 Checks if the argument string can be a valid playermodel.
 184 Returns a valid one in doubt.
 185 =============
 186 */
 187 string FallbackPlayerModel = "models/player/marine.zym";
 188 string CheckPlayerModel(string plyermodel) {
 189         if(strlen(plyermodel) < 4)
 190                 return FallbackPlayerModel;
 191         if( substring(plyermodel,0,14) != "models/player/")
 192                 return FallbackPlayerModel;
 193         else if(cvar("sv_servermodelsonly"))
 194         {
 195                 if(substring(plyermodel,strlen(plyermodel)-4,4) != ".zym")
 196                         return FallbackPlayerModel;
 197                 if(!fexists(plyermodel))
 198                         return FallbackPlayerModel;
 199         }
 200         return plyermodel;
 201 }
 202
 203 /*
 204 =============
 205 Client_customizeentityforclient
 206
 207 LOD reduction
 208 =============
 209 */
 210 float Client_customizeentityforclient()
 211 {
 212 #ifdef ALLOW_VARIABLE_LOD
 213         // self: me
 214         // other: the player viewing me
 215         float distance;
 216         float f;
 217
 218         if(self.flags & FL_NOTARGET) // we don't need LOD for spectators
 219                 return TRUE;
 220
 221         if(other.cvar_cl_playerdetailreduction <= 0)
 222         {
 223                 if(other.cvar_cl_playerdetailreduction <= -2)
 224                         self.modelindex = self.modelindex_lod2;
 225                 else if(other.cvar_cl_playerdetailreduction <= -1)
 226                         self.modelindex = self.modelindex_lod1;
 227                 else
 228                         self.modelindex = self.modelindex_lod0;
 229         }
 230         else
 231         {
 232                 distance = vlen(self.origin - other.origin);
 233                 f = (distance + 100.0) * other.cvar_cl_playerdetailreduction;
 234                 if(f > 10000)
 235                         self.modelindex = self.modelindex_lod2;
 236                 else if(f > 5000)
 237                         self.modelindex = self.modelindex_lod1;
 238                 else
 239                         self.modelindex = self.modelindex_lod0;
 240         }
 241 #endif
 242
 243         return TRUE;
 244 }
 245
 246 void setmodel_lod(entity e, string modelname)
 247 {
 248 #ifdef ALLOW_VARIABLE_LOD
 249         string s;
 250
 251         s = strcat(substring(modelname, 0, strlen(modelname) - 4), "_1.zym");
 252         if(fexists(s))
 253         {
 254                 precache_model(s);
 255                 setmodel(e, s); // players have high precision
 256                 self.modelindex_lod1 = self.modelindex;
 257         }
 258         else
 259                 self.modelindex_lod1 = -1;
 260
 261         s = strcat(substring(modelname, 0, strlen(modelname) - 4), "_2.zym");
 262         if(fexists(s))
 263         {
 264                 precache_model(s);
 265                 setmodel(e, s); // players have high precision
 266                 self.modelindex_lod2 = self.modelindex;
 267         }
 268         else
 269                 self.modelindex_lod2 = -1;
 270
 271         precache_model(modelname);
 272         setmodel(e, modelname); // players have high precision
 273         self.modelindex_lod0 = self.modelindex;
 274
 275         if(self.modelindex_lod1 < 0)
 276                 self.modelindex_lod1 = self.modelindex;
 277
 278         if(self.modelindex_lod2 < 0)
 279                 self.modelindex_lod2 = self.modelindex;
 280 #else
 281         precache_model(modelname);
 282         setmodel(e, modelname); // players have high precision
 283 #endif
 284 }
 285
 286 /*
 287 =============
 288 PutObserverInServer
 289
 290 putting a client as observer in the server
 291 =============
 292 */
 293 void PutObserverInServer (void)
 294 {
 295         entity  spot;
 296         spot = SelectSpawnPoint (FALSE);
 297         RemoveGrapplingHook(self); // Wazat's Grappling Hook
 298
 299         if(clienttype(self) == CLIENTTYPE_REAL)
 300         {
 301                 msg_entity = self;
 302                 WriteByte(MSG_ONE, SVC_SETVIEW);
 303                 WriteEntity(MSG_ONE, self);
 304         }
 305
 306         DropAllRunes(self);
 307         kh_Key_DropAll(self, TRUE);
 308
 309         if(self.flagcarried)
 310                 DropFlag(self.flagcarried);
 311
 312         WaypointSprite_PlayerDead();
 313
 314         DistributeFragsAmongTeam(self, self.team, 1);
 315
 316         if(self.frags <= 0 && self.frags > -666 && cvar("g_lms") && self.killcount != -666)
 317                 bprint ("^4", self.netname, "^4 has no more lives left\n");
 318         else if(self.killcount != -666)
 319                 bprint ("^4", self.netname, "^4 is spectating now\n");
 320
 321         self.classname = "observer";
 322         self.health = -666;
 323         self.takedamage = DAMAGE_NO;
 324         self.solid = SOLID_NOT;
 325         self.movetype = MOVETYPE_NOCLIP;
 326         self.flags = FL_CLIENT | FL_NOTARGET;
 327         self.armorvalue = 666;
 328         self.effects = 0;
 329         self.armorvalue = cvar("g_balance_armor_start");
 330         self.pauserotarmor_finished = 0;
 331         self.pauserothealth_finished = 0;
 332         self.pauseregen_finished = 0;
 333         self.damageforcescale = 0;
 334         self.death_time = 0;
 335         self.dead_time = 0;
 336         self.dead_frame = 0;
 337         self.die_frame = 0;
 338         self.deaths = 0;
 339         self.alpha = 0;
 340         self.scale = 0;
 341         self.fade_time = 0;
 342         self.pain_frame = 0;
 343         self.pain_finished = 0;
 344         self.strength_finished = 0;
 345         self.invincible_finished = 0;
 346         self.pushltime = 0;
 347         self.think = SUB_Null;
 348         self.nextthink = 0;
 349         self.hook_time = 0;
 350         self.runes = 0;
 351         self.deadflag = DEAD_NO;
 352         self.angles = spot.angles;
 353         self.angles_z = 0;
 354         self.fixangle = TRUE;
 355         self.crouch = FALSE;
 356
 357         self.view_ofs = PL_VIEW_OFS;
 358         setorigin (self, spot.origin);
 359         setsize (self, '0 0 0', '0 0 0');
 360         self.oldorigin = self.origin;
 361         self.items = 0;
 362         self.model = "";
 363         self.modelindex = 0;
 364         self.weapon = 0;
 365         self.weaponmodel = "";
 366         self.weaponentity = world;
 367         self.killcount = -666;
 368         self.velocity = '0 0 0';
 369         self.avelocity = '0 0 0';
 370         self.punchangle = '0 0 0';
 371         self.punchvector = '0 0 0';
 372         self.oldvelocity = self.velocity;
 373         self.customizeentityforclient = Client_customizeentityforclient;
 374
 375         if(cvar("g_arena"))
 376         {
 377                 if(self.frags != -2)
 378                 {
 379                         Spawnqueue_Insert(self);
 380                 }
 381                 else
 382                 {
 383                         Spawnqueue_Unmark(self);
 384                         Spawnqueue_Remove(self);
 385                 }
 386         }
 387         else if(!cvar("g_lms"))
 388                 self.frags = -666;
 389 }
 390
 391
 392 /*
 393 =============
 394 PutClientInServer
 395
 396 Called when a client spawns in the server
 397 =============
 398 */
 399 void PutClientInServer (void)
 400 {
 401         if(clienttype(self) == CLIENTTYPE_BOT)
 402         {
 403                 self.classname = "player";
 404         }
 405         else if(clienttype(self) == CLIENTTYPE_REAL)
 406         {
 407                 msg_entity = self;
 408                 WriteByte(MSG_ONE, SVC_SETVIEW);
 409                 WriteEntity(MSG_ONE, self);
 410         }
 411
 412         // player is dead and becomes observer
 413         if(cvar("g_lms") && self.frags < 1)
 414                 self.classname = "observer";
 415
 416         if(cvar("g_arena"))
 417         if(!self.spawned)
 418                 self.classname = "observer";
 419
 420         if(self.classname == "player") {
 421                 entity  spot;
 422
 423                 spot = SelectSpawnPoint (FALSE);
 424
 425                 RemoveGrapplingHook(self); // Wazat's Grappling Hook
 426
 427                 self.classname = "player";
 428                 self.iscreature = TRUE;
 429                 self.movetype = MOVETYPE_WALK;
 430                 self.solid = SOLID_SLIDEBOX;
 431                 self.flags = FL_CLIENT;
 432                 self.takedamage = DAMAGE_AIM;
 433                 self.effects = 0;
 434                 self.air_finished = time + 12;
 435                 self.dmg = 2;
 436
 437                 self.ammo_shells = start_ammo_shells;
 438                 self.ammo_nails = start_ammo_nails;
 439                 self.ammo_rockets = start_ammo_rockets;
 440                 self.ammo_cells = start_ammo_cells;
 441                 self.health = start_health;
 442                 self.armorvalue = start_armorvalue;
 443                 self.items = start_items;
 444                 self.switchweapon = start_switchweapon;
 445                 self.weapon = 0;
 446                 self.jump_interval = time;
 447
 448                 self.spawnshieldtime = time + cvar("g_spawnshieldtime");
 449                 self.pauserotarmor_finished = time + cvar("g_balance_pause_armor_rot_spawn");
 450                 self.pauserothealth_finished = time + cvar("g_balance_pause_health_rot_spawn");
 451                 self.pauseregen_finished = time + cvar("g_balance_pause_health_regen_spawn");
 452                 self.damageforcescale = 2;
 453                 self.death_time = 0;
 454                 self.dead_time = 0;
 455                 self.dead_frame = 0;
 456                 self.die_frame = 0;
 457                 self.alpha = 0;
 458                 self.scale = 0;
 459                 self.fade_time = 0;
 460                 self.pain_frame = 0;
 461                 self.pain_finished = 0;
 462                 self.strength_finished = 0;
 463                 self.invincible_finished = 0;
 464                 self.pushltime = 0;
 465                 //self.speed_finished = 0;
 466                 //self.slowmo_finished = 0;
 467                 // players have no think function
 468                 self.think = SUB_Null;
 469                 self.nextthink = 0;
 470                 self.hook_time = 0;
 471
 472                 self.runes = 0;
 473
 474                 self.deadflag = DEAD_NO;
 475
 476                 self.angles = spot.angles;
 477
 478                 self.angles_z = 0; // never spawn tilted even if the spot says to
 479                 self.fixangle = TRUE; // turn this way immediately
 480                 self.velocity = '0 0 0';
 481                 self.avelocity = '0 0 0';
 482                 self.punchangle = '0 0 0';
 483                 self.punchvector = '0 0 0';
 484                 self.oldvelocity = self.velocity;
 485
 486                 self.viewzoom = 0.6;
 487                 self.has_zoomed = 0;
 488
 489                 self.customizeentityforclient = Client_customizeentityforclient;
 490
 491                 if(cvar("sv_defaultcharacter") == 1) {
 492                         local string defaultmodel;
 493                         defaultmodel = cvar_string("sv_defaultplayermodel");
 494                         setmodel_lod (self, defaultmodel);
 495                         self.skin = stof(cvar_string("sv_defaultplayerskin"));
 496                         if(!teams_matter)
 497                                 if(strlen(cvar_string("sv_defaultplayercolors")))
 498                                         setcolor(self, cvar("sv_defaultplayercolors"));
 499                 } else {
 500                         self.playermodel = CheckPlayerModel(self.playermodel);
 501                         setmodel_lod (self, self.playermodel);
 502                         if(teams_matter)
 503                         {
 504                                 float s;
 505                                 s = stof(self.playerskin);
 506                                 if(s >= 0 && s < 3)
 507                                         self.skin = s;
 508                                 else if(s == 6)
 509                                         self.skin = 6;
 510                                 else
 511                                         self.skin = 0;
 512                         }
 513                         else
 514                                 self.skin = stof(self.playerskin);
 515                 }
 516
 517                 self.crouch = FALSE;
 518                 self.view_ofs = PL_VIEW_OFS;
 519                 setsize (self, PL_MIN, PL_MAX);
 520                 self.spawnorigin = spot.origin;
 521                 setorigin (self, spot.origin + '0 0 1' * (1 - self.mins_z - 24));
 522                 // don't reset back to last position, even if new position is stuck in solid
 523                 self.oldorigin = self.origin;
 524
 525                 if(cvar("g_arena"))
 526                 {
 527                         Spawnqueue_Remove(self);
 528                         Spawnqueue_Mark(self);
 529                 }
 530
 531                 self.event_damage = PlayerDamage;
 532
 533                 self.bot_attack = TRUE;
 534
 535                 self.statdraintime = time + 5;
 536                 self.button0 = self.button1 = self.button2 = self.button3 = 0;
 537
 538                 if(self.killcount == -666) {
 539                         self.killcount = 0;
 540                         if(!cvar("g_arena"))
 541                         if(!cvar("g_lms"))
 542                                 self.frags = 0;
 543                 }
 544
 545                 self.cnt = WEP_LASER;
 546                 self.nixnex_lastchange_id = -1;
 547
 548                 CL_SpawnWeaponentity();
 549                 self.alpha = default_player_alpha;
 550                 self.exteriorweaponentity.alpha = default_weapon_alpha;
 551
 552                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval")*2;
 553                 self.lms_traveled_distance = 0;
 554
 555                 if(cvar("spawn_debug"))
 556                 {
 557                         sprint(self, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 558                         remove(spot);   // usefull for checking if there are spawnpoints, that let drop through the floor
 559                 }
 560
 561                 //stuffcmd(self, "chase_active 0");
 562                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
 563
 564                 if (cvar("g_spawnsound"))
 565                         sound (self, CHAN_AUTO, "misc/spawn.wav", 1, ATTN_NORM);
 566
 567                 if(cvar("g_assault")) {
 568                         if(self.team == assault_attacker_team)
 569                                 centerprint(self, "You are attacking!\n");
 570                         else
 571                                 centerprint(self, "You are defending!\n");
 572                 }
 573
 574         } else if(self.classname == "observer") {
 575                 PutObserverInServer ();
 576         }
 577 }
 578
 579 /*
 580 =============
 581 SetNewParms
 582 =============
 583 */
 584 void SetNewParms (void)
 585 {
 586
 587 }
 588
 589 /*
 590 =============
 591 SetChangeParms
 592 =============
 593 */
 594 void SetChangeParms (void)
 595 {
 596
 597 }
 598
 599 /*
 600 =============
 601 ClientKill
 602
 603 Called when a client types 'kill' in the console
 604 =============
 605 */
 606 void ClientKill (void)
 607 {
 608         Damage(self, self, self, 100000, DEATH_KILL, self.origin, '0 0 0');
 609 }
 610
 611 void FixClientCvars(entity e)
 612 {
 613         // send prediction settings to the client
 614         stuffcmd(e, "\nin_bindmap 0 0\n");
 615         stuffcmd(e, strcat("cl_gravity ", ftos(cvar("sv_gravity")), "\n"));
 616         stuffcmd(e, strcat("cl_movement_accelerate ", ftos(cvar("sv_accelerate")), "\n"));
 617         stuffcmd(e, strcat("cl_movement_friction ", ftos(cvar("sv_friction")), "\n"));
 618         stuffcmd(e, strcat("cl_movement_maxspeed ", ftos(cvar("sv_maxspeed")), "\n"));
 619         stuffcmd(e, strcat("cl_movement_airaccelerate ", ftos(cvar("sv_airaccelerate")), "\n"));
 620         stuffcmd(e, strcat("cl_movement_maxairspeed ", ftos(cvar("sv_maxairspeed")), "\n"));
 621         stuffcmd(e, strcat("cl_movement_stopspeed ", ftos(cvar("sv_stopspeed")), "\n"));
 622         stuffcmd(e, strcat("cl_movement_jumpvelocity ", ftos(cvar("sv_jumpvelocity")), "\n"));
 623         stuffcmd(e, strcat("cl_movement_stepheight ", ftos(cvar("sv_stepheight")), "\n"));
 624         stuffcmd(e, strcat("set cl_movement_friction_on_land ", ftos(cvar("sv_friction_on_land")), "\n"));
 625         stuffcmd(e, strcat("set cl_movement_airaccel_qw ", ftos(cvar("sv_airaccel_qw")), "\n"));
 626         stuffcmd(e, strcat("set cl_movement_airaccel_sideways_friction ", ftos(cvar("sv_airaccel_sideways_friction")), "\n"));
 627         stuffcmd(e, "cl_movement_edgefriction 1\n");
 628 }
 629
 630 /*
 631 =============
 632 ClientConnect
 633
 634 Called when a client connects to the server
 635 =============
 636 */
 637 string ColoredTeamName(float t);
 638 //void dom_player_join_team(entity pl);
 639 void ClientConnect (void)
 640 {
 641         local string s;
 642
 643         if(Ban_IsClientBanned(self))
 644         {
 645                 s = strcat("^1NOTE:^7 banned client ", self.netaddress, " just tried to enter\n");
 646                 dropclient(self);
 647                 bprint(s);
 648                 return;
 649         }
 650
 651         self.classname = "player_joining";
 652         self.flags = self.flags | FL_CLIENT;
 653         self.version_nagtime = time + 10 + random() * 10;
 654
 655         if(player_count<0)
 656         {
 657                 dprint("BUG player count is lower than zero, this cannot happen!\n");
 658                 player_count = 0;
 659         }
 660
 661         bot_clientconnect();
 662
 663         //if(cvar("g_domination"))
 664         //      dom_player_join_team(self);
 665
 666         //JoinBestTeam(self, FALSE);
 667
 668         if((cvar("sv_spectate") == 1 && !cvar("g_lms")) || cvar("g_campaign")) {
 669                 self.classname = "observer";
 670         } else {
 671                 self.classname = "player";
 672                 campaign_bots_may_start = 1;
 673         }
 674
 675         self.playerid = (playerid_last = playerid_last + 1);
 676         if(cvar("sv_eventlog"))
 677         {
 678                 if(clienttype(self) == CLIENTTYPE_REAL)
 679                         s = "player";
 680                 else
 681                         s = "bot";
 682                 GameLogEcho(strcat(":join:", ftos(self.playerid), ":", s, ":", self.netname), TRUE);
 683                 s = strcat(":team:", ftos(self.playerid), ":");
 684                 s = strcat(s, ftos(self.team));
 685                 GameLogEcho(s, FALSE);
 686         }
 687
 688         //stuffcmd(self, "set tmpviewsize $viewsize \n");
 689
 690         bprint ("^4",self.netname);
 691         bprint ("^4 connected");
 692
 693         if(cvar("g_domination") || cvar("g_ctf"))
 694         {
 695                 bprint(" and joined the ");
 696                 bprint(ColoredTeamName(self.team));
 697         }
 698
 699         bprint("\n");
 700
 701         self.welcomemessage_time = 0;
 702
 703         stuffcmd(self, strcat("exec maps/", mapname, ".cfg\n"));
 704         // TODO: is this being used for anything else than cd tracks?
 705         // Remember: SVC_CDTRACK exists. Maybe it should be used.
 706
 707         FixClientCvars(self);
 708
 709         // waypoint sprites
 710         WaypointSprite_InitClient(self);
 711
 712         // Wazat's grappling hook
 713         SetGrappleHookBindings();
 714
 715         // get autoswitch state from player when he toggles it
 716         stuffcmd(self, "alias autoswitch \"set cl_autoswitch $1 ; cmd autoswitch $1\"\n");
 717
 718         // get version info from player
 719         stuffcmd(self, "cmd clientversion $gameversion\n");
 720
 721         // get other cvars from player
 722         GetCvars(0);
 723
 724         // set cvar for team scoreboard
 725         if (teams_matter)
 726         {
 727                 local float t;
 728                 t = cvar("teamplay");
 729                 // we have to stuff the correct teamplay value because if this is a listen server, this changes the teamplay mode of the server itself, which is bad
 730                 stuffcmd(self, strcat("set teamplay ", ftos(t), "\n"));
 731         }
 732         else
 733                 stuffcmd(self, "set teamplay 0\n");
 734
 735         if(cvar("g_lms"))
 736         {
 737                 self.frags = cvar("fraglimit");
 738                 // no fraglimit was set, so player gets 999 lives
 739                 if(self.frags < 1)
 740                         self.frags = 999;
 741
 742                 self.frags = LMS_NewPlayerLives();
 743                 if(!self.frags)
 744                 {
 745                         self.frags = -666;
 746                 }
 747         }
 748         else if(cvar("g_arena"))
 749         {
 750                 self.classname = "observer";
 751                 Spawnqueue_Insert(self);
 752         }
 753
 754         bot_relinkplayerlist();
 755
 756         self.jointime = time;
 757 }
 758
 759 /*
 760 =============
 761 ClientDisconnect
 762
 763 Called when a client disconnects from the server
 764 =============
 765 */
 766 void(entity e) DropFlag;
 767 .entity chatbubbleentity;
 768 .entity teambubbleentity;
 769 void ClientDisconnect (void)
 770 {
 771         float save;
 772         if(cvar("sv_eventlog"))
 773                 GameLogEcho(strcat(":part:", ftos(self.playerid)), FALSE);
 774         bprint ("^4",self.netname);
 775         bprint ("^4 disconnected\n");
 776
 777         if (self.chatbubbleentity)
 778         {
 779                 remove (self.chatbubbleentity);
 780                 self.chatbubbleentity = world;
 781         }
 782
 783         if (self.teambubbleentity)
 784         {
 785                 remove (self.teambubbleentity);
 786                 self.teambubbleentity = world;
 787         }
 788
 789         WaypointSprite_PlayerGone();
 790
 791         DropAllRunes(self);
 792         kh_Key_DropAll(self, TRUE);
 793
 794         if(self.flagcarried)
 795                 DropFlag(self.flagcarried);
 796
 797         DistributeFragsAmongTeam(self, self.team, 1);
 798
 799         save = self.flags;
 800         self.flags = self.flags - (self.flags & FL_CLIENT);
 801         bot_relinkplayerlist();
 802         self.flags = save;
 803
 804         // remove laserdot
 805         if(self.weaponentity)
 806                 if(self.weaponentity.lasertarget)
 807                         remove(self.weaponentity.lasertarget);
 808
 809         if(cvar("g_arena"))
 810         {
 811                 Spawnqueue_Unmark(self);
 812                 Spawnqueue_Remove(self);
 813         }
 814
 815         // free cvars
 816         GetCvars(-1);
 817 }
 818
 819 .float buttonchat;
 820 void() ChatBubbleThink =
 821 {
 822         self.nextthink = time;
 823         if (!self.owner.modelindex || self.owner.chatbubbleentity != self)
 824         {
 825                 self.owner.chatbubbleentity = world;
 826                 remove(self);
 827                 return;
 828         }
 829         setorigin(self, self.owner.origin + '0 0 15' + self.owner.maxs_z * '0 0 1');
 830         if (self.owner.buttonchat && !self.owner.deadflag)
 831                 self.model = self.mdl;
 832         else
 833                 self.model = "";
 834 };
 835
 836 void() UpdateChatBubble =
 837 {
 838         if (!self.modelindex)
 839                 return;
 840         // spawn a chatbubble entity if needed
 841         if (!self.chatbubbleentity)
 842         {
 843                 self.chatbubbleentity = spawn();
 844                 self.chatbubbleentity.owner = self;
 845                 self.chatbubbleentity.exteriormodeltoclient = self;
 846                 self.chatbubbleentity.think = ChatBubbleThink;
 847                 self.chatbubbleentity.nextthink = time;
 848                 setmodel(self.chatbubbleentity, "models/misc/chatbubble.spr"); // precision set below
 849                 setorigin(self.chatbubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
 850                 self.chatbubbleentity.mdl = self.chatbubbleentity.model;
 851                 self.chatbubbleentity.model = "";
 852                 self.chatbubbleentity.effects = EF_LOWPRECISION;
 853         }
 854 }
 855
 856
 857 void() TeamBubbleThink =
 858 {
 859         self.nextthink = time;
 860         if (!self.owner.modelindex || self.owner.teambubbleentity != self)
 861         {
 862                 self.owner.teambubbleentity = world;
 863                 remove(self);
 864                 return;
 865         }
 866 //      setorigin(self, self.owner.origin + '0 0 15' + self.owner.maxs_z * '0 0 1');  // bandwidth hog. setattachment does this now
 867         if (self.owner.buttonchat || self.owner.deadflag)
 868                 self.model = "";
 869         else
 870                 self.model = self.mdl;
 871
 872 };
 873
 874 float() TeamBubble_customizeentityforclient
 875 {
 876         return (self.owner != other && self.owner.team == other.team && other.killcount > -666);
 877 }
 878
 879 void() UpdateTeamBubble =
 880 {
 881         if (!self.modelindex || !cvar("teamplay"))
 882                 return;
 883         // spawn a teambubble entity if needed
 884         if (!self.teambubbleentity && cvar("teamplay"))
 885         {
 886                 self.teambubbleentity = spawn();
 887                 self.teambubbleentity.owner = self;
 888                 self.teambubbleentity.exteriormodeltoclient = self;
 889                 self.teambubbleentity.think = TeamBubbleThink;
 890                 self.teambubbleentity.nextthink = time;
 891                 setmodel(self.teambubbleentity, "models/misc/teambubble.spr"); // precision set below
 892 //              setorigin(self.teambubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
 893                 setorigin(self.teambubbleentity, self.teambubbleentity.origin + '0 0 15' + self.maxs_z * '0 0 1');
 894                 setattachment(self.teambubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
 895                 self.teambubbleentity.mdl = self.teambubbleentity.model;
 896                 self.teambubbleentity.model = self.teambubbleentity.mdl;
 897                 self.teambubbleentity.customizeentityforclient = TeamBubble_customizeentityforclient;
 898                 self.teambubbleentity.effects = EF_LOWPRECISION;
 899         }
 900 }
 901
 902 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
 903 // added to the model skins
 904 /*void() UpdateColorModHack =
 905 {
 906         local float c;
 907         c = self.clientcolors & 15;
 908         // LordHavoc: only bothering to support white, green, red, yellow, blue
 909              if (teamplay == 0) self.colormod = '0 0 0';
 910         else if (c ==  0) self.colormod = '1.00 1.00 1.00';
 911         else if (c ==  3) self.colormod = '0.10 1.73 0.10';
 912         else if (c ==  4) self.colormod = '1.73 0.10 0.10';
 913         else if (c == 12) self.colormod = '1.22 1.22 0.10';
 914         else if (c == 13) self.colormod = '0.10 0.10 1.73';
 915         else self.colormod = '1 1 1';
 916 };*/
 917
 918 void respawn(void)
 919 {
 920         CopyBody(1);
 921         PutClientInServer();
 922 }
 923
 924 void player_powerups (void)
 925 {
 926         if (cvar("g_minstagib"))
 927         {
 928                 self.effects = EF_FULLBRIGHT;
 929                 if (self.items & IT_STRENGTH)
 930                 {
 931                         if (time > self.strength_finished)
 932                         {
 933                                 self.alpha = default_player_alpha;
 934                                 self.exteriorweaponentity.alpha = default_weapon_alpha;
 935                                 self.items = self.items - (self.items & IT_STRENGTH);
 936                                 sprint(self, "^3Invisibility has worn off\n");
 937                         }
 938                 }
 939                 else
 940                 {
 941                         if (time < self.strength_finished)
 942                         {
 943                                 self.alpha = cvar("g_minstagib_invis_alpha");
 944                                 self.exteriorweaponentity.alpha = cvar("g_minstagib_invis_alpha");
 945                                 self.items = self.items | IT_STRENGTH;
 946                                 sprint(self, "^3You are invisible\n");
 947                         }
 948                 }
 949
 950                 if (self.items & IT_INVINCIBLE)
 951                 {
 952                         if (time > self.invincible_finished)
 953                         {
 954                                 self.items = self.items - (self.items & IT_INVINCIBLE);
 955                                 sprint(self, "^3Speed has worn off\n");
 956                         }
 957                 }
 958                 else
 959                 {
 960                         if (time < self.invincible_finished)
 961                         {
 962                                 self.items = self.items | IT_INVINCIBLE;
 963                                 sprint(self, "^3You are on speed\n");
 964                         }
 965                 }
 966                 return;
 967         }
 968
 969         self.effects = self.effects - (self.effects & (EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT));
 970         if (self.items & IT_STRENGTH)
 971         {
 972                 self.effects = self.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
 973                 if (time > self.strength_finished)
 974                 {
 975                         self.items = self.items - (self.items & IT_STRENGTH);
 976                         sprint(self, "^3Strength has worn off\n");
 977                 }
 978         }
 979         else
 980         {
 981                 if (time < self.strength_finished)
 982                 {
 983                         self.items = self.items | IT_STRENGTH;
 984                         sprint(self, "^3Strength infuses your weapons with devastating power\n");
 985                 }
 986         }
 987         if (self.items & IT_INVINCIBLE)
 988         {
 989                 self.effects = self.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
 990                 if (time > self.invincible_finished)
 991                 {
 992                         self.items = self.items - (self.items & IT_INVINCIBLE);
 993                         sprint(self, "^3Shield has worn off\n");
 994                 }
 995         }
 996         else
 997         {
 998                 if (time < self.invincible_finished)
 999                 {
1000                         self.items = self.items | IT_INVINCIBLE;
1001                         sprint(self, "^3Shield surrounds you\n");
1002                 }
1003         }
1004
1005         if (cvar("g_fullbrightplayers"))
1006                 self.effects = self.effects | EF_FULLBRIGHT;
1007
1008         // midair gamemode: damage only while in the air
1009         // if in midair mode, being on ground grants temporary invulnerability
1010         // (this is so that multishot weapon don't clear the ground flag on the
1011         // first damage in the frame, leaving the player vulnerable to the
1012         // remaining hits in the same frame)
1013         if (self.flags & FL_ONGROUND)
1014         if (cvar("g_midair"))
1015                 self.spawnshieldtime = max(self.spawnshieldtime, time + cvar("g_midair_shieldtime"));
1016
1017         if (time < self.spawnshieldtime)
1018                 self.effects = self.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1019 }
1020
1021 float CalcRegen(float current, float stable, float regenfactor)
1022 {
1023         if(current > stable)
1024                 return current;
1025         else if(current > stable - 0.25) // when close enough, "snap"
1026                 return stable;
1027         else
1028                 return min(stable, current + (stable - current) * regenfactor * frametime);
1029 }
1030
1031 void player_regen (void)
1032 {
1033         float maxh, maxa, limith, limita, max_mod, regen_mod, rot_mod, limit_mod;
1034         maxh = cvar("g_balance_health_stable");
1035         maxa = cvar("g_balance_armor_stable");
1036         limith = cvar("g_balance_health_limit");
1037         limita = cvar("g_balance_armor_limit");
1038
1039         if (cvar("g_minstagib") || (cvar("g_lms") && !cvar("g_lms_regenerate")))
1040                 return;
1041
1042         max_mod = regen_mod = rot_mod = limit_mod = 1;
1043
1044         if (self.runes & RUNE_REGEN)
1045         {
1046                 if (self.runes & CURSE_VENOM) // do we have both rune/curse?
1047                 {
1048                         regen_mod = cvar("g_balance_rune_regen_combo_regenrate");
1049                         max_mod = cvar("g_balance_rune_regen_combo_hpmod");
1050                         limit_mod = cvar("g_balance_rune_regen_combo_limitmod");
1051                 }
1052                 else
1053                 {
1054                         regen_mod = cvar("g_balance_rune_regen_regenrate");
1055                         max_mod = cvar("g_balance_rune_regen_hpmod");
1056                         limit_mod = cvar("g_balance_rune_regen_limitmod");
1057                 }
1058         }
1059         else if (self.runes & CURSE_VENOM)
1060         {
1061                 max_mod = cvar("g_balance_curse_venom_hpmod");
1062                 if (self.runes & RUNE_REGEN) // do we have both rune/curse?
1063                         rot_mod = cvar("g_balance_rune_regen_combo_rotrate");
1064                 else
1065                         rot_mod = cvar("g_balance_curse_venom_rotrate");
1066                 limit_mod = cvar("g_balance_curse_venom_limitmod");
1067                 //if (!self.runes & RUNE_REGEN)
1068                 //      rot_mod = cvar("g_balance_curse_venom_rotrate");
1069         }
1070         maxh = maxh * max_mod;
1071         //maxa = maxa * max_mod;
1072         limith = limith * limit_mod;
1073         limita = limita * limit_mod;
1074
1075         if (self.armorvalue > maxa)
1076         {
1077                 if (time > self.pauserotarmor_finished)
1078                 {
1079                         self.armorvalue = max(maxa, self.armorvalue + (maxa - self.armorvalue) * cvar("g_balance_armor_rot") * frametime);
1080                         self.armorvalue = max(maxa, self.armorvalue - cvar("g_balance_armor_rotlinear") * frametime);
1081                 }
1082         }
1083         else if (self.armorvalue < maxa)
1084         {
1085                 if (time > self.pauseregen_finished)
1086                 {
1087                         self.armorvalue = CalcRegen(self.armorvalue, maxa, cvar("g_balance_armor_regen"));
1088                         self.armorvalue = min(maxa, self.armorvalue + cvar("g_balance_armor_regenlinear") * frametime);
1089                 }
1090         }
1091         if (self.health > maxh)
1092         {
1093                 if (time > self.pauserothealth_finished)
1094                 {
1095                         self.health = max(maxh, self.health + (maxh - self.health) * rot_mod*cvar("g_balance_health_rot") * frametime);
1096                         self.health = max(maxh, self.health - rot_mod*cvar("g_balance_health_rotlinear") * frametime);
1097                 }
1098         }
1099         else if (self.health < maxh)
1100         {
1101                 if (time > self.pauseregen_finished)
1102                 {
1103                         self.health = CalcRegen(self.health, maxh, regen_mod * cvar("g_balance_health_regen"));
1104                         self.health = min(maxh, self.health + regen_mod*cvar("g_balance_health_regenlinear") * frametime);
1105                 }
1106         }
1107
1108         if (self.health > limith)
1109                 self.health = limith;
1110         if (self.armorvalue > limita)
1111                 self.armorvalue = limita;
1112
1113         // if player rotted to death...  die!
1114         if(self.health < 1)
1115                 self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
1116 }
1117
1118 /*
1119 ======================
1120 spectate mode routines
1121 ======================
1122 */
1123 void SpectateCopy(entity spectatee) {
1124         self.armortype = spectatee.armortype;
1125         self.armorvalue = spectatee.armorvalue;
1126         self.currentammo = spectatee.currentammo;
1127         self.effects = spectatee.effects;
1128         self.health = spectatee.health;
1129         self.impulse = 0;
1130         self.items = spectatee.items;
1131         self.punchangle = spectatee.punchangle;
1132         self.view_ofs = spectatee.view_ofs;
1133         self.v_angle = spectatee.v_angle;
1134         self.viewzoom = spectatee.viewzoom;
1135         setorigin(self, spectatee.origin);
1136         setsize(self, spectatee.mins, spectatee.maxs);
1137 }
1138
1139 void SpectateUpdate() {
1140         if(!self.enemy)
1141                         PutObserverInServer();
1142
1143         if (self != self.enemy) {
1144                 if(self.enemy.flags & FL_NOTARGET)
1145                         PutObserverInServer();
1146                 SpectateCopy(self.enemy);
1147                 self.dmg_take = self.enemy.dmg_take;
1148                 self.dmg_save = self.enemy.dmg_save;
1149                 self.dmg_inflictor = self.enemy.dmg_inflictor;
1150                 self.fixangle = TRUE;
1151                 self.angles = self.enemy.v_angle;
1152                 //msg_entity = self;
1153                 //WriteByte(MSG_ONE, SVC_SETANGLE);
1154                 //WriteAngle(MSG_ONE, self.enemy.v_angle_x);
1155                 //WriteAngle(MSG_ONE, self.enemy.v_angle_y);
1156                 //WriteAngle(MSG_ONE, self.enemy.v_angle_z);
1157         }
1158 }
1159
1160 float SpectateNext() {
1161         other = find(self.enemy, classname, "player");
1162         if (!other) {
1163                 other = find(other, classname, "player");
1164         }
1165         if (other) {
1166                 self.enemy = other;
1167         }
1168         if(self.enemy.classname == "player") {
1169                 msg_entity = self;
1170                 WriteByte(MSG_ONE, SVC_SETVIEW);
1171                 WriteEntity(MSG_ONE, self.enemy);
1172                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
1173                 SpectateUpdate();
1174                 return 1;
1175         } else {
1176                 return 0;
1177         }
1178 }
1179
1180 /*
1181 =============
1182 ShowRespawnCountdown()
1183
1184 Update a respawn countdown display.
1185 =============
1186 */
1187 void ShowRespawnCountdown()
1188 {
1189         float number;
1190         if(self.deadflag == DEAD_NO) // just respawned?
1191                 return;
1192         else
1193         {
1194                 number = ceil(self.death_time - time);
1195                 if(number <= 0)
1196                         return;
1197                 if(number <= self.respawn_countdown)
1198                 {
1199                         self.respawn_countdown = number - 1;
1200                         if(ceil(self.death_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
1201                                 play2(self, strcat("announcer/robotic/", ftos(number), ".ogg"));
1202                 }
1203         }
1204 }
1205
1206 void LeaveSpectatorMode()
1207 {
1208         if(!cvar("teamplay") || cvar("g_campaign") || cvar("g_balance_teams")) {
1209                 self.classname = "player";
1210                 if(cvar("g_campaign") || cvar("g_balance_teams"))
1211                         JoinBestTeam(self, 0);
1212                 if(cvar("g_campaign"))
1213                         campaign_bots_may_start = 1;
1214                 PutClientInServer();
1215                 if(!(self.flags & FL_NOTARGET))
1216                         bprint ("^4", self.netname, "^4 is playing now\n");
1217                 centerprint(self,"");
1218                 return;
1219         } else {
1220                 stuffcmd(self,"menu_showteamselect\n");
1221                 return;
1222         }
1223 }
1224
1225 /*
1226 =============
1227 PlayerPreThink
1228
1229 Called every frame for each client before the physics are run
1230 =============
1231 */
1232 void() ctf_setstatus;
1233 .float vote_nagtime;
1234 void PlayerPreThink (void)
1235 {
1236         // version nagging
1237         if(self.version_nagtime)
1238                 if(self.cvar_g_nexuizversion)
1239                         if(time > self.version_nagtime)
1240                         {
1241                                 if(strstr(self.cvar_g_nexuizversion, "svn", 0) < 0)
1242                                         if(self.cvar_g_nexuizversion != cvar_string("g_nexuizversion"))
1243                                         {
1244                                                 dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Nexuiz ", cvar_string("g_nexuizversion"), "^7, you have ^3Nexuiz ", self.cvar_g_nexuizversion, "\n");
1245                                                 sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Nexuiz ", cvar_string("g_nexuizversion"), "^7, you have ^3Nexuiz ", self.cvar_g_nexuizversion, "\n"));
1246                                         }
1247                                 self.version_nagtime = 0;
1248                         }
1249
1250         // vote nagging
1251         if(self.cvar_scr_centertime)
1252                 if(time > self.vote_nagtime)
1253                 {
1254                         VoteNag();
1255                         self.vote_nagtime = time + self.cvar_scr_centertime * 0.6;
1256                 }
1257
1258         // GOD MODE info
1259         if(!(self.flags & FL_GODMODE)) if(self.max_armorvalue)
1260         {
1261                 sprint(self, strcat("godmode saved you ", ftos(self.max_armorvalue), " units of damage, cheater!\n"));
1262                 self.max_armorvalue = 0;
1263         }
1264
1265         if(self.classname == "player") {
1266                 local vector m1, m2;
1267
1268 //              if(self.netname == "Wazat")
1269 //                      bprint(self.classname, "\n");
1270
1271                 CheckRules_Player();
1272
1273                 if(self.button7)
1274                         PrintWelcomeMessage(self);
1275
1276                 if(cvar("g_lms") || !cvar("sv_spectate"))
1277                 if((time - self.jointime) <= cvar("welcome_message_time"))
1278                         PrintWelcomeMessage(self);
1279
1280                 if (intermission_running)
1281                 {
1282                         IntermissionThink ();   // otherwise a button could be missed between
1283                         return;                                 // the think tics
1284                 }
1285
1286                 if(time > self.teleport_time)
1287                 {
1288                         self.effects = self.effects - (self.effects & EF_NODRAW);
1289                         if(self.weaponentity)
1290                                 self.weaponentity.flags = self.weaponentity.flags - (self.weaponentity.flags & EF_NODRAW);
1291                 }
1292
1293                 Nixnex_GiveCurrentWeapon();
1294                 UpdateSelectedPlayer();
1295
1296                 if (self.deadflag != DEAD_NO)
1297                 {
1298                         float button_pressed, force_respawn;
1299                         player_anim();
1300                         button_pressed = (self.button0 || self.button2 || self.button3 || self.button6 || self.buttonuse);
1301                         force_respawn = (cvar("g_lms") || cvar("g_forced_respawn"));
1302                         if (self.deadflag == DEAD_DYING)
1303                         {
1304                                 if(force_respawn)
1305                                         self.deadflag = DEAD_RESPAWNING;
1306                                 else if(!button_pressed)
1307                                         self.deadflag = DEAD_DEAD;
1308                         }
1309                         else if (self.deadflag == DEAD_DEAD)
1310                         {
1311                                 if(button_pressed)
1312                                         self.deadflag = DEAD_RESPAWNABLE;
1313                         }
1314                         else if (self.deadflag == DEAD_RESPAWNABLE)
1315                         {
1316                                 if(!button_pressed)
1317                                         self.deadflag = DEAD_RESPAWNING;
1318                         }
1319                         else if (self.deadflag == DEAD_RESPAWNING)
1320                         {
1321                                 if(time > self.death_time)
1322                                         respawn();
1323                         }
1324                         ShowRespawnCountdown();
1325                         return;
1326                 }
1327
1328                 if(cvar("g_lms") && !self.deadflag && cvar("g_lms_campcheck_interval"))
1329                 {
1330                         vector dist;
1331
1332                         // calculate player movement (in 2 dimensions only, so jumping on one spot doesn't count as movement)
1333                         dist = self.oldorigin - self.origin;
1334                         dist_z = 0;
1335                         self.lms_traveled_distance += fabs(vlen(dist));
1336
1337                         if(cvar("g_campaign"))
1338                         if(!campaign_bots_may_start)
1339                         {
1340                                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval")*2;
1341                                 self.lms_traveled_distance = 0;
1342                         }
1343
1344                         if(time > self.lms_nextcheck)
1345                         {
1346                                 //sprint(self, "distance: ", ftos(self.lms_traveled_distance), "\n");
1347                                 if(self.lms_traveled_distance < cvar("g_lms_campcheck_distance"))
1348                                 {
1349                                         centerprint(self, cvar_string("g_lms_campcheck_message"));
1350                                         // FIXME KadaverJack: gibbing player here causes playermodel to bounce around, instead of eye.md3
1351                                         // I wasn't able to find out WHY that happens, so I put a workaround in place that shall prevent players from being gibbed :(
1352                                         Damage(self, self, self, bound(0, cvar("g_lms_campcheck_damage"), self.health + self.armorvalue * cvar("g_balance_armor_blockpercent") + 5), DEATH_CAMP, self.origin, '0 0 0');
1353                                 }
1354                                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval");
1355                                 self.lms_traveled_distance = 0;
1356                         }
1357                 }
1358
1359                 if (self.button5 && !self.hook.state)
1360                 {
1361                         if (!self.crouch)
1362                         {
1363                                 self.crouch = TRUE;
1364                                 self.view_ofs = PL_CROUCH_VIEW_OFS;
1365                                 setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX);
1366                         }
1367                 }
1368                 else
1369                 {
1370                         if (self.crouch)
1371                         {
1372                                 tracebox(self.origin, PL_MIN, PL_MAX, self.origin, FALSE, self);
1373                                 if (!trace_startsolid)
1374                                 {
1375                                         self.crouch = FALSE;
1376                                         self.view_ofs = PL_VIEW_OFS;
1377                                         setsize (self, PL_MIN, PL_MAX);
1378                                 }
1379                         }
1380                 }
1381
1382                 if(cvar("sv_defaultcharacter") == 1) {
1383                         local string defaultmodel;
1384                         defaultmodel = cvar_string("sv_defaultplayermodel");
1385
1386                         if (defaultmodel != self.model)
1387                         {
1388                                 m1 = self.mins;
1389                                 m2 = self.maxs;
1390                                 setmodel_lod (self, defaultmodel);
1391                                 setsize (self, m1, m2);
1392                         }
1393
1394                         if (self.skin != cvar("sv_defaultplayerskin"))
1395                                 self.skin = cvar("sv_defaultplayerskin");
1396                         if(!teams_matter)
1397                                 if(strlen(cvar_string("sv_defaultplayercolors")))
1398                                         if(self.clientcolors != cvar("sv_defaultplayercolors"))
1399                                                 setcolor(self, cvar("sv_defaultplayercolors"));
1400                 } else {
1401                         if (self.playermodel != self.model)
1402                         {
1403                                 self.playermodel = CheckPlayerModel(self.playermodel);
1404                                 m1 = self.mins;
1405                                 m2 = self.maxs;
1406                                 setmodel_lod (self, self.playermodel);
1407                                 setsize (self, m1, m2);
1408                         }
1409
1410                         if(teams_matter)
1411                         {
1412                                 if (self.skin != math_mod(stof(self.playerskin), NUM_PLAYERSKINS_TEAMPLAY))
1413                                         self.skin = math_mod(stof(self.playerskin), NUM_PLAYERSKINS_TEAMPLAY);
1414                         }
1415                         else
1416                         {
1417                                 if (self.skin != stof(self.playerskin))
1418                                         self.skin = stof(self.playerskin);
1419                         }
1420                 }
1421
1422                 GrapplingHookFrame();
1423
1424                 W_WeaponFrame();
1425
1426                 {
1427                         float zoomfactor, zoomspeed, zoomdir;
1428                         zoomfactor = self.cvar_cl_zoomfactor;
1429                         if(zoomfactor < 1 || zoomfactor > 16)
1430                                 zoomfactor = 2.5;
1431                         zoomspeed = self.cvar_cl_zoomspeed;
1432                         if(zoomspeed >= 0) // < 0 is instant zoom
1433                                 if(zoomspeed < 0.5 || zoomspeed > 16)
1434                                         zoomspeed = 3.5;
1435
1436                         zoomdir = self.button4;
1437                         if(self.button3)
1438                                 if(self.weapon == WEP_NEX)
1439                                         if(!cvar("g_minstagib"))
1440                                                 zoomdir = 1;
1441
1442                         if(zoomdir)
1443                                 self.has_zoomed = 1;
1444
1445                         if(self.has_zoomed)
1446                         {
1447                                 if(zoomspeed <= 0) // instant zoom
1448                                 {
1449                                         if(zoomdir)
1450                                                 self.viewzoom = 1 / zoomfactor;
1451                                         else
1452                                                 self.viewzoom = 1;
1453                                 }
1454                                 else
1455                                 {
1456                                         // geometric zoom would be:
1457                                         //   self.viewzoom = bound(1 / zoomfactor, self.viewzoom * pow(zoomfactor, (zoomdir ? -1 : 1) * frametime * zoomspeed), 1);
1458                                         // however, testing showed that arithmetic/harmonic zoom works better
1459                                         if(zoomdir)
1460                                                 // self.viewzoom = 1 / bound(1, 1 / self.viewzoom + (zoomdir ? 1 : -1) * frametime * zoomspeed * (zoomfactor - 1), zoomfactor);
1461                                                 // zoom in = arithmetic: 1x, 2x, 3x, 4x, ..., 8x
1462                                                 self.viewzoom = 1 / bound(1, 1 / self.viewzoom + frametime * zoomspeed * (zoomfactor - 1), zoomfactor);
1463                                         else
1464                                                 // self.viewzoom = bound(1 / zoomfactor, self.viewzoom + (zoomdir ? -1 : 1) * frametime * zoomspeed * (1 - 1 / zoomfactor), 1);
1465                                                 // zoom out = harmonic: 8/1x, 8/2x, 8/3x, 8/4x, ..., 8/8x
1466                                                 self.viewzoom = bound(1 / zoomfactor, self.viewzoom + frametime * zoomspeed * (1 - 1 / zoomfactor), 1);
1467                                 }
1468                         }
1469                         else
1470                                 self.viewzoom = min(1, self.viewzoom + frametime); // spawn zoom-in
1471                 }
1472
1473                 player_powerups();
1474                 player_regen();
1475                 player_anim();
1476
1477                 if (cvar("g_minstagib"))
1478                         minstagib_ammocheck();
1479
1480                 ctf_setstatus();
1481                 kh_setstatus();
1482
1483                 //self.angles_y=self.v_angle_y + 90;   // temp
1484
1485                 //if (TetrisPreFrame()) return;
1486         } else if(gameover) {
1487                 if (intermission_running)
1488                         IntermissionThink ();   // otherwise a button could be missed between
1489                 return;
1490         } else if(self.classname == "observer") {
1491
1492                 if (self.flags & FL_JUMPRELEASED) {
1493                         if (self.button2 && self.version == cvar("gameversion")) {
1494                                 self.welcomemessage_time = 0;
1495                                 self.flags = self.flags - FL_JUMPRELEASED;
1496                                 LeaveSpectatorMode();
1497                                 return;
1498                         } else if(self.button0 && self.version == cvar("gameversion")) {
1499                                 self.welcomemessage_time = 0;
1500                                 self.flags = self.flags - FL_JUMPRELEASED;
1501                                 if(SpectateNext() == 1) {
1502                                         self.classname = "spectator";
1503                                 }
1504                         }
1505                 } else {
1506                         if (!(self.button0 || self.button2)) {
1507                                 self.flags = self.flags | FL_JUMPRELEASED;
1508                         }
1509                 }
1510                 PrintWelcomeMessage(self);
1511         } else if(self.classname == "spectator") {
1512                 if (self.flags & FL_JUMPRELEASED) {
1513                         if (self.button2 && self.version == cvar("gameversion")) {
1514                                 self.welcomemessage_time = 0;
1515                                 self.flags = self.flags - FL_JUMPRELEASED;
1516                                 LeaveSpectatorMode();
1517                                 return;
1518                         } else if(self.button0) {
1519                                 self.welcomemessage_time = 0;
1520                                 self.flags = self.flags - FL_JUMPRELEASED;
1521                                 if(SpectateNext() == 1) {
1522                                         self.classname = "spectator";
1523                                 } else {
1524                                         self.classname = "observer";
1525                                         PutClientInServer();
1526                                 }
1527                         } else if (self.button3) {
1528                                 self.welcomemessage_time = 0;
1529                                 self.flags = self.flags - FL_JUMPRELEASED;
1530                                 self.classname = "observer";
1531                                 PutClientInServer();
1532                         } else {
1533                                 SpectateUpdate();
1534                         }
1535                 } else {
1536                         if (!(self.button0 || self.button3)) {
1537                                 self.flags = self.flags | FL_JUMPRELEASED;
1538                         }
1539                 }
1540                 PrintWelcomeMessage(self);
1541                 self.flags = self.flags | FL_CLIENT | FL_NOTARGET;
1542         }
1543 }
1544
1545
1546 /*
1547 =============
1548 PlayerPostThink
1549
1550 Called every frame for each client after the physics are run
1551 =============
1552 */
1553 void PlayerPostThink (void)
1554 {
1555         // Savage: Check for nameless players
1556         if (strlen(self.netname) < 1) {
1557                 self.netname = "Player";
1558                 stuffcmd(self, "seta _cl_name Player\n");
1559         }
1560
1561         if(self.classname == "player") {
1562                 CheckRules_Player();
1563                 UpdateChatBubble();
1564                 UpdateTeamBubble();
1565                 if (self.impulse)
1566                         ImpulseCommands ();
1567                 if (intermission_running)
1568                         return;         // intermission or finale
1569
1570                 //PrintWelcomeMessage(self);
1571                 //if (TetrisPostFrame()) return;
1572         } else if (self.classname == "observer") {
1573                 //do nothing
1574         } else if (self.classname == "spectator") {
1575                 //do nothing
1576         }
1577         Arena_Warmup();
1578 }