data/qcsrc/server/cl_client.qc

   1 // let's abuse an existing field
   2 #define SPAWNPOINT_SCORE frags
   3
   4 .float wantswelcomemessage;
   5 .string netname_previous;
   6
   7 void spawnfunc_info_player_survivor (void)
   8 {
   9         spawnfunc_info_player_deathmatch();
  10 }
  11
  12 void spawnfunc_info_player_start (void)
  13 {
  14         spawnfunc_info_player_deathmatch();
  15 }
  16
  17 void spawnfunc_info_player_deathmatch (void)
  18 {
  19         self.classname = "info_player_deathmatch";
  20         relocate_spawnpoint();
  21 }
  22
  23 void spawnpoint_use()
  24 {
  25         if(teams_matter)
  26         if(have_team_spawns)
  27         {
  28                 self.team = activator.team;
  29                 some_spawn_has_been_used = 1;
  30         }
  31 };
  32
  33 // Returns:
  34 //   -1 if a spawn can't be used
  35 //   otherwise, a weight of the spawnpoint
  36 float Spawn_Score(entity spot, entity playerlist, float teamcheck)
  37 {
  38         float shortest, thisdist;
  39         entity player;
  40
  41         // filter out spots for the wrong team
  42         if(teamcheck)
  43         if(spot.team != teamcheck)
  44                 return -1;
  45
  46         if(race_spawns)
  47                 if(spot.target == "")
  48                         return -1;
  49
  50         // filter out spots for assault
  51         if(spot.target != "") {
  52                 local entity ent;
  53                 float good;
  54                 ent = find(world, targetname, spot.target);
  55                 while(ent) {
  56                         if(ent.classname == "target_objective")
  57                         {
  58                                 if(ent.health < 0 || ent.health >= ASSAULT_VALUE_INACTIVE)
  59                                         return -1;
  60                                 good = 1;
  61                         }
  62                         else if(ent.classname == "trigger_race_checkpoint")
  63                         {
  64                                 if(self.classname == "player") // spectators may spawn everywhere
  65                                 {
  66                                         if(ent.race_checkpoint != race_PreviousCheckpoint(self.race_checkpoint))
  67                                                 return -1;
  68                                         float pl;
  69                                         pl = self.race_place;
  70                                         if(pl > race_highest_place_spawn)
  71                                                 pl = 0;
  72                                         if(spot.race_place != pl)
  73                                                 return -1;
  74                                 }
  75                                 good = 1;
  76                         }
  77                         else
  78                         {
  79                         }
  80                         ent = find(ent, targetname, spot.target);
  81                 }
  82
  83                 if(!good)
  84                         return -1;
  85         }
  86
  87         player = playerlist;
  88         shortest = vlen(world.maxs - world.mins);
  89         for(player = playerlist; player; player = player.chain)
  90                 if (player != self)
  91                 {
  92                         thisdist = vlen(player.origin - spot.origin);
  93                         if (thisdist < shortest)
  94                                 shortest = thisdist;
  95                 }
  96         return shortest;
  97 }
  98
  99 float spawn_allbad;
 100 float spawn_allgood;
 101 entity Spawn_FilterOutBadSpots(entity firstspot, entity playerlist, float mindist, float teamcheck)
 102 {
 103         local entity spot, spotlist, spotlistend;
 104         spawn_allgood = TRUE;
 105         spawn_allbad = TRUE;
 106
 107         spotlist = world;
 108         spotlistend = world;
 109
 110         for(spot = firstspot; spot; spot = spot.chain)
 111         {
 112                 spot.SPAWNPOINT_SCORE = Spawn_Score(spot, playerlist, teamcheck);
 113
 114                 if(cvar("spawn_debugview"))
 115                 {
 116                         setmodel(spot, "models/runematch/rune.mdl");
 117                         if(spot.SPAWNPOINT_SCORE < mindist)
 118                         {
 119                                 spot.colormod = '1 0 0';
 120                                 spot.scale = 1;
 121                         }
 122                         else
 123                         {
 124                                 spot.colormod = '0 1 0';
 125                                 spot.scale = spot.SPAWNPOINT_SCORE / mindist;
 126                         }
 127                 }
 128
 129                 if(spot.SPAWNPOINT_SCORE >= 0) // spawning allowed here
 130                 {
 131                         if(spot.SPAWNPOINT_SCORE < mindist)
 132                         {
 133                                 // too short distance
 134                                 spawn_allgood = FALSE;
 135                         }
 136                         else
 137                         {
 138                                 // perfect
 139                                 spawn_allbad = FALSE;
 140
 141                                 if(spotlistend)
 142                                         spotlistend.chain = spot;
 143                                 spotlistend = spot;
 144                                 if(!spotlist)
 145                                         spotlist = spot;
 146
 147                                 /*
 148                                 if(teamcheck)
 149                                 if(spot.team != teamcheck)
 150                                         error("invalid spawn added");
 151
 152                                 print("added ", etos(spot), "\n");
 153                                 */
 154                         }
 155                 }
 156         }
 157         if(spotlistend)
 158                 spotlistend.chain = world;
 159
 160         /*
 161                 entity e;
 162                 if(teamcheck)
 163                         for(e = spotlist; e; e = e.chain)
 164                         {
 165                                 print("seen ", etos(e), "\n");
 166                                 if(e.team != teamcheck)
 167                                         error("invalid spawn found");
 168                         }
 169         */
 170
 171         return spotlist;
 172 }
 173
 174 entity Spawn_WeightedPoint(entity firstspot, float lower, float upper, float exponent)
 175 {
 176         // weight of a point: bound(lower, mindisttoplayer, upper)^exponent
 177         // multiplied by spot.cnt (useful if you distribute many spawnpoints in a small area)
 178         local entity spot;
 179
 180         RandomSelection_Init();
 181         for(spot = firstspot; spot; spot = spot.chain)
 182                 RandomSelection_Add(spot, 0, pow(bound(lower, spot.SPAWNPOINT_SCORE, upper), exponent) * spot.cnt, spot.SPAWNPOINT_SCORE >= lower);
 183
 184         return RandomSelection_chosen_ent;
 185 }
 186
 187 /*
 188 =============
 189 SelectSpawnPoint
 190
 191 Finds a point to respawn
 192 =============
 193 */
 194 entity SelectSpawnPoint (float anypoint)
 195 {
 196         local float teamcheck;
 197         local entity firstspot_new;
 198         local entity spot, firstspot, playerlist;
 199
 200         spot = find (world, classname, "testplayerstart");
 201         if (spot)
 202                 return spot;
 203
 204         teamcheck = 0;
 205
 206         if(!anypoint && have_team_spawns)
 207                 teamcheck = self.team;
 208
 209         // get the list of players
 210         playerlist = findchain(classname, "player");
 211         // get the entire list of spots
 212         firstspot = findchain(classname, "info_player_deathmatch");
 213         // filter out the bad ones
 214         // (note this returns the original list if none survived)
 215         firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, 100, teamcheck);
 216         if(!firstspot_new)
 217                 firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, -1, teamcheck);
 218         firstspot = firstspot_new;
 219
 220         // there is 50/50 chance of choosing a random spot or the furthest spot
 221         // (this means that roughly every other spawn will be furthest, so you
 222         // usually won't get fragged at spawn twice in a row)
 223         if (arena_roundbased)
 224         {
 225                 firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, 800, teamcheck);
 226                 if(firstspot_new)
 227                         firstspot = firstspot_new;
 228                 spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 229         }
 230         else if (random() > cvar("g_spawn_furthest"))
 231                 spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 232         else
 233                 spot = Spawn_WeightedPoint(firstspot, 1, 5000, 5); // chooses a far far away spawnpoint
 234
 235         if(cvar("spawn_debugview"))
 236         {
 237                 print("spot mindistance: ", ftos(spot.SPAWNPOINT_SCORE), "\n");
 238
 239                 entity e;
 240                 if(teamcheck)
 241                         for(e = firstspot; e; e = e.chain)
 242                                 if(e.team != teamcheck)
 243                                         error("invalid spawn found");
 244         }
 245
 246         if (!spot)
 247         {
 248                 if(cvar("spawn_debug"))
 249                         GotoNextMap();
 250                 else
 251                 {
 252                         if(some_spawn_has_been_used)
 253                                 return world; // team can't spawn any more, because of actions of other team
 254                         else
 255                                 error("Cannot find a spawn point - please fix the map!");
 256                 }
 257         }
 258
 259         return spot;
 260 }
 261
 262 /*
 263 =============
 264 CheckPlayerModel
 265
 266 Checks if the argument string can be a valid playermodel.
 267 Returns a valid one in doubt.
 268 =============
 269 */
 270 string FallbackPlayerModel = "models/player/marine.zym";
 271 string CheckPlayerModel(string plyermodel) {
 272         if(strlen(plyermodel) < 4)
 273                 return FallbackPlayerModel;
 274         if( substring(plyermodel,0,14) != "models/player/")
 275                 return FallbackPlayerModel;
 276         else if(cvar("sv_servermodelsonly"))
 277         {
 278                 if(substring(plyermodel,strlen(plyermodel)-4,4) != ".zym")
 279                 if(substring(plyermodel,strlen(plyermodel)-4,4) != ".dpm")
 280                 if(substring(plyermodel,strlen(plyermodel)-4,4) != ".md3")
 281                 if(substring(plyermodel,strlen(plyermodel)-4,4) != ".psk")
 282                         return FallbackPlayerModel;
 283                 if(!fexists(plyermodel))
 284                         return FallbackPlayerModel;
 285         }
 286         return plyermodel;
 287 }
 288
 289 /*
 290 =============
 291 Client_customizeentityforclient
 292
 293 LOD reduction
 294 =============
 295 */
 296 float Client_customizeentityforclient()
 297 {
 298 #ifdef ALLOW_VARIABLE_LOD
 299         // self: me
 300         // other: the player viewing me
 301         float distance;
 302         float f;
 303
 304         if(self.flags & FL_NOTARGET) // we don't need LOD for spectators
 305                 return TRUE;
 306
 307         if(other.cvar_cl_playerdetailreduction <= 0)
 308         {
 309                 if(other.cvar_cl_playerdetailreduction <= -2)
 310                         self.modelindex = self.modelindex_lod2;
 311                 else if(other.cvar_cl_playerdetailreduction <= -1)
 312                         self.modelindex = self.modelindex_lod1;
 313                 else
 314                         self.modelindex = self.modelindex_lod0;
 315         }
 316         else
 317         {
 318                 distance = vlen(self.origin - other.origin);
 319                 f = (distance + 100.0) * other.cvar_cl_playerdetailreduction;
 320                 if(f > 10000)
 321                         self.modelindex = self.modelindex_lod2;
 322                 else if(f > 5000)
 323                         self.modelindex = self.modelindex_lod1;
 324                 else
 325                         self.modelindex = self.modelindex_lod0;
 326         }
 327 #endif
 328
 329         return TRUE;
 330 }
 331
 332 void UpdatePlayerSounds();
 333 void setmodel_lod(entity e, string modelname)
 334 {
 335 #ifdef ALLOW_VARIABLE_LOD
 336         string s;
 337
 338         // FIXME: this only supports 3-letter extensions
 339         s = strcat(substring(modelname, 0, strlen(modelname) - 4), "_1", substring(modelname, 0, strlen(modelname) - 4));
 340         if(fexists(s))
 341         {
 342                 precache_model(s);
 343                 setmodel(e, s); // players have high precision
 344                 self.modelindex_lod1 = self.modelindex;
 345         }
 346         else
 347                 self.modelindex_lod1 = -1;
 348
 349         s = strcat(substring(modelname, 0, strlen(modelname) - 4), "_2", substring(modelname, 0, strlen(modelname) - 4));
 350         if(fexists(s))
 351         {
 352                 precache_model(s);
 353                 setmodel(e, s); // players have high precision
 354                 self.modelindex_lod2 = self.modelindex;
 355         }
 356         else
 357                 self.modelindex_lod2 = -1;
 358
 359         precache_model(modelname);
 360         setmodel(e, modelname); // players have high precision
 361         self.modelindex_lod0 = self.modelindex;
 362
 363         if(self.modelindex_lod1 < 0)
 364                 self.modelindex_lod1 = self.modelindex;
 365
 366         if(self.modelindex_lod2 < 0)
 367                 self.modelindex_lod2 = self.modelindex;
 368 #else
 369         precache_model(modelname);
 370         setmodel(e, modelname); // players have high precision
 371 #endif
 372         player_setupanimsformodel();
 373         UpdatePlayerSounds();
 374 }
 375
 376 /*
 377 =============
 378 PutObserverInServer
 379
 380 putting a client as observer in the server
 381 =============
 382 */
 383 void PutObserverInServer (void)
 384 {
 385         entity  spot;
 386
 387         race_PreSpawnObserver();
 388
 389         spot = SelectSpawnPoint (TRUE);
 390         if(!spot)
 391                 error("No spawnpoints for observers?!?\n");
 392         RemoveGrapplingHook(self); // Wazat's Grappling Hook
 393
 394         if(clienttype(self) == CLIENTTYPE_REAL)
 395         {
 396                 msg_entity = self;
 397                 WriteByte(MSG_ONE, SVC_SETVIEW);
 398                 WriteEntity(MSG_ONE, self);
 399         }
 400
 401         DropAllRunes(self);
 402         kh_Key_DropAll(self, TRUE);
 403
 404         Portal_ClearAll(self);
 405
 406         if(self.flagcarried)
 407                 DropFlag(self.flagcarried);
 408
 409         WaypointSprite_PlayerDead();
 410
 411         if(self.killcount != -666)
 412         {
 413                 if(g_lms)
 414                 {
 415                         if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
 416                                 bprint ("^4", self.netname, "^4 has no more lives left\n");
 417                         else
 418                                 bprint ("^4", self.netname, "^4 is spectating now\n"); // TODO turn this into a proper forfeit?
 419                 }
 420                 else
 421                         bprint ("^4", self.netname, "^4 is spectating now\n");
 422         }
 423
 424         PlayerScore_Clear(self); // clear scores when needed
 425
 426         self.spectatortime = time;
 427
 428         self.classname = "observer";
 429         self.health = -666;
 430         self.takedamage = DAMAGE_NO;
 431         self.solid = SOLID_NOT;
 432         self.movetype = MOVETYPE_NOCLIP;
 433         self.flags = FL_CLIENT | FL_NOTARGET;
 434         self.armorvalue = 666;
 435         self.effects = 0;
 436         self.armorvalue = cvar("g_balance_armor_start");
 437         self.pauserotarmor_finished = 0;
 438         self.pauserothealth_finished = 0;
 439         self.pauseregen_finished = 0;
 440         self.damageforcescale = 0;
 441         self.death_time = 0;
 442         self.dead_frame = 0;
 443         self.alpha = 0;
 444         self.scale = 0;
 445         self.fade_time = 0;
 446         self.pain_frame = 0;
 447         self.pain_finished = 0;
 448         self.strength_finished = 0;
 449         self.invincible_finished = 0;
 450         self.pushltime = 0;
 451         self.think = SUB_Null;
 452         self.nextthink = 0;
 453         self.hook_time = 0;
 454         self.runes = 0;
 455         self.deadflag = DEAD_NO;
 456         self.angles = spot.angles;
 457         self.angles_z = 0;
 458         self.fixangle = TRUE;
 459         self.crouch = FALSE;
 460
 461         self.view_ofs = PL_VIEW_OFS;
 462         setorigin (self, spot.origin);
 463         setsize (self, '0 0 0', '0 0 0');
 464         self.oldorigin = self.origin;
 465         self.items = 0;
 466         self.weapons = 0;
 467         self.model = "";
 468         self.modelindex = 0;
 469         self.weapon = 0;
 470         self.weaponmodel = "";
 471         self.weaponentity = world;
 472         self.killcount = -666;
 473         self.velocity = '0 0 0';
 474         self.avelocity = '0 0 0';
 475         self.punchangle = '0 0 0';
 476         self.punchvector = '0 0 0';
 477         self.oldvelocity = self.velocity;
 478         self.customizeentityforclient = Client_customizeentityforclient;
 479         self.wantswelcomemessage = 1;
 480
 481         if(g_arena)
 482         {
 483                 if(self.version_mismatch)
 484                 {
 485                         Spawnqueue_Unmark(self);
 486                         Spawnqueue_Remove(self);
 487                 }
 488                 else
 489                 {
 490                         Spawnqueue_Insert(self);
 491                 }
 492         }
 493         else if(g_lms)
 494         {
 495                 // Only if the player cannot play at all
 496                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) == 666)
 497                         self.frags = -666;
 498                 else
 499                         self.frags = -667;
 500         }
 501         else
 502                 self.frags = -666;
 503 }
 504
 505 float RestrictSkin(float s)
 506 {
 507         if(!teams_matter)
 508                 return s;
 509         if(s == 6)
 510                 return 6;
 511         return mod(s, 3);
 512 }
 513
 514 void FixPlayermodel()
 515 {
 516         local string defaultmodel;
 517         local float defaultskin;
 518         local vector m1, m2;
 519
 520         defaultmodel = "";
 521
 522         if(cvar("sv_defaultcharacter") == 1) {
 523                 defaultskin = 0;
 524
 525                 if(teams_matter)
 526                 {
 527                         defaultmodel = cvar_string(strcat("sv_defaultplayermodel_", Team_ColorNameLowerCase(self.team)));
 528                         defaultskin = cvar(strcat("sv_defaultplayerskin_", Team_ColorNameLowerCase(self.team)));
 529                 }
 530
 531                 if(defaultmodel == "")
 532                 {
 533                         defaultmodel = cvar_string("sv_defaultplayermodel");
 534                         defaultskin = cvar("sv_defaultplayerskin");
 535                 }
 536         }
 537
 538         if(defaultmodel != "")
 539         {
 540                 if (defaultmodel != self.model)
 541                 {
 542                         m1 = self.mins;
 543                         m2 = self.maxs;
 544                         setmodel_lod (self, defaultmodel);
 545                         setsize (self, m1, m2);
 546                 }
 547
 548                 self.skin = defaultskin;
 549         } else {
 550                 if (self.playermodel != self.model)
 551                 {
 552                         self.playermodel = CheckPlayerModel(self.playermodel);
 553                         m1 = self.mins;
 554                         m2 = self.maxs;
 555                         setmodel_lod (self, self.playermodel);
 556                         setsize (self, m1, m2);
 557                 }
 558
 559                 self.skin = RestrictSkin(stof(self.playerskin));
 560         }
 561
 562         if(!teams_matter)
 563                 if(strlen(cvar_string("sv_defaultplayercolors")))
 564                         if(self.clientcolors != cvar("sv_defaultplayercolors"))
 565                                 setcolor(self, cvar("sv_defaultplayercolors"));
 566 }
 567
 568 /*
 569 =============
 570 PutClientInServer
 571
 572 Called when a client spawns in the server
 573 =============
 574 */
 575 //void() ctf_playerchanged;
 576 void PutClientInServer (void)
 577 {
 578         if(clienttype(self) == CLIENTTYPE_BOT)
 579         {
 580                 self.classname = "player";
 581         }
 582         else if(clienttype(self) == CLIENTTYPE_REAL)
 583         {
 584                 msg_entity = self;
 585                 WriteByte(MSG_ONE, SVC_SETVIEW);
 586                 WriteEntity(MSG_ONE, self);
 587         }
 588
 589         // player is dead and becomes observer
 590         // FIXME fix LMS scoring for new system
 591         if(g_lms)
 592         {
 593                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
 594                         self.classname = "observer";
 595         }
 596
 597         if(g_arena)
 598         if(!self.spawned)
 599                 self.classname = "observer";
 600
 601         if(self.classname == "player") {
 602                 entity  spot;
 603
 604                 race_PreSpawn();
 605
 606                 spot = SelectSpawnPoint (FALSE);
 607                 if(!spot)
 608                 {
 609                         centerprint(self, "Sorry, no spawnpoints available!\nHope your team can fix it...");
 610                         return; // spawn failed
 611                 }
 612
 613                 RemoveGrapplingHook(self); // Wazat's Grappling Hook
 614
 615                 self.classname = "player";
 616                 self.iscreature = TRUE;
 617                 self.movetype = MOVETYPE_WALK;
 618                 self.solid = SOLID_SLIDEBOX;
 619                 if(independent_players)
 620                         MAKE_INDEPENDENT_PLAYER(self);
 621                 self.flags = FL_CLIENT;
 622                 self.takedamage = DAMAGE_AIM;
 623                 if(g_minstagib)
 624                         self.effects = EF_FULLBRIGHT;
 625                 else
 626                         self.effects = 0;
 627                 self.air_finished = time + 12;
 628                 self.dmg = 2;
 629
 630                 self.ammo_shells = start_ammo_shells;
 631                 self.ammo_nails = start_ammo_nails;
 632                 self.ammo_rockets = start_ammo_rockets;
 633                 self.ammo_cells = start_ammo_cells;
 634                 self.health = start_health;
 635                 self.armorvalue = start_armorvalue;
 636                 self.items = 0;
 637                 self.weapons = start_weapons;
 638                 self.switchweapon = start_switchweapon;
 639                 self.cnt = start_switchweapon;
 640                 self.weapon = 0;
 641                 self.jump_interval = time;
 642
 643                 self.spawnshieldtime = time + cvar("g_spawnshieldtime");
 644                 self.pauserotarmor_finished = time + cvar("g_balance_pause_armor_rot_spawn");
 645                 self.pauserothealth_finished = time + cvar("g_balance_pause_health_rot_spawn");
 646                 self.pauseregen_finished = time + cvar("g_balance_pause_health_regen_spawn");
 647                 //extend the pause of rotting if client was reset at the beginning of the countdown
 648                 if(!cvar("sv_ready_restart_after_countdown") && time < restart_countdown) {
 649                         self.spawnshieldtime += RESTART_COUNTDOWN;
 650                         self.pauserotarmor_finished += RESTART_COUNTDOWN;
 651                         self.pauserothealth_finished += RESTART_COUNTDOWN;
 652                         self.pauseregen_finished += RESTART_COUNTDOWN;
 653                 }
 654                 self.damageforcescale = 2;
 655                 self.death_time = 0;
 656                 self.dead_frame = 0;
 657                 self.alpha = 0;
 658                 self.scale = 0;
 659                 self.fade_time = 0;
 660                 self.pain_frame = 0;
 661                 self.pain_finished = 0;
 662                 self.strength_finished = 0;
 663                 self.invincible_finished = 0;
 664                 self.pushltime = 0;
 665                 //self.speed_finished = 0;
 666                 //self.slowmo_finished = 0;
 667                 // players have no think function
 668                 self.think = SUB_Null;
 669                 self.nextthink = 0;
 670                 self.hook_time = 0;
 671
 672                 self.runes = 0;
 673
 674                 self.deadflag = DEAD_NO;
 675
 676                 self.angles = spot.angles;
 677
 678                 self.angles_z = 0; // never spawn tilted even if the spot says to
 679                 self.fixangle = TRUE; // turn this way immediately
 680                 self.velocity = '0 0 0';
 681                 self.avelocity = '0 0 0';
 682                 self.punchangle = '0 0 0';
 683                 self.punchvector = '0 0 0';
 684                 self.oldvelocity = self.velocity;
 685
 686                 msg_entity = self;
 687                 WRITESPECTATABLE_MSG_ONE({
 688                         WriteByte(MSG_ONE, SVC_TEMPENTITY);
 689                         WriteByte(MSG_ONE, TE_CSQC_SPAWN);
 690                 });
 691
 692                 self.customizeentityforclient = Client_customizeentityforclient;
 693
 694                 self.model = "";
 695                 FixPlayermodel();
 696
 697                 self.crouch = FALSE;
 698                 self.view_ofs = PL_VIEW_OFS;
 699                 setsize (self, PL_MIN, PL_MAX);
 700                 self.spawnorigin = spot.origin;
 701                 setorigin (self, spot.origin + '0 0 1' * (1 - self.mins_z - 24));
 702                 // don't reset back to last position, even if new position is stuck in solid
 703                 self.oldorigin = self.origin;
 704
 705                 if(g_arena)
 706                 {
 707                         Spawnqueue_Remove(self);
 708                         Spawnqueue_Mark(self);
 709                 }
 710
 711                 self.event_damage = PlayerDamage;
 712
 713                 self.bot_attack = TRUE;
 714
 715                 self.statdraintime = time + 5;
 716                 self.BUTTON_ATCK = self.BUTTON_JUMP = self.BUTTON_ATCK2 = 0;
 717
 718                 if(self.killcount == -666) {
 719                         PlayerScore_Clear(self);
 720                         self.killcount = 0;
 721                         self.frags = 0;
 722                 }
 723
 724                 self.cnt = WEP_LASER;
 725                 self.nixnex_lastchange_id = -1;
 726
 727                 CL_SpawnWeaponentity();
 728                 self.alpha = default_player_alpha;
 729                 self.colormod = '1 1 1' * cvar("g_player_brightness");
 730                 self.exteriorweaponentity.alpha = default_weapon_alpha;
 731
 732                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval")*2;
 733                 self.lms_traveled_distance = 0;
 734                 self.speedrunning = FALSE;
 735
 736                 race_PostSpawn(spot);
 737
 738                 if(cvar("spawn_debug"))
 739                 {
 740                         sprint(self, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 741                         remove(spot);   // usefull for checking if there are spawnpoints, that let drop through the floor
 742                 }
 743
 744                 //stuffcmd(self, "chase_active 0");
 745                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
 746
 747                 if (cvar("g_spawnsound"))
 748                         sound (self, CHAN_TRIGGER, "misc/spawn.wav", VOL_BASE, ATTN_NORM);
 749
 750                 if(g_assault) {
 751                         if(self.team == assault_attacker_team)
 752                                 centerprint(self, "You are attacking!\n");
 753                         else
 754                                 centerprint(self, "You are defending!\n");
 755                 }
 756
 757         } else if(self.classname == "observer") {
 758                 PutObserverInServer ();
 759         }
 760
 761         //if(g_ctf)
 762         //      ctf_playerchanged();
 763 }
 764
 765 /*
 766 =============
 767 SendCSQCInfo
 768
 769 Send whatever CSQC needs NOW and cannot wait for SendServerInfo to happen...
 770 =============
 771 */
 772 void SendCSQCInfo(void)
 773 {
 774         float i;
 775         if(clienttype(self) != CLIENTTYPE_REAL)
 776                 return;
 777         msg_entity = self;
 778         WriteByte(MSG_ONE, SVC_TEMPENTITY);
 779         WriteByte(MSG_ONE, TE_CSQC_INIT);
 780         WriteShort(MSG_ONE, CSQC_REVISION);
 781         WriteByte(MSG_ONE, maxclients);
 782         for(i = 1; i <= 24; ++i)
 783                 WriteByte(MSG_ONE, (get_weaponinfo(i)).impulse + 1);
 784 }
 785
 786 /*
 787 =============
 788 SetNewParms
 789 =============
 790 */
 791 void SetNewParms (void)
 792 {
 793         // initialize parms for a new player
 794         parm1 = -(86400 * 366);
 795 }
 796
 797 /*
 798 =============
 799 SetChangeParms
 800 =============
 801 */
 802 void SetChangeParms (void)
 803 {
 804         // save parms for level change
 805         parm1 = self.parm_idlesince - time;
 806 }
 807
 808 /*
 809 =============
 810 DecodeLevelParms
 811 =============
 812 */
 813 void DecodeLevelParms (void)
 814 {
 815         // load parms
 816         self.parm_idlesince = parm1;
 817         if(self.parm_idlesince == -(86400 * 366))
 818                 self.parm_idlesince = time;
 819 }
 820
 821 /*
 822 =============
 823 ClientKill
 824
 825 Called when a client types 'kill' in the console
 826 =============
 827 */
 828
 829 void ClientKill_Now_TeamChange()
 830 {
 831         if(self.killindicator_teamchange == -1)
 832         {
 833                 self.team = -1;
 834                 JoinBestTeam( self, FALSE, FALSE );
 835         }
 836         else
 837         {
 838                 SV_ChangeTeam(self.killindicator_teamchange - 1);
 839         }
 840 }
 841
 842 void ClientKill_Now()
 843 {
 844         if(self.killindicator_teamchange)
 845                 ClientKill_Now_TeamChange();
 846
 847         // in any case:
 848         Damage(self, self, self, 100000, DEATH_KILL, self.origin, '0 0 0');
 849
 850         if(self.killindicator)
 851         {
 852                 dprint("Cleaned up after a leaked kill indicator.\n");
 853                 remove(self.killindicator);
 854                 self.killindicator = world;
 855         }
 856 }
 857 void KillIndicator_Think()
 858 {
 859         if (!self.owner.modelindex)
 860         {
 861                 self.owner.killindicator = world;
 862                 remove(self);
 863                 return;
 864         }
 865
 866         if(self.cnt <= 0)
 867         {
 868                 self = self.owner;
 869                 ClientKill_Now(); // no oldself needed
 870                 return;
 871         }
 872         else
 873         {
 874                 if(self.cnt <= 10)
 875                         setmodel(self, strcat("models/sprites/", ftos(self.cnt), ".spr32"));
 876                 if(clienttype(self.owner) == CLIENTTYPE_REAL)
 877                 {
 878                         if(self.cnt <= 10)
 879                                 announce(self.owner, strcat("announcer/robotic/", ftos(self.cnt), ".ogg"));
 880                         if(self.owner.killindicator_teamchange)
 881                         {
 882                                 if(self.owner.killindicator_teamchange == -1)
 883                                         centerprint(self.owner, strcat("Changing team in ", ftos(self.cnt), " seconds"));
 884                                 else
 885                                         centerprint(self.owner, strcat("Changing to ", ColoredTeamName(self.owner.killindicator_teamchange), " in ", ftos(self.cnt), " seconds"));
 886                         }
 887                         else
 888                                 centerprint(self.owner, strcat("^1Suicide in ", ftos(self.cnt), " seconds"));
 889                 }
 890                 self.nextthink = time + 1;
 891                 self.cnt -= 1;
 892         }
 893 }
 894
 895 void ClientKill_TeamChange (float targetteam) // 0 = don't change, -1 = auto
 896 {
 897         float killtime;
 898         entity e;
 899         killtime = cvar("g_balance_kill_delay");
 900
 901         self.killindicator_teamchange = targetteam;
 902
 903         if(!self.killindicator)
 904         {
 905                 if(killtime <= 0 || !self.modelindex || self.deadflag != DEAD_NO)
 906                 {
 907                         ClientKill_Now();
 908                 }
 909                 else
 910                 {
 911                         self.killindicator = spawn();
 912                         self.killindicator.owner = self;
 913                         self.killindicator.scale = 0.5;
 914                         setattachment(self.killindicator, self, "");
 915                         setorigin(self.killindicator, '0 0 52');
 916                         self.killindicator.think = KillIndicator_Think;
 917                         self.killindicator.nextthink = time + (self.lip) * 0.05;
 918                         self.killindicator.cnt = ceil(killtime);
 919                         self.killindicator.count = bound(0, ceil(killtime), 10);
 920                         sprint(self, strcat("^1You'll be dead in ", ftos(self.killindicator.cnt), " seconds\n"));
 921
 922                         for(e = world; (e = find(e, classname, "body")) != world; )
 923                         {
 924                                 if(e.enemy != self)
 925                                         continue;
 926                                 e.killindicator = spawn();
 927                                 e.killindicator.owner = e;
 928                                 e.killindicator.scale = 0.5;
 929                                 setattachment(e.killindicator, e, "");
 930                                 setorigin(e.killindicator, '0 0 52');
 931                                 e.killindicator.think = KillIndicator_Think;
 932                                 e.killindicator.nextthink = time + (e.lip) * 0.05;
 933                                 e.killindicator.cnt = ceil(killtime);
 934                         }
 935                         self.lip = 0;
 936                 }
 937         }
 938         if(self.killindicator)
 939         {
 940                 if(targetteam)
 941                         self.killindicator.colormod = TeamColor(targetteam);
 942                 else
 943                         self.killindicator.colormod = '0 0 0';
 944         }
 945 }
 946
 947 void ClientKill (void)
 948 {
 949         ClientKill_TeamChange(0);
 950 }
 951
 952 void DoTeamChange(float destteam)
 953 {
 954         float t, c0;
 955         if(!cvar("teamplay"))
 956         {
 957                 if(destteam >= 0)
 958                         SetPlayerColors(self, destteam);
 959                 return;
 960         }
 961         if(self.classname == "player")
 962         if(destteam == -1)
 963         {
 964                 CheckAllowedTeams(self);
 965                 t = FindSmallestTeam(self, TRUE);
 966                 switch(self.team)
 967                 {
 968                         case COLOR_TEAM1: c0 = c1; break;
 969                         case COLOR_TEAM2: c0 = c2; break;
 970                         case COLOR_TEAM3: c0 = c3; break;
 971                         case COLOR_TEAM4: c0 = c4; break;
 972                         default:          c0 = 999;
 973                 }
 974                 switch(t)
 975                 {
 976                         case 1:
 977                                 if(c0 > c1)
 978                                         destteam = COLOR_TEAM1;
 979                                 break;
 980                         case 2:
 981                                 if(c0 > c2)
 982                                         destteam = COLOR_TEAM2;
 983                                 break;
 984                         case 3:
 985                                 if(c0 > c3)
 986                                         destteam = COLOR_TEAM3;
 987                                 break;
 988                         case 4:
 989                                 if(c0 > c4)
 990                                         destteam = COLOR_TEAM4;
 991                                 break;
 992                 }
 993                 if(destteam == -1)
 994                         return;
 995         }
 996         if(destteam == self.team && !self.killindicator)
 997                 return;
 998         ClientKill_TeamChange(destteam);
 999 }
1000
1001 void FixClientCvars(entity e)
1002 {
1003         // send prediction settings to the client
1004         stuffcmd(e, "\nin_bindmap 0 0\n");
1005         /*
1006          * we no longer need to stuff this. Remove this comment block if you feel
1007          * 2.3 and higher (or was it 2.2.3?) don't need these any more
1008         stuffcmd(e, strcat("cl_gravity ", ftos(cvar("sv_gravity")), "\n"));
1009         stuffcmd(e, strcat("cl_movement_accelerate ", ftos(cvar("sv_accelerate")), "\n"));
1010         stuffcmd(e, strcat("cl_movement_friction ", ftos(cvar("sv_friction")), "\n"));
1011         stuffcmd(e, strcat("cl_movement_maxspeed ", ftos(cvar("sv_maxspeed")), "\n"));
1012         stuffcmd(e, strcat("cl_movement_airaccelerate ", ftos(cvar("sv_airaccelerate")), "\n"));
1013         stuffcmd(e, strcat("cl_movement_maxairspeed ", ftos(cvar("sv_maxairspeed")), "\n"));
1014         stuffcmd(e, strcat("cl_movement_stopspeed ", ftos(cvar("sv_stopspeed")), "\n"));
1015         stuffcmd(e, strcat("cl_movement_jumpvelocity ", ftos(cvar("sv_jumpvelocity")), "\n"));
1016         stuffcmd(e, strcat("cl_movement_stepheight ", ftos(cvar("sv_stepheight")), "\n"));
1017         stuffcmd(e, strcat("set cl_movement_friction_on_land ", ftos(cvar("sv_friction_on_land")), "\n"));
1018         stuffcmd(e, strcat("set cl_movement_airaccel_qw ", ftos(cvar("sv_airaccel_qw")), "\n"));
1019         stuffcmd(e, strcat("set cl_movement_airaccel_sideways_friction ", ftos(cvar("sv_airaccel_sideways_friction")), "\n"));
1020         stuffcmd(e, "cl_movement_edgefriction 1\n");
1021          */
1022 }
1023
1024 /*
1025 =============
1026 ClientConnect
1027
1028 Called when a client connects to the server
1029 =============
1030 */
1031 //void ctf_clientconnect();
1032 string ColoredTeamName(float t);
1033 void DecodeLevelParms (void);
1034 //void dom_player_join_team(entity pl);
1035 void ClientConnect (void)
1036 {
1037         local string s;
1038
1039         if(self.flags & FL_CLIENT)
1040         {
1041                 print("Warning: ClientConnect, but already connected!\n");
1042                 return;
1043         }
1044
1045         if(Ban_IsClientBanned(self))
1046         {
1047                 s = strcat("^1NOTE:^7 banned client ", self.netaddress, " just tried to enter\n");
1048                 dropclient(self);
1049                 bprint(s);
1050                 return;
1051         }
1052
1053         DecodeLevelParms();
1054
1055         self.classname = "player_joining";
1056
1057         self.flags = self.flags | FL_CLIENT;
1058         self.version_nagtime = time + 10 + random() * 10;
1059
1060         if(player_count<0)
1061         {
1062                 dprint("BUG player count is lower than zero, this cannot happen!\n");
1063                 player_count = 0;
1064         }
1065
1066         PlayerScore_Attach(self);
1067
1068         bot_clientconnect();
1069
1070         race_PreSpawnObserver();
1071
1072         //if(g_domination)
1073         //      dom_player_join_team(self);
1074
1075         //JoinBestTeam(self, FALSE, FALSE);
1076
1077         if((cvar("sv_spectate") == 1 && !g_lms) || cvar("g_campaign")) {
1078                 self.classname = "observer";
1079         } else {
1080                 self.classname = "player";
1081                 campaign_bots_may_start = 1;
1082         }
1083
1084         self.playerid = (playerid_last = playerid_last + 1);
1085         if(cvar("sv_eventlog"))
1086         {
1087                 if(clienttype(self) == CLIENTTYPE_REAL)
1088                         s = "player";
1089                 else
1090                         s = "bot";
1091                 GameLogEcho(strcat(":join:", ftos(self.playerid), ":", s, ":", self.netname));
1092                 s = strcat(":team:", ftos(self.playerid), ":");
1093                 s = strcat(s, ftos(self.team));
1094                 GameLogEcho(s);
1095         }
1096         self.netname_previous = strzone(self.netname);
1097
1098         //stuffcmd(self, "set tmpviewsize $viewsize \n");
1099
1100         bprint ("^4",self.netname);
1101         bprint ("^4 connected");
1102
1103         if(g_domination || g_ctf)
1104         {
1105                 bprint(" and joined the ");
1106                 bprint(ColoredTeamName(self.team));
1107         }
1108
1109         bprint("\n");
1110
1111         self.welcomemessage_time = 0;
1112
1113         stuffcmd(self, strcat(clientstuff, "\n"));
1114         stuffcmd(self, strcat("exec maps/", mapname, ".cfg\n"));
1115         stuffcmd(self, "cl_particles_reloadeffects\n");
1116
1117         FixClientCvars(self);
1118
1119         // spawnfunc_waypoint sprites
1120         WaypointSprite_InitClient(self);
1121
1122         // Wazat's grappling hook
1123         SetGrappleHookBindings();
1124
1125         // get autoswitch state from player when he toggles it
1126         stuffcmd(self, "alias autoswitch \"set cl_autoswitch $1 ; cmd autoswitch $1\"\n"); // default.cfg-ed in 2.4.1
1127
1128         // get version info from player
1129         stuffcmd(self, "cmd clientversion $gameversion\n");
1130
1131         // get other cvars from player
1132         GetCvars(0);
1133
1134         // set cvar for team scoreboard
1135         if (teams_matter)
1136         {
1137                 local float t;
1138                 t = cvar("teamplay");
1139                 // we have to stuff the correct teamplay value because if this is a listen server, this changes the teamplay mode of the server itself, which is bad
1140                 stuffcmd(self, strcat("set teamplay ", ftos(t), "\n"));
1141         }
1142         else
1143                 stuffcmd(self, "set teamplay 0\n");
1144
1145         // notify about available teams
1146         if(teamplay)
1147         {
1148                 CheckAllowedTeams(self);
1149                 t = 0; if(c1 >= 0) t |= 1; if(c2 >= 0) t |= 2; if(c3 >= 0) t |= 4; if(c4 >= 0) t |= 8;
1150                 stuffcmd(self, strcat("set _teams_available ", ftos(t), "\n"));
1151         }
1152         else
1153                 stuffcmd(self, "set _teams_available 0\n");
1154
1155         stuffcmd(self, strcat("set gametype ", ftos(game), "\n"));
1156
1157         if(g_arena)
1158         {
1159                 self.classname = "observer";
1160                 Spawnqueue_Insert(self);
1161         }
1162         /*else if(g_ctf)
1163         {
1164                 ctf_clientconnect();
1165         }*/
1166
1167         if(entcs_start)
1168                 attach_entcs();
1169
1170         bot_relinkplayerlist();
1171
1172         self.spectatortime = time;
1173         if(blockSpectators)
1174         {
1175                 sprint(self, strcat("^7You have to become a player within the next ", ftos(cvar("g_maxplayers_spectator_blocktime")), " seconds, otherwise you will be kicked, because spectators aren't allowed at this time!\n"));
1176         }
1177
1178         self.jointime = time;
1179         self.allowedTimeouts = cvar("sv_timeout_number");
1180
1181         if(clienttype(self) == CLIENTTYPE_REAL)
1182         {
1183                 sprint(self, strcat("nexuiz-csqc protocol ", ftos(CSQC_REVISION), "\n"));
1184                 SendCSQCInfo();
1185                 msg_entity = self;
1186                 if(mapvote_initialized && !cvar("g_maplist_textonly"))
1187                 {
1188                         MapVote_SendData(MSG_ONE);
1189                         MapVote_UpdateData(MSG_ONE);
1190                 }
1191                 ScoreInfo_Write(MSG_ONE);
1192         }
1193
1194         if(g_lms)
1195         {
1196                 if(PlayerScore_Add(self, SP_LMS_LIVES, LMS_NewPlayerLives()) <= 0)
1197                 {
1198                         PlayerScore_Add(self, SP_LMS_RANK, 666);
1199                         self.frags = -666; // FIXME do we still need this?
1200                 }
1201         }
1202 }
1203
1204 /*
1205 =============
1206 ClientDisconnect
1207
1208 Called when a client disconnects from the server
1209 =============
1210 */
1211 void(entity e) DropFlag;
1212 .entity chatbubbleentity;
1213 .entity teambubbleentity;
1214 void ReadyCount();
1215 //void() ctf_clientdisconnect;
1216 void ClientDisconnect (void)
1217 {
1218         float save;
1219
1220         if not(self.flags & FL_CLIENT)
1221         {
1222                 print("Warning: ClientDisconnect without ClientConnect\n");
1223                 return;
1224         }
1225
1226         bot_clientdisconnect();
1227
1228         if(entcs_start)
1229                 detach_entcs();
1230
1231         if(cvar("sv_eventlog"))
1232                 GameLogEcho(strcat(":part:", ftos(self.playerid)));
1233         bprint ("^4",self.netname);
1234         bprint ("^4 disconnected\n");
1235
1236         if (self.chatbubbleentity)
1237         {
1238                 remove (self.chatbubbleentity);
1239                 self.chatbubbleentity = world;
1240         }
1241
1242         if (self.teambubbleentity)
1243         {
1244                 remove (self.teambubbleentity);
1245                 self.teambubbleentity = world;
1246         }
1247
1248         if (self.killindicator)
1249         {
1250                 remove (self.killindicator);
1251                 self.killindicator = world;
1252         }
1253
1254         WaypointSprite_PlayerGone();
1255
1256         DropAllRunes(self);
1257         kh_Key_DropAll(self, TRUE);
1258
1259         Portal_ClearAll(self);
1260
1261         if(self.flagcarried)
1262                 DropFlag(self.flagcarried);
1263
1264         save = self.flags;
1265         self.flags = self.flags - (self.flags & FL_CLIENT);
1266         bot_relinkplayerlist();
1267         self.flags = save;
1268
1269         // remove laserdot
1270         if(self.weaponentity)
1271                 if(self.weaponentity.lasertarget)
1272                         remove(self.weaponentity.lasertarget);
1273
1274         if(g_arena)
1275         {
1276                 Spawnqueue_Unmark(self);
1277                 Spawnqueue_Remove(self);
1278         }
1279         /*if(g_ctf)
1280         {
1281                 ctf_clientdisconnect();
1282         }
1283         */
1284
1285         PlayerScore_Detach(self);
1286
1287         if(self.netname_previous)
1288                 strunzone(self.netname_previous);
1289
1290         ClearPlayerSounds();
1291
1292         // free cvars
1293         GetCvars(-1);
1294         self.playerid = 0;
1295
1296         ReadyCount();
1297 }
1298
1299 .float BUTTON_CHAT;
1300 void ChatBubbleThink()
1301 {
1302         self.nextthink = time;
1303         if (!self.owner.modelindex || self.owner.chatbubbleentity != self)
1304         {
1305                 self.owner.chatbubbleentity = world;
1306                 remove(self);
1307                 return;
1308         }
1309         setorigin(self, self.owner.origin + '0 0 15' + self.owner.maxs_z * '0 0 1');
1310         if (self.owner.BUTTON_CHAT && !self.owner.deadflag)
1311                 self.model = self.mdl;
1312         else
1313                 self.model = "";
1314 };
1315
1316 void UpdateChatBubble()
1317 {
1318         if (!self.modelindex)
1319                 return;
1320         // spawn a chatbubble entity if needed
1321         if (!self.chatbubbleentity)
1322         {
1323                 self.chatbubbleentity = spawn();
1324                 self.chatbubbleentity.owner = self;
1325                 self.chatbubbleentity.exteriormodeltoclient = self;
1326                 self.chatbubbleentity.think = ChatBubbleThink;
1327                 self.chatbubbleentity.nextthink = time;
1328                 setmodel(self.chatbubbleentity, "models/misc/chatbubble.spr"); // precision set below
1329                 setorigin(self.chatbubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1330                 self.chatbubbleentity.mdl = self.chatbubbleentity.model;
1331                 self.chatbubbleentity.model = "";
1332                 self.chatbubbleentity.effects = EF_LOWPRECISION;
1333         }
1334 }
1335
1336
1337 void TeamBubbleThink()
1338 {
1339         self.nextthink = time;
1340         if (!self.owner.modelindex || self.owner.teambubbleentity != self)
1341         {
1342                 self.owner.teambubbleentity = world;
1343                 remove(self);
1344                 return;
1345         }
1346 //      setorigin(self, self.owner.origin + '0 0 15' + self.owner.maxs_z * '0 0 1');  // bandwidth hog. setattachment does this now
1347         if (self.owner.BUTTON_CHAT || self.owner.deadflag || self.owner.killindicator)
1348                 self.model = "";
1349         else
1350                 self.model = self.mdl;
1351
1352 };
1353
1354 float TeamBubble_customizeentityforclient()
1355 {
1356         return (self.owner != other && self.owner.team == other.team && other.killcount > -666);
1357 }
1358
1359 void UpdateTeamBubble()
1360 {
1361         if (!self.modelindex || !cvar("teamplay"))
1362                 return;
1363         // spawn a teambubble entity if needed
1364         if (!self.teambubbleentity && cvar("teamplay"))
1365         {
1366                 self.teambubbleentity = spawn();
1367                 self.teambubbleentity.owner = self;
1368                 self.teambubbleentity.exteriormodeltoclient = self;
1369                 self.teambubbleentity.think = TeamBubbleThink;
1370                 self.teambubbleentity.nextthink = time;
1371                 setmodel(self.teambubbleentity, "models/misc/teambubble.spr"); // precision set below
1372 //              setorigin(self.teambubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1373                 setorigin(self.teambubbleentity, self.teambubbleentity.origin + '0 0 15' + self.maxs_z * '0 0 1');
1374                 setattachment(self.teambubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1375                 self.teambubbleentity.mdl = self.teambubbleentity.model;
1376                 self.teambubbleentity.model = self.teambubbleentity.mdl;
1377                 self.teambubbleentity.customizeentityforclient = TeamBubble_customizeentityforclient;
1378                 self.teambubbleentity.effects = EF_LOWPRECISION;
1379         }
1380 }
1381
1382 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1383 // added to the model skins
1384 /*void UpdateColorModHack()
1385 {
1386         local float c;
1387         c = self.clientcolors & 15;
1388         // LordHavoc: only bothering to support white, green, red, yellow, blue
1389              if (teamplay == 0) self.colormod = '0 0 0';
1390         else if (c ==  0) self.colormod = '1.00 1.00 1.00';
1391         else if (c ==  3) self.colormod = '0.10 1.73 0.10';
1392         else if (c ==  4) self.colormod = '1.73 0.10 0.10';
1393         else if (c == 12) self.colormod = '1.22 1.22 0.10';
1394         else if (c == 13) self.colormod = '0.10 0.10 1.73';
1395         else self.colormod = '1 1 1';
1396 };*/
1397
1398 void respawn(void)
1399 {
1400         CopyBody(1);
1401         self.effects |= EF_NODRAW; // prevent another CopyBody
1402         PutClientInServer();
1403 }
1404
1405 /**
1406  * When sv_timeout is used this function returs strings like
1407  * "Timeout begins in 2 seconds!\n" or "Timeout ends in 23 seconds!\n".
1408  * Called by centerprint functions
1409  * @param addOneSecond boolean, set to 1 if the welcome-message centerprint asks for the text
1410  */
1411 string getTimeoutText(float addOneSecond) {
1412         if (!cvar("sv_timeout") || !timeoutStatus)
1413                 return "";
1414
1415         local string retStr;
1416         if (timeoutStatus == 1) {
1417                 if (addOneSecond == 1) {
1418                         retStr = strcat("Timeout begins in ", ftos(remainingLeadTime + 1), " seconds!\n");
1419                 }
1420                 else {
1421                         retStr = strcat("Timeout begins in ", ftos(remainingLeadTime), " seconds!\n");
1422                 }
1423                 return retStr;
1424         }
1425         else if (timeoutStatus == 2) {
1426                 if (addOneSecond) {
1427                         retStr = strcat("Timeout ends in ", ftos(remainingTimeoutTime + 1), " seconds!\n");
1428                         //don't show messages like "Timeout ends in 0 seconds"...
1429                         if ((remainingTimeoutTime + 1) > 0)
1430                                 return retStr;
1431                         else
1432                                 return "";
1433                 }
1434                 else {
1435                         retStr = strcat("Timeout ends in ", ftos(remainingTimeoutTime), " seconds!\n");
1436                         //don't show messages like "Timeout ends in 0 seconds"...
1437                         if (remainingTimeoutTime > 0)
1438                                 return retStr;
1439                         else
1440                                 return "";
1441                 }
1442         }
1443         else return "";
1444 }
1445
1446 void player_powerups (void)
1447 {
1448         if (g_minstagib)
1449         {
1450                 if (self.items & IT_STRENGTH)
1451                 {
1452                         if (time > self.strength_finished)
1453                         {
1454                                 if (g_minstagib_invis_alpha > 0)
1455                                 {
1456                                         self.alpha = default_player_alpha;
1457                                         self.exteriorweaponentity.alpha = default_weapon_alpha;
1458                                         self.effects = self.effects | EF_FULLBRIGHT;
1459                                 }
1460                                 else
1461                                 {
1462                                         self.effects -= self.effects & EF_NODRAW;
1463                                 }
1464                                 self.items = self.items - (self.items & IT_STRENGTH);
1465                                 sprint(self, "^3Invisibility has worn off\n");
1466                         }
1467                 }
1468                 else
1469                 {
1470                         if (time < self.strength_finished)
1471                         {
1472                                 if (g_minstagib_invis_alpha > 0)
1473                                 {
1474                                         self.alpha = g_minstagib_invis_alpha;
1475                                         self.exteriorweaponentity.alpha = g_minstagib_invis_alpha;
1476                                         self.effects -= self.effects & EF_FULLBRIGHT;
1477                                 }
1478                                 else
1479                                 {
1480                                         self.effects = self.effects | EF_NODRAW;
1481                                 }
1482                                 self.items = self.items | IT_STRENGTH;
1483                                 sprint(self, "^3You are invisible\n");
1484                         }
1485                 }
1486
1487                 if (self.items & IT_INVINCIBLE)
1488                 {
1489                         if (time > self.invincible_finished)
1490                         {
1491                                 self.items = self.items - (self.items & IT_INVINCIBLE);
1492                                 sprint(self, "^3Speed has worn off\n");
1493                         }
1494                 }
1495                 else
1496                 {
1497                         if (time < self.invincible_finished)
1498                         {
1499                                 self.items = self.items | IT_INVINCIBLE;
1500                                 sprint(self, "^3You are on speed\n");
1501                         }
1502                 }
1503                 return;
1504         }
1505
1506         self.effects = self.effects - (self.effects & (EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT));
1507         if (self.items & IT_STRENGTH)
1508         {
1509                 self.effects = self.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1510                 if (time > self.strength_finished)
1511                 {
1512                         self.items = self.items - (self.items & IT_STRENGTH);
1513                         sprint(self, "^3Strength has worn off\n");
1514                 }
1515         }
1516         else
1517         {
1518                 if (time < self.strength_finished)
1519                 {
1520                         self.items = self.items | IT_STRENGTH;
1521                         sprint(self, "^3Strength infuses your weapons with devastating power\n");
1522                 }
1523         }
1524         if (self.items & IT_INVINCIBLE)
1525         {
1526                 self.effects = self.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1527                 if (time > self.invincible_finished)
1528                 {
1529                         self.items = self.items - (self.items & IT_INVINCIBLE);
1530                         sprint(self, "^3Shield has worn off\n");
1531                 }
1532         }
1533         else
1534         {
1535                 if (time < self.invincible_finished)
1536                 {
1537                         self.items = self.items | IT_INVINCIBLE;
1538                         sprint(self, "^3Shield surrounds you\n");
1539                 }
1540         }
1541
1542         if (cvar("g_fullbrightplayers"))
1543                 self.effects = self.effects | EF_FULLBRIGHT;
1544
1545         // midair gamemode: damage only while in the air
1546         // if in midair mode, being on ground grants temporary invulnerability
1547         // (this is so that multishot weapon don't clear the ground flag on the
1548         // first damage in the frame, leaving the player vulnerable to the
1549         // remaining hits in the same frame)
1550         if (self.flags & FL_ONGROUND)
1551         if (g_midair)
1552                 self.spawnshieldtime = max(self.spawnshieldtime, time + cvar("g_midair_shieldtime"));
1553
1554         if (time > restart_countdown)
1555         if (time < self.spawnshieldtime)
1556                 self.effects = self.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1557 }
1558
1559 float CalcRegen(float current, float stable, float regenfactor)
1560 {
1561         if(current > stable)
1562                 return current;
1563         else if(current > stable - 0.25) // when close enough, "snap"
1564                 return stable;
1565         else
1566                 return min(stable, current + (stable - current) * regenfactor * frametime);
1567 }
1568
1569 void player_regen (void)
1570 {
1571         float maxh, maxa, limith, limita, max_mod, regen_mod, rot_mod, limit_mod;
1572         maxh = cvar("g_balance_health_stable");
1573         maxa = cvar("g_balance_armor_stable");
1574         limith = cvar("g_balance_health_limit");
1575         limita = cvar("g_balance_armor_limit");
1576
1577         if (g_minstagib || (g_lms && !cvar("g_lms_regenerate")))
1578                 return;
1579
1580         max_mod = regen_mod = rot_mod = limit_mod = 1;
1581
1582         if (self.runes & RUNE_REGEN)
1583         {
1584                 if (self.runes & CURSE_VENOM) // do we have both rune/curse?
1585                 {
1586                         regen_mod = cvar("g_balance_rune_regen_combo_regenrate");
1587                         max_mod = cvar("g_balance_rune_regen_combo_hpmod");
1588                         limit_mod = cvar("g_balance_rune_regen_combo_limitmod");
1589                 }
1590                 else
1591                 {
1592                         regen_mod = cvar("g_balance_rune_regen_regenrate");
1593                         max_mod = cvar("g_balance_rune_regen_hpmod");
1594                         limit_mod = cvar("g_balance_rune_regen_limitmod");
1595                 }
1596         }
1597         else if (self.runes & CURSE_VENOM)
1598         {
1599                 max_mod = cvar("g_balance_curse_venom_hpmod");
1600                 if (self.runes & RUNE_REGEN) // do we have both rune/curse?
1601                         rot_mod = cvar("g_balance_rune_regen_combo_rotrate");
1602                 else
1603                         rot_mod = cvar("g_balance_curse_venom_rotrate");
1604                 limit_mod = cvar("g_balance_curse_venom_limitmod");
1605                 //if (!self.runes & RUNE_REGEN)
1606                 //      rot_mod = cvar("g_balance_curse_venom_rotrate");
1607         }
1608         maxh = maxh * max_mod;
1609         //maxa = maxa * max_mod;
1610         limith = limith * limit_mod;
1611         limita = limita * limit_mod;
1612
1613         if (self.armorvalue > maxa)
1614         {
1615                 if (time > self.pauserotarmor_finished)
1616                 {
1617                         self.armorvalue = max(maxa, self.armorvalue + (maxa - self.armorvalue) * cvar("g_balance_armor_rot") * frametime);
1618                         self.armorvalue = max(maxa, self.armorvalue - cvar("g_balance_armor_rotlinear") * frametime);
1619                 }
1620         }
1621         else if (self.armorvalue < maxa)
1622         {
1623                 if (time > self.pauseregen_finished)
1624                 {
1625                         self.armorvalue = CalcRegen(self.armorvalue, maxa, cvar("g_balance_armor_regen"));
1626                         self.armorvalue = min(maxa, self.armorvalue + cvar("g_balance_armor_regenlinear") * frametime);
1627                 }
1628         }
1629         if (self.health > maxh)
1630         {
1631                 if (time > self.pauserothealth_finished)
1632                 {
1633                         self.health = max(maxh, self.health + (maxh - self.health) * rot_mod*cvar("g_balance_health_rot") * frametime);
1634                         self.health = max(maxh, self.health - rot_mod*cvar("g_balance_health_rotlinear") * frametime);
1635                 }
1636         }
1637         else if (self.health < maxh)
1638         {
1639                 if (time > self.pauseregen_finished)
1640                 {
1641                         self.health = CalcRegen(self.health, maxh, regen_mod * cvar("g_balance_health_regen"));
1642                         self.health = min(maxh, self.health + regen_mod*cvar("g_balance_health_regenlinear") * frametime);
1643                 }
1644         }
1645
1646         if (self.health > limith)
1647                 self.health = limith;
1648         if (self.armorvalue > limita)
1649                 self.armorvalue = limita;
1650
1651         // if player rotted to death...  die!
1652         if(self.health < 1)
1653                 self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
1654 }
1655
1656 .float zoomstate;
1657 float zoomstate_set;
1658 void SetZoomState(float z)
1659 {
1660         if(z != self.zoomstate)
1661         {
1662                 msg_entity = self;
1663                 WriteByte(MSG_ONE, SVC_TEMPENTITY);
1664                 WriteByte(MSG_ONE, TE_CSQC_ZOOMNOTIFY);
1665                 WriteByte(MSG_ONE, z);
1666                 self.zoomstate = z;
1667         }
1668         zoomstate_set = 1;
1669 }
1670
1671 /*
1672 ======================
1673 spectate mode routines
1674 ======================
1675 */
1676 void SpectateCopy(entity spectatee) {
1677         self.armortype = spectatee.armortype;
1678         self.armorvalue = spectatee.armorvalue;
1679         self.currentammo = spectatee.currentammo;
1680         self.effects = spectatee.effects;
1681         self.health = spectatee.health;
1682         self.impulse = 0;
1683         self.items = spectatee.items;
1684         self.weapons = spectatee.weapons;
1685         self.punchangle = spectatee.punchangle;
1686         self.view_ofs = spectatee.view_ofs;
1687         self.v_angle = spectatee.v_angle;
1688         self.velocity = spectatee.velocity;
1689         self.dmg_take = spectatee.dmg_take;
1690         self.dmg_save = spectatee.dmg_save;
1691         self.dmg_inflictor = spectatee.dmg_inflictor;
1692         self.angles = spectatee.v_angle;
1693         self.fixangle = TRUE;
1694         setorigin(self, spectatee.origin);
1695         setsize(self, spectatee.mins, spectatee.maxs);
1696         SetZoomState(spectatee.zoomstate);
1697 }
1698
1699 float SpectateUpdate() {
1700         if(!self.enemy)
1701                 return 0;
1702
1703         if (self == self.enemy)
1704                 return 0;
1705
1706         if(self.enemy.flags & FL_NOTARGET)
1707                 return 0;
1708
1709         SpectateCopy(self.enemy);
1710
1711         return 1;
1712 }
1713
1714 float SpectateNext() {
1715         other = find(self.enemy, classname, "player");
1716         if (!other) {
1717                 other = find(other, classname, "player");
1718         }
1719         if (other) {
1720                 self.enemy = other;
1721         }
1722         if(self.enemy.classname == "player") {
1723                 msg_entity = self;
1724                 WriteByte(MSG_ONE, SVC_SETVIEW);
1725                 WriteEntity(MSG_ONE, self.enemy);
1726                 self.wantswelcomemessage = 1;
1727                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
1728                 if(!SpectateUpdate())
1729                         PutObserverInServer();
1730                 return 1;
1731         } else {
1732                 return 0;
1733         }
1734 }
1735
1736 /*
1737 =============
1738 ShowRespawnCountdown()
1739
1740 Update a respawn countdown display.
1741 =============
1742 */
1743 void ShowRespawnCountdown()
1744 {
1745         float number;
1746         if(self.deadflag == DEAD_NO) // just respawned?
1747                 return;
1748         else
1749         {
1750                 number = ceil(self.death_time - time);
1751                 if(number <= 0)
1752                         return;
1753                 if(number <= self.respawn_countdown)
1754                 {
1755                         self.respawn_countdown = number - 1;
1756                         if(ceil(self.death_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
1757                                 announce(self, strcat("announcer/robotic/", ftos(number), ".ogg"));
1758                 }
1759         }
1760 }
1761
1762 void LeaveSpectatorMode()
1763 {
1764         if(isJoinAllowed()) {
1765                 if(!cvar("teamplay") || cvar("g_campaign") || cvar("g_balance_teams")) {
1766                         self.classname = "player";
1767                         if(cvar("g_campaign") || cvar("g_balance_teams") || cvar("g_balance_teams_force"))
1768                                 JoinBestTeam(self, FALSE, TRUE);
1769                         if(cvar("g_campaign"))
1770                                 campaign_bots_may_start = 1;
1771                         PutClientInServer();
1772                         if(!(self.flags & FL_NOTARGET))
1773                                 bprint ("^4", self.netname, "^4 is playing now\n");
1774                         centerprint(self,"");
1775                         return;
1776                 } else {
1777                         stuffcmd(self,"menu_showteamselect\n");
1778                         return;
1779                 }
1780         }
1781         else {
1782                 //player may not join because of g_maxplayers is set
1783                 centerprint_atprio(self, CENTERPRIO_MAPVOTE, PREVENT_JOIN_TEXT);
1784         }
1785 }
1786
1787 /**
1788  * Determines whether the player is allowed to join. This depends on cvar
1789  * g_maxplayers, if it isn't used this function always return TRUE, otherwise
1790  * it checks whether the number of currently playing players exceeds g_maxplayers.
1791  * @return bool TRUE if the player is allowed to join, false otherwise
1792  */
1793 float isJoinAllowed() {
1794         if (!cvar("g_maxplayers"))
1795                 return TRUE;
1796
1797         local entity e;
1798         local float currentlyPlaying;
1799         FOR_EACH_REALPLAYER(e) {
1800                 if(e.classname == "player")
1801                         currentlyPlaying += 1;
1802         }
1803         if(currentlyPlaying < cvar("g_maxplayers"))
1804                 return TRUE;
1805
1806         return FALSE;
1807 }
1808
1809 /**
1810  * Checks whether the client is an observer or spectator, if so, he will get kicked after
1811  * g_maxplayers_spectator_blocktime seconds
1812  */
1813 void checkSpectatorBlock() {
1814         if(self.classname == "spectator" || self.classname == "observer") {
1815                 if( time > (self.spectatortime + cvar("g_maxplayers_spectator_blocktime")) ) {
1816                         sprint(self, "^7You were kicked from the server because you are spectator and spectators aren't allowed at the moment.\n");
1817                         dropclient(self);
1818                 }
1819         }
1820 }
1821
1822 float vercmp_recursive(string v1, string v2)
1823 {
1824         float dot1, dot2;
1825         string s1, s2;
1826         float r;
1827
1828         dot1 = strstrofs(v1, ".", 0);
1829         dot2 = strstrofs(v2, ".", 0);
1830         if(dot1 == -1)
1831                 s1 = v1;
1832         else
1833                 s1 = substring(v1, 0, dot1);
1834         if(dot2 == -1)
1835                 s2 = v2;
1836         else
1837                 s2 = substring(v2, 0, dot2);
1838
1839         r = stof(s1) - stof(s2);
1840         if(r != 0)
1841                 return r;
1842
1843         r = strcasecmp(s1, s2);
1844         if(r != 0)
1845                 return r;
1846
1847         if(dot1 == -1)
1848                 if(dot2 == -1)
1849                         return 0;
1850                 else
1851                         return -1;
1852         else
1853                 if(dot2 == -1)
1854                         return 1;
1855                 else
1856                         return vercmp_recursive(substring(v1, dot1 + 1, 999), substring(v2, dot2 + 1, 999));
1857 }
1858
1859 float vercmp(string v1, string v2)
1860 {
1861         if(strcasecmp(v1, v2) == 0) // early out check
1862                 return 0;
1863         return vercmp_recursive(v1, v2);
1864 }
1865
1866 void ObserverThink()
1867 {
1868         if (self.flags & FL_JUMPRELEASED) {
1869                 if (self.BUTTON_JUMP && !self.version_mismatch) {
1870                         self.welcomemessage_time = 0;
1871                         self.flags = self.flags - FL_JUMPRELEASED;
1872                         LeaveSpectatorMode();
1873                         return;
1874                 } else if(self.BUTTON_ATCK && !self.version_mismatch) {
1875                         self.welcomemessage_time = 0;
1876                         self.flags = self.flags - FL_JUMPRELEASED;
1877                         if(SpectateNext() == 1) {
1878                                 self.classname = "spectator";
1879                         }
1880                 }
1881         } else {
1882                 if (!(self.BUTTON_ATCK || self.BUTTON_JUMP)) {
1883                         self.flags = self.flags | FL_JUMPRELEASED;
1884                 }
1885         }
1886         if(self.BUTTON_ZOOM)
1887                 self.wantswelcomemessage = 0;
1888         if(self.wantswelcomemessage)
1889                 PrintWelcomeMessage(self);
1890 }
1891
1892 void SpectatorThink()
1893 {
1894         if (self.flags & FL_JUMPRELEASED) {
1895                 if (self.BUTTON_JUMP && !self.version_mismatch) {
1896                         self.welcomemessage_time = 0;
1897                         self.flags = self.flags - FL_JUMPRELEASED;
1898                         LeaveSpectatorMode();
1899                         return;
1900                 } else if(self.BUTTON_ATCK) {
1901                         self.welcomemessage_time = 0;
1902                         self.flags = self.flags - FL_JUMPRELEASED;
1903                         if(SpectateNext() == 1) {
1904                                 self.classname = "spectator";
1905                         } else {
1906                                 self.classname = "observer";
1907                                 PutClientInServer();
1908                         }
1909                 } else if (self.BUTTON_ATCK2) {
1910                         self.welcomemessage_time = 0;
1911                         self.flags = self.flags - FL_JUMPRELEASED;
1912                         self.classname = "observer";
1913                         PutClientInServer();
1914                 } else {
1915                         if(!SpectateUpdate())
1916                                 PutObserverInServer();
1917                 }
1918         } else {
1919                 if (!(self.BUTTON_ATCK || self.BUTTON_ATCK2)) {
1920                         self.flags = self.flags | FL_JUMPRELEASED;
1921                 }
1922         }
1923         if(self.BUTTON_ZOOM)
1924                 self.wantswelcomemessage = 0;
1925         if(self.wantswelcomemessage)
1926                 PrintWelcomeMessage(self);
1927         self.flags = self.flags | FL_CLIENT | FL_NOTARGET;
1928 }
1929
1930 /*
1931 =============
1932 PlayerPreThink
1933
1934 Called every frame for each client before the physics are run
1935 =============
1936 */
1937 void() ctf_setstatus;
1938 .float vote_nagtime;
1939 .float spectatee_status;
1940 void PlayerPreThink (void)
1941 {
1942         self.stat_sys_ticrate = cvar("sys_ticrate");
1943         if(blockSpectators)
1944                 checkSpectatorBlock();
1945
1946         zoomstate_set = 0;
1947
1948         if(self.netname_previous != self.netname)
1949         {
1950                 if(cvar("sv_eventlog"))
1951                         GameLogEcho(strcat(":name:", ftos(self.playerid), ":", self.netname));
1952                 if(self.netname_previous)
1953                         strunzone(self.netname_previous);
1954                 self.netname_previous = strzone(self.netname);
1955         }
1956
1957         // version nagging
1958         if(self.version_nagtime)
1959                 if(self.cvar_g_nexuizversion)
1960                         if(time > self.version_nagtime)
1961                         {
1962                                 if(strstr(self.cvar_g_nexuizversion, "svn", 0) < 0)
1963                                 {
1964                                         if(strstr(cvar_string("g_nexuizversion"), "svn", 0) >= 0)
1965                                         {
1966                                                 dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Nexuiz ", cvar_string("g_nexuizversion"), " (beta)^7, you have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1\n");
1967                                                 sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Nexuiz ", cvar_string("g_nexuizversion"), " (beta)^7, you have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1\n"));
1968                                         }
1969                                         else
1970                                         {
1971                                                 float r;
1972                                                 r = vercmp(self.cvar_g_nexuizversion, cvar_string("g_nexuizversion"));
1973                                                 if(r < 0)
1974                                                 {
1975                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - ^3Nexuiz ", cvar_string("g_nexuizversion"), "^7 is out, and you still have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1 - get the update from ^4http://www.nexuiz.com/^1!\n");
1976                                                         sprint(self, strcat("\{1}^1NOTE: ^3Nexuiz ", cvar_string("g_nexuizversion"), "^7 is out, and you still have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1 - get the update from ^4http://www.nexuiz.com/^1!\n"));
1977                                                 }
1978                                                 else if(r > 0)
1979                                                 {
1980                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Nexuiz ", cvar_string("g_nexuizversion"), "^7, you have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1\n");
1981                                                         sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Nexuiz ", cvar_string("g_nexuizversion"), "^7, you have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1\n"));
1982                                                 }
1983                                         }
1984                                 }
1985                                 self.version_nagtime = 0;
1986                         }
1987
1988         // vote nagging
1989         if(self.cvar_scr_centertime)
1990                 if(time > self.vote_nagtime)
1991                 {
1992                         VoteNag();
1993                         self.vote_nagtime = time + self.cvar_scr_centertime * 0.6;
1994                 }
1995
1996         // GOD MODE info
1997         if(!(self.flags & FL_GODMODE)) if(self.max_armorvalue)
1998         {
1999                 sprint(self, strcat("godmode saved you ", ftos(self.max_armorvalue), " units of damage, cheater!\n"));
2000                 self.max_armorvalue = 0;
2001         }
2002
2003         if(frametime)
2004                 antilag_record(self);
2005
2006         if(self.classname == "player") {
2007 //              if(self.netname == "Wazat")
2008 //                      bprint(self.classname, "\n");
2009
2010                 CheckRules_Player();
2011
2012                 if(self.BUTTON_INFO)
2013                         PrintWelcomeMessage(self);
2014
2015                 if(g_lms || !cvar("sv_spectate"))
2016                 if((time - self.jointime) <= cvar("welcome_message_time"))
2017                         PrintWelcomeMessage(self);
2018
2019                 if (intermission_running)
2020                 {
2021                         IntermissionThink ();   // otherwise a button could be missed between
2022                         return;                                 // the think tics
2023                 }
2024
2025                 if(self.teleport_time)
2026                 if(time > self.teleport_time)
2027                 {
2028                         self.teleport_time = 0;
2029                         self.effects = self.effects - (self.effects & EF_NODRAW);
2030                         if(self.weaponentity)
2031                                 self.weaponentity.flags = self.weaponentity.flags - (self.weaponentity.flags & EF_NODRAW);
2032                 }
2033
2034                 Nixnex_GiveCurrentWeapon();
2035
2036                 if(frametime > 0) // don't do this in cl_movement frames, just in server ticks
2037                         UpdateSelectedPlayer();
2038
2039                 //don't allow the player to turn around while game is paused!
2040                 if(timeoutStatus == 2) {
2041                         self.v_angle = self.lastV_angle;
2042                         self.angles = self.lastV_angle;
2043                         self.fixangle = TRUE;
2044                 }
2045
2046                 if (self.deadflag != DEAD_NO)
2047                 {
2048                         float button_pressed, force_respawn;
2049                         player_anim();
2050                         button_pressed = (self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE);
2051                         force_respawn = (g_lms || cvar("g_forced_respawn"));
2052                         if (self.deadflag == DEAD_DYING)
2053                         {
2054                                 if(force_respawn)
2055                                         self.deadflag = DEAD_RESPAWNING;
2056                                 else if(!button_pressed)
2057                                         self.deadflag = DEAD_DEAD;
2058                         }
2059                         else if (self.deadflag == DEAD_DEAD)
2060                         {
2061                                 if(button_pressed)
2062                                         self.deadflag = DEAD_RESPAWNABLE;
2063                         }
2064                         else if (self.deadflag == DEAD_RESPAWNABLE)
2065                         {
2066                                 if(!button_pressed)
2067                                         self.deadflag = DEAD_RESPAWNING;
2068                         }
2069                         else if (self.deadflag == DEAD_RESPAWNING)
2070                         {
2071                                 if(time > self.death_time)
2072                                 {
2073                                         self.death_time = time + 1; // only retry once a second
2074                                         respawn();
2075                                 }
2076                         }
2077                         ShowRespawnCountdown();
2078                         return;
2079                 }
2080
2081                 if(g_lms && !self.deadflag && cvar("g_lms_campcheck_interval"))
2082                 {
2083                         vector dist;
2084
2085                         // calculate player movement (in 2 dimensions only, so jumping on one spot doesn't count as movement)
2086                         dist = self.oldorigin - self.origin;
2087                         dist_z = 0;
2088                         self.lms_traveled_distance += fabs(vlen(dist));
2089
2090                         if((cvar("g_campaign") && !campaign_bots_may_start) || (time < restart_countdown))
2091                         {
2092                                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval")*2;
2093                                 self.lms_traveled_distance = 0;
2094                         }
2095
2096                         if(time > self.lms_nextcheck)
2097                         {
2098                                 //sprint(self, "distance: ", ftos(self.lms_traveled_distance), "\n");
2099                                 if(self.lms_traveled_distance < cvar("g_lms_campcheck_distance"))
2100                                 {
2101                                         centerprint(self, cvar_string("g_lms_campcheck_message"));
2102                                         // FIXME KadaverJack: gibbing player here causes playermodel to bounce around, instead of eye.md3
2103                                         // I wasn't able to find out WHY that happens, so I put a workaround in place that shall prevent players from being gibbed :(
2104                                         Damage(self, self, self, bound(0, cvar("g_lms_campcheck_damage"), self.health + self.armorvalue * cvar("g_balance_armor_blockpercent") + 5), DEATH_CAMP, self.origin, '0 0 0');
2105                                 }
2106                                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval");
2107                                 self.lms_traveled_distance = 0;
2108                         }
2109                 }
2110
2111                 if (self.BUTTON_CROUCH && !self.hook.state)
2112                 {
2113                         if (!self.crouch)
2114                         {
2115                                 self.crouch = TRUE;
2116                                 self.view_ofs = PL_CROUCH_VIEW_OFS;
2117                                 setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX);
2118                                 player_setanim(self.anim_duck, FALSE, TRUE, TRUE);
2119                         }
2120                 }
2121                 else
2122                 {
2123                         if (self.crouch)
2124                         {
2125                                 tracebox(self.origin, PL_MIN, PL_MAX, self.origin, FALSE, self);
2126                                 if (!trace_startsolid)
2127                                 {
2128                                         self.crouch = FALSE;
2129                                         self.view_ofs = PL_VIEW_OFS;
2130                                         setsize (self, PL_MIN, PL_MAX);
2131                                 }
2132                         }
2133                 }
2134
2135                 FixPlayermodel();
2136
2137                 GrapplingHookFrame();
2138
2139                 W_WeaponFrame();
2140
2141                 player_powerups();
2142                 player_regen();
2143                 player_anim();
2144
2145                 if (g_minstagib)
2146                         minstagib_ammocheck();
2147
2148                 ctf_setstatus();
2149                 kh_setstatus();
2150
2151                 //self.angles_y=self.v_angle_y + 90;   // temp
2152
2153                 //if (TetrisPreFrame()) return;
2154         } else if(gameover) {
2155                 if (intermission_running)
2156                         IntermissionThink ();   // otherwise a button could be missed between
2157                 return;
2158         } else if(self.classname == "observer") {
2159                 ObserverThink();
2160         } else if(self.classname == "spectator") {
2161                 SpectatorThink();
2162         }
2163
2164         if(!zoomstate_set)
2165                 SetZoomState(self.BUTTON_ZOOM || (self.BUTTON_ATCK2 && self.weapon == WEP_NEX));
2166
2167         float oldspectatee_status;
2168         oldspectatee_status = self.spectatee_status;
2169         if(self.classname == "spectator")
2170                 self.spectatee_status = num_for_edict(self.enemy);
2171         else if(self.classname == "observer")
2172                 self.spectatee_status = num_for_edict(self);
2173         else
2174                 self.spectatee_status = 0;
2175         if(self.spectatee_status != oldspectatee_status)
2176         {
2177                 msg_entity = self;
2178                 WriteByte(MSG_ONE, SVC_TEMPENTITY);
2179                 WriteByte(MSG_ONE, TE_CSQC_SPECTATING);
2180                 WriteByte(MSG_ONE, self.spectatee_status);
2181                 if(g_race)
2182                         race_InitSpectator();
2183         }
2184 }
2185
2186
2187 /*
2188 =============
2189 PlayerPostThink
2190
2191 Called every frame for each client after the physics are run
2192 =============
2193 */
2194 .float idlekick_lasttimeleft;
2195 .float race_penalty;
2196 .float race_penalty_nagged;
2197 void PlayerPostThink (void)
2198 {
2199         // Savage: Check for nameless players
2200         if (strlen(self.netname) < 1) {
2201                 self.netname = "Player";
2202                 stuffcmd(self, "seta _cl_name Player\n");
2203         }
2204
2205         if(sv_maxidle)
2206         {
2207                 float timeleft;
2208                 timeleft = ceil(sv_maxidle - (time - self.parm_idlesince));
2209                 if(timeleft <= 0)
2210                 {
2211                         bprint("^3", self.netname, "^3 was kicked for idling.\n");
2212                         announce(self, "announcer/robotic/terminated.ogg");
2213                         dropclient(self);
2214                         return;
2215                 }
2216                 else if(timeleft <= 10)
2217                 {
2218                         if(timeleft != self.idlekick_lasttimeleft)
2219                         {
2220                                 centerprint_atprio(self, CENTERPRIO_IDLEKICK, strcat("^3Stop idling!\n^3Disconnecting in ", ftos(timeleft), "..."));
2221                                 announce(self, strcat("announcer/robotic/", ftos(timeleft), ".ogg"));
2222                         }
2223                 }
2224                 else
2225                 {
2226                         centerprint_expire(self, CENTERPRIO_IDLEKICK);
2227                 }
2228                 self.idlekick_lasttimeleft = timeleft;
2229         }
2230
2231         if(self.classname == "player") {
2232                 CheckRules_Player();
2233                 UpdateChatBubble();
2234                 UpdateTeamBubble();
2235                 if (self.impulse)
2236                         ImpulseCommands();
2237                 if (intermission_running)
2238                         return;         // intermission or finale
2239
2240                 //PrintWelcomeMessage(self);
2241                 //if (TetrisPostFrame()) return;
2242
2243                 // restart countdown
2244                 if (restart_countdown) {
2245                         if(time < restart_countdown) {
2246                                 if (!cvar("sv_ready_restart_after_countdown"))
2247                                 {
2248                                         if(self.movement != '0 0 0' && g_race && !g_race_qualifying)
2249                                         {
2250                                                 if(time < restart_countdown - 2)
2251                                                 {
2252                                                         if(!self.race_penalty_nagged)
2253                                                         {
2254                                                                 centerprint_atprio(self, CENTERPRIO_IDLEKICK, "^1DO NOT MOVE DURING THE COUNTDOWN.");
2255                                                                 self.race_penalty_nagged = 1;
2256                                                         }
2257                                                 }
2258                                                 else if(!self.race_penalty)
2259                                                 {
2260                                                         centerprint_atprio(self, CENTERPRIO_IDLEKICK, "^1FIVE SECONDS PENALTY.");
2261                                                         self.race_penalty = time + 5;
2262                                                 }
2263                                         }
2264                                         self.movetype = MOVETYPE_NONE;
2265                                         self.velocity = '0 0 0';
2266                                         self.avelocity = '0 0 0';
2267                                         self.movement = '0 0 0';
2268                                 }
2269                         }
2270                         else if (time < self.race_penalty)
2271                         {
2272                                 self.movetype = MOVETYPE_NONE;
2273                                 self.velocity = '0 0 0';
2274                                 self.avelocity = '0 0 0';
2275                                 self.movement = '0 0 0';
2276                         }
2277                         else
2278                         {
2279                                 //allow the player to move again if sv_ready_restart_after_countdown is not used and countdown is over
2280                                 if (!cvar("sv_ready_restart_after_countdown"))
2281                                 {
2282                                         if(self.movetype == MOVETYPE_NONE)
2283                                         {
2284                                                 self.movetype = MOVETYPE_WALK;
2285                                         }
2286                                         self.race_penalty = 0;
2287                                         self.race_penalty_nagged = 0;
2288                                 }
2289                         }
2290                 }
2291
2292         } else if (self.classname == "observer") {
2293                 //do nothing
2294         } else if (self.classname == "spectator") {
2295                 //do nothing
2296         }
2297
2298         /*
2299         float i;
2300         for(i = 0; i < 1000; ++i)
2301         {
2302                 vector end;
2303                 end = self.origin + '0 0 1024' + 512 * randomvec();
2304                 tracebox(self.origin, self.mins, self.maxs, end, MOVE_NORMAL, self);
2305                 if(trace_fraction < 1)
2306                 if(!(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
2307                 {
2308                         print("I HIT SOLID: ", vtos(self.origin), " -> ", vtos(end), "\n");
2309                         break;
2310                 }
2311         }
2312         */
2313
2314         Arena_Warmup();
2315 }