data/qcsrc/menu/nexuiz/slider.c

   1 #ifdef INTERFACE
   2 CLASS(NexuizSlider) EXTENDS(Slider)
   3         METHOD(NexuizSlider, configureNexuizSlider, void(entity, float, float, float, string))
   4         METHOD(NexuizSlider, setValue, void(entity, float))
   5         ATTRIB(NexuizSlider, fontSize, float, SKINFONTSIZE_NORMAL)
   6         ATTRIB(NexuizSlider, valueSpace, float, SKINWIDTH_SLIDERTEXT)
   7         ATTRIB(NexuizSlider, image, string, SKINGFX_SLIDER)
   8         ATTRIB(NexuizSlider, tolerance, vector, SKINTOLERANCE_SLIDER)
   9         ATTRIB(NexuizSlider, align, float, 0.5)
  10         ATTRIB(NexuizSlider, color, vector, SKINCOLOR_SLIDER_N)
  11         ATTRIB(NexuizSlider, colorC, vector, SKINCOLOR_SLIDER_C)
  12         ATTRIB(NexuizSlider, colorF, vector, SKINCOLOR_SLIDER_F)
  13         ATTRIB(NexuizSlider, colorD, vector, SKINCOLOR_SLIDER_D)
  14         ATTRIB(NexuizSlider, color2, vector, SKINCOLOR_SLIDER_S)
  15
  16         ATTRIB(NexuizSlider, cvarName, string, string_null)
  17         METHOD(NexuizSlider, loadCvars, void(entity))
  18         METHOD(NexuizSlider, saveCvars, void(entity))
  19
  20         ATTRIB(NexuizSlider, alpha, float, SKINALPHA_TEXT)
  21         ATTRIB(NexuizSlider, disabledAlpha, float, SKINALPHA_DISABLED)
  22 ENDCLASS(NexuizSlider)
  23 entity makeNexuizSlider(float, float, float, string);
  24 #endif
  25
  26 #ifdef IMPLEMENTATION
  27 entity makeNexuizSlider(float theValueMin, float theValueMax, float theValueStep, string theCvar)
  28 {
  29         entity me;
  30         me = spawnNexuizSlider();
  31         me.configureNexuizSlider(me, theValueMin, theValueMax, theValueStep, theCvar);
  32         return me;
  33 }
  34 void configureNexuizSliderNexuizSlider(entity me, float theValueMin, float theValueMax, float theValueStep, string theCvar)
  35 {
  36         float v, vk, vp;
  37         v = theValueMin;
  38         vk = theValueStep;
  39         vp = theValueStep * 10;
  40         while(fabs(vp) < fabs(theValueMax - theValueMin) / 40)
  41                 vp *= 10;
  42         me.configureSliderVisuals(me, me.fontSize, me.align, me.valueSpace, me.image);
  43         me.configureSliderValues(me, theValueMin, v, theValueMax, theValueStep, vk, vp);
  44         if(theCvar)
  45         {
  46                 me.cvarName = theCvar;
  47                 me.loadCvars(me);
  48                 if(tooltipdb >= 0)
  49                         me.tooltip = getZonedTooltipForIdentifier(theCvar);
  50         }
  51 }
  52 void setValueNexuizSlider(entity me, float val)
  53 {
  54         if(val != me.value)
  55         {
  56                 me.value = val;
  57                 me.saveCvars(me);
  58         }
  59 }
  60 void loadCvarsNexuizSlider(entity me)
  61 {
  62         if not(me.cvarName)
  63                 return;
  64
  65         me.value = cvar(me.cvarName);
  66 }
  67 void saveCvarsNexuizSlider(entity me)
  68 {
  69         if not(me.cvarName)
  70                 return;
  71
  72         cvar_set(me.cvarName, ftos(me.value));
  73 }
  74 #endif