data/qcsrc/server/cl_client.qc

   1 // let's abuse an existing field
   2 #define SPAWNPOINT_SCORE frags
   3
   4 .float wantswelcomemessage;
   5 .string netname_previous;
   6
   7 void spawnfunc_info_player_survivor (void)
   8 {
   9         spawnfunc_info_player_deathmatch();
  10 }
  11
  12 void spawnfunc_info_player_start (void)
  13 {
  14         spawnfunc_info_player_deathmatch();
  15 }
  16
  17 void spawnfunc_info_player_deathmatch (void)
  18 {
  19         self.classname = "info_player_deathmatch";
  20         relocate_spawnpoint();
  21 }
  22
  23 void spawnpoint_use()
  24 {
  25         if(teams_matter)
  26         if(have_team_spawns)
  27         {
  28                 self.team = activator.team;
  29                 some_spawn_has_been_used = 1;
  30         }
  31 };
  32
  33 // Returns:
  34 //   -1 if a spawn can't be used
  35 //   otherwise, a weight of the spawnpoint
  36 float Spawn_Score(entity spot, entity playerlist, float teamcheck)
  37 {
  38         float shortest, thisdist;
  39         entity player;
  40
  41         // filter out spots for the wrong team
  42         if(teamcheck)
  43         if(spot.team != teamcheck)
  44                 return -1;
  45
  46         // filter out spots for assault
  47         if(spot.target != "") {
  48                 local entity ent;
  49                 ent = find(world, targetname, spot.target);
  50                 while(ent) {
  51                         if(ent.classname == "target_objective")
  52                                 if(ent.health < 0 || ent.health >= ASSAULT_VALUE_INACTIVE)
  53                                         return -1;
  54                         ent = find(ent, targetname, spot.target);
  55                 }
  56         }
  57
  58         player = playerlist;
  59         shortest = vlen(world.maxs - world.mins);
  60         for(player = playerlist; player; player = player.chain)
  61                 if (player != self)
  62                 {
  63                         thisdist = vlen(player.origin - spot.origin);
  64                         if (thisdist < shortest)
  65                                 shortest = thisdist;
  66                 }
  67         return shortest;
  68 }
  69
  70 float spawn_allbad;
  71 float spawn_allgood;
  72 entity Spawn_FilterOutBadSpots(entity firstspot, entity playerlist, float mindist, float teamcheck)
  73 {
  74         local entity spot, spotlist, spotlistend;
  75         spawn_allgood = TRUE;
  76         spawn_allbad = TRUE;
  77
  78         spotlist = world;
  79         spotlistend = world;
  80
  81         for(spot = firstspot; spot; spot = spot.chain)
  82         {
  83                 spot.SPAWNPOINT_SCORE = Spawn_Score(spot, playerlist, teamcheck);
  84
  85                 if(cvar("spawn_debugview"))
  86                 {
  87                         setmodel(spot, "models/runematch/rune.mdl");
  88                         if(spot.SPAWNPOINT_SCORE < mindist)
  89                         {
  90                                 spot.colormod = '1 0 0';
  91                                 spot.scale = 1;
  92                         }
  93                         else
  94                         {
  95                                 spot.colormod = '0 1 0';
  96                                 spot.scale = spot.SPAWNPOINT_SCORE / mindist;
  97                         }
  98                 }
  99
 100                 if(spot.SPAWNPOINT_SCORE >= 0) // spawning allowed here
 101                 {
 102                         if(spot.SPAWNPOINT_SCORE < mindist)
 103                         {
 104                                 // too short distance
 105                                 spawn_allgood = FALSE;
 106                         }
 107                         else
 108                         {
 109                                 // perfect
 110                                 spawn_allbad = FALSE;
 111
 112                                 if(spotlistend)
 113                                         spotlistend.chain = spot;
 114                                 spotlistend = spot;
 115                                 if(!spotlist)
 116                                         spotlist = spot;
 117
 118                                 /*
 119                                 if(teamcheck)
 120                                 if(spot.team != teamcheck)
 121                                         error("invalid spawn added");
 122
 123                                 print("added ", etos(spot), "\n");
 124                                 */
 125                         }
 126                 }
 127         }
 128         if(spotlistend)
 129                 spotlistend.chain = world;
 130
 131         /*
 132                 entity e;
 133                 if(teamcheck)
 134                         for(e = spotlist; e; e = e.chain)
 135                         {
 136                                 print("seen ", etos(e), "\n");
 137                                 if(e.team != teamcheck)
 138                                         error("invalid spawn found");
 139                         }
 140         */
 141
 142         return spotlist;
 143 }
 144
 145 entity Spawn_WeightedPoint(entity firstspot, float lower, float upper, float exponent)
 146 {
 147         // weight of a point: bound(lower, mindisttoplayer, upper)^exponent
 148         // multiplied by spot.cnt (useful if you distribute many spawnpoints in a small area)
 149         local entity spot;
 150
 151         RandomSelection_Init();
 152         for(spot = firstspot; spot; spot = spot.chain)
 153                 RandomSelection_Add(spot, 0, pow(bound(lower, spot.SPAWNPOINT_SCORE, upper), exponent) * spot.cnt, spot.SPAWNPOINT_SCORE >= lower);
 154
 155         return RandomSelection_chosen_ent;
 156 }
 157
 158 /*
 159 =============
 160 SelectSpawnPoint
 161
 162 Finds a point to respawn
 163 =============
 164 */
 165 entity SelectSpawnPoint (float anypoint)
 166 {
 167         local float teamcheck;
 168         local entity firstspot_new;
 169         local entity spot, firstspot, playerlist;
 170
 171         spot = find (world, classname, "testplayerstart");
 172         if (spot)
 173                 return spot;
 174
 175         teamcheck = 0;
 176
 177         if(!anypoint && have_team_spawns)
 178                 teamcheck = self.team;
 179
 180         // get the list of players
 181         playerlist = findchain(classname, "player");
 182         // get the entire list of spots
 183         firstspot = findchain(classname, "info_player_deathmatch");
 184         // filter out the bad ones
 185         // (note this returns the original list if none survived)
 186         firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, 100, teamcheck);
 187         if(!firstspot_new)
 188                 firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, -1, teamcheck);
 189         firstspot = firstspot_new;
 190
 191         // there is 50/50 chance of choosing a random spot or the furthest spot
 192         // (this means that roughly every other spawn will be furthest, so you
 193         // usually won't get fragged at spawn twice in a row)
 194         if (arena_roundbased)
 195         {
 196                 firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, 800, teamcheck);
 197                 if(firstspot_new)
 198                         firstspot = firstspot_new;
 199                 spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 200         }
 201         else if (random() > cvar("g_spawn_furthest"))
 202                 spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 203         else
 204                 spot = Spawn_WeightedPoint(firstspot, 1, 5000, 5); // chooses a far far away spawnpoint
 205
 206         if(cvar("spawn_debugview"))
 207         {
 208                 print("spot mindistance: ", ftos(spot.SPAWNPOINT_SCORE), "\n");
 209
 210                 entity e;
 211                 if(teamcheck)
 212                         for(e = firstspot; e; e = e.chain)
 213                                 if(e.team != teamcheck)
 214                                         error("invalid spawn found");
 215         }
 216
 217         if (!spot)
 218         {
 219                 if(cvar("spawn_debug"))
 220                         GotoNextMap();
 221                 else
 222                 {
 223                         if(some_spawn_has_been_used)
 224                                 return world; // team can't spawn any more, because of actions of other team
 225                         else
 226                                 error("Cannot find a spawn point - please fix the map!");
 227                 }
 228         }
 229
 230         return spot;
 231 }
 232
 233 /*
 234 =============
 235 CheckPlayerModel
 236
 237 Checks if the argument string can be a valid playermodel.
 238 Returns a valid one in doubt.
 239 =============
 240 */
 241 string FallbackPlayerModel = "models/player/marine.zym";
 242 string CheckPlayerModel(string plyermodel) {
 243         if(strlen(plyermodel) < 4)
 244                 return FallbackPlayerModel;
 245         if( substring(plyermodel,0,14) != "models/player/")
 246                 return FallbackPlayerModel;
 247         else if(cvar("sv_servermodelsonly"))
 248         {
 249                 if(substring(plyermodel,strlen(plyermodel)-4,4) != ".zym")
 250                 if(substring(plyermodel,strlen(plyermodel)-4,4) != ".dpm")
 251                 if(substring(plyermodel,strlen(plyermodel)-4,4) != ".md3")
 252                 if(substring(plyermodel,strlen(plyermodel)-4,4) != ".psk")
 253                         return FallbackPlayerModel;
 254                 if(!fexists(plyermodel))
 255                         return FallbackPlayerModel;
 256         }
 257         return plyermodel;
 258 }
 259
 260 /*
 261 =============
 262 Client_customizeentityforclient
 263
 264 LOD reduction
 265 =============
 266 */
 267 float Client_customizeentityforclient()
 268 {
 269 #ifdef ALLOW_VARIABLE_LOD
 270         // self: me
 271         // other: the player viewing me
 272         float distance;
 273         float f;
 274
 275         if(self.flags & FL_NOTARGET) // we don't need LOD for spectators
 276                 return TRUE;
 277
 278         if(other.cvar_cl_playerdetailreduction <= 0)
 279         {
 280                 if(other.cvar_cl_playerdetailreduction <= -2)
 281                         self.modelindex = self.modelindex_lod2;
 282                 else if(other.cvar_cl_playerdetailreduction <= -1)
 283                         self.modelindex = self.modelindex_lod1;
 284                 else
 285                         self.modelindex = self.modelindex_lod0;
 286         }
 287         else
 288         {
 289                 distance = vlen(self.origin - other.origin);
 290                 f = (distance + 100.0) * other.cvar_cl_playerdetailreduction;
 291                 if(f > 10000)
 292                         self.modelindex = self.modelindex_lod2;
 293                 else if(f > 5000)
 294                         self.modelindex = self.modelindex_lod1;
 295                 else
 296                         self.modelindex = self.modelindex_lod0;
 297         }
 298 #endif
 299
 300         return TRUE;
 301 }
 302
 303 void UpdatePlayerSounds();
 304 void setmodel_lod(entity e, string modelname)
 305 {
 306 #ifdef ALLOW_VARIABLE_LOD
 307         string s;
 308
 309         // FIXME: this only supports 3-letter extensions
 310         s = strcat(substring(modelname, 0, strlen(modelname) - 4), "_1", substring(modelname, 0, strlen(modelname) - 4));
 311         if(fexists(s))
 312         {
 313                 precache_model(s);
 314                 setmodel(e, s); // players have high precision
 315                 self.modelindex_lod1 = self.modelindex;
 316         }
 317         else
 318                 self.modelindex_lod1 = -1;
 319
 320         s = strcat(substring(modelname, 0, strlen(modelname) - 4), "_2", substring(modelname, 0, strlen(modelname) - 4));
 321         if(fexists(s))
 322         {
 323                 precache_model(s);
 324                 setmodel(e, s); // players have high precision
 325                 self.modelindex_lod2 = self.modelindex;
 326         }
 327         else
 328                 self.modelindex_lod2 = -1;
 329
 330         precache_model(modelname);
 331         setmodel(e, modelname); // players have high precision
 332         self.modelindex_lod0 = self.modelindex;
 333
 334         if(self.modelindex_lod1 < 0)
 335                 self.modelindex_lod1 = self.modelindex;
 336
 337         if(self.modelindex_lod2 < 0)
 338                 self.modelindex_lod2 = self.modelindex;
 339 #else
 340         precache_model(modelname);
 341         setmodel(e, modelname); // players have high precision
 342 #endif
 343         player_setupanimsformodel();
 344         UpdatePlayerSounds();
 345 }
 346
 347 /*
 348 =============
 349 PutObserverInServer
 350
 351 putting a client as observer in the server
 352 =============
 353 */
 354 void PutObserverInServer (void)
 355 {
 356         entity  spot;
 357         spot = SelectSpawnPoint (TRUE);
 358         if(!spot)
 359                 error("No spawnpoints for observers?!?\n");
 360         RemoveGrapplingHook(self); // Wazat's Grappling Hook
 361
 362         if(clienttype(self) == CLIENTTYPE_REAL)
 363         {
 364                 msg_entity = self;
 365                 WriteByte(MSG_ONE, SVC_SETVIEW);
 366                 WriteEntity(MSG_ONE, self);
 367         }
 368
 369         DropAllRunes(self);
 370         kh_Key_DropAll(self, TRUE);
 371
 372         if(self.flagcarried)
 373                 DropFlag(self.flagcarried);
 374
 375         WaypointSprite_PlayerDead();
 376
 377         if(self.killcount != -666)
 378         {
 379                 if(g_lms)
 380                 {
 381                         if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
 382                                 bprint ("^4", self.netname, "^4 has no more lives left\n");
 383                         else
 384                                 bprint ("^4", self.netname, "^4 is spectating now\n"); // TODO turn this into a proper forfeit?
 385                 }
 386                 else
 387                         bprint ("^4", self.netname, "^4 is spectating now\n");
 388         }
 389
 390         PlayerScore_Clear(self); // clear scores when needed
 391
 392         self.spectatortime = time;
 393
 394         self.classname = "observer";
 395         self.health = -666;
 396         self.takedamage = DAMAGE_NO;
 397         self.solid = SOLID_NOT;
 398         self.movetype = MOVETYPE_NOCLIP;
 399         self.flags = FL_CLIENT | FL_NOTARGET;
 400         self.armorvalue = 666;
 401         self.effects = 0;
 402         self.armorvalue = cvar("g_balance_armor_start");
 403         self.pauserotarmor_finished = 0;
 404         self.pauserothealth_finished = 0;
 405         self.pauseregen_finished = 0;
 406         self.damageforcescale = 0;
 407         self.death_time = 0;
 408         self.dead_frame = 0;
 409         self.alpha = 0;
 410         self.scale = 0;
 411         self.fade_time = 0;
 412         self.pain_frame = 0;
 413         self.pain_finished = 0;
 414         self.strength_finished = 0;
 415         self.invincible_finished = 0;
 416         self.pushltime = 0;
 417         self.think = SUB_Null;
 418         self.nextthink = 0;
 419         self.hook_time = 0;
 420         self.runes = 0;
 421         self.deadflag = DEAD_NO;
 422         self.angles = spot.angles;
 423         self.angles_z = 0;
 424         self.fixangle = TRUE;
 425         self.crouch = FALSE;
 426
 427         self.view_ofs = PL_VIEW_OFS;
 428         setorigin (self, spot.origin);
 429         setsize (self, '0 0 0', '0 0 0');
 430         self.oldorigin = self.origin;
 431         self.items = 0;
 432         self.model = "";
 433         self.modelindex = 0;
 434         self.weapon = 0;
 435         self.weaponmodel = "";
 436         self.weaponentity = world;
 437         self.killcount = -666;
 438         self.velocity = '0 0 0';
 439         self.avelocity = '0 0 0';
 440         self.punchangle = '0 0 0';
 441         self.punchvector = '0 0 0';
 442         self.oldvelocity = self.velocity;
 443         self.customizeentityforclient = Client_customizeentityforclient;
 444         self.viewzoom = 1;
 445         self.wantswelcomemessage = 1;
 446
 447         if(g_arena)
 448         {
 449                 if(self.version_mismatch)
 450                 {
 451                         Spawnqueue_Unmark(self);
 452                         Spawnqueue_Remove(self);
 453                 }
 454                 else
 455                 {
 456                         Spawnqueue_Insert(self);
 457                 }
 458         }
 459         else if(g_lms)
 460         {
 461                 // Only if the player cannot play at all
 462                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) == 666)
 463                         self.frags = -666;
 464                 else
 465                         self.frags = -667;
 466         }
 467         else
 468                 self.frags = -666;
 469 }
 470
 471 float RestrictSkin(float s)
 472 {
 473         if(!teams_matter)
 474                 return s;
 475         if(s == 6)
 476                 return 6;
 477         return mod(s, 3);
 478 }
 479
 480 void FixPlayermodel()
 481 {
 482         local string defaultmodel;
 483         local float defaultskin;
 484         local vector m1, m2;
 485
 486         defaultmodel = "";
 487
 488         if(cvar("sv_defaultcharacter") == 1) {
 489                 defaultskin = 0;
 490
 491                 if(teams_matter)
 492                 {
 493                         defaultmodel = cvar_string(strcat("sv_defaultplayermodel_", Team_ColorNameLowerCase(self.team)));
 494                         defaultskin = cvar(strcat("sv_defaultplayerskin_", Team_ColorNameLowerCase(self.team)));
 495                 }
 496
 497                 if(defaultmodel == "")
 498                 {
 499                         defaultmodel = cvar_string("sv_defaultplayermodel");
 500                         defaultskin = cvar("sv_defaultplayerskin");
 501                 }
 502         }
 503
 504         if(defaultmodel != "")
 505         {
 506                 if (defaultmodel != self.model)
 507                 {
 508                         m1 = self.mins;
 509                         m2 = self.maxs;
 510                         setmodel_lod (self, defaultmodel);
 511                         setsize (self, m1, m2);
 512                 }
 513
 514                 self.skin = defaultskin;
 515         } else {
 516                 if (self.playermodel != self.model)
 517                 {
 518                         self.playermodel = CheckPlayerModel(self.playermodel);
 519                         m1 = self.mins;
 520                         m2 = self.maxs;
 521                         setmodel_lod (self, self.playermodel);
 522                         setsize (self, m1, m2);
 523                 }
 524
 525                 self.skin = RestrictSkin(stof(self.playerskin));
 526         }
 527
 528         if(!teams_matter)
 529                 if(strlen(cvar_string("sv_defaultplayercolors")))
 530                         if(self.clientcolors != cvar("sv_defaultplayercolors"))
 531                                 setcolor(self, cvar("sv_defaultplayercolors"));
 532 }
 533
 534 /*
 535 =============
 536 PutClientInServer
 537
 538 Called when a client spawns in the server
 539 =============
 540 */
 541 //void() ctf_playerchanged;
 542 void PutClientInServer (void)
 543 {
 544         if(clienttype(self) == CLIENTTYPE_BOT)
 545         {
 546                 self.classname = "player";
 547         }
 548         else if(clienttype(self) == CLIENTTYPE_REAL)
 549         {
 550                 msg_entity = self;
 551                 WriteByte(MSG_ONE, SVC_SETVIEW);
 552                 WriteEntity(MSG_ONE, self);
 553         }
 554
 555         // player is dead and becomes observer
 556         // FIXME fix LMS scoring for new system
 557         if(g_lms)
 558         {
 559                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
 560                         self.classname = "observer";
 561         }
 562
 563         if(g_arena)
 564         if(!self.spawned)
 565                 self.classname = "observer";
 566
 567         if(self.classname == "player") {
 568                 entity  spot;
 569
 570                 spot = SelectSpawnPoint (FALSE);
 571                 if(!spot)
 572                 {
 573                         centerprint(self, "Sorry, no spawnpoints available!\nHope your team can fix it...");
 574                         return; // spawn failed
 575                 }
 576
 577                 RemoveGrapplingHook(self); // Wazat's Grappling Hook
 578
 579                 self.classname = "player";
 580                 self.iscreature = TRUE;
 581                 self.movetype = MOVETYPE_WALK;
 582                 self.solid = SOLID_SLIDEBOX;
 583                 self.flags = FL_CLIENT;
 584                 self.takedamage = DAMAGE_AIM;
 585                 if(g_minstagib)
 586                         self.effects = EF_FULLBRIGHT;
 587                 else
 588                         self.effects = 0;
 589                 self.air_finished = time + 12;
 590                 self.dmg = 2;
 591
 592                 self.ammo_shells = start_ammo_shells;
 593                 self.ammo_nails = start_ammo_nails;
 594                 self.ammo_rockets = start_ammo_rockets;
 595                 self.ammo_cells = start_ammo_cells;
 596                 self.health = start_health;
 597                 self.armorvalue = start_armorvalue;
 598                 self.items = start_items;
 599                 self.switchweapon = start_switchweapon;
 600                 self.cnt = start_switchweapon;
 601                 self.weapon = 0;
 602                 self.jump_interval = time;
 603
 604                 self.spawnshieldtime = time + cvar("g_spawnshieldtime");
 605                 self.pauserotarmor_finished = time + cvar("g_balance_pause_armor_rot_spawn");
 606                 self.pauserothealth_finished = time + cvar("g_balance_pause_health_rot_spawn");
 607                 self.pauseregen_finished = time + cvar("g_balance_pause_health_regen_spawn");
 608                 //extend the pause of rotting if client was reset at the beginning of the countdown
 609                 if(!cvar("sv_ready_restart_after_countdown") && time < restart_countdown) {
 610                         self.spawnshieldtime += RESTART_COUNTDOWN;
 611                         self.pauserotarmor_finished += RESTART_COUNTDOWN;
 612                         self.pauserothealth_finished += RESTART_COUNTDOWN;
 613                         self.pauseregen_finished += RESTART_COUNTDOWN;
 614                 }
 615                 self.damageforcescale = 2;
 616                 self.death_time = 0;
 617                 self.dead_frame = 0;
 618                 self.alpha = 0;
 619                 self.scale = 0;
 620                 self.fade_time = 0;
 621                 self.pain_frame = 0;
 622                 self.pain_finished = 0;
 623                 self.strength_finished = 0;
 624                 self.invincible_finished = 0;
 625                 self.pushltime = 0;
 626                 //self.speed_finished = 0;
 627                 //self.slowmo_finished = 0;
 628                 // players have no think function
 629                 self.think = SUB_Null;
 630                 self.nextthink = 0;
 631                 self.hook_time = 0;
 632
 633                 self.runes = 0;
 634
 635                 self.deadflag = DEAD_NO;
 636
 637                 self.angles = spot.angles;
 638
 639                 self.angles_z = 0; // never spawn tilted even if the spot says to
 640                 self.fixangle = TRUE; // turn this way immediately
 641                 self.velocity = '0 0 0';
 642                 self.avelocity = '0 0 0';
 643                 self.punchangle = '0 0 0';
 644                 self.punchvector = '0 0 0';
 645                 self.oldvelocity = self.velocity;
 646
 647                 self.viewzoom = 0.6;
 648                 self.has_zoomed = 0;
 649
 650                 self.customizeentityforclient = Client_customizeentityforclient;
 651
 652                 self.model = "";
 653                 FixPlayermodel();
 654
 655                 self.crouch = FALSE;
 656                 self.view_ofs = PL_VIEW_OFS;
 657                 setsize (self, PL_MIN, PL_MAX);
 658                 self.spawnorigin = spot.origin;
 659                 setorigin (self, spot.origin + '0 0 1' * (1 - self.mins_z - 24));
 660                 // don't reset back to last position, even if new position is stuck in solid
 661                 self.oldorigin = self.origin;
 662
 663                 if(g_arena)
 664                 {
 665                         Spawnqueue_Remove(self);
 666                         Spawnqueue_Mark(self);
 667                 }
 668
 669                 self.event_damage = PlayerDamage;
 670
 671                 self.bot_attack = TRUE;
 672
 673                 self.statdraintime = time + 5;
 674                 self.BUTTON_ATCK = self.BUTTON_JUMP = self.BUTTON_ATCK2 = 0;
 675
 676                 if(self.killcount == -666) {
 677                         PlayerScore_Clear(self);
 678                         self.killcount = 0;
 679                         self.frags = 0;
 680                 }
 681
 682                 self.cnt = WEP_LASER;
 683                 self.nixnex_lastchange_id = -1;
 684
 685                 CL_SpawnWeaponentity();
 686                 self.alpha = default_player_alpha;
 687                 self.colormod = '1 1 1' * cvar("g_player_brightness");
 688                 self.exteriorweaponentity.alpha = default_weapon_alpha;
 689
 690                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval")*2;
 691                 self.lms_traveled_distance = 0;
 692                 self.speedrunning = FALSE;
 693
 694                 if(cvar("spawn_debug"))
 695                 {
 696                         sprint(self, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 697                         remove(spot);   // usefull for checking if there are spawnpoints, that let drop through the floor
 698                 }
 699
 700                 //stuffcmd(self, "chase_active 0");
 701                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
 702
 703                 if (cvar("g_spawnsound"))
 704                         sound (self, CHAN_TRIGGER, "misc/spawn.wav", VOL_BASE, ATTN_NORM);
 705
 706                 if(g_assault) {
 707                         if(self.team == assault_attacker_team)
 708                                 centerprint(self, "You are attacking!\n");
 709                         else
 710                                 centerprint(self, "You are defending!\n");
 711                 }
 712
 713         } else if(self.classname == "observer") {
 714                 PutObserverInServer ();
 715         }
 716
 717         //if(g_ctf)
 718         //      ctf_playerchanged();
 719 }
 720
 721 /*
 722 =============
 723 SendCSQCInfo
 724
 725 Send whatever CSQC needs NOW and cannot wait for SendServerInfo to happen...
 726 =============
 727 */
 728 void SendCSQCInfo(void)
 729 {
 730         if(clienttype(self) != CLIENTTYPE_REAL)
 731                 return;
 732         msg_entity = self;
 733         WriteByte(MSG_ONE, SVC_TEMPENTITY);
 734         WriteByte(MSG_ONE, TE_CSQC_INIT);
 735         WriteShort(MSG_ONE, CSQC_REVISION);
 736         WriteByte(MSG_ONE, maxclients);
 737 }
 738
 739 /*
 740 =============
 741 SetNewParms
 742 =============
 743 */
 744 void SetNewParms (void)
 745 {
 746         // initialize parms for a new player
 747         parm1 = -(86400 * 366);
 748 }
 749
 750 /*
 751 =============
 752 SetChangeParms
 753 =============
 754 */
 755 void SetChangeParms (void)
 756 {
 757         // save parms for level change
 758         parm1 = self.parm_idlesince - time;
 759 }
 760
 761 /*
 762 =============
 763 DecodeLevelParms
 764 =============
 765 */
 766 void DecodeLevelParms (void)
 767 {
 768         // load parms
 769         self.parm_idlesince = parm1;
 770         if(self.parm_idlesince == -(86400 * 366))
 771                 self.parm_idlesince = time;
 772 }
 773
 774 /*
 775 =============
 776 ClientKill
 777
 778 Called when a client types 'kill' in the console
 779 =============
 780 */
 781
 782 void ClientKill_Now_TeamChange()
 783 {
 784         if(self.killindicator_teamchange == -1)
 785         {
 786                 self.team = -1;
 787                 JoinBestTeam( self, FALSE, FALSE );
 788         }
 789         else
 790         {
 791                 SV_ChangeTeam(self.killindicator_teamchange - 1);
 792         }
 793 }
 794
 795 void ClientKill_Now()
 796 {
 797         if(self.killindicator_teamchange)
 798                 ClientKill_Now_TeamChange();
 799
 800         // in any case:
 801         Damage(self, self, self, 100000, DEATH_KILL, self.origin, '0 0 0');
 802
 803         if(self.killindicator)
 804         {
 805                 dprint("Cleaned up after a leaked kill indicator.\n");
 806                 remove(self.killindicator);
 807                 self.killindicator = world;
 808         }
 809 }
 810 void KillIndicator_Think()
 811 {
 812         if (!self.owner.modelindex)
 813         {
 814                 self.owner.killindicator = world;
 815                 remove(self);
 816                 return;
 817         }
 818
 819         if(self.cnt <= 0)
 820         {
 821                 self = self.owner;
 822                 ClientKill_Now(); // no oldself needed
 823                 return;
 824         }
 825         else
 826         {
 827                 if(self.cnt <= 10)
 828                         setmodel(self, strcat("models/sprites/", ftos(self.cnt), ".spr32"));
 829                 if(clienttype(self.owner) == CLIENTTYPE_REAL)
 830                 {
 831                         if(self.cnt <= 10)
 832                                 announce(self.owner, strcat("announcer/robotic/", ftos(self.cnt), ".ogg"));
 833                         if(self.owner.killindicator_teamchange)
 834                         {
 835                                 if(self.owner.killindicator_teamchange == -1)
 836                                         centerprint(self.owner, strcat("Changing team in ", ftos(self.cnt), " seconds"));
 837                                 else
 838                                         centerprint(self.owner, strcat("Changing to ", ColoredTeamName(self.owner.killindicator_teamchange), " in ", ftos(self.cnt), " seconds"));
 839                         }
 840                         else
 841                                 centerprint(self.owner, strcat("^1Suicide in ", ftos(self.cnt), " seconds"));
 842                 }
 843                 self.nextthink = time + 1;
 844                 self.cnt -= 1;
 845         }
 846 }
 847
 848 void ClientKill_TeamChange (float targetteam) // 0 = don't change, -1 = auto
 849 {
 850         float killtime;
 851         entity e;
 852         killtime = cvar("g_balance_kill_delay");
 853
 854         self.killindicator_teamchange = targetteam;
 855
 856         if(!self.killindicator)
 857         {
 858                 if(killtime <= 0 || !self.modelindex || self.deadflag != DEAD_NO)
 859                 {
 860                         ClientKill_Now();
 861                 }
 862                 else
 863                 {
 864                         self.killindicator = spawn();
 865                         self.killindicator.owner = self;
 866                         self.killindicator.scale = 0.5;
 867                         setattachment(self.killindicator, self, "");
 868                         setorigin(self.killindicator, '0 0 52');
 869                         self.killindicator.think = KillIndicator_Think;
 870                         self.killindicator.nextthink = time + (self.lip) * 0.05;
 871                         self.killindicator.cnt = ceil(killtime);
 872                         self.killindicator.count = bound(0, ceil(killtime), 10);
 873                         sprint(self, strcat("^1You'll be dead in ", ftos(self.killindicator.cnt), " seconds\n"));
 874
 875                         for(e = world; (e = find(e, classname, "body")) != world; )
 876                         {
 877                                 if(e.enemy != self)
 878                                         continue;
 879                                 e.killindicator = spawn();
 880                                 e.killindicator.owner = e;
 881                                 e.killindicator.scale = 0.5;
 882                                 setattachment(e.killindicator, e, "");
 883                                 setorigin(e.killindicator, '0 0 52');
 884                                 e.killindicator.think = KillIndicator_Think;
 885                                 e.killindicator.nextthink = time + (e.lip) * 0.05;
 886                                 e.killindicator.cnt = ceil(killtime);
 887                         }
 888                         self.lip = 0;
 889                 }
 890         }
 891         if(self.killindicator)
 892         {
 893                 if(targetteam)
 894                         self.killindicator.colormod = TeamColor(targetteam);
 895                 else
 896                         self.killindicator.colormod = '0 0 0';
 897         }
 898 }
 899
 900 void ClientKill (void)
 901 {
 902         ClientKill_TeamChange(0);
 903 }
 904
 905 void DoTeamChange(float destteam)
 906 {
 907         float t, c0;
 908         if(!cvar("teamplay"))
 909         {
 910                 if(destteam >= 0)
 911                         SetPlayerColors(self, destteam);
 912                 return;
 913         }
 914         if(self.classname == "player")
 915         if(destteam == -1)
 916         {
 917                 CheckAllowedTeams(self);
 918                 t = FindSmallestTeam(self, TRUE);
 919                 switch(self.team)
 920                 {
 921                         case COLOR_TEAM1: c0 = c1; break;
 922                         case COLOR_TEAM2: c0 = c2; break;
 923                         case COLOR_TEAM3: c0 = c3; break;
 924                         case COLOR_TEAM4: c0 = c4; break;
 925                         default:          c0 = 999;
 926                 }
 927                 switch(t)
 928                 {
 929                         case 1:
 930                                 if(c0 > c1)
 931                                         destteam = COLOR_TEAM1;
 932                                 break;
 933                         case 2:
 934                                 if(c0 > c2)
 935                                         destteam = COLOR_TEAM2;
 936                                 break;
 937                         case 3:
 938                                 if(c0 > c3)
 939                                         destteam = COLOR_TEAM3;
 940                                 break;
 941                         case 4:
 942                                 if(c0 > c4)
 943                                         destteam = COLOR_TEAM4;
 944                                 break;
 945                 }
 946                 if(destteam == -1)
 947                         return;
 948         }
 949         if(destteam == self.team && !self.killindicator)
 950                 return;
 951         ClientKill_TeamChange(destteam);
 952 }
 953
 954 void FixClientCvars(entity e)
 955 {
 956         // send prediction settings to the client
 957         stuffcmd(e, "\nin_bindmap 0 0\n");
 958         /*
 959          * we no longer need to stuff this. Remove this comment block if you feel
 960          * 2.3 and higher (or was it 2.2.3?) don't need these any more
 961         stuffcmd(e, strcat("cl_gravity ", ftos(cvar("sv_gravity")), "\n"));
 962         stuffcmd(e, strcat("cl_movement_accelerate ", ftos(cvar("sv_accelerate")), "\n"));
 963         stuffcmd(e, strcat("cl_movement_friction ", ftos(cvar("sv_friction")), "\n"));
 964         stuffcmd(e, strcat("cl_movement_maxspeed ", ftos(cvar("sv_maxspeed")), "\n"));
 965         stuffcmd(e, strcat("cl_movement_airaccelerate ", ftos(cvar("sv_airaccelerate")), "\n"));
 966         stuffcmd(e, strcat("cl_movement_maxairspeed ", ftos(cvar("sv_maxairspeed")), "\n"));
 967         stuffcmd(e, strcat("cl_movement_stopspeed ", ftos(cvar("sv_stopspeed")), "\n"));
 968         stuffcmd(e, strcat("cl_movement_jumpvelocity ", ftos(cvar("sv_jumpvelocity")), "\n"));
 969         stuffcmd(e, strcat("cl_movement_stepheight ", ftos(cvar("sv_stepheight")), "\n"));
 970         stuffcmd(e, strcat("set cl_movement_friction_on_land ", ftos(cvar("sv_friction_on_land")), "\n"));
 971         stuffcmd(e, strcat("set cl_movement_airaccel_qw ", ftos(cvar("sv_airaccel_qw")), "\n"));
 972         stuffcmd(e, strcat("set cl_movement_airaccel_sideways_friction ", ftos(cvar("sv_airaccel_sideways_friction")), "\n"));
 973         stuffcmd(e, "cl_movement_edgefriction 1\n");
 974          */
 975 }
 976
 977 /*
 978 =============
 979 ClientConnect
 980
 981 Called when a client connects to the server
 982 =============
 983 */
 984 //void ctf_clientconnect();
 985 string ColoredTeamName(float t);
 986 void DecodeLevelParms (void);
 987 //void dom_player_join_team(entity pl);
 988 void ClientConnect (void)
 989 {
 990         local string s;
 991         float wep;
 992
 993         if(self.flags & FL_CLIENT)
 994         {
 995                 print("Warning: ClientConnect, but already connected!\n");
 996                 return;
 997         }
 998
 999         if(Ban_IsClientBanned(self))
1000         {
1001                 s = strcat("^1NOTE:^7 banned client ", self.netaddress, " just tried to enter\n");
1002                 dropclient(self);
1003                 bprint(s);
1004                 return;
1005         }
1006
1007         DecodeLevelParms();
1008
1009         self.classname = "player_joining";
1010
1011         self.flags = self.flags | FL_CLIENT;
1012         self.version_nagtime = time + 10 + random() * 10;
1013
1014         if(player_count<0)
1015         {
1016                 dprint("BUG player count is lower than zero, this cannot happen!\n");
1017                 player_count = 0;
1018         }
1019
1020         PlayerScore_Attach(self);
1021
1022         bot_clientconnect();
1023
1024         //if(g_domination)
1025         //      dom_player_join_team(self);
1026
1027         //JoinBestTeam(self, FALSE, FALSE);
1028
1029         if((cvar("sv_spectate") == 1 && !g_lms) || cvar("g_campaign")) {
1030                 self.classname = "observer";
1031         } else {
1032                 self.classname = "player";
1033                 campaign_bots_may_start = 1;
1034         }
1035
1036         self.playerid = (playerid_last = playerid_last + 1);
1037         if(cvar("sv_eventlog"))
1038         {
1039                 if(clienttype(self) == CLIENTTYPE_REAL)
1040                         s = "player";
1041                 else
1042                         s = "bot";
1043                 GameLogEcho(strcat(":join:", ftos(self.playerid), ":", s, ":", self.netname), TRUE);
1044                 s = strcat(":team:", ftos(self.playerid), ":");
1045                 s = strcat(s, ftos(self.team));
1046                 GameLogEcho(s, FALSE);
1047         }
1048         self.netname_previous = strzone(self.netname);
1049
1050         //stuffcmd(self, "set tmpviewsize $viewsize \n");
1051
1052         bprint ("^4",self.netname);
1053         bprint ("^4 connected");
1054
1055         if(g_domination || g_ctf)
1056         {
1057                 bprint(" and joined the ");
1058                 bprint(ColoredTeamName(self.team));
1059         }
1060
1061         bprint("\n");
1062
1063         self.welcomemessage_time = 0;
1064
1065         stuffcmd(self, strcat("exec maps/", mapname, ".cfg\n"));
1066         // TODO: is this being used for anything else than cd tracks?
1067         // Remember: SVC_CDTRACK exists. Maybe it should be used.
1068         //
1069         stuffcmd(self, "cl_particles_reloadeffects\n");
1070
1071         FixClientCvars(self);
1072
1073         // spawnfunc_waypoint sprites
1074         WaypointSprite_InitClient(self);
1075
1076         // Wazat's grappling hook
1077         SetGrappleHookBindings();
1078
1079         // get autoswitch state from player when he toggles it
1080         stuffcmd(self, "alias autoswitch \"set cl_autoswitch $1 ; cmd autoswitch $1\"\n"); // default.cfg-ed in 2.4.1
1081
1082         // get version info from player
1083         stuffcmd(self, "cmd clientversion $gameversion\n");
1084
1085         // send all weapon info strings
1086         stuffcmd(self, "register_bestweapon clear\n"); // clear the Quake stuff
1087         wep = WEP_FIRST;
1088         while (wep <= WEP_LAST)
1089         {
1090                 weapon_action(wep, WR_REGISTER);
1091                 wep = wep + 1;
1092         }
1093
1094         // get other cvars from player
1095         GetCvars(0);
1096
1097         // set cvar for team scoreboard
1098         if (teams_matter)
1099         {
1100                 local float t;
1101                 t = cvar("teamplay");
1102                 // we have to stuff the correct teamplay value because if this is a listen server, this changes the teamplay mode of the server itself, which is bad
1103                 stuffcmd(self, strcat("set teamplay ", ftos(t), "\n"));
1104         }
1105         else
1106                 stuffcmd(self, "set teamplay 0\n");
1107
1108         // notify about available teams
1109         if(teamplay)
1110         {
1111                 CheckAllowedTeams(self);
1112                 t = 0; if(c1 >= 0) t |= 1; if(c2 >= 0) t |= 2; if(c3 >= 0) t |= 4; if(c4 >= 0) t |= 8;
1113                 stuffcmd(self, strcat("set _teams_available ", ftos(t), "\n"));
1114         }
1115         else
1116                 stuffcmd(self, "set _teams_available 0\n");
1117
1118         stuffcmd(self, strcat("set gametype ", ftos(game), "\n"));
1119
1120         if(g_arena)
1121         {
1122                 self.classname = "observer";
1123                 Spawnqueue_Insert(self);
1124         }
1125         /*else if(g_ctf)
1126         {
1127                 ctf_clientconnect();
1128         }*/
1129
1130         if(entcs_start)
1131                 attach_entcs();
1132
1133         bot_relinkplayerlist();
1134
1135         self.spectatortime = time;
1136         if(blockSpectators)
1137         {
1138                 sprint(self, strcat("^7You have to become a player within the next ", ftos(cvar("g_maxplayers_spectator_blocktime")), " seconds, otherwise you will be kicked, because spectators aren't allowed at this time!\n"));
1139         }
1140
1141         self.jointime = time;
1142         self.allowedTimeouts = cvar("sv_timeout_number");
1143
1144         if(clienttype(self) == CLIENTTYPE_REAL)
1145         {
1146                 sprint(self, strcat("nexuiz-csqc protocol ", ftos(CSQC_REVISION), "\n"));
1147                 SendCSQCInfo();
1148                 msg_entity = self;
1149                 if(mapvote_initialized && !cvar("g_maplist_textonly"))
1150                 {
1151                         MapVote_SendData(MSG_ONE);
1152                         MapVote_UpdateData(MSG_ONE);
1153                 }
1154                 ScoreInfo_Write(MSG_ONE);
1155         }
1156
1157         if(g_lms)
1158         {
1159                 if(PlayerScore_Add(self, SP_LMS_LIVES, LMS_NewPlayerLives()) <= 0)
1160                 {
1161                         PlayerScore_Add(self, SP_LMS_RANK, 666);
1162                         self.frags = -666; // FIXME do we still need this?
1163                 }
1164         }
1165 }
1166
1167 /*
1168 =============
1169 ClientDisconnect
1170
1171 Called when a client disconnects from the server
1172 =============
1173 */
1174 void(entity e) DropFlag;
1175 .entity chatbubbleentity;
1176 .entity teambubbleentity;
1177 //void() ctf_clientdisconnect;
1178 void ClientDisconnect (void)
1179 {
1180         float save;
1181
1182         if not(self.flags & FL_CLIENT)
1183         {
1184                 print("Warning: ClientDisconnect without ClientConnect\n");
1185                 return;
1186         }
1187
1188         bot_clientdisconnect();
1189
1190         if(entcs_start)
1191                 detach_entcs();
1192
1193         if(cvar("sv_eventlog"))
1194                 GameLogEcho(strcat(":part:", ftos(self.playerid)), FALSE);
1195         bprint ("^4",self.netname);
1196         bprint ("^4 disconnected\n");
1197
1198         if (self.chatbubbleentity)
1199         {
1200                 remove (self.chatbubbleentity);
1201                 self.chatbubbleentity = world;
1202         }
1203
1204         if (self.teambubbleentity)
1205         {
1206                 remove (self.teambubbleentity);
1207                 self.teambubbleentity = world;
1208         }
1209
1210         if (self.killindicator)
1211         {
1212                 remove (self.killindicator);
1213                 self.killindicator = world;
1214         }
1215
1216         WaypointSprite_PlayerGone();
1217
1218         DropAllRunes(self);
1219         kh_Key_DropAll(self, TRUE);
1220
1221         if(self.flagcarried)
1222                 DropFlag(self.flagcarried);
1223
1224         save = self.flags;
1225         self.flags = self.flags - (self.flags & FL_CLIENT);
1226         bot_relinkplayerlist();
1227         self.flags = save;
1228
1229         // remove laserdot
1230         if(self.weaponentity)
1231                 if(self.weaponentity.lasertarget)
1232                         remove(self.weaponentity.lasertarget);
1233
1234         if(g_arena)
1235         {
1236                 Spawnqueue_Unmark(self);
1237                 Spawnqueue_Remove(self);
1238         }
1239         /*if(g_ctf)
1240         {
1241                 ctf_clientdisconnect();
1242         }
1243         */
1244
1245         PlayerScore_Detach(self);
1246
1247         if(self.netname_previous)
1248                 strunzone(self.netname_previous);
1249
1250         ClearPlayerSounds();
1251
1252         // free cvars
1253         GetCvars(-1);
1254         self.playerid = 0;
1255 }
1256
1257 .float BUTTON_CHAT;
1258 void ChatBubbleThink()
1259 {
1260         self.nextthink = time;
1261         if (!self.owner.modelindex || self.owner.chatbubbleentity != self)
1262         {
1263                 self.owner.chatbubbleentity = world;
1264                 remove(self);
1265                 return;
1266         }
1267         setorigin(self, self.owner.origin + '0 0 15' + self.owner.maxs_z * '0 0 1');
1268         if (self.owner.BUTTON_CHAT && !self.owner.deadflag)
1269                 self.model = self.mdl;
1270         else
1271                 self.model = "";
1272 };
1273
1274 void UpdateChatBubble()
1275 {
1276         if (!self.modelindex)
1277                 return;
1278         // spawn a chatbubble entity if needed
1279         if (!self.chatbubbleentity)
1280         {
1281                 self.chatbubbleentity = spawn();
1282                 self.chatbubbleentity.owner = self;
1283                 self.chatbubbleentity.exteriormodeltoclient = self;
1284                 self.chatbubbleentity.think = ChatBubbleThink;
1285                 self.chatbubbleentity.nextthink = time;
1286                 setmodel(self.chatbubbleentity, "models/misc/chatbubble.spr"); // precision set below
1287                 setorigin(self.chatbubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1288                 self.chatbubbleentity.mdl = self.chatbubbleentity.model;
1289                 self.chatbubbleentity.model = "";
1290                 self.chatbubbleentity.effects = EF_LOWPRECISION;
1291         }
1292 }
1293
1294
1295 void TeamBubbleThink()
1296 {
1297         self.nextthink = time;
1298         if (!self.owner.modelindex || self.owner.teambubbleentity != self)
1299         {
1300                 self.owner.teambubbleentity = world;
1301                 remove(self);
1302                 return;
1303         }
1304 //      setorigin(self, self.owner.origin + '0 0 15' + self.owner.maxs_z * '0 0 1');  // bandwidth hog. setattachment does this now
1305         if (self.owner.BUTTON_CHAT || self.owner.deadflag || self.owner.killindicator)
1306                 self.model = "";
1307         else
1308                 self.model = self.mdl;
1309
1310 };
1311
1312 float TeamBubble_customizeentityforclient()
1313 {
1314         return (self.owner != other && self.owner.team == other.team && other.killcount > -666);
1315 }
1316
1317 void UpdateTeamBubble()
1318 {
1319         if (!self.modelindex || !cvar("teamplay"))
1320                 return;
1321         // spawn a teambubble entity if needed
1322         if (!self.teambubbleentity && cvar("teamplay"))
1323         {
1324                 self.teambubbleentity = spawn();
1325                 self.teambubbleentity.owner = self;
1326                 self.teambubbleentity.exteriormodeltoclient = self;
1327                 self.teambubbleentity.think = TeamBubbleThink;
1328                 self.teambubbleentity.nextthink = time;
1329                 setmodel(self.teambubbleentity, "models/misc/teambubble.spr"); // precision set below
1330 //              setorigin(self.teambubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1331                 setorigin(self.teambubbleentity, self.teambubbleentity.origin + '0 0 15' + self.maxs_z * '0 0 1');
1332                 setattachment(self.teambubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1333                 self.teambubbleentity.mdl = self.teambubbleentity.model;
1334                 self.teambubbleentity.model = self.teambubbleentity.mdl;
1335                 self.teambubbleentity.customizeentityforclient = TeamBubble_customizeentityforclient;
1336                 self.teambubbleentity.effects = EF_LOWPRECISION;
1337         }
1338 }
1339
1340 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1341 // added to the model skins
1342 /*void UpdateColorModHack()
1343 {
1344         local float c;
1345         c = self.clientcolors & 15;
1346         // LordHavoc: only bothering to support white, green, red, yellow, blue
1347              if (teamplay == 0) self.colormod = '0 0 0';
1348         else if (c ==  0) self.colormod = '1.00 1.00 1.00';
1349         else if (c ==  3) self.colormod = '0.10 1.73 0.10';
1350         else if (c ==  4) self.colormod = '1.73 0.10 0.10';
1351         else if (c == 12) self.colormod = '1.22 1.22 0.10';
1352         else if (c == 13) self.colormod = '0.10 0.10 1.73';
1353         else self.colormod = '1 1 1';
1354 };*/
1355
1356 void respawn(void)
1357 {
1358         CopyBody(1);
1359         self.effects |= EF_NODRAW; // prevent another CopyBody
1360         PutClientInServer();
1361 }
1362
1363 /**
1364  * When sv_timeout is used this function returs strings like
1365  * "Timeout begins in 2 seconds!\n" or "Timeout ends in 23 seconds!\n".
1366  * Called by centerprint functions
1367  * @param addOneSecond boolean, set to 1 if the welcome-message centerprint asks for the text
1368  */
1369 string getTimeoutText(float addOneSecond) {
1370         if (!cvar("sv_timeout") || !timeoutStatus)
1371                 return "";
1372
1373         local string retStr;
1374         if (timeoutStatus == 1) {
1375                 if (addOneSecond == 1) {
1376                         retStr = strcat("Timeout begins in ", ftos(remainingLeadTime + 1), " seconds!\n");
1377                 }
1378                 else {
1379                         retStr = strcat("Timeout begins in ", ftos(remainingLeadTime), " seconds!\n");
1380                 }
1381                 return retStr;
1382         }
1383         else if (timeoutStatus == 2) {
1384                 if (addOneSecond) {
1385                         retStr = strcat("Timeout ends in ", ftos(remainingTimeoutTime + 1), " seconds!\n");
1386                         //don't show messages like "Timeout ends in 0 seconds"...
1387                         if ((remainingTimeoutTime + 1) > 0)
1388                                 return retStr;
1389                         else
1390                                 return "";
1391                 }
1392                 else {
1393                         retStr = strcat("Timeout ends in ", ftos(remainingTimeoutTime), " seconds!\n");
1394                         //don't show messages like "Timeout ends in 0 seconds"...
1395                         if (remainingTimeoutTime > 0)
1396                                 return retStr;
1397                         else
1398                                 return "";
1399                 }
1400         }
1401         else return "";
1402 }
1403
1404 void player_powerups (void)
1405 {
1406         if (g_minstagib)
1407         {
1408                 if (self.items & IT_STRENGTH)
1409                 {
1410                         if (time > self.strength_finished)
1411                         {
1412                                 if (g_minstagib_invis_alpha > 0)
1413                                 {
1414                                         self.alpha = default_player_alpha;
1415                                         self.exteriorweaponentity.alpha = default_weapon_alpha;
1416                                         self.effects = self.effects | EF_FULLBRIGHT;
1417                                 }
1418                                 else
1419                                 {
1420                                         self.effects -= self.effects & EF_NODRAW;
1421                                 }
1422                                 self.items = self.items - (self.items & IT_STRENGTH);
1423                                 sprint(self, "^3Invisibility has worn off\n");
1424                         }
1425                 }
1426                 else
1427                 {
1428                         if (time < self.strength_finished)
1429                         {
1430                                 if (g_minstagib_invis_alpha > 0)
1431                                 {
1432                                         self.alpha = g_minstagib_invis_alpha;
1433                                         self.exteriorweaponentity.alpha = g_minstagib_invis_alpha;
1434                                         self.effects -= self.effects & EF_FULLBRIGHT;
1435                                 }
1436                                 else
1437                                 {
1438                                         self.effects = self.effects | EF_NODRAW;
1439                                 }
1440                                 self.items = self.items | IT_STRENGTH;
1441                                 sprint(self, "^3You are invisible\n");
1442                         }
1443                 }
1444
1445                 if (self.items & IT_INVINCIBLE)
1446                 {
1447                         if (time > self.invincible_finished)
1448                         {
1449                                 self.items = self.items - (self.items & IT_INVINCIBLE);
1450                                 sprint(self, "^3Speed has worn off\n");
1451                         }
1452                 }
1453                 else
1454                 {
1455                         if (time < self.invincible_finished)
1456                         {
1457                                 self.items = self.items | IT_INVINCIBLE;
1458                                 sprint(self, "^3You are on speed\n");
1459                         }
1460                 }
1461                 return;
1462         }
1463
1464         self.effects = self.effects - (self.effects & (EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT));
1465         if (self.items & IT_STRENGTH)
1466         {
1467                 self.effects = self.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1468                 if (time > self.strength_finished)
1469                 {
1470                         self.items = self.items - (self.items & IT_STRENGTH);
1471                         sprint(self, "^3Strength has worn off\n");
1472                 }
1473         }
1474         else
1475         {
1476                 if (time < self.strength_finished)
1477                 {
1478                         self.items = self.items | IT_STRENGTH;
1479                         sprint(self, "^3Strength infuses your weapons with devastating power\n");
1480                 }
1481         }
1482         if (self.items & IT_INVINCIBLE)
1483         {
1484                 self.effects = self.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1485                 if (time > self.invincible_finished)
1486                 {
1487                         self.items = self.items - (self.items & IT_INVINCIBLE);
1488                         sprint(self, "^3Shield has worn off\n");
1489                 }
1490         }
1491         else
1492         {
1493                 if (time < self.invincible_finished)
1494                 {
1495                         self.items = self.items | IT_INVINCIBLE;
1496                         sprint(self, "^3Shield surrounds you\n");
1497                 }
1498         }
1499
1500         if (cvar("g_fullbrightplayers"))
1501                 self.effects = self.effects | EF_FULLBRIGHT;
1502
1503         // midair gamemode: damage only while in the air
1504         // if in midair mode, being on ground grants temporary invulnerability
1505         // (this is so that multishot weapon don't clear the ground flag on the
1506         // first damage in the frame, leaving the player vulnerable to the
1507         // remaining hits in the same frame)
1508         if (self.flags & FL_ONGROUND)
1509         if (g_midair)
1510                 self.spawnshieldtime = max(self.spawnshieldtime, time + cvar("g_midair_shieldtime"));
1511
1512         if (time < self.spawnshieldtime)
1513                 self.effects = self.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1514 }
1515
1516 float CalcRegen(float current, float stable, float regenfactor)
1517 {
1518         if(current > stable)
1519                 return current;
1520         else if(current > stable - 0.25) // when close enough, "snap"
1521                 return stable;
1522         else
1523                 return min(stable, current + (stable - current) * regenfactor * frametime);
1524 }
1525
1526 void player_regen (void)
1527 {
1528         float maxh, maxa, limith, limita, max_mod, regen_mod, rot_mod, limit_mod;
1529         maxh = cvar("g_balance_health_stable");
1530         maxa = cvar("g_balance_armor_stable");
1531         limith = cvar("g_balance_health_limit");
1532         limita = cvar("g_balance_armor_limit");
1533
1534         if (g_minstagib || (g_lms && !cvar("g_lms_regenerate")))
1535                 return;
1536
1537         max_mod = regen_mod = rot_mod = limit_mod = 1;
1538
1539         if (self.runes & RUNE_REGEN)
1540         {
1541                 if (self.runes & CURSE_VENOM) // do we have both rune/curse?
1542                 {
1543                         regen_mod = cvar("g_balance_rune_regen_combo_regenrate");
1544                         max_mod = cvar("g_balance_rune_regen_combo_hpmod");
1545                         limit_mod = cvar("g_balance_rune_regen_combo_limitmod");
1546                 }
1547                 else
1548                 {
1549                         regen_mod = cvar("g_balance_rune_regen_regenrate");
1550                         max_mod = cvar("g_balance_rune_regen_hpmod");
1551                         limit_mod = cvar("g_balance_rune_regen_limitmod");
1552                 }
1553         }
1554         else if (self.runes & CURSE_VENOM)
1555         {
1556                 max_mod = cvar("g_balance_curse_venom_hpmod");
1557                 if (self.runes & RUNE_REGEN) // do we have both rune/curse?
1558                         rot_mod = cvar("g_balance_rune_regen_combo_rotrate");
1559                 else
1560                         rot_mod = cvar("g_balance_curse_venom_rotrate");
1561                 limit_mod = cvar("g_balance_curse_venom_limitmod");
1562                 //if (!self.runes & RUNE_REGEN)
1563                 //      rot_mod = cvar("g_balance_curse_venom_rotrate");
1564         }
1565         maxh = maxh * max_mod;
1566         //maxa = maxa * max_mod;
1567         limith = limith * limit_mod;
1568         limita = limita * limit_mod;
1569
1570         if (self.armorvalue > maxa)
1571         {
1572                 if (time > self.pauserotarmor_finished)
1573                 {
1574                         self.armorvalue = max(maxa, self.armorvalue + (maxa - self.armorvalue) * cvar("g_balance_armor_rot") * frametime);
1575                         self.armorvalue = max(maxa, self.armorvalue - cvar("g_balance_armor_rotlinear") * frametime);
1576                 }
1577         }
1578         else if (self.armorvalue < maxa)
1579         {
1580                 if (time > self.pauseregen_finished)
1581                 {
1582                         self.armorvalue = CalcRegen(self.armorvalue, maxa, cvar("g_balance_armor_regen"));
1583                         self.armorvalue = min(maxa, self.armorvalue + cvar("g_balance_armor_regenlinear") * frametime);
1584                 }
1585         }
1586         if (self.health > maxh)
1587         {
1588                 if (time > self.pauserothealth_finished)
1589                 {
1590                         self.health = max(maxh, self.health + (maxh - self.health) * rot_mod*cvar("g_balance_health_rot") * frametime);
1591                         self.health = max(maxh, self.health - rot_mod*cvar("g_balance_health_rotlinear") * frametime);
1592                 }
1593         }
1594         else if (self.health < maxh)
1595         {
1596                 if (time > self.pauseregen_finished)
1597                 {
1598                         self.health = CalcRegen(self.health, maxh, regen_mod * cvar("g_balance_health_regen"));
1599                         self.health = min(maxh, self.health + regen_mod*cvar("g_balance_health_regenlinear") * frametime);
1600                 }
1601         }
1602
1603         if (self.health > limith)
1604                 self.health = limith;
1605         if (self.armorvalue > limita)
1606                 self.armorvalue = limita;
1607
1608         // if player rotted to death...  die!
1609         if(self.health < 1)
1610                 self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
1611 }
1612
1613 /*
1614 ======================
1615 spectate mode routines
1616 ======================
1617 */
1618 void SpectateCopy(entity spectatee) {
1619         self.armortype = spectatee.armortype;
1620         self.armorvalue = spectatee.armorvalue;
1621         self.currentammo = spectatee.currentammo;
1622         self.effects = spectatee.effects;
1623         self.health = spectatee.health;
1624         self.impulse = 0;
1625         self.items = spectatee.items;
1626         self.punchangle = spectatee.punchangle;
1627         self.view_ofs = spectatee.view_ofs;
1628         self.v_angle = spectatee.v_angle;
1629         self.viewzoom = spectatee.viewzoom;
1630         self.velocity = spectatee.velocity;
1631         self.dmg_take = spectatee.dmg_take;
1632         self.dmg_save = spectatee.dmg_save;
1633         self.dmg_inflictor = spectatee.dmg_inflictor;
1634         self.angles = spectatee.v_angle;
1635         self.fixangle = TRUE;
1636         setorigin(self, spectatee.origin);
1637         setsize(self, spectatee.mins, spectatee.maxs);
1638 }
1639
1640 float SpectateUpdate() {
1641         if(!self.enemy)
1642                 return 0;
1643
1644         if (self == self.enemy)
1645                 return 0;
1646
1647         if(self.enemy.flags & FL_NOTARGET)
1648                 return 0;
1649
1650         SpectateCopy(self.enemy);
1651
1652         return 1;
1653 }
1654
1655 float SpectateNext() {
1656         other = find(self.enemy, classname, "player");
1657         if (!other) {
1658                 other = find(other, classname, "player");
1659         }
1660         if (other) {
1661                 self.enemy = other;
1662         }
1663         if(self.enemy.classname == "player") {
1664                 msg_entity = self;
1665                 WriteByte(MSG_ONE, SVC_SETVIEW);
1666                 WriteEntity(MSG_ONE, self.enemy);
1667                 self.wantswelcomemessage = 1;
1668                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
1669                 if(!SpectateUpdate())
1670                         PutObserverInServer();
1671                 return 1;
1672         } else {
1673                 return 0;
1674         }
1675 }
1676
1677 /*
1678 =============
1679 ShowRespawnCountdown()
1680
1681 Update a respawn countdown display.
1682 =============
1683 */
1684 void ShowRespawnCountdown()
1685 {
1686         float number;
1687         if(self.deadflag == DEAD_NO) // just respawned?
1688                 return;
1689         else
1690         {
1691                 number = ceil(self.death_time - time);
1692                 if(number <= 0)
1693                         return;
1694                 if(number <= self.respawn_countdown)
1695                 {
1696                         self.respawn_countdown = number - 1;
1697                         if(ceil(self.death_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
1698                                 announce(self, strcat("announcer/robotic/", ftos(number), ".ogg"));
1699                 }
1700         }
1701 }
1702
1703 void LeaveSpectatorMode()
1704 {
1705         if(isJoinAllowed()) {
1706                 if(!cvar("teamplay") || cvar("g_campaign") || cvar("g_balance_teams")) {
1707                         self.classname = "player";
1708                         if(cvar("g_campaign") || cvar("g_balance_teams") || cvar("g_balance_teams_force"))
1709                                 JoinBestTeam(self, FALSE, TRUE);
1710                         if(cvar("g_campaign"))
1711                                 campaign_bots_may_start = 1;
1712                         PutClientInServer();
1713                         if(!(self.flags & FL_NOTARGET))
1714                                 bprint ("^4", self.netname, "^4 is playing now\n");
1715                         centerprint(self,"");
1716                         return;
1717                 } else {
1718                         stuffcmd(self,"menu_showteamselect\n");
1719                         return;
1720                 }
1721         }
1722         else {
1723                 //player may not join because of g_maxplayers is set
1724                 centerprint_atprio(self, CENTERPRIO_MAPVOTE, PREVENT_JOIN_TEXT);
1725         }
1726 }
1727
1728 /**
1729  * Determines whether the player is allowed to join. This depends on cvar
1730  * g_maxplayers, if it isn't used this function always return TRUE, otherwise
1731  * it checks whether the number of currently playing players exceeds g_maxplayers.
1732  * @return bool TRUE if the player is allowed to join, false otherwise
1733  */
1734 float isJoinAllowed() {
1735         if (!cvar("g_maxplayers"))
1736                 return TRUE;
1737
1738         local entity e;
1739         local float currentlyPlaying;
1740         FOR_EACH_REALPLAYER(e) {
1741                 if(e.classname == "player")
1742                         currentlyPlaying += 1;
1743         }
1744         if(currentlyPlaying < cvar("g_maxplayers"))
1745                 return TRUE;
1746
1747         return FALSE;
1748 }
1749
1750 /**
1751  * Checks whether the client is an observer or spectator, if so, he will get kicked after
1752  * g_maxplayers_spectator_blocktime seconds
1753  */
1754 void checkSpectatorBlock() {
1755         if(self.classname == "spectator" || self.classname == "observer") {
1756                 if( time > (self.spectatortime + cvar("g_maxplayers_spectator_blocktime")) ) {
1757                         sprint(self, "^7You were kicked from the server because you are spectator and spectators aren't allowed at the moment.\n");
1758                         dropclient(self);
1759                 }
1760         }
1761 }
1762
1763 float vercmp_recursive(string v1, string v2)
1764 {
1765         float dot1, dot2;
1766         string s1, s2;
1767         float r;
1768
1769         dot1 = strstrofs(v1, ".", 0);
1770         dot2 = strstrofs(v2, ".", 0);
1771         if(dot1 == -1)
1772                 s1 = v1;
1773         else
1774                 s1 = substring(v1, 0, dot1);
1775         if(dot2 == -1)
1776                 s2 = v2;
1777         else
1778                 s2 = substring(v2, 0, dot2);
1779
1780         r = stof(s1) - stof(s2);
1781         if(r != 0)
1782                 return r;
1783
1784         r = strcasecmp(s1, s2);
1785         if(r != 0)
1786                 return r;
1787
1788         if(dot1 == -1)
1789                 if(dot2 == -1)
1790                         return 0;
1791                 else
1792                         return -1;
1793         else
1794                 if(dot2 == -1)
1795                         return 1;
1796                 else
1797                         return vercmp_recursive(substring(v1, dot1 + 1, 999), substring(v2, dot2 + 1, 999));
1798 }
1799
1800 float vercmp(string v1, string v2)
1801 {
1802         if(strcasecmp(v1, v2) == 0) // early out check
1803                 return 0;
1804         return vercmp_recursive(v1, v2);
1805 }
1806
1807 void ObserverThink()
1808 {
1809         if (self.flags & FL_JUMPRELEASED) {
1810                 if (self.BUTTON_JUMP && !self.version_mismatch) {
1811                         self.welcomemessage_time = 0;
1812                         self.flags = self.flags - FL_JUMPRELEASED;
1813                         LeaveSpectatorMode();
1814                         return;
1815                 } else if(self.BUTTON_ATCK && !self.version_mismatch) {
1816                         self.welcomemessage_time = 0;
1817                         self.flags = self.flags - FL_JUMPRELEASED;
1818                         if(SpectateNext() == 1) {
1819                                 self.classname = "spectator";
1820                         }
1821                 }
1822         } else {
1823                 if (!(self.BUTTON_ATCK || self.BUTTON_JUMP)) {
1824                         self.flags = self.flags | FL_JUMPRELEASED;
1825                 }
1826         }
1827         if(self.BUTTON_ZOOM)
1828                 self.wantswelcomemessage = 0;
1829         if(self.wantswelcomemessage)
1830                 PrintWelcomeMessage(self);
1831 }
1832
1833 void SpectatorThink()
1834 {
1835         if (self.flags & FL_JUMPRELEASED) {
1836                 if (self.BUTTON_JUMP && !self.version_mismatch) {
1837                         self.welcomemessage_time = 0;
1838                         self.flags = self.flags - FL_JUMPRELEASED;
1839                         LeaveSpectatorMode();
1840                         return;
1841                 } else if(self.BUTTON_ATCK) {
1842                         self.welcomemessage_time = 0;
1843                         self.flags = self.flags - FL_JUMPRELEASED;
1844                         if(SpectateNext() == 1) {
1845                                 self.classname = "spectator";
1846                         } else {
1847                                 self.classname = "observer";
1848                                 PutClientInServer();
1849                         }
1850                 } else if (self.BUTTON_ATCK2) {
1851                         self.welcomemessage_time = 0;
1852                         self.flags = self.flags - FL_JUMPRELEASED;
1853                         self.classname = "observer";
1854                         PutClientInServer();
1855                 } else {
1856                         if(!SpectateUpdate())
1857                                 PutObserverInServer();
1858                 }
1859         } else {
1860                 if (!(self.BUTTON_ATCK || self.BUTTON_ATCK2)) {
1861                         self.flags = self.flags | FL_JUMPRELEASED;
1862                 }
1863         }
1864         if(self.BUTTON_ZOOM)
1865                 self.wantswelcomemessage = 0;
1866         if(self.wantswelcomemessage)
1867                 PrintWelcomeMessage(self);
1868         self.flags = self.flags | FL_CLIENT | FL_NOTARGET;
1869 }
1870
1871 /*
1872 =============
1873 PlayerPreThink
1874
1875 Called every frame for each client before the physics are run
1876 =============
1877 */
1878 void() ctf_setstatus;
1879 .float vote_nagtime;
1880 void PlayerPreThink (void)
1881 {
1882         if(blockSpectators)
1883                 checkSpectatorBlock();
1884
1885         if(self.netname_previous != self.netname)
1886         {
1887                 if(cvar("sv_eventlog"))
1888                         GameLogEcho(strcat(":name:", ftos(self.playerid), ":", self.netname), TRUE);
1889                 if(self.netname_previous)
1890                         strunzone(self.netname_previous);
1891                 self.netname_previous = strzone(self.netname);
1892         }
1893
1894         // version nagging
1895         if(self.version_nagtime)
1896                 if(self.cvar_g_nexuizversion)
1897                         if(time > self.version_nagtime)
1898                         {
1899                                 if(strstr(self.cvar_g_nexuizversion, "svn", 0) < 0)
1900                                 {
1901                                         if(strstr(cvar_string("g_nexuizversion"), "svn", 0) >= 0)
1902                                         {
1903                                                 dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Nexuiz ", cvar_string("g_nexuizversion"), " (beta)^7, you have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1\n");
1904                                                 sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Nexuiz ", cvar_string("g_nexuizversion"), " (beta)^7, you have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1\n"));
1905                                         }
1906                                         else
1907                                         {
1908                                                 float r;
1909                                                 r = vercmp(self.cvar_g_nexuizversion, cvar_string("g_nexuizversion"));
1910                                                 if(r < 0)
1911                                                 {
1912                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - ^3Nexuiz ", cvar_string("g_nexuizversion"), "^7 is out, and you still have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1 - get the update from ^4http://www.nexuiz.com/^1!\n");
1913                                                         sprint(self, strcat("\{1}^1NOTE: ^3Nexuiz ", cvar_string("g_nexuizversion"), "^7 is out, and you still have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1 - get the update from ^4http://www.nexuiz.com/^1!\n"));
1914                                                 }
1915                                                 else if(r > 0)
1916                                                 {
1917                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Nexuiz ", cvar_string("g_nexuizversion"), "^7, you have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1\n");
1918                                                         sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Nexuiz ", cvar_string("g_nexuizversion"), "^7, you have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1\n"));
1919                                                 }
1920                                         }
1921                                 }
1922                                 self.version_nagtime = 0;
1923                         }
1924
1925         // vote nagging
1926         if(self.cvar_scr_centertime)
1927                 if(time > self.vote_nagtime)
1928                 {
1929                         VoteNag();
1930                         self.vote_nagtime = time + self.cvar_scr_centertime * 0.6;
1931                 }
1932
1933         // GOD MODE info
1934         if(!(self.flags & FL_GODMODE)) if(self.max_armorvalue)
1935         {
1936                 sprint(self, strcat("godmode saved you ", ftos(self.max_armorvalue), " units of damage, cheater!\n"));
1937                 self.max_armorvalue = 0;
1938         }
1939
1940         if(frametime)
1941                 antilag_record(self);
1942
1943         if(self.classname == "player") {
1944 //              if(self.netname == "Wazat")
1945 //                      bprint(self.classname, "\n");
1946
1947                 CheckRules_Player();
1948
1949                 if(self.BUTTON_INFO)
1950                         PrintWelcomeMessage(self);
1951
1952                 if(g_lms || !cvar("sv_spectate"))
1953                 if((time - self.jointime) <= cvar("welcome_message_time"))
1954                         PrintWelcomeMessage(self);
1955
1956                 if (intermission_running)
1957                 {
1958                         IntermissionThink ();   // otherwise a button could be missed between
1959                         return;                                 // the think tics
1960                 }
1961
1962                 if(self.teleport_time)
1963                 if(time > self.teleport_time)
1964                 {
1965                         self.teleport_time = 0;
1966                         self.effects = self.effects - (self.effects & EF_NODRAW);
1967                         if(self.weaponentity)
1968                                 self.weaponentity.flags = self.weaponentity.flags - (self.weaponentity.flags & EF_NODRAW);
1969                 }
1970
1971                 Nixnex_GiveCurrentWeapon();
1972
1973                 if(frametime > 0) // don't do this in cl_movement frames, just in server ticks
1974                         UpdateSelectedPlayer();
1975
1976                 //don't allow the player to turn around while game is paused!
1977                 if(timeoutStatus == 2) {
1978                         self.v_angle = self.lastV_angle;
1979                         self.angles = self.lastV_angle;
1980                         self.fixangle = TRUE;
1981                 }
1982
1983                 if (self.deadflag != DEAD_NO)
1984                 {
1985                         float button_pressed, force_respawn;
1986                         player_anim();
1987                         button_pressed = (self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE);
1988                         force_respawn = (g_lms || cvar("g_forced_respawn"));
1989                         if (self.deadflag == DEAD_DYING)
1990                         {
1991                                 if(force_respawn)
1992                                         self.deadflag = DEAD_RESPAWNING;
1993                                 else if(!button_pressed)
1994                                         self.deadflag = DEAD_DEAD;
1995                         }
1996                         else if (self.deadflag == DEAD_DEAD)
1997                         {
1998                                 if(button_pressed)
1999                                         self.deadflag = DEAD_RESPAWNABLE;
2000                         }
2001                         else if (self.deadflag == DEAD_RESPAWNABLE)
2002                         {
2003                                 if(!button_pressed)
2004                                         self.deadflag = DEAD_RESPAWNING;
2005                         }
2006                         else if (self.deadflag == DEAD_RESPAWNING)
2007                         {
2008                                 if(time > self.death_time)
2009                                 {
2010                                         self.death_time = time + 1; // only retry once a second
2011                                         respawn();
2012                                 }
2013                         }
2014                         ShowRespawnCountdown();
2015                         return;
2016                 }
2017
2018                 if(g_lms && !self.deadflag && cvar("g_lms_campcheck_interval"))
2019                 {
2020                         vector dist;
2021
2022                         // calculate player movement (in 2 dimensions only, so jumping on one spot doesn't count as movement)
2023                         dist = self.oldorigin - self.origin;
2024                         dist_z = 0;
2025                         self.lms_traveled_distance += fabs(vlen(dist));
2026
2027                         if((cvar("g_campaign") && !campaign_bots_may_start) || (time < restart_countdown))
2028                         {
2029                                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval")*2;
2030                                 self.lms_traveled_distance = 0;
2031                         }
2032
2033                         if(time > self.lms_nextcheck)
2034                         {
2035                                 //sprint(self, "distance: ", ftos(self.lms_traveled_distance), "\n");
2036                                 if(self.lms_traveled_distance < cvar("g_lms_campcheck_distance"))
2037                                 {
2038                                         centerprint(self, cvar_string("g_lms_campcheck_message"));
2039                                         // FIXME KadaverJack: gibbing player here causes playermodel to bounce around, instead of eye.md3
2040                                         // I wasn't able to find out WHY that happens, so I put a workaround in place that shall prevent players from being gibbed :(
2041                                         Damage(self, self, self, bound(0, cvar("g_lms_campcheck_damage"), self.health + self.armorvalue * cvar("g_balance_armor_blockpercent") + 5), DEATH_CAMP, self.origin, '0 0 0');
2042                                 }
2043                                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval");
2044                                 self.lms_traveled_distance = 0;
2045                         }
2046                 }
2047
2048                 if (self.BUTTON_CROUCH && !self.hook.state)
2049                 {
2050                         if (!self.crouch)
2051                         {
2052                                 self.crouch = TRUE;
2053                                 self.view_ofs = PL_CROUCH_VIEW_OFS;
2054                                 setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX);
2055                                 player_setanim(self.anim_duck, FALSE, TRUE, TRUE);
2056                         }
2057                 }
2058                 else
2059                 {
2060                         if (self.crouch)
2061                         {
2062                                 tracebox(self.origin, PL_MIN, PL_MAX, self.origin, FALSE, self);
2063                                 if (!trace_startsolid)
2064                                 {
2065                                         self.crouch = FALSE;
2066                                         self.view_ofs = PL_VIEW_OFS;
2067                                         setsize (self, PL_MIN, PL_MAX);
2068                                 }
2069                         }
2070                 }
2071
2072                 FixPlayermodel();
2073
2074                 GrapplingHookFrame();
2075
2076                 W_WeaponFrame();
2077
2078                 {
2079                         float zoomfactor, zoomspeed, zoomdir;
2080                         zoomfactor = self.cvar_cl_zoomfactor;
2081                         if(zoomfactor < 1 || zoomfactor > 16)
2082                                 zoomfactor = 2.5;
2083                         zoomspeed = self.cvar_cl_zoomspeed;
2084                         if(zoomspeed >= 0) // < 0 is instant zoom
2085                                 if(zoomspeed < 0.5 || zoomspeed > 16)
2086                                         zoomspeed = 3.5;
2087
2088                         zoomdir = self.BUTTON_ZOOM;
2089                         if(self.BUTTON_ATCK2)
2090                                 if(self.weapon == WEP_NEX)
2091                                         if(!g_minstagib)
2092                                                 zoomdir = 1;
2093
2094                         if(zoomdir)
2095                                 self.has_zoomed = 1;
2096
2097                         if(self.has_zoomed)
2098                         {
2099                                 if(zoomspeed <= 0) // instant zoom
2100                                 {
2101                                         if(zoomdir)
2102                                                 self.viewzoom = 1 / zoomfactor;
2103                                         else
2104                                                 self.viewzoom = 1;
2105                                 }
2106                                 else
2107                                 {
2108                                         // geometric zoom would be:
2109                                         //   self.viewzoom = bound(1 / zoomfactor, self.viewzoom * pow(zoomfactor, (zoomdir ? -1 : 1) * frametime * zoomspeed), 1);
2110                                         // however, testing showed that arithmetic/harmonic zoom works better
2111                                         if(zoomdir)
2112                                                 // self.viewzoom = 1 / bound(1, 1 / self.viewzoom + (zoomdir ? 1 : -1) * frametime * zoomspeed * (zoomfactor - 1), zoomfactor);
2113                                                 // zoom in = arithmetic: 1x, 2x, 3x, 4x, ..., 8x
2114                                                 self.viewzoom = 1 / bound(1, 1 / self.viewzoom + frametime * zoomspeed * (zoomfactor - 1), zoomfactor);
2115                                         else
2116                                                 // self.viewzoom = bound(1 / zoomfactor, self.viewzoom + (zoomdir ? -1 : 1) * frametime * zoomspeed * (1 - 1 / zoomfactor), 1);
2117                                                 // zoom out = harmonic: 8/1x, 8/2x, 8/3x, 8/4x, ..., 8/8x
2118                                                 self.viewzoom = bound(1 / zoomfactor, self.viewzoom + frametime * zoomspeed * (1 - 1 / zoomfactor), 1);
2119                                 }
2120                         }
2121                         else
2122                                 self.viewzoom = min(1, self.viewzoom + frametime); // spawn zoom-in
2123                 }
2124
2125                 player_powerups();
2126                 player_regen();
2127                 player_anim();
2128
2129                 if (g_minstagib)
2130                         minstagib_ammocheck();
2131
2132                 ctf_setstatus();
2133                 kh_setstatus();
2134
2135                 //self.angles_y=self.v_angle_y + 90;   // temp
2136
2137                 //if (TetrisPreFrame()) return;
2138         } else if(gameover) {
2139                 if (intermission_running)
2140                         IntermissionThink ();   // otherwise a button could be missed between
2141                 return;
2142         } else if(self.classname == "observer") {
2143                 ObserverThink();
2144         } else if(self.classname == "spectator") {
2145                 SpectatorThink();
2146         }
2147 }
2148
2149
2150 /*
2151 =============
2152 PlayerPostThink
2153
2154 Called every frame for each client after the physics are run
2155 =============
2156 */
2157 .float idlekick_lasttimeleft;
2158 void PlayerPostThink (void)
2159 {
2160         // Savage: Check for nameless players
2161         if (strlen(self.netname) < 1) {
2162                 self.netname = "Player";
2163                 stuffcmd(self, "seta _cl_name Player\n");
2164         }
2165
2166         if(sv_maxidle)
2167         {
2168                 float timeleft;
2169                 timeleft = ceil(sv_maxidle - (time - self.parm_idlesince));
2170                 if(timeleft <= 0)
2171                 {
2172                         bprint("^3", self.netname, "^3 was kicked for idling.\n");
2173                         announce(self, "announcer/robotic/terminated.ogg");
2174                         dropclient(self);
2175                         return;
2176                 }
2177                 else if(timeleft <= 10)
2178                 {
2179                         if(timeleft != self.idlekick_lasttimeleft)
2180                         {
2181                                 centerprint_atprio(self, CENTERPRIO_IDLEKICK, strcat("^3Stop idling!\n^3Disconnecting in ", ftos(timeleft), "..."));
2182                                 announce(self, strcat("announcer/robotic/", ftos(timeleft), ".ogg"));
2183                         }
2184                 }
2185                 else
2186                 {
2187                         centerprint_expire(self, CENTERPRIO_IDLEKICK);
2188                 }
2189                 self.idlekick_lasttimeleft = timeleft;
2190         }
2191
2192         if(self.classname == "player") {
2193                 CheckRules_Player();
2194                 UpdateChatBubble();
2195                 UpdateTeamBubble();
2196                 if (self.impulse)
2197                         ImpulseCommands();
2198                 if (intermission_running)
2199                         return;         // intermission or finale
2200
2201                 //PrintWelcomeMessage(self);
2202                 //if (TetrisPostFrame()) return;
2203
2204                 // restart countdown
2205                 if (restart_countdown) {
2206                         if(time < restart_countdown) {
2207                                 if (!cvar("sv_ready_restart_after_countdown"))
2208                                 {
2209                                         self.movetype = MOVETYPE_NONE;
2210                                         self.velocity = '0 0 0';
2211                                         self.avelocity = '0 0 0';
2212                                         self.movement = '0 0 0';
2213                                 }
2214                         }
2215                         else
2216                         {
2217                                 //allow the player to move again if sv_ready_restart_after_countdown is not used and countdown is over
2218                                 if (!cvar("sv_ready_restart_after_countdown"))
2219                                 {
2220                                         if(self.movetype == MOVETYPE_NONE)
2221                                         {
2222                                                 self.movetype = MOVETYPE_WALK;
2223                                         }
2224                                 }
2225                         }
2226                 }
2227
2228         } else if (self.classname == "observer") {
2229                 //do nothing
2230         } else if (self.classname == "spectator") {
2231                 //do nothing
2232         }
2233
2234         /*
2235         float i;
2236         for(i = 0; i < 1000; ++i)
2237         {
2238                 vector end;
2239                 end = self.origin + '0 0 1024' + 512 * randomvec();
2240                 tracebox(self.origin, self.mins, self.maxs, end, MOVE_NORMAL, self);
2241                 if(trace_fraction < 1)
2242                 if(!(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
2243                 {
2244                         print("I HIT SOLID: ", vtos(self.origin), " -> ", vtos(end), "\n");
2245                         break;
2246                 }
2247         }
2248         */
2249
2250         Arena_Warmup();
2251 }