data/qcsrc/server/cheats.qc

   1 void CopyBody(float keepvelocity);
   2
   3 #ifdef NOCHEATS
   4
   5 float CheatImpulse(float i) { return 0; }
   6 float CheatCommand(float argc) { return 0; }
   7 float CheatFrame() { return 0; }
   8 void CheatInit() { cheatcount_total = world.cheatcount; }
   9 void CheatShutdown() { }
  10 void CheatInitClient() { }
  11 void CheatShutdownClient() { }
  12 void Drag_MoveDrag(entity from, entity to) { }
  13
  14 #else
  15
  16 .float maycheat;
  17 float sv_cheats;
  18 float autocvar_sv_cheats;
  19
  20 #define CHIMPULSE_SPEEDRUN_INIT 30
  21 #define CHIMPULSE_GIVE_ALL 99
  22 #define CHIMPULSE_CLONE_MOVING 140
  23 #define CHIMPULSE_SPEEDRUN 141
  24 #define CHIMPULSE_CLONE_STANDING 142
  25 #define CHIMPULSE_TELEPORT 143
  26 #define CHIMPULSE_R00T 148
  27
  28 #define CHRAME_DRAG 1
  29
  30 void CheatInit()
  31 {
  32         sv_cheats = cvar("sv_cheats");
  33 }
  34
  35 void CheatShutdown()
  36 {
  37 }
  38
  39 void CheatInitClient()
  40 {
  41 }
  42
  43 void CheatShutdownClient()
  44 {
  45 }
  46
  47 float CheatsAllowed(float i, float argc, float fr) // the cheat gets passed as argument for possible future ACL checking
  48 {
  49         // dead people cannot cheat
  50         if(self.deadflag != DEAD_NO)
  51                 return 0;
  52         if(self.classname != "player")
  53                 return 0;
  54
  55         // sv_clones
  56         if(i == CHIMPULSE_CLONE_MOVING || i == CHIMPULSE_CLONE_STANDING)
  57                 if(self.lip < sv_clones)
  58                         return 1;
  59
  60         // haha
  61         if(self.maycheat)
  62                 return 1;
  63
  64         // sv_cheats
  65         if(sv_cheats && autocvar_sv_cheats)
  66                 return 1;
  67
  68         return 0;
  69 }
  70
  71 #define BEGIN_CHEAT_FUNCTION() \
  72         float cheating; \
  73         cheating = 0
  74 #define DID_CHEAT() \
  75         ++cheating
  76 #define ADD_CHEATS(e,n) \
  77         cheatcount_total += n; \
  78         e.cheatcount += n
  79 #define END_CHEAT_FUNCTION() \
  80         ADD_CHEATS(self,cheating); \
  81         return cheating
  82
  83 float CheatImpulse(float i)
  84 {
  85         BEGIN_CHEAT_FUNCTION();
  86         if not(CheatsAllowed(i, 0, 0))
  87                 return 0;
  88         switch(i)
  89         {
  90                 entity e, e2;
  91                 vector org;
  92
  93                 case CHIMPULSE_SPEEDRUN_INIT: // deploy personal waypoint
  94                         if(!self.personal)
  95                         {
  96                                 self.personal = spawn();
  97                                 self.personal.classname = "personal_wp";
  98                         }
  99                         self.personal.origin = self.origin;
 100                         self.personal.v_angle = self.v_angle;
 101                         self.personal.velocity = self.velocity;
 102                         self.personal.ammo_rockets = self.ammo_rockets;
 103                         self.personal.ammo_nails = self.ammo_nails;
 104                         self.personal.ammo_cells = self.ammo_cells;
 105                         self.personal.ammo_shells = self.ammo_shells;
 106                         self.personal.ammo_fuel = self.ammo_fuel;
 107                         self.personal.health = self.health;
 108                         self.personal.armorvalue = self.armorvalue;
 109                         self.personal.weapons = self.weapons;
 110                         self.personal.items = self.items;
 111                         self.personal.pauserotarmor_finished = self.pauserotarmor_finished;
 112                         self.personal.pauserothealth_finished = self.pauserothealth_finished;
 113                         self.personal.pauserotfuel_finished = self.pauserotfuel_finished;
 114                         self.personal.pauseregen_finished = self.pauseregen_finished;
 115                         self.personal.strength_finished = self.strength_finished;
 116                         self.personal.invincible_finished = self.invincible_finished;
 117                         self.personal.teleport_time = time;
 118                         break; // this part itself doesn't cheat, so let's not count this
 119                 case CHIMPULSE_CLONE_MOVING:
 120                         makevectors (self.v_angle);
 121                         self.velocity = self.velocity + v_forward * 300;
 122                         CopyBody(1);
 123                         self.lip += 1;
 124                         self.velocity = self.velocity - v_forward * 300;
 125                         DID_CHEAT();
 126                         break;
 127                 case CHIMPULSE_CLONE_STANDING:
 128                         CopyBody(0);
 129                         self.lip += 1;
 130                         DID_CHEAT();
 131                         break;
 132                 case CHIMPULSE_GIVE_ALL:
 133                         CheatCommand(tokenize_console("give all"));
 134                         break; // already counted as cheat
 135                 case CHIMPULSE_SPEEDRUN:
 136                         if(self.personal)
 137                         {
 138                                 self.speedrunning = TRUE;
 139                                 tracebox(self.personal.origin, self.mins, self.maxs, self.personal.origin, MOVE_WORLDONLY, self);
 140                                 if(trace_startsolid)
 141                                 {
 142                                         sprint(self, "Cannot move there, cheater - only waypoints set using g_waypointsprite_personal work\n");
 143                                 }
 144                                 else
 145                                 {
 146                                         // Abort speedrun, teleport back
 147                                         setorigin(self, self.personal.origin);
 148                                         self.oldvelocity = self.velocity = self.personal.velocity;
 149                                         self.angles = self.personal.v_angle;
 150                                         self.fixangle = TRUE;
 151                                         if(self.flagcarried)
 152                                         {
 153                                                 bprint("The ", self.flagcarried.netname, " was returned to base by its carrier\n");
 154                                                 ReturnFlag(self.flagcarried);
 155                                         }
 156                                 }
 157                                 if(g_ctf)
 158                                 {
 159                                         self.ammo_rockets = 999;
 160                                         self.ammo_nails = 999;
 161                                         self.ammo_cells = 999;
 162                                         self.ammo_shells = 999;
 163                                         self.ammo_fuel = 999;
 164                                         self.health = start_health;
 165                                         self.armorvalue = start_armorvalue;
 166                                         self.weapons |= weaponsInMap;
 167                                         self.pauserotarmor_finished = time + cvar("g_balance_pause_armor_rot_spawn");
 168                                         self.pauserothealth_finished = time + cvar("g_balance_pause_health_rot_spawn");
 169                                         self.pauserotfuel_finished = time + cvar("g_balance_pause_fuel_rot_spawn");
 170                                         self.pauseregen_finished = time + cvar("g_balance_pause_health_regen_spawn");
 171                                         self.strength_finished = 0;
 172                                         self.invincible_finished = 0;
 173                                 }
 174                                 else
 175                                 {
 176                                         self.ammo_rockets = self.personal.ammo_rockets;
 177                                         self.ammo_nails = self.personal.ammo_nails;
 178                                         self.ammo_cells = self.personal.ammo_cells;
 179                                         self.ammo_shells = self.personal.ammo_shells;
 180                                         self.ammo_fuel = self.personal.ammo_fuel;
 181                                         self.health = self.personal.health;
 182                                         self.armorvalue = self.personal.armorvalue;
 183                                         self.weapons = self.personal.weapons;
 184                                         self.items = self.personal.items;
 185                                         self.pauserotarmor_finished = time + self.personal.pauserotarmor_finished - self.personal.teleport_time;
 186                                         self.pauserothealth_finished = time + self.personal.pauserothealth_finished - self.personal.teleport_time;
 187                                         self.pauserotfuel_finished = time + self.personal.pauserotfuel_finished - self.personal.teleport_time;
 188                                         self.pauseregen_finished = time + self.personal.pauseregen_finished - self.personal.teleport_time;
 189                                         self.strength_finished = time + self.personal.strength_finished - self.personal.teleport_time;
 190                                         self.invincible_finished = time + self.personal.invincible_finished - self.personal.teleport_time;
 191                                 }
 192                                 DID_CHEAT();
 193                                 break;
 194                         }
 195                         if(self.deadflag != DEAD_NO)
 196                                 sprint(self, "UR DEAD AHAHAH))\n");
 197                         else
 198                                 sprint(self, "No waypoint set, cheater (use g_waypointsprite_personal to set one)\n");
 199                         break;
 200                 case CHIMPULSE_TELEPORT:
 201                         if(MoveToRandomMapLocation(self, DPCONTENTS_SOLID | DPCONTENTS_CORPSE | DPCONTENTS_PLAYERCLIP, DPCONTENTS_SLIME | DPCONTENTS_LAVA | DPCONTENTS_SKY | DPCONTENTS_BODY | DPCONTENTS_DONOTENTER, Q3SURFACEFLAG_SKY, ((sv_cheats >= 2) ? 100000 : 100), 1024, 256))
 202                         {
 203                                 self.angles_x = -self.angles_x;
 204                                 self.fixangle = TRUE;
 205                                 self.velocity = '0 0 0';
 206                                 DID_CHEAT();
 207                                 break;
 208                         }
 209                         sprint(self, "Emergency teleport could not find a good location, forget it!\n");
 210                         break;
 211                 case CHIMPULSE_R00T:
 212                         FOR_EACH_PLAYER(e)
 213                         {
 214                                 if( e.playermodel == "models/player/jeandarc.zym"
 215                                                 ||  e.playermodel == "models/player/pyria.zym"
 216                                                 ||  e.playermodel == "models/player/skadi.zym"
 217                                                 || (e.playermodel == "models/player/specop.zym" && random() < 0.5) // you never know
 218                                                 ||  e.playermodel == "models/player/visitant.zym")
 219                                 {
 220                                         makevectors(e.angles);
 221                                         traceline(e.origin, e.origin + v_right * 256, MOVE_NORMAL, e);
 222                                 }
 223                                 else
 224                                 {
 225                                         org_x = random();
 226                                         org_y = random();
 227                                         org_z = 0;
 228                                         org = normalize(org);
 229                                         traceline(e.origin, e.origin + org * 256, MOVE_NORMAL, e); // random direction
 230                                 }
 231
 232                                 org = findbetterlocation(trace_endpos, 12);
 233
 234                                 e2 = spawn();
 235                                 setorigin(e2, org);
 236                                 pointparticles(particleeffectnum("rocket_explode"), org, '0 0 0', 1);
 237                                 sound(e2, CHAN_PROJECTILE, "weapons/rocket_impact.wav", VOL_BASE, ATTN_NORM);
 238                                 RadiusDamage(e2, e, 1000, 0, 128, e, 500, DEATH_CHEAT, world);
 239                                 remove(e2);
 240                         }
 241                         print("404 Sportsmanship not found.\n");
 242                         DID_CHEAT();
 243                         break;
 244         }
 245
 246         END_CHEAT_FUNCTION();
 247 }
 248
 249 void DragBox_Think();
 250 float drag_lastcnt;
 251 float CheatCommand(float argc)
 252 {
 253         BEGIN_CHEAT_FUNCTION();
 254         if not(CheatsAllowed(0, argc, 0))
 255                 return 0;
 256         string cmd;
 257         cmd = argv(0);
 258         switch(cmd)
 259         {
 260                 entity e;
 261                 float effectnum, f;
 262                 vector start, end;
 263                 entity oldself;
 264
 265                 case "pointparticles":
 266                         if(argc == 5)
 267                         {
 268                                 // arguments:
 269                                 //   effectname
 270                                 //   origin (0..1, on crosshair line)
 271                                 //   velocity
 272                                 //   howmany
 273                                 effectnum = particleeffectnum(argv(1));
 274                                 f = stof(argv(2));
 275                                 start = (1-f) * self.origin + f * self.cursor_trace_endpos;
 276                                 end = stov(argv(3));
 277                                 f = stof(argv(4));
 278                                 pointparticles(effectnum, start, end, f);
 279                                 DID_CHEAT();
 280                                 break;
 281                         }
 282                         sprint(self, "Usage: sv_cheats 1; restart; cmd pointparticles effectname position(0..1) velocityvector multiplier\n");
 283                         break;
 284                 case "trailparticles":
 285                         if(argc == 2)
 286                         {
 287                                 // arguments:
 288                                 //   effectname
 289                                 effectnum = particleeffectnum(argv(1));
 290                                 W_SetupShot(self, FALSE, FALSE, "",0);
 291                                 traceline(w_shotorg, w_shotorg + w_shotdir * MAX_SHOT_DISTANCE, MOVE_NORMAL, self);
 292                                 trailparticles(self, effectnum, w_shotorg, trace_endpos);
 293                                 DID_CHEAT();
 294                                 break;
 295                         }
 296                         sprint(self, "Usage: sv_cheats 1; restart; cmd trailparticles effectname\n");
 297                         break;
 298                 case "make":
 299                         if(argc == 3)
 300                         {
 301                                 // arguments:
 302                                 //   modelname mode
 303                                 f = stof(argv(2));
 304                                 W_SetupShot(self, FALSE, FALSE, "", 0);
 305                                 traceline(w_shotorg, w_shotorg + w_shotdir * 2048, MOVE_NORMAL, self);
 306                                 if((trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT) || trace_fraction == 1)
 307                                 {
 308                                         sprint(self, "cannot make stuff there (bad surface)\n");
 309                                 }
 310                                 else
 311                                 {
 312                                         e = spawn();
 313                                         e.model = strzone(argv(1));
 314                                         e.mdl = "rocket_explode";
 315                                         e.health = 1000;
 316                                         setorigin(e, trace_endpos);
 317                                         e.effects = EF_NOMODELFLAGS;
 318                                         if(f == 1)
 319                                         {
 320                                                 e.angles = fixedvectoangles2(trace_plane_normal, v_forward);
 321                                                 e.angles = AnglesTransform_Multiply(e.angles, '-90 0 0'); // so unrotated models work
 322                                         }
 323                                         oldself = self;
 324                                         self = e;
 325                                         spawnfunc_func_breakable();
 326                                         self = oldself;
 327                                         // now, is it valid?
 328                                         if(f == 0)
 329                                         {
 330                                                 tracebox(e.origin, e.mins, e.maxs, e.origin, MOVE_NORMAL, e);
 331                                                 if(trace_startsolid)
 332                                                 {
 333                                                         remove(e);
 334                                                         sprint(self, "cannot make stuff there (no space)\n");
 335                                                 }
 336                                                 else
 337                                                         DID_CHEAT();
 338                                         }
 339                                         else
 340                                                 DID_CHEAT();
 341                                 }
 342                         }
 343                         else
 344                                 sprint(self, "Usage: sv_cheats 1; restart; cmd make models/... 0/1/2\n");
 345                         break;
 346                 case "penalty":
 347                         if(argc == 3)
 348                         {
 349                                 race_ImposePenaltyTime(self, stof(argv(1)), argv(2));
 350                                 DID_CHEAT();
 351                                 break;
 352                         }
 353                         sprint(self, "Usage: sv_cheats 1; restart; cmd penalty 5.0 AHAHAHAHAHAHAH))\n");
 354                         break;
 355                 case "dragbox_spawn":
 356                         e = spawn();
 357                         e.classname = "dragbox_box";
 358                         e.think = DragBox_Think;
 359                         e.nextthink = time;
 360                         e.solid = -1; // black
 361                         setmodel(e, "null"); // network it
 362                         if(argc == 4)
 363                                 e.cnt = stof(argv(1));
 364                         else
 365                                 e.cnt = max(0, drag_lastcnt);
 366
 367                         e.aiment = spawn();
 368                         e.aiment.classname = "dragbox_corner_1";
 369                         e.aiment.owner = e;
 370                         setmodel(e.aiment, "models/marker.md3");
 371                         e.aiment.skin = 0;
 372                         setsize(e.aiment, '0 0 0', '0 0 0');
 373                         if(argc == 4)
 374                                 setorigin(e.aiment, stov(argv(2)));
 375                         else
 376                                 setorigin(e.aiment, self.cursor_trace_endpos);
 377
 378                         e.enemy = spawn();
 379                         e.enemy.classname = "dragbox_corner_2";
 380                         e.enemy.owner = e;
 381                         setmodel(e.enemy, "models/marker.md3");
 382                         e.enemy.skin = 1;
 383                         setsize(e.enemy, '0 0 0', '0 0 0');
 384                         end = normalize(self.cursor_trace_start - e.aiment.origin);
 385                         end_x = (end_x > 0) * 2 - 1;
 386                         end_y = (end_y > 0) * 2 - 1;
 387                         end_z = (end_z > 0) * 2 - 1;
 388                         if(argc == 4)
 389                                 setorigin(e.enemy, stov(argv(3)));
 390                         else
 391                                 setorigin(e.enemy, e.aiment.origin + 32 * end);
 392
 393                         e.killindicator = spawn();
 394                         e.killindicator.classname = "drag_digit";
 395                         e.killindicator.owner = e;
 396                         setattachment(e.killindicator, e, "");
 397                         setorigin(e.killindicator, '0 0 -8');
 398                         e.killindicator.killindicator = spawn();
 399                         e.killindicator.killindicator.classname = "drag_digit";
 400                         e.killindicator.killindicator.owner = e;
 401                         setattachment(e.killindicator.killindicator, e, "");
 402                         setorigin(e.killindicator.killindicator, '0 0 8');
 403                         DID_CHEAT();
 404                         break;
 405                 case "dragpoint_spawn":
 406                         e = spawn();
 407                         e.classname = "dragpoint";
 408                         e.think = DragBox_Think;
 409                         e.nextthink = time;
 410                         e.solid = 0; // nothing special
 411                         setmodel(e, "models/marker.md3");
 412                         setsize(e, PL_MIN, PL_MAX);
 413                         e.skin = 2;
 414                         if(argc == 3)
 415                                 e.cnt = stof(argv(1));
 416                         else
 417                                 e.cnt = drag_lastcnt;
 418                         if(argc == 3)
 419                                 setorigin(e, stov(argv(2)));
 420                         else
 421                         {
 422                                 setorigin(e, self.cursor_trace_endpos + normalize(self.cursor_trace_start - self.cursor_trace_endpos));
 423                                 move_out_of_solid(e);
 424                         }
 425
 426                         e.killindicator = spawn();
 427                         e.killindicator.classname = "drag_digit";
 428                         e.killindicator.owner = e;
 429                         setattachment(e.killindicator, e, "");
 430                         setorigin(e.killindicator, '0 0 40');
 431                         e.killindicator.killindicator = spawn();
 432                         e.killindicator.killindicator.classname = "drag_digit";
 433                         e.killindicator.killindicator.owner = e;
 434                         setattachment(e.killindicator.killindicator, e, "");
 435                         setorigin(e.killindicator.killindicator, '0 0 56');
 436                         DID_CHEAT();
 437                         break;
 438                 case "drag_remove":
 439                         RandomSelection_Init();
 440                         for(e = world; (e = find(e, classname, "dragbox_box")); )
 441                                 RandomSelection_Add(e, 0, string_null, 1, 1 / vlen(e.origin + (e.mins + e.maxs) * 0.5 - self.cursor_trace_endpos));
 442                         for(e = world; (e = find(e, classname, "dragpoint")); )
 443                                 RandomSelection_Add(e, 0, string_null, 1, 1 / vlen(e.origin + (e.mins + e.maxs) * 0.5 - self.cursor_trace_endpos));
 444                         if(RandomSelection_chosen_ent)
 445                         {
 446                                 remove(RandomSelection_chosen_ent.killindicator.killindicator);
 447                                 remove(RandomSelection_chosen_ent.killindicator);
 448                                 if(RandomSelection_chosen_ent.aiment)
 449                                         remove(RandomSelection_chosen_ent.aiment);
 450                                 if(RandomSelection_chosen_ent.enemy)
 451                                         remove(RandomSelection_chosen_ent.enemy);
 452                                 remove(RandomSelection_chosen_ent);
 453                         }
 454                         DID_CHEAT();
 455                         break;
 456                 case "drag_setcnt":
 457                         if(argc == 2)
 458                         {
 459                                 RandomSelection_Init();
 460                                 for(e = world; (e = find(e, classname, "dragbox_box")); )
 461                                         RandomSelection_Add(e, 0, string_null, 1, 1 / vlen(e.origin + (e.mins + e.maxs) * 0.5 - self.cursor_trace_endpos));
 462                                 for(e = world; (e = find(e, classname, "dragpoint")); )
 463                                         RandomSelection_Add(e, 0, string_null, 1, 1 / vlen(e.origin + (e.mins + e.maxs) * 0.5 - self.cursor_trace_endpos));
 464                                 if(RandomSelection_chosen_ent)
 465                                 {
 466                                         if(substring(argv(1), 0, 1) == "*")
 467                                                 RandomSelection_chosen_ent.cnt = drag_lastcnt = RandomSelection_chosen_ent.cnt + stof(substring(argv(1), 1, -1));
 468                                         else
 469                                                 RandomSelection_chosen_ent.cnt = drag_lastcnt = stof(argv(1));
 470                                 }
 471                                 DID_CHEAT();
 472                                 break;
 473                         }
 474                         sprint(self, "Usage: sv_cheats 1; restart; cmd dragbox_setcnt cnt\n");
 475                         break;
 476                 case "drag_save":
 477                         if(argc == 2)
 478                         {
 479                                 f = fopen(argv(1), FILE_WRITE);
 480                                 fputs(f, "cmd drag_clear\n");
 481                                 for(e = world; (e = find(e, classname, "dragbox_box")); )
 482                                 {
 483                                         fputs(f, strcat("cmd dragbox_spawn ", ftos(e.cnt), " \"", vtos(e.aiment.origin), "\" \"", vtos(e.enemy.origin), "\"\n"));
 484                                 }
 485                                 for(e = world; (e = find(e, classname, "dragpoint")); )
 486                                 {
 487                                         fputs(f, strcat("cmd dragpoint_spawn ", ftos(e.cnt), " \"", vtos(e.origin), "\"\n"));
 488                                 }
 489                                 fclose(f);
 490                                 DID_CHEAT();
 491                                 break;
 492                         }
 493                         sprint(self, "Usage: sv_cheats 1; restart; cmd dragbox_save filename\n");
 494                         break;
 495                 case "drag_saveraceent":
 496                         if(argc == 2)
 497                         {
 498                                 f = fopen(argv(1), FILE_WRITE);
 499                                 for(e = world; (e = find(e, classname, "dragbox_box")); )
 500                                 {
 501                                         fputs(f, "{\n");
 502                                         fputs(f, "\"classname\" \"trigger_race_checkpoint\"\n");
 503                                         fputs(f, strcat("\"origin\" \"", ftos(e.absmin_x), " ", ftos(e.absmin_y), " ", ftos(e.absmin_z), "\"\n"));
 504                                         fputs(f, strcat("\"maxs\" \"", ftos(e.absmax_x - e.absmin_x), " ", ftos(e.absmax_y - e.absmin_y), " ", ftos(e.absmax_z - e.absmin_z), "\"\n"));
 505                                         fputs(f, strcat("\"cnt\" \"", ftos(e.cnt), "\"\n"));
 506                                         fputs(f, strcat("\"targetname\" \"checkpoint", ftos(e.cnt), "\"\n"));
 507                                         fputs(f, "}\n");
 508                                 }
 509                                 for(e = world; (e = find(e, classname, "dragpoint")); )
 510                                 {
 511                                         start = '0 0 0';
 512                                         effectnum = 0;
 513                                         for(oldself = world; (oldself = find(oldself, classname, "dragbox_box")); )
 514                                         {
 515                                                 if(e.cnt <= 0 && oldself.cnt == 0 || e.cnt == oldself.cnt)
 516                                                 {
 517                                                         start = start + oldself.origin;
 518                                                         ++effectnum;
 519                                                 }
 520                                         }
 521                                         start *= 1 / effectnum;
 522                                         fputs(f, "{\n");
 523                                         fputs(f, "\"classname\" \"info_player_race\"\n");
 524                                         fputs(f, strcat("\"angle\" \"", ftos(vectoyaw(start - e.origin)), "\"\n"));
 525                                         fputs(f, strcat("\"origin\" \"", ftos(e.origin_x), " ", ftos(e.origin_y), " ", ftos(e.origin_z), "\"\n"));
 526                                         if(e.cnt == -2)
 527                                         {
 528                                                 fputs(f, "\"target\" \"checkpoint0\"\n");
 529                                                 fputs(f, "\"race_place\" \"0\"\n");
 530                                         }
 531                                         else if(e.cnt == -1)
 532                                         {
 533                                                 fputs(f, "\"target\" \"checkpoint0\"\n");
 534                                                 fputs(f, "\"race_place\" \"-1\"\n");
 535                                         }
 536                                         else
 537                                         {
 538                                                 fputs(f, strcat("\"target\" \"checkpoint", ftos(e.cnt), "\"\n"));
 539                                                 if(e.cnt == 0)
 540                                                 {
 541                                                         // these need race_place
 542                                                         // counting...
 543                                                         effectnum = 1;
 544                                                         for(oldself = world; (oldself = find(oldself, classname, "dragpoint")); )
 545                                                         if(oldself.cnt == 0)
 546                                                         {
 547                                                                 if(vlen(oldself.origin - start) < vlen(e.origin - start))
 548                                                                         ++effectnum;
 549                                                                 else if(vlen(oldself.origin - start) == vlen(e.origin - start) && num_for_edict(oldself) < num_for_edict(e))
 550                                                                         ++effectnum;
 551                                                         }
 552                                                         fputs(f, strcat("\"race_place\" \"", ftos(effectnum), "\"\n"));
 553                                                 }
 554                                         }
 555                                         fputs(f, "}\n");
 556                                 }
 557                                 fclose(f);
 558                                 DID_CHEAT();
 559                                 break;
 560                         }
 561                         sprint(self, "Usage: sv_cheats 1; restart; cmd dragbox_save filename\n");
 562                         break;
 563                 case "drag_clear":
 564                         for(e = world; (e = find(e, classname, "dragbox_box")); )
 565                                 remove(e);
 566                         for(e = world; (e = find(e, classname, "dragbox_corner_1")); )
 567                                 remove(e);
 568                         for(e = world; (e = find(e, classname, "dragbox_corner_2")); )
 569                                 remove(e);
 570                         for(e = world; (e = find(e, classname, "dragpoint")); )
 571                                 remove(e);
 572                         for(e = world; (e = find(e, classname, "drag_digit")); )
 573                                 remove(e);
 574                         DID_CHEAT();
 575                         break;
 576                 case "warp":
 577                         if(argc == 2) if(cvar("g_campaign"))
 578                         {
 579                                 CampaignLevelWarp(stof(argv(1)));
 580                                 DID_CHEAT();
 581                         }
 582                         break;
 583                 case "god":
 584                         BITXOR_ASSIGN(self.flags, FL_GODMODE);
 585                         if(self.flags & FL_GODMODE)
 586                         {
 587                                 sprint(self, "godmode ON\n");
 588                                 DID_CHEAT();
 589                         }
 590                         else
 591                                 sprint(self, "godmode OFF\n");
 592                         break;
 593                 case "notarget":
 594                         BITXOR_ASSIGN(self.flags, FL_NOTARGET);
 595                         if(self.flags & FL_NOTARGET)
 596                         {
 597                                 sprint(self, "notarget ON\n");
 598                                 DID_CHEAT();
 599                         }
 600                         else
 601                                 sprint(self, "notarget OFF\n");
 602                         break;
 603                 case "noclip":
 604                         if(self.movetype != MOVETYPE_NOCLIP)
 605                         {
 606                                 self.movetype = MOVETYPE_NOCLIP;
 607                                 sprint(self, "noclip ON\n");
 608                                 DID_CHEAT();
 609                         }
 610                         else
 611                         {
 612                                 self.movetype = MOVETYPE_WALK;
 613                                 sprint(self, "noclip OFF\n");
 614                         }
 615                         break;
 616                 case "fly":
 617                         if(self.movetype != MOVETYPE_FLY)
 618                         {
 619                                 self.movetype = MOVETYPE_FLY;
 620                                 sprint(self, "flmodey ON\n");
 621                                 DID_CHEAT();
 622                         }
 623                         else
 624                         {
 625                                 self.movetype = MOVETYPE_WALK;
 626                                 sprint(self, "flymode OFF\n");
 627                         }
 628                         break;
 629                 case "give":
 630                         if(GiveItems(self, 1, argc))
 631                                 DID_CHEAT();
 632                         break;
 633         }
 634
 635         END_CHEAT_FUNCTION();
 636 }
 637
 638 void Drag_Begin(entity dragger, entity draggee, vector touchpoint);
 639 void Drag_Finish(entity dragger);
 640 float Drag_IsDraggable(entity draggee);
 641 float Drag_MayChangeAngles(entity draggee);
 642 void Drag_MoveForward(entity dragger);
 643 void Drag_SetSpeed(entity dragger, float s);
 644 void Drag_MoveBackward(entity dragger);
 645 void Drag_Update(entity dragger);
 646 float Drag_CanDrag(entity dragger);
 647 float Drag_IsDragging(entity dragger);
 648 void Drag_MoveDrag(entity from, entity to);
 649 .entity dragentity;
 650
 651 float CheatFrame()
 652 {
 653         BEGIN_CHEAT_FUNCTION();
 654
 655         if(CheatsAllowed(0, 0, CHRAME_DRAG))
 656                 if(Drag_CanDrag(self))
 657                         if(self.BUTTON_DRAG)
 658                                 if(!self.dragentity)
 659                                         if(self.cursor_trace_ent)
 660                                                 if(Drag_IsDraggable(self.cursor_trace_ent))
 661                                                 {
 662                                                         if(self.cursor_trace_ent.draggedby)
 663                                                                 Drag_Finish(self.cursor_trace_ent.draggedby);
 664                                                         if(self.cursor_trace_ent.tag_entity)
 665                                                                 detach_sameorigin(self.cursor_trace_ent);
 666                                                         Drag_Begin(self, self.cursor_trace_ent, self.cursor_trace_endpos);
 667                                                         DID_CHEAT();
 668                                                 }
 669         if(Drag_IsDragging(self))
 670         {
 671                 if(self.BUTTON_DRAG)
 672                 {
 673                         if(self.impulse == 10 || self.impulse == 15 || self.impulse == 18)
 674                         {
 675                                 Drag_MoveForward(self);
 676                                 self.impulse = 0;
 677                         }
 678                         else if(self.impulse == 12 || self.impulse == 16 || self.impulse == 19)
 679                         {
 680                                 Drag_MoveBackward(self);
 681                                 self.impulse = 0;
 682                         }
 683                         else if(self.impulse >= 1 && self.impulse <= 9)
 684                         {
 685                                 Drag_SetSpeed(self, self.impulse - 1);
 686                         }
 687                         else if(self.impulse == 14)
 688                         {
 689                                 Drag_SetSpeed(self, 9);
 690                         }
 691
 692                         if(frametime)
 693                                 Drag_Update(self);
 694                 }
 695                 else
 696                 {
 697                         Drag_Finish(self);
 698                 }
 699         }
 700
 701         END_CHEAT_FUNCTION();
 702 }
 703
 704
 705
 706
 707
 708 // ENTITY DRAGGING
 709
 710 // on dragger:
 711 .float draggravity;
 712 .float dragspeed; // speed of mouse wheel action
 713 .float dragdistance; // distance of dragentity's draglocalvector from view_ofs
 714 .vector draglocalvector; // local attachment vector of the dragentity
 715 .float draglocalangle;
 716 // on draggee:
 717 .entity draggedby;
 718 .float dragmovetype;
 719 void Drag_Begin(entity dragger, entity draggee, vector touchpoint)
 720 {
 721         float tagscale;
 722
 723         draggee.dragmovetype = draggee.movetype;
 724         draggee.draggravity = draggee.gravity;
 725         draggee.movetype = MOVETYPE_WALK;
 726         draggee.gravity = 0.00001;
 727         draggee.flags &~= FL_ONGROUND;
 728         draggee.draggedby = dragger;
 729
 730         dragger.dragentity = draggee;
 731
 732         dragger.dragdistance = vlen(touchpoint - dragger.origin - dragger.view_ofs);
 733         dragger.draglocalangle = draggee.angles_y - dragger.v_angle_y;
 734         touchpoint = touchpoint - gettaginfo(draggee, 0);
 735         tagscale = pow(vlen(v_forward), -2);
 736         dragger.draglocalvector_x = touchpoint * v_forward * tagscale;
 737         dragger.draglocalvector_y = touchpoint * v_right * tagscale;
 738         dragger.draglocalvector_z = touchpoint * v_up * tagscale;
 739
 740         dragger.dragspeed = 64;
 741 }
 742
 743 void Drag_Finish(entity dragger)
 744 {
 745         entity draggee;
 746         draggee = dragger.dragentity;
 747         if(dragger)
 748                 dragger.dragentity = world;
 749         draggee.draggedby = world;
 750         draggee.movetype = draggee.dragmovetype;
 751         draggee.gravity = draggee.draggravity;
 752
 753         switch(draggee.movetype)
 754         {
 755                 case MOVETYPE_TOSS:
 756                 case MOVETYPE_WALK:
 757                 case MOVETYPE_STEP:
 758                 case MOVETYPE_FLYMISSILE:
 759                 case MOVETYPE_BOUNCE:
 760                 case MOVETYPE_BOUNCEMISSILE:
 761                 case MOVETYPE_PHYSICS:
 762                         break;
 763                 default:
 764                         draggee.velocity = '0 0 0';
 765                         break;
 766         }
 767
 768         if((draggee.flags & FL_ITEM) && (vlen(draggee.velocity) < 32))
 769         {
 770                 draggee.velocity = '0 0 0';
 771                 draggee.flags |= FL_ONGROUND; // floating items are FUN
 772         }
 773 }
 774
 775 float Drag_IsDraggable(entity draggee)
 776 {
 777         // TODO add more checks for bad stuff here
 778         if(draggee.classname == "func_bobbing")
 779                 return FALSE;
 780         if(draggee.classname == "door") // FIXME find out why these must be excluded, or work around the problem (trying to drag these causes like 4 fps)
 781                 return FALSE;
 782         if(draggee.classname == "plat")
 783                 return FALSE;
 784         if(draggee.classname == "func_button")
 785                 return FALSE;
 786         if(draggee.model == "")
 787                 return FALSE;
 788         if(draggee.classname == "spectator")
 789                 return FALSE;
 790         if(draggee.classname == "observer")
 791                 return FALSE;
 792         if(draggee.classname == "exteriorweaponentity")
 793                 return FALSE;
 794
 795         return TRUE;
 796 }
 797
 798 float Drag_MayChangeAngles(entity draggee)
 799 {
 800         // TODO add more checks for bad stuff here
 801         if(substring(draggee.model, 0, 1) == "*")
 802                 return FALSE;
 803         return TRUE;
 804 }
 805
 806 void Drag_MoveForward(entity dragger)
 807 {
 808         dragger.dragdistance += dragger.dragspeed;
 809 }
 810
 811 void Drag_SetSpeed(entity dragger, float s)
 812 {
 813         dragger.dragspeed = pow(2, s);
 814 }
 815
 816 void Drag_MoveBackward(entity dragger)
 817 {
 818         dragger.dragdistance = max(0, dragger.dragdistance - dragger.dragspeed);
 819 }
 820
 821 void Drag_Update(entity dragger)
 822 {
 823         vector curorigin, neworigin, goodvelocity;
 824         float f;
 825         entity draggee;
 826
 827         draggee = dragger.dragentity;
 828         draggee.flags &~= FL_ONGROUND;
 829
 830         curorigin = gettaginfo(draggee, 0);
 831         curorigin = curorigin + v_forward * dragger.draglocalvector_x + v_right * dragger.draglocalvector_y + v_up * dragger.draglocalvector_z;
 832         makevectors(dragger.v_angle);
 833         neworigin = dragger.origin + dragger.view_ofs + v_forward * dragger.dragdistance;
 834         goodvelocity = (neworigin - curorigin) * (1 / frametime);
 835
 836         while(draggee.angles_y - dragger.v_angle_y - dragger.draglocalangle > 180)
 837                 dragger.draglocalangle += 360;
 838         while(draggee.angles_y - dragger.v_angle_y - dragger.draglocalangle <= -180)
 839                 dragger.draglocalangle -= 360;
 840
 841         f = min(frametime * 10, 1);
 842         draggee.velocity = draggee.velocity * (1 - f) + goodvelocity * f;
 843
 844         if(Drag_MayChangeAngles(draggee))
 845                 draggee.angles_y = draggee.angles_y * (1 - f) + (dragger.v_angle_y + dragger.draglocalangle) * f;
 846
 847         draggee.ltime = max(servertime + serverframetime, draggee.ltime); // fixes func_train breakage
 848
 849         te_lightning1(dragger, dragger.origin + dragger.view_ofs, curorigin);
 850 }
 851
 852 float Drag_CanDrag(entity dragger)
 853 {
 854         return (dragger.deadflag == DEAD_NO) || (dragger.classname == "player");
 855 }
 856
 857 float Drag_IsDragging(entity dragger)
 858 {
 859         if(!dragger.dragentity)
 860                 return FALSE;
 861         if(wasfreed(dragger.dragentity) || dragger.dragentity.draggedby != dragger)
 862         {
 863                 dragger.dragentity = world;
 864                 return FALSE;
 865         }
 866         if(!Drag_CanDrag(dragger) || !Drag_IsDraggable(dragger.dragentity))
 867         {
 868                 Drag_Finish(dragger);
 869                 return FALSE;
 870         }
 871         return TRUE;
 872 }
 873
 874 void Drag_MoveDrag(entity from, entity to)
 875 {
 876         if(from.draggedby)
 877         {
 878                 to.draggedby = from.draggedby;
 879                 to.draggedby.dragentity = to;
 880                 from.draggedby = world;
 881         }
 882 }
 883
 884
 885
 886
 887
 888
 889 void DragBox_Think()
 890 {
 891         if(self.aiment && self.enemy)
 892         {
 893                 self.origin_x = (self.aiment.origin_x + self.enemy.origin_x) * 0.5;
 894                 self.origin_y = (self.aiment.origin_y + self.enemy.origin_y) * 0.5;
 895                 self.origin_z = (self.aiment.origin_z + self.enemy.origin_z) * 0.5;
 896                 self.maxs_x = fabs(self.aiment.origin_x - self.enemy.origin_x) * 0.5;
 897                 self.maxs_y = fabs(self.aiment.origin_y - self.enemy.origin_y) * 0.5;
 898                 self.maxs_z = fabs(self.aiment.origin_z - self.enemy.origin_z) * 0.5;
 899                 self.mins = -1 * self.maxs;
 900                 setorigin(self, self.origin); setsize(self, self.mins, self.maxs); // link edict
 901         }
 902
 903         if(self.cnt == -1) // actually race_place -1
 904         {
 905                 // show "10 10" for qualifying spawns
 906                 setmodel(self.killindicator, "models/sprites/10.spr32");
 907                 setmodel(self.killindicator.killindicator, "models/sprites/10.spr32");
 908         }
 909         else if(self.cnt == -2) // actually race_place 0
 910         {
 911                 // show "10 0" for loser spawns
 912                 setmodel(self.killindicator, "models/sprites/10.spr32");
 913                 setmodel(self.killindicator.killindicator, "models/sprites/0.spr32");
 914         }
 915         else
 916         {
 917                 setmodel(self.killindicator, strcat("models/sprites/", ftos(mod(self.cnt, 10)), ".spr32"));
 918                 setmodel(self.killindicator.killindicator, strcat("models/sprites/", ftos(floor(self.cnt / 10)), ".spr32"));
 919         }
 920
 921         self.nextthink = time;
 922 }
 923
 924 #endif