data/qcsrc/server/cl_client.qc

   1 void race_send_recordtime(float msg);
   2 void race_SendRankings(float pos, float prevpos, float del, float msg);
   3
   4 void send_CSQC_teamnagger() {
   5         WriteByte(0, SVC_TEMPENTITY);
   6         WriteByte(0, TE_CSQC_TEAMNAGGER);
   7 }
   8
   9 void Announce(string snd) {
  10         WriteByte(MSG_ALL, SVC_TEMPENTITY);
  11         WriteByte(MSG_ALL, TE_CSQC_ANNOUNCE);
  12         WriteString(MSG_ALL, snd);
  13 }
  14
  15 void AnnounceTo(entity e, string snd) {
  16         msg_entity = e;
  17         WriteByte(MSG_ONE, SVC_TEMPENTITY);
  18         WriteByte(MSG_ONE, TE_CSQC_ANNOUNCE);
  19         WriteString(MSG_ONE, snd);
  20 }
  21
  22 float ClientData_Send(entity to, float sf)
  23 {
  24         if(to != self.owner)
  25         {
  26                 error("wtf");
  27                 return FALSE;
  28         }
  29
  30         entity e;
  31
  32         e = to;
  33         if(to.classname == "spectator")
  34                 e = to.enemy;
  35
  36         sf = 0;
  37
  38         if(e.race_completed)
  39                 sf |= 1; // forced scoreboard
  40         if(to.spectatee_status)
  41                 sf |= 2; // spectator ent number follows
  42         if(e.zoomstate)
  43                 sf |= 4; // zoomed
  44         if(e.porto_v_angle_held)
  45                 sf |= 8; // angles held
  46
  47         WriteByte(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
  48         WriteByte(MSG_ENTITY, sf);
  49
  50         if(sf & 2)
  51                 WriteByte(MSG_ENTITY, to.spectatee_status);
  52
  53         if(sf & 8)
  54         {
  55                 WriteAngle(MSG_ENTITY, e.v_angle_x);
  56                 WriteAngle(MSG_ENTITY, e.v_angle_y);
  57         }
  58
  59         return TRUE;
  60 }
  61
  62 void ClientData_Attach()
  63 {
  64         Net_LinkEntity(self.clientdata = spawn(), FALSE, 0, ClientData_Send);
  65         self.clientdata.drawonlytoclient = self;
  66         self.clientdata.owner = self;
  67 }
  68
  69 void ClientData_Detach()
  70 {
  71         remove(self.clientdata);
  72         self.clientdata = world;
  73 }
  74
  75 void ClientData_Touch(entity e)
  76 {
  77         e.clientdata.SendFlags = 1;
  78
  79         // make it spectatable
  80         entity e2;
  81         FOR_EACH_REALCLIENT(e2)
  82         {
  83                 if(e2 != e)
  84                         if(e2.classname == "spectator")
  85                                 if(e2.enemy == e)
  86                                         e2.clientdata.SendFlags = 1;
  87         }
  88 }
  89
  90
  91 .vector spawnpoint_score;
  92 .string netname_previous;
  93
  94 void spawnfunc_info_player_survivor (void)
  95 {
  96         spawnfunc_info_player_deathmatch();
  97 }
  98
  99 void spawnfunc_info_player_start (void)
 100 {
 101         spawnfunc_info_player_deathmatch();
 102 }
 103
 104 void spawnfunc_info_player_deathmatch (void)
 105 {
 106         self.classname = "info_player_deathmatch";
 107         relocate_spawnpoint();
 108 }
 109
 110 void spawnpoint_use()
 111 {
 112         if(teams_matter)
 113         if(have_team_spawns > 0)
 114         {
 115                 self.team = activator.team;
 116                 some_spawn_has_been_used = 1;
 117         }
 118 };
 119
 120 // Returns:
 121 //   _x: prio (-1 if unusable)
 122 //   _y: weight
 123 vector Spawn_Score(entity spot, entity playerlist, float teamcheck, float anypoint)
 124 {
 125         float shortest, thisdist;
 126         float prio;
 127         entity player;
 128
 129         prio = 0;
 130
 131         // filter out spots for the wrong team
 132         if(teamcheck)
 133         if(spot.team != teamcheck)
 134                 return '-1 0 0';
 135
 136         if(race_spawns)
 137                 if(spot.target == "")
 138                         return '-1 0 0';
 139
 140         if(clienttype(self) == CLIENTTYPE_REAL)
 141         {
 142                 if(spot.restriction == 1)
 143                         return '-1 0 0';
 144         }
 145         else
 146         {
 147                 if(spot.restriction == 2)
 148                         return '-1 0 0';
 149         }
 150
 151         // filter out spots for assault
 152         if(spot.target != "") {
 153                 local entity ent;
 154                 float good, found;
 155                 ent = find(world, targetname, spot.target);
 156
 157                 while(ent) {
 158                         if(ent.classname == "target_objective")
 159                         {
 160                                 found = 1;
 161                                 if(ent.health < 0 || ent.health >= ASSAULT_VALUE_INACTIVE)
 162                                         return '-1 0 0';
 163                                 good = 1;
 164                         }
 165                         else if(ent.classname == "trigger_race_checkpoint")
 166                         {
 167                                 found = 1;
 168                                 if(!anypoint) // spectators may spawn everywhere
 169
 170                                 {
 171                                         if(g_race_qualifying)
 172                                         {
 173                                                 // spawn at first
 174                                                 if(ent.race_checkpoint != 0)
 175                                                         return '-1 0 0';
 176                                                 if(spot.race_place != race_lowest_place_spawn)
 177                                                         return '-1 0 0';
 178                                         }
 179                                         else
 180                                         {
 181                                                 if(ent.race_checkpoint != self.race_respawn_checkpoint)
 182                                                         return '-1 0 0';
 183                                                 // try reusing the previous spawn
 184                                                 if(ent == self.race_respawn_spotref || spot == self.race_respawn_spotref)
 185                                                         prio += 1;
 186                                                 if(ent.race_checkpoint == 0)
 187                                                 {
 188                                                         float pl;
 189                                                         pl = self.race_place;
 190                                                         if(pl > race_highest_place_spawn)
 191                                                                 pl = 0;
 192                                                         if(pl == 0 && !self.race_started)
 193                                                                 pl = race_highest_place_spawn; // use last place if he has not even touched finish yet
 194                                                         if(spot.race_place != pl)
 195                                                                 return '-1 0 0';
 196                                                 }
 197                                         }
 198                                 }
 199                                 good = 1;
 200                         }
 201                         ent = find(ent, targetname, spot.target);
 202                 }
 203
 204                 if(found && !good)
 205                         return '-1 0 0';
 206         }
 207
 208         player = playerlist;
 209         shortest = vlen(world.maxs - world.mins);
 210         for(player = playerlist; player; player = player.chain)
 211                 if (player != self)
 212                 {
 213                         thisdist = vlen(player.origin - spot.origin);
 214                         if (thisdist < shortest)
 215                                 shortest = thisdist;
 216                 }
 217         return prio * '1 0 0' + shortest * '0 1 0';
 218 }
 219
 220 float spawn_allbad;
 221 float spawn_allgood;
 222 entity Spawn_FilterOutBadSpots(entity firstspot, entity playerlist, float mindist, float teamcheck, float anypoint)
 223 {
 224         local entity spot, spotlist, spotlistend;
 225         spawn_allgood = TRUE;
 226         spawn_allbad = TRUE;
 227
 228         spotlist = world;
 229         spotlistend = world;
 230
 231         for(spot = firstspot; spot; spot = spot.chain)
 232         {
 233                 spot.spawnpoint_score = Spawn_Score(spot, playerlist, teamcheck, anypoint);
 234
 235                 if(cvar("spawn_debugview"))
 236                 {
 237                         setmodel(spot, "models/runematch/rune.mdl");
 238                         if(spot.spawnpoint_score_y < mindist)
 239                         {
 240                                 spot.colormod = '1 0 0';
 241                                 spot.scale = 1;
 242                         }
 243                         else
 244                         {
 245                                 spot.colormod = '0 1 0';
 246                                 spot.scale = spot.spawnpoint_score_y / mindist;
 247                         }
 248                 }
 249
 250                 if(spot.spawnpoint_score_x >= 0) // spawning allowed here
 251                 {
 252                         if(spot.spawnpoint_score_y < mindist)
 253                         {
 254                                 // too short distance
 255                                 spawn_allgood = FALSE;
 256                         }
 257                         else
 258                         {
 259                                 // perfect
 260                                 spawn_allbad = FALSE;
 261
 262                                 if(spotlistend)
 263                                         spotlistend.chain = spot;
 264                                 spotlistend = spot;
 265                                 if(!spotlist)
 266                                         spotlist = spot;
 267
 268                                 /*
 269                                 if(teamcheck)
 270                                 if(spot.team != teamcheck)
 271                                         error("invalid spawn added");
 272
 273                                 print("added ", etos(spot), "\n");
 274                                 */
 275                         }
 276                 }
 277         }
 278         if(spotlistend)
 279                 spotlistend.chain = world;
 280
 281         /*
 282                 entity e;
 283                 if(teamcheck)
 284                         for(e = spotlist; e; e = e.chain)
 285                         {
 286                                 print("seen ", etos(e), "\n");
 287                                 if(e.team != teamcheck)
 288                                         error("invalid spawn found");
 289                         }
 290         */
 291
 292         return spotlist;
 293 }
 294
 295 entity Spawn_WeightedPoint(entity firstspot, float lower, float upper, float exponent)
 296 {
 297         // weight of a point: bound(lower, mindisttoplayer, upper)^exponent
 298         // multiplied by spot.cnt (useful if you distribute many spawnpoints in a small area)
 299         local entity spot;
 300
 301         RandomSelection_Init();
 302         for(spot = firstspot; spot; spot = spot.chain)
 303                 RandomSelection_Add(spot, 0, string_null, pow(bound(lower, spot.spawnpoint_score_y, upper), exponent) * spot.cnt, (spot.spawnpoint_score_y >= lower) * 0.5 + spot.spawnpoint_score_x);
 304
 305         return RandomSelection_chosen_ent;
 306 }
 307
 308 /*
 309 =============
 310 SelectSpawnPoint
 311
 312 Finds a point to respawn
 313 =============
 314 */
 315 entity SelectSpawnPoint (float anypoint)
 316 {
 317         local float teamcheck;
 318         local entity firstspot_new;
 319         local entity spot, firstspot, playerlist;
 320
 321         spot = find (world, classname, "testplayerstart");
 322         if (spot)
 323                 return spot;
 324
 325         teamcheck = 0;
 326
 327         if(!anypoint && have_team_spawns > 0)
 328                 teamcheck = self.team;
 329
 330         // get the list of players
 331         playerlist = findchain(classname, "player");
 332         // get the entire list of spots
 333         firstspot = findchain(classname, "info_player_deathmatch");
 334         // filter out the bad ones
 335         // (note this returns the original list if none survived)
 336         if(anypoint)
 337         {
 338                 spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 339         }
 340         else
 341         {
 342                 firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, 100, teamcheck, anypoint);
 343                 if(!firstspot_new)
 344                         firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, -1, teamcheck, anypoint);
 345                 firstspot = firstspot_new;
 346
 347                 // there is 50/50 chance of choosing a random spot or the furthest spot
 348                 // (this means that roughly every other spawn will be furthest, so you
 349                 // usually won't get fragged at spawn twice in a row)
 350                 if (arena_roundbased && !g_ca)
 351                 {
 352                         firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, 800, teamcheck, anypoint);
 353                         if(firstspot_new)
 354                                 firstspot = firstspot_new;
 355                         spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 356                 }
 357                 else if (random() > cvar("g_spawn_furthest"))
 358                         spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 359                 else
 360                         spot = Spawn_WeightedPoint(firstspot, 1, 5000, 5); // chooses a far far away spawnpoint
 361         }
 362
 363         if(cvar("spawn_debugview"))
 364         {
 365                 print("spot mindistance: ", vtos(spot.spawnpoint_score), "\n");
 366
 367                 entity e;
 368                 if(teamcheck)
 369                         for(e = firstspot; e; e = e.chain)
 370                                 if(e.team != teamcheck)
 371                                         error("invalid spawn found");
 372         }
 373
 374         if (!spot)
 375         {
 376                 if(cvar("spawn_debug"))
 377                         GotoNextMap();
 378                 else
 379                 {
 380                         if(some_spawn_has_been_used)
 381                                 return world; // team can't spawn any more, because of actions of other team
 382                         else
 383                                 error("Cannot find a spawn point - please fix the map!");
 384                 }
 385         }
 386
 387         return spot;
 388 }
 389
 390 /*
 391 =============
 392 CheckPlayerModel
 393
 394 Checks if the argument string can be a valid playermodel.
 395 Returns a valid one in doubt.
 396 =============
 397 */
 398 string FallbackPlayerModel = "models/player/marine.zym";
 399 string CheckPlayerModel(string plyermodel) {
 400         if(strlen(plyermodel) < 4)
 401                 return FallbackPlayerModel;
 402         if( substring(plyermodel,0,14) != "models/player/")
 403                 return FallbackPlayerModel;
 404         else if(cvar("sv_servermodelsonly"))
 405         {
 406                 if(substring(plyermodel,-4,4) != ".zym")
 407                 if(substring(plyermodel,-4,4) != ".dpm")
 408                 if(substring(plyermodel,-4,4) != ".md3")
 409                 if(substring(plyermodel,-4,4) != ".psk")
 410                         return FallbackPlayerModel;
 411                 // forbid the LOD models
 412                 if(substring(plyermodel, -9,5) == "_lod1")
 413                         return FallbackPlayerModel;
 414                 if(substring(plyermodel, -9,5) == "_lod2")
 415                         return FallbackPlayerModel;
 416                 if(plyermodel != strtolower(plyermodel))
 417                         return FallbackPlayerModel;
 418                 if(!fexists(plyermodel))
 419                         return FallbackPlayerModel;
 420         }
 421         return plyermodel;
 422 }
 423
 424 /*
 425 =============
 426 Client_customizeentityforclient
 427
 428 LOD reduction
 429 =============
 430 */
 431 void Client_uncustomizeentityforclient()
 432 {
 433         if(self.modelindex == 0) // no need to uncustomize then
 434                 return;
 435         self.modelindex = self.modelindex_lod0;
 436         self.skin = self.skinindex;
 437 }
 438
 439 float Client_customizeentityforclient()
 440 {
 441         entity modelsource;
 442
 443         if(self.modelindex == 0)
 444                 return TRUE;
 445
 446         // forcemodel stuff
 447
 448 #ifdef PROFILING
 449         float t0;
 450         t0 = gettime(GETTIME_HIRES); // reference
 451 #endif
 452
 453         modelsource = self;
 454
 455 #ifdef ALLOW_FORCEMODELS
 456         if(other.cvar_cl_forceplayermodelsfromnexuiz)
 457                 if not(self.modelindex_lod0_from_nexuiz)
 458                         modelsource = other;
 459         if(other.cvar_cl_forceplayermodels && sv_clforceplayermodels)
 460                 modelsource = other;
 461 #endif
 462
 463         self.skin = modelsource.skinindex;
 464
 465 #if 0
 466         if(modelsource == self)
 467                 self.skin = modelsource.skinindex;
 468         else
 469                 self.skin = mod(modelsource.skinindex, 3); // forbid the fbskins as forced skins
 470 #endif
 471
 472         // self: me
 473         // other: the player viewing me
 474         float distance;
 475         float f;
 476
 477         if(other.cvar_cl_playerdetailreduction <= 0)
 478         {
 479                 if(other.cvar_cl_playerdetailreduction <= -2)
 480                         self.modelindex = modelsource.modelindex_lod2;
 481                 else if(other.cvar_cl_playerdetailreduction <= -1)
 482                         self.modelindex = modelsource.modelindex_lod1;
 483                 else
 484                         self.modelindex = modelsource.modelindex_lod0;
 485         }
 486         else
 487         {
 488                 distance = vlen(self.origin - other.origin);
 489                 f = (distance + 100.0) * other.cvar_cl_playerdetailreduction;
 490                 if(f > sv_loddistance2)
 491                         self.modelindex = modelsource.modelindex_lod2;
 492                 else if(f > sv_loddistance1)
 493                         self.modelindex = modelsource.modelindex_lod1;
 494                 else
 495                         self.modelindex = modelsource.modelindex_lod0;
 496         }
 497
 498 #ifdef PROFILING
 499         float t1;
 500         t1 = gettime(GETTIME_HIRES); // reference
 501         client_cefc_accumulator += (t1 - t0);
 502 #endif
 503
 504         return TRUE;
 505 }
 506
 507 void UpdatePlayerSounds();
 508 void setmodel_lod(entity e, string modelname)
 509 {
 510         string s;
 511
 512         if(sv_loddistance1)
 513         {
 514                 // FIXME: this only supports 3-letter extensions
 515                 s = strcat(substring(modelname, 0, strlen(modelname)-4), "_lod1", substring(modelname, -4, 4));
 516                 if(fexists(s))
 517                 {
 518                         setmodel(e, s); // players have high precision
 519                         self.modelindex_lod1 = self.modelindex;
 520                 }
 521                 else
 522                         self.modelindex_lod1 = -1;
 523
 524                 s = strcat(substring(modelname, 0, strlen(modelname)-4), "_lod2", substring(modelname, -4, 4));
 525                 if(fexists(s))
 526                 {
 527                         setmodel(e, s); // players have high precision
 528                         self.modelindex_lod2 = self.modelindex;
 529                 }
 530                 else
 531                         self.modelindex_lod2 = -1;
 532
 533                 precache_model(modelname);
 534                 setmodel(e, modelname); // players have high precision
 535                 self.modelindex_lod0 = self.modelindex;
 536
 537                 if(self.modelindex_lod1 < 0)
 538                         self.modelindex_lod1 = self.modelindex;
 539
 540                 if(self.modelindex_lod2 < 0)
 541                         self.modelindex_lod2 = self.modelindex;
 542         }
 543         else
 544         {
 545                 precache_model(modelname);
 546                 setmodel(e, modelname); // players have high precision
 547                 self.modelindex_lod0 = self.modelindex;
 548                         // save it for possible player model forcing
 549         }
 550
 551         s = whichpack(self.model);
 552         self.modelindex_lod0_from_nexuiz = ((s == "") || (substring(s, 0, 4) == "data"));
 553
 554         player_setupanimsformodel();
 555         UpdatePlayerSounds();
 556 }
 557
 558 /*
 559 =============
 560 PutObserverInServer
 561
 562 putting a client as observer in the server
 563 =============
 564 */
 565 void FixPlayermodel();
 566 void PutObserverInServer (void)
 567 {
 568         entity  spot;
 569
 570         race_PreSpawnObserver();
 571
 572         spot = SelectSpawnPoint (TRUE);
 573         if(!spot)
 574                 error("No spawnpoints for observers?!?\n");
 575         RemoveGrapplingHook(self); // Wazat's Grappling Hook
 576
 577         if(clienttype(self) == CLIENTTYPE_REAL)
 578         {
 579                 msg_entity = self;
 580                 WriteByte(MSG_ONE, SVC_SETVIEW);
 581                 WriteEntity(MSG_ONE, self);
 582         }
 583
 584         DropAllRunes(self);
 585         kh_Key_DropAll(self, TRUE);
 586
 587         Portal_ClearAll(self);
 588
 589         if(self.flagcarried)
 590                 DropFlag(self.flagcarried, world, world);
 591
 592         if(self.ballcarried)
 593                 DropBall(self.ballcarried, self.origin + self.ballcarried.origin, self.velocity);
 594
 595         WaypointSprite_PlayerDead();
 596
 597         if not(g_ca)  // don't reset teams when moving a ca player to the spectators
 598                 self.team = -1;  // move this as it is needed to log the player spectating in eventlog
 599
 600         if(self.killcount != -666) {
 601                 if(g_lms) {
 602                         if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
 603                                 bprint ("^4", self.netname, "^4 has no more lives left\n");
 604                         else
 605                                 bprint ("^4", self.netname, "^4 is spectating now\n"); // TODO turn this into a proper forfeit?
 606                 } else
 607                         bprint ("^4", self.netname, "^4 is spectating now\n");
 608
 609                 if(self.just_joined == FALSE) {
 610                         LogTeamchange(self.playerid, -1, 4);
 611                 } else
 612                         self.just_joined = FALSE;
 613         }
 614
 615         PlayerScore_Clear(self); // clear scores when needed
 616
 617         self.spectatortime = time;
 618
 619         self.classname = "observer";
 620         self.iscreature = FALSE;
 621         self.health = -666;
 622         self.takedamage = DAMAGE_NO;
 623         self.solid = SOLID_NOT;
 624         self.movetype = MOVETYPE_NOCLIP;
 625         self.flags = FL_CLIENT | FL_NOTARGET;
 626         self.armorvalue = 666;
 627         self.effects = 0;
 628         self.armorvalue = cvar("g_balance_armor_start");
 629         self.pauserotarmor_finished = 0;
 630         self.pauserothealth_finished = 0;
 631         self.pauseregen_finished = 0;
 632         self.damageforcescale = 0;
 633         self.death_time = 0;
 634         self.dead_frame = 0;
 635         self.alpha = 0;
 636         self.scale = 0;
 637         self.fade_time = 0;
 638         self.pain_frame = 0;
 639         self.pain_finished = 0;
 640         self.strength_finished = 0;
 641         self.invincible_finished = 0;
 642         self.pushltime = 0;
 643         self.think = SUB_Null;
 644         self.nextthink = 0;
 645         self.hook_time = 0;
 646         self.runes = 0;
 647         self.deadflag = DEAD_NO;
 648         self.angles = spot.angles;
 649         self.angles_z = 0;
 650         self.fixangle = TRUE;
 651         self.crouch = FALSE;
 652
 653         self.view_ofs = PL_VIEW_OFS;
 654         setorigin (self, spot.origin);
 655         setsize (self, '0 0 0', '0 0 0');
 656         self.prevorigin = self.origin;
 657         self.items = 0;
 658         self.weapons = 0;
 659         self.model = "";
 660         FixPlayermodel();
 661         self.model = "";
 662         self.modelindex = 0;
 663         self.weapon = 0;
 664         self.weaponmodel = "";
 665         self.weaponentity = world;
 666         self.exteriorweaponentity = world;
 667         self.killcount = -666;
 668         self.velocity = '0 0 0';
 669         self.avelocity = '0 0 0';
 670         self.punchangle = '0 0 0';
 671         self.punchvector = '0 0 0';
 672         self.oldvelocity = self.velocity;
 673         self.fire_endtime = -1;
 674
 675         if(sv_loddistance1)
 676                 SetCustomizer(self, Client_customizeentityforclient, Client_uncustomizeentityforclient);
 677
 678         if(g_arena)
 679         {
 680                 if(self.version_mismatch)
 681                 {
 682                         Spawnqueue_Unmark(self);
 683                         Spawnqueue_Remove(self);
 684                 }
 685                 else
 686                 {
 687                         Spawnqueue_Insert(self);
 688                 }
 689         }
 690         else if(g_lms)
 691         {
 692                 // Only if the player cannot play at all
 693                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) == 666)
 694                         self.frags = FRAGS_SPECTATOR;
 695                 else
 696                         self.frags = FRAGS_LMS_LOSER;
 697         }
 698         else
 699                 self.frags = FRAGS_SPECTATOR;
 700 }
 701
 702 float RestrictSkin(float s)
 703 {
 704         if(!teams_matter)
 705                 return s;
 706         if(s == 6)
 707                 return 6;
 708         return mod(s, 3);
 709 }
 710
 711 void FixPlayermodel()
 712 {
 713         local string defaultmodel;
 714         local float defaultskin, chmdl, oldskin;
 715         local vector m1, m2;
 716
 717         defaultmodel = "";
 718
 719         if(cvar("sv_defaultcharacter") == 1) {
 720                 defaultskin = 0;
 721
 722                 if(teams_matter)
 723                 {
 724                         string s;
 725                         s = Team_ColorNameLowerCase(self.team);
 726                         if(s != "neutral")
 727                         {
 728                                 defaultmodel = cvar_string(strcat("sv_defaultplayermodel_", s));
 729                                 defaultskin = cvar(strcat("sv_defaultplayerskin_", s));
 730                         }
 731                 }
 732
 733                 if(defaultmodel == "")
 734                 {
 735                         defaultmodel = cvar_string("sv_defaultplayermodel");
 736                         defaultskin = cvar("sv_defaultplayerskin");
 737                 }
 738         }
 739
 740         if(self.modelindex == 0 && self.deadflag == DEAD_NO)
 741         {
 742                 if(self.model != "")
 743                         bprint("\{1}^1Player ", self.netname, "^1 has a zero modelindex, trying to fix...\n");
 744                 self.model = ""; // force the != checks to return true
 745         }
 746
 747         if(defaultmodel != "")
 748         {
 749                 if (defaultmodel != self.model)
 750                 {
 751                         m1 = self.mins;
 752                         m2 = self.maxs;
 753                         setmodel_lod (self, defaultmodel);
 754                         setsize (self, m1, m2);
 755                         chmdl = TRUE;
 756                 }
 757
 758                 oldskin = self.skinindex;
 759                 self.skinindex = defaultskin;
 760         } else {
 761                 if (self.playermodel != self.model || self.playermodel == "")
 762                 {
 763                         self.playermodel = CheckPlayerModel(self.playermodel); // this is never "", so no endless loop
 764                         m1 = self.mins;
 765                         m2 = self.maxs;
 766                         setmodel_lod (self, self.playermodel);
 767                         setsize (self, m1, m2);
 768                         chmdl = TRUE;
 769                 }
 770
 771                 oldskin = self.skinindex;
 772                 self.skinindex = RestrictSkin(stof(self.playerskin));
 773         }
 774
 775         if(chmdl || oldskin != self.skinindex)
 776                 self.species = player_getspecies(); // model or skin has changed
 777
 778         if(!teams_matter)
 779                 if(strlen(cvar_string("sv_defaultplayercolors")))
 780                         if(self.clientcolors != cvar("sv_defaultplayercolors"))
 781                                 setcolor(self, cvar("sv_defaultplayercolors"));
 782 }
 783
 784 void PlayerTouchExplode(entity p1, entity p2)
 785 {
 786         vector org;
 787         org = (p1.origin + p2.origin) * 0.5;
 788         org_z += (p1.mins_z + p2.mins_z) * 0.5;
 789
 790         te_explosion(org);
 791
 792         entity e;
 793         e = spawn();
 794         setorigin(e, org);
 795         RadiusDamage(e, world, g_touchexplode_damage, g_touchexplode_edgedamage, g_touchexplode_radius, world, g_touchexplode_force, DEATH_TOUCHEXPLODE, world);
 796         remove(e);
 797 }
 798
 799 /*
 800 =============
 801 PutClientInServer
 802
 803 Called when a client spawns in the server
 804 =============
 805 */
 806 //void() ctf_playerchanged;
 807 void PutClientInServer (void)
 808 {
 809         if(clienttype(self) == CLIENTTYPE_BOT)
 810         {
 811                 self.classname = "player";
 812         }
 813         else if(clienttype(self) == CLIENTTYPE_REAL)
 814         {
 815                 msg_entity = self;
 816                 WriteByte(MSG_ONE, SVC_SETVIEW);
 817                 WriteEntity(MSG_ONE, self);
 818         }
 819
 820         // player is dead and becomes observer
 821         // FIXME fix LMS scoring for new system
 822         if(g_lms)
 823         {
 824                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
 825                         self.classname = "observer";
 826         }
 827
 828         if(g_arena || (g_ca && !allowed_to_spawn))
 829         if(!self.spawned)
 830                 self.classname = "observer";
 831
 832         if(gameover)
 833                 self.classname = "observer";
 834
 835         if(self.classname == "player" && (!g_ca || (g_ca && allowed_to_spawn))) {
 836                 entity spot, oldself;
 837                 float j;
 838
 839                 if(self.team < 0)
 840                         JoinBestTeam(self, FALSE, TRUE);
 841
 842                 race_PreSpawn();
 843
 844                 spot = SelectSpawnPoint (FALSE);
 845                 if(!spot)
 846                 {
 847                         centerprint(self, "Sorry, no spawnpoints available!\nHope your team can fix it...");
 848                         return; // spawn failed
 849                 }
 850
 851                 RemoveGrapplingHook(self); // Wazat's Grappling Hook
 852
 853                 self.classname = "player";
 854                 self.wasplayer = TRUE;
 855                 self.iscreature = TRUE;
 856                 self.movetype = MOVETYPE_WALK;
 857                 self.solid = SOLID_SLIDEBOX;
 858                 if(cvar("g_playerclip_collisions"))
 859                         self.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP;
 860                 else
 861                         self.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY;
 862                 self.frags = FRAGS_PLAYER;
 863                 if(independent_players)
 864                         MAKE_INDEPENDENT_PLAYER(self);
 865                 self.flags = FL_CLIENT;
 866                 self.takedamage = DAMAGE_AIM;
 867                 if(g_minstagib)
 868                         self.effects = EF_FULLBRIGHT;
 869                 else
 870                         self.effects = 0;
 871                 self.air_finished = time + 12;
 872                 self.dmg = 2;
 873
 874                 if(inWarmupStage)
 875                 {
 876                         self.ammo_shells = warmup_start_ammo_shells;
 877                         self.ammo_nails = warmup_start_ammo_nails;
 878                         self.ammo_rockets = warmup_start_ammo_rockets;
 879                         self.ammo_cells = warmup_start_ammo_cells;
 880                         self.ammo_fuel = warmup_start_ammo_fuel;
 881                         self.health = warmup_start_health;
 882                         self.armorvalue = warmup_start_armorvalue;
 883                         self.weapons = warmup_start_weapons;
 884                 }
 885                 else
 886                 {
 887                         self.ammo_shells = start_ammo_shells;
 888                         self.ammo_nails = start_ammo_nails;
 889                         self.ammo_rockets = start_ammo_rockets;
 890                         self.ammo_cells = start_ammo_cells;
 891                         self.ammo_fuel = start_ammo_fuel;
 892                         self.health = start_health;
 893                         self.armorvalue = start_armorvalue;
 894                         self.weapons = start_weapons;
 895                 }
 896
 897                 if(g_weaponarena_random)
 898                         self.weapons = randombits(self.weapons, g_weaponarena_random, FALSE);
 899
 900                 self.items = start_items;
 901                 self.switchweapon = w_getbestweapon(self);
 902                 self.cnt = self.switchweapon;
 903                 self.weapon = 0;
 904                 self.jump_interval = time;
 905
 906                 self.spawnshieldtime = time + cvar("g_spawnshieldtime");
 907                 self.pauserotarmor_finished = time + cvar("g_balance_pause_armor_rot_spawn");
 908                 self.pauserothealth_finished = time + cvar("g_balance_pause_health_rot_spawn");
 909                 self.pauserotfuel_finished = time + cvar("g_balance_pause_fuel_rot_spawn");
 910                 self.pauseregen_finished = time + cvar("g_balance_pause_health_regen_spawn");
 911                 //extend the pause of rotting if client was reset at the beginning of the countdown
 912                 if(!cvar("sv_ready_restart_after_countdown") && time < game_starttime) { // TODO why is this cvar NOTted?
 913                         self.spawnshieldtime += game_starttime - time;
 914                         self.pauserotarmor_finished += game_starttime - time;
 915                         self.pauserothealth_finished += game_starttime - time;
 916                         self.pauseregen_finished += game_starttime - time;
 917                 }
 918                 self.damageforcescale = 2;
 919                 self.death_time = 0;
 920                 self.dead_frame = 0;
 921                 self.alpha = 0;
 922                 self.scale = 0;
 923                 self.fade_time = 0;
 924                 self.pain_frame = 0;
 925                 self.pain_finished = 0;
 926                 self.strength_finished = 0;
 927                 self.invincible_finished = 0;
 928                 self.pushltime = 0;
 929                 // players have no think function
 930                 self.think = SUB_Null;
 931                 self.nextthink = 0;
 932                 self.hook_time = 0;
 933                 self.dmg_team = 0;
 934
 935                 self.metertime = 0;
 936
 937                 self.runes = 0;
 938
 939                 self.deadflag = DEAD_NO;
 940
 941                 self.angles = spot.angles;
 942
 943                 self.angles_z = 0; // never spawn tilted even if the spot says to
 944                 self.fixangle = TRUE; // turn this way immediately
 945                 self.velocity = '0 0 0';
 946                 self.avelocity = '0 0 0';
 947                 self.punchangle = '0 0 0';
 948                 self.punchvector = '0 0 0';
 949                 self.oldvelocity = self.velocity;
 950                 self.fire_endtime = -1;
 951
 952                 msg_entity = self;
 953                 WRITESPECTATABLE_MSG_ONE({
 954                         WriteByte(MSG_ONE, SVC_TEMPENTITY);
 955                         WriteByte(MSG_ONE, TE_CSQC_SPAWN);
 956                 });
 957
 958                 if(sv_loddistance1)
 959                         SetCustomizer(self, Client_customizeentityforclient, Client_uncustomizeentityforclient);
 960
 961                 self.model = "";
 962                 FixPlayermodel();
 963
 964                 self.crouch = FALSE;
 965                 self.view_ofs = PL_VIEW_OFS;
 966                 setsize (self, PL_MIN, PL_MAX);
 967                 self.spawnorigin = spot.origin;
 968                 setorigin (self, spot.origin + '0 0 1' * (1 - self.mins_z - 24));
 969                 // don't reset back to last position, even if new position is stuck in solid
 970                 self.oldorigin = self.origin;
 971                 self.prevorigin = self.origin;
 972                 self.lastrocket = world; // stop rocket guiding, no revenge from the grave!
 973
 974                 if(g_arena)
 975                 {
 976                         Spawnqueue_Remove(self);
 977                         Spawnqueue_Mark(self);
 978                 }
 979
 980                 else if(g_ca)
 981                         self.caplayer = 1;
 982
 983                 self.event_damage = PlayerDamage;
 984
 985                 self.bot_attack = TRUE;
 986
 987                 self.statdraintime = time + 5;
 988                 self.BUTTON_ATCK = self.BUTTON_JUMP = self.BUTTON_ATCK2 = 0;
 989
 990                 if(self.killcount == -666) {
 991                         PlayerScore_Clear(self);
 992                         self.killcount = 0;
 993                 }
 994
 995                 self.cnt = WEP_LASER;
 996                 self.nixnex_lastchange_id = -1;
 997
 998                 CL_SpawnWeaponentity();
 999                 self.alpha = default_player_alpha;
1000                 self.colormod = '1 1 1' * cvar("g_player_brightness");
1001                 self.exteriorweaponentity.alpha = default_weapon_alpha;
1002
1003                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval")*2;
1004                 self.lms_traveled_distance = 0;
1005                 self.speedrunning = FALSE;
1006
1007                 race_PostSpawn(spot);
1008
1009                 if(cvar("spawn_debug"))
1010                 {
1011                         sprint(self, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
1012                         remove(spot);   // usefull for checking if there are spawnpoints, that let drop through the floor
1013                 }
1014
1015                 //stuffcmd(self, "chase_active 0");
1016                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
1017
1018                 if (cvar("g_spawnsound"))
1019                         sound (self, CHAN_TRIGGER, "misc/spawn.wav", VOL_BASE, ATTN_NORM);
1020
1021                 if(g_assault) {
1022                         if(self.team == assault_attacker_team)
1023                                 centerprint(self, "You are attacking!");
1024                         else
1025                                 centerprint(self, "You are defending!");
1026                 }
1027
1028                 target_voicescript_clear(self);
1029
1030                 // reset fields the weapons may use
1031         for (j = WEP_FIRST; j <= WEP_LAST; ++j)
1032             weapon_action(j, WR_RESETPLAYER);
1033
1034                 oldself = self;
1035                 self = spot;
1036                         activator = oldself;
1037                                 SUB_UseTargets();
1038                         activator = world;
1039                 self = oldself;
1040         } else if(self.classname == "observer" || (g_ca && !allowed_to_spawn)) {
1041                 PutObserverInServer ();
1042         }
1043
1044         //if(g_ctf)
1045         //      ctf_playerchanged();
1046 }
1047
1048 float ClientInit_SendEntity(entity to, float sf)
1049 {
1050         WriteByte(MSG_ENTITY, ENT_CLIENT_INIT);
1051         WriteByte(MSG_ENTITY, g_nexball_meter_period * 32);
1052         WriteCoord(MSG_ENTITY, hook_shotorigin_x);
1053         WriteCoord(MSG_ENTITY, hook_shotorigin_y);
1054         WriteCoord(MSG_ENTITY, hook_shotorigin_z);
1055
1056         if(sv_foginterval && world.fog != "")
1057                 WriteString(MSG_ENTITY, world.fog);
1058         else
1059                 WriteString(MSG_ENTITY, "");
1060         WriteByte(MSG_ENTITY, cvar("g_balance_armor_blockpercent") * 255.0);
1061         WriteByte(MSG_ENTITY, cvar("g_balance_weaponswitchdelay") * 255.0);
1062         return TRUE;
1063 }
1064
1065 void ClientInit_Spawn()
1066 {
1067         Net_LinkEntity(spawn(), FALSE, 0, ClientInit_SendEntity);
1068 }
1069
1070 /*
1071 =============
1072 SetNewParms
1073 =============
1074 */
1075 void SetNewParms (void)
1076 {
1077         // initialize parms for a new player
1078         parm1 = -(86400 * 366);
1079 }
1080
1081 /*
1082 =============
1083 SetChangeParms
1084 =============
1085 */
1086 void SetChangeParms (void)
1087 {
1088         // save parms for level change
1089         parm1 = self.parm_idlesince - time;
1090 }
1091
1092 /*
1093 =============
1094 DecodeLevelParms
1095 =============
1096 */
1097 void DecodeLevelParms (void)
1098 {
1099         // load parms
1100         self.parm_idlesince = parm1;
1101         if(self.parm_idlesince == -(86400 * 366))
1102                 self.parm_idlesince = time;
1103
1104         // whatever happens, allow 60 seconds of idling directly after connect for map loading
1105         self.parm_idlesince = max(self.parm_idlesince, time - sv_maxidle + 60);
1106 }
1107
1108 /*
1109 =============
1110 ClientKill
1111
1112 Called when a client types 'kill' in the console
1113 =============
1114 */
1115
1116 void ClientKill_Now_TeamChange()
1117 {
1118         if(self.killindicator_teamchange == -1)
1119         {
1120                 self.team = -1;
1121                 JoinBestTeam( self, FALSE, FALSE );
1122         }
1123         else
1124                 SV_ChangeTeam(self.killindicator_teamchange - 1);
1125 }
1126
1127 void ClientKill_Now()
1128 {
1129         if(self.killindicator_teamchange)
1130                 ClientKill_Now_TeamChange();
1131
1132         // in any case:
1133         Damage(self, self, self, 100000, DEATH_KILL, self.origin, '0 0 0');
1134
1135         if(self.killindicator)
1136         {
1137                 dprint("Cleaned up after a leaked kill indicator.\n");
1138                 remove(self.killindicator);
1139                 self.killindicator = world;
1140         }
1141 }
1142 void KillIndicator_Think()
1143 {
1144         if (!self.owner.modelindex)
1145         {
1146                 self.owner.killindicator = world;
1147                 remove(self);
1148                 return;
1149         }
1150
1151         if(self.cnt <= 0)
1152         {
1153                 self = self.owner;
1154                 ClientKill_Now(); // no oldself needed
1155                 return;
1156         }
1157         else
1158         {
1159                 if(self.cnt <= 10)
1160                         setmodel(self, strcat("models/sprites/", ftos(self.cnt), ".spr32"));
1161                 if(clienttype(self.owner) == CLIENTTYPE_REAL)
1162                 {
1163                         if(self.cnt <= 10)
1164                                 AnnounceTo(self.owner, strcat(ftos(self.cnt), ""));
1165                         if(self.owner.killindicator_teamchange)
1166                         {
1167                                 if(self.owner.killindicator_teamchange == -1)
1168                                         centerprint(self.owner, strcat("Changing team in ", ftos(self.cnt), " seconds"));
1169                                 else
1170                                         centerprint(self.owner, strcat("Changing to ", ColoredTeamName(self.owner.killindicator_teamchange), " in ", ftos(self.cnt), " seconds"));
1171                         }
1172                         else
1173                                 centerprint(self.owner, strcat("^1Suicide in ", ftos(self.cnt), " seconds"));
1174                 }
1175                 self.nextthink = time + 1;
1176                 self.cnt -= 1;
1177         }
1178 }
1179
1180 void ClientKill_TeamChange (float targetteam) // 0 = don't change, -1 = auto
1181 {
1182         float killtime;
1183         entity e;
1184         killtime = cvar("g_balance_kill_delay");
1185
1186         if(g_race_qualifying)
1187                 killtime = 0;
1188
1189         self.killindicator_teamchange = targetteam;
1190
1191         if(!self.killindicator)
1192         {
1193                 if(killtime <= 0 || !self.modelindex || self.deadflag != DEAD_NO)
1194                 {
1195                         ClientKill_Now();
1196                 }
1197                 else
1198                 {
1199                         self.killindicator = spawn();
1200                         self.killindicator.owner = self;
1201                         self.killindicator.scale = 0.5;
1202                         setattachment(self.killindicator, self, "");
1203                         setorigin(self.killindicator, '0 0 52');
1204                         self.killindicator.think = KillIndicator_Think;
1205                         self.killindicator.nextthink = time + (self.lip) * 0.05;
1206                         self.killindicator.cnt = ceil(killtime);
1207                         self.killindicator.count = bound(0, ceil(killtime), 10);
1208                         sprint(self, strcat("^1You'll be dead in ", ftos(self.killindicator.cnt), " seconds\n"));
1209
1210                         for(e = world; (e = find(e, classname, "body")) != world; )
1211                         {
1212                                 if(e.enemy != self)
1213                                         continue;
1214                                 e.killindicator = spawn();
1215                                 e.killindicator.owner = e;
1216                                 e.killindicator.scale = 0.5;
1217                                 setattachment(e.killindicator, e, "");
1218                                 setorigin(e.killindicator, '0 0 52');
1219                                 e.killindicator.think = KillIndicator_Think;
1220                                 e.killindicator.nextthink = time + (e.lip) * 0.05;
1221                                 e.killindicator.cnt = ceil(killtime);
1222                         }
1223                         self.lip = 0;
1224                 }
1225         }
1226         if(self.killindicator)
1227         {
1228                 if(targetteam)
1229                         self.killindicator.colormod = TeamColor(targetteam);
1230                 else
1231                         self.killindicator.colormod = '0 0 0';
1232         }
1233 }
1234
1235 void ClientKill (void)
1236 {
1237         ClientKill_TeamChange(0);
1238 }
1239
1240 void DoTeamChange(float destteam)
1241 {
1242         float t, c0;
1243         if(!teams_matter)
1244         {
1245                 if(destteam >= 0)
1246                         SetPlayerColors(self, destteam);
1247                 return;
1248         }
1249         if(self.classname == "player")
1250         if(destteam == -1)
1251         {
1252                 CheckAllowedTeams(self);
1253                 t = FindSmallestTeam(self, TRUE);
1254                 switch(self.team)
1255                 {
1256                         case COLOR_TEAM1: c0 = c1; break;
1257                         case COLOR_TEAM2: c0 = c2; break;
1258                         case COLOR_TEAM3: c0 = c3; break;
1259                         case COLOR_TEAM4: c0 = c4; break;
1260                         default:          c0 = 999;
1261                 }
1262                 switch(t)
1263                 {
1264                         case 1:
1265                                 if(c0 > c1)
1266                                         destteam = COLOR_TEAM1;
1267                                 break;
1268                         case 2:
1269                                 if(c0 > c2)
1270                                         destteam = COLOR_TEAM2;
1271                                 break;
1272                         case 3:
1273                                 if(c0 > c3)
1274                                         destteam = COLOR_TEAM3;
1275                                 break;
1276                         case 4:
1277                                 if(c0 > c4)
1278                                         destteam = COLOR_TEAM4;
1279                                 break;
1280                 }
1281                 if(destteam == -1)
1282                         return;
1283         }
1284         if(destteam == self.team && destteam >= 0 && !self.killindicator)
1285                 return;
1286         ClientKill_TeamChange(destteam);
1287 }
1288
1289 void FixClientCvars(entity e)
1290 {
1291         // send prediction settings to the client
1292         stuffcmd(e, "\nin_bindmap 0 0\n");
1293         if(g_race || g_cts)
1294                 stuffcmd(e, "cl_cmd settemp cl_movecliptokeyboard 2\n");
1295         if(cvar("g_antilag") == 3) // client side hitscan
1296                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor -1\n");
1297         /*
1298          * we no longer need to stuff this. Remove this comment block if you feel
1299          * 2.3 and higher (or was it 2.2.3?) don't need these any more
1300         stuffcmd(e, strcat("cl_gravity ", ftos(cvar("sv_gravity")), "\n"));
1301         stuffcmd(e, strcat("cl_movement_accelerate ", ftos(cvar("sv_accelerate")), "\n"));
1302         stuffcmd(e, strcat("cl_movement_friction ", ftos(cvar("sv_friction")), "\n"));
1303         stuffcmd(e, strcat("cl_movement_maxspeed ", ftos(cvar("sv_maxspeed")), "\n"));
1304         stuffcmd(e, strcat("cl_movement_airaccelerate ", ftos(cvar("sv_airaccelerate")), "\n"));
1305         stuffcmd(e, strcat("cl_movement_maxairspeed ", ftos(cvar("sv_maxairspeed")), "\n"));
1306         stuffcmd(e, strcat("cl_movement_stopspeed ", ftos(cvar("sv_stopspeed")), "\n"));
1307         stuffcmd(e, strcat("cl_movement_jumpvelocity ", ftos(cvar("sv_jumpvelocity")), "\n"));
1308         stuffcmd(e, strcat("cl_movement_stepheight ", ftos(cvar("sv_stepheight")), "\n"));
1309         stuffcmd(e, strcat("set cl_movement_friction_on_land ", ftos(cvar("sv_friction_on_land")), "\n"));
1310         stuffcmd(e, strcat("set cl_movement_airaccel_qw ", ftos(cvar("sv_airaccel_qw")), "\n"));
1311         stuffcmd(e, strcat("set cl_movement_airaccel_sideways_friction ", ftos(cvar("sv_airaccel_sideways_friction")), "\n"));
1312         stuffcmd(e, "cl_movement_edgefriction 1\n");
1313          */
1314 }
1315
1316 /*
1317 =============
1318 ClientConnect
1319
1320 Called when a client connects to the server
1321 =============
1322 */
1323 //void ctf_clientconnect();
1324 string ColoredTeamName(float t);
1325 void DecodeLevelParms (void);
1326 //void dom_player_join_team(entity pl);
1327 #ifdef UID
1328 .float uid_kicktime;
1329 .string uid;
1330 #endif
1331 void ClientConnect (void)
1332 {
1333         float t;
1334
1335         if(self.flags & FL_CLIENT)
1336         {
1337                 print("Warning: ClientConnect, but already connected!\n");
1338                 return;
1339         }
1340
1341         if(Ban_MaybeEnforceBan(self))
1342                 return;
1343
1344         DecodeLevelParms();
1345
1346         self.classname = "player_joining";
1347
1348         self.flags = FL_CLIENT;
1349         self.version_nagtime = time + 10 + random() * 10;
1350
1351         if(player_count<0)
1352         {
1353                 dprint("BUG player count is lower than zero, this cannot happen!\n");
1354                 player_count = 0;
1355         }
1356
1357         PlayerScore_Attach(self);
1358         ClientData_Attach();
1359
1360         bot_clientconnect();
1361
1362         playerdemo_init();
1363
1364         anticheat_init();
1365
1366         race_PreSpawnObserver();
1367
1368         //if(g_domination)
1369         //      dom_player_join_team(self);
1370
1371         JoinBestTeam(self, FALSE, FALSE); // if the team number is valid, keep it
1372
1373         if((cvar("sv_spectate") == 1 && !g_lms) || cvar("g_campaign")) {
1374                 self.classname = "observer";
1375         } else {
1376                 if(teams_matter)
1377                 {
1378                         if(cvar("g_balance_teams") || cvar("g_balance_teams_force"))
1379                         {
1380                                 self.classname = "player";
1381                                 campaign_bots_may_start = 1;
1382                         }
1383                         else
1384                         {
1385                                 self.classname = "observer"; // do it anyway
1386                         }
1387                 }
1388                 else
1389                 {
1390                         self.classname = "player";
1391                         campaign_bots_may_start = 1;
1392                 }
1393         }
1394
1395         self.playerid = (playerid_last = playerid_last + 1);
1396
1397         if(cvar("sv_eventlog"))
1398                 GameLogEcho(strcat(":join:", ftos(self.playerid), ":", ftos(num_for_edict(self)), ":", ((clienttype(self) == CLIENTTYPE_REAL) ? self.netaddress : "bot"), ":", self.netname));
1399
1400         LogTeamchange(self.playerid, self.team, 1);
1401
1402         self.just_joined = TRUE;  // stop spamming the eventlog with additional lines when the client connects
1403
1404         self.netname_previous = strzone(self.netname);
1405
1406         bprint("^4", self.netname, "^4 connected");
1407
1408         if(self.classname != "observer" && (g_domination || g_ctf))
1409                 bprint(" and joined the ", ColoredTeamName(self.team));
1410
1411         bprint("\n");
1412
1413         self.welcomemessage_time = 0;
1414
1415         stuffcmd(self, strcat(clientstuff, "\n"));
1416         stuffcmd(self, strcat("exec maps/", mapname, ".cfg\n"));
1417         stuffcmd(self, "cl_particles_reloadeffects\n");
1418
1419         FixClientCvars(self);
1420
1421         // spawnfunc_waypoint sprites
1422         WaypointSprite_InitClient(self);
1423
1424         // Wazat's grappling hook
1425         SetGrappleHookBindings();
1426
1427         // get autoswitch state from player when he toggles it
1428         stuffcmd(self, "alias autoswitch \"set cl_autoswitch $1 ; cmd autoswitch $1\"\n"); // default.cfg-ed in 2.4.1
1429
1430         // get version info from player
1431         stuffcmd(self, "cmd clientversion $gameversion\n");
1432
1433         // get other cvars from player
1434         GetCvars(0);
1435
1436         // set cvar for team scoreboard
1437         stuffcmd(self, strcat("set teamplay ", ftos(teamplay), "\n"));
1438
1439         // notify about available teams
1440         if(teams_matter)
1441         {
1442                 CheckAllowedTeams(self);
1443                 t = 0; if(c1 >= 0) t |= 1; if(c2 >= 0) t |= 2; if(c3 >= 0) t |= 4; if(c4 >= 0) t |= 8;
1444                 stuffcmd(self, strcat("set _teams_available ", ftos(t), "\n"));
1445         }
1446         else
1447                 stuffcmd(self, "set _teams_available 0\n");
1448
1449         stuffcmd(self, strcat("set gametype ", ftos(game), "\n"));
1450
1451         if(g_arena || g_ca)
1452         {
1453                 self.classname = "observer";
1454                 if(g_arena)
1455                         Spawnqueue_Insert(self);
1456         }
1457         /*else if(g_ctf)
1458         {
1459                 ctf_clientconnect();
1460         }*/
1461
1462         if(teams_matter || radar_showennemies)
1463                 attach_entcs();
1464
1465         bot_relinkplayerlist();
1466
1467         self.spectatortime = time;
1468         if(blockSpectators)
1469         {
1470                 sprint(self, strcat("^7You have to become a player within the next ", ftos(cvar("g_maxplayers_spectator_blocktime")), " seconds, otherwise you will be kicked, because spectators aren't allowed at this time!\n"));
1471         }
1472
1473         self.jointime = time;
1474         self.allowedTimeouts = cvar("sv_timeout_number");
1475
1476         if(clienttype(self) == CLIENTTYPE_REAL)
1477         {
1478                 if(cvar("g_bugrigs") || g_weaponarena == WEPBIT_TUBA)
1479                         stuffcmd(self, "cl_cmd settemp chase_active 1\n");
1480         }
1481
1482         if(g_lms)
1483         {
1484                 if(PlayerScore_Add(self, SP_LMS_LIVES, LMS_NewPlayerLives()) <= 0)
1485                 {
1486                         PlayerScore_Add(self, SP_LMS_RANK, 666);
1487                         self.frags = FRAGS_SPECTATOR;
1488                 }
1489         }
1490
1491         if(!sv_foginterval && world.fog != "")
1492                 stuffcmd(self, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1493
1494         SoundEntity_Attach(self);
1495
1496         if(cvar("g_hitplots") || strstrofs(strcat(" ", cvar_string("g_hitplots_individuals"), " "), strcat(" ", self.netaddress, " "), 0) >= 0)
1497         {
1498                 self.hitplotfh = fopen(strcat("hits-", matchid, "-", self.netaddress, "-", ftos(self.playerid), ".plot"), FILE_WRITE);
1499                 fputs(self.hitplotfh, strcat("#name ", self.netname, "\n"));
1500         }
1501         else
1502                 self.hitplotfh = -1;
1503
1504 #ifdef UID
1505         if(clienttype(self) == CLIENTTYPE_REAL)
1506         if not(self.uid)
1507                 self.uid_kicktime = time + 60;
1508 #endif
1509
1510         if(g_race || g_cts) {
1511                 string rr;
1512                 if(g_cts)
1513                         rr = CTS_RECORD;
1514                 else
1515                         rr = RACE_RECORD;
1516                 t = stof(db_get(ServerProgsDB, strcat(GetMapname(), rr, "time")));
1517
1518                 race_send_recordtime(MSG_ONE);
1519                 race_send_speedaward(MSG_ONE);
1520
1521                 speedaward_alltimebest = stof(db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/speed")));
1522                 speedaward_alltimebest_holder = db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/netname"));
1523                 race_send_speedaward_alltimebest(MSG_ONE);
1524
1525                 float i;
1526                 for (i = 1; i <= RANKINGS_CNT; ++i) {
1527                         race_SendRankings(i, 0, 0, MSG_ONE);
1528                 }
1529         }
1530         else if(cvar("sv_teamnagger") && !g_ca) // teamnagger is currently bad for ca
1531                 send_CSQC_teamnagger();
1532
1533         CheatInitClient();
1534 }
1535
1536 /*
1537 =============
1538 ClientDisconnect
1539
1540 Called when a client disconnects from the server
1541 =============
1542 */
1543 .entity chatbubbleentity;
1544 .entity teambubbleentity;
1545 void ReadyCount();
1546 void ClientDisconnect (void)
1547 {
1548         if not(self.flags & FL_CLIENT)
1549         {
1550                 print("Warning: ClientDisconnect without ClientConnect\n");
1551                 return;
1552         }
1553
1554         CheatShutdownClient();
1555
1556         if(self.hitplotfh >= 0)
1557         {
1558                 fclose(self.hitplotfh);
1559                 self.hitplotfh = -1;
1560         }
1561
1562         anticheat_report();
1563         anticheat_shutdown();
1564
1565         playerdemo_shutdown();
1566
1567         bot_clientdisconnect();
1568
1569         if(self.entcs)
1570                 detach_entcs();
1571
1572         if(cvar("sv_eventlog"))
1573                 GameLogEcho(strcat(":part:", ftos(self.playerid)));
1574         bprint ("^4",self.netname);
1575         bprint ("^4 disconnected\n");
1576
1577         SoundEntity_Detach(self);
1578
1579         DropAllRunes(self);
1580         kh_Key_DropAll(self, TRUE);
1581
1582         Portal_ClearAll(self);
1583
1584         if(self.flagcarried)
1585                 DropFlag(self.flagcarried, world, world);
1586         if(self.ballcarried)
1587                 DropBall(self.ballcarried, self.origin + self.ballcarried.origin, self.velocity);
1588
1589         // Here, everything has been done that requires this player to be a client.
1590
1591         self.flags &~= FL_CLIENT;
1592
1593         if (self.chatbubbleentity)
1594                 remove (self.chatbubbleentity);
1595
1596         if (self.teambubbleentity)
1597                 remove (self.teambubbleentity);
1598
1599         if (self.killindicator)
1600                 remove (self.killindicator);
1601
1602         WaypointSprite_PlayerGone();
1603
1604         bot_relinkplayerlist();
1605
1606         // remove laserdot
1607         if(self.weaponentity)
1608                 if(self.weaponentity.lasertarget)
1609                         remove(self.weaponentity.lasertarget);
1610
1611         if(g_arena)
1612         {
1613                 Spawnqueue_Unmark(self);
1614                 Spawnqueue_Remove(self);
1615         }
1616
1617         ClientData_Detach();
1618         PlayerScore_Detach(self);
1619
1620         if(self.netname_previous)
1621                 strunzone(self.netname_previous);
1622         if(self.clientstatus)
1623                 strunzone(self.clientstatus);
1624
1625         ClearPlayerSounds();
1626
1627         if(self.personal)
1628                 remove(self.personal);
1629
1630         self.playerid = 0;
1631         ReadyCount();
1632
1633         // free cvars
1634         GetCvars(-1);
1635 }
1636
1637 .float BUTTON_CHAT;
1638 void ChatBubbleThink()
1639 {
1640         self.nextthink = time;
1641         if (!self.owner.modelindex || self.owner.chatbubbleentity != self)
1642         {
1643                 if(self.owner) // but why can that ever be world?
1644                         self.owner.chatbubbleentity = world;
1645                 remove(self);
1646                 return;
1647         }
1648         if ((self.owner.BUTTON_CHAT && !self.owner.deadflag)
1649 #ifdef TETRIS
1650                 || self.owner.tetris_on
1651 #endif
1652         )
1653                 self.model = self.mdl;
1654         else
1655                 self.model = "";
1656 };
1657
1658 void UpdateChatBubble()
1659 {
1660         if (!self.modelindex)
1661                 return;
1662         // spawn a chatbubble entity if needed
1663         if (!self.chatbubbleentity)
1664         {
1665                 self.chatbubbleentity = spawn();
1666                 self.chatbubbleentity.owner = self;
1667                 self.chatbubbleentity.exteriormodeltoclient = self;
1668                 self.chatbubbleentity.think = ChatBubbleThink;
1669                 self.chatbubbleentity.nextthink = time;
1670                 setmodel(self.chatbubbleentity, "models/misc/chatbubble.spr"); // precision set below
1671                 //setorigin(self.chatbubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1672                 setorigin(self.chatbubbleentity, '0 0 15' + self.maxs_z * '0 0 1');
1673                 setattachment(self.chatbubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1674                 self.chatbubbleentity.mdl = self.chatbubbleentity.model;
1675                 self.chatbubbleentity.model = "";
1676                 self.chatbubbleentity.effects = EF_LOWPRECISION;
1677         }
1678 }
1679
1680
1681 void TeamBubbleThink()
1682 {
1683         self.nextthink = time;
1684         if (!self.owner.modelindex || self.owner.teambubbleentity != self)
1685         {
1686                 if(self.owner) // but why can that ever be world?
1687                         self.owner.teambubbleentity = world;
1688                 remove(self);
1689                 return;
1690         }
1691 //      setorigin(self, self.owner.origin + '0 0 15' + self.owner.maxs_z * '0 0 1');  // bandwidth hog. setattachment does this now
1692         if (self.owner.BUTTON_CHAT || self.owner.deadflag || self.owner.killindicator)
1693                 self.model = "";
1694         else
1695                 self.model = self.mdl;
1696
1697 };
1698
1699 float TeamBubble_customizeentityforclient()
1700 {
1701         return (self.owner != other && self.owner.team == other.team && other.killcount > -666);
1702 }
1703
1704 void UpdateTeamBubble()
1705 {
1706         if (!self.modelindex || !teams_matter)
1707                 return;
1708         // spawn a teambubble entity if needed
1709         if (!self.teambubbleentity && teams_matter)
1710         {
1711                 self.teambubbleentity = spawn();
1712                 self.teambubbleentity.owner = self;
1713                 self.teambubbleentity.exteriormodeltoclient = self;
1714                 self.teambubbleentity.think = TeamBubbleThink;
1715                 self.teambubbleentity.nextthink = time;
1716                 setmodel(self.teambubbleentity, "models/misc/teambubble.spr"); // precision set below
1717 //              setorigin(self.teambubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1718                 setorigin(self.teambubbleentity, '0 0 15' + self.maxs_z * '0 0 1');
1719                 setattachment(self.teambubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1720                 self.teambubbleentity.mdl = self.teambubbleentity.model;
1721                 self.teambubbleentity.model = self.teambubbleentity.mdl;
1722                 self.teambubbleentity.customizeentityforclient = TeamBubble_customizeentityforclient;
1723                 self.teambubbleentity.effects = EF_LOWPRECISION;
1724         }
1725 }
1726
1727 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1728 // added to the model skins
1729 /*void UpdateColorModHack()
1730 {
1731         local float c;
1732         c = self.clientcolors & 15;
1733         // LordHavoc: only bothering to support white, green, red, yellow, blue
1734              if (!teams_matter) self.colormod = '0 0 0';
1735         else if (c ==  0) self.colormod = '1.00 1.00 1.00';
1736         else if (c ==  3) self.colormod = '0.10 1.73 0.10';
1737         else if (c ==  4) self.colormod = '1.73 0.10 0.10';
1738         else if (c == 12) self.colormod = '1.22 1.22 0.10';
1739         else if (c == 13) self.colormod = '0.10 0.10 1.73';
1740         else self.colormod = '1 1 1';
1741 };*/
1742
1743 void respawn(void)
1744 {
1745         CopyBody(1);
1746         self.effects |= EF_NODRAW; // prevent another CopyBody
1747         PutClientInServer();
1748 }
1749
1750 void play_countdown(float finished, string samp)
1751 {
1752         if(clienttype(self) == CLIENTTYPE_REAL)
1753                 if(floor(finished - time - frametime) != floor(finished - time))
1754                         if(finished - time < 6)
1755                                 sound (self, CHAN_AUTO, samp, VOL_BASE, ATTN_NORM);
1756 }
1757
1758 /**
1759  * When sv_timeout is used this function returs strings like
1760  * "Timeout begins in 2 seconds!\n" or "Timeout ends in 23 seconds!\n".
1761  * Called by centerprint functions
1762  * @param addOneSecond boolean, set to 1 if the welcome-message centerprint asks for the text
1763  */
1764 string getTimeoutText(float addOneSecond) {
1765         if (!cvar("sv_timeout") || !timeoutStatus)
1766                 return "";
1767
1768         local string retStr;
1769         if (timeoutStatus == 1) {
1770                 if (addOneSecond == 1) {
1771                         retStr = strcat("Timeout begins in ", ftos(remainingLeadTime + 1), " seconds!\n");
1772                 }
1773                 else {
1774                         retStr = strcat("Timeout begins in ", ftos(remainingLeadTime), " seconds!\n");
1775                 }
1776                 return retStr;
1777         }
1778         else if (timeoutStatus == 2) {
1779                 if (addOneSecond) {
1780                         retStr = strcat("Timeout ends in ", ftos(remainingTimeoutTime + 1), " seconds!\n");
1781                         //don't show messages like "Timeout ends in 0 seconds"...
1782                         if ((remainingTimeoutTime + 1) > 0)
1783                                 return retStr;
1784                         else
1785                                 return "";
1786                 }
1787                 else {
1788                         retStr = strcat("Timeout ends in ", ftos(remainingTimeoutTime), " seconds!\n");
1789                         //don't show messages like "Timeout ends in 0 seconds"...
1790                         if (remainingTimeoutTime > 0)
1791                                 return retStr;
1792                         else
1793                                 return "";
1794                 }
1795         }
1796         else return "";
1797 }
1798
1799 void player_powerups (void)
1800 {
1801         if((self.items & IT_USING_JETPACK) && !self.deadflag)
1802         {
1803                 SoundEntity_StartSound(self, CHAN_PLAYER, "misc/jetpack_fly.wav", VOL_BASE, cvar("g_jetpack_attenuation"));
1804                 self.modelflags |= MF_ROCKET;
1805         }
1806         else
1807         {
1808                 SoundEntity_StopSound(self, CHAN_PLAYER);
1809                 self.modelflags &~= MF_ROCKET;
1810         }
1811
1812         self.effects &~= (EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
1813
1814         if(!self.modelindex || self.deadflag) // don't apply the flags if the player is gibbed
1815                 return;
1816
1817         Fire_ApplyDamage(self);
1818         Fire_ApplyEffect(self);
1819
1820         if (g_minstagib)
1821         {
1822                 self.effects |= EF_FULLBRIGHT;
1823
1824                 if (self.items & IT_STRENGTH)
1825                 {
1826                         play_countdown(self.strength_finished, "misc/poweroff.wav");
1827                         if (time > self.strength_finished)
1828                         {
1829                                 self.alpha = default_player_alpha;
1830                                 self.exteriorweaponentity.alpha = default_weapon_alpha;
1831                                 self.items &~= IT_STRENGTH;
1832                                 sprint(self, "^3Invisibility has worn off\n");
1833                         }
1834                 }
1835                 else
1836                 {
1837                         if (time < self.strength_finished)
1838                         {
1839                                 self.alpha = g_minstagib_invis_alpha;
1840                                 self.exteriorweaponentity.alpha = g_minstagib_invis_alpha;
1841                                 self.items |= IT_STRENGTH;
1842                                 sprint(self, "^3You are invisible\n");
1843                         }
1844                 }
1845
1846                 if (self.items & IT_INVINCIBLE)
1847                 {
1848                         play_countdown(self.invincible_finished, "misc/poweroff.wav");
1849                         if (time > self.invincible_finished && cvar("g_balance_powerup_timer"))
1850                         {
1851                                 self.items = self.items - (self.items & IT_INVINCIBLE);
1852                                 sprint(self, "^3Speed has worn off\n");
1853                         }
1854                 }
1855                 else
1856                 {
1857                         if (time < self.invincible_finished)
1858                         {
1859                                 self.items = self.items | IT_INVINCIBLE;
1860                                 sprint(self, "^3You are on speed\n");
1861                         }
1862                 }
1863                 return;
1864         }
1865
1866         if (self.items & IT_STRENGTH)
1867         {
1868                 play_countdown(self.strength_finished, "misc/poweroff.wav");
1869                 self.effects = self.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1870                 if (time > self.strength_finished && cvar("g_balance_powerup_timer"))
1871                 {
1872                         self.items = self.items - (self.items & IT_STRENGTH);
1873                         sprint(self, "^3Strength has worn off\n");
1874                 }
1875         }
1876         else
1877         {
1878                 if (time < self.strength_finished)
1879                 {
1880                         self.items = self.items | IT_STRENGTH;
1881                         sprint(self, "^3Strength infuses your weapons with devastating power\n");
1882                 }
1883         }
1884         if (self.items & IT_INVINCIBLE)
1885         {
1886                 play_countdown(self.invincible_finished, "misc/poweroff.wav");
1887                 self.effects = self.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1888                 if (time > self.invincible_finished && cvar("g_balance_powerup_timer"))
1889                 {
1890                         self.items = self.items - (self.items & IT_INVINCIBLE);
1891                         sprint(self, "^3Shield has worn off\n");
1892                 }
1893         }
1894         else
1895         {
1896                 if (time < self.invincible_finished)
1897                 {
1898                         self.items = self.items | IT_INVINCIBLE;
1899                         sprint(self, "^3Shield surrounds you\n");
1900                 }
1901         }
1902
1903         if(cvar("g_nodepthtestplayers"))
1904                 self.effects = self.effects | EF_NODEPTHTEST;
1905
1906         if(cvar("g_fullbrightplayers"))
1907                 self.effects = self.effects | EF_FULLBRIGHT;
1908
1909         // midair gamemode: damage only while in the air
1910         // if in midair mode, being on ground grants temporary invulnerability
1911         // (this is so that multishot weapon don't clear the ground flag on the
1912         // first damage in the frame, leaving the player vulnerable to the
1913         // remaining hits in the same frame)
1914         if (self.flags & FL_ONGROUND)
1915         if (g_midair)
1916                 self.spawnshieldtime = max(self.spawnshieldtime, time + cvar("g_midair_shieldtime"));
1917
1918         if (time >= game_starttime)
1919         if (time < self.spawnshieldtime)
1920                 self.effects = self.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1921 }
1922
1923 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
1924 {
1925         if(current > stable)
1926                 return current;
1927         else if(current > stable - 0.25) // when close enough, "snap"
1928                 return stable;
1929         else
1930                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
1931 }
1932
1933 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
1934 {
1935         if(current < stable)
1936                 return current;
1937         else if(current < stable + 0.25) // when close enough, "snap"
1938                 return stable;
1939         else
1940                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
1941 }
1942
1943 float CalcRotRegen(float current, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit)
1944 {
1945         if(current > rotstable)
1946         {
1947                 if(rotframetime > 0)
1948                 {
1949                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
1950                         current = max(rotstable, current - rotlinear * rotframetime);
1951                 }
1952         }
1953         else if(current < regenstable)
1954         {
1955                 if(regenframetime > 0)
1956                 {
1957                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
1958                         current = min(regenstable, current + regenlinear * regenframetime);
1959                 }
1960         }
1961
1962         if(current > limit)
1963                 current = limit;
1964
1965         return current;
1966 }
1967
1968 void player_regen (void)
1969 {
1970         float minh, mina, minf, maxh, maxa, maxf, limith, limita, limitf, max_mod, regen_mod, rot_mod, limit_mod;
1971         maxh = cvar("g_balance_health_rotstable");
1972         maxa = cvar("g_balance_armor_rotstable");
1973         maxf = cvar("g_balance_fuel_rotstable");
1974         minh = cvar("g_balance_health_regenstable");
1975         mina = cvar("g_balance_armor_regenstable");
1976         minf = cvar("g_balance_fuel_regenstable");
1977         limith = cvar("g_balance_health_limit");
1978         limita = cvar("g_balance_armor_limit");
1979         limitf = cvar("g_balance_fuel_limit");
1980
1981         max_mod = regen_mod = rot_mod = limit_mod = 1;
1982
1983         if (self.runes & RUNE_REGEN)
1984         {
1985                 if (self.runes & CURSE_VENOM) // do we have both rune/curse?
1986                 {
1987                         regen_mod = cvar("g_balance_rune_regen_combo_regenrate");
1988                         max_mod = cvar("g_balance_rune_regen_combo_hpmod");
1989                         limit_mod = cvar("g_balance_rune_regen_combo_limitmod");
1990                 }
1991                 else
1992                 {
1993                         regen_mod = cvar("g_balance_rune_regen_regenrate");
1994                         max_mod = cvar("g_balance_rune_regen_hpmod");
1995                         limit_mod = cvar("g_balance_rune_regen_limitmod");
1996                 }
1997         }
1998         else if (self.runes & CURSE_VENOM)
1999         {
2000                 max_mod = cvar("g_balance_curse_venom_hpmod");
2001                 if (self.runes & RUNE_REGEN) // do we have both rune/curse?
2002                         rot_mod = cvar("g_balance_rune_regen_combo_rotrate");
2003                 else
2004                         rot_mod = cvar("g_balance_curse_venom_rotrate");
2005                 limit_mod = cvar("g_balance_curse_venom_limitmod");
2006                 //if (!self.runes & RUNE_REGEN)
2007                 //      rot_mod = cvar("g_balance_curse_venom_rotrate");
2008         }
2009         maxh = maxh * max_mod;
2010         //maxa = maxa * max_mod;
2011         //maxf = maxf * max_mod;
2012         minh = minh * max_mod;
2013         //mina = mina * max_mod;
2014         //minf = minf * max_mod;
2015         limith = limith * limit_mod;
2016         limita = limita * limit_mod;
2017         //limitf = limitf * limit_mod;
2018
2019         if(g_lms && g_ca)
2020                 rot_mod = 0;
2021
2022         if (!g_minstagib && !g_ca && (!g_lms || cvar("g_lms_regenerate")))
2023         {
2024                 self.armorvalue = CalcRotRegen(self.armorvalue, mina, cvar("g_balance_armor_regen"), cvar("g_balance_armor_regenlinear"), regen_mod * frametime * (time > self.pauseregen_finished), maxa, cvar("g_balance_armor_rot"), cvar("g_balance_armor_rotlinear"), rot_mod * frametime * (time > self.pauserotarmor_finished), limita);
2025                 self.health = CalcRotRegen(self.health, minh, cvar("g_balance_health_regen"), cvar("g_balance_health_regenlinear"), regen_mod * frametime * (time > self.pauseregen_finished), maxh, cvar("g_balance_health_rot"), cvar("g_balance_health_rotlinear"), rot_mod * frametime * (time > self.pauserothealth_finished), limith);
2026
2027                 // if player rotted to death...  die!
2028                 if(self.health < 1)
2029                         self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
2030         }
2031
2032         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
2033                 self.ammo_fuel = CalcRotRegen(self.ammo_fuel, minf, cvar("g_balance_fuel_regen"), cvar("g_balance_fuel_regenlinear"), regen_mod * frametime * (time > self.pauseregen_finished) * (self.items & IT_FUEL_REGEN != 0), maxf, cvar("g_balance_fuel_rot"), cvar("g_balance_fuel_rotlinear"), rot_mod * frametime * (time > self.pauserotfuel_finished), limitf);
2034 }
2035
2036 float zoomstate_set;
2037 void SetZoomState(float z)
2038 {
2039         if(z != self.zoomstate)
2040         {
2041                 self.zoomstate = z;
2042                 ClientData_Touch(self);
2043         }
2044         zoomstate_set = 1;
2045 }
2046
2047 void GetPressedKeys(void) {
2048         if (self.movement_x > 0) // get if movement keys are pressed
2049         {       // forward key pressed
2050                 self.pressedkeys |= KEY_FORWARD;
2051                 self.pressedkeys &~= KEY_BACKWARD;
2052         }
2053         else if (self.movement_x < 0)
2054         {       // backward key pressed
2055                 self.pressedkeys |= KEY_BACKWARD;
2056                 self.pressedkeys &~= KEY_FORWARD;
2057         }
2058         else
2059         {       // no x input
2060                 self.pressedkeys &~= KEY_FORWARD;
2061                 self.pressedkeys &~= KEY_BACKWARD;
2062         }
2063
2064         if (self.movement_y > 0)
2065         {       // right key pressed
2066                 self.pressedkeys |= KEY_RIGHT;
2067                 self.pressedkeys &~= KEY_LEFT;
2068         }
2069         else if (self.movement_y < 0)
2070         {       // left key pressed
2071                 self.pressedkeys |= KEY_LEFT;
2072                 self.pressedkeys &~= KEY_RIGHT;
2073         }
2074         else
2075         {       // no y input
2076                 self.pressedkeys &~= KEY_RIGHT;
2077                 self.pressedkeys &~= KEY_LEFT;
2078         }
2079
2080         if (self.BUTTON_JUMP) // get if jump and crouch keys are pressed
2081                 self.pressedkeys |= KEY_JUMP;
2082         else
2083                 self.pressedkeys &~= KEY_JUMP;
2084         if (self.BUTTON_CROUCH)
2085                 self.pressedkeys |= KEY_CROUCH;
2086         else
2087                 self.pressedkeys &~= KEY_CROUCH;
2088 }
2089
2090 void update_stats (float number, float hit, float fired) {
2091 // self.stat_hit   = number + ((number==0) ? 1 : 64) * hit   * sv_accuracy_data_share;
2092 // self.stat_fired = number + ((number==0) ? 1 : 64) * fired * sv_accuracy_data_share;
2093
2094         if(number) {
2095                 self.stat_hit = number + 64 * hit * sv_accuracy_data_share;
2096                 self.stat_fired = number + 64 * fired * sv_accuracy_data_share;
2097         } else {
2098                 self.stat_hit = hit * sv_accuracy_data_share;
2099                 self.stat_fired = fired * sv_accuracy_data_share;
2100         }
2101 }
2102
2103 /*
2104 ======================
2105 spectate mode routines
2106 ======================
2107 */
2108
2109 .float weapon_count;
2110 void SpectateCopy(entity spectatee) {
2111         if(spectatee.weapon_count < WEP_LAST) {
2112                 update_stats (spectatee.weapon_count, spectatee.cvar_cl_accuracy_data_share * floor(spectatee.stats_hit[spectatee.weapon_count - 1]), spectatee.cvar_cl_accuracy_data_share * floor(spectatee.stats_fired[spectatee.weapon_count - 1]));
2113                 spectatee.weapon_count ++;
2114         } else
2115                 update_stats (0, spectatee.cvar_cl_accuracy_data_share * spectatee.stat_hit, spectatee.cvar_cl_accuracy_data_share * spectatee.stat_fired);
2116
2117         self.kh_state = spectatee.kh_state;
2118         self.armortype = spectatee.armortype;
2119         self.armorvalue = spectatee.armorvalue;
2120         self.ammo_cells = spectatee.ammo_cells;
2121         self.ammo_shells = spectatee.ammo_shells;
2122         self.ammo_nails = spectatee.ammo_nails;
2123         self.ammo_rockets = spectatee.ammo_rockets;
2124         self.ammo_fuel = spectatee.ammo_fuel;
2125         self.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
2126         self.health = spectatee.health;
2127         self.impulse = 0;
2128         self.items = spectatee.items;
2129         self.metertime = spectatee.metertime;
2130         self.strength_finished = spectatee.strength_finished;
2131         self.invincible_finished = spectatee.invincible_finished;
2132         self.pressedkeys = spectatee.pressedkeys;
2133         self.weapons = spectatee.weapons;
2134         self.switchweapon = spectatee.switchweapon;
2135         self.weapon = spectatee.weapon;
2136         self.punchangle = spectatee.punchangle;
2137         self.view_ofs = spectatee.view_ofs;
2138         self.v_angle = spectatee.v_angle;
2139         self.velocity = spectatee.velocity;
2140         self.dmg_take = spectatee.dmg_take;
2141         self.dmg_save = spectatee.dmg_save;
2142         self.dmg_inflictor = spectatee.dmg_inflictor;
2143         self.angles = spectatee.v_angle;
2144         self.fixangle = TRUE;
2145         setorigin(self, spectatee.origin);
2146         setsize(self, spectatee.mins, spectatee.maxs);
2147         SetZoomState(spectatee.zoomstate);
2148
2149         anticheat_spectatecopy(spectatee);
2150 }
2151
2152 float SpectateUpdate() {
2153         if(!self.enemy)
2154                 return 0;
2155
2156         if (self == self.enemy)
2157                 return 0;
2158
2159         if(self.enemy.classname != "player")
2160                 return 0;
2161
2162         SpectateCopy(self.enemy);
2163
2164         return 1;
2165 }
2166
2167 float SpectateNext() {
2168         other = find(self.enemy, classname, "player");
2169
2170         if (!other)
2171                 other = find(other, classname, "player");
2172
2173         if (other)
2174                 self.enemy = other;
2175
2176         if(self.enemy.classname == "player") {
2177                 msg_entity = self;
2178                 WriteByte(MSG_ONE, SVC_SETVIEW);
2179                 WriteEntity(MSG_ONE, self.enemy);
2180                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
2181                 self.movetype = MOVETYPE_NONE;
2182
2183                 self.enemy.weapon_count = 0;
2184
2185                 if(!SpectateUpdate())
2186                         PutObserverInServer();
2187
2188                 return 1;
2189         } else {
2190                 return 0;
2191         }
2192 }
2193
2194 /*
2195 =============
2196 ShowRespawnCountdown()
2197
2198 Update a respawn countdown display.
2199 =============
2200 */
2201 void ShowRespawnCountdown()
2202 {
2203         float number;
2204         if(self.deadflag == DEAD_NO) // just respawned?
2205                 return;
2206         else
2207         {
2208                 number = ceil(self.death_time - time);
2209                 if(number <= 0)
2210                         return;
2211                 if(number <= self.respawn_countdown)
2212                 {
2213                         self.respawn_countdown = number - 1;
2214                         if(ceil(self.death_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
2215                                 AnnounceTo(self, strcat(ftos(number), ""));
2216                 }
2217         }
2218 }
2219
2220 void LeaveSpectatorMode()
2221 {
2222         if(isJoinAllowed()) {
2223                 if(!teams_matter || cvar("g_campaign") || cvar("g_balance_teams") || (self.wasplayer && cvar("g_changeteam_banned"))) {
2224                         self.classname = "player";
2225
2226                         if(cvar("g_campaign") || cvar("g_balance_teams") || cvar("g_balance_teams_force"))
2227                                 JoinBestTeam(self, FALSE, TRUE);
2228
2229                         if(cvar("g_campaign"))
2230                                 campaign_bots_may_start = 1;
2231
2232                         self.stat_count = WEP_LAST;
2233
2234                         PutClientInServer();
2235
2236                         if(self.classname == "player")
2237                                 bprint ("^4", self.netname, "^4 is playing now\n");
2238
2239                         if(!cvar("g_campaign"))
2240                                 centerprint(self,""); // clear MOTD
2241
2242                         return;
2243                 } else {
2244                         if (g_ca && self.caplayer) {
2245                         }       // do nothing
2246                         else
2247                                 stuffcmd(self,"menu_showteamselect\n");
2248                         return;
2249                 }
2250         }
2251         else {
2252                 //player may not join because of g_maxplayers is set
2253                 centerprint_atprio(self, CENTERPRIO_MAPVOTE, PREVENT_JOIN_TEXT);
2254         }
2255 }
2256
2257 /**
2258  * Determines whether the player is allowed to join. This depends on cvar
2259  * g_maxplayers, if it isn't used this function always return TRUE, otherwise
2260  * it checks whether the number of currently playing players exceeds g_maxplayers.
2261  * @return bool TRUE if the player is allowed to join, false otherwise
2262  */
2263 float isJoinAllowed() {
2264         if (!cvar("g_maxplayers"))
2265                 return TRUE;
2266
2267         local entity e;
2268         local float currentlyPlaying;
2269         FOR_EACH_REALPLAYER(e) {
2270                 if(e.classname == "player")
2271                         currentlyPlaying += 1;
2272         }
2273         if(currentlyPlaying < cvar("g_maxplayers"))
2274                 return TRUE;
2275
2276         return FALSE;
2277 }
2278
2279 /**
2280  * Checks whether the client is an observer or spectator, if so, he will get kicked after
2281  * g_maxplayers_spectator_blocktime seconds
2282  */
2283 void checkSpectatorBlock() {
2284         if(self.classname == "spectator" || self.classname == "observer") {
2285                 if( time > (self.spectatortime + cvar("g_maxplayers_spectator_blocktime")) ) {
2286                         sprint(self, "^7You were kicked from the server because you are spectator and spectators aren't allowed at the moment.\n");
2287                         dropclient(self);
2288                 }
2289         }
2290 }
2291
2292 float vercmp_recursive(string v1, string v2)
2293 {
2294         float dot1, dot2;
2295         string s1, s2;
2296         float r;
2297
2298         dot1 = strstrofs(v1, ".", 0);
2299         dot2 = strstrofs(v2, ".", 0);
2300         if(dot1 == -1)
2301                 s1 = v1;
2302         else
2303                 s1 = substring(v1, 0, dot1);
2304         if(dot2 == -1)
2305                 s2 = v2;
2306         else
2307                 s2 = substring(v2, 0, dot2);
2308
2309         r = stof(s1) - stof(s2);
2310         if(r != 0)
2311                 return r;
2312
2313         r = strcasecmp(s1, s2);
2314         if(r != 0)
2315                 return r;
2316
2317         if(dot1 == -1)
2318                 if(dot2 == -1)
2319                         return 0;
2320                 else
2321                         return -1;
2322         else
2323                 if(dot2 == -1)
2324                         return 1;
2325                 else
2326                         return vercmp_recursive(substring(v1, dot1 + 1, 999), substring(v2, dot2 + 1, 999));
2327 }
2328
2329 float vercmp(string v1, string v2)
2330 {
2331         if(strcasecmp(v1, v2) == 0) // early out check
2332                 return 0;
2333         return vercmp_recursive(v1, v2);
2334 }
2335
2336 void ObserverThink()
2337 {
2338         if (self.flags & FL_JUMPRELEASED) {
2339                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2340                         self.welcomemessage_time = 0;
2341                         self.flags &~= FL_JUMPRELEASED;
2342                         self.flags |= FL_SPAWNING;
2343                 } else if(self.BUTTON_ATCK && !self.version_mismatch) {
2344                         self.welcomemessage_time = 0;
2345                         self.flags &~= FL_JUMPRELEASED;
2346                         if(SpectateNext() == 1) {
2347                                 self.classname = "spectator";
2348                         }
2349                 }
2350         } else {
2351                 if (!(self.BUTTON_ATCK || self.BUTTON_JUMP)) {
2352                         self.flags |= FL_JUMPRELEASED;
2353                         if(self.flags & FL_SPAWNING)
2354                         {
2355                                 self.flags &~= FL_SPAWNING;
2356                                 LeaveSpectatorMode();
2357                                 return;
2358                         }
2359                 }
2360         }
2361         PrintWelcomeMessage(self);
2362 }
2363
2364 void SpectatorThink()
2365 {
2366         if (self.flags & FL_JUMPRELEASED) {
2367                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2368                         self.welcomemessage_time = 0;
2369                         self.flags &~= FL_JUMPRELEASED;
2370                         self.flags |= FL_SPAWNING;
2371                 } else if(self.BUTTON_ATCK) {
2372                         self.welcomemessage_time = 0;
2373                         self.flags &~= FL_JUMPRELEASED;
2374                         if(SpectateNext() == 1) {
2375                                 self.classname = "spectator";
2376                         } else {
2377                                 self.classname = "observer";
2378                                 self.stat_count = WEP_LAST;
2379                                 PutClientInServer();
2380                         }
2381                 } else if (self.BUTTON_ATCK2) {
2382                         self.welcomemessage_time = 0;
2383                         self.flags &~= FL_JUMPRELEASED;
2384                         self.classname = "observer";
2385                         self.stat_count = WEP_LAST;
2386                         PutClientInServer();
2387                 } else {
2388                         if(!SpectateUpdate())
2389                                 PutObserverInServer();
2390                 }
2391         } else {
2392                 if (!(self.BUTTON_ATCK || self.BUTTON_ATCK2)) {
2393                         self.flags |= FL_JUMPRELEASED;
2394                         if(self.flags & FL_SPAWNING)
2395                         {
2396                                 self.flags &~= FL_SPAWNING;
2397                                 LeaveSpectatorMode();
2398                                 return;
2399                         }
2400                 }
2401         }
2402
2403         PrintWelcomeMessage(self);
2404         self.flags |= FL_CLIENT | FL_NOTARGET;
2405 }
2406
2407 .float touchexplode_time;
2408
2409 /*
2410 =============
2411 PlayerPreThink
2412
2413 Called every frame for each client before the physics are run
2414 =============
2415 */
2416 void() ctf_setstatus;
2417 void() nexball_setstatus;
2418 .float items_added;
2419 void PlayerPreThink (void)
2420 {
2421         self.stat_game_starttime = game_starttime;
2422         self.stat_allow_oldnexbeam = cvar("g_allow_oldnexbeam");
2423         self.stat_leadlimit = cvar("leadlimit");
2424
2425         if(frametime)
2426         {
2427                 // physics frames: update anticheat stuff
2428                 anticheat_prethink();
2429         }
2430
2431         if(blockSpectators && frametime)
2432                 // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2433                 checkSpectatorBlock();
2434
2435         zoomstate_set = 0;
2436
2437         if(self.netname_previous != self.netname)
2438         {
2439                 if(cvar("sv_eventlog"))
2440                         GameLogEcho(strcat(":name:", ftos(self.playerid), ":", self.netname));
2441                 if(self.netname_previous)
2442                         strunzone(self.netname_previous);
2443                 self.netname_previous = strzone(self.netname);
2444         }
2445
2446         // version nagging
2447         if(self.version_nagtime)
2448                 if(self.cvar_g_nexuizversion)
2449                         if(time > self.version_nagtime)
2450                         {
2451                                 if(strstr(self.cvar_g_nexuizversion, "svn", 0) < 0)
2452                                 {
2453                                         if(strstr(cvar_string("g_nexuizversion"), "svn", 0) >= 0)
2454                                         {
2455                                                 dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Nexuiz ", cvar_string("g_nexuizversion"), " (beta)^7, you have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1\n");
2456                                                 sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Nexuiz ", cvar_string("g_nexuizversion"), " (beta)^7, you have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1\n"));
2457                                         }
2458                                         else
2459                                         {
2460                                                 float r;
2461                                                 r = vercmp(self.cvar_g_nexuizversion, cvar_string("g_nexuizversion"));
2462                                                 if(r < 0)
2463                                                 {
2464                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - ^3Nexuiz ", cvar_string("g_nexuizversion"), "^7 is out, and you still have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1 - get the update from ^4http://www.nexuiz.com/^1!\n");
2465                                                         sprint(self, strcat("\{1}^1NOTE: ^3Nexuiz ", cvar_string("g_nexuizversion"), "^7 is out, and you still have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1 - get the update from ^4http://www.nexuiz.com/^1!\n"));
2466                                                 }
2467                                                 else if(r > 0)
2468                                                 {
2469                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Nexuiz ", cvar_string("g_nexuizversion"), "^7, you have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1\n");
2470                                                         sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Nexuiz ", cvar_string("g_nexuizversion"), "^7, you have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1\n"));
2471                                                 }
2472                                         }
2473                                 }
2474                                 self.version_nagtime = 0;
2475                         }
2476
2477         // GOD MODE info
2478         if(!(self.flags & FL_GODMODE)) if(self.max_armorvalue)
2479         {
2480                 sprint(self, strcat("godmode saved you ", ftos(self.max_armorvalue), " units of damage, cheater!\n"));
2481                 self.max_armorvalue = 0;
2482         }
2483
2484 #ifdef TETRIS
2485         if (TetrisPreFrame())
2486                 return;
2487 #endif
2488
2489         if(self.classname == "player") {
2490 //              if(self.netname == "Wazat")
2491 //                      bprint(self.classname, "\n");
2492
2493                 CheckRules_Player();
2494
2495                 PrintWelcomeMessage(self);
2496
2497                 if (intermission_running)
2498                 {
2499                         IntermissionThink ();   // otherwise a button could be missed between
2500                         return;                                 // the think tics
2501                 }
2502
2503                 if(self.teleport_time)
2504                 if(time > self.teleport_time)
2505                 {
2506                         self.teleport_time = 0;
2507                         self.effects = self.effects - (self.effects & EF_NODRAW);
2508                 }
2509
2510                 Nixnex_GiveCurrentWeapon();
2511
2512                 if(frametime > 0) // don't do this in cl_movement frames, just in server ticks
2513                         UpdateSelectedPlayer();
2514
2515                 //don't allow the player to turn around while game is paused!
2516                 if(timeoutStatus == 2) {
2517                         self.v_angle = self.lastV_angle;
2518                         self.angles = self.lastV_angle;
2519                         self.fixangle = TRUE;
2520                 }
2521
2522                 if(frametime)
2523                 {
2524                         if(cvar("gameversion") >= 20600) // only do this for 2.6 and above FIXME remove this check when making 2.6
2525                                 self.glowmod = colormapPaletteColor(self.clientcolors & 0x0F, TRUE) * 2;
2526                         player_powerups();
2527                 }
2528
2529                 if (self.deadflag != DEAD_NO)
2530                 {
2531                         float button_pressed, force_respawn;
2532                         if(self.personal && g_race_qualifying)
2533                         {
2534                                 if(time > self.death_time)
2535                                 {
2536                                         self.death_time = time + 1; // only retry once a second
2537                                         respawn();
2538                                         self.impulse = 141;
2539                                 }
2540                         }
2541                         else
2542                         {
2543                                 if(frametime)
2544                                         player_anim();
2545                                 button_pressed = (self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE);
2546                                 force_respawn = (g_lms || (g_ca) || cvar("g_forced_respawn"));
2547                                 if (self.deadflag == DEAD_DYING)
2548                                 {
2549                                         if(force_respawn)
2550                                                 self.deadflag = DEAD_RESPAWNING;
2551                                         else if(!button_pressed)
2552                                                 self.deadflag = DEAD_DEAD;
2553                                 }
2554                                 else if (self.deadflag == DEAD_DEAD)
2555                                 {
2556                                         if(button_pressed)
2557                                                 self.deadflag = DEAD_RESPAWNABLE;
2558                                 }
2559                                 else if (self.deadflag == DEAD_RESPAWNABLE)
2560                                 {
2561                                         if(!button_pressed)
2562                                                 self.deadflag = DEAD_RESPAWNING;
2563                                 }
2564                                 else if (self.deadflag == DEAD_RESPAWNING)
2565                                 {
2566                                         if(time > self.death_time)
2567                                         {
2568                                                 self.death_time = time + 1; // only retry once a second
2569                                                 respawn();
2570                                         }
2571                                 }
2572                                 ShowRespawnCountdown();
2573                         }
2574                         return;
2575                 }
2576
2577                 if(g_touchexplode)
2578                 if(time > self.touchexplode_time)
2579                 if(self.classname == "player")
2580                 if(self.deadflag == DEAD_NO)
2581                 if not(IS_INDEPENDENT_PLAYER(self))
2582                 FOR_EACH_PLAYER(other) if(self != other)
2583                 {
2584                         if(time > other.touchexplode_time)
2585                         if(other.classname == "player")
2586                         if(other.deadflag == DEAD_NO)
2587                         if not(IS_INDEPENDENT_PLAYER(other))
2588                         if(boxesoverlap(self.absmin, self.absmax, other.absmin, other.absmax))
2589                         {
2590                                 PlayerTouchExplode(self, other);
2591                                 self.touchexplode_time = other.touchexplode_time = time + 0.2;
2592                         }
2593                 }
2594
2595                 if(g_lms && !self.deadflag && cvar("g_lms_campcheck_interval"))
2596                 {
2597                         vector dist;
2598
2599                         // calculate player movement (in 2 dimensions only, so jumping on one spot doesn't count as movement)
2600                         dist = self.prevorigin - self.origin;
2601                         dist_z = 0;
2602                         self.lms_traveled_distance += fabs(vlen(dist));
2603
2604                         if((cvar("g_campaign") && !campaign_bots_may_start) || (time < game_starttime))
2605                         {
2606                                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval")*2;
2607                                 self.lms_traveled_distance = 0;
2608                         }
2609
2610                         if(time > self.lms_nextcheck)
2611                         {
2612                                 //sprint(self, "distance: ", ftos(self.lms_traveled_distance), "\n");
2613                                 if(self.lms_traveled_distance < cvar("g_lms_campcheck_distance"))
2614                                 {
2615                                         centerprint(self, cvar_string("g_lms_campcheck_message"));
2616                                         // FIXME KadaverJack: gibbing player here causes playermodel to bounce around, instead of eye.md3
2617                                         // I wasn't able to find out WHY that happens, so I put a workaround in place that shall prevent players from being gibbed :(
2618                                         Damage(self, self, self, bound(0, cvar("g_lms_campcheck_damage"), self.health + self.armorvalue * cvar("g_balance_armor_blockpercent") + 5), DEATH_CAMP, self.origin, '0 0 0');
2619                                 }
2620                                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval");
2621                                 self.lms_traveled_distance = 0;
2622                         }
2623                 }
2624
2625                 self.prevorigin = self.origin;
2626
2627                 if ((self.BUTTON_CROUCH && !self.hook.state) || self.health <= g_bloodloss)
2628                 {
2629                         if (!self.crouch)
2630                         {
2631                                 self.crouch = TRUE;
2632                                 self.view_ofs = PL_CROUCH_VIEW_OFS;
2633                                 setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX);
2634                                 setanim(self, self.anim_duck, FALSE, TRUE, TRUE);
2635                         }
2636                 }
2637                 else
2638                 {
2639                         if (self.crouch)
2640                         {
2641                                 tracebox(self.origin, PL_MIN, PL_MAX, self.origin, FALSE, self);
2642                                 if (!trace_startsolid)
2643                                 {
2644                                         self.crouch = FALSE;
2645                                         self.view_ofs = PL_VIEW_OFS;
2646                                         setsize (self, PL_MIN, PL_MAX);
2647                                 }
2648                         }
2649                 }
2650
2651                 if(self.health <= g_bloodloss && self.deadflag == DEAD_NO)
2652                 {
2653                         if(self.bloodloss_timer < time)
2654                         {
2655                                 self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
2656                                 self.bloodloss_timer = time + 0.5 + random() * 0.5;
2657                         }
2658                 }
2659
2660                 FixPlayermodel();
2661
2662                 GrapplingHookFrame();
2663
2664                 // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2665                 //if(frametime)
2666                 {
2667                         self.items &~= self.items_added;
2668
2669                         W_WeaponFrame();
2670
2671                         self.items_added = 0;
2672                         if(self.items & IT_JETPACK)
2673                                 if(self.items & IT_FUEL_REGEN || self.ammo_fuel >= 0.01)
2674                                         self.items_added |= IT_FUEL;
2675
2676                         self.items |= self.items_added;
2677                 }
2678
2679                 player_regen();
2680                 if(frametime)
2681                         player_anim();
2682
2683                 if (g_minstagib)
2684                         minstagib_ammocheck();
2685
2686                 ctf_setstatus();
2687                 nexball_setstatus();
2688
2689                 self.dmg_team = max(0, self.dmg_team - cvar("g_teamdamage_resetspeed") * frametime);
2690
2691                 //self.angles_y=self.v_angle_y + 90;   // temp
2692         } else if(gameover) {
2693                 if (intermission_running)
2694                         IntermissionThink ();   // otherwise a button could be missed between
2695                 return;
2696         } else if(self.classname == "observer") {
2697                 ObserverThink();
2698         } else if(self.classname == "spectator") {
2699                 SpectatorThink();
2700         }
2701
2702         if(!zoomstate_set)
2703                 SetZoomState(self.BUTTON_ZOOM || (self.BUTTON_ATCK2 && self.weapon == WEP_NEX));
2704
2705         float oldspectatee_status;
2706         oldspectatee_status = self.spectatee_status;
2707         if(self.classname == "spectator")
2708                 self.spectatee_status = num_for_edict(self.enemy);
2709         else if(self.classname == "observer")
2710                 self.spectatee_status = num_for_edict(self);
2711         else
2712                 self.spectatee_status = 0;
2713         if(self.spectatee_status != oldspectatee_status)
2714         {
2715                 ClientData_Touch(self);
2716                 if(g_race || g_cts)
2717                         race_InitSpectator();
2718         }
2719
2720         if(self.teamkill_soundtime)
2721         if(time > self.teamkill_soundtime)
2722         {
2723                 self.teamkill_soundtime = 0;
2724
2725                 entity oldpusher, oldself;
2726
2727                 oldself = self; self = self.teamkill_soundsource;
2728                 oldpusher = self.pusher; self.pusher = oldself;
2729
2730                 PlayerSound(playersound_teamshoot, CHAN_VOICE, VOICETYPE_LASTATTACKER_ONLY);
2731
2732                 self.pusher = oldpusher;
2733                 self = oldself;
2734         }
2735
2736         if(self.taunt_soundtime)
2737         if(time > self.taunt_soundtime)
2738         {
2739                 self.taunt_soundtime = 0;
2740                 PlayerSound(playersound_taunt, CHAN_VOICE, VOICETYPE_AUTOTAUNT);
2741         }
2742
2743         target_voicescript_next(self);
2744 }
2745
2746 float isInvisibleString(string s)
2747 {
2748         float i, n, c;
2749         s = strdecolorize(s);
2750         for((i = 0), (n = strlen(s)); i < n; ++i)
2751         {
2752                 c = str2chr(s, i);
2753                 switch(c)
2754                 {
2755                         case 0:
2756                         case 32:
2757                         case 160:
2758                                 break;
2759                         default:
2760                                 return FALSE;
2761                 }
2762         }
2763         return TRUE;
2764 }
2765
2766 /*
2767 =============
2768 PlayerPostThink
2769
2770 Called every frame for each client after the physics are run
2771 =============
2772 */
2773 .float idlekick_lasttimeleft;
2774 void PlayerPostThink (void)
2775 {
2776         // Savage: Check for nameless players
2777         if (isInvisibleString(self.netname)) {
2778                 self.netname = "Player";
2779                 stuffcmd(self, strcat("name ", self.netname, substring(ftos(random()), 2, -1), "\n"));
2780         }
2781
2782         // send the clients accuracy stats to the client
2783         if(self.stat_count > 0)
2784         if(frametime)
2785         {
2786                 self.stat_hit = self.stat_count + 64 * floor(self.(stats_hit[self.stat_count - 1]));
2787                 self.stat_fired = self.stat_count + 64 * floor(self.(stats_fired[self.stat_count - 1]));
2788                 self.stat_count -= 1;
2789         }
2790
2791 #ifdef UID
2792         if(self.uid_kicktime)
2793         if(time > self.uid_kicktime)
2794         {
2795                 bprint("^3", self.netname, "^3 was kicked for missing UID.\n");
2796                 dropclient(self);
2797                 return;
2798         }
2799 #endif
2800
2801         if(sv_maxidle && frametime)
2802         {
2803                 // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2804                 float timeleft;
2805                 timeleft = ceil(sv_maxidle - (time - self.parm_idlesince));
2806                 if(timeleft <= 0)
2807                 {
2808                         bprint("^3", self.netname, "^3 was kicked for idling.\n");
2809                         AnnounceTo(self, "terminated");
2810                         dropclient(self);
2811                         return;
2812                 }
2813                 else if(timeleft <= 10)
2814                 {
2815                         if(timeleft != self.idlekick_lasttimeleft)
2816                         {
2817                                 centerprint_atprio(self, CENTERPRIO_IDLEKICK, strcat("^3Stop idling!\n^3Disconnecting in ", ftos(timeleft), "..."));
2818                                 AnnounceTo(self, strcat(ftos(timeleft), ""));
2819                         }
2820                 }
2821                 else
2822                 {
2823                         centerprint_expire(self, CENTERPRIO_IDLEKICK);
2824                 }
2825                 self.idlekick_lasttimeleft = timeleft;
2826         }
2827
2828 #ifdef TETRIS
2829         if(self.impulse == 100)
2830                 ImpulseCommands();
2831         if (TetrisPostFrame())
2832                 return;
2833 #endif
2834
2835         CheatFrame();
2836
2837         if(self.classname == "player") {
2838                 CheckRules_Player();
2839                 UpdateChatBubble();
2840                 UpdateTeamBubble();
2841                 if (self.impulse)
2842                         ImpulseCommands();
2843                 if (intermission_running)
2844                         return;         // intermission or finale
2845
2846                 GetPressedKeys();
2847         } else if (self.classname == "observer") {
2848                 //do nothing
2849         } else if (self.classname == "spectator") {
2850                 //do nothing
2851         }
2852
2853         /*
2854         float i;
2855         for(i = 0; i < 1000; ++i)
2856         {
2857                 vector end;
2858                 end = self.origin + '0 0 1024' + 512 * randomvec();
2859                 tracebox(self.origin, self.mins, self.maxs, end, MOVE_NORMAL, self);
2860                 if(trace_fraction < 1)
2861                 if(!(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
2862                 {
2863                         print("I HIT SOLID: ", vtos(self.origin), " -> ", vtos(end), "\n");
2864                         break;
2865                 }
2866         }
2867         */
2868
2869         Arena_Warmup();
2870
2871         //pointparticles(particleeffectnum("machinegun_impact"), self.origin + self.view_ofs + '0 0 7', '0 0 0', 1);
2872
2873         if(self.waypointsprite_attachedforcarrier)
2874                 WaypointSprite_UpdateHealth(self.waypointsprite_attachedforcarrier, '1 0 0' * healtharmor_maxdamage(self.health, self.armorvalue, cvar("g_balance_armor_blockpercent")));
2875
2876         playerdemo_write();
2877
2878         /*
2879         if(g_race)
2880                 dprint(sprintf("%f %.6f\n", time, race_GetFractionalLapCount(self)));
2881         */
2882 }