data/qcsrc/server/arena.qc

   1 float maxspawned;
   2 float numspawned;
   3 float arena_roundbased;
   4 .float spawned;
   5 .entity spawnqueue_next;
   6 .entity spawnqueue_prev;
   7 .float spawnqueue_in;
   8 entity spawnqueue_first;
   9 entity spawnqueue_last;
  10 entity champion;
  11 float warmup;
  12
  13 void PutObserverInServer();
  14 void PutClientInServer();
  15 void(entity e) DropFlag;
  16 void(entity e) ReturnFlag;
  17 void(entity e) removedecor;
  18 void dom_controlpoint_setup();
  19 void onslaught_generator_reset();
  20 void onslaught_controlpoint_reset();
  21
  22 /**
  23  * Resets the state of all clients, items, flags, runes, keys, weapons, waypoints, ... of the map.
  24  * Sets the 'warmup' global variable.
  25  */
  26 void reset_map()
  27 {
  28         if(g_arena)
  29         if(cvar("g_arena_warmup"))
  30                 warmup = time + cvar("g_arena_warmup");
  31
  32         lms_lowest_lives = 999;
  33         lms_next_place = player_count;
  34
  35         self = nextent(world);
  36         while(self)
  37         {
  38                 if(self.classname == STR_ITEM_KH_KEY)
  39                 {
  40                         kh_Key_AssignTo(self, world);
  41                         //if(self.owner)
  42                         //      kh_Key_DropAll(self.owner, TRUE);
  43                         kh_Key_Remove(self);
  44                 }
  45                 else if(self.classname == "droppedweapon"               // cleanup
  46                                 || self.classname == "gib"
  47                                 || self.classname == "body")
  48                 {
  49                         remove(self);
  50                 }
  51                 else if(self.items & (IT_KEY1 | IT_KEY2))
  52                 {
  53                         DropFlag(self);
  54                         ReturnFlag(self);
  55                 }
  56                 else if(self.classname == "rune")
  57                 {
  58                         if(self.owner)
  59                         if(self.owner.classname != "runematch_spawn_point")
  60                                 DropAllRunes(self.owner);
  61                         rune_respawn();
  62                 }
  63                 else if(self.classname == "sprite_waypoint")
  64                 {
  65                         if(self.health | g_keyhunt)
  66                                 WaypointSprite_Kill(self);
  67                 }
  68                 else if(self.classname == "dom_controlpoint")
  69                 {
  70                         dom_controlpoint_setup();
  71                 }
  72                 else if(self.flags & FL_ITEM)                   // reset items
  73                 {
  74                         self.model = self.mdl;
  75                         self.solid = SOLID_TRIGGER;
  76                         setorigin (self, self.origin);
  77                         self.think = SUB_Null;
  78                         self.nextthink = 0;
  79                 }
  80                 else if(self.flags & FL_PROJECTILE)             // remove any projectiles left
  81                 {
  82                         sound(self, CHAN_PROJECTILE, "misc/null.wav", VOL_BASE, ATTN_NORM);
  83                         remove(self);
  84                 }
  85                 else if(self.isdecor)
  86                 {
  87                         removedecor(self);
  88                 }
  89                 else if(self.classname == "onslaught_generator")
  90                 {
  91                         onslaught_generator_reset();
  92                 }
  93                 else if(self.classname == "onslaught_controlpoint")
  94                 {
  95                         onslaught_controlpoint_reset();
  96                 }
  97                 // TODO properly reset Assault
  98                 // General teambased game modes
  99                 else if(self.classname == "info_player_deathmatch")
 100                 {
 101                         self.team = self.team_saved;
 102                 }
 103                 self = nextent(self);
 104         }
 105
 106         // Moving the player reset code here since the player-reset depends
 107         // on spawnpoint entities which have to be reset first --blub
 108         FOR_EACH_CLIENT(self) {
 109                 if(self.flags & FL_CLIENT)                              // reset all players
 110                 {
 111                         if(g_arena)
 112                         {
 113                                 if(self.spawned)
 114                                         PutClientInServer();
 115                                 else
 116                                         PutObserverInServer();
 117                         }
 118                         else
 119                         {
 120                                 /*
 121                                 only reset players if a restart countdown is active
 122                                 this can either be due to cvar sv_ready_restart_after_countdown having set
 123                                 restart_mapalreadyrestarted to 1 after the countdown ended or when
 124                                 sv_ready_restart_after_countdown is not used and countdown is still running
 125                                 */
 126                                 if (restart_mapalreadyrestarted || (time < restart_countdown))
 127                                 {
 128                                         //NEW: changed behaviour so that it prevents that previous spectators/observers suddenly spawn as players
 129                                         if (self.classname == "player") {
 130                                                 PlayerScore_Clear(self);
 131                                                 if(g_lms)
 132                                                         PlayerScore_Add(self, SP_LMS_LIVES, LMS_NewPlayerLives());
 133                                                 self.killcount = 0;
 134                                                 //stop the player from moving so that he stands still once he gets respawned
 135                                                 self.velocity = '0 0 0';
 136                                                 self.avelocity = '0 0 0';
 137                                                 self.movement = '0 0 0';
 138                                                 PutClientInServer();
 139                                         }
 140                                 }
 141                         }
 142                 }
 143         }
 144
 145         if(g_keyhunt)
 146                 kh_Controller_SetThink(cvar("g_balance_keyhunt_delay_round")+RESTART_COUNTDOWN, "", kh_StartRound);
 147
 148         if(g_arena)
 149         if(champion)
 150                 UpdateFrags(champion, +1);
 151 }
 152
 153 void Spawnqueue_Insert(entity e)
 154 {
 155         if(e.spawnqueue_in)
 156                 return;
 157         dprint(strcat("Into queue: ", e.netname, "\n"));
 158         e.spawnqueue_in = TRUE;
 159         e.spawnqueue_prev = spawnqueue_last;
 160         e.spawnqueue_next = world;
 161         if(spawnqueue_last)
 162                 spawnqueue_last.spawnqueue_next = e;
 163         spawnqueue_last = e;
 164         if(!spawnqueue_first)
 165                 spawnqueue_first = e;
 166 }
 167
 168 void Spawnqueue_Remove(entity e)
 169 {
 170         if(!e.spawnqueue_in)
 171                 return;
 172         dprint(strcat("Out of queue: ", e.netname, "\n"));
 173         e.spawnqueue_in = FALSE;
 174         if(e == spawnqueue_first)
 175                 spawnqueue_first = e.spawnqueue_next;
 176         if(e == spawnqueue_last)
 177                 spawnqueue_last = e.spawnqueue_prev;
 178         if(e.spawnqueue_prev)
 179                 e.spawnqueue_prev.spawnqueue_next = e.spawnqueue_next;
 180         if(e.spawnqueue_next)
 181                 e.spawnqueue_next.spawnqueue_prev = e.spawnqueue_prev;
 182         e.spawnqueue_next = world;
 183         e.spawnqueue_prev = world;
 184 }
 185
 186 void Spawnqueue_Unmark(entity e)
 187 {
 188         if(!e.spawned)
 189                 return;
 190         e.spawned = FALSE;
 191         numspawned = numspawned - 1;
 192 }
 193
 194 void Spawnqueue_Mark(entity e)
 195 {
 196         if(e.spawned)
 197                 return;
 198         e.spawned = TRUE;
 199         numspawned = numspawned + 1;
 200 }
 201
 202 /**
 203  * If roundbased arena game mode is active, it centerprints the texts for the
 204  * player when player is waiting for the countdown to finish.
 205  * Blocks the players movement while countdown is active.
 206  * Unblocks the player once the countdown is over.
 207  *
 208  * Called in PlayerPostThink()
 209  */
 210 void Arena_Warmup()
 211 {
 212         float f;
 213         string msg;
 214
 215         if(!g_arena || !arena_roundbased || (time < restart_countdown))
 216                 return;
 217
 218         f = rint(warmup - time);
 219
 220         msg = NEWLINES;
 221         if(time < warmup && self.spawned)
 222         {
 223                 if(champion)
 224                         msg = strcat(msg, "The Champion is ", champion.netname, "^7\n\n\n");
 225
 226                 if(f)
 227                         msg = strcat(msg, "Round will start in ", ftos(f));
 228                 else
 229                 {
 230                         if(self.spawned)
 231                                 msg = strcat(msg, "^1Fight!");
 232                 }
 233
 234                 centerprint(self, msg);
 235
 236                 if(self.spawned)
 237                         self.movetype = MOVETYPE_NONE;
 238
 239                 self.velocity = '0 0 0';
 240                 self.avelocity = '0 0 0';
 241                 self.movement = '0 0 0';
 242                 //self.fixangle = TRUE;
 243         }
 244         else if(self.movetype == MOVETYPE_NONE)
 245         {
 246                 self.movetype = MOVETYPE_WALK;
 247                 centerprint(self, "\n");
 248         }
 249
 250 }
 251
 252 float next_round;
 253
 254 /**
 255  * This function finds out whether an arena round is over 1 player is left.
 256  * It determines the last player who's still alive and saves it's entity reference
 257  * in the global variable 'champion'. Then the new enemy/enemies are put into the server.
 258  *
 259  * Gets called in StartFrame()
 260  */
 261 void Spawnqueue_Check()
 262 {
 263         if(time < warmup + 1)
 264                 return;
 265
 266         //extend next_round if it isn't set yet and only 1 player is spawned
 267         if(!next_round)
 268         if(numspawned < 2)
 269                 next_round = time + 3;
 270
 271         if(!arena_roundbased || (next_round && next_round < time && player_count > 1))
 272         {
 273                 next_round = 0;
 274
 275                 if(arena_roundbased)
 276                 {
 277                         champion = find(world, classname, "player");
 278                         while(champion && champion.deadflag)
 279                                 champion = find(champion, classname, "player");
 280                         reset_map();
 281                 }
 282
 283                 while(numspawned < maxspawned && spawnqueue_first)
 284                 {
 285                         self = spawnqueue_first;
 286
 287                         bprint ("^4", self.netname, "^4 is the next challenger\n");
 288
 289                         Spawnqueue_Remove(self);
 290                         Spawnqueue_Mark(self);
 291
 292                         self.classname = "player";
 293                         PutClientInServer();
 294                 }
 295         }
 296 }