data/qcsrc/server/cheats.qc

   1 void CopyBody(float keepvelocity);
   2
   3 .float maycheat;
   4 float sv_cheats;
   5 float autocvar_sv_cheats;
   6
   7 #define CHIMPULSE_SPEEDRUN_INIT 30
   8 #define CHIMPULSE_GIVE_ALL 99
   9 #define CHIMPULSE_CLONE_MOVING 140
  10 #define CHIMPULSE_SPEEDRUN 141
  11 #define CHIMPULSE_CLONE_STANDING 142
  12 #define CHIMPULSE_TELEPORT 143
  13 #define CHIMPULSE_R00T 148
  14
  15 #define CHRAME_DRAG 1
  16
  17 float CheatsAllowed(float i, float argc, float fr) // the cheat gets passed as argument for possible future ACL checking
  18 {
  19         if(i == CHIMPULSE_CLONE_MOVING || i == CHIMPULSE_CLONE_STANDING)
  20                 if(self.lip < sv_clones)
  21                         goto allow;
  22         if(self.maycheat)
  23                 return 1;
  24         if(sv_cheats && autocvar_sv_cheats)
  25                 return 1;
  26         if(autocvar_sv_cheats)
  27                 sprint(self, "Cheats are not yet allowed, and will be activated at next map change.\n");
  28         return 0;
  29 }
  30
  31 float CheatImpulse(float i)
  32 {
  33         if not(CheatsAllowed(i, 0, 0))
  34                 return 0;
  35         switch(i)
  36         {
  37                 float wep;
  38                 entity e, e2;
  39                 vector org;
  40
  41                 case CHIMPULSE_SPEEDRUN_INIT: // deploy personal waypoint
  42                         if(!self.personal)
  43                         {
  44                                 self.personal = spawn();
  45                                 self.personal.classname = "personal_wp";
  46                         }
  47                         self.personal.origin = self.origin;
  48                         self.personal.v_angle = self.v_angle;
  49                         self.personal.velocity = self.velocity;
  50                         self.personal.ammo_rockets = self.ammo_rockets;
  51                         self.personal.ammo_nails = self.ammo_nails;
  52                         self.personal.ammo_cells = self.ammo_cells;
  53                         self.personal.ammo_shells = self.ammo_shells;
  54                         self.personal.ammo_fuel = self.ammo_fuel;
  55                         self.personal.health = self.health;
  56                         self.personal.armorvalue = self.armorvalue;
  57                         self.personal.weapons = self.weapons;
  58                         self.personal.items = self.items;
  59                         self.personal.pauserotarmor_finished = self.pauserotarmor_finished;
  60                         self.personal.pauserothealth_finished = self.pauserothealth_finished;
  61                         self.personal.pauserotfuel_finished = self.pauserotfuel_finished;
  62                         self.personal.pauseregen_finished = self.pauseregen_finished;
  63                         self.personal.strength_finished = self.strength_finished;
  64                         self.personal.invincible_finished = self.invincible_finished;
  65                         self.personal.teleport_time = time;
  66                         goto cheated;
  67                 case CHIMPULSE_CLONE_MOVING:
  68                         makevectors (self.v_angle);
  69                         self.velocity = self.velocity + v_forward * 300;
  70                         CopyBody(1);
  71                         self.lip += 1;
  72                         self.velocity = self.velocity - v_forward * 300;
  73                         goto cheated;
  74                 case CHIMPULSE_CLONE_STANDING:
  75                         CopyBody(0);
  76                         self.lip += 1;
  77                         goto cheated;
  78                 case CHIMPULSE_GIVE_ALL:
  79                         self.weapons |= WEPBIT_ALL;
  80                         self.items |= IT_UNLIMITED_AMMO;
  81                         self.ammo_shells = g_pickup_shells_max;
  82                         self.ammo_nails = g_pickup_nails_max;
  83                         self.ammo_rockets = g_pickup_rockets_max;
  84                         self.ammo_cells = g_pickup_cells_max;
  85                         self.ammo_fuel = g_pickup_fuel_max;
  86                         self.health = g_pickup_healthsmall_max;
  87                         self.armorvalue = g_pickup_armorsmall_max;
  88                         self.pauserotarmor_finished = time + cvar("g_balance_pause_armor_rot_spawn");
  89                         self.pauserothealth_finished = time + cvar("g_balance_pause_health_rot_spawn");
  90                         self.pauserotfuel_finished = time + cvar("g_balance_pause_fuel_rot_spawn");
  91                         self.pauseregen_finished = time + cvar("g_balance_pause_health_regen_spawn");
  92                         // precache weapon models/sounds
  93                         wep = WEP_FIRST;
  94                         while (wep <= WEP_LAST)
  95                         {
  96                                 weapon_action(wep, WR_PRECACHE);
  97                                 wep = wep + 1;
  98                         }
  99                         goto cheated;
 100                 case CHIMPULSE_SPEEDRUN:
 101                         if(self.personal)
 102                         {
 103                                 self.speedrunning = TRUE;
 104                                 tracebox(self.personal.origin, self.mins, self.maxs, self.personal.origin, MOVE_WORLDONLY, self);
 105                                 if(trace_startsolid)
 106                                 {
 107                                         sprint(self, "Cannot move there, cheater - only waypoints set using g_waypointsprite_personal work\n");
 108                                 }
 109                                 else
 110                                 {
 111                                         // Abort speedrun, teleport back
 112                                         setorigin(self, self.personal.origin);
 113                                         self.oldvelocity = self.velocity = self.personal.velocity;
 114                                         self.angles = self.personal.v_angle;
 115                                         self.fixangle = TRUE;
 116                                         if(self.flagcarried)
 117                                         {
 118                                                 bprint("The ", self.flagcarried.netname, " was returned to base by its carrier\n");
 119                                                 ReturnFlag(self.flagcarried);
 120                                         }
 121                                 }
 122                                 if(g_ctf)
 123                                 {
 124                                         self.ammo_rockets = 999;
 125                                         self.ammo_nails = 999;
 126                                         self.ammo_cells = 999;
 127                                         self.ammo_shells = 999;
 128                                         self.ammo_fuel = 999;
 129                                         self.health = start_health;
 130                                         self.armorvalue = start_armorvalue;
 131                                         self.weapons |= weaponsInMap;
 132                                         self.pauserotarmor_finished = time + cvar("g_balance_pause_armor_rot_spawn");
 133                                         self.pauserothealth_finished = time + cvar("g_balance_pause_health_rot_spawn");
 134                                         self.pauserotfuel_finished = time + cvar("g_balance_pause_fuel_rot_spawn");
 135                                         self.pauseregen_finished = time + cvar("g_balance_pause_health_regen_spawn");
 136                                         self.strength_finished = 0;
 137                                         self.invincible_finished = 0;
 138                                 }
 139                                 else
 140                                 {
 141                                         self.ammo_rockets = self.personal.ammo_rockets;
 142                                         self.ammo_nails = self.personal.ammo_nails;
 143                                         self.ammo_cells = self.personal.ammo_cells;
 144                                         self.ammo_shells = self.personal.ammo_shells;
 145                                         self.ammo_fuel = self.personal.ammo_fuel;
 146                                         self.health = self.personal.health;
 147                                         self.armorvalue = self.personal.armorvalue;
 148                                         self.weapons = self.personal.weapons;
 149                                         self.items = self.personal.items;
 150                                         self.pauserotarmor_finished = time + self.personal.pauserotarmor_finished - self.personal.teleport_time;
 151                                         self.pauserothealth_finished = time + self.personal.pauserothealth_finished - self.personal.teleport_time;
 152                                         self.pauserotfuel_finished = time + self.personal.pauserotfuel_finished - self.personal.teleport_time;
 153                                         self.pauseregen_finished = time + self.personal.pauseregen_finished - self.personal.teleport_time;
 154                                         self.strength_finished = time + self.personal.strength_finished - self.personal.teleport_time;
 155                                         self.invincible_finished = time + self.personal.invincible_finished - self.personal.teleport_time;
 156                                 }
 157                                 goto cheated;
 158                         }
 159                         else if(self.deadflag != DEAD_NO)
 160                                 sprint(self, "UR DEAD AHAHAH))\n");
 161                         else
 162                                 sprint(self, "No waypoint set, cheater (use g_waypointsprite_personal to set one)\n");
 163                         break;
 164                 case CHIMPULSE_TELEPORT:
 165                         if(MoveToRandomMapLocation(self, DPCONTENTS_SOLID | DPCONTENTS_CORPSE | DPCONTENTS_PLAYERCLIP, DPCONTENTS_SLIME | DPCONTENTS_LAVA | DPCONTENTS_SKY | DPCONTENTS_BODY | DPCONTENTS_DONOTENTER, Q3SURFACEFLAG_SKY, ((sv_cheats >= 2) ? 100000 : 100), 1024, 256))
 166                         {
 167                                 self.angles_x = -self.angles_x;
 168                                 self.fixangle = TRUE;
 169                                 self.velocity = '0 0 0';
 170                                 goto cheated;
 171                         }
 172                         else
 173                                 sprint(self, "Emergency teleport could not find a good location, forget it!\n");
 174                         break;
 175                 case CHIMPULSE_R00T:
 176                         FOR_EACH_PLAYER(e)
 177                         {
 178                                 if( e.playermodel == "models/player/jeandarc.zym"
 179                                                 ||  e.playermodel == "models/player/pyria.zym"
 180                                                 ||  e.playermodel == "models/player/skadi.zym"
 181                                                 || (e.playermodel == "models/player/specop.zym" && random() < 0.5) // you never know
 182                                                 ||  e.playermodel == "models/player/visitant.zym")
 183                                 {
 184                                         makevectors(e.angles);
 185                                         traceline(e.origin, e.origin + v_right * 256, MOVE_NORMAL, e);
 186                                 }
 187                                 else
 188                                 {
 189                                         org_x = random();
 190                                         org_y = random();
 191                                         org_z = 0;
 192                                         org = normalize(org);
 193                                         traceline(e.origin, e.origin + org * 256, MOVE_NORMAL, e); // random direction
 194                                 }
 195
 196                                 org = findbetterlocation(trace_endpos, 12);
 197
 198                                 e2 = spawn();
 199                                 setorigin(e2, org);
 200                                 pointparticles(particleeffectnum("rocket_explode"), org, '0 0 0', 1);
 201                                 sound(e2, CHAN_PROJECTILE, "weapons/rocket_impact.wav", VOL_BASE, ATTN_NORM);
 202                                 RadiusDamage(e2, e, 1000, 0, 128, e, 500, DEATH_CHEAT, world);
 203                                 remove(e2);
 204                         }
 205                         print("404 Sportsmanship not found.\n");
 206                         goto cheated;
 207         }
 208         return 0;
 209
 210 :cheated
 211         cheatcount_total += 1;
 212         self.cheatcount += 1;
 213         return 1;
 214 }
 215
 216 float CheatCommand(float argc)
 217 {
 218         if not(CheatsAllowed(0, argc, 0))
 219                 return 0;
 220         string cmd;
 221         cmd = argv(0);
 222         switch(cmd)
 223         {
 224                 entity e;
 225                 float effectnum, f;
 226                 vector start, end;
 227                 entity oldself;
 228
 229                 case "pointparticles":
 230                         if(argc == 5)
 231                         {
 232                                 // arguments:
 233                                 //   effectname
 234                                 //   origin (0..1, on crosshair line)
 235                                 //   velocity
 236                                 //   howmany
 237                                 effectnum = particleeffectnum(argv(1));
 238                                 f = stof(argv(2));
 239                                 start = (1-f) * self.origin + f * self.cursor_trace_endpos;
 240                                 end = stov(argv(3));
 241                                 f = stof(argv(4));
 242                                 pointparticles(effectnum, start, end, f);
 243                                 goto cheated;
 244                         }
 245                         sprint(self, "Usage: sv_cheats 1; restart; cmd pointparticles effectname position(0..1) velocityvector multiplier\n");
 246                         break;
 247                 case "trailparticles":
 248                         if(argc == 2)
 249                         {
 250                                 // arguments:
 251                                 //   effectname
 252                                 effectnum = particleeffectnum(argv(1));
 253                                 W_SetupShot(self, FALSE, FALSE, "",0);
 254                                 traceline(w_shotorg, w_shotorg + w_shotdir * MAX_SHOT_DISTANCE, MOVE_NORMAL, self);
 255                                 trailparticles(self, effectnum, w_shotorg, trace_endpos);
 256                                 goto cheated;
 257                         }
 258                         sprint(self, "Usage: sv_cheats 1; restart; cmd trailparticles effectname\n");
 259                         break;
 260                 case "make":
 261                         if(argc == 3)
 262                         {
 263                                 // arguments:
 264                                 //   modelname mode
 265                                 f = stof(argv(2));
 266                                 W_SetupShot(self, FALSE, FALSE, "", 0);
 267                                 traceline(w_shotorg, w_shotorg + w_shotdir * 2048, MOVE_NORMAL, self);
 268                                 if((trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT) || trace_fraction == 1)
 269                                 {
 270                                         sprint(self, "cannot make stuff there (bad surface)\n");
 271                                 }
 272                                 else
 273                                 {
 274                                         e = spawn();
 275                                         e.model = strzone(argv(1));
 276                                         e.mdl = "rocket_explode";
 277                                         e.health = 1000;
 278                                         setorigin(e, trace_endpos);
 279                                         e.effects = EF_NOMODELFLAGS;
 280                                         if(f == 1)
 281                                         {
 282                                                 e.angles = fixedvectoangles2(trace_plane_normal, v_forward);
 283                                                 e.angles = AnglesTransform_Multiply(e.angles, '-90 0 0'); // so unrotated models work
 284                                         }
 285                                         oldself = self;
 286                                         self = e;
 287                                         spawnfunc_func_breakable();
 288                                         self = oldself;
 289                                         // now, is it valid?
 290                                         if(f == 0)
 291                                         {
 292                                                 tracebox(e.origin, e.mins, e.maxs, e.origin, MOVE_NORMAL, e);
 293                                                 if(trace_startsolid)
 294                                                 {
 295                                                         remove(e);
 296                                                         sprint(self, "cannot make stuff there (no space)\n");
 297                                                 }
 298                                                 else
 299                                                         goto cheated;
 300                                         }
 301                                         else
 302                                                 goto cheated;
 303                                 }
 304                         }
 305                         else
 306                                 sprint(self, "Usage: sv_cheats 1; restart; cmd make models/... 0/1/2\n");
 307                         break;
 308                 case "penalty":
 309                         if(argc == 3)
 310                         {
 311                                 race_ImposePenaltyTime(self, stof(argv(1)), argv(2));
 312                                 goto cheated;
 313                         }
 314                         sprint(self, "Usage: sv_cheats 1; restart; cmd penalty 5.0 AHAHAHAHAHAHAH))\n");
 315                         break;
 316                 case "dragbox_spawn":
 317                         e = spawn();
 318                         e.classname = "dragbox_box";
 319                         e.think = DragBox_Think;
 320                         e.nextthink = time;
 321                         e.solid = -1; // black
 322                         setmodel(e, "null"); // network it
 323                         if(argc == 4)
 324                                 e.cnt = stof(argv(1));
 325                         else
 326                                 e.cnt = max(0, drag_lastcnt);
 327
 328                         e.aiment = spawn();
 329                         e.aiment.classname = "dragbox_corner_1";
 330                         e.aiment.owner = e;
 331                         setmodel(e.aiment, "models/marker.md3");
 332                         e.aiment.skin = 0;
 333                         setsize(e.aiment, '0 0 0', '0 0 0');
 334                         if(argc == 4)
 335                                 setorigin(e.aiment, stov(argv(2)));
 336                         else
 337                                 setorigin(e.aiment, self.cursor_trace_endpos);
 338
 339                         e.enemy = spawn();
 340                         e.enemy.classname = "dragbox_corner_2";
 341                         e.enemy.owner = e;
 342                         setmodel(e.enemy, "models/marker.md3");
 343                         e.enemy.skin = 1;
 344                         setsize(e.enemy, '0 0 0', '0 0 0');
 345                         end = normalize(self.cursor_trace_start - e.aiment.origin);
 346                         end_x = (end_x > 0) * 2 - 1;
 347                         end_y = (end_y > 0) * 2 - 1;
 348                         end_z = (end_z > 0) * 2 - 1;
 349                         if(argc == 4)
 350                                 setorigin(e.enemy, stov(argv(3)));
 351                         else
 352                                 setorigin(e.enemy, e.aiment.origin + 32 * end);
 353
 354                         e.killindicator = spawn();
 355                         e.killindicator.classname = "drag_digit";
 356                         e.killindicator.owner = e;
 357                         setattachment(e.killindicator, e, "");
 358                         setorigin(e.killindicator, '0 0 -8');
 359                         e.killindicator.killindicator = spawn();
 360                         e.killindicator.killindicator.classname = "drag_digit";
 361                         e.killindicator.killindicator.owner = e;
 362                         setattachment(e.killindicator.killindicator, e, "");
 363                         setorigin(e.killindicator.killindicator, '0 0 8');
 364                         goto cheated;
 365                 case "dragpoint_spawn":
 366                         e = spawn();
 367                         e.classname = "dragpoint";
 368                         e.think = DragBox_Think;
 369                         e.nextthink = time;
 370                         e.solid = 0; // nothing special
 371                         setmodel(e, "models/marker.md3");
 372                         setsize(e, PL_MIN, PL_MAX);
 373                         e.skin = 2;
 374                         if(argc == 3)
 375                                 e.cnt = stof(argv(1));
 376                         else
 377                                 e.cnt = drag_lastcnt;
 378                         if(argc == 3)
 379                                 setorigin(e, stov(argv(2)));
 380                         else
 381                         {
 382                                 setorigin(e, self.cursor_trace_endpos + normalize(self.cursor_trace_start - self.cursor_trace_endpos));
 383                                 move_out_of_solid(e);
 384                         }
 385
 386                         e.killindicator = spawn();
 387                         e.killindicator.classname = "drag_digit";
 388                         e.killindicator.owner = e;
 389                         setattachment(e.killindicator, e, "");
 390                         setorigin(e.killindicator, '0 0 40');
 391                         e.killindicator.killindicator = spawn();
 392                         e.killindicator.killindicator.classname = "drag_digit";
 393                         e.killindicator.killindicator.owner = e;
 394                         setattachment(e.killindicator.killindicator, e, "");
 395                         setorigin(e.killindicator.killindicator, '0 0 56');
 396                         goto cheated;
 397                 case "drag_remove":
 398                         RandomSelection_Init();
 399                         for(e = world; (e = find(e, classname, "dragbox_box")); )
 400                                 RandomSelection_Add(e, 0, string_null, 1, 1 / vlen(e.origin + (e.mins + e.maxs) * 0.5 - self.cursor_trace_endpos));
 401                         for(e = world; (e = find(e, classname, "dragpoint")); )
 402                                 RandomSelection_Add(e, 0, string_null, 1, 1 / vlen(e.origin + (e.mins + e.maxs) * 0.5 - self.cursor_trace_endpos));
 403                         if(RandomSelection_chosen_ent)
 404                         {
 405                                 remove(RandomSelection_chosen_ent.killindicator.killindicator);
 406                                 remove(RandomSelection_chosen_ent.killindicator);
 407                                 if(RandomSelection_chosen_ent.aiment)
 408                                         remove(RandomSelection_chosen_ent.aiment);
 409                                 if(RandomSelection_chosen_ent.enemy)
 410                                         remove(RandomSelection_chosen_ent.enemy);
 411                                 remove(RandomSelection_chosen_ent);
 412                         }
 413                         goto cheated;
 414                 case "drag_setcnt":
 415                         if(argc == 2)
 416                         {
 417                                 RandomSelection_Init();
 418                                 for(e = world; (e = find(e, classname, "dragbox_box")); )
 419                                         RandomSelection_Add(e, 0, string_null, 1, 1 / vlen(e.origin + (e.mins + e.maxs) * 0.5 - self.cursor_trace_endpos));
 420                                 for(e = world; (e = find(e, classname, "dragpoint")); )
 421                                         RandomSelection_Add(e, 0, string_null, 1, 1 / vlen(e.origin + (e.mins + e.maxs) * 0.5 - self.cursor_trace_endpos));
 422                                 if(RandomSelection_chosen_ent)
 423                                 {
 424                                         if(substring(argv(1), 0, 1) == "*")
 425                                                 RandomSelection_chosen_ent.cnt = drag_lastcnt = RandomSelection_chosen_ent.cnt + stof(substring(argv(1), 1, -1));
 426                                         else
 427                                                 RandomSelection_chosen_ent.cnt = drag_lastcnt = stof(argv(1));
 428                                 }
 429                                 goto cheated;
 430                         }
 431                         else
 432                                 sprint(self, "Usage: sv_cheats 1; restart; cmd dragbox_setcnt cnt\n");
 433                         break;
 434                 case "drag_save":
 435                         if(argc == 2)
 436                         {
 437                                 f = fopen(argv(1), FILE_WRITE);
 438                                 fputs(f, "cmd drag_clear\n");
 439                                 for(e = world; (e = find(e, classname, "dragbox_box")); )
 440                                 {
 441                                         fputs(f, strcat("cmd dragbox_spawn ", ftos(e.cnt), " \"", vtos(e.aiment.origin), "\" \"", vtos(e.enemy.origin), "\"\n"));
 442                                 }
 443                                 for(e = world; (e = find(e, classname, "dragpoint")); )
 444                                 {
 445                                         fputs(f, strcat("cmd dragpoint_spawn ", ftos(e.cnt), " \"", vtos(e.origin), "\"\n"));
 446                                 }
 447                                 fclose(f);
 448                                 goto cheated;
 449                         }
 450                         else
 451                                 sprint(self, "Usage: sv_cheats 1; restart; cmd dragbox_save filename\n");
 452                         break;
 453                 case "drag_saveraceent":
 454                         if(argc == 2)
 455                         {
 456                                 f = fopen(argv(1), FILE_WRITE);
 457                                 for(e = world; (e = find(e, classname, "dragbox_box")); )
 458                                 {
 459                                         fputs(f, "{\n");
 460                                         fputs(f, "\"classname\" \"trigger_race_checkpoint\"\n");
 461                                         fputs(f, strcat("\"origin\" \"", ftos(e.absmin_x), " ", ftos(e.absmin_y), " ", ftos(e.absmin_z), "\"\n"));
 462                                         fputs(f, strcat("\"maxs\" \"", ftos(e.absmax_x - e.absmin_x), " ", ftos(e.absmax_y - e.absmin_y), " ", ftos(e.absmax_z - e.absmin_z), "\"\n"));
 463                                         fputs(f, strcat("\"cnt\" \"", ftos(e.cnt), "\"\n"));
 464                                         fputs(f, strcat("\"targetname\" \"checkpoint", ftos(e.cnt), "\"\n"));
 465                                         fputs(f, "}\n");
 466                                 }
 467                                 for(e = world; (e = find(e, classname, "dragpoint")); )
 468                                 {
 469                                         start = '0 0 0';
 470                                         effectnum = 0;
 471                                         for(oldself = world; (oldself = find(oldself, classname, "dragbox_box")); )
 472                                         {
 473                                                 if(e.cnt <= 0 && oldself.cnt == 0 || e.cnt == oldself.cnt)
 474                                                 {
 475                                                         start = start + oldself.origin;
 476                                                         ++effectnum;
 477                                                 }
 478                                         }
 479                                         start *= 1 / effectnum;
 480                                         fputs(f, "{\n");
 481                                         fputs(f, "\"classname\" \"info_player_race\"\n");
 482                                         fputs(f, strcat("\"angle\" \"", ftos(vectoyaw(start - e.origin)), "\"\n"));
 483                                         fputs(f, strcat("\"origin\" \"", ftos(e.origin_x), " ", ftos(e.origin_y), " ", ftos(e.origin_z), "\"\n"));
 484                                         if(e.cnt == -2)
 485                                         {
 486                                                 fputs(f, "\"target\" \"checkpoint0\"\n");
 487                                                 fputs(f, "\"race_place\" \"0\"\n");
 488                                         }
 489                                         else if(e.cnt == -1)
 490                                         {
 491                                                 fputs(f, "\"target\" \"checkpoint0\"\n");
 492                                                 fputs(f, "\"race_place\" \"-1\"\n");
 493                                         }
 494                                         else
 495                                         {
 496                                                 fputs(f, strcat("\"target\" \"checkpoint", ftos(e.cnt), "\"\n"));
 497                                                 if(e.cnt == 0)
 498                                                 {
 499                                                         // these need race_place
 500                                                         // counting...
 501                                                         effectnum = 1;
 502                                                         for(oldself = world; (oldself = find(oldself, classname, "dragpoint")); )
 503                                                         if(oldself.cnt == 0)
 504                                                         {
 505                                                                 if(vlen(oldself.origin - start) < vlen(e.origin - start))
 506                                                                         ++effectnum;
 507                                                                 else if(vlen(oldself.origin - start) == vlen(e.origin - start) && num_for_edict(oldself) < num_for_edict(e))
 508                                                                         ++effectnum;
 509                                                         }
 510                                                         fputs(f, strcat("\"race_place\" \"", ftos(effectnum), "\"\n"));
 511                                                 }
 512                                         }
 513                                         fputs(f, "}\n");
 514                                 }
 515                                 fclose(f);
 516                                 goto cheated;
 517                         }
 518                         else
 519                                 sprint(self, "Usage: sv_cheats 1; restart; cmd dragbox_save filename\n");
 520                         break;
 521                 case "drag_clear":
 522                         for(e = world; (e = find(e, classname, "dragbox_box")); )
 523                                 remove(e);
 524                         for(e = world; (e = find(e, classname, "dragbox_corner_1")); )
 525                                 remove(e);
 526                         for(e = world; (e = find(e, classname, "dragbox_corner_2")); )
 527                                 remove(e);
 528                         for(e = world; (e = find(e, classname, "dragpoint")); )
 529                                 remove(e);
 530                         for(e = world; (e = find(e, classname, "drag_digit")); )
 531                                 remove(e);
 532                         goto cheated;
 533                 case "god":
 534                         BITXOR_ASSIGN(self.flags, FL_GODMODE);
 535                         if(self.flags & FL_GODMODE)
 536                         {
 537                                 sprint(self, "godmode ON\n");
 538                                 goto cheated;
 539                         }
 540                         else
 541                                 sprint(self, "godmode OFF\n");
 542                         break;
 543                 case "notarget":
 544                         BITXOR_ASSIGN(self.flags, FL_NOTARGET);
 545                         if(self.flags & FL_NOTARGET)
 546                         {
 547                                 sprint(self, "notarget ON\n");
 548                                 goto cheated;
 549                         }
 550                         else
 551                                 sprint(self, "notarget OFF\n");
 552                         break;
 553                 case "noclip":
 554                         if(self.movetype != MOVETYPE_NOCLIP)
 555                         {
 556                                 self.movetype = MOVETYPE_NOCLIP;
 557                                 sprint(self, "noclip ON\n");
 558                                 goto cheated;
 559                         }
 560                         else
 561                         {
 562                                 self.movetype = MOVETYPE_WALK;
 563                                 sprint(self, "noclip OFF\n");
 564                         }
 565                         break;
 566                 case "fly":
 567                         if(self.movetype != MOVETYPE_FLY)
 568                         {
 569                                 self.movetype = MOVETYPE_FLY;
 570                                 sprint(self, "flmodey ON\n");
 571                                 goto cheated;
 572                         }
 573                         else
 574                         {
 575                                 self.movetype = MOVETYPE_WALK;
 576                                 sprint(self, "flymode OFF\n");
 577                         }
 578                         break;
 579                 case "give":
 580                         // TODO
 581                         break;
 582         }
 583         return 0;
 584
 585 :cheated
 586         cheatcount_total += 1;
 587         self.cheatcount += 1;
 588         return 1;
 589 }
 590
 591 void Drag_Begin(entity dragger, entity draggee, vector touchpoint);
 592 void Drag_Finish(entity dragger);
 593 float Drag_IsDraggable(entity draggee);
 594 float Drag_MayChangeAngles(entity draggee);
 595 void Drag_MoveForward(entity dragger);
 596 void Drag_SetSpeed(entity dragger, float s);
 597 void Drag_MoveBackward(entity dragger);
 598 void Drag_Update(entity dragger);
 599 float Drag_CanDrag(entity dragger);
 600 float Drag_IsDragging(entity dragger);
 601 void Drag_MoveDrag(entity from, entity to);
 602 .entity dragentity;
 603
 604 float CheatFrame()
 605 {
 606         float cheating;
 607         cheating = 0;
 608
 609         if(CheatsAllowed(0, 0, CHRAME_DRAG))
 610                 if(Drag_CanDrag(self))
 611                         if(self.BUTTON_DRAG)
 612                                 if(!self.dragentity)
 613                                         if(self.cursor_trace_ent)
 614                                                 if(Drag_IsDraggable(self.cursor_trace_ent))
 615                                                 {
 616                                                         if(self.cursor_trace_ent.draggedby)
 617                                                                 Drag_Finish(self.cursor_trace_ent.draggedby);
 618                                                         if(self.cursor_trace_ent.tag_entity)
 619                                                                 detach_sameorigin(self.cursor_trace_ent);
 620                                                         Drag_Begin(self, self.cursor_trace_ent, self.cursor_trace_endpos);
 621                                                         ++cheating;
 622                                                 }
 623         if(Drag_IsDragging(self))
 624         {
 625                 if(self.BUTTON_DRAG)
 626                 {
 627                         if(self.impulse == 10 || self.impulse == 15 || self.impulse == 18)
 628                         {
 629                                 Drag_MoveForward(self);
 630                                 self.impulse = 0;
 631                         }
 632                         else if(self.impulse == 12 || self.impulse == 16 || self.impulse == 19)
 633                         {
 634                                 Drag_MoveBackward(self);
 635                                 self.impulse = 0;
 636                         }
 637                         else if(self.impulse >= 1 && self.impulse <= 9)
 638                         {
 639                                 Drag_SetSpeed(self, self.impulse - 1);
 640                         }
 641                         else if(self.impulse == 14)
 642                         {
 643                                 Drag_SetSpeed(self, 9);
 644                         }
 645
 646                         if(frametime)
 647                                 Drag_Update(self);
 648                 }
 649                 else
 650                 {
 651                         Drag_Finish(self);
 652                 }
 653         }
 654
 655         if(cheating)
 656         {
 657                 cheatcount_total += 1;
 658                 self.cheatcount += 1;
 659                 return 1;
 660         }
 661
 662         return cheating;
 663 }
 664
 665
 666
 667
 668
 669 // ENTITY DRAGGING
 670
 671 // on dragger:
 672 .float draggravity;
 673 .float dragspeed; // speed of mouse wheel action
 674 .float dragdistance; // distance of dragentity's draglocalvector from view_ofs
 675 .vector draglocalvector; // local attachment vector of the dragentity
 676 .float draglocalangle;
 677 // on draggee:
 678 .entity draggedby;
 679 .float dragmovetype;
 680 void Drag_Begin(entity dragger, entity draggee, vector touchpoint)
 681 {
 682         float tagscale;
 683
 684         draggee.dragmovetype = draggee.movetype;
 685         draggee.draggravity = draggee.gravity;
 686         draggee.movetype = MOVETYPE_WALK;
 687         draggee.gravity = 0.00001;
 688         draggee.flags &~= FL_ONGROUND;
 689         draggee.draggedby = dragger;
 690
 691         dragger.dragentity = draggee;
 692
 693         dragger.dragdistance = vlen(touchpoint - dragger.origin - dragger.view_ofs);
 694         dragger.draglocalangle = draggee.angles_y - dragger.v_angle_y;
 695         touchpoint = touchpoint - gettaginfo(draggee, 0);
 696         tagscale = pow(vlen(v_forward), -2);
 697         dragger.draglocalvector_x = touchpoint * v_forward * tagscale;
 698         dragger.draglocalvector_y = touchpoint * v_right * tagscale;
 699         dragger.draglocalvector_z = touchpoint * v_up * tagscale;
 700
 701         dragger.dragspeed = 64;
 702 }
 703
 704 void Drag_Finish(entity dragger)
 705 {
 706         entity draggee;
 707         draggee = dragger.dragentity;
 708         if(dragger)
 709                 dragger.dragentity = world;
 710         draggee.draggedby = world;
 711         draggee.movetype = draggee.dragmovetype;
 712         draggee.gravity = draggee.draggravity;
 713
 714         switch(draggee.movetype)
 715         {
 716                 case MOVETYPE_TOSS:
 717                 case MOVETYPE_WALK:
 718                 case MOVETYPE_STEP:
 719                 case MOVETYPE_FLYMISSILE:
 720                 case MOVETYPE_BOUNCE:
 721                 case MOVETYPE_BOUNCEMISSILE:
 722                 case MOVETYPE_PHYSICS:
 723                         break;
 724                 default:
 725                         draggee.velocity = '0 0 0';
 726                         break;
 727         }
 728
 729         if((draggee.flags & FL_ITEM) && (vlen(draggee.velocity) < 32))
 730         {
 731                 draggee.velocity = '0 0 0';
 732                 draggee.flags |= FL_ONGROUND; // floating items are FUN
 733         }
 734 }
 735
 736 float Drag_IsDraggable(entity draggee)
 737 {
 738         // TODO add more checks for bad stuff here
 739         if(draggee.classname == "func_bobbing")
 740                 return FALSE;
 741         if(draggee.classname == "door") // FIXME find out why these must be excluded, or work around the problem (trying to drag these causes like 4 fps)
 742                 return FALSE;
 743         if(draggee.classname == "plat")
 744                 return FALSE;
 745         if(draggee.classname == "func_button")
 746                 return FALSE;
 747         if(draggee.model == "")
 748                 return FALSE;
 749         if(draggee.classname == "spectator")
 750                 return FALSE;
 751         if(draggee.classname == "observer")
 752                 return FALSE;
 753         if(draggee.classname == "exteriorweaponentity")
 754                 return FALSE;
 755
 756         return TRUE;
 757 }
 758
 759 float Drag_MayChangeAngles(entity draggee)
 760 {
 761         // TODO add more checks for bad stuff here
 762         if(substring(draggee.model, 0, 1) == "*")
 763                 return FALSE;
 764         return TRUE;
 765 }
 766
 767 void Drag_MoveForward(entity dragger)
 768 {
 769         dragger.dragdistance += dragger.dragspeed;
 770 }
 771
 772 void Drag_SetSpeed(entity dragger, float s)
 773 {
 774         dragger.dragspeed = pow(2, s);
 775 }
 776
 777 void Drag_MoveBackward(entity dragger)
 778 {
 779         dragger.dragdistance = max(0, dragger.dragdistance - dragger.dragspeed);
 780 }
 781
 782 void Drag_Update(entity dragger)
 783 {
 784         vector curorigin, neworigin, goodvelocity;
 785         float f;
 786         entity draggee;
 787
 788         draggee = dragger.dragentity;
 789         draggee.flags &~= FL_ONGROUND;
 790
 791         curorigin = gettaginfo(draggee, 0);
 792         curorigin = curorigin + v_forward * dragger.draglocalvector_x + v_right * dragger.draglocalvector_y + v_up * dragger.draglocalvector_z;
 793         makevectors(dragger.v_angle);
 794         neworigin = dragger.origin + dragger.view_ofs + v_forward * dragger.dragdistance;
 795         goodvelocity = (neworigin - curorigin) * (1 / frametime);
 796
 797         while(draggee.angles_y - dragger.v_angle_y - dragger.draglocalangle > 180)
 798                 dragger.draglocalangle += 360;
 799         while(draggee.angles_y - dragger.v_angle_y - dragger.draglocalangle <= -180)
 800                 dragger.draglocalangle -= 360;
 801
 802         f = min(frametime * 10, 1);
 803         draggee.velocity = draggee.velocity * (1 - f) + goodvelocity * f;
 804
 805         if(Drag_MayChangeAngles(draggee))
 806                 draggee.angles_y = draggee.angles_y * (1 - f) + (dragger.v_angle_y + dragger.draglocalangle) * f;
 807
 808         draggee.ltime = max(servertime + serverframetime, draggee.ltime); // fixes func_train breakage
 809
 810         te_lightning1(dragger, dragger.origin + dragger.view_ofs, curorigin);
 811 }
 812
 813 float Drag_CanDrag(entity dragger)
 814 {
 815         return (dragger.deadflag == DEAD_NO) || (dragger.classname == "player");
 816 }
 817
 818 float Drag_IsDragging(entity dragger)
 819 {
 820         if(!dragger.dragentity)
 821                 return FALSE;
 822         if(wasfreed(dragger.dragentity) || dragger.dragentity.draggedby != dragger)
 823         {
 824                 dragger.dragentity = world;
 825                 return FALSE;
 826         }
 827         if(!Drag_CanDrag(dragger) || !Drag_IsDraggable(dragger.dragentity))
 828         {
 829                 Drag_Finish(dragger);
 830                 return FALSE;
 831         }
 832         return TRUE;
 833 }
 834
 835 void Drag_MoveDrag(entity from, entity to)
 836 {
 837         if(from.draggedby)
 838         {
 839                 to.draggedby = from.draggedby;
 840                 to.draggedby.dragentity = to;
 841                 from.draggedby = world;
 842         }
 843 }
 844