data/qcsrc/server/bots.qc

   1 // rough simulation of walking from one point to another to test if a path
   2 // can be traveled, used by havocbot
   3
   4
   5 vector stepheightvec;
   6 float navigation_testtracewalk;
   7 float(entity e, vector start, vector m1, vector m2, vector end) tracewalk =
   8 {
   9         local vector org;
  10         local vector move;
  11         local vector dir;
  12         local float dist;
  13         local float totaldist;
  14         local float stepdist;
  15         local float yaw;
  16         local float ignorehazards;
  17         if (navigation_testtracewalk)
  18         {
  19                 if (navigation_testtracewalk > 1)
  20                         dprint("tracewalk: ");
  21                 //te_wizspike(start);
  22                 //te_knightspike(end);
  23                 //te_lightning2(world, start, end);
  24         }
  25         move = end - start;
  26         move_z = 0;
  27         org = start;
  28         dist = totaldist = vlen(move);
  29         dir = normalize(move);
  30         stepdist = 32;
  31         ignorehazards = FALSE;
  32         //self.angles = vectoangles(dir);
  33         traceline(start, start, FALSE, e);
  34         if (trace_dpstartcontents & (DPCONTENTS_SLIME | DPCONTENTS_LAVA))
  35                 ignorehazards = TRUE;
  36         tracebox(start, m1, m2, start, TRUE, e);
  37         if (trace_startsolid)
  38         {
  39                 // failed - bad start
  40                 if (navigation_testtracewalk)
  41                 {
  42                         if (navigation_testtracewalk > 1)
  43                                 dprint("bad-start\n");
  44                         te_knightspike(start);
  45                 }
  46                 return 0;
  47         }
  48         yaw = vectoyaw(move);
  49         move = end - org;
  50         while (1)
  51         {
  52                 if (boxesoverlap(end, end, org + m1 + '-1 -1 -1', org + m2 + '1 1 1'))
  53                 {
  54                         if (navigation_testtracewalk)
  55                         {
  56                                 if (navigation_testtracewalk > 1)
  57                                         dprint("success\n");
  58                                 te_wizspike(org);
  59                         }
  60                         // succeeded
  61                         return 1;
  62                 }
  63                 if (dist <= 0)
  64                         break;
  65                 if (navigation_testtracewalk)
  66                 {
  67                         //dprint("trying ");
  68                         //te_gunshot(org);
  69                         particle(org, '0 0 0', 104, 8);
  70                 }
  71                 if (stepdist > dist)
  72                         stepdist = dist;
  73                 dist = dist - stepdist;
  74                 traceline(org, org, FALSE, e);
  75                 if (!ignorehazards)
  76                 {
  77                         if (trace_dpstartcontents & (DPCONTENTS_SLIME | DPCONTENTS_LAVA))
  78                         {
  79                                 if (navigation_testtracewalk)
  80                                 {
  81                                         if (navigation_testtracewalk > 1)
  82                                                 dprint("hazard\n");
  83                                         te_gunshot(org);
  84                                 }
  85                                 // hazards blocking path
  86                                 return 0;
  87                         }
  88                 }
  89                 if (trace_dpstartcontents & DPCONTENTS_LIQUIDSMASK)
  90                 {
  91                         move = normalize(end - org);
  92                         tracebox(org, m1, m2, org + move * stepdist, MOVE_WORLDONLY, e);
  93                         if (trace_fraction < 1)
  94                         {
  95                                 if (navigation_testtracewalk)
  96                                 {
  97                                         if (navigation_testtracewalk > 1)
  98                                                 dprint("swimming-hit-something\n");
  99                                         //particle(org, move * 64, 104, 4);
 100                                         te_gunshot(org);
 101                                 }
 102                                 // failed
 103                                 return 0;
 104                         }
 105                         org = trace_endpos;
 106                 }
 107                 else
 108                 {
 109                         move = dir * stepdist + org;
 110                         tracebox(org, m1, m2, move, MOVE_WORLDONLY, e);
 111                         if (trace_fraction < 1)
 112                         {
 113                                 tracebox(org + stepheightvec, m1, m2, move + stepheightvec, MOVE_WORLDONLY, e);
 114                                 if (trace_fraction < 1 || trace_startsolid)
 115                                 {
 116                                         if (navigation_testtracewalk)
 117                                         {
 118                                                 if (navigation_testtracewalk > 1)
 119                                                         dprint("hit-something\n");
 120                                                 //move = normalize(end - org);
 121                                                 //particle(org, move * 64, 104, 4);
 122                                                 te_gunshot(org);
 123                                         }
 124                                         // failed
 125                                         return 0;
 126                                 }
 127                         }
 128                         move = trace_endpos;
 129                         tracebox(move, m1, m2, move + '0 0 -65536', FALSE, e);
 130                         /*
 131                         // trace down from stepheight as far as possible and move there,
 132                         // if this starts in solid we try again without the stepup, and
 133                         // if that also fails we assume it is a wall
 134                         // (this is the same logic as the Quake walkmove function used)
 135                         tracebox(move + '0 0 18', m1, m2, move + '0 0 -65536', FALSE, e);
 136                         if (trace_startsolid)
 137                         {
 138                                 tracebox(move, m1, m2, move + '0 0 -65536', FALSE, e);
 139                                 if (trace_startsolid)
 140                                 {
 141                                         if (navigation_testtracewalk)
 142                                         {
 143                                                 if (navigation_testtracewalk > 1)
 144                                                         dprint("hit-something\n");
 145                                                 //move = normalize(end - org);
 146                                                 //particle(org, move * 64, 104, 4);
 147                                                 te_knightspike(org);
 148                                         }
 149                                         // failed
 150                                         return 0;
 151                                 }
 152                         }
 153                         */
 154                         // moved successfully
 155                         if (navigation_testtracewalk > 1)
 156                                 dprint("moved ");
 157                         org = trace_endpos;
 158                 }
 159         }
 160         if (navigation_testtracewalk)
 161         {
 162                 if (navigation_testtracewalk > 1)
 163                         dprint("wrong-place\n");
 164                 te_knightspike(org);
 165                 //te_gunshot(end);
 166         }
 167         // moved but didn't arrive at the intended destination
 168         return 0;
 169 };
 170
 171
 172 // grenade tracing to decide the best pitch to fire at
 173
 174 entity tracetossent;
 175 entity tracetossfaketarget;
 176
 177 // traces multiple trajectories to find one that will impact the target
 178 // 'end' vector is the place it aims for,
 179 // returns TRUE only if it hit targ (don't target non-solid entities)
 180 vector findtrajectory_velocity;
 181 float(vector org, vector m1, vector m2, entity targ, float shotspeed, float shotspeedupward, float maxtime, float shotdelay, entity ignore) findtrajectorywithleading =
 182 {
 183         local float c, savesolid, shottime;
 184         local vector dir, end, v;
 185         if (shotspeed < 1)
 186                 return FALSE; // could cause division by zero if calculated
 187         if (targ.solid < SOLID_BBOX) // SOLID_NOT and SOLID_TRIGGER
 188                 return FALSE; // could never hit it
 189         if (!tracetossent)
 190                 tracetossent = spawn();
 191         tracetossent.owner = ignore;
 192         setsize(tracetossent, m1, m2);
 193         savesolid = targ.solid;
 194         targ.solid = SOLID_NOT;
 195         shottime = ((vlen(targ.origin - org) / shotspeed) + shotdelay);
 196         v = targ.velocity * shottime + targ.origin;
 197         tracebox(targ.origin, targ.mins, targ.maxs, v, FALSE, targ);
 198         v = trace_endpos;
 199         end = v + (targ.mins + targ.maxs) * 0.5;
 200         if ((vlen(end - org) / shotspeed + 0.2) > maxtime)
 201         {
 202                 // out of range
 203                 targ.solid = savesolid;
 204                 return FALSE;
 205         }
 206
 207         if (!tracetossfaketarget)
 208                 tracetossfaketarget = spawn();
 209         tracetossfaketarget.solid = savesolid;
 210         tracetossfaketarget.movetype = targ.movetype;
 211         setmodel(tracetossfaketarget, targ.model); // no low precision
 212         tracetossfaketarget.model = targ.model;
 213         tracetossfaketarget.modelindex = targ.modelindex;
 214         setsize(tracetossfaketarget, targ.mins, targ.maxs);
 215         setorigin(tracetossfaketarget, v);
 216
 217         c = 0;
 218         dir = normalize(end - org);
 219         while (c < 10) // 10 traces
 220         {
 221                 setorigin(tracetossent, org); // reset
 222                 tracetossent.velocity = findtrajectory_velocity = normalize(dir) * shotspeed + shotspeedupward * '0 0 1';
 223                 tracetoss(tracetossent, ignore); // love builtin functions...
 224                 if (trace_ent == tracetossfaketarget) // done
 225                 {
 226                         targ.solid = savesolid;
 227
 228                         // make it disappear
 229                         tracetossfaketarget.solid = SOLID_NOT;
 230                         tracetossfaketarget.movetype = MOVETYPE_NONE;
 231                         tracetossfaketarget.model = "";
 232                         tracetossfaketarget.modelindex = 0;
 233                         // relink to remove it from physics considerations
 234                         setorigin(tracetossfaketarget, v);
 235
 236                         return TRUE;
 237                 }
 238                 dir_z = dir_z + 0.1; // aim up a little more
 239                 c = c + 1;
 240         }
 241         targ.solid = savesolid;
 242
 243         // make it disappear
 244         tracetossfaketarget.solid = SOLID_NOT;
 245         tracetossfaketarget.movetype = MOVETYPE_NONE;
 246         tracetossfaketarget.model = "";
 247         tracetossfaketarget.modelindex = 0;
 248         // relink to remove it from physics considerations
 249         setorigin(tracetossfaketarget, v);
 250
 251         // leave a valid one even if it won't reach
 252         findtrajectory_velocity = normalize(end - org) * shotspeed + shotspeedupward * '0 0 1';
 253         return FALSE;
 254 };
 255
 256
 257
 258 // lag simulation
 259
 260 .void(float t, float f1, float f2, entity e1, vector v1, vector v2, vector v3, vector v4) lag_func;
 261
 262 // upto 5 queued messages
 263 .float lag1_time;
 264 .float lag1_float1;
 265 .float lag1_float2;
 266 .entity lag1_entity1;
 267 .vector lag1_vec1;
 268 .vector lag1_vec2;
 269 .vector lag1_vec3;
 270 .vector lag1_vec4;
 271
 272 .float lag2_time;
 273 .float lag2_float1;
 274 .float lag2_float2;
 275 .entity lag2_entity1;
 276 .vector lag2_vec1;
 277 .vector lag2_vec2;
 278 .vector lag2_vec3;
 279 .vector lag2_vec4;
 280
 281 .float lag3_time;
 282 .float lag3_float1;
 283 .float lag3_float2;
 284 .entity lag3_entity1;
 285 .vector lag3_vec1;
 286 .vector lag3_vec2;
 287 .vector lag3_vec3;
 288 .vector lag3_vec4;
 289
 290 .float lag4_time;
 291 .float lag4_float1;
 292 .float lag4_float2;
 293 .entity lag4_entity1;
 294 .vector lag4_vec1;
 295 .vector lag4_vec2;
 296 .vector lag4_vec3;
 297 .vector lag4_vec4;
 298
 299 .float lag5_time;
 300 .float lag5_float1;
 301 .float lag5_float2;
 302 .entity lag5_entity1;
 303 .vector lag5_vec1;
 304 .vector lag5_vec2;
 305 .vector lag5_vec3;
 306 .vector lag5_vec4;
 307
 308 void() lag_update =
 309 {
 310         if (self.lag1_time) if (time > self.lag1_time) {self.lag_func(self.lag1_time, self.lag1_float1, self.lag1_float2, self.lag1_entity1, self.lag1_vec1, self.lag1_vec2, self.lag1_vec3, self.lag1_vec4);self.lag1_time = 0;}
 311         if (self.lag2_time) if (time > self.lag2_time) {self.lag_func(self.lag2_time, self.lag2_float1, self.lag2_float2, self.lag2_entity1, self.lag2_vec1, self.lag2_vec2, self.lag2_vec3, self.lag2_vec4);self.lag2_time = 0;}
 312         if (self.lag3_time) if (time > self.lag3_time) {self.lag_func(self.lag3_time, self.lag3_float1, self.lag3_float2, self.lag3_entity1, self.lag3_vec1, self.lag3_vec2, self.lag3_vec3, self.lag3_vec4);self.lag3_time = 0;}
 313         if (self.lag4_time) if (time > self.lag4_time) {self.lag_func(self.lag4_time, self.lag4_float1, self.lag4_float2, self.lag4_entity1, self.lag4_vec1, self.lag4_vec2, self.lag4_vec3, self.lag4_vec4);self.lag4_time = 0;}
 314         if (self.lag5_time) if (time > self.lag5_time) {self.lag_func(self.lag5_time, self.lag5_float1, self.lag5_float2, self.lag5_entity1, self.lag5_vec1, self.lag5_vec2, self.lag5_vec3, self.lag5_vec4);self.lag5_time = 0;}
 315 };
 316
 317 float(float t, float f1, float f2, entity e1, vector v1, vector v2, vector v3, vector v4) lag_additem =
 318 {
 319         if (self.lag1_time == 0) {self.lag1_time = t;self.lag1_float1 = f1;self.lag1_float2 = f2;self.lag1_entity1 = e1;self.lag1_vec1 = v1;self.lag1_vec2 = v2;self.lag1_vec3 = v3;self.lag1_vec4 = v4;return TRUE;}
 320         if (self.lag2_time == 0) {self.lag2_time = t;self.lag2_float1 = f1;self.lag2_float2 = f2;self.lag2_entity1 = e1;self.lag2_vec1 = v1;self.lag2_vec2 = v2;self.lag2_vec3 = v3;self.lag2_vec4 = v4;return TRUE;}
 321         if (self.lag3_time == 0) {self.lag3_time = t;self.lag3_float1 = f1;self.lag3_float2 = f2;self.lag3_entity1 = e1;self.lag3_vec1 = v1;self.lag3_vec2 = v2;self.lag3_vec3 = v3;self.lag3_vec4 = v4;return TRUE;}
 322         if (self.lag4_time == 0) {self.lag4_time = t;self.lag4_float1 = f1;self.lag4_float2 = f2;self.lag4_entity1 = e1;self.lag4_vec1 = v1;self.lag4_vec2 = v2;self.lag4_vec3 = v3;self.lag4_vec4 = v4;return TRUE;}
 323         if (self.lag5_time == 0) {self.lag5_time = t;self.lag5_float1 = f1;self.lag5_float2 = f2;self.lag5_entity1 = e1;self.lag5_vec1 = v1;self.lag5_vec2 = v2;self.lag5_vec3 = v3;self.lag5_vec4 = v4;return TRUE;}
 324         // no room for it (what is the best thing to do here??)
 325         return FALSE;
 326 };
 327
 328
 329 // Random skill system
 330 .float bot_thinkskill;
 331 .float bot_mouseskill;
 332 .float bot_predictionskill;
 333 .float bot_offsetskill;
 334
 335
 336 // waypoint navigation system
 337
 338 // itemscore = (howmuchmoreIwant / howmuchIcanwant) / itemdistance
 339 // waypointscore = 0.7 / waypointdistance
 340
 341 .entity wp00, wp01, wp02, wp03, wp04, wp05, wp06, wp07;
 342 .entity wp08, wp09, wp10, wp11, wp12, wp13, wp14, wp15;
 343 .entity wp16, wp17, wp18, wp19, wp20, wp21, wp22, wp23, wp24, wp25, wp26, wp27, wp28, wp29, wp30, wp31;
 344 .float wp00mincost, wp01mincost, wp02mincost, wp03mincost, wp04mincost, wp05mincost, wp06mincost, wp07mincost;
 345 .float wp08mincost, wp09mincost, wp10mincost, wp11mincost, wp12mincost, wp13mincost, wp14mincost, wp15mincost;
 346 .float wp16mincost, wp17mincost, wp18mincost, wp19mincost, wp20mincost, wp21mincost, wp22mincost, wp23mincost, wp24mincost, wp25mincost, wp26mincost, wp27mincost, wp28mincost, wp29mincost, wp30mincost, wp31mincost;
 347 .float wpfire, wpcost;
 348 .float wpisbox;
 349 .float wpflags;
 350 .vector wpnearestpoint;
 351
 352 // stack of current goals (the last one of which may be an item or other
 353 // desirable object, the rest are typically waypoints to reach it)
 354 .entity goalcurrent, goalstack01, goalstack02, goalstack03;
 355 .entity goalstack04, goalstack05, goalstack06, goalstack07;
 356 .entity goalstack08, goalstack09, goalstack10, goalstack11;
 357 .entity goalstack12, goalstack13, goalstack14, goalstack15;
 358 .entity goalstack16, goalstack17, goalstack18, goalstack19;
 359 .entity goalstack20, goalstack21, goalstack22, goalstack23;
 360 .entity goalstack24, goalstack25, goalstack26, goalstack27;
 361 .entity goalstack28, goalstack29, goalstack30, goalstack31;
 362
 363 .entity nearestwaypoint;
 364 .float nearestwaypointtimeout;
 365
 366 // used during navigation_goalrating_begin/end sessions
 367 float navigation_bestrating;
 368 entity navigation_bestgoal;
 369
 370
 371
 372
 373
 374 /////////////////////////////////////////////////////////////////////////////
 375 // waypoint management
 376 /////////////////////////////////////////////////////////////////////////////
 377
 378 // waypoints with this flag are not saved, they are automatically generated
 379 // waypoints like jump pads, teleporters, and items
 380 float WAYPOINTFLAG_GENERATED = 8388608;
 381 float WAYPOINTFLAG_ITEM = 4194304;
 382 float WAYPOINTFLAG_TELEPORT = 2097152;
 383 float WAYPOINTFLAG_NORELINK = 1048576;
 384
 385 // add a new link to the waypoint, replacing the furthest link it already has
 386 void(entity from, entity to) waypoint_addlink =
 387 {
 388         local float c;
 389
 390         if (from == to)
 391                 return;
 392         if (from.wpflags & WAYPOINTFLAG_NORELINK)
 393                 return;
 394
 395         if (from.wp00 == to) return;if (from.wp01 == to) return;if (from.wp02 == to) return;if (from.wp03 == to) return;
 396         if (from.wp04 == to) return;if (from.wp05 == to) return;if (from.wp06 == to) return;if (from.wp07 == to) return;
 397         if (from.wp08 == to) return;if (from.wp09 == to) return;if (from.wp10 == to) return;if (from.wp11 == to) return;
 398         if (from.wp12 == to) return;if (from.wp13 == to) return;if (from.wp14 == to) return;if (from.wp15 == to) return;
 399         if (from.wp16 == to) return;if (from.wp17 == to) return;if (from.wp18 == to) return;if (from.wp19 == to) return;
 400         if (from.wp20 == to) return;if (from.wp21 == to) return;if (from.wp22 == to) return;if (from.wp23 == to) return;
 401         if (from.wp24 == to) return;if (from.wp25 == to) return;if (from.wp26 == to) return;if (from.wp27 == to) return;
 402         if (from.wp28 == to) return;if (from.wp29 == to) return;if (from.wp30 == to) return;if (from.wp31 == to) return;
 403
 404         if (to.wpisbox || from.wpisbox)
 405         {
 406                 // if either is a box we have to find the nearest points on them to
 407                 // calculate the distance properly
 408                 local vector v1, v2, m1, m2;
 409                 v1 = from.origin;
 410                 m1 = to.absmin;
 411                 m2 = to.absmax;
 412                 v1_x = bound(m1_x, v1_x, m2_x);
 413                 v1_y = bound(m1_y, v1_y, m2_y);
 414                 v1_z = bound(m1_z, v1_z, m2_z);
 415                 v2 = to.origin;
 416                 m1 = from.absmin;
 417                 m2 = from.absmax;
 418                 v2_x = bound(m1_x, v2_x, m2_x);
 419                 v2_y = bound(m1_y, v2_y, m2_y);
 420                 v2_z = bound(m1_z, v2_z, m2_z);
 421                 v2 = to.origin;
 422                 c = vlen(v2 - v1);
 423         }
 424         else
 425                 c = vlen(to.origin - from.origin);
 426
 427         if (from.wp31mincost < c) return;
 428         if (from.wp30mincost < c) {from.wp31 = to;from.wp31mincost = c;return;} from.wp31 = from.wp30;from.wp31mincost = from.wp30mincost;
 429         if (from.wp29mincost < c) {from.wp30 = to;from.wp30mincost = c;return;} from.wp30 = from.wp29;from.wp30mincost = from.wp29mincost;
 430         if (from.wp28mincost < c) {from.wp29 = to;from.wp29mincost = c;return;} from.wp29 = from.wp28;from.wp29mincost = from.wp28mincost;
 431         if (from.wp27mincost < c) {from.wp28 = to;from.wp28mincost = c;return;} from.wp28 = from.wp27;from.wp28mincost = from.wp27mincost;
 432         if (from.wp26mincost < c) {from.wp27 = to;from.wp27mincost = c;return;} from.wp27 = from.wp26;from.wp27mincost = from.wp26mincost;
 433         if (from.wp25mincost < c) {from.wp26 = to;from.wp26mincost = c;return;} from.wp26 = from.wp25;from.wp26mincost = from.wp25mincost;
 434         if (from.wp24mincost < c) {from.wp25 = to;from.wp25mincost = c;return;} from.wp25 = from.wp24;from.wp25mincost = from.wp24mincost;
 435         if (from.wp23mincost < c) {from.wp24 = to;from.wp24mincost = c;return;} from.wp24 = from.wp23;from.wp24mincost = from.wp23mincost;
 436         if (from.wp22mincost < c) {from.wp23 = to;from.wp23mincost = c;return;} from.wp23 = from.wp22;from.wp23mincost = from.wp22mincost;
 437         if (from.wp21mincost < c) {from.wp22 = to;from.wp22mincost = c;return;} from.wp22 = from.wp21;from.wp22mincost = from.wp21mincost;
 438         if (from.wp20mincost < c) {from.wp21 = to;from.wp21mincost = c;return;} from.wp21 = from.wp20;from.wp21mincost = from.wp20mincost;
 439         if (from.wp19mincost < c) {from.wp20 = to;from.wp20mincost = c;return;} from.wp20 = from.wp19;from.wp20mincost = from.wp19mincost;
 440         if (from.wp18mincost < c) {from.wp19 = to;from.wp19mincost = c;return;} from.wp19 = from.wp18;from.wp19mincost = from.wp18mincost;
 441         if (from.wp17mincost < c) {from.wp18 = to;from.wp18mincost = c;return;} from.wp18 = from.wp17;from.wp18mincost = from.wp17mincost;
 442         if (from.wp16mincost < c) {from.wp17 = to;from.wp17mincost = c;return;} from.wp17 = from.wp16;from.wp17mincost = from.wp16mincost;
 443         if (from.wp15mincost < c) {from.wp16 = to;from.wp16mincost = c;return;} from.wp16 = from.wp15;from.wp16mincost = from.wp15mincost;
 444         if (from.wp14mincost < c) {from.wp15 = to;from.wp15mincost = c;return;} from.wp15 = from.wp14;from.wp15mincost = from.wp14mincost;
 445         if (from.wp13mincost < c) {from.wp14 = to;from.wp14mincost = c;return;} from.wp14 = from.wp13;from.wp14mincost = from.wp13mincost;
 446         if (from.wp12mincost < c) {from.wp13 = to;from.wp13mincost = c;return;} from.wp13 = from.wp12;from.wp13mincost = from.wp12mincost;
 447         if (from.wp11mincost < c) {from.wp12 = to;from.wp12mincost = c;return;} from.wp12 = from.wp11;from.wp12mincost = from.wp11mincost;
 448         if (from.wp10mincost < c) {from.wp11 = to;from.wp11mincost = c;return;} from.wp11 = from.wp10;from.wp11mincost = from.wp10mincost;
 449         if (from.wp09mincost < c) {from.wp10 = to;from.wp10mincost = c;return;} from.wp10 = from.wp09;from.wp10mincost = from.wp09mincost;
 450         if (from.wp08mincost < c) {from.wp09 = to;from.wp09mincost = c;return;} from.wp09 = from.wp08;from.wp09mincost = from.wp08mincost;
 451         if (from.wp07mincost < c) {from.wp08 = to;from.wp08mincost = c;return;} from.wp08 = from.wp07;from.wp08mincost = from.wp07mincost;
 452         if (from.wp06mincost < c) {from.wp07 = to;from.wp07mincost = c;return;} from.wp07 = from.wp06;from.wp07mincost = from.wp06mincost;
 453         if (from.wp05mincost < c) {from.wp06 = to;from.wp06mincost = c;return;} from.wp06 = from.wp05;from.wp06mincost = from.wp05mincost;
 454         if (from.wp04mincost < c) {from.wp05 = to;from.wp05mincost = c;return;} from.wp05 = from.wp04;from.wp05mincost = from.wp04mincost;
 455         if (from.wp03mincost < c) {from.wp04 = to;from.wp04mincost = c;return;} from.wp04 = from.wp03;from.wp04mincost = from.wp03mincost;
 456         if (from.wp02mincost < c) {from.wp03 = to;from.wp03mincost = c;return;} from.wp03 = from.wp02;from.wp03mincost = from.wp02mincost;
 457         if (from.wp01mincost < c) {from.wp02 = to;from.wp02mincost = c;return;} from.wp02 = from.wp01;from.wp02mincost = from.wp01mincost;
 458         if (from.wp00mincost < c) {from.wp01 = to;from.wp01mincost = c;return;} from.wp01 = from.wp00;from.wp01mincost = from.wp00mincost;
 459         from.wp00 = to;from.wp00mincost = c;return;
 460 };
 461
 462 // relink this waypoint
 463 // (precompile a list of all reachable waypoints from this waypoint)
 464 // (SLOW!)
 465 void() waypoint_think =
 466 {
 467         local entity e;
 468         local vector sv, sm1, sm2, ev, em1, em2, dv;
 469         //dprint("waypoint_think wpisbox = ", ftos(self.wpisbox), "\n");
 470         sm1 = self.origin + self.mins;
 471         sm2 = self.origin + self.maxs;
 472         e = find(world, classname, "waypoint");
 473         stepheightvec = cvar("sv_stepheight") * '0 0 1';
 474         while (e)
 475         {
 476                 if (boxesoverlap(self.absmin, self.absmax, e.absmin, e.absmax))
 477                 {
 478                         waypoint_addlink(self, e);
 479                         waypoint_addlink(e, self);
 480                 }
 481                 else
 482                 {
 483                         sv = e.origin;
 484                         sv_x = bound(sm1_x, sv_x, sm2_x);
 485                         sv_y = bound(sm1_y, sv_y, sm2_y);
 486                         sv_z = bound(sm1_z, sv_z, sm2_z);
 487                         ev = self.origin;
 488                         em1 = e.origin + e.mins;
 489                         em2 = e.origin + e.maxs;
 490                         ev_x = bound(em1_x, ev_x, em2_x);
 491                         ev_y = bound(em1_y, ev_y, em2_y);
 492                         ev_z = bound(em1_z, ev_z, em2_z);
 493                         dv = ev - sv;
 494                         dv_z = 0;
 495                         if (vlen(dv) < 1050) // max search distance in XY
 496                         {
 497                                 navigation_testtracewalk = 0;
 498                                 if (!self.wpisbox)
 499                                 {
 500                                         tracebox(sv - PL_MIN_z * '0 0 1', PL_MIN, PL_MAX, sv, FALSE, self);
 501                                         if (!trace_startsolid)
 502                                         {
 503                                                 //dprint("sv deviation", vtos(trace_endpos - sv), "\n");
 504                                                 sv = trace_endpos + '0 0 1';
 505                                         }
 506                                 }
 507                                 if (!e.wpisbox)
 508                                 {
 509                                         tracebox(ev - PL_MIN_z * '0 0 1', PL_MIN, PL_MAX, ev, FALSE, e);
 510                                         if (!trace_startsolid)
 511                                         {
 512                                                 //dprint("ev deviation", vtos(trace_endpos - ev), "\n");
 513                                                 ev = trace_endpos + '0 0 1';
 514                                         }
 515                                 }
 516                                 //traceline(self.origin, e.origin, FALSE, world);
 517                                 //if (trace_fraction == 1)
 518                                 if (!self.wpisbox)
 519                                 if (tracewalk(self, sv, PL_MIN, PL_MAX, ev))
 520                                         waypoint_addlink(self, e);
 521                                 if (!e.wpisbox)
 522                                 if (tracewalk(e, ev, PL_MIN, PL_MAX, sv))
 523                                         waypoint_addlink(e, self);
 524                         }
 525                 }
 526                 e = find(e, classname, "waypoint");
 527         }
 528         navigation_testtracewalk = 0;
 529 };
 530
 531 void(entity wp) waypoint_clearlinks =
 532 {
 533         // clear links to other waypoints
 534         local float f;
 535         f = 10000000;
 536         wp.wp00 = wp.wp01 = wp.wp02 = wp.wp03 = wp.wp04 = wp.wp05 = wp.wp06 = wp.wp07 = world;wp.wp00mincost = wp.wp01mincost = wp.wp02mincost = wp.wp03mincost = wp.wp04mincost = wp.wp05mincost = wp.wp06mincost = wp.wp07mincost = f;
 537         wp.wp08 = wp.wp09 = wp.wp10 = wp.wp11 = wp.wp12 = wp.wp13 = wp.wp14 = wp.wp15 = world;wp.wp08mincost = wp.wp09mincost = wp.wp10mincost = wp.wp11mincost = wp.wp12mincost = wp.wp13mincost = wp.wp14mincost = wp.wp15mincost = f;
 538         wp.wp16 = wp.wp17 = wp.wp18 = wp.wp19 = wp.wp20 = wp.wp21 = wp.wp22 = wp.wp23 = world;wp.wp16mincost = wp.wp17mincost = wp.wp18mincost = wp.wp19mincost = wp.wp20mincost = wp.wp21mincost = wp.wp22mincost = wp.wp23mincost = f;
 539         wp.wp24 = wp.wp25 = wp.wp26 = wp.wp27 = wp.wp28 = wp.wp29 = wp.wp30 = wp.wp31 = world;wp.wp24mincost = wp.wp25mincost = wp.wp26mincost = wp.wp27mincost = wp.wp28mincost = wp.wp29mincost = wp.wp30mincost = wp.wp31mincost = f;
 540 };
 541
 542 // tell a waypoint to relink
 543 void(entity wp) waypoint_schedulerelink =
 544 {
 545         if (wp == world)
 546                 return;
 547         // TODO: add some sort of visible box in edit mode for box waypoints
 548         if (cvar("g_waypointeditor"))
 549         {
 550                 local vector m1, m2;
 551                 m1 = wp.mins;
 552                 m2 = wp.maxs;
 553                 setmodel(wp, "models/runematch/rune.mdl"); wp.effects = EF_LOWPRECISION;
 554                 setsize(wp, m1, m2);
 555         }
 556         else
 557                 wp.model = "";
 558         wp.wpisbox = vlen(wp.size) > 0;
 559         wp.enemy = world;
 560         wp.owner = world;
 561         if (!(wp.wpflags & WAYPOINTFLAG_NORELINK))
 562                 waypoint_clearlinks(wp);
 563         // schedule an actual relink on next frame
 564         wp.think = waypoint_think;
 565         wp.nextthink = time;
 566         wp.effects = EF_LOWPRECISION;
 567 }
 568
 569 // create a new waypoint and automatically link it to other waypoints, and link
 570 // them back to it as well
 571 // (suitable for waypoint editor)
 572 entity(vector m1, vector m2, float f) waypoint_spawn =
 573 {
 574         local entity w;
 575         local vector org;
 576         org = (m1 + m2) * 0.5;
 577         m1 = m1 - org;
 578         m2 = m2 - org;
 579         w = find(world, classname, "waypoint");
 580         while (w)
 581         {
 582                 // if a matching waypoint already exists, don't add a duplicate
 583                 if (w.origin == org && w.mins == m1 && w.maxs == m2)
 584                         return w;
 585                 w = find(w, classname, "waypoint");
 586         }
 587         w = spawn();
 588         w.classname = "waypoint";
 589         w.wpflags = f;
 590         setorigin(w, org);
 591         setsize(w, PL_MIN + m1, PL_MAX + m2);
 592
 593         if(!(f & WAYPOINTFLAG_GENERATED))
 594         {
 595                 org = w.origin + '0 0 2';
 596                 tracebox(org, w.mins, w.maxs, w.origin, MOVE_WORLDONLY, w);
 597                 if(trace_startsolid)
 598                 {
 599                         org = w.origin + '2 2 2';
 600                         tracebox(org, w.mins, w.maxs, w.origin, MOVE_WORLDONLY, w);
 601                         if(trace_startsolid)
 602                         {
 603                                 org = w.origin + '-2 -2 2';
 604                                 tracebox(org, w.mins, w.maxs, w.origin, MOVE_WORLDONLY, w);
 605                                 if(trace_startsolid)
 606                                 {
 607                                         org = w.origin + '-2 2 2';
 608                                         tracebox(org, w.mins, w.maxs, w.origin, MOVE_WORLDONLY, w);
 609                                         if(trace_startsolid)
 610                                         {
 611                                                 org = w.origin + '2 -2 2';
 612                                                 tracebox(org, w.mins, w.maxs, w.origin, MOVE_WORLDONLY, w);
 613                                                 if(trace_startsolid)
 614                                                 {
 615                                                         // this WP is in solid, refuse it
 616                                                         dprint("Killed a waypoint that was stuck in solid at ", vtos(org), "\n");
 617                                                         remove(w);
 618                                                         return world;
 619                                                 }
 620                                         }
 621                                 }
 622                         }
 623                 }
 624
 625                 org = org * 0.05 + trace_endpos * 0.95; // don't trust the trace fully
 626                 tracebox(org, w.mins, w.maxs, org - '0 0 128', MOVE_WORLDONLY, w);
 627
 628                 if(trace_fraction == 1 || trace_startsolid)
 629                 {
 630                         // this WP is in air, refuse it
 631                         dprint("Killed a waypoint that was stuck in air/ceiling at ", vtos(w.origin), "\n");
 632                         remove(w);
 633                         return world;
 634                 }
 635                 trace_endpos_z += 0.1; // don't trust the trace fully
 636
 637 //              dprint("Moved waypoint at ", vtos(w.origin), " by ", ftos(vlen(w.origin - trace_endpos)));
 638 //              dprint(" direction: ", vtos((trace_endpos - w.origin)), "\n");
 639
 640                 setorigin(w, trace_endpos);
 641         }
 642
 643         setsize(w, m1, m2);
 644
 645         waypoint_clearlinks(w);
 646         //waypoint_schedulerelink(w);
 647         return w;
 648 };
 649
 650 // waypoint map entity
 651 void() waypoint =
 652 {
 653         setorigin(self, self.origin);
 654         // schedule a relink after other waypoints have had a chance to spawn
 655         waypoint_clearlinks(self);
 656         //waypoint_schedulerelink(self);
 657 };
 658
 659 // remove a waypoint, and schedule all neighbors to relink
 660 void(entity e) waypoint_remove =
 661 {
 662         // tell all linked waypoints that they need to relink
 663         waypoint_schedulerelink(e.wp00);
 664         waypoint_schedulerelink(e.wp01);
 665         waypoint_schedulerelink(e.wp02);
 666         waypoint_schedulerelink(e.wp03);
 667         waypoint_schedulerelink(e.wp04);
 668         waypoint_schedulerelink(e.wp05);
 669         waypoint_schedulerelink(e.wp06);
 670         waypoint_schedulerelink(e.wp07);
 671         waypoint_schedulerelink(e.wp08);
 672         waypoint_schedulerelink(e.wp09);
 673         waypoint_schedulerelink(e.wp10);
 674         waypoint_schedulerelink(e.wp11);
 675         waypoint_schedulerelink(e.wp12);
 676         waypoint_schedulerelink(e.wp13);
 677         waypoint_schedulerelink(e.wp14);
 678         waypoint_schedulerelink(e.wp15);
 679         waypoint_schedulerelink(e.wp16);
 680         waypoint_schedulerelink(e.wp17);
 681         waypoint_schedulerelink(e.wp18);
 682         waypoint_schedulerelink(e.wp19);
 683         waypoint_schedulerelink(e.wp20);
 684         waypoint_schedulerelink(e.wp21);
 685         waypoint_schedulerelink(e.wp22);
 686         waypoint_schedulerelink(e.wp23);
 687         waypoint_schedulerelink(e.wp24);
 688         waypoint_schedulerelink(e.wp25);
 689         waypoint_schedulerelink(e.wp26);
 690         waypoint_schedulerelink(e.wp27);
 691         waypoint_schedulerelink(e.wp28);
 692         waypoint_schedulerelink(e.wp29);
 693         waypoint_schedulerelink(e.wp30);
 694         waypoint_schedulerelink(e.wp31);
 695         // and now remove the waypoint
 696         remove(e);
 697 };
 698
 699 // empties the map of waypoints
 700 void() waypoint_removeall =
 701 {
 702         local entity head, next;
 703         head = findchain(classname, "waypoint");
 704         while (head)
 705         {
 706                 next = head.chain;
 707                 remove(head);
 708                 head = next;
 709         }
 710 };
 711
 712 // tell all waypoints to relink
 713 // (is this useful at all?)
 714 void() waypoint_schedulerelinkall =
 715 {
 716         local entity head;
 717         head = findchain(classname, "waypoint");
 718         while (head)
 719         {
 720                 waypoint_schedulerelink(head);
 721                 head = head.chain;
 722         }
 723 };
 724
 725 // save waypoints to gamedir/data/maps/mapname.waypoints
 726 // TODO: support saving wayboxes
 727 void() waypoint_saveall =
 728 {
 729         local string filename, s;
 730         local float file, c;
 731         local entity w;
 732         filename = strcat("maps/", mapname);
 733         filename = strcat(filename, ".waypoints");
 734         file = fopen(filename, FILE_WRITE);
 735         if (file >= 0)
 736         {
 737                 c = 0;
 738                 w = findchain(classname, "waypoint");
 739                 while (w)
 740                 {
 741                         if (!(w.wpflags & WAYPOINTFLAG_GENERATED))
 742                         {
 743                                 s = strcat(vtos(w.origin + w.mins), "\n");
 744                                 s = strcat(s, vtos(w.origin + w.maxs));
 745                                 s = strcat(s, "\n");
 746                                 s = strcat(s, ftos(w.wpflags));
 747                                 s = strcat(s, "\n");
 748                                 fputs(file, s);
 749                                 c = c + 1;
 750                         }
 751                         w = w.chain;
 752                 }
 753                 fclose(file);
 754                 bprint("saved ");
 755                 bprint(ftos(c));
 756                 bprint(" waypoints to maps/");
 757                 bprint(mapname);
 758                 bprint(".waypoints\n");
 759         }
 760         else
 761         {
 762                 bprint("waypoint save to ");
 763                 bprint(filename);
 764                 bprint(" failed\n");
 765         }
 766 };
 767
 768 // load waypoints from file
 769 float() waypoint_loadall =
 770 {
 771         local string filename, s;
 772         local float file, cwp, cwb, fl;
 773         local vector m1, m2;
 774         cwp = 0;
 775         cwb = 0;
 776         filename = strcat("maps/", mapname);
 777         filename = strcat(filename, ".waypoints");
 778         file = fopen(filename, FILE_READ);
 779         if (file >= 0)
 780         {
 781                 while (1)
 782                 {
 783                         s = fgets(file);
 784                         if (!s)
 785                                 break;
 786                         m1 = stov(s);
 787                         s = fgets(file);
 788                         if (!s)
 789                                 break;
 790                         m2 = stov(s);
 791                         s = fgets(file);
 792                         if (!s)
 793                                 break;
 794                         fl = stof(s);
 795                         waypoint_spawn(m1, m2, fl);
 796                         if (m1 == m2)
 797                                 cwp = cwp + 1;
 798                         else
 799                                 cwb = cwb + 1;
 800                 }
 801                 fclose(file);
 802                 dprint("loaded ");
 803                 dprint(ftos(cwp));
 804                 dprint(" waypoints and ");
 805                 dprint(ftos(cwb));
 806                 dprint(" wayboxes from maps/");
 807                 dprint(mapname);
 808                 dprint(".waypoints\n");
 809         }
 810         else
 811         {
 812                 dprint("waypoint load from ");
 813                 dprint(filename);
 814                 dprint(" failed\n");
 815         }
 816         return cwp + cwb;
 817 };
 818
 819 void(entity e) waypoint_spawnforitem =
 820 {
 821         local entity w;
 822         local vector org;
 823
 824         if(!bot_waypoints_for_items)
 825                 return;
 826
 827         org = e.origin + (e.mins + e.maxs) * 0.5;
 828         org_z = e.origin_z + e.mins_z - PL_MIN_z + 1;
 829         e.nearestwaypointtimeout = time + 1000000000;
 830         // don't spawn an item waypoint if it already exists
 831         w = findchain(classname, "waypoint");
 832         while (w)
 833         {
 834                 if (vlen(w.size) > 1)
 835                 {
 836                         if (boxesoverlap(org, org, w.absmin, w.absmax))
 837                         {
 838                                 e.nearestwaypoint = w;
 839                                 return;
 840                         }
 841                 }
 842                 else
 843                 {
 844                         if (vlen(w.origin - org) < 16)
 845                         {
 846                                 e.nearestwaypoint = w;
 847                                 return;
 848                         }
 849                 }
 850                 w = w.chain;
 851         }
 852         e.nearestwaypoint = waypoint_spawn(org, org, WAYPOINTFLAG_GENERATED | WAYPOINTFLAG_ITEM);
 853 };
 854
 855 void(entity e, vector destination, float timetaken) waypoint_spawnforteleporter =
 856 {
 857         local entity w;
 858         local entity dw;
 859         w = waypoint_spawn(e.absmin, e.absmax, WAYPOINTFLAG_GENERATED | WAYPOINTFLAG_TELEPORT | WAYPOINTFLAG_NORELINK);
 860         dw = waypoint_spawn(destination, destination, WAYPOINTFLAG_GENERATED);
 861         // one way link to the destination
 862         w.wp00 = dw;
 863         w.wp00mincost = timetaken; // this is just for jump pads
 864         // the teleporter's nearest waypoint is this one
 865         // (teleporters are not goals, so this is probably useless)
 866         e.nearestwaypoint = w;
 867         e.nearestwaypointtimeout = time + 1000000000;
 868 };
 869
 870
 871
 872
 873
 874 /////////////////////////////////////////////////////////////////////////////
 875 // goal stack
 876 /////////////////////////////////////////////////////////////////////////////
 877
 878 // completely empty the goal stack, used when deciding where to go
 879 void() navigation_clearroute =
 880 {
 881         self.goalcurrent = world;
 882         self.goalstack01 = world;
 883         self.goalstack02 = world;
 884         self.goalstack03 = world;
 885         self.goalstack04 = world;
 886         self.goalstack05 = world;
 887         self.goalstack06 = world;
 888         self.goalstack07 = world;
 889         self.goalstack08 = world;
 890         self.goalstack09 = world;
 891         self.goalstack10 = world;
 892         self.goalstack11 = world;
 893         self.goalstack12 = world;
 894         self.goalstack13 = world;
 895         self.goalstack14 = world;
 896         self.goalstack15 = world;
 897         self.goalstack16 = world;
 898         self.goalstack17 = world;
 899         self.goalstack18 = world;
 900         self.goalstack19 = world;
 901         self.goalstack20 = world;
 902         self.goalstack21 = world;
 903         self.goalstack22 = world;
 904         self.goalstack23 = world;
 905         self.goalstack24 = world;
 906         self.goalstack25 = world;
 907         self.goalstack26 = world;
 908         self.goalstack27 = world;
 909         self.goalstack28 = world;
 910         self.goalstack29 = world;
 911         self.goalstack30 = world;
 912         self.goalstack31 = world;
 913 };
 914
 915 // add a new goal at the beginning of the stack
 916 // (in other words: add a new prerequisite before going to the later goals)
 917 void(entity e) navigation_pushroute =
 918 {
 919         self.goalstack31 = self.goalstack30;
 920         self.goalstack30 = self.goalstack29;
 921         self.goalstack29 = self.goalstack28;
 922         self.goalstack28 = self.goalstack27;
 923         self.goalstack27 = self.goalstack26;
 924         self.goalstack26 = self.goalstack25;
 925         self.goalstack25 = self.goalstack24;
 926         self.goalstack24 = self.goalstack23;
 927         self.goalstack23 = self.goalstack22;
 928         self.goalstack22 = self.goalstack21;
 929         self.goalstack21 = self.goalstack20;
 930         self.goalstack20 = self.goalstack19;
 931         self.goalstack19 = self.goalstack18;
 932         self.goalstack18 = self.goalstack17;
 933         self.goalstack17 = self.goalstack16;
 934         self.goalstack16 = self.goalstack15;
 935         self.goalstack15 = self.goalstack14;
 936         self.goalstack14 = self.goalstack13;
 937         self.goalstack13 = self.goalstack12;
 938         self.goalstack12 = self.goalstack11;
 939         self.goalstack11 = self.goalstack10;
 940         self.goalstack10 = self.goalstack09;
 941         self.goalstack09 = self.goalstack08;
 942         self.goalstack08 = self.goalstack07;
 943         self.goalstack07 = self.goalstack06;
 944         self.goalstack06 = self.goalstack05;
 945         self.goalstack05 = self.goalstack04;
 946         self.goalstack04 = self.goalstack03;
 947         self.goalstack03 = self.goalstack02;
 948         self.goalstack02 = self.goalstack01;
 949         self.goalstack01 = self.goalcurrent;
 950         self.goalcurrent = e;
 951 };
 952
 953 // remove first goal from stack
 954 // (in other words: remove a prerequisite for reaching the later goals)
 955 // (used when a waypoint is reached)
 956 void() navigation_poproute =
 957 {
 958         self.goalcurrent = self.goalstack01;
 959         self.goalstack01 = self.goalstack02;
 960         self.goalstack02 = self.goalstack03;
 961         self.goalstack03 = self.goalstack04;
 962         self.goalstack04 = self.goalstack05;
 963         self.goalstack05 = self.goalstack06;
 964         self.goalstack06 = self.goalstack07;
 965         self.goalstack07 = self.goalstack08;
 966         self.goalstack08 = self.goalstack09;
 967         self.goalstack09 = self.goalstack10;
 968         self.goalstack10 = self.goalstack11;
 969         self.goalstack11 = self.goalstack12;
 970         self.goalstack12 = self.goalstack13;
 971         self.goalstack13 = self.goalstack14;
 972         self.goalstack14 = self.goalstack15;
 973         self.goalstack15 = self.goalstack16;
 974         self.goalstack16 = self.goalstack17;
 975         self.goalstack17 = self.goalstack18;
 976         self.goalstack18 = self.goalstack19;
 977         self.goalstack19 = self.goalstack20;
 978         self.goalstack20 = self.goalstack21;
 979         self.goalstack21 = self.goalstack22;
 980         self.goalstack22 = self.goalstack23;
 981         self.goalstack23 = self.goalstack24;
 982         self.goalstack24 = self.goalstack25;
 983         self.goalstack25 = self.goalstack26;
 984         self.goalstack26 = self.goalstack27;
 985         self.goalstack27 = self.goalstack28;
 986         self.goalstack28 = self.goalstack29;
 987         self.goalstack29 = self.goalstack30;
 988         self.goalstack30 = self.goalstack31;
 989         self.goalstack31 = world;
 990 };
 991
 992 // find the waypoint near a dynamic goal such as a dropped weapon
 993 entity(entity player, float walkfromwp) navigation_findnearestwaypoint =
 994 {
 995         local entity waylist, w, best;
 996         local float dist, bestdist;
 997         local vector v, org, pm1, pm2;
 998         pm1 = player.origin + PL_MIN;
 999         pm2 = player.origin + PL_MAX;
1000         waylist = findchain(classname, "waypoint");
1001         // do two scans, because box test is cheaper
1002         w = waylist;
1003         while (w)
1004         {
1005                 // if object is touching waypoint
1006                 if (boxesoverlap(pm1, pm2, w.absmin, w.absmax))
1007                         return w;
1008                 w = w.chain;
1009         }
1010
1011         org = player.origin + (player.mins_z - PL_MIN_z) * '0 0 1';
1012         if(player.tag_entity)
1013                 org = org + player.tag_entity.origin;
1014         if (navigation_testtracewalk)
1015                 te_plasmaburn(org);
1016         best = world;
1017         bestdist = 1050;
1018
1019         // box check failed, try walk
1020         w = waylist;
1021         while (w)
1022         {
1023                 // if object can walk from waypoint
1024                 if (w.wpisbox)
1025                 {
1026                         local vector wm1, wm2;
1027                         wm1 = w.origin + w.mins;
1028                         wm2 = w.origin + w.maxs;
1029                         v_x = bound(wm1_x, org_x, wm2_x);
1030                         v_y = bound(wm1_y, org_y, wm2_y);
1031                         v_z = bound(wm1_z, org_z, wm2_z);
1032                 }
1033                 else
1034                         v = w.origin;
1035                 dist = vlen(v - org);
1036                 if (bestdist > dist)
1037                 {
1038                         if (walkfromwp)
1039                         {
1040                                 traceline(v, org, TRUE, player);
1041                                 if (trace_fraction == 1)
1042                                 if (tracewalk(player, v, PL_MIN, PL_MAX, org))
1043                                 {
1044                                         bestdist = dist;
1045                                         best = w;
1046                                 }
1047                         }
1048                         else
1049                         {
1050                                 traceline(v, org, TRUE, player);
1051                                 if (trace_fraction == 1)
1052                                 if (tracewalk(player, org, PL_MIN, PL_MAX, v))
1053                                 {
1054                                         bestdist = dist;
1055                                         best = w;
1056                                 }
1057                         }
1058                 }
1059                 w = w.chain;
1060         }
1061         return best;
1062 }
1063
1064 // finds the waypoints near the bot initiating a navigation query
1065 void() navigation_markroutes_nearestwaypoints =
1066 {
1067         local entity head;
1068         local float dist;
1069         local vector v, m1, m2;
1070         //navigation_testtracewalk = TRUE;
1071         head = findchain(classname, "waypoint");
1072         while (head)
1073         {
1074                 m1 = head.origin + head.mins;
1075                 m2 = head.origin + head.maxs;
1076                 v = self.origin;
1077                 v_x = bound(m1_x, v_x, m2_x);
1078                 v_y = bound(m1_y, v_y, m2_y);
1079                 v_z = bound(m1_z, v_z, m2_z);
1080                 dist = vlen(v - self.origin);
1081                 if (dist < 1000)
1082                 {
1083                         if (dist < 4)
1084                         {
1085                                 // if bot is very near a waypoint don't bother doing a trace
1086                                 head.wpnearestpoint = v;
1087                                 head.wpcost = dist + head.dmg;
1088                                 head.wpfire = 1;
1089                                 head.enemy = world;
1090                         }
1091                         else
1092                         {
1093                                 tracebox(self.origin, '-16 -16 0', '16 16 0', v, TRUE, self);
1094                                 if (trace_fraction == 1)
1095                                 {
1096                                         if (tracewalk(self, self.origin, self.mins, self.maxs, v))
1097                                         {
1098                                                 head.wpnearestpoint = v;
1099                                                 head.wpcost = dist + head.dmg;
1100                                                 head.wpfire = 1;
1101                                                 head.enemy = world;
1102                                         }
1103                                 }
1104                         }
1105                 }
1106                 head = head.chain;
1107         }
1108         //navigation_testtracewalk = FALSE;
1109 }
1110
1111 // updates a path link if a waypoint link is better than the current one
1112 void(entity w, entity wp, float cost2, vector p) navigation_markroutes_checkwaypoint =
1113 {
1114         local vector m1;
1115         local vector m2;
1116         local vector v;
1117         if (wp.wpisbox)
1118         {
1119                 m1 = wp.absmin;
1120                 m2 = wp.absmax;
1121                 v_x = bound(m1_x, p_x, m2_x);
1122                 v_y = bound(m1_y, p_y, m2_y);
1123                 v_z = bound(m1_z, p_z, m2_z);
1124         }
1125         else
1126                 v = wp.origin;
1127         cost2 = cost2 + vlen(v);
1128         if (wp.wpcost > cost2)
1129         {
1130                 wp.wpcost = cost2;
1131                 wp.enemy = w;
1132                 wp.wpfire = 1;
1133                 wp.wpnearestpoint = v;
1134         }
1135 };
1136
1137 // queries the entire waypoint network for pathes leading away from the bot
1138 void() navigation_markroutes =
1139 {
1140         local entity w, wp, waylist;
1141         local float searching, cost, cost2;
1142         local vector p;
1143         w = waylist = findchain(classname, "waypoint");
1144         while (w)
1145         {
1146                 w.wpnearestpoint = '0 0 0';
1147                 w.wpcost = 10000000;
1148                 w.wpfire = 0;
1149                 w.enemy = world;
1150                 w = w.chain;
1151         }
1152         navigation_markroutes_nearestwaypoints();
1153         searching = TRUE;
1154         while (searching)
1155         {
1156                 searching = FALSE;
1157                 w = waylist;
1158                 while (w)
1159                 {
1160                         if (w.wpfire)
1161                         {
1162                                 searching = TRUE;
1163                                 w.wpfire = 0;
1164                                 cost = w.wpcost;
1165                                 p = w.wpnearestpoint;
1166                                 wp = w.wp00;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + wp.wp00mincost) navigation_markroutes_checkwaypoint(w, wp, cost2, p);
1167                                 wp = w.wp01;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + wp.wp01mincost) navigation_markroutes_checkwaypoint(w, wp, cost2, p);
1168                                 wp = w.wp02;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + wp.wp02mincost) navigation_markroutes_checkwaypoint(w, wp, cost2, p);
1169                                 wp = w.wp03;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + wp.wp03mincost) navigation_markroutes_checkwaypoint(w, wp, cost2, p);
1170                                 wp = w.wp04;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + wp.wp04mincost) navigation_markroutes_checkwaypoint(w, wp, cost2, p);
1171                                 wp = w.wp05;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + wp.wp05mincost) navigation_markroutes_checkwaypoint(w, wp, cost2, p);
1172                                 wp = w.wp06;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + wp.wp06mincost) navigation_markroutes_checkwaypoint(w, wp, cost2, p);
1173                                 wp = w.wp07;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + wp.wp07mincost) navigation_markroutes_checkwaypoint(w, wp, cost2, p);
1174                                 wp = w.wp08;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + wp.wp08mincost) navigation_markroutes_checkwaypoint(w, wp, cost2, p);
1175                                 wp = w.wp09;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + wp.wp09mincost) navigation_markroutes_checkwaypoint(w, wp, cost2, p);
1176                                 wp = w.wp10;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + wp.wp10mincost) navigation_markroutes_checkwaypoint(w, wp, cost2, p);
1177                                 wp = w.wp11;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + wp.wp11mincost) navigation_markroutes_checkwaypoint(w, wp, cost2, p);
1178                                 wp = w.wp12;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + wp.wp12mincost) navigation_markroutes_checkwaypoint(w, wp, cost2, p);
1179                                 wp = w.wp13;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + wp.wp13mincost) navigation_markroutes_checkwaypoint(w, wp, cost2, p);
1180                                 wp = w.wp14;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + wp.wp14mincost) navigation_markroutes_checkwaypoint(w, wp, cost2, p);
1181                                 wp = w.wp15;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + wp.wp15mincost) navigation_markroutes_checkwaypoint(w, wp, cost2, p);
1182                                 wp = w.wp16;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + wp.wp16mincost) navigation_markroutes_checkwaypoint(w, wp, cost2, p);
1183                                 wp = w.wp17;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + wp.wp17mincost) navigation_markroutes_checkwaypoint(w, wp, cost2, p);
1184                                 wp = w.wp18;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + wp.wp18mincost) navigation_markroutes_checkwaypoint(w, wp, cost2, p);
1185                                 wp = w.wp19;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + wp.wp19mincost) navigation_markroutes_checkwaypoint(w, wp, cost2, p);
1186                                 wp = w.wp20;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + wp.wp20mincost) navigation_markroutes_checkwaypoint(w, wp, cost2, p);
1187                                 wp = w.wp21;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + wp.wp21mincost) navigation_markroutes_checkwaypoint(w, wp, cost2, p);
1188                                 wp = w.wp22;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + wp.wp22mincost) navigation_markroutes_checkwaypoint(w, wp, cost2, p);
1189                                 wp = w.wp23;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + wp.wp23mincost) navigation_markroutes_checkwaypoint(w, wp, cost2, p);
1190                                 wp = w.wp24;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + wp.wp24mincost) navigation_markroutes_checkwaypoint(w, wp, cost2, p);
1191                                 wp = w.wp25;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + wp.wp25mincost) navigation_markroutes_checkwaypoint(w, wp, cost2, p);
1192                                 wp = w.wp26;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + wp.wp26mincost) navigation_markroutes_checkwaypoint(w, wp, cost2, p);
1193                                 wp = w.wp27;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + wp.wp27mincost) navigation_markroutes_checkwaypoint(w, wp, cost2, p);
1194                                 wp = w.wp28;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + wp.wp28mincost) navigation_markroutes_checkwaypoint(w, wp, cost2, p);
1195                                 wp = w.wp29;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + wp.wp29mincost) navigation_markroutes_checkwaypoint(w, wp, cost2, p);
1196                                 wp = w.wp30;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + wp.wp30mincost) navigation_markroutes_checkwaypoint(w, wp, cost2, p);
1197                                 wp = w.wp31;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + wp.wp31mincost) navigation_markroutes_checkwaypoint(w, wp, cost2, p);
1198                                 }}}}}}}}}}}}}}}}}}}}}}}}}}}}}}}}
1199                         }
1200                         w = w.chain;
1201                 }
1202         }
1203 };
1204
1205 // updates the best goal according to a weighted calculation of travel cost and item value of a new proposed item
1206 void(entity e, float f) navigation_routerating =
1207 {
1208         if (!e)
1209                 return;
1210         //te_wizspike(e.origin);
1211         //bprint(etos(e));
1212         //bprint("\n");
1213         // update the cached waypoint link on a dynamic item entity
1214         if (time > e.nearestwaypointtimeout)
1215         {
1216                 e.nearestwaypoint = navigation_findnearestwaypoint(e, TRUE);
1217                 e.nearestwaypointtimeout = time + random() * 3 + 5;
1218         }
1219         //dprint(e.classname, " ", ftos(f));
1220         if (e.nearestwaypoint)
1221         if (e.nearestwaypoint.wpcost < 10000000)
1222         {
1223                 //te_wizspike(e.nearestwaypoint.wpnearestpoint);
1224                 //dprint(e.classname, " ", ftos(f), "*(500/(500+", ftos((e.nearestwaypoint.wpcost + vlen(e.origin - e.nearestwaypoint.wpnearestpoint))), " = ");
1225                 f = f * 500 / ((e.nearestwaypoint.wpcost + vlen(e.origin - e.nearestwaypoint.wpnearestpoint)) + 500);
1226                 //dprint(ftos(f));
1227                 if (navigation_bestrating < f)
1228                 {
1229                         navigation_bestrating = f;
1230                         navigation_bestgoal = e;
1231                 }
1232         }
1233         //dprint("\n");
1234 };
1235
1236 // replaces the goal stack with the path to a given item
1237 void(entity e) navigation_routetogoal =
1238 {
1239         // if already going to this goal, don't stop
1240         //if (self.goalentity == e)
1241         //      return;
1242         // clear the route and add the new one
1243         navigation_clearroute();
1244         self.goalentity = e;
1245         // if there is no goal, just exit
1246         if (!e)
1247                 return;
1248         // put the entity on the goal stack as the only item
1249         navigation_pushroute(e);
1250         //te_smallflash((e.absmin + e.absmax) * 0.5);
1251         //bprint("navigation_routetogoal(");
1252         //bprint(etos(e));
1253         //bprint(") : ");
1254         //bprint(etos(e));
1255         tracebox(self.origin, '-16 -16 0', '16 16 0', e.origin, TRUE, self);
1256         if (trace_fraction == 1)
1257         if (tracewalk(self, self.origin, PL_MIN, PL_MAX, e.origin))
1258                 return;
1259         // see if there are waypoints describing a path to the item
1260         e = e.nearestwaypoint;
1261         while (e != world)
1262         {
1263                 //bprint(" ");
1264                 //bprint(etos(e));
1265                 //te_smallflash((e.absmin + e.absmax) * 0.5);
1266                 //tracebox(self.origin, '-16 -16 0', '16 16 0', e.origin, TRUE, self);
1267                 //if (trace_fraction == 1)
1268                 //if (tracewalk(self, self.origin, PL_MIN, PL_MAX, e.origin))
1269                 //      break;
1270                 // add the waypoint to the path
1271                 navigation_pushroute(e);
1272                 e = e.enemy;
1273         }
1274         //bprint("\n");
1275 };
1276
1277 // removes any currently touching waypoints from the goal stack
1278 // (this is how bots detect if they have reached a goal)
1279 void() navigation_poptouchedgoals =
1280 {
1281         local vector org, m1, m2;
1282         org = self.origin;// + self.velocity * 0.1;
1283         m1 = org + self.mins;
1284         m2 = org + self.maxs;
1285         while (self.goalcurrent && boxesoverlap(m1, m2, self.goalcurrent.absmin, self.goalcurrent.absmax))
1286                 navigation_poproute();
1287 }
1288
1289 // begin a goal selection session (queries waypoint network)
1290 void() navigation_goalrating_start =
1291 {
1292         navigation_bestrating = -1;
1293         navigation_bestgoal = world;
1294         navigation_markroutes();
1295 };
1296
1297 // ends a goal selection session (updates goal stack to the best goal)
1298 void() navigation_goalrating_end =
1299 {
1300         navigation_routetogoal(navigation_bestgoal);
1301 };
1302
1303
1304
1305
1306
1307 //////////////////////////////////////////////////////////////////////////////
1308 // general bot functions
1309 //////////////////////////////////////////////////////////////////////////////
1310
1311 .float isbot; // true if this client is actually a bot
1312
1313 float skill;
1314 entity bot_list;
1315 .entity nextbot;
1316
1317 float sv_maxspeed;
1318 .float createdtime;
1319
1320 .float bot_attack;
1321 .float bot_dodge;
1322 .float bot_dodgerating;
1323
1324 //.float bot_painintensity;
1325 .float bot_firetimer;
1326 //.float bot_oldhealth;
1327 .void() bot_ai;
1328
1329 .entity bot_aimtarg;
1330 .float bot_aimlatency;
1331 .vector bot_aimselforigin;
1332 .vector bot_aimselfvelocity;
1333 .vector bot_aimtargorigin;
1334 .vector bot_aimtargvelocity;
1335
1336 .float bot_pickup;
1337 .float(entity player, entity item) bot_pickupevalfunc;
1338 .float bot_pickupbasevalue;
1339 .float bot_canfire;
1340
1341 // used for aiming currently
1342 // FIXME: make the weapon code use these and then replace the calculations here with a call to the weapon code
1343 vector shotorg;
1344 vector shotdir;
1345
1346 const float BOTSKINS = 19;
1347 const float BOTNAMES = 32;
1348 string(float r) bot_namefornumber =
1349 {
1350         if (r <  1) return "Thunderstorm";
1351         if (r <  2) return "Darkness";
1352         if (r <  3) return "Scorcher";
1353         if (r <  4) return "Paranoia";
1354         if (r <  5) return "Eureka";
1355         if (r <  6) return "Mystery";
1356         if (r <  7) return "Toxic";
1357         if (r <  8) return "Dominion";
1358         if (r <  9) return "Pegasus";
1359         if (r < 10) return "Sensible";
1360         if (r < 11) return "Gator";
1361         if (r < 12) return "Kangaroo";
1362         if (r < 13) return "Deadline";
1363         if (r < 14) return "Frosty";
1364         if (r < 15) return "Roadkill";
1365         if (r < 16) return "Death";
1366         if (r < 17) return "Panic";
1367         if (r < 18) return "Discovery";
1368         if (r < 19) return "Shadow";
1369         if (r < 20) return "Acidic";
1370         if (r < 21) return "Dominator";
1371         if (r < 22) return "Hellfire";
1372         if (r < 23) return "Necrotic";
1373         if (r < 24) return "Newbie";
1374         if (r < 25) return "Spellbinder";
1375         if (r < 26) return "Lion";
1376         if (r < 27) return "Controlled";
1377         if (r < 28) return "Airhead";
1378         if (r < 29) return "Delirium";
1379         if (r < 30) return "Resurrection";
1380         if (r < 31) return "Danger";
1381         return "Flatline";
1382 };
1383
1384 string(float r) bot_skinfornumber =
1385 {
1386              if (r <  1) {self.playermodel = "models/player/carni.zym"          ;self.playerskin = "0";return "Carni"          ;}
1387         else if (r <  2) {self.playermodel = "models/player/carni.zym"          ;self.playerskin = "1";return "Armored Carni"  ;}
1388         else if (r <  3) {self.playermodel = "models/player/crash.zym"          ;self.playerskin = "0";return "Quark"          ;}
1389         else if (r <  4) {self.playermodel = "models/player/grunt.zym"          ;self.playerskin = "0";return "Grunt"          ;}
1390         else if (r <  5) {self.playermodel = "models/player/headhunter.zym"     ;self.playerskin = "0";return "HeadHunter"     ;}
1391         else if (r <  6) {self.playermodel = "models/player/insurrectionist.zym";self.playerskin = "0";return "Insurrectionist";}
1392         else if (r <  7) {self.playermodel = "models/player/lurk.zym"           ;self.playerskin = "0";return "Lurk"           ;}
1393         else if (r <  8) {self.playermodel = "models/player/lurk.zym"           ;self.playerskin = "1";return "Reptile"        ;}
1394         else if (r <  9) {self.playermodel = "models/player/lycanthrope.zym"    ;self.playerskin = "0";return "Lycanthrope"    ;}
1395         else if (r < 10) {self.playermodel = "models/player/marine.zym"         ;self.playerskin = "0";return "Marine"         ;}
1396         else if (r < 11) {self.playermodel = "models/player/nexus.zym"          ;self.playerskin = "0";return "Nexus"          ;}
1397         else if (r < 12) {self.playermodel = "models/player/nexus.zym"          ;self.playerskin = "1";return "Mulder"         ;}
1398         else if (r < 13) {self.playermodel = "models/player/nexus.zym"          ;self.playerskin = "2";return "Xolar"          ;}
1399         else if (r < 14) {self.playermodel = "models/player/pyria.zym"          ;self.playerskin = "0";return "Pyria"          ;}
1400         else if (r < 15) {self.playermodel = "models/player/shock.zym"          ;self.playerskin = "0";return "Shock"          ;}
1401         else if (r < 16) {self.playermodel = "models/player/skadi.zym"          ;self.playerskin = "0";return "Skadi"          ;}
1402         else if (r < 17) {self.playermodel = "models/player/specop.zym"         ;self.playerskin = "0";return "Specop"         ;}
1403         else             {self.playermodel = "models/player/visitant.zym"       ;self.playerskin = "0";return "Fricka"         ;}
1404 };
1405
1406 void() bot_setnameandstuff =
1407 {
1408         local string name, prefix, suffix;
1409         local float r, b, shirt, pants;
1410
1411         prefix = cvar_string("bot_prefix");
1412         suffix = cvar_string("bot_suffix");
1413
1414         // this is really only a default, JoinBestTeam is called later
1415         pants = bound(0, floor(random() * 13), 13);
1416         //shirt = bound(0, floor(random() * 16), 15);
1417         shirt = pants;
1418         self.clientcolors = shirt * 16 + pants;
1419         self.team = pants + 1;
1420
1421         // now pick a name...
1422
1423         if (cvar("bot_usemodelnames"))
1424         {
1425                 // first see if all skins are taken
1426                 b = 0;
1427                 do
1428                 {
1429                         name = bot_skinfornumber(b);
1430                         b = b + 1;
1431                 }
1432                 while (b < BOTSKINS && find(world, netname, name));
1433
1434                 // randomly pick a skin, if it's taken either repeat until we find one,
1435                 // or give up if we already know all skins are taken
1436                 do
1437                 {
1438                         r = floor(random() * BOTSKINS);
1439                         name = bot_skinfornumber(r);
1440                 }
1441                 while (b < BOTSKINS && find(world, netname, name));
1442         }
1443         else
1444         {
1445                 // first see if all names are taken
1446                 b = 0;
1447                 do
1448                 {
1449                         name = bot_namefornumber(b);
1450                         b = b + 1;
1451                 }
1452                 while (b < BOTNAMES && find(world, netname, name));
1453
1454                 // randomly pick a name, if it's taken either repeat until we find one,
1455                 // or give up if we already know all names are taken
1456                 do
1457                 {
1458                         r = floor(random() * BOTNAMES);
1459                         name = bot_namefornumber(r);
1460                 }
1461                 while (b < BOTNAMES && find(world, netname, name));
1462
1463                 // randomly pick a skin
1464                 bot_skinfornumber(floor(random() * BOTSKINS));
1465         }
1466         if(!cvar("g_campaign"))
1467                 self.netname = strzone(strcat(prefix, name, suffix));
1468         else
1469                 self.netname = name;
1470 };
1471
1472 float bot_ignore_bots; // let bots not attack other bots (only works in non-teamplay)
1473 float(entity e) bot_shouldattack =
1474 {
1475         if (e.team == self.team)
1476         {
1477                 if (e == self)
1478                         return FALSE;
1479                 if (teamplay)
1480                 if (e.team != 0)
1481                         return FALSE;
1482         }
1483         if(!teamplay)
1484                 if(bot_ignore_bots)
1485                         if(clienttype(e) == CLIENTTYPE_BOT)
1486                                 return FALSE;
1487         if (!e.takedamage)
1488                 return FALSE;
1489         if (e.deadflag)
1490                 return FALSE;
1491         if (e.buttonchat)
1492                 return FALSE;
1493         return TRUE;
1494 };
1495
1496 void(float t, float f1, float f2, entity e1, vector v1, vector v2, vector v3, vector v4) bot_lagfunc =
1497 {
1498         self.bot_aimtarg = e1;
1499         self.bot_aimlatency = self.ping; // FIXME?  Shouldn't this be in the lag item?
1500         self.bot_aimselforigin = v1;
1501         self.bot_aimselfvelocity = v2;
1502         self.bot_aimtargorigin = v3;
1503         self.bot_aimtargvelocity = v4;
1504         if(skill <= 0)
1505                 self.bot_canfire = (random() < 0.8);
1506         else if(skill <= 1)
1507                 self.bot_canfire = (random() < 0.9);
1508         else if(skill <= 2)
1509                 self.bot_canfire = (random() < 0.95);
1510         else
1511                 self.bot_canfire = 1;
1512 };
1513
1514 .float bot_badaimtime;
1515 .float bot_aimthinktime;
1516 .vector bot_mouseaim;
1517 .vector bot_badaimoffset;
1518 .vector bot_1st_order_aimfilter;
1519 .vector bot_2nd_order_aimfilter;
1520 .vector bot_3th_order_aimfilter;
1521 .vector bot_4th_order_aimfilter;
1522 .vector bot_5th_order_aimfilter;
1523 .vector bot_olddesiredang;
1524 float(vector v, float maxfiredeviation) bot_aimdir =
1525 {
1526 /*
1527         local float snapcos;
1528         local vector olddir, newdir, desireddir;
1529
1530         makevectors(self.v_angle);
1531         olddir = newdir = v_forward;
1532         desireddir = normalize(v);
1533         snapcos = cos(cvar("bot_ai_aimskill_snapangle") * frametime * (skill + 1) * 0.5);
1534         if (desireddir * olddir < v_forward_x)
1535                 newdir = desireddir;
1536         else
1537         {
1538                 local float blendrate;
1539                 blendrate = cvar("bot_ai_aimskill_blendrate") * frametime * (skill + 1) * 0.5;
1540                 newdir = olddir + (desireddir - olddir) * bound(0, blendrate, 1);
1541         }
1542
1543         // decide whether to fire this time
1544         if ((desireddir * newdir) >= cos(maxfiredeviation))
1545                 self.bot_firetimer = time + 0.3;
1546
1547         self.v_angle = vectoangles(newdir);
1548         self.v_angle_x = self.v_angle_x * -1;
1549
1550         makevectors(self.v_angle);
1551         shotorg = self.origin + self.view_ofs;
1552         shotdir = newdir;
1553
1554         return time < self.bot_firetimer;
1555 */
1556
1557         local float dist;
1558         local vector desiredang, diffang;
1559
1560         //dprint("aim ", self.netname, ": old:", vtos(self.v_angle));
1561         // make sure v_angle is sane first
1562         //self.v_angle_x = bound(-180, self.v_angle_x, 180);
1563         //while (self.v_angle_x < -180) self.v_angle_x = self.v_angle_x + 360;
1564         //while (self.v_angle_x >= 180) self.v_angle_x = self.v_angle_x - 360;
1565         while (self.v_angle_y < -180) self.v_angle_y = self.v_angle_y + 360;
1566         while (self.v_angle_y >= 180) self.v_angle_y = self.v_angle_y - 360;
1567         //while (self.v_angle_z < -180) self.v_angle_z = self.v_angle_z + 360;
1568         //while (self.v_angle_z >= 180) self.v_angle_z = self.v_angle_z - 360;
1569         self.v_angle_z = 0;
1570
1571         // get the desired angles to aim at
1572         //dprint(" at:", vtos(v));
1573         v = normalize(v);
1574         //te_lightning2(world, self.origin + self.view_ofs, self.origin + self.view_ofs + v * 200);
1575         if (time >= self.bot_badaimtime)
1576         {
1577                 self.bot_badaimtime = max(self.bot_badaimtime + 0.3, time);
1578                 self.bot_badaimoffset = randomvec() * bound(0, 5 - 0.5 * (skill+self.bot_offsetskill), 5);
1579         }
1580         desiredang = vectoangles(v) + self.bot_badaimoffset*cvar("bot_ai_aimskill_offset");
1581         //dprint(" desired:", vtos(desiredang));
1582         if (desiredang_x >= 180)
1583                 desiredang_x = desiredang_x - 360;
1584         desiredang_x = 0 - desiredang_x;
1585         desiredang_z = self.v_angle_z;
1586         desiredang_x = bound(-90, desiredang_x, 90);
1587         //dprint(" / ", vtos(desiredang));
1588
1589         //// pain throws off aim
1590         //if (self.bot_painintensity)
1591         //{
1592         //      // shake from pain
1593         //      desiredang = desiredang + randomvec() * self.bot_painintensity * 0.2;
1594         //}
1595
1596         // calculate turn angles
1597         diffang = (desiredang - self.bot_olddesiredang)*(1/frametime);
1598         self.bot_olddesiredang = desiredang;
1599         //dprint(" diff:", vtos(diffang));
1600
1601         // wrap yaw turn
1602         while (diffang_y < -180)
1603                 diffang_y = diffang_y + 360;
1604         while (diffang_y >  180)
1605                 diffang_y = diffang_y - 360;
1606
1607         // Here we will try to anticipate the comming aiming direction
1608         self.bot_1st_order_aimfilter= self.bot_1st_order_aimfilter
1609                 + (diffang                      - self.bot_1st_order_aimfilter) * bound(0, cvar("bot_ai_aimskill_order_filter_1st"),1);
1610         self.bot_2nd_order_aimfilter= self.bot_2nd_order_aimfilter
1611                 + (self.bot_1st_order_aimfilter - self.bot_2nd_order_aimfilter) * bound(0, cvar("bot_ai_aimskill_order_filter_2nd"),1);
1612         self.bot_3th_order_aimfilter= self.bot_3th_order_aimfilter
1613                 + (self.bot_2nd_order_aimfilter - self.bot_3th_order_aimfilter) * bound(0, cvar("bot_ai_aimskill_order_filter_3th"),1);
1614         self.bot_4th_order_aimfilter= self.bot_4th_order_aimfilter
1615                 + (self.bot_3th_order_aimfilter - self.bot_4th_order_aimfilter) * bound(0, cvar("bot_ai_aimskill_order_filter_4th"),1);
1616         self.bot_5th_order_aimfilter= self.bot_5th_order_aimfilter
1617                 + (self.bot_4th_order_aimfilter - self.bot_5th_order_aimfilter) * bound(0, cvar("bot_ai_aimskill_order_filter_5th"),1);
1618
1619         local float blend;
1620         //blend = (bound(0,skill,10)*0.1)*pow(1-bound(0,skill,10)*0.05,2.5)*5.656854249; //Plot formule before changing !
1621         blend = bound(0,skill,10)*0.1;
1622         desiredang = desiredang + blend *
1623         (
1624                   self.bot_1st_order_aimfilter * cvar("bot_ai_aimskill_order_mix_1st")
1625                 + self.bot_2nd_order_aimfilter * cvar("bot_ai_aimskill_order_mix_2nd")
1626                 + self.bot_3th_order_aimfilter * cvar("bot_ai_aimskill_order_mix_3th")
1627                 + self.bot_4th_order_aimfilter * cvar("bot_ai_aimskill_order_mix_4th")
1628                 + self.bot_5th_order_aimfilter * cvar("bot_ai_aimskill_order_mix_5th")
1629         );
1630         while (desiredang_z < -180)
1631                 desiredang_z = desiredang_z + 360;
1632         while (desiredang_z >  180)
1633                 desiredang_z = desiredang_z - 360;
1634         // calculate turn angles
1635         diffang = desiredang - self.bot_mouseaim;
1636         //dprint(" diff:", vtos(diffang));
1637
1638         // wrap yaw turn
1639         while (diffang_y < -180)
1640                 diffang_y = diffang_y + 360;
1641         while (diffang_y >  180)
1642                 diffang_y = diffang_y - 360;
1643
1644         if (time >= self.bot_aimthinktime)
1645         {
1646                 self.bot_aimthinktime = max(self.bot_aimthinktime + 0.5 - 0.05*(skill+self.bot_thinkskill), time);
1647                 self.bot_mouseaim = self.bot_mouseaim + diffang * (1-random()*0.1*bound(1,10-skill,10));
1648         }
1649
1650         //self.v_angle = self.v_angle + diffang * bound(0, r * frametime * (skill * 0.5 + 2), 1);
1651
1652         desiredang = self.bot_mouseaim*bound(0,cvar("bot_ai_aimskill_think"),1) + desiredang * bound(0,(1-cvar("bot_ai_aimskill_think")),1);
1653
1654         // calculate turn angles
1655         diffang = desiredang - self.v_angle;
1656         //dprint(" diff:", vtos(diffang));
1657
1658         // wrap yaw turn
1659         while (diffang_y < -180)
1660                 diffang_y = diffang_y + 360;
1661         while (diffang_y >  180)
1662                 diffang_y = diffang_y - 360;
1663         // calculate turn angles
1664         diffang = desiredang - self.v_angle;
1665         //dprint(" diff:", vtos(diffang));
1666
1667         // wrap yaw turn
1668         while (diffang_y < -180)
1669                 diffang_y = diffang_y + 360;
1670         while (diffang_y >  180)
1671                 diffang_y = diffang_y - 360;
1672
1673         // jitter tracking
1674         dist = vlen(diffang);
1675         //diffang = diffang + randomvec() * (dist * 0.05 * (3.5 - bound(0, skill, 3)));
1676
1677         // turn
1678         local float r, fixedrate, blendrate;
1679         fixedrate = cvar("bot_ai_aimskill_fixedrate") / bound(1,dist,1000);
1680         blendrate = cvar("bot_ai_aimskill_blendrate");
1681         r = max(fixedrate, blendrate);
1682         //self.v_angle = self.v_angle + diffang * bound(frametime, r * frametime * (2+skill*skill*0.05-random()*0.05*(10-skill)), 1);
1683         self.v_angle = self.v_angle + diffang * bound(frametime, r * frametime * (2+pow(skill+self.bot_mouseskill,3)*0.005-random()), 1);
1684         self.v_angle = self.v_angle * bound(0,cvar("bot_ai_aimskill_mouse"),1) + desiredang * bound(0,(1-cvar("bot_ai_aimskill_mouse")),1);
1685         //self.v_angle = self.v_angle + diffang * bound(0, r * frametime * (skill * 0.5 + 2), 1);
1686         //self.v_angle = self.v_angle + diffang * (1/ blendrate);
1687         self.v_angle_z = 0;
1688         while (self.v_angle_y < -180)
1689                 self.v_angle_y = self.v_angle_y + 360;
1690         while (self.v_angle_y >= 180)
1691                 self.v_angle_y = self.v_angle_y - 360;
1692         //dprint(" turn:", vtos(self.v_angle));
1693
1694         makevectors(self.v_angle);
1695         shotorg = self.origin + self.view_ofs;
1696         shotdir = v_forward;
1697
1698         //dprint(" dir:", vtos(v_forward));
1699         //te_lightning2(world, shotorg, shotorg + shotdir * 100);
1700
1701         // calculate turn angles again
1702         diffang = desiredang - self.v_angle;
1703         while (diffang_y < -180)
1704                 diffang_y = diffang_y + 360;
1705         while (diffang_y >  180)
1706                 diffang_y = diffang_y - 360;
1707
1708         //bprint("e ");bprintvector(diffang);bprint(" < ");bprintfloat(maxfiredeviation);bprint("\n");
1709
1710         // decide whether to fire this time
1711         // note the maxfiredeviation is in degrees so this has to convert to radians first
1712         //if ((normalize(v) * shotdir) >= cos(maxfiredeviation * (3.14159265358979323846 / 180)))
1713         if ((normalize(v) * shotdir) >= cos(maxfiredeviation * (3.14159265358979323846 / 180)))
1714         if (vlen(trace_endpos-shotorg) < 500+500*bound(0, skill, 10) || random()*random()>bound(0,skill*0.05,1))
1715                 self.bot_firetimer = time + bound(0.1, 0.5-skill*0.05, 0.5);
1716         traceline(shotorg,shotorg+shotdir*1000,FALSE,world);
1717         //dprint(ftos(maxfiredeviation),"\n");
1718         //dprint(" diff:", vtos(diffang), "\n");
1719
1720         return self.bot_canfire && (time < self.bot_firetimer);
1721 };
1722
1723 vector(vector targorigin, vector targvelocity, float shotspeed, float shotdelay) bot_shotlead =
1724 {
1725         // Try to add code here that predicts gravity effect here, no clue HOW to though ... well not yet atleast...
1726         return targorigin + targvelocity * (shotdelay + vlen(targorigin - shotorg) / shotspeed);
1727 };
1728
1729 float(float shotspeed, float shotspeedupward, float maxshottime, float applygravity) bot_aim =
1730 {
1731         local float f, r;
1732         local vector v;
1733         /*
1734         eprint(self);
1735         dprint("bot_aim(", ftos(shotspeed));
1736         dprint(", ", ftos(shotspeedupward));
1737         dprint(", ", ftos(maxshottime));
1738         dprint(", ", ftos(applygravity));
1739         dprint(");\n");
1740         */
1741         if (!shotspeed)
1742         {
1743                 dprint("bot_aim: WARNING: weapon ", W_Name(self.weapon), " shotspeed is zero!\n");
1744                 shotspeed = 1000000;
1745         }
1746         if (!maxshottime)
1747         {
1748                 dprint("bot_aim: WARNING: weapon ", W_Name(self.weapon), " maxshottime is zero!\n");
1749                 maxshottime = 1;
1750         }
1751         makevectors(self.v_angle);
1752         shotorg = self.origin + self.view_ofs;
1753         shotdir = v_forward;
1754         v = bot_shotlead(self.bot_aimtargorigin, self.bot_aimtargvelocity, shotspeed, self.bot_aimlatency);
1755         local float distanceratio;
1756         distanceratio =sqrt(bound(0,skill,10000))*0.3*(vlen(v-shotorg)-100)/cvar("bot_ai_aimskill_firetolerance_distdegrees");
1757         distanceratio = bound(0,distanceratio,1);
1758         r =  (cvar("bot_ai_aimskill_firetolerance_maxdegrees")-cvar("bot_ai_aimskill_firetolerance_mindegrees"))
1759                 * (1-distanceratio) + cvar("bot_ai_aimskill_firetolerance_mindegrees");
1760         if (applygravity && self.bot_aimtarg)
1761         {
1762                 if (!findtrajectorywithleading(shotorg, '0 0 0', '0 0 0', self.bot_aimtarg, shotspeed, shotspeedupward, maxshottime, 0, self))
1763                         return FALSE;
1764                 f = bot_aimdir(findtrajectory_velocity - shotspeedupward * '0 0 1', r);
1765         }
1766         else
1767         {
1768                 f = bot_aimdir(v - shotorg, r);
1769                 //dprint("AIM: ");dprint(vtos(self.bot_aimtargorigin));dprint(" + ");dprint(vtos(self.bot_aimtargvelocity));dprint(" * ");dprint(ftos(self.bot_aimlatency + vlen(self.bot_aimtargorigin - shotorg) / shotspeed));dprint(" = ");dprint(vtos(v));dprint(" : aimdir = ");dprint(vtos(normalize(v - shotorg)));dprint(" : ");dprint(vtos(shotdir));dprint("\n");
1770                 traceline(shotorg, shotorg + shotdir * 10000, FALSE, self);
1771                 if (trace_ent.takedamage)
1772                 if (trace_fraction < 1)
1773                 if (!bot_shouldattack(trace_ent))
1774                         return FALSE;
1775                 traceline(shotorg, self.bot_aimtargorigin, FALSE, self);
1776                 if (trace_fraction < 1)
1777                 if (trace_ent != self.enemy)
1778                 if (!bot_shouldattack(trace_ent))
1779                         return FALSE;
1780         }
1781         if (r > maxshottime * shotspeed)
1782                 return FALSE;
1783         return f;
1784 };
1785
1786 // TODO: move this painintensity code to the player damage code
1787 void() bot_think =
1788 {
1789         //if (self.bot_painintensity > 0)
1790         //      self.bot_painintensity = self.bot_painintensity - (skill + 1) * 40 * frametime;
1791
1792         //self.bot_painintensity = self.bot_painintensity + self.bot_oldhealth - self.health;
1793         //self.bot_painintensity = bound(0, self.bot_painintensity, 100);
1794
1795         if(time < restart_countdown || ((cvar("g_campaign") && !campaign_bots_may_start)))
1796         {
1797                 self.nextthink = time + 0.5;
1798                 return;
1799         }
1800
1801         if (self.fixangle)
1802         {
1803                 self.v_angle = self.angles;
1804                 self.v_angle_z = 0;
1805                 self.fixangle = FALSE;
1806         }
1807
1808         self.dmg_take = 0;
1809         self.dmg_save = 0;
1810         self.dmg_inflictor = world;
1811
1812         // calculate an aiming latency based on the skill setting
1813         // (simulated network latency + naturally delayed reflexes)
1814         //self.ping = 0.7 - bound(0, 0.05 * skill, 0.5); // moved the reflexes to bot_aimdir (under the name 'think')
1815         // minimum ping 20+10 random
1816         self.ping = bound(0,0.07 - bound(0, skill * 0.005,0.05)+random()*0.01,0.65); // Now holds real lag to server, and higer skill players take a less laggy server
1817         // skill 10 = ping 0.2 (adrenaline)
1818         // skill 0 = ping 0.7 (slightly drunk)
1819
1820         // clear buttons
1821         self.button0 = 0;
1822         self.button1 = 0;
1823         self.button2 = 0;
1824         self.button3 = 0;
1825         self.button4 = 0;
1826         self.button5 = 0;
1827         self.button6 = 0;
1828         self.button7 = 0;
1829         self.button8 = 0;
1830         self.buttonchat = 0;
1831         self.buttonuse = 0;
1832
1833         // if dead, just wait until we can respawn
1834         if (self.deadflag)
1835         {
1836                 if (self.deadflag == DEAD_DEAD)
1837                         self.button2 = 1; // press jump to respawn
1838                 return;
1839         }
1840
1841         // now call the current bot AI (havocbot for example)
1842         self.bot_ai();
1843 };
1844
1845 entity bot_strategytoken;
1846 entity player_list;
1847 .entity nextplayer;
1848 void() bot_relinkplayerlist =
1849 {
1850         local entity e;
1851         local entity prevbot;
1852         player_count = 0;
1853         currentbots = 0;
1854         player_list = e = findchainflags(flags, FL_CLIENT);
1855         bot_list = world;
1856         prevbot = world;
1857         while (e)
1858         {
1859                 player_count = player_count + 1;
1860                 e.nextplayer = e.chain;
1861                 if (clienttype(e) == CLIENTTYPE_BOT)
1862                 {
1863                         if (prevbot)
1864                                 prevbot.nextbot = e;
1865                         else
1866                                 bot_list = e;
1867                         prevbot = e;
1868                         currentbots = currentbots + 1;
1869                 }
1870                 e = e.chain;
1871         }
1872         dprint(strcat("relink: ", ftos(currentbots), " bots seen.\n"));
1873         bot_strategytoken = bot_list;
1874 };
1875
1876 void() havocbot_setupbot;
1877 float JoinBestTeam(entity pl, float only_return_best);
1878
1879 void() bot_clientconnect =
1880 {
1881         if (clienttype(self) != CLIENTTYPE_BOT)
1882                 return;
1883         self.lag_func = bot_lagfunc;
1884         self.isbot = TRUE;
1885         self.createdtime = self.nextthink;
1886         JoinBestTeam(self, FALSE);
1887         havocbot_setupbot();
1888         self.bot_mouseskill=random()-0.5;
1889         self.bot_thinkskill=random()-0.5;
1890         self.bot_predictionskill=random()-0.5;
1891         self.bot_offsetskill=random()-0.5;
1892 };
1893
1894 entity() bot_spawn =
1895 {
1896         local entity oldself, bot;
1897         bot = spawnclient();
1898         if (bot)
1899         {
1900                 currentbots = currentbots + 1;
1901                 oldself = self;
1902                 self = bot;
1903                 bot_setnameandstuff();
1904                 ClientConnect();
1905                 PutClientInServer();
1906                 self = oldself;
1907         }
1908         return bot;
1909 };
1910
1911 void CheckAllowedTeams(entity for_whom); void GetTeamCounts(entity other); float c1, c2, c3, c4;
1912 void() bot_removefromlargestteam =
1913 {
1914         local float besttime, bestcount, thiscount;
1915         local entity best, head;
1916         CheckAllowedTeams(world);
1917         GetTeamCounts(world);
1918         head = findchainfloat(isbot, TRUE);
1919         if (!head)
1920                 return;
1921         best = head;
1922         besttime = head.createdtime;
1923         bestcount = 0;
1924         while (head)
1925         {
1926                 if(head.team == COLOR_TEAM1)
1927                         thiscount = c1;
1928                 else if(head.team == COLOR_TEAM2)
1929                         thiscount = c2;
1930                 else if(head.team == COLOR_TEAM3)
1931                         thiscount = c3;
1932                 else if(head.team == COLOR_TEAM4)
1933                         thiscount = c4;
1934                 else
1935                         thiscount = 0;
1936                 if (thiscount > bestcount)
1937                 {
1938                         bestcount = thiscount;
1939                         besttime = head.createdtime;
1940                         best = head;
1941                 }
1942                 else if (thiscount == bestcount && besttime < head.createdtime)
1943                 {
1944                         besttime = head.createdtime;
1945                         best = head;
1946                 }
1947                 head = head.chain;
1948         }
1949         currentbots = currentbots - 1;
1950         dropclient(best);
1951 };
1952
1953 void() bot_removenewest =
1954 {
1955         local float besttime;
1956         local entity best, head;
1957
1958         if(teams_matter)
1959         {
1960                 bot_removefromlargestteam();
1961                 return;
1962         }
1963
1964         head = findchainfloat(isbot, TRUE);
1965         if (!head)
1966                 return;
1967         best = head;
1968         besttime = head.createdtime;
1969         while (head)
1970         {
1971                 if (besttime < head.createdtime)
1972                 {
1973                         besttime = head.createdtime;
1974                         best = head;
1975                 }
1976                 head = head.chain;
1977         }
1978         currentbots = currentbots - 1;
1979         dropclient(best);
1980 };
1981
1982 float botframe_waypointeditorlightningtime;
1983 void() botframe_showwaypointlinks =
1984 {
1985         local entity player, head, w;
1986         if (time < botframe_waypointeditorlightningtime)
1987                 return;
1988         botframe_waypointeditorlightningtime = time + 0.5;
1989         player = find(world, classname, "player");
1990         while (player)
1991         {
1992                 if (!player.isbot)
1993                 if (player.flags & FL_ONGROUND)
1994                 {
1995                         //navigation_testtracewalk = TRUE;
1996                         head = navigation_findnearestwaypoint(player, FALSE);
1997                         //navigation_testtracewalk = FALSE;
1998                         if (head)
1999                         {
2000                                 w = head     ;if (w) te_lightning2(world, w.origin, player.origin);
2001                                 w = head.wp00;if (w) te_lightning2(world, w.origin, head.origin);
2002                                 w = head.wp01;if (w) te_lightning2(world, w.origin, head.origin);
2003                                 w = head.wp02;if (w) te_lightning2(world, w.origin, head.origin);
2004                                 w = head.wp03;if (w) te_lightning2(world, w.origin, head.origin);
2005                                 w = head.wp04;if (w) te_lightning2(world, w.origin, head.origin);
2006                                 w = head.wp05;if (w) te_lightning2(world, w.origin, head.origin);
2007                                 w = head.wp06;if (w) te_lightning2(world, w.origin, head.origin);
2008                                 w = head.wp07;if (w) te_lightning2(world, w.origin, head.origin);
2009                                 w = head.wp08;if (w) te_lightning2(world, w.origin, head.origin);
2010                                 w = head.wp09;if (w) te_lightning2(world, w.origin, head.origin);
2011                                 w = head.wp10;if (w) te_lightning2(world, w.origin, head.origin);
2012                                 w = head.wp11;if (w) te_lightning2(world, w.origin, head.origin);
2013                                 w = head.wp12;if (w) te_lightning2(world, w.origin, head.origin);
2014                                 w = head.wp13;if (w) te_lightning2(world, w.origin, head.origin);
2015                                 w = head.wp14;if (w) te_lightning2(world, w.origin, head.origin);
2016                                 w = head.wp15;if (w) te_lightning2(world, w.origin, head.origin);
2017                                 w = head.wp16;if (w) te_lightning2(world, w.origin, head.origin);
2018                                 w = head.wp17;if (w) te_lightning2(world, w.origin, head.origin);
2019                                 w = head.wp18;if (w) te_lightning2(world, w.origin, head.origin);
2020                                 w = head.wp19;if (w) te_lightning2(world, w.origin, head.origin);
2021                                 w = head.wp20;if (w) te_lightning2(world, w.origin, head.origin);
2022                                 w = head.wp21;if (w) te_lightning2(world, w.origin, head.origin);
2023                                 w = head.wp22;if (w) te_lightning2(world, w.origin, head.origin);
2024                                 w = head.wp23;if (w) te_lightning2(world, w.origin, head.origin);
2025                                 w = head.wp24;if (w) te_lightning2(world, w.origin, head.origin);
2026                                 w = head.wp25;if (w) te_lightning2(world, w.origin, head.origin);
2027                                 w = head.wp26;if (w) te_lightning2(world, w.origin, head.origin);
2028                                 w = head.wp27;if (w) te_lightning2(world, w.origin, head.origin);
2029                                 w = head.wp28;if (w) te_lightning2(world, w.origin, head.origin);
2030                                 w = head.wp29;if (w) te_lightning2(world, w.origin, head.origin);
2031                                 w = head.wp30;if (w) te_lightning2(world, w.origin, head.origin);
2032                                 w = head.wp31;if (w) te_lightning2(world, w.origin, head.origin);
2033                         }
2034                 }
2035                 player = find(player, classname, "player");
2036         }
2037 };
2038
2039 entity botframe_dangerwaypoint;
2040 void() botframe_updatedangerousobjects =
2041 {
2042         local entity head, bot_dodgelist;
2043         local vector m1, m2, v;
2044         local float c, d, danger;
2045         c = 0;
2046         bot_dodgelist = findchainfloat(bot_dodge, TRUE);
2047         botframe_dangerwaypoint = find(botframe_dangerwaypoint, classname, "waypoint");
2048         while (botframe_dangerwaypoint != world)
2049         {
2050                 danger = 0;
2051                 m1 = botframe_dangerwaypoint.mins;
2052                 m2 = botframe_dangerwaypoint.maxs;
2053                 head = bot_dodgelist;
2054                 while (head)
2055                 {
2056                         v = head.origin;
2057                         v_x = bound(m1_x, v_x, m2_x);
2058                         v_y = bound(m1_y, v_y, m2_y);
2059                         v_z = bound(m1_z, v_z, m2_z);
2060                         d = head.bot_dodgerating - vlen(head.origin - v);
2061                         if (d > 0)
2062                         {
2063                                 traceline(head.origin, v, TRUE, world);
2064                                 if (trace_fraction == 1)
2065                                         danger = danger + d;
2066                         }
2067                         head = head.chain;
2068                 }
2069                 botframe_dangerwaypoint.dmg = danger;
2070                 c = c + 1;
2071                 if (c >= 256)
2072                         break;
2073                 botframe_dangerwaypoint = find(botframe_dangerwaypoint, classname, "waypoint");
2074         }
2075 };
2076
2077
2078 float botframe_spawnedwaypoints;
2079 float botframe_nextthink;
2080
2081 float autoskill_nextthink;
2082 .float totalfrags_lastcheck;
2083 void(float factor) autoskill =
2084 {
2085         float bestbot;
2086         float bestplayer;
2087         entity head;
2088
2089         bestbot = -1;
2090         bestplayer = -1;
2091         FOR_EACH_PLAYER(head)
2092         {
2093                 if(clienttype(head) == CLIENTTYPE_REAL)
2094                         bestplayer = max(bestplayer, head.totalfrags - head.totalfrags_lastcheck);
2095                 else
2096                         bestbot = max(bestbot, head.totalfrags - head.totalfrags_lastcheck);
2097         }
2098
2099         dprint("autoskill: best player got ", ftos(bestplayer), ", ");
2100         dprint("best bot got ", ftos(bestbot), "; ");
2101         if(bestbot < 0 || bestplayer < 0)
2102         {
2103                 dprint("not doing anything\n");
2104                 // don't return, let it reset all counters below
2105         }
2106         else if(bestbot <= bestplayer * factor - 2)
2107         {
2108                 if(cvar("skill") < 17)
2109                 {
2110                         dprint("2 frags difference, increasing skill\n");
2111                         cvar_set("skill", ftos(cvar("skill") + 1));
2112                         bprint("^2SKILL UP!^7 Now at level ", ftos(cvar("skill")), "\n");
2113                 }
2114         }
2115         else if(bestbot >= bestplayer * factor + 2)
2116         {
2117                 if(cvar("skill") > 0)
2118                 {
2119                         dprint("2 frags difference, decreasing skill\n");
2120                         cvar_set("skill", ftos(cvar("skill") - 1));
2121                         bprint("^1SKILL DOWN!^7 Now at level ", ftos(cvar("skill")), "\n");
2122                 }
2123         }
2124         else
2125         {
2126                 dprint("not doing anything\n");
2127                 return;
2128                 // don't reset counters, wait for them to accumulate
2129         }
2130
2131         FOR_EACH_PLAYER(head)
2132                 head.totalfrags_lastcheck = head.totalfrags;
2133 }
2134
2135 void() bot_serverframe =
2136 {
2137         float realplayers, bots, activerealplayers;
2138         entity head;
2139
2140         if (intermission_running)
2141                 return;
2142
2143         if (time < 2)
2144                 return;
2145
2146         if(time > autoskill_nextthink)
2147         {
2148                 float a;
2149                 a = cvar("skill_auto");
2150                 if(!cvar("g_campaign"))
2151                         if(a)
2152                                 autoskill(a);
2153                 autoskill_nextthink = time + 5;
2154         }
2155
2156         activerealplayers = 0;
2157         realplayers = 0;
2158
2159         FOR_EACH_REALCLIENT(head)
2160         {
2161                 if(head.classname == "player" || g_lms || g_arena)
2162                         ++activerealplayers;
2163                 ++realplayers;
2164         }
2165
2166         // add/remove bots if needed to make sure there are at least
2167         // minplayers+bot_number, or remove all bots if no one is playing
2168         // But don't remove bots immediately on level change, as the real players
2169         // usually haven't rejoined yet
2170         bots_would_leave = FALSE;
2171         if (realplayers || cvar("bot_join_empty") || (currentbots > 0 && time < 5))
2172         {
2173                 float realminplayers, minplayers;
2174                 realminplayers = cvar("minplayers");
2175                 minplayers = max(0, floor(realminplayers));
2176
2177                 float realminbots, minbots;
2178                 if(cvar("bot_vs_human"))
2179                         realminbots = ceil(fabs(cvar("bot_vs_human")) * activerealplayers);
2180                 else
2181                         realminbots = cvar("bot_number");
2182                 minbots = max(0, floor(realminbots));
2183
2184                 bots = min(max(minbots, minplayers - activerealplayers), maxclients - realplayers);
2185                 if(bots > minbots)
2186                         bots_would_leave = TRUE;
2187         }
2188         else
2189         {
2190                 // if there are no players, remove bots
2191                 bots = 0;
2192         }
2193
2194         bot_ignore_bots = cvar("bot_ignore_bots");
2195
2196         // only add one bot per frame to avoid utter chaos
2197         if(time > botframe_nextthink)
2198         {
2199                 //dprint(ftos(bots), " ? ", ftos(currentbots), "\n");
2200                 while (currentbots < bots)
2201                 {
2202                         if (bot_spawn() == world)
2203                         {
2204                                 bprint("Can not add bot, server full.\n");
2205                                 botframe_nextthink = time + 10;
2206                                 break;
2207                         }
2208                 }
2209                 while (currentbots > bots)
2210                         bot_removenewest();
2211         }
2212
2213         if(botframe_spawnedwaypoints)
2214         {
2215                 if(cvar("waypoint_benchmark"))
2216                         localcmd("quit\n");
2217         }
2218
2219         if (currentbots > 0 || cvar("g_waypointeditor"))
2220         if (!botframe_spawnedwaypoints)
2221         {
2222                 botframe_spawnedwaypoints = TRUE;
2223                 waypoint_loadall();
2224                 waypoint_schedulerelinkall();
2225         }
2226
2227         if (bot_list)
2228         {
2229                 // cycle the goal token from one bot to the next each frame
2230                 // (this prevents them from all doing waypoint searches on the same
2231                 //  frame, which causes choppy framerates)
2232                 if (bot_strategytoken)
2233                         bot_strategytoken = bot_strategytoken.nextbot;
2234                 if (!bot_strategytoken)
2235                         bot_strategytoken = bot_list;
2236
2237                 botframe_updatedangerousobjects();
2238         }
2239
2240         if (cvar("g_waypointeditor"))
2241                 botframe_showwaypointlinks();
2242 };