data/qcsrc/server/antilag.qc

   1 #define ANTILAG_MAX_ORIGINS 64
   2 .vector antilag_origins[ANTILAG_MAX_ORIGINS];
   3 .float antilag_times[ANTILAG_MAX_ORIGINS];
   4 .float antilag_index;
   5 .vector antilag_saved_origin;
   6
   7 .float antilag_debug;
   8
   9 void antilag_dummy()
  10 {
  11         self.antilag_times = 0;
  12         self.antilag_origins = '0 0 0';
  13 }
  14
  15 void antilag_record(entity e, float t)
  16 {
  17         if(time < e.(antilag_times[e.antilag_index]))
  18                 return;
  19         e.antilag_index = e.antilag_index + 1;
  20         if(e.antilag_index >= ANTILAG_MAX_ORIGINS)
  21                 e.antilag_index = 0;
  22         e.(antilag_times[e.antilag_index]) = t;
  23         e.(antilag_origins[e.antilag_index]) = e.origin;
  24
  25         if(e.antilag_debug)
  26                 te_spark(antilag_takebackorigin(e, t - e.antilag_debug), '0 0 0', 32);
  27 }
  28
  29 // finds the index BEFORE t
  30 float antilag_find(entity e, float t)
  31 {
  32         float i;
  33
  34         for(i = e.antilag_index; i > 0; --i)
  35                 if(e.(antilag_times[i]) >= t)
  36                         if(e.(antilag_times[i - 1]) < t)
  37                                 return i - 1;
  38
  39         if(e.(antilag_times[0]) >= t)
  40                 if(e.(antilag_times[ANTILAG_MAX_ORIGINS - 1]) < t)
  41                         return ANTILAG_MAX_ORIGINS - 1;
  42
  43         for(i = ANTILAG_MAX_ORIGINS - 1; i > e.antilag_index + 1; --i)
  44                 if(e.(antilag_times[i]) >= t)
  45                         if(e.(antilag_times[i - 1]) < t)
  46                                 return i - 1;
  47
  48         // if we get here, t is sandwiched nowhere, so let's assume it's in the present
  49         return -1;
  50 }
  51
  52 vector lerp(float t0, vector v0, float t1, vector v1, float t)
  53 {
  54         return v0 + (v1 - v0) * ((t - t0) / (t1 - t0));
  55 }
  56
  57 vector antilag_takebackorigin(entity e, float t)
  58 {
  59         float i0, i1;
  60
  61         i0 = antilag_find(e, t);
  62         if(i0 < 0)
  63         {
  64                 i0 = e.antilag_index - 1;
  65                 if(i0 < 0)
  66                         i0 = ANTILAG_MAX_ORIGINS - 1;
  67         }
  68         i1 = i0 + 1;
  69         if(i1 >= ANTILAG_MAX_ORIGINS)
  70                 i1 = 0;
  71
  72         return lerp(e.(antilag_times[i0]), e.(antilag_origins[i0]), e.(antilag_times[i1]), e.(antilag_origins[i1]), t);
  73 }
  74
  75 void antilag_takeback(entity e, float t)
  76 {
  77         e.antilag_saved_origin = e.origin;
  78         setorigin(e, antilag_takebackorigin(e, t));
  79 }
  80
  81 void antilag_restore(entity e)
  82 {
  83         setorigin(e, e.antilag_saved_origin);
  84 }