19574e8b72621d89b88873190e20ff57f678629b
[divverent/nexuiz.git] / data / qcsrc / menu / nexuiz / textslider.c
1 #ifdef INTERFACE
2 CLASS(NexuizTextSlider) EXTENDS(TextSlider)
3         METHOD(NexuizTextSlider, configureNexuizTextSlider, void(entity, string))
4         METHOD(NexuizTextSlider, setValue, void(entity, float))
5         METHOD(NexuizTextSlider, configureNexuizTextSliderValues, void(entity))
6         ATTRIB(NexuizTextSlider, fontSize, float, SKINFONTSIZE_NORMAL)
7         ATTRIB(NexuizTextSlider, valueSpace, float, SKINWIDTH_SLIDERTEXT)
8         ATTRIB(NexuizTextSlider, image, string, SKINGFX_SLIDER)
9         ATTRIB(NexuizSlider, tolerance, vector, SKINTOLERANCE_SLIDER)
10         ATTRIB(NexuizTextSlider, align, float, 0.5)
11         ATTRIB(NexuizSlider, color, vector, SKINCOLOR_SLIDER_N)
12         ATTRIB(NexuizSlider, colorC, vector, SKINCOLOR_SLIDER_C)
13         ATTRIB(NexuizSlider, colorF, vector, SKINCOLOR_SLIDER_F)
14         ATTRIB(NexuizSlider, colorD, vector, SKINCOLOR_SLIDER_D)
15         ATTRIB(NexuizSlider, color2, vector, SKINCOLOR_SLIDER_S)
16
17         ATTRIB(NexuizTextSlider, cvarName, string, string_null)
18         METHOD(NexuizTextSlider, loadCvars, void(entity))
19         METHOD(NexuizTextSlider, saveCvars, void(entity))
20
21         ATTRIB(NexuizTextSlider, alpha, float, SKINALPHA_TEXT)
22         ATTRIB(NexuizTextSlider, disabledAlpha, float, SKINALPHA_DISABLED)
23 ENDCLASS(NexuizTextSlider)
24 entity makeNexuizTextSlider(string); // note: you still need to call addValue and configureNexuizTextSliderValues!
25 #endif
26
27 #ifdef IMPLEMENTATION
28 entity makeNexuizTextSlider(string theCvar)
29 {
30         entity me;
31         me = spawnNexuizTextSlider();
32         me.configureNexuizTextSlider(me, theCvar);
33         return me;
34 }
35 void configureNexuizTextSliderNexuizTextSlider(entity me, string theCvar)
36 {
37         me.configureSliderVisuals(me, me.fontSize, me.align, me.valueSpace, me.image);
38         if(theCvar)
39         {
40                 me.cvarName = theCvar;
41                 me.tooltip = getZonedTooltipForIdentifier(theCvar);
42                 // don't load it yet
43         }
44 }
45 void setValueNexuizTextSlider(entity me, float val)
46 {
47         if(val != me.value)
48         {
49                 me.value = val;
50                 me.saveCvars(me);
51         }
52 }
53 void loadCvarsNexuizTextSlider(entity me)
54 {
55         if not(me.cvarName)
56                 return;
57
58         var float n = tokenize_console(me.cvarName);
59         var string s = cvar_string(argv(0));
60         float i;
61         for(i = 1; i < n; ++i)
62                 s = strcat(s, " ", cvar_string(argv(i)));
63         me.setValueFromIdentifier(me, s);
64 }
65 void saveCvarsNexuizTextSlider(entity me)
66 {
67         if not(me.cvarName)
68                 return;
69
70         if(me.value >= 0 && me.value < me.nValues)
71         {
72                 var float n = tokenize_console(me.cvarName);
73                 if(n == 1)
74                 {
75                         // this is a special case to allow spaces in the identifiers
76                         cvar_set(argv(0), me.getIdentifier(me));
77                 }
78                 else
79                 {
80                         var float m = tokenize_console(strcat(me.cvarName, " ", me.getIdentifier(me)));
81                         if(m != n * 2)
82                                 error("NexuizTextSlider: invalid identifier ", me.getIdentifier(me), " does not match cvar list ", me.cvarName);
83                         float i;
84                         for(i = 0; i < n; ++i)
85                                 cvar_set(argv(i), argv(i + n));
86                 }
87         }
88 }
89 void configureNexuizTextSliderValuesNexuizTextSlider(entity me)
90 {
91         me.configureTextSliderValues(me, string_null);
92         me.loadCvars(me);
93 }
94 #endif