data/qcsrc/server/arena.qc

   1 float maxspawned;
   2 float numspawned;
   3 float arena_roundbased;
   4 .float spawned;
   5 .entity spawnqueue_next;
   6 .entity spawnqueue_prev;
   7 .float spawnqueue_in;
   8 entity spawnqueue_first;
   9 entity spawnqueue_last;
  10 entity champion;
  11 float warmup;
  12
  13 void PutObserverInServer();
  14 void PutClientInServer();
  15 void(entity e) DropFlag;
  16 void(entity e) ReturnFlag;
  17 void(entity e) removedecor;
  18 void dom_controlpoint_setup();
  19 void onslaught_generator_reset();
  20 void onslaught_controlpoint_reset();
  21
  22 /**
  23  * Resets the state of all clients, items, flags, runes, keys, weapons, waypoints, ... of the map.
  24  * Sets the 'warmup' global variable.
  25  */
  26 void reset_map()
  27 {
  28         if(g_arena)
  29         if(cvar("g_arena_warmup"))
  30                 warmup = time + cvar("g_arena_warmup");
  31
  32         lms_lowest_lives = 999;
  33         lms_next_place = player_count;
  34
  35         race_ReadyRestart();
  36
  37         for(self = world; (self = nextent(self)); )
  38         if(clienttype(self) == CLIENTTYPE_NOTACLIENT)
  39         {
  40                 if(self.classname == STR_ITEM_KH_KEY)
  41                 {
  42                         kh_Key_AssignTo(self, world);
  43                         //if(self.owner)
  44                         //      kh_Key_DropAll(self.owner, TRUE);
  45                         kh_Key_Remove(self);
  46                 }
  47                 else if(self.classname == "droppedweapon"               // cleanup
  48                                 || self.classname == "gib"
  49                                 || self.classname == "body")
  50                 {
  51                         remove(self);
  52                 }
  53                 else if(self.items & (IT_KEY1 | IT_KEY2))
  54                 {
  55                         DropFlag(self);
  56                         ReturnFlag(self);
  57                 }
  58                 else if(self.classname == "rune")
  59                 {
  60                         if(self.owner)
  61                         if(self.owner.classname != "runematch_spawn_point")
  62                                 DropAllRunes(self.owner);
  63                         rune_respawn();
  64                 }
  65                 else if(self.classname == "sprite_waypoint")
  66                 {
  67                         if(self.health | g_keyhunt)
  68                                 WaypointSprite_Kill(self);
  69                 }
  70                 else if(self.classname == "dom_controlpoint")
  71                 {
  72                         dom_controlpoint_setup();
  73                 }
  74                 else if(self.flags & FL_ITEM)                   // reset items
  75                 {
  76                         self.model = self.mdl;
  77                         self.solid = SOLID_TRIGGER;
  78                         setorigin (self, self.origin);
  79                         self.think = SUB_Null;
  80                         self.nextthink = 0;
  81                 }
  82                 else if(self.flags & FL_PROJECTILE)             // remove any projectiles left
  83                 {
  84                         sound(self, CHAN_PROJECTILE, "misc/null.wav", VOL_BASE, ATTN_NORM);
  85                         remove(self);
  86                 }
  87                 else if(self.isdecor)
  88                 {
  89                         removedecor(self);
  90                 }
  91                 else if(self.classname == "onslaught_generator")
  92                 {
  93                         onslaught_generator_reset();
  94                 }
  95                 else if(self.classname == "onslaught_controlpoint")
  96                 {
  97                         onslaught_controlpoint_reset();
  98                 }
  99                 // TODO properly reset Assault
 100                 // General teambased game modes
 101                 else if(self.classname == "info_player_deathmatch")
 102                 {
 103                         self.team = self.team_saved;
 104                 }
 105         }
 106
 107         // Moving the player reset code here since the player-reset depends
 108         // on spawnpoint entities which have to be reset first --blub
 109         FOR_EACH_CLIENT(self) {
 110                 if(self.flags & FL_CLIENT)                              // reset all players
 111                 {
 112                         if(g_arena)
 113                         {
 114                                 if(self.spawned)
 115                                         PutClientInServer();
 116                                 else
 117                                         PutObserverInServer();
 118                         }
 119                         else
 120                         {
 121                                 /*
 122                                 only reset players if a restart countdown is active
 123                                 this can either be due to cvar sv_ready_restart_after_countdown having set
 124                                 restart_mapalreadyrestarted to 1 after the countdown ended or when
 125                                 sv_ready_restart_after_countdown is not used and countdown is still running
 126                                 */
 127                                 if (restart_mapalreadyrestarted || (time < restart_countdown))
 128                                 {
 129                                         //NEW: changed behaviour so that it prevents that previous spectators/observers suddenly spawn as players
 130                                         if (self.classname == "player") {
 131                                                 PlayerScore_Clear(self);
 132                                                 if(g_lms)
 133                                                         PlayerScore_Add(self, SP_LMS_LIVES, LMS_NewPlayerLives());
 134                                                 self.killcount = 0;
 135                                                 //stop the player from moving so that he stands still once he gets respawned
 136                                                 self.velocity = '0 0 0';
 137                                                 self.avelocity = '0 0 0';
 138                                                 self.movement = '0 0 0';
 139                                                 PutClientInServer();
 140                                         }
 141                                 }
 142                         }
 143                 }
 144         }
 145
 146         if(g_keyhunt)
 147                 kh_Controller_SetThink(cvar("g_balance_keyhunt_delay_round")+RESTART_COUNTDOWN, "", kh_StartRound);
 148
 149         if(g_arena)
 150         if(champion)
 151                 UpdateFrags(champion, +1);
 152 }
 153
 154 void Spawnqueue_Insert(entity e)
 155 {
 156         if(e.spawnqueue_in)
 157                 return;
 158         dprint(strcat("Into queue: ", e.netname, "\n"));
 159         e.spawnqueue_in = TRUE;
 160         e.spawnqueue_prev = spawnqueue_last;
 161         e.spawnqueue_next = world;
 162         if(spawnqueue_last)
 163                 spawnqueue_last.spawnqueue_next = e;
 164         spawnqueue_last = e;
 165         if(!spawnqueue_first)
 166                 spawnqueue_first = e;
 167 }
 168
 169 void Spawnqueue_Remove(entity e)
 170 {
 171         if(!e.spawnqueue_in)
 172                 return;
 173         dprint(strcat("Out of queue: ", e.netname, "\n"));
 174         e.spawnqueue_in = FALSE;
 175         if(e == spawnqueue_first)
 176                 spawnqueue_first = e.spawnqueue_next;
 177         if(e == spawnqueue_last)
 178                 spawnqueue_last = e.spawnqueue_prev;
 179         if(e.spawnqueue_prev)
 180                 e.spawnqueue_prev.spawnqueue_next = e.spawnqueue_next;
 181         if(e.spawnqueue_next)
 182                 e.spawnqueue_next.spawnqueue_prev = e.spawnqueue_prev;
 183         e.spawnqueue_next = world;
 184         e.spawnqueue_prev = world;
 185 }
 186
 187 void Spawnqueue_Unmark(entity e)
 188 {
 189         if(!e.spawned)
 190                 return;
 191         e.spawned = FALSE;
 192         numspawned = numspawned - 1;
 193 }
 194
 195 void Spawnqueue_Mark(entity e)
 196 {
 197         if(e.spawned)
 198                 return;
 199         e.spawned = TRUE;
 200         numspawned = numspawned + 1;
 201 }
 202
 203 /**
 204  * If roundbased arena game mode is active, it centerprints the texts for the
 205  * player when player is waiting for the countdown to finish.
 206  * Blocks the players movement while countdown is active.
 207  * Unblocks the player once the countdown is over.
 208  *
 209  * Called in PlayerPostThink()
 210  */
 211 void Arena_Warmup()
 212 {
 213         float f;
 214         string msg;
 215
 216         if(!g_arena || !arena_roundbased || (time < restart_countdown))
 217                 return;
 218
 219         f = rint(warmup - time);
 220
 221         msg = NEWLINES;
 222         if(time < warmup && self.spawned)
 223         {
 224                 if(champion)
 225                         msg = strcat(msg, "The Champion is ", champion.netname, "^7\n\n\n");
 226
 227                 if(f)
 228                         msg = strcat(msg, "Round will start in ", ftos(f));
 229                 else
 230                 {
 231                         if(self.spawned)
 232                                 msg = strcat(msg, "^1Fight!");
 233                 }
 234
 235                 centerprint(self, msg);
 236
 237                 if(self.spawned)
 238                         self.movetype = MOVETYPE_NONE;
 239
 240                 self.velocity = '0 0 0';
 241                 self.avelocity = '0 0 0';
 242                 self.movement = '0 0 0';
 243                 //self.fixangle = TRUE;
 244         }
 245         else if(self.movetype == MOVETYPE_NONE)
 246         {
 247                 self.movetype = MOVETYPE_WALK;
 248                 centerprint(self, "\n");
 249         }
 250
 251 }
 252
 253 float next_round;
 254
 255 /**
 256  * This function finds out whether an arena round is over 1 player is left.
 257  * It determines the last player who's still alive and saves it's entity reference
 258  * in the global variable 'champion'. Then the new enemy/enemies are put into the server.
 259  *
 260  * Gets called in StartFrame()
 261  */
 262 void Spawnqueue_Check()
 263 {
 264         if(time < warmup + 1)
 265                 return;
 266
 267         //extend next_round if it isn't set yet and only 1 player is spawned
 268         if(!next_round)
 269         if(numspawned < 2)
 270                 next_round = time + 3;
 271
 272         if(!arena_roundbased || (next_round && next_round < time && player_count > 1))
 273         {
 274                 next_round = 0;
 275
 276                 if(arena_roundbased)
 277                 {
 278                         champion = find(world, classname, "player");
 279                         while(champion && champion.deadflag)
 280                                 champion = find(champion, classname, "player");
 281                         reset_map();
 282                 }
 283
 284                 while(numspawned < maxspawned && spawnqueue_first)
 285                 {
 286                         self = spawnqueue_first;
 287
 288                         bprint ("^4", self.netname, "^4 is the next challenger\n");
 289
 290                         Spawnqueue_Remove(self);
 291                         Spawnqueue_Mark(self);
 292
 293                         self.classname = "player";
 294                         PutClientInServer();
 295                 }
 296         }
 297 }