data/qcsrc/server/cl_client.qc

   1 void info_player_start (void)
   2 {
   3         info_player_deathmatch();
   4 }
   5
   6 void info_player_deathmatch (void)
   7 {
   8         self.classname = "info_player_deathmatch";
   9         relocate_spawnpoint();
  10 }
  11
  12 float spawn_allbad;
  13 float spawn_allgood;
  14 entity Spawn_FilterOutBadSpots(entity firstspot, entity playerlist, float mindist, float teamcheck)
  15 {
  16         local entity spot, player, nextspot, previousspot, newfirstspot;
  17         local float pcount;
  18         spot = firstspot;
  19         newfirstspot = world;
  20         previousspot = world;
  21         spawn_allgood = TRUE;
  22         spawn_allbad = TRUE;
  23         while (spot)
  24         {
  25                 nextspot = spot.chain;
  26                 // count team mismatches as bad spots
  27
  28                 local float spotactive;
  29                 spotactive = 1;
  30
  31                 // filter out spots for assault
  32                 if(spot.target != "") {
  33                         local entity ent;
  34                         ent = find(world, targetname, spot.target);
  35                         while(ent) {
  36                                 if(ent.classname == "target_objective")
  37                                         if(ent.health < 0 || ent.health >= ASSAULT_VALUE_INACTIVE)
  38                                                 spotactive = 0;
  39                                 ent = find(ent, targetname, spot.target);
  40                         }
  41                 }
  42
  43                 if (spot.team == teamcheck && spotactive > 0)
  44                 {
  45                         pcount = 0;
  46                         player = playerlist;
  47                         while (player)
  48                         {
  49                                 if (player != self)
  50                                 if (vlen(player.origin - spot.origin) < mindist)
  51                                         pcount = pcount + 1;
  52                                 player = player.chain;
  53                         }
  54                         if (!pcount)
  55                         {
  56                                 spawn_allbad = FALSE;
  57                                 if (newfirstspot)
  58                                         previousspot.chain = spot;
  59                                 else
  60                                         newfirstspot = spot;
  61                                 previousspot = spot;
  62                                 spot.chain = world;
  63                         }
  64                         else
  65                                 spawn_allgood = FALSE;
  66                 }
  67                 spot = nextspot;
  68         }
  69         // if we couldn't find ANY good points, return the original list
  70         if (!newfirstspot)
  71                 newfirstspot = firstspot;
  72         return newfirstspot;
  73 }
  74
  75 entity Spawn_RandomPoint(entity firstspot)
  76 {
  77         local entity spot;
  78         local float numspots;
  79         // count number of spots
  80         numspots = 0;
  81         spot = firstspot;
  82         while (spot)
  83         {
  84                 numspots = numspots + 1;
  85                 spot = spot.chain;
  86         }
  87         // pick a random one
  88         numspots = numspots * random();
  89         spot = firstspot;
  90         while (spot.chain && numspots >= 1)
  91         {
  92                 numspots = numspots - 1;
  93                 spot = spot.chain;
  94         }
  95         return spot;
  96 }
  97
  98 entity Spawn_FurthestPoint(entity firstspot, entity playerlist)
  99 {
 100         local entity best, spot, player;
 101         local float bestrating, rating;
 102         best = world;
 103         bestrating = -1000000;
 104         spot = firstspot;
 105         while (spot)
 106         {
 107                 rating = 1000000000;
 108                 player = playerlist;
 109                 while (player)
 110                 {
 111                         if (player != self)
 112                                 rating = min(rating, vlen(player.origin - spot.origin));
 113                         player = player.chain;
 114                 }
 115                 rating = rating + random() * 16;
 116                 if (bestrating < rating)
 117                 {
 118                         best = spot;
 119                         bestrating = rating;
 120                 }
 121                 spot = spot.chain;
 122         }
 123         return best;
 124 }
 125
 126 /*
 127 =============
 128 SelectSpawnPoint
 129
 130 Finds a point to respawn
 131 =============
 132 */
 133 entity SelectSpawnPoint (float anypoint)
 134 {
 135         local float teamcheck;
 136         local entity spot, firstspot, playerlist;
 137
 138         spot = find (world, classname, "testplayerstart");
 139         if (spot)
 140                 return spot;
 141
 142         teamcheck = 0;
 143
 144         if(!anypoint && (g_ctf || g_assault))
 145                 teamcheck = self.team;
 146
 147         // get the list of players
 148         playerlist = findchain(classname, "player");
 149         // get the entire list of spots
 150         firstspot = findchain(classname, "info_player_deathmatch");
 151         // filter out the bad ones
 152         // (note this returns the original list if none survived)
 153         firstspot = Spawn_FilterOutBadSpots(firstspot, playerlist, 100, teamcheck);
 154
 155         // there is 50/50 chance of choosing a random spot or the furthest spot
 156         // (this means that roughly every other spawn will be furthest, so you
 157         // usually won't get fragged at spawn twice in a row)
 158         if (arena_roundbased)
 159         {
 160                 firstspot = Spawn_FilterOutBadSpots(firstspot, playerlist, 800, teamcheck);
 161                 spot = Spawn_RandomPoint(firstspot);
 162         }
 163         else if (random() > 0.5 || spawn_allbad || spawn_allgood)
 164                 spot = Spawn_RandomPoint(firstspot);
 165         else
 166                 spot = Spawn_FurthestPoint(firstspot, playerlist);
 167
 168         if (!spot)
 169         {
 170                 if(cvar("spawn_debug"))
 171                         GotoNextMap();
 172                 else
 173                         error ("PutClientInServer: no start points on level");
 174         }
 175
 176         return spot;
 177 }
 178
 179 /*
 180 =============
 181 CheckPlayerModel
 182
 183 Checks if the argument string can be a valid playermodel.
 184 Returns a valid one in doubt.
 185 =============
 186 */
 187 string FallbackPlayerModel = "models/player/marine.zym";
 188 string CheckPlayerModel(string plyermodel) {
 189         if(strlen(plyermodel) < 4)
 190                 return FallbackPlayerModel;
 191         if( substring(plyermodel,0,14) != "models/player/")
 192                 return FallbackPlayerModel;
 193         else if(cvar("sv_servermodelsonly"))
 194         {
 195                 if(substring(plyermodel,strlen(plyermodel)-4,4) != ".zym")
 196                 if(substring(plyermodel,strlen(plyermodel)-4,4) != ".dpm")
 197                 if(substring(plyermodel,strlen(plyermodel)-4,4) != ".md3")
 198                 if(substring(plyermodel,strlen(plyermodel)-4,4) != ".psk")
 199                         return FallbackPlayerModel;
 200                 if(!fexists(plyermodel))
 201                         return FallbackPlayerModel;
 202         }
 203         return plyermodel;
 204 }
 205
 206 /*
 207 =============
 208 Client_customizeentityforclient
 209
 210 LOD reduction
 211 =============
 212 */
 213 float Client_customizeentityforclient()
 214 {
 215 #ifdef ALLOW_VARIABLE_LOD
 216         // self: me
 217         // other: the player viewing me
 218         float distance;
 219         float f;
 220
 221         if(self.flags & FL_NOTARGET) // we don't need LOD for spectators
 222                 return TRUE;
 223
 224         if(other.cvar_cl_playerdetailreduction <= 0)
 225         {
 226                 if(other.cvar_cl_playerdetailreduction <= -2)
 227                         self.modelindex = self.modelindex_lod2;
 228                 else if(other.cvar_cl_playerdetailreduction <= -1)
 229                         self.modelindex = self.modelindex_lod1;
 230                 else
 231                         self.modelindex = self.modelindex_lod0;
 232         }
 233         else
 234         {
 235                 distance = vlen(self.origin - other.origin);
 236                 f = (distance + 100.0) * other.cvar_cl_playerdetailreduction;
 237                 if(f > 10000)
 238                         self.modelindex = self.modelindex_lod2;
 239                 else if(f > 5000)
 240                         self.modelindex = self.modelindex_lod1;
 241                 else
 242                         self.modelindex = self.modelindex_lod0;
 243         }
 244 #endif
 245
 246         return TRUE;
 247 }
 248
 249 void UpdatePlayerSounds();
 250 void setmodel_lod(entity e, string modelname)
 251 {
 252 #ifdef ALLOW_VARIABLE_LOD
 253         string s;
 254
 255         // FIXME: this only supports 3-letter extensions
 256         s = strcat(substring(modelname, 0, strlen(modelname) - 4), "_1", substring(modelname, 0, strlen(modelname) - 4));
 257         if(fexists(s))
 258         {
 259                 precache_model(s);
 260                 setmodel(e, s); // players have high precision
 261                 self.modelindex_lod1 = self.modelindex;
 262         }
 263         else
 264                 self.modelindex_lod1 = -1;
 265
 266         s = strcat(substring(modelname, 0, strlen(modelname) - 4), "_2", substring(modelname, 0, strlen(modelname) - 4));
 267         if(fexists(s))
 268         {
 269                 precache_model(s);
 270                 setmodel(e, s); // players have high precision
 271                 self.modelindex_lod2 = self.modelindex;
 272         }
 273         else
 274                 self.modelindex_lod2 = -1;
 275
 276         precache_model(modelname);
 277         setmodel(e, modelname); // players have high precision
 278         self.modelindex_lod0 = self.modelindex;
 279
 280         if(self.modelindex_lod1 < 0)
 281                 self.modelindex_lod1 = self.modelindex;
 282
 283         if(self.modelindex_lod2 < 0)
 284                 self.modelindex_lod2 = self.modelindex;
 285 #else
 286         precache_model(modelname);
 287         setmodel(e, modelname); // players have high precision
 288 #endif
 289         player_setupanimsformodel();
 290         UpdatePlayerSounds();
 291 }
 292
 293 /*
 294 =============
 295 PutObserverInServer
 296
 297 putting a client as observer in the server
 298 =============
 299 */
 300 void PutObserverInServer (void)
 301 {
 302         entity  spot;
 303         spot = SelectSpawnPoint (TRUE);
 304         RemoveGrapplingHook(self); // Wazat's Grappling Hook
 305
 306         if(clienttype(self) == CLIENTTYPE_REAL)
 307         {
 308                 msg_entity = self;
 309                 WriteByte(MSG_ONE, SVC_SETVIEW);
 310                 WriteEntity(MSG_ONE, self);
 311         }
 312
 313         DropAllRunes(self);
 314         kh_Key_DropAll(self, TRUE);
 315
 316         if(self.flagcarried)
 317                 DropFlag(self.flagcarried);
 318
 319         WaypointSprite_PlayerDead();
 320
 321         DistributeFragsAmongTeam(self, self.team, 1);
 322
 323         if(self.frags <= 0 && self.frags > -666 && g_lms && self.killcount != -666)
 324                 bprint ("^4", self.netname, "^4 has no more lives left\n");
 325         else if(self.killcount != -666)
 326                 bprint ("^4", self.netname, "^4 is spectating now\n");
 327
 328         self.classname = "observer";
 329         self.health = -666;
 330         self.takedamage = DAMAGE_NO;
 331         self.solid = SOLID_NOT;
 332         self.movetype = MOVETYPE_NOCLIP;
 333         self.flags = FL_CLIENT | FL_NOTARGET;
 334         self.armorvalue = 666;
 335         self.effects = 0;
 336         self.armorvalue = cvar("g_balance_armor_start");
 337         self.pauserotarmor_finished = 0;
 338         self.pauserothealth_finished = 0;
 339         self.pauseregen_finished = 0;
 340         self.damageforcescale = 0;
 341         self.death_time = 0;
 342         self.dead_frame = 0;
 343         self.deaths = 0;
 344         self.alpha = 0;
 345         self.scale = 0;
 346         self.fade_time = 0;
 347         self.pain_frame = 0;
 348         self.pain_finished = 0;
 349         self.strength_finished = 0;
 350         self.invincible_finished = 0;
 351         self.pushltime = 0;
 352         self.think = SUB_Null;
 353         self.nextthink = 0;
 354         self.hook_time = 0;
 355         self.runes = 0;
 356         self.deadflag = DEAD_NO;
 357         self.angles = spot.angles;
 358         self.angles_z = 0;
 359         self.fixangle = TRUE;
 360         self.crouch = FALSE;
 361
 362         self.view_ofs = PL_VIEW_OFS;
 363         setorigin (self, spot.origin);
 364         setsize (self, '0 0 0', '0 0 0');
 365         self.oldorigin = self.origin;
 366         self.items = 0;
 367         self.model = "";
 368         self.modelindex = 0;
 369         self.weapon = 0;
 370         self.weaponmodel = "";
 371         self.weaponentity = world;
 372         self.killcount = -666;
 373         self.velocity = '0 0 0';
 374         self.avelocity = '0 0 0';
 375         self.punchangle = '0 0 0';
 376         self.punchvector = '0 0 0';
 377         self.oldvelocity = self.velocity;
 378         self.customizeentityforclient = Client_customizeentityforclient;
 379
 380         if(g_arena)
 381         {
 382                 if(self.frags != -2)
 383                 {
 384                         Spawnqueue_Insert(self);
 385                 }
 386                 else
 387                 {
 388                         Spawnqueue_Unmark(self);
 389                         Spawnqueue_Remove(self);
 390                 }
 391         }
 392         else if(!g_lms)
 393                 self.frags = -666;
 394 }
 395
 396 float RestrictSkin(float s)
 397 {
 398         if(!teams_matter)
 399                 return s;
 400         if(s == 6)
 401                 return 6;
 402         return math_mod(s, 3);
 403 }
 404
 405 /*
 406 =============
 407 PutClientInServer
 408
 409 Called when a client spawns in the server
 410 =============
 411 */
 412 void PutClientInServer (void)
 413 {
 414         if(clienttype(self) == CLIENTTYPE_BOT)
 415         {
 416                 self.classname = "player";
 417         }
 418         else if(clienttype(self) == CLIENTTYPE_REAL)
 419         {
 420                 msg_entity = self;
 421                 WriteByte(MSG_ONE, SVC_SETVIEW);
 422                 WriteEntity(MSG_ONE, self);
 423         }
 424
 425         // player is dead and becomes observer
 426         if(g_lms && self.frags < 1)
 427                 self.classname = "observer";
 428
 429         if(g_arena)
 430         if(!self.spawned)
 431                 self.classname = "observer";
 432
 433         if(self.classname == "player") {
 434                 entity  spot;
 435
 436                 spot = SelectSpawnPoint (FALSE);
 437
 438                 RemoveGrapplingHook(self); // Wazat's Grappling Hook
 439
 440                 self.classname = "player";
 441                 self.iscreature = TRUE;
 442                 self.movetype = MOVETYPE_WALK;
 443                 self.solid = SOLID_SLIDEBOX;
 444                 self.flags = FL_CLIENT;
 445                 self.takedamage = DAMAGE_AIM;
 446                 self.effects = 0;
 447                 self.air_finished = time + 12;
 448                 self.dmg = 2;
 449
 450                 self.ammo_shells = start_ammo_shells;
 451                 self.ammo_nails = start_ammo_nails;
 452                 self.ammo_rockets = start_ammo_rockets;
 453                 self.ammo_cells = start_ammo_cells;
 454                 self.health = start_health;
 455                 self.armorvalue = start_armorvalue;
 456                 self.items = start_items;
 457                 self.switchweapon = start_switchweapon;
 458                 self.weapon = 0;
 459                 self.jump_interval = time;
 460
 461                 self.spawnshieldtime = time + cvar("g_spawnshieldtime");
 462                 self.pauserotarmor_finished = time + cvar("g_balance_pause_armor_rot_spawn");
 463                 self.pauserothealth_finished = time + cvar("g_balance_pause_health_rot_spawn");
 464                 self.pauseregen_finished = time + cvar("g_balance_pause_health_regen_spawn");
 465                 self.damageforcescale = 2;
 466                 self.death_time = 0;
 467                 self.dead_frame = 0;
 468                 self.alpha = 0;
 469                 self.scale = 0;
 470                 self.fade_time = 0;
 471                 self.pain_frame = 0;
 472                 self.pain_finished = 0;
 473                 self.strength_finished = 0;
 474                 self.invincible_finished = 0;
 475                 self.pushltime = 0;
 476                 //self.speed_finished = 0;
 477                 //self.slowmo_finished = 0;
 478                 // players have no think function
 479                 self.think = SUB_Null;
 480                 self.nextthink = 0;
 481                 self.hook_time = 0;
 482
 483                 self.runes = 0;
 484
 485                 self.deadflag = DEAD_NO;
 486
 487                 self.angles = spot.angles;
 488
 489                 self.angles_z = 0; // never spawn tilted even if the spot says to
 490                 self.fixangle = TRUE; // turn this way immediately
 491                 self.velocity = '0 0 0';
 492                 self.avelocity = '0 0 0';
 493                 self.punchangle = '0 0 0';
 494                 self.punchvector = '0 0 0';
 495                 self.oldvelocity = self.velocity;
 496
 497                 self.viewzoom = 0.6;
 498                 self.has_zoomed = 0;
 499
 500                 self.customizeentityforclient = Client_customizeentityforclient;
 501
 502                 if(cvar("sv_defaultcharacter") == 1) {
 503                         local string defaultmodel;
 504                         defaultmodel = cvar_string("sv_defaultplayermodel");
 505                         setmodel_lod (self, defaultmodel);
 506                         self.skin = stof(cvar_string("sv_defaultplayerskin"));
 507                 } else {
 508                         self.playermodel = CheckPlayerModel(self.playermodel);
 509                         setmodel_lod (self, self.playermodel);
 510                         self.skin = RestrictSkin(stof(self.playerskin));
 511                 }
 512                 if(!teams_matter)
 513                         if(strlen(cvar_string("sv_defaultplayercolors")))
 514                                 setcolor(self, cvar("sv_defaultplayercolors"));
 515
 516                 self.crouch = FALSE;
 517                 self.view_ofs = PL_VIEW_OFS;
 518                 setsize (self, PL_MIN, PL_MAX);
 519                 self.spawnorigin = spot.origin;
 520                 setorigin (self, spot.origin + '0 0 1' * (1 - self.mins_z - 24));
 521                 // don't reset back to last position, even if new position is stuck in solid
 522                 self.oldorigin = self.origin;
 523
 524                 if(g_arena)
 525                 {
 526                         Spawnqueue_Remove(self);
 527                         Spawnqueue_Mark(self);
 528                 }
 529
 530                 self.event_damage = PlayerDamage;
 531
 532                 self.bot_attack = TRUE;
 533
 534                 self.statdraintime = time + 5;
 535                 self.button0 = self.button1 = self.button2 = self.button3 = 0;
 536
 537                 if(self.killcount == -666) {
 538                         self.killcount = 0;
 539                         if(!g_arena)
 540                         if(!g_lms)
 541                                 self.frags = 0;
 542                 }
 543
 544                 self.cnt = WEP_LASER;
 545                 self.nixnex_lastchange_id = -1;
 546
 547                 CL_SpawnWeaponentity();
 548                 self.alpha = default_player_alpha;
 549                 self.colormod = '1 1 1' * cvar("g_player_brightness");
 550                 self.exteriorweaponentity.alpha = default_weapon_alpha;
 551
 552                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval")*2;
 553                 self.lms_traveled_distance = 0;
 554
 555                 if(cvar("spawn_debug"))
 556                 {
 557                         sprint(self, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 558                         remove(spot);   // usefull for checking if there are spawnpoints, that let drop through the floor
 559                 }
 560
 561                 //stuffcmd(self, "chase_active 0");
 562                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
 563
 564                 if (cvar("g_spawnsound"))
 565                         sound (self, CHAN_AUTO, "misc/spawn.wav", 1, ATTN_NORM);
 566
 567                 if(g_assault) {
 568                         if(self.team == assault_attacker_team)
 569                                 centerprint(self, "You are attacking!\n");
 570                         else
 571                                 centerprint(self, "You are defending!\n");
 572                 }
 573
 574         } else if(self.classname == "observer") {
 575                 PutObserverInServer ();
 576         }
 577 }
 578
 579 /*
 580 =============
 581 SetNewParms
 582 =============
 583 */
 584 void SetNewParms (void)
 585 {
 586
 587 }
 588
 589 /*
 590 =============
 591 SetChangeParms
 592 =============
 593 */
 594 void SetChangeParms (void)
 595 {
 596
 597 }
 598
 599 /*
 600 =============
 601 ClientKill
 602
 603 Called when a client types 'kill' in the console
 604 =============
 605 */
 606 void ClientKill (void)
 607 {
 608         Damage(self, self, self, 100000, DEATH_KILL, self.origin, '0 0 0');
 609 }
 610
 611 void FixClientCvars(entity e)
 612 {
 613         float t;
 614         // send prediction settings to the client
 615         stuffcmd(e, "\nin_bindmap 0 0\n");
 616         stuffcmd(e, strcat("cl_gravity ", ftos(cvar("sv_gravity")), "\n"));
 617         stuffcmd(e, strcat("cl_movement_accelerate ", ftos(cvar("sv_accelerate")), "\n"));
 618         stuffcmd(e, strcat("cl_movement_friction ", ftos(cvar("sv_friction")), "\n"));
 619         stuffcmd(e, strcat("cl_movement_maxspeed ", ftos(cvar("sv_maxspeed")), "\n"));
 620         stuffcmd(e, strcat("cl_movement_airaccelerate ", ftos(cvar("sv_airaccelerate")), "\n"));
 621         stuffcmd(e, strcat("cl_movement_maxairspeed ", ftos(cvar("sv_maxairspeed")), "\n"));
 622         stuffcmd(e, strcat("cl_movement_stopspeed ", ftos(cvar("sv_stopspeed")), "\n"));
 623         stuffcmd(e, strcat("cl_movement_jumpvelocity ", ftos(cvar("sv_jumpvelocity")), "\n"));
 624         stuffcmd(e, strcat("cl_movement_stepheight ", ftos(cvar("sv_stepheight")), "\n"));
 625         stuffcmd(e, strcat("set cl_movement_friction_on_land ", ftos(cvar("sv_friction_on_land")), "\n"));
 626         stuffcmd(e, strcat("set cl_movement_airaccel_qw ", ftos(cvar("sv_airaccel_qw")), "\n"));
 627         stuffcmd(e, strcat("set cl_movement_airaccel_sideways_friction ", ftos(cvar("sv_airaccel_sideways_friction")), "\n"));
 628         stuffcmd(e, "cl_movement_edgefriction 1\n");
 629
 630         // notify about available teams
 631         if(teamplay)
 632         {
 633                 CheckAllowedTeams(e);
 634                 t = 0; if(c1 >= 0) t |= 1; if(c2 >= 0) t |= 2; if(c3 >= 0) t |= 4; if(c4 >= 0) t |= 8;
 635                 stuffcmd(e, strcat("set _teams_available ", ftos(t), "\n"));
 636         }
 637         else
 638                 stuffcmd(e, "set _teams_available 0\n");
 639 }
 640
 641 /*
 642 =============
 643 ClientConnect
 644
 645 Called when a client connects to the server
 646 =============
 647 */
 648 string ColoredTeamName(float t);
 649 //void dom_player_join_team(entity pl);
 650 void ClientConnect (void)
 651 {
 652         local string s;
 653         float wep;
 654
 655         if(Ban_IsClientBanned(self))
 656         {
 657                 s = strcat("^1NOTE:^7 banned client ", self.netaddress, " just tried to enter\n");
 658                 dropclient(self);
 659                 bprint(s);
 660                 return;
 661         }
 662
 663         self.classname = "player_joining";
 664         self.flags = self.flags | FL_CLIENT;
 665         self.version_nagtime = time + 10 + random() * 10;
 666
 667         if(player_count<0)
 668         {
 669                 dprint("BUG player count is lower than zero, this cannot happen!\n");
 670                 player_count = 0;
 671         }
 672
 673         bot_clientconnect();
 674
 675         //if(g_domination)
 676         //      dom_player_join_team(self);
 677
 678         //JoinBestTeam(self, FALSE);
 679
 680         if((cvar("sv_spectate") == 1 && !g_lms) || cvar("g_campaign")) {
 681                 self.classname = "observer";
 682         } else {
 683                 self.classname = "player";
 684                 campaign_bots_may_start = 1;
 685         }
 686
 687         self.playerid = (playerid_last = playerid_last + 1);
 688         if(cvar("sv_eventlog"))
 689         {
 690                 if(clienttype(self) == CLIENTTYPE_REAL)
 691                         s = "player";
 692                 else
 693                         s = "bot";
 694                 GameLogEcho(strcat(":join:", ftos(self.playerid), ":", s, ":", self.netname), TRUE);
 695                 s = strcat(":team:", ftos(self.playerid), ":");
 696                 s = strcat(s, ftos(self.team));
 697                 GameLogEcho(s, FALSE);
 698         }
 699
 700         //stuffcmd(self, "set tmpviewsize $viewsize \n");
 701
 702         bprint ("^4",self.netname);
 703         bprint ("^4 connected");
 704
 705         if(g_domination || g_ctf)
 706         {
 707                 bprint(" and joined the ");
 708                 bprint(ColoredTeamName(self.team));
 709         }
 710
 711         bprint("\n");
 712
 713         self.welcomemessage_time = 0;
 714
 715         stuffcmd(self, strcat("exec maps/", mapname, ".cfg\n"));
 716         // TODO: is this being used for anything else than cd tracks?
 717         // Remember: SVC_CDTRACK exists. Maybe it should be used.
 718
 719         FixClientCvars(self);
 720
 721         // waypoint sprites
 722         WaypointSprite_InitClient(self);
 723
 724         // Wazat's grappling hook
 725         SetGrappleHookBindings();
 726
 727         // get autoswitch state from player when he toggles it
 728         stuffcmd(self, "alias autoswitch \"set cl_autoswitch $1 ; cmd autoswitch $1\"\n");
 729
 730         // get version info from player
 731         stuffcmd(self, "cmd clientversion $gameversion\n");
 732
 733         // send all weapon info strings
 734         stuffcmd(self, "register_bestweapon clear\n"); // clear the Quake stuff
 735         wep = WEP_FIRST;
 736         while (wep <= WEP_LAST)
 737         {
 738                 weapon_action(wep, WR_REGISTER);
 739                 wep = wep + 1;
 740         }
 741
 742         // get other cvars from player
 743         GetCvars(0);
 744
 745         // set cvar for team scoreboard
 746         if (teams_matter)
 747         {
 748                 local float t;
 749                 t = cvar("teamplay");
 750                 // we have to stuff the correct teamplay value because if this is a listen server, this changes the teamplay mode of the server itself, which is bad
 751                 stuffcmd(self, strcat("set teamplay ", ftos(t), "\n"));
 752         }
 753         else
 754                 stuffcmd(self, "set teamplay 0\n");
 755
 756         if(g_lms)
 757         {
 758                 self.frags = LMS_NewPlayerLives();
 759                 if(!self.frags)
 760                         self.frags = -666;
 761         }
 762         else if(g_arena)
 763         {
 764                 self.classname = "observer";
 765                 Spawnqueue_Insert(self);
 766         }
 767
 768         bot_relinkplayerlist();
 769
 770         self.jointime = time;
 771 }
 772
 773 /*
 774 =============
 775 ClientDisconnect
 776
 777 Called when a client disconnects from the server
 778 =============
 779 */
 780 void(entity e) DropFlag;
 781 .entity chatbubbleentity;
 782 .entity teambubbleentity;
 783 void ClientDisconnect (void)
 784 {
 785         float save;
 786         if(cvar("sv_eventlog"))
 787                 GameLogEcho(strcat(":part:", ftos(self.playerid)), FALSE);
 788         bprint ("^4",self.netname);
 789         bprint ("^4 disconnected\n");
 790
 791         if (self.chatbubbleentity)
 792         {
 793                 remove (self.chatbubbleentity);
 794                 self.chatbubbleentity = world;
 795         }
 796
 797         if (self.teambubbleentity)
 798         {
 799                 remove (self.teambubbleentity);
 800                 self.teambubbleentity = world;
 801         }
 802
 803         WaypointSprite_PlayerGone();
 804
 805         DropAllRunes(self);
 806         kh_Key_DropAll(self, TRUE);
 807
 808         if(self.flagcarried)
 809                 DropFlag(self.flagcarried);
 810
 811         DistributeFragsAmongTeam(self, self.team, 1);
 812
 813         save = self.flags;
 814         self.flags = self.flags - (self.flags & FL_CLIENT);
 815         bot_relinkplayerlist();
 816         self.flags = save;
 817
 818         // remove laserdot
 819         if(self.weaponentity)
 820                 if(self.weaponentity.lasertarget)
 821                         remove(self.weaponentity.lasertarget);
 822
 823         if(g_arena)
 824         {
 825                 Spawnqueue_Unmark(self);
 826                 Spawnqueue_Remove(self);
 827         }
 828
 829         // free cvars
 830         GetCvars(-1);
 831 }
 832
 833 .float buttonchat;
 834 void() ChatBubbleThink =
 835 {
 836         self.nextthink = time;
 837         if (!self.owner.modelindex || self.owner.chatbubbleentity != self)
 838         {
 839                 self.owner.chatbubbleentity = world;
 840                 remove(self);
 841                 return;
 842         }
 843         setorigin(self, self.owner.origin + '0 0 15' + self.owner.maxs_z * '0 0 1');
 844         if (self.owner.buttonchat && !self.owner.deadflag)
 845                 self.model = self.mdl;
 846         else
 847                 self.model = "";
 848 };
 849
 850 void() UpdateChatBubble =
 851 {
 852         if (!self.modelindex)
 853                 return;
 854         // spawn a chatbubble entity if needed
 855         if (!self.chatbubbleentity)
 856         {
 857                 self.chatbubbleentity = spawn();
 858                 self.chatbubbleentity.owner = self;
 859                 self.chatbubbleentity.exteriormodeltoclient = self;
 860                 self.chatbubbleentity.think = ChatBubbleThink;
 861                 self.chatbubbleentity.nextthink = time;
 862                 setmodel(self.chatbubbleentity, "models/misc/chatbubble.spr"); // precision set below
 863                 setorigin(self.chatbubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
 864                 self.chatbubbleentity.mdl = self.chatbubbleentity.model;
 865                 self.chatbubbleentity.model = "";
 866                 self.chatbubbleentity.effects = EF_LOWPRECISION;
 867         }
 868 }
 869
 870
 871 void() TeamBubbleThink =
 872 {
 873         self.nextthink = time;
 874         if (!self.owner.modelindex || self.owner.teambubbleentity != self)
 875         {
 876                 self.owner.teambubbleentity = world;
 877                 remove(self);
 878                 return;
 879         }
 880 //      setorigin(self, self.owner.origin + '0 0 15' + self.owner.maxs_z * '0 0 1');  // bandwidth hog. setattachment does this now
 881         if (self.owner.buttonchat || self.owner.deadflag)
 882                 self.model = "";
 883         else
 884                 self.model = self.mdl;
 885
 886 };
 887
 888 float() TeamBubble_customizeentityforclient
 889 {
 890         return (self.owner != other && self.owner.team == other.team && other.killcount > -666);
 891 }
 892
 893 void() UpdateTeamBubble =
 894 {
 895         if (!self.modelindex || !cvar("teamplay"))
 896                 return;
 897         // spawn a teambubble entity if needed
 898         if (!self.teambubbleentity && cvar("teamplay"))
 899         {
 900                 self.teambubbleentity = spawn();
 901                 self.teambubbleentity.owner = self;
 902                 self.teambubbleentity.exteriormodeltoclient = self;
 903                 self.teambubbleentity.think = TeamBubbleThink;
 904                 self.teambubbleentity.nextthink = time;
 905                 setmodel(self.teambubbleentity, "models/misc/teambubble.spr"); // precision set below
 906 //              setorigin(self.teambubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
 907                 setorigin(self.teambubbleentity, self.teambubbleentity.origin + '0 0 15' + self.maxs_z * '0 0 1');
 908                 setattachment(self.teambubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
 909                 self.teambubbleentity.mdl = self.teambubbleentity.model;
 910                 self.teambubbleentity.model = self.teambubbleentity.mdl;
 911                 self.teambubbleentity.customizeentityforclient = TeamBubble_customizeentityforclient;
 912                 self.teambubbleentity.effects = EF_LOWPRECISION;
 913         }
 914 }
 915
 916 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
 917 // added to the model skins
 918 /*void() UpdateColorModHack =
 919 {
 920         local float c;
 921         c = self.clientcolors & 15;
 922         // LordHavoc: only bothering to support white, green, red, yellow, blue
 923              if (teamplay == 0) self.colormod = '0 0 0';
 924         else if (c ==  0) self.colormod = '1.00 1.00 1.00';
 925         else if (c ==  3) self.colormod = '0.10 1.73 0.10';
 926         else if (c ==  4) self.colormod = '1.73 0.10 0.10';
 927         else if (c == 12) self.colormod = '1.22 1.22 0.10';
 928         else if (c == 13) self.colormod = '0.10 0.10 1.73';
 929         else self.colormod = '1 1 1';
 930 };*/
 931
 932 void respawn(void)
 933 {
 934         CopyBody(1);
 935         PutClientInServer();
 936 }
 937
 938 void player_powerups (void)
 939 {
 940         if (g_minstagib)
 941         {
 942                 self.effects = EF_FULLBRIGHT;
 943                 if (self.items & IT_STRENGTH)
 944                 {
 945                         if (time > self.strength_finished)
 946                         {
 947                                 self.alpha = default_player_alpha;
 948                                 self.exteriorweaponentity.alpha = default_weapon_alpha;
 949                                 self.items = self.items - (self.items & IT_STRENGTH);
 950                                 sprint(self, "^3Invisibility has worn off\n");
 951                         }
 952                 }
 953                 else
 954                 {
 955                         if (time < self.strength_finished)
 956                         {
 957                                 self.alpha = cvar("g_minstagib_invis_alpha");
 958                                 self.exteriorweaponentity.alpha = cvar("g_minstagib_invis_alpha");
 959                                 self.items = self.items | IT_STRENGTH;
 960                                 sprint(self, "^3You are invisible\n");
 961                         }
 962                 }
 963
 964                 if (self.items & IT_INVINCIBLE)
 965                 {
 966                         if (time > self.invincible_finished)
 967                         {
 968                                 self.items = self.items - (self.items & IT_INVINCIBLE);
 969                                 sprint(self, "^3Speed has worn off\n");
 970                         }
 971                 }
 972                 else
 973                 {
 974                         if (time < self.invincible_finished)
 975                         {
 976                                 self.items = self.items | IT_INVINCIBLE;
 977                                 sprint(self, "^3You are on speed\n");
 978                         }
 979                 }
 980                 return;
 981         }
 982
 983         self.effects = self.effects - (self.effects & (EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT));
 984         if (self.items & IT_STRENGTH)
 985         {
 986                 self.effects = self.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
 987                 if (time > self.strength_finished)
 988                 {
 989                         self.items = self.items - (self.items & IT_STRENGTH);
 990                         sprint(self, "^3Strength has worn off\n");
 991                 }
 992         }
 993         else
 994         {
 995                 if (time < self.strength_finished)
 996                 {
 997                         self.items = self.items | IT_STRENGTH;
 998                         sprint(self, "^3Strength infuses your weapons with devastating power\n");
 999                 }
1000         }
1001         if (self.items & IT_INVINCIBLE)
1002         {
1003                 self.effects = self.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1004                 if (time > self.invincible_finished)
1005                 {
1006                         self.items = self.items - (self.items & IT_INVINCIBLE);
1007                         sprint(self, "^3Shield has worn off\n");
1008                 }
1009         }
1010         else
1011         {
1012                 if (time < self.invincible_finished)
1013                 {
1014                         self.items = self.items | IT_INVINCIBLE;
1015                         sprint(self, "^3Shield surrounds you\n");
1016                 }
1017         }
1018
1019         if (cvar("g_fullbrightplayers"))
1020                 self.effects = self.effects | EF_FULLBRIGHT;
1021
1022         // midair gamemode: damage only while in the air
1023         // if in midair mode, being on ground grants temporary invulnerability
1024         // (this is so that multishot weapon don't clear the ground flag on the
1025         // first damage in the frame, leaving the player vulnerable to the
1026         // remaining hits in the same frame)
1027         if (self.flags & FL_ONGROUND)
1028         if (g_midair)
1029                 self.spawnshieldtime = max(self.spawnshieldtime, time + cvar("g_midair_shieldtime"));
1030
1031         if (time < self.spawnshieldtime)
1032                 self.effects = self.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1033 }
1034
1035 float CalcRegen(float current, float stable, float regenfactor)
1036 {
1037         if(current > stable)
1038                 return current;
1039         else if(current > stable - 0.25) // when close enough, "snap"
1040                 return stable;
1041         else
1042                 return min(stable, current + (stable - current) * regenfactor * frametime);
1043 }
1044
1045 void player_regen (void)
1046 {
1047         float maxh, maxa, limith, limita, max_mod, regen_mod, rot_mod, limit_mod;
1048         maxh = cvar("g_balance_health_stable");
1049         maxa = cvar("g_balance_armor_stable");
1050         limith = cvar("g_balance_health_limit");
1051         limita = cvar("g_balance_armor_limit");
1052
1053         if (g_minstagib || (g_lms && !cvar("g_lms_regenerate")))
1054                 return;
1055
1056         max_mod = regen_mod = rot_mod = limit_mod = 1;
1057
1058         if (self.runes & RUNE_REGEN)
1059         {
1060                 if (self.runes & CURSE_VENOM) // do we have both rune/curse?
1061                 {
1062                         regen_mod = cvar("g_balance_rune_regen_combo_regenrate");
1063                         max_mod = cvar("g_balance_rune_regen_combo_hpmod");
1064                         limit_mod = cvar("g_balance_rune_regen_combo_limitmod");
1065                 }
1066                 else
1067                 {
1068                         regen_mod = cvar("g_balance_rune_regen_regenrate");
1069                         max_mod = cvar("g_balance_rune_regen_hpmod");
1070                         limit_mod = cvar("g_balance_rune_regen_limitmod");
1071                 }
1072         }
1073         else if (self.runes & CURSE_VENOM)
1074         {
1075                 max_mod = cvar("g_balance_curse_venom_hpmod");
1076                 if (self.runes & RUNE_REGEN) // do we have both rune/curse?
1077                         rot_mod = cvar("g_balance_rune_regen_combo_rotrate");
1078                 else
1079                         rot_mod = cvar("g_balance_curse_venom_rotrate");
1080                 limit_mod = cvar("g_balance_curse_venom_limitmod");
1081                 //if (!self.runes & RUNE_REGEN)
1082                 //      rot_mod = cvar("g_balance_curse_venom_rotrate");
1083         }
1084         maxh = maxh * max_mod;
1085         //maxa = maxa * max_mod;
1086         limith = limith * limit_mod;
1087         limita = limita * limit_mod;
1088
1089         if (self.armorvalue > maxa)
1090         {
1091                 if (time > self.pauserotarmor_finished)
1092                 {
1093                         self.armorvalue = max(maxa, self.armorvalue + (maxa - self.armorvalue) * cvar("g_balance_armor_rot") * frametime);
1094                         self.armorvalue = max(maxa, self.armorvalue - cvar("g_balance_armor_rotlinear") * frametime);
1095                 }
1096         }
1097         else if (self.armorvalue < maxa)
1098         {
1099                 if (time > self.pauseregen_finished)
1100                 {
1101                         self.armorvalue = CalcRegen(self.armorvalue, maxa, cvar("g_balance_armor_regen"));
1102                         self.armorvalue = min(maxa, self.armorvalue + cvar("g_balance_armor_regenlinear") * frametime);
1103                 }
1104         }
1105         if (self.health > maxh)
1106         {
1107                 if (time > self.pauserothealth_finished)
1108                 {
1109                         self.health = max(maxh, self.health + (maxh - self.health) * rot_mod*cvar("g_balance_health_rot") * frametime);
1110                         self.health = max(maxh, self.health - rot_mod*cvar("g_balance_health_rotlinear") * frametime);
1111                 }
1112         }
1113         else if (self.health < maxh)
1114         {
1115                 if (time > self.pauseregen_finished)
1116                 {
1117                         self.health = CalcRegen(self.health, maxh, regen_mod * cvar("g_balance_health_regen"));
1118                         self.health = min(maxh, self.health + regen_mod*cvar("g_balance_health_regenlinear") * frametime);
1119                 }
1120         }
1121
1122         if (self.health > limith)
1123                 self.health = limith;
1124         if (self.armorvalue > limita)
1125                 self.armorvalue = limita;
1126
1127         // if player rotted to death...  die!
1128         if(self.health < 1)
1129                 self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
1130 }
1131
1132 /*
1133 ======================
1134 spectate mode routines
1135 ======================
1136 */
1137 void SpectateCopy(entity spectatee) {
1138         self.armortype = spectatee.armortype;
1139         self.armorvalue = spectatee.armorvalue;
1140         self.currentammo = spectatee.currentammo;
1141         self.effects = spectatee.effects;
1142         self.health = spectatee.health;
1143         self.impulse = 0;
1144         self.items = spectatee.items;
1145         self.punchangle = spectatee.punchangle;
1146         self.view_ofs = spectatee.view_ofs;
1147         self.v_angle = spectatee.v_angle;
1148         self.viewzoom = spectatee.viewzoom;
1149         self.velocity = spectatee.velocity;
1150         self.dmg_take = spectatee.dmg_take;
1151         self.dmg_save = spectatee.dmg_save;
1152         self.dmg_inflictor = spectatee.dmg_inflictor;
1153         self.angles = spectatee.v_angle;
1154         self.fixangle = TRUE;
1155         setorigin(self, spectatee.origin);
1156         setsize(self, spectatee.mins, spectatee.maxs);
1157 }
1158
1159 void SpectateUpdate() {
1160         if(!self.enemy)
1161                         PutObserverInServer();
1162
1163         if (self != self.enemy) {
1164                 if(self.enemy.flags & FL_NOTARGET)
1165                         PutObserverInServer();
1166                 SpectateCopy(self.enemy);
1167                 //msg_entity = self;
1168                 //WriteByte(MSG_ONE, SVC_SETANGLE);
1169                 //WriteAngle(MSG_ONE, self.enemy.v_angle_x);
1170                 //WriteAngle(MSG_ONE, self.enemy.v_angle_y);
1171                 //WriteAngle(MSG_ONE, self.enemy.v_angle_z);
1172         }
1173 }
1174
1175 float SpectateNext() {
1176         other = find(self.enemy, classname, "player");
1177         if (!other) {
1178                 other = find(other, classname, "player");
1179         }
1180         if (other) {
1181                 self.enemy = other;
1182         }
1183         if(self.enemy.classname == "player") {
1184                 msg_entity = self;
1185                 WriteByte(MSG_ONE, SVC_SETVIEW);
1186                 WriteEntity(MSG_ONE, self.enemy);
1187                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
1188                 SpectateUpdate();
1189                 return 1;
1190         } else {
1191                 return 0;
1192         }
1193 }
1194
1195 /*
1196 =============
1197 ShowRespawnCountdown()
1198
1199 Update a respawn countdown display.
1200 =============
1201 */
1202 void ShowRespawnCountdown()
1203 {
1204         float number;
1205         if(self.deadflag == DEAD_NO) // just respawned?
1206                 return;
1207         else
1208         {
1209                 number = ceil(self.death_time - time);
1210                 if(number <= 0)
1211                         return;
1212                 if(number <= self.respawn_countdown)
1213                 {
1214                         self.respawn_countdown = number - 1;
1215                         if(ceil(self.death_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
1216                                 play2(self, strcat("announcer/robotic/", ftos(number), ".ogg"));
1217                 }
1218         }
1219 }
1220
1221 void LeaveSpectatorMode()
1222 {
1223         if(!cvar("teamplay") || cvar("g_campaign") || cvar("g_balance_teams")) {
1224                 self.classname = "player";
1225                 if(cvar("g_campaign") || cvar("g_balance_teams"))
1226                         JoinBestTeam(self, 0);
1227                 if(cvar("g_campaign"))
1228                         campaign_bots_may_start = 1;
1229                 PutClientInServer();
1230                 if(!(self.flags & FL_NOTARGET))
1231                         bprint ("^4", self.netname, "^4 is playing now\n");
1232                 centerprint(self,"");
1233                 return;
1234         } else {
1235                 stuffcmd(self,"menu_showteamselect\n");
1236                 return;
1237         }
1238 }
1239
1240 /*
1241 =============
1242 PlayerPreThink
1243
1244 Called every frame for each client before the physics are run
1245 =============
1246 */
1247 void() ctf_setstatus;
1248 .float vote_nagtime;
1249 void PlayerPreThink (void)
1250 {
1251         float f;
1252
1253         // version nagging
1254         if(self.version_nagtime)
1255                 if(self.cvar_g_nexuizversion)
1256                         if(time > self.version_nagtime)
1257                         {
1258                                 if(strstr(self.cvar_g_nexuizversion, "svn", 0) < 0)
1259                                         if(self.cvar_g_nexuizversion != cvar_string("g_nexuizversion"))
1260                                         {
1261                                                 dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Nexuiz ", cvar_string("g_nexuizversion"), "^7, you have ^3Nexuiz ", self.cvar_g_nexuizversion, "\n");
1262                                                 sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Nexuiz ", cvar_string("g_nexuizversion"), "^7, you have ^3Nexuiz ", self.cvar_g_nexuizversion, "\n"));
1263                                         }
1264                                 self.version_nagtime = 0;
1265                         }
1266
1267         // vote nagging
1268         if(self.cvar_scr_centertime)
1269                 if(time > self.vote_nagtime)
1270                 {
1271                         VoteNag();
1272                         self.vote_nagtime = time + self.cvar_scr_centertime * 0.6;
1273                 }
1274
1275         // GOD MODE info
1276         if(!(self.flags & FL_GODMODE)) if(self.max_armorvalue)
1277         {
1278                 sprint(self, strcat("godmode saved you ", ftos(self.max_armorvalue), " units of damage, cheater!\n"));
1279                 self.max_armorvalue = 0;
1280         }
1281
1282         if(self.classname == "player") {
1283                 local vector m1, m2;
1284
1285 //              if(self.netname == "Wazat")
1286 //                      bprint(self.classname, "\n");
1287
1288                 CheckRules_Player();
1289
1290                 if(self.button7)
1291                         PrintWelcomeMessage(self);
1292
1293                 if(g_lms || !cvar("sv_spectate"))
1294                 if((time - self.jointime) <= cvar("welcome_message_time"))
1295                         PrintWelcomeMessage(self);
1296
1297                 if (intermission_running)
1298                 {
1299                         IntermissionThink ();   // otherwise a button could be missed between
1300                         return;                                 // the think tics
1301                 }
1302
1303                 if(time > self.teleport_time)
1304                 {
1305                         self.effects = self.effects - (self.effects & EF_NODRAW);
1306                         if(self.weaponentity)
1307                                 self.weaponentity.flags = self.weaponentity.flags - (self.weaponentity.flags & EF_NODRAW);
1308                 }
1309
1310                 Nixnex_GiveCurrentWeapon();
1311
1312                 if(frametime > 0) // don't do this in cl_movement frames, just in server ticks
1313                         UpdateSelectedPlayer();
1314
1315                 if (self.deadflag != DEAD_NO)
1316                 {
1317                         float button_pressed, force_respawn;
1318                         player_anim();
1319                         button_pressed = (self.button0 || self.button2 || self.button3 || self.button6 || self.buttonuse);
1320                         force_respawn = (g_lms || cvar("g_forced_respawn"));
1321                         if (self.deadflag == DEAD_DYING)
1322                         {
1323                                 if(force_respawn)
1324                                         self.deadflag = DEAD_RESPAWNING;
1325                                 else if(!button_pressed)
1326                                         self.deadflag = DEAD_DEAD;
1327                         }
1328                         else if (self.deadflag == DEAD_DEAD)
1329                         {
1330                                 if(button_pressed)
1331                                         self.deadflag = DEAD_RESPAWNABLE;
1332                         }
1333                         else if (self.deadflag == DEAD_RESPAWNABLE)
1334                         {
1335                                 if(!button_pressed)
1336                                         self.deadflag = DEAD_RESPAWNING;
1337                         }
1338                         else if (self.deadflag == DEAD_RESPAWNING)
1339                         {
1340                                 if(time > self.death_time)
1341                                         respawn();
1342                         }
1343                         ShowRespawnCountdown();
1344                         return;
1345                 }
1346
1347                 if(g_lms && !self.deadflag && cvar("g_lms_campcheck_interval"))
1348                 {
1349                         vector dist;
1350
1351                         // calculate player movement (in 2 dimensions only, so jumping on one spot doesn't count as movement)
1352                         dist = self.oldorigin - self.origin;
1353                         dist_z = 0;
1354                         self.lms_traveled_distance += fabs(vlen(dist));
1355
1356                         if((cvar("g_campaign") && !campaign_bots_may_start) || (time < restart_countdown))
1357                         {
1358                                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval")*2;
1359                                 self.lms_traveled_distance = 0;
1360                         }
1361
1362                         if(time > self.lms_nextcheck)
1363                         {
1364                                 //sprint(self, "distance: ", ftos(self.lms_traveled_distance), "\n");
1365                                 if(self.lms_traveled_distance < cvar("g_lms_campcheck_distance"))
1366                                 {
1367                                         centerprint(self, cvar_string("g_lms_campcheck_message"));
1368                                         // FIXME KadaverJack: gibbing player here causes playermodel to bounce around, instead of eye.md3
1369                                         // I wasn't able to find out WHY that happens, so I put a workaround in place that shall prevent players from being gibbed :(
1370                                         Damage(self, self, self, bound(0, cvar("g_lms_campcheck_damage"), self.health + self.armorvalue * cvar("g_balance_armor_blockpercent") + 5), DEATH_CAMP, self.origin, '0 0 0');
1371                                 }
1372                                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval");
1373                                 self.lms_traveled_distance = 0;
1374                         }
1375                 }
1376
1377                 if (self.button5 && !self.hook.state)
1378                 {
1379                         if (!self.crouch)
1380                         {
1381                                 self.crouch = TRUE;
1382                                 self.view_ofs = PL_CROUCH_VIEW_OFS;
1383                                 setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX);
1384                                 player_setanim(self.anim_duck, FALSE, TRUE, TRUE);
1385                         }
1386                 }
1387                 else
1388                 {
1389                         if (self.crouch)
1390                         {
1391                                 tracebox(self.origin, PL_MIN, PL_MAX, self.origin, FALSE, self);
1392                                 if (!trace_startsolid)
1393                                 {
1394                                         self.crouch = FALSE;
1395                                         self.view_ofs = PL_VIEW_OFS;
1396                                         setsize (self, PL_MIN, PL_MAX);
1397                                 }
1398                         }
1399                 }
1400
1401                 if(cvar("sv_defaultcharacter") == 1) {
1402                         local string defaultmodel;
1403                         defaultmodel = cvar_string("sv_defaultplayermodel");
1404
1405                         if (defaultmodel != self.model)
1406                         {
1407                                 m1 = self.mins;
1408                                 m2 = self.maxs;
1409                                 setmodel_lod (self, defaultmodel);
1410                                 setsize (self, m1, m2);
1411                         }
1412
1413                         if (self.skin != cvar("sv_defaultplayerskin"))
1414                                 self.skin = cvar("sv_defaultplayerskin");
1415                 } else {
1416                         if (self.playermodel != self.model)
1417                         {
1418                                 self.playermodel = CheckPlayerModel(self.playermodel);
1419                                 m1 = self.mins;
1420                                 m2 = self.maxs;
1421                                 setmodel_lod (self, self.playermodel);
1422                                 setsize (self, m1, m2);
1423                         }
1424
1425                         f = RestrictSkin(stof(self.playerskin));
1426                         if(self.skin != f)
1427                                 self.skin = f;
1428                 }
1429                 if(!teams_matter)
1430                         if(strlen(cvar_string("sv_defaultplayercolors")))
1431                                 if(self.clientcolors != cvar("sv_defaultplayercolors"))
1432                                         setcolor(self, cvar("sv_defaultplayercolors"));
1433
1434                 GrapplingHookFrame();
1435
1436                 W_WeaponFrame();
1437
1438                 {
1439                         float zoomfactor, zoomspeed, zoomdir;
1440                         zoomfactor = self.cvar_cl_zoomfactor;
1441                         if(zoomfactor < 1 || zoomfactor > 16)
1442                                 zoomfactor = 2.5;
1443                         zoomspeed = self.cvar_cl_zoomspeed;
1444                         if(zoomspeed >= 0) // < 0 is instant zoom
1445                                 if(zoomspeed < 0.5 || zoomspeed > 16)
1446                                         zoomspeed = 3.5;
1447
1448                         zoomdir = self.button4;
1449                         if(self.button3)
1450                                 if(self.weapon == WEP_NEX)
1451                                         if(!g_minstagib)
1452                                                 zoomdir = 1;
1453
1454                         if(zoomdir)
1455                                 self.has_zoomed = 1;
1456
1457                         if(self.has_zoomed)
1458                         {
1459                                 if(zoomspeed <= 0) // instant zoom
1460                                 {
1461                                         if(zoomdir)
1462                                                 self.viewzoom = 1 / zoomfactor;
1463                                         else
1464                                                 self.viewzoom = 1;
1465                                 }
1466                                 else
1467                                 {
1468                                         // geometric zoom would be:
1469                                         //   self.viewzoom = bound(1 / zoomfactor, self.viewzoom * pow(zoomfactor, (zoomdir ? -1 : 1) * frametime * zoomspeed), 1);
1470                                         // however, testing showed that arithmetic/harmonic zoom works better
1471                                         if(zoomdir)
1472                                                 // self.viewzoom = 1 / bound(1, 1 / self.viewzoom + (zoomdir ? 1 : -1) * frametime * zoomspeed * (zoomfactor - 1), zoomfactor);
1473                                                 // zoom in = arithmetic: 1x, 2x, 3x, 4x, ..., 8x
1474                                                 self.viewzoom = 1 / bound(1, 1 / self.viewzoom + frametime * zoomspeed * (zoomfactor - 1), zoomfactor);
1475                                         else
1476                                                 // self.viewzoom = bound(1 / zoomfactor, self.viewzoom + (zoomdir ? -1 : 1) * frametime * zoomspeed * (1 - 1 / zoomfactor), 1);
1477                                                 // zoom out = harmonic: 8/1x, 8/2x, 8/3x, 8/4x, ..., 8/8x
1478                                                 self.viewzoom = bound(1 / zoomfactor, self.viewzoom + frametime * zoomspeed * (1 - 1 / zoomfactor), 1);
1479                                 }
1480                         }
1481                         else
1482                                 self.viewzoom = min(1, self.viewzoom + frametime); // spawn zoom-in
1483                 }
1484
1485                 player_powerups();
1486                 player_regen();
1487                 player_anim();
1488
1489                 if (g_minstagib)
1490                         minstagib_ammocheck();
1491
1492                 ctf_setstatus();
1493                 kh_setstatus();
1494
1495                 //self.angles_y=self.v_angle_y + 90;   // temp
1496
1497                 //if (TetrisPreFrame()) return;
1498         } else if(gameover) {
1499                 if (intermission_running)
1500                         IntermissionThink ();   // otherwise a button could be missed between
1501                 return;
1502         } else if(self.classname == "observer") {
1503
1504                 if (self.flags & FL_JUMPRELEASED) {
1505                         if (self.button2 && self.version == cvar("gameversion")) {
1506                                 self.welcomemessage_time = 0;
1507                                 self.flags = self.flags - FL_JUMPRELEASED;
1508                                 LeaveSpectatorMode();
1509                                 return;
1510                         } else if(self.button0 && self.version == cvar("gameversion")) {
1511                                 self.welcomemessage_time = 0;
1512                                 self.flags = self.flags - FL_JUMPRELEASED;
1513                                 if(SpectateNext() == 1) {
1514                                         self.classname = "spectator";
1515                                 }
1516                         }
1517                 } else {
1518                         if (!(self.button0 || self.button2)) {
1519                                 self.flags = self.flags | FL_JUMPRELEASED;
1520                         }
1521                 }
1522                 PrintWelcomeMessage(self);
1523         } else if(self.classname == "spectator") {
1524                 if (self.flags & FL_JUMPRELEASED) {
1525                         if (self.button2 && self.version == cvar("gameversion")) {
1526                                 self.welcomemessage_time = 0;
1527                                 self.flags = self.flags - FL_JUMPRELEASED;
1528                                 LeaveSpectatorMode();
1529                                 return;
1530                         } else if(self.button0) {
1531                                 self.welcomemessage_time = 0;
1532                                 self.flags = self.flags - FL_JUMPRELEASED;
1533                                 if(SpectateNext() == 1) {
1534                                         self.classname = "spectator";
1535                                 } else {
1536                                         self.classname = "observer";
1537                                         PutClientInServer();
1538                                 }
1539                         } else if (self.button3) {
1540                                 self.welcomemessage_time = 0;
1541                                 self.flags = self.flags - FL_JUMPRELEASED;
1542                                 self.classname = "observer";
1543                                 PutClientInServer();
1544                         } else {
1545                                 SpectateUpdate();
1546                         }
1547                 } else {
1548                         if (!(self.button0 || self.button3)) {
1549                                 self.flags = self.flags | FL_JUMPRELEASED;
1550                         }
1551                 }
1552                 PrintWelcomeMessage(self);
1553                 self.flags = self.flags | FL_CLIENT | FL_NOTARGET;
1554         }
1555 }
1556
1557
1558 /*
1559 =============
1560 PlayerPostThink
1561
1562 Called every frame for each client after the physics are run
1563 =============
1564 */
1565 void PlayerPostThink (void)
1566 {
1567         // Savage: Check for nameless players
1568         if (strlen(self.netname) < 1) {
1569                 self.netname = "Player";
1570                 stuffcmd(self, "seta _cl_name Player\n");
1571         }
1572
1573         if(self.classname == "player") {
1574                 CheckRules_Player();
1575                 UpdateChatBubble();
1576                 UpdateTeamBubble();
1577                 if (self.impulse)
1578                         ImpulseCommands();
1579                 if (intermission_running)
1580                         return;         // intermission or finale
1581
1582                 //PrintWelcomeMessage(self);
1583                 //if (TetrisPostFrame()) return;
1584
1585                 // restart countdown
1586                 if(time < restart_countdown)
1587                 {
1588                         string s;
1589                         float sec;
1590
1591                         sec = ceil(restart_countdown-time);
1592                         s = strcat(NEWLINES, "^1Game starts in ", ftos(sec), " seconds");
1593                         centerprint(self, s);
1594                         self.movetype = MOVETYPE_NONE;
1595                         self.velocity = '0 0 0';
1596                         self.avelocity = '0 0 0';
1597                         self.movement = '0 0 0';
1598                 }
1599                 else if(self.movetype == MOVETYPE_NONE)
1600                 {
1601                         self.movetype = MOVETYPE_WALK;
1602                         centerprint(self, "\n");
1603                 }
1604         } else if (self.classname == "observer") {
1605                 //do nothing
1606         } else if (self.classname == "spectator") {
1607                 //do nothing
1608         }
1609
1610         Arena_Warmup();
1611 }