data/qcsrc/menu/nexuiz/maplist.c

   1 #ifdef INTERFACE
   2 CLASS(NexuizMapList) EXTENDS(NexuizListBox)
   3         METHOD(NexuizMapList, configureNexuizMapList, void(entity))
   4         ATTRIB(NexuizMapList, rowsPerItem, float, 4)
   5         METHOD(NexuizMapList, draw, void(entity))
   6         METHOD(NexuizMapList, drawListBoxItem, void(entity, float, vector, float))
   7         METHOD(NexuizMapList, clickListBoxItem, void(entity, float, vector))
   8         METHOD(NexuizMapList, resizeNotify, void(entity, vector, vector, vector, vector))
   9         METHOD(NexuizMapList, refilter, void(entity))
  10         METHOD(NexuizMapList, keyDown, float(entity, float, float, float))
  11
  12         ATTRIB(NexuizMapList, realFontSize, vector, '0 0 0')
  13         ATTRIB(NexuizMapList, columnPreviewOrigin, float, 0)
  14         ATTRIB(NexuizMapList, columnPreviewSize, float, 0)
  15         ATTRIB(NexuizMapList, columnNameOrigin, float, 0)
  16         ATTRIB(NexuizMapList, columnNameSize, float, 0)
  17         ATTRIB(NexuizMapList, checkMarkOrigin, vector, '0 0 0')
  18         ATTRIB(NexuizMapList, checkMarkSize, vector, '0 0 0')
  19         ATTRIB(NexuizMapList, realUpperMargin1, float, 0)
  20         ATTRIB(NexuizMapList, realUpperMargin2, float, 0)
  21
  22         ATTRIB(NexuizMapList, lastClickedMap, float, -1)
  23         ATTRIB(NexuizMapList, lastClickedTime, float, 0)
  24
  25         ATTRIB(NexuizMapList, lastGametype, float, 0)
  26         ATTRIB(NexuizMapList, lastFeatures, float, 0)
  27
  28         ATTRIB(NexuizMapList, origin, vector, '0 0 0')
  29         ATTRIB(NexuizMapList, itemAbsSize, vector, '0 0 0')
  30
  31         ATTRIB(NexuizMapList, g_maplistCache, string, string_null)
  32         METHOD(NexuizMapList, g_maplistCacheToggle, void(entity, float))
  33         METHOD(NexuizMapList, g_maplistCacheQuery, float(entity, float))
  34
  35         ATTRIB(NexuizMapList, startButton, entity, NULL)
  36
  37         ATTRIB(NexuizMapList, cvarName, string, "dummy")
  38         METHOD(NexuizMapList, loadCvars, void(entity))
  39
  40         ATTRIB(NexuizMapList, typeToSearchString, string, string_null)
  41         ATTRIB(NexuizMapList, typeToSearchTime, float, 0)
  42 ENDCLASS(NexuizMapList)
  43 entity makeNexuizMapList();
  44 void MapList_All(entity btn, entity me);
  45 void MapList_None(entity btn, entity me);
  46 void MapList_LoadMap(entity btn, entity me);
  47 #endif
  48
  49 #ifdef IMPLEMENTATION
  50 entity makeNexuizMapList()
  51 {
  52         entity me;
  53         me = spawnNexuizMapList();
  54         me.configureNexuizMapList(me);
  55         return me;
  56 }
  57 void configureNexuizMapListNexuizMapList(entity me)
  58 {
  59         me.configureNexuizListBox(me);
  60         me.refilter(me);
  61 }
  62
  63 void loadCvarsNexuizMapList(entity me)
  64 {
  65         me.refilter(me);
  66 }
  67
  68 float g_maplistCacheQueryNexuizMapList(entity me, float i)
  69 {
  70         return stof(substring(me.g_maplistCache, i, 1));
  71 }
  72 void g_maplistCacheToggleNexuizMapList(entity me, float i)
  73 {
  74         string a, b, c, s, bspname;
  75         float n;
  76         s = me.g_maplistCache;
  77         if not(s)
  78                 return;
  79         b = substring(s, i, 1);
  80         if(b == "0")
  81                 b = "1";
  82         else if(b == "1")
  83                 b = "0";
  84         else
  85                 return; // nothing happens
  86         a = substring(s, 0, i);
  87         c = substring(s, i+1, strlen(s) - (i+1));
  88         strunzone(s);
  89         me.g_maplistCache = strzone(strcat(a, b, c));
  90         // TODO also update the actual cvar
  91         if not((bspname = MapInfo_BSPName_ByID(i)))
  92                 return;
  93         if(b == "1")
  94                 cvar_set("g_maplist", strcat(bspname, " ", cvar_string("g_maplist")));
  95         else
  96         {
  97                 s = "";
  98                 n = tokenize(cvar_string("g_maplist"));
  99                 for(i = 0; i < n; ++i)
 100                         if(argv(i) != bspname)
 101                                 s = strcat(s, " ", argv(i));
 102                 cvar_set("g_maplist", substring(s, 1, strlen(s) - 1));
 103         }
 104 }
 105
 106 void drawNexuizMapList(entity me)
 107 {
 108         if(me.startButton)
 109                 me.startButton.disabled = ((me.selectedItem < 0) || (me.selectedItem >= me.nItems));
 110         drawListBox(me);
 111 }
 112
 113 void resizeNotifyNexuizMapList(entity me, vector relOrigin, vector relSize, vector absOrigin, vector absSize)
 114 {
 115         me.origin = absOrigin;
 116         me.itemAbsSize = '0 0 0';
 117         resizeNotifyNexuizListBox(me, relOrigin, relSize, absOrigin, absSize);
 118
 119         me.realFontSize_y = me.fontSize / (me.itemAbsSize_y = (absSize_y * me.itemHeight));
 120         me.realFontSize_x = me.fontSize / (me.itemAbsSize_x = (absSize_x * (1 - me.controlWidth)));
 121         me.realUpperMargin1 = 0.5 * (1 - 2.5 * me.realFontSize_y);
 122         me.realUpperMargin2 = me.realUpperMargin1 + 1.5 * me.realFontSize_y;
 123
 124         me.columnPreviewOrigin = 0;
 125         me.columnPreviewSize = me.itemAbsSize_y / me.itemAbsSize_x * 4 / 3;
 126         me.columnNameOrigin = me.columnPreviewOrigin + me.columnPreviewSize + me.realFontSize_x;
 127         me.columnNameSize = 1 - me.columnPreviewSize - 2 * me.realFontSize_x;
 128
 129         me.checkMarkSize = (eX * (me.itemAbsSize_y / me.itemAbsSize_x) + eY) * 0.5;
 130         me.checkMarkOrigin = eY + eX * (me.columnPreviewOrigin + me.columnPreviewSize) - me.checkMarkSize;
 131 }
 132 void clickListBoxItemNexuizMapList(entity me, float i, vector where)
 133 {
 134         if(where_x <= me.columnPreviewOrigin + me.columnPreviewSize)
 135         {
 136                 if(where_x >= 0)
 137                         me.g_maplistCacheToggle(me, i);
 138         }
 139         if(where_x >= me.columnNameOrigin)
 140                 if(where_x <= 1)
 141                         {
 142                                 if(i == me.lastClickedMap)
 143                                         if(time < me.lastClickedTime + 0.3)
 144                                         {
 145                                                 // DOUBLE CLICK!
 146                                                 // pop up map info screen
 147                                                 main.mapInfoDialog.loadMapInfo(main.mapInfoDialog, i);
 148                                                 DialogOpenButton_Click_withCoords(NULL, main.mapInfoDialog, me.origin + eX * (me.columnNameOrigin * me.size_x) + eY * ((me.itemHeight * i - me.scrollPos) * me.size_y), eY * me.itemAbsSize_y + eX * (me.itemAbsSize_x * me.columnNameSize));
 149                                                 return;
 150                                         }
 151                                 me.lastClickedMap = i;
 152                                 me.lastClickedTime = time;
 153                         }
 154 }
 155 void drawListBoxItemNexuizMapList(entity me, float i, vector absSize, float isSelected)
 156 {
 157         // layout: Ping, Map name, Map name, NP, TP, MP
 158         string s;
 159         float p;
 160         float theAlpha;
 161         float included;
 162
 163         if(!MapInfo_Get_ByID(i))
 164                 return;
 165
 166         included = me.g_maplistCacheQuery(me, i);
 167         if(included)
 168                 theAlpha = SKINALPHA_MAPLIST_INCLUDEDFG;
 169         else
 170                 theAlpha = SKINALPHA_MAPLIST_NOTINCLUDEDFG;
 171
 172         if(isSelected)
 173                 draw_Fill('0 0 0', '1 1 0', SKINCOLOR_LISTBOX_SELECTED, SKINALPHA_LISTBOX_SELECTED);
 174         else if(included)
 175                 draw_Fill('0 0 0', '1 1 0', SKINCOLOR_MAPLIST_INCLUDEDBG, SKINALPHA_MAPLIST_INCLUDEDBG);
 176
 177         s = ftos(p);
 178         draw_Picture(me.columnPreviewOrigin * eX, strcat("/maps/", MapInfo_Map_bspname), me.columnPreviewSize * eX + eY, '1 1 1', theAlpha);
 179         if(included)
 180                 draw_Picture(me.checkMarkOrigin, "checkmark", me.checkMarkSize, '1 1 1', 1);
 181         s = draw_TextShortenToWidth(strcat(MapInfo_Map_bspname, ": ", MapInfo_Map_title), me.columnNameSize / me.realFontSize_x, 0);
 182         draw_Text(me.realUpperMargin1 * eY + (me.columnNameOrigin + 0.00 * (me.columnNameSize - draw_TextWidth(s, 0) * me.realFontSize_x)) * eX, s, me.realFontSize, SKINCOLOR_MAPLIST_TITLE, theAlpha, 0);
 183         s = draw_TextShortenToWidth(MapInfo_Map_author, me.columnNameSize / me.realFontSize_x, 0);
 184         draw_Text(me.realUpperMargin2 * eY + (me.columnNameOrigin + 1.00 * (me.columnNameSize - draw_TextWidth(s, 0) * me.realFontSize_x)) * eX, s, me.realFontSize, SKINCOLOR_MAPLIST_AUTHOR, theAlpha, 0);
 185 }
 186
 187 void refilterNexuizMapList(entity me)
 188 {
 189         float i, j, n;
 190         string s;
 191         float gt, f;
 192         gt = MapInfo_CurrentGametype();
 193         f = MapInfo_CurrentFeatures();
 194         MapInfo_FilterGametype(gt, f, 0);
 195         me.nItems = MapInfo_count;
 196         for(i = 0; i < MapInfo_count; ++i)
 197                 draw_PreloadPicture(strcat("/maps/", MapInfo_BSPName_ByID(i)));
 198         if(me.g_maplistCache)
 199                 strunzone(me.g_maplistCache);
 200         s = "0";
 201         for(i = 1; i < MapInfo_count; i *= 2)
 202                 s = strcat(s, s);
 203         n = tokenize(cvar_string("g_maplist"));
 204         for(i = 0; i < n; ++i)
 205         {
 206                 j = MapInfo_FindName(argv(i));
 207                 if(j >= 0)
 208                         s = strcat(
 209                                 substring(s, 0, j),
 210                                 "1",
 211                                 substring(s, j+1, MapInfo_count - (j+1))
 212                         );
 213         }
 214         me.g_maplistCache = strzone(s);
 215         if(gt != me.lastGametype || f != me.lastFeatures)
 216         {
 217                 me.lastGametype = gt;
 218                 me.lastFeatures = f;
 219                 me.setSelected(me, 0);
 220         }
 221 }
 222 void MapList_All(entity btn, entity me)
 223 {
 224         float i;
 225         string s;
 226         MapInfo_FilterGametype(MAPINFO_TYPE_ALL, 0, 0); // all
 227         s = "";
 228         for(i = 0; i < MapInfo_count; ++i)
 229                 s = strcat(s, " ", MapInfo_BSPName_ByID(i));
 230         cvar_set("g_maplist", substring(s, 1, strlen(s) - 1));
 231         me.refilter(me);
 232 }
 233 void MapList_None(entity btn, entity me)
 234 {
 235         cvar_set("g_maplist", "");
 236         me.refilter(me);
 237 }
 238 void MapList_LoadMap(entity btn, entity me)
 239 {
 240         string m;
 241         if(me.selectedItem >= me.nItems || me.selectedItem < 0)
 242                 return;
 243         m = MapInfo_BSPName_ByID(me.selectedItem);
 244         if not(m)
 245                 return;
 246         if(MapInfo_CheckMap(m))
 247         {
 248                 localcmd("\ndisconnect\nwait\nmaxplayers $menu_maxplayers\ng_maplist_shufflenow\n");
 249                 MapInfo_LoadMap(m);
 250         }
 251         else
 252         {
 253                 print("Huh? Can't play this. Refiltering so this won't happen again.\n");
 254                 me.refilter(me);
 255         }
 256 }
 257
 258 float keyDownNexuizMapList(entity me, float scan, float ascii, float shift)
 259 {
 260         string ch, save;
 261         if(scan == K_ENTER)
 262         {
 263                 // pop up map info screen
 264                 main.mapInfoDialog.loadMapInfo(main.mapInfoDialog, me.selectedItem);
 265                 DialogOpenButton_Click_withCoords(NULL, main.mapInfoDialog, me.origin + eX * (me.columnNameOrigin * me.size_x) + eY * ((me.itemHeight * me.selectedItem - me.scrollPos) * me.size_y), eY * me.itemAbsSize_y + eX * (me.itemAbsSize_x * me.columnNameSize));
 266         }
 267         else if(scan == K_SPACE)
 268         {
 269                 me.g_maplistCacheToggle(me, me.selectedItem);
 270         }
 271         else if(ascii == 43) // +
 272         {
 273                 if not(me.g_maplistCacheQuery(me, me.selectedItem))
 274                         me.g_maplistCacheToggle(me, me.selectedItem);
 275         }
 276         else if(ascii == 45) // -
 277         {
 278                 if(me.g_maplistCacheQuery(me, me.selectedItem))
 279                         me.g_maplistCacheToggle(me, me.selectedItem);
 280         }
 281         else if(scan == K_BACKSPACE)
 282         {
 283                 if(time < me.typeToSearchTime)
 284                 {
 285                         save = substring(me.typeToSearchString, 0, strlen(me.typeToSearchString) - 1);
 286                         if(me.typeToSearchString)
 287                                 strunzone(me.typeToSearchString);
 288                         me.typeToSearchString = strzone(save);
 289                         me.typeToSearchTime = time + 0.5;
 290                         if(strlen(me.typeToSearchString))
 291                         {
 292                                 MapInfo_FindName(me.typeToSearchString);
 293                                 if(MapInfo_FindName_firstResult >= 0)
 294                                         me.setSelected(me, MapInfo_FindName_firstResult);
 295                         }
 296                 }
 297         }
 298         else if(ascii >= 32 && ascii != 127)
 299         {
 300                 ch = chr(ascii);
 301                 if(time > me.typeToSearchTime)
 302                         save = ch;
 303                 else
 304                         save = strcat(me.typeToSearchString, ch);
 305                 if(me.typeToSearchString)
 306                         strunzone(me.typeToSearchString);
 307                 me.typeToSearchString = strzone(save);
 308                 me.typeToSearchTime = time + 0.5;
 309                 MapInfo_FindName(me.typeToSearchString);
 310                 if(MapInfo_FindName_firstResult >= 0)
 311                         me.setSelected(me, MapInfo_FindName_firstResult);
 312         }
 313         else
 314                 return keyDownListBox(me, scan, ascii, shift);
 315         return 1;
 316 }
 317 #endif