data/qcsrc/server/cl_client.qc

   1 void race_send_recordtime(float msg);
   2 void race_SendRankings(float pos, float prevpos, float del, float msg);
   3
   4 void send_CSQC_teamnagger() {
   5         WriteByte(0, SVC_TEMPENTITY);
   6         WriteByte(0, TE_CSQC_TEAMNAGGER);
   7 }
   8
   9 float ClientData_Send(entity to, float sf)
  10 {
  11         if(to != self.owner)
  12         {
  13                 error("wtf");
  14                 return FALSE;
  15         }
  16
  17         entity e;
  18
  19         e = to;
  20         if(to.classname == "spectator")
  21                 e = to.enemy;
  22
  23         sf = 0;
  24
  25         if(e.race_completed)
  26                 sf |= 1; // forced scoreboard
  27         if(to.spectatee_status)
  28                 sf |= 2; // spectator ent number follows
  29         if(e.zoomstate)
  30                 sf |= 4; // zoomed
  31         if(e.porto_v_angle_held)
  32                 sf |= 8; // angles held
  33
  34         WriteByte(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
  35         WriteByte(MSG_ENTITY, sf);
  36
  37         if(sf & 2)
  38                 WriteByte(MSG_ENTITY, to.spectatee_status);
  39
  40         if(sf & 8)
  41         {
  42                 WriteAngle(MSG_ENTITY, e.v_angle_x);
  43                 WriteAngle(MSG_ENTITY, e.v_angle_y);
  44         }
  45
  46         return TRUE;
  47 }
  48
  49 void ClientData_Attach()
  50 {
  51         Net_LinkEntity(self.clientdata = spawn(), FALSE, 0, ClientData_Send);
  52         self.clientdata.drawonlytoclient = self;
  53         self.clientdata.owner = self;
  54 }
  55
  56 void ClientData_Detach()
  57 {
  58         remove(self.clientdata);
  59         self.clientdata = world;
  60 }
  61
  62 void ClientData_Touch(entity e)
  63 {
  64         e.clientdata.SendFlags = 1;
  65
  66         // make it spectatable
  67         entity e2;
  68         FOR_EACH_REALCLIENT(e2)
  69         {
  70                 if(e2 != e)
  71                         if(e2.classname == "spectator")
  72                                 if(e2.enemy == e)
  73                                         e2.clientdata.SendFlags = 1;
  74         }
  75 }
  76
  77
  78 .vector spawnpoint_score;
  79 .string netname_previous;
  80
  81 void spawnfunc_info_player_survivor (void)
  82 {
  83         spawnfunc_info_player_deathmatch();
  84 }
  85
  86 void spawnfunc_info_player_start (void)
  87 {
  88         spawnfunc_info_player_deathmatch();
  89 }
  90
  91 void spawnfunc_info_player_deathmatch (void)
  92 {
  93         self.classname = "info_player_deathmatch";
  94         relocate_spawnpoint();
  95 }
  96
  97 void spawnpoint_use()
  98 {
  99         if(teams_matter)
 100         if(have_team_spawns > 0)
 101         {
 102                 self.team = activator.team;
 103                 some_spawn_has_been_used = 1;
 104         }
 105 };
 106
 107 // Returns:
 108 //   _x: prio (-1 if unusable)
 109 //   _y: weight
 110 vector Spawn_Score(entity spot, entity playerlist, float teamcheck, float anypoint)
 111 {
 112         float shortest, thisdist;
 113         float prio;
 114         entity player;
 115
 116         prio = 0;
 117
 118         // filter out spots for the wrong team
 119         if(teamcheck)
 120         if(spot.team != teamcheck)
 121                 return '-1 0 0';
 122
 123         if(race_spawns)
 124                 if(spot.target == "")
 125                         return '-1 0 0';
 126
 127         if(clienttype(self) == CLIENTTYPE_REAL)
 128         {
 129                 if(spot.restriction == 1)
 130                         return '-1 0 0';
 131         }
 132         else
 133         {
 134                 if(spot.restriction == 2)
 135                         return '-1 0 0';
 136         }
 137
 138         // filter out spots for assault
 139         if(spot.target != "") {
 140                 local entity ent;
 141                 float good, found;
 142                 ent = find(world, targetname, spot.target);
 143
 144                 while(ent) {
 145                         if(ent.classname == "target_objective")
 146                         {
 147                                 found = 1;
 148                                 if(ent.health < 0 || ent.health >= ASSAULT_VALUE_INACTIVE)
 149                                         return '-1 0 0';
 150                                 good = 1;
 151                         }
 152                         else if(ent.classname == "trigger_race_checkpoint")
 153                         {
 154                                 found = 1;
 155                                 if(!anypoint) // spectators may spawn everywhere
 156
 157                                 {
 158                                         if(g_race_qualifying)
 159                                         {
 160                                                 // spawn at first
 161                                                 if(ent.race_checkpoint != 0)
 162                                                         return '-1 0 0';
 163                                                 if(spot.race_place != race_lowest_place_spawn)
 164                                                         return '-1 0 0';
 165                                         }
 166                                         else
 167                                         {
 168                                                 if(ent.race_checkpoint != self.race_respawn_checkpoint)
 169                                                         return '-1 0 0';
 170                                                 // try reusing the previous spawn
 171                                                 if(ent == self.race_respawn_spotref || spot == self.race_respawn_spotref)
 172                                                         prio += 1;
 173                                                 if(ent.race_checkpoint == 0)
 174                                                 {
 175                                                         float pl;
 176                                                         pl = self.race_place;
 177                                                         if(pl > race_highest_place_spawn)
 178                                                                 pl = 0;
 179                                                         if(pl == 0 && !self.race_started)
 180                                                                 pl = race_highest_place_spawn; // use last place if he has not even touched finish yet
 181                                                         if(spot.race_place != pl)
 182                                                                 return '-1 0 0';
 183                                                 }
 184                                         }
 185                                 }
 186                                 good = 1;
 187                         }
 188                         ent = find(ent, targetname, spot.target);
 189                 }
 190
 191                 if(found && !good)
 192                         return '-1 0 0';
 193         }
 194
 195         player = playerlist;
 196         shortest = vlen(world.maxs - world.mins);
 197         for(player = playerlist; player; player = player.chain)
 198                 if (player != self)
 199                 {
 200                         thisdist = vlen(player.origin - spot.origin);
 201                         if (thisdist < shortest)
 202                                 shortest = thisdist;
 203                 }
 204         return prio * '1 0 0' + shortest * '0 1 0';
 205 }
 206
 207 float spawn_allbad;
 208 float spawn_allgood;
 209 entity Spawn_FilterOutBadSpots(entity firstspot, entity playerlist, float mindist, float teamcheck, float anypoint)
 210 {
 211         local entity spot, spotlist, spotlistend;
 212         spawn_allgood = TRUE;
 213         spawn_allbad = TRUE;
 214
 215         spotlist = world;
 216         spotlistend = world;
 217
 218         for(spot = firstspot; spot; spot = spot.chain)
 219         {
 220                 spot.spawnpoint_score = Spawn_Score(spot, playerlist, teamcheck, anypoint);
 221
 222                 if(cvar("spawn_debugview"))
 223                 {
 224                         setmodel(spot, "models/runematch/rune.mdl");
 225                         if(spot.spawnpoint_score_y < mindist)
 226                         {
 227                                 spot.colormod = '1 0 0';
 228                                 spot.scale = 1;
 229                         }
 230                         else
 231                         {
 232                                 spot.colormod = '0 1 0';
 233                                 spot.scale = spot.spawnpoint_score_y / mindist;
 234                         }
 235                 }
 236
 237                 if(spot.spawnpoint_score_x >= 0) // spawning allowed here
 238                 {
 239                         if(spot.spawnpoint_score_y < mindist)
 240                         {
 241                                 // too short distance
 242                                 spawn_allgood = FALSE;
 243                         }
 244                         else
 245                         {
 246                                 // perfect
 247                                 spawn_allbad = FALSE;
 248
 249                                 if(spotlistend)
 250                                         spotlistend.chain = spot;
 251                                 spotlistend = spot;
 252                                 if(!spotlist)
 253                                         spotlist = spot;
 254
 255                                 /*
 256                                 if(teamcheck)
 257                                 if(spot.team != teamcheck)
 258                                         error("invalid spawn added");
 259
 260                                 print("added ", etos(spot), "\n");
 261                                 */
 262                         }
 263                 }
 264         }
 265         if(spotlistend)
 266                 spotlistend.chain = world;
 267
 268         /*
 269                 entity e;
 270                 if(teamcheck)
 271                         for(e = spotlist; e; e = e.chain)
 272                         {
 273                                 print("seen ", etos(e), "\n");
 274                                 if(e.team != teamcheck)
 275                                         error("invalid spawn found");
 276                         }
 277         */
 278
 279         return spotlist;
 280 }
 281
 282 entity Spawn_WeightedPoint(entity firstspot, float lower, float upper, float exponent)
 283 {
 284         // weight of a point: bound(lower, mindisttoplayer, upper)^exponent
 285         // multiplied by spot.cnt (useful if you distribute many spawnpoints in a small area)
 286         local entity spot;
 287
 288         RandomSelection_Init();
 289         for(spot = firstspot; spot; spot = spot.chain)
 290                 RandomSelection_Add(spot, 0, string_null, pow(bound(lower, spot.spawnpoint_score_y, upper), exponent) * spot.cnt, (spot.spawnpoint_score_y >= lower) * 0.5 + spot.spawnpoint_score_x);
 291
 292         return RandomSelection_chosen_ent;
 293 }
 294
 295 /*
 296 =============
 297 SelectSpawnPoint
 298
 299 Finds a point to respawn
 300 =============
 301 */
 302 entity SelectSpawnPoint (float anypoint)
 303 {
 304         local float teamcheck;
 305         local entity firstspot_new;
 306         local entity spot, firstspot, playerlist;
 307
 308         spot = find (world, classname, "testplayerstart");
 309         if (spot)
 310                 return spot;
 311
 312         teamcheck = 0;
 313
 314         if(!anypoint && have_team_spawns > 0)
 315                 teamcheck = self.team;
 316
 317         // get the list of players
 318         playerlist = findchain(classname, "player");
 319         // get the entire list of spots
 320         firstspot = findchain(classname, "info_player_deathmatch");
 321         // filter out the bad ones
 322         // (note this returns the original list if none survived)
 323         if(anypoint)
 324         {
 325                 spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 326         }
 327         else
 328         {
 329                 firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, 100, teamcheck, anypoint);
 330                 if(!firstspot_new)
 331                         firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, -1, teamcheck, anypoint);
 332                 firstspot = firstspot_new;
 333
 334                 // there is 50/50 chance of choosing a random spot or the furthest spot
 335                 // (this means that roughly every other spawn will be furthest, so you
 336                 // usually won't get fragged at spawn twice in a row)
 337                 if (arena_roundbased && !g_ca)
 338                 {
 339                         firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, 800, teamcheck, anypoint);
 340                         if(firstspot_new)
 341                                 firstspot = firstspot_new;
 342                         spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 343                 }
 344                 else if (random() > cvar("g_spawn_furthest"))
 345                         spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 346                 else
 347                         spot = Spawn_WeightedPoint(firstspot, 1, 5000, 5); // chooses a far far away spawnpoint
 348         }
 349
 350         if(cvar("spawn_debugview"))
 351         {
 352                 print("spot mindistance: ", vtos(spot.spawnpoint_score), "\n");
 353
 354                 entity e;
 355                 if(teamcheck)
 356                         for(e = firstspot; e; e = e.chain)
 357                                 if(e.team != teamcheck)
 358                                         error("invalid spawn found");
 359         }
 360
 361         if (!spot)
 362         {
 363                 if(cvar("spawn_debug"))
 364                         GotoNextMap();
 365                 else
 366                 {
 367                         if(some_spawn_has_been_used)
 368                                 return world; // team can't spawn any more, because of actions of other team
 369                         else
 370                                 error("Cannot find a spawn point - please fix the map!");
 371                 }
 372         }
 373
 374         return spot;
 375 }
 376
 377 /*
 378 =============
 379 CheckPlayerModel
 380
 381 Checks if the argument string can be a valid playermodel.
 382 Returns a valid one in doubt.
 383 =============
 384 */
 385 string FallbackPlayerModel = "models/player/marine.zym";
 386 string CheckPlayerModel(string plyermodel) {
 387         if(strlen(plyermodel) < 4)
 388                 return FallbackPlayerModel;
 389         if( substring(plyermodel,0,14) != "models/player/")
 390                 return FallbackPlayerModel;
 391         else if(cvar("sv_servermodelsonly"))
 392         {
 393                 if(substring(plyermodel,-4,4) != ".zym")
 394                 if(substring(plyermodel,-4,4) != ".dpm")
 395                 if(substring(plyermodel,-4,4) != ".md3")
 396                 if(substring(plyermodel,-4,4) != ".psk")
 397                         return FallbackPlayerModel;
 398                 // forbid the LOD models
 399                 if(substring(plyermodel, -9,5) == "_lod1")
 400                         return FallbackPlayerModel;
 401                 if(substring(plyermodel, -9,5) == "_lod2")
 402                         return FallbackPlayerModel;
 403                 if(plyermodel != strtolower(plyermodel))
 404                         return FallbackPlayerModel;
 405                 if(!fexists(plyermodel))
 406                         return FallbackPlayerModel;
 407         }
 408         return plyermodel;
 409 }
 410
 411 /*
 412 =============
 413 Client_customizeentityforclient
 414
 415 LOD reduction
 416 =============
 417 */
 418 void Client_uncustomizeentityforclient()
 419 {
 420         if(self.modelindex == 0) // no need to uncustomize then
 421                 return;
 422         self.modelindex = self.modelindex_lod0;
 423         self.skin = self.skinindex;
 424 }
 425
 426 float Client_customizeentityforclient()
 427 {
 428         entity modelsource;
 429
 430         if(self.modelindex == 0)
 431                 return TRUE;
 432
 433         // forcemodel stuff
 434
 435 #ifdef PROFILING
 436         float t0;
 437         t0 = gettime(GETTIME_HIRES); // reference
 438 #endif
 439
 440         modelsource = self;
 441
 442 #ifdef ALLOW_FORCEMODELS
 443         if(other.cvar_cl_forceplayermodelsfromnexuiz)
 444                 if not(self.modelindex_lod0_from_nexuiz)
 445                         modelsource = other;
 446         if(other.cvar_cl_forceplayermodels && sv_clforceplayermodels)
 447                 modelsource = other;
 448 #endif
 449
 450         self.skin = modelsource.skinindex;
 451
 452 #if 0
 453         if(modelsource == self)
 454                 self.skin = modelsource.skinindex;
 455         else
 456                 self.skin = mod(modelsource.skinindex, 3); // forbid the fbskins as forced skins
 457 #endif
 458
 459         // self: me
 460         // other: the player viewing me
 461         float distance;
 462         float f;
 463
 464         if(other.cvar_cl_playerdetailreduction <= 0)
 465         {
 466                 if(other.cvar_cl_playerdetailreduction <= -2)
 467                         self.modelindex = modelsource.modelindex_lod2;
 468                 else if(other.cvar_cl_playerdetailreduction <= -1)
 469                         self.modelindex = modelsource.modelindex_lod1;
 470                 else
 471                         self.modelindex = modelsource.modelindex_lod0;
 472         }
 473         else
 474         {
 475                 distance = vlen(self.origin - other.origin);
 476                 f = (distance + 100.0) * other.cvar_cl_playerdetailreduction;
 477                 if(f > sv_loddistance2)
 478                         self.modelindex = modelsource.modelindex_lod2;
 479                 else if(f > sv_loddistance1)
 480                         self.modelindex = modelsource.modelindex_lod1;
 481                 else
 482                         self.modelindex = modelsource.modelindex_lod0;
 483         }
 484
 485 #ifdef PROFILING
 486         float t1;
 487         t1 = gettime(GETTIME_HIRES); // reference
 488         client_cefc_accumulator += (t1 - t0);
 489 #endif
 490
 491         return TRUE;
 492 }
 493
 494 void UpdatePlayerSounds();
 495 void setmodel_lod(entity e, string modelname)
 496 {
 497         string s;
 498
 499         if(sv_loddistance1)
 500         {
 501                 // FIXME: this only supports 3-letter extensions
 502                 s = strcat(substring(modelname, 0, strlen(modelname)-4), "_lod1", substring(modelname, -4, 4));
 503                 if(fexists(s))
 504                 {
 505                         setmodel(e, s); // players have high precision
 506                         self.modelindex_lod1 = self.modelindex;
 507                 }
 508                 else
 509                         self.modelindex_lod1 = -1;
 510
 511                 s = strcat(substring(modelname, 0, strlen(modelname)-4), "_lod2", substring(modelname, -4, 4));
 512                 if(fexists(s))
 513                 {
 514                         setmodel(e, s); // players have high precision
 515                         self.modelindex_lod2 = self.modelindex;
 516                 }
 517                 else
 518                         self.modelindex_lod2 = -1;
 519
 520                 precache_model(modelname);
 521                 setmodel(e, modelname); // players have high precision
 522                 self.modelindex_lod0 = self.modelindex;
 523
 524                 if(self.modelindex_lod1 < 0)
 525                         self.modelindex_lod1 = self.modelindex;
 526
 527                 if(self.modelindex_lod2 < 0)
 528                         self.modelindex_lod2 = self.modelindex;
 529         }
 530         else
 531         {
 532                 precache_model(modelname);
 533                 setmodel(e, modelname); // players have high precision
 534                 self.modelindex_lod0 = self.modelindex;
 535                         // save it for possible player model forcing
 536         }
 537
 538         s = whichpack(self.model);
 539         self.modelindex_lod0_from_nexuiz = ((s == "") || (substring(s, 0, 4) == "data"));
 540
 541         player_setupanimsformodel();
 542         UpdatePlayerSounds();
 543 }
 544
 545 /*
 546 =============
 547 PutObserverInServer
 548
 549 putting a client as observer in the server
 550 =============
 551 */
 552 void FixPlayermodel();
 553 void PutObserverInServer (void)
 554 {
 555         entity  spot;
 556
 557         race_PreSpawnObserver();
 558
 559         spot = SelectSpawnPoint (TRUE);
 560         if(!spot)
 561                 error("No spawnpoints for observers?!?\n");
 562         RemoveGrapplingHook(self); // Wazat's Grappling Hook
 563
 564         if(clienttype(self) == CLIENTTYPE_REAL)
 565         {
 566                 msg_entity = self;
 567                 WriteByte(MSG_ONE, SVC_SETVIEW);
 568                 WriteEntity(MSG_ONE, self);
 569         }
 570
 571         DropAllRunes(self);
 572         kh_Key_DropAll(self, TRUE);
 573
 574         Portal_ClearAll(self);
 575
 576         if(self.flagcarried)
 577                 DropFlag(self.flagcarried, world, world);
 578
 579         if(self.ballcarried)
 580                 DropBall(self.ballcarried, self.origin + self.ballcarried.origin, self.velocity);
 581
 582         WaypointSprite_PlayerDead();
 583
 584         if not(g_ca)  // don't reset teams when moving a ca player to the spectators
 585                 self.team = -1;  // move this as it is needed to log the player spectating in eventlog
 586
 587         if(self.killcount != -666) {
 588                 if(g_lms) {
 589                         if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
 590                                 bprint ("^4", self.netname, "^4 has no more lives left\n");
 591                         else
 592                                 bprint ("^4", self.netname, "^4 is spectating now\n"); // TODO turn this into a proper forfeit?
 593                 } else
 594                         bprint ("^4", self.netname, "^4 is spectating now\n");
 595
 596                 if(self.just_joined == FALSE) {
 597                         LogTeamchange(self.playerid, -1, 4);
 598                 } else
 599                         self.just_joined = FALSE;
 600         }
 601
 602         PlayerScore_Clear(self); // clear scores when needed
 603
 604         self.spectatortime = time;
 605
 606         self.classname = "observer";
 607         self.iscreature = FALSE;
 608         self.health = -666;
 609         self.takedamage = DAMAGE_NO;
 610         self.solid = SOLID_NOT;
 611         self.movetype = MOVETYPE_NOCLIP;
 612         self.flags = FL_CLIENT | FL_NOTARGET;
 613         self.armorvalue = 666;
 614         self.effects = 0;
 615         self.armorvalue = cvar("g_balance_armor_start");
 616         self.pauserotarmor_finished = 0;
 617         self.pauserothealth_finished = 0;
 618         self.pauseregen_finished = 0;
 619         self.damageforcescale = 0;
 620         self.death_time = 0;
 621         self.dead_frame = 0;
 622         self.alpha = 0;
 623         self.scale = 0;
 624         self.fade_time = 0;
 625         self.pain_frame = 0;
 626         self.pain_finished = 0;
 627         self.strength_finished = 0;
 628         self.invincible_finished = 0;
 629         self.pushltime = 0;
 630         self.think = SUB_Null;
 631         self.nextthink = 0;
 632         self.hook_time = 0;
 633         self.runes = 0;
 634         self.deadflag = DEAD_NO;
 635         self.angles = spot.angles;
 636         self.angles_z = 0;
 637         self.fixangle = TRUE;
 638         self.crouch = FALSE;
 639
 640         self.view_ofs = PL_VIEW_OFS;
 641         setorigin (self, spot.origin);
 642         setsize (self, '0 0 0', '0 0 0');
 643         self.prevorigin = self.origin;
 644         self.items = 0;
 645         self.weapons = 0;
 646         self.model = "";
 647         FixPlayermodel();
 648         self.model = "";
 649         self.modelindex = 0;
 650         self.weapon = 0;
 651         self.weaponmodel = "";
 652         self.weaponentity = world;
 653         self.exteriorweaponentity = world;
 654         self.killcount = -666;
 655         self.velocity = '0 0 0';
 656         self.avelocity = '0 0 0';
 657         self.punchangle = '0 0 0';
 658         self.punchvector = '0 0 0';
 659         self.oldvelocity = self.velocity;
 660         self.fire_endtime = -1;
 661
 662         if(sv_loddistance1)
 663                 SetCustomizer(self, Client_customizeentityforclient, Client_uncustomizeentityforclient);
 664
 665         if(g_arena)
 666         {
 667                 if(self.version_mismatch)
 668                 {
 669                         Spawnqueue_Unmark(self);
 670                         Spawnqueue_Remove(self);
 671                 }
 672                 else
 673                 {
 674                         Spawnqueue_Insert(self);
 675                 }
 676         }
 677         else if(g_lms)
 678         {
 679                 // Only if the player cannot play at all
 680                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) == 666)
 681                         self.frags = FRAGS_SPECTATOR;
 682                 else
 683                         self.frags = FRAGS_LMS_LOSER;
 684         }
 685         else
 686                 self.frags = FRAGS_SPECTATOR;
 687 }
 688
 689 float RestrictSkin(float s)
 690 {
 691         if(!teams_matter)
 692                 return s;
 693         if(s == 6)
 694                 return 6;
 695         return mod(s, 3);
 696 }
 697
 698 void FixPlayermodel()
 699 {
 700         local string defaultmodel;
 701         local float defaultskin, chmdl, oldskin;
 702         local vector m1, m2;
 703
 704         defaultmodel = "";
 705
 706         if(cvar("sv_defaultcharacter") == 1) {
 707                 defaultskin = 0;
 708
 709                 if(teams_matter)
 710                 {
 711                         string s;
 712                         s = Team_ColorNameLowerCase(self.team);
 713                         if(s != "neutral")
 714                         {
 715                                 defaultmodel = cvar_string(strcat("sv_defaultplayermodel_", s));
 716                                 defaultskin = cvar(strcat("sv_defaultplayerskin_", s));
 717                         }
 718                 }
 719
 720                 if(defaultmodel == "")
 721                 {
 722                         defaultmodel = cvar_string("sv_defaultplayermodel");
 723                         defaultskin = cvar("sv_defaultplayerskin");
 724                 }
 725         }
 726
 727         if(self.modelindex == 0 && self.deadflag == DEAD_NO)
 728         {
 729                 if(self.model != "")
 730                         bprint("\{1}^1Player ", self.netname, "^1 has a zero modelindex, trying to fix...\n");
 731                 self.model = ""; // force the != checks to return true
 732         }
 733
 734         if(defaultmodel != "")
 735         {
 736                 if (defaultmodel != self.model)
 737                 {
 738                         m1 = self.mins;
 739                         m2 = self.maxs;
 740                         setmodel_lod (self, defaultmodel);
 741                         setsize (self, m1, m2);
 742                         chmdl = TRUE;
 743                 }
 744
 745                 oldskin = self.skinindex;
 746                 self.skinindex = defaultskin;
 747         } else {
 748                 if (self.playermodel != self.model || self.playermodel == "")
 749                 {
 750                         self.playermodel = CheckPlayerModel(self.playermodel); // this is never "", so no endless loop
 751                         m1 = self.mins;
 752                         m2 = self.maxs;
 753                         setmodel_lod (self, self.playermodel);
 754                         setsize (self, m1, m2);
 755                         chmdl = TRUE;
 756                 }
 757
 758                 oldskin = self.skinindex;
 759                 self.skinindex = RestrictSkin(stof(self.playerskin));
 760         }
 761
 762         if(chmdl || oldskin != self.skinindex)
 763                 self.species = player_getspecies(); // model or skin has changed
 764
 765         if(!teams_matter)
 766                 if(strlen(cvar_string("sv_defaultplayercolors")))
 767                         if(self.clientcolors != cvar("sv_defaultplayercolors"))
 768                                 setcolor(self, cvar("sv_defaultplayercolors"));
 769 }
 770
 771 void PlayerTouchExplode(entity p1, entity p2)
 772 {
 773         vector org;
 774         org = (p1.origin + p2.origin) * 0.5;
 775         org_z += (p1.mins_z + p2.mins_z) * 0.5;
 776
 777         te_explosion(org);
 778
 779         entity e;
 780         e = spawn();
 781         setorigin(e, org);
 782         RadiusDamage(e, world, g_touchexplode_damage, g_touchexplode_edgedamage, g_touchexplode_radius, world, g_touchexplode_force, DEATH_TOUCHEXPLODE, world);
 783         remove(e);
 784 }
 785
 786 /*
 787 =============
 788 PutClientInServer
 789
 790 Called when a client spawns in the server
 791 =============
 792 */
 793 //void() ctf_playerchanged;
 794 void PutClientInServer (void)
 795 {
 796         if(clienttype(self) == CLIENTTYPE_BOT)
 797         {
 798                 self.classname = "player";
 799         }
 800         else if(clienttype(self) == CLIENTTYPE_REAL)
 801         {
 802                 msg_entity = self;
 803                 WriteByte(MSG_ONE, SVC_SETVIEW);
 804                 WriteEntity(MSG_ONE, self);
 805         }
 806
 807         // player is dead and becomes observer
 808         // FIXME fix LMS scoring for new system
 809         if(g_lms)
 810         {
 811                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
 812                         self.classname = "observer";
 813         }
 814
 815         if(g_arena || (g_ca && !allowed_to_spawn))
 816         if(!self.spawned)
 817                 self.classname = "observer";
 818
 819         if(gameover)
 820                 self.classname = "observer";
 821
 822         if(self.classname == "player" && (!g_ca || (g_ca && allowed_to_spawn))) {
 823                 entity spot, oldself;
 824                 float j;
 825
 826                 if(self.team < 0)
 827                         JoinBestTeam(self, FALSE, TRUE);
 828
 829                 race_PreSpawn();
 830
 831                 spot = SelectSpawnPoint (FALSE);
 832                 if(!spot)
 833                 {
 834                         centerprint(self, "Sorry, no spawnpoints available!\nHope your team can fix it...");
 835                         return; // spawn failed
 836                 }
 837
 838                 RemoveGrapplingHook(self); // Wazat's Grappling Hook
 839
 840                 self.classname = "player";
 841                 self.wasplayer = TRUE;
 842                 self.iscreature = TRUE;
 843                 self.movetype = MOVETYPE_WALK;
 844                 self.solid = SOLID_SLIDEBOX;
 845                 if(cvar("g_playerclip_collisions"))
 846                         self.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP;
 847                 else
 848                         self.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY;
 849                 self.frags = FRAGS_PLAYER;
 850                 if(independent_players)
 851                         MAKE_INDEPENDENT_PLAYER(self);
 852                 self.flags = FL_CLIENT;
 853                 self.takedamage = DAMAGE_AIM;
 854                 if(g_minstagib)
 855                         self.effects = EF_FULLBRIGHT;
 856                 else
 857                         self.effects = 0;
 858                 self.air_finished = time + 12;
 859                 self.dmg = 2;
 860
 861                 if(inWarmupStage)
 862                 {
 863                         self.ammo_shells = warmup_start_ammo_shells;
 864                         self.ammo_nails = warmup_start_ammo_nails;
 865                         self.ammo_rockets = warmup_start_ammo_rockets;
 866                         self.ammo_cells = warmup_start_ammo_cells;
 867                         self.ammo_fuel = warmup_start_ammo_fuel;
 868                         self.health = warmup_start_health;
 869                         self.armorvalue = warmup_start_armorvalue;
 870                         self.weapons = warmup_start_weapons;
 871                 }
 872                 else
 873                 {
 874                         self.ammo_shells = start_ammo_shells;
 875                         self.ammo_nails = start_ammo_nails;
 876                         self.ammo_rockets = start_ammo_rockets;
 877                         self.ammo_cells = start_ammo_cells;
 878                         self.ammo_fuel = start_ammo_fuel;
 879                         self.health = start_health;
 880                         self.armorvalue = start_armorvalue;
 881                         self.weapons = start_weapons;
 882                 }
 883
 884                 if(g_weaponarena_random)
 885                         self.weapons = randombits(self.weapons, g_weaponarena_random, FALSE);
 886
 887                 self.items = start_items;
 888                 self.switchweapon = w_getbestweapon(self);
 889                 self.cnt = self.switchweapon;
 890                 self.weapon = 0;
 891                 self.jump_interval = time;
 892
 893                 self.spawnshieldtime = time + cvar("g_spawnshieldtime");
 894                 self.pauserotarmor_finished = time + cvar("g_balance_pause_armor_rot_spawn");
 895                 self.pauserothealth_finished = time + cvar("g_balance_pause_health_rot_spawn");
 896                 self.pauserotfuel_finished = time + cvar("g_balance_pause_fuel_rot_spawn");
 897                 self.pauseregen_finished = time + cvar("g_balance_pause_health_regen_spawn");
 898                 //extend the pause of rotting if client was reset at the beginning of the countdown
 899                 if(!cvar("sv_ready_restart_after_countdown") && time < game_starttime) { // TODO why is this cvar NOTted?
 900                         self.spawnshieldtime += game_starttime - time;
 901                         self.pauserotarmor_finished += game_starttime - time;
 902                         self.pauserothealth_finished += game_starttime - time;
 903                         self.pauseregen_finished += game_starttime - time;
 904                 }
 905                 self.damageforcescale = 2;
 906                 self.death_time = 0;
 907                 self.dead_frame = 0;
 908                 self.alpha = 0;
 909                 self.scale = 0;
 910                 self.fade_time = 0;
 911                 self.pain_frame = 0;
 912                 self.pain_finished = 0;
 913                 self.strength_finished = 0;
 914                 self.invincible_finished = 0;
 915                 self.pushltime = 0;
 916                 // players have no think function
 917                 self.think = SUB_Null;
 918                 self.nextthink = 0;
 919                 self.hook_time = 0;
 920                 self.dmg_team = 0;
 921
 922                 self.metertime = 0;
 923
 924                 self.runes = 0;
 925
 926                 self.deadflag = DEAD_NO;
 927
 928                 self.angles = spot.angles;
 929
 930                 self.angles_z = 0; // never spawn tilted even if the spot says to
 931                 self.fixangle = TRUE; // turn this way immediately
 932                 self.velocity = '0 0 0';
 933                 self.avelocity = '0 0 0';
 934                 self.punchangle = '0 0 0';
 935                 self.punchvector = '0 0 0';
 936                 self.oldvelocity = self.velocity;
 937                 self.fire_endtime = -1;
 938
 939                 msg_entity = self;
 940                 WRITESPECTATABLE_MSG_ONE({
 941                         WriteByte(MSG_ONE, SVC_TEMPENTITY);
 942                         WriteByte(MSG_ONE, TE_CSQC_SPAWN);
 943                 });
 944
 945                 if(sv_loddistance1)
 946                         SetCustomizer(self, Client_customizeentityforclient, Client_uncustomizeentityforclient);
 947
 948                 self.model = "";
 949                 FixPlayermodel();
 950
 951                 self.crouch = FALSE;
 952                 self.view_ofs = PL_VIEW_OFS;
 953                 setsize (self, PL_MIN, PL_MAX);
 954                 self.spawnorigin = spot.origin;
 955                 setorigin (self, spot.origin + '0 0 1' * (1 - self.mins_z - 24));
 956                 // don't reset back to last position, even if new position is stuck in solid
 957                 self.oldorigin = self.origin;
 958                 self.prevorigin = self.origin;
 959                 self.lastrocket = world; // stop rocket guiding, no revenge from the grave!
 960
 961                 if(g_arena)
 962                 {
 963                         Spawnqueue_Remove(self);
 964                         Spawnqueue_Mark(self);
 965                 }
 966
 967                 else if(g_ca)
 968                         self.caplayer = 1;
 969
 970                 self.event_damage = PlayerDamage;
 971
 972                 self.bot_attack = TRUE;
 973
 974                 self.statdraintime = time + 5;
 975                 self.BUTTON_ATCK = self.BUTTON_JUMP = self.BUTTON_ATCK2 = 0;
 976
 977                 if(self.killcount == -666) {
 978                         PlayerScore_Clear(self);
 979                         self.killcount = 0;
 980                 }
 981
 982                 self.cnt = WEP_LASER;
 983                 self.nixnex_lastchange_id = -1;
 984
 985                 CL_SpawnWeaponentity();
 986                 self.alpha = default_player_alpha;
 987                 self.colormod = '1 1 1' * cvar("g_player_brightness");
 988                 self.exteriorweaponentity.alpha = default_weapon_alpha;
 989
 990                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval")*2;
 991                 self.lms_traveled_distance = 0;
 992                 self.speedrunning = FALSE;
 993
 994                 race_PostSpawn(spot);
 995
 996                 if(cvar("spawn_debug"))
 997                 {
 998                         sprint(self, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 999                         remove(spot);   // usefull for checking if there are spawnpoints, that let drop through the floor
1000                 }
1001
1002                 //stuffcmd(self, "chase_active 0");
1003                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
1004
1005                 if (cvar("g_spawnsound"))
1006                         sound (self, CHAN_TRIGGER, "misc/spawn.wav", VOL_BASE, ATTN_NORM);
1007
1008                 if(g_assault) {
1009                         if(self.team == assault_attacker_team)
1010                                 centerprint(self, "You are attacking!");
1011                         else
1012                                 centerprint(self, "You are defending!");
1013                 }
1014
1015                 target_voicescript_clear(self);
1016
1017                 // reset fields the weapons may use
1018         for (j = WEP_FIRST; j <= WEP_LAST; ++j)
1019             weapon_action(j, WR_RESETPLAYER);
1020
1021                 oldself = self;
1022                 self = spot;
1023                         activator = oldself;
1024                                 SUB_UseTargets();
1025                         activator = world;
1026                 self = oldself;
1027         } else if(self.classname == "observer" || (g_ca && !allowed_to_spawn)) {
1028                 PutObserverInServer ();
1029         }
1030
1031         //if(g_ctf)
1032         //      ctf_playerchanged();
1033 }
1034
1035 float ClientInit_SendEntity(entity to, float sf)
1036 {
1037         WriteByte(MSG_ENTITY, ENT_CLIENT_INIT);
1038         WriteByte(MSG_ENTITY, g_nexball_meter_period * 32);
1039         WriteCoord(MSG_ENTITY, hook_shotorigin_x);
1040         WriteCoord(MSG_ENTITY, hook_shotorigin_y);
1041         WriteCoord(MSG_ENTITY, hook_shotorigin_z);
1042
1043         if(sv_foginterval && world.fog != "")
1044                 WriteString(MSG_ENTITY, world.fog);
1045         else
1046                 WriteString(MSG_ENTITY, "");
1047         WriteByte(MSG_ENTITY, cvar("g_balance_armor_blockpercent") * 255.0);
1048         WriteByte(MSG_ENTITY, cvar("g_balance_weaponswitchdelay") * 255.0);
1049         return TRUE;
1050 }
1051
1052 void ClientInit_Spawn()
1053 {
1054         Net_LinkEntity(spawn(), FALSE, 0, ClientInit_SendEntity);
1055 }
1056
1057 /*
1058 =============
1059 SetNewParms
1060 =============
1061 */
1062 void SetNewParms (void)
1063 {
1064         // initialize parms for a new player
1065         parm1 = -(86400 * 366);
1066 }
1067
1068 /*
1069 =============
1070 SetChangeParms
1071 =============
1072 */
1073 void SetChangeParms (void)
1074 {
1075         // save parms for level change
1076         parm1 = self.parm_idlesince - time;
1077 }
1078
1079 /*
1080 =============
1081 DecodeLevelParms
1082 =============
1083 */
1084 void DecodeLevelParms (void)
1085 {
1086         // load parms
1087         self.parm_idlesince = parm1;
1088         if(self.parm_idlesince == -(86400 * 366))
1089                 self.parm_idlesince = time;
1090
1091         // whatever happens, allow 60 seconds of idling directly after connect for map loading
1092         self.parm_idlesince = max(self.parm_idlesince, time - sv_maxidle + 60);
1093 }
1094
1095 /*
1096 =============
1097 ClientKill
1098
1099 Called when a client types 'kill' in the console
1100 =============
1101 */
1102
1103 void ClientKill_Now_TeamChange()
1104 {
1105         if(self.killindicator_teamchange == -1)
1106         {
1107                 self.team = -1;
1108                 JoinBestTeam( self, FALSE, FALSE );
1109         }
1110         else
1111                 SV_ChangeTeam(self.killindicator_teamchange - 1);
1112 }
1113
1114 void ClientKill_Now()
1115 {
1116         if(self.killindicator_teamchange)
1117                 ClientKill_Now_TeamChange();
1118
1119         // in any case:
1120         Damage(self, self, self, 100000, DEATH_KILL, self.origin, '0 0 0');
1121
1122         if(self.killindicator)
1123         {
1124                 dprint("Cleaned up after a leaked kill indicator.\n");
1125                 remove(self.killindicator);
1126                 self.killindicator = world;
1127         }
1128 }
1129 void KillIndicator_Think()
1130 {
1131         if (!self.owner.modelindex)
1132         {
1133                 self.owner.killindicator = world;
1134                 remove(self);
1135                 return;
1136         }
1137
1138         if(self.cnt <= 0)
1139         {
1140                 self = self.owner;
1141                 ClientKill_Now(); // no oldself needed
1142                 return;
1143         }
1144         else
1145         {
1146                 if(self.cnt <= 10)
1147                         setmodel(self, strcat("models/sprites/", ftos(self.cnt), ".spr32"));
1148                 if(clienttype(self.owner) == CLIENTTYPE_REAL)
1149                 {
1150                         if(self.cnt <= 10)
1151                                 announce(self.owner, strcat("announcer/robotic/", ftos(self.cnt), ".wav"));
1152                         if(self.owner.killindicator_teamchange)
1153                         {
1154                                 if(self.owner.killindicator_teamchange == -1)
1155                                         centerprint(self.owner, strcat("Changing team in ", ftos(self.cnt), " seconds"));
1156                                 else
1157                                         centerprint(self.owner, strcat("Changing to ", ColoredTeamName(self.owner.killindicator_teamchange), " in ", ftos(self.cnt), " seconds"));
1158                         }
1159                         else
1160                                 centerprint(self.owner, strcat("^1Suicide in ", ftos(self.cnt), " seconds"));
1161                 }
1162                 self.nextthink = time + 1;
1163                 self.cnt -= 1;
1164         }
1165 }
1166
1167 void ClientKill_TeamChange (float targetteam) // 0 = don't change, -1 = auto
1168 {
1169         float killtime;
1170         entity e;
1171         killtime = cvar("g_balance_kill_delay");
1172
1173         if(g_race_qualifying)
1174                 killtime = 0;
1175
1176         self.killindicator_teamchange = targetteam;
1177
1178         if(!self.killindicator)
1179         {
1180                 if(killtime <= 0 || !self.modelindex || self.deadflag != DEAD_NO)
1181                 {
1182                         ClientKill_Now();
1183                 }
1184                 else
1185                 {
1186                         self.killindicator = spawn();
1187                         self.killindicator.owner = self;
1188                         self.killindicator.scale = 0.5;
1189                         setattachment(self.killindicator, self, "");
1190                         setorigin(self.killindicator, '0 0 52');
1191                         self.killindicator.think = KillIndicator_Think;
1192                         self.killindicator.nextthink = time + (self.lip) * 0.05;
1193                         self.killindicator.cnt = ceil(killtime);
1194                         self.killindicator.count = bound(0, ceil(killtime), 10);
1195                         sprint(self, strcat("^1You'll be dead in ", ftos(self.killindicator.cnt), " seconds\n"));
1196
1197                         for(e = world; (e = find(e, classname, "body")) != world; )
1198                         {
1199                                 if(e.enemy != self)
1200                                         continue;
1201                                 e.killindicator = spawn();
1202                                 e.killindicator.owner = e;
1203                                 e.killindicator.scale = 0.5;
1204                                 setattachment(e.killindicator, e, "");
1205                                 setorigin(e.killindicator, '0 0 52');
1206                                 e.killindicator.think = KillIndicator_Think;
1207                                 e.killindicator.nextthink = time + (e.lip) * 0.05;
1208                                 e.killindicator.cnt = ceil(killtime);
1209                         }
1210                         self.lip = 0;
1211                 }
1212         }
1213         if(self.killindicator)
1214         {
1215                 if(targetteam)
1216                         self.killindicator.colormod = TeamColor(targetteam);
1217                 else
1218                         self.killindicator.colormod = '0 0 0';
1219         }
1220 }
1221
1222 void ClientKill (void)
1223 {
1224         ClientKill_TeamChange(0);
1225 }
1226
1227 void DoTeamChange(float destteam)
1228 {
1229         float t, c0;
1230         if(!teams_matter)
1231         {
1232                 if(destteam >= 0)
1233                         SetPlayerColors(self, destteam);
1234                 return;
1235         }
1236         if(self.classname == "player")
1237         if(destteam == -1)
1238         {
1239                 CheckAllowedTeams(self);
1240                 t = FindSmallestTeam(self, TRUE);
1241                 switch(self.team)
1242                 {
1243                         case COLOR_TEAM1: c0 = c1; break;
1244                         case COLOR_TEAM2: c0 = c2; break;
1245                         case COLOR_TEAM3: c0 = c3; break;
1246                         case COLOR_TEAM4: c0 = c4; break;
1247                         default:          c0 = 999;
1248                 }
1249                 switch(t)
1250                 {
1251                         case 1:
1252                                 if(c0 > c1)
1253                                         destteam = COLOR_TEAM1;
1254                                 break;
1255                         case 2:
1256                                 if(c0 > c2)
1257                                         destteam = COLOR_TEAM2;
1258                                 break;
1259                         case 3:
1260                                 if(c0 > c3)
1261                                         destteam = COLOR_TEAM3;
1262                                 break;
1263                         case 4:
1264                                 if(c0 > c4)
1265                                         destteam = COLOR_TEAM4;
1266                                 break;
1267                 }
1268                 if(destteam == -1)
1269                         return;
1270         }
1271         if(destteam == self.team && destteam >= 0 && !self.killindicator)
1272                 return;
1273         ClientKill_TeamChange(destteam);
1274 }
1275
1276 void FixClientCvars(entity e)
1277 {
1278         // send prediction settings to the client
1279         stuffcmd(e, "\nin_bindmap 0 0\n");
1280         if(g_race || g_cts)
1281                 stuffcmd(e, "cl_cmd settemp cl_movecliptokeyboard 2\n");
1282         /*
1283          * we no longer need to stuff this. Remove this comment block if you feel
1284          * 2.3 and higher (or was it 2.2.3?) don't need these any more
1285         stuffcmd(e, strcat("cl_gravity ", ftos(cvar("sv_gravity")), "\n"));
1286         stuffcmd(e, strcat("cl_movement_accelerate ", ftos(cvar("sv_accelerate")), "\n"));
1287         stuffcmd(e, strcat("cl_movement_friction ", ftos(cvar("sv_friction")), "\n"));
1288         stuffcmd(e, strcat("cl_movement_maxspeed ", ftos(cvar("sv_maxspeed")), "\n"));
1289         stuffcmd(e, strcat("cl_movement_airaccelerate ", ftos(cvar("sv_airaccelerate")), "\n"));
1290         stuffcmd(e, strcat("cl_movement_maxairspeed ", ftos(cvar("sv_maxairspeed")), "\n"));
1291         stuffcmd(e, strcat("cl_movement_stopspeed ", ftos(cvar("sv_stopspeed")), "\n"));
1292         stuffcmd(e, strcat("cl_movement_jumpvelocity ", ftos(cvar("sv_jumpvelocity")), "\n"));
1293         stuffcmd(e, strcat("cl_movement_stepheight ", ftos(cvar("sv_stepheight")), "\n"));
1294         stuffcmd(e, strcat("set cl_movement_friction_on_land ", ftos(cvar("sv_friction_on_land")), "\n"));
1295         stuffcmd(e, strcat("set cl_movement_airaccel_qw ", ftos(cvar("sv_airaccel_qw")), "\n"));
1296         stuffcmd(e, strcat("set cl_movement_airaccel_sideways_friction ", ftos(cvar("sv_airaccel_sideways_friction")), "\n"));
1297         stuffcmd(e, "cl_movement_edgefriction 1\n");
1298          */
1299 }
1300
1301 /*
1302 =============
1303 ClientConnect
1304
1305 Called when a client connects to the server
1306 =============
1307 */
1308 //void ctf_clientconnect();
1309 string ColoredTeamName(float t);
1310 void DecodeLevelParms (void);
1311 //void dom_player_join_team(entity pl);
1312 #ifdef UID
1313 .float uid_kicktime;
1314 .string uid;
1315 #endif
1316 void ClientConnect (void)
1317 {
1318         float t;
1319
1320         if(self.flags & FL_CLIENT)
1321         {
1322                 print("Warning: ClientConnect, but already connected!\n");
1323                 return;
1324         }
1325
1326         if(Ban_MaybeEnforceBan(self))
1327                 return;
1328
1329         DecodeLevelParms();
1330
1331         self.classname = "player_joining";
1332
1333         self.flags = FL_CLIENT;
1334         self.version_nagtime = time + 10 + random() * 10;
1335
1336         if(player_count<0)
1337         {
1338                 dprint("BUG player count is lower than zero, this cannot happen!\n");
1339                 player_count = 0;
1340         }
1341
1342         PlayerScore_Attach(self);
1343         ClientData_Attach();
1344
1345         bot_clientconnect();
1346
1347         playerdemo_init();
1348
1349         anticheat_init();
1350
1351         race_PreSpawnObserver();
1352
1353         //if(g_domination)
1354         //      dom_player_join_team(self);
1355
1356         JoinBestTeam(self, FALSE, FALSE); // if the team number is valid, keep it
1357
1358         if((cvar("sv_spectate") == 1 && !g_lms) || cvar("g_campaign")) {
1359                 self.classname = "observer";
1360         } else {
1361                 if(teams_matter)
1362                 {
1363                         if(cvar("g_balance_teams") || cvar("g_balance_teams_force"))
1364                         {
1365                                 self.classname = "player";
1366                                 campaign_bots_may_start = 1;
1367                         }
1368                         else
1369                         {
1370                                 self.classname = "observer"; // do it anyway
1371                         }
1372                 }
1373                 else
1374                 {
1375                         self.classname = "player";
1376                         campaign_bots_may_start = 1;
1377                 }
1378         }
1379
1380         self.playerid = (playerid_last = playerid_last + 1);
1381
1382         if(cvar("sv_eventlog"))
1383                 GameLogEcho(strcat(":join:", ftos(self.playerid), ":", ftos(num_for_edict(self)), ":", ((clienttype(self) == CLIENTTYPE_REAL) ? self.netaddress : "bot"), ":", self.netname));
1384
1385         LogTeamchange(self.playerid, self.team, 1);
1386
1387         self.just_joined = TRUE;  // stop spamming the eventlog with additional lines when the client connects
1388
1389         self.netname_previous = strzone(self.netname);
1390
1391         bprint("^4", self.netname, "^4 connected");
1392
1393         if(self.classname != "observer" && (g_domination || g_ctf))
1394                 bprint(" and joined the ", ColoredTeamName(self.team));
1395
1396         bprint("\n");
1397
1398         self.welcomemessage_time = 0;
1399
1400         stuffcmd(self, strcat(clientstuff, "\n"));
1401         stuffcmd(self, strcat("exec maps/", mapname, ".cfg\n"));
1402         stuffcmd(self, "cl_particles_reloadeffects\n");
1403
1404         FixClientCvars(self);
1405
1406         // spawnfunc_waypoint sprites
1407         WaypointSprite_InitClient(self);
1408
1409         // Wazat's grappling hook
1410         SetGrappleHookBindings();
1411
1412         // get autoswitch state from player when he toggles it
1413         stuffcmd(self, "alias autoswitch \"set cl_autoswitch $1 ; cmd autoswitch $1\"\n"); // default.cfg-ed in 2.4.1
1414
1415         // get version info from player
1416         stuffcmd(self, "cmd clientversion $gameversion\n");
1417
1418         // get other cvars from player
1419         GetCvars(0);
1420
1421         // set cvar for team scoreboard
1422         stuffcmd(self, strcat("set teamplay ", ftos(teamplay), "\n"));
1423
1424         // notify about available teams
1425         if(teams_matter)
1426         {
1427                 CheckAllowedTeams(self);
1428                 t = 0; if(c1 >= 0) t |= 1; if(c2 >= 0) t |= 2; if(c3 >= 0) t |= 4; if(c4 >= 0) t |= 8;
1429                 stuffcmd(self, strcat("set _teams_available ", ftos(t), "\n"));
1430         }
1431         else
1432                 stuffcmd(self, "set _teams_available 0\n");
1433
1434         stuffcmd(self, strcat("set gametype ", ftos(game), "\n"));
1435
1436         if(g_arena || g_ca)
1437         {
1438                 self.classname = "observer";
1439                 if(g_arena)
1440                         Spawnqueue_Insert(self);
1441         }
1442         /*else if(g_ctf)
1443         {
1444                 ctf_clientconnect();
1445         }*/
1446
1447         if(teams_matter || radar_showennemies)
1448                 attach_entcs();
1449
1450         bot_relinkplayerlist();
1451
1452         self.spectatortime = time;
1453         if(blockSpectators)
1454         {
1455                 sprint(self, strcat("^7You have to become a player within the next ", ftos(cvar("g_maxplayers_spectator_blocktime")), " seconds, otherwise you will be kicked, because spectators aren't allowed at this time!\n"));
1456         }
1457
1458         self.jointime = time;
1459         self.allowedTimeouts = cvar("sv_timeout_number");
1460
1461         if(clienttype(self) == CLIENTTYPE_REAL)
1462         {
1463                 if(cvar("g_bugrigs") || g_weaponarena == WEPBIT_TUBA)
1464                         stuffcmd(self, "cl_cmd settemp chase_active 1\n");
1465         }
1466
1467         if(g_lms)
1468         {
1469                 if(PlayerScore_Add(self, SP_LMS_LIVES, LMS_NewPlayerLives()) <= 0)
1470                 {
1471                         PlayerScore_Add(self, SP_LMS_RANK, 666);
1472                         self.frags = FRAGS_SPECTATOR;
1473                 }
1474         }
1475
1476         if(!sv_foginterval && world.fog != "")
1477                 stuffcmd(self, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1478
1479         SoundEntity_Attach(self);
1480
1481         if(cvar("g_hitplots") || strstrofs(strcat(" ", cvar_string("g_hitplots_individuals"), " "), strcat(" ", self.netaddress, " "), 0) >= 0)
1482         {
1483                 self.hitplotfh = fopen(strcat("hits-", matchid, "-", self.netaddress, "-", ftos(self.playerid), ".plot"), FILE_WRITE);
1484                 fputs(self.hitplotfh, strcat("#name ", self.netname, "\n"));
1485         }
1486         else
1487                 self.hitplotfh = -1;
1488
1489 #ifdef UID
1490         if(clienttype(self) == CLIENTTYPE_REAL)
1491         if not(self.uid)
1492                 self.uid_kicktime = time + 60;
1493 #endif
1494
1495         if(g_race || g_cts) {
1496                 string rr;
1497                 if(g_cts)
1498                         rr = CTS_RECORD;
1499                 else
1500                         rr = RACE_RECORD;
1501                 t = stof(db_get(ServerProgsDB, strcat(GetMapname(), rr, "time")));
1502
1503                 race_send_recordtime(MSG_ONE);
1504                 race_send_speedaward(MSG_ONE);
1505
1506                 speedaward_alltimebest = stof(db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/speed")));
1507                 speedaward_alltimebest_holder = db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/netname"));
1508                 race_send_speedaward_alltimebest(MSG_ONE);
1509
1510                 float i;
1511                 for (i = 1; i <= RANKINGS_CNT; ++i) {
1512                         race_SendRankings(i, 0, 0, MSG_ONE);
1513                 }
1514         }
1515         else if(cvar("sv_teamnagger") && !g_ca) // teamnagger is currently bad for ca
1516                 send_CSQC_teamnagger();
1517
1518         CheatInitClient();
1519 }
1520
1521 /*
1522 =============
1523 ClientDisconnect
1524
1525 Called when a client disconnects from the server
1526 =============
1527 */
1528 .entity chatbubbleentity;
1529 .entity teambubbleentity;
1530 void ReadyCount();
1531 void ClientDisconnect (void)
1532 {
1533         if not(self.flags & FL_CLIENT)
1534         {
1535                 print("Warning: ClientDisconnect without ClientConnect\n");
1536                 return;
1537         }
1538
1539         CheatShutdownClient();
1540
1541         if(self.hitplotfh >= 0)
1542         {
1543                 fclose(self.hitplotfh);
1544                 self.hitplotfh = -1;
1545         }
1546
1547         anticheat_report();
1548         anticheat_shutdown();
1549
1550         playerdemo_shutdown();
1551
1552         bot_clientdisconnect();
1553
1554         if(self.entcs)
1555                 detach_entcs();
1556
1557         if(cvar("sv_eventlog"))
1558                 GameLogEcho(strcat(":part:", ftos(self.playerid)));
1559         bprint ("^4",self.netname);
1560         bprint ("^4 disconnected\n");
1561
1562         SoundEntity_Detach(self);
1563
1564         DropAllRunes(self);
1565         kh_Key_DropAll(self, TRUE);
1566
1567         Portal_ClearAll(self);
1568
1569         if(self.flagcarried)
1570                 DropFlag(self.flagcarried, world, world);
1571         if(self.ballcarried)
1572                 DropBall(self.ballcarried, self.origin + self.ballcarried.origin, self.velocity);
1573
1574         // Here, everything has been done that requires this player to be a client.
1575
1576         self.flags &~= FL_CLIENT;
1577
1578         if (self.chatbubbleentity)
1579                 remove (self.chatbubbleentity);
1580
1581         if (self.teambubbleentity)
1582                 remove (self.teambubbleentity);
1583
1584         if (self.killindicator)
1585                 remove (self.killindicator);
1586
1587         WaypointSprite_PlayerGone();
1588
1589         bot_relinkplayerlist();
1590
1591         // remove laserdot
1592         if(self.weaponentity)
1593                 if(self.weaponentity.lasertarget)
1594                         remove(self.weaponentity.lasertarget);
1595
1596         if(g_arena)
1597         {
1598                 Spawnqueue_Unmark(self);
1599                 Spawnqueue_Remove(self);
1600         }
1601
1602         ClientData_Detach();
1603         PlayerScore_Detach(self);
1604
1605         if(self.netname_previous)
1606                 strunzone(self.netname_previous);
1607         if(self.clientstatus)
1608                 strunzone(self.clientstatus);
1609
1610         ClearPlayerSounds();
1611
1612         if(self.personal)
1613                 remove(self.personal);
1614
1615         self.playerid = 0;
1616         ReadyCount();
1617
1618         // free cvars
1619         GetCvars(-1);
1620 }
1621
1622 .float BUTTON_CHAT;
1623 void ChatBubbleThink()
1624 {
1625         self.nextthink = time;
1626         if (!self.owner.modelindex || self.owner.chatbubbleentity != self)
1627         {
1628                 if(self.owner) // but why can that ever be world?
1629                         self.owner.chatbubbleentity = world;
1630                 remove(self);
1631                 return;
1632         }
1633         if ((self.owner.BUTTON_CHAT && !self.owner.deadflag)
1634 #ifdef TETRIS
1635                 || self.owner.tetris_on
1636 #endif
1637         )
1638                 self.model = self.mdl;
1639         else
1640                 self.model = "";
1641 };
1642
1643 void UpdateChatBubble()
1644 {
1645         if (!self.modelindex)
1646                 return;
1647         // spawn a chatbubble entity if needed
1648         if (!self.chatbubbleentity)
1649         {
1650                 self.chatbubbleentity = spawn();
1651                 self.chatbubbleentity.owner = self;
1652                 self.chatbubbleentity.exteriormodeltoclient = self;
1653                 self.chatbubbleentity.think = ChatBubbleThink;
1654                 self.chatbubbleentity.nextthink = time;
1655                 setmodel(self.chatbubbleentity, "models/misc/chatbubble.spr"); // precision set below
1656                 //setorigin(self.chatbubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1657                 setorigin(self.chatbubbleentity, '0 0 15' + self.maxs_z * '0 0 1');
1658                 setattachment(self.chatbubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1659                 self.chatbubbleentity.mdl = self.chatbubbleentity.model;
1660                 self.chatbubbleentity.model = "";
1661                 self.chatbubbleentity.effects = EF_LOWPRECISION;
1662         }
1663 }
1664
1665
1666 void TeamBubbleThink()
1667 {
1668         self.nextthink = time;
1669         if (!self.owner.modelindex || self.owner.teambubbleentity != self)
1670         {
1671                 if(self.owner) // but why can that ever be world?
1672                         self.owner.teambubbleentity = world;
1673                 remove(self);
1674                 return;
1675         }
1676 //      setorigin(self, self.owner.origin + '0 0 15' + self.owner.maxs_z * '0 0 1');  // bandwidth hog. setattachment does this now
1677         if (self.owner.BUTTON_CHAT || self.owner.deadflag || self.owner.killindicator)
1678                 self.model = "";
1679         else
1680                 self.model = self.mdl;
1681
1682 };
1683
1684 float TeamBubble_customizeentityforclient()
1685 {
1686         return (self.owner != other && self.owner.team == other.team && other.killcount > -666);
1687 }
1688
1689 void UpdateTeamBubble()
1690 {
1691         if (!self.modelindex || !teams_matter)
1692                 return;
1693         // spawn a teambubble entity if needed
1694         if (!self.teambubbleentity && teams_matter)
1695         {
1696                 self.teambubbleentity = spawn();
1697                 self.teambubbleentity.owner = self;
1698                 self.teambubbleentity.exteriormodeltoclient = self;
1699                 self.teambubbleentity.think = TeamBubbleThink;
1700                 self.teambubbleentity.nextthink = time;
1701                 setmodel(self.teambubbleentity, "models/misc/teambubble.spr"); // precision set below
1702 //              setorigin(self.teambubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1703                 setorigin(self.teambubbleentity, '0 0 15' + self.maxs_z * '0 0 1');
1704                 setattachment(self.teambubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1705                 self.teambubbleentity.mdl = self.teambubbleentity.model;
1706                 self.teambubbleentity.model = self.teambubbleentity.mdl;
1707                 self.teambubbleentity.customizeentityforclient = TeamBubble_customizeentityforclient;
1708                 self.teambubbleentity.effects = EF_LOWPRECISION;
1709         }
1710 }
1711
1712 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1713 // added to the model skins
1714 /*void UpdateColorModHack()
1715 {
1716         local float c;
1717         c = self.clientcolors & 15;
1718         // LordHavoc: only bothering to support white, green, red, yellow, blue
1719              if (!teams_matter) self.colormod = '0 0 0';
1720         else if (c ==  0) self.colormod = '1.00 1.00 1.00';
1721         else if (c ==  3) self.colormod = '0.10 1.73 0.10';
1722         else if (c ==  4) self.colormod = '1.73 0.10 0.10';
1723         else if (c == 12) self.colormod = '1.22 1.22 0.10';
1724         else if (c == 13) self.colormod = '0.10 0.10 1.73';
1725         else self.colormod = '1 1 1';
1726 };*/
1727
1728 void respawn(void)
1729 {
1730         CopyBody(1);
1731         self.effects |= EF_NODRAW; // prevent another CopyBody
1732         PutClientInServer();
1733 }
1734
1735 void play_countdown(float finished, string samp)
1736 {
1737         if(clienttype(self) == CLIENTTYPE_REAL)
1738                 if(floor(finished - time - frametime) != floor(finished - time))
1739                         if(finished - time < 6)
1740                                 sound (self, CHAN_AUTO, samp, VOL_BASE, ATTN_NORM);
1741 }
1742
1743 /**
1744  * When sv_timeout is used this function returs strings like
1745  * "Timeout begins in 2 seconds!\n" or "Timeout ends in 23 seconds!\n".
1746  * Called by centerprint functions
1747  * @param addOneSecond boolean, set to 1 if the welcome-message centerprint asks for the text
1748  */
1749 string getTimeoutText(float addOneSecond) {
1750         if (!cvar("sv_timeout") || !timeoutStatus)
1751                 return "";
1752
1753         local string retStr;
1754         if (timeoutStatus == 1) {
1755                 if (addOneSecond == 1) {
1756                         retStr = strcat("Timeout begins in ", ftos(remainingLeadTime + 1), " seconds!\n");
1757                 }
1758                 else {
1759                         retStr = strcat("Timeout begins in ", ftos(remainingLeadTime), " seconds!\n");
1760                 }
1761                 return retStr;
1762         }
1763         else if (timeoutStatus == 2) {
1764                 if (addOneSecond) {
1765                         retStr = strcat("Timeout ends in ", ftos(remainingTimeoutTime + 1), " seconds!\n");
1766                         //don't show messages like "Timeout ends in 0 seconds"...
1767                         if ((remainingTimeoutTime + 1) > 0)
1768                                 return retStr;
1769                         else
1770                                 return "";
1771                 }
1772                 else {
1773                         retStr = strcat("Timeout ends in ", ftos(remainingTimeoutTime), " seconds!\n");
1774                         //don't show messages like "Timeout ends in 0 seconds"...
1775                         if (remainingTimeoutTime > 0)
1776                                 return retStr;
1777                         else
1778                                 return "";
1779                 }
1780         }
1781         else return "";
1782 }
1783
1784 void player_powerups (void)
1785 {
1786         if((self.items & IT_USING_JETPACK) && !self.deadflag)
1787         {
1788                 SoundEntity_StartSound(self, CHAN_PLAYER, "misc/jetpack_fly.wav", VOL_BASE, cvar("g_jetpack_attenuation"));
1789                 self.modelflags |= MF_ROCKET;
1790         }
1791         else
1792         {
1793                 SoundEntity_StopSound(self, CHAN_PLAYER);
1794                 self.modelflags &~= MF_ROCKET;
1795         }
1796
1797         self.effects &~= (EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
1798
1799         if(!self.modelindex || self.deadflag) // don't apply the flags if the player is gibbed
1800                 return;
1801
1802         Fire_ApplyDamage(self);
1803         Fire_ApplyEffect(self);
1804
1805         if (g_minstagib)
1806         {
1807                 self.effects |= EF_FULLBRIGHT;
1808
1809                 if (self.items & IT_STRENGTH)
1810                 {
1811                         play_countdown(self.strength_finished, "misc/poweroff.wav");
1812                         if (time > self.strength_finished)
1813                         {
1814                                 self.alpha = default_player_alpha;
1815                                 self.exteriorweaponentity.alpha = default_weapon_alpha;
1816                                 self.items &~= IT_STRENGTH;
1817                                 sprint(self, "^3Invisibility has worn off\n");
1818                         }
1819                 }
1820                 else
1821                 {
1822                         if (time < self.strength_finished)
1823                         {
1824                                 self.alpha = g_minstagib_invis_alpha;
1825                                 self.exteriorweaponentity.alpha = g_minstagib_invis_alpha;
1826                                 self.items |= IT_STRENGTH;
1827                                 sprint(self, "^3You are invisible\n");
1828                         }
1829                 }
1830
1831                 if (self.items & IT_INVINCIBLE)
1832                 {
1833                         play_countdown(self.invincible_finished, "misc/poweroff.wav");
1834                         if (time > self.invincible_finished && cvar("g_balance_powerup_timer"))
1835                         {
1836                                 self.items = self.items - (self.items & IT_INVINCIBLE);
1837                                 sprint(self, "^3Speed has worn off\n");
1838                         }
1839                 }
1840                 else
1841                 {
1842                         if (time < self.invincible_finished)
1843                         {
1844                                 self.items = self.items | IT_INVINCIBLE;
1845                                 sprint(self, "^3You are on speed\n");
1846                         }
1847                 }
1848                 return;
1849         }
1850
1851         if (self.items & IT_STRENGTH)
1852         {
1853                 play_countdown(self.strength_finished, "misc/poweroff.wav");
1854                 self.effects = self.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1855                 if (time > self.strength_finished && cvar("g_balance_powerup_timer"))
1856                 {
1857                         self.items = self.items - (self.items & IT_STRENGTH);
1858                         sprint(self, "^3Strength has worn off\n");
1859                 }
1860         }
1861         else
1862         {
1863                 if (time < self.strength_finished)
1864                 {
1865                         self.items = self.items | IT_STRENGTH;
1866                         sprint(self, "^3Strength infuses your weapons with devastating power\n");
1867                 }
1868         }
1869         if (self.items & IT_INVINCIBLE)
1870         {
1871                 play_countdown(self.invincible_finished, "misc/poweroff.wav");
1872                 self.effects = self.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1873                 if (time > self.invincible_finished && cvar("g_balance_powerup_timer"))
1874                 {
1875                         self.items = self.items - (self.items & IT_INVINCIBLE);
1876                         sprint(self, "^3Shield has worn off\n");
1877                 }
1878         }
1879         else
1880         {
1881                 if (time < self.invincible_finished)
1882                 {
1883                         self.items = self.items | IT_INVINCIBLE;
1884                         sprint(self, "^3Shield surrounds you\n");
1885                 }
1886         }
1887
1888         if(cvar("g_nodepthtestplayers"))
1889                 self.effects = self.effects | EF_NODEPTHTEST;
1890
1891         if(cvar("g_fullbrightplayers"))
1892                 self.effects = self.effects | EF_FULLBRIGHT;
1893
1894         // midair gamemode: damage only while in the air
1895         // if in midair mode, being on ground grants temporary invulnerability
1896         // (this is so that multishot weapon don't clear the ground flag on the
1897         // first damage in the frame, leaving the player vulnerable to the
1898         // remaining hits in the same frame)
1899         if (self.flags & FL_ONGROUND)
1900         if (g_midair)
1901                 self.spawnshieldtime = max(self.spawnshieldtime, time + cvar("g_midair_shieldtime"));
1902
1903         if (time >= game_starttime)
1904         if (time < self.spawnshieldtime)
1905                 self.effects = self.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1906 }
1907
1908 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
1909 {
1910         if(current > stable)
1911                 return current;
1912         else if(current > stable - 0.25) // when close enough, "snap"
1913                 return stable;
1914         else
1915                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
1916 }
1917
1918 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
1919 {
1920         if(current < stable)
1921                 return current;
1922         else if(current < stable + 0.25) // when close enough, "snap"
1923                 return stable;
1924         else
1925                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
1926 }
1927
1928 float CalcRotRegen(float current, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit)
1929 {
1930         if(current > rotstable)
1931         {
1932                 if(rotframetime > 0)
1933                 {
1934                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
1935                         current = max(rotstable, current - rotlinear * rotframetime);
1936                 }
1937         }
1938         else if(current < regenstable)
1939         {
1940                 if(regenframetime > 0)
1941                 {
1942                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
1943                         current = min(regenstable, current + regenlinear * regenframetime);
1944                 }
1945         }
1946
1947         if(current > limit)
1948                 current = limit;
1949
1950         return current;
1951 }
1952
1953 void player_regen (void)
1954 {
1955         float minh, mina, minf, maxh, maxa, maxf, limith, limita, limitf, max_mod, regen_mod, rot_mod, limit_mod;
1956         maxh = cvar("g_balance_health_rotstable");
1957         maxa = cvar("g_balance_armor_rotstable");
1958         maxf = cvar("g_balance_fuel_rotstable");
1959         minh = cvar("g_balance_health_regenstable");
1960         mina = cvar("g_balance_armor_regenstable");
1961         minf = cvar("g_balance_fuel_regenstable");
1962         limith = cvar("g_balance_health_limit");
1963         limita = cvar("g_balance_armor_limit");
1964         limitf = cvar("g_balance_fuel_limit");
1965
1966         max_mod = regen_mod = rot_mod = limit_mod = 1;
1967
1968         if (self.runes & RUNE_REGEN)
1969         {
1970                 if (self.runes & CURSE_VENOM) // do we have both rune/curse?
1971                 {
1972                         regen_mod = cvar("g_balance_rune_regen_combo_regenrate");
1973                         max_mod = cvar("g_balance_rune_regen_combo_hpmod");
1974                         limit_mod = cvar("g_balance_rune_regen_combo_limitmod");
1975                 }
1976                 else
1977                 {
1978                         regen_mod = cvar("g_balance_rune_regen_regenrate");
1979                         max_mod = cvar("g_balance_rune_regen_hpmod");
1980                         limit_mod = cvar("g_balance_rune_regen_limitmod");
1981                 }
1982         }
1983         else if (self.runes & CURSE_VENOM)
1984         {
1985                 max_mod = cvar("g_balance_curse_venom_hpmod");
1986                 if (self.runes & RUNE_REGEN) // do we have both rune/curse?
1987                         rot_mod = cvar("g_balance_rune_regen_combo_rotrate");
1988                 else
1989                         rot_mod = cvar("g_balance_curse_venom_rotrate");
1990                 limit_mod = cvar("g_balance_curse_venom_limitmod");
1991                 //if (!self.runes & RUNE_REGEN)
1992                 //      rot_mod = cvar("g_balance_curse_venom_rotrate");
1993         }
1994         maxh = maxh * max_mod;
1995         //maxa = maxa * max_mod;
1996         //maxf = maxf * max_mod;
1997         minh = minh * max_mod;
1998         //mina = mina * max_mod;
1999         //minf = minf * max_mod;
2000         limith = limith * limit_mod;
2001         limita = limita * limit_mod;
2002         //limitf = limitf * limit_mod;
2003
2004         if(g_lms && g_ca)
2005                 rot_mod = 0;
2006
2007         if (!g_minstagib && !g_ca && (!g_lms || cvar("g_lms_regenerate")))
2008         {
2009                 self.armorvalue = CalcRotRegen(self.armorvalue, mina, cvar("g_balance_armor_regen"), cvar("g_balance_armor_regenlinear"), regen_mod * frametime * (time > self.pauseregen_finished), maxa, cvar("g_balance_armor_rot"), cvar("g_balance_armor_rotlinear"), rot_mod * frametime * (time > self.pauserotarmor_finished), limita);
2010                 self.health = CalcRotRegen(self.health, minh, cvar("g_balance_health_regen"), cvar("g_balance_health_regenlinear"), regen_mod * frametime * (time > self.pauseregen_finished), maxh, cvar("g_balance_health_rot"), cvar("g_balance_health_rotlinear"), rot_mod * frametime * (time > self.pauserothealth_finished), limith);
2011
2012                 // if player rotted to death...  die!
2013                 if(self.health < 1)
2014                         self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
2015         }
2016
2017         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
2018                 self.ammo_fuel = CalcRotRegen(self.ammo_fuel, minf, cvar("g_balance_fuel_regen"), cvar("g_balance_fuel_regenlinear"), regen_mod * frametime * (time > self.pauseregen_finished) * (self.items & IT_FUEL_REGEN != 0), maxf, cvar("g_balance_fuel_rot"), cvar("g_balance_fuel_rotlinear"), rot_mod * frametime * (time > self.pauserotfuel_finished), limitf);
2019 }
2020
2021 float zoomstate_set;
2022 void SetZoomState(float z)
2023 {
2024         if(z != self.zoomstate)
2025         {
2026                 self.zoomstate = z;
2027                 ClientData_Touch(self);
2028         }
2029         zoomstate_set = 1;
2030 }
2031
2032 void GetPressedKeys(void) {
2033         if (self.movement_x > 0) // get if movement keys are pressed
2034         {       // forward key pressed
2035                 self.pressedkeys |= KEY_FORWARD;
2036                 self.pressedkeys &~= KEY_BACKWARD;
2037         }
2038         else if (self.movement_x < 0)
2039         {       // backward key pressed
2040                 self.pressedkeys |= KEY_BACKWARD;
2041                 self.pressedkeys &~= KEY_FORWARD;
2042         }
2043         else
2044         {       // no x input
2045                 self.pressedkeys &~= KEY_FORWARD;
2046                 self.pressedkeys &~= KEY_BACKWARD;
2047         }
2048
2049         if (self.movement_y > 0)
2050         {       // right key pressed
2051                 self.pressedkeys |= KEY_RIGHT;
2052                 self.pressedkeys &~= KEY_LEFT;
2053         }
2054         else if (self.movement_y < 0)
2055         {       // left key pressed
2056                 self.pressedkeys |= KEY_LEFT;
2057                 self.pressedkeys &~= KEY_RIGHT;
2058         }
2059         else
2060         {       // no y input
2061                 self.pressedkeys &~= KEY_RIGHT;
2062                 self.pressedkeys &~= KEY_LEFT;
2063         }
2064
2065         if (self.BUTTON_JUMP) // get if jump and crouch keys are pressed
2066                 self.pressedkeys |= KEY_JUMP;
2067         else
2068                 self.pressedkeys &~= KEY_JUMP;
2069         if (self.BUTTON_CROUCH)
2070                 self.pressedkeys |= KEY_CROUCH;
2071         else
2072                 self.pressedkeys &~= KEY_CROUCH;
2073 }
2074
2075 void update_stats (float number, float hit, float fired) {
2076 // self.stat_hit   = number + ((number==0) ? 1 : 64) * hit   * sv_accuracy_data_share;
2077 // self.stat_fired = number + ((number==0) ? 1 : 64) * fired * sv_accuracy_data_share;
2078
2079         if(number) {
2080                 self.stat_hit = number + 64 * hit * sv_accuracy_data_share;
2081                 self.stat_fired = number + 64 * fired * sv_accuracy_data_share;
2082         } else {
2083                 self.stat_hit = hit * sv_accuracy_data_share;
2084                 self.stat_fired = fired * sv_accuracy_data_share;
2085         }
2086 }
2087
2088 /*
2089 ======================
2090 spectate mode routines
2091 ======================
2092 */
2093
2094 .float weapon_count;
2095 void SpectateCopy(entity spectatee) {
2096         if(spectatee.weapon_count < WEP_LAST) {
2097                 update_stats (spectatee.weapon_count, spectatee.cvar_cl_accuracy_data_share * floor(spectatee.stats_hit[spectatee.weapon_count - 1]), spectatee.cvar_cl_accuracy_data_share * floor(spectatee.stats_fired[spectatee.weapon_count - 1]));
2098                 spectatee.weapon_count ++;
2099         } else
2100                 update_stats (0, spectatee.cvar_cl_accuracy_data_share * spectatee.stat_hit, spectatee.cvar_cl_accuracy_data_share * spectatee.stat_fired);
2101
2102         self.kh_state = spectatee.kh_state;
2103         self.armortype = spectatee.armortype;
2104         self.armorvalue = spectatee.armorvalue;
2105         self.ammo_cells = spectatee.ammo_cells;
2106         self.ammo_shells = spectatee.ammo_shells;
2107         self.ammo_nails = spectatee.ammo_nails;
2108         self.ammo_rockets = spectatee.ammo_rockets;
2109         self.ammo_fuel = spectatee.ammo_fuel;
2110         self.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
2111         self.health = spectatee.health;
2112         self.impulse = 0;
2113         self.items = spectatee.items;
2114         self.metertime = spectatee.metertime;
2115         self.strength_finished = spectatee.strength_finished;
2116         self.invincible_finished = spectatee.invincible_finished;
2117         self.pressedkeys = spectatee.pressedkeys;
2118         self.weapons = spectatee.weapons;
2119         self.switchweapon = spectatee.switchweapon;
2120         self.weapon = spectatee.weapon;
2121         self.punchangle = spectatee.punchangle;
2122         self.view_ofs = spectatee.view_ofs;
2123         self.v_angle = spectatee.v_angle;
2124         self.velocity = spectatee.velocity;
2125         self.dmg_take = spectatee.dmg_take;
2126         self.dmg_save = spectatee.dmg_save;
2127         self.dmg_inflictor = spectatee.dmg_inflictor;
2128         self.angles = spectatee.v_angle;
2129         self.fixangle = TRUE;
2130         setorigin(self, spectatee.origin);
2131         setsize(self, spectatee.mins, spectatee.maxs);
2132         SetZoomState(spectatee.zoomstate);
2133
2134         anticheat_spectatecopy(spectatee);
2135 }
2136
2137 float SpectateUpdate() {
2138         if(!self.enemy)
2139                 return 0;
2140
2141         if (self == self.enemy)
2142                 return 0;
2143
2144         if(self.enemy.classname != "player")
2145                 return 0;
2146
2147         SpectateCopy(self.enemy);
2148
2149         return 1;
2150 }
2151
2152 float SpectateNext() {
2153         other = find(self.enemy, classname, "player");
2154
2155         if (!other)
2156                 other = find(other, classname, "player");
2157
2158         if (other)
2159                 self.enemy = other;
2160
2161         if(self.enemy.classname == "player") {
2162                 msg_entity = self;
2163                 WriteByte(MSG_ONE, SVC_SETVIEW);
2164                 WriteEntity(MSG_ONE, self.enemy);
2165                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
2166                 self.movetype = MOVETYPE_NONE;
2167
2168                 self.enemy.weapon_count = 0;
2169
2170                 if(!SpectateUpdate())
2171                         PutObserverInServer();
2172
2173                 return 1;
2174         } else {
2175                 return 0;
2176         }
2177 }
2178
2179 /*
2180 =============
2181 ShowRespawnCountdown()
2182
2183 Update a respawn countdown display.
2184 =============
2185 */
2186 void ShowRespawnCountdown()
2187 {
2188         float number;
2189         if(self.deadflag == DEAD_NO) // just respawned?
2190                 return;
2191         else
2192         {
2193                 number = ceil(self.death_time - time);
2194                 if(number <= 0)
2195                         return;
2196                 if(number <= self.respawn_countdown)
2197                 {
2198                         self.respawn_countdown = number - 1;
2199                         if(ceil(self.death_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
2200                                 announce(self, strcat("announcer/robotic/", ftos(number), ".wav"));
2201                 }
2202         }
2203 }
2204
2205 void LeaveSpectatorMode()
2206 {
2207         if(isJoinAllowed()) {
2208                 if(!teams_matter || cvar("g_campaign") || cvar("g_balance_teams") || (self.wasplayer && cvar("g_changeteam_banned"))) {
2209                         self.classname = "player";
2210
2211                         if(cvar("g_campaign") || cvar("g_balance_teams") || cvar("g_balance_teams_force"))
2212                                 JoinBestTeam(self, FALSE, TRUE);
2213
2214                         if(cvar("g_campaign"))
2215                                 campaign_bots_may_start = 1;
2216
2217                         self.stat_count = WEP_LAST;
2218
2219                         PutClientInServer();
2220
2221                         if(self.classname == "player")
2222                                 bprint ("^4", self.netname, "^4 is playing now\n");
2223
2224                         if(!cvar("g_campaign"))
2225                                 centerprint(self,""); // clear MOTD
2226
2227                         return;
2228                 } else {
2229                         if (g_ca && self.caplayer) {
2230                         }       // do nothing
2231                         else
2232                                 stuffcmd(self,"menu_showteamselect\n");
2233                         return;
2234                 }
2235         }
2236         else {
2237                 //player may not join because of g_maxplayers is set
2238                 centerprint_atprio(self, CENTERPRIO_MAPVOTE, PREVENT_JOIN_TEXT);
2239         }
2240 }
2241
2242 /**
2243  * Determines whether the player is allowed to join. This depends on cvar
2244  * g_maxplayers, if it isn't used this function always return TRUE, otherwise
2245  * it checks whether the number of currently playing players exceeds g_maxplayers.
2246  * @return bool TRUE if the player is allowed to join, false otherwise
2247  */
2248 float isJoinAllowed() {
2249         if (!cvar("g_maxplayers"))
2250                 return TRUE;
2251
2252         local entity e;
2253         local float currentlyPlaying;
2254         FOR_EACH_REALPLAYER(e) {
2255                 if(e.classname == "player")
2256                         currentlyPlaying += 1;
2257         }
2258         if(currentlyPlaying < cvar("g_maxplayers"))
2259                 return TRUE;
2260
2261         return FALSE;
2262 }
2263
2264 /**
2265  * Checks whether the client is an observer or spectator, if so, he will get kicked after
2266  * g_maxplayers_spectator_blocktime seconds
2267  */
2268 void checkSpectatorBlock() {
2269         if(self.classname == "spectator" || self.classname == "observer") {
2270                 if( time > (self.spectatortime + cvar("g_maxplayers_spectator_blocktime")) ) {
2271                         sprint(self, "^7You were kicked from the server because you are spectator and spectators aren't allowed at the moment.\n");
2272                         dropclient(self);
2273                 }
2274         }
2275 }
2276
2277 float vercmp_recursive(string v1, string v2)
2278 {
2279         float dot1, dot2;
2280         string s1, s2;
2281         float r;
2282
2283         dot1 = strstrofs(v1, ".", 0);
2284         dot2 = strstrofs(v2, ".", 0);
2285         if(dot1 == -1)
2286                 s1 = v1;
2287         else
2288                 s1 = substring(v1, 0, dot1);
2289         if(dot2 == -1)
2290                 s2 = v2;
2291         else
2292                 s2 = substring(v2, 0, dot2);
2293
2294         r = stof(s1) - stof(s2);
2295         if(r != 0)
2296                 return r;
2297
2298         r = strcasecmp(s1, s2);
2299         if(r != 0)
2300                 return r;
2301
2302         if(dot1 == -1)
2303                 if(dot2 == -1)
2304                         return 0;
2305                 else
2306                         return -1;
2307         else
2308                 if(dot2 == -1)
2309                         return 1;
2310                 else
2311                         return vercmp_recursive(substring(v1, dot1 + 1, 999), substring(v2, dot2 + 1, 999));
2312 }
2313
2314 float vercmp(string v1, string v2)
2315 {
2316         if(strcasecmp(v1, v2) == 0) // early out check
2317                 return 0;
2318         return vercmp_recursive(v1, v2);
2319 }
2320
2321 void ObserverThink()
2322 {
2323         if (self.flags & FL_JUMPRELEASED) {
2324                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2325                         self.welcomemessage_time = 0;
2326                         self.flags &~= FL_JUMPRELEASED;
2327                         self.flags |= FL_SPAWNING;
2328                 } else if(self.BUTTON_ATCK && !self.version_mismatch) {
2329                         self.welcomemessage_time = 0;
2330                         self.flags &~= FL_JUMPRELEASED;
2331                         if(SpectateNext() == 1) {
2332                                 self.classname = "spectator";
2333                         }
2334                 }
2335         } else {
2336                 if (!(self.BUTTON_ATCK || self.BUTTON_JUMP)) {
2337                         self.flags |= FL_JUMPRELEASED;
2338                         if(self.flags & FL_SPAWNING)
2339                         {
2340                                 self.flags &~= FL_SPAWNING;
2341                                 LeaveSpectatorMode();
2342                                 return;
2343                         }
2344                 }
2345         }
2346         PrintWelcomeMessage(self);
2347 }
2348
2349 void SpectatorThink()
2350 {
2351         if (self.flags & FL_JUMPRELEASED) {
2352                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2353                         self.welcomemessage_time = 0;
2354                         self.flags &~= FL_JUMPRELEASED;
2355                         self.flags |= FL_SPAWNING;
2356                 } else if(self.BUTTON_ATCK) {
2357                         self.welcomemessage_time = 0;
2358                         self.flags &~= FL_JUMPRELEASED;
2359                         if(SpectateNext() == 1) {
2360                                 self.classname = "spectator";
2361                         } else {
2362                                 self.classname = "observer";
2363                                 self.stat_count = WEP_LAST;
2364                                 PutClientInServer();
2365                         }
2366                 } else if (self.BUTTON_ATCK2) {
2367                         self.welcomemessage_time = 0;
2368                         self.flags &~= FL_JUMPRELEASED;
2369                         self.classname = "observer";
2370                         self.stat_count = WEP_LAST;
2371                         PutClientInServer();
2372                 } else {
2373                         if(!SpectateUpdate())
2374                                 PutObserverInServer();
2375                 }
2376         } else {
2377                 if (!(self.BUTTON_ATCK || self.BUTTON_ATCK2)) {
2378                         self.flags |= FL_JUMPRELEASED;
2379                         if(self.flags & FL_SPAWNING)
2380                         {
2381                                 self.flags &~= FL_SPAWNING;
2382                                 LeaveSpectatorMode();
2383                                 return;
2384                         }
2385                 }
2386         }
2387
2388         PrintWelcomeMessage(self);
2389         self.flags |= FL_CLIENT | FL_NOTARGET;
2390 }
2391
2392 .float touchexplode_time;
2393
2394 /*
2395 =============
2396 PlayerPreThink
2397
2398 Called every frame for each client before the physics are run
2399 =============
2400 */
2401 void() ctf_setstatus;
2402 void() nexball_setstatus;
2403 .float items_added;
2404 void PlayerPreThink (void)
2405 {
2406         self.stat_game_starttime = game_starttime;
2407         self.stat_allow_oldnexbeam = cvar("g_allow_oldnexbeam");
2408         self.stat_leadlimit = cvar("leadlimit");
2409
2410         if(frametime)
2411         {
2412                 // physics frames: update anticheat stuff
2413                 anticheat_prethink();
2414         }
2415
2416         if(blockSpectators && frametime)
2417                 // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2418                 checkSpectatorBlock();
2419
2420         zoomstate_set = 0;
2421
2422         if(self.netname_previous != self.netname)
2423         {
2424                 if(cvar("sv_eventlog"))
2425                         GameLogEcho(strcat(":name:", ftos(self.playerid), ":", self.netname));
2426                 if(self.netname_previous)
2427                         strunzone(self.netname_previous);
2428                 self.netname_previous = strzone(self.netname);
2429         }
2430
2431         // version nagging
2432         if(self.version_nagtime)
2433                 if(self.cvar_g_nexuizversion)
2434                         if(time > self.version_nagtime)
2435                         {
2436                                 if(strstr(self.cvar_g_nexuizversion, "svn", 0) < 0)
2437                                 {
2438                                         if(strstr(cvar_string("g_nexuizversion"), "svn", 0) >= 0)
2439                                         {
2440                                                 dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Nexuiz ", cvar_string("g_nexuizversion"), " (beta)^7, you have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1\n");
2441                                                 sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Nexuiz ", cvar_string("g_nexuizversion"), " (beta)^7, you have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1\n"));
2442                                         }
2443                                         else
2444                                         {
2445                                                 float r;
2446                                                 r = vercmp(self.cvar_g_nexuizversion, cvar_string("g_nexuizversion"));
2447                                                 if(r < 0)
2448                                                 {
2449                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - ^3Nexuiz ", cvar_string("g_nexuizversion"), "^7 is out, and you still have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1 - get the update from ^4http://www.nexuiz.com/^1!\n");
2450                                                         sprint(self, strcat("\{1}^1NOTE: ^3Nexuiz ", cvar_string("g_nexuizversion"), "^7 is out, and you still have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1 - get the update from ^4http://www.nexuiz.com/^1!\n"));
2451                                                 }
2452                                                 else if(r > 0)
2453                                                 {
2454                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Nexuiz ", cvar_string("g_nexuizversion"), "^7, you have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1\n");
2455                                                         sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Nexuiz ", cvar_string("g_nexuizversion"), "^7, you have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1\n"));
2456                                                 }
2457                                         }
2458                                 }
2459                                 self.version_nagtime = 0;
2460                         }
2461
2462         // GOD MODE info
2463         if(!(self.flags & FL_GODMODE)) if(self.max_armorvalue)
2464         {
2465                 sprint(self, strcat("godmode saved you ", ftos(self.max_armorvalue), " units of damage, cheater!\n"));
2466                 self.max_armorvalue = 0;
2467         }
2468
2469 #ifdef TETRIS
2470         if (TetrisPreFrame())
2471                 return;
2472 #endif
2473
2474         if(self.classname == "player") {
2475 //              if(self.netname == "Wazat")
2476 //                      bprint(self.classname, "\n");
2477
2478                 CheckRules_Player();
2479
2480                 PrintWelcomeMessage(self);
2481
2482                 if (intermission_running)
2483                 {
2484                         IntermissionThink ();   // otherwise a button could be missed between
2485                         return;                                 // the think tics
2486                 }
2487
2488                 if(self.teleport_time)
2489                 if(time > self.teleport_time)
2490                 {
2491                         self.teleport_time = 0;
2492                         self.effects = self.effects - (self.effects & EF_NODRAW);
2493                 }
2494
2495                 Nixnex_GiveCurrentWeapon();
2496
2497                 if(frametime > 0) // don't do this in cl_movement frames, just in server ticks
2498                         UpdateSelectedPlayer();
2499
2500                 //don't allow the player to turn around while game is paused!
2501                 if(timeoutStatus == 2) {
2502                         self.v_angle = self.lastV_angle;
2503                         self.angles = self.lastV_angle;
2504                         self.fixangle = TRUE;
2505                 }
2506
2507                 if(frametime)
2508                 {
2509                         if(cvar("gameversion") >= 20600) // only do this for 2.6 and above FIXME remove this check when making 2.6
2510                                 self.glowmod = colormapPaletteColor(self.clientcolors & 0x0F, TRUE) * 2;
2511                         player_powerups();
2512                 }
2513
2514                 if (self.deadflag != DEAD_NO)
2515                 {
2516                         float button_pressed, force_respawn;
2517                         if(self.personal && g_race_qualifying)
2518                         {
2519                                 if(time > self.death_time)
2520                                 {
2521                                         self.death_time = time + 1; // only retry once a second
2522                                         respawn();
2523                                         self.impulse = 141;
2524                                 }
2525                         }
2526                         else
2527                         {
2528                                 if(frametime)
2529                                         player_anim();
2530                                 button_pressed = (self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE);
2531                                 force_respawn = (g_lms || (g_ca) || cvar("g_forced_respawn"));
2532                                 if (self.deadflag == DEAD_DYING)
2533                                 {
2534                                         if(force_respawn)
2535                                                 self.deadflag = DEAD_RESPAWNING;
2536                                         else if(!button_pressed)
2537                                                 self.deadflag = DEAD_DEAD;
2538                                 }
2539                                 else if (self.deadflag == DEAD_DEAD)
2540                                 {
2541                                         if(button_pressed)
2542                                                 self.deadflag = DEAD_RESPAWNABLE;
2543                                 }
2544                                 else if (self.deadflag == DEAD_RESPAWNABLE)
2545                                 {
2546                                         if(!button_pressed)
2547                                                 self.deadflag = DEAD_RESPAWNING;
2548                                 }
2549                                 else if (self.deadflag == DEAD_RESPAWNING)
2550                                 {
2551                                         if(time > self.death_time)
2552                                         {
2553                                                 self.death_time = time + 1; // only retry once a second
2554                                                 respawn();
2555                                         }
2556                                 }
2557                                 ShowRespawnCountdown();
2558                         }
2559                         return;
2560                 }
2561
2562                 if(g_touchexplode)
2563                 if(time > self.touchexplode_time)
2564                 if(self.classname == "player")
2565                 if(self.deadflag == DEAD_NO)
2566                 if not(IS_INDEPENDENT_PLAYER(self))
2567                 FOR_EACH_PLAYER(other) if(self != other)
2568                 {
2569                         if(time > other.touchexplode_time)
2570                         if(other.classname == "player")
2571                         if(other.deadflag == DEAD_NO)
2572                         if not(IS_INDEPENDENT_PLAYER(other))
2573                         if(boxesoverlap(self.absmin, self.absmax, other.absmin, other.absmax))
2574                         {
2575                                 PlayerTouchExplode(self, other);
2576                                 self.touchexplode_time = other.touchexplode_time = time + 0.2;
2577                         }
2578                 }
2579
2580                 if(g_lms && !self.deadflag && cvar("g_lms_campcheck_interval"))
2581                 {
2582                         vector dist;
2583
2584                         // calculate player movement (in 2 dimensions only, so jumping on one spot doesn't count as movement)
2585                         dist = self.prevorigin - self.origin;
2586                         dist_z = 0;
2587                         self.lms_traveled_distance += fabs(vlen(dist));
2588
2589                         if((cvar("g_campaign") && !campaign_bots_may_start) || (time < game_starttime))
2590                         {
2591                                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval")*2;
2592                                 self.lms_traveled_distance = 0;
2593                         }
2594
2595                         if(time > self.lms_nextcheck)
2596                         {
2597                                 //sprint(self, "distance: ", ftos(self.lms_traveled_distance), "\n");
2598                                 if(self.lms_traveled_distance < cvar("g_lms_campcheck_distance"))
2599                                 {
2600                                         centerprint(self, cvar_string("g_lms_campcheck_message"));
2601                                         // FIXME KadaverJack: gibbing player here causes playermodel to bounce around, instead of eye.md3
2602                                         // I wasn't able to find out WHY that happens, so I put a workaround in place that shall prevent players from being gibbed :(
2603                                         Damage(self, self, self, bound(0, cvar("g_lms_campcheck_damage"), self.health + self.armorvalue * cvar("g_balance_armor_blockpercent") + 5), DEATH_CAMP, self.origin, '0 0 0');
2604                                 }
2605                                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval");
2606                                 self.lms_traveled_distance = 0;
2607                         }
2608                 }
2609
2610                 self.prevorigin = self.origin;
2611
2612                 if ((self.BUTTON_CROUCH && !self.hook.state) || self.health <= g_bloodloss)
2613                 {
2614                         if (!self.crouch)
2615                         {
2616                                 self.crouch = TRUE;
2617                                 self.view_ofs = PL_CROUCH_VIEW_OFS;
2618                                 setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX);
2619                                 setanim(self, self.anim_duck, FALSE, TRUE, TRUE);
2620                         }
2621                 }
2622                 else
2623                 {
2624                         if (self.crouch)
2625                         {
2626                                 tracebox(self.origin, PL_MIN, PL_MAX, self.origin, FALSE, self);
2627                                 if (!trace_startsolid)
2628                                 {
2629                                         self.crouch = FALSE;
2630                                         self.view_ofs = PL_VIEW_OFS;
2631                                         setsize (self, PL_MIN, PL_MAX);
2632                                 }
2633                         }
2634                 }
2635
2636                 if(self.health <= g_bloodloss && self.deadflag == DEAD_NO)
2637                 {
2638                         if(self.bloodloss_timer < time)
2639                         {
2640                                 self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
2641                                 self.bloodloss_timer = time + 0.5 + random() * 0.5;
2642                         }
2643                 }
2644
2645                 FixPlayermodel();
2646
2647                 GrapplingHookFrame();
2648
2649                 // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2650                 //if(frametime)
2651                 {
2652                         self.items &~= self.items_added;
2653
2654                         W_WeaponFrame();
2655
2656                         self.items_added = 0;
2657                         if(self.items & IT_JETPACK)
2658                                 if(self.items & IT_FUEL_REGEN || self.ammo_fuel >= 0.01)
2659                                         self.items_added |= IT_FUEL;
2660
2661                         self.items |= self.items_added;
2662                 }
2663
2664                 player_regen();
2665                 if(frametime)
2666                         player_anim();
2667
2668                 if (g_minstagib)
2669                         minstagib_ammocheck();
2670
2671                 ctf_setstatus();
2672                 nexball_setstatus();
2673
2674                 self.dmg_team = max(0, self.dmg_team - cvar("g_teamdamage_resetspeed") * frametime);
2675
2676                 //self.angles_y=self.v_angle_y + 90;   // temp
2677         } else if(gameover) {
2678                 if (intermission_running)
2679                         IntermissionThink ();   // otherwise a button could be missed between
2680                 return;
2681         } else if(self.classname == "observer") {
2682                 ObserverThink();
2683         } else if(self.classname == "spectator") {
2684                 SpectatorThink();
2685         }
2686
2687         if(!zoomstate_set)
2688                 SetZoomState(self.BUTTON_ZOOM || (self.BUTTON_ATCK2 && self.weapon == WEP_NEX));
2689
2690         float oldspectatee_status;
2691         oldspectatee_status = self.spectatee_status;
2692         if(self.classname == "spectator")
2693                 self.spectatee_status = num_for_edict(self.enemy);
2694         else if(self.classname == "observer")
2695                 self.spectatee_status = num_for_edict(self);
2696         else
2697                 self.spectatee_status = 0;
2698         if(self.spectatee_status != oldspectatee_status)
2699         {
2700                 ClientData_Touch(self);
2701                 if(g_race || g_cts)
2702                         race_InitSpectator();
2703         }
2704
2705         if(self.teamkill_soundtime)
2706         if(time > self.teamkill_soundtime)
2707         {
2708                 self.teamkill_soundtime = 0;
2709
2710                 entity oldpusher, oldself;
2711
2712                 oldself = self; self = self.teamkill_soundsource;
2713                 oldpusher = self.pusher; self.pusher = oldself;
2714
2715                 PlayerSound(playersound_teamshoot, CHAN_VOICE, VOICETYPE_LASTATTACKER_ONLY);
2716
2717                 self.pusher = oldpusher;
2718                 self = oldself;
2719         }
2720
2721         if(self.taunt_soundtime)
2722         if(time > self.taunt_soundtime)
2723         {
2724                 self.taunt_soundtime = 0;
2725                 PlayerSound(playersound_taunt, CHAN_VOICE, VOICETYPE_AUTOTAUNT);
2726         }
2727
2728         target_voicescript_next(self);
2729 }
2730
2731 float isInvisibleString(string s)
2732 {
2733         float i, n, c;
2734         s = strdecolorize(s);
2735         for((i = 0), (n = strlen(s)); i < n; ++i)
2736         {
2737                 c = str2chr(s, i);
2738                 switch(c)
2739                 {
2740                         case 0:
2741                         case 32:
2742                         case 160:
2743                                 break;
2744                         default:
2745                                 return FALSE;
2746                 }
2747         }
2748         return TRUE;
2749 }
2750
2751 /*
2752 =============
2753 PlayerPostThink
2754
2755 Called every frame for each client after the physics are run
2756 =============
2757 */
2758 .float idlekick_lasttimeleft;
2759 void PlayerPostThink (void)
2760 {
2761         // Savage: Check for nameless players
2762         if (isInvisibleString(self.netname)) {
2763                 self.netname = "Player";
2764                 stuffcmd(self, strcat("name ", self.netname, substring(ftos(random()), 2, -1), "\n"));
2765         }
2766
2767         // send the clients accuracy stats to the client
2768         if(self.stat_count > 0)
2769         if(frametime)
2770         {
2771                 self.stat_hit = self.stat_count + 64 * floor(self.(stats_hit[self.stat_count - 1]));
2772                 self.stat_fired = self.stat_count + 64 * floor(self.(stats_fired[self.stat_count - 1]));
2773                 self.stat_count -= 1;
2774         }
2775
2776 #ifdef UID
2777         if(self.uid_kicktime)
2778         if(time > self.uid_kicktime)
2779         {
2780                 bprint("^3", self.netname, "^3 was kicked for missing UID.\n");
2781                 dropclient(self);
2782                 return;
2783         }
2784 #endif
2785
2786         if(sv_maxidle && frametime)
2787         {
2788                 // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2789                 float timeleft;
2790                 timeleft = ceil(sv_maxidle - (time - self.parm_idlesince));
2791                 if(timeleft <= 0)
2792                 {
2793                         bprint("^3", self.netname, "^3 was kicked for idling.\n");
2794                         announce(self, "announcer/robotic/terminated.wav");
2795                         dropclient(self);
2796                         return;
2797                 }
2798                 else if(timeleft <= 10)
2799                 {
2800                         if(timeleft != self.idlekick_lasttimeleft)
2801                         {
2802                                 centerprint_atprio(self, CENTERPRIO_IDLEKICK, strcat("^3Stop idling!\n^3Disconnecting in ", ftos(timeleft), "..."));
2803                                 announce(self, strcat("announcer/robotic/", ftos(timeleft), ".wav"));
2804                         }
2805                 }
2806                 else
2807                 {
2808                         centerprint_expire(self, CENTERPRIO_IDLEKICK);
2809                 }
2810                 self.idlekick_lasttimeleft = timeleft;
2811         }
2812
2813 #ifdef TETRIS
2814         if(self.impulse == 100)
2815                 ImpulseCommands();
2816         if (TetrisPostFrame())
2817                 return;
2818 #endif
2819
2820         CheatFrame();
2821
2822         if(self.classname == "player") {
2823                 CheckRules_Player();
2824                 UpdateChatBubble();
2825                 UpdateTeamBubble();
2826                 if (self.impulse)
2827                         ImpulseCommands();
2828                 if (intermission_running)
2829                         return;         // intermission or finale
2830
2831                 GetPressedKeys();
2832         } else if (self.classname == "observer") {
2833                 //do nothing
2834         } else if (self.classname == "spectator") {
2835                 //do nothing
2836         }
2837
2838         /*
2839         float i;
2840         for(i = 0; i < 1000; ++i)
2841         {
2842                 vector end;
2843                 end = self.origin + '0 0 1024' + 512 * randomvec();
2844                 tracebox(self.origin, self.mins, self.maxs, end, MOVE_NORMAL, self);
2845                 if(trace_fraction < 1)
2846                 if(!(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
2847                 {
2848                         print("I HIT SOLID: ", vtos(self.origin), " -> ", vtos(end), "\n");
2849                         break;
2850                 }
2851         }
2852         */
2853
2854         Arena_Warmup();
2855
2856         //pointparticles(particleeffectnum("machinegun_impact"), self.origin + self.view_ofs + '0 0 7', '0 0 0', 1);
2857
2858         if(self.waypointsprite_attachedforcarrier)
2859                 WaypointSprite_UpdateHealth(self.waypointsprite_attachedforcarrier, '1 0 0' * healtharmor_maxdamage(self.health, self.armorvalue, cvar("g_balance_armor_blockpercent")));
2860
2861         playerdemo_write();
2862
2863         /*
2864         if(g_race)
2865                 dprint(sprintf("%f %.6f\n", time, race_GetFractionalLapCount(self)));
2866         */
2867 }